src/HOL/Fun.thy
author hoelzl
Tue Nov 05 09:44:57 2013 +0100 (2013-11-05)
changeset 54257 5c7a3b6b05a9
parent 54147 97a8ff4e4ac9
child 54578 9387251b6a46
permissions -rw-r--r--
generalize SUP and INF to the syntactic type classes Sup and Inf
     1 (*  Title:      HOL/Fun.thy
     2     Author:     Tobias Nipkow, Cambridge University Computer Laboratory
     3     Copyright   1994  University of Cambridge
     4 *)
     5 
     6 header {* Notions about functions *}
     7 
     8 theory Fun
     9 imports Complete_Lattices
    10 keywords "enriched_type" :: thy_goal
    11 begin
    12 
    13 lemma apply_inverse:
    14   "f x = u \<Longrightarrow> (\<And>x. P x \<Longrightarrow> g (f x) = x) \<Longrightarrow> P x \<Longrightarrow> x = g u"
    15   by auto
    16 
    17 
    18 subsection {* The Identity Function @{text id} *}
    19 
    20 definition id :: "'a \<Rightarrow> 'a" where
    21   "id = (\<lambda>x. x)"
    22 
    23 lemma id_apply [simp]: "id x = x"
    24   by (simp add: id_def)
    25 
    26 lemma image_id [simp]: "image id = id"
    27   by (simp add: id_def fun_eq_iff)
    28 
    29 lemma vimage_id [simp]: "vimage id = id"
    30   by (simp add: id_def fun_eq_iff)
    31 
    32 code_printing
    33   constant id \<rightharpoonup> (Haskell) "id"
    34 
    35 
    36 subsection {* The Composition Operator @{text "f \<circ> g"} *}
    37 
    38 definition comp :: "('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "o" 55) where
    39   "f o g = (\<lambda>x. f (g x))"
    40 
    41 notation (xsymbols)
    42   comp  (infixl "\<circ>" 55)
    43 
    44 notation (HTML output)
    45   comp  (infixl "\<circ>" 55)
    46 
    47 lemma comp_apply [simp]: "(f o g) x = f (g x)"
    48   by (simp add: comp_def)
    49 
    50 lemma comp_assoc: "(f o g) o h = f o (g o h)"
    51   by (simp add: fun_eq_iff)
    52 
    53 lemma id_comp [simp]: "id o g = g"
    54   by (simp add: fun_eq_iff)
    55 
    56 lemma comp_id [simp]: "f o id = f"
    57   by (simp add: fun_eq_iff)
    58 
    59 lemma comp_eq_dest:
    60   "a o b = c o d \<Longrightarrow> a (b v) = c (d v)"
    61   by (simp add: fun_eq_iff)
    62 
    63 lemma comp_eq_elim:
    64   "a o b = c o d \<Longrightarrow> ((\<And>v. a (b v) = c (d v)) \<Longrightarrow> R) \<Longrightarrow> R"
    65   by (simp add: fun_eq_iff) 
    66 
    67 lemma image_comp:
    68   "(f o g) ` r = f ` (g ` r)"
    69   by auto
    70 
    71 lemma vimage_comp:
    72   "(g \<circ> f) -` x = f -` (g -` x)"
    73   by auto
    74 
    75 lemma INF_comp:
    76   "INFI A (g \<circ> f) = INFI (f ` A) g"
    77   by (simp add: INF_def image_comp)
    78 
    79 lemma SUP_comp:
    80   "SUPR A (g \<circ> f) = SUPR (f ` A) g"
    81   by (simp add: SUP_def image_comp)
    82 
    83 code_printing
    84   constant comp \<rightharpoonup> (SML) infixl 5 "o" and (Haskell) infixr 9 "."
    85 
    86 
    87 subsection {* The Forward Composition Operator @{text fcomp} *}
    88 
    89 definition fcomp :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "\<circ>>" 60) where
    90   "f \<circ>> g = (\<lambda>x. g (f x))"
    91 
    92 lemma fcomp_apply [simp]:  "(f \<circ>> g) x = g (f x)"
    93   by (simp add: fcomp_def)
    94 
    95 lemma fcomp_assoc: "(f \<circ>> g) \<circ>> h = f \<circ>> (g \<circ>> h)"
    96   by (simp add: fcomp_def)
    97 
    98 lemma id_fcomp [simp]: "id \<circ>> g = g"
    99   by (simp add: fcomp_def)
   100 
   101 lemma fcomp_id [simp]: "f \<circ>> id = f"
   102   by (simp add: fcomp_def)
   103 
   104 code_printing
   105   constant fcomp \<rightharpoonup> (Eval) infixl 1 "#>"
   106 
   107 no_notation fcomp (infixl "\<circ>>" 60)
   108 
   109 
   110 subsection {* Mapping functions *}
   111 
   112 definition map_fun :: "('c \<Rightarrow> 'a) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'c \<Rightarrow> 'd" where
   113   "map_fun f g h = g \<circ> h \<circ> f"
   114 
   115 lemma map_fun_apply [simp]:
   116   "map_fun f g h x = g (h (f x))"
   117   by (simp add: map_fun_def)
   118 
   119 
   120 subsection {* Injectivity and Bijectivity *}
   121 
   122 definition inj_on :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> bool" where -- "injective"
   123   "inj_on f A \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. f x = f y \<longrightarrow> x = y)"
   124 
   125 definition bij_betw :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> bool" where -- "bijective"
   126   "bij_betw f A B \<longleftrightarrow> inj_on f A \<and> f ` A = B"
   127 
   128 text{*A common special case: functions injective, surjective or bijective over
   129 the entire domain type.*}
   130 
   131 abbreviation
   132   "inj f \<equiv> inj_on f UNIV"
   133 
   134 abbreviation surj :: "('a \<Rightarrow> 'b) \<Rightarrow> bool" where -- "surjective"
   135   "surj f \<equiv> (range f = UNIV)"
   136 
   137 abbreviation
   138   "bij f \<equiv> bij_betw f UNIV UNIV"
   139 
   140 text{* The negated case: *}
   141 translations
   142 "\<not> CONST surj f" <= "CONST range f \<noteq> CONST UNIV"
   143 
   144 lemma injI:
   145   assumes "\<And>x y. f x = f y \<Longrightarrow> x = y"
   146   shows "inj f"
   147   using assms unfolding inj_on_def by auto
   148 
   149 theorem range_ex1_eq: "inj f \<Longrightarrow> b : range f = (EX! x. b = f x)"
   150   by (unfold inj_on_def, blast)
   151 
   152 lemma injD: "[| inj(f); f(x) = f(y) |] ==> x=y"
   153 by (simp add: inj_on_def)
   154 
   155 lemma inj_on_eq_iff: "inj_on f A ==> x:A ==> y:A ==> (f(x) = f(y)) = (x=y)"
   156 by (force simp add: inj_on_def)
   157 
   158 lemma inj_on_cong:
   159   "(\<And> a. a : A \<Longrightarrow> f a = g a) \<Longrightarrow> inj_on f A = inj_on g A"
   160 unfolding inj_on_def by auto
   161 
   162 lemma inj_on_strict_subset:
   163   "\<lbrakk> inj_on f B; A < B \<rbrakk> \<Longrightarrow> f`A < f`B"
   164 unfolding inj_on_def unfolding image_def by blast
   165 
   166 lemma inj_comp:
   167   "inj f \<Longrightarrow> inj g \<Longrightarrow> inj (f \<circ> g)"
   168   by (simp add: inj_on_def)
   169 
   170 lemma inj_fun: "inj f \<Longrightarrow> inj (\<lambda>x y. f x)"
   171   by (simp add: inj_on_def fun_eq_iff)
   172 
   173 lemma inj_eq: "inj f ==> (f(x) = f(y)) = (x=y)"
   174 by (simp add: inj_on_eq_iff)
   175 
   176 lemma inj_on_id[simp]: "inj_on id A"
   177   by (simp add: inj_on_def)
   178 
   179 lemma inj_on_id2[simp]: "inj_on (%x. x) A"
   180 by (simp add: inj_on_def)
   181 
   182 lemma inj_on_Int: "inj_on f A \<or> inj_on f B \<Longrightarrow> inj_on f (A \<inter> B)"
   183 unfolding inj_on_def by blast
   184 
   185 lemma inj_on_INTER:
   186   "\<lbrakk>I \<noteq> {}; \<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)\<rbrakk> \<Longrightarrow> inj_on f (\<Inter> i \<in> I. A i)"
   187 unfolding inj_on_def by blast
   188 
   189 lemma inj_on_Inter:
   190   "\<lbrakk>S \<noteq> {}; \<And> A. A \<in> S \<Longrightarrow> inj_on f A\<rbrakk> \<Longrightarrow> inj_on f (Inter S)"
   191 unfolding inj_on_def by blast
   192 
   193 lemma inj_on_UNION_chain:
   194   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
   195          INJ: "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
   196   shows "inj_on f (\<Union> i \<in> I. A i)"
   197 proof -
   198   {
   199     fix i j x y
   200     assume *: "i \<in> I" "j \<in> I" and **: "x \<in> A i" "y \<in> A j"
   201       and ***: "f x = f y"
   202     have "x = y"
   203     proof -
   204       {
   205         assume "A i \<le> A j"
   206         with ** have "x \<in> A j" by auto
   207         with INJ * ** *** have ?thesis
   208         by(auto simp add: inj_on_def)
   209       }
   210       moreover
   211       {
   212         assume "A j \<le> A i"
   213         with ** have "y \<in> A i" by auto
   214         with INJ * ** *** have ?thesis
   215         by(auto simp add: inj_on_def)
   216       }
   217       ultimately show ?thesis using CH * by blast
   218     qed
   219   }
   220   then show ?thesis by (unfold inj_on_def UNION_eq) auto
   221 qed
   222 
   223 lemma surj_id: "surj id"
   224 by simp
   225 
   226 lemma bij_id[simp]: "bij id"
   227 by (simp add: bij_betw_def)
   228 
   229 lemma inj_onI:
   230     "(!! x y. [|  x:A;  y:A;  f(x) = f(y) |] ==> x=y) ==> inj_on f A"
   231 by (simp add: inj_on_def)
   232 
   233 lemma inj_on_inverseI: "(!!x. x:A ==> g(f(x)) = x) ==> inj_on f A"
   234 by (auto dest:  arg_cong [of concl: g] simp add: inj_on_def)
   235 
   236 lemma inj_onD: "[| inj_on f A;  f(x)=f(y);  x:A;  y:A |] ==> x=y"
   237 by (unfold inj_on_def, blast)
   238 
   239 lemma inj_on_iff: "[| inj_on f A;  x:A;  y:A |] ==> (f(x)=f(y)) = (x=y)"
   240 by (blast dest!: inj_onD)
   241 
   242 lemma comp_inj_on:
   243      "[| inj_on f A;  inj_on g (f`A) |] ==> inj_on (g o f) A"
   244 by (simp add: comp_def inj_on_def)
   245 
   246 lemma inj_on_imageI: "inj_on (g o f) A \<Longrightarrow> inj_on g (f ` A)"
   247 apply(simp add:inj_on_def image_def)
   248 apply blast
   249 done
   250 
   251 lemma inj_on_image_iff: "\<lbrakk> ALL x:A. ALL y:A. (g(f x) = g(f y)) = (g x = g y);
   252   inj_on f A \<rbrakk> \<Longrightarrow> inj_on g (f ` A) = inj_on g A"
   253 apply(unfold inj_on_def)
   254 apply blast
   255 done
   256 
   257 lemma inj_on_contraD: "[| inj_on f A;  ~x=y;  x:A;  y:A |] ==> ~ f(x)=f(y)"
   258 by (unfold inj_on_def, blast)
   259 
   260 lemma inj_singleton: "inj (%s. {s})"
   261 by (simp add: inj_on_def)
   262 
   263 lemma inj_on_empty[iff]: "inj_on f {}"
   264 by(simp add: inj_on_def)
   265 
   266 lemma subset_inj_on: "[| inj_on f B; A <= B |] ==> inj_on f A"
   267 by (unfold inj_on_def, blast)
   268 
   269 lemma inj_on_Un:
   270  "inj_on f (A Un B) =
   271   (inj_on f A & inj_on f B & f`(A-B) Int f`(B-A) = {})"
   272 apply(unfold inj_on_def)
   273 apply (blast intro:sym)
   274 done
   275 
   276 lemma inj_on_insert[iff]:
   277   "inj_on f (insert a A) = (inj_on f A & f a ~: f`(A-{a}))"
   278 apply(unfold inj_on_def)
   279 apply (blast intro:sym)
   280 done
   281 
   282 lemma inj_on_diff: "inj_on f A ==> inj_on f (A-B)"
   283 apply(unfold inj_on_def)
   284 apply (blast)
   285 done
   286 
   287 lemma comp_inj_on_iff:
   288   "inj_on f A \<Longrightarrow> inj_on f' (f ` A) \<longleftrightarrow> inj_on (f' o f) A"
   289 by(auto simp add: comp_inj_on inj_on_def)
   290 
   291 lemma inj_on_imageI2:
   292   "inj_on (f' o f) A \<Longrightarrow> inj_on f A"
   293 by(auto simp add: comp_inj_on inj_on_def)
   294 
   295 lemma inj_img_insertE:
   296   assumes "inj_on f A"
   297   assumes "x \<notin> B" and "insert x B = f ` A"
   298   obtains x' A' where "x' \<notin> A'" and "A = insert x' A'"
   299     and "x = f x'" and "B = f ` A'" 
   300 proof -
   301   from assms have "x \<in> f ` A" by auto
   302   then obtain x' where *: "x' \<in> A" "x = f x'" by auto
   303   then have "A = insert x' (A - {x'})" by auto
   304   with assms * have "B = f ` (A - {x'})"
   305     by (auto dest: inj_on_contraD)
   306   have "x' \<notin> A - {x'}" by simp
   307   from `x' \<notin> A - {x'}` `A = insert x' (A - {x'})` `x = f x'` `B = image f (A - {x'})`
   308   show ?thesis ..
   309 qed
   310 
   311 lemma surj_def: "surj f \<longleftrightarrow> (\<forall>y. \<exists>x. y = f x)"
   312   by auto
   313 
   314 lemma surjI: assumes *: "\<And> x. g (f x) = x" shows "surj g"
   315   using *[symmetric] by auto
   316 
   317 lemma surjD: "surj f \<Longrightarrow> \<exists>x. y = f x"
   318   by (simp add: surj_def)
   319 
   320 lemma surjE: "surj f \<Longrightarrow> (\<And>x. y = f x \<Longrightarrow> C) \<Longrightarrow> C"
   321   by (simp add: surj_def, blast)
   322 
   323 lemma comp_surj: "[| surj f;  surj g |] ==> surj (g o f)"
   324 apply (simp add: comp_def surj_def, clarify)
   325 apply (drule_tac x = y in spec, clarify)
   326 apply (drule_tac x = x in spec, blast)
   327 done
   328 
   329 lemma bij_betw_imp_surj: "bij_betw f A UNIV \<Longrightarrow> surj f"
   330   unfolding bij_betw_def by auto
   331 
   332 lemma bij_betw_empty1:
   333   assumes "bij_betw f {} A"
   334   shows "A = {}"
   335 using assms unfolding bij_betw_def by blast
   336 
   337 lemma bij_betw_empty2:
   338   assumes "bij_betw f A {}"
   339   shows "A = {}"
   340 using assms unfolding bij_betw_def by blast
   341 
   342 lemma inj_on_imp_bij_betw:
   343   "inj_on f A \<Longrightarrow> bij_betw f A (f ` A)"
   344 unfolding bij_betw_def by simp
   345 
   346 lemma bij_def: "bij f \<longleftrightarrow> inj f \<and> surj f"
   347   unfolding bij_betw_def ..
   348 
   349 lemma bijI: "[| inj f; surj f |] ==> bij f"
   350 by (simp add: bij_def)
   351 
   352 lemma bij_is_inj: "bij f ==> inj f"
   353 by (simp add: bij_def)
   354 
   355 lemma bij_is_surj: "bij f ==> surj f"
   356 by (simp add: bij_def)
   357 
   358 lemma bij_betw_imp_inj_on: "bij_betw f A B \<Longrightarrow> inj_on f A"
   359 by (simp add: bij_betw_def)
   360 
   361 lemma bij_betw_trans:
   362   "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (g o f) A C"
   363 by(auto simp add:bij_betw_def comp_inj_on)
   364 
   365 lemma bij_comp: "bij f \<Longrightarrow> bij g \<Longrightarrow> bij (g o f)"
   366   by (rule bij_betw_trans)
   367 
   368 lemma bij_betw_comp_iff:
   369   "bij_betw f A A' \<Longrightarrow> bij_betw f' A' A'' \<longleftrightarrow> bij_betw (f' o f) A A''"
   370 by(auto simp add: bij_betw_def inj_on_def)
   371 
   372 lemma bij_betw_comp_iff2:
   373   assumes BIJ: "bij_betw f' A' A''" and IM: "f ` A \<le> A'"
   374   shows "bij_betw f A A' \<longleftrightarrow> bij_betw (f' o f) A A''"
   375 using assms
   376 proof(auto simp add: bij_betw_comp_iff)
   377   assume *: "bij_betw (f' \<circ> f) A A''"
   378   thus "bij_betw f A A'"
   379   using IM
   380   proof(auto simp add: bij_betw_def)
   381     assume "inj_on (f' \<circ> f) A"
   382     thus "inj_on f A" using inj_on_imageI2 by blast
   383   next
   384     fix a' assume **: "a' \<in> A'"
   385     hence "f' a' \<in> A''" using BIJ unfolding bij_betw_def by auto
   386     then obtain a where 1: "a \<in> A \<and> f'(f a) = f' a'" using *
   387     unfolding bij_betw_def by force
   388     hence "f a \<in> A'" using IM by auto
   389     hence "f a = a'" using BIJ ** 1 unfolding bij_betw_def inj_on_def by auto
   390     thus "a' \<in> f ` A" using 1 by auto
   391   qed
   392 qed
   393 
   394 lemma bij_betw_inv: assumes "bij_betw f A B" shows "EX g. bij_betw g B A"
   395 proof -
   396   have i: "inj_on f A" and s: "f ` A = B"
   397     using assms by(auto simp:bij_betw_def)
   398   let ?P = "%b a. a:A \<and> f a = b" let ?g = "%b. The (?P b)"
   399   { fix a b assume P: "?P b a"
   400     hence ex1: "\<exists>a. ?P b a" using s unfolding image_def by blast
   401     hence uex1: "\<exists>!a. ?P b a" by(blast dest:inj_onD[OF i])
   402     hence " ?g b = a" using the1_equality[OF uex1, OF P] P by simp
   403   } note g = this
   404   have "inj_on ?g B"
   405   proof(rule inj_onI)
   406     fix x y assume "x:B" "y:B" "?g x = ?g y"
   407     from s `x:B` obtain a1 where a1: "?P x a1" unfolding image_def by blast
   408     from s `y:B` obtain a2 where a2: "?P y a2" unfolding image_def by blast
   409     from g[OF a1] a1 g[OF a2] a2 `?g x = ?g y` show "x=y" by simp
   410   qed
   411   moreover have "?g ` B = A"
   412   proof(auto simp:image_def)
   413     fix b assume "b:B"
   414     with s obtain a where P: "?P b a" unfolding image_def by blast
   415     thus "?g b \<in> A" using g[OF P] by auto
   416   next
   417     fix a assume "a:A"
   418     then obtain b where P: "?P b a" using s unfolding image_def by blast
   419     then have "b:B" using s unfolding image_def by blast
   420     with g[OF P] show "\<exists>b\<in>B. a = ?g b" by blast
   421   qed
   422   ultimately show ?thesis by(auto simp:bij_betw_def)
   423 qed
   424 
   425 lemma bij_betw_cong:
   426   "(\<And> a. a \<in> A \<Longrightarrow> f a = g a) \<Longrightarrow> bij_betw f A A' = bij_betw g A A'"
   427 unfolding bij_betw_def inj_on_def by force
   428 
   429 lemma bij_betw_id[intro, simp]:
   430   "bij_betw id A A"
   431 unfolding bij_betw_def id_def by auto
   432 
   433 lemma bij_betw_id_iff:
   434   "bij_betw id A B \<longleftrightarrow> A = B"
   435 by(auto simp add: bij_betw_def)
   436 
   437 lemma bij_betw_combine:
   438   assumes "bij_betw f A B" "bij_betw f C D" "B \<inter> D = {}"
   439   shows "bij_betw f (A \<union> C) (B \<union> D)"
   440   using assms unfolding bij_betw_def inj_on_Un image_Un by auto
   441 
   442 lemma bij_betw_UNION_chain:
   443   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
   444          BIJ: "\<And> i. i \<in> I \<Longrightarrow> bij_betw f (A i) (A' i)"
   445   shows "bij_betw f (\<Union> i \<in> I. A i) (\<Union> i \<in> I. A' i)"
   446 proof (unfold bij_betw_def, auto)
   447   have "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
   448   using BIJ bij_betw_def[of f] by auto
   449   thus "inj_on f (\<Union> i \<in> I. A i)"
   450   using CH inj_on_UNION_chain[of I A f] by auto
   451 next
   452   fix i x
   453   assume *: "i \<in> I" "x \<in> A i"
   454   hence "f x \<in> A' i" using BIJ bij_betw_def[of f] by auto
   455   thus "\<exists>j \<in> I. f x \<in> A' j" using * by blast
   456 next
   457   fix i x'
   458   assume *: "i \<in> I" "x' \<in> A' i"
   459   hence "\<exists>x \<in> A i. x' = f x" using BIJ bij_betw_def[of f] by blast
   460   then have "\<exists>j \<in> I. \<exists>x \<in> A j. x' = f x"
   461     using * by blast
   462   then show "x' \<in> f ` (\<Union>x\<in>I. A x)" by (simp add: image_def)
   463 qed
   464 
   465 lemma bij_betw_subset:
   466   assumes BIJ: "bij_betw f A A'" and
   467           SUB: "B \<le> A" and IM: "f ` B = B'"
   468   shows "bij_betw f B B'"
   469 using assms
   470 by(unfold bij_betw_def inj_on_def, auto simp add: inj_on_def)
   471 
   472 lemma surj_image_vimage_eq: "surj f ==> f ` (f -` A) = A"
   473 by simp
   474 
   475 lemma surj_vimage_empty:
   476   assumes "surj f" shows "f -` A = {} \<longleftrightarrow> A = {}"
   477   using surj_image_vimage_eq[OF `surj f`, of A]
   478   by (intro iffI) fastforce+
   479 
   480 lemma inj_vimage_image_eq: "inj f ==> f -` (f ` A) = A"
   481 by (simp add: inj_on_def, blast)
   482 
   483 lemma vimage_subsetD: "surj f ==> f -` B <= A ==> B <= f ` A"
   484 by (blast intro: sym)
   485 
   486 lemma vimage_subsetI: "inj f ==> B <= f ` A ==> f -` B <= A"
   487 by (unfold inj_on_def, blast)
   488 
   489 lemma vimage_subset_eq: "bij f ==> (f -` B <= A) = (B <= f ` A)"
   490 apply (unfold bij_def)
   491 apply (blast del: subsetI intro: vimage_subsetI vimage_subsetD)
   492 done
   493 
   494 lemma inj_on_image_eq_iff: "\<lbrakk> inj_on f C; A \<subseteq> C; B \<subseteq> C \<rbrakk> \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   495 by(fastforce simp add: inj_on_def)
   496 
   497 lemma inj_on_Un_image_eq_iff: "inj_on f (A \<union> B) \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   498 by(erule inj_on_image_eq_iff) simp_all
   499 
   500 lemma inj_on_image_Int:
   501    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A Int B) = f`A Int f`B"
   502 apply (simp add: inj_on_def, blast)
   503 done
   504 
   505 lemma inj_on_image_set_diff:
   506    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A-B) = f`A - f`B"
   507 apply (simp add: inj_on_def, blast)
   508 done
   509 
   510 lemma image_Int: "inj f ==> f`(A Int B) = f`A Int f`B"
   511 by (simp add: inj_on_def, blast)
   512 
   513 lemma image_set_diff: "inj f ==> f`(A-B) = f`A - f`B"
   514 by (simp add: inj_on_def, blast)
   515 
   516 lemma inj_image_mem_iff: "inj f ==> (f a : f`A) = (a : A)"
   517 by (blast dest: injD)
   518 
   519 lemma inj_image_subset_iff: "inj f ==> (f`A <= f`B) = (A<=B)"
   520 by (simp add: inj_on_def, blast)
   521 
   522 lemma inj_image_eq_iff: "inj f ==> (f`A = f`B) = (A = B)"
   523 by (blast dest: injD)
   524 
   525 (*injectivity's required.  Left-to-right inclusion holds even if A is empty*)
   526 lemma image_INT:
   527    "[| inj_on f C;  ALL x:A. B x <= C;  j:A |]
   528     ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   529 apply (simp add: inj_on_def, blast)
   530 done
   531 
   532 (*Compare with image_INT: no use of inj_on, and if f is surjective then
   533   it doesn't matter whether A is empty*)
   534 lemma bij_image_INT: "bij f ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   535 apply (simp add: bij_def)
   536 apply (simp add: inj_on_def surj_def, blast)
   537 done
   538 
   539 lemma surj_Compl_image_subset: "surj f ==> -(f`A) <= f`(-A)"
   540 by auto
   541 
   542 lemma inj_image_Compl_subset: "inj f ==> f`(-A) <= -(f`A)"
   543 by (auto simp add: inj_on_def)
   544 
   545 lemma bij_image_Compl_eq: "bij f ==> f`(-A) = -(f`A)"
   546 apply (simp add: bij_def)
   547 apply (rule equalityI)
   548 apply (simp_all (no_asm_simp) add: inj_image_Compl_subset surj_Compl_image_subset)
   549 done
   550 
   551 lemma inj_vimage_singleton: "inj f \<Longrightarrow> f -` {a} \<subseteq> {THE x. f x = a}"
   552   -- {* The inverse image of a singleton under an injective function
   553          is included in a singleton. *}
   554   apply (auto simp add: inj_on_def)
   555   apply (blast intro: the_equality [symmetric])
   556   done
   557 
   558 lemma inj_on_vimage_singleton:
   559   "inj_on f A \<Longrightarrow> f -` {a} \<inter> A \<subseteq> {THE x. x \<in> A \<and> f x = a}"
   560   by (auto simp add: inj_on_def intro: the_equality [symmetric])
   561 
   562 lemma (in ordered_ab_group_add) inj_uminus[simp, intro]: "inj_on uminus A"
   563   by (auto intro!: inj_onI)
   564 
   565 lemma (in linorder) strict_mono_imp_inj_on: "strict_mono f \<Longrightarrow> inj_on f A"
   566   by (auto intro!: inj_onI dest: strict_mono_eq)
   567 
   568 
   569 subsection{*Function Updating*}
   570 
   571 definition fun_upd :: "('a => 'b) => 'a => 'b => ('a => 'b)" where
   572   "fun_upd f a b == % x. if x=a then b else f x"
   573 
   574 nonterminal updbinds and updbind
   575 
   576 syntax
   577   "_updbind" :: "['a, 'a] => updbind"             ("(2_ :=/ _)")
   578   ""         :: "updbind => updbinds"             ("_")
   579   "_updbinds":: "[updbind, updbinds] => updbinds" ("_,/ _")
   580   "_Update"  :: "['a, updbinds] => 'a"            ("_/'((_)')" [1000, 0] 900)
   581 
   582 translations
   583   "_Update f (_updbinds b bs)" == "_Update (_Update f b) bs"
   584   "f(x:=y)" == "CONST fun_upd f x y"
   585 
   586 (* Hint: to define the sum of two functions (or maps), use sum_case.
   587          A nice infix syntax could be defined (in Datatype.thy or below) by
   588 notation
   589   sum_case  (infixr "'(+')"80)
   590 *)
   591 
   592 lemma fun_upd_idem_iff: "(f(x:=y) = f) = (f x = y)"
   593 apply (simp add: fun_upd_def, safe)
   594 apply (erule subst)
   595 apply (rule_tac [2] ext, auto)
   596 done
   597 
   598 lemma fun_upd_idem: "f x = y ==> f(x:=y) = f"
   599   by (simp only: fun_upd_idem_iff)
   600 
   601 lemma fun_upd_triv [iff]: "f(x := f x) = f"
   602   by (simp only: fun_upd_idem)
   603 
   604 lemma fun_upd_apply [simp]: "(f(x:=y))z = (if z=x then y else f z)"
   605 by (simp add: fun_upd_def)
   606 
   607 (* fun_upd_apply supersedes these two,   but they are useful
   608    if fun_upd_apply is intentionally removed from the simpset *)
   609 lemma fun_upd_same: "(f(x:=y)) x = y"
   610 by simp
   611 
   612 lemma fun_upd_other: "z~=x ==> (f(x:=y)) z = f z"
   613 by simp
   614 
   615 lemma fun_upd_upd [simp]: "f(x:=y,x:=z) = f(x:=z)"
   616 by (simp add: fun_eq_iff)
   617 
   618 lemma fun_upd_twist: "a ~= c ==> (m(a:=b))(c:=d) = (m(c:=d))(a:=b)"
   619 by (rule ext, auto)
   620 
   621 lemma inj_on_fun_updI: "\<lbrakk> inj_on f A; y \<notin> f`A \<rbrakk> \<Longrightarrow> inj_on (f(x:=y)) A"
   622 by (fastforce simp:inj_on_def image_def)
   623 
   624 lemma fun_upd_image:
   625      "f(x:=y) ` A = (if x \<in> A then insert y (f ` (A-{x})) else f ` A)"
   626 by auto
   627 
   628 lemma fun_upd_comp: "f \<circ> (g(x := y)) = (f \<circ> g)(x := f y)"
   629   by auto
   630 
   631 lemma UNION_fun_upd:
   632   "UNION J (A(i:=B)) = (UNION (J-{i}) A \<union> (if i\<in>J then B else {}))"
   633 by (auto split: if_splits)
   634 
   635 
   636 subsection {* @{text override_on} *}
   637 
   638 definition override_on :: "('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b" where
   639   "override_on f g A = (\<lambda>a. if a \<in> A then g a else f a)"
   640 
   641 lemma override_on_emptyset[simp]: "override_on f g {} = f"
   642 by(simp add:override_on_def)
   643 
   644 lemma override_on_apply_notin[simp]: "a ~: A ==> (override_on f g A) a = f a"
   645 by(simp add:override_on_def)
   646 
   647 lemma override_on_apply_in[simp]: "a : A ==> (override_on f g A) a = g a"
   648 by(simp add:override_on_def)
   649 
   650 
   651 subsection {* @{text swap} *}
   652 
   653 definition swap :: "'a \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)" where
   654   "swap a b f = f (a := f b, b:= f a)"
   655 
   656 lemma swap_self [simp]: "swap a a f = f"
   657 by (simp add: swap_def)
   658 
   659 lemma swap_commute: "swap a b f = swap b a f"
   660 by (rule ext, simp add: fun_upd_def swap_def)
   661 
   662 lemma swap_nilpotent [simp]: "swap a b (swap a b f) = f"
   663 by (rule ext, simp add: fun_upd_def swap_def)
   664 
   665 lemma swap_triple:
   666   assumes "a \<noteq> c" and "b \<noteq> c"
   667   shows "swap a b (swap b c (swap a b f)) = swap a c f"
   668   using assms by (simp add: fun_eq_iff swap_def)
   669 
   670 lemma comp_swap: "f \<circ> swap a b g = swap a b (f \<circ> g)"
   671 by (rule ext, simp add: fun_upd_def swap_def)
   672 
   673 lemma swap_image_eq [simp]:
   674   assumes "a \<in> A" "b \<in> A" shows "swap a b f ` A = f ` A"
   675 proof -
   676   have subset: "\<And>f. swap a b f ` A \<subseteq> f ` A"
   677     using assms by (auto simp: image_iff swap_def)
   678   then have "swap a b (swap a b f) ` A \<subseteq> (swap a b f) ` A" .
   679   with subset[of f] show ?thesis by auto
   680 qed
   681 
   682 lemma inj_on_imp_inj_on_swap:
   683   "\<lbrakk>inj_on f A; a \<in> A; b \<in> A\<rbrakk> \<Longrightarrow> inj_on (swap a b f) A"
   684   by (simp add: inj_on_def swap_def, blast)
   685 
   686 lemma inj_on_swap_iff [simp]:
   687   assumes A: "a \<in> A" "b \<in> A" shows "inj_on (swap a b f) A \<longleftrightarrow> inj_on f A"
   688 proof
   689   assume "inj_on (swap a b f) A"
   690   with A have "inj_on (swap a b (swap a b f)) A"
   691     by (iprover intro: inj_on_imp_inj_on_swap)
   692   thus "inj_on f A" by simp
   693 next
   694   assume "inj_on f A"
   695   with A show "inj_on (swap a b f) A" by (iprover intro: inj_on_imp_inj_on_swap)
   696 qed
   697 
   698 lemma surj_imp_surj_swap: "surj f \<Longrightarrow> surj (swap a b f)"
   699   by simp
   700 
   701 lemma surj_swap_iff [simp]: "surj (swap a b f) \<longleftrightarrow> surj f"
   702   by simp
   703 
   704 lemma bij_betw_swap_iff [simp]:
   705   "\<lbrakk> x \<in> A; y \<in> A \<rbrakk> \<Longrightarrow> bij_betw (swap x y f) A B \<longleftrightarrow> bij_betw f A B"
   706   by (auto simp: bij_betw_def)
   707 
   708 lemma bij_swap_iff [simp]: "bij (swap a b f) \<longleftrightarrow> bij f"
   709   by simp
   710 
   711 hide_const (open) swap
   712 
   713 subsection {* Inversion of injective functions *}
   714 
   715 definition the_inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
   716   "the_inv_into A f == %x. THE y. y : A & f y = x"
   717 
   718 lemma the_inv_into_f_f:
   719   "[| inj_on f A;  x : A |] ==> the_inv_into A f (f x) = x"
   720 apply (simp add: the_inv_into_def inj_on_def)
   721 apply blast
   722 done
   723 
   724 lemma f_the_inv_into_f:
   725   "inj_on f A ==> y : f`A  ==> f (the_inv_into A f y) = y"
   726 apply (simp add: the_inv_into_def)
   727 apply (rule the1I2)
   728  apply(blast dest: inj_onD)
   729 apply blast
   730 done
   731 
   732 lemma the_inv_into_into:
   733   "[| inj_on f A; x : f ` A; A <= B |] ==> the_inv_into A f x : B"
   734 apply (simp add: the_inv_into_def)
   735 apply (rule the1I2)
   736  apply(blast dest: inj_onD)
   737 apply blast
   738 done
   739 
   740 lemma the_inv_into_onto[simp]:
   741   "inj_on f A ==> the_inv_into A f ` (f ` A) = A"
   742 by (fast intro:the_inv_into_into the_inv_into_f_f[symmetric])
   743 
   744 lemma the_inv_into_f_eq:
   745   "[| inj_on f A; f x = y; x : A |] ==> the_inv_into A f y = x"
   746   apply (erule subst)
   747   apply (erule the_inv_into_f_f, assumption)
   748   done
   749 
   750 lemma the_inv_into_comp:
   751   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
   752   the_inv_into A (f o g) x = (the_inv_into A g o the_inv_into (g ` A) f) x"
   753 apply (rule the_inv_into_f_eq)
   754   apply (fast intro: comp_inj_on)
   755  apply (simp add: f_the_inv_into_f the_inv_into_into)
   756 apply (simp add: the_inv_into_into)
   757 done
   758 
   759 lemma inj_on_the_inv_into:
   760   "inj_on f A \<Longrightarrow> inj_on (the_inv_into A f) (f ` A)"
   761 by (auto intro: inj_onI simp: image_def the_inv_into_f_f)
   762 
   763 lemma bij_betw_the_inv_into:
   764   "bij_betw f A B \<Longrightarrow> bij_betw (the_inv_into A f) B A"
   765 by (auto simp add: bij_betw_def inj_on_the_inv_into the_inv_into_into)
   766 
   767 abbreviation the_inv :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'a)" where
   768   "the_inv f \<equiv> the_inv_into UNIV f"
   769 
   770 lemma the_inv_f_f:
   771   assumes "inj f"
   772   shows "the_inv f (f x) = x" using assms UNIV_I
   773   by (rule the_inv_into_f_f)
   774 
   775 
   776 subsection {* Cantor's Paradox *}
   777 
   778 lemma Cantors_paradox:
   779   "\<not>(\<exists>f. f ` A = Pow A)"
   780 proof clarify
   781   fix f assume "f ` A = Pow A" hence *: "Pow A \<le> f ` A" by blast
   782   let ?X = "{a \<in> A. a \<notin> f a}"
   783   have "?X \<in> Pow A" unfolding Pow_def by auto
   784   with * obtain x where "x \<in> A \<and> f x = ?X" by blast
   785   thus False by best
   786 qed
   787 
   788 subsection {* Setup *} 
   789 
   790 subsubsection {* Proof tools *}
   791 
   792 text {* simplifies terms of the form
   793   f(...,x:=y,...,x:=z,...) to f(...,x:=z,...) *}
   794 
   795 simproc_setup fun_upd2 ("f(v := w, x := y)") = {* fn _ =>
   796 let
   797   fun gen_fun_upd NONE T _ _ = NONE
   798     | gen_fun_upd (SOME f) T x y = SOME (Const (@{const_name fun_upd}, T) $ f $ x $ y)
   799   fun dest_fun_T1 (Type (_, T :: Ts)) = T
   800   fun find_double (t as Const (@{const_name fun_upd},T) $ f $ x $ y) =
   801     let
   802       fun find (Const (@{const_name fun_upd},T) $ g $ v $ w) =
   803             if v aconv x then SOME g else gen_fun_upd (find g) T v w
   804         | find t = NONE
   805     in (dest_fun_T1 T, gen_fun_upd (find f) T x y) end
   806 
   807   val ss = simpset_of @{context}
   808 
   809   fun proc ctxt ct =
   810     let
   811       val t = Thm.term_of ct
   812     in
   813       case find_double t of
   814         (T, NONE) => NONE
   815       | (T, SOME rhs) =>
   816           SOME (Goal.prove ctxt [] [] (Logic.mk_equals (t, rhs))
   817             (fn _ =>
   818               rtac eq_reflection 1 THEN
   819               rtac ext 1 THEN
   820               simp_tac (put_simpset ss ctxt) 1))
   821     end
   822 in proc end
   823 *}
   824 
   825 
   826 subsubsection {* Functorial structure of types *}
   827 
   828 ML_file "Tools/enriched_type.ML"
   829 
   830 enriched_type map_fun: map_fun
   831   by (simp_all add: fun_eq_iff)
   832 
   833 enriched_type vimage
   834   by (simp_all add: fun_eq_iff vimage_comp)
   835 
   836 text {* Legacy theorem names *}
   837 
   838 lemmas o_def = comp_def
   839 lemmas o_apply = comp_apply
   840 lemmas o_assoc = comp_assoc [symmetric]
   841 lemmas id_o = id_comp
   842 lemmas o_id = comp_id
   843 lemmas o_eq_dest = comp_eq_dest
   844 lemmas o_eq_elim = comp_eq_elim
   845 lemmas image_compose = image_comp
   846 lemmas vimage_compose = vimage_comp
   847 
   848 end
   849