src/HOL/Set.thy
author haftmann
Fri Apr 20 11:21:42 2007 +0200 (2007-04-20)
changeset 22744 5cbe966d67a2
parent 22478 110f7f6f8a5d
child 22845 5f9138bcb3d7
permissions -rw-r--r--
Isar definitions are now added explicitly to code theorem table
     1 (*  Title:      HOL/Set.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel
     4 *)
     5 
     6 header {* Set theory for higher-order logic *}
     7 
     8 theory Set
     9 imports Lattices
    10 begin
    11 
    12 text {* A set in HOL is simply a predicate. *}
    13 
    14 
    15 subsection {* Basic syntax *}
    16 
    17 global
    18 
    19 typedecl 'a set
    20 arities set :: (type) type
    21 
    22 consts
    23   "{}"          :: "'a set"                             ("{}")
    24   UNIV          :: "'a set"
    25   insert        :: "'a => 'a set => 'a set"
    26   Collect       :: "('a => bool) => 'a set"              -- "comprehension"
    27   Int           :: "'a set => 'a set => 'a set"          (infixl 70)
    28   Un            :: "'a set => 'a set => 'a set"          (infixl 65)
    29   UNION         :: "'a set => ('a => 'b set) => 'b set"  -- "general union"
    30   INTER         :: "'a set => ('a => 'b set) => 'b set"  -- "general intersection"
    31   Union         :: "'a set set => 'a set"                -- "union of a set"
    32   Inter         :: "'a set set => 'a set"                -- "intersection of a set"
    33   Pow           :: "'a set => 'a set set"                -- "powerset"
    34   Ball          :: "'a set => ('a => bool) => bool"      -- "bounded universal quantifiers"
    35   Bex           :: "'a set => ('a => bool) => bool"      -- "bounded existential quantifiers"
    36   Bex1          :: "'a set => ('a => bool) => bool"      -- "bounded unique existential quantifiers"
    37   image         :: "('a => 'b) => 'a set => 'b set"      (infixr "`" 90)
    38   "op :"        :: "'a => 'a set => bool"                -- "membership"
    39 
    40 notation
    41   "op :"  ("op :") and
    42   "op :"  ("(_/ : _)" [50, 51] 50)
    43 
    44 local
    45 
    46 
    47 subsection {* Additional concrete syntax *}
    48 
    49 abbreviation
    50   range :: "('a => 'b) => 'b set" where -- "of function"
    51   "range f == f ` UNIV"
    52 
    53 abbreviation
    54   "not_mem x A == ~ (x : A)" -- "non-membership"
    55 
    56 notation
    57   not_mem  ("op ~:") and
    58   not_mem  ("(_/ ~: _)" [50, 51] 50)
    59 
    60 notation (xsymbols)
    61   "op Int"  (infixl "\<inter>" 70) and
    62   "op Un"  (infixl "\<union>" 65) and
    63   "op :"  ("op \<in>") and
    64   "op :"  ("(_/ \<in> _)" [50, 51] 50) and
    65   not_mem  ("op \<notin>") and
    66   not_mem  ("(_/ \<notin> _)" [50, 51] 50) and
    67   Union  ("\<Union>_" [90] 90) and
    68   Inter  ("\<Inter>_" [90] 90)
    69 
    70 notation (HTML output)
    71   "op Int"  (infixl "\<inter>" 70) and
    72   "op Un"  (infixl "\<union>" 65) and
    73   "op :"  ("op \<in>") and
    74   "op :"  ("(_/ \<in> _)" [50, 51] 50) and
    75   not_mem  ("op \<notin>") and
    76   not_mem  ("(_/ \<notin> _)" [50, 51] 50)
    77 
    78 syntax
    79   "@Finset"     :: "args => 'a set"                       ("{(_)}")
    80   "@Coll"       :: "pttrn => bool => 'a set"              ("(1{_./ _})")
    81   "@SetCompr"   :: "'a => idts => bool => 'a set"         ("(1{_ |/_./ _})")
    82   "@Collect"    :: "idt => 'a set => bool => 'a set"      ("(1{_ :/ _./ _})")
    83   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" [0, 10] 10)
    84   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" [0, 10] 10)
    85   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" [0, 10] 10)
    86   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" [0, 10] 10)
    87   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3ALL _:_./ _)" [0, 0, 10] 10)
    88   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3EX _:_./ _)" [0, 0, 10] 10)
    89   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3EX! _:_./ _)" [0, 0, 10] 10)
    90   "_Bleast"     :: "id => 'a set => bool => 'a"           ("(3LEAST _:_./ _)" [0, 0, 10] 10)
    91 
    92 syntax (HOL)
    93   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3! _:_./ _)" [0, 0, 10] 10)
    94   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3? _:_./ _)" [0, 0, 10] 10)
    95   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3?! _:_./ _)" [0, 0, 10] 10)
    96 
    97 translations
    98   "{x, xs}"     == "insert x {xs}"
    99   "{x}"         == "insert x {}"
   100   "{x. P}"      == "Collect (%x. P)"
   101   "{x:A. P}"    => "{x. x:A & P}"
   102   "UN x y. B"   == "UN x. UN y. B"
   103   "UN x. B"     == "UNION UNIV (%x. B)"
   104   "UN x. B"     == "UN x:UNIV. B"
   105   "INT x y. B"  == "INT x. INT y. B"
   106   "INT x. B"    == "INTER UNIV (%x. B)"
   107   "INT x. B"    == "INT x:UNIV. B"
   108   "UN x:A. B"   == "UNION A (%x. B)"
   109   "INT x:A. B"  == "INTER A (%x. B)"
   110   "ALL x:A. P"  == "Ball A (%x. P)"
   111   "EX x:A. P"   == "Bex A (%x. P)"
   112   "EX! x:A. P"  == "Bex1 A (%x. P)"
   113   "LEAST x:A. P" => "LEAST x. x:A & P"
   114 
   115 syntax (xsymbols)
   116   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3\<forall>_\<in>_./ _)" [0, 0, 10] 10)
   117   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3\<exists>_\<in>_./ _)" [0, 0, 10] 10)
   118   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3\<exists>!_\<in>_./ _)" [0, 0, 10] 10)
   119   "_Bleast"     :: "id => 'a set => bool => 'a"           ("(3LEAST_\<in>_./ _)" [0, 0, 10] 10)
   120 
   121 syntax (HTML output)
   122   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3\<forall>_\<in>_./ _)" [0, 0, 10] 10)
   123   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3\<exists>_\<in>_./ _)" [0, 0, 10] 10)
   124   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3\<exists>!_\<in>_./ _)" [0, 0, 10] 10)
   125 
   126 syntax (xsymbols)
   127   "@Collect"    :: "idt => 'a set => bool => 'a set"      ("(1{_ \<in>/ _./ _})")
   128   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" [0, 10] 10)
   129   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" [0, 10] 10)
   130   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" [0, 10] 10)
   131   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" [0, 10] 10)
   132 
   133 syntax (latex output)
   134   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   135   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   136   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 10] 10)
   137   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 10] 10)
   138 
   139 text{*
   140   Note the difference between ordinary xsymbol syntax of indexed
   141   unions and intersections (e.g.\ @{text"\<Union>a\<^isub>1\<in>A\<^isub>1. B"})
   142   and their \LaTeX\ rendition: @{term"\<Union>a\<^isub>1\<in>A\<^isub>1. B"}. The
   143   former does not make the index expression a subscript of the
   144   union/intersection symbol because this leads to problems with nested
   145   subscripts in Proof General. *}
   146 
   147 instance set :: (type) ord
   148   subset_def:  "A \<le> B \<equiv> \<forall>x\<in>A. x \<in> B"
   149   psubset_def: "A < B \<equiv> A \<le> B \<and> A \<noteq> B" ..
   150 
   151 lemmas [code nofunc] = subset_def psubset_def
   152 
   153 abbreviation
   154   subset :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   155   "subset \<equiv> less"
   156 
   157 abbreviation
   158   subset_eq :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   159   "subset_eq \<equiv> less_eq"
   160 
   161 notation (output)
   162   subset  ("op <") and
   163   subset  ("(_/ < _)" [50, 51] 50) and
   164   subset_eq  ("op <=") and
   165   subset_eq  ("(_/ <= _)" [50, 51] 50)
   166 
   167 notation (xsymbols)
   168   subset  ("op \<subset>") and
   169   subset  ("(_/ \<subset> _)" [50, 51] 50) and
   170   subset_eq  ("op \<subseteq>") and
   171   subset_eq  ("(_/ \<subseteq> _)" [50, 51] 50)
   172 
   173 notation (HTML output)
   174   subset  ("op \<subset>") and
   175   subset  ("(_/ \<subset> _)" [50, 51] 50) and
   176   subset_eq  ("op \<subseteq>") and
   177   subset_eq  ("(_/ \<subseteq> _)" [50, 51] 50)
   178 
   179 abbreviation (input)
   180   supset :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   181   "supset \<equiv> greater"
   182 
   183 abbreviation (input)
   184   supset_eq :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   185   "supset_eq \<equiv> greater_eq"
   186 
   187 notation (xsymbols)
   188   supset  ("op \<supset>") and
   189   supset  ("(_/ \<supset> _)" [50, 51] 50) and
   190   supset_eq  ("op \<supseteq>") and
   191   supset_eq  ("(_/ \<supseteq> _)" [50, 51] 50)
   192 
   193 
   194 subsubsection "Bounded quantifiers"
   195 
   196 syntax (output)
   197   "_setlessAll" :: "[idt, 'a, bool] => bool"  ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   198   "_setlessEx"  :: "[idt, 'a, bool] => bool"  ("(3EX _<_./ _)"  [0, 0, 10] 10)
   199   "_setleAll"   :: "[idt, 'a, bool] => bool"  ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   200   "_setleEx"    :: "[idt, 'a, bool] => bool"  ("(3EX _<=_./ _)" [0, 0, 10] 10)
   201   "_setleEx1"   :: "[idt, 'a, bool] => bool"  ("(3EX! _<=_./ _)" [0, 0, 10] 10)
   202 
   203 syntax (xsymbols)
   204   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subset>_./ _)"  [0, 0, 10] 10)
   205   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subset>_./ _)"  [0, 0, 10] 10)
   206   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subseteq>_./ _)" [0, 0, 10] 10)
   207   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subseteq>_./ _)" [0, 0, 10] 10)
   208   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3\<exists>!_\<subseteq>_./ _)" [0, 0, 10] 10)
   209 
   210 syntax (HOL output)
   211   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3! _<_./ _)"  [0, 0, 10] 10)
   212   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3? _<_./ _)"  [0, 0, 10] 10)
   213   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3! _<=_./ _)" [0, 0, 10] 10)
   214   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3? _<=_./ _)" [0, 0, 10] 10)
   215   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3?! _<=_./ _)" [0, 0, 10] 10)
   216 
   217 syntax (HTML output)
   218   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subset>_./ _)"  [0, 0, 10] 10)
   219   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subset>_./ _)"  [0, 0, 10] 10)
   220   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subseteq>_./ _)" [0, 0, 10] 10)
   221   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subseteq>_./ _)" [0, 0, 10] 10)
   222   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3\<exists>!_\<subseteq>_./ _)" [0, 0, 10] 10)
   223 
   224 translations
   225  "\<forall>A\<subset>B. P"   =>  "ALL A. A \<subset> B --> P"
   226  "\<exists>A\<subset>B. P"   =>  "EX A. A \<subset> B & P"
   227  "\<forall>A\<subseteq>B. P"   =>  "ALL A. A \<subseteq> B --> P"
   228  "\<exists>A\<subseteq>B. P"   =>  "EX A. A \<subseteq> B & P"
   229  "\<exists>!A\<subseteq>B. P"  =>  "EX! A. A \<subseteq> B & P"
   230 
   231 print_translation {*
   232 let
   233   val Type (set_type, _) = @{typ "'a set"};
   234   val All_binder = Syntax.binder_name @{const_syntax "All"};
   235   val Ex_binder = Syntax.binder_name @{const_syntax "Ex"};
   236   val impl = @{const_syntax "op -->"};
   237   val conj = @{const_syntax "op &"};
   238   val sbset = @{const_syntax "subset"};
   239   val sbset_eq = @{const_syntax "subset_eq"};
   240 
   241   val trans =
   242    [((All_binder, impl, sbset), "_setlessAll"),
   243     ((All_binder, impl, sbset_eq), "_setleAll"),
   244     ((Ex_binder, conj, sbset), "_setlessEx"),
   245     ((Ex_binder, conj, sbset_eq), "_setleEx")];
   246 
   247   fun mk v v' c n P =
   248     if v = v' andalso not (Term.exists_subterm (fn Free (x, _) => x = v | _ => false) n)
   249     then Syntax.const c $ Syntax.mark_bound v' $ n $ P else raise Match;
   250 
   251   fun tr' q = (q,
   252     fn [Const ("_bound", _) $ Free (v, Type (T, _)), Const (c, _) $ (Const (d, _) $ (Const ("_bound", _) $ Free (v', _)) $ n) $ P] =>
   253          if T = (set_type) then case AList.lookup (op =) trans (q, c, d)
   254           of NONE => raise Match
   255            | SOME l => mk v v' l n P
   256          else raise Match
   257      | _ => raise Match);
   258 in
   259   [tr' All_binder, tr' Ex_binder]
   260 end
   261 *}
   262 
   263 
   264 text {*
   265   \medskip Translate between @{text "{e | x1...xn. P}"} and @{text
   266   "{u. EX x1..xn. u = e & P}"}; @{text "{y. EX x1..xn. y = e & P}"} is
   267   only translated if @{text "[0..n] subset bvs(e)"}.
   268 *}
   269 
   270 parse_translation {*
   271   let
   272     val ex_tr = snd (mk_binder_tr ("EX ", "Ex"));
   273 
   274     fun nvars (Const ("_idts", _) $ _ $ idts) = nvars idts + 1
   275       | nvars _ = 1;
   276 
   277     fun setcompr_tr [e, idts, b] =
   278       let
   279         val eq = Syntax.const "op =" $ Bound (nvars idts) $ e;
   280         val P = Syntax.const "op &" $ eq $ b;
   281         val exP = ex_tr [idts, P];
   282       in Syntax.const "Collect" $ Term.absdummy (dummyT, exP) end;
   283 
   284   in [("@SetCompr", setcompr_tr)] end;
   285 *}
   286 
   287 (* To avoid eta-contraction of body: *)
   288 print_translation {*
   289 let
   290   fun btr' syn [A,Abs abs] =
   291     let val (x,t) = atomic_abs_tr' abs
   292     in Syntax.const syn $ x $ A $ t end
   293 in
   294 [("Ball", btr' "_Ball"),("Bex", btr' "_Bex"),
   295  ("UNION", btr' "@UNION"),("INTER", btr' "@INTER")]
   296 end
   297 *}
   298 
   299 print_translation {*
   300 let
   301   val ex_tr' = snd (mk_binder_tr' ("Ex", "DUMMY"));
   302 
   303   fun setcompr_tr' [Abs (abs as (_, _, P))] =
   304     let
   305       fun check (Const ("Ex", _) $ Abs (_, _, P), n) = check (P, n + 1)
   306         | check (Const ("op &", _) $ (Const ("op =", _) $ Bound m $ e) $ P, n) =
   307             n > 0 andalso m = n andalso not (loose_bvar1 (P, n)) andalso
   308             ((0 upto (n - 1)) subset add_loose_bnos (e, 0, []))
   309         | check _ = false
   310 
   311         fun tr' (_ $ abs) =
   312           let val _ $ idts $ (_ $ (_ $ _ $ e) $ Q) = ex_tr' [abs]
   313           in Syntax.const "@SetCompr" $ e $ idts $ Q end;
   314     in if check (P, 0) then tr' P
   315        else let val (x as _ $ Free(xN,_), t) = atomic_abs_tr' abs
   316                 val M = Syntax.const "@Coll" $ x $ t
   317             in case t of
   318                  Const("op &",_)
   319                    $ (Const("op :",_) $ (Const("_bound",_) $ Free(yN,_)) $ A)
   320                    $ P =>
   321                    if xN=yN then Syntax.const "@Collect" $ x $ A $ P else M
   322                | _ => M
   323             end
   324     end;
   325   in [("Collect", setcompr_tr')] end;
   326 *}
   327 
   328 
   329 subsection {* Rules and definitions *}
   330 
   331 text {* Isomorphisms between predicates and sets. *}
   332 
   333 axioms
   334   mem_Collect_eq: "(a : {x. P(x)}) = P(a)"
   335   Collect_mem_eq: "{x. x:A} = A"
   336 finalconsts
   337   Collect
   338   "op :"
   339 
   340 defs
   341   Ball_def:     "Ball A P       == ALL x. x:A --> P(x)"
   342   Bex_def:      "Bex A P        == EX x. x:A & P(x)"
   343   Bex1_def:     "Bex1 A P       == EX! x. x:A & P(x)"
   344 
   345 instance set :: (type) minus
   346   Compl_def:    "- A            == {x. ~x:A}"
   347   set_diff_def: "A - B          == {x. x:A & ~x:B}" ..
   348 
   349 lemmas [code nofunc] = Compl_def set_diff_def
   350 
   351 defs
   352   Un_def:       "A Un B         == {x. x:A | x:B}"
   353   Int_def:      "A Int B        == {x. x:A & x:B}"
   354   INTER_def:    "INTER A B      == {y. ALL x:A. y: B(x)}"
   355   UNION_def:    "UNION A B      == {y. EX x:A. y: B(x)}"
   356   Inter_def:    "Inter S        == (INT x:S. x)"
   357   Union_def:    "Union S        == (UN x:S. x)"
   358   Pow_def:      "Pow A          == {B. B <= A}"
   359   empty_def:    "{}             == {x. False}"
   360   UNIV_def:     "UNIV           == {x. True}"
   361   insert_def:   "insert a B     == {x. x=a} Un B"
   362   image_def:    "f`A            == {y. EX x:A. y = f(x)}"
   363 
   364 
   365 subsection {* Lemmas and proof tool setup *}
   366 
   367 subsubsection {* Relating predicates and sets *}
   368 
   369 declare mem_Collect_eq [iff]  Collect_mem_eq [simp]
   370 
   371 lemma CollectI: "P(a) ==> a : {x. P(x)}"
   372   by simp
   373 
   374 lemma CollectD: "a : {x. P(x)} ==> P(a)"
   375   by simp
   376 
   377 lemma Collect_cong: "(!!x. P x = Q x) ==> {x. P(x)} = {x. Q(x)}"
   378   by simp
   379 
   380 lemmas CollectE = CollectD [elim_format]
   381 
   382 
   383 subsubsection {* Bounded quantifiers *}
   384 
   385 lemma ballI [intro!]: "(!!x. x:A ==> P x) ==> ALL x:A. P x"
   386   by (simp add: Ball_def)
   387 
   388 lemmas strip = impI allI ballI
   389 
   390 lemma bspec [dest?]: "ALL x:A. P x ==> x:A ==> P x"
   391   by (simp add: Ball_def)
   392 
   393 lemma ballE [elim]: "ALL x:A. P x ==> (P x ==> Q) ==> (x ~: A ==> Q) ==> Q"
   394   by (unfold Ball_def) blast
   395 
   396 ML {* bind_thm ("rev_ballE", permute_prems 1 1 @{thm ballE}) *}
   397 
   398 text {*
   399   \medskip This tactic takes assumptions @{prop "ALL x:A. P x"} and
   400   @{prop "a:A"}; creates assumption @{prop "P a"}.
   401 *}
   402 
   403 ML {*
   404   fun ball_tac i = etac @{thm ballE} i THEN contr_tac (i + 1)
   405 *}
   406 
   407 text {*
   408   Gives better instantiation for bound:
   409 *}
   410 
   411 ML_setup {*
   412   change_claset (fn cs => cs addbefore ("bspec", datac @{thm bspec} 1))
   413 *}
   414 
   415 lemma bexI [intro]: "P x ==> x:A ==> EX x:A. P x"
   416   -- {* Normally the best argument order: @{prop "P x"} constrains the
   417     choice of @{prop "x:A"}. *}
   418   by (unfold Bex_def) blast
   419 
   420 lemma rev_bexI [intro?]: "x:A ==> P x ==> EX x:A. P x"
   421   -- {* The best argument order when there is only one @{prop "x:A"}. *}
   422   by (unfold Bex_def) blast
   423 
   424 lemma bexCI: "(ALL x:A. ~P x ==> P a) ==> a:A ==> EX x:A. P x"
   425   by (unfold Bex_def) blast
   426 
   427 lemma bexE [elim!]: "EX x:A. P x ==> (!!x. x:A ==> P x ==> Q) ==> Q"
   428   by (unfold Bex_def) blast
   429 
   430 lemma ball_triv [simp]: "(ALL x:A. P) = ((EX x. x:A) --> P)"
   431   -- {* Trival rewrite rule. *}
   432   by (simp add: Ball_def)
   433 
   434 lemma bex_triv [simp]: "(EX x:A. P) = ((EX x. x:A) & P)"
   435   -- {* Dual form for existentials. *}
   436   by (simp add: Bex_def)
   437 
   438 lemma bex_triv_one_point1 [simp]: "(EX x:A. x = a) = (a:A)"
   439   by blast
   440 
   441 lemma bex_triv_one_point2 [simp]: "(EX x:A. a = x) = (a:A)"
   442   by blast
   443 
   444 lemma bex_one_point1 [simp]: "(EX x:A. x = a & P x) = (a:A & P a)"
   445   by blast
   446 
   447 lemma bex_one_point2 [simp]: "(EX x:A. a = x & P x) = (a:A & P a)"
   448   by blast
   449 
   450 lemma ball_one_point1 [simp]: "(ALL x:A. x = a --> P x) = (a:A --> P a)"
   451   by blast
   452 
   453 lemma ball_one_point2 [simp]: "(ALL x:A. a = x --> P x) = (a:A --> P a)"
   454   by blast
   455 
   456 ML_setup {*
   457   local
   458     val unfold_bex_tac = unfold_tac @{thms "Bex_def"};
   459     fun prove_bex_tac ss = unfold_bex_tac ss THEN Quantifier1.prove_one_point_ex_tac;
   460     val rearrange_bex = Quantifier1.rearrange_bex prove_bex_tac;
   461 
   462     val unfold_ball_tac = unfold_tac @{thms "Ball_def"};
   463     fun prove_ball_tac ss = unfold_ball_tac ss THEN Quantifier1.prove_one_point_all_tac;
   464     val rearrange_ball = Quantifier1.rearrange_ball prove_ball_tac;
   465   in
   466     val defBEX_regroup = Simplifier.simproc (the_context ())
   467       "defined BEX" ["EX x:A. P x & Q x"] rearrange_bex;
   468     val defBALL_regroup = Simplifier.simproc (the_context ())
   469       "defined BALL" ["ALL x:A. P x --> Q x"] rearrange_ball;
   470   end;
   471 
   472   Addsimprocs [defBALL_regroup, defBEX_regroup];
   473 *}
   474 
   475 
   476 subsubsection {* Congruence rules *}
   477 
   478 lemma ball_cong:
   479   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   480     (ALL x:A. P x) = (ALL x:B. Q x)"
   481   by (simp add: Ball_def)
   482 
   483 lemma strong_ball_cong [cong]:
   484   "A = B ==> (!!x. x:B =simp=> P x = Q x) ==>
   485     (ALL x:A. P x) = (ALL x:B. Q x)"
   486   by (simp add: simp_implies_def Ball_def)
   487 
   488 lemma bex_cong:
   489   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   490     (EX x:A. P x) = (EX x:B. Q x)"
   491   by (simp add: Bex_def cong: conj_cong)
   492 
   493 lemma strong_bex_cong [cong]:
   494   "A = B ==> (!!x. x:B =simp=> P x = Q x) ==>
   495     (EX x:A. P x) = (EX x:B. Q x)"
   496   by (simp add: simp_implies_def Bex_def cong: conj_cong)
   497 
   498 
   499 subsubsection {* Subsets *}
   500 
   501 lemma subsetI [atp,intro!]: "(!!x. x:A ==> x:B) ==> A \<subseteq> B"
   502   by (simp add: subset_def)
   503 
   504 text {*
   505   \medskip Map the type @{text "'a set => anything"} to just @{typ
   506   'a}; for overloading constants whose first argument has type @{typ
   507   "'a set"}.
   508 *}
   509 
   510 lemma subsetD [elim]: "A \<subseteq> B ==> c \<in> A ==> c \<in> B"
   511   -- {* Rule in Modus Ponens style. *}
   512   by (unfold subset_def) blast
   513 
   514 declare subsetD [intro?] -- FIXME
   515 
   516 lemma rev_subsetD: "c \<in> A ==> A \<subseteq> B ==> c \<in> B"
   517   -- {* The same, with reversed premises for use with @{text erule} --
   518       cf @{text rev_mp}. *}
   519   by (rule subsetD)
   520 
   521 declare rev_subsetD [intro?] -- FIXME
   522 
   523 text {*
   524   \medskip Converts @{prop "A \<subseteq> B"} to @{prop "x \<in> A ==> x \<in> B"}.
   525 *}
   526 
   527 ML {*
   528   fun impOfSubs th = th RSN (2, @{thm rev_subsetD})
   529 *}
   530 
   531 lemma subsetCE [elim]: "A \<subseteq>  B ==> (c \<notin> A ==> P) ==> (c \<in> B ==> P) ==> P"
   532   -- {* Classical elimination rule. *}
   533   by (unfold subset_def) blast
   534 
   535 text {*
   536   \medskip Takes assumptions @{prop "A \<subseteq> B"}; @{prop "c \<in> A"} and
   537   creates the assumption @{prop "c \<in> B"}.
   538 *}
   539 
   540 ML {*
   541   fun set_mp_tac i = etac @{thm subsetCE} i THEN mp_tac i
   542 *}
   543 
   544 lemma contra_subsetD: "A \<subseteq> B ==> c \<notin> B ==> c \<notin> A"
   545   by blast
   546 
   547 lemma subset_refl [simp,atp]: "A \<subseteq> A"
   548   by fast
   549 
   550 lemma subset_trans: "A \<subseteq> B ==> B \<subseteq> C ==> A \<subseteq> C"
   551   by blast
   552 
   553 
   554 subsubsection {* Equality *}
   555 
   556 lemma set_ext: assumes prem: "(!!x. (x:A) = (x:B))" shows "A = B"
   557   apply (rule prem [THEN ext, THEN arg_cong, THEN box_equals])
   558    apply (rule Collect_mem_eq)
   559   apply (rule Collect_mem_eq)
   560   done
   561 
   562 (* Due to Brian Huffman *)
   563 lemma expand_set_eq: "(A = B) = (ALL x. (x:A) = (x:B))"
   564 by(auto intro:set_ext)
   565 
   566 lemma subset_antisym [intro!]: "A \<subseteq> B ==> B \<subseteq> A ==> A = B"
   567   -- {* Anti-symmetry of the subset relation. *}
   568   by (iprover intro: set_ext subsetD)
   569 
   570 lemmas equalityI [intro!] = subset_antisym
   571 
   572 text {*
   573   \medskip Equality rules from ZF set theory -- are they appropriate
   574   here?
   575 *}
   576 
   577 lemma equalityD1: "A = B ==> A \<subseteq> B"
   578   by (simp add: subset_refl)
   579 
   580 lemma equalityD2: "A = B ==> B \<subseteq> A"
   581   by (simp add: subset_refl)
   582 
   583 text {*
   584   \medskip Be careful when adding this to the claset as @{text
   585   subset_empty} is in the simpset: @{prop "A = {}"} goes to @{prop "{}
   586   \<subseteq> A"} and @{prop "A \<subseteq> {}"} and then back to @{prop "A = {}"}!
   587 *}
   588 
   589 lemma equalityE: "A = B ==> (A \<subseteq> B ==> B \<subseteq> A ==> P) ==> P"
   590   by (simp add: subset_refl)
   591 
   592 lemma equalityCE [elim]:
   593     "A = B ==> (c \<in> A ==> c \<in> B ==> P) ==> (c \<notin> A ==> c \<notin> B ==> P) ==> P"
   594   by blast
   595 
   596 lemma eqset_imp_iff: "A = B ==> (x : A) = (x : B)"
   597   by simp
   598 
   599 lemma eqelem_imp_iff: "x = y ==> (x : A) = (y : A)"
   600   by simp
   601 
   602 
   603 subsubsection {* The universal set -- UNIV *}
   604 
   605 lemma UNIV_I [simp]: "x : UNIV"
   606   by (simp add: UNIV_def)
   607 
   608 declare UNIV_I [intro]  -- {* unsafe makes it less likely to cause problems *}
   609 
   610 lemma UNIV_witness [intro?]: "EX x. x : UNIV"
   611   by simp
   612 
   613 lemma subset_UNIV [simp]: "A \<subseteq> UNIV"
   614   by (rule subsetI) (rule UNIV_I)
   615 
   616 text {*
   617   \medskip Eta-contracting these two rules (to remove @{text P})
   618   causes them to be ignored because of their interaction with
   619   congruence rules.
   620 *}
   621 
   622 lemma ball_UNIV [simp]: "Ball UNIV P = All P"
   623   by (simp add: Ball_def)
   624 
   625 lemma bex_UNIV [simp]: "Bex UNIV P = Ex P"
   626   by (simp add: Bex_def)
   627 
   628 
   629 subsubsection {* The empty set *}
   630 
   631 lemma empty_iff [simp]: "(c : {}) = False"
   632   by (simp add: empty_def)
   633 
   634 lemma emptyE [elim!]: "a : {} ==> P"
   635   by simp
   636 
   637 lemma empty_subsetI [iff]: "{} \<subseteq> A"
   638     -- {* One effect is to delete the ASSUMPTION @{prop "{} <= A"} *}
   639   by blast
   640 
   641 lemma equals0I: "(!!y. y \<in> A ==> False) ==> A = {}"
   642   by blast
   643 
   644 lemma equals0D: "A = {} ==> a \<notin> A"
   645     -- {* Use for reasoning about disjointness: @{prop "A Int B = {}"} *}
   646   by blast
   647 
   648 lemma ball_empty [simp]: "Ball {} P = True"
   649   by (simp add: Ball_def)
   650 
   651 lemma bex_empty [simp]: "Bex {} P = False"
   652   by (simp add: Bex_def)
   653 
   654 lemma UNIV_not_empty [iff]: "UNIV ~= {}"
   655   by (blast elim: equalityE)
   656 
   657 
   658 subsubsection {* The Powerset operator -- Pow *}
   659 
   660 lemma Pow_iff [iff]: "(A \<in> Pow B) = (A \<subseteq> B)"
   661   by (simp add: Pow_def)
   662 
   663 lemma PowI: "A \<subseteq> B ==> A \<in> Pow B"
   664   by (simp add: Pow_def)
   665 
   666 lemma PowD: "A \<in> Pow B ==> A \<subseteq> B"
   667   by (simp add: Pow_def)
   668 
   669 lemma Pow_bottom: "{} \<in> Pow B"
   670   by simp
   671 
   672 lemma Pow_top: "A \<in> Pow A"
   673   by (simp add: subset_refl)
   674 
   675 
   676 subsubsection {* Set complement *}
   677 
   678 lemma Compl_iff [simp]: "(c \<in> -A) = (c \<notin> A)"
   679   by (unfold Compl_def) blast
   680 
   681 lemma ComplI [intro!]: "(c \<in> A ==> False) ==> c \<in> -A"
   682   by (unfold Compl_def) blast
   683 
   684 text {*
   685   \medskip This form, with negated conclusion, works well with the
   686   Classical prover.  Negated assumptions behave like formulae on the
   687   right side of the notional turnstile ... *}
   688 
   689 lemma ComplD [dest!]: "c : -A ==> c~:A"
   690   by (unfold Compl_def) blast
   691 
   692 lemmas ComplE = ComplD [elim_format]
   693 
   694 
   695 subsubsection {* Binary union -- Un *}
   696 
   697 lemma Un_iff [simp]: "(c : A Un B) = (c:A | c:B)"
   698   by (unfold Un_def) blast
   699 
   700 lemma UnI1 [elim?]: "c:A ==> c : A Un B"
   701   by simp
   702 
   703 lemma UnI2 [elim?]: "c:B ==> c : A Un B"
   704   by simp
   705 
   706 text {*
   707   \medskip Classical introduction rule: no commitment to @{prop A} vs
   708   @{prop B}.
   709 *}
   710 
   711 lemma UnCI [intro!]: "(c~:B ==> c:A) ==> c : A Un B"
   712   by auto
   713 
   714 lemma UnE [elim!]: "c : A Un B ==> (c:A ==> P) ==> (c:B ==> P) ==> P"
   715   by (unfold Un_def) blast
   716 
   717 
   718 subsubsection {* Binary intersection -- Int *}
   719 
   720 lemma Int_iff [simp]: "(c : A Int B) = (c:A & c:B)"
   721   by (unfold Int_def) blast
   722 
   723 lemma IntI [intro!]: "c:A ==> c:B ==> c : A Int B"
   724   by simp
   725 
   726 lemma IntD1: "c : A Int B ==> c:A"
   727   by simp
   728 
   729 lemma IntD2: "c : A Int B ==> c:B"
   730   by simp
   731 
   732 lemma IntE [elim!]: "c : A Int B ==> (c:A ==> c:B ==> P) ==> P"
   733   by simp
   734 
   735 
   736 subsubsection {* Set difference *}
   737 
   738 lemma Diff_iff [simp]: "(c : A - B) = (c:A & c~:B)"
   739   by (unfold set_diff_def) blast
   740 
   741 lemma DiffI [intro!]: "c : A ==> c ~: B ==> c : A - B"
   742   by simp
   743 
   744 lemma DiffD1: "c : A - B ==> c : A"
   745   by simp
   746 
   747 lemma DiffD2: "c : A - B ==> c : B ==> P"
   748   by simp
   749 
   750 lemma DiffE [elim!]: "c : A - B ==> (c:A ==> c~:B ==> P) ==> P"
   751   by simp
   752 
   753 
   754 subsubsection {* Augmenting a set -- insert *}
   755 
   756 lemma insert_iff [simp]: "(a : insert b A) = (a = b | a:A)"
   757   by (unfold insert_def) blast
   758 
   759 lemma insertI1: "a : insert a B"
   760   by simp
   761 
   762 lemma insertI2: "a : B ==> a : insert b B"
   763   by simp
   764 
   765 lemma insertE [elim!]: "a : insert b A ==> (a = b ==> P) ==> (a:A ==> P) ==> P"
   766   by (unfold insert_def) blast
   767 
   768 lemma insertCI [intro!]: "(a~:B ==> a = b) ==> a: insert b B"
   769   -- {* Classical introduction rule. *}
   770   by auto
   771 
   772 lemma subset_insert_iff: "(A \<subseteq> insert x B) = (if x:A then A - {x} \<subseteq> B else A \<subseteq> B)"
   773   by auto
   774 
   775 
   776 subsubsection {* Singletons, using insert *}
   777 
   778 lemma singletonI [intro!]: "a : {a}"
   779     -- {* Redundant? But unlike @{text insertCI}, it proves the subgoal immediately! *}
   780   by (rule insertI1)
   781 
   782 lemma singletonD [dest!]: "b : {a} ==> b = a"
   783   by blast
   784 
   785 lemmas singletonE = singletonD [elim_format]
   786 
   787 lemma singleton_iff: "(b : {a}) = (b = a)"
   788   by blast
   789 
   790 lemma singleton_inject [dest!]: "{a} = {b} ==> a = b"
   791   by blast
   792 
   793 lemma singleton_insert_inj_eq [iff]: "({b} = insert a A) = (a = b & A \<subseteq> {b})"
   794   by blast
   795 
   796 lemma singleton_insert_inj_eq' [iff]: "(insert a A = {b}) = (a = b & A \<subseteq> {b})"
   797   by blast
   798 
   799 lemma subset_singletonD: "A \<subseteq> {x} ==> A = {} | A = {x}"
   800   by fast
   801 
   802 lemma singleton_conv [simp]: "{x. x = a} = {a}"
   803   by blast
   804 
   805 lemma singleton_conv2 [simp]: "{x. a = x} = {a}"
   806   by blast
   807 
   808 lemma diff_single_insert: "A - {x} \<subseteq> B ==> x \<in> A ==> A \<subseteq> insert x B"
   809   by blast
   810 
   811 lemma doubleton_eq_iff: "({a,b} = {c,d}) = (a=c & b=d | a=d & b=c)"
   812   by (blast elim: equalityE)
   813 
   814 
   815 subsubsection {* Unions of families *}
   816 
   817 text {*
   818   @{term [source] "UN x:A. B x"} is @{term "Union (B`A)"}.
   819 *}
   820 
   821 lemma UN_iff [simp]: "(b: (UN x:A. B x)) = (EX x:A. b: B x)"
   822   by (unfold UNION_def) blast
   823 
   824 lemma UN_I [intro]: "a:A ==> b: B a ==> b: (UN x:A. B x)"
   825   -- {* The order of the premises presupposes that @{term A} is rigid;
   826     @{term b} may be flexible. *}
   827   by auto
   828 
   829 lemma UN_E [elim!]: "b : (UN x:A. B x) ==> (!!x. x:A ==> b: B x ==> R) ==> R"
   830   by (unfold UNION_def) blast
   831 
   832 lemma UN_cong [cong]:
   833     "A = B ==> (!!x. x:B ==> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   834   by (simp add: UNION_def)
   835 
   836 
   837 subsubsection {* Intersections of families *}
   838 
   839 text {* @{term [source] "INT x:A. B x"} is @{term "Inter (B`A)"}. *}
   840 
   841 lemma INT_iff [simp]: "(b: (INT x:A. B x)) = (ALL x:A. b: B x)"
   842   by (unfold INTER_def) blast
   843 
   844 lemma INT_I [intro!]: "(!!x. x:A ==> b: B x) ==> b : (INT x:A. B x)"
   845   by (unfold INTER_def) blast
   846 
   847 lemma INT_D [elim]: "b : (INT x:A. B x) ==> a:A ==> b: B a"
   848   by auto
   849 
   850 lemma INT_E [elim]: "b : (INT x:A. B x) ==> (b: B a ==> R) ==> (a~:A ==> R) ==> R"
   851   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a:A"}. *}
   852   by (unfold INTER_def) blast
   853 
   854 lemma INT_cong [cong]:
   855     "A = B ==> (!!x. x:B ==> C x = D x) ==> (INT x:A. C x) = (INT x:B. D x)"
   856   by (simp add: INTER_def)
   857 
   858 
   859 subsubsection {* Union *}
   860 
   861 lemma Union_iff [simp]: "(A : Union C) = (EX X:C. A:X)"
   862   by (unfold Union_def) blast
   863 
   864 lemma UnionI [intro]: "X:C ==> A:X ==> A : Union C"
   865   -- {* The order of the premises presupposes that @{term C} is rigid;
   866     @{term A} may be flexible. *}
   867   by auto
   868 
   869 lemma UnionE [elim!]: "A : Union C ==> (!!X. A:X ==> X:C ==> R) ==> R"
   870   by (unfold Union_def) blast
   871 
   872 
   873 subsubsection {* Inter *}
   874 
   875 lemma Inter_iff [simp]: "(A : Inter C) = (ALL X:C. A:X)"
   876   by (unfold Inter_def) blast
   877 
   878 lemma InterI [intro!]: "(!!X. X:C ==> A:X) ==> A : Inter C"
   879   by (simp add: Inter_def)
   880 
   881 text {*
   882   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   883   contains @{term A} as an element, but @{prop "A:X"} can hold when
   884   @{prop "X:C"} does not!  This rule is analogous to @{text spec}.
   885 *}
   886 
   887 lemma InterD [elim]: "A : Inter C ==> X:C ==> A:X"
   888   by auto
   889 
   890 lemma InterE [elim]: "A : Inter C ==> (X~:C ==> R) ==> (A:X ==> R) ==> R"
   891   -- {* ``Classical'' elimination rule -- does not require proving
   892     @{prop "X:C"}. *}
   893   by (unfold Inter_def) blast
   894 
   895 text {*
   896   \medskip Image of a set under a function.  Frequently @{term b} does
   897   not have the syntactic form of @{term "f x"}.
   898 *}
   899 
   900 lemma image_eqI [simp, intro]: "b = f x ==> x:A ==> b : f`A"
   901   by (unfold image_def) blast
   902 
   903 lemma imageI: "x : A ==> f x : f ` A"
   904   by (rule image_eqI) (rule refl)
   905 
   906 lemma rev_image_eqI: "x:A ==> b = f x ==> b : f`A"
   907   -- {* This version's more effective when we already have the
   908     required @{term x}. *}
   909   by (unfold image_def) blast
   910 
   911 lemma imageE [elim!]:
   912   "b : (%x. f x)`A ==> (!!x. b = f x ==> x:A ==> P) ==> P"
   913   -- {* The eta-expansion gives variable-name preservation. *}
   914   by (unfold image_def) blast
   915 
   916 lemma image_Un: "f`(A Un B) = f`A Un f`B"
   917   by blast
   918 
   919 lemma image_iff: "(z : f`A) = (EX x:A. z = f x)"
   920   by blast
   921 
   922 lemma image_subset_iff: "(f`A \<subseteq> B) = (\<forall>x\<in>A. f x \<in> B)"
   923   -- {* This rewrite rule would confuse users if made default. *}
   924   by blast
   925 
   926 lemma subset_image_iff: "(B \<subseteq> f`A) = (EX AA. AA \<subseteq> A & B = f`AA)"
   927   apply safe
   928    prefer 2 apply fast
   929   apply (rule_tac x = "{a. a : A & f a : B}" in exI, fast)
   930   done
   931 
   932 lemma image_subsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f`A \<subseteq> B"
   933   -- {* Replaces the three steps @{text subsetI}, @{text imageE},
   934     @{text hypsubst}, but breaks too many existing proofs. *}
   935   by blast
   936 
   937 text {*
   938   \medskip Range of a function -- just a translation for image!
   939 *}
   940 
   941 lemma range_eqI: "b = f x ==> b \<in> range f"
   942   by simp
   943 
   944 lemma rangeI: "f x \<in> range f"
   945   by simp
   946 
   947 lemma rangeE [elim?]: "b \<in> range (\<lambda>x. f x) ==> (!!x. b = f x ==> P) ==> P"
   948   by blast
   949 
   950 
   951 subsubsection {* Set reasoning tools *}
   952 
   953 text {*
   954   Rewrite rules for boolean case-splitting: faster than @{text
   955   "split_if [split]"}.
   956 *}
   957 
   958 lemma split_if_eq1: "((if Q then x else y) = b) = ((Q --> x = b) & (~ Q --> y = b))"
   959   by (rule split_if)
   960 
   961 lemma split_if_eq2: "(a = (if Q then x else y)) = ((Q --> a = x) & (~ Q --> a = y))"
   962   by (rule split_if)
   963 
   964 text {*
   965   Split ifs on either side of the membership relation.  Not for @{text
   966   "[simp]"} -- can cause goals to blow up!
   967 *}
   968 
   969 lemma split_if_mem1: "((if Q then x else y) : b) = ((Q --> x : b) & (~ Q --> y : b))"
   970   by (rule split_if)
   971 
   972 lemma split_if_mem2: "(a : (if Q then x else y)) = ((Q --> a : x) & (~ Q --> a : y))"
   973   by (rule split_if)
   974 
   975 lemmas split_ifs = if_bool_eq_conj split_if_eq1 split_if_eq2 split_if_mem1 split_if_mem2
   976 
   977 lemmas mem_simps =
   978   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
   979   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
   980   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
   981 
   982 (*Would like to add these, but the existing code only searches for the
   983   outer-level constant, which in this case is just "op :"; we instead need
   984   to use term-nets to associate patterns with rules.  Also, if a rule fails to
   985   apply, then the formula should be kept.
   986   [("HOL.uminus", Compl_iff RS iffD1), ("HOL.minus", [Diff_iff RS iffD1]),
   987    ("op Int", [IntD1,IntD2]),
   988    ("Collect", [CollectD]), ("Inter", [InterD]), ("INTER", [INT_D])]
   989  *)
   990 
   991 ML_setup {*
   992   val mksimps_pairs = [("Ball", @{thms bspec})] @ mksimps_pairs;
   993   change_simpset (fn ss => ss setmksimps (mksimps mksimps_pairs));
   994 *}
   995 
   996 
   997 subsubsection {* The ``proper subset'' relation *}
   998 
   999 lemma psubsetI [intro!]: "A \<subseteq> B ==> A \<noteq> B ==> A \<subset> B"
  1000   by (unfold psubset_def) blast
  1001 
  1002 lemma psubsetE [elim!]: 
  1003     "[|A \<subset> B;  [|A \<subseteq> B; ~ (B\<subseteq>A)|] ==> R|] ==> R"
  1004   by (unfold psubset_def) blast
  1005 
  1006 lemma psubset_insert_iff:
  1007   "(A \<subset> insert x B) = (if x \<in> B then A \<subset> B else if x \<in> A then A - {x} \<subset> B else A \<subseteq> B)"
  1008   by (auto simp add: psubset_def subset_insert_iff)
  1009 
  1010 lemma psubset_eq: "(A \<subset> B) = (A \<subseteq> B & A \<noteq> B)"
  1011   by (simp only: psubset_def)
  1012 
  1013 lemma psubset_imp_subset: "A \<subset> B ==> A \<subseteq> B"
  1014   by (simp add: psubset_eq)
  1015 
  1016 lemma psubset_trans: "[| A \<subset> B; B \<subset> C |] ==> A \<subset> C"
  1017 apply (unfold psubset_def)
  1018 apply (auto dest: subset_antisym)
  1019 done
  1020 
  1021 lemma psubsetD: "[| A \<subset> B; c \<in> A |] ==> c \<in> B"
  1022 apply (unfold psubset_def)
  1023 apply (auto dest: subsetD)
  1024 done
  1025 
  1026 lemma psubset_subset_trans: "A \<subset> B ==> B \<subseteq> C ==> A \<subset> C"
  1027   by (auto simp add: psubset_eq)
  1028 
  1029 lemma subset_psubset_trans: "A \<subseteq> B ==> B \<subset> C ==> A \<subset> C"
  1030   by (auto simp add: psubset_eq)
  1031 
  1032 lemma psubset_imp_ex_mem: "A \<subset> B ==> \<exists>b. b \<in> (B - A)"
  1033   by (unfold psubset_def) blast
  1034 
  1035 lemma atomize_ball:
  1036     "(!!x. x \<in> A ==> P x) == Trueprop (\<forall>x\<in>A. P x)"
  1037   by (simp only: Ball_def atomize_all atomize_imp)
  1038 
  1039 lemmas [symmetric, rulify] = atomize_ball
  1040   and [symmetric, defn] = atomize_ball
  1041 
  1042 
  1043 subsection {* Order on sets *}
  1044 
  1045 instance set :: (type) order
  1046   by (intro_classes,
  1047       (assumption | rule subset_refl subset_trans subset_antisym psubset_eq)+)
  1048 
  1049 
  1050 subsection {* Further set-theory lemmas *}
  1051 
  1052 subsubsection {* Derived rules involving subsets. *}
  1053 
  1054 text {* @{text insert}. *}
  1055 
  1056 lemma subset_insertI: "B \<subseteq> insert a B"
  1057   apply (rule subsetI)
  1058   apply (erule insertI2)
  1059   done
  1060 
  1061 lemma subset_insertI2: "A \<subseteq> B \<Longrightarrow> A \<subseteq> insert b B"
  1062 by blast
  1063 
  1064 lemma subset_insert: "x \<notin> A ==> (A \<subseteq> insert x B) = (A \<subseteq> B)"
  1065   by blast
  1066 
  1067 
  1068 text {* \medskip Big Union -- least upper bound of a set. *}
  1069 
  1070 lemma Union_upper: "B \<in> A ==> B \<subseteq> Union A"
  1071   by (iprover intro: subsetI UnionI)
  1072 
  1073 lemma Union_least: "(!!X. X \<in> A ==> X \<subseteq> C) ==> Union A \<subseteq> C"
  1074   by (iprover intro: subsetI elim: UnionE dest: subsetD)
  1075 
  1076 
  1077 text {* \medskip General union. *}
  1078 
  1079 lemma UN_upper: "a \<in> A ==> B a \<subseteq> (\<Union>x\<in>A. B x)"
  1080   by blast
  1081 
  1082 lemma UN_least: "(!!x. x \<in> A ==> B x \<subseteq> C) ==> (\<Union>x\<in>A. B x) \<subseteq> C"
  1083   by (iprover intro: subsetI elim: UN_E dest: subsetD)
  1084 
  1085 
  1086 text {* \medskip Big Intersection -- greatest lower bound of a set. *}
  1087 
  1088 lemma Inter_lower: "B \<in> A ==> Inter A \<subseteq> B"
  1089   by blast
  1090 
  1091 lemma Inter_subset:
  1092   "[| !!X. X \<in> A ==> X \<subseteq> B; A ~= {} |] ==> \<Inter>A \<subseteq> B"
  1093   by blast
  1094 
  1095 lemma Inter_greatest: "(!!X. X \<in> A ==> C \<subseteq> X) ==> C \<subseteq> Inter A"
  1096   by (iprover intro: InterI subsetI dest: subsetD)
  1097 
  1098 lemma INT_lower: "a \<in> A ==> (\<Inter>x\<in>A. B x) \<subseteq> B a"
  1099   by blast
  1100 
  1101 lemma INT_greatest: "(!!x. x \<in> A ==> C \<subseteq> B x) ==> C \<subseteq> (\<Inter>x\<in>A. B x)"
  1102   by (iprover intro: INT_I subsetI dest: subsetD)
  1103 
  1104 
  1105 text {* \medskip Finite Union -- the least upper bound of two sets. *}
  1106 
  1107 lemma Un_upper1: "A \<subseteq> A \<union> B"
  1108   by blast
  1109 
  1110 lemma Un_upper2: "B \<subseteq> A \<union> B"
  1111   by blast
  1112 
  1113 lemma Un_least: "A \<subseteq> C ==> B \<subseteq> C ==> A \<union> B \<subseteq> C"
  1114   by blast
  1115 
  1116 
  1117 text {* \medskip Finite Intersection -- the greatest lower bound of two sets. *}
  1118 
  1119 lemma Int_lower1: "A \<inter> B \<subseteq> A"
  1120   by blast
  1121 
  1122 lemma Int_lower2: "A \<inter> B \<subseteq> B"
  1123   by blast
  1124 
  1125 lemma Int_greatest: "C \<subseteq> A ==> C \<subseteq> B ==> C \<subseteq> A \<inter> B"
  1126   by blast
  1127 
  1128 
  1129 text {* \medskip Set difference. *}
  1130 
  1131 lemma Diff_subset: "A - B \<subseteq> A"
  1132   by blast
  1133 
  1134 lemma Diff_subset_conv: "(A - B \<subseteq> C) = (A \<subseteq> B \<union> C)"
  1135 by blast
  1136 
  1137 
  1138 text {* \medskip Monotonicity. *}
  1139 
  1140 lemma mono_Un: "mono f ==> f A \<union> f B \<subseteq> f (A \<union> B)"
  1141   by (auto simp add: mono_def)
  1142 
  1143 lemma mono_Int: "mono f ==> f (A \<inter> B) \<subseteq> f A \<inter> f B"
  1144   by (auto simp add: mono_def)
  1145 
  1146 subsubsection {* Equalities involving union, intersection, inclusion, etc. *}
  1147 
  1148 text {* @{text "{}"}. *}
  1149 
  1150 lemma Collect_const [simp]: "{s. P} = (if P then UNIV else {})"
  1151   -- {* supersedes @{text "Collect_False_empty"} *}
  1152   by auto
  1153 
  1154 lemma subset_empty [simp]: "(A \<subseteq> {}) = (A = {})"
  1155   by blast
  1156 
  1157 lemma not_psubset_empty [iff]: "\<not> (A < {})"
  1158   by (unfold psubset_def) blast
  1159 
  1160 lemma Collect_empty_eq [simp]: "(Collect P = {}) = (\<forall>x. \<not> P x)"
  1161 by blast
  1162 
  1163 lemma empty_Collect_eq [simp]: "({} = Collect P) = (\<forall>x. \<not> P x)"
  1164 by blast
  1165 
  1166 lemma Collect_neg_eq: "{x. \<not> P x} = - {x. P x}"
  1167   by blast
  1168 
  1169 lemma Collect_disj_eq: "{x. P x | Q x} = {x. P x} \<union> {x. Q x}"
  1170   by blast
  1171 
  1172 lemma Collect_imp_eq: "{x. P x --> Q x} = -{x. P x} \<union> {x. Q x}"
  1173   by blast
  1174 
  1175 lemma Collect_conj_eq: "{x. P x & Q x} = {x. P x} \<inter> {x. Q x}"
  1176   by blast
  1177 
  1178 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
  1179   by blast
  1180 
  1181 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
  1182   by blast
  1183 
  1184 lemma Collect_ex_eq: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
  1185   by blast
  1186 
  1187 lemma Collect_bex_eq: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
  1188   by blast
  1189 
  1190 
  1191 text {* \medskip @{text insert}. *}
  1192 
  1193 lemma insert_is_Un: "insert a A = {a} Un A"
  1194   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a {}"} *}
  1195   by blast
  1196 
  1197 lemma insert_not_empty [simp]: "insert a A \<noteq> {}"
  1198   by blast
  1199 
  1200 lemmas empty_not_insert = insert_not_empty [symmetric, standard]
  1201 declare empty_not_insert [simp]
  1202 
  1203 lemma insert_absorb: "a \<in> A ==> insert a A = A"
  1204   -- {* @{text "[simp]"} causes recursive calls when there are nested inserts *}
  1205   -- {* with \emph{quadratic} running time *}
  1206   by blast
  1207 
  1208 lemma insert_absorb2 [simp]: "insert x (insert x A) = insert x A"
  1209   by blast
  1210 
  1211 lemma insert_commute: "insert x (insert y A) = insert y (insert x A)"
  1212   by blast
  1213 
  1214 lemma insert_subset [simp]: "(insert x A \<subseteq> B) = (x \<in> B & A \<subseteq> B)"
  1215   by blast
  1216 
  1217 lemma mk_disjoint_insert: "a \<in> A ==> \<exists>B. A = insert a B & a \<notin> B"
  1218   -- {* use new @{text B} rather than @{text "A - {a}"} to avoid infinite unfolding *}
  1219   apply (rule_tac x = "A - {a}" in exI, blast)
  1220   done
  1221 
  1222 lemma insert_Collect: "insert a (Collect P) = {u. u \<noteq> a --> P u}"
  1223   by auto
  1224 
  1225 lemma UN_insert_distrib: "u \<in> A ==> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
  1226   by blast
  1227 
  1228 lemma insert_inter_insert[simp]: "insert a A \<inter> insert a B = insert a (A \<inter> B)"
  1229   by blast
  1230 
  1231 lemma insert_disjoint[simp]:
  1232  "(insert a A \<inter> B = {}) = (a \<notin> B \<and> A \<inter> B = {})"
  1233  "({} = insert a A \<inter> B) = (a \<notin> B \<and> {} = A \<inter> B)"
  1234   by auto
  1235 
  1236 lemma disjoint_insert[simp]:
  1237  "(B \<inter> insert a A = {}) = (a \<notin> B \<and> B \<inter> A = {})"
  1238  "({} = A \<inter> insert b B) = (b \<notin> A \<and> {} = A \<inter> B)"
  1239   by auto
  1240 
  1241 text {* \medskip @{text image}. *}
  1242 
  1243 lemma image_empty [simp]: "f`{} = {}"
  1244   by blast
  1245 
  1246 lemma image_insert [simp]: "f ` insert a B = insert (f a) (f`B)"
  1247   by blast
  1248 
  1249 lemma image_constant: "x \<in> A ==> (\<lambda>x. c) ` A = {c}"
  1250   by auto
  1251 
  1252 lemma image_constant_conv: "(%x. c) ` A = (if A = {} then {} else {c})"
  1253 by auto
  1254 
  1255 lemma image_image: "f ` (g ` A) = (\<lambda>x. f (g x)) ` A"
  1256   by blast
  1257 
  1258 lemma insert_image [simp]: "x \<in> A ==> insert (f x) (f`A) = f`A"
  1259   by blast
  1260 
  1261 lemma image_is_empty [iff]: "(f`A = {}) = (A = {})"
  1262   by blast
  1263 
  1264 
  1265 lemma image_Collect: "f ` {x. P x} = {f x | x. P x}"
  1266   -- {* NOT suitable as a default simprule: the RHS isn't simpler than the LHS,
  1267       with its implicit quantifier and conjunction.  Also image enjoys better
  1268       equational properties than does the RHS. *}
  1269   by blast
  1270 
  1271 lemma if_image_distrib [simp]:
  1272   "(\<lambda>x. if P x then f x else g x) ` S
  1273     = (f ` (S \<inter> {x. P x})) \<union> (g ` (S \<inter> {x. \<not> P x}))"
  1274   by (auto simp add: image_def)
  1275 
  1276 lemma image_cong: "M = N ==> (!!x. x \<in> N ==> f x = g x) ==> f`M = g`N"
  1277   by (simp add: image_def)
  1278 
  1279 
  1280 text {* \medskip @{text range}. *}
  1281 
  1282 lemma full_SetCompr_eq: "{u. \<exists>x. u = f x} = range f"
  1283   by auto
  1284 
  1285 lemma range_composition [simp]: "range (\<lambda>x. f (g x)) = f`range g"
  1286 by (subst image_image, simp)
  1287 
  1288 
  1289 text {* \medskip @{text Int} *}
  1290 
  1291 lemma Int_absorb [simp]: "A \<inter> A = A"
  1292   by blast
  1293 
  1294 lemma Int_left_absorb: "A \<inter> (A \<inter> B) = A \<inter> B"
  1295   by blast
  1296 
  1297 lemma Int_commute: "A \<inter> B = B \<inter> A"
  1298   by blast
  1299 
  1300 lemma Int_left_commute: "A \<inter> (B \<inter> C) = B \<inter> (A \<inter> C)"
  1301   by blast
  1302 
  1303 lemma Int_assoc: "(A \<inter> B) \<inter> C = A \<inter> (B \<inter> C)"
  1304   by blast
  1305 
  1306 lemmas Int_ac = Int_assoc Int_left_absorb Int_commute Int_left_commute
  1307   -- {* Intersection is an AC-operator *}
  1308 
  1309 lemma Int_absorb1: "B \<subseteq> A ==> A \<inter> B = B"
  1310   by blast
  1311 
  1312 lemma Int_absorb2: "A \<subseteq> B ==> A \<inter> B = A"
  1313   by blast
  1314 
  1315 lemma Int_empty_left [simp]: "{} \<inter> B = {}"
  1316   by blast
  1317 
  1318 lemma Int_empty_right [simp]: "A \<inter> {} = {}"
  1319   by blast
  1320 
  1321 lemma disjoint_eq_subset_Compl: "(A \<inter> B = {}) = (A \<subseteq> -B)"
  1322   by blast
  1323 
  1324 lemma disjoint_iff_not_equal: "(A \<inter> B = {}) = (\<forall>x\<in>A. \<forall>y\<in>B. x \<noteq> y)"
  1325   by blast
  1326 
  1327 lemma Int_UNIV_left [simp]: "UNIV \<inter> B = B"
  1328   by blast
  1329 
  1330 lemma Int_UNIV_right [simp]: "A \<inter> UNIV = A"
  1331   by blast
  1332 
  1333 lemma Int_eq_Inter: "A \<inter> B = \<Inter>{A, B}"
  1334   by blast
  1335 
  1336 lemma Int_Un_distrib: "A \<inter> (B \<union> C) = (A \<inter> B) \<union> (A \<inter> C)"
  1337   by blast
  1338 
  1339 lemma Int_Un_distrib2: "(B \<union> C) \<inter> A = (B \<inter> A) \<union> (C \<inter> A)"
  1340   by blast
  1341 
  1342 lemma Int_UNIV [simp]: "(A \<inter> B = UNIV) = (A = UNIV & B = UNIV)"
  1343   by blast
  1344 
  1345 lemma Int_subset_iff [simp]: "(C \<subseteq> A \<inter> B) = (C \<subseteq> A & C \<subseteq> B)"
  1346   by blast
  1347 
  1348 lemma Int_Collect: "(x \<in> A \<inter> {x. P x}) = (x \<in> A & P x)"
  1349   by blast
  1350 
  1351 
  1352 text {* \medskip @{text Un}. *}
  1353 
  1354 lemma Un_absorb [simp]: "A \<union> A = A"
  1355   by blast
  1356 
  1357 lemma Un_left_absorb: "A \<union> (A \<union> B) = A \<union> B"
  1358   by blast
  1359 
  1360 lemma Un_commute: "A \<union> B = B \<union> A"
  1361   by blast
  1362 
  1363 lemma Un_left_commute: "A \<union> (B \<union> C) = B \<union> (A \<union> C)"
  1364   by blast
  1365 
  1366 lemma Un_assoc: "(A \<union> B) \<union> C = A \<union> (B \<union> C)"
  1367   by blast
  1368 
  1369 lemmas Un_ac = Un_assoc Un_left_absorb Un_commute Un_left_commute
  1370   -- {* Union is an AC-operator *}
  1371 
  1372 lemma Un_absorb1: "A \<subseteq> B ==> A \<union> B = B"
  1373   by blast
  1374 
  1375 lemma Un_absorb2: "B \<subseteq> A ==> A \<union> B = A"
  1376   by blast
  1377 
  1378 lemma Un_empty_left [simp]: "{} \<union> B = B"
  1379   by blast
  1380 
  1381 lemma Un_empty_right [simp]: "A \<union> {} = A"
  1382   by blast
  1383 
  1384 lemma Un_UNIV_left [simp]: "UNIV \<union> B = UNIV"
  1385   by blast
  1386 
  1387 lemma Un_UNIV_right [simp]: "A \<union> UNIV = UNIV"
  1388   by blast
  1389 
  1390 lemma Un_eq_Union: "A \<union> B = \<Union>{A, B}"
  1391   by blast
  1392 
  1393 lemma Un_insert_left [simp]: "(insert a B) \<union> C = insert a (B \<union> C)"
  1394   by blast
  1395 
  1396 lemma Un_insert_right [simp]: "A \<union> (insert a B) = insert a (A \<union> B)"
  1397   by blast
  1398 
  1399 lemma Int_insert_left:
  1400     "(insert a B) Int C = (if a \<in> C then insert a (B \<inter> C) else B \<inter> C)"
  1401   by auto
  1402 
  1403 lemma Int_insert_right:
  1404     "A \<inter> (insert a B) = (if a \<in> A then insert a (A \<inter> B) else A \<inter> B)"
  1405   by auto
  1406 
  1407 lemma Un_Int_distrib: "A \<union> (B \<inter> C) = (A \<union> B) \<inter> (A \<union> C)"
  1408   by blast
  1409 
  1410 lemma Un_Int_distrib2: "(B \<inter> C) \<union> A = (B \<union> A) \<inter> (C \<union> A)"
  1411   by blast
  1412 
  1413 lemma Un_Int_crazy:
  1414     "(A \<inter> B) \<union> (B \<inter> C) \<union> (C \<inter> A) = (A \<union> B) \<inter> (B \<union> C) \<inter> (C \<union> A)"
  1415   by blast
  1416 
  1417 lemma subset_Un_eq: "(A \<subseteq> B) = (A \<union> B = B)"
  1418   by blast
  1419 
  1420 lemma Un_empty [iff]: "(A \<union> B = {}) = (A = {} & B = {})"
  1421   by blast
  1422 
  1423 lemma Un_subset_iff [simp]: "(A \<union> B \<subseteq> C) = (A \<subseteq> C & B \<subseteq> C)"
  1424   by blast
  1425 
  1426 lemma Un_Diff_Int: "(A - B) \<union> (A \<inter> B) = A"
  1427   by blast
  1428 
  1429 lemma Diff_Int2: "A \<inter> C - B \<inter> C = A \<inter> C - B"
  1430   by blast
  1431 
  1432 
  1433 text {* \medskip Set complement *}
  1434 
  1435 lemma Compl_disjoint [simp]: "A \<inter> -A = {}"
  1436   by blast
  1437 
  1438 lemma Compl_disjoint2 [simp]: "-A \<inter> A = {}"
  1439   by blast
  1440 
  1441 lemma Compl_partition: "A \<union> -A = UNIV"
  1442   by blast
  1443 
  1444 lemma Compl_partition2: "-A \<union> A = UNIV"
  1445   by blast
  1446 
  1447 lemma double_complement [simp]: "- (-A) = (A::'a set)"
  1448   by blast
  1449 
  1450 lemma Compl_Un [simp]: "-(A \<union> B) = (-A) \<inter> (-B)"
  1451   by blast
  1452 
  1453 lemma Compl_Int [simp]: "-(A \<inter> B) = (-A) \<union> (-B)"
  1454   by blast
  1455 
  1456 lemma Compl_UN [simp]: "-(\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
  1457   by blast
  1458 
  1459 lemma Compl_INT [simp]: "-(\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
  1460   by blast
  1461 
  1462 lemma subset_Compl_self_eq: "(A \<subseteq> -A) = (A = {})"
  1463   by blast
  1464 
  1465 lemma Un_Int_assoc_eq: "((A \<inter> B) \<union> C = A \<inter> (B \<union> C)) = (C \<subseteq> A)"
  1466   -- {* Halmos, Naive Set Theory, page 16. *}
  1467   by blast
  1468 
  1469 lemma Compl_UNIV_eq [simp]: "-UNIV = {}"
  1470   by blast
  1471 
  1472 lemma Compl_empty_eq [simp]: "-{} = UNIV"
  1473   by blast
  1474 
  1475 lemma Compl_subset_Compl_iff [iff]: "(-A \<subseteq> -B) = (B \<subseteq> A)"
  1476   by blast
  1477 
  1478 lemma Compl_eq_Compl_iff [iff]: "(-A = -B) = (A = (B::'a set))"
  1479   by blast
  1480 
  1481 
  1482 text {* \medskip @{text Union}. *}
  1483 
  1484 lemma Union_empty [simp]: "Union({}) = {}"
  1485   by blast
  1486 
  1487 lemma Union_UNIV [simp]: "Union UNIV = UNIV"
  1488   by blast
  1489 
  1490 lemma Union_insert [simp]: "Union (insert a B) = a \<union> \<Union>B"
  1491   by blast
  1492 
  1493 lemma Union_Un_distrib [simp]: "\<Union>(A Un B) = \<Union>A \<union> \<Union>B"
  1494   by blast
  1495 
  1496 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
  1497   by blast
  1498 
  1499 lemma Union_empty_conv [simp]: "(\<Union>A = {}) = (\<forall>x\<in>A. x = {})"
  1500   by blast
  1501 
  1502 lemma empty_Union_conv [simp]: "({} = \<Union>A) = (\<forall>x\<in>A. x = {})"
  1503   by blast
  1504 
  1505 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) = (\<forall>B\<in>C. B \<inter> A = {})"
  1506   by blast
  1507 
  1508 
  1509 text {* \medskip @{text Inter}. *}
  1510 
  1511 lemma Inter_empty [simp]: "\<Inter>{} = UNIV"
  1512   by blast
  1513 
  1514 lemma Inter_UNIV [simp]: "\<Inter>UNIV = {}"
  1515   by blast
  1516 
  1517 lemma Inter_insert [simp]: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
  1518   by blast
  1519 
  1520 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
  1521   by blast
  1522 
  1523 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
  1524   by blast
  1525 
  1526 lemma Inter_UNIV_conv [simp]:
  1527   "(\<Inter>A = UNIV) = (\<forall>x\<in>A. x = UNIV)"
  1528   "(UNIV = \<Inter>A) = (\<forall>x\<in>A. x = UNIV)"
  1529   by blast+
  1530 
  1531 
  1532 text {*
  1533   \medskip @{text UN} and @{text INT}.
  1534 
  1535   Basic identities: *}
  1536 
  1537 lemma UN_empty [simp]: "(\<Union>x\<in>{}. B x) = {}"
  1538   by blast
  1539 
  1540 lemma UN_empty2 [simp]: "(\<Union>x\<in>A. {}) = {}"
  1541   by blast
  1542 
  1543 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
  1544   by blast
  1545 
  1546 lemma UN_absorb: "k \<in> I ==> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
  1547   by auto
  1548 
  1549 lemma INT_empty [simp]: "(\<Inter>x\<in>{}. B x) = UNIV"
  1550   by blast
  1551 
  1552 lemma INT_absorb: "k \<in> I ==> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
  1553   by blast
  1554 
  1555 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
  1556   by blast
  1557 
  1558 lemma UN_Un: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
  1559   by blast
  1560 
  1561 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
  1562   by blast
  1563 
  1564 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
  1565   by blast
  1566 
  1567 lemma INT_subset_iff: "(B \<subseteq> (\<Inter>i\<in>I. A i)) = (\<forall>i\<in>I. B \<subseteq> A i)"
  1568   by blast
  1569 
  1570 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
  1571   by blast
  1572 
  1573 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
  1574   by blast
  1575 
  1576 lemma INT_insert_distrib:
  1577     "u \<in> A ==> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
  1578   by blast
  1579 
  1580 lemma Union_image_eq [simp]: "\<Union>(B`A) = (\<Union>x\<in>A. B x)"
  1581   by blast
  1582 
  1583 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
  1584   by blast
  1585 
  1586 lemma Inter_image_eq [simp]: "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
  1587   by blast
  1588 
  1589 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
  1590   by auto
  1591 
  1592 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
  1593   by auto
  1594 
  1595 lemma UN_eq: "(\<Union>x\<in>A. B x) = \<Union>({Y. \<exists>x\<in>A. Y = B x})"
  1596   by blast
  1597 
  1598 lemma INT_eq: "(\<Inter>x\<in>A. B x) = \<Inter>({Y. \<exists>x\<in>A. Y = B x})"
  1599   -- {* Look: it has an \emph{existential} quantifier *}
  1600   by blast
  1601 
  1602 lemma UNION_empty_conv[simp]:
  1603   "({} = (UN x:A. B x)) = (\<forall>x\<in>A. B x = {})"
  1604   "((UN x:A. B x) = {}) = (\<forall>x\<in>A. B x = {})"
  1605 by blast+
  1606 
  1607 lemma INTER_UNIV_conv[simp]:
  1608  "(UNIV = (INT x:A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
  1609  "((INT x:A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
  1610 by blast+
  1611 
  1612 
  1613 text {* \medskip Distributive laws: *}
  1614 
  1615 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
  1616   by blast
  1617 
  1618 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
  1619   by blast
  1620 
  1621 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A`C) \<union> \<Union>(B`C)"
  1622   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
  1623   -- {* Union of a family of unions *}
  1624   by blast
  1625 
  1626 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
  1627   -- {* Equivalent version *}
  1628   by blast
  1629 
  1630 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
  1631   by blast
  1632 
  1633 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A`C) \<inter> \<Inter>(B`C)"
  1634   by blast
  1635 
  1636 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
  1637   -- {* Equivalent version *}
  1638   by blast
  1639 
  1640 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
  1641   -- {* Halmos, Naive Set Theory, page 35. *}
  1642   by blast
  1643 
  1644 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
  1645   by blast
  1646 
  1647 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
  1648   by blast
  1649 
  1650 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
  1651   by blast
  1652 
  1653 
  1654 text {* \medskip Bounded quantifiers.
  1655 
  1656   The following are not added to the default simpset because
  1657   (a) they duplicate the body and (b) there are no similar rules for @{text Int}. *}
  1658 
  1659 lemma ball_Un: "(\<forall>x \<in> A \<union> B. P x) = ((\<forall>x\<in>A. P x) & (\<forall>x\<in>B. P x))"
  1660   by blast
  1661 
  1662 lemma bex_Un: "(\<exists>x \<in> A \<union> B. P x) = ((\<exists>x\<in>A. P x) | (\<exists>x\<in>B. P x))"
  1663   by blast
  1664 
  1665 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) = (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
  1666   by blast
  1667 
  1668 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) = (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
  1669   by blast
  1670 
  1671 
  1672 text {* \medskip Set difference. *}
  1673 
  1674 lemma Diff_eq: "A - B = A \<inter> (-B)"
  1675   by blast
  1676 
  1677 lemma Diff_eq_empty_iff [simp]: "(A - B = {}) = (A \<subseteq> B)"
  1678   by blast
  1679 
  1680 lemma Diff_cancel [simp]: "A - A = {}"
  1681   by blast
  1682 
  1683 lemma Diff_idemp [simp]: "(A - B) - B = A - (B::'a set)"
  1684 by blast
  1685 
  1686 lemma Diff_triv: "A \<inter> B = {} ==> A - B = A"
  1687   by (blast elim: equalityE)
  1688 
  1689 lemma empty_Diff [simp]: "{} - A = {}"
  1690   by blast
  1691 
  1692 lemma Diff_empty [simp]: "A - {} = A"
  1693   by blast
  1694 
  1695 lemma Diff_UNIV [simp]: "A - UNIV = {}"
  1696   by blast
  1697 
  1698 lemma Diff_insert0 [simp]: "x \<notin> A ==> A - insert x B = A - B"
  1699   by blast
  1700 
  1701 lemma Diff_insert: "A - insert a B = A - B - {a}"
  1702   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1703   by blast
  1704 
  1705 lemma Diff_insert2: "A - insert a B = A - {a} - B"
  1706   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1707   by blast
  1708 
  1709 lemma insert_Diff_if: "insert x A - B = (if x \<in> B then A - B else insert x (A - B))"
  1710   by auto
  1711 
  1712 lemma insert_Diff1 [simp]: "x \<in> B ==> insert x A - B = A - B"
  1713   by blast
  1714 
  1715 lemma insert_Diff_single[simp]: "insert a (A - {a}) = insert a A"
  1716 by blast
  1717 
  1718 lemma insert_Diff: "a \<in> A ==> insert a (A - {a}) = A"
  1719   by blast
  1720 
  1721 lemma Diff_insert_absorb: "x \<notin> A ==> (insert x A) - {x} = A"
  1722   by auto
  1723 
  1724 lemma Diff_disjoint [simp]: "A \<inter> (B - A) = {}"
  1725   by blast
  1726 
  1727 lemma Diff_partition: "A \<subseteq> B ==> A \<union> (B - A) = B"
  1728   by blast
  1729 
  1730 lemma double_diff: "A \<subseteq> B ==> B \<subseteq> C ==> B - (C - A) = A"
  1731   by blast
  1732 
  1733 lemma Un_Diff_cancel [simp]: "A \<union> (B - A) = A \<union> B"
  1734   by blast
  1735 
  1736 lemma Un_Diff_cancel2 [simp]: "(B - A) \<union> A = B \<union> A"
  1737   by blast
  1738 
  1739 lemma Diff_Un: "A - (B \<union> C) = (A - B) \<inter> (A - C)"
  1740   by blast
  1741 
  1742 lemma Diff_Int: "A - (B \<inter> C) = (A - B) \<union> (A - C)"
  1743   by blast
  1744 
  1745 lemma Un_Diff: "(A \<union> B) - C = (A - C) \<union> (B - C)"
  1746   by blast
  1747 
  1748 lemma Int_Diff: "(A \<inter> B) - C = A \<inter> (B - C)"
  1749   by blast
  1750 
  1751 lemma Diff_Int_distrib: "C \<inter> (A - B) = (C \<inter> A) - (C \<inter> B)"
  1752   by blast
  1753 
  1754 lemma Diff_Int_distrib2: "(A - B) \<inter> C = (A \<inter> C) - (B \<inter> C)"
  1755   by blast
  1756 
  1757 lemma Diff_Compl [simp]: "A - (- B) = A \<inter> B"
  1758   by auto
  1759 
  1760 lemma Compl_Diff_eq [simp]: "- (A - B) = -A \<union> B"
  1761   by blast
  1762 
  1763 
  1764 text {* \medskip Quantification over type @{typ bool}. *}
  1765 
  1766 lemma bool_induct: "P True \<Longrightarrow> P False \<Longrightarrow> P x"
  1767   by (cases x) auto
  1768 
  1769 lemma all_bool_eq: "(\<forall>b. P b) \<longleftrightarrow> P True \<and> P False"
  1770   by (auto intro: bool_induct)
  1771 
  1772 lemma bool_contrapos: "P x \<Longrightarrow> \<not> P False \<Longrightarrow> P True"
  1773   by (cases x) auto
  1774 
  1775 lemma ex_bool_eq: "(\<exists>b. P b) \<longleftrightarrow> P True \<or> P False"
  1776   by (auto intro: bool_contrapos)
  1777 
  1778 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
  1779   by (auto simp add: split_if_mem2)
  1780 
  1781 lemma UN_bool_eq: "(\<Union>b::bool. A b) = (A True \<union> A False)"
  1782   by (auto intro: bool_contrapos)
  1783 
  1784 lemma INT_bool_eq: "(\<Inter>b::bool. A b) = (A True \<inter> A False)"
  1785   by (auto intro: bool_induct)
  1786 
  1787 text {* \medskip @{text Pow} *}
  1788 
  1789 lemma Pow_empty [simp]: "Pow {} = {{}}"
  1790   by (auto simp add: Pow_def)
  1791 
  1792 lemma Pow_insert: "Pow (insert a A) = Pow A \<union> (insert a ` Pow A)"
  1793   by (blast intro: image_eqI [where ?x = "u - {a}", standard])
  1794 
  1795 lemma Pow_Compl: "Pow (- A) = {-B | B. A \<in> Pow B}"
  1796   by (blast intro: exI [where ?x = "- u", standard])
  1797 
  1798 lemma Pow_UNIV [simp]: "Pow UNIV = UNIV"
  1799   by blast
  1800 
  1801 lemma Un_Pow_subset: "Pow A \<union> Pow B \<subseteq> Pow (A \<union> B)"
  1802   by blast
  1803 
  1804 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
  1805   by blast
  1806 
  1807 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
  1808   by blast
  1809 
  1810 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
  1811   by blast
  1812 
  1813 lemma Pow_Int_eq [simp]: "Pow (A \<inter> B) = Pow A \<inter> Pow B"
  1814   by blast
  1815 
  1816 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
  1817   by blast
  1818 
  1819 
  1820 text {* \medskip Miscellany. *}
  1821 
  1822 lemma set_eq_subset: "(A = B) = (A \<subseteq> B & B \<subseteq> A)"
  1823   by blast
  1824 
  1825 lemma subset_iff: "(A \<subseteq> B) = (\<forall>t. t \<in> A --> t \<in> B)"
  1826   by blast
  1827 
  1828 lemma subset_iff_psubset_eq: "(A \<subseteq> B) = ((A \<subset> B) | (A = B))"
  1829   by (unfold psubset_def) blast
  1830 
  1831 lemma all_not_in_conv [simp]: "(\<forall>x. x \<notin> A) = (A = {})"
  1832   by blast
  1833 
  1834 lemma ex_in_conv: "(\<exists>x. x \<in> A) = (A \<noteq> {})"
  1835   by blast
  1836 
  1837 lemma distinct_lemma: "f x \<noteq> f y ==> x \<noteq> y"
  1838   by iprover
  1839 
  1840 
  1841 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
  1842            and Intersections. *}
  1843 
  1844 lemma UN_simps [simp]:
  1845   "!!a B C. (UN x:C. insert a (B x)) = (if C={} then {} else insert a (UN x:C. B x))"
  1846   "!!A B C. (UN x:C. A x Un B)   = ((if C={} then {} else (UN x:C. A x) Un B))"
  1847   "!!A B C. (UN x:C. A Un B x)   = ((if C={} then {} else A Un (UN x:C. B x)))"
  1848   "!!A B C. (UN x:C. A x Int B)  = ((UN x:C. A x) Int B)"
  1849   "!!A B C. (UN x:C. A Int B x)  = (A Int (UN x:C. B x))"
  1850   "!!A B C. (UN x:C. A x - B)    = ((UN x:C. A x) - B)"
  1851   "!!A B C. (UN x:C. A - B x)    = (A - (INT x:C. B x))"
  1852   "!!A B. (UN x: Union A. B x) = (UN y:A. UN x:y. B x)"
  1853   "!!A B C. (UN z: UNION A B. C z) = (UN  x:A. UN z: B(x). C z)"
  1854   "!!A B f. (UN x:f`A. B x)     = (UN a:A. B (f a))"
  1855   by auto
  1856 
  1857 lemma INT_simps [simp]:
  1858   "!!A B C. (INT x:C. A x Int B) = (if C={} then UNIV else (INT x:C. A x) Int B)"
  1859   "!!A B C. (INT x:C. A Int B x) = (if C={} then UNIV else A Int (INT x:C. B x))"
  1860   "!!A B C. (INT x:C. A x - B)   = (if C={} then UNIV else (INT x:C. A x) - B)"
  1861   "!!A B C. (INT x:C. A - B x)   = (if C={} then UNIV else A - (UN x:C. B x))"
  1862   "!!a B C. (INT x:C. insert a (B x)) = insert a (INT x:C. B x)"
  1863   "!!A B C. (INT x:C. A x Un B)  = ((INT x:C. A x) Un B)"
  1864   "!!A B C. (INT x:C. A Un B x)  = (A Un (INT x:C. B x))"
  1865   "!!A B. (INT x: Union A. B x) = (INT y:A. INT x:y. B x)"
  1866   "!!A B C. (INT z: UNION A B. C z) = (INT x:A. INT z: B(x). C z)"
  1867   "!!A B f. (INT x:f`A. B x)    = (INT a:A. B (f a))"
  1868   by auto
  1869 
  1870 lemma ball_simps [simp]:
  1871   "!!A P Q. (ALL x:A. P x | Q) = ((ALL x:A. P x) | Q)"
  1872   "!!A P Q. (ALL x:A. P | Q x) = (P | (ALL x:A. Q x))"
  1873   "!!A P Q. (ALL x:A. P --> Q x) = (P --> (ALL x:A. Q x))"
  1874   "!!A P Q. (ALL x:A. P x --> Q) = ((EX x:A. P x) --> Q)"
  1875   "!!P. (ALL x:{}. P x) = True"
  1876   "!!P. (ALL x:UNIV. P x) = (ALL x. P x)"
  1877   "!!a B P. (ALL x:insert a B. P x) = (P a & (ALL x:B. P x))"
  1878   "!!A P. (ALL x:Union A. P x) = (ALL y:A. ALL x:y. P x)"
  1879   "!!A B P. (ALL x: UNION A B. P x) = (ALL a:A. ALL x: B a. P x)"
  1880   "!!P Q. (ALL x:Collect Q. P x) = (ALL x. Q x --> P x)"
  1881   "!!A P f. (ALL x:f`A. P x) = (ALL x:A. P (f x))"
  1882   "!!A P. (~(ALL x:A. P x)) = (EX x:A. ~P x)"
  1883   by auto
  1884 
  1885 lemma bex_simps [simp]:
  1886   "!!A P Q. (EX x:A. P x & Q) = ((EX x:A. P x) & Q)"
  1887   "!!A P Q. (EX x:A. P & Q x) = (P & (EX x:A. Q x))"
  1888   "!!P. (EX x:{}. P x) = False"
  1889   "!!P. (EX x:UNIV. P x) = (EX x. P x)"
  1890   "!!a B P. (EX x:insert a B. P x) = (P(a) | (EX x:B. P x))"
  1891   "!!A P. (EX x:Union A. P x) = (EX y:A. EX x:y. P x)"
  1892   "!!A B P. (EX x: UNION A B. P x) = (EX a:A. EX x:B a. P x)"
  1893   "!!P Q. (EX x:Collect Q. P x) = (EX x. Q x & P x)"
  1894   "!!A P f. (EX x:f`A. P x) = (EX x:A. P (f x))"
  1895   "!!A P. (~(EX x:A. P x)) = (ALL x:A. ~P x)"
  1896   by auto
  1897 
  1898 lemma ball_conj_distrib:
  1899   "(ALL x:A. P x & Q x) = ((ALL x:A. P x) & (ALL x:A. Q x))"
  1900   by blast
  1901 
  1902 lemma bex_disj_distrib:
  1903   "(EX x:A. P x | Q x) = ((EX x:A. P x) | (EX x:A. Q x))"
  1904   by blast
  1905 
  1906 
  1907 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
  1908 
  1909 lemma UN_extend_simps:
  1910   "!!a B C. insert a (UN x:C. B x) = (if C={} then {a} else (UN x:C. insert a (B x)))"
  1911   "!!A B C. (UN x:C. A x) Un B    = (if C={} then B else (UN x:C. A x Un B))"
  1912   "!!A B C. A Un (UN x:C. B x)   = (if C={} then A else (UN x:C. A Un B x))"
  1913   "!!A B C. ((UN x:C. A x) Int B) = (UN x:C. A x Int B)"
  1914   "!!A B C. (A Int (UN x:C. B x)) = (UN x:C. A Int B x)"
  1915   "!!A B C. ((UN x:C. A x) - B) = (UN x:C. A x - B)"
  1916   "!!A B C. (A - (INT x:C. B x)) = (UN x:C. A - B x)"
  1917   "!!A B. (UN y:A. UN x:y. B x) = (UN x: Union A. B x)"
  1918   "!!A B C. (UN  x:A. UN z: B(x). C z) = (UN z: UNION A B. C z)"
  1919   "!!A B f. (UN a:A. B (f a)) = (UN x:f`A. B x)"
  1920   by auto
  1921 
  1922 lemma INT_extend_simps:
  1923   "!!A B C. (INT x:C. A x) Int B = (if C={} then B else (INT x:C. A x Int B))"
  1924   "!!A B C. A Int (INT x:C. B x) = (if C={} then A else (INT x:C. A Int B x))"
  1925   "!!A B C. (INT x:C. A x) - B   = (if C={} then UNIV-B else (INT x:C. A x - B))"
  1926   "!!A B C. A - (UN x:C. B x)   = (if C={} then A else (INT x:C. A - B x))"
  1927   "!!a B C. insert a (INT x:C. B x) = (INT x:C. insert a (B x))"
  1928   "!!A B C. ((INT x:C. A x) Un B)  = (INT x:C. A x Un B)"
  1929   "!!A B C. A Un (INT x:C. B x)  = (INT x:C. A Un B x)"
  1930   "!!A B. (INT y:A. INT x:y. B x) = (INT x: Union A. B x)"
  1931   "!!A B C. (INT x:A. INT z: B(x). C z) = (INT z: UNION A B. C z)"
  1932   "!!A B f. (INT a:A. B (f a))    = (INT x:f`A. B x)"
  1933   by auto
  1934 
  1935 
  1936 subsubsection {* Monotonicity of various operations *}
  1937 
  1938 lemma image_mono: "A \<subseteq> B ==> f`A \<subseteq> f`B"
  1939   by blast
  1940 
  1941 lemma Pow_mono: "A \<subseteq> B ==> Pow A \<subseteq> Pow B"
  1942   by blast
  1943 
  1944 lemma Union_mono: "A \<subseteq> B ==> \<Union>A \<subseteq> \<Union>B"
  1945   by blast
  1946 
  1947 lemma Inter_anti_mono: "B \<subseteq> A ==> \<Inter>A \<subseteq> \<Inter>B"
  1948   by blast
  1949 
  1950 lemma UN_mono:
  1951   "A \<subseteq> B ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  1952     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
  1953   by (blast dest: subsetD)
  1954 
  1955 lemma INT_anti_mono:
  1956   "B \<subseteq> A ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  1957     (\<Inter>x\<in>A. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
  1958   -- {* The last inclusion is POSITIVE! *}
  1959   by (blast dest: subsetD)
  1960 
  1961 lemma insert_mono: "C \<subseteq> D ==> insert a C \<subseteq> insert a D"
  1962   by blast
  1963 
  1964 lemma Un_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<union> B \<subseteq> C \<union> D"
  1965   by blast
  1966 
  1967 lemma Int_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<inter> B \<subseteq> C \<inter> D"
  1968   by blast
  1969 
  1970 lemma Diff_mono: "A \<subseteq> C ==> D \<subseteq> B ==> A - B \<subseteq> C - D"
  1971   by blast
  1972 
  1973 lemma Compl_anti_mono: "A \<subseteq> B ==> -B \<subseteq> -A"
  1974   by blast
  1975 
  1976 text {* \medskip Monotonicity of implications. *}
  1977 
  1978 lemma in_mono: "A \<subseteq> B ==> x \<in> A --> x \<in> B"
  1979   apply (rule impI)
  1980   apply (erule subsetD, assumption)
  1981   done
  1982 
  1983 lemma conj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 & P2) --> (Q1 & Q2)"
  1984   by iprover
  1985 
  1986 lemma disj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 | P2) --> (Q1 | Q2)"
  1987   by iprover
  1988 
  1989 lemma imp_mono: "Q1 --> P1 ==> P2 --> Q2 ==> (P1 --> P2) --> (Q1 --> Q2)"
  1990   by iprover
  1991 
  1992 lemma imp_refl: "P --> P" ..
  1993 
  1994 lemma ex_mono: "(!!x. P x --> Q x) ==> (EX x. P x) --> (EX x. Q x)"
  1995   by iprover
  1996 
  1997 lemma all_mono: "(!!x. P x --> Q x) ==> (ALL x. P x) --> (ALL x. Q x)"
  1998   by iprover
  1999 
  2000 lemma Collect_mono: "(!!x. P x --> Q x) ==> Collect P \<subseteq> Collect Q"
  2001   by blast
  2002 
  2003 lemma Int_Collect_mono:
  2004     "A \<subseteq> B ==> (!!x. x \<in> A ==> P x --> Q x) ==> A \<inter> Collect P \<subseteq> B \<inter> Collect Q"
  2005   by blast
  2006 
  2007 lemmas basic_monos =
  2008   subset_refl imp_refl disj_mono conj_mono
  2009   ex_mono Collect_mono in_mono
  2010 
  2011 lemma eq_to_mono: "a = b ==> c = d ==> b --> d ==> a --> c"
  2012   by iprover
  2013 
  2014 lemma eq_to_mono2: "a = b ==> c = d ==> ~ b --> ~ d ==> ~ a --> ~ c"
  2015   by iprover
  2016 
  2017 lemma Least_mono:
  2018   "mono (f::'a::order => 'b::order) ==> EX x:S. ALL y:S. x <= y
  2019     ==> (LEAST y. y : f ` S) = f (LEAST x. x : S)"
  2020     -- {* Courtesy of Stephan Merz *}
  2021   apply clarify
  2022   apply (erule_tac P = "%x. x : S" in LeastI2_order, fast)
  2023   apply (rule LeastI2_order)
  2024   apply (auto elim: monoD intro!: order_antisym)
  2025   done
  2026 
  2027 
  2028 subsection {* Inverse image of a function *}
  2029 
  2030 constdefs
  2031   vimage :: "('a => 'b) => 'b set => 'a set"    (infixr "-`" 90)
  2032   "f -` B == {x. f x : B}"
  2033 
  2034 
  2035 subsubsection {* Basic rules *}
  2036 
  2037 lemma vimage_eq [simp]: "(a : f -` B) = (f a : B)"
  2038   by (unfold vimage_def) blast
  2039 
  2040 lemma vimage_singleton_eq: "(a : f -` {b}) = (f a = b)"
  2041   by simp
  2042 
  2043 lemma vimageI [intro]: "f a = b ==> b:B ==> a : f -` B"
  2044   by (unfold vimage_def) blast
  2045 
  2046 lemma vimageI2: "f a : A ==> a : f -` A"
  2047   by (unfold vimage_def) fast
  2048 
  2049 lemma vimageE [elim!]: "a: f -` B ==> (!!x. f a = x ==> x:B ==> P) ==> P"
  2050   by (unfold vimage_def) blast
  2051 
  2052 lemma vimageD: "a : f -` A ==> f a : A"
  2053   by (unfold vimage_def) fast
  2054 
  2055 
  2056 subsubsection {* Equations *}
  2057 
  2058 lemma vimage_empty [simp]: "f -` {} = {}"
  2059   by blast
  2060 
  2061 lemma vimage_Compl: "f -` (-A) = -(f -` A)"
  2062   by blast
  2063 
  2064 lemma vimage_Un [simp]: "f -` (A Un B) = (f -` A) Un (f -` B)"
  2065   by blast
  2066 
  2067 lemma vimage_Int [simp]: "f -` (A Int B) = (f -` A) Int (f -` B)"
  2068   by fast
  2069 
  2070 lemma vimage_Union: "f -` (Union A) = (UN X:A. f -` X)"
  2071   by blast
  2072 
  2073 lemma vimage_UN: "f-`(UN x:A. B x) = (UN x:A. f -` B x)"
  2074   by blast
  2075 
  2076 lemma vimage_INT: "f-`(INT x:A. B x) = (INT x:A. f -` B x)"
  2077   by blast
  2078 
  2079 lemma vimage_Collect_eq [simp]: "f -` Collect P = {y. P (f y)}"
  2080   by blast
  2081 
  2082 lemma vimage_Collect: "(!!x. P (f x) = Q x) ==> f -` (Collect P) = Collect Q"
  2083   by blast
  2084 
  2085 lemma vimage_insert: "f-`(insert a B) = (f-`{a}) Un (f-`B)"
  2086   -- {* NOT suitable for rewriting because of the recurrence of @{term "{a}"}. *}
  2087   by blast
  2088 
  2089 lemma vimage_Diff: "f -` (A - B) = (f -` A) - (f -` B)"
  2090   by blast
  2091 
  2092 lemma vimage_UNIV [simp]: "f -` UNIV = UNIV"
  2093   by blast
  2094 
  2095 lemma vimage_eq_UN: "f-`B = (UN y: B. f-`{y})"
  2096   -- {* NOT suitable for rewriting *}
  2097   by blast
  2098 
  2099 lemma vimage_mono: "A \<subseteq> B ==> f -` A \<subseteq> f -` B"
  2100   -- {* monotonicity *}
  2101   by blast
  2102 
  2103 
  2104 subsection {* Getting the Contents of a Singleton Set *}
  2105 
  2106 constdefs
  2107   contents :: "'a set => 'a"
  2108    "contents X == THE x. X = {x}"
  2109 
  2110 lemma contents_eq [simp]: "contents {x} = x"
  2111 by (simp add: contents_def)
  2112 
  2113 
  2114 subsection {* Transitivity rules for calculational reasoning *}
  2115 
  2116 lemma set_rev_mp: "x:A ==> A \<subseteq> B ==> x:B"
  2117   by (rule subsetD)
  2118 
  2119 lemma set_mp: "A \<subseteq> B ==> x:A ==> x:B"
  2120   by (rule subsetD)
  2121 
  2122 lemmas basic_trans_rules [trans] =
  2123   order_trans_rules set_rev_mp set_mp
  2124 
  2125 
  2126 subsection {* Sets as lattice *}
  2127 
  2128 instance set :: (type) distrib_lattice
  2129   inf_set_eq: "inf A B \<equiv> A \<inter> B"
  2130   sup_set_eq: "sup A B \<equiv> A \<union> B"
  2131   by intro_classes (auto simp add: inf_set_eq sup_set_eq)
  2132 
  2133 lemmas [code nofunc] = inf_set_eq sup_set_eq
  2134 
  2135 
  2136 subsection {* Basic ML bindings *}
  2137 
  2138 ML {*
  2139 val Ball_def = @{thm Ball_def}
  2140 val Bex_def = @{thm Bex_def}
  2141 val CollectD = @{thm CollectD}
  2142 val CollectE = @{thm CollectE}
  2143 val CollectI = @{thm CollectI}
  2144 val Collect_conj_eq = @{thm Collect_conj_eq}
  2145 val Collect_mem_eq = @{thm Collect_mem_eq}
  2146 val IntD1 = @{thm IntD1}
  2147 val IntD2 = @{thm IntD2}
  2148 val IntE = @{thm IntE}
  2149 val IntI = @{thm IntI}
  2150 val Int_Collect = @{thm Int_Collect}
  2151 val UNIV_I = @{thm UNIV_I}
  2152 val UNIV_witness = @{thm UNIV_witness}
  2153 val UnE = @{thm UnE}
  2154 val UnI1 = @{thm UnI1}
  2155 val UnI2 = @{thm UnI2}
  2156 val ballE = @{thm ballE}
  2157 val ballI = @{thm ballI}
  2158 val bexCI = @{thm bexCI}
  2159 val bexE = @{thm bexE}
  2160 val bexI = @{thm bexI}
  2161 val bex_triv = @{thm bex_triv}
  2162 val bspec = @{thm bspec}
  2163 val contra_subsetD = @{thm contra_subsetD}
  2164 val distinct_lemma = @{thm distinct_lemma}
  2165 val eq_to_mono = @{thm eq_to_mono}
  2166 val eq_to_mono2 = @{thm eq_to_mono2}
  2167 val equalityCE = @{thm equalityCE}
  2168 val equalityD1 = @{thm equalityD1}
  2169 val equalityD2 = @{thm equalityD2}
  2170 val equalityE = @{thm equalityE}
  2171 val equalityI = @{thm equalityI}
  2172 val imageE = @{thm imageE}
  2173 val imageI = @{thm imageI}
  2174 val image_Un = @{thm image_Un}
  2175 val image_insert = @{thm image_insert}
  2176 val insert_commute = @{thm insert_commute}
  2177 val insert_iff = @{thm insert_iff}
  2178 val mem_Collect_eq = @{thm mem_Collect_eq}
  2179 val rangeE = @{thm rangeE}
  2180 val rangeI = @{thm rangeI}
  2181 val range_eqI = @{thm range_eqI}
  2182 val subsetCE = @{thm subsetCE}
  2183 val subsetD = @{thm subsetD}
  2184 val subsetI = @{thm subsetI}
  2185 val subset_refl = @{thm subset_refl}
  2186 val subset_trans = @{thm subset_trans}
  2187 val vimageD = @{thm vimageD}
  2188 val vimageE = @{thm vimageE}
  2189 val vimageI = @{thm vimageI}
  2190 val vimageI2 = @{thm vimageI2}
  2191 val vimage_Collect = @{thm vimage_Collect}
  2192 val vimage_Int = @{thm vimage_Int}
  2193 val vimage_Un = @{thm vimage_Un}
  2194 *}
  2195 
  2196 end