src/HOL/Divides.thy
author huffman
Tue Mar 27 10:20:31 2012 +0200 (2012-03-27)
changeset 47136 5b6c5641498a
parent 47135 fb67b596067f
child 47137 7f5f0531cae6
permissions -rw-r--r--
simplify some proofs
     1 (*  Title:      HOL/Divides.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1999  University of Cambridge
     4 *)
     5 
     6 header {* The division operators div and mod *}
     7 
     8 theory Divides
     9 imports Nat_Numeral Nat_Transfer
    10 uses "~~/src/Provers/Arith/cancel_div_mod.ML"
    11 begin
    12 
    13 subsection {* Syntactic division operations *}
    14 
    15 class div = dvd +
    16   fixes div :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "div" 70)
    17     and mod :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "mod" 70)
    18 
    19 
    20 subsection {* Abstract division in commutative semirings. *}
    21 
    22 class semiring_div = comm_semiring_1_cancel + no_zero_divisors + div +
    23   assumes mod_div_equality: "a div b * b + a mod b = a"
    24     and div_by_0 [simp]: "a div 0 = 0"
    25     and div_0 [simp]: "0 div a = 0"
    26     and div_mult_self1 [simp]: "b \<noteq> 0 \<Longrightarrow> (a + c * b) div b = c + a div b"
    27     and div_mult_mult1 [simp]: "c \<noteq> 0 \<Longrightarrow> (c * a) div (c * b) = a div b"
    28 begin
    29 
    30 text {* @{const div} and @{const mod} *}
    31 
    32 lemma mod_div_equality2: "b * (a div b) + a mod b = a"
    33   unfolding mult_commute [of b]
    34   by (rule mod_div_equality)
    35 
    36 lemma mod_div_equality': "a mod b + a div b * b = a"
    37   using mod_div_equality [of a b]
    38   by (simp only: add_ac)
    39 
    40 lemma div_mod_equality: "((a div b) * b + a mod b) + c = a + c"
    41   by (simp add: mod_div_equality)
    42 
    43 lemma div_mod_equality2: "(b * (a div b) + a mod b) + c = a + c"
    44   by (simp add: mod_div_equality2)
    45 
    46 lemma mod_by_0 [simp]: "a mod 0 = a"
    47   using mod_div_equality [of a zero] by simp
    48 
    49 lemma mod_0 [simp]: "0 mod a = 0"
    50   using mod_div_equality [of zero a] div_0 by simp
    51 
    52 lemma div_mult_self2 [simp]:
    53   assumes "b \<noteq> 0"
    54   shows "(a + b * c) div b = c + a div b"
    55   using assms div_mult_self1 [of b a c] by (simp add: mult_commute)
    56 
    57 lemma mod_mult_self1 [simp]: "(a + c * b) mod b = a mod b"
    58 proof (cases "b = 0")
    59   case True then show ?thesis by simp
    60 next
    61   case False
    62   have "a + c * b = (a + c * b) div b * b + (a + c * b) mod b"
    63     by (simp add: mod_div_equality)
    64   also from False div_mult_self1 [of b a c] have
    65     "\<dots> = (c + a div b) * b + (a + c * b) mod b"
    66       by (simp add: algebra_simps)
    67   finally have "a = a div b * b + (a + c * b) mod b"
    68     by (simp add: add_commute [of a] add_assoc left_distrib)
    69   then have "a div b * b + (a + c * b) mod b = a div b * b + a mod b"
    70     by (simp add: mod_div_equality)
    71   then show ?thesis by simp
    72 qed
    73 
    74 lemma mod_mult_self2 [simp]: "(a + b * c) mod b = a mod b"
    75   by (simp add: mult_commute [of b])
    76 
    77 lemma div_mult_self1_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> b * a div b = a"
    78   using div_mult_self2 [of b 0 a] by simp
    79 
    80 lemma div_mult_self2_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> a * b div b = a"
    81   using div_mult_self1 [of b 0 a] by simp
    82 
    83 lemma mod_mult_self1_is_0 [simp]: "b * a mod b = 0"
    84   using mod_mult_self2 [of 0 b a] by simp
    85 
    86 lemma mod_mult_self2_is_0 [simp]: "a * b mod b = 0"
    87   using mod_mult_self1 [of 0 a b] by simp
    88 
    89 lemma div_by_1 [simp]: "a div 1 = a"
    90   using div_mult_self2_is_id [of 1 a] zero_neq_one by simp
    91 
    92 lemma mod_by_1 [simp]: "a mod 1 = 0"
    93 proof -
    94   from mod_div_equality [of a one] div_by_1 have "a + a mod 1 = a" by simp
    95   then have "a + a mod 1 = a + 0" by simp
    96   then show ?thesis by (rule add_left_imp_eq)
    97 qed
    98 
    99 lemma mod_self [simp]: "a mod a = 0"
   100   using mod_mult_self2_is_0 [of 1] by simp
   101 
   102 lemma div_self [simp]: "a \<noteq> 0 \<Longrightarrow> a div a = 1"
   103   using div_mult_self2_is_id [of _ 1] by simp
   104 
   105 lemma div_add_self1 [simp]:
   106   assumes "b \<noteq> 0"
   107   shows "(b + a) div b = a div b + 1"
   108   using assms div_mult_self1 [of b a 1] by (simp add: add_commute)
   109 
   110 lemma div_add_self2 [simp]:
   111   assumes "b \<noteq> 0"
   112   shows "(a + b) div b = a div b + 1"
   113   using assms div_add_self1 [of b a] by (simp add: add_commute)
   114 
   115 lemma mod_add_self1 [simp]:
   116   "(b + a) mod b = a mod b"
   117   using mod_mult_self1 [of a 1 b] by (simp add: add_commute)
   118 
   119 lemma mod_add_self2 [simp]:
   120   "(a + b) mod b = a mod b"
   121   using mod_mult_self1 [of a 1 b] by simp
   122 
   123 lemma mod_div_decomp:
   124   fixes a b
   125   obtains q r where "q = a div b" and "r = a mod b"
   126     and "a = q * b + r"
   127 proof -
   128   from mod_div_equality have "a = a div b * b + a mod b" by simp
   129   moreover have "a div b = a div b" ..
   130   moreover have "a mod b = a mod b" ..
   131   note that ultimately show thesis by blast
   132 qed
   133 
   134 lemma dvd_eq_mod_eq_0 [code]: "a dvd b \<longleftrightarrow> b mod a = 0"
   135 proof
   136   assume "b mod a = 0"
   137   with mod_div_equality [of b a] have "b div a * a = b" by simp
   138   then have "b = a * (b div a)" unfolding mult_commute ..
   139   then have "\<exists>c. b = a * c" ..
   140   then show "a dvd b" unfolding dvd_def .
   141 next
   142   assume "a dvd b"
   143   then have "\<exists>c. b = a * c" unfolding dvd_def .
   144   then obtain c where "b = a * c" ..
   145   then have "b mod a = a * c mod a" by simp
   146   then have "b mod a = c * a mod a" by (simp add: mult_commute)
   147   then show "b mod a = 0" by simp
   148 qed
   149 
   150 lemma mod_div_trivial [simp]: "a mod b div b = 0"
   151 proof (cases "b = 0")
   152   assume "b = 0"
   153   thus ?thesis by simp
   154 next
   155   assume "b \<noteq> 0"
   156   hence "a div b + a mod b div b = (a mod b + a div b * b) div b"
   157     by (rule div_mult_self1 [symmetric])
   158   also have "\<dots> = a div b"
   159     by (simp only: mod_div_equality')
   160   also have "\<dots> = a div b + 0"
   161     by simp
   162   finally show ?thesis
   163     by (rule add_left_imp_eq)
   164 qed
   165 
   166 lemma mod_mod_trivial [simp]: "a mod b mod b = a mod b"
   167 proof -
   168   have "a mod b mod b = (a mod b + a div b * b) mod b"
   169     by (simp only: mod_mult_self1)
   170   also have "\<dots> = a mod b"
   171     by (simp only: mod_div_equality')
   172   finally show ?thesis .
   173 qed
   174 
   175 lemma dvd_imp_mod_0: "a dvd b \<Longrightarrow> b mod a = 0"
   176 by (rule dvd_eq_mod_eq_0[THEN iffD1])
   177 
   178 lemma dvd_div_mult_self: "a dvd b \<Longrightarrow> (b div a) * a = b"
   179 by (subst (2) mod_div_equality [of b a, symmetric]) (simp add:dvd_imp_mod_0)
   180 
   181 lemma dvd_mult_div_cancel: "a dvd b \<Longrightarrow> a * (b div a) = b"
   182 by (drule dvd_div_mult_self) (simp add: mult_commute)
   183 
   184 lemma dvd_div_mult: "a dvd b \<Longrightarrow> (b div a) * c = b * c div a"
   185 apply (cases "a = 0")
   186  apply simp
   187 apply (auto simp: dvd_def mult_assoc)
   188 done
   189 
   190 lemma div_dvd_div[simp]:
   191   "a dvd b \<Longrightarrow> a dvd c \<Longrightarrow> (b div a dvd c div a) = (b dvd c)"
   192 apply (cases "a = 0")
   193  apply simp
   194 apply (unfold dvd_def)
   195 apply auto
   196  apply(blast intro:mult_assoc[symmetric])
   197 apply(fastforce simp add: mult_assoc)
   198 done
   199 
   200 lemma dvd_mod_imp_dvd: "[| k dvd m mod n;  k dvd n |] ==> k dvd m"
   201   apply (subgoal_tac "k dvd (m div n) *n + m mod n")
   202    apply (simp add: mod_div_equality)
   203   apply (simp only: dvd_add dvd_mult)
   204   done
   205 
   206 text {* Addition respects modular equivalence. *}
   207 
   208 lemma mod_add_left_eq: "(a + b) mod c = (a mod c + b) mod c"
   209 proof -
   210   have "(a + b) mod c = (a div c * c + a mod c + b) mod c"
   211     by (simp only: mod_div_equality)
   212   also have "\<dots> = (a mod c + b + a div c * c) mod c"
   213     by (simp only: add_ac)
   214   also have "\<dots> = (a mod c + b) mod c"
   215     by (rule mod_mult_self1)
   216   finally show ?thesis .
   217 qed
   218 
   219 lemma mod_add_right_eq: "(a + b) mod c = (a + b mod c) mod c"
   220 proof -
   221   have "(a + b) mod c = (a + (b div c * c + b mod c)) mod c"
   222     by (simp only: mod_div_equality)
   223   also have "\<dots> = (a + b mod c + b div c * c) mod c"
   224     by (simp only: add_ac)
   225   also have "\<dots> = (a + b mod c) mod c"
   226     by (rule mod_mult_self1)
   227   finally show ?thesis .
   228 qed
   229 
   230 lemma mod_add_eq: "(a + b) mod c = (a mod c + b mod c) mod c"
   231 by (rule trans [OF mod_add_left_eq mod_add_right_eq])
   232 
   233 lemma mod_add_cong:
   234   assumes "a mod c = a' mod c"
   235   assumes "b mod c = b' mod c"
   236   shows "(a + b) mod c = (a' + b') mod c"
   237 proof -
   238   have "(a mod c + b mod c) mod c = (a' mod c + b' mod c) mod c"
   239     unfolding assms ..
   240   thus ?thesis
   241     by (simp only: mod_add_eq [symmetric])
   242 qed
   243 
   244 lemma div_add [simp]: "z dvd x \<Longrightarrow> z dvd y
   245   \<Longrightarrow> (x + y) div z = x div z + y div z"
   246 by (cases "z = 0", simp, unfold dvd_def, auto simp add: algebra_simps)
   247 
   248 text {* Multiplication respects modular equivalence. *}
   249 
   250 lemma mod_mult_left_eq: "(a * b) mod c = ((a mod c) * b) mod c"
   251 proof -
   252   have "(a * b) mod c = ((a div c * c + a mod c) * b) mod c"
   253     by (simp only: mod_div_equality)
   254   also have "\<dots> = (a mod c * b + a div c * b * c) mod c"
   255     by (simp only: algebra_simps)
   256   also have "\<dots> = (a mod c * b) mod c"
   257     by (rule mod_mult_self1)
   258   finally show ?thesis .
   259 qed
   260 
   261 lemma mod_mult_right_eq: "(a * b) mod c = (a * (b mod c)) mod c"
   262 proof -
   263   have "(a * b) mod c = (a * (b div c * c + b mod c)) mod c"
   264     by (simp only: mod_div_equality)
   265   also have "\<dots> = (a * (b mod c) + a * (b div c) * c) mod c"
   266     by (simp only: algebra_simps)
   267   also have "\<dots> = (a * (b mod c)) mod c"
   268     by (rule mod_mult_self1)
   269   finally show ?thesis .
   270 qed
   271 
   272 lemma mod_mult_eq: "(a * b) mod c = ((a mod c) * (b mod c)) mod c"
   273 by (rule trans [OF mod_mult_left_eq mod_mult_right_eq])
   274 
   275 lemma mod_mult_cong:
   276   assumes "a mod c = a' mod c"
   277   assumes "b mod c = b' mod c"
   278   shows "(a * b) mod c = (a' * b') mod c"
   279 proof -
   280   have "(a mod c * (b mod c)) mod c = (a' mod c * (b' mod c)) mod c"
   281     unfolding assms ..
   282   thus ?thesis
   283     by (simp only: mod_mult_eq [symmetric])
   284 qed
   285 
   286 lemma mod_mod_cancel:
   287   assumes "c dvd b"
   288   shows "a mod b mod c = a mod c"
   289 proof -
   290   from `c dvd b` obtain k where "b = c * k"
   291     by (rule dvdE)
   292   have "a mod b mod c = a mod (c * k) mod c"
   293     by (simp only: `b = c * k`)
   294   also have "\<dots> = (a mod (c * k) + a div (c * k) * k * c) mod c"
   295     by (simp only: mod_mult_self1)
   296   also have "\<dots> = (a div (c * k) * (c * k) + a mod (c * k)) mod c"
   297     by (simp only: add_ac mult_ac)
   298   also have "\<dots> = a mod c"
   299     by (simp only: mod_div_equality)
   300   finally show ?thesis .
   301 qed
   302 
   303 lemma div_mult_div_if_dvd:
   304   "y dvd x \<Longrightarrow> z dvd w \<Longrightarrow> (x div y) * (w div z) = (x * w) div (y * z)"
   305   apply (cases "y = 0", simp)
   306   apply (cases "z = 0", simp)
   307   apply (auto elim!: dvdE simp add: algebra_simps)
   308   apply (subst mult_assoc [symmetric])
   309   apply (simp add: no_zero_divisors)
   310   done
   311 
   312 lemma div_mult_swap:
   313   assumes "c dvd b"
   314   shows "a * (b div c) = (a * b) div c"
   315 proof -
   316   from assms have "b div c * (a div 1) = b * a div (c * 1)"
   317     by (simp only: div_mult_div_if_dvd one_dvd)
   318   then show ?thesis by (simp add: mult_commute)
   319 qed
   320    
   321 lemma div_mult_mult2 [simp]:
   322   "c \<noteq> 0 \<Longrightarrow> (a * c) div (b * c) = a div b"
   323   by (drule div_mult_mult1) (simp add: mult_commute)
   324 
   325 lemma div_mult_mult1_if [simp]:
   326   "(c * a) div (c * b) = (if c = 0 then 0 else a div b)"
   327   by simp_all
   328 
   329 lemma mod_mult_mult1:
   330   "(c * a) mod (c * b) = c * (a mod b)"
   331 proof (cases "c = 0")
   332   case True then show ?thesis by simp
   333 next
   334   case False
   335   from mod_div_equality
   336   have "((c * a) div (c * b)) * (c * b) + (c * a) mod (c * b) = c * a" .
   337   with False have "c * ((a div b) * b + a mod b) + (c * a) mod (c * b)
   338     = c * a + c * (a mod b)" by (simp add: algebra_simps)
   339   with mod_div_equality show ?thesis by simp 
   340 qed
   341   
   342 lemma mod_mult_mult2:
   343   "(a * c) mod (b * c) = (a mod b) * c"
   344   using mod_mult_mult1 [of c a b] by (simp add: mult_commute)
   345 
   346 lemma dvd_mod: "k dvd m \<Longrightarrow> k dvd n \<Longrightarrow> k dvd (m mod n)"
   347   unfolding dvd_def by (auto simp add: mod_mult_mult1)
   348 
   349 lemma dvd_mod_iff: "k dvd n \<Longrightarrow> k dvd (m mod n) \<longleftrightarrow> k dvd m"
   350 by (blast intro: dvd_mod_imp_dvd dvd_mod)
   351 
   352 lemma div_power:
   353   "y dvd x \<Longrightarrow> (x div y) ^ n = x ^ n div y ^ n"
   354 apply (induct n)
   355  apply simp
   356 apply(simp add: div_mult_div_if_dvd dvd_power_same)
   357 done
   358 
   359 lemma dvd_div_eq_mult:
   360   assumes "a \<noteq> 0" and "a dvd b"  
   361   shows "b div a = c \<longleftrightarrow> b = c * a"
   362 proof
   363   assume "b = c * a"
   364   then show "b div a = c" by (simp add: assms)
   365 next
   366   assume "b div a = c"
   367   then have "b div a * a = c * a" by simp
   368   moreover from `a dvd b` have "b div a * a = b" by (simp add: dvd_div_mult_self)
   369   ultimately show "b = c * a" by simp
   370 qed
   371    
   372 lemma dvd_div_div_eq_mult:
   373   assumes "a \<noteq> 0" "c \<noteq> 0" and "a dvd b" "c dvd d"
   374   shows "b div a = d div c \<longleftrightarrow> b * c = a * d"
   375   using assms by (auto simp add: mult_commute [of _ a] dvd_div_mult_self dvd_div_eq_mult div_mult_swap intro: sym)
   376 
   377 end
   378 
   379 class ring_div = semiring_div + comm_ring_1
   380 begin
   381 
   382 subclass ring_1_no_zero_divisors ..
   383 
   384 text {* Negation respects modular equivalence. *}
   385 
   386 lemma mod_minus_eq: "(- a) mod b = (- (a mod b)) mod b"
   387 proof -
   388   have "(- a) mod b = (- (a div b * b + a mod b)) mod b"
   389     by (simp only: mod_div_equality)
   390   also have "\<dots> = (- (a mod b) + - (a div b) * b) mod b"
   391     by (simp only: minus_add_distrib minus_mult_left add_ac)
   392   also have "\<dots> = (- (a mod b)) mod b"
   393     by (rule mod_mult_self1)
   394   finally show ?thesis .
   395 qed
   396 
   397 lemma mod_minus_cong:
   398   assumes "a mod b = a' mod b"
   399   shows "(- a) mod b = (- a') mod b"
   400 proof -
   401   have "(- (a mod b)) mod b = (- (a' mod b)) mod b"
   402     unfolding assms ..
   403   thus ?thesis
   404     by (simp only: mod_minus_eq [symmetric])
   405 qed
   406 
   407 text {* Subtraction respects modular equivalence. *}
   408 
   409 lemma mod_diff_left_eq: "(a - b) mod c = (a mod c - b) mod c"
   410   unfolding diff_minus
   411   by (intro mod_add_cong mod_minus_cong) simp_all
   412 
   413 lemma mod_diff_right_eq: "(a - b) mod c = (a - b mod c) mod c"
   414   unfolding diff_minus
   415   by (intro mod_add_cong mod_minus_cong) simp_all
   416 
   417 lemma mod_diff_eq: "(a - b) mod c = (a mod c - b mod c) mod c"
   418   unfolding diff_minus
   419   by (intro mod_add_cong mod_minus_cong) simp_all
   420 
   421 lemma mod_diff_cong:
   422   assumes "a mod c = a' mod c"
   423   assumes "b mod c = b' mod c"
   424   shows "(a - b) mod c = (a' - b') mod c"
   425   unfolding diff_minus using assms
   426   by (intro mod_add_cong mod_minus_cong)
   427 
   428 lemma dvd_neg_div: "y dvd x \<Longrightarrow> -x div y = - (x div y)"
   429 apply (case_tac "y = 0") apply simp
   430 apply (auto simp add: dvd_def)
   431 apply (subgoal_tac "-(y * k) = y * - k")
   432  apply (erule ssubst)
   433  apply (erule div_mult_self1_is_id)
   434 apply simp
   435 done
   436 
   437 lemma dvd_div_neg: "y dvd x \<Longrightarrow> x div -y = - (x div y)"
   438 apply (case_tac "y = 0") apply simp
   439 apply (auto simp add: dvd_def)
   440 apply (subgoal_tac "y * k = -y * -k")
   441  apply (erule ssubst)
   442  apply (rule div_mult_self1_is_id)
   443  apply simp
   444 apply simp
   445 done
   446 
   447 end
   448 
   449 
   450 subsection {* Division on @{typ nat} *}
   451 
   452 text {*
   453   We define @{const div} and @{const mod} on @{typ nat} by means
   454   of a characteristic relation with two input arguments
   455   @{term "m\<Colon>nat"}, @{term "n\<Colon>nat"} and two output arguments
   456   @{term "q\<Colon>nat"}(uotient) and @{term "r\<Colon>nat"}(emainder).
   457 *}
   458 
   459 definition divmod_nat_rel :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat \<Rightarrow> bool" where
   460   "divmod_nat_rel m n qr \<longleftrightarrow>
   461     m = fst qr * n + snd qr \<and>
   462       (if n = 0 then fst qr = 0 else if n > 0 then 0 \<le> snd qr \<and> snd qr < n else n < snd qr \<and> snd qr \<le> 0)"
   463 
   464 text {* @{const divmod_nat_rel} is total: *}
   465 
   466 lemma divmod_nat_rel_ex:
   467   obtains q r where "divmod_nat_rel m n (q, r)"
   468 proof (cases "n = 0")
   469   case True  with that show thesis
   470     by (auto simp add: divmod_nat_rel_def)
   471 next
   472   case False
   473   have "\<exists>q r. m = q * n + r \<and> r < n"
   474   proof (induct m)
   475     case 0 with `n \<noteq> 0`
   476     have "(0\<Colon>nat) = 0 * n + 0 \<and> 0 < n" by simp
   477     then show ?case by blast
   478   next
   479     case (Suc m) then obtain q' r'
   480       where m: "m = q' * n + r'" and n: "r' < n" by auto
   481     then show ?case proof (cases "Suc r' < n")
   482       case True
   483       from m n have "Suc m = q' * n + Suc r'" by simp
   484       with True show ?thesis by blast
   485     next
   486       case False then have "n \<le> Suc r'" by auto
   487       moreover from n have "Suc r' \<le> n" by auto
   488       ultimately have "n = Suc r'" by auto
   489       with m have "Suc m = Suc q' * n + 0" by simp
   490       with `n \<noteq> 0` show ?thesis by blast
   491     qed
   492   qed
   493   with that show thesis
   494     using `n \<noteq> 0` by (auto simp add: divmod_nat_rel_def)
   495 qed
   496 
   497 text {* @{const divmod_nat_rel} is injective: *}
   498 
   499 lemma divmod_nat_rel_unique:
   500   assumes "divmod_nat_rel m n qr"
   501     and "divmod_nat_rel m n qr'"
   502   shows "qr = qr'"
   503 proof (cases "n = 0")
   504   case True with assms show ?thesis
   505     by (cases qr, cases qr')
   506       (simp add: divmod_nat_rel_def)
   507 next
   508   case False
   509   have aux: "\<And>q r q' r'. q' * n + r' = q * n + r \<Longrightarrow> r < n \<Longrightarrow> q' \<le> (q\<Colon>nat)"
   510   apply (rule leI)
   511   apply (subst less_iff_Suc_add)
   512   apply (auto simp add: add_mult_distrib)
   513   done
   514   from `n \<noteq> 0` assms have "fst qr = fst qr'"
   515     by (auto simp add: divmod_nat_rel_def intro: order_antisym dest: aux sym)
   516   moreover from this assms have "snd qr = snd qr'"
   517     by (simp add: divmod_nat_rel_def)
   518   ultimately show ?thesis by (cases qr, cases qr') simp
   519 qed
   520 
   521 text {*
   522   We instantiate divisibility on the natural numbers by
   523   means of @{const divmod_nat_rel}:
   524 *}
   525 
   526 definition divmod_nat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat" where
   527   "divmod_nat m n = (THE qr. divmod_nat_rel m n qr)"
   528 
   529 lemma divmod_nat_rel_divmod_nat:
   530   "divmod_nat_rel m n (divmod_nat m n)"
   531 proof -
   532   from divmod_nat_rel_ex
   533     obtain qr where rel: "divmod_nat_rel m n qr" .
   534   then show ?thesis
   535   by (auto simp add: divmod_nat_def intro: theI elim: divmod_nat_rel_unique)
   536 qed
   537 
   538 lemma divmod_nat_unique:
   539   assumes "divmod_nat_rel m n qr" 
   540   shows "divmod_nat m n = qr"
   541   using assms by (auto intro: divmod_nat_rel_unique divmod_nat_rel_divmod_nat)
   542 
   543 instantiation nat :: semiring_div
   544 begin
   545 
   546 definition div_nat where
   547   "m div n = fst (divmod_nat m n)"
   548 
   549 lemma fst_divmod_nat [simp]:
   550   "fst (divmod_nat m n) = m div n"
   551   by (simp add: div_nat_def)
   552 
   553 definition mod_nat where
   554   "m mod n = snd (divmod_nat m n)"
   555 
   556 lemma snd_divmod_nat [simp]:
   557   "snd (divmod_nat m n) = m mod n"
   558   by (simp add: mod_nat_def)
   559 
   560 lemma divmod_nat_div_mod:
   561   "divmod_nat m n = (m div n, m mod n)"
   562   by (simp add: prod_eq_iff)
   563 
   564 lemma div_nat_unique:
   565   assumes "divmod_nat_rel m n (q, r)" 
   566   shows "m div n = q"
   567   using assms by (auto dest!: divmod_nat_unique simp add: prod_eq_iff)
   568 
   569 lemma mod_nat_unique:
   570   assumes "divmod_nat_rel m n (q, r)" 
   571   shows "m mod n = r"
   572   using assms by (auto dest!: divmod_nat_unique simp add: prod_eq_iff)
   573 
   574 lemma divmod_nat_rel: "divmod_nat_rel m n (m div n, m mod n)"
   575   using divmod_nat_rel_divmod_nat by (simp add: divmod_nat_div_mod)
   576 
   577 lemma divmod_nat_zero: "divmod_nat m 0 = (0, m)"
   578   by (simp add: divmod_nat_unique divmod_nat_rel_def)
   579 
   580 lemma divmod_nat_zero_left: "divmod_nat 0 n = (0, 0)"
   581   by (simp add: divmod_nat_unique divmod_nat_rel_def)
   582 
   583 lemma divmod_nat_base:
   584   assumes "m < n"
   585   shows "divmod_nat m n = (0, m)"
   586 proof (rule divmod_nat_unique)
   587   show "divmod_nat_rel m n (0, m)"
   588     unfolding divmod_nat_rel_def using assms by simp
   589 qed
   590 
   591 lemma divmod_nat_step:
   592   assumes "0 < n" and "n \<le> m"
   593   shows "divmod_nat m n = (Suc ((m - n) div n), (m - n) mod n)"
   594 proof (rule divmod_nat_unique)
   595   have "divmod_nat_rel (m - n) n ((m - n) div n, (m - n) mod n)"
   596     by (rule divmod_nat_rel)
   597   thus "divmod_nat_rel m n (Suc ((m - n) div n), (m - n) mod n)"
   598     unfolding divmod_nat_rel_def using assms by auto
   599 qed
   600 
   601 text {* The ''recursion'' equations for @{const div} and @{const mod} *}
   602 
   603 lemma div_less [simp]:
   604   fixes m n :: nat
   605   assumes "m < n"
   606   shows "m div n = 0"
   607   using assms divmod_nat_base by (simp add: prod_eq_iff)
   608 
   609 lemma le_div_geq:
   610   fixes m n :: nat
   611   assumes "0 < n" and "n \<le> m"
   612   shows "m div n = Suc ((m - n) div n)"
   613   using assms divmod_nat_step by (simp add: prod_eq_iff)
   614 
   615 lemma mod_less [simp]:
   616   fixes m n :: nat
   617   assumes "m < n"
   618   shows "m mod n = m"
   619   using assms divmod_nat_base by (simp add: prod_eq_iff)
   620 
   621 lemma le_mod_geq:
   622   fixes m n :: nat
   623   assumes "n \<le> m"
   624   shows "m mod n = (m - n) mod n"
   625   using assms divmod_nat_step by (cases "n = 0") (simp_all add: prod_eq_iff)
   626 
   627 instance proof
   628   fix m n :: nat
   629   show "m div n * n + m mod n = m"
   630     using divmod_nat_rel [of m n] by (simp add: divmod_nat_rel_def)
   631 next
   632   fix m n q :: nat
   633   assume "n \<noteq> 0"
   634   then show "(q + m * n) div n = m + q div n"
   635     by (induct m) (simp_all add: le_div_geq)
   636 next
   637   fix m n q :: nat
   638   assume "m \<noteq> 0"
   639   hence "\<And>a b. divmod_nat_rel n q (a, b) \<Longrightarrow> divmod_nat_rel (m * n) (m * q) (a, m * b)"
   640     unfolding divmod_nat_rel_def
   641     by (auto split: split_if_asm, simp_all add: algebra_simps)
   642   moreover from divmod_nat_rel have "divmod_nat_rel n q (n div q, n mod q)" .
   643   ultimately have "divmod_nat_rel (m * n) (m * q) (n div q, m * (n mod q))" .
   644   thus "(m * n) div (m * q) = n div q" by (rule div_nat_unique)
   645 next
   646   fix n :: nat show "n div 0 = 0"
   647     by (simp add: div_nat_def divmod_nat_zero)
   648 next
   649   fix n :: nat show "0 div n = 0"
   650     by (simp add: div_nat_def divmod_nat_zero_left)
   651 qed
   652 
   653 end
   654 
   655 lemma divmod_nat_if [code]: "divmod_nat m n = (if n = 0 \<or> m < n then (0, m) else
   656   let (q, r) = divmod_nat (m - n) n in (Suc q, r))"
   657   by (simp add: prod_eq_iff prod_case_beta not_less le_div_geq le_mod_geq)
   658 
   659 text {* Simproc for cancelling @{const div} and @{const mod} *}
   660 
   661 ML {*
   662 structure Cancel_Div_Mod_Nat = Cancel_Div_Mod
   663 (
   664   val div_name = @{const_name div};
   665   val mod_name = @{const_name mod};
   666   val mk_binop = HOLogic.mk_binop;
   667   val mk_sum = Nat_Arith.mk_sum;
   668   val dest_sum = Nat_Arith.dest_sum;
   669 
   670   val div_mod_eqs = map mk_meta_eq [@{thm div_mod_equality}, @{thm div_mod_equality2}];
   671 
   672   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac
   673     (@{thm add_0_left} :: @{thm add_0_right} :: @{thms add_ac}))
   674 )
   675 *}
   676 
   677 simproc_setup cancel_div_mod_nat ("(m::nat) + n") = {* K Cancel_Div_Mod_Nat.proc *}
   678 
   679 
   680 subsubsection {* Quotient *}
   681 
   682 lemma div_geq: "0 < n \<Longrightarrow>  \<not> m < n \<Longrightarrow> m div n = Suc ((m - n) div n)"
   683 by (simp add: le_div_geq linorder_not_less)
   684 
   685 lemma div_if: "0 < n \<Longrightarrow> m div n = (if m < n then 0 else Suc ((m - n) div n))"
   686 by (simp add: div_geq)
   687 
   688 lemma div_mult_self_is_m [simp]: "0<n ==> (m*n) div n = (m::nat)"
   689 by simp
   690 
   691 lemma div_mult_self1_is_m [simp]: "0<n ==> (n*m) div n = (m::nat)"
   692 by simp
   693 
   694 
   695 subsubsection {* Remainder *}
   696 
   697 lemma mod_less_divisor [simp]:
   698   fixes m n :: nat
   699   assumes "n > 0"
   700   shows "m mod n < (n::nat)"
   701   using assms divmod_nat_rel [of m n] unfolding divmod_nat_rel_def by auto
   702 
   703 lemma mod_less_eq_dividend [simp]:
   704   fixes m n :: nat
   705   shows "m mod n \<le> m"
   706 proof (rule add_leD2)
   707   from mod_div_equality have "m div n * n + m mod n = m" .
   708   then show "m div n * n + m mod n \<le> m" by auto
   709 qed
   710 
   711 lemma mod_geq: "\<not> m < (n\<Colon>nat) \<Longrightarrow> m mod n = (m - n) mod n"
   712 by (simp add: le_mod_geq linorder_not_less)
   713 
   714 lemma mod_if: "m mod (n\<Colon>nat) = (if m < n then m else (m - n) mod n)"
   715 by (simp add: le_mod_geq)
   716 
   717 lemma mod_1 [simp]: "m mod Suc 0 = 0"
   718 by (induct m) (simp_all add: mod_geq)
   719 
   720 lemma mod_mult_distrib: "(m mod n) * (k\<Colon>nat) = (m * k) mod (n * k)"
   721   apply (cases "n = 0", simp)
   722   apply (cases "k = 0", simp)
   723   apply (induct m rule: nat_less_induct)
   724   apply (subst mod_if, simp)
   725   apply (simp add: mod_geq diff_mult_distrib)
   726   done
   727 
   728 lemma mod_mult_distrib2: "(k::nat) * (m mod n) = (k*m) mod (k*n)"
   729 by (simp add: mult_commute [of k] mod_mult_distrib)
   730 
   731 (* a simple rearrangement of mod_div_equality: *)
   732 lemma mult_div_cancel: "(n::nat) * (m div n) = m - (m mod n)"
   733 by (cut_tac a = m and b = n in mod_div_equality2, arith)
   734 
   735 lemma mod_le_divisor[simp]: "0 < n \<Longrightarrow> m mod n \<le> (n::nat)"
   736   apply (drule mod_less_divisor [where m = m])
   737   apply simp
   738   done
   739 
   740 subsubsection {* Quotient and Remainder *}
   741 
   742 lemma divmod_nat_rel_mult1_eq:
   743   "divmod_nat_rel b c (q, r)
   744    \<Longrightarrow> divmod_nat_rel (a * b) c (a * q + a * r div c, a * r mod c)"
   745 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   746 
   747 lemma div_mult1_eq:
   748   "(a * b) div c = a * (b div c) + a * (b mod c) div (c::nat)"
   749 by (blast intro: divmod_nat_rel_mult1_eq [THEN div_nat_unique] divmod_nat_rel)
   750 
   751 lemma divmod_nat_rel_add1_eq:
   752   "divmod_nat_rel a c (aq, ar) \<Longrightarrow> divmod_nat_rel b c (bq, br)
   753    \<Longrightarrow> divmod_nat_rel (a + b) c (aq + bq + (ar + br) div c, (ar + br) mod c)"
   754 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   755 
   756 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
   757 lemma div_add1_eq:
   758   "(a+b) div (c::nat) = a div c + b div c + ((a mod c + b mod c) div c)"
   759 by (blast intro: divmod_nat_rel_add1_eq [THEN div_nat_unique] divmod_nat_rel)
   760 
   761 lemma mod_lemma: "[| (0::nat) < c; r < b |] ==> b * (q mod c) + r < b * c"
   762   apply (cut_tac m = q and n = c in mod_less_divisor)
   763   apply (drule_tac [2] m = "q mod c" in less_imp_Suc_add, auto)
   764   apply (erule_tac P = "%x. ?lhs < ?rhs x" in ssubst)
   765   apply (simp add: add_mult_distrib2)
   766   done
   767 
   768 lemma divmod_nat_rel_mult2_eq:
   769   "divmod_nat_rel a b (q, r)
   770    \<Longrightarrow> divmod_nat_rel a (b * c) (q div c, b *(q mod c) + r)"
   771 by (auto simp add: mult_ac divmod_nat_rel_def add_mult_distrib2 [symmetric] mod_lemma)
   772 
   773 lemma div_mult2_eq: "a div (b*c) = (a div b) div (c::nat)"
   774 by (force simp add: divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN div_nat_unique])
   775 
   776 lemma mod_mult2_eq: "a mod (b*c) = b*(a div b mod c) + a mod (b::nat)"
   777 by (auto simp add: mult_commute divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN mod_nat_unique])
   778 
   779 
   780 subsubsection {* Further Facts about Quotient and Remainder *}
   781 
   782 lemma div_1 [simp]: "m div Suc 0 = m"
   783 by (induct m) (simp_all add: div_geq)
   784 
   785 (* Monotonicity of div in first argument *)
   786 lemma div_le_mono [rule_format (no_asm)]:
   787     "\<forall>m::nat. m \<le> n --> (m div k) \<le> (n div k)"
   788 apply (case_tac "k=0", simp)
   789 apply (induct "n" rule: nat_less_induct, clarify)
   790 apply (case_tac "n<k")
   791 (* 1  case n<k *)
   792 apply simp
   793 (* 2  case n >= k *)
   794 apply (case_tac "m<k")
   795 (* 2.1  case m<k *)
   796 apply simp
   797 (* 2.2  case m>=k *)
   798 apply (simp add: div_geq diff_le_mono)
   799 done
   800 
   801 (* Antimonotonicity of div in second argument *)
   802 lemma div_le_mono2: "!!m::nat. [| 0<m; m\<le>n |] ==> (k div n) \<le> (k div m)"
   803 apply (subgoal_tac "0<n")
   804  prefer 2 apply simp
   805 apply (induct_tac k rule: nat_less_induct)
   806 apply (rename_tac "k")
   807 apply (case_tac "k<n", simp)
   808 apply (subgoal_tac "~ (k<m) ")
   809  prefer 2 apply simp
   810 apply (simp add: div_geq)
   811 apply (subgoal_tac "(k-n) div n \<le> (k-m) div n")
   812  prefer 2
   813  apply (blast intro: div_le_mono diff_le_mono2)
   814 apply (rule le_trans, simp)
   815 apply (simp)
   816 done
   817 
   818 lemma div_le_dividend [simp]: "m div n \<le> (m::nat)"
   819 apply (case_tac "n=0", simp)
   820 apply (subgoal_tac "m div n \<le> m div 1", simp)
   821 apply (rule div_le_mono2)
   822 apply (simp_all (no_asm_simp))
   823 done
   824 
   825 (* Similar for "less than" *)
   826 lemma div_less_dividend [rule_format]:
   827      "!!n::nat. 1<n ==> 0 < m --> m div n < m"
   828 apply (induct_tac m rule: nat_less_induct)
   829 apply (rename_tac "m")
   830 apply (case_tac "m<n", simp)
   831 apply (subgoal_tac "0<n")
   832  prefer 2 apply simp
   833 apply (simp add: div_geq)
   834 apply (case_tac "n<m")
   835  apply (subgoal_tac "(m-n) div n < (m-n) ")
   836   apply (rule impI less_trans_Suc)+
   837 apply assumption
   838   apply (simp_all)
   839 done
   840 
   841 declare div_less_dividend [simp]
   842 
   843 text{*A fact for the mutilated chess board*}
   844 lemma mod_Suc: "Suc(m) mod n = (if Suc(m mod n) = n then 0 else Suc(m mod n))"
   845 apply (case_tac "n=0", simp)
   846 apply (induct "m" rule: nat_less_induct)
   847 apply (case_tac "Suc (na) <n")
   848 (* case Suc(na) < n *)
   849 apply (frule lessI [THEN less_trans], simp add: less_not_refl3)
   850 (* case n \<le> Suc(na) *)
   851 apply (simp add: linorder_not_less le_Suc_eq mod_geq)
   852 apply (auto simp add: Suc_diff_le le_mod_geq)
   853 done
   854 
   855 lemma mod_eq_0_iff: "(m mod d = 0) = (\<exists>q::nat. m = d*q)"
   856 by (auto simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
   857 
   858 lemmas mod_eq_0D [dest!] = mod_eq_0_iff [THEN iffD1]
   859 
   860 (*Loses information, namely we also have r<d provided d is nonzero*)
   861 lemma mod_eqD: "(m mod d = r) ==> \<exists>q::nat. m = r + q*d"
   862   apply (cut_tac a = m in mod_div_equality)
   863   apply (simp only: add_ac)
   864   apply (blast intro: sym)
   865   done
   866 
   867 lemma split_div:
   868  "P(n div k :: nat) =
   869  ((k = 0 \<longrightarrow> P 0) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P i)))"
   870  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   871 proof
   872   assume P: ?P
   873   show ?Q
   874   proof (cases)
   875     assume "k = 0"
   876     with P show ?Q by simp
   877   next
   878     assume not0: "k \<noteq> 0"
   879     thus ?Q
   880     proof (simp, intro allI impI)
   881       fix i j
   882       assume n: "n = k*i + j" and j: "j < k"
   883       show "P i"
   884       proof (cases)
   885         assume "i = 0"
   886         with n j P show "P i" by simp
   887       next
   888         assume "i \<noteq> 0"
   889         with not0 n j P show "P i" by(simp add:add_ac)
   890       qed
   891     qed
   892   qed
   893 next
   894   assume Q: ?Q
   895   show ?P
   896   proof (cases)
   897     assume "k = 0"
   898     with Q show ?P by simp
   899   next
   900     assume not0: "k \<noteq> 0"
   901     with Q have R: ?R by simp
   902     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   903     show ?P by simp
   904   qed
   905 qed
   906 
   907 lemma split_div_lemma:
   908   assumes "0 < n"
   909   shows "n * q \<le> m \<and> m < n * Suc q \<longleftrightarrow> q = ((m\<Colon>nat) div n)" (is "?lhs \<longleftrightarrow> ?rhs")
   910 proof
   911   assume ?rhs
   912   with mult_div_cancel have nq: "n * q = m - (m mod n)" by simp
   913   then have A: "n * q \<le> m" by simp
   914   have "n - (m mod n) > 0" using mod_less_divisor assms by auto
   915   then have "m < m + (n - (m mod n))" by simp
   916   then have "m < n + (m - (m mod n))" by simp
   917   with nq have "m < n + n * q" by simp
   918   then have B: "m < n * Suc q" by simp
   919   from A B show ?lhs ..
   920 next
   921   assume P: ?lhs
   922   then have "divmod_nat_rel m n (q, m - n * q)"
   923     unfolding divmod_nat_rel_def by (auto simp add: mult_ac)
   924   with divmod_nat_rel_unique divmod_nat_rel [of m n]
   925   have "(q, m - n * q) = (m div n, m mod n)" by auto
   926   then show ?rhs by simp
   927 qed
   928 
   929 theorem split_div':
   930   "P ((m::nat) div n) = ((n = 0 \<and> P 0) \<or>
   931    (\<exists>q. (n * q \<le> m \<and> m < n * (Suc q)) \<and> P q))"
   932   apply (case_tac "0 < n")
   933   apply (simp only: add: split_div_lemma)
   934   apply simp_all
   935   done
   936 
   937 lemma split_mod:
   938  "P(n mod k :: nat) =
   939  ((k = 0 \<longrightarrow> P n) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P j)))"
   940  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   941 proof
   942   assume P: ?P
   943   show ?Q
   944   proof (cases)
   945     assume "k = 0"
   946     with P show ?Q by simp
   947   next
   948     assume not0: "k \<noteq> 0"
   949     thus ?Q
   950     proof (simp, intro allI impI)
   951       fix i j
   952       assume "n = k*i + j" "j < k"
   953       thus "P j" using not0 P by(simp add:add_ac mult_ac)
   954     qed
   955   qed
   956 next
   957   assume Q: ?Q
   958   show ?P
   959   proof (cases)
   960     assume "k = 0"
   961     with Q show ?P by simp
   962   next
   963     assume not0: "k \<noteq> 0"
   964     with Q have R: ?R by simp
   965     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   966     show ?P by simp
   967   qed
   968 qed
   969 
   970 theorem mod_div_equality': "(m::nat) mod n = m - (m div n) * n"
   971   apply (rule_tac P="%x. m mod n = x - (m div n) * n" in
   972     subst [OF mod_div_equality [of _ n]])
   973   apply arith
   974   done
   975 
   976 lemma div_mod_equality':
   977   fixes m n :: nat
   978   shows "m div n * n = m - m mod n"
   979 proof -
   980   have "m mod n \<le> m mod n" ..
   981   from div_mod_equality have 
   982     "m div n * n + m mod n - m mod n = m - m mod n" by simp
   983   with diff_add_assoc [OF `m mod n \<le> m mod n`, of "m div n * n"] have
   984     "m div n * n + (m mod n - m mod n) = m - m mod n"
   985     by simp
   986   then show ?thesis by simp
   987 qed
   988 
   989 
   990 subsubsection {* An ``induction'' law for modulus arithmetic. *}
   991 
   992 lemma mod_induct_0:
   993   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
   994   and base: "P i" and i: "i<p"
   995   shows "P 0"
   996 proof (rule ccontr)
   997   assume contra: "\<not>(P 0)"
   998   from i have p: "0<p" by simp
   999   have "\<forall>k. 0<k \<longrightarrow> \<not> P (p-k)" (is "\<forall>k. ?A k")
  1000   proof
  1001     fix k
  1002     show "?A k"
  1003     proof (induct k)
  1004       show "?A 0" by simp  -- "by contradiction"
  1005     next
  1006       fix n
  1007       assume ih: "?A n"
  1008       show "?A (Suc n)"
  1009       proof (clarsimp)
  1010         assume y: "P (p - Suc n)"
  1011         have n: "Suc n < p"
  1012         proof (rule ccontr)
  1013           assume "\<not>(Suc n < p)"
  1014           hence "p - Suc n = 0"
  1015             by simp
  1016           with y contra show "False"
  1017             by simp
  1018         qed
  1019         hence n2: "Suc (p - Suc n) = p-n" by arith
  1020         from p have "p - Suc n < p" by arith
  1021         with y step have z: "P ((Suc (p - Suc n)) mod p)"
  1022           by blast
  1023         show "False"
  1024         proof (cases "n=0")
  1025           case True
  1026           with z n2 contra show ?thesis by simp
  1027         next
  1028           case False
  1029           with p have "p-n < p" by arith
  1030           with z n2 False ih show ?thesis by simp
  1031         qed
  1032       qed
  1033     qed
  1034   qed
  1035   moreover
  1036   from i obtain k where "0<k \<and> i+k=p"
  1037     by (blast dest: less_imp_add_positive)
  1038   hence "0<k \<and> i=p-k" by auto
  1039   moreover
  1040   note base
  1041   ultimately
  1042   show "False" by blast
  1043 qed
  1044 
  1045 lemma mod_induct:
  1046   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
  1047   and base: "P i" and i: "i<p" and j: "j<p"
  1048   shows "P j"
  1049 proof -
  1050   have "\<forall>j<p. P j"
  1051   proof
  1052     fix j
  1053     show "j<p \<longrightarrow> P j" (is "?A j")
  1054     proof (induct j)
  1055       from step base i show "?A 0"
  1056         by (auto elim: mod_induct_0)
  1057     next
  1058       fix k
  1059       assume ih: "?A k"
  1060       show "?A (Suc k)"
  1061       proof
  1062         assume suc: "Suc k < p"
  1063         hence k: "k<p" by simp
  1064         with ih have "P k" ..
  1065         with step k have "P (Suc k mod p)"
  1066           by blast
  1067         moreover
  1068         from suc have "Suc k mod p = Suc k"
  1069           by simp
  1070         ultimately
  1071         show "P (Suc k)" by simp
  1072       qed
  1073     qed
  1074   qed
  1075   with j show ?thesis by blast
  1076 qed
  1077 
  1078 lemma div2_Suc_Suc [simp]: "Suc (Suc m) div 2 = Suc (m div 2)"
  1079 by (auto simp add: numeral_2_eq_2 le_div_geq)
  1080 
  1081 lemma add_self_div_2 [simp]: "(m + m) div 2 = (m::nat)"
  1082 by (simp add: nat_mult_2 [symmetric])
  1083 
  1084 lemma mod2_Suc_Suc [simp]: "Suc(Suc(m)) mod 2 = m mod 2"
  1085 apply (subgoal_tac "m mod 2 < 2")
  1086 apply (erule less_2_cases [THEN disjE])
  1087 apply (simp_all (no_asm_simp) add: Let_def mod_Suc)
  1088 done
  1089 
  1090 lemma mod2_gr_0 [simp]: "0 < (m\<Colon>nat) mod 2 \<longleftrightarrow> m mod 2 = 1"
  1091 proof -
  1092   { fix n :: nat have  "(n::nat) < 2 \<Longrightarrow> n = 0 \<or> n = 1" by (cases n) simp_all }
  1093   moreover have "m mod 2 < 2" by simp
  1094   ultimately have "m mod 2 = 0 \<or> m mod 2 = 1" .
  1095   then show ?thesis by auto
  1096 qed
  1097 
  1098 text{*These lemmas collapse some needless occurrences of Suc:
  1099     at least three Sucs, since two and fewer are rewritten back to Suc again!
  1100     We already have some rules to simplify operands smaller than 3.*}
  1101 
  1102 lemma div_Suc_eq_div_add3 [simp]: "m div (Suc (Suc (Suc n))) = m div (3+n)"
  1103 by (simp add: Suc3_eq_add_3)
  1104 
  1105 lemma mod_Suc_eq_mod_add3 [simp]: "m mod (Suc (Suc (Suc n))) = m mod (3+n)"
  1106 by (simp add: Suc3_eq_add_3)
  1107 
  1108 lemma Suc_div_eq_add3_div: "(Suc (Suc (Suc m))) div n = (3+m) div n"
  1109 by (simp add: Suc3_eq_add_3)
  1110 
  1111 lemma Suc_mod_eq_add3_mod: "(Suc (Suc (Suc m))) mod n = (3+m) mod n"
  1112 by (simp add: Suc3_eq_add_3)
  1113 
  1114 lemmas Suc_div_eq_add3_div_numeral [simp] = Suc_div_eq_add3_div [of _ "numeral v"] for v
  1115 lemmas Suc_mod_eq_add3_mod_numeral [simp] = Suc_mod_eq_add3_mod [of _ "numeral v"] for v
  1116 
  1117 
  1118 lemma Suc_times_mod_eq: "1<k ==> Suc (k * m) mod k = 1" 
  1119 apply (induct "m")
  1120 apply (simp_all add: mod_Suc)
  1121 done
  1122 
  1123 declare Suc_times_mod_eq [of "numeral w", simp] for w
  1124 
  1125 lemma [simp]: "n div k \<le> (Suc n) div k"
  1126 by (simp add: div_le_mono) 
  1127 
  1128 lemma Suc_n_div_2_gt_zero [simp]: "(0::nat) < n ==> 0 < (n + 1) div 2"
  1129 by (cases n) simp_all
  1130 
  1131 lemma div_2_gt_zero [simp]: assumes A: "(1::nat) < n" shows "0 < n div 2"
  1132 proof -
  1133   from A have B: "0 < n - 1" and C: "n - 1 + 1 = n" by simp_all
  1134   from Suc_n_div_2_gt_zero [OF B] C show ?thesis by simp 
  1135 qed
  1136 
  1137   (* Potential use of algebra : Equality modulo n*)
  1138 lemma mod_mult_self3 [simp]: "(k*n + m) mod n = m mod (n::nat)"
  1139 by (simp add: mult_ac add_ac)
  1140 
  1141 lemma mod_mult_self4 [simp]: "Suc (k*n + m) mod n = Suc m mod n"
  1142 proof -
  1143   have "Suc (k * n + m) mod n = (k * n + Suc m) mod n" by simp
  1144   also have "... = Suc m mod n" by (rule mod_mult_self3) 
  1145   finally show ?thesis .
  1146 qed
  1147 
  1148 lemma mod_Suc_eq_Suc_mod: "Suc m mod n = Suc (m mod n) mod n"
  1149 apply (subst mod_Suc [of m]) 
  1150 apply (subst mod_Suc [of "m mod n"], simp) 
  1151 done
  1152 
  1153 lemma mod_2_not_eq_zero_eq_one_nat:
  1154   fixes n :: nat
  1155   shows "n mod 2 \<noteq> 0 \<longleftrightarrow> n mod 2 = 1"
  1156   by simp
  1157 
  1158 
  1159 subsection {* Division on @{typ int} *}
  1160 
  1161 definition divmod_int_rel :: "int \<Rightarrow> int \<Rightarrow> int \<times> int \<Rightarrow> bool" where
  1162     --{*definition of quotient and remainder*}
  1163     "divmod_int_rel a b = (\<lambda>(q, r). a = b * q + r \<and>
  1164                (if 0 < b then 0 \<le> r \<and> r < b else b < r \<and> r \<le> 0))"
  1165 
  1166 definition adjust :: "int \<Rightarrow> int \<times> int \<Rightarrow> int \<times> int" where
  1167     --{*for the division algorithm*}
  1168     "adjust b = (\<lambda>(q, r). if 0 \<le> r - b then (2 * q + 1, r - b)
  1169                          else (2 * q, r))"
  1170 
  1171 text{*algorithm for the case @{text "a\<ge>0, b>0"}*}
  1172 function posDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1173   "posDivAlg a b = (if a < b \<or>  b \<le> 0 then (0, a)
  1174      else adjust b (posDivAlg a (2 * b)))"
  1175 by auto
  1176 termination by (relation "measure (\<lambda>(a, b). nat (a - b + 1))")
  1177   (auto simp add: mult_2)
  1178 
  1179 text{*algorithm for the case @{text "a<0, b>0"}*}
  1180 function negDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1181   "negDivAlg a b = (if 0 \<le>a + b \<or> b \<le> 0  then (-1, a + b)
  1182      else adjust b (negDivAlg a (2 * b)))"
  1183 by auto
  1184 termination by (relation "measure (\<lambda>(a, b). nat (- a - b))")
  1185   (auto simp add: mult_2)
  1186 
  1187 text{*algorithm for the general case @{term "b\<noteq>0"}*}
  1188 
  1189 definition divmod_int :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1190     --{*The full division algorithm considers all possible signs for a, b
  1191        including the special case @{text "a=0, b<0"} because 
  1192        @{term negDivAlg} requires @{term "a<0"}.*}
  1193   "divmod_int a b = (if 0 \<le> a then if 0 \<le> b then posDivAlg a b
  1194                   else if a = 0 then (0, 0)
  1195                        else apsnd uminus (negDivAlg (-a) (-b))
  1196                else 
  1197                   if 0 < b then negDivAlg a b
  1198                   else apsnd uminus (posDivAlg (-a) (-b)))"
  1199 
  1200 instantiation int :: Divides.div
  1201 begin
  1202 
  1203 definition div_int where
  1204   "a div b = fst (divmod_int a b)"
  1205 
  1206 lemma fst_divmod_int [simp]:
  1207   "fst (divmod_int a b) = a div b"
  1208   by (simp add: div_int_def)
  1209 
  1210 definition mod_int where
  1211   "a mod b = snd (divmod_int a b)"
  1212 
  1213 lemma snd_divmod_int [simp]:
  1214   "snd (divmod_int a b) = a mod b"
  1215   by (simp add: mod_int_def)
  1216 
  1217 instance ..
  1218 
  1219 end
  1220 
  1221 lemma divmod_int_mod_div:
  1222   "divmod_int p q = (p div q, p mod q)"
  1223   by (simp add: prod_eq_iff)
  1224 
  1225 text{*
  1226 Here is the division algorithm in ML:
  1227 
  1228 \begin{verbatim}
  1229     fun posDivAlg (a,b) =
  1230       if a<b then (0,a)
  1231       else let val (q,r) = posDivAlg(a, 2*b)
  1232                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1233            end
  1234 
  1235     fun negDivAlg (a,b) =
  1236       if 0\<le>a+b then (~1,a+b)
  1237       else let val (q,r) = negDivAlg(a, 2*b)
  1238                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1239            end;
  1240 
  1241     fun negateSnd (q,r:int) = (q,~r);
  1242 
  1243     fun divmod (a,b) = if 0\<le>a then 
  1244                           if b>0 then posDivAlg (a,b) 
  1245                            else if a=0 then (0,0)
  1246                                 else negateSnd (negDivAlg (~a,~b))
  1247                        else 
  1248                           if 0<b then negDivAlg (a,b)
  1249                           else        negateSnd (posDivAlg (~a,~b));
  1250 \end{verbatim}
  1251 *}
  1252 
  1253 
  1254 subsubsection {* Uniqueness and Monotonicity of Quotients and Remainders *}
  1255 
  1256 lemma unique_quotient_lemma:
  1257      "[| b*q' + r'  \<le> b*q + r;  0 \<le> r';  r' < b;  r < b |]  
  1258       ==> q' \<le> (q::int)"
  1259 apply (subgoal_tac "r' + b * (q'-q) \<le> r")
  1260  prefer 2 apply (simp add: right_diff_distrib)
  1261 apply (subgoal_tac "0 < b * (1 + q - q') ")
  1262 apply (erule_tac [2] order_le_less_trans)
  1263  prefer 2 apply (simp add: right_diff_distrib right_distrib)
  1264 apply (subgoal_tac "b * q' < b * (1 + q) ")
  1265  prefer 2 apply (simp add: right_diff_distrib right_distrib)
  1266 apply (simp add: mult_less_cancel_left)
  1267 done
  1268 
  1269 lemma unique_quotient_lemma_neg:
  1270      "[| b*q' + r' \<le> b*q + r;  r \<le> 0;  b < r;  b < r' |]  
  1271       ==> q \<le> (q'::int)"
  1272 by (rule_tac b = "-b" and r = "-r'" and r' = "-r" in unique_quotient_lemma, 
  1273     auto)
  1274 
  1275 lemma unique_quotient:
  1276      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r') |]  
  1277       ==> q = q'"
  1278 apply (simp add: divmod_int_rel_def linorder_neq_iff split: split_if_asm)
  1279 apply (blast intro: order_antisym
  1280              dest: order_eq_refl [THEN unique_quotient_lemma] 
  1281              order_eq_refl [THEN unique_quotient_lemma_neg] sym)+
  1282 done
  1283 
  1284 
  1285 lemma unique_remainder:
  1286      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r') |]  
  1287       ==> r = r'"
  1288 apply (subgoal_tac "q = q'")
  1289  apply (simp add: divmod_int_rel_def)
  1290 apply (blast intro: unique_quotient)
  1291 done
  1292 
  1293 
  1294 subsubsection {* Correctness of @{term posDivAlg}, the Algorithm for Non-Negative Dividends *}
  1295 
  1296 text{*And positive divisors*}
  1297 
  1298 lemma adjust_eq [simp]:
  1299      "adjust b (q, r) = 
  1300       (let diff = r - b in  
  1301         if 0 \<le> diff then (2 * q + 1, diff)   
  1302                      else (2*q, r))"
  1303   by (simp add: Let_def adjust_def)
  1304 
  1305 declare posDivAlg.simps [simp del]
  1306 
  1307 text{*use with a simproc to avoid repeatedly proving the premise*}
  1308 lemma posDivAlg_eqn:
  1309      "0 < b ==>  
  1310       posDivAlg a b = (if a<b then (0,a) else adjust b (posDivAlg a (2*b)))"
  1311 by (rule posDivAlg.simps [THEN trans], simp)
  1312 
  1313 text{*Correctness of @{term posDivAlg}: it computes quotients correctly*}
  1314 theorem posDivAlg_correct:
  1315   assumes "0 \<le> a" and "0 < b"
  1316   shows "divmod_int_rel a b (posDivAlg a b)"
  1317   using assms
  1318   apply (induct a b rule: posDivAlg.induct)
  1319   apply auto
  1320   apply (simp add: divmod_int_rel_def)
  1321   apply (subst posDivAlg_eqn, simp add: right_distrib)
  1322   apply (case_tac "a < b")
  1323   apply simp_all
  1324   apply (erule splitE)
  1325   apply (auto simp add: right_distrib Let_def mult_ac mult_2_right)
  1326   done
  1327 
  1328 
  1329 subsubsection {* Correctness of @{term negDivAlg}, the Algorithm for Negative Dividends *}
  1330 
  1331 text{*And positive divisors*}
  1332 
  1333 declare negDivAlg.simps [simp del]
  1334 
  1335 text{*use with a simproc to avoid repeatedly proving the premise*}
  1336 lemma negDivAlg_eqn:
  1337      "0 < b ==>  
  1338       negDivAlg a b =       
  1339        (if 0\<le>a+b then (-1,a+b) else adjust b (negDivAlg a (2*b)))"
  1340 by (rule negDivAlg.simps [THEN trans], simp)
  1341 
  1342 (*Correctness of negDivAlg: it computes quotients correctly
  1343   It doesn't work if a=0 because the 0/b equals 0, not -1*)
  1344 lemma negDivAlg_correct:
  1345   assumes "a < 0" and "b > 0"
  1346   shows "divmod_int_rel a b (negDivAlg a b)"
  1347   using assms
  1348   apply (induct a b rule: negDivAlg.induct)
  1349   apply (auto simp add: linorder_not_le)
  1350   apply (simp add: divmod_int_rel_def)
  1351   apply (subst negDivAlg_eqn, assumption)
  1352   apply (case_tac "a + b < (0\<Colon>int)")
  1353   apply simp_all
  1354   apply (erule splitE)
  1355   apply (auto simp add: right_distrib Let_def mult_ac mult_2_right)
  1356   done
  1357 
  1358 
  1359 subsubsection {* Existence Shown by Proving the Division Algorithm to be Correct *}
  1360 
  1361 (*the case a=0*)
  1362 lemma divmod_int_rel_0: "b \<noteq> 0 ==> divmod_int_rel 0 b (0, 0)"
  1363 by (auto simp add: divmod_int_rel_def linorder_neq_iff)
  1364 
  1365 lemma posDivAlg_0 [simp]: "posDivAlg 0 b = (0, 0)"
  1366 by (subst posDivAlg.simps, auto)
  1367 
  1368 lemma negDivAlg_minus1 [simp]: "negDivAlg -1 b = (-1, b - 1)"
  1369 by (subst negDivAlg.simps, auto)
  1370 
  1371 lemma divmod_int_rel_neg: "divmod_int_rel (-a) (-b) qr ==> divmod_int_rel a b (apsnd uminus qr)"
  1372 by (auto simp add: split_ifs divmod_int_rel_def)
  1373 
  1374 lemma divmod_int_correct: "b \<noteq> 0 ==> divmod_int_rel a b (divmod_int a b)"
  1375 by (force simp add: linorder_neq_iff divmod_int_rel_0 divmod_int_def divmod_int_rel_neg
  1376                     posDivAlg_correct negDivAlg_correct)
  1377 
  1378 text{*Arbitrary definitions for division by zero.  Useful to simplify 
  1379     certain equations.*}
  1380 
  1381 lemma DIVISION_BY_ZERO [simp]: "a div (0::int) = 0 & a mod (0::int) = a"
  1382 by (simp add: div_int_def mod_int_def divmod_int_def posDivAlg.simps)  
  1383 
  1384 
  1385 text{*Basic laws about division and remainder*}
  1386 
  1387 lemma zmod_zdiv_equality: "(a::int) = b * (a div b) + (a mod b)"
  1388 apply (case_tac "b = 0", simp)
  1389 apply (cut_tac a = a and b = b in divmod_int_correct)
  1390 apply (auto simp add: divmod_int_rel_def prod_eq_iff)
  1391 done
  1392 
  1393 lemma zdiv_zmod_equality: "(b * (a div b) + (a mod b)) + k = (a::int)+k"
  1394 by(simp add: zmod_zdiv_equality[symmetric])
  1395 
  1396 lemma zdiv_zmod_equality2: "((a div b) * b + (a mod b)) + k = (a::int)+k"
  1397 by(simp add: mult_commute zmod_zdiv_equality[symmetric])
  1398 
  1399 text {* Tool setup *}
  1400 
  1401 (* FIXME: Theorem list add_0s doesn't exist, because Numeral0 has gone. *)
  1402 lemmas add_0s = add_0_left add_0_right
  1403 
  1404 ML {*
  1405 structure Cancel_Div_Mod_Int = Cancel_Div_Mod
  1406 (
  1407   val div_name = @{const_name div};
  1408   val mod_name = @{const_name mod};
  1409   val mk_binop = HOLogic.mk_binop;
  1410   val mk_sum = Arith_Data.mk_sum HOLogic.intT;
  1411   val dest_sum = Arith_Data.dest_sum;
  1412 
  1413   val div_mod_eqs = map mk_meta_eq [@{thm zdiv_zmod_equality}, @{thm zdiv_zmod_equality2}];
  1414 
  1415   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac 
  1416     (@{thm diff_minus} :: @{thms add_0s} @ @{thms add_ac}))
  1417 )
  1418 *}
  1419 
  1420 simproc_setup cancel_div_mod_int ("(k::int) + l") = {* K Cancel_Div_Mod_Int.proc *}
  1421 
  1422 lemma pos_mod_conj : "(0::int) < b ==> 0 \<le> a mod b & a mod b < b"
  1423 apply (cut_tac a = a and b = b in divmod_int_correct)
  1424 apply (auto simp add: divmod_int_rel_def prod_eq_iff)
  1425 done
  1426 
  1427 lemmas pos_mod_sign [simp] = pos_mod_conj [THEN conjunct1]
  1428    and pos_mod_bound [simp] = pos_mod_conj [THEN conjunct2]
  1429 
  1430 lemma neg_mod_conj : "b < (0::int) ==> a mod b \<le> 0 & b < a mod b"
  1431 apply (cut_tac a = a and b = b in divmod_int_correct)
  1432 apply (auto simp add: divmod_int_rel_def prod_eq_iff)
  1433 done
  1434 
  1435 lemmas neg_mod_sign [simp] = neg_mod_conj [THEN conjunct1]
  1436    and neg_mod_bound [simp] = neg_mod_conj [THEN conjunct2]
  1437 
  1438 
  1439 subsubsection {* General Properties of div and mod *}
  1440 
  1441 lemma divmod_int_rel_div_mod: "b \<noteq> 0 ==> divmod_int_rel a b (a div b, a mod b)"
  1442 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1443 apply (force simp add: divmod_int_rel_def linorder_neq_iff)
  1444 done
  1445 
  1446 lemma divmod_int_rel_div: "[| divmod_int_rel a b (q, r) |] ==> a div b = q"
  1447 apply (cases "b = 0")
  1448 apply (simp add: divmod_int_rel_def)
  1449 by (simp add: divmod_int_rel_div_mod [THEN unique_quotient])
  1450 
  1451 lemma divmod_int_rel_mod: "[| divmod_int_rel a b (q, r) |] ==> a mod b = r"
  1452 apply (cases "b = 0")
  1453 apply (simp add: divmod_int_rel_def)
  1454 by (simp add: divmod_int_rel_div_mod [THEN unique_remainder])
  1455 
  1456 lemma div_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a div b = 0"
  1457 apply (rule divmod_int_rel_div)
  1458 apply (auto simp add: divmod_int_rel_def)
  1459 done
  1460 
  1461 lemma div_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a div b = 0"
  1462 apply (rule divmod_int_rel_div)
  1463 apply (auto simp add: divmod_int_rel_def)
  1464 done
  1465 
  1466 lemma div_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a div b = -1"
  1467 apply (rule divmod_int_rel_div)
  1468 apply (auto simp add: divmod_int_rel_def)
  1469 done
  1470 
  1471 (*There is no div_neg_pos_trivial because  0 div b = 0 would supersede it*)
  1472 
  1473 lemma mod_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a mod b = a"
  1474 apply (rule_tac q = 0 in divmod_int_rel_mod)
  1475 apply (auto simp add: divmod_int_rel_def)
  1476 done
  1477 
  1478 lemma mod_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a mod b = a"
  1479 apply (rule_tac q = 0 in divmod_int_rel_mod)
  1480 apply (auto simp add: divmod_int_rel_def)
  1481 done
  1482 
  1483 lemma mod_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a mod b = a+b"
  1484 apply (rule_tac q = "-1" in divmod_int_rel_mod)
  1485 apply (auto simp add: divmod_int_rel_def)
  1486 done
  1487 
  1488 text{*There is no @{text mod_neg_pos_trivial}.*}
  1489 
  1490 
  1491 (*Simpler laws such as -a div b = -(a div b) FAIL, but see just below*)
  1492 lemma zdiv_zminus_zminus [simp]: "(-a) div (-b) = a div (b::int)"
  1493 apply (case_tac "b = 0", simp)
  1494 apply (simp add: divmod_int_rel_div_mod [THEN divmod_int_rel_neg, simplified, 
  1495                                  THEN divmod_int_rel_div, THEN sym])
  1496 
  1497 done
  1498 
  1499 (*Simpler laws such as -a mod b = -(a mod b) FAIL, but see just below*)
  1500 lemma zmod_zminus_zminus [simp]: "(-a) mod (-b) = - (a mod (b::int))"
  1501 apply (case_tac "b = 0", simp)
  1502 apply (subst divmod_int_rel_div_mod [THEN divmod_int_rel_neg, simplified, THEN divmod_int_rel_mod],
  1503        auto)
  1504 done
  1505 
  1506 
  1507 subsubsection {* Laws for div and mod with Unary Minus *}
  1508 
  1509 lemma zminus1_lemma:
  1510      "divmod_int_rel a b (q, r)
  1511       ==> divmod_int_rel (-a) b (if r=0 then -q else -q - 1,  
  1512                           if r=0 then 0 else b-r)"
  1513 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_diff_distrib)
  1514 
  1515 
  1516 lemma zdiv_zminus1_eq_if:
  1517      "b \<noteq> (0::int)  
  1518       ==> (-a) div b =  
  1519           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1520 by (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN divmod_int_rel_div])
  1521 
  1522 lemma zmod_zminus1_eq_if:
  1523      "(-a::int) mod b = (if a mod b = 0 then 0 else  b - (a mod b))"
  1524 apply (case_tac "b = 0", simp)
  1525 apply (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN divmod_int_rel_mod])
  1526 done
  1527 
  1528 lemma zmod_zminus1_not_zero:
  1529   fixes k l :: int
  1530   shows "- k mod l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1531   unfolding zmod_zminus1_eq_if by auto
  1532 
  1533 lemma zdiv_zminus2: "a div (-b) = (-a::int) div b"
  1534 by (cut_tac a = "-a" in zdiv_zminus_zminus, auto)
  1535 
  1536 lemma zmod_zminus2: "a mod (-b) = - ((-a::int) mod b)"
  1537 by (cut_tac a = "-a" and b = b in zmod_zminus_zminus, auto)
  1538 
  1539 lemma zdiv_zminus2_eq_if:
  1540      "b \<noteq> (0::int)  
  1541       ==> a div (-b) =  
  1542           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1543 by (simp add: zdiv_zminus1_eq_if zdiv_zminus2)
  1544 
  1545 lemma zmod_zminus2_eq_if:
  1546      "a mod (-b::int) = (if a mod b = 0 then 0 else  (a mod b) - b)"
  1547 by (simp add: zmod_zminus1_eq_if zmod_zminus2)
  1548 
  1549 lemma zmod_zminus2_not_zero:
  1550   fixes k l :: int
  1551   shows "k mod - l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1552   unfolding zmod_zminus2_eq_if by auto 
  1553 
  1554 
  1555 subsubsection {* Division of a Number by Itself *}
  1556 
  1557 lemma self_quotient_aux1: "[| (0::int) < a; a = r + a*q; r < a |] ==> 1 \<le> q"
  1558 apply (subgoal_tac "0 < a*q")
  1559  apply (simp add: zero_less_mult_iff, arith)
  1560 done
  1561 
  1562 lemma self_quotient_aux2: "[| (0::int) < a; a = r + a*q; 0 \<le> r |] ==> q \<le> 1"
  1563 apply (subgoal_tac "0 \<le> a* (1-q) ")
  1564  apply (simp add: zero_le_mult_iff)
  1565 apply (simp add: right_diff_distrib)
  1566 done
  1567 
  1568 lemma self_quotient: "[| divmod_int_rel a a (q, r) |] ==> q = 1"
  1569 apply (simp add: split_ifs divmod_int_rel_def linorder_neq_iff)
  1570 apply (rule order_antisym, safe, simp_all)
  1571 apply (rule_tac [3] a = "-a" and r = "-r" in self_quotient_aux1)
  1572 apply (rule_tac a = "-a" and r = "-r" in self_quotient_aux2)
  1573 apply (force intro: self_quotient_aux1 self_quotient_aux2 simp add: add_commute)+
  1574 done
  1575 
  1576 lemma self_remainder: "[| divmod_int_rel a a (q, r) |] ==> r = 0"
  1577 apply (frule self_quotient)
  1578 apply (simp add: divmod_int_rel_def)
  1579 done
  1580 
  1581 lemma zdiv_self [simp]: "a \<noteq> 0 ==> a div a = (1::int)"
  1582 by (simp add: divmod_int_rel_div_mod [THEN self_quotient])
  1583 
  1584 (*Here we have 0 mod 0 = 0, also assumed by Knuth (who puts m mod 0 = 0) *)
  1585 lemma zmod_self [simp]: "a mod a = (0::int)"
  1586 apply (case_tac "a = 0", simp)
  1587 apply (simp add: divmod_int_rel_div_mod [THEN self_remainder])
  1588 done
  1589 
  1590 
  1591 subsubsection {* Computation of Division and Remainder *}
  1592 
  1593 lemma zdiv_zero [simp]: "(0::int) div b = 0"
  1594 by (simp add: div_int_def divmod_int_def)
  1595 
  1596 lemma div_eq_minus1: "(0::int) < b ==> -1 div b = -1"
  1597 by (simp add: div_int_def divmod_int_def)
  1598 
  1599 lemma zmod_zero [simp]: "(0::int) mod b = 0"
  1600 by (simp add: mod_int_def divmod_int_def)
  1601 
  1602 lemma zmod_minus1: "(0::int) < b ==> -1 mod b = b - 1"
  1603 by (simp add: mod_int_def divmod_int_def)
  1604 
  1605 text{*a positive, b positive *}
  1606 
  1607 lemma div_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a div b = fst (posDivAlg a b)"
  1608 by (simp add: div_int_def divmod_int_def)
  1609 
  1610 lemma mod_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a mod b = snd (posDivAlg a b)"
  1611 by (simp add: mod_int_def divmod_int_def)
  1612 
  1613 text{*a negative, b positive *}
  1614 
  1615 lemma div_neg_pos: "[| a < 0;  0 < b |] ==> a div b = fst (negDivAlg a b)"
  1616 by (simp add: div_int_def divmod_int_def)
  1617 
  1618 lemma mod_neg_pos: "[| a < 0;  0 < b |] ==> a mod b = snd (negDivAlg a b)"
  1619 by (simp add: mod_int_def divmod_int_def)
  1620 
  1621 text{*a positive, b negative *}
  1622 
  1623 lemma div_pos_neg:
  1624      "[| 0 < a;  b < 0 |] ==> a div b = fst (apsnd uminus (negDivAlg (-a) (-b)))"
  1625 by (simp add: div_int_def divmod_int_def)
  1626 
  1627 lemma mod_pos_neg:
  1628      "[| 0 < a;  b < 0 |] ==> a mod b = snd (apsnd uminus (negDivAlg (-a) (-b)))"
  1629 by (simp add: mod_int_def divmod_int_def)
  1630 
  1631 text{*a negative, b negative *}
  1632 
  1633 lemma div_neg_neg:
  1634      "[| a < 0;  b \<le> 0 |] ==> a div b = fst (apsnd uminus (posDivAlg (-a) (-b)))"
  1635 by (simp add: div_int_def divmod_int_def)
  1636 
  1637 lemma mod_neg_neg:
  1638      "[| a < 0;  b \<le> 0 |] ==> a mod b = snd (apsnd uminus (posDivAlg (-a) (-b)))"
  1639 by (simp add: mod_int_def divmod_int_def)
  1640 
  1641 text {*Simplify expresions in which div and mod combine numerical constants*}
  1642 
  1643 lemma int_div_pos_eq: "\<lbrakk>(a::int) = b * q + r; 0 \<le> r; r < b\<rbrakk> \<Longrightarrow> a div b = q"
  1644   by (rule divmod_int_rel_div [of a b q r]) (simp add: divmod_int_rel_def)
  1645 
  1646 lemma int_div_neg_eq: "\<lbrakk>(a::int) = b * q + r; r \<le> 0; b < r\<rbrakk> \<Longrightarrow> a div b = q"
  1647   by (rule divmod_int_rel_div [of a b q r],
  1648     simp add: divmod_int_rel_def)
  1649 
  1650 lemma int_mod_pos_eq: "\<lbrakk>(a::int) = b * q + r; 0 \<le> r; r < b\<rbrakk> \<Longrightarrow> a mod b = r"
  1651   by (rule divmod_int_rel_mod [of a b q r],
  1652     simp add: divmod_int_rel_def)
  1653 
  1654 lemma int_mod_neg_eq: "\<lbrakk>(a::int) = b * q + r; r \<le> 0; b < r\<rbrakk> \<Longrightarrow> a mod b = r"
  1655   by (rule divmod_int_rel_mod [of a b q r],
  1656     simp add: divmod_int_rel_def)
  1657 
  1658 (* simprocs adapted from HOL/ex/Binary.thy *)
  1659 ML {*
  1660 local
  1661   val mk_number = HOLogic.mk_number HOLogic.intT
  1662   val plus = @{term "plus :: int \<Rightarrow> int \<Rightarrow> int"}
  1663   val times = @{term "times :: int \<Rightarrow> int \<Rightarrow> int"}
  1664   val zero = @{term "0 :: int"}
  1665   val less = @{term "op < :: int \<Rightarrow> int \<Rightarrow> bool"}
  1666   val le = @{term "op \<le> :: int \<Rightarrow> int \<Rightarrow> bool"}
  1667   val simps = @{thms arith_simps} @ @{thms rel_simps} @
  1668     map (fn th => th RS sym) [@{thm numeral_1_eq_1}]
  1669   fun prove ctxt goal = Goal.prove ctxt [] [] (HOLogic.mk_Trueprop goal)
  1670     (K (ALLGOALS (full_simp_tac (HOL_basic_ss addsimps simps))));
  1671   fun binary_proc proc ss ct =
  1672     (case Thm.term_of ct of
  1673       _ $ t $ u =>
  1674       (case try (pairself (`(snd o HOLogic.dest_number))) (t, u) of
  1675         SOME args => proc (Simplifier.the_context ss) args
  1676       | NONE => NONE)
  1677     | _ => NONE);
  1678 in
  1679   fun divmod_proc posrule negrule =
  1680     binary_proc (fn ctxt => fn ((a, t), (b, u)) =>
  1681       if b = 0 then NONE else let
  1682         val (q, r) = pairself mk_number (Integer.div_mod a b)
  1683         val goal1 = HOLogic.mk_eq (t, plus $ (times $ u $ q) $ r)
  1684         val (goal2, goal3, rule) = if b > 0
  1685           then (le $ zero $ r, less $ r $ u, posrule RS eq_reflection)
  1686           else (le $ r $ zero, less $ u $ r, negrule RS eq_reflection)
  1687       in SOME (rule OF map (prove ctxt) [goal1, goal2, goal3]) end)
  1688 end
  1689 *}
  1690 
  1691 simproc_setup binary_int_div
  1692   ("numeral m div numeral n :: int" |
  1693    "numeral m div neg_numeral n :: int" |
  1694    "neg_numeral m div numeral n :: int" |
  1695    "neg_numeral m div neg_numeral n :: int") =
  1696   {* K (divmod_proc @{thm int_div_pos_eq} @{thm int_div_neg_eq}) *}
  1697 
  1698 simproc_setup binary_int_mod
  1699   ("numeral m mod numeral n :: int" |
  1700    "numeral m mod neg_numeral n :: int" |
  1701    "neg_numeral m mod numeral n :: int" |
  1702    "neg_numeral m mod neg_numeral n :: int") =
  1703   {* K (divmod_proc @{thm int_mod_pos_eq} @{thm int_mod_neg_eq}) *}
  1704 
  1705 lemmas posDivAlg_eqn_numeral [simp] =
  1706     posDivAlg_eqn [of "numeral v" "numeral w", OF zero_less_numeral] for v w
  1707 
  1708 lemmas negDivAlg_eqn_numeral [simp] =
  1709     negDivAlg_eqn [of "numeral v" "neg_numeral w", OF zero_less_numeral] for v w
  1710 
  1711 
  1712 text{*Special-case simplification *}
  1713 
  1714 lemma zmod_minus1_right [simp]: "a mod (-1::int) = 0"
  1715 apply (cut_tac a = a and b = "-1" in neg_mod_sign)
  1716 apply (cut_tac [2] a = a and b = "-1" in neg_mod_bound)
  1717 apply (auto simp del: neg_mod_sign neg_mod_bound)
  1718 done
  1719 
  1720 lemma zdiv_minus1_right [simp]: "a div (-1::int) = -a"
  1721 by (cut_tac a = a and b = "-1" in zmod_zdiv_equality, auto)
  1722 
  1723 (** The last remaining special cases for constant arithmetic:
  1724     1 div z and 1 mod z **)
  1725 
  1726 lemmas div_pos_pos_1_numeral [simp] =
  1727   div_pos_pos [OF zero_less_one, of "numeral w", OF zero_le_numeral] for w
  1728 
  1729 lemmas div_pos_neg_1_numeral [simp] =
  1730   div_pos_neg [OF zero_less_one, of "neg_numeral w",
  1731   OF neg_numeral_less_zero] for w
  1732 
  1733 lemmas mod_pos_pos_1_numeral [simp] =
  1734   mod_pos_pos [OF zero_less_one, of "numeral w", OF zero_le_numeral] for w
  1735 
  1736 lemmas mod_pos_neg_1_numeral [simp] =
  1737   mod_pos_neg [OF zero_less_one, of "neg_numeral w",
  1738   OF neg_numeral_less_zero] for w
  1739 
  1740 lemmas posDivAlg_eqn_1_numeral [simp] =
  1741     posDivAlg_eqn [of concl: 1 "numeral w", OF zero_less_numeral] for w
  1742 
  1743 lemmas negDivAlg_eqn_1_numeral [simp] =
  1744     negDivAlg_eqn [of concl: 1 "numeral w", OF zero_less_numeral] for w
  1745 
  1746 
  1747 subsubsection {* Monotonicity in the First Argument (Dividend) *}
  1748 
  1749 lemma zdiv_mono1: "[| a \<le> a';  0 < (b::int) |] ==> a div b \<le> a' div b"
  1750 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1751 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1752 apply (rule unique_quotient_lemma)
  1753 apply (erule subst)
  1754 apply (erule subst, simp_all)
  1755 done
  1756 
  1757 lemma zdiv_mono1_neg: "[| a \<le> a';  (b::int) < 0 |] ==> a' div b \<le> a div b"
  1758 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1759 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1760 apply (rule unique_quotient_lemma_neg)
  1761 apply (erule subst)
  1762 apply (erule subst, simp_all)
  1763 done
  1764 
  1765 
  1766 subsubsection {* Monotonicity in the Second Argument (Divisor) *}
  1767 
  1768 lemma q_pos_lemma:
  1769      "[| 0 \<le> b'*q' + r'; r' < b';  0 < b' |] ==> 0 \<le> (q'::int)"
  1770 apply (subgoal_tac "0 < b'* (q' + 1) ")
  1771  apply (simp add: zero_less_mult_iff)
  1772 apply (simp add: right_distrib)
  1773 done
  1774 
  1775 lemma zdiv_mono2_lemma:
  1776      "[| b*q + r = b'*q' + r';  0 \<le> b'*q' + r';   
  1777          r' < b';  0 \<le> r;  0 < b';  b' \<le> b |]   
  1778       ==> q \<le> (q'::int)"
  1779 apply (frule q_pos_lemma, assumption+) 
  1780 apply (subgoal_tac "b*q < b* (q' + 1) ")
  1781  apply (simp add: mult_less_cancel_left)
  1782 apply (subgoal_tac "b*q = r' - r + b'*q'")
  1783  prefer 2 apply simp
  1784 apply (simp (no_asm_simp) add: right_distrib)
  1785 apply (subst add_commute, rule add_less_le_mono, arith)
  1786 apply (rule mult_right_mono, auto)
  1787 done
  1788 
  1789 lemma zdiv_mono2:
  1790      "[| (0::int) \<le> a;  0 < b';  b' \<le> b |] ==> a div b \<le> a div b'"
  1791 apply (subgoal_tac "b \<noteq> 0")
  1792  prefer 2 apply arith
  1793 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1794 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1795 apply (rule zdiv_mono2_lemma)
  1796 apply (erule subst)
  1797 apply (erule subst, simp_all)
  1798 done
  1799 
  1800 lemma q_neg_lemma:
  1801      "[| b'*q' + r' < 0;  0 \<le> r';  0 < b' |] ==> q' \<le> (0::int)"
  1802 apply (subgoal_tac "b'*q' < 0")
  1803  apply (simp add: mult_less_0_iff, arith)
  1804 done
  1805 
  1806 lemma zdiv_mono2_neg_lemma:
  1807      "[| b*q + r = b'*q' + r';  b'*q' + r' < 0;   
  1808          r < b;  0 \<le> r';  0 < b';  b' \<le> b |]   
  1809       ==> q' \<le> (q::int)"
  1810 apply (frule q_neg_lemma, assumption+) 
  1811 apply (subgoal_tac "b*q' < b* (q + 1) ")
  1812  apply (simp add: mult_less_cancel_left)
  1813 apply (simp add: right_distrib)
  1814 apply (subgoal_tac "b*q' \<le> b'*q'")
  1815  prefer 2 apply (simp add: mult_right_mono_neg, arith)
  1816 done
  1817 
  1818 lemma zdiv_mono2_neg:
  1819      "[| a < (0::int);  0 < b';  b' \<le> b |] ==> a div b' \<le> a div b"
  1820 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1821 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1822 apply (rule zdiv_mono2_neg_lemma)
  1823 apply (erule subst)
  1824 apply (erule subst, simp_all)
  1825 done
  1826 
  1827 
  1828 subsubsection {* More Algebraic Laws for div and mod *}
  1829 
  1830 text{*proving (a*b) div c = a * (b div c) + a * (b mod c) *}
  1831 
  1832 lemma zmult1_lemma:
  1833      "[| divmod_int_rel b c (q, r) |]  
  1834       ==> divmod_int_rel (a * b) c (a*q + a*r div c, a*r mod c)"
  1835 by (auto simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_distrib mult_ac)
  1836 
  1837 lemma zdiv_zmult1_eq: "(a*b) div c = a*(b div c) + a*(b mod c) div (c::int)"
  1838 apply (case_tac "c = 0", simp)
  1839 apply (blast intro: divmod_int_rel_div_mod [THEN zmult1_lemma, THEN divmod_int_rel_div])
  1840 done
  1841 
  1842 lemma zmod_zmult1_eq: "(a*b) mod c = a*(b mod c) mod (c::int)"
  1843 apply (case_tac "c = 0", simp)
  1844 apply (blast intro: divmod_int_rel_div_mod [THEN zmult1_lemma, THEN divmod_int_rel_mod])
  1845 done
  1846 
  1847 lemma zmod_zdiv_trivial: "(a mod b) div b = (0::int)"
  1848 apply (case_tac "b = 0", simp)
  1849 apply (auto simp add: linorder_neq_iff div_pos_pos_trivial div_neg_neg_trivial)
  1850 done
  1851 
  1852 text{*proving (a+b) div c = a div c + b div c + ((a mod c + b mod c) div c) *}
  1853 
  1854 lemma zadd1_lemma:
  1855      "[| divmod_int_rel a c (aq, ar);  divmod_int_rel b c (bq, br) |]  
  1856       ==> divmod_int_rel (a+b) c (aq + bq + (ar+br) div c, (ar+br) mod c)"
  1857 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_distrib)
  1858 
  1859 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
  1860 lemma zdiv_zadd1_eq:
  1861      "(a+b) div (c::int) = a div c + b div c + ((a mod c + b mod c) div c)"
  1862 apply (case_tac "c = 0", simp)
  1863 apply (blast intro: zadd1_lemma [OF divmod_int_rel_div_mod divmod_int_rel_div_mod] divmod_int_rel_div)
  1864 done
  1865 
  1866 instance int :: ring_div
  1867 proof
  1868   fix a b c :: int
  1869   assume not0: "b \<noteq> 0"
  1870   show "(a + c * b) div b = c + a div b"
  1871     unfolding zdiv_zadd1_eq [of a "c * b"] using not0 
  1872       by (simp add: zmod_zmult1_eq zmod_zdiv_trivial zdiv_zmult1_eq)
  1873 next
  1874   fix a b c :: int
  1875   assume "a \<noteq> 0"
  1876   then show "(a * b) div (a * c) = b div c"
  1877   proof (cases "b \<noteq> 0 \<and> c \<noteq> 0")
  1878     case False then show ?thesis by auto
  1879   next
  1880     case True then have "b \<noteq> 0" and "c \<noteq> 0" by auto
  1881     with `a \<noteq> 0`
  1882     have "\<And>q r. divmod_int_rel b c (q, r) \<Longrightarrow> divmod_int_rel (a * b) (a * c) (q, a * r)"
  1883       apply (auto simp add: divmod_int_rel_def) 
  1884       apply (auto simp add: algebra_simps)
  1885       apply (auto simp add: zero_less_mult_iff zero_le_mult_iff mult_le_0_iff mult_commute [of a] mult_less_cancel_right)
  1886       done
  1887     moreover with `c \<noteq> 0` divmod_int_rel_div_mod have "divmod_int_rel b c (b div c, b mod c)" by auto
  1888     ultimately have "divmod_int_rel (a * b) (a * c) (b div c, a * (b mod c))" .
  1889     from this show ?thesis by (rule divmod_int_rel_div)
  1890   qed
  1891 qed auto
  1892 
  1893 lemma posDivAlg_div_mod:
  1894   assumes "k \<ge> 0"
  1895   and "l \<ge> 0"
  1896   shows "posDivAlg k l = (k div l, k mod l)"
  1897 proof (cases "l = 0")
  1898   case True then show ?thesis by (simp add: posDivAlg.simps)
  1899 next
  1900   case False with assms posDivAlg_correct
  1901     have "divmod_int_rel k l (fst (posDivAlg k l), snd (posDivAlg k l))"
  1902     by simp
  1903   from divmod_int_rel_div [OF this] divmod_int_rel_mod [OF this]
  1904   show ?thesis by simp
  1905 qed
  1906 
  1907 lemma negDivAlg_div_mod:
  1908   assumes "k < 0"
  1909   and "l > 0"
  1910   shows "negDivAlg k l = (k div l, k mod l)"
  1911 proof -
  1912   from assms have "l \<noteq> 0" by simp
  1913   from assms negDivAlg_correct
  1914     have "divmod_int_rel k l (fst (negDivAlg k l), snd (negDivAlg k l))"
  1915     by simp
  1916   from divmod_int_rel_div [OF this] divmod_int_rel_mod [OF this]
  1917   show ?thesis by simp
  1918 qed
  1919 
  1920 lemma zmod_eq_0_iff: "(m mod d = 0) = (EX q::int. m = d*q)"
  1921 by (simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
  1922 
  1923 (* REVISIT: should this be generalized to all semiring_div types? *)
  1924 lemmas zmod_eq_0D [dest!] = zmod_eq_0_iff [THEN iffD1]
  1925 
  1926 lemma zmod_zdiv_equality':
  1927   "(m\<Colon>int) mod n = m - (m div n) * n"
  1928   by (rule_tac P="%x. m mod n = x - (m div n) * n" in subst [OF mod_div_equality [of _ n]])
  1929     arith
  1930 
  1931 
  1932 subsubsection {* Proving  @{term "a div (b*c) = (a div b) div c"} *}
  1933 
  1934 (*The condition c>0 seems necessary.  Consider that 7 div ~6 = ~2 but
  1935   7 div 2 div ~3 = 3 div ~3 = ~1.  The subcase (a div b) mod c = 0 seems
  1936   to cause particular problems.*)
  1937 
  1938 text{*first, four lemmas to bound the remainder for the cases b<0 and b>0 *}
  1939 
  1940 lemma zmult2_lemma_aux1: "[| (0::int) < c;  b < r;  r \<le> 0 |] ==> b*c < b*(q mod c) + r"
  1941 apply (subgoal_tac "b * (c - q mod c) < r * 1")
  1942  apply (simp add: algebra_simps)
  1943 apply (rule order_le_less_trans)
  1944  apply (erule_tac [2] mult_strict_right_mono)
  1945  apply (rule mult_left_mono_neg)
  1946   using add1_zle_eq[of "q mod c"]apply(simp add: algebra_simps)
  1947  apply (simp)
  1948 apply (simp)
  1949 done
  1950 
  1951 lemma zmult2_lemma_aux2:
  1952      "[| (0::int) < c;   b < r;  r \<le> 0 |] ==> b * (q mod c) + r \<le> 0"
  1953 apply (subgoal_tac "b * (q mod c) \<le> 0")
  1954  apply arith
  1955 apply (simp add: mult_le_0_iff)
  1956 done
  1957 
  1958 lemma zmult2_lemma_aux3: "[| (0::int) < c;  0 \<le> r;  r < b |] ==> 0 \<le> b * (q mod c) + r"
  1959 apply (subgoal_tac "0 \<le> b * (q mod c) ")
  1960 apply arith
  1961 apply (simp add: zero_le_mult_iff)
  1962 done
  1963 
  1964 lemma zmult2_lemma_aux4: "[| (0::int) < c; 0 \<le> r; r < b |] ==> b * (q mod c) + r < b * c"
  1965 apply (subgoal_tac "r * 1 < b * (c - q mod c) ")
  1966  apply (simp add: right_diff_distrib)
  1967 apply (rule order_less_le_trans)
  1968  apply (erule mult_strict_right_mono)
  1969  apply (rule_tac [2] mult_left_mono)
  1970   apply simp
  1971  using add1_zle_eq[of "q mod c"] apply (simp add: algebra_simps)
  1972 apply simp
  1973 done
  1974 
  1975 lemma zmult2_lemma: "[| divmod_int_rel a b (q, r); 0 < c |]  
  1976       ==> divmod_int_rel a (b * c) (q div c, b*(q mod c) + r)"
  1977 by (auto simp add: mult_ac divmod_int_rel_def linorder_neq_iff
  1978                    zero_less_mult_iff right_distrib [symmetric] 
  1979                    zmult2_lemma_aux1 zmult2_lemma_aux2 zmult2_lemma_aux3 zmult2_lemma_aux4)
  1980 
  1981 lemma zdiv_zmult2_eq: "(0::int) < c ==> a div (b*c) = (a div b) div c"
  1982 apply (case_tac "b = 0", simp)
  1983 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN divmod_int_rel_div])
  1984 done
  1985 
  1986 lemma zmod_zmult2_eq:
  1987      "(0::int) < c ==> a mod (b*c) = b*(a div b mod c) + a mod b"
  1988 apply (case_tac "b = 0", simp)
  1989 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN divmod_int_rel_mod])
  1990 done
  1991 
  1992 lemma div_pos_geq:
  1993   fixes k l :: int
  1994   assumes "0 < l" and "l \<le> k"
  1995   shows "k div l = (k - l) div l + 1"
  1996 proof -
  1997   have "k = (k - l) + l" by simp
  1998   then obtain j where k: "k = j + l" ..
  1999   with assms show ?thesis by simp
  2000 qed
  2001 
  2002 lemma mod_pos_geq:
  2003   fixes k l :: int
  2004   assumes "0 < l" and "l \<le> k"
  2005   shows "k mod l = (k - l) mod l"
  2006 proof -
  2007   have "k = (k - l) + l" by simp
  2008   then obtain j where k: "k = j + l" ..
  2009   with assms show ?thesis by simp
  2010 qed
  2011 
  2012 
  2013 subsubsection {* Splitting Rules for div and mod *}
  2014 
  2015 text{*The proofs of the two lemmas below are essentially identical*}
  2016 
  2017 lemma split_pos_lemma:
  2018  "0<k ==> 
  2019     P(n div k :: int)(n mod k) = (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i j)"
  2020 apply (rule iffI, clarify)
  2021  apply (erule_tac P="P ?x ?y" in rev_mp)  
  2022  apply (subst mod_add_eq) 
  2023  apply (subst zdiv_zadd1_eq) 
  2024  apply (simp add: div_pos_pos_trivial mod_pos_pos_trivial)  
  2025 txt{*converse direction*}
  2026 apply (drule_tac x = "n div k" in spec) 
  2027 apply (drule_tac x = "n mod k" in spec, simp)
  2028 done
  2029 
  2030 lemma split_neg_lemma:
  2031  "k<0 ==>
  2032     P(n div k :: int)(n mod k) = (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i j)"
  2033 apply (rule iffI, clarify)
  2034  apply (erule_tac P="P ?x ?y" in rev_mp)  
  2035  apply (subst mod_add_eq) 
  2036  apply (subst zdiv_zadd1_eq) 
  2037  apply (simp add: div_neg_neg_trivial mod_neg_neg_trivial)  
  2038 txt{*converse direction*}
  2039 apply (drule_tac x = "n div k" in spec) 
  2040 apply (drule_tac x = "n mod k" in spec, simp)
  2041 done
  2042 
  2043 lemma split_zdiv:
  2044  "P(n div k :: int) =
  2045   ((k = 0 --> P 0) & 
  2046    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i)) & 
  2047    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i)))"
  2048 apply (case_tac "k=0", simp)
  2049 apply (simp only: linorder_neq_iff)
  2050 apply (erule disjE) 
  2051  apply (simp_all add: split_pos_lemma [of concl: "%x y. P x"] 
  2052                       split_neg_lemma [of concl: "%x y. P x"])
  2053 done
  2054 
  2055 lemma split_zmod:
  2056  "P(n mod k :: int) =
  2057   ((k = 0 --> P n) & 
  2058    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P j)) & 
  2059    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P j)))"
  2060 apply (case_tac "k=0", simp)
  2061 apply (simp only: linorder_neq_iff)
  2062 apply (erule disjE) 
  2063  apply (simp_all add: split_pos_lemma [of concl: "%x y. P y"] 
  2064                       split_neg_lemma [of concl: "%x y. P y"])
  2065 done
  2066 
  2067 text {* Enable (lin)arith to deal with @{const div} and @{const mod}
  2068   when these are applied to some constant that is of the form
  2069   @{term "numeral k"}: *}
  2070 declare split_zdiv [of _ _ "numeral k", arith_split] for k
  2071 declare split_zmod [of _ _ "numeral k", arith_split] for k
  2072 
  2073 
  2074 subsubsection {* Speeding up the Division Algorithm with Shifting *}
  2075 
  2076 text{*computing div by shifting *}
  2077 
  2078 lemma pos_zdiv_mult_2: "(0::int) \<le> a ==> (1 + 2*b) div (2*a) = b div a"
  2079 proof cases
  2080   assume "a=0"
  2081     thus ?thesis by simp
  2082 next
  2083   assume "a\<noteq>0" and le_a: "0\<le>a"   
  2084   hence a_pos: "1 \<le> a" by arith
  2085   hence one_less_a2: "1 < 2 * a" by arith
  2086   hence le_2a: "2 * (1 + b mod a) \<le> 2 * a"
  2087     unfolding mult_le_cancel_left
  2088     by (simp add: add1_zle_eq add_commute [of 1])
  2089   with a_pos have "0 \<le> b mod a" by simp
  2090   hence le_addm: "0 \<le> 1 mod (2*a) + 2*(b mod a)"
  2091     by (simp add: mod_pos_pos_trivial one_less_a2)
  2092   with  le_2a
  2093   have "(1 mod (2*a) + 2*(b mod a)) div (2*a) = 0"
  2094     by (simp add: div_pos_pos_trivial le_addm mod_pos_pos_trivial one_less_a2
  2095                   right_distrib) 
  2096   thus ?thesis
  2097     by (subst zdiv_zadd1_eq,
  2098         simp add: mod_mult_mult1 one_less_a2
  2099                   div_pos_pos_trivial)
  2100 qed
  2101 
  2102 lemma neg_zdiv_mult_2: 
  2103   assumes A: "a \<le> (0::int)" shows "(1 + 2*b) div (2*a) = (b+1) div a"
  2104 proof -
  2105   have R: "1 + - (2 * (b + 1)) = - (1 + 2 * b)" by simp
  2106   have "(1 + 2 * (-b - 1)) div (2 * (-a)) = (-b - 1) div (-a)"
  2107     by (rule pos_zdiv_mult_2, simp add: A)
  2108   thus ?thesis
  2109     by (simp only: R zdiv_zminus_zminus diff_minus
  2110       minus_add_distrib [symmetric] mult_minus_right)
  2111 qed
  2112 
  2113 (* FIXME: add rules for negative numerals *)
  2114 lemma zdiv_numeral_Bit0 [simp]:
  2115   "numeral (Num.Bit0 v) div numeral (Num.Bit0 w) =
  2116     numeral v div (numeral w :: int)"
  2117   unfolding numeral.simps unfolding mult_2 [symmetric]
  2118   by (rule div_mult_mult1, simp)
  2119 
  2120 lemma zdiv_numeral_Bit1 [simp]:
  2121   "numeral (Num.Bit1 v) div numeral (Num.Bit0 w) =  
  2122     (numeral v div (numeral w :: int))"
  2123   unfolding numeral.simps
  2124   unfolding mult_2 [symmetric] add_commute [of _ 1]
  2125   by (rule pos_zdiv_mult_2, simp)
  2126 
  2127 
  2128 subsubsection {* Computing mod by Shifting (proofs resemble those for div) *}
  2129 
  2130 lemma pos_zmod_mult_2:
  2131   fixes a b :: int
  2132   assumes "0 \<le> a"
  2133   shows "(1 + 2 * b) mod (2 * a) = 1 + 2 * (b mod a)"
  2134 proof (cases "0 < a")
  2135   case False with assms show ?thesis by simp
  2136 next
  2137   case True
  2138   then have "b mod a < a" by (rule pos_mod_bound)
  2139   then have "1 + b mod a \<le> a" by simp
  2140   then have A: "2 * (1 + b mod a) \<le> 2 * a" by simp
  2141   from `0 < a` have "0 \<le> b mod a" by (rule pos_mod_sign)
  2142   then have B: "0 \<le> 1 + 2 * (b mod a)" by simp
  2143   have "((1\<Colon>int) mod ((2\<Colon>int) * a) + (2\<Colon>int) * b mod ((2\<Colon>int) * a)) mod ((2\<Colon>int) * a) = (1\<Colon>int) + (2\<Colon>int) * (b mod a)"
  2144     using `0 < a` and A
  2145     by (auto simp add: mod_mult_mult1 mod_pos_pos_trivial ring_distribs intro!: mod_pos_pos_trivial B)
  2146   then show ?thesis by (subst mod_add_eq)
  2147 qed
  2148 
  2149 lemma neg_zmod_mult_2:
  2150   fixes a b :: int
  2151   assumes "a \<le> 0"
  2152   shows "(1 + 2 * b) mod (2 * a) = 2 * ((b + 1) mod a) - 1"
  2153 proof -
  2154   from assms have "0 \<le> - a" by auto
  2155   then have "(1 + 2 * (- b - 1)) mod (2 * (- a)) = 1 + 2 * ((- b - 1) mod (- a))"
  2156     by (rule pos_zmod_mult_2)
  2157   then show ?thesis by (simp add: zmod_zminus2 algebra_simps)
  2158      (simp add: diff_minus add_ac)
  2159 qed
  2160 
  2161 (* FIXME: add rules for negative numerals *)
  2162 lemma zmod_numeral_Bit0 [simp]:
  2163   "numeral (Num.Bit0 v) mod numeral (Num.Bit0 w) =  
  2164     (2::int) * (numeral v mod numeral w)"
  2165   unfolding numeral_Bit0 [of v] numeral_Bit0 [of w]
  2166   unfolding mult_2 [symmetric] by (rule mod_mult_mult1)
  2167 
  2168 lemma zmod_numeral_Bit1 [simp]:
  2169   "numeral (Num.Bit1 v) mod numeral (Num.Bit0 w) =
  2170     2 * (numeral v mod numeral w) + (1::int)"
  2171   unfolding numeral_Bit1 [of v] numeral_Bit0 [of w]
  2172   unfolding mult_2 [symmetric] add_commute [of _ 1]
  2173   by (rule pos_zmod_mult_2, simp)
  2174 
  2175 lemma zdiv_eq_0_iff:
  2176  "(i::int) div k = 0 \<longleftrightarrow> k=0 \<or> 0\<le>i \<and> i<k \<or> i\<le>0 \<and> k<i" (is "?L = ?R")
  2177 proof
  2178   assume ?L
  2179   have "?L \<longrightarrow> ?R" by (rule split_zdiv[THEN iffD2]) simp
  2180   with `?L` show ?R by blast
  2181 next
  2182   assume ?R thus ?L
  2183     by(auto simp: div_pos_pos_trivial div_neg_neg_trivial)
  2184 qed
  2185 
  2186 
  2187 subsubsection {* Quotients of Signs *}
  2188 
  2189 lemma div_neg_pos_less0: "[| a < (0::int);  0 < b |] ==> a div b < 0"
  2190 apply (subgoal_tac "a div b \<le> -1", force)
  2191 apply (rule order_trans)
  2192 apply (rule_tac a' = "-1" in zdiv_mono1)
  2193 apply (auto simp add: div_eq_minus1)
  2194 done
  2195 
  2196 lemma div_nonneg_neg_le0: "[| (0::int) \<le> a; b < 0 |] ==> a div b \<le> 0"
  2197 by (drule zdiv_mono1_neg, auto)
  2198 
  2199 lemma div_nonpos_pos_le0: "[| (a::int) \<le> 0; b > 0 |] ==> a div b \<le> 0"
  2200 by (drule zdiv_mono1, auto)
  2201 
  2202 text{* Now for some equivalences of the form @{text"a div b >=< 0 \<longleftrightarrow> \<dots>"}
  2203 conditional upon the sign of @{text a} or @{text b}. There are many more.
  2204 They should all be simp rules unless that causes too much search. *}
  2205 
  2206 lemma pos_imp_zdiv_nonneg_iff: "(0::int) < b ==> (0 \<le> a div b) = (0 \<le> a)"
  2207 apply auto
  2208 apply (drule_tac [2] zdiv_mono1)
  2209 apply (auto simp add: linorder_neq_iff)
  2210 apply (simp (no_asm_use) add: linorder_not_less [symmetric])
  2211 apply (blast intro: div_neg_pos_less0)
  2212 done
  2213 
  2214 lemma neg_imp_zdiv_nonneg_iff:
  2215   "b < (0::int) ==> (0 \<le> a div b) = (a \<le> (0::int))"
  2216 apply (subst zdiv_zminus_zminus [symmetric])
  2217 apply (subst pos_imp_zdiv_nonneg_iff, auto)
  2218 done
  2219 
  2220 (*But not (a div b \<le> 0 iff a\<le>0); consider a=1, b=2 when a div b = 0.*)
  2221 lemma pos_imp_zdiv_neg_iff: "(0::int) < b ==> (a div b < 0) = (a < 0)"
  2222 by (simp add: linorder_not_le [symmetric] pos_imp_zdiv_nonneg_iff)
  2223 
  2224 lemma pos_imp_zdiv_pos_iff:
  2225   "0<k \<Longrightarrow> 0 < (i::int) div k \<longleftrightarrow> k \<le> i"
  2226 using pos_imp_zdiv_nonneg_iff[of k i] zdiv_eq_0_iff[of i k]
  2227 by arith
  2228 
  2229 (*Again the law fails for \<le>: consider a = -1, b = -2 when a div b = 0*)
  2230 lemma neg_imp_zdiv_neg_iff: "b < (0::int) ==> (a div b < 0) = (0 < a)"
  2231 by (simp add: linorder_not_le [symmetric] neg_imp_zdiv_nonneg_iff)
  2232 
  2233 lemma nonneg1_imp_zdiv_pos_iff:
  2234   "(0::int) <= a \<Longrightarrow> (a div b > 0) = (a >= b & b>0)"
  2235 apply rule
  2236  apply rule
  2237   using div_pos_pos_trivial[of a b]apply arith
  2238  apply(cases "b=0")apply simp
  2239  using div_nonneg_neg_le0[of a b]apply arith
  2240 using int_one_le_iff_zero_less[of "a div b"] zdiv_mono1[of b a b]apply simp
  2241 done
  2242 
  2243 lemma zmod_le_nonneg_dividend: "(m::int) \<ge> 0 ==> m mod k \<le> m"
  2244 apply (rule split_zmod[THEN iffD2])
  2245 apply(fastforce dest: q_pos_lemma intro: split_mult_pos_le)
  2246 done
  2247 
  2248 
  2249 subsubsection {* The Divides Relation *}
  2250 
  2251 lemmas zdvd_iff_zmod_eq_0_numeral [simp] =
  2252   dvd_eq_mod_eq_0 [of "numeral x::int" "numeral y::int"]
  2253   dvd_eq_mod_eq_0 [of "numeral x::int" "neg_numeral y::int"]
  2254   dvd_eq_mod_eq_0 [of "neg_numeral x::int" "numeral y::int"]
  2255   dvd_eq_mod_eq_0 [of "neg_numeral x::int" "neg_numeral y::int"] for x y
  2256 
  2257 lemma zdvd_zmod: "f dvd m ==> f dvd (n::int) ==> f dvd m mod n"
  2258   by (rule dvd_mod) (* TODO: remove *)
  2259 
  2260 lemma zdvd_zmod_imp_zdvd: "k dvd m mod n ==> k dvd n ==> k dvd (m::int)"
  2261   by (rule dvd_mod_imp_dvd) (* TODO: remove *)
  2262 
  2263 lemmas dvd_eq_mod_eq_0_numeral [simp] =
  2264   dvd_eq_mod_eq_0 [of "numeral x" "numeral y"] for x y
  2265 
  2266 
  2267 subsubsection {* Further properties *}
  2268 
  2269 lemma zmult_div_cancel: "(n::int) * (m div n) = m - (m mod n)"
  2270   using zmod_zdiv_equality[where a="m" and b="n"]
  2271   by (simp add: algebra_simps)
  2272 
  2273 lemma zpower_zmod: "((x::int) mod m)^y mod m = x^y mod m"
  2274 apply (induct "y", auto)
  2275 apply (rule zmod_zmult1_eq [THEN trans])
  2276 apply (simp (no_asm_simp))
  2277 apply (rule mod_mult_eq [symmetric])
  2278 done
  2279 
  2280 lemma zdiv_int: "int (a div b) = (int a) div (int b)"
  2281 apply (subst split_div, auto)
  2282 apply (subst split_zdiv, auto)
  2283 apply (rule_tac a="int (b * i) + int j" and b="int b" and r="int j" and r'=ja in unique_quotient)
  2284 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2285 done
  2286 
  2287 lemma zmod_int: "int (a mod b) = (int a) mod (int b)"
  2288 apply (subst split_mod, auto)
  2289 apply (subst split_zmod, auto)
  2290 apply (rule_tac a="int (b * i) + int j" and b="int b" and q="int i" and q'=ia 
  2291        in unique_remainder)
  2292 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2293 done
  2294 
  2295 lemma abs_div: "(y::int) dvd x \<Longrightarrow> abs (x div y) = abs x div abs y"
  2296 by (unfold dvd_def, cases "y=0", auto simp add: abs_mult)
  2297 
  2298 lemma zdvd_mult_div_cancel:"(n::int) dvd m \<Longrightarrow> n * (m div n) = m"
  2299 apply (subgoal_tac "m mod n = 0")
  2300  apply (simp add: zmult_div_cancel)
  2301 apply (simp only: dvd_eq_mod_eq_0)
  2302 done
  2303 
  2304 text{*Suggested by Matthias Daum*}
  2305 lemma int_power_div_base:
  2306      "\<lbrakk>0 < m; 0 < k\<rbrakk> \<Longrightarrow> k ^ m div k = (k::int) ^ (m - Suc 0)"
  2307 apply (subgoal_tac "k ^ m = k ^ ((m - Suc 0) + Suc 0)")
  2308  apply (erule ssubst)
  2309  apply (simp only: power_add)
  2310  apply simp_all
  2311 done
  2312 
  2313 text {* by Brian Huffman *}
  2314 lemma zminus_zmod: "- ((x::int) mod m) mod m = - x mod m"
  2315 by (rule mod_minus_eq [symmetric])
  2316 
  2317 lemma zdiff_zmod_left: "(x mod m - y) mod m = (x - y) mod (m::int)"
  2318 by (rule mod_diff_left_eq [symmetric])
  2319 
  2320 lemma zdiff_zmod_right: "(x - y mod m) mod m = (x - y) mod (m::int)"
  2321 by (rule mod_diff_right_eq [symmetric])
  2322 
  2323 lemmas zmod_simps =
  2324   mod_add_left_eq  [symmetric]
  2325   mod_add_right_eq [symmetric]
  2326   zmod_zmult1_eq   [symmetric]
  2327   mod_mult_left_eq [symmetric]
  2328   zpower_zmod
  2329   zminus_zmod zdiff_zmod_left zdiff_zmod_right
  2330 
  2331 text {* Distributive laws for function @{text nat}. *}
  2332 
  2333 lemma nat_div_distrib: "0 \<le> x \<Longrightarrow> nat (x div y) = nat x div nat y"
  2334 apply (rule linorder_cases [of y 0])
  2335 apply (simp add: div_nonneg_neg_le0)
  2336 apply simp
  2337 apply (simp add: nat_eq_iff pos_imp_zdiv_nonneg_iff zdiv_int)
  2338 done
  2339 
  2340 (*Fails if y<0: the LHS collapses to (nat z) but the RHS doesn't*)
  2341 lemma nat_mod_distrib:
  2342   "\<lbrakk>0 \<le> x; 0 \<le> y\<rbrakk> \<Longrightarrow> nat (x mod y) = nat x mod nat y"
  2343 apply (case_tac "y = 0", simp)
  2344 apply (simp add: nat_eq_iff zmod_int)
  2345 done
  2346 
  2347 text  {* transfer setup *}
  2348 
  2349 lemma transfer_nat_int_functions:
  2350     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) div (nat y) = nat (x div y)"
  2351     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) mod (nat y) = nat (x mod y)"
  2352   by (auto simp add: nat_div_distrib nat_mod_distrib)
  2353 
  2354 lemma transfer_nat_int_function_closures:
  2355     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x div y >= 0"
  2356     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x mod y >= 0"
  2357   apply (cases "y = 0")
  2358   apply (auto simp add: pos_imp_zdiv_nonneg_iff)
  2359   apply (cases "y = 0")
  2360   apply auto
  2361 done
  2362 
  2363 declare transfer_morphism_nat_int [transfer add return:
  2364   transfer_nat_int_functions
  2365   transfer_nat_int_function_closures
  2366 ]
  2367 
  2368 lemma transfer_int_nat_functions:
  2369     "(int x) div (int y) = int (x div y)"
  2370     "(int x) mod (int y) = int (x mod y)"
  2371   by (auto simp add: zdiv_int zmod_int)
  2372 
  2373 lemma transfer_int_nat_function_closures:
  2374     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x div y)"
  2375     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x mod y)"
  2376   by (simp_all only: is_nat_def transfer_nat_int_function_closures)
  2377 
  2378 declare transfer_morphism_int_nat [transfer add return:
  2379   transfer_int_nat_functions
  2380   transfer_int_nat_function_closures
  2381 ]
  2382 
  2383 text{*Suggested by Matthias Daum*}
  2384 lemma int_div_less_self: "\<lbrakk>0 < x; 1 < k\<rbrakk> \<Longrightarrow> x div k < (x::int)"
  2385 apply (subgoal_tac "nat x div nat k < nat x")
  2386  apply (simp add: nat_div_distrib [symmetric])
  2387 apply (rule Divides.div_less_dividend, simp_all)
  2388 done
  2389 
  2390 lemma zmod_eq_dvd_iff: "(x::int) mod n = y mod n \<longleftrightarrow> n dvd x - y"
  2391 proof
  2392   assume H: "x mod n = y mod n"
  2393   hence "x mod n - y mod n = 0" by simp
  2394   hence "(x mod n - y mod n) mod n = 0" by simp 
  2395   hence "(x - y) mod n = 0" by (simp add: mod_diff_eq[symmetric])
  2396   thus "n dvd x - y" by (simp add: dvd_eq_mod_eq_0)
  2397 next
  2398   assume H: "n dvd x - y"
  2399   then obtain k where k: "x-y = n*k" unfolding dvd_def by blast
  2400   hence "x = n*k + y" by simp
  2401   hence "x mod n = (n*k + y) mod n" by simp
  2402   thus "x mod n = y mod n" by (simp add: mod_add_left_eq)
  2403 qed
  2404 
  2405 lemma nat_mod_eq_lemma: assumes xyn: "(x::nat) mod n = y  mod n" and xy:"y \<le> x"
  2406   shows "\<exists>q. x = y + n * q"
  2407 proof-
  2408   from xy have th: "int x - int y = int (x - y)" by simp 
  2409   from xyn have "int x mod int n = int y mod int n" 
  2410     by (simp add: zmod_int [symmetric])
  2411   hence "int n dvd int x - int y" by (simp only: zmod_eq_dvd_iff[symmetric]) 
  2412   hence "n dvd x - y" by (simp add: th zdvd_int)
  2413   then show ?thesis using xy unfolding dvd_def apply clarsimp apply (rule_tac x="k" in exI) by arith
  2414 qed
  2415 
  2416 lemma nat_mod_eq_iff: "(x::nat) mod n = y mod n \<longleftrightarrow> (\<exists>q1 q2. x + n * q1 = y + n * q2)" 
  2417   (is "?lhs = ?rhs")
  2418 proof
  2419   assume H: "x mod n = y mod n"
  2420   {assume xy: "x \<le> y"
  2421     from H have th: "y mod n = x mod n" by simp
  2422     from nat_mod_eq_lemma[OF th xy] have ?rhs 
  2423       apply clarify  apply (rule_tac x="q" in exI) by (rule exI[where x="0"], simp)}
  2424   moreover
  2425   {assume xy: "y \<le> x"
  2426     from nat_mod_eq_lemma[OF H xy] have ?rhs 
  2427       apply clarify  apply (rule_tac x="0" in exI) by (rule_tac x="q" in exI, simp)}
  2428   ultimately  show ?rhs using linear[of x y] by blast  
  2429 next
  2430   assume ?rhs then obtain q1 q2 where q12: "x + n * q1 = y + n * q2" by blast
  2431   hence "(x + n * q1) mod n = (y + n * q2) mod n" by simp
  2432   thus  ?lhs by simp
  2433 qed
  2434 
  2435 lemma div_nat_numeral [simp]:
  2436   "(numeral v :: nat) div numeral v' = nat (numeral v div numeral v')"
  2437   by (simp add: nat_div_distrib)
  2438 
  2439 lemma one_div_nat_numeral [simp]:
  2440   "Suc 0 div numeral v' = nat (1 div numeral v')"
  2441   by (subst nat_div_distrib, simp_all)
  2442 
  2443 lemma mod_nat_numeral [simp]:
  2444   "(numeral v :: nat) mod numeral v' = nat (numeral v mod numeral v')"
  2445   by (simp add: nat_mod_distrib)
  2446 
  2447 lemma one_mod_nat_numeral [simp]:
  2448   "Suc 0 mod numeral v' = nat (1 mod numeral v')"
  2449   by (subst nat_mod_distrib) simp_all
  2450 
  2451 lemma mod_2_not_eq_zero_eq_one_int:
  2452   fixes k :: int
  2453   shows "k mod 2 \<noteq> 0 \<longleftrightarrow> k mod 2 = 1"
  2454   by auto
  2455 
  2456 
  2457 subsubsection {* Tools setup *}
  2458 
  2459 text {* Nitpick *}
  2460 
  2461 lemmas [nitpick_unfold] = dvd_eq_mod_eq_0 mod_div_equality' zmod_zdiv_equality'
  2462 
  2463 
  2464 subsubsection {* Code generation *}
  2465 
  2466 definition pdivmod :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  2467   "pdivmod k l = (\<bar>k\<bar> div \<bar>l\<bar>, \<bar>k\<bar> mod \<bar>l\<bar>)"
  2468 
  2469 lemma pdivmod_posDivAlg [code]:
  2470   "pdivmod k l = (if l = 0 then (0, \<bar>k\<bar>) else posDivAlg \<bar>k\<bar> \<bar>l\<bar>)"
  2471 by (subst posDivAlg_div_mod) (simp_all add: pdivmod_def)
  2472 
  2473 lemma divmod_int_pdivmod: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2474   apsnd ((op *) (sgn l)) (if 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0
  2475     then pdivmod k l
  2476     else (let (r, s) = pdivmod k l in
  2477        if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2478 proof -
  2479   have aux: "\<And>q::int. - k = l * q \<longleftrightarrow> k = l * - q" by auto
  2480   show ?thesis
  2481     by (simp add: divmod_int_mod_div pdivmod_def)
  2482       (auto simp add: aux not_less not_le zdiv_zminus1_eq_if
  2483       zmod_zminus1_eq_if zdiv_zminus2_eq_if zmod_zminus2_eq_if)
  2484 qed
  2485 
  2486 lemma divmod_int_code [code]: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2487   apsnd ((op *) (sgn l)) (if sgn k = sgn l
  2488     then pdivmod k l
  2489     else (let (r, s) = pdivmod k l in
  2490       if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2491 proof -
  2492   have "k \<noteq> 0 \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0 \<longleftrightarrow> sgn k = sgn l"
  2493     by (auto simp add: not_less sgn_if)
  2494   then show ?thesis by (simp add: divmod_int_pdivmod)
  2495 qed
  2496 
  2497 code_modulename SML
  2498   Divides Arith
  2499 
  2500 code_modulename OCaml
  2501   Divides Arith
  2502 
  2503 code_modulename Haskell
  2504   Divides Arith
  2505 
  2506 end