src/HOL/Tools/specification_package.ML
author wenzelm
Thu Aug 03 17:30:36 2006 +0200 (2006-08-03)
changeset 20328 5b240a4216b0
parent 19876 11d447d5d68c
child 20344 d02b43ea722e
permissions -rw-r--r--
RuleInsts.bires_inst_tac;
     1 (*  Title:      HOL/Tools/specification_package.ML
     2     ID:         $Id$
     3     Author:     Sebastian Skalberg, TU Muenchen
     4 
     5 Package for defining constants by specification.
     6 *)
     7 
     8 signature SPECIFICATION_PACKAGE =
     9 sig
    10   val quiet_mode: bool ref
    11   val add_specification: string option -> (bstring * xstring * bool) list ->
    12     theory * thm -> theory * thm
    13 end
    14 
    15 structure SpecificationPackage: SPECIFICATION_PACKAGE =
    16 struct
    17 
    18 (* messages *)
    19 
    20 val quiet_mode = ref false
    21 fun message s = if ! quiet_mode then () else writeln s
    22 
    23 
    24 (* Actual code *)
    25 
    26 local
    27     val exE_some = thm "exE_some";
    28 
    29     fun mk_definitional [] arg = arg
    30       | mk_definitional ((thname,cname,covld)::cos) (thy,thm) =
    31         case HOLogic.dest_Trueprop (concl_of thm) of
    32             Const("Ex",_) $ P =>
    33             let
    34                 val ctype = domain_type (type_of P)
    35                 val cname_full = Sign.intern_const (sign_of thy) cname
    36                 val cdefname = if thname = ""
    37                                then Thm.def_name (Sign.base_name cname)
    38                                else thname
    39                 val def_eq = Logic.mk_equals (Const(cname_full,ctype),
    40                                               HOLogic.choice_const ctype $  P)
    41                 val (thms, thy') = PureThy.add_defs_i covld [((cdefname,def_eq),[])] thy
    42                 val thm' = [thm,hd thms] MRS exE_some
    43             in
    44                 mk_definitional cos (thy',thm')
    45             end
    46           | _ => raise THM ("Internal error: Bad specification theorem",0,[thm])
    47 
    48     fun mk_axiomatic axname cos arg =
    49         let
    50             fun process [] (thy,tm) =
    51                 let
    52                     val (thms, thy') = PureThy.add_axioms_i [((axname,HOLogic.mk_Trueprop tm),[])] thy
    53                 in
    54                     (thy',hd thms)
    55                 end
    56               | process ((thname,cname,covld)::cos) (thy,tm) =
    57                 case tm of
    58                     Const("Ex",_) $ P =>
    59                     let
    60                         val ctype = domain_type (type_of P)
    61                         val cname_full = Sign.intern_const (sign_of thy) cname
    62                         val cdefname = if thname = ""
    63                                        then Thm.def_name (Sign.base_name cname)
    64                                        else thname
    65                         val co = Const(cname_full,ctype)
    66                         val thy' = Theory.add_finals_i covld [co] thy
    67                         val tm' = case P of
    68                                       Abs(_, _, bodt) => subst_bound (co, bodt)
    69                                     | _ => P $ co
    70                     in
    71                         process cos (thy',tm')
    72                     end
    73                   | _ => raise TERM ("Internal error: Bad specification theorem",[tm])
    74         in
    75             process cos arg
    76         end
    77 
    78 in
    79 fun proc_exprop axiomatic cos arg =
    80     case axiomatic of
    81         SOME axname => mk_axiomatic axname cos (apsnd (HOLogic.dest_Trueprop o concl_of) arg)
    82       | NONE => mk_definitional cos arg
    83 end
    84 
    85 fun add_specification axiomatic cos arg =
    86     arg |> apsnd Thm.freezeT
    87         |> proc_exprop axiomatic cos
    88         |> apsnd standard
    89 
    90 fun add_spec x y (context, thm) =
    91   (Context.the_theory context, thm) |> add_specification x y |>> Context.Theory;
    92 
    93 
    94 (* Collect all intances of constants in term *)
    95 
    96 fun collect_consts (        t $ u,tms) = collect_consts (u,collect_consts (t,tms))
    97   | collect_consts (   Abs(_,_,t),tms) = collect_consts (t,tms)
    98   | collect_consts (tm as Const _,tms) = insert (op aconv) tm tms
    99   | collect_consts (            _,tms) = tms
   100 
   101 (* Complementing Type.varify... *)
   102 
   103 fun unvarify t fmap =
   104     let
   105         val fmap' = map Library.swap fmap
   106         fun unthaw (f as (a, S)) =
   107             (case AList.lookup (op =) fmap' a of
   108                  NONE => TVar f
   109                | SOME (b, _) => TFree (b, S))
   110     in
   111         map_term_types (map_type_tvar unthaw) t
   112     end
   113 
   114 (* The syntactic meddling needed to setup add_specification for work *)
   115 
   116 fun process_spec axiomatic cos alt_props thy =
   117     let
   118         fun zip3 [] [] [] = []
   119           | zip3 (x::xs) (y::ys) (z::zs) = (x,y,z)::zip3 xs ys zs
   120           | zip3 _ _ _ = error "SpecificationPackage.process_spec internal error"
   121 
   122         fun myfoldr f [x] = x
   123           | myfoldr f (x::xs) = f (x,myfoldr f xs)
   124           | myfoldr f [] = error "SpecificationPackage.process_spec internal error"
   125 
   126         val rew_imps = alt_props |>
   127           map (ObjectLogic.atomize_cterm o Thm.read_cterm thy o rpair Term.propT o snd)
   128         val props' = rew_imps |>
   129           map (HOLogic.dest_Trueprop o term_of o snd o dest_equals o cprop_of)
   130 
   131         fun proc_single prop =
   132             let
   133                 val frees = Term.term_frees prop
   134                 val tsig = Sign.tsig_of (sign_of thy)
   135                 val _ = assert (forall (fn v => Type.of_sort tsig (type_of v,HOLogic.typeS)) frees)
   136                                "Specificaton: Only free variables of sort 'type' allowed"
   137                 val prop_closed = foldr (fn ((vname,T),prop) => HOLogic.mk_all (vname,T,prop)) prop (map dest_Free frees)
   138             in
   139                 (prop_closed,frees)
   140             end
   141 
   142         val props'' = map proc_single props'
   143         val frees = map snd props''
   144         val prop  = myfoldr HOLogic.mk_conj (map fst props'')
   145         val cprop = cterm_of thy (HOLogic.mk_Trueprop prop)
   146 
   147         val (prop_thawed,vmap) = Type.varify (prop,[])
   148         val thawed_prop_consts = collect_consts (prop_thawed,[])
   149         val (altcos,overloaded) = Library.split_list cos
   150         val (names,sconsts) = Library.split_list altcos
   151         val consts = map (term_of o Thm.read_cterm thy o rpair TypeInfer.logicT) sconsts
   152         val _ = assert (not (Library.exists (not o Term.is_Const) consts))
   153                        "Specification: Non-constant found as parameter"
   154 
   155         fun proc_const c =
   156             let
   157                 val c' = fst (Type.varify (c,[]))
   158                 val (cname,ctyp) = dest_Const c'
   159             in
   160                 case List.filter (fn t => let val (name,typ) = dest_Const t
   161                                      in name = cname andalso Sign.typ_equiv thy (typ, ctyp)
   162                                      end) thawed_prop_consts of
   163                     [] => error ("Specification: No suitable instances of constant \"" ^ (Sign.string_of_term thy c) ^ "\" found")
   164                   | [cf] => unvarify cf vmap
   165                   | _ => error ("Specification: Several variations of \"" ^ (Sign.string_of_term thy c) ^ "\" found (try applying explicit type constraints)")
   166             end
   167         val proc_consts = map proc_const consts
   168         fun mk_exist (c,prop) =
   169             let
   170                 val T = type_of c
   171                 val cname = Sign.base_name (fst (dest_Const c))
   172                 val vname = if Syntax.is_identifier cname
   173                             then cname
   174                             else "x"
   175             in
   176                 HOLogic.exists_const T $ Abs(vname,T,Term.abstract_over (c,prop))
   177             end
   178         val ex_prop = foldr mk_exist prop proc_consts
   179         val cnames = map (fst o dest_Const) proc_consts
   180         fun post_process (arg as (thy,thm)) =
   181             let
   182                 fun inst_all thy (thm,v) =
   183                     let
   184                         val cv = cterm_of thy v
   185                         val cT = ctyp_of_term cv
   186                         val spec' = instantiate' [SOME cT] [NONE,SOME cv] spec
   187                     in
   188                         thm RS spec'
   189                     end
   190                 fun remove_alls frees thm = Library.foldl (inst_all (sign_of_thm thm)) (thm,frees)
   191                 fun process_single ((name,atts),rew_imp,frees) args =
   192                     let
   193                         fun undo_imps thm =
   194                             equal_elim (symmetric rew_imp) thm
   195 
   196                         fun add_final (arg as (thy, thm)) =
   197                             if name = ""
   198                             then arg |> Library.swap
   199                             else (writeln ("  " ^ name ^ ": " ^ (string_of_thm thm));
   200                                   PureThy.store_thm ((name, thm), []) thy)
   201                     in
   202                         args |> apsnd (remove_alls frees)
   203                              |> apsnd undo_imps
   204                              |> apsnd standard
   205                              |> Thm.theory_attributes (map (Attrib.attribute thy) atts)
   206                              |> add_final
   207                              |> Library.swap
   208                     end
   209 
   210                 fun process_all [proc_arg] args =
   211                     process_single proc_arg args
   212                   | process_all (proc_arg::rest) (thy,thm) =
   213                     let
   214                         val single_th = thm RS conjunct1
   215                         val rest_th   = thm RS conjunct2
   216                         val (thy',_)  = process_single proc_arg (thy,single_th)
   217                     in
   218                         process_all rest (thy',rest_th)
   219                     end
   220                   | process_all [] _ = error "SpecificationPackage.process_spec internal error"
   221                 val alt_names = map fst alt_props
   222                 val _ = if exists (fn(name,_) => not (name = "")) alt_names
   223                         then writeln "specification"
   224                         else ()
   225             in
   226                 arg |> apsnd Thm.freezeT
   227                     |> process_all (zip3 alt_names rew_imps frees)
   228             end
   229             fun post_proc (context, th) =
   230                 post_process (Context.theory_of context, th) |>> Context.Theory;
   231     in
   232       IsarThy.theorem_i PureThy.internalK
   233         ("", [add_spec axiomatic (zip3 names cnames overloaded), post_proc])
   234         (HOLogic.mk_Trueprop ex_prop, []) thy
   235     end
   236 
   237 
   238 (* outer syntax *)
   239 
   240 local structure P = OuterParse and K = OuterKeyword in
   241 
   242 val opt_name = Scan.optional (P.name --| P.$$$ ":") ""
   243 val opt_overloaded = P.opt_keyword "overloaded";
   244 
   245 val specification_decl =
   246   P.$$$ "(" |-- Scan.repeat1 (opt_name -- P.term -- opt_overloaded) --| P.$$$ ")" --
   247           Scan.repeat1 (P.opt_thm_name ":" -- P.prop)
   248 
   249 val specificationP =
   250   OuterSyntax.command "specification" "define constants by specification" K.thy_goal
   251     (specification_decl >> (fn (cos,alt_props) =>
   252                                Toplevel.print o (Toplevel.theory_to_proof
   253                                                      (process_spec NONE cos alt_props))))
   254 
   255 val ax_specification_decl =
   256     P.name --
   257     (P.$$$ "(" |-- Scan.repeat1 (opt_name -- P.term -- opt_overloaded) --| P.$$$ ")" --
   258            Scan.repeat1 (P.opt_thm_name ":" -- P.prop))
   259 
   260 val ax_specificationP =
   261   OuterSyntax.command "ax_specification" "define constants by specification" K.thy_goal
   262     (ax_specification_decl >> (fn (axname,(cos,alt_props)) =>
   263                                Toplevel.print o (Toplevel.theory_to_proof
   264                                                      (process_spec (SOME axname) cos alt_props))))
   265 
   266 val _ = OuterSyntax.add_parsers [specificationP,ax_specificationP]
   267 
   268 end
   269 
   270 
   271 end