src/HOL/BNF/BNF_Def.thy
author hoelzl
Tue Nov 05 09:44:57 2013 +0100 (2013-11-05)
changeset 54257 5c7a3b6b05a9
parent 53561 92bcac4f9ac9
child 54421 632be352a5a3
permissions -rw-r--r--
generalize SUP and INF to the syntactic type classes Sup and Inf
     1 (*  Title:      HOL/BNF/BNF_Def.thy
     2     Author:     Dmitriy Traytel, TU Muenchen
     3     Copyright   2012
     4 
     5 Definition of bounded natural functors.
     6 *)
     7 
     8 header {* Definition of Bounded Natural Functors *}
     9 
    10 theory BNF_Def
    11 imports BNF_Util
    12 keywords
    13   "print_bnfs" :: diag and
    14   "bnf" :: thy_goal
    15 begin
    16 
    17 lemma collect_o: "collect F o g = collect ((\<lambda>f. f o g) ` F)"
    18   by (rule ext) (auto simp only: o_apply collect_def)
    19 
    20 definition convol ("<_ , _>") where
    21 "<f , g> \<equiv> %a. (f a, g a)"
    22 
    23 lemma fst_convol:
    24 "fst o <f , g> = f"
    25 apply(rule ext)
    26 unfolding convol_def by simp
    27 
    28 lemma snd_convol:
    29 "snd o <f , g> = g"
    30 apply(rule ext)
    31 unfolding convol_def by simp
    32 
    33 lemma convol_mem_GrpI:
    34 "x \<in> A \<Longrightarrow> <id , g> x \<in> (Collect (split (Grp A g)))"
    35 unfolding convol_def Grp_def by auto
    36 
    37 definition csquare where
    38 "csquare A f1 f2 p1 p2 \<longleftrightarrow> (\<forall> a \<in> A. f1 (p1 a) = f2 (p2 a))"
    39 
    40 (* The pullback of sets *)
    41 definition thePull where
    42 "thePull B1 B2 f1 f2 = {(b1,b2). b1 \<in> B1 \<and> b2 \<in> B2 \<and> f1 b1 = f2 b2}"
    43 
    44 lemma wpull_thePull:
    45 "wpull (thePull B1 B2 f1 f2) B1 B2 f1 f2 fst snd"
    46 unfolding wpull_def thePull_def by auto
    47 
    48 lemma wppull_thePull:
    49 assumes "wppull A B1 B2 f1 f2 e1 e2 p1 p2"
    50 shows
    51 "\<exists> j. \<forall> a' \<in> thePull B1 B2 f1 f2.
    52    j a' \<in> A \<and>
    53    e1 (p1 (j a')) = e1 (fst a') \<and> e2 (p2 (j a')) = e2 (snd a')"
    54 (is "\<exists> j. \<forall> a' \<in> ?A'. ?phi a' (j a')")
    55 proof(rule bchoice[of ?A' ?phi], default)
    56   fix a' assume a': "a' \<in> ?A'"
    57   hence "fst a' \<in> B1" unfolding thePull_def by auto
    58   moreover
    59   from a' have "snd a' \<in> B2" unfolding thePull_def by auto
    60   moreover have "f1 (fst a') = f2 (snd a')"
    61   using a' unfolding csquare_def thePull_def by auto
    62   ultimately show "\<exists> ja'. ?phi a' ja'"
    63   using assms unfolding wppull_def by blast
    64 qed
    65 
    66 lemma wpull_wppull:
    67 assumes wp: "wpull A' B1 B2 f1 f2 p1' p2'" and
    68 1: "\<forall> a' \<in> A'. j a' \<in> A \<and> e1 (p1 (j a')) = e1 (p1' a') \<and> e2 (p2 (j a')) = e2 (p2' a')"
    69 shows "wppull A B1 B2 f1 f2 e1 e2 p1 p2"
    70 unfolding wppull_def proof safe
    71   fix b1 b2
    72   assume b1: "b1 \<in> B1" and b2: "b2 \<in> B2" and f: "f1 b1 = f2 b2"
    73   then obtain a' where a': "a' \<in> A'" and b1: "b1 = p1' a'" and b2: "b2 = p2' a'"
    74   using wp unfolding wpull_def by blast
    75   show "\<exists>a\<in>A. e1 (p1 a) = e1 b1 \<and> e2 (p2 a) = e2 b2"
    76   apply (rule bexI[of _ "j a'"]) unfolding b1 b2 using a' 1 by auto
    77 qed
    78 
    79 lemma wppull_id: "\<lbrakk>wpull UNIV UNIV UNIV f1 f2 p1 p2; e1 = id; e2 = id\<rbrakk> \<Longrightarrow>
    80    wppull UNIV UNIV UNIV f1 f2 e1 e2 p1 p2"
    81 by (erule wpull_wppull) auto
    82 
    83 lemma eq_alt: "op = = Grp UNIV id"
    84 unfolding Grp_def by auto
    85 
    86 lemma leq_conversepI: "R = op = \<Longrightarrow> R \<le> R^--1"
    87   by auto
    88 
    89 lemma eq_OOI: "R = op = \<Longrightarrow> R = R OO R"
    90   by auto
    91 
    92 lemma OO_Grp_alt: "(Grp A f)^--1 OO Grp A g = (\<lambda>x y. \<exists>z. z \<in> A \<and> f z = x \<and> g z = y)"
    93   unfolding Grp_def by auto
    94 
    95 lemma Grp_UNIV_id: "f = id \<Longrightarrow> (Grp UNIV f)^--1 OO Grp UNIV f = Grp UNIV f"
    96 unfolding Grp_def by auto
    97 
    98 lemma Grp_UNIV_idI: "x = y \<Longrightarrow> Grp UNIV id x y"
    99 unfolding Grp_def by auto
   100 
   101 lemma Grp_mono: "A \<le> B \<Longrightarrow> Grp A f \<le> Grp B f"
   102 unfolding Grp_def by auto
   103 
   104 lemma GrpI: "\<lbrakk>f x = y; x \<in> A\<rbrakk> \<Longrightarrow> Grp A f x y"
   105 unfolding Grp_def by auto
   106 
   107 lemma GrpE: "Grp A f x y \<Longrightarrow> (\<lbrakk>f x = y; x \<in> A\<rbrakk> \<Longrightarrow> R) \<Longrightarrow> R"
   108 unfolding Grp_def by auto
   109 
   110 lemma Collect_split_Grp_eqD: "z \<in> Collect (split (Grp A f)) \<Longrightarrow> (f \<circ> fst) z = snd z"
   111 unfolding Grp_def o_def by auto
   112 
   113 lemma Collect_split_Grp_inD: "z \<in> Collect (split (Grp A f)) \<Longrightarrow> fst z \<in> A"
   114 unfolding Grp_def o_def by auto
   115 
   116 definition "pick_middlep P Q a c = (SOME b. P a b \<and> Q b c)"
   117 
   118 lemma pick_middlep:
   119 "(P OO Q) a c \<Longrightarrow> P a (pick_middlep P Q a c) \<and> Q (pick_middlep P Q a c) c"
   120 unfolding pick_middlep_def apply(rule someI_ex) by auto
   121 
   122 definition fstOp where "fstOp P Q ac = (fst ac, pick_middlep P Q (fst ac) (snd ac))"
   123 definition sndOp where "sndOp P Q ac = (pick_middlep P Q (fst ac) (snd ac), (snd ac))"
   124 
   125 lemma fstOp_in: "ac \<in> Collect (split (P OO Q)) \<Longrightarrow> fstOp P Q ac \<in> Collect (split P)"
   126 unfolding fstOp_def mem_Collect_eq
   127 by (subst (asm) surjective_pairing, unfold prod.cases) (erule pick_middlep[THEN conjunct1])
   128 
   129 lemma fst_fstOp: "fst bc = (fst \<circ> fstOp P Q) bc"
   130 unfolding comp_def fstOp_def by simp
   131 
   132 lemma snd_sndOp: "snd bc = (snd \<circ> sndOp P Q) bc"
   133 unfolding comp_def sndOp_def by simp
   134 
   135 lemma sndOp_in: "ac \<in> Collect (split (P OO Q)) \<Longrightarrow> sndOp P Q ac \<in> Collect (split Q)"
   136 unfolding sndOp_def mem_Collect_eq
   137 by (subst (asm) surjective_pairing, unfold prod.cases) (erule pick_middlep[THEN conjunct2])
   138 
   139 lemma csquare_fstOp_sndOp:
   140 "csquare (Collect (split (P OO Q))) snd fst (fstOp P Q) (sndOp P Q)"
   141 unfolding csquare_def fstOp_def sndOp_def using pick_middlep by simp
   142 
   143 lemma wppull_fstOp_sndOp:
   144 shows "wppull (Collect (split (P OO Q))) (Collect (split P)) (Collect (split Q))
   145   snd fst fst snd (fstOp P Q) (sndOp P Q)"
   146 using pick_middlep unfolding wppull_def fstOp_def sndOp_def relcompp.simps by auto
   147 
   148 lemma snd_fst_flip: "snd xy = (fst o (%(x, y). (y, x))) xy"
   149 by (simp split: prod.split)
   150 
   151 lemma fst_snd_flip: "fst xy = (snd o (%(x, y). (y, x))) xy"
   152 by (simp split: prod.split)
   153 
   154 lemma flip_pred: "A \<subseteq> Collect (split (R ^--1)) \<Longrightarrow> (%(x, y). (y, x)) ` A \<subseteq> Collect (split R)"
   155 by auto
   156 
   157 lemma Collect_split_mono: "A \<le> B \<Longrightarrow> Collect (split A) \<subseteq> Collect (split B)"
   158   by auto
   159 
   160 lemma Collect_split_mono_strong: 
   161   "\<lbrakk>\<forall>a\<in>fst ` A. \<forall>b \<in> snd ` A. P a b \<longrightarrow> Q a b; A \<subseteq> Collect (split P)\<rbrakk> \<Longrightarrow>
   162   A \<subseteq> Collect (split Q)"
   163   by fastforce
   164 
   165 lemma predicate2_eqD: "A = B \<Longrightarrow> A a b \<longleftrightarrow> B a b"
   166 by metis
   167 
   168 lemma sum_case_o_inj:
   169 "sum_case f g \<circ> Inl = f"
   170 "sum_case f g \<circ> Inr = g"
   171 by auto
   172 
   173 lemma card_order_csum_cone_cexp_def:
   174   "card_order r \<Longrightarrow> ( |A1| +c cone) ^c r = |Func UNIV (Inl ` A1 \<union> {Inr ()})|"
   175   unfolding cexp_def cone_def Field_csum Field_card_of by (auto dest: Field_card_order)
   176 
   177 lemma If_the_inv_into_in_Func:
   178   "\<lbrakk>inj_on g C; C \<subseteq> B \<union> {x}\<rbrakk> \<Longrightarrow>
   179   (\<lambda>i. if i \<in> g ` C then the_inv_into C g i else x) \<in> Func UNIV (B \<union> {x})"
   180 unfolding Func_def by (auto dest: the_inv_into_into)
   181 
   182 lemma If_the_inv_into_f_f:
   183   "\<lbrakk>i \<in> C; inj_on g C\<rbrakk> \<Longrightarrow>
   184   ((\<lambda>i. if i \<in> g ` C then the_inv_into C g i else x) o g) i = id i"
   185 unfolding Func_def by (auto elim: the_inv_into_f_f)
   186 
   187 definition vimage2p where
   188   "vimage2p f g R = (\<lambda>x y. R (f x) (g y))"
   189 
   190 lemma vimage2pI: "R (f x) (g y) \<Longrightarrow> vimage2p f g R x y"
   191   unfolding vimage2p_def by -
   192 
   193 lemma vimage2pD: "vimage2p f g R x y \<Longrightarrow> R (f x) (g y)"
   194   unfolding vimage2p_def by -
   195 
   196 lemma fun_rel_iff_leq_vimage2p: "(fun_rel R S) f g = (R \<le> vimage2p f g S)"
   197   unfolding fun_rel_def vimage2p_def by auto
   198 
   199 lemma convol_image_vimage2p: "<f o fst, g o snd> ` Collect (split (vimage2p f g R)) \<subseteq> Collect (split R)"
   200   unfolding vimage2p_def convol_def by auto
   201 
   202 ML_file "Tools/bnf_def_tactics.ML"
   203 ML_file "Tools/bnf_def.ML"
   204 
   205 
   206 end