src/HOL/Parity.thy
author hoelzl
Tue Nov 05 09:44:57 2013 +0100 (2013-11-05)
changeset 54257 5c7a3b6b05a9
parent 54228 229282d53781
child 54489 03ff4d1e6784
permissions -rw-r--r--
generalize SUP and INF to the syntactic type classes Sup and Inf
     1 (*  Title:      HOL/Parity.thy
     2     Author:     Jeremy Avigad
     3     Author:     Jacques D. Fleuriot
     4 *)
     5 
     6 header {* Even and Odd for int and nat *}
     7 
     8 theory Parity
     9 imports Main
    10 begin
    11 
    12 class even_odd = semiring_div_parity
    13 begin
    14 
    15 definition even :: "'a \<Rightarrow> bool"
    16 where
    17   even_def [presburger]: "even a \<longleftrightarrow> a mod 2 = 0"
    18 
    19 lemma even_iff_2_dvd [algebra]:
    20   "even a \<longleftrightarrow> 2 dvd a"
    21   by (simp add: even_def dvd_eq_mod_eq_0)
    22 
    23 lemma even_zero [simp]:
    24   "even 0"
    25   by (simp add: even_def)
    26 
    27 lemma even_times_anything:
    28   "even a \<Longrightarrow> even (a * b)"
    29   by (simp add: even_iff_2_dvd)
    30 
    31 lemma anything_times_even:
    32   "even a \<Longrightarrow> even (b * a)"
    33   by (simp add: even_iff_2_dvd)
    34 
    35 abbreviation odd :: "'a \<Rightarrow> bool"
    36 where
    37   "odd a \<equiv> \<not> even a"
    38 
    39 lemma odd_times_odd:
    40   "odd a \<Longrightarrow> odd b \<Longrightarrow> odd (a * b)" 
    41   by (auto simp add: even_def mod_mult_left_eq)
    42 
    43 lemma even_product [simp, presburger]:
    44   "even (a * b) \<longleftrightarrow> even a \<or> even b"
    45   apply (auto simp add: even_times_anything anything_times_even)
    46   apply (rule ccontr)
    47   apply (auto simp add: odd_times_odd)
    48   done
    49 
    50 end
    51 
    52 instance nat and int  :: even_odd ..
    53 
    54 lemma even_nat_def [presburger]:
    55   "even x \<longleftrightarrow> even (int x)"
    56   by (auto simp add: even_def int_eq_iff int_mult nat_mult_distrib)
    57   
    58 lemma transfer_int_nat_relations:
    59   "even (int x) \<longleftrightarrow> even x"
    60   by (simp add: even_nat_def)
    61 
    62 declare transfer_morphism_int_nat[transfer add return:
    63   transfer_int_nat_relations
    64 ]
    65 
    66 lemma odd_one_int [simp]:
    67   "odd (1::int)"
    68   by presburger
    69 
    70 lemma odd_1_nat [simp]:
    71   "odd (1::nat)"
    72   by presburger
    73 
    74 lemma even_numeral_int [simp]: "even (numeral (Num.Bit0 k) :: int)"
    75   unfolding even_def by simp
    76 
    77 lemma odd_numeral_int [simp]: "odd (numeral (Num.Bit1 k) :: int)"
    78   unfolding even_def by simp
    79 
    80 (* TODO: proper simp rules for Num.Bit0, Num.Bit1 *)
    81 declare even_def [of "neg_numeral v", simp] for v
    82 
    83 lemma even_numeral_nat [simp]: "even (numeral (Num.Bit0 k) :: nat)"
    84   unfolding even_nat_def by simp
    85 
    86 lemma odd_numeral_nat [simp]: "odd (numeral (Num.Bit1 k) :: nat)"
    87   unfolding even_nat_def by simp
    88 
    89 subsection {* Even and odd are mutually exclusive *}
    90 
    91 
    92 subsection {* Behavior under integer arithmetic operations *}
    93 
    94 lemma even_plus_even: "even (x::int) ==> even y ==> even (x + y)"
    95 by presburger
    96 
    97 lemma even_plus_odd: "even (x::int) ==> odd y ==> odd (x + y)"
    98 by presburger
    99 
   100 lemma odd_plus_even: "odd (x::int) ==> even y ==> odd (x + y)"
   101 by presburger
   102 
   103 lemma odd_plus_odd: "odd (x::int) ==> odd y ==> even (x + y)" by presburger
   104 
   105 lemma even_sum[simp,presburger]:
   106   "even ((x::int) + y) = ((even x & even y) | (odd x & odd y))"
   107 by presburger
   108 
   109 lemma even_neg[simp,presburger,algebra]: "even (-(x::int)) = even x"
   110 by presburger
   111 
   112 lemma even_difference[simp]:
   113     "even ((x::int) - y) = ((even x & even y) | (odd x & odd y))" by presburger
   114 
   115 lemma even_power[simp,presburger]: "even ((x::int)^n) = (even x & n \<noteq> 0)"
   116 by (induct n) auto
   117 
   118 lemma odd_pow: "odd x ==> odd((x::int)^n)" by simp
   119 
   120 
   121 subsection {* Equivalent definitions *}
   122 
   123 lemma two_times_even_div_two: "even (x::int) ==> 2 * (x div 2) = x" 
   124 by presburger
   125 
   126 lemma two_times_odd_div_two_plus_one:
   127   "odd (x::int) ==> 2 * (x div 2) + 1 = x"
   128 by presburger
   129 
   130 lemma even_equiv_def: "even (x::int) = (EX y. x = 2 * y)" by presburger
   131 
   132 lemma odd_equiv_def: "odd (x::int) = (EX y. x = 2 * y + 1)" by presburger
   133 
   134 subsection {* even and odd for nats *}
   135 
   136 lemma pos_int_even_equiv_nat_even: "0 \<le> x ==> even x = even (nat x)"
   137 by (simp add: even_nat_def)
   138 
   139 lemma even_product_nat[simp,presburger,algebra]:
   140   "even((x::nat) * y) = (even x | even y)"
   141 by (simp add: even_nat_def int_mult)
   142 
   143 lemma even_sum_nat[simp,presburger,algebra]:
   144   "even ((x::nat) + y) = ((even x & even y) | (odd x & odd y))"
   145 by presburger
   146 
   147 lemma even_difference_nat[simp,presburger,algebra]:
   148   "even ((x::nat) - y) = (x < y | (even x & even y) | (odd x & odd y))"
   149 by presburger
   150 
   151 lemma even_Suc[simp,presburger,algebra]: "even (Suc x) = odd x"
   152 by presburger
   153 
   154 lemma even_power_nat[simp,presburger,algebra]:
   155   "even ((x::nat)^y) = (even x & 0 < y)"
   156 by (simp add: even_nat_def int_power)
   157 
   158 
   159 subsection {* Equivalent definitions *}
   160 
   161 lemma even_nat_mod_two_eq_zero: "even (x::nat) ==> x mod (Suc (Suc 0)) = 0"
   162 by presburger
   163 
   164 lemma odd_nat_mod_two_eq_one: "odd (x::nat) ==> x mod (Suc (Suc 0)) = Suc 0"
   165 by presburger
   166 
   167 lemma even_nat_equiv_def: "even (x::nat) = (x mod Suc (Suc 0) = 0)"
   168 by presburger
   169 
   170 lemma odd_nat_equiv_def: "odd (x::nat) = (x mod Suc (Suc 0) = Suc 0)"
   171 by presburger
   172 
   173 lemma even_nat_div_two_times_two: "even (x::nat) ==>
   174     Suc (Suc 0) * (x div Suc (Suc 0)) = x" by presburger
   175 
   176 lemma odd_nat_div_two_times_two_plus_one: "odd (x::nat) ==>
   177     Suc( Suc (Suc 0) * (x div Suc (Suc 0))) = x" by presburger
   178 
   179 lemma even_nat_equiv_def2: "even (x::nat) = (EX y. x = Suc (Suc 0) * y)"
   180 by presburger
   181 
   182 lemma odd_nat_equiv_def2: "odd (x::nat) = (EX y. x = Suc(Suc (Suc 0) * y))"
   183 by presburger
   184 
   185 
   186 subsection {* Parity and powers *}
   187 
   188 lemma (in comm_ring_1) neg_power_if:
   189   "(- a) ^ n = (if even n then (a ^ n) else - (a ^ n))"
   190   by (induct n) simp_all
   191 
   192 lemma (in comm_ring_1)
   193   shows minus_one_even_power [simp]: "even n \<Longrightarrow> (- 1) ^ n = 1"
   194   and minus_one_odd_power [simp]: "odd n \<Longrightarrow> (- 1) ^ n = - 1"
   195   by (simp_all add: neg_power_if del: minus_one)
   196 
   197 lemma (in comm_ring_1)
   198   shows neg_one_even_power [simp]: "even n \<Longrightarrow> (-1) ^ n = 1"
   199   and neg_one_odd_power [simp]: "odd n \<Longrightarrow> (-1) ^ n = - 1"
   200   by (simp_all add: minus_one [symmetric] del: minus_one)
   201 
   202 lemma zero_le_even_power: "even n ==>
   203     0 <= (x::'a::{linordered_ring,monoid_mult}) ^ n"
   204   apply (simp add: even_nat_equiv_def2)
   205   apply (erule exE)
   206   apply (erule ssubst)
   207   apply (subst power_add)
   208   apply (rule zero_le_square)
   209   done
   210 
   211 lemma zero_le_odd_power: "odd n ==>
   212     (0 <= (x::'a::{linordered_idom}) ^ n) = (0 <= x)"
   213 apply (auto simp: odd_nat_equiv_def2 power_add zero_le_mult_iff)
   214 apply (metis field_power_not_zero divisors_zero order_antisym_conv zero_le_square)
   215 done
   216 
   217 lemma zero_le_power_eq [presburger]: "(0 <= (x::'a::{linordered_idom}) ^ n) =
   218     (even n | (odd n & 0 <= x))"
   219   apply auto
   220   apply (subst zero_le_odd_power [symmetric])
   221   apply assumption+
   222   apply (erule zero_le_even_power)
   223   done
   224 
   225 lemma zero_less_power_eq[presburger]: "(0 < (x::'a::{linordered_idom}) ^ n) =
   226     (n = 0 | (even n & x ~= 0) | (odd n & 0 < x))"
   227 
   228   unfolding order_less_le zero_le_power_eq by auto
   229 
   230 lemma power_less_zero_eq[presburger]: "((x::'a::{linordered_idom}) ^ n < 0) =
   231     (odd n & x < 0)"
   232   apply (subst linorder_not_le [symmetric])+
   233   apply (subst zero_le_power_eq)
   234   apply auto
   235   done
   236 
   237 lemma power_le_zero_eq[presburger]: "((x::'a::{linordered_idom}) ^ n <= 0) =
   238     (n ~= 0 & ((odd n & x <= 0) | (even n & x = 0)))"
   239   apply (subst linorder_not_less [symmetric])+
   240   apply (subst zero_less_power_eq)
   241   apply auto
   242   done
   243 
   244 lemma power_even_abs: "even n ==>
   245     (abs (x::'a::{linordered_idom}))^n = x^n"
   246   apply (subst power_abs [symmetric])
   247   apply (simp add: zero_le_even_power)
   248   done
   249 
   250 lemma power_minus_even [simp]: "even n ==>
   251     (- x)^n = (x^n::'a::{comm_ring_1})"
   252   apply (subst power_minus)
   253   apply simp
   254   done
   255 
   256 lemma power_minus_odd [simp]: "odd n ==>
   257     (- x)^n = - (x^n::'a::{comm_ring_1})"
   258   apply (subst power_minus)
   259   apply simp
   260   done
   261 
   262 lemma power_mono_even: fixes x y :: "'a :: {linordered_idom}"
   263   assumes "even n" and "\<bar>x\<bar> \<le> \<bar>y\<bar>"
   264   shows "x^n \<le> y^n"
   265 proof -
   266   have "0 \<le> \<bar>x\<bar>" by auto
   267   with `\<bar>x\<bar> \<le> \<bar>y\<bar>`
   268   have "\<bar>x\<bar>^n \<le> \<bar>y\<bar>^n" by (rule power_mono)
   269   thus ?thesis unfolding power_even_abs[OF `even n`] .
   270 qed
   271 
   272 lemma odd_pos: "odd (n::nat) \<Longrightarrow> 0 < n" by presburger
   273 
   274 lemma power_mono_odd: fixes x y :: "'a :: {linordered_idom}"
   275   assumes "odd n" and "x \<le> y"
   276   shows "x^n \<le> y^n"
   277 proof (cases "y < 0")
   278   case True with `x \<le> y` have "-y \<le> -x" and "0 \<le> -y" by auto
   279   hence "(-y)^n \<le> (-x)^n" by (rule power_mono)
   280   thus ?thesis unfolding power_minus_odd[OF `odd n`] by auto
   281 next
   282   case False
   283   show ?thesis
   284   proof (cases "x < 0")
   285     case True hence "n \<noteq> 0" and "x \<le> 0" using `odd n`[THEN odd_pos] by auto
   286     hence "x^n \<le> 0" unfolding power_le_zero_eq using `odd n` by auto
   287     moreover
   288     from `\<not> y < 0` have "0 \<le> y" by auto
   289     hence "0 \<le> y^n" by auto
   290     ultimately show ?thesis by auto
   291   next
   292     case False hence "0 \<le> x" by auto
   293     with `x \<le> y` show ?thesis using power_mono by auto
   294   qed
   295 qed
   296 
   297 
   298 subsection {* More Even/Odd Results *}
   299  
   300 lemma even_mult_two_ex: "even(n) = (\<exists>m::nat. n = 2*m)" by presburger
   301 lemma odd_Suc_mult_two_ex: "odd(n) = (\<exists>m. n = Suc (2*m))" by presburger
   302 lemma even_add [simp]: "even(m + n::nat) = (even m = even n)"  by presburger
   303 
   304 lemma odd_add [simp]: "odd(m + n::nat) = (odd m \<noteq> odd n)" by presburger
   305 
   306 lemma lemma_even_div2 [simp]: "even (n::nat) ==> (n + 1) div 2 = n div 2" by presburger
   307 
   308 lemma lemma_not_even_div2 [simp]: "~even n ==> (n + 1) div 2 = Suc (n div 2)"
   309 by presburger
   310 
   311 lemma even_num_iff: "0 < n ==> even n = (~ even(n - 1 :: nat))"  by presburger
   312 lemma even_even_mod_4_iff: "even (n::nat) = even (n mod 4)" by presburger
   313 
   314 lemma lemma_odd_mod_4_div_2: "n mod 4 = (3::nat) ==> odd((n - 1) div 2)" by presburger
   315 
   316 lemma lemma_even_mod_4_div_2: "n mod 4 = (1::nat) ==> even ((n - 1) div 2)"
   317   by presburger
   318 
   319 text {* Simplify, when the exponent is a numeral *}
   320 
   321 lemmas zero_le_power_eq_numeral [simp] =
   322   zero_le_power_eq [of _ "numeral w"] for w
   323 
   324 lemmas zero_less_power_eq_numeral [simp] =
   325   zero_less_power_eq [of _ "numeral w"] for w
   326 
   327 lemmas power_le_zero_eq_numeral [simp] =
   328   power_le_zero_eq [of _ "numeral w"] for w
   329 
   330 lemmas power_less_zero_eq_numeral [simp] =
   331   power_less_zero_eq [of _ "numeral w"] for w
   332 
   333 lemmas zero_less_power_nat_eq_numeral [simp] =
   334   nat_zero_less_power_iff [of _ "numeral w"] for w
   335 
   336 lemmas power_eq_0_iff_numeral [simp] =
   337   power_eq_0_iff [of _ "numeral w"] for w
   338 
   339 lemmas power_even_abs_numeral [simp] =
   340   power_even_abs [of "numeral w" _] for w
   341 
   342 
   343 subsection {* An Equivalence for @{term [source] "0 \<le> a^n"} *}
   344 
   345 lemma zero_le_power_iff[presburger]:
   346   "(0 \<le> a^n) = (0 \<le> (a::'a::{linordered_idom}) | even n)"
   347 proof cases
   348   assume even: "even n"
   349   then obtain k where "n = 2*k"
   350     by (auto simp add: even_nat_equiv_def2 numeral_2_eq_2)
   351   thus ?thesis by (simp add: zero_le_even_power even)
   352 next
   353   assume odd: "odd n"
   354   then obtain k where "n = Suc(2*k)"
   355     by (auto simp add: odd_nat_equiv_def2 numeral_2_eq_2)
   356   moreover have "a ^ (2 * k) \<le> 0 \<Longrightarrow> a = 0"
   357     by (induct k) (auto simp add: zero_le_mult_iff mult_le_0_iff)
   358   ultimately show ?thesis
   359     by (auto simp add: zero_le_mult_iff zero_le_even_power)
   360 qed
   361 
   362 
   363 subsection {* Miscellaneous *}
   364 
   365 lemma [presburger]:"(x + 1) div 2 = x div 2 \<longleftrightarrow> even (x::int)" by presburger
   366 lemma [presburger]: "(x + 1) div 2 = x div 2 + 1 \<longleftrightarrow> odd (x::int)" by presburger
   367 lemma even_plus_one_div_two: "even (x::int) ==> (x + 1) div 2 = x div 2"  by presburger
   368 lemma odd_plus_one_div_two: "odd (x::int) ==> (x + 1) div 2 = x div 2 + 1" by presburger
   369 
   370 lemma [presburger]: "(Suc x) div Suc (Suc 0) = x div Suc (Suc 0) \<longleftrightarrow> even x" by presburger
   371 lemma even_nat_plus_one_div_two: "even (x::nat) ==>
   372     (Suc x) div Suc (Suc 0) = x div Suc (Suc 0)" by presburger
   373 
   374 lemma odd_nat_plus_one_div_two: "odd (x::nat) ==>
   375     (Suc x) div Suc (Suc 0) = Suc (x div Suc (Suc 0))" by presburger
   376 
   377 end
   378