src/HOL/Nominal/nominal_inductive.ML
author blanchet
Wed Mar 04 10:45:52 2009 +0100 (2009-03-04)
changeset 30240 5b25fee0362c
parent 29585 c23295521af5
child 30242 aea5d7fa7ef5
permissions -rw-r--r--
Merge.
     1 (*  Title:      HOL/Nominal/nominal_inductive.ML
     2     Author:     Stefan Berghofer, TU Muenchen
     3 
     4 Infrastructure for proving equivariance and strong induction theorems
     5 for inductive predicates involving nominal datatypes.
     6 *)
     7 
     8 signature NOMINAL_INDUCTIVE =
     9 sig
    10   val prove_strong_ind: string -> (string * string list) list -> local_theory -> Proof.state
    11   val prove_eqvt: string -> string list -> local_theory -> local_theory
    12 end
    13 
    14 structure NominalInductive : NOMINAL_INDUCTIVE =
    15 struct
    16 
    17 val inductive_forall_name = "HOL.induct_forall";
    18 val inductive_forall_def = thm "induct_forall_def";
    19 val inductive_atomize = thms "induct_atomize";
    20 val inductive_rulify = thms "induct_rulify";
    21 
    22 fun rulify_term thy = MetaSimplifier.rewrite_term thy inductive_rulify [];
    23 
    24 val atomize_conv =
    25   MetaSimplifier.rewrite_cterm (true, false, false) (K (K NONE))
    26     (HOL_basic_ss addsimps inductive_atomize);
    27 val atomize_intr = Conv.fconv_rule (Conv.prems_conv ~1 atomize_conv);
    28 fun atomize_induct ctxt = Conv.fconv_rule (Conv.prems_conv ~1
    29   (Conv.params_conv ~1 (K (Conv.prems_conv ~1 atomize_conv)) ctxt));
    30 
    31 fun preds_of ps t = gen_inter (op = o apfst dest_Free) (ps, Term.add_frees t []);
    32 
    33 val fresh_prod = thm "fresh_prod";
    34 
    35 val perm_bool = mk_meta_eq (thm "perm_bool");
    36 val perm_boolI = thm "perm_boolI";
    37 val (_, [perm_boolI_pi, _]) = Drule.strip_comb (snd (Thm.dest_comb
    38   (Drule.strip_imp_concl (cprop_of perm_boolI))));
    39 
    40 fun mk_perm_bool pi th = th RS Drule.cterm_instantiate
    41   [(perm_boolI_pi, pi)] perm_boolI;
    42 
    43 fun mk_perm_bool_simproc names = Simplifier.simproc_i
    44   (theory_of_thm perm_bool) "perm_bool" [@{term "perm pi x"}] (fn thy => fn ss =>
    45     fn Const ("Nominal.perm", _) $ _ $ t =>
    46          if the_default "" (try (head_of #> dest_Const #> fst) t) mem names
    47          then SOME perm_bool else NONE
    48      | _ => NONE);
    49 
    50 fun transp ([] :: _) = []
    51   | transp xs = map hd xs :: transp (map tl xs);
    52 
    53 fun add_binders thy i (t as (_ $ _)) bs = (case strip_comb t of
    54       (Const (s, T), ts) => (case strip_type T of
    55         (Ts, Type (tname, _)) =>
    56           (case NominalPackage.get_nominal_datatype thy tname of
    57              NONE => fold (add_binders thy i) ts bs
    58            | SOME {descr, index, ...} => (case AList.lookup op =
    59                  (#3 (the (AList.lookup op = descr index))) s of
    60                NONE => fold (add_binders thy i) ts bs
    61              | SOME cargs => fst (fold (fn (xs, x) => fn (bs', cargs') =>
    62                  let val (cargs1, (u, _) :: cargs2) = chop (length xs) cargs'
    63                  in (add_binders thy i u
    64                    (fold (fn (u, T) =>
    65                       if exists (fn j => j < i) (loose_bnos u) then I
    66                       else insert (op aconv o pairself fst)
    67                         (incr_boundvars (~i) u, T)) cargs1 bs'), cargs2)
    68                  end) cargs (bs, ts ~~ Ts))))
    69       | _ => fold (add_binders thy i) ts bs)
    70     | (u, ts) => add_binders thy i u (fold (add_binders thy i) ts bs))
    71   | add_binders thy i (Abs (_, _, t)) bs = add_binders thy (i + 1) t bs
    72   | add_binders thy i _ bs = bs;
    73 
    74 fun split_conj f names (Const ("op &", _) $ p $ q) _ = (case head_of p of
    75       Const (name, _) =>
    76         if name mem names then SOME (f p q) else NONE
    77     | _ => NONE)
    78   | split_conj _ _ _ _ = NONE;
    79 
    80 fun strip_all [] t = t
    81   | strip_all (_ :: xs) (Const ("All", _) $ Abs (s, T, t)) = strip_all xs t;
    82 
    83 (*********************************************************************)
    84 (* maps  R ... & (ALL pi_1 ... pi_n z. P z (pi_1 o ... o pi_n o t))  *)
    85 (* or    ALL pi_1 ... pi_n z. P z (pi_1 o ... o pi_n o t)            *)
    86 (* to    R ... & id (ALL z. P z (pi_1 o ... o pi_n o t))             *)
    87 (* or    id (ALL z. P z (pi_1 o ... o pi_n o t))                     *)
    88 (*                                                                   *)
    89 (* where "id" protects the subformula from simplification            *)
    90 (*********************************************************************)
    91 
    92 fun inst_conj_all names ps pis (Const ("op &", _) $ p $ q) _ =
    93       (case head_of p of
    94          Const (name, _) =>
    95            if name mem names then SOME (HOLogic.mk_conj (p,
    96              Const ("Fun.id", HOLogic.boolT --> HOLogic.boolT) $
    97                (subst_bounds (pis, strip_all pis q))))
    98            else NONE
    99        | _ => NONE)
   100   | inst_conj_all names ps pis t u =
   101       if member (op aconv) ps (head_of u) then
   102         SOME (Const ("Fun.id", HOLogic.boolT --> HOLogic.boolT) $
   103           (subst_bounds (pis, strip_all pis t)))
   104       else NONE
   105   | inst_conj_all _ _ _ _ _ = NONE;
   106 
   107 fun inst_conj_all_tac k = EVERY
   108   [TRY (EVERY [etac conjE 1, rtac conjI 1, atac 1]),
   109    REPEAT_DETERM_N k (etac allE 1),
   110    simp_tac (HOL_basic_ss addsimps [@{thm id_apply}]) 1];
   111 
   112 fun map_term f t u = (case f t u of
   113       NONE => map_term' f t u | x => x)
   114 and map_term' f (t $ u) (t' $ u') = (case (map_term f t t', map_term f u u') of
   115       (NONE, NONE) => NONE
   116     | (SOME t'', NONE) => SOME (t'' $ u)
   117     | (NONE, SOME u'') => SOME (t $ u'')
   118     | (SOME t'', SOME u'') => SOME (t'' $ u''))
   119   | map_term' f (Abs (s, T, t)) (Abs (s', T', t')) = (case map_term f t t' of
   120       NONE => NONE
   121     | SOME t'' => SOME (Abs (s, T, t'')))
   122   | map_term' _ _ _ = NONE;
   123 
   124 (*********************************************************************)
   125 (*         Prove  F[f t]  from  F[t],  where F is monotone           *)
   126 (*********************************************************************)
   127 
   128 fun map_thm ctxt f tac monos opt th =
   129   let
   130     val prop = prop_of th;
   131     fun prove t =
   132       Goal.prove ctxt [] [] t (fn _ =>
   133         EVERY [cut_facts_tac [th] 1, etac rev_mp 1,
   134           REPEAT_DETERM (FIRSTGOAL (resolve_tac monos)),
   135           REPEAT_DETERM (rtac impI 1 THEN (atac 1 ORELSE tac))])
   136   in Option.map prove (map_term f prop (the_default prop opt)) end;
   137 
   138 val eta_contract_cterm = Thm.dest_arg o Thm.cprop_of o Thm.eta_conversion;
   139 
   140 fun first_order_matchs pats objs = Thm.first_order_match
   141   (eta_contract_cterm (Conjunction.mk_conjunction_balanced pats),
   142    eta_contract_cterm (Conjunction.mk_conjunction_balanced objs));
   143 
   144 fun first_order_mrs ths th = ths MRS
   145   Thm.instantiate (first_order_matchs (cprems_of th) (map cprop_of ths)) th;
   146 
   147 fun prove_strong_ind s avoids ctxt =
   148   let
   149     val thy = ProofContext.theory_of ctxt;
   150     val ({names, ...}, {raw_induct, intrs, elims, ...}) =
   151       InductivePackage.the_inductive ctxt (Sign.intern_const thy s);
   152     val ind_params = InductivePackage.params_of raw_induct;
   153     val raw_induct = atomize_induct ctxt raw_induct;
   154     val elims = map (atomize_induct ctxt) elims;
   155     val monos = InductivePackage.get_monos ctxt;
   156     val eqvt_thms = NominalThmDecls.get_eqvt_thms ctxt;
   157     val _ = (case names \\ fold (Term.add_const_names o Thm.prop_of) eqvt_thms [] of
   158         [] => ()
   159       | xs => error ("Missing equivariance theorem for predicate(s): " ^
   160           commas_quote xs));
   161     val induct_cases = map fst (fst (RuleCases.get (the
   162       (Induct.lookup_inductP ctxt (hd names)))));
   163     val ([raw_induct'], ctxt') = Variable.import_terms false [prop_of raw_induct] ctxt;
   164     val concls = raw_induct' |> Logic.strip_imp_concl |> HOLogic.dest_Trueprop |>
   165       HOLogic.dest_conj |> map (HOLogic.dest_imp ##> strip_comb);
   166     val ps = map (fst o snd) concls;
   167 
   168     val _ = (case duplicates (op = o pairself fst) avoids of
   169         [] => ()
   170       | xs => error ("Duplicate case names: " ^ commas_quote (map fst xs)));
   171     val _ = assert_all (null o duplicates op = o snd) avoids
   172       (fn (a, _) => error ("Duplicate variable names for case " ^ quote a));
   173     val _ = (case map fst avoids \\ induct_cases of
   174         [] => ()
   175       | xs => error ("No such case(s) in inductive definition: " ^ commas_quote xs));
   176     val avoids' = if null induct_cases then replicate (length intrs) ("", [])
   177       else map (fn name =>
   178         (name, the_default [] (AList.lookup op = avoids name))) induct_cases;
   179     fun mk_avoids params (name, ps) =
   180       let val k = length params - 1
   181       in map (fn x => case find_index (equal x o fst) params of
   182           ~1 => error ("No such variable in case " ^ quote name ^
   183             " of inductive definition: " ^ quote x)
   184         | i => (Bound (k - i), snd (nth params i))) ps
   185       end;
   186 
   187     val prems = map (fn (prem, avoid) =>
   188       let
   189         val prems = map (incr_boundvars 1) (Logic.strip_assums_hyp prem);
   190         val concl = incr_boundvars 1 (Logic.strip_assums_concl prem);
   191         val params = Logic.strip_params prem
   192       in
   193         (params,
   194          fold (add_binders thy 0) (prems @ [concl]) [] @
   195            map (apfst (incr_boundvars 1)) (mk_avoids params avoid),
   196          prems, strip_comb (HOLogic.dest_Trueprop concl))
   197       end) (Logic.strip_imp_prems raw_induct' ~~ avoids');
   198 
   199     val atomTs = distinct op = (maps (map snd o #2) prems);
   200     val ind_sort = if null atomTs then HOLogic.typeS
   201       else Sign.certify_sort thy (map (fn T => Sign.intern_class thy
   202         ("fs_" ^ Sign.base_name (fst (dest_Type T)))) atomTs);
   203     val ([fs_ctxt_tyname], _) = Name.variants ["'n"] (Variable.names_of ctxt');
   204     val ([fs_ctxt_name], ctxt'') = Variable.variant_fixes ["z"] ctxt';
   205     val fsT = TFree (fs_ctxt_tyname, ind_sort);
   206 
   207     val inductive_forall_def' = Drule.instantiate'
   208       [SOME (ctyp_of thy fsT)] [] inductive_forall_def;
   209 
   210     fun lift_pred' t (Free (s, T)) ts =
   211       list_comb (Free (s, fsT --> T), t :: ts);
   212     val lift_pred = lift_pred' (Bound 0);
   213 
   214     fun lift_prem (t as (f $ u)) =
   215           let val (p, ts) = strip_comb t
   216           in
   217             if p mem ps then
   218               Const (inductive_forall_name,
   219                 (fsT --> HOLogic.boolT) --> HOLogic.boolT) $
   220                   Abs ("z", fsT, lift_pred p (map (incr_boundvars 1) ts))
   221             else lift_prem f $ lift_prem u
   222           end
   223       | lift_prem (Abs (s, T, t)) = Abs (s, T, lift_prem t)
   224       | lift_prem t = t;
   225 
   226     fun mk_distinct [] = []
   227       | mk_distinct ((x, T) :: xs) = List.mapPartial (fn (y, U) =>
   228           if T = U then SOME (HOLogic.mk_Trueprop
   229             (HOLogic.mk_not (HOLogic.eq_const T $ x $ y)))
   230           else NONE) xs @ mk_distinct xs;
   231 
   232     fun mk_fresh (x, T) = HOLogic.mk_Trueprop
   233       (NominalPackage.fresh_const T fsT $ x $ Bound 0);
   234 
   235     val (prems', prems'') = split_list (map (fn (params, bvars, prems, (p, ts)) =>
   236       let
   237         val params' = params @ [("y", fsT)];
   238         val prem = Logic.list_implies
   239           (map mk_fresh bvars @ mk_distinct bvars @
   240            map (fn prem =>
   241              if null (preds_of ps prem) then prem
   242              else lift_prem prem) prems,
   243            HOLogic.mk_Trueprop (lift_pred p ts));
   244         val vs = map (Var o apfst (rpair 0)) (Term.rename_wrt_term prem params')
   245       in
   246         (list_all (params', prem), (rev vs, subst_bounds (vs, prem)))
   247       end) prems);
   248 
   249     val ind_vars =
   250       (DatatypeProp.indexify_names (replicate (length atomTs) "pi") ~~
   251        map NominalAtoms.mk_permT atomTs) @ [("z", fsT)];
   252     val ind_Ts = rev (map snd ind_vars);
   253 
   254     val concl = HOLogic.mk_Trueprop (foldr1 HOLogic.mk_conj
   255       (map (fn (prem, (p, ts)) => HOLogic.mk_imp (prem,
   256         HOLogic.list_all (ind_vars, lift_pred p
   257           (map (fold_rev (NominalPackage.mk_perm ind_Ts)
   258             (map Bound (length atomTs downto 1))) ts)))) concls));
   259 
   260     val concl' = HOLogic.mk_Trueprop (foldr1 HOLogic.mk_conj
   261       (map (fn (prem, (p, ts)) => HOLogic.mk_imp (prem,
   262         lift_pred' (Free (fs_ctxt_name, fsT)) p ts)) concls));
   263 
   264     val vc_compat = map (fn (params, bvars, prems, (p, ts)) =>
   265       map (fn q => list_all (params, incr_boundvars ~1 (Logic.list_implies
   266           (List.mapPartial (fn prem =>
   267              if null (preds_of ps prem) then SOME prem
   268              else map_term (split_conj (K o I) names) prem prem) prems, q))))
   269         (mk_distinct bvars @
   270          maps (fn (t, T) => map (fn (u, U) => HOLogic.mk_Trueprop
   271            (NominalPackage.fresh_const U T $ u $ t)) bvars)
   272              (ts ~~ binder_types (fastype_of p)))) prems;
   273 
   274     val perm_pi_simp = PureThy.get_thms thy "perm_pi_simp";
   275     val pt2_atoms = map (fn aT => PureThy.get_thm thy
   276       ("pt_" ^ Sign.base_name (fst (dest_Type aT)) ^ "2")) atomTs;
   277     val eqvt_ss = Simplifier.theory_context thy HOL_basic_ss
   278       addsimps (eqvt_thms @ perm_pi_simp @ pt2_atoms)
   279       addsimprocs [mk_perm_bool_simproc ["Fun.id"],
   280         NominalPermeq.perm_simproc_app, NominalPermeq.perm_simproc_fun];
   281     val fresh_bij = PureThy.get_thms thy "fresh_bij";
   282     val perm_bij = PureThy.get_thms thy "perm_bij";
   283     val fs_atoms = map (fn aT => PureThy.get_thm thy
   284       ("fs_" ^ Sign.base_name (fst (dest_Type aT)) ^ "1")) atomTs;
   285     val exists_fresh' = PureThy.get_thms thy "exists_fresh'";
   286     val fresh_atm = PureThy.get_thms thy "fresh_atm";
   287     val swap_simps = PureThy.get_thms thy "swap_simps";
   288     val perm_fresh_fresh = PureThy.get_thms thy "perm_fresh_fresh";
   289 
   290     fun obtain_fresh_name ts T (freshs1, freshs2, ctxt) =
   291       let
   292         (** protect terms to avoid that fresh_prod interferes with  **)
   293         (** pairs used in introduction rules of inductive predicate **)
   294         fun protect t =
   295           let val T = fastype_of t in Const ("Fun.id", T --> T) $ t end;
   296         val p = foldr1 HOLogic.mk_prod (map protect ts @ freshs1);
   297         val ex = Goal.prove ctxt [] [] (HOLogic.mk_Trueprop
   298             (HOLogic.exists_const T $ Abs ("x", T,
   299               NominalPackage.fresh_const T (fastype_of p) $
   300                 Bound 0 $ p)))
   301           (fn _ => EVERY
   302             [resolve_tac exists_fresh' 1,
   303              resolve_tac fs_atoms 1]);
   304         val (([cx], ths), ctxt') = Obtain.result
   305           (fn _ => EVERY
   306             [etac exE 1,
   307              full_simp_tac (HOL_ss addsimps (fresh_prod :: fresh_atm)) 1,
   308              full_simp_tac (HOL_basic_ss addsimps [@{thm id_apply}]) 1,
   309              REPEAT (etac conjE 1)])
   310           [ex] ctxt
   311       in (freshs1 @ [term_of cx], freshs2 @ ths, ctxt') end;
   312 
   313     fun mk_ind_proof ctxt' thss =
   314       Goal.prove ctxt' [] prems' concl' (fn {prems = ihyps, context = ctxt} =>
   315         let val th = Goal.prove ctxt [] [] concl (fn {context, ...} =>
   316           rtac raw_induct 1 THEN
   317           EVERY (maps (fn ((((_, bvars, oprems, _), vc_compat_ths), ihyp), (vs, ihypt)) =>
   318             [REPEAT (rtac allI 1), simp_tac eqvt_ss 1,
   319              SUBPROOF (fn {prems = gprems, params, concl, context = ctxt', ...} =>
   320                let
   321                  val (params', (pis, z)) =
   322                    chop (length params - length atomTs - 1) (map term_of params) ||>
   323                    split_last;
   324                  val bvars' = map
   325                    (fn (Bound i, T) => (nth params' (length params' - i), T)
   326                      | (t, T) => (t, T)) bvars;
   327                  val pi_bvars = map (fn (t, _) =>
   328                    fold_rev (NominalPackage.mk_perm []) pis t) bvars';
   329                  val (P, ts) = strip_comb (HOLogic.dest_Trueprop (term_of concl));
   330                  val (freshs1, freshs2, ctxt'') = fold
   331                    (obtain_fresh_name (ts @ pi_bvars))
   332                    (map snd bvars') ([], [], ctxt');
   333                  val freshs2' = NominalPackage.mk_not_sym freshs2;
   334                  val pis' = map NominalPackage.perm_of_pair (pi_bvars ~~ freshs1);
   335                  fun concat_perm pi1 pi2 =
   336                    let val T = fastype_of pi1
   337                    in if T = fastype_of pi2 then
   338                        Const ("List.append", T --> T --> T) $ pi1 $ pi2
   339                      else pi2
   340                    end;
   341                  val pis'' = fold (concat_perm #> map) pis' pis;
   342                  val env = Pattern.first_order_match thy (ihypt, prop_of ihyp)
   343                    (Vartab.empty, Vartab.empty);
   344                  val ihyp' = Thm.instantiate ([], map (pairself (cterm_of thy))
   345                    (map (Envir.subst_vars env) vs ~~
   346                     map (fold_rev (NominalPackage.mk_perm [])
   347                       (rev pis' @ pis)) params' @ [z])) ihyp;
   348                  fun mk_pi th =
   349                    Simplifier.simplify (HOL_basic_ss addsimps [@{thm id_apply}]
   350                        addsimprocs [NominalPackage.perm_simproc])
   351                      (Simplifier.simplify eqvt_ss
   352                        (fold_rev (mk_perm_bool o cterm_of thy)
   353                          (rev pis' @ pis) th));
   354                  val (gprems1, gprems2) = split_list
   355                    (map (fn (th, t) =>
   356                       if null (preds_of ps t) then (SOME th, mk_pi th)
   357                       else
   358                         (map_thm ctxt (split_conj (K o I) names)
   359                            (etac conjunct1 1) monos NONE th,
   360                          mk_pi (the (map_thm ctxt (inst_conj_all names ps (rev pis''))
   361                            (inst_conj_all_tac (length pis'')) monos (SOME t) th))))
   362                       (gprems ~~ oprems)) |>> List.mapPartial I;
   363                  val vc_compat_ths' = map (fn th =>
   364                    let
   365                      val th' = first_order_mrs gprems1 th;
   366                      val (bop, lhs, rhs) = (case concl_of th' of
   367                          _ $ (fresh $ lhs $ rhs) =>
   368                            (fn t => fn u => fresh $ t $ u, lhs, rhs)
   369                        | _ $ (_ $ (_ $ lhs $ rhs)) =>
   370                            (curry (HOLogic.mk_not o HOLogic.mk_eq), lhs, rhs));
   371                      val th'' = Goal.prove ctxt'' [] [] (HOLogic.mk_Trueprop
   372                          (bop (fold_rev (NominalPackage.mk_perm []) pis lhs)
   373                             (fold_rev (NominalPackage.mk_perm []) pis rhs)))
   374                        (fn _ => simp_tac (HOL_basic_ss addsimps
   375                           (fresh_bij @ perm_bij)) 1 THEN rtac th' 1)
   376                    in Simplifier.simplify (eqvt_ss addsimps fresh_atm) th'' end)
   377                      vc_compat_ths;
   378                  val vc_compat_ths'' = NominalPackage.mk_not_sym vc_compat_ths';
   379                  (** Since swap_simps simplifies (pi :: 'a prm) o (x :: 'b) to x **)
   380                  (** we have to pre-simplify the rewrite rules                   **)
   381                  val swap_simps_ss = HOL_ss addsimps swap_simps @
   382                     map (Simplifier.simplify (HOL_ss addsimps swap_simps))
   383                       (vc_compat_ths'' @ freshs2');
   384                  val th = Goal.prove ctxt'' [] []
   385                    (HOLogic.mk_Trueprop (list_comb (P $ hd ts,
   386                      map (fold (NominalPackage.mk_perm []) pis') (tl ts))))
   387                    (fn _ => EVERY ([simp_tac eqvt_ss 1, rtac ihyp' 1,
   388                      REPEAT_DETERM_N (nprems_of ihyp - length gprems)
   389                        (simp_tac swap_simps_ss 1),
   390                      REPEAT_DETERM_N (length gprems)
   391                        (simp_tac (HOL_basic_ss
   392                           addsimps [inductive_forall_def']
   393                           addsimprocs [NominalPackage.perm_simproc]) 1 THEN
   394                         resolve_tac gprems2 1)]));
   395                  val final = Goal.prove ctxt'' [] [] (term_of concl)
   396                    (fn _ => cut_facts_tac [th] 1 THEN full_simp_tac (HOL_ss
   397                      addsimps vc_compat_ths'' @ freshs2' @
   398                        perm_fresh_fresh @ fresh_atm) 1);
   399                  val final' = ProofContext.export ctxt'' ctxt' [final];
   400                in resolve_tac final' 1 end) context 1])
   401                  (prems ~~ thss ~~ ihyps ~~ prems'')))
   402         in
   403           cut_facts_tac [th] 1 THEN REPEAT (etac conjE 1) THEN
   404           REPEAT (REPEAT (resolve_tac [conjI, impI] 1) THEN
   405             etac impE 1 THEN atac 1 THEN REPEAT (etac @{thm allE_Nil} 1) THEN
   406             asm_full_simp_tac (simpset_of thy) 1)
   407         end) |> singleton (ProofContext.export ctxt' ctxt);
   408 
   409     (** strong case analysis rule **)
   410 
   411     val cases_prems = map (fn ((name, avoids), rule) =>
   412       let
   413         val ([rule'], ctxt') = Variable.import_terms false [prop_of rule] ctxt;
   414         val prem :: prems = Logic.strip_imp_prems rule';
   415         val concl = Logic.strip_imp_concl rule'
   416       in
   417         (prem,
   418          List.drop (snd (strip_comb (HOLogic.dest_Trueprop prem)), length ind_params),
   419          concl,
   420          fold_map (fn (prem, (_, avoid)) => fn ctxt =>
   421            let
   422              val prems = Logic.strip_assums_hyp prem;
   423              val params = Logic.strip_params prem;
   424              val bnds = fold (add_binders thy 0) prems [] @ mk_avoids params avoid;
   425              fun mk_subst (p as (s, T)) (i, j, ctxt, ps, qs, is, ts) =
   426                if member (op = o apsnd fst) bnds (Bound i) then
   427                  let
   428                    val ([s'], ctxt') = Variable.variant_fixes [s] ctxt;
   429                    val t = Free (s', T)
   430                  in (i + 1, j, ctxt', ps, (t, T) :: qs, i :: is, t :: ts) end
   431                else (i + 1, j + 1, ctxt, p :: ps, qs, is, Bound j :: ts);
   432              val (_, _, ctxt', ps, qs, is, ts) = fold_rev mk_subst params
   433                (0, 0, ctxt, [], [], [], [])
   434            in
   435              ((ps, qs, is, map (curry subst_bounds (rev ts)) prems), ctxt')
   436            end) (prems ~~ avoids) ctxt')
   437       end)
   438         (InductivePackage.partition_rules' raw_induct (intrs ~~ avoids') ~~
   439          elims);
   440 
   441     val cases_prems' =
   442       map (fn (prem, args, concl, (prems, _)) =>
   443         let
   444           fun mk_prem (ps, [], _, prems) =
   445                 list_all (ps, Logic.list_implies (prems, concl))
   446             | mk_prem (ps, qs, _, prems) =
   447                 list_all (ps, Logic.mk_implies
   448                   (Logic.list_implies
   449                     (mk_distinct qs @
   450                      maps (fn (t, T) => map (fn u => HOLogic.mk_Trueprop
   451                       (NominalPackage.fresh_const T (fastype_of u) $ t $ u))
   452                         args) qs,
   453                      HOLogic.mk_Trueprop (foldr1 HOLogic.mk_conj
   454                        (map HOLogic.dest_Trueprop prems))),
   455                    concl))
   456           in map mk_prem prems end) cases_prems;
   457 
   458     val cases_eqvt_ss = Simplifier.theory_context thy HOL_ss
   459       addsimps eqvt_thms @ swap_simps @ perm_pi_simp
   460       addsimprocs [NominalPermeq.perm_simproc_app,
   461         NominalPermeq.perm_simproc_fun];
   462 
   463     val simp_fresh_atm = map
   464       (Simplifier.simplify (HOL_basic_ss addsimps fresh_atm));
   465 
   466     fun mk_cases_proof ((((name, thss), elim), (prem, args, concl, (prems, ctxt'))),
   467         prems') =
   468       (name, Goal.prove ctxt' [] (prem :: prems') concl
   469         (fn {prems = hyp :: hyps, context = ctxt1} =>
   470         EVERY (rtac (hyp RS elim) 1 ::
   471           map (fn (((_, vc_compat_ths), case_hyp), (_, qs, is, _)) =>
   472             SUBPROOF (fn {prems = case_hyps, params, context = ctxt2, concl, ...} =>
   473               if null qs then
   474                 rtac (first_order_mrs case_hyps case_hyp) 1
   475               else
   476                 let
   477                   val params' = map (term_of o nth (rev params)) is;
   478                   val tab = params' ~~ map fst qs;
   479                   val (hyps1, hyps2) = chop (length args) case_hyps;
   480                   (* turns a = t and [x1 # t, ..., xn # t] *)
   481                   (* into [x1 # a, ..., xn # a]            *)
   482                   fun inst_fresh th' ths =
   483                     let val (ths1, ths2) = chop (length qs) ths
   484                     in
   485                       (map (fn th =>
   486                          let
   487                            val (cf, ct) =
   488                              Thm.dest_comb (Thm.dest_arg (cprop_of th));
   489                            val arg_cong' = Drule.instantiate'
   490                              [SOME (ctyp_of_term ct)]
   491                              [NONE, SOME ct, SOME cf] (arg_cong RS iffD2);
   492                            val inst = Thm.first_order_match (ct,
   493                              Thm.dest_arg (Thm.dest_arg (cprop_of th')))
   494                          in [th', th] MRS Thm.instantiate inst arg_cong'
   495                          end) ths1,
   496                        ths2)
   497                     end;
   498                   val (vc_compat_ths1, vc_compat_ths2) =
   499                     chop (length vc_compat_ths - length args * length qs)
   500                       (map (first_order_mrs hyps2) vc_compat_ths);
   501                   val vc_compat_ths' =
   502                     NominalPackage.mk_not_sym vc_compat_ths1 @
   503                     flat (fst (fold_map inst_fresh hyps1 vc_compat_ths2));
   504                   val (freshs1, freshs2, ctxt3) = fold
   505                     (obtain_fresh_name (args @ map fst qs @ params'))
   506                     (map snd qs) ([], [], ctxt2);
   507                   val freshs2' = NominalPackage.mk_not_sym freshs2;
   508                   val pis = map (NominalPackage.perm_of_pair)
   509                     ((freshs1 ~~ map fst qs) @ (params' ~~ freshs1));
   510                   val mk_pis = fold_rev mk_perm_bool (map (cterm_of thy) pis);
   511                   val obj = cterm_of thy (foldr1 HOLogic.mk_conj (map (map_aterms
   512                      (fn x as Free _ =>
   513                            if x mem args then x
   514                            else (case AList.lookup op = tab x of
   515                              SOME y => y
   516                            | NONE => fold_rev (NominalPackage.mk_perm []) pis x)
   517                        | x => x) o HOLogic.dest_Trueprop o prop_of) case_hyps));
   518                   val inst = Thm.first_order_match (Thm.dest_arg
   519                     (Drule.strip_imp_concl (hd (cprems_of case_hyp))), obj);
   520                   val th = Goal.prove ctxt3 [] [] (term_of concl)
   521                     (fn {context = ctxt4, ...} =>
   522                        rtac (Thm.instantiate inst case_hyp) 1 THEN
   523                        SUBPROOF (fn {prems = fresh_hyps, ...} =>
   524                          let
   525                            val fresh_hyps' = NominalPackage.mk_not_sym fresh_hyps;
   526                            val case_ss = cases_eqvt_ss addsimps freshs2' @
   527                              simp_fresh_atm (vc_compat_ths' @ fresh_hyps');
   528                            val fresh_fresh_ss = case_ss addsimps perm_fresh_fresh;
   529                            val hyps1' = map
   530                              (mk_pis #> Simplifier.simplify fresh_fresh_ss) hyps1;
   531                            val hyps2' = map
   532                              (mk_pis #> Simplifier.simplify case_ss) hyps2;
   533                            val case_hyps' = hyps1' @ hyps2'
   534                          in
   535                            simp_tac case_ss 1 THEN
   536                            REPEAT_DETERM (TRY (rtac conjI 1) THEN
   537                              resolve_tac case_hyps' 1)
   538                          end) ctxt4 1)
   539                   val final = ProofContext.export ctxt3 ctxt2 [th]
   540                 in resolve_tac final 1 end) ctxt1 1)
   541                   (thss ~~ hyps ~~ prems))) |>
   542                   singleton (ProofContext.export ctxt' ctxt))
   543 
   544   in
   545     ctxt'' |>
   546     Proof.theorem_i NONE (fn thss => fn ctxt =>
   547       let
   548         val rec_name = space_implode "_" (map Sign.base_name names);
   549         val rec_qualified = Binding.qualify false rec_name;
   550         val ind_case_names = RuleCases.case_names induct_cases;
   551         val induct_cases' = InductivePackage.partition_rules' raw_induct
   552           (intrs ~~ induct_cases); 
   553         val thss' = map (map atomize_intr) thss;
   554         val thsss = InductivePackage.partition_rules' raw_induct (intrs ~~ thss');
   555         val strong_raw_induct =
   556           mk_ind_proof ctxt thss' |> InductivePackage.rulify;
   557         val strong_cases = map (mk_cases_proof ##> InductivePackage.rulify)
   558           (thsss ~~ elims ~~ cases_prems ~~ cases_prems');
   559         val strong_induct =
   560           if length names > 1 then
   561             (strong_raw_induct, [ind_case_names, RuleCases.consumes 0])
   562           else (strong_raw_induct RSN (2, rev_mp),
   563             [ind_case_names, RuleCases.consumes 1]);
   564         val ((_, [strong_induct']), ctxt') = LocalTheory.note Thm.theoremK
   565           ((rec_qualified (Binding.name "strong_induct"),
   566             map (Attrib.internal o K) (#2 strong_induct)), [#1 strong_induct])
   567           ctxt;
   568         val strong_inducts =
   569           ProjectRule.projects ctxt (1 upto length names) strong_induct'
   570       in
   571         ctxt' |>
   572         LocalTheory.note Thm.theoremK
   573           ((rec_qualified (Binding.name "strong_inducts"),
   574             [Attrib.internal (K ind_case_names),
   575              Attrib.internal (K (RuleCases.consumes 1))]),
   576            strong_inducts) |> snd |>
   577         LocalTheory.notes Thm.theoremK (map (fn ((name, elim), (_, cases)) =>
   578             ((Binding.name (NameSpace.qualified (Sign.base_name name) "strong_cases"),
   579               [Attrib.internal (K (RuleCases.case_names (map snd cases))),
   580                Attrib.internal (K (RuleCases.consumes 1))]), [([elim], [])]))
   581           (strong_cases ~~ induct_cases')) |> snd
   582       end)
   583       (map (map (rulify_term thy #> rpair [])) vc_compat)
   584   end;
   585 
   586 fun prove_eqvt s xatoms ctxt =
   587   let
   588     val thy = ProofContext.theory_of ctxt;
   589     val ({names, ...}, {raw_induct, intrs, elims, ...}) =
   590       InductivePackage.the_inductive ctxt (Sign.intern_const thy s);
   591     val raw_induct = atomize_induct ctxt raw_induct;
   592     val elims = map (atomize_induct ctxt) elims;
   593     val intrs = map atomize_intr intrs;
   594     val monos = InductivePackage.get_monos ctxt;
   595     val intrs' = InductivePackage.unpartition_rules intrs
   596       (map (fn (((s, ths), (_, k)), th) =>
   597            (s, ths ~~ InductivePackage.infer_intro_vars th k ths))
   598          (InductivePackage.partition_rules raw_induct intrs ~~
   599           InductivePackage.arities_of raw_induct ~~ elims));
   600     val k = length (InductivePackage.params_of raw_induct);
   601     val atoms' = NominalAtoms.atoms_of thy;
   602     val atoms =
   603       if null xatoms then atoms' else
   604       let val atoms = map (Sign.intern_type thy) xatoms
   605       in
   606         (case duplicates op = atoms of
   607              [] => ()
   608            | xs => error ("Duplicate atoms: " ^ commas xs);
   609          case atoms \\ atoms' of
   610              [] => ()
   611            | xs => error ("No such atoms: " ^ commas xs);
   612          atoms)
   613       end;
   614     val perm_pi_simp = PureThy.get_thms thy "perm_pi_simp";
   615     val eqvt_ss = Simplifier.theory_context thy HOL_basic_ss addsimps
   616       (NominalThmDecls.get_eqvt_thms ctxt @ perm_pi_simp) addsimprocs
   617       [mk_perm_bool_simproc names,
   618        NominalPermeq.perm_simproc_app, NominalPermeq.perm_simproc_fun];
   619     val (([t], [pi]), ctxt') = ctxt |>
   620       Variable.import_terms false [concl_of raw_induct] ||>>
   621       Variable.variant_fixes ["pi"];
   622     val ps = map (fst o HOLogic.dest_imp)
   623       (HOLogic.dest_conj (HOLogic.dest_Trueprop t));
   624     fun eqvt_tac ctxt'' pi (intr, vs) st =
   625       let
   626         fun eqvt_err s =
   627           let val ([t], ctxt''') = Variable.import_terms true [prop_of intr] ctxt
   628           in error ("Could not prove equivariance for introduction rule\n" ^
   629             Syntax.string_of_term ctxt''' t ^ "\n" ^ s)
   630           end;
   631         val res = SUBPROOF (fn {prems, params, ...} =>
   632           let
   633             val prems' = map (fn th => the_default th (map_thm ctxt'
   634               (split_conj (K I) names) (etac conjunct2 1) monos NONE th)) prems;
   635             val prems'' = map (fn th => Simplifier.simplify eqvt_ss
   636               (mk_perm_bool (cterm_of thy pi) th)) prems';
   637             val intr' = Drule.cterm_instantiate (map (cterm_of thy) vs ~~
   638                map (cterm_of thy o NominalPackage.mk_perm [] pi o term_of) params)
   639                intr
   640           in (rtac intr' THEN_ALL_NEW (TRY o resolve_tac prems'')) 1
   641           end) ctxt' 1 st
   642       in
   643         case (Seq.pull res handle THM (s, _, _) => eqvt_err s) of
   644           NONE => eqvt_err ("Rule does not match goal\n" ^
   645             Syntax.string_of_term ctxt'' (hd (prems_of st)))
   646         | SOME (th, _) => Seq.single th
   647       end;
   648     val thss = map (fn atom =>
   649       let val pi' = Free (pi, NominalAtoms.mk_permT (Type (atom, [])))
   650       in map (fn th => zero_var_indexes (th RS mp))
   651         (DatatypeAux.split_conj_thm (Goal.prove ctxt' [] []
   652           (HOLogic.mk_Trueprop (foldr1 HOLogic.mk_conj (map (fn p =>
   653             let
   654               val (h, ts) = strip_comb p;
   655               val (ts1, ts2) = chop k ts
   656             in
   657               HOLogic.mk_imp (p, list_comb (h, ts1 @
   658                 map (NominalPackage.mk_perm [] pi') ts2))
   659             end) ps)))
   660           (fn {context, ...} => EVERY (rtac raw_induct 1 :: map (fn intr_vs =>
   661               full_simp_tac eqvt_ss 1 THEN
   662               eqvt_tac context pi' intr_vs) intrs')) |>
   663           singleton (ProofContext.export ctxt' ctxt)))
   664       end) atoms
   665   in
   666     ctxt |>
   667     LocalTheory.notes Thm.theoremK (map (fn (name, ths) =>
   668         ((Binding.name (NameSpace.qualified (Sign.base_name name) "eqvt"),
   669           [Attrib.internal (K NominalThmDecls.eqvt_add)]), [(ths, [])]))
   670       (names ~~ transp thss)) |> snd
   671   end;
   672 
   673 
   674 (* outer syntax *)
   675 
   676 local structure P = OuterParse and K = OuterKeyword in
   677 
   678 val _ = OuterKeyword.keyword "avoids";
   679 
   680 val _ =
   681   OuterSyntax.local_theory_to_proof "nominal_inductive"
   682     "prove equivariance and strong induction theorem for inductive predicate involving nominal datatypes" K.thy_goal
   683     (P.xname -- Scan.optional (P.$$$ "avoids" |-- P.and_list1 (P.name --
   684       (P.$$$ ":" |-- Scan.repeat1 P.name))) [] >> (fn (name, avoids) =>
   685         prove_strong_ind name avoids));
   686 
   687 val _ =
   688   OuterSyntax.local_theory "equivariance"
   689     "prove equivariance for inductive predicate involving nominal datatypes" K.thy_decl
   690     (P.xname -- Scan.optional (P.$$$ "[" |-- P.list1 P.name --| P.$$$ "]") [] >>
   691       (fn (name, atoms) => prove_eqvt name atoms));
   692 
   693 end;
   694 
   695 end