src/HOL/Tools/res_clause.ML
author haftmann
Wed Jun 07 16:55:39 2006 +0200 (2006-06-07)
changeset 19818 5c5c1208a3fa
parent 19719 837025cc6317
child 20015 1ffcf4802802
permissions -rw-r--r--
adding case theorems for code generator
     1 (*  Author: Jia Meng, Cambridge University Computer Laboratory
     2     ID: $Id$
     3     Copyright 2004 University of Cambridge
     4 
     5 ML data structure for storing/printing FOL clauses and arity clauses.
     6 Typed equality is treated differently.
     7 *)
     8 
     9 signature RES_CLAUSE =
    10   sig
    11   exception CLAUSE of string * term
    12   type clause and arityClause and classrelClause
    13   type fol_type
    14   type typ_var
    15   type type_literal
    16   val add_typs_aux : (typ_var * string list) list -> type_literal list * type_literal list
    17   val arity_clause_thy: theory -> arityClause list 
    18   val ascii_of : string -> string
    19   val bracket_pack : string list -> string
    20   val check_var_pairs: ''a * ''b -> (''a * ''b) list -> int
    21   val classrel_clauses_thy: theory -> classrelClause list 
    22   val clause_eq : clause * clause -> bool
    23   val clause_prefix : string 
    24   val clause2tptp : clause -> string * string list
    25   val const_prefix : string
    26   val dfg_write_file:  thm list -> string -> ((thm * (string * int)) list * classrelClause list * arityClause list) -> unit
    27   val fixed_var_prefix : string
    28   val gen_tptp_cls : int * string * string * string -> string
    29   val gen_tptp_type_cls : int * string * string * string * int -> string
    30   val get_axiomName : clause ->  string
    31   val hash_clause : clause -> int
    32   val init : theory -> unit
    33   val isMeta : string -> bool
    34   val isTaut : clause -> bool
    35   val keep_types : bool ref
    36   val list_ord : ('a * 'b -> order) -> 'a list * 'b list -> order
    37   val make_axiom_clause : thm -> string * int -> clause option
    38   val make_conjecture_clauses : thm list -> clause list
    39   val make_fixed_const : string -> string		
    40   val make_fixed_type_const : string -> string   
    41   val make_fixed_type_var : string -> string
    42   val make_fixed_var : string -> string
    43   val make_schematic_type_var : string * int -> string
    44   val make_schematic_var : string * int -> string
    45   val make_type_class : string -> string
    46   val mk_fol_type: string * string * fol_type list -> fol_type
    47   val mk_typ_var_sort : Term.typ -> typ_var * sort
    48   val paren_pack : string list -> string
    49   val schematic_var_prefix : string
    50   val special_equal : bool ref
    51   val string_of_fol_type : fol_type -> string
    52   val tconst_prefix : string 
    53   val tfree_prefix : string
    54   val tptp_arity_clause : arityClause -> string
    55   val tptp_classrelClause : classrelClause -> string
    56   val tptp_of_typeLit : type_literal -> string
    57   val tptp_tfree_clause : string -> string
    58   val tptp_write_file: thm list -> string -> ((thm * (string * int)) list * classrelClause list * arityClause list) -> unit
    59   val tvar_prefix : string
    60   val types_eq: fol_type list * fol_type list -> (string*string) list * (string*string) list -> bool * ((string*string) list * (string*string) list)
    61   val types_ord : fol_type list * fol_type list -> order
    62   val union_all : ''a list list -> ''a list
    63   val writeln_strs: TextIO.outstream -> TextIO.vector list -> unit
    64   val dfg_sign: bool -> string -> string
    65   val dfg_of_typeLit: type_literal -> string
    66   val get_tvar_strs: (typ_var * sort) list -> string list
    67   val gen_dfg_cls: int * string * string * string * string list -> string
    68   val add_foltype_funcs: fol_type * int Symtab.table -> int Symtab.table
    69   val add_arityClause_funcs: arityClause * int Symtab.table -> int Symtab.table
    70   val add_arityClause_preds: arityClause * int Symtab.table -> int Symtab.table
    71   val add_classrelClause_preds : classrelClause * int Symtab.table -> int Symtab.table
    72   val dfg_tfree_clause : string -> string
    73   val string_of_start: string -> string
    74   val string_of_descrip : string -> string
    75   val string_of_symbols: string -> string -> string
    76   val string_of_funcs: (string * int) list -> string
    77   val string_of_preds: (string * Int.int) list -> string
    78   val dfg_classrelClause: classrelClause -> string
    79   val dfg_arity_clause: arityClause -> string
    80 end;
    81 
    82 structure ResClause : RES_CLAUSE =
    83 struct
    84 
    85 (* Added for typed equality *)
    86 val special_equal = ref false; (* by default,equality does not carry type information *)
    87 val eq_typ_wrapper = "typeinfo"; (* default string *)
    88 
    89 
    90 val schematic_var_prefix = "V_";
    91 val fixed_var_prefix = "v_";
    92 
    93 val tvar_prefix = "T_";
    94 val tfree_prefix = "t_";
    95 
    96 val clause_prefix = "cls_"; 
    97 val arclause_prefix = "clsarity_" 
    98 val clrelclause_prefix = "clsrel_";
    99 
   100 val const_prefix = "c_";
   101 val tconst_prefix = "tc_"; 
   102 val class_prefix = "class_"; 
   103 
   104 fun union_all xss = foldl (op union) [] xss;
   105 
   106 (*Provide readable names for the more common symbolic functions*)
   107 val const_trans_table =
   108       Symtab.make [("op =", "equal"),
   109 	  	   ("Orderings.less_eq", "lessequals"),
   110 		   ("Orderings.less", "less"),
   111 		   ("op &", "and"),
   112 		   ("op |", "or"),
   113 		   ("HOL.plus", "plus"),
   114 		   ("HOL.minus", "minus"),
   115 		   ("HOL.times", "times"),
   116 		   ("Divides.op div", "div"),
   117 		   ("HOL.divide", "divide"),
   118 		   ("op -->", "implies"),
   119 		   ("{}", "emptyset"),
   120 		   ("op :", "in"),
   121 		   ("op Un", "union"),
   122 		   ("op Int", "inter"),
   123 		   ("List.op @", "append")];
   124 
   125 val type_const_trans_table =
   126       Symtab.make [("*", "prod"),
   127 	  	   ("+", "sum"),
   128 		   ("~=>", "map")];
   129 
   130 (*Escaping of special characters.
   131   Alphanumeric characters are left unchanged.
   132   The character _ goes to __
   133   Characters in the range ASCII space to / go to _A to _P, respectively.
   134   Other printing characters go to _NNN where NNN is the decimal ASCII code.*)
   135 local
   136 
   137 val A_minus_space = Char.ord #"A" - Char.ord #" ";
   138 
   139 fun ascii_of_c c =
   140   if Char.isAlphaNum c then String.str c
   141   else if c = #"_" then "__"
   142   else if #" " <= c andalso c <= #"/" 
   143        then "_" ^ String.str (Char.chr (Char.ord c + A_minus_space))
   144   else if Char.isPrint c then ("_" ^ Int.toString (Char.ord c))
   145   else ""
   146 
   147 in
   148 
   149 val ascii_of = String.translate ascii_of_c;
   150 
   151 end;
   152 
   153 (* convert a list of strings into one single string; surrounded by brackets *)
   154 fun paren_pack [] = ""   (*empty argument list*)
   155   | paren_pack strings = "(" ^ commas strings ^ ")";
   156 
   157 fun bracket_pack strings = "[" ^ commas strings ^ "]";
   158 
   159 
   160 (*Remove the initial ' character from a type variable, if it is present*)
   161 fun trim_type_var s =
   162   if s <> "" andalso String.sub(s,0) = #"'" then String.extract(s,1,NONE)
   163   else error ("trim_type: Malformed type variable encountered: " ^ s);
   164 
   165 fun ascii_of_indexname (v,0) = ascii_of v
   166   | ascii_of_indexname (v,i) = ascii_of v ^ "_" ^ Int.toString i;
   167 
   168 fun make_schematic_var v = schematic_var_prefix ^ (ascii_of_indexname v);
   169 fun make_fixed_var x = fixed_var_prefix ^ (ascii_of x);
   170 
   171 fun make_schematic_type_var (x,i) = 
   172       tvar_prefix ^ (ascii_of_indexname (trim_type_var x,i));
   173 fun make_fixed_type_var x = tfree_prefix ^ (ascii_of (trim_type_var x));
   174 
   175 fun lookup_const c =
   176     case Symtab.lookup const_trans_table c of
   177         SOME c' => c'
   178       | NONE => ascii_of c;
   179 
   180 fun lookup_type_const c = 
   181     case Symtab.lookup type_const_trans_table c of
   182         SOME c' => c'
   183       | NONE => ascii_of c;
   184 
   185 fun make_fixed_const "op =" = "equal"   (*MUST BE "equal" because it's built-in to ATPs*)
   186   | make_fixed_const c      = const_prefix ^ lookup_const c;
   187 
   188 fun make_fixed_type_const c = tconst_prefix ^ lookup_type_const c;
   189 
   190 fun make_type_class clas = class_prefix ^ ascii_of clas;
   191 
   192 
   193 (***** definitions and functions for FOL clauses, for conversion to TPTP or DFG format. *****)
   194 
   195 val keep_types = ref true;
   196 
   197 datatype kind = Axiom | Hypothesis | Conjecture;
   198 fun name_of_kind Axiom = "axiom"
   199   | name_of_kind Hypothesis = "hypothesis"
   200   | name_of_kind Conjecture = "conjecture";
   201 
   202 type clause_id = int;
   203 type axiom_name = string;
   204 
   205 
   206 type polarity = bool;
   207 
   208 (* "tag" is used for vampire specific syntax FIXME REMOVE *)
   209 type tag = bool; 
   210 
   211 
   212 (**** Isabelle FOL clauses ****)
   213 
   214 val tagged = ref false;
   215 
   216 type pred_name = string;
   217 
   218 datatype typ_var = FOLTVar of indexname | FOLTFree of string;
   219 
   220 (*FIXME: give the constructors more sensible names*)
   221 datatype fol_type = AtomV of string
   222 		  | AtomF of string
   223 		  | Comp of string * fol_type list;
   224 
   225 fun string_of_fol_type (AtomV x) = x
   226   | string_of_fol_type (AtomF x) = x
   227   | string_of_fol_type (Comp(tcon,tps)) = 
   228       tcon ^ (paren_pack (map string_of_fol_type tps));
   229       
   230 fun mk_fol_type ("Var",x,_) = AtomV(x)
   231   | mk_fol_type ("Fixed",x,_) = AtomF(x)
   232   | mk_fol_type ("Comp",con,args) = Comp(con,args)
   233 
   234 
   235 (*First string is the type class; the second is a TVar or TFfree*)
   236 datatype type_literal = LTVar of string * string | LTFree of string * string;
   237 
   238 datatype fol_term = UVar of string * fol_type
   239                  | Fun of string * fol_type list * fol_term list;
   240 datatype predicate = Predicate of pred_name * fol_type list * fol_term list;
   241 
   242 datatype literal = Literal of polarity * predicate * tag;
   243 
   244 fun mk_typ_var_sort (TFree(a,s)) = (FOLTFree a,s)
   245   | mk_typ_var_sort (TVar(v,s)) = (FOLTVar v,s);
   246 
   247 
   248 (*A clause has first-order literals and other, type-related literals*)
   249 datatype clause = 
   250 	 Clause of {clause_id: clause_id,
   251 		    axiom_name: axiom_name,
   252 		    th: thm,
   253 		    kind: kind,
   254 		    literals: literal list,
   255 		    types_sorts: (typ_var * sort) list};
   256 
   257 fun get_axiomName (Clause cls) = #axiom_name cls;
   258 
   259 exception CLAUSE of string * term;
   260 
   261 fun isFalse (Literal (pol,Predicate(pname,_,[]),_)) =
   262       (pol andalso pname = "c_False") orelse
   263       (not pol andalso pname = "c_True")
   264   | isFalse _ = false;
   265 
   266 fun isTrue (Literal (pol,Predicate(pname,_,[]),_)) =
   267       (pol andalso pname = "c_True") orelse
   268       (not pol andalso pname = "c_False")
   269   | isTrue _ = false;
   270   
   271 fun isTaut (Clause {literals,...}) = exists isTrue literals;  
   272 
   273 fun make_clause (clause_id, axiom_name, th, kind, literals, types_sorts) =
   274   if forall isFalse literals 
   275   then error "Problem too trivial for resolution (empty clause)"
   276   else
   277      Clause {clause_id = clause_id, axiom_name = axiom_name, 
   278              th = th, kind = kind, 
   279              literals = literals, types_sorts = types_sorts};
   280 
   281 
   282 (*Declarations of the current theory--to allow suppressing types.*)
   283 val const_typargs = ref (Library.K [] : (string*typ -> typ list));
   284 
   285 fun num_typargs(s,T) = if !keep_types then length (!const_typargs (s,T)) else 0;
   286 
   287 (*Initialize the type suppression mechanism with the current theory before
   288     producing any clauses!*)
   289 fun init thy = (const_typargs := Sign.const_typargs thy);
   290     
   291 
   292 (*Flatten a type to a fol_type while accumulating sort constraints on the TFrees and
   293   TVars it contains.*)    
   294 fun type_of (Type (a, Ts)) = 
   295       let val (folTyps, ts) = types_of Ts 
   296 	  val t = make_fixed_type_const a
   297       in (Comp(t,folTyps), ts) end
   298   | type_of (TFree (a,s)) = (AtomF(make_fixed_type_var a), [(FOLTFree a, s)]) 
   299   | type_of (TVar (v, s)) = (AtomV(make_schematic_type_var v), [(FOLTVar v, s)])
   300 and types_of Ts =
   301       let val (folTyps,ts) = ListPair.unzip (map type_of Ts)
   302       in (folTyps, union_all ts) end;
   303 
   304 
   305 fun const_types_of (c,T) = types_of (!const_typargs (c,T));
   306 
   307 (* Any variables created via the METAHYPS tactical should be treated as
   308    universal vars, although it is represented as "Free(...)" by Isabelle *)
   309 val isMeta = String.isPrefix "METAHYP1_"
   310 
   311 fun pred_name_type (Const(c,T)) = (make_fixed_const c, const_types_of (c,T))
   312   | pred_name_type (Free(x,T))  = 
   313       if isMeta x then raise CLAUSE("Predicate Not First Order 1", Free(x,T)) 
   314       else (make_fixed_var x, ([],[]))
   315   | pred_name_type (v as Var _) = raise CLAUSE("Predicate Not First Order 2", v)
   316   | pred_name_type t        = raise CLAUSE("Predicate input unexpected", t);
   317 
   318 
   319 (* For typed equality *)
   320 (* here "arg_typ" is the type of "="'s argument's type, not the type of the equality *)
   321 (* Find type of equality arg *)
   322 fun eq_arg_type (Type("fun",[T,_])) = 
   323     let val (folT,_) = type_of T;
   324     in  folT  end;
   325 
   326 fun fun_name_type (Const(c,T)) args = (make_fixed_const c, const_types_of (c,T))
   327   | fun_name_type (Free(x,T)) args  = 
   328        if isMeta x then raise CLAUSE("Function Not First Order", Free(x,T))
   329        else (make_fixed_var x, ([],[]))
   330   | fun_name_type f args = raise CLAUSE("Function Not First Order 1", f);
   331 
   332 (*Convert a term to a fol_term while accumulating sort constraints on the TFrees and
   333   TVars it contains.*)    
   334 fun term_of (Var(ind_nm,T)) = 
   335       let val (folType,ts) = type_of T
   336       in (UVar(make_schematic_var ind_nm, folType), ts) end
   337   | term_of (Free(x,T)) = 
   338       let val (folType, ts) = type_of T
   339       in
   340 	  if isMeta x then (UVar(make_schematic_var(x,0),folType), ts)
   341 	  else (Fun(make_fixed_var x, [folType], []), ts)
   342       end
   343   | term_of app = 
   344       let val (f,args) = strip_comb app
   345 	  val (funName,(contys,ts1)) = fun_name_type f args
   346 	  val (args',ts2) = terms_of args
   347       in
   348 	  (Fun(funName,contys,args'), union_all (ts1::ts2))
   349       end
   350 and terms_of ts = ListPair.unzip (map term_of ts)
   351 
   352 (*Create a predicate value, again accumulating sort constraints.*)    
   353 fun pred_of (Const("op =", typ), args) =
   354       let val arg_typ = eq_arg_type typ 
   355 	  val (args',ts) = terms_of args
   356 	  val equal_name = make_fixed_const "op ="
   357       in
   358 	  (Predicate(equal_name,[arg_typ],args'),
   359 	   union_all ts)
   360       end
   361   | pred_of (pred,args) = 
   362       let val (pname, (predType,ts1)) = pred_name_type pred
   363 	  val (args',ts2) = terms_of args
   364       in
   365 	  (Predicate(pname,predType,args'), union_all (ts1::ts2))
   366       end;
   367 
   368 (*Treatment of literals, possibly negated or tagged*)
   369 fun predicate_of ((Const("Not",_) $ P), polarity, tag) =
   370       predicate_of (P, not polarity, tag)
   371   | predicate_of ((Const("HOL.tag",_) $ P), polarity, tag) =
   372       predicate_of (P, polarity, true)
   373   | predicate_of (term,polarity,tag) =
   374         (pred_of (strip_comb term), polarity, tag);
   375 
   376 fun literals_of_term1 args (Const("Trueprop",_) $ P) = literals_of_term1 args P
   377   | literals_of_term1 args (Const("op |",_) $ P $ Q) = 
   378       literals_of_term1 (literals_of_term1 args P) Q
   379   | literals_of_term1 (lits, ts) P =
   380       let val ((pred, ts'), polarity, tag) = predicate_of (P,true,false)
   381 	  val lits' = Literal(polarity,pred,tag) :: lits
   382       in
   383 	  (lits', ts union ts')
   384       end;
   385 
   386 val literals_of_term = literals_of_term1 ([],[]);
   387 
   388 
   389 fun list_ord _ ([],[]) = EQUAL
   390   | list_ord _ ([],_) = LESS
   391   | list_ord _ (_,[]) = GREATER
   392   | list_ord ord (x::xs, y::ys) = 
   393       (case ord(x,y) of EQUAL => list_ord ord (xs,ys)
   394 	 	      | xy_ord => xy_ord);
   395 		     
   396 fun type_ord (AtomV(_),AtomV(_)) = EQUAL
   397   | type_ord (AtomV(_),_) = LESS
   398   | type_ord (AtomF(_),AtomV(_)) = GREATER
   399   | type_ord (AtomF(f1),AtomF(f2)) = string_ord (f1,f2)
   400   | type_ord (AtomF(_),_) = LESS
   401   | type_ord (Comp(_,_),AtomV(_)) = GREATER
   402   | type_ord (Comp(_,_),AtomF(_)) = GREATER
   403   | type_ord (Comp(con1,args1),Comp(con2,args2)) = 
   404       (case string_ord(con1,con2) of EQUAL => types_ord (args1,args2)
   405 		      | con_ord => con_ord)
   406 and
   407     types_ord ([],[]) = EQUAL
   408   | types_ord (tps1,tps2) = list_ord type_ord (tps1,tps2);
   409 
   410 
   411 fun term_ord (UVar _, UVar _) = EQUAL
   412   | term_ord (UVar _, _) = LESS
   413   | term_ord (Fun _, UVar _) = GREATER
   414   | term_ord (Fun(f1,tps1,tms1),Fun(f2,tps2,tms2)) = 
   415      (case string_ord (f1,f2) of
   416          EQUAL => 
   417 	   (case terms_ord (tms1,tms2) of EQUAL => types_ord (tps1,tps2)
   418 	      | tms_ord => tms_ord)
   419        | fn_ord => fn_ord)
   420 
   421 and
   422       terms_ord ([],[]) = EQUAL
   423     | terms_ord (tms1,tms2) = list_ord term_ord (tms1,tms2);
   424 
   425 
   426 
   427 fun predicate_ord (Predicate(pname1,ftyps1,ftms1),Predicate(pname2,ftyps2,ftms2)) = 
   428   case string_ord (pname1,pname2) of
   429        EQUAL => (case terms_ord(ftms1,ftms2) of EQUAL => types_ord(ftyps1,ftyps2)
   430 				              | ftms_ord => ftms_ord)
   431      | pname_ord => pname_ord
   432 			   
   433 
   434 fun literal_ord (Literal(false,_,_),Literal(true,_,_)) = LESS
   435   | literal_ord (Literal(true,_,_),Literal(false,_,_)) = GREATER
   436   | literal_ord (Literal(_,pred1,_),Literal(_,pred2,_)) = predicate_ord(pred1,pred2);
   437 
   438 fun sort_lits lits = sort literal_ord lits;
   439 
   440 
   441 (********** clause equivalence ******************)
   442 
   443 fun check_var_pairs (x,y) [] = 0 
   444   | check_var_pairs (x,y) ((u,v)::w) =
   445     if (x,y) = (u,v) then 1 
   446     else
   447 	if x=u orelse y=v then 2 (*conflict*)
   448 	else check_var_pairs (x,y) w;
   449 
   450 fun type_eq (AtomV(v1),AtomV(v2)) (vars,tvars) =
   451     (case check_var_pairs (v1,v2) tvars of 0 => (true,(vars,(v1,v2)::tvars))
   452 					 | 1 => (true,(vars,tvars))
   453 					 | 2 => (false,(vars,tvars)))
   454   | type_eq (AtomV(_),_) vtvars = (false,vtvars)
   455   | type_eq (AtomF(f1),AtomF(f2)) vtvars = (f1=f2,vtvars)
   456   | type_eq (AtomF(_),_) vtvars = (false,vtvars)
   457   | type_eq (Comp(con1,args1),Comp(con2,args2)) vtvars =
   458       let val (eq1,vtvars1) = 
   459 	      if con1 = con2 then types_eq (args1,args2) vtvars
   460 	      else (false,vtvars)
   461       in
   462 	  (eq1,vtvars1)
   463       end
   464   | type_eq (Comp(_,_),_) vtvars = (false,vtvars)
   465 
   466 and types_eq ([],[]) vtvars = (true,vtvars)
   467   | types_eq (tp1::tps1,tp2::tps2) vtvars =
   468       let val (eq1,vtvars1) = type_eq (tp1,tp2) vtvars
   469 	  val (eq2,vtvars2) = if eq1 then types_eq (tps1,tps2) vtvars1
   470 			      else (eq1,vtvars1)
   471       in
   472 	  (eq2,vtvars2)
   473       end;
   474 
   475 
   476 fun term_eq (UVar(v1,tp1),UVar(v2,tp2)) (vars,tvars) =
   477     (case check_var_pairs (v1,v2) vars of 0 => type_eq (tp1,tp2) (((v1,v2)::vars),tvars)
   478 					| 1 => type_eq (tp1,tp2) (vars,tvars)
   479 					| 2 => (false,(vars,tvars)))
   480   | term_eq (UVar _,_) vtvars = (false,vtvars)
   481   | term_eq (Fun(f1,tps1,tms1),Fun(f2,tps2,tms2)) vtvars =
   482       let val (eq1,vtvars1) = 
   483 	      if f1 = f2 then terms_eq (tms1,tms2) vtvars
   484 	      else (false,vtvars)
   485 	  val (eq2,vtvars2) =
   486 	      if eq1 then types_eq (tps1,tps2) vtvars1
   487 	      else (eq1,vtvars1)
   488       in
   489 	  (eq2,vtvars2)
   490       end
   491   | term_eq (Fun(_,_,_),_) vtvars = (false,vtvars)
   492 
   493 and terms_eq ([],[]) vtvars = (true,vtvars)
   494   | terms_eq (tm1::tms1,tm2::tms2) vtvars =
   495       let val (eq1,vtvars1) = term_eq (tm1,tm2) vtvars
   496 	  val (eq2,vtvars2) = if eq1 then terms_eq (tms1,tms2) vtvars1
   497 				     else (eq1,vtvars1)
   498       in
   499 	  (eq2,vtvars2)
   500       end;
   501 					     
   502 
   503 fun pred_eq (Predicate(pname1,tps1,tms1),Predicate(pname2,tps2,tms2)) vtvars =
   504     let val (eq1,vtvars1) = 
   505 	    if pname1 = pname2 then terms_eq (tms1,tms2) vtvars
   506 	    else (false,vtvars)
   507 	val (eq2,vtvars2) = 
   508 	    if eq1 then types_eq (tps1,tps2) vtvars1
   509 	    else (eq1,vtvars1)
   510     in
   511 	(eq2,vtvars2)
   512     end;
   513 					      
   514 
   515 fun lit_eq (Literal(pol1,pred1,_),Literal(pol2,pred2,_)) vtvars =
   516     if (pol1 = pol2) then pred_eq (pred1,pred2) vtvars
   517     else (false,vtvars);
   518 
   519 fun lits_eq ([],[]) vtvars = (true,vtvars)
   520   | lits_eq (l1::ls1,l2::ls2) vtvars = 
   521       let val (eq1,vtvars1) = lit_eq (l1,l2) vtvars
   522       in
   523 	  if eq1 then lits_eq (ls1,ls2) vtvars1
   524 	  else (false,vtvars1)
   525       end
   526   | lits_eq _ vtvars = (false,vtvars);
   527 
   528 (*Equality of two clauses up to variable renaming*)
   529 fun clause_eq (Clause{literals=lits1,...}, Clause{literals=lits2,...}) =
   530   #1 (lits_eq (lits1,lits2) ([],[]));
   531 
   532 
   533 (*** Hash function for clauses ***)
   534 
   535 val xor_words = List.foldl Word.xorb 0w0;
   536 
   537 fun hashw_term (UVar _, w) = w
   538   | hashw_term (Fun(f,tps,args), w) = 
   539       List.foldl hashw_term (Polyhash.hashw_string (f,w)) args;
   540   
   541 fun hashw_pred (Predicate(pn,_,args), w) = 
   542     List.foldl hashw_term (Polyhash.hashw_string (pn,w)) args;
   543     
   544 fun hash1_literal (Literal(true,pred,_)) = hashw_pred (pred, 0w0)
   545   | hash1_literal (Literal(false,pred,_)) = Word.notb (hashw_pred (pred, 0w0));
   546   
   547 fun hash_clause (Clause{literals,...}) =
   548   Word.toIntX (xor_words (map hash1_literal literals));
   549 
   550 
   551 (*Make literals for sorted type variables.  FIXME: can it use map?*) 
   552 fun sorts_on_typs (_, [])   = ([]) 
   553   | sorts_on_typs (v, "HOL.type" :: s) =
   554       sorts_on_typs (v,s)                (*IGNORE sort "type"*)
   555   | sorts_on_typs ((FOLTVar indx), s::ss) =
   556       LTVar(make_type_class s, make_schematic_type_var indx) :: 
   557       sorts_on_typs ((FOLTVar indx), ss)
   558   | sorts_on_typs ((FOLTFree x), s::ss) =
   559       LTFree(make_type_class s, make_fixed_type_var x) :: 
   560       sorts_on_typs ((FOLTFree x), ss);
   561 
   562 
   563 fun pred_of_sort (LTVar (s,ty)) = (s,1)
   564 |   pred_of_sort (LTFree (s,ty)) = (s,1)
   565 
   566 (*Given a list of sorted type variables, return two separate lists.
   567   The first is for TVars, the second for TFrees.*)
   568 fun add_typs_aux [] = ([],[])
   569   | add_typs_aux ((FOLTVar indx,s)::tss) = 
   570       let val vs = sorts_on_typs (FOLTVar indx, s)
   571 	  val (vss,fss) = add_typs_aux tss
   572       in
   573 	  (vs union vss, fss)
   574       end
   575   | add_typs_aux ((FOLTFree x,s)::tss) =
   576       let val fs = sorts_on_typs (FOLTFree x, s)
   577 	  val (vss,fss) = add_typs_aux tss
   578       in
   579 	  (vss, fs union fss)
   580       end;
   581 
   582 
   583 (** make axiom and conjecture clauses. **)
   584 
   585 fun get_tvar_strs [] = []
   586   | get_tvar_strs ((FOLTVar indx,s)::tss) = 
   587       (make_schematic_type_var indx) ins (get_tvar_strs tss)
   588   | get_tvar_strs((FOLTFree x,s)::tss) = get_tvar_strs tss
   589 
   590 (* check if a clause is first-order before making a conjecture clause*)
   591 fun make_conjecture_clause n thm =
   592     let val t = prop_of thm
   593 	val _ = check_is_fol_term t
   594 	    handle TERM("check_is_fol_term",_) => raise CLAUSE("Goal is not FOL",t)
   595 	val (lits,types_sorts) = literals_of_term t
   596     in
   597 	make_clause(n, "conjecture", thm, Conjecture, lits, types_sorts)
   598     end;
   599     
   600 fun make_conjecture_clauses_aux _ [] = []
   601   | make_conjecture_clauses_aux n (t::ts) =
   602       make_conjecture_clause n t :: make_conjecture_clauses_aux (n+1) ts
   603 
   604 val make_conjecture_clauses = make_conjecture_clauses_aux 0
   605 
   606 (** Too general means, positive equality literal with a variable X as one operand,
   607   when X does not occur properly in the other operand. This rules out clearly
   608   inconsistent clauses such as V=a|V=b, though it by no means guarantees soundness. **)
   609 
   610 fun occurs a (UVar(b,_)) = a=b
   611   | occurs a (Fun (_,_,ts)) = exists (occurs a) ts
   612 
   613 (*Is the first operand a variable that does not properly occur in the second operand?*)
   614 fun too_general_terms (UVar _, UVar _) = false
   615   | too_general_terms (Fun _, _) = false
   616   | too_general_terms (UVar (a,_), t) = not (occurs a t);
   617 
   618 fun too_general_lit (Literal (true,Predicate("equal",_,[x,y]),_)) =
   619       too_general_terms (x,y) orelse too_general_terms(y,x)
   620   | too_general_lit _ = false;
   621 
   622 (*before converting an axiom clause to "clause" format, check if it is FOL*)
   623 fun make_axiom_clause thm (ax_name,cls_id) =
   624     let val term = prop_of thm
   625 	val (lits,types_sorts) = literals_of_term term
   626     in 
   627 	if not (Meson.is_fol_term term) then
   628 	   (Output.debug ("Omitting " ^ ax_name ^ ": Axiom is not FOL"); 
   629 	    NONE)
   630 	else if forall too_general_lit lits then
   631 	   (Output.debug ("Omitting " ^ ax_name ^ ": equalities are too general"); 
   632 	    NONE)
   633 	else SOME (make_clause(cls_id, ax_name, thm, Axiom, sort_lits lits, types_sorts))
   634     end
   635     handle CLAUSE _ => NONE;
   636 
   637 
   638 fun make_axiom_clauses [] = []
   639   | make_axiom_clauses ((thm,(name,id))::thms) =
   640     case make_axiom_clause thm (name,id) of SOME cls => if isTaut cls then make_axiom_clauses thms else cls :: make_axiom_clauses thms
   641 						    | NONE => make_axiom_clauses thms;
   642 
   643 (**** Isabelle arities ****)
   644 
   645 exception ARCLAUSE of string;
   646  
   647 type class = string; 
   648 type tcons = string; 
   649 
   650 datatype arLit = TConsLit of bool * (class * tcons * string list)
   651                | TVarLit of bool * (class * string);
   652  
   653 datatype arityClause =  
   654 	 ArityClause of {clause_id: clause_id,
   655 	  	         axiom_name: axiom_name,
   656 			 kind: kind,
   657 			 conclLit: arLit,
   658 			 premLits: arLit list};
   659 
   660 
   661 fun gen_TVars 0 = []
   662   | gen_TVars n = ("T_" ^ Int.toString n) :: gen_TVars (n-1);
   663 
   664 fun pack_sort(_,[])  = []
   665   | pack_sort(tvar, "HOL.type"::srt) = pack_sort(tvar, srt)   (*IGNORE sort "type"*)
   666   | pack_sort(tvar, cls::srt) =  (make_type_class cls, tvar) :: pack_sort(tvar, srt);
   667     
   668 fun make_TVarLit (b, (cls,str)) = TVarLit(b, (cls,str));
   669 fun make_TConsLit (b, (cls,tcons,tvars)) = 
   670       TConsLit(b, (make_type_class cls, make_fixed_type_const tcons, tvars));
   671 
   672 (*Arity of type constructor tcon :: (arg1,...,argN)res*)
   673 fun make_axiom_arity_clause (tcons, n, (res,args)) =
   674    let val nargs = length args
   675        val tvars = gen_TVars nargs
   676        val tvars_srts = ListPair.zip (tvars,args)
   677        val tvars_srts' = union_all(map pack_sort tvars_srts)
   678        val false_tvars_srts' = map (pair false) tvars_srts'
   679    in
   680       ArityClause {clause_id = n, kind = Axiom, 
   681                    axiom_name = lookup_type_const tcons,
   682                    conclLit = make_TConsLit(true, (res,tcons,tvars)), 
   683                    premLits = map make_TVarLit false_tvars_srts'}
   684    end;
   685 
   686 
   687 (**** Isabelle class relations ****)
   688 
   689 datatype classrelClause = 
   690 	 ClassrelClause of {axiom_name: axiom_name,
   691 			    subclass: class,
   692 			    superclass: class};
   693 
   694 fun make_axiom_classrelClause n subclass superclass =
   695   ClassrelClause {axiom_name = clrelclause_prefix ^ ascii_of subclass ^ 
   696                                 "_" ^ Int.toString n,
   697                   subclass = make_type_class subclass, 
   698                   superclass = make_type_class superclass};
   699 
   700 fun classrelClauses_of_aux n sub [] = []
   701   | classrelClauses_of_aux n sub ("HOL.type"::sups) = (*Should be ignored*)
   702       classrelClauses_of_aux n sub sups
   703   | classrelClauses_of_aux n sub (sup::sups) =
   704       make_axiom_classrelClause n sub sup :: classrelClauses_of_aux (n+1) sub sups;
   705 
   706 fun classrelClauses_of (sub,sups) = classrelClauses_of_aux 0 sub sups;
   707 
   708 val classrel_clauses_thy =
   709   maps classrelClauses_of o Graph.dest o #classes o Sorts.rep_algebra o Sign.classes_of;
   710 
   711 
   712 (** Isabelle arities **)
   713 
   714 fun arity_clause _ (tcons, []) = []
   715   | arity_clause n (tcons, ("HOL.type",_)::ars) =  (*ignore*)
   716       arity_clause n (tcons,ars)
   717   | arity_clause n (tcons, ar::ars) =
   718       make_axiom_arity_clause (tcons,n,ar) :: 
   719       arity_clause (n+1) (tcons,ars);
   720 
   721 fun multi_arity_clause [] = []
   722   | multi_arity_clause ((tcons,ars) :: tc_arlists) =
   723       (*Reversal ensures that older entries always get the same axiom name*)
   724       arity_clause 0 (tcons, rev ars)  @  
   725       multi_arity_clause tc_arlists 
   726 
   727 fun arity_clause_thy thy =
   728   let val arities = thy |> Sign.classes_of
   729     |> Sorts.rep_algebra |> #arities |> Symtab.dest
   730     |> map (apsnd (map (fn (c, (_, Ss)) => (c, Ss))));
   731   in multi_arity_clause (rev arities) end;
   732 
   733 
   734 (**** Find occurrences of predicates in clauses ****)
   735 
   736 (*FIXME: multiple-arity checking doesn't work, as update_new is the wrong 
   737   function (it flags repeated declarations of a function, even with the same arity)*)
   738 
   739 fun update_many (tab, keypairs) = foldl (uncurry Symtab.update) tab keypairs;
   740 
   741 fun add_predicate_preds (Predicate(pname,tys,tms), preds) = 
   742   if pname = "equal" then preds (*equality is built-in and requires no declaration*)
   743   else Symtab.update (pname, length tys + length tms) preds
   744 
   745 fun add_literal_preds (Literal(_,pred,_), preds) = add_predicate_preds (pred,preds)
   746 
   747 fun add_type_sort_preds ((FOLTVar indx,s), preds) = 
   748       update_many (preds, map pred_of_sort (sorts_on_typs (FOLTVar indx, s)))
   749   | add_type_sort_preds ((FOLTFree x,s), preds) =
   750       update_many (preds, map pred_of_sort (sorts_on_typs (FOLTFree x, s)));
   751 
   752 fun add_clause_preds (Clause {literals, types_sorts, ...}, preds) =
   753   foldl add_literal_preds (foldl add_type_sort_preds preds types_sorts) literals
   754   handle Symtab.DUP a => raise ERROR ("predicate " ^ a ^ " has multiple arities")
   755 
   756 fun add_classrelClause_preds (ClassrelClause {subclass,superclass,...}, preds) =
   757   Symtab.update (subclass,1) (Symtab.update (superclass,1) preds);
   758 
   759 fun add_arityClause_preds (ArityClause {conclLit,...}, preds) =
   760   let val TConsLit(_, (tclass, _, _)) = conclLit
   761   in  Symtab.update (tclass,1) preds  end;
   762 
   763 fun preds_of_clauses clauses clsrel_clauses arity_clauses = 
   764   Symtab.dest
   765     (foldl add_classrelClause_preds 
   766       (foldl add_arityClause_preds
   767         (foldl add_clause_preds Symtab.empty clauses)
   768         arity_clauses)
   769       clsrel_clauses)
   770 
   771 (*** Find occurrences of functions in clauses ***)
   772 
   773 fun add_foltype_funcs (AtomV _, funcs) = funcs
   774   | add_foltype_funcs (AtomF a, funcs) = Symtab.update (a,0) funcs
   775   | add_foltype_funcs (Comp(a,tys), funcs) = 
   776       foldl add_foltype_funcs (Symtab.update (a, length tys) funcs) tys;
   777 
   778 fun add_folterm_funcs (UVar _, funcs) = funcs
   779   | add_folterm_funcs (Fun(a,tys,[]), funcs) = Symtab.update (a,0) funcs
   780       (*A constant is a special case: it has no type argument even if overloaded*)
   781   | add_folterm_funcs (Fun(a,tys,tms), funcs) = 
   782       foldl add_foltype_funcs 
   783 	    (foldl add_folterm_funcs (Symtab.update (a, length tys + length tms) funcs) 
   784 	           tms) 
   785 	    tys
   786 
   787 fun add_predicate_funcs (Predicate(_,tys,tms), funcs) = 
   788     foldl add_foltype_funcs (foldl add_folterm_funcs funcs tms) tys;
   789 
   790 fun add_literal_funcs (Literal(_,pred,_), funcs) = add_predicate_funcs (pred,funcs)
   791 
   792 fun add_arityClause_funcs (ArityClause {conclLit,...}, funcs) =
   793   let val TConsLit(_, (_, tcons, tvars)) = conclLit
   794   in  Symtab.update (tcons, length tvars) funcs  end;
   795 
   796 fun add_clause_funcs (Clause {literals, ...}, funcs) =
   797   foldl add_literal_funcs funcs literals
   798   handle Symtab.DUP a => raise ERROR ("function " ^ a ^ " has multiple arities")
   799 
   800 fun funcs_of_clauses clauses arity_clauses = 
   801   Symtab.dest (foldl add_arityClause_funcs 
   802                      (foldl add_clause_funcs Symtab.empty clauses)
   803                      arity_clauses)
   804 
   805 
   806 (**** String-oriented operations ****)
   807 
   808 fun wrap_eq_type typ t = eq_typ_wrapper ^"(" ^ t ^ "," ^ typ ^ ")";
   809 
   810 (*Only need to wrap equality's arguments with "typeinfo" if the output clauses are typed 
   811  and if we specifically ask for types to be included.   *)
   812 fun string_of_equality (typ,terms) =
   813       let val [tstr1,tstr2] = map string_of_term terms
   814 	  val typ' = string_of_fol_type typ
   815       in
   816 	  if !keep_types andalso !special_equal 
   817 	  then "equal(" ^ (wrap_eq_type typ' tstr1) ^ "," ^ 
   818 		 	  (wrap_eq_type typ' tstr2) ^ ")"
   819 	  else "equal(" ^ tstr1 ^ "," ^ tstr2 ^ ")"
   820       end
   821 and string_of_term (UVar(x,_)) = x
   822   | string_of_term (Fun("equal",[typ],terms)) = string_of_equality(typ,terms)
   823   | string_of_term (Fun (name,typs,[])) = name (*Overloaded consts like 0 don't get types!*)
   824   | string_of_term (Fun (name,typs,terms)) = 
   825       let val terms_as_strings = map string_of_term terms
   826 	  val typs' = if !keep_types then map string_of_fol_type typs else []
   827       in  name ^ (paren_pack (terms_as_strings @ typs'))  end;
   828 
   829 (* before output the string of the predicate, check if the predicate corresponds to an equality or not. *)
   830 fun string_of_predicate (Predicate("equal",[typ],terms)) = string_of_equality(typ,terms)
   831   | string_of_predicate (Predicate(name,typs,terms)) = 
   832       let val terms_as_strings = map string_of_term terms
   833 	  val typs' = if !keep_types then map string_of_fol_type typs else []
   834       in  name ^ (paren_pack (terms_as_strings @ typs'))  end;
   835 
   836 fun string_of_clausename (cls_id,ax_name) = 
   837     clause_prefix ^ ascii_of ax_name ^ "_" ^ Int.toString cls_id;
   838 
   839 fun string_of_type_clsname (cls_id,ax_name,idx) = 
   840     string_of_clausename (cls_id,ax_name) ^ "_tcs" ^ (Int.toString idx);
   841 
   842 (*Write a list of strings to a file*)
   843 fun writeln_strs os = List.app (fn s => TextIO.output (os,s));
   844 
   845     
   846 (**** Producing DFG files ****)
   847 
   848 (*Attach sign in DFG syntax: false means negate.*)
   849 fun dfg_sign true s = s
   850   | dfg_sign false s = "not(" ^ s ^ ")"  
   851 
   852 fun dfg_literal (Literal(pol,pred,tag)) = dfg_sign pol (string_of_predicate pred)
   853 
   854 fun dfg_of_typeLit (LTVar (s,ty)) = "not(" ^ s ^ "(" ^ ty ^ "))"
   855   | dfg_of_typeLit (LTFree (s,ty)) = s ^ "(" ^ ty ^ ")";
   856  
   857 (*Enclose the clause body by quantifiers, if necessary*)
   858 fun dfg_forall [] body = body  
   859   | dfg_forall vars body = "forall([" ^ commas vars ^ "],\n" ^ body ^ ")"
   860 
   861 fun gen_dfg_cls (cls_id, ax_name, knd, lits, vars) = 
   862     "clause( %(" ^ knd ^ ")\n" ^ 
   863     dfg_forall vars ("or(" ^ lits ^ ")") ^ ",\n" ^ 
   864     string_of_clausename (cls_id,ax_name) ^  ").\n\n";
   865 
   866 fun dfg_clause_aux (Clause{literals, types_sorts, ...}) = 
   867   let val lits = map dfg_literal literals
   868       val (tvar_lits,tfree_lits) = add_typs_aux types_sorts
   869       val tvar_lits_strs = 
   870 	  if !keep_types then map dfg_of_typeLit tvar_lits else []
   871       val tfree_lits =
   872           if !keep_types then map dfg_of_typeLit tfree_lits else []
   873   in
   874       (tvar_lits_strs @ lits, tfree_lits)
   875   end; 
   876 
   877 fun dfg_folterms (Literal(pol,pred,tag)) = 
   878   let val Predicate (_, _, folterms) = pred
   879   in  folterms  end
   880 
   881 fun get_uvars (UVar(a,typ)) = [a] 
   882   | get_uvars (Fun (_,typ,tlist)) = union_all(map get_uvars tlist)
   883 
   884 fun dfg_vars (Clause {literals,...}) =
   885   union_all (map get_uvars (List.concat (map dfg_folterms literals)))
   886 
   887 fun clause2dfg (cls as Clause{axiom_name,clause_id,kind,types_sorts,...}) =
   888     let val (lits,tfree_lits) = dfg_clause_aux cls 
   889             (*"lits" includes the typing assumptions (TVars)*)
   890         val vars = dfg_vars cls
   891         val tvars = get_tvar_strs types_sorts
   892 	val knd = name_of_kind kind
   893 	val lits_str = commas lits
   894 	val cls_str = gen_dfg_cls(clause_id, axiom_name, knd, lits_str, tvars@vars) 
   895     in (cls_str, tfree_lits) end;
   896 
   897 fun string_of_arity (name, num) =  "(" ^ name ^ "," ^ Int.toString num ^ ")"
   898 
   899 fun string_of_preds [] = ""
   900   | string_of_preds preds = "predicates[" ^ commas(map string_of_arity preds) ^ "].\n";
   901 
   902 fun string_of_funcs [] = ""
   903   | string_of_funcs funcs = "functions[" ^ commas(map string_of_arity funcs) ^ "].\n" ;
   904 
   905 fun string_of_symbols predstr funcstr = 
   906   "list_of_symbols.\n" ^ predstr  ^ funcstr  ^ "end_of_list.\n\n";
   907 
   908 fun string_of_start name = "begin_problem(" ^ name ^ ").\n\n";
   909 
   910 fun string_of_descrip name = 
   911   "list_of_descriptions.\nname({*" ^ name ^ 
   912   "*}).\nauthor({*Isabelle*}).\nstatus(unknown).\ndescription({*auto-generated*}).\nend_of_list.\n\n"
   913 
   914 fun dfg_tfree_clause tfree_lit =
   915   "clause( %(conjecture)\n" ^ "or( " ^ tfree_lit ^ "),\n" ^ "tfree_tcs" ^ ").\n\n"
   916 
   917 fun string_of_arClauseID (ArityClause {clause_id,axiom_name,...}) =
   918     arclause_prefix ^ ascii_of axiom_name ^ "_" ^ Int.toString clause_id;
   919 
   920 fun dfg_of_arLit (TConsLit(pol,(c,t,args))) =
   921       dfg_sign pol (c ^ "(" ^ t ^ paren_pack args ^ ")")
   922   | dfg_of_arLit (TVarLit(pol,(c,str))) =
   923       dfg_sign pol (c ^ "(" ^ str ^ ")")
   924     
   925 fun dfg_classrelLits sub sup = 
   926     let val tvar = "(T)"
   927     in 
   928 	"not(" ^ sub ^ tvar ^ "), " ^ sup ^ tvar
   929     end;
   930 
   931 fun dfg_classrelClause (ClassrelClause {axiom_name,subclass,superclass,...}) =
   932   "clause(forall([T],\nor( " ^ dfg_classrelLits subclass superclass ^ ")),\n" ^
   933   axiom_name ^ ").\n\n";
   934       
   935 fun dfg_arity_clause (arcls as ArityClause{kind,conclLit,premLits,...}) = 
   936   let val arcls_id = string_of_arClauseID arcls
   937       val knd = name_of_kind kind
   938       val TConsLit(_, (_,_,tvars)) = conclLit
   939       val lits = map dfg_of_arLit (conclLit :: premLits)
   940   in
   941       "clause( %(" ^ knd ^ ")\n" ^ 
   942       dfg_forall tvars ("or( " ^ commas lits ^ ")") ^ ",\n" ^
   943       arcls_id ^ ").\n\n"
   944   end;
   945 
   946 (* write out a subgoal in DFG format to the file "xxxx_N"*)
   947 fun dfg_write_file thms filename (axclauses,classrel_clauses,arity_clauses) = 
   948   let 
   949     val _ = Output.debug ("Preparing to write the DFG file " ^ filename)
   950     val conjectures = make_conjecture_clauses thms
   951     val axclauses' = make_axiom_clauses axclauses
   952     val (dfg_clss, tfree_litss) = ListPair.unzip (map clause2dfg conjectures)
   953     val clss = conjectures @ axclauses'
   954     val funcs = funcs_of_clauses clss arity_clauses
   955     and preds = preds_of_clauses clss classrel_clauses arity_clauses
   956     and probname = Path.pack (Path.base (Path.unpack filename))
   957     val (axstrs, _) = ListPair.unzip (map clause2dfg axclauses')
   958     val tfree_clss = map dfg_tfree_clause (union_all tfree_litss) 
   959     val out = TextIO.openOut filename
   960   in
   961     TextIO.output (out, string_of_start probname); 
   962     TextIO.output (out, string_of_descrip probname); 
   963     TextIO.output (out, string_of_symbols (string_of_funcs funcs) (string_of_preds preds)); 
   964     TextIO.output (out, "list_of_clauses(axioms,cnf).\n");
   965     writeln_strs out axstrs;
   966     List.app (curry TextIO.output out o dfg_classrelClause) classrel_clauses;
   967     List.app (curry TextIO.output out o dfg_arity_clause) arity_clauses;
   968     TextIO.output (out, "end_of_list.\n\nlist_of_clauses(conjectures,cnf).\n");
   969     writeln_strs out tfree_clss;
   970     writeln_strs out dfg_clss;
   971     TextIO.output (out, "end_of_list.\n\nend_problem.\n");
   972     TextIO.closeOut out
   973   end;
   974 
   975 
   976 (**** Produce TPTP files ****)
   977 
   978 (*Attach sign in TPTP syntax: false means negate.*)
   979 fun tptp_sign true s = "++" ^ s
   980   | tptp_sign false s = "--" ^ s
   981 
   982 fun tptp_literal (Literal(pol,pred,tag)) =  (*FIXME REMOVE TAGGING*)
   983     let val pred_string = string_of_predicate pred
   984 	val tagged_pol = 
   985 	      if (tag andalso !tagged) then (if pol then "+++" else "---")
   986 	      else (if pol then "++" else "--")
   987      in
   988 	tagged_pol ^ pred_string
   989     end;
   990 
   991 fun tptp_of_typeLit (LTVar (s,ty)) = "--" ^ s ^ "(" ^ ty ^ ")"
   992   | tptp_of_typeLit (LTFree (s,ty)) = "++" ^ s ^ "(" ^ ty ^ ")";
   993  
   994 fun gen_tptp_cls (cls_id,ax_name,knd,lits) = 
   995     "input_clause(" ^ string_of_clausename (cls_id,ax_name) ^ "," ^ 
   996     knd ^ "," ^ lits ^ ").\n";
   997 
   998 fun gen_tptp_type_cls (cls_id,ax_name,knd,tfree_lit,idx) = 
   999     "input_clause(" ^ string_of_type_clsname (cls_id,ax_name,idx) ^ "," ^ 
  1000     knd ^ ",[" ^ tfree_lit ^ "]).\n";
  1001 
  1002 fun tptp_type_lits (Clause {literals, types_sorts, ...}) = 
  1003     let val lits = map tptp_literal literals
  1004 	val (tvar_lits,tfree_lits) = add_typs_aux types_sorts
  1005         val tvar_lits_strs =
  1006             if !keep_types then map tptp_of_typeLit tvar_lits else []
  1007 	val tfree_lits =
  1008 	    if !keep_types then map tptp_of_typeLit tfree_lits else []
  1009     in
  1010 	(tvar_lits_strs @ lits, tfree_lits)
  1011     end; 
  1012 
  1013 fun clause2tptp (cls as Clause {clause_id, axiom_name, kind, ...}) =
  1014     let val (lits,tfree_lits) = tptp_type_lits cls 
  1015             (*"lits" includes the typing assumptions (TVars)*)
  1016 	val knd = name_of_kind kind
  1017 	val cls_str = gen_tptp_cls(clause_id, axiom_name, knd, bracket_pack lits) 
  1018     in
  1019 	(cls_str,tfree_lits) 
  1020     end;
  1021 
  1022 fun tptp_tfree_clause tfree_lit =
  1023     "input_clause(" ^ "tfree_tcs," ^ "conjecture" ^ ",[" ^ tfree_lit ^ "]).\n";
  1024 
  1025 fun tptp_of_arLit (TConsLit(b,(c,t,args))) =
  1026       tptp_sign b (c ^ "(" ^ t ^ paren_pack args ^ ")")
  1027   | tptp_of_arLit (TVarLit(b,(c,str))) =
  1028       tptp_sign b (c ^ "(" ^ str ^ ")")
  1029     
  1030 fun tptp_arity_clause (arcls as ArityClause{kind,conclLit,premLits,...}) = 
  1031   let val arcls_id = string_of_arClauseID arcls
  1032       val knd = name_of_kind kind
  1033       val lits = map tptp_of_arLit (conclLit :: premLits)
  1034   in
  1035     "input_clause(" ^ arcls_id ^ "," ^ knd ^ "," ^ bracket_pack lits ^ ").\n"
  1036   end;
  1037 
  1038 fun tptp_classrelLits sub sup = 
  1039     let val tvar = "(T)"
  1040     in 
  1041 	"[--" ^ sub ^ tvar ^ ",++" ^ sup ^ tvar ^ "]"
  1042     end;
  1043 
  1044 fun tptp_classrelClause (ClassrelClause {axiom_name,subclass,superclass,...}) =
  1045   "input_clause(" ^ axiom_name ^ ",axiom," ^ tptp_classrelLits subclass superclass ^ ").\n" 
  1046 
  1047 (* write out a subgoal as tptp clauses to the file "xxxx_N"*)
  1048 fun tptp_write_file thms filename (axclauses,classrel_clauses,arity_clauses) =
  1049   let
  1050     val _ = Output.debug ("Preparing to write the TPTP file " ^ filename)
  1051     val clss = make_conjecture_clauses thms
  1052     val axclauses' = make_axiom_clauses axclauses
  1053     val (tptp_clss,tfree_litss) = ListPair.unzip (map clause2tptp clss)
  1054     val tfree_clss = map tptp_tfree_clause (foldl (op union_string) [] tfree_litss)
  1055     val out = TextIO.openOut filename
  1056   in
  1057     List.app (curry TextIO.output out o #1 o clause2tptp) axclauses';
  1058     writeln_strs out tfree_clss;
  1059     writeln_strs out tptp_clss;
  1060     List.app (curry TextIO.output out o tptp_classrelClause) classrel_clauses;
  1061     List.app (curry TextIO.output out o tptp_arity_clause) arity_clauses;
  1062     TextIO.closeOut out
  1063   end;
  1064 
  1065 
  1066 
  1067 
  1068 
  1069 end;