src/Pure/Syntax/syn_ext.ML
author wenzelm
Tue Mar 21 12:18:15 2006 +0100 (2006-03-21)
changeset 19305 5c16895d548b
parent 19046 bc5c6c9b114e
child 19482 9f11af8f7ef9
permissions -rw-r--r--
avoid polymorphic equality;
     1 (*  Title:      Pure/Syntax/syn_ext.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel and Carsten Clasohm, TU Muenchen
     4 
     5 Syntax extension (internal interface).
     6 *)
     7 
     8 signature SYN_EXT0 =
     9 sig
    10   val dddot_indexname: indexname
    11   val constrainC: string
    12   val typeT: typ
    13   val max_pri: int
    14   val stamp_trfun: stamp -> string * 'a -> string * ('a * stamp)
    15   val mk_trfun: string * 'a -> string * ('a * stamp)
    16   val eq_trfun: ('a * stamp) * ('a * stamp) -> bool
    17   val tokentrans_mode: string -> (string * (string -> string * real)) list ->
    18     (string * string * (string -> string * real)) list
    19   val standard_token_classes: string list
    20 end;
    21 
    22 signature SYN_EXT =
    23 sig
    24   include SYN_EXT0
    25   val logic: string
    26   val args: string
    27   val cargs: string
    28   val any: string
    29   val sprop: string
    30   val typ_to_nonterm: typ -> string
    31   datatype xsymb =
    32     Delim of string |
    33     Argument of string * int |
    34     Space of string |
    35     Bg of int | Brk of int | En
    36   datatype xprod = XProd of string * xsymb list * string * int
    37   val chain_pri: int
    38   val delims_of: xprod list -> string list list
    39   datatype mfix = Mfix of string * typ * string * int list * int
    40   datatype syn_ext =
    41     SynExt of {
    42       xprods: xprod list,
    43       consts: string list,
    44       prmodes: string list,
    45       parse_ast_translation:
    46         (string * ((Context.generic -> Ast.ast list -> Ast.ast) * stamp)) list,
    47       parse_rules: (Ast.ast * Ast.ast) list,
    48       parse_translation:
    49         (string * ((Context.generic -> term list -> term) * stamp)) list,
    50       print_translation:
    51         (string * ((Context.generic -> bool -> typ -> term list -> term) * stamp)) list,
    52       print_rules: (Ast.ast * Ast.ast) list,
    53       print_ast_translation:
    54         (string * ((Context.generic -> Ast.ast list -> Ast.ast) * stamp)) list,
    55       token_translation: (string * string * (string -> string * real)) list}
    56   val mfix_delims: string -> string list
    57   val mfix_args: string -> int
    58   val escape_mfix: string -> string
    59   val unlocalize_mfix: string -> string
    60   val syn_ext': bool -> (string -> bool) -> mfix list ->
    61     string list -> (string * ((Context.generic -> Ast.ast list -> Ast.ast) * stamp)) list *
    62     (string * ((Context.generic -> term list -> term) * stamp)) list *
    63     (string * ((Context.generic -> bool -> typ -> term list -> term) * stamp)) list *
    64     (string * ((Context.generic -> Ast.ast list -> Ast.ast) * stamp)) list
    65     -> (string * string * (string -> string * real)) list
    66     -> (Ast.ast * Ast.ast) list * (Ast.ast * Ast.ast) list -> syn_ext
    67   val syn_ext: mfix list -> string list ->
    68     (string * ((Context.generic -> Ast.ast list -> Ast.ast) * stamp)) list *
    69     (string * ((Context.generic -> term list -> term) * stamp)) list *
    70     (string * ((Context.generic -> bool -> typ -> term list -> term) * stamp)) list *
    71     (string * ((Context.generic -> Ast.ast list -> Ast.ast) * stamp)) list
    72     -> (string * string * (string -> string * real)) list
    73     -> (Ast.ast * Ast.ast) list * (Ast.ast * Ast.ast) list -> syn_ext
    74   val syn_ext_const_names: string list -> syn_ext
    75   val syn_ext_rules: (Ast.ast * Ast.ast) list * (Ast.ast * Ast.ast) list -> syn_ext
    76   val syn_ext_trfuns:
    77     (string * ((Ast.ast list -> Ast.ast) * stamp)) list *
    78     (string * ((term list -> term) * stamp)) list *
    79     (string * ((bool -> typ -> term list -> term) * stamp)) list *
    80     (string * ((Ast.ast list -> Ast.ast) * stamp)) list -> syn_ext
    81   val syn_ext_advanced_trfuns:
    82     (string * ((Context.generic -> Ast.ast list -> Ast.ast) * stamp)) list *
    83     (string * ((Context.generic -> term list -> term) * stamp)) list *
    84     (string * ((Context.generic -> bool -> typ -> term list -> term) * stamp)) list *
    85     (string * ((Context.generic -> Ast.ast list -> Ast.ast) * stamp)) list -> syn_ext
    86   val syn_ext_tokentrfuns: (string * string * (string -> string * real)) list -> syn_ext
    87   val standard_token_markers: string list
    88   val pure_ext: syn_ext
    89 end;
    90 
    91 structure SynExt: SYN_EXT =
    92 struct
    93 
    94 
    95 (** misc definitions **)
    96 
    97 val dddot_indexname = ("dddot", 0);
    98 val constrainC = "_constrain";
    99 
   100 
   101 (* syntactic categories *)
   102 
   103 val logic = "logic";
   104 val logicT = Type (logic, []);
   105 
   106 val args = "args";
   107 val cargs = "cargs";
   108 
   109 val typeT = Type ("type", []);
   110 
   111 val sprop = "#prop";
   112 val spropT = Type (sprop, []);
   113 
   114 val any = "any";
   115 val anyT = Type (any, []);
   116 
   117 
   118 
   119 (** datatype xprod **)
   120 
   121 (*Delim s: delimiter s
   122   Argument (s, p): nonterminal s requiring priority >= p, or valued token
   123   Space s: some white space for printing
   124   Bg, Brk, En: blocks and breaks for pretty printing*)
   125 
   126 datatype xsymb =
   127   Delim of string |
   128   Argument of string * int |
   129   Space of string |
   130   Bg of int | Brk of int | En;
   131 
   132 fun is_delim (Delim _) = true
   133   | is_delim _ = false;
   134 
   135 fun is_terminal (Delim _) = true
   136   | is_terminal (Argument (s, _)) = Lexicon.is_terminal s
   137   | is_terminal _ = false;
   138 
   139 fun is_argument (Argument _) = true
   140   | is_argument _ = false;
   141 
   142 fun is_index (Argument ("index", _)) = true
   143   | is_index _ = false;
   144 
   145 val index = Argument ("index", 1000);
   146 
   147 
   148 (*XProd (lhs, syms, c, p):
   149     lhs: name of nonterminal on the lhs of the production
   150     syms: list of symbols on the rhs of the production
   151     c: head of parse tree
   152     p: priority of this production*)
   153 
   154 datatype xprod = XProd of string * xsymb list * string * int;
   155 
   156 val max_pri = 1000;   (*maximum legal priority*)
   157 val chain_pri = ~1;   (*dummy for chain productions*)
   158 
   159 fun delims_of xprods =
   160   fold (fn XProd (_, xsymbs, _, _) =>
   161     fold (fn Delim s => insert (op =) s | _ => I) xsymbs) xprods []
   162   |> map Symbol.explode;
   163 
   164 
   165 
   166 (** datatype mfix **)
   167 
   168 (*Mfix (sy, ty, c, ps, p):
   169     sy: rhs of production as symbolic string
   170     ty: type description of production
   171     c: head of parse tree
   172     ps: priorities of arguments in sy
   173     p: priority of production*)
   174 
   175 datatype mfix = Mfix of string * typ * string * int list * int;
   176 
   177 fun err_in_mfix msg (Mfix (sy, _, const, _, _)) =
   178   cat_error msg ("in mixfix annotation " ^ quote sy ^ " for " ^ quote const);
   179 
   180 
   181 (* typ_to_nonterm *)
   182 
   183 fun typ_to_nt _ (Type (c, _)) = c
   184   | typ_to_nt default _ = default;
   185 
   186 (*get nonterminal for rhs*)
   187 val typ_to_nonterm = typ_to_nt any;
   188 
   189 (*get nonterminal for lhs*)
   190 val typ_to_nonterm1 = typ_to_nt logic;
   191 
   192 
   193 (* read mixfix annotations *)
   194 
   195 local
   196 
   197 fun is_meta c = c mem ["(", ")", "/", "_", "\\<index>"];
   198 
   199 val scan_delim_char =
   200   $$ "'" |-- Scan.one ((not o Symbol.is_blank) andf Symbol.not_eof) ||
   201   Scan.one ((not o is_meta) andf (not o Symbol.is_blank) andf Symbol.not_eof);
   202 
   203 fun read_int ["0", "0"] = ~1
   204   | read_int cs = #1 (Library.read_int cs);
   205 
   206 val scan_sym =
   207   $$ "_" >> K (Argument ("", 0)) ||
   208   $$ "\\<index>" >> K index ||
   209   $$ "(" |-- Scan.any Symbol.is_digit >> (Bg o read_int) ||
   210   $$ ")" >> K En ||
   211   $$ "/" -- $$ "/" >> K (Brk ~1) ||
   212   $$ "/" |-- Scan.any Symbol.is_blank >> (Brk o length) ||
   213   Scan.any1 Symbol.is_blank >> (Space o implode) ||
   214   Scan.repeat1 scan_delim_char >> (Delim o implode);
   215 
   216 val scan_symb =
   217   scan_sym >> SOME ||
   218   $$ "'" -- Scan.one Symbol.is_blank >> K NONE;
   219 
   220 val scan_symbs = Scan.repeat scan_symb --| Scan.ahead (~$$ "'");
   221 val read_symbs = List.mapPartial I o the o Scan.read Symbol.stopper scan_symbs;
   222 
   223 fun unique_index xsymbs =
   224   if length (List.filter is_index xsymbs) <= 1 then xsymbs
   225   else error "Duplicate index arguments (\\<index>)";
   226 
   227 in
   228 
   229 val read_mfix = unique_index o read_symbs o Symbol.explode;
   230 
   231 fun mfix_delims sy = fold_rev (fn Delim s => cons s | _ => I) (read_mfix sy) [];
   232 val mfix_args = length o List.filter is_argument o read_mfix;
   233 
   234 val escape_mfix = implode o map (fn s => if is_meta s then "'" ^ s else s) o Symbol.explode;
   235 
   236 end;
   237 
   238 val unlocalize_mfix =
   239   let
   240     fun unloc ("'" :: "\\<^loc>" :: ss) = unloc ss
   241       | unloc ("\\<^loc>" :: ss) = unloc ss
   242       | unloc (s :: ss) = s :: unloc ss
   243       | unloc [] = [];
   244   in Symbol.explode #> unloc #> implode end;  
   245 
   246 
   247 (* mfix_to_xprod *)
   248 
   249 fun mfix_to_xprod convert is_logtype (mfix as Mfix (sy, typ, const, pris, pri)) =
   250   let
   251     fun check_pri p =
   252       if p >= 0 andalso p <= max_pri then ()
   253       else err_in_mfix ("Precedence out of range: " ^ string_of_int p) mfix;
   254 
   255     fun blocks_ok [] 0 = true
   256       | blocks_ok [] _ = false
   257       | blocks_ok (Bg _ :: syms) n = blocks_ok syms (n + 1)
   258       | blocks_ok (En :: _) 0 = false
   259       | blocks_ok (En :: syms) n = blocks_ok syms (n - 1)
   260       | blocks_ok (_ :: syms) n = blocks_ok syms n;
   261 
   262     fun check_blocks syms =
   263       if blocks_ok syms 0 then ()
   264       else err_in_mfix "Unbalanced block parentheses" mfix;
   265 
   266 
   267     val cons_fst = apfst o cons;
   268 
   269     fun add_args [] ty [] = ([], typ_to_nonterm1 ty)
   270       | add_args [] _ _ = err_in_mfix "Too many precedences" mfix
   271       | add_args ((arg as Argument ("index", _)) :: syms) ty ps =
   272           cons_fst arg (add_args syms ty ps)
   273       | add_args (Argument _ :: syms) (Type ("fun", [ty, tys])) [] =
   274           cons_fst (Argument (typ_to_nonterm ty, 0)) (add_args syms tys [])
   275       | add_args (Argument _ :: syms) (Type ("fun", [ty, tys])) (p :: ps) =
   276           cons_fst (Argument (typ_to_nonterm ty, p)) (add_args syms tys ps)
   277       | add_args (Argument _ :: _) _ _ =
   278           err_in_mfix "More arguments than in corresponding type" mfix
   279       | add_args (sym :: syms) ty ps = cons_fst sym (add_args syms ty ps);
   280 
   281     fun rem_pri (Argument (s, _)) = Argument (s, chain_pri)
   282       | rem_pri sym = sym;
   283 
   284     fun logify_types copy_prod (a as (Argument (s, p))) =
   285           if s <> "prop" andalso is_logtype s then Argument (logic, p) else a
   286       | logify_types _ a = a;
   287 
   288 
   289     val raw_symbs = read_mfix sy handle ERROR msg => err_in_mfix msg mfix;
   290     val args = List.filter (fn Argument _ => true | _ => false) raw_symbs;
   291     val (const', typ', parse_rules) =
   292       if not (exists is_index args) then (const, typ, [])
   293       else
   294         let
   295           val indexed_const = if const <> "" then "_indexed_" ^ const
   296             else err_in_mfix "Missing constant name for indexed syntax" mfix;
   297           val rangeT = Term.range_type typ handle Match =>
   298             err_in_mfix "Missing structure argument for indexed syntax" mfix;
   299 
   300           val xs = map Ast.Variable (Term.invent_names [] "xa" (length args - 1));
   301           val (xs1, xs2) = chop (find_index is_index args) xs;
   302           val i = Ast.Variable "i";
   303           val lhs = Ast.mk_appl (Ast.Constant indexed_const)
   304             (xs1 @ [Ast.mk_appl (Ast.Constant "_index") [i]] @ xs2);
   305           val rhs = Ast.mk_appl (Ast.Constant const) (i :: xs);
   306         in (indexed_const, rangeT, [(lhs, rhs)]) end;
   307 
   308     val (symbs, lhs) = add_args raw_symbs typ' pris;
   309 
   310     val copy_prod =
   311       lhs mem ["prop", "logic"]
   312         andalso const <> ""
   313         andalso not (null symbs)
   314         andalso not (exists is_delim symbs);
   315     val lhs' =
   316       if convert andalso not copy_prod then
   317        (if lhs = "prop" then sprop else if is_logtype lhs then logic else lhs)
   318       else lhs;
   319     val symbs' = map (logify_types copy_prod) symbs;
   320     val xprod = XProd (lhs', symbs', const', pri);
   321 
   322     val _ = (List.app check_pri pris; check_pri pri; check_blocks symbs');
   323     val xprod' =
   324       if Lexicon.is_terminal lhs' then err_in_mfix ("Illegal lhs: " ^ lhs') mfix
   325       else if const <> "" then xprod
   326       else if length (List.filter is_argument symbs') <> 1 then
   327         err_in_mfix "Copy production must have exactly one argument" mfix
   328       else if exists is_terminal symbs' then xprod
   329       else XProd (lhs', map rem_pri symbs', "", chain_pri);
   330 
   331   in (xprod', parse_rules) end;
   332 
   333 
   334 
   335 (** datatype syn_ext **)
   336 
   337 datatype syn_ext =
   338   SynExt of {
   339     xprods: xprod list,
   340     consts: string list,
   341     prmodes: string list,
   342     parse_ast_translation:
   343       (string * ((Context.generic -> Ast.ast list -> Ast.ast) * stamp)) list,
   344     parse_rules: (Ast.ast * Ast.ast) list,
   345     parse_translation:
   346       (string * ((Context.generic -> term list -> term) * stamp)) list,
   347     print_translation:
   348       (string * ((Context.generic -> bool -> typ -> term list -> term) * stamp)) list,
   349     print_rules: (Ast.ast * Ast.ast) list,
   350     print_ast_translation:
   351       (string * ((Context.generic -> Ast.ast list -> Ast.ast) * stamp)) list,
   352     token_translation: (string * string * (string -> string * real)) list};
   353 
   354 
   355 (* syn_ext *)
   356 
   357 fun syn_ext' convert is_logtype mfixes consts trfuns tokentrfuns (parse_rules, print_rules) =
   358   let
   359     val (parse_ast_translation, parse_translation, print_translation,
   360       print_ast_translation) = trfuns;
   361 
   362     val (xprods, parse_rules') = map (mfix_to_xprod convert is_logtype) mfixes
   363       |> split_list |> apsnd (rev o List.concat);
   364     val mfix_consts =
   365       distinct (op =) (map (fn Mfix x => #3 x) mfixes @ map (fn XProd x => #3 x) xprods);
   366   in
   367     SynExt {
   368       xprods = xprods,
   369       consts = consts union_string mfix_consts,
   370       prmodes = distinct (op =) (map (fn (m, _, _) => m) tokentrfuns),
   371       parse_ast_translation = parse_ast_translation,
   372       parse_rules = parse_rules' @ parse_rules,
   373       parse_translation = parse_translation,
   374       print_translation = print_translation,
   375       print_rules = map swap parse_rules' @ print_rules,
   376       print_ast_translation = print_ast_translation,
   377       token_translation = tokentrfuns}
   378   end;
   379 
   380 
   381 val syn_ext = syn_ext' true (K false);
   382 
   383 fun syn_ext_const_names cs = syn_ext [] cs ([], [], [], []) [] ([], []);
   384 fun syn_ext_rules rules = syn_ext [] [] ([], [], [], []) [] rules;
   385 fun syn_ext_advanced_trfuns trfuns = syn_ext [] [] trfuns [] ([], []);
   386 fun syn_ext_tokentrfuns trfuns = syn_ext [] [] ([], [], [], []) trfuns ([], []);
   387 
   388 fun syn_ext_trfuns (atrs, trs, tr's, atr's) =
   389   let fun simple (name, (f, s)) = (name, (K f, s)) in
   390     syn_ext_advanced_trfuns (map simple atrs, map simple trs, map simple tr's, map simple atr's)
   391   end;
   392 
   393 fun stamp_trfun s (c, f) = (c, (f, s));
   394 fun mk_trfun tr = stamp_trfun (stamp ()) tr;
   395 fun eq_trfun ((_, s1:stamp), (_, s2)) = s1 = s2;
   396 
   397 
   398 (* token translations *)
   399 
   400 fun tokentrans_mode m trs = map (fn (s, f) => (m, s, f)) trs;
   401 
   402 val standard_token_classes =
   403   ["class", "tfree", "tvar", "free", "bound", "var", "num", "xnum", "xstr"];
   404 
   405 val standard_token_markers = map (fn s => "_" ^ s) standard_token_classes;
   406 
   407 
   408 (* pure_ext *)
   409 
   410 val pure_ext = syn_ext' false (K false)
   411   [Mfix ("_", spropT --> propT, "", [0], 0),
   412    Mfix ("_", logicT --> anyT, "", [0], 0),
   413    Mfix ("_", spropT --> anyT, "", [0], 0),
   414    Mfix ("'(_')", logicT --> logicT, "", [0], max_pri),
   415    Mfix ("'(_')", spropT --> spropT, "", [0], max_pri),
   416    Mfix ("_::_",  [logicT, typeT] ---> logicT, "_constrain", [4, 0], 3),
   417    Mfix ("_::_",  [spropT, typeT] ---> spropT, "_constrain", [4, 0], 3)]
   418   []
   419   ([], [], [], [])
   420   []
   421   ([], []);
   422 
   423 end;