src/HOL/Complete_Lattices.thy
author hoelzl
Tue Nov 05 09:44:57 2013 +0100 (2013-11-05)
changeset 54257 5c7a3b6b05a9
parent 54147 97a8ff4e4ac9
child 54259 71c701dc5bf9
permissions -rw-r--r--
generalize SUP and INF to the syntactic type classes Sup and Inf
     1  (*  Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel; Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Complete lattices *}
     4 
     5 theory Complete_Lattices
     6 imports Set
     7 begin
     8 
     9 notation
    10   less_eq (infix "\<sqsubseteq>" 50) and
    11   less (infix "\<sqsubset>" 50)
    12 
    13 
    14 subsection {* Syntactic infimum and supremum operations *}
    15 
    16 class Inf =
    17   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
    18 begin
    19 
    20 definition INFI :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
    21   INF_def: "INFI A f = \<Sqinter>(f ` A)"
    22 
    23 end
    24 
    25 class Sup =
    26   fixes Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
    27 begin
    28 
    29 definition SUPR :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
    30   SUP_def: "SUPR A f = \<Squnion>(f ` A)"
    31 
    32 end
    33 
    34 text {*
    35   Note: must use names @{const INFI} and @{const SUPR} here instead of
    36   @{text INF} and @{text SUP} to allow the following syntax coexist
    37   with the plain constant names.
    38 *}
    39 
    40 syntax
    41   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3INF _./ _)" [0, 10] 10)
    42   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3INF _:_./ _)" [0, 0, 10] 10)
    43   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3SUP _./ _)" [0, 10] 10)
    44   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3SUP _:_./ _)" [0, 0, 10] 10)
    45 
    46 syntax (xsymbols)
    47   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Sqinter>_./ _)" [0, 10] 10)
    48   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Sqinter>_\<in>_./ _)" [0, 0, 10] 10)
    49   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Squnion>_./ _)" [0, 10] 10)
    50   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Squnion>_\<in>_./ _)" [0, 0, 10] 10)
    51 
    52 translations
    53   "INF x y. B"   == "INF x. INF y. B"
    54   "INF x. B"     == "CONST INFI CONST UNIV (%x. B)"
    55   "INF x. B"     == "INF x:CONST UNIV. B"
    56   "INF x:A. B"   == "CONST INFI A (%x. B)"
    57   "SUP x y. B"   == "SUP x. SUP y. B"
    58   "SUP x. B"     == "CONST SUPR CONST UNIV (%x. B)"
    59   "SUP x. B"     == "SUP x:CONST UNIV. B"
    60   "SUP x:A. B"   == "CONST SUPR A (%x. B)"
    61 
    62 print_translation {*
    63   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
    64     Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
    65 *} -- {* to avoid eta-contraction of body *}
    66 
    67 subsection {* Abstract complete lattices *}
    68 
    69 text {* A complete lattice always has a bottom and a top,
    70 so we include them into the following type class,
    71 along with assumptions that define bottom and top
    72 in terms of infimum and supremum. *}
    73 
    74 class complete_lattice = lattice + Inf + Sup + bot + top +
    75   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
    76      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
    77   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
    78      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
    79   assumes Inf_empty [simp]: "\<Sqinter>{} = \<top>"
    80   assumes Sup_empty [simp]: "\<Squnion>{} = \<bottom>"
    81 begin
    82 
    83 subclass bounded_lattice
    84 proof
    85   fix a
    86   show "\<bottom> \<le> a" by (auto intro: Sup_least simp only: Sup_empty [symmetric])
    87   show "a \<le> \<top>" by (auto intro: Inf_greatest simp only: Inf_empty [symmetric])
    88 qed
    89 
    90 lemma dual_complete_lattice:
    91   "class.complete_lattice Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
    92   by (auto intro!: class.complete_lattice.intro dual_lattice)
    93     (unfold_locales, (fact Inf_empty Sup_empty
    94         Sup_upper Sup_least Inf_lower Inf_greatest)+)
    95 
    96 end
    97 
    98 context complete_lattice
    99 begin
   100 
   101 lemma INF_foundation_dual:
   102   "Sup.SUPR Inf = INFI"
   103   by (simp add: fun_eq_iff INF_def Sup.SUP_def)
   104 
   105 lemma SUP_foundation_dual:
   106   "Inf.INFI Sup = SUPR" by (simp add: fun_eq_iff SUP_def Inf.INF_def)
   107 
   108 lemma Sup_eqI:
   109   "(\<And>y. y \<in> A \<Longrightarrow> y \<le> x) \<Longrightarrow> (\<And>y. (\<And>z. z \<in> A \<Longrightarrow> z \<le> y) \<Longrightarrow> x \<le> y) \<Longrightarrow> \<Squnion>A = x"
   110   by (blast intro: antisym Sup_least Sup_upper)
   111 
   112 lemma Inf_eqI:
   113   "(\<And>i. i \<in> A \<Longrightarrow> x \<le> i) \<Longrightarrow> (\<And>y. (\<And>i. i \<in> A \<Longrightarrow> y \<le> i) \<Longrightarrow> y \<le> x) \<Longrightarrow> \<Sqinter>A = x"
   114   by (blast intro: antisym Inf_greatest Inf_lower)
   115 
   116 lemma SUP_eqI:
   117   "(\<And>i. i \<in> A \<Longrightarrow> f i \<le> x) \<Longrightarrow> (\<And>y. (\<And>i. i \<in> A \<Longrightarrow> f i \<le> y) \<Longrightarrow> x \<le> y) \<Longrightarrow> (\<Squnion>i\<in>A. f i) = x"
   118   unfolding SUP_def by (rule Sup_eqI) auto
   119 
   120 lemma INF_eqI:
   121   "(\<And>i. i \<in> A \<Longrightarrow> x \<le> f i) \<Longrightarrow> (\<And>y. (\<And>i. i \<in> A \<Longrightarrow> f i \<ge> y) \<Longrightarrow> x \<ge> y) \<Longrightarrow> (\<Sqinter>i\<in>A. f i) = x"
   122   unfolding INF_def by (rule Inf_eqI) auto
   123 
   124 lemma INF_lower: "i \<in> A \<Longrightarrow> (\<Sqinter>i\<in>A. f i) \<sqsubseteq> f i"
   125   by (auto simp add: INF_def intro: Inf_lower)
   126 
   127 lemma INF_greatest: "(\<And>i. i \<in> A \<Longrightarrow> u \<sqsubseteq> f i) \<Longrightarrow> u \<sqsubseteq> (\<Sqinter>i\<in>A. f i)"
   128   by (auto simp add: INF_def intro: Inf_greatest)
   129 
   130 lemma SUP_upper: "i \<in> A \<Longrightarrow> f i \<sqsubseteq> (\<Squnion>i\<in>A. f i)"
   131   by (auto simp add: SUP_def intro: Sup_upper)
   132 
   133 lemma SUP_least: "(\<And>i. i \<in> A \<Longrightarrow> f i \<sqsubseteq> u) \<Longrightarrow> (\<Squnion>i\<in>A. f i) \<sqsubseteq> u"
   134   by (auto simp add: SUP_def intro: Sup_least)
   135 
   136 lemma Inf_lower2: "u \<in> A \<Longrightarrow> u \<sqsubseteq> v \<Longrightarrow> \<Sqinter>A \<sqsubseteq> v"
   137   using Inf_lower [of u A] by auto
   138 
   139 lemma INF_lower2: "i \<in> A \<Longrightarrow> f i \<sqsubseteq> u \<Longrightarrow> (\<Sqinter>i\<in>A. f i) \<sqsubseteq> u"
   140   using INF_lower [of i A f] by auto
   141 
   142 lemma Sup_upper2: "u \<in> A \<Longrightarrow> v \<sqsubseteq> u \<Longrightarrow> v \<sqsubseteq> \<Squnion>A"
   143   using Sup_upper [of u A] by auto
   144 
   145 lemma SUP_upper2: "i \<in> A \<Longrightarrow> u \<sqsubseteq> f i \<Longrightarrow> u \<sqsubseteq> (\<Squnion>i\<in>A. f i)"
   146   using SUP_upper [of i A f] by auto
   147 
   148 lemma le_Inf_iff: "b \<sqsubseteq> \<Sqinter>A \<longleftrightarrow> (\<forall>a\<in>A. b \<sqsubseteq> a)"
   149   by (auto intro: Inf_greatest dest: Inf_lower)
   150 
   151 lemma le_INF_iff: "u \<sqsubseteq> (\<Sqinter>i\<in>A. f i) \<longleftrightarrow> (\<forall>i\<in>A. u \<sqsubseteq> f i)"
   152   by (auto simp add: INF_def le_Inf_iff)
   153 
   154 lemma Sup_le_iff: "\<Squnion>A \<sqsubseteq> b \<longleftrightarrow> (\<forall>a\<in>A. a \<sqsubseteq> b)"
   155   by (auto intro: Sup_least dest: Sup_upper)
   156 
   157 lemma SUP_le_iff: "(\<Squnion>i\<in>A. f i) \<sqsubseteq> u \<longleftrightarrow> (\<forall>i\<in>A. f i \<sqsubseteq> u)"
   158   by (auto simp add: SUP_def Sup_le_iff)
   159 
   160 lemma Inf_insert [simp]: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
   161   by (auto intro: le_infI le_infI1 le_infI2 antisym Inf_greatest Inf_lower)
   162 
   163 lemma INF_insert: "(\<Sqinter>x\<in>insert a A. f x) = f a \<sqinter> INFI A f"
   164   by (simp add: INF_def)
   165 
   166 lemma Sup_insert [simp]: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
   167   by (auto intro: le_supI le_supI1 le_supI2 antisym Sup_least Sup_upper)
   168 
   169 lemma SUP_insert: "(\<Squnion>x\<in>insert a A. f x) = f a \<squnion> SUPR A f"
   170   by (simp add: SUP_def)
   171 
   172 lemma INF_empty [simp]: "(\<Sqinter>x\<in>{}. f x) = \<top>"
   173   by (simp add: INF_def)
   174 
   175 lemma SUP_empty [simp]: "(\<Squnion>x\<in>{}. f x) = \<bottom>"
   176   by (simp add: SUP_def)
   177 
   178 lemma Inf_UNIV [simp]:
   179   "\<Sqinter>UNIV = \<bottom>"
   180   by (auto intro!: antisym Inf_lower)
   181 
   182 lemma Sup_UNIV [simp]:
   183   "\<Squnion>UNIV = \<top>"
   184   by (auto intro!: antisym Sup_upper)
   185 
   186 lemma INF_image [simp]: "(\<Sqinter>x\<in>f`A. g x) = (\<Sqinter>x\<in>A. g (f x))"
   187   by (simp add: INF_def image_image)
   188 
   189 lemma SUP_image [simp]: "(\<Squnion>x\<in>f`A. g x) = (\<Squnion>x\<in>A. g (f x))"
   190   by (simp add: SUP_def image_image)
   191 
   192 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<sqsubseteq> a}"
   193   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
   194 
   195 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<sqsubseteq> b}"
   196   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
   197 
   198 lemma Inf_superset_mono: "B \<subseteq> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> \<Sqinter>B"
   199   by (auto intro: Inf_greatest Inf_lower)
   200 
   201 lemma Sup_subset_mono: "A \<subseteq> B \<Longrightarrow> \<Squnion>A \<sqsubseteq> \<Squnion>B"
   202   by (auto intro: Sup_least Sup_upper)
   203 
   204 lemma INF_cong:
   205   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Sqinter>x\<in>A. C x) = (\<Sqinter>x\<in>B. D x)"
   206   by (simp add: INF_def image_def)
   207 
   208 lemma SUP_cong:
   209   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Squnion>x\<in>A. C x) = (\<Squnion>x\<in>B. D x)"
   210   by (simp add: SUP_def image_def)
   211 
   212 lemma Inf_mono:
   213   assumes "\<And>b. b \<in> B \<Longrightarrow> \<exists>a\<in>A. a \<sqsubseteq> b"
   214   shows "\<Sqinter>A \<sqsubseteq> \<Sqinter>B"
   215 proof (rule Inf_greatest)
   216   fix b assume "b \<in> B"
   217   with assms obtain a where "a \<in> A" and "a \<sqsubseteq> b" by blast
   218   from `a \<in> A` have "\<Sqinter>A \<sqsubseteq> a" by (rule Inf_lower)
   219   with `a \<sqsubseteq> b` show "\<Sqinter>A \<sqsubseteq> b" by auto
   220 qed
   221 
   222 lemma INF_mono:
   223   "(\<And>m. m \<in> B \<Longrightarrow> \<exists>n\<in>A. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Sqinter>n\<in>A. f n) \<sqsubseteq> (\<Sqinter>n\<in>B. g n)"
   224   unfolding INF_def by (rule Inf_mono) fast
   225 
   226 lemma Sup_mono:
   227   assumes "\<And>a. a \<in> A \<Longrightarrow> \<exists>b\<in>B. a \<sqsubseteq> b"
   228   shows "\<Squnion>A \<sqsubseteq> \<Squnion>B"
   229 proof (rule Sup_least)
   230   fix a assume "a \<in> A"
   231   with assms obtain b where "b \<in> B" and "a \<sqsubseteq> b" by blast
   232   from `b \<in> B` have "b \<sqsubseteq> \<Squnion>B" by (rule Sup_upper)
   233   with `a \<sqsubseteq> b` show "a \<sqsubseteq> \<Squnion>B" by auto
   234 qed
   235 
   236 lemma SUP_mono:
   237   "(\<And>n. n \<in> A \<Longrightarrow> \<exists>m\<in>B. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Squnion>n\<in>A. f n) \<sqsubseteq> (\<Squnion>n\<in>B. g n)"
   238   unfolding SUP_def by (rule Sup_mono) fast
   239 
   240 lemma INF_superset_mono:
   241   "B \<subseteq> A \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> f x \<sqsubseteq> g x) \<Longrightarrow> (\<Sqinter>x\<in>A. f x) \<sqsubseteq> (\<Sqinter>x\<in>B. g x)"
   242   -- {* The last inclusion is POSITIVE! *}
   243   by (blast intro: INF_mono dest: subsetD)
   244 
   245 lemma SUP_subset_mono:
   246   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<sqsubseteq> g x) \<Longrightarrow> (\<Squnion>x\<in>A. f x) \<sqsubseteq> (\<Squnion>x\<in>B. g x)"
   247   by (blast intro: SUP_mono dest: subsetD)
   248 
   249 lemma Inf_less_eq:
   250   assumes "\<And>v. v \<in> A \<Longrightarrow> v \<sqsubseteq> u"
   251     and "A \<noteq> {}"
   252   shows "\<Sqinter>A \<sqsubseteq> u"
   253 proof -
   254   from `A \<noteq> {}` obtain v where "v \<in> A" by blast
   255   moreover from `v \<in> A` assms(1) have "v \<sqsubseteq> u" by blast
   256   ultimately show ?thesis by (rule Inf_lower2)
   257 qed
   258 
   259 lemma less_eq_Sup:
   260   assumes "\<And>v. v \<in> A \<Longrightarrow> u \<sqsubseteq> v"
   261     and "A \<noteq> {}"
   262   shows "u \<sqsubseteq> \<Squnion>A"
   263 proof -
   264   from `A \<noteq> {}` obtain v where "v \<in> A" by blast
   265   moreover from `v \<in> A` assms(1) have "u \<sqsubseteq> v" by blast
   266   ultimately show ?thesis by (rule Sup_upper2)
   267 qed
   268 
   269 lemma SUPR_eq:
   270   assumes "\<And>i. i \<in> A \<Longrightarrow> \<exists>j\<in>B. f i \<le> g j"
   271   assumes "\<And>j. j \<in> B \<Longrightarrow> \<exists>i\<in>A. g j \<le> f i"
   272   shows "(SUP i:A. f i) = (SUP j:B. g j)"
   273   by (intro antisym SUP_least) (blast intro: SUP_upper2 dest: assms)+
   274 
   275 lemma INFI_eq:
   276   assumes "\<And>i. i \<in> A \<Longrightarrow> \<exists>j\<in>B. f i \<ge> g j"
   277   assumes "\<And>j. j \<in> B \<Longrightarrow> \<exists>i\<in>A. g j \<ge> f i"
   278   shows "(INF i:A. f i) = (INF j:B. g j)"
   279   by (intro antisym INF_greatest) (blast intro: INF_lower2 dest: assms)+
   280 
   281 lemma less_eq_Inf_inter: "\<Sqinter>A \<squnion> \<Sqinter>B \<sqsubseteq> \<Sqinter>(A \<inter> B)"
   282   by (auto intro: Inf_greatest Inf_lower)
   283 
   284 lemma Sup_inter_less_eq: "\<Squnion>(A \<inter> B) \<sqsubseteq> \<Squnion>A \<sqinter> \<Squnion>B "
   285   by (auto intro: Sup_least Sup_upper)
   286 
   287 lemma Inf_union_distrib: "\<Sqinter>(A \<union> B) = \<Sqinter>A \<sqinter> \<Sqinter>B"
   288   by (rule antisym) (auto intro: Inf_greatest Inf_lower le_infI1 le_infI2)
   289 
   290 lemma INF_union:
   291   "(\<Sqinter>i \<in> A \<union> B. M i) = (\<Sqinter>i \<in> A. M i) \<sqinter> (\<Sqinter>i\<in>B. M i)"
   292   by (auto intro!: antisym INF_mono intro: le_infI1 le_infI2 INF_greatest INF_lower)
   293 
   294 lemma Sup_union_distrib: "\<Squnion>(A \<union> B) = \<Squnion>A \<squnion> \<Squnion>B"
   295   by (rule antisym) (auto intro: Sup_least Sup_upper le_supI1 le_supI2)
   296 
   297 lemma SUP_union:
   298   "(\<Squnion>i \<in> A \<union> B. M i) = (\<Squnion>i \<in> A. M i) \<squnion> (\<Squnion>i\<in>B. M i)"
   299   by (auto intro!: antisym SUP_mono intro: le_supI1 le_supI2 SUP_least SUP_upper)
   300 
   301 lemma INF_inf_distrib: "(\<Sqinter>a\<in>A. f a) \<sqinter> (\<Sqinter>a\<in>A. g a) = (\<Sqinter>a\<in>A. f a \<sqinter> g a)"
   302   by (rule antisym) (rule INF_greatest, auto intro: le_infI1 le_infI2 INF_lower INF_mono)
   303 
   304 lemma SUP_sup_distrib: "(\<Squnion>a\<in>A. f a) \<squnion> (\<Squnion>a\<in>A. g a) = (\<Squnion>a\<in>A. f a \<squnion> g a)" (is "?L = ?R")
   305 proof (rule antisym)
   306   show "?L \<le> ?R" by (auto intro: le_supI1 le_supI2 SUP_upper SUP_mono)
   307 next
   308   show "?R \<le> ?L" by (rule SUP_least) (auto intro: le_supI1 le_supI2 SUP_upper)
   309 qed
   310 
   311 lemma Inf_top_conv [simp]:
   312   "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   313   "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   314 proof -
   315   show "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   316   proof
   317     assume "\<forall>x\<in>A. x = \<top>"
   318     then have "A = {} \<or> A = {\<top>}" by auto
   319     then show "\<Sqinter>A = \<top>" by auto
   320   next
   321     assume "\<Sqinter>A = \<top>"
   322     show "\<forall>x\<in>A. x = \<top>"
   323     proof (rule ccontr)
   324       assume "\<not> (\<forall>x\<in>A. x = \<top>)"
   325       then obtain x where "x \<in> A" and "x \<noteq> \<top>" by blast
   326       then obtain B where "A = insert x B" by blast
   327       with `\<Sqinter>A = \<top>` `x \<noteq> \<top>` show False by simp
   328     qed
   329   qed
   330   then show "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)" by auto
   331 qed
   332 
   333 lemma INF_top_conv [simp]:
   334  "(\<Sqinter>x\<in>A. B x) = \<top> \<longleftrightarrow> (\<forall>x\<in>A. B x = \<top>)"
   335  "\<top> = (\<Sqinter>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = \<top>)"
   336   by (auto simp add: INF_def)
   337 
   338 lemma Sup_bot_conv [simp]:
   339   "\<Squnion>A = \<bottom> \<longleftrightarrow> (\<forall>x\<in>A. x = \<bottom>)" (is ?P)
   340   "\<bottom> = \<Squnion>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<bottom>)" (is ?Q)
   341   using dual_complete_lattice
   342   by (rule complete_lattice.Inf_top_conv)+
   343 
   344 lemma SUP_bot_conv [simp]:
   345  "(\<Squnion>x\<in>A. B x) = \<bottom> \<longleftrightarrow> (\<forall>x\<in>A. B x = \<bottom>)"
   346  "\<bottom> = (\<Squnion>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = \<bottom>)"
   347   by (auto simp add: SUP_def)
   348 
   349 lemma INF_const [simp]: "A \<noteq> {} \<Longrightarrow> (\<Sqinter>i\<in>A. f) = f"
   350   by (auto intro: antisym INF_lower INF_greatest)
   351 
   352 lemma SUP_const [simp]: "A \<noteq> {} \<Longrightarrow> (\<Squnion>i\<in>A. f) = f"
   353   by (auto intro: antisym SUP_upper SUP_least)
   354 
   355 lemma INF_top [simp]: "(\<Sqinter>x\<in>A. \<top>) = \<top>"
   356   by (cases "A = {}") simp_all
   357 
   358 lemma SUP_bot [simp]: "(\<Squnion>x\<in>A. \<bottom>) = \<bottom>"
   359   by (cases "A = {}") simp_all
   360 
   361 lemma INF_commute: "(\<Sqinter>i\<in>A. \<Sqinter>j\<in>B. f i j) = (\<Sqinter>j\<in>B. \<Sqinter>i\<in>A. f i j)"
   362   by (iprover intro: INF_lower INF_greatest order_trans antisym)
   363 
   364 lemma SUP_commute: "(\<Squnion>i\<in>A. \<Squnion>j\<in>B. f i j) = (\<Squnion>j\<in>B. \<Squnion>i\<in>A. f i j)"
   365   by (iprover intro: SUP_upper SUP_least order_trans antisym)
   366 
   367 lemma INF_absorb:
   368   assumes "k \<in> I"
   369   shows "A k \<sqinter> (\<Sqinter>i\<in>I. A i) = (\<Sqinter>i\<in>I. A i)"
   370 proof -
   371   from assms obtain J where "I = insert k J" by blast
   372   then show ?thesis by (simp add: INF_insert)
   373 qed
   374 
   375 lemma SUP_absorb:
   376   assumes "k \<in> I"
   377   shows "A k \<squnion> (\<Squnion>i\<in>I. A i) = (\<Squnion>i\<in>I. A i)"
   378 proof -
   379   from assms obtain J where "I = insert k J" by blast
   380   then show ?thesis by (simp add: SUP_insert)
   381 qed
   382 
   383 lemma INF_constant:
   384   "(\<Sqinter>y\<in>A. c) = (if A = {} then \<top> else c)"
   385   by simp
   386 
   387 lemma SUP_constant:
   388   "(\<Squnion>y\<in>A. c) = (if A = {} then \<bottom> else c)"
   389   by simp
   390 
   391 lemma less_INF_D:
   392   assumes "y < (\<Sqinter>i\<in>A. f i)" "i \<in> A" shows "y < f i"
   393 proof -
   394   note `y < (\<Sqinter>i\<in>A. f i)`
   395   also have "(\<Sqinter>i\<in>A. f i) \<le> f i" using `i \<in> A`
   396     by (rule INF_lower)
   397   finally show "y < f i" .
   398 qed
   399 
   400 lemma SUP_lessD:
   401   assumes "(\<Squnion>i\<in>A. f i) < y" "i \<in> A" shows "f i < y"
   402 proof -
   403   have "f i \<le> (\<Squnion>i\<in>A. f i)" using `i \<in> A`
   404     by (rule SUP_upper)
   405   also note `(\<Squnion>i\<in>A. f i) < y`
   406   finally show "f i < y" .
   407 qed
   408 
   409 lemma INF_UNIV_bool_expand:
   410   "(\<Sqinter>b. A b) = A True \<sqinter> A False"
   411   by (simp add: UNIV_bool INF_insert inf_commute)
   412 
   413 lemma SUP_UNIV_bool_expand:
   414   "(\<Squnion>b. A b) = A True \<squnion> A False"
   415   by (simp add: UNIV_bool SUP_insert sup_commute)
   416 
   417 lemma Inf_le_Sup: "A \<noteq> {} \<Longrightarrow> Inf A \<le> Sup A"
   418   by (blast intro: Sup_upper2 Inf_lower ex_in_conv)
   419 
   420 lemma INF_le_SUP: "A \<noteq> {} \<Longrightarrow> INFI A f \<le> SUPR A f"
   421   unfolding INF_def SUP_def by (rule Inf_le_Sup) auto
   422 
   423 end
   424 
   425 class complete_distrib_lattice = complete_lattice +
   426   assumes sup_Inf: "a \<squnion> \<Sqinter>B = (\<Sqinter>b\<in>B. a \<squnion> b)"
   427   assumes inf_Sup: "a \<sqinter> \<Squnion>B = (\<Squnion>b\<in>B. a \<sqinter> b)"
   428 begin
   429 
   430 lemma sup_INF:
   431   "a \<squnion> (\<Sqinter>b\<in>B. f b) = (\<Sqinter>b\<in>B. a \<squnion> f b)"
   432   by (simp add: INF_def sup_Inf image_image)
   433 
   434 lemma inf_SUP:
   435   "a \<sqinter> (\<Squnion>b\<in>B. f b) = (\<Squnion>b\<in>B. a \<sqinter> f b)"
   436   by (simp add: SUP_def inf_Sup image_image)
   437 
   438 lemma dual_complete_distrib_lattice:
   439   "class.complete_distrib_lattice Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
   440   apply (rule class.complete_distrib_lattice.intro)
   441   apply (fact dual_complete_lattice)
   442   apply (rule class.complete_distrib_lattice_axioms.intro)
   443   apply (simp_all only: INF_foundation_dual SUP_foundation_dual inf_Sup sup_Inf)
   444   done
   445 
   446 subclass distrib_lattice proof
   447   fix a b c
   448   from sup_Inf have "a \<squnion> \<Sqinter>{b, c} = (\<Sqinter>d\<in>{b, c}. a \<squnion> d)" .
   449   then show "a \<squnion> b \<sqinter> c = (a \<squnion> b) \<sqinter> (a \<squnion> c)" by (simp add: INF_def)
   450 qed
   451 
   452 lemma Inf_sup:
   453   "\<Sqinter>B \<squnion> a = (\<Sqinter>b\<in>B. b \<squnion> a)"
   454   by (simp add: sup_Inf sup_commute)
   455 
   456 lemma Sup_inf:
   457   "\<Squnion>B \<sqinter> a = (\<Squnion>b\<in>B. b \<sqinter> a)"
   458   by (simp add: inf_Sup inf_commute)
   459 
   460 lemma INF_sup: 
   461   "(\<Sqinter>b\<in>B. f b) \<squnion> a = (\<Sqinter>b\<in>B. f b \<squnion> a)"
   462   by (simp add: sup_INF sup_commute)
   463 
   464 lemma SUP_inf:
   465   "(\<Squnion>b\<in>B. f b) \<sqinter> a = (\<Squnion>b\<in>B. f b \<sqinter> a)"
   466   by (simp add: inf_SUP inf_commute)
   467 
   468 lemma Inf_sup_eq_top_iff:
   469   "(\<Sqinter>B \<squnion> a = \<top>) \<longleftrightarrow> (\<forall>b\<in>B. b \<squnion> a = \<top>)"
   470   by (simp only: Inf_sup INF_top_conv)
   471 
   472 lemma Sup_inf_eq_bot_iff:
   473   "(\<Squnion>B \<sqinter> a = \<bottom>) \<longleftrightarrow> (\<forall>b\<in>B. b \<sqinter> a = \<bottom>)"
   474   by (simp only: Sup_inf SUP_bot_conv)
   475 
   476 lemma INF_sup_distrib2:
   477   "(\<Sqinter>a\<in>A. f a) \<squnion> (\<Sqinter>b\<in>B. g b) = (\<Sqinter>a\<in>A. \<Sqinter>b\<in>B. f a \<squnion> g b)"
   478   by (subst INF_commute) (simp add: sup_INF INF_sup)
   479 
   480 lemma SUP_inf_distrib2:
   481   "(\<Squnion>a\<in>A. f a) \<sqinter> (\<Squnion>b\<in>B. g b) = (\<Squnion>a\<in>A. \<Squnion>b\<in>B. f a \<sqinter> g b)"
   482   by (subst SUP_commute) (simp add: inf_SUP SUP_inf)
   483 
   484 end
   485 
   486 class complete_boolean_algebra = boolean_algebra + complete_distrib_lattice
   487 begin
   488 
   489 lemma dual_complete_boolean_algebra:
   490   "class.complete_boolean_algebra Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom> (\<lambda>x y. x \<squnion> - y) uminus"
   491   by (rule class.complete_boolean_algebra.intro, rule dual_complete_distrib_lattice, rule dual_boolean_algebra)
   492 
   493 lemma uminus_Inf:
   494   "- (\<Sqinter>A) = \<Squnion>(uminus ` A)"
   495 proof (rule antisym)
   496   show "- \<Sqinter>A \<le> \<Squnion>(uminus ` A)"
   497     by (rule compl_le_swap2, rule Inf_greatest, rule compl_le_swap2, rule Sup_upper) simp
   498   show "\<Squnion>(uminus ` A) \<le> - \<Sqinter>A"
   499     by (rule Sup_least, rule compl_le_swap1, rule Inf_lower) auto
   500 qed
   501 
   502 lemma uminus_INF: "- (\<Sqinter>x\<in>A. B x) = (\<Squnion>x\<in>A. - B x)"
   503   by (simp add: INF_def SUP_def uminus_Inf image_image)
   504 
   505 lemma uminus_Sup:
   506   "- (\<Squnion>A) = \<Sqinter>(uminus ` A)"
   507 proof -
   508   have "\<Squnion>A = - \<Sqinter>(uminus ` A)" by (simp add: image_image uminus_Inf)
   509   then show ?thesis by simp
   510 qed
   511   
   512 lemma uminus_SUP: "- (\<Squnion>x\<in>A. B x) = (\<Sqinter>x\<in>A. - B x)"
   513   by (simp add: INF_def SUP_def uminus_Sup image_image)
   514 
   515 end
   516 
   517 class complete_linorder = linorder + complete_lattice
   518 begin
   519 
   520 lemma dual_complete_linorder:
   521   "class.complete_linorder Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
   522   by (rule class.complete_linorder.intro, rule dual_complete_lattice, rule dual_linorder)
   523 
   524 lemma complete_linorder_inf_min: "inf = min"
   525   by (auto intro: antisym simp add: min_def fun_eq_iff)
   526 
   527 lemma complete_linorder_sup_max: "sup = max"
   528   by (auto intro: antisym simp add: max_def fun_eq_iff)
   529 
   530 lemma Inf_less_iff:
   531   "\<Sqinter>S \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>S. x \<sqsubset> a)"
   532   unfolding not_le [symmetric] le_Inf_iff by auto
   533 
   534 lemma INF_less_iff:
   535   "(\<Sqinter>i\<in>A. f i) \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>A. f x \<sqsubset> a)"
   536   unfolding INF_def Inf_less_iff by auto
   537 
   538 lemma less_Sup_iff:
   539   "a \<sqsubset> \<Squnion>S \<longleftrightarrow> (\<exists>x\<in>S. a \<sqsubset> x)"
   540   unfolding not_le [symmetric] Sup_le_iff by auto
   541 
   542 lemma less_SUP_iff:
   543   "a \<sqsubset> (\<Squnion>i\<in>A. f i) \<longleftrightarrow> (\<exists>x\<in>A. a \<sqsubset> f x)"
   544   unfolding SUP_def less_Sup_iff by auto
   545 
   546 lemma Sup_eq_top_iff [simp]:
   547   "\<Squnion>A = \<top> \<longleftrightarrow> (\<forall>x<\<top>. \<exists>i\<in>A. x < i)"
   548 proof
   549   assume *: "\<Squnion>A = \<top>"
   550   show "(\<forall>x<\<top>. \<exists>i\<in>A. x < i)" unfolding * [symmetric]
   551   proof (intro allI impI)
   552     fix x assume "x < \<Squnion>A" then show "\<exists>i\<in>A. x < i"
   553       unfolding less_Sup_iff by auto
   554   qed
   555 next
   556   assume *: "\<forall>x<\<top>. \<exists>i\<in>A. x < i"
   557   show "\<Squnion>A = \<top>"
   558   proof (rule ccontr)
   559     assume "\<Squnion>A \<noteq> \<top>"
   560     with top_greatest [of "\<Squnion>A"]
   561     have "\<Squnion>A < \<top>" unfolding le_less by auto
   562     then have "\<Squnion>A < \<Squnion>A"
   563       using * unfolding less_Sup_iff by auto
   564     then show False by auto
   565   qed
   566 qed
   567 
   568 lemma SUP_eq_top_iff [simp]:
   569   "(\<Squnion>i\<in>A. f i) = \<top> \<longleftrightarrow> (\<forall>x<\<top>. \<exists>i\<in>A. x < f i)"
   570   unfolding SUP_def by auto
   571 
   572 lemma Inf_eq_bot_iff [simp]:
   573   "\<Sqinter>A = \<bottom> \<longleftrightarrow> (\<forall>x>\<bottom>. \<exists>i\<in>A. i < x)"
   574   using dual_complete_linorder
   575   by (rule complete_linorder.Sup_eq_top_iff)
   576 
   577 lemma INF_eq_bot_iff [simp]:
   578   "(\<Sqinter>i\<in>A. f i) = \<bottom> \<longleftrightarrow> (\<forall>x>\<bottom>. \<exists>i\<in>A. f i < x)"
   579   unfolding INF_def by auto
   580 
   581 lemma le_Sup_iff: "x \<le> \<Squnion>A \<longleftrightarrow> (\<forall>y<x. \<exists>a\<in>A. y < a)"
   582 proof safe
   583   fix y assume "x \<le> \<Squnion>A" "y < x"
   584   then have "y < \<Squnion>A" by auto
   585   then show "\<exists>a\<in>A. y < a"
   586     unfolding less_Sup_iff .
   587 qed (auto elim!: allE[of _ "\<Squnion>A"] simp add: not_le[symmetric] Sup_upper)
   588 
   589 lemma le_SUP_iff: "x \<le> SUPR A f \<longleftrightarrow> (\<forall>y<x. \<exists>i\<in>A. y < f i)"
   590   unfolding le_Sup_iff SUP_def by simp
   591 
   592 lemma Inf_le_iff: "\<Sqinter>A \<le> x \<longleftrightarrow> (\<forall>y>x. \<exists>a\<in>A. y > a)"
   593 proof safe
   594   fix y assume "x \<ge> \<Sqinter>A" "y > x"
   595   then have "y > \<Sqinter>A" by auto
   596   then show "\<exists>a\<in>A. y > a"
   597     unfolding Inf_less_iff .
   598 qed (auto elim!: allE[of _ "\<Sqinter>A"] simp add: not_le[symmetric] Inf_lower)
   599 
   600 lemma INF_le_iff:
   601   "INFI A f \<le> x \<longleftrightarrow> (\<forall>y>x. \<exists>i\<in>A. y > f i)"
   602   unfolding Inf_le_iff INF_def by simp
   603 
   604 subclass complete_distrib_lattice
   605 proof
   606   fix a and B
   607   show "a \<squnion> \<Sqinter>B = (\<Sqinter>b\<in>B. a \<squnion> b)" and "a \<sqinter> \<Squnion>B = (\<Squnion>b\<in>B. a \<sqinter> b)"
   608     by (safe intro!: INF_eqI [symmetric] sup_mono Inf_lower SUP_eqI [symmetric] inf_mono Sup_upper)
   609       (auto simp: not_less [symmetric] Inf_less_iff less_Sup_iff
   610         le_max_iff_disj complete_linorder_sup_max min_le_iff_disj complete_linorder_inf_min)
   611 qed
   612 
   613 end
   614 
   615 
   616 subsection {* Complete lattice on @{typ bool} *}
   617 
   618 instantiation bool :: complete_lattice
   619 begin
   620 
   621 definition
   622   [simp, code]: "\<Sqinter>A \<longleftrightarrow> False \<notin> A"
   623 
   624 definition
   625   [simp, code]: "\<Squnion>A \<longleftrightarrow> True \<in> A"
   626 
   627 instance proof
   628 qed (auto intro: bool_induct)
   629 
   630 end
   631 
   632 lemma not_False_in_image_Ball [simp]:
   633   "False \<notin> P ` A \<longleftrightarrow> Ball A P"
   634   by auto
   635 
   636 lemma True_in_image_Bex [simp]:
   637   "True \<in> P ` A \<longleftrightarrow> Bex A P"
   638   by auto
   639 
   640 lemma INF_bool_eq [simp]:
   641   "INFI = Ball"
   642   by (simp add: fun_eq_iff INF_def)
   643 
   644 lemma SUP_bool_eq [simp]:
   645   "SUPR = Bex"
   646   by (simp add: fun_eq_iff SUP_def)
   647 
   648 instance bool :: complete_boolean_algebra proof
   649 qed (auto intro: bool_induct)
   650 
   651 
   652 subsection {* Complete lattice on @{typ "_ \<Rightarrow> _"} *}
   653 
   654 instantiation "fun" :: (type, complete_lattice) complete_lattice
   655 begin
   656 
   657 definition
   658   "\<Sqinter>A = (\<lambda>x. \<Sqinter>f\<in>A. f x)"
   659 
   660 lemma Inf_apply [simp, code]:
   661   "(\<Sqinter>A) x = (\<Sqinter>f\<in>A. f x)"
   662   by (simp add: Inf_fun_def)
   663 
   664 definition
   665   "\<Squnion>A = (\<lambda>x. \<Squnion>f\<in>A. f x)"
   666 
   667 lemma Sup_apply [simp, code]:
   668   "(\<Squnion>A) x = (\<Squnion>f\<in>A. f x)"
   669   by (simp add: Sup_fun_def)
   670 
   671 instance proof
   672 qed (auto simp add: le_fun_def intro: INF_lower INF_greatest SUP_upper SUP_least)
   673 
   674 end
   675 
   676 lemma INF_apply [simp]:
   677   "(\<Sqinter>y\<in>A. f y) x = (\<Sqinter>y\<in>A. f y x)"
   678   by (auto intro: arg_cong [of _ _ Inf] simp add: INF_def)
   679 
   680 lemma SUP_apply [simp]:
   681   "(\<Squnion>y\<in>A. f y) x = (\<Squnion>y\<in>A. f y x)"
   682   by (auto intro: arg_cong [of _ _ Sup] simp add: SUP_def)
   683 
   684 instance "fun" :: (type, complete_distrib_lattice) complete_distrib_lattice proof
   685 qed (auto simp add: INF_def SUP_def inf_Sup sup_Inf image_image)
   686 
   687 instance "fun" :: (type, complete_boolean_algebra) complete_boolean_algebra ..
   688 
   689 
   690 subsection {* Complete lattice on unary and binary predicates *}
   691 
   692 lemma INF1_iff: "(\<Sqinter>x\<in>A. B x) b = (\<forall>x\<in>A. B x b)"
   693   by simp
   694 
   695 lemma INF2_iff: "(\<Sqinter>x\<in>A. B x) b c = (\<forall>x\<in>A. B x b c)"
   696   by simp
   697 
   698 lemma INF1_I: "(\<And>x. x \<in> A \<Longrightarrow> B x b) \<Longrightarrow> (\<Sqinter>x\<in>A. B x) b"
   699   by auto
   700 
   701 lemma INF2_I: "(\<And>x. x \<in> A \<Longrightarrow> B x b c) \<Longrightarrow> (\<Sqinter>x\<in>A. B x) b c"
   702   by auto
   703 
   704 lemma INF1_D: "(\<Sqinter>x\<in>A. B x) b \<Longrightarrow> a \<in> A \<Longrightarrow> B a b"
   705   by auto
   706 
   707 lemma INF2_D: "(\<Sqinter>x\<in>A. B x) b c \<Longrightarrow> a \<in> A \<Longrightarrow> B a b c"
   708   by auto
   709 
   710 lemma INF1_E: "(\<Sqinter>x\<in>A. B x) b \<Longrightarrow> (B a b \<Longrightarrow> R) \<Longrightarrow> (a \<notin> A \<Longrightarrow> R) \<Longrightarrow> R"
   711   by auto
   712 
   713 lemma INF2_E: "(\<Sqinter>x\<in>A. B x) b c \<Longrightarrow> (B a b c \<Longrightarrow> R) \<Longrightarrow> (a \<notin> A \<Longrightarrow> R) \<Longrightarrow> R"
   714   by auto
   715 
   716 lemma SUP1_iff: "(\<Squnion>x\<in>A. B x) b = (\<exists>x\<in>A. B x b)"
   717   by simp
   718 
   719 lemma SUP2_iff: "(\<Squnion>x\<in>A. B x) b c = (\<exists>x\<in>A. B x b c)"
   720   by simp
   721 
   722 lemma SUP1_I: "a \<in> A \<Longrightarrow> B a b \<Longrightarrow> (\<Squnion>x\<in>A. B x) b"
   723   by auto
   724 
   725 lemma SUP2_I: "a \<in> A \<Longrightarrow> B a b c \<Longrightarrow> (\<Squnion>x\<in>A. B x) b c"
   726   by auto
   727 
   728 lemma SUP1_E: "(\<Squnion>x\<in>A. B x) b \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> B x b \<Longrightarrow> R) \<Longrightarrow> R"
   729   by auto
   730 
   731 lemma SUP2_E: "(\<Squnion>x\<in>A. B x) b c \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> B x b c \<Longrightarrow> R) \<Longrightarrow> R"
   732   by auto
   733 
   734 
   735 subsection {* Complete lattice on @{typ "_ set"} *}
   736 
   737 instantiation "set" :: (type) complete_lattice
   738 begin
   739 
   740 definition
   741   "\<Sqinter>A = {x. \<Sqinter>((\<lambda>B. x \<in> B) ` A)}"
   742 
   743 definition
   744   "\<Squnion>A = {x. \<Squnion>((\<lambda>B. x \<in> B) ` A)}"
   745 
   746 instance proof
   747 qed (auto simp add: less_eq_set_def Inf_set_def Sup_set_def le_fun_def)
   748 
   749 end
   750 
   751 instance "set" :: (type) complete_boolean_algebra
   752 proof
   753 qed (auto simp add: INF_def SUP_def Inf_set_def Sup_set_def image_def)
   754   
   755 
   756 subsubsection {* Inter *}
   757 
   758 abbreviation Inter :: "'a set set \<Rightarrow> 'a set" where
   759   "Inter S \<equiv> \<Sqinter>S"
   760   
   761 notation (xsymbols)
   762   Inter  ("\<Inter>_" [900] 900)
   763 
   764 lemma Inter_eq:
   765   "\<Inter>A = {x. \<forall>B \<in> A. x \<in> B}"
   766 proof (rule set_eqI)
   767   fix x
   768   have "(\<forall>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<forall>B\<in>A. x \<in> B)"
   769     by auto
   770   then show "x \<in> \<Inter>A \<longleftrightarrow> x \<in> {x. \<forall>B \<in> A. x \<in> B}"
   771     by (simp add: Inf_set_def image_def)
   772 qed
   773 
   774 lemma Inter_iff [simp]: "A \<in> \<Inter>C \<longleftrightarrow> (\<forall>X\<in>C. A \<in> X)"
   775   by (unfold Inter_eq) blast
   776 
   777 lemma InterI [intro!]: "(\<And>X. X \<in> C \<Longrightarrow> A \<in> X) \<Longrightarrow> A \<in> \<Inter>C"
   778   by (simp add: Inter_eq)
   779 
   780 text {*
   781   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   782   contains @{term A} as an element, but @{prop "A \<in> X"} can hold when
   783   @{prop "X \<in> C"} does not!  This rule is analogous to @{text spec}.
   784 *}
   785 
   786 lemma InterD [elim, Pure.elim]: "A \<in> \<Inter>C \<Longrightarrow> X \<in> C \<Longrightarrow> A \<in> X"
   787   by auto
   788 
   789 lemma InterE [elim]: "A \<in> \<Inter>C \<Longrightarrow> (X \<notin> C \<Longrightarrow> R) \<Longrightarrow> (A \<in> X \<Longrightarrow> R) \<Longrightarrow> R"
   790   -- {* ``Classical'' elimination rule -- does not require proving
   791     @{prop "X \<in> C"}. *}
   792   by (unfold Inter_eq) blast
   793 
   794 lemma Inter_lower: "B \<in> A \<Longrightarrow> \<Inter>A \<subseteq> B"
   795   by (fact Inf_lower)
   796 
   797 lemma Inter_subset:
   798   "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> B) \<Longrightarrow> A \<noteq> {} \<Longrightarrow> \<Inter>A \<subseteq> B"
   799   by (fact Inf_less_eq)
   800 
   801 lemma Inter_greatest: "(\<And>X. X \<in> A \<Longrightarrow> C \<subseteq> X) \<Longrightarrow> C \<subseteq> Inter A"
   802   by (fact Inf_greatest)
   803 
   804 lemma Inter_empty: "\<Inter>{} = UNIV"
   805   by (fact Inf_empty) (* already simp *)
   806 
   807 lemma Inter_UNIV: "\<Inter>UNIV = {}"
   808   by (fact Inf_UNIV) (* already simp *)
   809 
   810 lemma Inter_insert: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
   811   by (fact Inf_insert) (* already simp *)
   812 
   813 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
   814   by (fact less_eq_Inf_inter)
   815 
   816 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
   817   by (fact Inf_union_distrib)
   818 
   819 lemma Inter_UNIV_conv [simp]:
   820   "\<Inter>A = UNIV \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   821   "UNIV = \<Inter>A \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   822   by (fact Inf_top_conv)+
   823 
   824 lemma Inter_anti_mono: "B \<subseteq> A \<Longrightarrow> \<Inter>A \<subseteq> \<Inter>B"
   825   by (fact Inf_superset_mono)
   826 
   827 
   828 subsubsection {* Intersections of families *}
   829 
   830 abbreviation INTER :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   831   "INTER \<equiv> INFI"
   832 
   833 text {*
   834   Note: must use name @{const INTER} here instead of @{text INT}
   835   to allow the following syntax coexist with the plain constant name.
   836 *}
   837 
   838 syntax
   839   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" [0, 10] 10)
   840   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" [0, 0, 10] 10)
   841 
   842 syntax (xsymbols)
   843   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" [0, 10] 10)
   844   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" [0, 0, 10] 10)
   845 
   846 syntax (latex output)
   847   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   848   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   849 
   850 translations
   851   "INT x y. B"  == "INT x. INT y. B"
   852   "INT x. B"    == "CONST INTER CONST UNIV (%x. B)"
   853   "INT x. B"    == "INT x:CONST UNIV. B"
   854   "INT x:A. B"  == "CONST INTER A (%x. B)"
   855 
   856 print_translation {*
   857   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INTER} @{syntax_const "_INTER"}]
   858 *} -- {* to avoid eta-contraction of body *}
   859 
   860 lemma INTER_eq:
   861   "(\<Inter>x\<in>A. B x) = {y. \<forall>x\<in>A. y \<in> B x}"
   862   by (auto simp add: INF_def)
   863 
   864 lemma Inter_image_eq [simp]:
   865   "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
   866   by (rule sym) (fact INF_def)
   867 
   868 lemma INT_iff [simp]: "b \<in> (\<Inter>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. b \<in> B x)"
   869   by (auto simp add: INF_def image_def)
   870 
   871 lemma INT_I [intro!]: "(\<And>x. x \<in> A \<Longrightarrow> b \<in> B x) \<Longrightarrow> b \<in> (\<Inter>x\<in>A. B x)"
   872   by (auto simp add: INF_def image_def)
   873 
   874 lemma INT_D [elim, Pure.elim]: "b \<in> (\<Inter>x\<in>A. B x) \<Longrightarrow> a \<in> A \<Longrightarrow> b \<in> B a"
   875   by auto
   876 
   877 lemma INT_E [elim]: "b \<in> (\<Inter>x\<in>A. B x) \<Longrightarrow> (b \<in> B a \<Longrightarrow> R) \<Longrightarrow> (a \<notin> A \<Longrightarrow> R) \<Longrightarrow> R"
   878   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a\<in>A"}. *}
   879   by (auto simp add: INF_def image_def)
   880 
   881 lemma INT_cong [cong]:
   882   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Inter>x\<in>A. C x) = (\<Inter>x\<in>B. D x)"
   883   by (fact INF_cong)
   884 
   885 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
   886   by blast
   887 
   888 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
   889   by blast
   890 
   891 lemma INT_lower: "a \<in> A \<Longrightarrow> (\<Inter>x\<in>A. B x) \<subseteq> B a"
   892   by (fact INF_lower)
   893 
   894 lemma INT_greatest: "(\<And>x. x \<in> A \<Longrightarrow> C \<subseteq> B x) \<Longrightarrow> C \<subseteq> (\<Inter>x\<in>A. B x)"
   895   by (fact INF_greatest)
   896 
   897 lemma INT_empty: "(\<Inter>x\<in>{}. B x) = UNIV"
   898   by (fact INF_empty)
   899 
   900 lemma INT_absorb: "k \<in> I \<Longrightarrow> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
   901   by (fact INF_absorb)
   902 
   903 lemma INT_subset_iff: "B \<subseteq> (\<Inter>i\<in>I. A i) \<longleftrightarrow> (\<forall>i\<in>I. B \<subseteq> A i)"
   904   by (fact le_INF_iff)
   905 
   906 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
   907   by (fact INF_insert)
   908 
   909 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
   910   by (fact INF_union)
   911 
   912 lemma INT_insert_distrib:
   913   "u \<in> A \<Longrightarrow> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
   914   by blast
   915 
   916 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
   917   by (fact INF_constant)
   918 
   919 lemma INTER_UNIV_conv:
   920  "(UNIV = (\<Inter>x\<in>A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
   921  "((\<Inter>x\<in>A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
   922   by (fact INF_top_conv)+ (* already simp *)
   923 
   924 lemma INT_bool_eq: "(\<Inter>b. A b) = A True \<inter> A False"
   925   by (fact INF_UNIV_bool_expand)
   926 
   927 lemma INT_anti_mono:
   928   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow> (\<Inter>x\<in>B. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
   929   -- {* The last inclusion is POSITIVE! *}
   930   by (fact INF_superset_mono)
   931 
   932 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
   933   by blast
   934 
   935 lemma vimage_INT: "f -` (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. f -` B x)"
   936   by blast
   937 
   938 
   939 subsubsection {* Union *}
   940 
   941 abbreviation Union :: "'a set set \<Rightarrow> 'a set" where
   942   "Union S \<equiv> \<Squnion>S"
   943 
   944 notation (xsymbols)
   945   Union  ("\<Union>_" [900] 900)
   946 
   947 lemma Union_eq:
   948   "\<Union>A = {x. \<exists>B \<in> A. x \<in> B}"
   949 proof (rule set_eqI)
   950   fix x
   951   have "(\<exists>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<exists>B\<in>A. x \<in> B)"
   952     by auto
   953   then show "x \<in> \<Union>A \<longleftrightarrow> x \<in> {x. \<exists>B\<in>A. x \<in> B}"
   954     by (simp add: Sup_set_def image_def)
   955 qed
   956 
   957 lemma Union_iff [simp]:
   958   "A \<in> \<Union>C \<longleftrightarrow> (\<exists>X\<in>C. A\<in>X)"
   959   by (unfold Union_eq) blast
   960 
   961 lemma UnionI [intro]:
   962   "X \<in> C \<Longrightarrow> A \<in> X \<Longrightarrow> A \<in> \<Union>C"
   963   -- {* The order of the premises presupposes that @{term C} is rigid;
   964     @{term A} may be flexible. *}
   965   by auto
   966 
   967 lemma UnionE [elim!]:
   968   "A \<in> \<Union>C \<Longrightarrow> (\<And>X. A \<in> X \<Longrightarrow> X \<in> C \<Longrightarrow> R) \<Longrightarrow> R"
   969   by auto
   970 
   971 lemma Union_upper: "B \<in> A \<Longrightarrow> B \<subseteq> \<Union>A"
   972   by (fact Sup_upper)
   973 
   974 lemma Union_least: "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> C) \<Longrightarrow> \<Union>A \<subseteq> C"
   975   by (fact Sup_least)
   976 
   977 lemma Union_empty: "\<Union>{} = {}"
   978   by (fact Sup_empty) (* already simp *)
   979 
   980 lemma Union_UNIV: "\<Union>UNIV = UNIV"
   981   by (fact Sup_UNIV) (* already simp *)
   982 
   983 lemma Union_insert: "\<Union>insert a B = a \<union> \<Union>B"
   984   by (fact Sup_insert) (* already simp *)
   985 
   986 lemma Union_Un_distrib [simp]: "\<Union>(A \<union> B) = \<Union>A \<union> \<Union>B"
   987   by (fact Sup_union_distrib)
   988 
   989 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
   990   by (fact Sup_inter_less_eq)
   991 
   992 lemma Union_empty_conv: "(\<Union>A = {}) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
   993   by (fact Sup_bot_conv) (* already simp *)
   994 
   995 lemma empty_Union_conv: "({} = \<Union>A) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
   996   by (fact Sup_bot_conv) (* already simp *)
   997 
   998 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
   999   by blast
  1000 
  1001 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
  1002   by blast
  1003 
  1004 lemma Union_mono: "A \<subseteq> B \<Longrightarrow> \<Union>A \<subseteq> \<Union>B"
  1005   by (fact Sup_subset_mono)
  1006 
  1007 
  1008 subsubsection {* Unions of families *}
  1009 
  1010 abbreviation UNION :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
  1011   "UNION \<equiv> SUPR"
  1012 
  1013 text {*
  1014   Note: must use name @{const UNION} here instead of @{text UN}
  1015   to allow the following syntax coexist with the plain constant name.
  1016 *}
  1017 
  1018 syntax
  1019   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" [0, 10] 10)
  1020   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" [0, 0, 10] 10)
  1021 
  1022 syntax (xsymbols)
  1023   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" [0, 10] 10)
  1024   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" [0, 0, 10] 10)
  1025 
  1026 syntax (latex output)
  1027   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
  1028   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
  1029 
  1030 translations
  1031   "UN x y. B"   == "UN x. UN y. B"
  1032   "UN x. B"     == "CONST UNION CONST UNIV (%x. B)"
  1033   "UN x. B"     == "UN x:CONST UNIV. B"
  1034   "UN x:A. B"   == "CONST UNION A (%x. B)"
  1035 
  1036 text {*
  1037   Note the difference between ordinary xsymbol syntax of indexed
  1038   unions and intersections (e.g.\ @{text"\<Union>a\<^sub>1\<in>A\<^sub>1. B"})
  1039   and their \LaTeX\ rendition: @{term"\<Union>a\<^sub>1\<in>A\<^sub>1. B"}. The
  1040   former does not make the index expression a subscript of the
  1041   union/intersection symbol because this leads to problems with nested
  1042   subscripts in Proof General.
  1043 *}
  1044 
  1045 print_translation {*
  1046   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax UNION} @{syntax_const "_UNION"}]
  1047 *} -- {* to avoid eta-contraction of body *}
  1048 
  1049 lemma UNION_eq:
  1050   "(\<Union>x\<in>A. B x) = {y. \<exists>x\<in>A. y \<in> B x}"
  1051   by (auto simp add: SUP_def)
  1052 
  1053 lemma bind_UNION [code]:
  1054   "Set.bind A f = UNION A f"
  1055   by (simp add: bind_def UNION_eq)
  1056 
  1057 lemma member_bind [simp]:
  1058   "x \<in> Set.bind P f \<longleftrightarrow> x \<in> UNION P f "
  1059   by (simp add: bind_UNION)
  1060 
  1061 lemma Union_image_eq [simp]:
  1062   "\<Union>(B ` A) = (\<Union>x\<in>A. B x)"
  1063   by (rule sym) (fact SUP_def)
  1064 
  1065 lemma UN_iff [simp]: "b \<in> (\<Union>x\<in>A. B x) \<longleftrightarrow> (\<exists>x\<in>A. b \<in> B x)"
  1066   by (auto simp add: SUP_def image_def)
  1067 
  1068 lemma UN_I [intro]: "a \<in> A \<Longrightarrow> b \<in> B a \<Longrightarrow> b \<in> (\<Union>x\<in>A. B x)"
  1069   -- {* The order of the premises presupposes that @{term A} is rigid;
  1070     @{term b} may be flexible. *}
  1071   by auto
  1072 
  1073 lemma UN_E [elim!]: "b \<in> (\<Union>x\<in>A. B x) \<Longrightarrow> (\<And>x. x\<in>A \<Longrightarrow> b \<in> B x \<Longrightarrow> R) \<Longrightarrow> R"
  1074   by (auto simp add: SUP_def image_def)
  1075 
  1076 lemma UN_cong [cong]:
  1077   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Union>x\<in>A. C x) = (\<Union>x\<in>B. D x)"
  1078   by (fact SUP_cong)
  1079 
  1080 lemma strong_UN_cong:
  1081   "A = B \<Longrightarrow> (\<And>x. x \<in> B =simp=> C x = D x) \<Longrightarrow> (\<Union>x\<in>A. C x) = (\<Union>x\<in>B. D x)"
  1082   by (unfold simp_implies_def) (fact UN_cong)
  1083 
  1084 lemma image_eq_UN: "f ` A = (\<Union>x\<in>A. {f x})"
  1085   by blast
  1086 
  1087 lemma UN_upper: "a \<in> A \<Longrightarrow> B a \<subseteq> (\<Union>x\<in>A. B x)"
  1088   by (fact SUP_upper)
  1089 
  1090 lemma UN_least: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C) \<Longrightarrow> (\<Union>x\<in>A. B x) \<subseteq> C"
  1091   by (fact SUP_least)
  1092 
  1093 lemma Collect_bex_eq: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
  1094   by blast
  1095 
  1096 lemma UN_insert_distrib: "u \<in> A \<Longrightarrow> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
  1097   by blast
  1098 
  1099 lemma UN_empty: "(\<Union>x\<in>{}. B x) = {}"
  1100   by (fact SUP_empty)
  1101 
  1102 lemma UN_empty2: "(\<Union>x\<in>A. {}) = {}"
  1103   by (fact SUP_bot) (* already simp *)
  1104 
  1105 lemma UN_absorb: "k \<in> I \<Longrightarrow> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
  1106   by (fact SUP_absorb)
  1107 
  1108 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
  1109   by (fact SUP_insert)
  1110 
  1111 lemma UN_Un [simp]: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
  1112   by (fact SUP_union)
  1113 
  1114 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
  1115   by blast
  1116 
  1117 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
  1118   by (fact SUP_le_iff)
  1119 
  1120 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
  1121   by (fact SUP_constant)
  1122 
  1123 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
  1124   by blast
  1125 
  1126 lemma UNION_empty_conv:
  1127   "{} = (\<Union>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
  1128   "(\<Union>x\<in>A. B x) = {} \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
  1129   by (fact SUP_bot_conv)+ (* already simp *)
  1130 
  1131 lemma Collect_ex_eq: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
  1132   by blast
  1133 
  1134 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) \<longleftrightarrow> (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
  1135   by blast
  1136 
  1137 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) \<longleftrightarrow> (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
  1138   by blast
  1139 
  1140 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
  1141   by (auto simp add: split_if_mem2)
  1142 
  1143 lemma UN_bool_eq: "(\<Union>b. A b) = (A True \<union> A False)"
  1144   by (fact SUP_UNIV_bool_expand)
  1145 
  1146 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
  1147   by blast
  1148 
  1149 lemma UN_mono:
  1150   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow>
  1151     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
  1152   by (fact SUP_subset_mono)
  1153 
  1154 lemma vimage_Union: "f -` (\<Union>A) = (\<Union>X\<in>A. f -` X)"
  1155   by blast
  1156 
  1157 lemma vimage_UN: "f -` (\<Union>x\<in>A. B x) = (\<Union>x\<in>A. f -` B x)"
  1158   by blast
  1159 
  1160 lemma vimage_eq_UN: "f -` B = (\<Union>y\<in>B. f -` {y})"
  1161   -- {* NOT suitable for rewriting *}
  1162   by blast
  1163 
  1164 lemma image_UN: "f ` UNION A B = (\<Union>x\<in>A. f ` B x)"
  1165   by blast
  1166 
  1167 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
  1168   by blast
  1169 
  1170 
  1171 subsubsection {* Distributive laws *}
  1172 
  1173 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
  1174   by (fact inf_Sup)
  1175 
  1176 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
  1177   by (fact sup_Inf)
  1178 
  1179 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
  1180   by (fact Sup_inf)
  1181 
  1182 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
  1183   by (rule sym) (rule INF_inf_distrib)
  1184 
  1185 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
  1186   by (rule sym) (rule SUP_sup_distrib)
  1187 
  1188 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A ` C) \<inter> \<Inter>(B ` C)"
  1189   by (simp only: INT_Int_distrib INF_def)
  1190 
  1191 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A ` C) \<union> \<Union>(B ` C)"
  1192   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
  1193   -- {* Union of a family of unions *}
  1194   by (simp only: UN_Un_distrib SUP_def)
  1195 
  1196 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
  1197   by (fact sup_INF)
  1198 
  1199 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
  1200   -- {* Halmos, Naive Set Theory, page 35. *}
  1201   by (fact inf_SUP)
  1202 
  1203 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
  1204   by (fact SUP_inf_distrib2)
  1205 
  1206 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
  1207   by (fact INF_sup_distrib2)
  1208 
  1209 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) \<longleftrightarrow> (\<forall>B\<in>C. B \<inter> A = {})"
  1210   by (fact Sup_inf_eq_bot_iff)
  1211 
  1212 
  1213 subsubsection {* Complement *}
  1214 
  1215 lemma Compl_INT [simp]: "- (\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
  1216   by (fact uminus_INF)
  1217 
  1218 lemma Compl_UN [simp]: "- (\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
  1219   by (fact uminus_SUP)
  1220 
  1221 
  1222 subsubsection {* Miniscoping and maxiscoping *}
  1223 
  1224 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
  1225            and Intersections. *}
  1226 
  1227 lemma UN_simps [simp]:
  1228   "\<And>a B C. (\<Union>x\<in>C. insert a (B x)) = (if C={} then {} else insert a (\<Union>x\<in>C. B x))"
  1229   "\<And>A B C. (\<Union>x\<in>C. A x \<union> B) = ((if C={} then {} else (\<Union>x\<in>C. A x) \<union> B))"
  1230   "\<And>A B C. (\<Union>x\<in>C. A \<union> B x) = ((if C={} then {} else A \<union> (\<Union>x\<in>C. B x)))"
  1231   "\<And>A B C. (\<Union>x\<in>C. A x \<inter> B) = ((\<Union>x\<in>C. A x) \<inter> B)"
  1232   "\<And>A B C. (\<Union>x\<in>C. A \<inter> B x) = (A \<inter>(\<Union>x\<in>C. B x))"
  1233   "\<And>A B C. (\<Union>x\<in>C. A x - B) = ((\<Union>x\<in>C. A x) - B)"
  1234   "\<And>A B C. (\<Union>x\<in>C. A - B x) = (A - (\<Inter>x\<in>C. B x))"
  1235   "\<And>A B. (\<Union>x\<in>\<Union>A. B x) = (\<Union>y\<in>A. \<Union>x\<in>y. B x)"
  1236   "\<And>A B C. (\<Union>z\<in>UNION A B. C z) = (\<Union>x\<in>A. \<Union>z\<in>B x. C z)"
  1237   "\<And>A B f. (\<Union>x\<in>f`A. B x) = (\<Union>a\<in>A. B (f a))"
  1238   by auto
  1239 
  1240 lemma INT_simps [simp]:
  1241   "\<And>A B C. (\<Inter>x\<in>C. A x \<inter> B) = (if C={} then UNIV else (\<Inter>x\<in>C. A x) \<inter> B)"
  1242   "\<And>A B C. (\<Inter>x\<in>C. A \<inter> B x) = (if C={} then UNIV else A \<inter>(\<Inter>x\<in>C. B x))"
  1243   "\<And>A B C. (\<Inter>x\<in>C. A x - B) = (if C={} then UNIV else (\<Inter>x\<in>C. A x) - B)"
  1244   "\<And>A B C. (\<Inter>x\<in>C. A - B x) = (if C={} then UNIV else A - (\<Union>x\<in>C. B x))"
  1245   "\<And>a B C. (\<Inter>x\<in>C. insert a (B x)) = insert a (\<Inter>x\<in>C. B x)"
  1246   "\<And>A B C. (\<Inter>x\<in>C. A x \<union> B) = ((\<Inter>x\<in>C. A x) \<union> B)"
  1247   "\<And>A B C. (\<Inter>x\<in>C. A \<union> B x) = (A \<union> (\<Inter>x\<in>C. B x))"
  1248   "\<And>A B. (\<Inter>x\<in>\<Union>A. B x) = (\<Inter>y\<in>A. \<Inter>x\<in>y. B x)"
  1249   "\<And>A B C. (\<Inter>z\<in>UNION A B. C z) = (\<Inter>x\<in>A. \<Inter>z\<in>B x. C z)"
  1250   "\<And>A B f. (\<Inter>x\<in>f`A. B x) = (\<Inter>a\<in>A. B (f a))"
  1251   by auto
  1252 
  1253 lemma UN_ball_bex_simps [simp]:
  1254   "\<And>A P. (\<forall>x\<in>\<Union>A. P x) \<longleftrightarrow> (\<forall>y\<in>A. \<forall>x\<in>y. P x)"
  1255   "\<And>A B P. (\<forall>x\<in>UNION A B. P x) = (\<forall>a\<in>A. \<forall>x\<in> B a. P x)"
  1256   "\<And>A P. (\<exists>x\<in>\<Union>A. P x) \<longleftrightarrow> (\<exists>y\<in>A. \<exists>x\<in>y. P x)"
  1257   "\<And>A B P. (\<exists>x\<in>UNION A B. P x) \<longleftrightarrow> (\<exists>a\<in>A. \<exists>x\<in>B a. P x)"
  1258   by auto
  1259 
  1260 
  1261 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
  1262 
  1263 lemma UN_extend_simps:
  1264   "\<And>a B C. insert a (\<Union>x\<in>C. B x) = (if C={} then {a} else (\<Union>x\<in>C. insert a (B x)))"
  1265   "\<And>A B C. (\<Union>x\<in>C. A x) \<union> B = (if C={} then B else (\<Union>x\<in>C. A x \<union> B))"
  1266   "\<And>A B C. A \<union> (\<Union>x\<in>C. B x) = (if C={} then A else (\<Union>x\<in>C. A \<union> B x))"
  1267   "\<And>A B C. ((\<Union>x\<in>C. A x) \<inter> B) = (\<Union>x\<in>C. A x \<inter> B)"
  1268   "\<And>A B C. (A \<inter> (\<Union>x\<in>C. B x)) = (\<Union>x\<in>C. A \<inter> B x)"
  1269   "\<And>A B C. ((\<Union>x\<in>C. A x) - B) = (\<Union>x\<in>C. A x - B)"
  1270   "\<And>A B C. (A - (\<Inter>x\<in>C. B x)) = (\<Union>x\<in>C. A - B x)"
  1271   "\<And>A B. (\<Union>y\<in>A. \<Union>x\<in>y. B x) = (\<Union>x\<in>\<Union>A. B x)"
  1272   "\<And>A B C. (\<Union>x\<in>A. \<Union>z\<in>B x. C z) = (\<Union>z\<in>UNION A B. C z)"
  1273   "\<And>A B f. (\<Union>a\<in>A. B (f a)) = (\<Union>x\<in>f`A. B x)"
  1274   by auto
  1275 
  1276 lemma INT_extend_simps:
  1277   "\<And>A B C. (\<Inter>x\<in>C. A x) \<inter> B = (if C={} then B else (\<Inter>x\<in>C. A x \<inter> B))"
  1278   "\<And>A B C. A \<inter> (\<Inter>x\<in>C. B x) = (if C={} then A else (\<Inter>x\<in>C. A \<inter> B x))"
  1279   "\<And>A B C. (\<Inter>x\<in>C. A x) - B = (if C={} then UNIV - B else (\<Inter>x\<in>C. A x - B))"
  1280   "\<And>A B C. A - (\<Union>x\<in>C. B x) = (if C={} then A else (\<Inter>x\<in>C. A - B x))"
  1281   "\<And>a B C. insert a (\<Inter>x\<in>C. B x) = (\<Inter>x\<in>C. insert a (B x))"
  1282   "\<And>A B C. ((\<Inter>x\<in>C. A x) \<union> B) = (\<Inter>x\<in>C. A x \<union> B)"
  1283   "\<And>A B C. A \<union> (\<Inter>x\<in>C. B x) = (\<Inter>x\<in>C. A \<union> B x)"
  1284   "\<And>A B. (\<Inter>y\<in>A. \<Inter>x\<in>y. B x) = (\<Inter>x\<in>\<Union>A. B x)"
  1285   "\<And>A B C. (\<Inter>x\<in>A. \<Inter>z\<in>B x. C z) = (\<Inter>z\<in>UNION A B. C z)"
  1286   "\<And>A B f. (\<Inter>a\<in>A. B (f a)) = (\<Inter>x\<in>f`A. B x)"
  1287   by auto
  1288 
  1289 text {* Finally *}
  1290 
  1291 no_notation
  1292   less_eq (infix "\<sqsubseteq>" 50) and
  1293   less (infix "\<sqsubset>" 50)
  1294 
  1295 lemmas mem_simps =
  1296   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
  1297   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
  1298   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
  1299 
  1300 end
  1301