src/HOL/Tools/inductive.ML
author wenzelm
Fri Mar 16 18:20:12 2012 +0100 (2012-03-16)
changeset 46961 5c6955f487e5
parent 46949 94aa7b81bcf6
child 47876 0521ee2e504d
permissions -rw-r--r--
outer syntax command definitions based on formal command_spec derived from theory header declarations;
     1 (*  Title:      HOL/Tools/inductive.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Stefan Berghofer and Markus Wenzel, TU Muenchen
     4 
     5 (Co)Inductive Definition module for HOL.
     6 
     7 Features:
     8   * least or greatest fixedpoints
     9   * mutually recursive definitions
    10   * definitions involving arbitrary monotone operators
    11   * automatically proves introduction and elimination rules
    12 
    13   Introduction rules have the form
    14   [| M Pj ti, ..., Q x, ... |] ==> Pk t
    15   where M is some monotone operator (usually the identity)
    16   Q x is any side condition on the free variables
    17   ti, t are any terms
    18   Pj, Pk are two of the predicates being defined in mutual recursion
    19 *)
    20 
    21 signature BASIC_INDUCTIVE =
    22 sig
    23   type inductive_result =
    24     {preds: term list, elims: thm list, raw_induct: thm,
    25      induct: thm, inducts: thm list, intrs: thm list, eqs: thm list}
    26   val transform_result: morphism -> inductive_result -> inductive_result
    27   type inductive_info = {names: string list, coind: bool} * inductive_result
    28   val the_inductive: Proof.context -> string -> inductive_info
    29   val print_inductives: Proof.context -> unit
    30   val get_monos: Proof.context -> thm list
    31   val mono_add: attribute
    32   val mono_del: attribute
    33   val mk_cases: Proof.context -> term -> thm
    34   val inductive_forall_def: thm
    35   val rulify: thm -> thm
    36   val inductive_cases: (Attrib.binding * string list) list -> local_theory ->
    37     thm list list * local_theory
    38   val inductive_cases_i: (Attrib.binding * term list) list -> local_theory ->
    39     thm list list * local_theory
    40   type inductive_flags =
    41     {quiet_mode: bool, verbose: bool, alt_name: binding, coind: bool,
    42       no_elim: bool, no_ind: bool, skip_mono: bool, fork_mono: bool}
    43   val add_inductive_i:
    44     inductive_flags -> ((binding * typ) * mixfix) list ->
    45     (string * typ) list -> (Attrib.binding * term) list -> thm list -> local_theory ->
    46     inductive_result * local_theory
    47   val add_inductive: bool -> bool ->
    48     (binding * string option * mixfix) list ->
    49     (binding * string option * mixfix) list ->
    50     (Attrib.binding * string) list ->
    51     (Facts.ref * Attrib.src list) list ->
    52     bool -> local_theory -> inductive_result * local_theory
    53   val add_inductive_global: inductive_flags ->
    54     ((binding * typ) * mixfix) list -> (string * typ) list -> (Attrib.binding * term) list ->
    55     thm list -> theory -> inductive_result * theory
    56   val arities_of: thm -> (string * int) list
    57   val params_of: thm -> term list
    58   val partition_rules: thm -> thm list -> (string * thm list) list
    59   val partition_rules': thm -> (thm * 'a) list -> (string * (thm * 'a) list) list
    60   val unpartition_rules: thm list -> (string * 'a list) list -> 'a list
    61   val infer_intro_vars: thm -> int -> thm list -> term list list
    62   val setup: theory -> theory
    63 end;
    64 
    65 signature INDUCTIVE =
    66 sig
    67   include BASIC_INDUCTIVE
    68   type add_ind_def =
    69     inductive_flags ->
    70     term list -> (Attrib.binding * term) list -> thm list ->
    71     term list -> (binding * mixfix) list ->
    72     local_theory -> inductive_result * local_theory
    73   val declare_rules: binding -> bool -> bool -> string list -> term list ->
    74     thm list -> binding list -> Attrib.src list list -> (thm * string list * int) list ->
    75     thm list -> thm -> local_theory -> thm list * thm list * thm list * thm * thm list * local_theory
    76   val add_ind_def: add_ind_def
    77   val gen_add_inductive_i: add_ind_def -> inductive_flags ->
    78     ((binding * typ) * mixfix) list -> (string * typ) list -> (Attrib.binding * term) list ->
    79     thm list -> local_theory -> inductive_result * local_theory
    80   val gen_add_inductive: add_ind_def -> bool -> bool ->
    81     (binding * string option * mixfix) list ->
    82     (binding * string option * mixfix) list ->
    83     (Attrib.binding * string) list -> (Facts.ref * Attrib.src list) list ->
    84     bool -> local_theory -> inductive_result * local_theory
    85   val gen_ind_decl: add_ind_def -> bool -> (bool -> local_theory -> local_theory) parser
    86 end;
    87 
    88 structure Inductive: INDUCTIVE =
    89 struct
    90 
    91 (** theory context references **)
    92 
    93 val inductive_forall_def = @{thm induct_forall_def};
    94 val inductive_conj_name = "HOL.induct_conj";
    95 val inductive_conj_def = @{thm induct_conj_def};
    96 val inductive_conj = @{thms induct_conj};
    97 val inductive_atomize = @{thms induct_atomize};
    98 val inductive_rulify = @{thms induct_rulify};
    99 val inductive_rulify_fallback = @{thms induct_rulify_fallback};
   100 
   101 val simp_thms1 =
   102   map mk_meta_eq
   103     @{lemma "(~ True) = False" "(~ False) = True"
   104         "(True --> P) = P" "(False --> P) = True"
   105         "(P & True) = P" "(True & P) = P"
   106       by (fact simp_thms)+};
   107 
   108 val simp_thms2 =
   109   map mk_meta_eq [@{thm inf_fun_def}, @{thm inf_bool_def}] @ simp_thms1;
   110 
   111 val simp_thms3 =
   112   map mk_meta_eq [@{thm le_fun_def}, @{thm le_bool_def}, @{thm sup_fun_def}, @{thm sup_bool_def}];
   113 
   114 
   115 
   116 (** misc utilities **)
   117 
   118 fun message quiet_mode s = if quiet_mode then () else writeln s;
   119 fun clean_message quiet_mode s = if ! quick_and_dirty then () else message quiet_mode s;
   120 
   121 fun coind_prefix true = "co"
   122   | coind_prefix false = "";
   123 
   124 fun log (b: int) m n = if m >= n then 0 else 1 + log b (b * m) n;
   125 
   126 fun make_bool_args f g [] i = []
   127   | make_bool_args f g (x :: xs) i =
   128       (if i mod 2 = 0 then f x else g x) :: make_bool_args f g xs (i div 2);
   129 
   130 fun make_bool_args' xs =
   131   make_bool_args (K @{term False}) (K @{term True}) xs;
   132 
   133 fun arg_types_of k c = drop k (binder_types (fastype_of c));
   134 
   135 fun find_arg T x [] = raise Fail "find_arg"
   136   | find_arg T x ((p as (_, (SOME _, _))) :: ps) =
   137       apsnd (cons p) (find_arg T x ps)
   138   | find_arg T x ((p as (U, (NONE, y))) :: ps) =
   139       if (T: typ) = U then (y, (U, (SOME x, y)) :: ps)
   140       else apsnd (cons p) (find_arg T x ps);
   141 
   142 fun make_args Ts xs =
   143   map (fn (T, (NONE, ())) => Const (@{const_name undefined}, T) | (_, (SOME t, ())) => t)
   144     (fold (fn (t, T) => snd o find_arg T t) xs (map (rpair (NONE, ())) Ts));
   145 
   146 fun make_args' Ts xs Us =
   147   fst (fold_map (fn T => find_arg T ()) Us (Ts ~~ map (pair NONE) xs));
   148 
   149 fun dest_predicate cs params t =
   150   let
   151     val k = length params;
   152     val (c, ts) = strip_comb t;
   153     val (xs, ys) = chop k ts;
   154     val i = find_index (fn c' => c' = c) cs;
   155   in
   156     if xs = params andalso i >= 0 then
   157       SOME (c, i, ys, chop (length ys) (arg_types_of k c))
   158     else NONE
   159   end;
   160 
   161 fun mk_names a 0 = []
   162   | mk_names a 1 = [a]
   163   | mk_names a n = map (fn i => a ^ string_of_int i) (1 upto n);
   164 
   165 fun select_disj 1 1 = []
   166   | select_disj _ 1 = [rtac disjI1]
   167   | select_disj n i = rtac disjI2 :: select_disj (n - 1) (i - 1);
   168 
   169 
   170 
   171 (** context data **)
   172 
   173 type inductive_result =
   174   {preds: term list, elims: thm list, raw_induct: thm,
   175    induct: thm, inducts: thm list, intrs: thm list, eqs: thm list};
   176 
   177 fun transform_result phi {preds, elims, raw_induct: thm, induct, inducts, intrs, eqs} =
   178   let
   179     val term = Morphism.term phi;
   180     val thm = Morphism.thm phi;
   181     val fact = Morphism.fact phi;
   182   in
   183    {preds = map term preds, elims = fact elims, raw_induct = thm raw_induct,
   184     induct = thm induct, inducts = fact inducts, intrs = fact intrs, eqs = fact eqs}
   185   end;
   186 
   187 type inductive_info = {names: string list, coind: bool} * inductive_result;
   188 
   189 val empty_equations =
   190   Item_Net.init Thm.eq_thm_prop
   191     (single o fst o HOLogic.dest_eq o HOLogic.dest_Trueprop o Thm.prop_of);
   192 
   193 datatype data = Data of
   194  {infos: inductive_info Symtab.table,
   195   monos: thm list,
   196   equations: thm Item_Net.T};
   197 
   198 fun make_data (infos, monos, equations) =
   199   Data {infos = infos, monos = monos, equations = equations};
   200 
   201 structure Data = Generic_Data
   202 (
   203   type T = data;
   204   val empty = make_data (Symtab.empty, [], empty_equations);
   205   val extend = I;
   206   fun merge (Data {infos = infos1, monos = monos1, equations = equations1},
   207       Data {infos = infos2, monos = monos2, equations = equations2}) =
   208     make_data (Symtab.merge (K true) (infos1, infos2),
   209       Thm.merge_thms (monos1, monos2),
   210       Item_Net.merge (equations1, equations2));
   211 );
   212 
   213 fun map_data f =
   214   Data.map (fn Data {infos, monos, equations} => make_data (f (infos, monos, equations)));
   215 
   216 fun rep_data ctxt = Data.get (Context.Proof ctxt) |> (fn Data rep => rep);
   217 
   218 fun print_inductives ctxt =
   219   let
   220     val {infos, monos, ...} = rep_data ctxt;
   221     val space = Consts.space_of (Proof_Context.consts_of ctxt);
   222   in
   223     [Pretty.strs ("(co)inductives:" :: map #1 (Name_Space.extern_table ctxt (space, infos))),
   224      Pretty.big_list "monotonicity rules:" (map (Display.pretty_thm ctxt) monos)]
   225     |> Pretty.chunks |> Pretty.writeln
   226   end;
   227 
   228 
   229 (* inductive info *)
   230 
   231 fun the_inductive ctxt name =
   232   (case Symtab.lookup (#infos (rep_data ctxt)) name of
   233     NONE => error ("Unknown (co)inductive predicate " ^ quote name)
   234   | SOME info => info);
   235 
   236 fun put_inductives names info =
   237   map_data (fn (infos, monos, equations) =>
   238     (fold (fn name => Symtab.update (name, info)) names infos, monos, equations));
   239 
   240 
   241 (* monotonicity rules *)
   242 
   243 val get_monos = #monos o rep_data;
   244 
   245 fun mk_mono ctxt thm =
   246   let
   247     fun eq_to_mono thm' = thm' RS (thm' RS @{thm eq_to_mono});
   248     fun dest_less_concl thm = dest_less_concl (thm RS @{thm le_funD})
   249       handle THM _ => thm RS @{thm le_boolD}
   250   in
   251     (case concl_of thm of
   252       Const ("==", _) $ _ $ _ => eq_to_mono (thm RS meta_eq_to_obj_eq)
   253     | _ $ (Const (@{const_name HOL.eq}, _) $ _ $ _) => eq_to_mono thm
   254     | _ $ (Const (@{const_name Orderings.less_eq}, _) $ _ $ _) =>
   255       dest_less_concl (Seq.hd (REPEAT (FIRSTGOAL
   256         (resolve_tac [@{thm le_funI}, @{thm le_boolI'}])) thm))
   257     | _ => thm)
   258   end handle THM _ => error ("Bad monotonicity theorem:\n" ^ Display.string_of_thm ctxt thm);
   259 
   260 val mono_add =
   261   Thm.declaration_attribute (fn thm => fn context =>
   262     map_data (fn (infos, monos, equations) =>
   263       (infos, Thm.add_thm (mk_mono (Context.proof_of context) thm) monos, equations)) context);
   264 
   265 val mono_del =
   266   Thm.declaration_attribute (fn thm => fn context =>
   267     map_data (fn (infos, monos, equations) =>
   268       (infos, Thm.del_thm (mk_mono (Context.proof_of context) thm) monos, equations)) context);
   269 
   270 
   271 (* equations *)
   272 
   273 val get_equations = #equations o rep_data;
   274 
   275 val equation_add_permissive =
   276   Thm.declaration_attribute (fn thm =>
   277     map_data (fn (infos, monos, equations) =>
   278       (infos, monos, perhaps (try (Item_Net.update thm)) equations)));
   279 
   280 
   281 
   282 (** process rules **)
   283 
   284 local
   285 
   286 fun err_in_rule ctxt name t msg =
   287   error (cat_lines ["Ill-formed introduction rule " ^ Binding.print name,
   288     Syntax.string_of_term ctxt t, msg]);
   289 
   290 fun err_in_prem ctxt name t p msg =
   291   error (cat_lines ["Ill-formed premise", Syntax.string_of_term ctxt p,
   292     "in introduction rule " ^ Binding.print name, Syntax.string_of_term ctxt t, msg]);
   293 
   294 val bad_concl = "Conclusion of introduction rule must be an inductive predicate";
   295 
   296 val bad_ind_occ = "Inductive predicate occurs in argument of inductive predicate";
   297 
   298 val bad_app = "Inductive predicate must be applied to parameter(s) ";
   299 
   300 fun atomize_term thy = Raw_Simplifier.rewrite_term thy inductive_atomize [];
   301 
   302 in
   303 
   304 fun check_rule ctxt cs params ((binding, att), rule) =
   305   let
   306     val params' = Term.variant_frees rule (Logic.strip_params rule);
   307     val frees = rev (map Free params');
   308     val concl = subst_bounds (frees, Logic.strip_assums_concl rule);
   309     val prems = map (curry subst_bounds frees) (Logic.strip_assums_hyp rule);
   310     val rule' = Logic.list_implies (prems, concl);
   311     val aprems = map (atomize_term (Proof_Context.theory_of ctxt)) prems;
   312     val arule = fold_rev (Logic.all o Free) params' (Logic.list_implies (aprems, concl));
   313 
   314     fun check_ind err t =
   315       (case dest_predicate cs params t of
   316         NONE => err (bad_app ^
   317           commas (map (Syntax.string_of_term ctxt) params))
   318       | SOME (_, _, ys, _) =>
   319           if exists (fn c => exists (fn t => Logic.occs (c, t)) ys) cs
   320           then err bad_ind_occ else ());
   321 
   322     fun check_prem' prem t =
   323       if member (op =) cs (head_of t) then
   324         check_ind (err_in_prem ctxt binding rule prem) t
   325       else
   326         (case t of
   327           Abs (_, _, t) => check_prem' prem t
   328         | t $ u => (check_prem' prem t; check_prem' prem u)
   329         | _ => ());
   330 
   331     fun check_prem (prem, aprem) =
   332       if can HOLogic.dest_Trueprop aprem then check_prem' prem prem
   333       else err_in_prem ctxt binding rule prem "Non-atomic premise";
   334 
   335     val _ =
   336       (case concl of
   337         Const (@{const_name Trueprop}, _) $ t =>
   338           if member (op =) cs (head_of t) then
   339            (check_ind (err_in_rule ctxt binding rule') t;
   340             List.app check_prem (prems ~~ aprems))
   341           else err_in_rule ctxt binding rule' bad_concl
   342        | _ => err_in_rule ctxt binding rule' bad_concl);
   343   in
   344     ((binding, att), arule)
   345   end;
   346 
   347 val rulify =
   348   hol_simplify inductive_conj
   349   #> hol_simplify inductive_rulify
   350   #> hol_simplify inductive_rulify_fallback
   351   #> Simplifier.norm_hhf;
   352 
   353 end;
   354 
   355 
   356 
   357 (** proofs for (co)inductive predicates **)
   358 
   359 (* prove monotonicity *)
   360 
   361 fun prove_mono quiet_mode skip_mono fork_mono predT fp_fun monos ctxt =
   362  (message (quiet_mode orelse skip_mono andalso !quick_and_dirty orelse fork_mono)
   363     "  Proving monotonicity ...";
   364   (if skip_mono then Skip_Proof.prove else if fork_mono then Goal.prove_future else Goal.prove) ctxt
   365     [] []
   366     (HOLogic.mk_Trueprop
   367       (Const (@{const_name Orderings.mono}, (predT --> predT) --> HOLogic.boolT) $ fp_fun))
   368     (fn _ => EVERY [rtac @{thm monoI} 1,
   369       REPEAT (resolve_tac [@{thm le_funI}, @{thm le_boolI'}] 1),
   370       REPEAT (FIRST
   371         [atac 1,
   372          resolve_tac (map (mk_mono ctxt) monos @ get_monos ctxt) 1,
   373          etac @{thm le_funE} 1, dtac @{thm le_boolD} 1])]));
   374 
   375 
   376 (* prove introduction rules *)
   377 
   378 fun prove_intrs quiet_mode coind mono fp_def k intr_ts rec_preds_defs ctxt ctxt' =
   379   let
   380     val _ = clean_message quiet_mode "  Proving the introduction rules ...";
   381 
   382     val unfold = funpow k (fn th => th RS fun_cong)
   383       (mono RS (fp_def RS
   384         (if coind then @{thm def_gfp_unfold} else @{thm def_lfp_unfold})));
   385 
   386     val rules = [refl, TrueI, @{lemma "~ False" by (rule notI)}, exI, conjI];
   387 
   388     val intrs = map_index (fn (i, intr) =>
   389       Skip_Proof.prove ctxt [] [] intr (fn _ => EVERY
   390        [rewrite_goals_tac rec_preds_defs,
   391         rtac (unfold RS iffD2) 1,
   392         EVERY1 (select_disj (length intr_ts) (i + 1)),
   393         (*Not ares_tac, since refl must be tried before any equality assumptions;
   394           backtracking may occur if the premises have extra variables!*)
   395         DEPTH_SOLVE_1 (resolve_tac rules 1 APPEND assume_tac 1)])
   396        |> singleton (Proof_Context.export ctxt ctxt')) intr_ts
   397 
   398   in (intrs, unfold) end;
   399 
   400 
   401 (* prove elimination rules *)
   402 
   403 fun prove_elims quiet_mode cs params intr_ts intr_names unfold rec_preds_defs ctxt ctxt''' =
   404   let
   405     val _ = clean_message quiet_mode "  Proving the elimination rules ...";
   406 
   407     val ([pname], ctxt') = Variable.variant_fixes ["P"] ctxt;
   408     val P = HOLogic.mk_Trueprop (Free (pname, HOLogic.boolT));
   409 
   410     fun dest_intr r =
   411       (the (dest_predicate cs params (HOLogic.dest_Trueprop (Logic.strip_assums_concl r))),
   412        Logic.strip_assums_hyp r, Logic.strip_params r);
   413 
   414     val intrs = map dest_intr intr_ts ~~ intr_names;
   415 
   416     val rules1 = [disjE, exE, FalseE];
   417     val rules2 = [conjE, FalseE, @{lemma "~ True ==> R" by (rule notE [OF _ TrueI])}];
   418 
   419     fun prove_elim c =
   420       let
   421         val Ts = arg_types_of (length params) c;
   422         val (anames, ctxt'') = Variable.variant_fixes (mk_names "a" (length Ts)) ctxt';
   423         val frees = map Free (anames ~~ Ts);
   424 
   425         fun mk_elim_prem ((_, _, us, _), ts, params') =
   426           Logic.list_all (params',
   427             Logic.list_implies (map (HOLogic.mk_Trueprop o HOLogic.mk_eq)
   428               (frees ~~ us) @ ts, P));
   429         val c_intrs = filter (equal c o #1 o #1 o #1) intrs;
   430         val prems = HOLogic.mk_Trueprop (list_comb (c, params @ frees)) ::
   431            map mk_elim_prem (map #1 c_intrs)
   432       in
   433         (Skip_Proof.prove ctxt'' [] prems P
   434           (fn {prems, ...} => EVERY
   435             [cut_tac (hd prems) 1,
   436              rewrite_goals_tac rec_preds_defs,
   437              dtac (unfold RS iffD1) 1,
   438              REPEAT (FIRSTGOAL (eresolve_tac rules1)),
   439              REPEAT (FIRSTGOAL (eresolve_tac rules2)),
   440              EVERY (map (fn prem =>
   441                DEPTH_SOLVE_1 (ares_tac [rewrite_rule rec_preds_defs prem, conjI] 1)) (tl prems))])
   442           |> singleton (Proof_Context.export ctxt'' ctxt'''),
   443          map #2 c_intrs, length Ts)
   444       end
   445 
   446    in map prove_elim cs end;
   447 
   448 
   449 (* prove simplification equations *)
   450 
   451 fun prove_eqs quiet_mode cs params intr_ts intrs
   452     (elims: (thm * bstring list * int) list) ctxt ctxt'' =  (* FIXME ctxt'' ?? *)
   453   let
   454     val _ = clean_message quiet_mode "  Proving the simplification rules ...";
   455 
   456     fun dest_intr r =
   457       (the (dest_predicate cs params (HOLogic.dest_Trueprop (Logic.strip_assums_concl r))),
   458        Logic.strip_assums_hyp r, Logic.strip_params r);
   459     val intr_ts' = map dest_intr intr_ts;
   460 
   461     fun prove_eq c (elim: thm * 'a * 'b) =
   462       let
   463         val Ts = arg_types_of (length params) c;
   464         val (anames, ctxt') = Variable.variant_fixes (mk_names "a" (length Ts)) ctxt;
   465         val frees = map Free (anames ~~ Ts);
   466         val c_intrs = filter (equal c o #1 o #1 o #1) (intr_ts' ~~ intrs);
   467         fun mk_intr_conj (((_, _, us, _), ts, params'), _) =
   468           let
   469             fun list_ex ([], t) = t
   470               | list_ex ((a, T) :: vars, t) =
   471                   HOLogic.exists_const T $ Abs (a, T, list_ex (vars, t));
   472             val conjs = map2 (curry HOLogic.mk_eq) frees us @ (map HOLogic.dest_Trueprop ts);
   473           in
   474             list_ex (params', if null conjs then @{term True} else foldr1 HOLogic.mk_conj conjs)
   475           end;
   476         val lhs = list_comb (c, params @ frees);
   477         val rhs =
   478           if null c_intrs then @{term False}
   479           else foldr1 HOLogic.mk_disj (map mk_intr_conj c_intrs);
   480         val eq = HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs));
   481         fun prove_intr1 (i, _) = Subgoal.FOCUS_PREMS (fn {params, prems, ...} =>
   482             let
   483               val (prems', last_prem) = split_last prems;
   484             in
   485               EVERY1 (select_disj (length c_intrs) (i + 1)) THEN
   486               EVERY (replicate (length params) (rtac @{thm exI} 1)) THEN
   487               EVERY (map (fn prem => (rtac @{thm conjI} 1 THEN rtac prem 1)) prems') THEN
   488               rtac last_prem 1
   489             end) ctxt' 1;
   490         fun prove_intr2 (((_, _, us, _), ts, params'), intr) =
   491           EVERY (replicate (length params') (etac @{thm exE} 1)) THEN
   492           EVERY (replicate (length ts + length us - 1) (etac @{thm conjE} 1)) THEN
   493           Subgoal.FOCUS_PREMS (fn {params, prems, ...} =>
   494             let
   495               val (eqs, prems') = chop (length us) prems;
   496               val rew_thms = map (fn th => th RS @{thm eq_reflection}) eqs;
   497             in
   498               rewrite_goal_tac rew_thms 1 THEN
   499               rtac intr 1 THEN
   500               EVERY (map (fn p => rtac p 1) prems')
   501             end) ctxt' 1;
   502       in
   503         Skip_Proof.prove ctxt' [] [] eq (fn _ =>
   504           rtac @{thm iffI} 1 THEN etac (#1 elim) 1 THEN
   505           EVERY (map_index prove_intr1 c_intrs) THEN
   506           (if null c_intrs then etac @{thm FalseE} 1
   507            else
   508             let val (c_intrs', last_c_intr) = split_last c_intrs in
   509               EVERY (map (fn ci => etac @{thm disjE} 1 THEN prove_intr2 ci) c_intrs') THEN
   510               prove_intr2 last_c_intr
   511             end))
   512         |> rulify
   513         |> singleton (Proof_Context.export ctxt' ctxt'')
   514       end;
   515   in
   516     map2 prove_eq cs elims
   517   end;
   518 
   519 
   520 (* derivation of simplified elimination rules *)
   521 
   522 local
   523 
   524 (*delete needless equality assumptions*)
   525 val refl_thin = Goal.prove_global @{theory HOL} [] [] @{prop "!!P. a = a ==> P ==> P"}
   526   (fn _ => assume_tac 1);
   527 val elim_rls = [asm_rl, FalseE, refl_thin, conjE, exE];
   528 val elim_tac = REPEAT o Tactic.eresolve_tac elim_rls;
   529 
   530 fun simp_case_tac ss i =
   531   EVERY' [elim_tac, asm_full_simp_tac ss, elim_tac, REPEAT o bound_hyp_subst_tac] i;
   532 
   533 in
   534 
   535 fun mk_cases ctxt prop =
   536   let
   537     val thy = Proof_Context.theory_of ctxt;
   538     val ss = simpset_of ctxt;
   539 
   540     fun err msg =
   541       error (Pretty.string_of (Pretty.block
   542         [Pretty.str msg, Pretty.fbrk, Syntax.pretty_term ctxt prop]));
   543 
   544     val elims = Induct.find_casesP ctxt prop;
   545 
   546     val cprop = Thm.cterm_of thy prop;
   547     val tac = ALLGOALS (simp_case_tac ss) THEN prune_params_tac;
   548     fun mk_elim rl =
   549       Thm.implies_intr cprop (Tactic.rule_by_tactic ctxt tac (Thm.assume cprop RS rl))
   550       |> singleton (Variable.export (Variable.auto_fixes prop ctxt) ctxt);
   551   in
   552     (case get_first (try mk_elim) elims of
   553       SOME r => r
   554     | NONE => err "Proposition not an inductive predicate:")
   555   end;
   556 
   557 end;
   558 
   559 
   560 (* inductive_cases *)
   561 
   562 fun gen_inductive_cases prep_att prep_prop args lthy =
   563   let
   564     val thy = Proof_Context.theory_of lthy;
   565     val thmss =
   566       map snd args
   567       |> burrow (grouped 10 Par_List.map (mk_cases lthy o prep_prop lthy));
   568     val facts =
   569       map2 (fn ((a, atts), _) => fn thms => ((a, map (prep_att thy) atts), [(thms, [])]))
   570         args thmss;
   571   in lthy |> Local_Theory.notes facts |>> map snd end;
   572 
   573 val inductive_cases = gen_inductive_cases Attrib.intern_src Syntax.read_prop;
   574 val inductive_cases_i = gen_inductive_cases (K I) Syntax.check_prop;
   575 
   576 
   577 val ind_cases_setup =
   578   Method.setup @{binding ind_cases}
   579     (Scan.lift (Scan.repeat1 Args.name_source --
   580       Scan.optional (Args.$$$ "for" |-- Scan.repeat1 Args.binding) []) >>
   581       (fn (raw_props, fixes) => fn ctxt =>
   582         let
   583           val (_, ctxt') = Variable.add_fixes_binding fixes ctxt;
   584           val props = Syntax.read_props ctxt' raw_props;
   585           val ctxt'' = fold Variable.declare_term props ctxt';
   586           val rules = Proof_Context.export ctxt'' ctxt (map (mk_cases ctxt'') props)
   587         in Method.erule 0 rules end))
   588     "dynamic case analysis on predicates";
   589 
   590 
   591 (* derivation of simplified equation *)
   592 
   593 fun mk_simp_eq ctxt prop =
   594   let
   595     val thy = Proof_Context.theory_of ctxt;
   596     val ctxt' = Variable.auto_fixes prop ctxt;
   597     val lhs_of = fst o HOLogic.dest_eq o HOLogic.dest_Trueprop o Thm.prop_of;
   598     val substs =
   599       Item_Net.retrieve (get_equations ctxt) (HOLogic.dest_Trueprop prop)
   600       |> map_filter
   601         (fn eq => SOME (Pattern.match thy (lhs_of eq, HOLogic.dest_Trueprop prop)
   602             (Vartab.empty, Vartab.empty), eq)
   603           handle Pattern.MATCH => NONE);
   604     val (subst, eq) =
   605       (case substs of
   606         [s] => s
   607       | _ => error
   608         ("equations matching pattern " ^ Syntax.string_of_term ctxt prop ^ " is not unique"));
   609     val inst =
   610       map (fn v => (cterm_of thy (Var v), cterm_of thy (Envir.subst_term subst (Var v))))
   611         (Term.add_vars (lhs_of eq) []);
   612   in
   613     Drule.cterm_instantiate inst eq
   614     |> Conv.fconv_rule (Conv.arg_conv (Conv.arg_conv (Simplifier.full_rewrite (simpset_of ctxt))))
   615     |> singleton (Variable.export ctxt' ctxt)
   616   end
   617 
   618 
   619 (* inductive simps *)
   620 
   621 fun gen_inductive_simps prep_att prep_prop args lthy =
   622   let
   623     val thy = Proof_Context.theory_of lthy;
   624     val facts = args |> map (fn ((a, atts), props) =>
   625       ((a, map (prep_att thy) atts),
   626         map (Thm.no_attributes o single o mk_simp_eq lthy o prep_prop lthy) props));
   627   in lthy |> Local_Theory.notes facts |>> map snd end;
   628 
   629 val inductive_simps = gen_inductive_simps Attrib.intern_src Syntax.read_prop;
   630 val inductive_simps_i = gen_inductive_simps (K I) Syntax.check_prop;
   631 
   632 
   633 (* prove induction rule *)
   634 
   635 fun prove_indrule quiet_mode cs argTs bs xs rec_const params intr_ts mono
   636     fp_def rec_preds_defs ctxt ctxt''' =  (* FIXME ctxt''' ?? *)
   637   let
   638     val _ = clean_message quiet_mode "  Proving the induction rule ...";
   639 
   640     (* predicates for induction rule *)
   641 
   642     val (pnames, ctxt') = Variable.variant_fixes (mk_names "P" (length cs)) ctxt;
   643     val preds =
   644       map2 (curry Free) pnames
   645         (map (fn c => arg_types_of (length params) c ---> HOLogic.boolT) cs);
   646 
   647     (* transform an introduction rule into a premise for induction rule *)
   648 
   649     fun mk_ind_prem r =
   650       let
   651         fun subst s =
   652           (case dest_predicate cs params s of
   653             SOME (_, i, ys, (_, Ts)) =>
   654               let
   655                 val k = length Ts;
   656                 val bs = map Bound (k - 1 downto 0);
   657                 val P = list_comb (nth preds i, map (incr_boundvars k) ys @ bs);
   658                 val Q =
   659                   fold_rev Term.abs (mk_names "x" k ~~ Ts)
   660                     (HOLogic.mk_binop inductive_conj_name
   661                       (list_comb (incr_boundvars k s, bs), P));
   662               in (Q, case Ts of [] => SOME (s, P) | _ => NONE) end
   663           | NONE =>
   664               (case s of
   665                 t $ u => (fst (subst t) $ fst (subst u), NONE)
   666               | Abs (a, T, t) => (Abs (a, T, fst (subst t)), NONE)
   667               | _ => (s, NONE)));
   668 
   669         fun mk_prem s prems =
   670           (case subst s of
   671             (_, SOME (t, u)) => t :: u :: prems
   672           | (t, _) => t :: prems);
   673 
   674         val SOME (_, i, ys, _) =
   675           dest_predicate cs params (HOLogic.dest_Trueprop (Logic.strip_assums_concl r));
   676       in
   677         fold_rev (Logic.all o Free) (Logic.strip_params r)
   678           (Logic.list_implies (map HOLogic.mk_Trueprop (fold_rev mk_prem
   679             (map HOLogic.dest_Trueprop (Logic.strip_assums_hyp r)) []),
   680               HOLogic.mk_Trueprop (list_comb (nth preds i, ys))))
   681       end;
   682 
   683     val ind_prems = map mk_ind_prem intr_ts;
   684 
   685 
   686     (* make conclusions for induction rules *)
   687 
   688     val Tss = map (binder_types o fastype_of) preds;
   689     val (xnames, ctxt'') = Variable.variant_fixes (mk_names "x" (length (flat Tss))) ctxt';
   690     val mutual_ind_concl =
   691       HOLogic.mk_Trueprop (foldr1 HOLogic.mk_conj
   692         (map (fn (((xnames, Ts), c), P) =>
   693           let val frees = map Free (xnames ~~ Ts)
   694           in HOLogic.mk_imp (list_comb (c, params @ frees), list_comb (P, frees)) end)
   695         (unflat Tss xnames ~~ Tss ~~ cs ~~ preds)));
   696 
   697 
   698     (* make predicate for instantiation of abstract induction rule *)
   699 
   700     val ind_pred =
   701       fold_rev lambda (bs @ xs) (foldr1 HOLogic.mk_conj
   702         (map_index (fn (i, P) => fold_rev (curry HOLogic.mk_imp)
   703            (make_bool_args HOLogic.mk_not I bs i)
   704            (list_comb (P, make_args' argTs xs (binder_types (fastype_of P))))) preds));
   705 
   706     val ind_concl =
   707       HOLogic.mk_Trueprop
   708         (HOLogic.mk_binrel @{const_name Orderings.less_eq} (rec_const, ind_pred));
   709 
   710     val raw_fp_induct = mono RS (fp_def RS @{thm def_lfp_induct});
   711 
   712     val induct = Skip_Proof.prove ctxt'' [] ind_prems ind_concl
   713       (fn {prems, ...} => EVERY
   714         [rewrite_goals_tac [inductive_conj_def],
   715          DETERM (rtac raw_fp_induct 1),
   716          REPEAT (resolve_tac [@{thm le_funI}, @{thm le_boolI}] 1),
   717          rewrite_goals_tac simp_thms2,
   718          (*This disjE separates out the introduction rules*)
   719          REPEAT (FIRSTGOAL (eresolve_tac [disjE, exE, FalseE])),
   720          (*Now break down the individual cases.  No disjE here in case
   721            some premise involves disjunction.*)
   722          REPEAT (FIRSTGOAL (etac conjE ORELSE' bound_hyp_subst_tac)),
   723          REPEAT (FIRSTGOAL
   724            (resolve_tac [conjI, impI] ORELSE' (etac notE THEN' atac))),
   725          EVERY (map (fn prem => DEPTH_SOLVE_1 (ares_tac [rewrite_rule
   726              (inductive_conj_def :: rec_preds_defs @ simp_thms2) prem,
   727            conjI, refl] 1)) prems)]);
   728 
   729     val lemma = Skip_Proof.prove ctxt'' [] []
   730       (Logic.mk_implies (ind_concl, mutual_ind_concl)) (fn _ => EVERY
   731         [rewrite_goals_tac rec_preds_defs,
   732          REPEAT (EVERY
   733            [REPEAT (resolve_tac [conjI, impI] 1),
   734             REPEAT (eresolve_tac [@{thm le_funE}, @{thm le_boolE}] 1),
   735             atac 1,
   736             rewrite_goals_tac simp_thms1,
   737             atac 1])]);
   738 
   739   in singleton (Proof_Context.export ctxt'' ctxt''') (induct RS lemma) end;
   740 
   741 
   742 
   743 (** specification of (co)inductive predicates **)
   744 
   745 fun mk_ind_def quiet_mode skip_mono fork_mono alt_name coind
   746     cs intr_ts monos params cnames_syn lthy =
   747   let
   748     val fp_name = if coind then @{const_name Inductive.gfp} else @{const_name Inductive.lfp};
   749 
   750     val argTs = fold (combine (op =) o arg_types_of (length params)) cs [];
   751     val k = log 2 1 (length cs);
   752     val predT = replicate k HOLogic.boolT ---> argTs ---> HOLogic.boolT;
   753     val p :: xs =
   754       map Free (Variable.variant_frees lthy intr_ts
   755         (("p", predT) :: (mk_names "x" (length argTs) ~~ argTs)));
   756     val bs =
   757       map Free (Variable.variant_frees lthy (p :: xs @ intr_ts)
   758         (map (rpair HOLogic.boolT) (mk_names "b" k)));
   759 
   760     fun subst t =
   761       (case dest_predicate cs params t of
   762         SOME (_, i, ts, (Ts, Us)) =>
   763           let
   764             val l = length Us;
   765             val zs = map Bound (l - 1 downto 0);
   766           in
   767             fold_rev (Term.abs o pair "z") Us
   768               (list_comb (p,
   769                 make_bool_args' bs i @ make_args argTs
   770                   ((map (incr_boundvars l) ts ~~ Ts) @ (zs ~~ Us))))
   771           end
   772       | NONE =>
   773           (case t of
   774             t1 $ t2 => subst t1 $ subst t2
   775           | Abs (x, T, u) => Abs (x, T, subst u)
   776           | _ => t));
   777 
   778     (* transform an introduction rule into a conjunction  *)
   779     (*   [| p_i t; ... |] ==> p_j u                       *)
   780     (* is transformed into                                *)
   781     (*   b_j & x_j = u & p b_j t & ...                    *)
   782 
   783     fun transform_rule r =
   784       let
   785         val SOME (_, i, ts, (Ts, _)) =
   786           dest_predicate cs params (HOLogic.dest_Trueprop (Logic.strip_assums_concl r));
   787         val ps =
   788           make_bool_args HOLogic.mk_not I bs i @
   789           map HOLogic.mk_eq (make_args' argTs xs Ts ~~ ts) @
   790           map (subst o HOLogic.dest_Trueprop) (Logic.strip_assums_hyp r);
   791       in
   792         fold_rev (fn (x, T) => fn P => HOLogic.exists_const T $ Abs (x, T, P))
   793           (Logic.strip_params r)
   794           (if null ps then @{term True} else foldr1 HOLogic.mk_conj ps)
   795       end;
   796 
   797     (* make a disjunction of all introduction rules *)
   798 
   799     val fp_fun =
   800       fold_rev lambda (p :: bs @ xs)
   801         (if null intr_ts then @{term False}
   802          else foldr1 HOLogic.mk_disj (map transform_rule intr_ts));
   803 
   804     (* add definiton of recursive predicates to theory *)
   805 
   806     val rec_name =
   807       if Binding.is_empty alt_name then
   808         Binding.name (space_implode "_" (map (Binding.name_of o fst) cnames_syn))
   809       else alt_name;
   810 
   811     val ((rec_const, (_, fp_def)), lthy') = lthy
   812       |> Local_Theory.conceal
   813       |> Local_Theory.define
   814         ((rec_name, case cnames_syn of [(_, syn)] => syn | _ => NoSyn),
   815          ((Thm.def_binding rec_name, @{attributes [nitpick_unfold]}),
   816            fold_rev lambda params
   817              (Const (fp_name, (predT --> predT) --> predT) $ fp_fun)))
   818       ||> Local_Theory.restore_naming lthy;
   819     val fp_def' =
   820       Simplifier.rewrite (HOL_basic_ss addsimps [fp_def])
   821         (cterm_of (Proof_Context.theory_of lthy') (list_comb (rec_const, params)));
   822     val specs =
   823       if length cs < 2 then []
   824       else
   825         map_index (fn (i, (name_mx, c)) =>
   826           let
   827             val Ts = arg_types_of (length params) c;
   828             val xs =
   829               map Free (Variable.variant_frees lthy intr_ts (mk_names "x" (length Ts) ~~ Ts));
   830           in
   831             (name_mx, (apfst Binding.conceal Attrib.empty_binding, fold_rev lambda (params @ xs)
   832               (list_comb (rec_const, params @ make_bool_args' bs i @
   833                 make_args argTs (xs ~~ Ts)))))
   834           end) (cnames_syn ~~ cs);
   835     val (consts_defs, lthy'') = lthy'
   836       |> fold_map Local_Theory.define specs;
   837     val preds = (case cs of [_] => [rec_const] | _ => map #1 consts_defs);
   838 
   839     val (_, lthy''') = Variable.add_fixes (map (fst o dest_Free) params) lthy'';
   840     val mono = prove_mono quiet_mode skip_mono fork_mono predT fp_fun monos lthy''';
   841     val (_, lthy'''') =
   842       Local_Theory.note (apfst Binding.conceal Attrib.empty_binding,
   843         Proof_Context.export lthy''' lthy'' [mono]) lthy'';
   844 
   845   in (lthy'''', lthy''', rec_name, mono, fp_def', map (#2 o #2) consts_defs,
   846     list_comb (rec_const, params), preds, argTs, bs, xs)
   847   end;
   848 
   849 fun declare_rules rec_binding coind no_ind cnames
   850     preds intrs intr_bindings intr_atts elims eqs raw_induct lthy =
   851   let
   852     val rec_name = Binding.name_of rec_binding;
   853     fun rec_qualified qualified = Binding.qualify qualified rec_name;
   854     val intr_names = map Binding.name_of intr_bindings;
   855     val ind_case_names = Rule_Cases.case_names intr_names;
   856     val induct =
   857       if coind then
   858         (raw_induct, [Rule_Cases.case_names [rec_name],
   859           Rule_Cases.case_conclusion (rec_name, intr_names),
   860           Rule_Cases.consumes 1, Induct.coinduct_pred (hd cnames)])
   861       else if no_ind orelse length cnames > 1 then
   862         (raw_induct, [ind_case_names, Rule_Cases.consumes 0])
   863       else (raw_induct RSN (2, rev_mp), [ind_case_names, Rule_Cases.consumes 1]);
   864 
   865     val (intrs', lthy1) =
   866       lthy |>
   867       Spec_Rules.add
   868         (if coind then Spec_Rules.Co_Inductive else Spec_Rules.Inductive) (preds, intrs) |>
   869       Local_Theory.notes
   870         (map (rec_qualified false) intr_bindings ~~ intr_atts ~~
   871           map (fn th => [([th],
   872            [Attrib.internal (K (Context_Rules.intro_query NONE))])]) intrs) |>>
   873       map (hd o snd);
   874     val (((_, elims'), (_, [induct'])), lthy2) =
   875       lthy1 |>
   876       Local_Theory.note ((rec_qualified true (Binding.name "intros"), []), intrs') ||>>
   877       fold_map (fn (name, (elim, cases, k)) =>
   878         Local_Theory.note
   879           ((Binding.qualify true (Long_Name.base_name name) (Binding.name "cases"),
   880             [Attrib.internal (K (Rule_Cases.case_names cases)),
   881              Attrib.internal (K (Rule_Cases.consumes 1)),
   882              Attrib.internal (K (Rule_Cases.constraints k)),
   883              Attrib.internal (K (Induct.cases_pred name)),
   884              Attrib.internal (K (Context_Rules.elim_query NONE))]), [elim]) #>
   885         apfst (hd o snd)) (if null elims then [] else cnames ~~ elims) ||>>
   886       Local_Theory.note
   887         ((rec_qualified true (Binding.name (coind_prefix coind ^ "induct")),
   888           map (Attrib.internal o K) (#2 induct)), [rulify (#1 induct)]);
   889 
   890     val (eqs', lthy3) = lthy2 |>
   891       fold_map (fn (name, eq) => Local_Theory.note
   892           ((Binding.qualify true (Long_Name.base_name name) (Binding.name "simps"),
   893             [Attrib.internal (K equation_add_permissive)]), [eq])
   894           #> apfst (hd o snd))
   895         (if null eqs then [] else (cnames ~~ eqs))
   896     val (inducts, lthy4) =
   897       if no_ind orelse coind then ([], lthy3)
   898       else
   899         let val inducts = cnames ~~ Project_Rule.projects lthy3 (1 upto length cnames) induct' in
   900           lthy3 |>
   901           Local_Theory.notes [((rec_qualified true (Binding.name "inducts"), []),
   902             inducts |> map (fn (name, th) => ([th],
   903               [Attrib.internal (K ind_case_names),
   904                Attrib.internal (K (Rule_Cases.consumes 1)),
   905                Attrib.internal (K (Induct.induct_pred name))])))] |>> snd o hd
   906         end;
   907   in (intrs', elims', eqs', induct', inducts, lthy4) end;
   908 
   909 type inductive_flags =
   910   {quiet_mode: bool, verbose: bool, alt_name: binding, coind: bool,
   911     no_elim: bool, no_ind: bool, skip_mono: bool, fork_mono: bool};
   912 
   913 type add_ind_def =
   914   inductive_flags ->
   915   term list -> (Attrib.binding * term) list -> thm list ->
   916   term list -> (binding * mixfix) list ->
   917   local_theory -> inductive_result * local_theory;
   918 
   919 fun add_ind_def {quiet_mode, verbose, alt_name, coind, no_elim, no_ind, skip_mono, fork_mono}
   920     cs intros monos params cnames_syn lthy =
   921   let
   922     val _ = null cnames_syn andalso error "No inductive predicates given";
   923     val names = map (Binding.name_of o fst) cnames_syn;
   924     val _ = message (quiet_mode andalso not verbose)
   925       ("Proofs for " ^ coind_prefix coind ^ "inductive predicate(s) " ^ commas_quote names);
   926 
   927     val cnames = map (Local_Theory.full_name lthy o #1) cnames_syn;  (* FIXME *)
   928     val ((intr_names, intr_atts), intr_ts) =
   929       apfst split_list (split_list (map (check_rule lthy cs params) intros));
   930 
   931     val (lthy1, lthy2, rec_name, mono, fp_def, rec_preds_defs, rec_const, preds,
   932       argTs, bs, xs) = mk_ind_def quiet_mode skip_mono fork_mono alt_name coind cs intr_ts
   933         monos params cnames_syn lthy;
   934 
   935     val (intrs, unfold) = prove_intrs quiet_mode coind mono fp_def (length bs + length xs)
   936       intr_ts rec_preds_defs lthy2 lthy1;
   937     val elims =
   938       if no_elim then []
   939       else
   940         prove_elims quiet_mode cs params intr_ts (map Binding.name_of intr_names)
   941           unfold rec_preds_defs lthy2 lthy1;
   942     val raw_induct = zero_var_indexes
   943       (if no_ind then Drule.asm_rl
   944        else if coind then
   945          singleton (Proof_Context.export lthy2 lthy1)
   946            (rotate_prems ~1 (Object_Logic.rulify
   947              (fold_rule rec_preds_defs
   948                (rewrite_rule simp_thms3
   949                 (mono RS (fp_def RS @{thm def_coinduct}))))))
   950        else
   951          prove_indrule quiet_mode cs argTs bs xs rec_const params intr_ts mono fp_def
   952            rec_preds_defs lthy2 lthy1);
   953     val eqs =
   954       if no_elim then [] else prove_eqs quiet_mode cs params intr_ts intrs elims lthy2 lthy1;
   955 
   956     val elims' = map (fn (th, ns, i) => (rulify th, ns, i)) elims;
   957     val intrs' = map rulify intrs;
   958 
   959     val (intrs'', elims'', eqs', induct, inducts, lthy3) =
   960       declare_rules rec_name coind no_ind
   961         cnames preds intrs' intr_names intr_atts elims' eqs raw_induct lthy1;
   962 
   963     val result =
   964       {preds = preds,
   965        intrs = intrs'',
   966        elims = elims'',
   967        raw_induct = rulify raw_induct,
   968        induct = induct,
   969        inducts = inducts,
   970        eqs = eqs'};
   971 
   972     val lthy4 = lthy3
   973       |> Local_Theory.declaration {syntax = false, pervasive = false} (fn phi =>
   974         let val result' = transform_result phi result;
   975         in put_inductives cnames (*global names!?*) ({names = cnames, coind = coind}, result') end);
   976   in (result, lthy4) end;
   977 
   978 
   979 (* external interfaces *)
   980 
   981 fun gen_add_inductive_i mk_def
   982     (flags as {quiet_mode, verbose, alt_name, coind, no_elim, no_ind, skip_mono, fork_mono})
   983     cnames_syn pnames spec monos lthy =
   984   let
   985     val thy = Proof_Context.theory_of lthy;
   986     val _ = Theory.requires thy "Inductive" (coind_prefix coind ^ "inductive definitions");
   987 
   988 
   989     (* abbrevs *)
   990 
   991     val (_, ctxt1) = Variable.add_fixes (map (Binding.name_of o fst o fst) cnames_syn) lthy;
   992 
   993     fun get_abbrev ((name, atts), t) =
   994       if can (Logic.strip_assums_concl #> Logic.dest_equals) t then
   995         let
   996           val _ = Binding.is_empty name andalso null atts orelse
   997             error "Abbreviations may not have names or attributes";
   998           val ((x, T), rhs) = Local_Defs.abs_def (snd (Local_Defs.cert_def ctxt1 t));
   999           val var =
  1000             (case find_first (fn ((c, _), _) => Binding.name_of c = x) cnames_syn of
  1001               NONE => error ("Undeclared head of abbreviation " ^ quote x)
  1002             | SOME ((b, T'), mx) =>
  1003                 if T <> T' then error ("Bad type specification for abbreviation " ^ quote x)
  1004                 else (b, mx));
  1005         in SOME (var, rhs) end
  1006       else NONE;
  1007 
  1008     val abbrevs = map_filter get_abbrev spec;
  1009     val bs = map (Binding.name_of o fst o fst) abbrevs;
  1010 
  1011 
  1012     (* predicates *)
  1013 
  1014     val pre_intros = filter_out (is_some o get_abbrev) spec;
  1015     val cnames_syn' = filter_out (member (op =) bs o Binding.name_of o fst o fst) cnames_syn;
  1016     val cs = map (Free o apfst Binding.name_of o fst) cnames_syn';
  1017     val ps = map Free pnames;
  1018 
  1019     val (_, ctxt2) = lthy |> Variable.add_fixes (map (Binding.name_of o fst o fst) cnames_syn');
  1020     val _ = map (fn abbr => Local_Defs.fixed_abbrev abbr ctxt2) abbrevs;
  1021     val ctxt3 = ctxt2 |> fold (snd oo Local_Defs.fixed_abbrev) abbrevs;
  1022     val expand = Assumption.export_term ctxt3 lthy #> Proof_Context.cert_term lthy;
  1023 
  1024     fun close_rule r =
  1025       fold (Logic.all o Free) (fold_aterms
  1026         (fn t as Free (v as (s, _)) =>
  1027             if Variable.is_fixed ctxt1 s orelse
  1028               member (op =) ps t then I else insert (op =) v
  1029           | _ => I) r []) r;
  1030 
  1031     val intros = map (apsnd (Syntax.check_term lthy #> close_rule #> expand)) pre_intros;
  1032     val preds = map (fn ((c, _), mx) => (c, mx)) cnames_syn';
  1033   in
  1034     lthy
  1035     |> mk_def flags cs intros monos ps preds
  1036     ||> fold (snd oo Local_Theory.abbrev Syntax.mode_default) abbrevs
  1037   end;
  1038 
  1039 fun gen_add_inductive mk_def verbose coind cnames_syn pnames_syn intro_srcs raw_monos int lthy =
  1040   let
  1041     val ((vars, intrs), _) = lthy
  1042       |> Proof_Context.set_mode Proof_Context.mode_abbrev
  1043       |> Specification.read_spec (cnames_syn @ pnames_syn) intro_srcs;
  1044     val (cs, ps) = chop (length cnames_syn) vars;
  1045     val monos = Attrib.eval_thms lthy raw_monos;
  1046     val flags = {quiet_mode = false, verbose = verbose, alt_name = Binding.empty,
  1047       coind = coind, no_elim = false, no_ind = false, skip_mono = false, fork_mono = not int};
  1048   in
  1049     lthy
  1050     |> gen_add_inductive_i mk_def flags cs (map (apfst Binding.name_of o fst) ps) intrs monos
  1051   end;
  1052 
  1053 val add_inductive_i = gen_add_inductive_i add_ind_def;
  1054 val add_inductive = gen_add_inductive add_ind_def;
  1055 
  1056 fun add_inductive_global flags cnames_syn pnames pre_intros monos thy =
  1057   let
  1058     val name = Sign.full_name thy (fst (fst (hd cnames_syn)));
  1059     val ctxt' = thy
  1060       |> Named_Target.theory_init
  1061       |> add_inductive_i flags cnames_syn pnames pre_intros monos |> snd
  1062       |> Local_Theory.exit;
  1063     val info = #2 (the_inductive ctxt' name);
  1064   in (info, Proof_Context.theory_of ctxt') end;
  1065 
  1066 
  1067 (* read off arities of inductive predicates from raw induction rule *)
  1068 fun arities_of induct =
  1069   map (fn (_ $ t $ u) =>
  1070       (fst (dest_Const (head_of t)), length (snd (strip_comb u))))
  1071     (HOLogic.dest_conj (HOLogic.dest_Trueprop (concl_of induct)));
  1072 
  1073 (* read off parameters of inductive predicate from raw induction rule *)
  1074 fun params_of induct =
  1075   let
  1076     val (_ $ t $ u :: _) = HOLogic.dest_conj (HOLogic.dest_Trueprop (concl_of induct));
  1077     val (_, ts) = strip_comb t;
  1078     val (_, us) = strip_comb u;
  1079   in
  1080     List.take (ts, length ts - length us)
  1081   end;
  1082 
  1083 val pname_of_intr =
  1084   concl_of #> HOLogic.dest_Trueprop #> head_of #> dest_Const #> fst;
  1085 
  1086 (* partition introduction rules according to predicate name *)
  1087 fun gen_partition_rules f induct intros =
  1088   fold_rev (fn r => AList.map_entry op = (pname_of_intr (f r)) (cons r)) intros
  1089     (map (rpair [] o fst) (arities_of induct));
  1090 
  1091 val partition_rules = gen_partition_rules I;
  1092 fun partition_rules' induct = gen_partition_rules fst induct;
  1093 
  1094 fun unpartition_rules intros xs =
  1095   fold_map (fn r => AList.map_entry_yield op = (pname_of_intr r)
  1096     (fn x :: xs => (x, xs)) #>> the) intros xs |> fst;
  1097 
  1098 (* infer order of variables in intro rules from order of quantifiers in elim rule *)
  1099 fun infer_intro_vars elim arity intros =
  1100   let
  1101     val thy = theory_of_thm elim;
  1102     val _ :: cases = prems_of elim;
  1103     val used = map (fst o fst) (Term.add_vars (prop_of elim) []);
  1104     fun mtch (t, u) =
  1105       let
  1106         val params = Logic.strip_params t;
  1107         val vars =
  1108           map (Var o apfst (rpair 0))
  1109             (Name.variant_list used (map fst params) ~~ map snd params);
  1110         val ts =
  1111           map (curry subst_bounds (rev vars))
  1112             (List.drop (Logic.strip_assums_hyp t, arity));
  1113         val us = Logic.strip_imp_prems u;
  1114         val tab =
  1115           fold (Pattern.first_order_match thy) (ts ~~ us) (Vartab.empty, Vartab.empty);
  1116       in
  1117         map (Envir.subst_term tab) vars
  1118       end
  1119   in
  1120     map (mtch o apsnd prop_of) (cases ~~ intros)
  1121   end;
  1122 
  1123 
  1124 
  1125 (** package setup **)
  1126 
  1127 (* setup theory *)
  1128 
  1129 val setup =
  1130   ind_cases_setup #>
  1131   Attrib.setup @{binding mono} (Attrib.add_del mono_add mono_del)
  1132     "declaration of monotonicity rule";
  1133 
  1134 
  1135 (* outer syntax *)
  1136 
  1137 fun gen_ind_decl mk_def coind =
  1138   Parse.fixes -- Parse.for_fixes --
  1139   Scan.optional Parse_Spec.where_alt_specs [] --
  1140   Scan.optional (@{keyword "monos"} |-- Parse.!!! Parse_Spec.xthms1) []
  1141   >> (fn (((preds, params), specs), monos) =>
  1142       (snd oo gen_add_inductive mk_def true coind preds params specs monos));
  1143 
  1144 val ind_decl = gen_ind_decl add_ind_def;
  1145 
  1146 val _ =
  1147   Outer_Syntax.local_theory' @{command_spec "inductive"} "define inductive predicates"
  1148     (ind_decl false);
  1149 
  1150 val _ =
  1151   Outer_Syntax.local_theory' @{command_spec "coinductive"} "define coinductive predicates"
  1152     (ind_decl true);
  1153 
  1154 val _ =
  1155   Outer_Syntax.local_theory @{command_spec "inductive_cases"}
  1156     "create simplified instances of elimination rules (improper)"
  1157     (Parse.and_list1 Parse_Spec.specs >> (snd oo inductive_cases));
  1158 
  1159 val _ =
  1160   Outer_Syntax.local_theory @{command_spec "inductive_simps"}
  1161     "create simplification rules for inductive predicates"
  1162     (Parse.and_list1 Parse_Spec.specs >> (snd oo inductive_simps));
  1163 
  1164 end;