src/HOL/Tools/Predicate_Compile/predicate_compile_aux.ML
author wenzelm
Wed Nov 26 16:55:43 2014 +0100 (2014-11-26)
changeset 59057 5b649fb2f2e1
parent 57962 0284a7d083be
child 59058 a78612c67ec0
permissions -rw-r--r--
added ML antiquotation @{apply n} or @{apply n(k)};
     1 (*  Title:      HOL/Tools/Predicate_Compile/predicate_compile_aux.ML
     2     Author:     Lukas Bulwahn, TU Muenchen
     3 
     4 Auxilary functions for predicate compiler.
     5 *)
     6 
     7 signature PREDICATE_COMPILE_AUX =
     8 sig
     9   val find_indices : ('a -> bool) -> 'a list -> int list
    10   (* mode *)
    11   datatype mode = Bool | Input | Output | Pair of mode * mode | Fun of mode * mode
    12   val eq_mode : mode * mode -> bool
    13   val mode_ord: mode * mode -> order
    14   val list_fun_mode : mode list -> mode
    15   val strip_fun_mode : mode -> mode list
    16   val dest_fun_mode : mode -> mode list
    17   val dest_tuple_mode : mode -> mode list
    18   val all_modes_of_typ : typ -> mode list
    19   val all_smodes_of_typ : typ -> mode list
    20   val fold_map_aterms_prodT : ('a -> 'a -> 'a) -> (typ -> 'b -> 'a * 'b) -> typ -> 'b -> 'a * 'b
    21   val map_filter_prod : (term -> term option) -> term -> term option
    22   val replace_ho_args : mode -> term list -> term list -> term list
    23   val ho_arg_modes_of : mode -> mode list
    24   val ho_argsT_of : mode -> typ list -> typ list
    25   val ho_args_of : mode -> term list -> term list
    26   val ho_args_of_typ : typ -> term list -> term list
    27   val ho_argsT_of_typ : typ list -> typ list
    28   val split_map_mode : (mode -> term -> term option * term option)
    29     -> mode -> term list -> term list * term list
    30   val split_map_modeT : (mode -> typ -> typ option * typ option)
    31     -> mode -> typ list -> typ list * typ list
    32   val split_mode : mode -> term list -> term list * term list
    33   val split_modeT : mode -> typ list -> typ list * typ list
    34   val string_of_mode : mode -> string
    35   val ascii_string_of_mode : mode -> string
    36   (* premises *)
    37   datatype indprem = Prem of term | Negprem of term | Sidecond of term
    38     | Generator of (string * typ)
    39   val dest_indprem : indprem -> term
    40   val map_indprem : (term -> term) -> indprem -> indprem
    41   (* general syntactic functions *)
    42   val is_equationlike : thm -> bool
    43   val is_pred_equation : thm -> bool
    44   val is_intro : string -> thm -> bool
    45   val is_predT : typ -> bool
    46   val get_constrs : theory -> (string * (int * string)) list
    47   val is_constrt : theory -> term -> bool
    48   val is_constr : Proof.context -> string -> bool
    49   val strip_ex : term -> (string * typ) list * term
    50   val focus_ex : term -> Name.context -> ((string * typ) list * term) * Name.context
    51   val strip_all : term -> (string * typ) list * term
    52   val strip_intro_concl : thm -> term * term list
    53   (* introduction rule combinators *)
    54   val map_atoms : (term -> term) -> term -> term
    55   val fold_atoms : (term -> 'a -> 'a) -> term -> 'a -> 'a
    56   val fold_map_atoms : (term -> 'a -> term * 'a) -> term -> 'a -> term * 'a
    57   val maps_premises : (term -> term list) -> term -> term
    58   val map_concl : (term -> term) -> term -> term
    59   val map_term : theory -> (term -> term) -> thm -> thm
    60   (* split theorems of case expressions *)
    61   val prepare_split_thm : Proof.context -> thm -> thm
    62   val find_split_thm : theory -> term -> thm option
    63   (* datastructures and setup for generic compilation *)
    64   datatype compilation_funs = CompilationFuns of {
    65     mk_monadT : typ -> typ,
    66     dest_monadT : typ -> typ,
    67     mk_empty : typ -> term,
    68     mk_single : term -> term,
    69     mk_bind : term * term -> term,
    70     mk_plus : term * term -> term,
    71     mk_if : term -> term,
    72     mk_iterate_upto : typ -> term * term * term -> term,
    73     mk_not : term -> term,
    74     mk_map : typ -> typ -> term -> term -> term
    75   };
    76   val mk_monadT : compilation_funs -> typ -> typ
    77   val dest_monadT : compilation_funs -> typ -> typ
    78   val mk_empty : compilation_funs -> typ -> term
    79   val mk_single : compilation_funs -> term -> term
    80   val mk_bind : compilation_funs -> term * term -> term
    81   val mk_plus : compilation_funs -> term * term -> term
    82   val mk_if : compilation_funs -> term -> term
    83   val mk_iterate_upto : compilation_funs -> typ -> term * term * term -> term
    84   val mk_not : compilation_funs -> term -> term
    85   val mk_map : compilation_funs -> typ -> typ -> term -> term -> term
    86   val funT_of : compilation_funs -> mode -> typ -> typ
    87   (* Different compilations *)
    88   datatype compilation = Pred | Depth_Limited | Random | Depth_Limited_Random | DSeq | Annotated
    89     | Pos_Random_DSeq | Neg_Random_DSeq | New_Pos_Random_DSeq | New_Neg_Random_DSeq
    90     | Pos_Generator_DSeq | Neg_Generator_DSeq | Pos_Generator_CPS | Neg_Generator_CPS
    91   val negative_compilation_of : compilation -> compilation
    92   val compilation_for_polarity : bool -> compilation -> compilation
    93   val is_depth_limited_compilation : compilation -> bool
    94   val string_of_compilation : compilation -> string
    95   val compilation_names : (string * compilation) list
    96   val non_random_compilations : compilation list
    97   val random_compilations : compilation list
    98   (* Different options for compiler *)
    99   datatype options = Options of {
   100     expected_modes : (string * mode list) option,
   101     proposed_modes : (string * mode list) list,
   102     proposed_names : ((string * mode) * string) list,
   103     show_steps : bool,
   104     show_proof_trace : bool,
   105     show_intermediate_results : bool,
   106     show_mode_inference : bool,
   107     show_modes : bool,
   108     show_compilation : bool,
   109     show_caught_failures : bool,
   110     show_invalid_clauses : bool,
   111     skip_proof : bool,
   112     no_topmost_reordering : bool,
   113     function_flattening : bool,
   114     fail_safe_function_flattening : bool,
   115     specialise : bool,
   116     no_higher_order_predicate : string list,
   117     inductify : bool,
   118     detect_switches : bool,
   119     smart_depth_limiting : bool,
   120     compilation : compilation
   121   };
   122   val expected_modes : options -> (string * mode list) option
   123   val proposed_modes : options -> string -> mode list option
   124   val proposed_names : options -> string -> mode -> string option
   125   val show_steps : options -> bool
   126   val show_proof_trace : options -> bool
   127   val show_intermediate_results : options -> bool
   128   val show_mode_inference : options -> bool
   129   val show_modes : options -> bool
   130   val show_compilation : options -> bool
   131   val show_caught_failures : options -> bool
   132   val show_invalid_clauses : options -> bool
   133   val skip_proof : options -> bool
   134   val no_topmost_reordering : options -> bool
   135   val function_flattening : options -> bool
   136   val fail_safe_function_flattening : options -> bool
   137   val specialise : options -> bool
   138   val no_higher_order_predicate : options -> string list
   139   val is_inductify : options -> bool
   140   val detect_switches : options -> bool
   141   val smart_depth_limiting : options -> bool
   142   val compilation : options -> compilation
   143   val default_options : options
   144   val bool_options : string list
   145   val print_step : options -> string -> unit
   146   (* conversions *)
   147   val imp_prems_conv : conv -> conv
   148   (* simple transformations *)
   149   val split_conjuncts_in_assms : Proof.context -> thm -> thm
   150   val dest_conjunct_prem : thm -> thm list
   151   val expand_tuples : theory -> thm -> thm
   152   val case_betapply : theory -> term -> term
   153   val eta_contract_ho_arguments : theory -> thm -> thm
   154   val remove_equalities : theory -> thm -> thm
   155   val remove_pointless_clauses : thm -> thm list
   156   val peephole_optimisation : theory -> thm -> thm option
   157   (* auxillary *)
   158   val unify_consts : theory -> term list -> term list -> (term list * term list)
   159   val mk_casesrule : Proof.context -> term -> thm list -> term
   160   val preprocess_intro : theory -> thm -> thm
   161 
   162   val define_quickcheck_predicate :
   163     term -> theory -> (((string * typ) * (string * typ) list) * thm) * theory
   164 end
   165 
   166 structure Predicate_Compile_Aux : PREDICATE_COMPILE_AUX =
   167 struct
   168 
   169 (* general functions *)
   170 
   171 fun comb_option f (SOME x1, SOME x2) = SOME (f (x1, x2))
   172   | comb_option f (NONE, SOME x2) = SOME x2
   173   | comb_option f (SOME x1, NONE) = SOME x1
   174   | comb_option f (NONE, NONE) = NONE
   175 
   176 fun map2_optional f (x :: xs) (y :: ys) = f x (SOME y) :: (map2_optional f xs ys)
   177   | map2_optional f (x :: xs) [] = (f x NONE) :: (map2_optional f xs [])
   178   | map2_optional f [] [] = []
   179 
   180 fun find_indices f xs =
   181   map_filter (fn (i, true) => SOME i | (_, false) => NONE) (map_index (apsnd f) xs)
   182 
   183 (* mode *)
   184 
   185 datatype mode = Bool | Input | Output | Pair of mode * mode | Fun of mode * mode
   186 
   187 (* equality of instantiatedness with respect to equivalences:
   188   Pair Input Input == Input and Pair Output Output == Output *)
   189 fun eq_mode (Fun (m1, m2), Fun (m3, m4)) = eq_mode (m1, m3) andalso eq_mode (m2, m4)
   190   | eq_mode (Pair (m1, m2), Pair (m3, m4)) = eq_mode (m1, m3) andalso eq_mode (m2, m4)
   191   | eq_mode (Pair (m1, m2), Input) = eq_mode (m1, Input) andalso eq_mode (m2, Input)
   192   | eq_mode (Pair (m1, m2), Output) = eq_mode (m1, Output) andalso eq_mode (m2, Output)
   193   | eq_mode (Input, Pair (m1, m2)) = eq_mode (Input, m1) andalso eq_mode (Input, m2)
   194   | eq_mode (Output, Pair (m1, m2)) = eq_mode (Output, m1) andalso eq_mode (Output, m2)
   195   | eq_mode (Input, Input) = true
   196   | eq_mode (Output, Output) = true
   197   | eq_mode (Bool, Bool) = true
   198   | eq_mode _ = false
   199 
   200 fun mode_ord (Input, Output) = LESS
   201   | mode_ord (Output, Input) = GREATER
   202   | mode_ord (Input, Input) = EQUAL
   203   | mode_ord (Output, Output) = EQUAL
   204   | mode_ord (Bool, Bool) = EQUAL
   205   | mode_ord (Pair (m1, m2), Pair (m3, m4)) = prod_ord mode_ord mode_ord ((m1, m2), (m3, m4))
   206   | mode_ord (Fun (m1, m2), Fun (m3, m4)) = prod_ord mode_ord mode_ord ((m1, m2), (m3, m4))
   207 
   208 fun list_fun_mode [] = Bool
   209   | list_fun_mode (m :: ms) = Fun (m, list_fun_mode ms)
   210 
   211 (* name: binder_modes? *)
   212 fun strip_fun_mode (Fun (mode, mode')) = mode :: strip_fun_mode mode'
   213   | strip_fun_mode Bool = []
   214   | strip_fun_mode _ = raise Fail "Bad mode for strip_fun_mode"
   215 
   216 (* name: strip_fun_mode? *)
   217 fun dest_fun_mode (Fun (mode, mode')) = mode :: dest_fun_mode mode'
   218   | dest_fun_mode mode = [mode]
   219 
   220 fun dest_tuple_mode (Pair (mode, mode')) = mode :: dest_tuple_mode mode'
   221   | dest_tuple_mode _ = []
   222 
   223 fun all_modes_of_typ' (T as Type ("fun", _)) =
   224   let
   225     val (S, U) = strip_type T
   226   in
   227     if U = HOLogic.boolT then
   228       fold_rev (fn m1 => fn m2 => map_product (curry Fun) m1 m2)
   229         (map all_modes_of_typ' S) [Bool]
   230     else
   231       [Input, Output]
   232   end
   233   | all_modes_of_typ' (Type (@{type_name Product_Type.prod}, [T1, T2])) =
   234     map_product (curry Pair) (all_modes_of_typ' T1) (all_modes_of_typ' T2)
   235   | all_modes_of_typ' _ = [Input, Output]
   236 
   237 fun all_modes_of_typ (T as Type ("fun", _)) =
   238     let
   239       val (S, U) = strip_type T
   240     in
   241       if U = @{typ bool} then
   242         fold_rev (fn m1 => fn m2 => map_product (curry Fun) m1 m2)
   243           (map all_modes_of_typ' S) [Bool]
   244       else
   245         raise Fail "Invocation of all_modes_of_typ with a non-predicate type"
   246     end
   247   | all_modes_of_typ @{typ bool} = [Bool]
   248   | all_modes_of_typ _ =
   249     raise Fail "Invocation of all_modes_of_typ with a non-predicate type"
   250 
   251 fun all_smodes_of_typ (T as Type ("fun", _)) =
   252   let
   253     val (S, U) = strip_type T
   254     fun all_smodes (Type (@{type_name Product_Type.prod}, [T1, T2])) =
   255       map_product (curry Pair) (all_smodes T1) (all_smodes T2)
   256       | all_smodes _ = [Input, Output]
   257   in
   258     if U = HOLogic.boolT then
   259       fold_rev (fn m1 => fn m2 => map_product (curry Fun) m1 m2) (map all_smodes S) [Bool]
   260     else
   261       raise Fail "invalid type for predicate"
   262   end
   263 
   264 fun ho_arg_modes_of mode =
   265   let
   266     fun ho_arg_mode (m as Fun _) =  [m]
   267       | ho_arg_mode (Pair (m1, m2)) = ho_arg_mode m1 @ ho_arg_mode m2
   268       | ho_arg_mode _ = []
   269   in
   270     maps ho_arg_mode (strip_fun_mode mode)
   271   end
   272 
   273 fun ho_args_of mode ts =
   274   let
   275     fun ho_arg (Fun _) (SOME t) = [t]
   276       | ho_arg (Fun _) NONE = raise Fail "mode and term do not match"
   277       | ho_arg (Pair (m1, m2)) (SOME (Const (@{const_name Pair}, _) $ t1 $ t2)) =
   278           ho_arg m1 (SOME t1) @ ho_arg m2 (SOME t2)
   279       | ho_arg (Pair (m1, m2)) NONE = ho_arg m1 NONE @ ho_arg m2 NONE
   280       | ho_arg _ _ = []
   281   in
   282     flat (map2_optional ho_arg (strip_fun_mode mode) ts)
   283   end
   284 
   285 fun ho_args_of_typ T ts =
   286   let
   287     fun ho_arg (T as Type ("fun", [_, _])) (SOME t) =
   288           if body_type T = @{typ bool} then [t] else []
   289       | ho_arg (Type ("fun", [_, _])) NONE = raise Fail "mode and term do not match"
   290       | ho_arg (Type(@{type_name "Product_Type.prod"}, [T1, T2]))
   291          (SOME (Const (@{const_name Pair}, _) $ t1 $ t2)) =
   292           ho_arg T1 (SOME t1) @ ho_arg T2 (SOME t2)
   293       | ho_arg (Type(@{type_name "Product_Type.prod"}, [T1, T2])) NONE =
   294           ho_arg T1 NONE @ ho_arg T2 NONE
   295       | ho_arg _ _ = []
   296   in
   297     flat (map2_optional ho_arg (binder_types T) ts)
   298   end
   299 
   300 fun ho_argsT_of_typ Ts =
   301   let
   302     fun ho_arg (T as Type("fun", [_,_])) = if body_type T = @{typ bool} then [T] else []
   303       | ho_arg (Type (@{type_name "Product_Type.prod"}, [T1, T2])) =
   304           ho_arg T1 @ ho_arg T2
   305       | ho_arg _ = []
   306   in
   307     maps ho_arg Ts
   308   end
   309 
   310 
   311 (* temporary function should be replaced by unsplit_input or so? *)
   312 fun replace_ho_args mode hoargs ts =
   313   let
   314     fun replace (Fun _, _) (arg' :: hoargs') = (arg', hoargs')
   315       | replace (Pair (m1, m2), Const (@{const_name Pair}, T) $ t1 $ t2) hoargs =
   316           let
   317             val (t1', hoargs') = replace (m1, t1) hoargs
   318             val (t2', hoargs'') = replace (m2, t2) hoargs'
   319           in
   320             (Const (@{const_name Pair}, T) $ t1' $ t2', hoargs'')
   321           end
   322       | replace (_, t) hoargs = (t, hoargs)
   323   in
   324     fst (fold_map replace (strip_fun_mode mode ~~ ts) hoargs)
   325   end
   326 
   327 fun ho_argsT_of mode Ts =
   328   let
   329     fun ho_arg (Fun _) T = [T]
   330       | ho_arg (Pair (m1, m2)) (Type (@{type_name Product_Type.prod}, [T1, T2])) =
   331           ho_arg m1 T1 @ ho_arg m2 T2
   332       | ho_arg _ _ = []
   333   in
   334     flat (map2 ho_arg (strip_fun_mode mode) Ts)
   335   end
   336 
   337 (* splits mode and maps function to higher-order argument types *)
   338 fun split_map_mode f mode ts =
   339   let
   340     fun split_arg_mode' (m as Fun _) t = f m t
   341       | split_arg_mode' (Pair (m1, m2)) (Const (@{const_name Pair}, _) $ t1 $ t2) =
   342         let
   343           val (i1, o1) = split_arg_mode' m1 t1
   344           val (i2, o2) = split_arg_mode' m2 t2
   345         in
   346           (comb_option HOLogic.mk_prod (i1, i2), comb_option HOLogic.mk_prod (o1, o2))
   347         end
   348       | split_arg_mode' m t =
   349         if eq_mode (m, Input) then (SOME t, NONE)
   350         else if eq_mode (m, Output) then (NONE,  SOME t)
   351         else raise Fail "split_map_mode: mode and term do not match"
   352   in
   353     (pairself (map_filter I) o split_list) (map2 split_arg_mode' (strip_fun_mode mode) ts)
   354   end
   355 
   356 (* splits mode and maps function to higher-order argument types *)
   357 fun split_map_modeT f mode Ts =
   358   let
   359     fun split_arg_mode' (m as Fun _) T = f m T
   360       | split_arg_mode' (Pair (m1, m2)) (Type (@{type_name Product_Type.prod}, [T1, T2])) =
   361         let
   362           val (i1, o1) = split_arg_mode' m1 T1
   363           val (i2, o2) = split_arg_mode' m2 T2
   364         in
   365           (comb_option HOLogic.mk_prodT (i1, i2), comb_option HOLogic.mk_prodT (o1, o2))
   366         end
   367       | split_arg_mode' Input T = (SOME T, NONE)
   368       | split_arg_mode' Output T = (NONE,  SOME T)
   369       | split_arg_mode' _ _ = raise Fail "split_modeT': mode and type do not match"
   370   in
   371     (pairself (map_filter I) o split_list) (map2 split_arg_mode' (strip_fun_mode mode) Ts)
   372   end
   373 
   374 fun split_mode mode ts = split_map_mode (fn _ => fn _ => (NONE, NONE)) mode ts
   375 
   376 fun fold_map_aterms_prodT comb f (Type (@{type_name Product_Type.prod}, [T1, T2])) s =
   377       let
   378         val (x1, s') = fold_map_aterms_prodT comb f T1 s
   379         val (x2, s'') = fold_map_aterms_prodT comb f T2 s'
   380       in
   381         (comb x1 x2, s'')
   382       end
   383   | fold_map_aterms_prodT _ f T s = f T s
   384 
   385 fun map_filter_prod f (Const (@{const_name Pair}, _) $ t1 $ t2) =
   386       comb_option HOLogic.mk_prod (map_filter_prod f t1, map_filter_prod f t2)
   387   | map_filter_prod f t = f t
   388 
   389 fun split_modeT mode Ts =
   390   let
   391     fun split_arg_mode (Fun _) _ = ([], [])
   392       | split_arg_mode (Pair (m1, m2)) (Type (@{type_name Product_Type.prod}, [T1, T2])) =
   393           let
   394             val (i1, o1) = split_arg_mode m1 T1
   395             val (i2, o2) = split_arg_mode m2 T2
   396           in
   397             (i1 @ i2, o1 @ o2)
   398           end
   399       | split_arg_mode Input T = ([T], [])
   400       | split_arg_mode Output T = ([], [T])
   401       | split_arg_mode _ _ = raise Fail "split_modeT: mode and type do not match"
   402   in
   403     (pairself flat o split_list) (map2 split_arg_mode (strip_fun_mode mode) Ts)
   404   end
   405 
   406 fun string_of_mode mode =
   407   let
   408     fun string_of_mode1 Input = "i"
   409       | string_of_mode1 Output = "o"
   410       | string_of_mode1 Bool = "bool"
   411       | string_of_mode1 mode = "(" ^ (string_of_mode3 mode) ^ ")"
   412     and string_of_mode2 (Pair (m1, m2)) = string_of_mode3 m1 ^ " * " ^  string_of_mode2 m2
   413       | string_of_mode2 mode = string_of_mode1 mode
   414     and string_of_mode3 (Fun (m1, m2)) = string_of_mode2 m1 ^ " => " ^ string_of_mode3 m2
   415       | string_of_mode3 mode = string_of_mode2 mode
   416   in string_of_mode3 mode end
   417 
   418 fun ascii_string_of_mode mode' =
   419   let
   420     fun ascii_string_of_mode' Input = "i"
   421       | ascii_string_of_mode' Output = "o"
   422       | ascii_string_of_mode' Bool = "b"
   423       | ascii_string_of_mode' (Pair (m1, m2)) =
   424           "P" ^ ascii_string_of_mode' m1 ^ ascii_string_of_mode'_Pair m2
   425       | ascii_string_of_mode' (Fun (m1, m2)) =
   426           "F" ^ ascii_string_of_mode' m1 ^ ascii_string_of_mode'_Fun m2 ^ "B"
   427     and ascii_string_of_mode'_Fun (Fun (m1, m2)) =
   428           ascii_string_of_mode' m1 ^ (if m2 = Bool then "" else "_" ^ ascii_string_of_mode'_Fun m2)
   429       | ascii_string_of_mode'_Fun Bool = "B"
   430       | ascii_string_of_mode'_Fun m = ascii_string_of_mode' m
   431     and ascii_string_of_mode'_Pair (Pair (m1, m2)) =
   432           ascii_string_of_mode' m1 ^ ascii_string_of_mode'_Pair m2
   433       | ascii_string_of_mode'_Pair m = ascii_string_of_mode' m
   434   in ascii_string_of_mode'_Fun mode' end
   435 
   436 
   437 (* premises *)
   438 
   439 datatype indprem =
   440   Prem of term | Negprem of term | Sidecond of term | Generator of (string * typ)
   441 
   442 fun dest_indprem (Prem t) = t
   443   | dest_indprem (Negprem t) = t
   444   | dest_indprem (Sidecond t) = t
   445   | dest_indprem (Generator _) = raise Fail "cannot destruct generator"
   446 
   447 fun map_indprem f (Prem t) = Prem (f t)
   448   | map_indprem f (Negprem t) = Negprem (f t)
   449   | map_indprem f (Sidecond t) = Sidecond (f t)
   450   | map_indprem f (Generator (v, T)) = Generator (dest_Free (f (Free (v, T))))
   451 
   452 
   453 (* general syntactic functions *)
   454 
   455 fun is_equationlike_term (Const (@{const_name Pure.eq}, _) $ _ $ _) = true
   456   | is_equationlike_term
   457       (Const (@{const_name Trueprop}, _) $ (Const (@{const_name HOL.eq}, _) $ _ $ _)) = true
   458   | is_equationlike_term _ = false
   459 
   460 val is_equationlike = is_equationlike_term o prop_of
   461 
   462 fun is_pred_equation_term (Const (@{const_name Pure.eq}, _) $ u $ v) =
   463       (fastype_of u = @{typ bool}) andalso (fastype_of v = @{typ bool})
   464   | is_pred_equation_term _ = false
   465 
   466 val is_pred_equation = is_pred_equation_term o prop_of
   467 
   468 fun is_intro_term constname t =
   469   the_default false (try (fn t =>
   470     case fst (strip_comb (HOLogic.dest_Trueprop (Logic.strip_imp_concl t))) of
   471       Const (c, _) => c = constname
   472     | _ => false) t)
   473 
   474 fun is_intro constname t = is_intro_term constname (prop_of t)
   475 
   476 fun is_predT (T as Type("fun", [_, _])) = (body_type T = @{typ bool})
   477   | is_predT _ = false
   478 
   479 fun get_constrs thy =
   480   let
   481     val ctxt = Proof_Context.init_global thy
   482   in
   483     Ctr_Sugar.ctr_sugars_of ctxt
   484     |> maps (map_filter (try dest_Const) o #ctrs)
   485     |> map (apsnd (fn T => (BNF_Util.num_binder_types T, fst (dest_Type (body_type T)))))
   486   end
   487 
   488 (*** check if a term contains only constructor functions ***)
   489 (* TODO: another copy in the core! *)
   490 (* FIXME: constructor terms are supposed to be seen in the way the code generator
   491   sees constructors.*)
   492 fun is_constrt thy =
   493   let
   494     val cnstrs = get_constrs thy
   495     fun check t =
   496       (case strip_comb t of
   497         (Var _, []) => true
   498       | (Free _, []) => true
   499       | (Const (s, T), ts) =>
   500           (case (AList.lookup (op =) cnstrs s, body_type T) of
   501             (SOME (i, Tname), Type (Tname', _)) =>
   502               length ts = i andalso Tname = Tname' andalso forall check ts
   503           | _ => false)
   504       | _ => false)
   505   in check end
   506 
   507 val is_constr = Code.is_constr o Proof_Context.theory_of
   508 
   509 fun strip_all t = (Term.strip_all_vars t, Term.strip_all_body t)
   510 
   511 fun strip_ex (Const (@{const_name Ex}, _) $ Abs (x, T, t)) =
   512       let
   513         val (xTs, t') = strip_ex t
   514       in
   515         ((x, T) :: xTs, t')
   516       end
   517   | strip_ex t = ([], t)
   518 
   519 fun focus_ex t nctxt =
   520   let
   521     val ((xs, Ts), t') = apfst split_list (strip_ex t)
   522     val (xs', nctxt') = fold_map Name.variant xs nctxt;
   523     val ps' = xs' ~~ Ts;
   524     val vs = map Free ps';
   525     val t'' = Term.subst_bounds (rev vs, t');
   526   in ((ps', t''), nctxt') end
   527 
   528 val strip_intro_concl = strip_comb o HOLogic.dest_Trueprop o Logic.strip_imp_concl o prop_of
   529 
   530 
   531 (* introduction rule combinators *)
   532 
   533 fun map_atoms f intro =
   534   let
   535     val (literals, head) = Logic.strip_horn intro
   536     fun appl t =
   537       (case t of
   538         (@{term Not} $ t') => HOLogic.mk_not (f t')
   539       | _ => f t)
   540   in
   541     Logic.list_implies
   542       (map (HOLogic.mk_Trueprop o appl o HOLogic.dest_Trueprop) literals, head)
   543   end
   544 
   545 fun fold_atoms f intro s =
   546   let
   547     val (literals, _) = Logic.strip_horn intro
   548     fun appl t s =
   549       (case t of
   550         (@{term Not} $ t') => f t' s
   551       | _ => f t s)
   552   in fold appl (map HOLogic.dest_Trueprop literals) s end
   553 
   554 fun fold_map_atoms f intro s =
   555   let
   556     val (literals, head) = Logic.strip_horn intro
   557     fun appl t s =
   558       (case t of
   559         (@{term Not} $ t') => apfst HOLogic.mk_not (f t' s)
   560       | _ => f t s)
   561     val (literals', s') = fold_map appl (map HOLogic.dest_Trueprop literals) s
   562   in
   563     (Logic.list_implies (map HOLogic.mk_Trueprop literals', head), s')
   564   end;
   565 
   566 fun map_filter_premises f intro =
   567   let
   568     val (premises, head) = Logic.strip_horn intro
   569   in
   570     Logic.list_implies (map_filter f premises, head)
   571   end
   572 
   573 fun maps_premises f intro =
   574   let
   575     val (premises, head) = Logic.strip_horn intro
   576   in
   577     Logic.list_implies (maps f premises, head)
   578   end
   579 
   580 fun map_concl f intro =
   581   let
   582     val (premises, head) = Logic.strip_horn intro
   583   in
   584     Logic.list_implies (premises, f head)
   585   end
   586 
   587 
   588 (* combinators to apply a function to all basic parts of nested products *)
   589 
   590 fun map_products f (Const (@{const_name Pair}, T) $ t1 $ t2) =
   591   Const (@{const_name Pair}, T) $ map_products f t1 $ map_products f t2
   592   | map_products f t = f t
   593 
   594 
   595 (* split theorems of case expressions *)
   596 
   597 fun prepare_split_thm ctxt split_thm =
   598     (split_thm RS @{thm iffD2})
   599     |> Local_Defs.unfold ctxt [@{thm atomize_conjL[symmetric]},
   600       @{thm atomize_all[symmetric]}, @{thm atomize_imp[symmetric]}]
   601 
   602 fun find_split_thm thy (Const (name, _)) =
   603     Option.map #split (Ctr_Sugar.ctr_sugar_of_case (Proof_Context.init_global thy) name)
   604   | find_split_thm _ _ = NONE
   605 
   606 
   607 (* lifting term operations to theorems *)
   608 
   609 fun map_term thy f th =
   610   Skip_Proof.make_thm thy (f (prop_of th))
   611 
   612 (*
   613 fun equals_conv lhs_cv rhs_cv ct =
   614   case Thm.term_of ct of
   615     Const (@{const_name Pure.eq}, _) $ _ $ _ => Conv.arg_conv cv ct
   616   | _ => error "equals_conv"
   617 *)
   618 
   619 
   620 (* Different compilations *)
   621 
   622 datatype compilation = Pred | Depth_Limited | Random | Depth_Limited_Random | DSeq | Annotated
   623   | Pos_Random_DSeq | Neg_Random_DSeq | New_Pos_Random_DSeq | New_Neg_Random_DSeq |
   624     Pos_Generator_DSeq | Neg_Generator_DSeq | Pos_Generator_CPS | Neg_Generator_CPS
   625 
   626 fun negative_compilation_of Pos_Random_DSeq = Neg_Random_DSeq
   627   | negative_compilation_of Neg_Random_DSeq = Pos_Random_DSeq
   628   | negative_compilation_of New_Pos_Random_DSeq = New_Neg_Random_DSeq
   629   | negative_compilation_of New_Neg_Random_DSeq = New_Pos_Random_DSeq
   630   | negative_compilation_of Pos_Generator_DSeq = Neg_Generator_DSeq
   631   | negative_compilation_of Neg_Generator_DSeq = Pos_Generator_DSeq
   632   | negative_compilation_of Pos_Generator_CPS = Neg_Generator_CPS
   633   | negative_compilation_of Neg_Generator_CPS = Pos_Generator_CPS
   634   | negative_compilation_of c = c
   635 
   636 fun compilation_for_polarity false Pos_Random_DSeq = Neg_Random_DSeq
   637   | compilation_for_polarity false New_Pos_Random_DSeq = New_Neg_Random_DSeq
   638   | compilation_for_polarity _ c = c
   639 
   640 fun is_depth_limited_compilation c =
   641   (c = New_Pos_Random_DSeq) orelse (c = New_Neg_Random_DSeq) orelse
   642   (c = Pos_Generator_DSeq) orelse (c = Pos_Generator_DSeq)
   643 
   644 fun string_of_compilation c =
   645   (case c of
   646     Pred => ""
   647   | Random => "random"
   648   | Depth_Limited => "depth limited"
   649   | Depth_Limited_Random => "depth limited random"
   650   | DSeq => "dseq"
   651   | Annotated => "annotated"
   652   | Pos_Random_DSeq => "pos_random dseq"
   653   | Neg_Random_DSeq => "neg_random_dseq"
   654   | New_Pos_Random_DSeq => "new_pos_random dseq"
   655   | New_Neg_Random_DSeq => "new_neg_random_dseq"
   656   | Pos_Generator_DSeq => "pos_generator_dseq"
   657   | Neg_Generator_DSeq => "neg_generator_dseq"
   658   | Pos_Generator_CPS => "pos_generator_cps"
   659   | Neg_Generator_CPS => "neg_generator_cps")
   660 
   661 val compilation_names =
   662  [("pred", Pred),
   663   ("random", Random),
   664   ("depth_limited", Depth_Limited),
   665   ("depth_limited_random", Depth_Limited_Random),
   666   (*("annotated", Annotated),*)
   667   ("dseq", DSeq),
   668   ("random_dseq", Pos_Random_DSeq),
   669   ("new_random_dseq", New_Pos_Random_DSeq),
   670   ("generator_dseq", Pos_Generator_DSeq),
   671   ("generator_cps", Pos_Generator_CPS)]
   672 
   673 val non_random_compilations = [Pred, Depth_Limited, DSeq, Annotated]
   674 
   675 
   676 val random_compilations = [Random, Depth_Limited_Random,
   677   Pos_Random_DSeq, Neg_Random_DSeq, New_Pos_Random_DSeq, New_Neg_Random_DSeq,
   678   Pos_Generator_CPS, Neg_Generator_CPS]
   679 
   680 
   681 (* datastructures and setup for generic compilation *)
   682 
   683 datatype compilation_funs = CompilationFuns of {
   684   mk_monadT : typ -> typ,
   685   dest_monadT : typ -> typ,
   686   mk_empty : typ -> term,
   687   mk_single : term -> term,
   688   mk_bind : term * term -> term,
   689   mk_plus : term * term -> term,
   690   mk_if : term -> term,
   691   mk_iterate_upto : typ -> term * term * term -> term,
   692   mk_not : term -> term,
   693   mk_map : typ -> typ -> term -> term -> term
   694 }
   695 
   696 fun mk_monadT (CompilationFuns funs) = #mk_monadT funs
   697 fun dest_monadT (CompilationFuns funs) = #dest_monadT funs
   698 fun mk_empty (CompilationFuns funs) = #mk_empty funs
   699 fun mk_single (CompilationFuns funs) = #mk_single funs
   700 fun mk_bind (CompilationFuns funs) = #mk_bind funs
   701 fun mk_plus (CompilationFuns funs) = #mk_plus funs
   702 fun mk_if (CompilationFuns funs) = #mk_if funs
   703 fun mk_iterate_upto (CompilationFuns funs) = #mk_iterate_upto funs
   704 fun mk_not (CompilationFuns funs) = #mk_not funs
   705 fun mk_map (CompilationFuns funs) = #mk_map funs
   706 
   707 
   708 (** function types and names of different compilations **)
   709 
   710 fun funT_of compfuns mode T =
   711   let
   712     val Ts = binder_types T
   713     val (inTs, outTs) =
   714       split_map_modeT (fn m => fn T => (SOME (funT_of compfuns m T), NONE)) mode Ts
   715   in
   716     inTs ---> (mk_monadT compfuns (HOLogic.mk_tupleT outTs))
   717   end
   718 
   719 
   720 (* Different options for compiler *)
   721 
   722 datatype options = Options of {
   723   expected_modes : (string * mode list) option,
   724   proposed_modes : (string * mode list) list,
   725   proposed_names : ((string * mode) * string) list,
   726   show_steps : bool,
   727   show_proof_trace : bool,
   728   show_intermediate_results : bool,
   729   show_mode_inference : bool,
   730   show_modes : bool,
   731   show_compilation : bool,
   732   show_caught_failures : bool,
   733   show_invalid_clauses : bool,
   734   skip_proof : bool,
   735   no_topmost_reordering : bool,
   736   function_flattening : bool,
   737   specialise : bool,
   738   fail_safe_function_flattening : bool,
   739   no_higher_order_predicate : string list,
   740   inductify : bool,
   741   detect_switches : bool,
   742   smart_depth_limiting : bool,
   743   compilation : compilation
   744 }
   745 
   746 fun expected_modes (Options opt) = #expected_modes opt
   747 fun proposed_modes (Options opt) = AList.lookup (op =) (#proposed_modes opt)
   748 fun proposed_names (Options opt) name mode = AList.lookup (eq_pair (op =) eq_mode)
   749   (#proposed_names opt) (name, mode)
   750 
   751 fun show_steps (Options opt) = #show_steps opt
   752 fun show_intermediate_results (Options opt) = #show_intermediate_results opt
   753 fun show_proof_trace (Options opt) = #show_proof_trace opt
   754 fun show_modes (Options opt) = #show_modes opt
   755 fun show_mode_inference (Options opt) = #show_mode_inference opt
   756 fun show_compilation (Options opt) = #show_compilation opt
   757 fun show_caught_failures (Options opt) = #show_caught_failures opt
   758 fun show_invalid_clauses (Options opt) = #show_invalid_clauses opt
   759 fun skip_proof (Options opt) = #skip_proof opt
   760 
   761 fun function_flattening (Options opt) = #function_flattening opt
   762 fun fail_safe_function_flattening (Options opt) = #fail_safe_function_flattening opt
   763 fun specialise (Options opt) = #specialise opt
   764 fun no_topmost_reordering (Options opt) = #no_topmost_reordering opt
   765 fun no_higher_order_predicate (Options opt) = #no_higher_order_predicate opt
   766 
   767 fun is_inductify (Options opt) = #inductify opt
   768 
   769 fun compilation (Options opt) = #compilation opt
   770 
   771 fun detect_switches (Options opt) = #detect_switches opt
   772 
   773 fun smart_depth_limiting (Options opt) = #smart_depth_limiting opt
   774 
   775 val default_options = Options {
   776   expected_modes = NONE,
   777   proposed_modes = [],
   778   proposed_names = [],
   779   show_steps = false,
   780   show_intermediate_results = false,
   781   show_proof_trace = false,
   782   show_modes = false,
   783   show_mode_inference = false,
   784   show_compilation = false,
   785   show_caught_failures = false,
   786   show_invalid_clauses = false,
   787   skip_proof = true,
   788   no_topmost_reordering = false,
   789   function_flattening = false,
   790   specialise = false,
   791   fail_safe_function_flattening = false,
   792   no_higher_order_predicate = [],
   793   inductify = false,
   794   detect_switches = true,
   795   smart_depth_limiting = false,
   796   compilation = Pred
   797 }
   798 
   799 val bool_options = ["show_steps", "show_intermediate_results", "show_proof_trace", "show_modes",
   800   "show_mode_inference", "show_compilation", "show_invalid_clauses", "skip_proof", "inductify",
   801   "no_function_flattening", "detect_switches", "specialise", "no_topmost_reordering",
   802   "smart_depth_limiting"]
   803 
   804 fun print_step options s =
   805   if show_steps options then tracing s else ()
   806 
   807 
   808 (* simple transformations *)
   809 
   810 (** tuple processing **)
   811 
   812 fun rewrite_args [] (pats, intro_t, ctxt) = (pats, intro_t, ctxt)
   813   | rewrite_args (arg::args) (pats, intro_t, ctxt) =
   814       (case HOLogic.strip_tupleT (fastype_of arg) of
   815         (_ :: _ :: _) =>
   816         let
   817           fun rewrite_arg'
   818                 (Const (@{const_name Pair}, _) $ _ $ t2, Type (@{type_name Product_Type.prod}, [_, T2]))
   819                 (args, (pats, intro_t, ctxt)) =
   820                 rewrite_arg' (t2, T2) (args, (pats, intro_t, ctxt))
   821             | rewrite_arg'
   822                 (t, Type (@{type_name Product_Type.prod}, [T1, T2])) (args, (pats, intro_t, ctxt)) =
   823                 let
   824                   val thy = Proof_Context.theory_of ctxt
   825                   val ([x, y], ctxt') = Variable.variant_fixes ["x", "y"] ctxt
   826                   val pat = (t, HOLogic.mk_prod (Free (x, T1), Free (y, T2)))
   827                   val intro_t' = Pattern.rewrite_term thy [pat] [] intro_t
   828                   val args' = map (Pattern.rewrite_term thy [pat] []) args
   829                 in
   830                   rewrite_arg' (Free (y, T2), T2) (args', (pat::pats, intro_t', ctxt'))
   831                 end
   832             | rewrite_arg' _ (args, (pats, intro_t, ctxt)) = (args, (pats, intro_t, ctxt))
   833           val (args', (pats, intro_t', ctxt')) =
   834             rewrite_arg' (arg, fastype_of arg) (args, (pats, intro_t, ctxt))
   835         in
   836           rewrite_args args' (pats, intro_t', ctxt')
   837         end
   838   | _ => rewrite_args args (pats, intro_t, ctxt))
   839 
   840 fun rewrite_prem atom =
   841   let
   842     val (_, args) = strip_comb atom
   843   in rewrite_args args end
   844 
   845 fun split_conjuncts_in_assms ctxt th =
   846   let
   847     val ((_, [fixed_th]), ctxt') = Variable.import false [th] ctxt
   848     fun split_conjs i nprems th =
   849       if i > nprems then th
   850       else
   851         (case try Drule.RSN (@{thm conjI}, (i, th)) of
   852           SOME th' => split_conjs i (nprems + 1) th'
   853         | NONE => split_conjs (i + 1) nprems th)
   854   in
   855     singleton (Variable.export ctxt' ctxt)
   856       (split_conjs 1 (Thm.nprems_of fixed_th) fixed_th)
   857   end
   858 
   859 fun dest_conjunct_prem th =
   860   (case HOLogic.dest_Trueprop (prop_of th) of
   861     (Const (@{const_name HOL.conj}, _) $ _ $ _) =>
   862       dest_conjunct_prem (th RS @{thm conjunct1})
   863         @ dest_conjunct_prem (th RS @{thm conjunct2})
   864    | _ => [th])
   865 
   866 fun expand_tuples thy intro =
   867   let
   868     val ctxt = Proof_Context.init_global thy
   869     val (((T_insts, t_insts), [intro']), ctxt1) = Variable.import false [intro] ctxt
   870     val intro_t = prop_of intro'
   871     val concl = Logic.strip_imp_concl intro_t
   872     val (_, args) = strip_comb (HOLogic.dest_Trueprop concl)
   873     val (pats', intro_t', ctxt2) = rewrite_args args ([], intro_t, ctxt1)
   874     val (pats', _, ctxt3) = fold_atoms rewrite_prem intro_t' (pats', intro_t', ctxt2)
   875     fun rewrite_pat (ct1, ct2) =
   876       (ct1, cterm_of thy (Pattern.rewrite_term thy pats' [] (term_of ct2)))
   877     val t_insts' = map rewrite_pat t_insts
   878     val intro'' = Thm.instantiate (T_insts, t_insts') intro
   879     val [intro'''] = Variable.export ctxt3 ctxt [intro'']
   880     val intro'''' =
   881       Simplifier.full_simplify
   882         (put_simpset HOL_basic_ss ctxt
   883           addsimps [@{thm fst_conv}, @{thm snd_conv}, @{thm Pair_eq}])
   884       intro'''
   885     (* splitting conjunctions introduced by Pair_eq*)
   886     val intro''''' = split_conjuncts_in_assms ctxt intro''''
   887   in
   888     intro'''''
   889   end
   890 
   891 
   892 (** making case distributivity rules **)
   893 (*** this should be part of the datatype package ***)
   894 
   895 fun datatype_name_of_case_name thy =
   896   Ctr_Sugar.ctr_sugar_of_case (Proof_Context.init_global thy)
   897   #> the #> #ctrs #> hd #> fastype_of #> body_type #> dest_Type #> fst
   898 
   899 fun make_case_comb thy Tcon =
   900   let
   901     val ctxt = Proof_Context.init_global thy
   902     val SOME {casex, ...} = Ctr_Sugar.ctr_sugar_of ctxt Tcon
   903     val casex' = Type.legacy_freeze casex
   904     val Ts = BNF_Util.binder_fun_types (fastype_of casex')
   905   in
   906     list_comb (casex', map_index (fn (j, T) => Free ("f" ^ string_of_int j,  T)) Ts)
   907   end
   908 
   909 fun make_case_distrib thy Tcon =
   910   let
   911     val comb = make_case_comb thy Tcon;
   912     val Type ("fun", [T, T']) = fastype_of comb;
   913     val (Const (case_name, _), fs) = strip_comb comb
   914     val used = Term.add_tfree_names comb []
   915     val U = TFree (singleton (Name.variant_list used) "'t", @{sort type})
   916     val x = Free ("x", T)
   917     val f = Free ("f", T' --> U)
   918     fun apply_f f' =
   919       let
   920         val Ts = binder_types (fastype_of f')
   921         val bs = map Bound ((length Ts - 1) downto 0)
   922       in
   923         fold_rev absdummy Ts (f $ (list_comb (f', bs)))
   924       end
   925     val fs' = map apply_f fs
   926     val case_c' = Const (case_name, (map fastype_of fs') @ [T] ---> U)
   927   in
   928     HOLogic.mk_eq (f $ (comb $ x), list_comb (case_c', fs') $ x)
   929   end
   930 
   931 fun case_rewrite thy Tcon =
   932   (Drule.export_without_context o Skip_Proof.make_thm thy o HOLogic.mk_Trueprop)
   933     (make_case_distrib thy Tcon)
   934 
   935 fun instantiated_case_rewrite thy Tcon =
   936   let
   937     val th = case_rewrite thy Tcon
   938     val ctxt = Proof_Context.init_global thy
   939     val f = fst (strip_comb (fst (HOLogic.dest_eq (HOLogic.dest_Trueprop (prop_of th)))))
   940     val Type ("fun", [uninst_T, uninst_T']) = fastype_of f
   941     val ([yname], ctxt') = Variable.add_fixes ["y"] ctxt
   942     val T' = TFree ("'t'", @{sort type})
   943     val U = TFree ("'u", @{sort type})
   944     val y = Free (yname, U)
   945     val f' = absdummy (U --> T') (Bound 0 $ y)
   946     val th' = Thm.certify_instantiate
   947       ([(dest_TVar uninst_T, U --> T'), (dest_TVar uninst_T', T')],
   948        [((fst (dest_Var f), (U --> T') --> T'), f')]) th
   949     val [th'] = Variable.export (Variable.declare_thm th' ctxt') ctxt [th']
   950   in
   951     th'
   952   end
   953 
   954 fun case_betapply thy t =
   955   let
   956     val case_name = fst (dest_Const (fst (strip_comb t)))
   957     val Tcon = datatype_name_of_case_name thy case_name
   958     val th = instantiated_case_rewrite thy Tcon
   959   in
   960     Raw_Simplifier.rewrite_term thy [th RS @{thm eq_reflection}] [] t
   961   end
   962 
   963 
   964 (*** conversions ***)
   965 
   966 fun imp_prems_conv cv ct =
   967   (case Thm.term_of ct of
   968     Const (@{const_name Pure.imp}, _) $ _ $ _ =>
   969       Conv.combination_conv (Conv.arg_conv cv) (imp_prems_conv cv) ct
   970   | _ => Conv.all_conv ct)
   971 
   972 
   973 (** eta contract higher-order arguments **)
   974 
   975 fun eta_contract_ho_arguments thy intro =
   976   let
   977     fun f atom = list_comb (apsnd ((map o map_products) Envir.eta_contract) (strip_comb atom))
   978   in
   979     map_term thy (map_concl f o map_atoms f) intro
   980   end
   981 
   982 
   983 (** remove equalities **)
   984 
   985 fun remove_equalities thy intro =
   986   let
   987     fun remove_eqs intro_t =
   988       let
   989         val (prems, concl) = Logic.strip_horn intro_t
   990         fun remove_eq (prems, concl) =
   991           let
   992             fun removable_eq prem =
   993               (case try (HOLogic.dest_eq o HOLogic.dest_Trueprop) prem of
   994                 SOME (lhs, rhs) =>
   995                   (case lhs of
   996                     Var _ => true
   997                   | _ => (case rhs of Var _ => true | _ => false))
   998               | NONE => false)
   999           in
  1000             (case find_first removable_eq prems of
  1001               NONE => (prems, concl)
  1002             | SOME eq =>
  1003                 let
  1004                   val (lhs, rhs) = HOLogic.dest_eq (HOLogic.dest_Trueprop eq)
  1005                   val prems' = remove (op =) eq prems
  1006                   val subst =
  1007                     (case lhs of
  1008                       (v as Var _) =>
  1009                         (fn t => if t = v then rhs else t)
  1010                     | _ => (case rhs of (v as Var _) => (fn t => if t = v then lhs else t)))
  1011                 in
  1012                   remove_eq (map (map_aterms subst) prems', map_aterms subst concl)
  1013                 end)
  1014           end
  1015       in
  1016         Logic.list_implies (remove_eq (prems, concl))
  1017       end
  1018   in
  1019     map_term thy remove_eqs intro
  1020   end
  1021 
  1022 
  1023 (* Some last processing *)
  1024 
  1025 fun remove_pointless_clauses intro =
  1026   if Logic.strip_imp_prems (prop_of intro) = [@{prop "False"}] then
  1027     []
  1028   else [intro]
  1029 
  1030 
  1031 (* some peephole optimisations *)
  1032 
  1033 fun peephole_optimisation thy intro =
  1034   let
  1035     val ctxt = Proof_Context.init_global thy  (* FIXME proper context!? *)
  1036     val process =
  1037       rewrite_rule ctxt (Named_Theorems.get ctxt @{named_theorems code_pred_simp})
  1038     fun process_False intro_t =
  1039       if member (op =) (Logic.strip_imp_prems intro_t) @{prop "False"}
  1040       then NONE else SOME intro_t
  1041     fun process_True intro_t =
  1042       map_filter_premises (fn p => if p = @{prop True} then NONE else SOME p) intro_t
  1043   in
  1044     Option.map (Skip_Proof.make_thm thy)
  1045       (process_False (process_True (prop_of (process intro))))
  1046   end
  1047 
  1048 
  1049 (* importing introduction rules *)
  1050 
  1051 fun import_intros inp_pred [] ctxt =
  1052       let
  1053         val ([outp_pred], ctxt') = Variable.import_terms true [inp_pred] ctxt
  1054         val T = fastype_of outp_pred
  1055         val paramTs = ho_argsT_of_typ (binder_types T)
  1056         val (param_names, _) = Variable.variant_fixes
  1057           (map (fn i => "p" ^ (string_of_int i)) (1 upto (length paramTs))) ctxt'
  1058         val params = map2 (curry Free) param_names paramTs
  1059       in
  1060         (((outp_pred, params), []), ctxt')
  1061       end
  1062   | import_intros inp_pred (th :: ths) ctxt =
  1063       let
  1064         val ((_, [th']), ctxt') = Variable.import true [th] ctxt
  1065         val thy = Proof_Context.theory_of ctxt'
  1066         val (pred, args) = strip_intro_concl th'
  1067         val T = fastype_of pred
  1068         val ho_args = ho_args_of_typ T args
  1069         fun subst_of (pred', pred) =
  1070           let
  1071             val subst = Sign.typ_match thy (fastype_of pred', fastype_of pred) Vartab.empty
  1072               handle Type.TYPE_MATCH =>
  1073                 error ("Type mismatch of predicate " ^ fst (dest_Const pred) ^
  1074                   " (trying to match " ^ Syntax.string_of_typ ctxt (fastype_of pred') ^
  1075                   " and " ^ Syntax.string_of_typ ctxt (fastype_of pred) ^ ")" ^
  1076                   " in " ^ Display.string_of_thm ctxt th)
  1077           in map (fn (indexname, (s, T)) => ((indexname, s), T)) (Vartab.dest subst) end
  1078         fun instantiate_typ th =
  1079           let
  1080             val (pred', _) = strip_intro_concl th
  1081             val _ =
  1082               if not (fst (dest_Const pred) = fst (dest_Const pred')) then
  1083                 raise Fail "Trying to instantiate another predicate"
  1084               else ()
  1085           in Thm.certify_instantiate (subst_of (pred', pred), []) th end
  1086         fun instantiate_ho_args th =
  1087           let
  1088             val (_, args') =
  1089               (strip_comb o HOLogic.dest_Trueprop o Logic.strip_imp_concl o prop_of) th
  1090             val ho_args' = map dest_Var (ho_args_of_typ T args')
  1091           in Thm.certify_instantiate ([], ho_args' ~~ ho_args) th end
  1092         val outp_pred =
  1093           Term_Subst.instantiate (subst_of (inp_pred, pred), []) inp_pred
  1094         val ((_, ths'), ctxt1) =
  1095           Variable.import false (map (instantiate_typ #> instantiate_ho_args) ths) ctxt'
  1096       in
  1097         (((outp_pred, ho_args), th' :: ths'), ctxt1)
  1098       end
  1099 
  1100 
  1101 (* generation of case rules from user-given introduction rules *)
  1102 
  1103 fun mk_args2 (Type (@{type_name Product_Type.prod}, [T1, T2])) st =
  1104       let
  1105         val (t1, st') = mk_args2 T1 st
  1106         val (t2, st'') = mk_args2 T2 st'
  1107       in
  1108         (HOLogic.mk_prod (t1, t2), st'')
  1109       end
  1110   (*| mk_args2 (T as Type ("fun", _)) (params, ctxt) =
  1111     let
  1112       val (S, U) = strip_type T
  1113     in
  1114       if U = HOLogic.boolT then
  1115         (hd params, (tl params, ctxt))
  1116       else
  1117         let
  1118           val ([x], ctxt') = Variable.variant_fixes ["x"] ctxt
  1119         in
  1120           (Free (x, T), (params, ctxt'))
  1121         end
  1122     end*)
  1123   | mk_args2 T (params, ctxt) =
  1124       let
  1125         val ([x], ctxt') = Variable.variant_fixes ["x"] ctxt
  1126       in
  1127         (Free (x, T), (params, ctxt'))
  1128       end
  1129 
  1130 fun mk_casesrule ctxt pred introrules =
  1131   let
  1132     (* TODO: can be simplified if parameters are not treated specially ? *)
  1133     val (((pred, params), intros_th), ctxt1) = import_intros pred introrules ctxt
  1134     (* TODO: distinct required ? -- test case with more than one parameter! *)
  1135     val params = distinct (op aconv) params
  1136     val intros = map prop_of intros_th
  1137     val ([propname], ctxt2) = Variable.variant_fixes ["thesis"] ctxt1
  1138     val prop = HOLogic.mk_Trueprop (Free (propname, HOLogic.boolT))
  1139     val argsT = binder_types (fastype_of pred)
  1140     (* TODO: can be simplified if parameters are not treated specially ? <-- see uncommented code! *)
  1141     val (argvs, _) = fold_map mk_args2 argsT (params, ctxt2)
  1142     fun mk_case intro =
  1143       let
  1144         val (_, args) = (strip_comb o HOLogic.dest_Trueprop o Logic.strip_imp_concl) intro
  1145         val prems = Logic.strip_imp_prems intro
  1146         val eqprems =
  1147           map2 (HOLogic.mk_Trueprop oo (curry HOLogic.mk_eq)) argvs args
  1148         val frees = map Free (fold Term.add_frees (args @ prems) [])
  1149       in fold Logic.all frees (Logic.list_implies (eqprems @ prems, prop)) end
  1150     val assm = HOLogic.mk_Trueprop (list_comb (pred, argvs))
  1151     val cases = map mk_case intros
  1152   in Logic.list_implies (assm :: cases, prop) end;
  1153 
  1154 
  1155 (* unifying constants to have the same type variables *)
  1156 
  1157 fun unify_consts thy cs intr_ts =
  1158   let
  1159      val add_term_consts_2 = fold_aterms (fn Const c => insert (op =) c | _ => I);
  1160      fun varify (t, (i, ts)) =
  1161        let val t' = map_types (Logic.incr_tvar (i + 1)) (#2 (Type.varify_global [] t))
  1162        in (maxidx_of_term t', t' :: ts) end
  1163      val (i, cs') = List.foldr varify (~1, []) cs
  1164      val (i', intr_ts') = List.foldr varify (i, []) intr_ts
  1165      val rec_consts = fold add_term_consts_2 cs' []
  1166      val intr_consts = fold add_term_consts_2 intr_ts' []
  1167      fun unify (cname, cT) =
  1168        let val consts = map snd (filter (fn c => fst c = cname) intr_consts)
  1169        in fold (Sign.typ_unify thy) ((replicate (length consts) cT) ~~ consts) end
  1170      val (env, _) = fold unify rec_consts (Vartab.empty, i')
  1171      val subst = map_types (Envir.norm_type env)
  1172    in (map subst cs', map subst intr_ts')
  1173    end handle Type.TUNIFY =>
  1174      (warning "Occurrences of recursive constant have non-unifiable types"; (cs, intr_ts))
  1175 
  1176 
  1177 (* preprocessing rules *)
  1178 
  1179 fun preprocess_equality thy rule =
  1180   Conv.fconv_rule
  1181     (imp_prems_conv
  1182       (HOLogic.Trueprop_conv
  1183         (Conv.try_conv (Conv.rewr_conv (Thm.symmetric @{thm Predicate.eq_is_eq})))))
  1184     (Thm.transfer thy rule)
  1185 
  1186 fun preprocess_intro thy = expand_tuples thy #> preprocess_equality thy
  1187 
  1188 
  1189 (* defining a quickcheck predicate *)
  1190 
  1191 fun strip_imp_prems (Const(@{const_name HOL.implies}, _) $ A $ B) = A :: strip_imp_prems B
  1192   | strip_imp_prems _ = [];
  1193 
  1194 fun strip_imp_concl (Const(@{const_name HOL.implies}, _) $ _ $ B) = strip_imp_concl B
  1195   | strip_imp_concl A = A;
  1196 
  1197 fun strip_horn A = (strip_imp_prems A, strip_imp_concl A)
  1198 
  1199 fun define_quickcheck_predicate t thy =
  1200   let
  1201     val (vs, t') = strip_abs t
  1202     val vs' = Variable.variant_frees (Proof_Context.init_global thy) [] vs (* FIXME proper context!? *)
  1203     val t'' = subst_bounds (map Free (rev vs'), t')
  1204     val (prems, concl) = strip_horn t''
  1205     val constname = "quickcheck"
  1206     val full_constname = Sign.full_bname thy constname
  1207     val constT = map snd vs' ---> @{typ bool}
  1208     val thy1 = Sign.add_consts [(Binding.name constname, constT, NoSyn)] thy
  1209     val const = Const (full_constname, constT)
  1210     val t =
  1211       Logic.list_implies
  1212         (map HOLogic.mk_Trueprop (prems @ [HOLogic.mk_not concl]),
  1213           HOLogic.mk_Trueprop (list_comb (const, map Free vs')))
  1214     val intro =
  1215       Goal.prove (Proof_Context.init_global thy1) (map fst vs') [] t
  1216         (fn _ => ALLGOALS Skip_Proof.cheat_tac)
  1217   in
  1218     ((((full_constname, constT), vs'), intro), thy1)
  1219   end
  1220 
  1221 end