src/HOL/FunDef.thy
author hoelzl
Tue Nov 05 09:44:57 2013 +0100 (2013-11-05)
changeset 54257 5c7a3b6b05a9
parent 53603 59ef06cda7b9
child 54407 e95831757903
permissions -rw-r--r--
generalize SUP and INF to the syntactic type classes Sup and Inf
     1 (*  Title:      HOL/FunDef.thy
     2     Author:     Alexander Krauss, TU Muenchen
     3 *)
     4 
     5 header {* Function Definitions and Termination Proofs *}
     6 
     7 theory FunDef
     8 imports Partial_Function SAT Wellfounded
     9 keywords "function" "termination" :: thy_goal and "fun" "fun_cases" :: thy_decl
    10 begin
    11 
    12 subsection {* Definitions with default value. *}
    13 
    14 definition
    15   THE_default :: "'a \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> 'a" where
    16   "THE_default d P = (if (\<exists>!x. P x) then (THE x. P x) else d)"
    17 
    18 lemma THE_defaultI': "\<exists>!x. P x \<Longrightarrow> P (THE_default d P)"
    19   by (simp add: theI' THE_default_def)
    20 
    21 lemma THE_default1_equality:
    22     "\<lbrakk>\<exists>!x. P x; P a\<rbrakk> \<Longrightarrow> THE_default d P = a"
    23   by (simp add: the1_equality THE_default_def)
    24 
    25 lemma THE_default_none:
    26     "\<not>(\<exists>!x. P x) \<Longrightarrow> THE_default d P = d"
    27   by (simp add:THE_default_def)
    28 
    29 
    30 lemma fundef_ex1_existence:
    31   assumes f_def: "f == (\<lambda>x::'a. THE_default (d x) (\<lambda>y. G x y))"
    32   assumes ex1: "\<exists>!y. G x y"
    33   shows "G x (f x)"
    34   apply (simp only: f_def)
    35   apply (rule THE_defaultI')
    36   apply (rule ex1)
    37   done
    38 
    39 lemma fundef_ex1_uniqueness:
    40   assumes f_def: "f == (\<lambda>x::'a. THE_default (d x) (\<lambda>y. G x y))"
    41   assumes ex1: "\<exists>!y. G x y"
    42   assumes elm: "G x (h x)"
    43   shows "h x = f x"
    44   apply (simp only: f_def)
    45   apply (rule THE_default1_equality [symmetric])
    46    apply (rule ex1)
    47   apply (rule elm)
    48   done
    49 
    50 lemma fundef_ex1_iff:
    51   assumes f_def: "f == (\<lambda>x::'a. THE_default (d x) (\<lambda>y. G x y))"
    52   assumes ex1: "\<exists>!y. G x y"
    53   shows "(G x y) = (f x = y)"
    54   apply (auto simp:ex1 f_def THE_default1_equality)
    55   apply (rule THE_defaultI')
    56   apply (rule ex1)
    57   done
    58 
    59 lemma fundef_default_value:
    60   assumes f_def: "f == (\<lambda>x::'a. THE_default (d x) (\<lambda>y. G x y))"
    61   assumes graph: "\<And>x y. G x y \<Longrightarrow> D x"
    62   assumes "\<not> D x"
    63   shows "f x = d x"
    64 proof -
    65   have "\<not>(\<exists>y. G x y)"
    66   proof
    67     assume "\<exists>y. G x y"
    68     hence "D x" using graph ..
    69     with `\<not> D x` show False ..
    70   qed
    71   hence "\<not>(\<exists>!y. G x y)" by blast
    72 
    73   thus ?thesis
    74     unfolding f_def
    75     by (rule THE_default_none)
    76 qed
    77 
    78 definition in_rel_def[simp]:
    79   "in_rel R x y == (x, y) \<in> R"
    80 
    81 lemma wf_in_rel:
    82   "wf R \<Longrightarrow> wfP (in_rel R)"
    83   by (simp add: wfP_def)
    84 
    85 ML_file "Tools/Function/function_common.ML"
    86 ML_file "Tools/Function/context_tree.ML"
    87 ML_file "Tools/Function/function_core.ML"
    88 ML_file "Tools/Function/sum_tree.ML"
    89 ML_file "Tools/Function/mutual.ML"
    90 ML_file "Tools/Function/pattern_split.ML"
    91 ML_file "Tools/Function/relation.ML"
    92 ML_file "Tools/Function/function_elims.ML"
    93 
    94 method_setup relation = {*
    95   Args.term >> (fn t => fn ctxt => SIMPLE_METHOD' (Function_Relation.relation_infer_tac ctxt t))
    96 *} "prove termination using a user-specified wellfounded relation"
    97 
    98 ML_file "Tools/Function/function.ML"
    99 ML_file "Tools/Function/pat_completeness.ML"
   100 
   101 method_setup pat_completeness = {*
   102   Scan.succeed (SIMPLE_METHOD' o Pat_Completeness.pat_completeness_tac)
   103 *} "prove completeness of datatype patterns"
   104 
   105 ML_file "Tools/Function/fun.ML"
   106 ML_file "Tools/Function/induction_schema.ML"
   107 
   108 method_setup induction_schema = {*
   109   Scan.succeed (RAW_METHOD o Induction_Schema.induction_schema_tac)
   110 *} "prove an induction principle"
   111 
   112 setup {*
   113   Function.setup
   114   #> Function_Fun.setup
   115 *}
   116 
   117 subsection {* Measure Functions *}
   118 
   119 inductive is_measure :: "('a \<Rightarrow> nat) \<Rightarrow> bool"
   120 where is_measure_trivial: "is_measure f"
   121 
   122 ML_file "Tools/Function/measure_functions.ML"
   123 setup MeasureFunctions.setup
   124 
   125 lemma measure_size[measure_function]: "is_measure size"
   126 by (rule is_measure_trivial)
   127 
   128 lemma measure_fst[measure_function]: "is_measure f \<Longrightarrow> is_measure (\<lambda>p. f (fst p))"
   129 by (rule is_measure_trivial)
   130 lemma measure_snd[measure_function]: "is_measure f \<Longrightarrow> is_measure (\<lambda>p. f (snd p))"
   131 by (rule is_measure_trivial)
   132 
   133 ML_file "Tools/Function/lexicographic_order.ML"
   134 
   135 method_setup lexicographic_order = {*
   136   Method.sections clasimp_modifiers >>
   137   (K (SIMPLE_METHOD o Lexicographic_Order.lexicographic_order_tac false))
   138 *} "termination prover for lexicographic orderings"
   139 
   140 setup Lexicographic_Order.setup
   141 
   142 
   143 subsection {* Congruence Rules *}
   144 
   145 lemma let_cong [fundef_cong]:
   146   "M = N \<Longrightarrow> (\<And>x. x = N \<Longrightarrow> f x = g x) \<Longrightarrow> Let M f = Let N g"
   147   unfolding Let_def by blast
   148 
   149 lemmas [fundef_cong] =
   150   if_cong image_cong INT_cong UN_cong
   151   bex_cong ball_cong imp_cong Option.map_cong Option.bind_cong
   152 
   153 lemma split_cong [fundef_cong]:
   154   "(\<And>x y. (x, y) = q \<Longrightarrow> f x y = g x y) \<Longrightarrow> p = q
   155     \<Longrightarrow> split f p = split g q"
   156   by (auto simp: split_def)
   157 
   158 lemma comp_cong [fundef_cong]:
   159   "f (g x) = f' (g' x') \<Longrightarrow> (f o g) x = (f' o g') x'"
   160   unfolding o_apply .
   161 
   162 subsection {* Simp rules for termination proofs *}
   163 
   164 lemma termination_basic_simps[termination_simp]:
   165   "x < (y::nat) \<Longrightarrow> x < y + z"
   166   "x < z \<Longrightarrow> x < y + z"
   167   "x \<le> y \<Longrightarrow> x \<le> y + (z::nat)"
   168   "x \<le> z \<Longrightarrow> x \<le> y + (z::nat)"
   169   "x < y \<Longrightarrow> x \<le> (y::nat)"
   170 by arith+
   171 
   172 declare le_imp_less_Suc[termination_simp]
   173 
   174 lemma prod_size_simp[termination_simp]:
   175   "prod_size f g p = f (fst p) + g (snd p) + Suc 0"
   176 by (induct p) auto
   177 
   178 subsection {* Decomposition *}
   179 
   180 lemma less_by_empty:
   181   "A = {} \<Longrightarrow> A \<subseteq> B"
   182 and  union_comp_emptyL:
   183   "\<lbrakk> A O C = {}; B O C = {} \<rbrakk> \<Longrightarrow> (A \<union> B) O C = {}"
   184 and union_comp_emptyR:
   185   "\<lbrakk> A O B = {}; A O C = {} \<rbrakk> \<Longrightarrow> A O (B \<union> C) = {}"
   186 and wf_no_loop:
   187   "R O R = {} \<Longrightarrow> wf R"
   188 by (auto simp add: wf_comp_self[of R])
   189 
   190 
   191 subsection {* Reduction Pairs *}
   192 
   193 definition
   194   "reduction_pair P = (wf (fst P) \<and> fst P O snd P \<subseteq> fst P)"
   195 
   196 lemma reduction_pairI[intro]: "wf R \<Longrightarrow> R O S \<subseteq> R \<Longrightarrow> reduction_pair (R, S)"
   197 unfolding reduction_pair_def by auto
   198 
   199 lemma reduction_pair_lemma:
   200   assumes rp: "reduction_pair P"
   201   assumes "R \<subseteq> fst P"
   202   assumes "S \<subseteq> snd P"
   203   assumes "wf S"
   204   shows "wf (R \<union> S)"
   205 proof -
   206   from rp `S \<subseteq> snd P` have "wf (fst P)" "fst P O S \<subseteq> fst P"
   207     unfolding reduction_pair_def by auto
   208   with `wf S` have "wf (fst P \<union> S)"
   209     by (auto intro: wf_union_compatible)
   210   moreover from `R \<subseteq> fst P` have "R \<union> S \<subseteq> fst P \<union> S" by auto
   211   ultimately show ?thesis by (rule wf_subset)
   212 qed
   213 
   214 definition
   215   "rp_inv_image = (\<lambda>(R,S) f. (inv_image R f, inv_image S f))"
   216 
   217 lemma rp_inv_image_rp:
   218   "reduction_pair P \<Longrightarrow> reduction_pair (rp_inv_image P f)"
   219   unfolding reduction_pair_def rp_inv_image_def split_def
   220   by force
   221 
   222 
   223 subsection {* Concrete orders for SCNP termination proofs *}
   224 
   225 definition "pair_less = less_than <*lex*> less_than"
   226 definition "pair_leq = pair_less^="
   227 definition "max_strict = max_ext pair_less"
   228 definition "max_weak = max_ext pair_leq \<union> {({}, {})}"
   229 definition "min_strict = min_ext pair_less"
   230 definition "min_weak = min_ext pair_leq \<union> {({}, {})}"
   231 
   232 lemma wf_pair_less[simp]: "wf pair_less"
   233   by (auto simp: pair_less_def)
   234 
   235 text {* Introduction rules for @{text pair_less}/@{text pair_leq} *}
   236 lemma pair_leqI1: "a < b \<Longrightarrow> ((a, s), (b, t)) \<in> pair_leq"
   237   and pair_leqI2: "a \<le> b \<Longrightarrow> s \<le> t \<Longrightarrow> ((a, s), (b, t)) \<in> pair_leq"
   238   and pair_lessI1: "a < b  \<Longrightarrow> ((a, s), (b, t)) \<in> pair_less"
   239   and pair_lessI2: "a \<le> b \<Longrightarrow> s < t \<Longrightarrow> ((a, s), (b, t)) \<in> pair_less"
   240   unfolding pair_leq_def pair_less_def by auto
   241 
   242 text {* Introduction rules for max *}
   243 lemma smax_emptyI:
   244   "finite Y \<Longrightarrow> Y \<noteq> {} \<Longrightarrow> ({}, Y) \<in> max_strict"
   245   and smax_insertI:
   246   "\<lbrakk>y \<in> Y; (x, y) \<in> pair_less; (X, Y) \<in> max_strict\<rbrakk> \<Longrightarrow> (insert x X, Y) \<in> max_strict"
   247   and wmax_emptyI:
   248   "finite X \<Longrightarrow> ({}, X) \<in> max_weak"
   249   and wmax_insertI:
   250   "\<lbrakk>y \<in> YS; (x, y) \<in> pair_leq; (XS, YS) \<in> max_weak\<rbrakk> \<Longrightarrow> (insert x XS, YS) \<in> max_weak"
   251 unfolding max_strict_def max_weak_def by (auto elim!: max_ext.cases)
   252 
   253 text {* Introduction rules for min *}
   254 lemma smin_emptyI:
   255   "X \<noteq> {} \<Longrightarrow> (X, {}) \<in> min_strict"
   256   and smin_insertI:
   257   "\<lbrakk>x \<in> XS; (x, y) \<in> pair_less; (XS, YS) \<in> min_strict\<rbrakk> \<Longrightarrow> (XS, insert y YS) \<in> min_strict"
   258   and wmin_emptyI:
   259   "(X, {}) \<in> min_weak"
   260   and wmin_insertI:
   261   "\<lbrakk>x \<in> XS; (x, y) \<in> pair_leq; (XS, YS) \<in> min_weak\<rbrakk> \<Longrightarrow> (XS, insert y YS) \<in> min_weak"
   262 by (auto simp: min_strict_def min_weak_def min_ext_def)
   263 
   264 text {* Reduction Pairs *}
   265 
   266 lemma max_ext_compat:
   267   assumes "R O S \<subseteq> R"
   268   shows "max_ext R O (max_ext S \<union> {({},{})}) \<subseteq> max_ext R"
   269 using assms
   270 apply auto
   271 apply (elim max_ext.cases)
   272 apply rule
   273 apply auto[3]
   274 apply (drule_tac x=xa in meta_spec)
   275 apply simp
   276 apply (erule bexE)
   277 apply (drule_tac x=xb in meta_spec)
   278 by auto
   279 
   280 lemma max_rpair_set: "reduction_pair (max_strict, max_weak)"
   281   unfolding max_strict_def max_weak_def
   282 apply (intro reduction_pairI max_ext_wf)
   283 apply simp
   284 apply (rule max_ext_compat)
   285 by (auto simp: pair_less_def pair_leq_def)
   286 
   287 lemma min_ext_compat:
   288   assumes "R O S \<subseteq> R"
   289   shows "min_ext R O  (min_ext S \<union> {({},{})}) \<subseteq> min_ext R"
   290 using assms
   291 apply (auto simp: min_ext_def)
   292 apply (drule_tac x=ya in bspec, assumption)
   293 apply (erule bexE)
   294 apply (drule_tac x=xc in bspec)
   295 apply assumption
   296 by auto
   297 
   298 lemma min_rpair_set: "reduction_pair (min_strict, min_weak)"
   299   unfolding min_strict_def min_weak_def
   300 apply (intro reduction_pairI min_ext_wf)
   301 apply simp
   302 apply (rule min_ext_compat)
   303 by (auto simp: pair_less_def pair_leq_def)
   304 
   305 
   306 subsection {* Tool setup *}
   307 
   308 ML_file "Tools/Function/termination.ML"
   309 ML_file "Tools/Function/scnp_solve.ML"
   310 ML_file "Tools/Function/scnp_reconstruct.ML"
   311 ML_file "Tools/Function/fun_cases.ML"
   312 
   313 setup {* ScnpReconstruct.setup *}
   314 
   315 ML_val -- "setup inactive"
   316 {*
   317   Context.theory_map (Function_Common.set_termination_prover
   318     (ScnpReconstruct.decomp_scnp_tac [ScnpSolve.MAX, ScnpSolve.MIN, ScnpSolve.MS]))
   319 *}
   320 
   321 end