src/HOL/Complex.thy
author paulson <lp15@cam.ac.uk>
Fri Mar 21 15:36:00 2014 +0000 (2014-03-21)
changeset 56238 5d147e1e18d1
parent 56217 dc429a5b13c4
child 56331 bea2196627cb
permissions -rw-r--r--
a few new lemmas and generalisations of old ones
     1 (*  Title:       HOL/Complex.thy
     2     Author:      Jacques D. Fleuriot
     3     Copyright:   2001 University of Edinburgh
     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     5 *)
     6 
     7 header {* Complex Numbers: Rectangular and Polar Representations *}
     8 
     9 theory Complex
    10 imports Transcendental
    11 begin
    12 
    13 datatype complex = Complex real real
    14 
    15 primrec Re :: "complex \<Rightarrow> real"
    16   where Re: "Re (Complex x y) = x"
    17 
    18 primrec Im :: "complex \<Rightarrow> real"
    19   where Im: "Im (Complex x y) = y"
    20 
    21 lemma complex_surj [simp]: "Complex (Re z) (Im z) = z"
    22   by (induct z) simp
    23 
    24 lemma complex_eqI [intro?]: "\<lbrakk>Re x = Re y; Im x = Im y\<rbrakk> \<Longrightarrow> x = y"
    25   by (induct x, induct y) simp
    26 
    27 lemma complex_eq_iff: "x = y \<longleftrightarrow> Re x = Re y \<and> Im x = Im y"
    28   by (induct x, induct y) simp
    29 
    30 
    31 subsection {* Addition and Subtraction *}
    32 
    33 instantiation complex :: ab_group_add
    34 begin
    35 
    36 definition complex_zero_def:
    37   "0 = Complex 0 0"
    38 
    39 definition complex_add_def:
    40   "x + y = Complex (Re x + Re y) (Im x + Im y)"
    41 
    42 definition complex_minus_def:
    43   "- x = Complex (- Re x) (- Im x)"
    44 
    45 definition complex_diff_def:
    46   "x - (y\<Colon>complex) = x + - y"
    47 
    48 lemma Complex_eq_0 [simp]: "Complex a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"
    49   by (simp add: complex_zero_def)
    50 
    51 lemma complex_Re_zero [simp]: "Re 0 = 0"
    52   by (simp add: complex_zero_def)
    53 
    54 lemma complex_Im_zero [simp]: "Im 0 = 0"
    55   by (simp add: complex_zero_def)
    56 
    57 lemma complex_add [simp]:
    58   "Complex a b + Complex c d = Complex (a + c) (b + d)"
    59   by (simp add: complex_add_def)
    60 
    61 lemma complex_Re_add [simp]: "Re (x + y) = Re x + Re y"
    62   by (simp add: complex_add_def)
    63 
    64 lemma complex_Im_add [simp]: "Im (x + y) = Im x + Im y"
    65   by (simp add: complex_add_def)
    66 
    67 lemma complex_minus [simp]:
    68   "- (Complex a b) = Complex (- a) (- b)"
    69   by (simp add: complex_minus_def)
    70 
    71 lemma complex_Re_minus [simp]: "Re (- x) = - Re x"
    72   by (simp add: complex_minus_def)
    73 
    74 lemma complex_Im_minus [simp]: "Im (- x) = - Im x"
    75   by (simp add: complex_minus_def)
    76 
    77 lemma complex_diff [simp]:
    78   "Complex a b - Complex c d = Complex (a - c) (b - d)"
    79   by (simp add: complex_diff_def)
    80 
    81 lemma complex_Re_diff [simp]: "Re (x - y) = Re x - Re y"
    82   by (simp add: complex_diff_def)
    83 
    84 lemma complex_Im_diff [simp]: "Im (x - y) = Im x - Im y"
    85   by (simp add: complex_diff_def)
    86 
    87 instance
    88   by intro_classes (simp_all add: complex_add_def complex_diff_def)
    89 
    90 end
    91 
    92 
    93 subsection {* Multiplication and Division *}
    94 
    95 instantiation complex :: field_inverse_zero
    96 begin
    97 
    98 definition complex_one_def:
    99   "1 = Complex 1 0"
   100 
   101 definition complex_mult_def:
   102   "x * y = Complex (Re x * Re y - Im x * Im y) (Re x * Im y + Im x * Re y)"
   103 
   104 definition complex_inverse_def:
   105   "inverse x =
   106     Complex (Re x / ((Re x)\<^sup>2 + (Im x)\<^sup>2)) (- Im x / ((Re x)\<^sup>2 + (Im x)\<^sup>2))"
   107 
   108 definition complex_divide_def:
   109   "x / (y\<Colon>complex) = x * inverse y"
   110 
   111 lemma Complex_eq_1 [simp]:
   112   "Complex a b = 1 \<longleftrightarrow> a = 1 \<and> b = 0"
   113   by (simp add: complex_one_def)
   114 
   115 lemma Complex_eq_neg_1 [simp]:
   116   "Complex a b = - 1 \<longleftrightarrow> a = - 1 \<and> b = 0"
   117   by (simp add: complex_one_def)
   118 
   119 lemma complex_Re_one [simp]: "Re 1 = 1"
   120   by (simp add: complex_one_def)
   121 
   122 lemma complex_Im_one [simp]: "Im 1 = 0"
   123   by (simp add: complex_one_def)
   124 
   125 lemma complex_mult [simp]:
   126   "Complex a b * Complex c d = Complex (a * c - b * d) (a * d + b * c)"
   127   by (simp add: complex_mult_def)
   128 
   129 lemma complex_Re_mult [simp]: "Re (x * y) = Re x * Re y - Im x * Im y"
   130   by (simp add: complex_mult_def)
   131 
   132 lemma complex_Im_mult [simp]: "Im (x * y) = Re x * Im y + Im x * Re y"
   133   by (simp add: complex_mult_def)
   134 
   135 lemma complex_inverse [simp]:
   136   "inverse (Complex a b) = Complex (a / (a\<^sup>2 + b\<^sup>2)) (- b / (a\<^sup>2 + b\<^sup>2))"
   137   by (simp add: complex_inverse_def)
   138 
   139 lemma complex_Re_inverse:
   140   "Re (inverse x) = Re x / ((Re x)\<^sup>2 + (Im x)\<^sup>2)"
   141   by (simp add: complex_inverse_def)
   142 
   143 lemma complex_Im_inverse:
   144   "Im (inverse x) = - Im x / ((Re x)\<^sup>2 + (Im x)\<^sup>2)"
   145   by (simp add: complex_inverse_def)
   146 
   147 instance
   148   by intro_classes (simp_all add: complex_mult_def
   149     distrib_left distrib_right right_diff_distrib left_diff_distrib
   150     complex_inverse_def complex_divide_def
   151     power2_eq_square add_divide_distrib [symmetric]
   152     complex_eq_iff)
   153 
   154 end
   155 
   156 
   157 subsection {* Numerals and Arithmetic *}
   158 
   159 lemma complex_Re_of_nat [simp]: "Re (of_nat n) = of_nat n"
   160   by (induct n) simp_all
   161 
   162 lemma complex_Im_of_nat [simp]: "Im (of_nat n) = 0"
   163   by (induct n) simp_all
   164 
   165 lemma complex_Re_of_int [simp]: "Re (of_int z) = of_int z"
   166   by (cases z rule: int_diff_cases) simp
   167 
   168 lemma complex_Im_of_int [simp]: "Im (of_int z) = 0"
   169   by (cases z rule: int_diff_cases) simp
   170 
   171 lemma complex_Re_numeral [simp]: "Re (numeral v) = numeral v"
   172   using complex_Re_of_int [of "numeral v"] by simp
   173 
   174 lemma complex_Re_neg_numeral [simp]: "Re (- numeral v) = - numeral v"
   175   using complex_Re_of_int [of "- numeral v"] by simp
   176 
   177 lemma complex_Im_numeral [simp]: "Im (numeral v) = 0"
   178   using complex_Im_of_int [of "numeral v"] by simp
   179 
   180 lemma complex_Im_neg_numeral [simp]: "Im (- numeral v) = 0"
   181   using complex_Im_of_int [of "- numeral v"] by simp
   182 
   183 lemma Complex_eq_numeral [simp]:
   184   "Complex a b = numeral w \<longleftrightarrow> a = numeral w \<and> b = 0"
   185   by (simp add: complex_eq_iff)
   186 
   187 lemma Complex_eq_neg_numeral [simp]:
   188   "Complex a b = - numeral w \<longleftrightarrow> a = - numeral w \<and> b = 0"
   189   by (simp add: complex_eq_iff)
   190 
   191 
   192 subsection {* Scalar Multiplication *}
   193 
   194 instantiation complex :: real_field
   195 begin
   196 
   197 definition complex_scaleR_def:
   198   "scaleR r x = Complex (r * Re x) (r * Im x)"
   199 
   200 lemma complex_scaleR [simp]:
   201   "scaleR r (Complex a b) = Complex (r * a) (r * b)"
   202   unfolding complex_scaleR_def by simp
   203 
   204 lemma complex_Re_scaleR [simp]: "Re (scaleR r x) = r * Re x"
   205   unfolding complex_scaleR_def by simp
   206 
   207 lemma complex_Im_scaleR [simp]: "Im (scaleR r x) = r * Im x"
   208   unfolding complex_scaleR_def by simp
   209 
   210 instance
   211 proof
   212   fix a b :: real and x y :: complex
   213   show "scaleR a (x + y) = scaleR a x + scaleR a y"
   214     by (simp add: complex_eq_iff distrib_left)
   215   show "scaleR (a + b) x = scaleR a x + scaleR b x"
   216     by (simp add: complex_eq_iff distrib_right)
   217   show "scaleR a (scaleR b x) = scaleR (a * b) x"
   218     by (simp add: complex_eq_iff mult_assoc)
   219   show "scaleR 1 x = x"
   220     by (simp add: complex_eq_iff)
   221   show "scaleR a x * y = scaleR a (x * y)"
   222     by (simp add: complex_eq_iff algebra_simps)
   223   show "x * scaleR a y = scaleR a (x * y)"
   224     by (simp add: complex_eq_iff algebra_simps)
   225 qed
   226 
   227 end
   228 
   229 
   230 subsection{* Properties of Embedding from Reals *}
   231 
   232 abbreviation complex_of_real :: "real \<Rightarrow> complex"
   233   where "complex_of_real \<equiv> of_real"
   234 
   235 lemma complex_of_real_def: "complex_of_real r = Complex r 0"
   236   by (simp add: of_real_def complex_scaleR_def)
   237 
   238 lemma Re_complex_of_real [simp]: "Re (complex_of_real z) = z"
   239   by (simp add: complex_of_real_def)
   240 
   241 lemma Im_complex_of_real [simp]: "Im (complex_of_real z) = 0"
   242   by (simp add: complex_of_real_def)
   243 
   244 lemma Complex_add_complex_of_real [simp]:
   245   shows "Complex x y + complex_of_real r = Complex (x+r) y"
   246   by (simp add: complex_of_real_def)
   247 
   248 lemma complex_of_real_add_Complex [simp]:
   249   shows "complex_of_real r + Complex x y = Complex (r+x) y"
   250   by (simp add: complex_of_real_def)
   251 
   252 lemma Complex_mult_complex_of_real:
   253   shows "Complex x y * complex_of_real r = Complex (x*r) (y*r)"
   254   by (simp add: complex_of_real_def)
   255 
   256 lemma complex_of_real_mult_Complex:
   257   shows "complex_of_real r * Complex x y = Complex (r*x) (r*y)"
   258   by (simp add: complex_of_real_def)
   259 
   260 lemma complex_eq_cancel_iff2 [simp]:
   261   shows "(Complex x y = complex_of_real xa) = (x = xa & y = 0)"
   262   by (simp add: complex_of_real_def)
   263 
   264 lemma complex_split_polar:
   265      "\<exists>r a. z = complex_of_real r * (Complex (cos a) (sin a))"
   266   by (simp add: complex_eq_iff polar_Ex)
   267 
   268 
   269 subsection {* Vector Norm *}
   270 
   271 instantiation complex :: real_normed_field
   272 begin
   273 
   274 definition complex_norm_def:
   275   "norm z = sqrt ((Re z)\<^sup>2 + (Im z)\<^sup>2)"
   276 
   277 abbreviation cmod :: "complex \<Rightarrow> real"
   278   where "cmod \<equiv> norm"
   279 
   280 definition complex_sgn_def:
   281   "sgn x = x /\<^sub>R cmod x"
   282 
   283 definition dist_complex_def:
   284   "dist x y = cmod (x - y)"
   285 
   286 definition open_complex_def:
   287   "open (S :: complex set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   288 
   289 lemmas cmod_def = complex_norm_def
   290 
   291 lemma complex_norm [simp]: "cmod (Complex x y) = sqrt (x\<^sup>2 + y\<^sup>2)"
   292   by (simp add: complex_norm_def)
   293 
   294 instance proof
   295   fix r :: real and x y :: complex and S :: "complex set"
   296   show "(norm x = 0) = (x = 0)"
   297     by (induct x) simp
   298   show "norm (x + y) \<le> norm x + norm y"
   299     by (induct x, induct y)
   300        (simp add: real_sqrt_sum_squares_triangle_ineq)
   301   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
   302     by (induct x)
   303        (simp add: power_mult_distrib distrib_left [symmetric] real_sqrt_mult)
   304   show "norm (x * y) = norm x * norm y"
   305     by (induct x, induct y)
   306        (simp add: real_sqrt_mult [symmetric] power2_eq_square algebra_simps)
   307   show "sgn x = x /\<^sub>R cmod x"
   308     by (rule complex_sgn_def)
   309   show "dist x y = cmod (x - y)"
   310     by (rule dist_complex_def)
   311   show "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   312     by (rule open_complex_def)
   313 qed
   314 
   315 end
   316 
   317 lemma cmod_unit_one: "cmod (Complex (cos a) (sin a)) = 1"
   318   by simp
   319 
   320 lemma cmod_complex_polar:
   321   "cmod (complex_of_real r * Complex (cos a) (sin a)) = abs r"
   322   by (simp add: norm_mult)
   323 
   324 lemma complex_Re_le_cmod: "Re x \<le> cmod x"
   325   unfolding complex_norm_def
   326   by (rule real_sqrt_sum_squares_ge1)
   327 
   328 lemma complex_mod_minus_le_complex_mod: "- cmod x \<le> cmod x"
   329   by (rule order_trans [OF _ norm_ge_zero], simp)
   330 
   331 lemma complex_mod_triangle_ineq2: "cmod(b + a) - cmod b \<le> cmod a"
   332   by (rule ord_le_eq_trans [OF norm_triangle_ineq2], simp)
   333 
   334 lemma abs_Re_le_cmod: "\<bar>Re x\<bar> \<le> cmod x"
   335   by (cases x) simp
   336 
   337 lemma abs_Im_le_cmod: "\<bar>Im x\<bar> \<le> cmod x"
   338   by (cases x) simp
   339 
   340 text {* Properties of complex signum. *}
   341 
   342 lemma sgn_eq: "sgn z = z / complex_of_real (cmod z)"
   343   by (simp add: sgn_div_norm divide_inverse scaleR_conv_of_real mult_commute)
   344 
   345 lemma Re_sgn [simp]: "Re(sgn z) = Re(z)/cmod z"
   346   by (simp add: complex_sgn_def divide_inverse)
   347 
   348 lemma Im_sgn [simp]: "Im(sgn z) = Im(z)/cmod z"
   349   by (simp add: complex_sgn_def divide_inverse)
   350 
   351 
   352 subsection {* Completeness of the Complexes *}
   353 
   354 lemma bounded_linear_Re: "bounded_linear Re"
   355   by (rule bounded_linear_intro [where K=1], simp_all add: complex_norm_def)
   356 
   357 lemma bounded_linear_Im: "bounded_linear Im"
   358   by (rule bounded_linear_intro [where K=1], simp_all add: complex_norm_def)
   359 
   360 lemmas tendsto_Re [tendsto_intros] =
   361   bounded_linear.tendsto [OF bounded_linear_Re]
   362 
   363 lemmas tendsto_Im [tendsto_intros] =
   364   bounded_linear.tendsto [OF bounded_linear_Im]
   365 
   366 lemmas isCont_Re [simp] = bounded_linear.isCont [OF bounded_linear_Re]
   367 lemmas isCont_Im [simp] = bounded_linear.isCont [OF bounded_linear_Im]
   368 lemmas Cauchy_Re = bounded_linear.Cauchy [OF bounded_linear_Re]
   369 lemmas Cauchy_Im = bounded_linear.Cauchy [OF bounded_linear_Im]
   370 
   371 lemma tendsto_Complex [tendsto_intros]:
   372   assumes "(f ---> a) F" and "(g ---> b) F"
   373   shows "((\<lambda>x. Complex (f x) (g x)) ---> Complex a b) F"
   374 proof (rule tendstoI)
   375   fix r :: real assume "0 < r"
   376   hence "0 < r / sqrt 2" by (simp add: divide_pos_pos)
   377   have "eventually (\<lambda>x. dist (f x) a < r / sqrt 2) F"
   378     using `(f ---> a) F` and `0 < r / sqrt 2` by (rule tendstoD)
   379   moreover
   380   have "eventually (\<lambda>x. dist (g x) b < r / sqrt 2) F"
   381     using `(g ---> b) F` and `0 < r / sqrt 2` by (rule tendstoD)
   382   ultimately
   383   show "eventually (\<lambda>x. dist (Complex (f x) (g x)) (Complex a b) < r) F"
   384     by (rule eventually_elim2)
   385        (simp add: dist_norm real_sqrt_sum_squares_less)
   386 qed
   387 
   388 instance complex :: banach
   389 proof
   390   fix X :: "nat \<Rightarrow> complex"
   391   assume X: "Cauchy X"
   392   from Cauchy_Re [OF X] have 1: "(\<lambda>n. Re (X n)) ----> lim (\<lambda>n. Re (X n))"
   393     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   394   from Cauchy_Im [OF X] have 2: "(\<lambda>n. Im (X n)) ----> lim (\<lambda>n. Im (X n))"
   395     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   396   have "X ----> Complex (lim (\<lambda>n. Re (X n))) (lim (\<lambda>n. Im (X n)))"
   397     using tendsto_Complex [OF 1 2] by simp
   398   thus "convergent X"
   399     by (rule convergentI)
   400 qed
   401 
   402 declare
   403   DERIV_power[where 'a=complex, THEN DERIV_cong,
   404               unfolded of_nat_def[symmetric], DERIV_intros]
   405 
   406 
   407 subsection {* The Complex Number $i$ *}
   408 
   409 definition "ii" :: complex  ("\<i>")
   410   where i_def: "ii \<equiv> Complex 0 1"
   411 
   412 lemma complex_Re_i [simp]: "Re ii = 0"
   413   by (simp add: i_def)
   414 
   415 lemma complex_Im_i [simp]: "Im ii = 1"
   416   by (simp add: i_def)
   417 
   418 lemma Complex_eq_i [simp]: "(Complex x y = ii) = (x = 0 \<and> y = 1)"
   419   by (simp add: i_def)
   420 
   421 lemma norm_ii [simp]: "norm ii = 1"
   422   by (simp add: i_def)
   423 
   424 lemma complex_i_not_zero [simp]: "ii \<noteq> 0"
   425   by (simp add: complex_eq_iff)
   426 
   427 lemma complex_i_not_one [simp]: "ii \<noteq> 1"
   428   by (simp add: complex_eq_iff)
   429 
   430 lemma complex_i_not_numeral [simp]: "ii \<noteq> numeral w"
   431   by (simp add: complex_eq_iff)
   432 
   433 lemma complex_i_not_neg_numeral [simp]: "ii \<noteq> - numeral w"
   434   by (simp add: complex_eq_iff)
   435 
   436 lemma i_mult_Complex [simp]: "ii * Complex a b = Complex (- b) a"
   437   by (simp add: complex_eq_iff)
   438 
   439 lemma Complex_mult_i [simp]: "Complex a b * ii = Complex (- b) a"
   440   by (simp add: complex_eq_iff)
   441 
   442 lemma i_complex_of_real [simp]: "ii * complex_of_real r = Complex 0 r"
   443   by (simp add: i_def complex_of_real_def)
   444 
   445 lemma complex_of_real_i [simp]: "complex_of_real r * ii = Complex 0 r"
   446   by (simp add: i_def complex_of_real_def)
   447 
   448 lemma i_squared [simp]: "ii * ii = -1"
   449   by (simp add: i_def)
   450 
   451 lemma power2_i [simp]: "ii\<^sup>2 = -1"
   452   by (simp add: power2_eq_square)
   453 
   454 lemma inverse_i [simp]: "inverse ii = - ii"
   455   by (rule inverse_unique, simp)
   456 
   457 lemma complex_i_mult_minus [simp]: "ii * (ii * x) = - x"
   458   by (simp add: mult_assoc [symmetric])
   459 
   460 
   461 subsection {* Complex Conjugation *}
   462 
   463 definition cnj :: "complex \<Rightarrow> complex" where
   464   "cnj z = Complex (Re z) (- Im z)"
   465 
   466 lemma complex_cnj [simp]: "cnj (Complex a b) = Complex a (- b)"
   467   by (simp add: cnj_def)
   468 
   469 lemma complex_Re_cnj [simp]: "Re (cnj x) = Re x"
   470   by (simp add: cnj_def)
   471 
   472 lemma complex_Im_cnj [simp]: "Im (cnj x) = - Im x"
   473   by (simp add: cnj_def)
   474 
   475 lemma complex_cnj_cancel_iff [simp]: "(cnj x = cnj y) = (x = y)"
   476   by (simp add: complex_eq_iff)
   477 
   478 lemma complex_cnj_cnj [simp]: "cnj (cnj z) = z"
   479   by (simp add: cnj_def)
   480 
   481 lemma complex_cnj_zero [simp]: "cnj 0 = 0"
   482   by (simp add: complex_eq_iff)
   483 
   484 lemma complex_cnj_zero_iff [iff]: "(cnj z = 0) = (z = 0)"
   485   by (simp add: complex_eq_iff)
   486 
   487 lemma complex_cnj_add: "cnj (x + y) = cnj x + cnj y"
   488   by (simp add: complex_eq_iff)
   489 
   490 lemma complex_cnj_diff: "cnj (x - y) = cnj x - cnj y"
   491   by (simp add: complex_eq_iff)
   492 
   493 lemma complex_cnj_minus: "cnj (- x) = - cnj x"
   494   by (simp add: complex_eq_iff)
   495 
   496 lemma complex_cnj_one [simp]: "cnj 1 = 1"
   497   by (simp add: complex_eq_iff)
   498 
   499 lemma complex_cnj_mult: "cnj (x * y) = cnj x * cnj y"
   500   by (simp add: complex_eq_iff)
   501 
   502 lemma complex_cnj_inverse: "cnj (inverse x) = inverse (cnj x)"
   503   by (simp add: complex_inverse_def)
   504 
   505 lemma complex_cnj_divide: "cnj (x / y) = cnj x / cnj y"
   506   by (simp add: complex_divide_def complex_cnj_mult complex_cnj_inverse)
   507 
   508 lemma complex_cnj_power: "cnj (x ^ n) = cnj x ^ n"
   509   by (induct n, simp_all add: complex_cnj_mult)
   510 
   511 lemma complex_cnj_of_nat [simp]: "cnj (of_nat n) = of_nat n"
   512   by (simp add: complex_eq_iff)
   513 
   514 lemma complex_cnj_of_int [simp]: "cnj (of_int z) = of_int z"
   515   by (simp add: complex_eq_iff)
   516 
   517 lemma complex_cnj_numeral [simp]: "cnj (numeral w) = numeral w"
   518   by (simp add: complex_eq_iff)
   519 
   520 lemma complex_cnj_neg_numeral [simp]: "cnj (- numeral w) = - numeral w"
   521   by (simp add: complex_eq_iff)
   522 
   523 lemma complex_cnj_scaleR: "cnj (scaleR r x) = scaleR r (cnj x)"
   524   by (simp add: complex_eq_iff)
   525 
   526 lemma complex_mod_cnj [simp]: "cmod (cnj z) = cmod z"
   527   by (simp add: complex_norm_def)
   528 
   529 lemma complex_cnj_complex_of_real [simp]: "cnj (of_real x) = of_real x"
   530   by (simp add: complex_eq_iff)
   531 
   532 lemma complex_cnj_i [simp]: "cnj ii = - ii"
   533   by (simp add: complex_eq_iff)
   534 
   535 lemma complex_add_cnj: "z + cnj z = complex_of_real (2 * Re z)"
   536   by (simp add: complex_eq_iff)
   537 
   538 lemma complex_diff_cnj: "z - cnj z = complex_of_real (2 * Im z) * ii"
   539   by (simp add: complex_eq_iff)
   540 
   541 lemma complex_mult_cnj: "z * cnj z = complex_of_real ((Re z)\<^sup>2 + (Im z)\<^sup>2)"
   542   by (simp add: complex_eq_iff power2_eq_square)
   543 
   544 lemma complex_mod_mult_cnj: "cmod (z * cnj z) = (cmod z)\<^sup>2"
   545   by (simp add: norm_mult power2_eq_square)
   546 
   547 lemma complex_mod_sqrt_Re_mult_cnj: "cmod z = sqrt (Re (z * cnj z))"
   548   by (simp add: cmod_def power2_eq_square)
   549 
   550 lemma complex_In_mult_cnj_zero [simp]: "Im (z * cnj z) = 0"
   551   by simp
   552 
   553 lemma bounded_linear_cnj: "bounded_linear cnj"
   554   using complex_cnj_add complex_cnj_scaleR
   555   by (rule bounded_linear_intro [where K=1], simp)
   556 
   557 lemmas tendsto_cnj [tendsto_intros] =
   558   bounded_linear.tendsto [OF bounded_linear_cnj]
   559 
   560 lemmas isCont_cnj [simp] =
   561   bounded_linear.isCont [OF bounded_linear_cnj]
   562 
   563 
   564 subsection{*Basic Lemmas*}
   565 
   566 lemma complex_eq_0: "z=0 \<longleftrightarrow> (Re z)\<^sup>2 + (Im z)\<^sup>2 = 0"
   567   by (metis complex_Im_zero complex_Re_zero complex_eqI sum_power2_eq_zero_iff)
   568 
   569 lemma complex_neq_0: "z\<noteq>0 \<longleftrightarrow> (Re z)\<^sup>2 + (Im z)\<^sup>2 > 0"
   570 by (metis complex_eq_0 less_numeral_extra(3) sum_power2_gt_zero_iff)
   571 
   572 lemma complex_norm_square: "of_real ((norm z)\<^sup>2) = z * cnj z"
   573 apply (cases z, auto)
   574 by (metis complex_of_real_def of_real_add of_real_power power2_eq_square)
   575 
   576 lemma complex_div_eq_0: 
   577     "(Re(a / b) = 0 \<longleftrightarrow> Re(a * cnj b) = 0) & (Im(a / b) = 0 \<longleftrightarrow> Im(a * cnj b) = 0)"
   578 proof (cases "b=0")
   579   case True then show ?thesis by auto
   580 next
   581   case False
   582   show ?thesis
   583   proof (cases b)
   584     case (Complex x y)
   585     then have "x\<^sup>2 + y\<^sup>2 > 0"
   586       by (metis Complex_eq_0 False sum_power2_gt_zero_iff)
   587     then have "!!u v. u / (x\<^sup>2 + y\<^sup>2) + v / (x\<^sup>2 + y\<^sup>2) = (u + v) / (x\<^sup>2 + y\<^sup>2)"
   588       by (metis add_divide_distrib)
   589     with Complex False show ?thesis
   590       by (auto simp: complex_divide_def)
   591   qed
   592 qed
   593 
   594 lemma re_complex_div_eq_0: "Re(a / b) = 0 \<longleftrightarrow> Re(a * cnj b) = 0"
   595   and im_complex_div_eq_0: "Im(a / b) = 0 \<longleftrightarrow> Im(a * cnj b) = 0"
   596 using complex_div_eq_0 by auto
   597 
   598 
   599 lemma complex_div_gt_0: 
   600     "(Re(a / b) > 0 \<longleftrightarrow> Re(a * cnj b) > 0) & (Im(a / b) > 0 \<longleftrightarrow> Im(a * cnj b) > 0)"
   601 proof (cases "b=0")
   602   case True then show ?thesis by auto
   603 next
   604   case False
   605   show ?thesis
   606   proof (cases b)
   607     case (Complex x y)
   608     then have "x\<^sup>2 + y\<^sup>2 > 0"
   609       by (metis Complex_eq_0 False sum_power2_gt_zero_iff)
   610     moreover have "!!u v. u / (x\<^sup>2 + y\<^sup>2) + v / (x\<^sup>2 + y\<^sup>2) = (u + v) / (x\<^sup>2 + y\<^sup>2)"
   611       by (metis add_divide_distrib)
   612     ultimately show ?thesis using Complex False `0 < x\<^sup>2 + y\<^sup>2`
   613       apply (simp add: complex_divide_def  zero_less_divide_iff less_divide_eq)
   614       apply (metis less_divide_eq mult_zero_left diff_conv_add_uminus minus_divide_left)
   615       done
   616   qed
   617 qed
   618 
   619 lemma re_complex_div_gt_0: "Re(a / b) > 0 \<longleftrightarrow> Re(a * cnj b) > 0"
   620   and im_complex_div_gt_0: "Im(a / b) > 0 \<longleftrightarrow> Im(a * cnj b) > 0"
   621 using complex_div_gt_0 by auto
   622 
   623 lemma re_complex_div_ge_0: "Re(a / b) \<ge> 0 \<longleftrightarrow> Re(a * cnj b) \<ge> 0"
   624   by (metis le_less re_complex_div_eq_0 re_complex_div_gt_0)
   625 
   626 lemma im_complex_div_ge_0: "Im(a / b) \<ge> 0 \<longleftrightarrow> Im(a * cnj b) \<ge> 0"
   627   by (metis im_complex_div_eq_0 im_complex_div_gt_0 le_less)
   628 
   629 lemma re_complex_div_lt_0: "Re(a / b) < 0 \<longleftrightarrow> Re(a * cnj b) < 0"
   630   by (metis less_asym neq_iff re_complex_div_eq_0 re_complex_div_gt_0)
   631 
   632 lemma im_complex_div_lt_0: "Im(a / b) < 0 \<longleftrightarrow> Im(a * cnj b) < 0"
   633   by (metis im_complex_div_eq_0 im_complex_div_gt_0 less_asym neq_iff)
   634 
   635 lemma re_complex_div_le_0: "Re(a / b) \<le> 0 \<longleftrightarrow> Re(a * cnj b) \<le> 0"
   636   by (metis not_le re_complex_div_gt_0)
   637 
   638 lemma im_complex_div_le_0: "Im(a / b) \<le> 0 \<longleftrightarrow> Im(a * cnj b) \<le> 0"
   639   by (metis im_complex_div_gt_0 not_le)
   640 
   641 lemma Re_setsum: "Re(setsum f s) = setsum (%x. Re(f x)) s"
   642 apply (cases "finite s")
   643   by (induct s rule: finite_induct) auto
   644 
   645 lemma Im_setsum: "Im(setsum f s) = setsum (%x. Im(f x)) s"
   646 apply (cases "finite s")
   647   by (induct s rule: finite_induct) auto
   648 
   649 lemma Complex_setsum': "setsum (%x. Complex (f x) 0) s = Complex (setsum f s) 0"
   650 apply (cases "finite s")
   651   by (induct s rule: finite_induct) auto
   652 
   653 lemma Complex_setsum: "Complex (setsum f s) 0 = setsum (%x. Complex (f x) 0) s"
   654   by (metis Complex_setsum')
   655 
   656 lemma cnj_setsum: "cnj (setsum f s) = setsum (%x. cnj (f x)) s"
   657 apply (cases "finite s")
   658   by (induct s rule: finite_induct) (auto simp: complex_cnj_add)
   659 
   660 lemma of_real_setsum: "of_real (setsum f s) = setsum (%x. of_real(f x)) s"
   661 apply (cases "finite s")
   662   by (induct s rule: finite_induct) auto
   663 
   664 lemma of_real_setprod: "of_real (setprod f s) = setprod (%x. of_real(f x)) s"
   665 apply (cases "finite s")
   666   by (induct s rule: finite_induct) auto
   667 
   668 lemma Reals_cnj_iff: "z \<in> \<real> \<longleftrightarrow> cnj z = z"
   669 by (metis Reals_cases Reals_of_real complex.exhaust complex.inject complex_cnj 
   670           complex_of_real_def equal_neg_zero)
   671 
   672 lemma Complex_in_Reals: "Complex x 0 \<in> \<real>"
   673   by (metis Reals_of_real complex_of_real_def)
   674 
   675 lemma in_Reals_norm: "z \<in> \<real> \<Longrightarrow> norm(z) = abs(Re z)"
   676   by (metis Re_complex_of_real Reals_cases norm_of_real)
   677 
   678 
   679 subsection{*Finally! Polar Form for Complex Numbers*}
   680 
   681 subsubsection {* $\cos \theta + i \sin \theta$ *}
   682 
   683 definition cis :: "real \<Rightarrow> complex" where
   684   "cis a = Complex (cos a) (sin a)"
   685 
   686 lemma Re_cis [simp]: "Re (cis a) = cos a"
   687   by (simp add: cis_def)
   688 
   689 lemma Im_cis [simp]: "Im (cis a) = sin a"
   690   by (simp add: cis_def)
   691 
   692 lemma cis_zero [simp]: "cis 0 = 1"
   693   by (simp add: cis_def)
   694 
   695 lemma norm_cis [simp]: "norm (cis a) = 1"
   696   by (simp add: cis_def)
   697 
   698 lemma sgn_cis [simp]: "sgn (cis a) = cis a"
   699   by (simp add: sgn_div_norm)
   700 
   701 lemma cis_neq_zero [simp]: "cis a \<noteq> 0"
   702   by (metis norm_cis norm_zero zero_neq_one)
   703 
   704 lemma cis_mult: "cis a * cis b = cis (a + b)"
   705   by (simp add: cis_def cos_add sin_add)
   706 
   707 lemma DeMoivre: "(cis a) ^ n = cis (real n * a)"
   708   by (induct n, simp_all add: real_of_nat_Suc algebra_simps cis_mult)
   709 
   710 lemma cis_inverse [simp]: "inverse(cis a) = cis (-a)"
   711   by (simp add: cis_def)
   712 
   713 lemma cis_divide: "cis a / cis b = cis (a - b)"
   714   by (simp add: complex_divide_def cis_mult)
   715 
   716 lemma cos_n_Re_cis_pow_n: "cos (real n * a) = Re(cis a ^ n)"
   717   by (auto simp add: DeMoivre)
   718 
   719 lemma sin_n_Im_cis_pow_n: "sin (real n * a) = Im(cis a ^ n)"
   720   by (auto simp add: DeMoivre)
   721 
   722 subsubsection {* $r(\cos \theta + i \sin \theta)$ *}
   723 
   724 definition rcis :: "[real, real] \<Rightarrow> complex" where
   725   "rcis r a = complex_of_real r * cis a"
   726 
   727 lemma Re_rcis [simp]: "Re(rcis r a) = r * cos a"
   728   by (simp add: rcis_def)
   729 
   730 lemma Im_rcis [simp]: "Im(rcis r a) = r * sin a"
   731   by (simp add: rcis_def)
   732 
   733 lemma rcis_Ex: "\<exists>r a. z = rcis r a"
   734   by (simp add: complex_eq_iff polar_Ex)
   735 
   736 lemma complex_mod_rcis [simp]: "cmod(rcis r a) = abs r"
   737   by (simp add: rcis_def norm_mult)
   738 
   739 lemma cis_rcis_eq: "cis a = rcis 1 a"
   740   by (simp add: rcis_def)
   741 
   742 lemma rcis_mult: "rcis r1 a * rcis r2 b = rcis (r1*r2) (a + b)"
   743   by (simp add: rcis_def cis_mult)
   744 
   745 lemma rcis_zero_mod [simp]: "rcis 0 a = 0"
   746   by (simp add: rcis_def)
   747 
   748 lemma rcis_zero_arg [simp]: "rcis r 0 = complex_of_real r"
   749   by (simp add: rcis_def)
   750 
   751 lemma rcis_eq_zero_iff [simp]: "rcis r a = 0 \<longleftrightarrow> r = 0"
   752   by (simp add: rcis_def)
   753 
   754 lemma DeMoivre2: "(rcis r a) ^ n = rcis (r ^ n) (real n * a)"
   755   by (simp add: rcis_def power_mult_distrib DeMoivre)
   756 
   757 lemma rcis_inverse: "inverse(rcis r a) = rcis (1/r) (-a)"
   758   by (simp add: divide_inverse rcis_def)
   759 
   760 lemma rcis_divide: "rcis r1 a / rcis r2 b = rcis (r1/r2) (a - b)"
   761   by (simp add: rcis_def cis_divide [symmetric])
   762 
   763 subsubsection {* Complex exponential *}
   764 
   765 abbreviation expi :: "complex \<Rightarrow> complex"
   766   where "expi \<equiv> exp"
   767 
   768 lemma cis_conv_exp: "cis b = exp (Complex 0 b)"
   769 proof (rule complex_eqI)
   770   { fix n have "Complex 0 b ^ n =
   771     real (fact n) *\<^sub>R Complex (cos_coeff n * b ^ n) (sin_coeff n * b ^ n)"
   772       apply (induct n)
   773       apply (simp add: cos_coeff_def sin_coeff_def)
   774       apply (simp add: sin_coeff_Suc cos_coeff_Suc del: mult_Suc)
   775       done } note * = this
   776   show "Re (cis b) = Re (exp (Complex 0 b))"
   777     unfolding exp_def cis_def cos_def
   778     by (subst bounded_linear.suminf[OF bounded_linear_Re summable_exp_generic],
   779       simp add: * mult_assoc [symmetric])
   780   show "Im (cis b) = Im (exp (Complex 0 b))"
   781     unfolding exp_def cis_def sin_def
   782     by (subst bounded_linear.suminf[OF bounded_linear_Im summable_exp_generic],
   783       simp add: * mult_assoc [symmetric])
   784 qed
   785 
   786 lemma expi_def: "expi z = complex_of_real (exp (Re z)) * cis (Im z)"
   787   unfolding cis_conv_exp exp_of_real [symmetric] mult_exp_exp by simp
   788 
   789 lemma Re_exp: "Re (exp z) = exp (Re z) * cos (Im z)"
   790   unfolding expi_def by simp
   791 
   792 lemma Im_exp: "Im (exp z) = exp (Re z) * sin (Im z)"
   793   unfolding expi_def by simp
   794 
   795 lemma complex_expi_Ex: "\<exists>a r. z = complex_of_real r * expi a"
   796 apply (insert rcis_Ex [of z])
   797 apply (auto simp add: expi_def rcis_def mult_assoc [symmetric])
   798 apply (rule_tac x = "ii * complex_of_real a" in exI, auto)
   799 done
   800 
   801 lemma expi_two_pi_i [simp]: "expi((2::complex) * complex_of_real pi * ii) = 1"
   802   by (simp add: expi_def cis_def)
   803 
   804 subsubsection {* Complex argument *}
   805 
   806 definition arg :: "complex \<Rightarrow> real" where
   807   "arg z = (if z = 0 then 0 else (SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi))"
   808 
   809 lemma arg_zero: "arg 0 = 0"
   810   by (simp add: arg_def)
   811 
   812 lemma of_nat_less_of_int_iff: (* TODO: move *)
   813   "(of_nat n :: 'a::linordered_idom) < of_int x \<longleftrightarrow> int n < x"
   814   by (metis of_int_of_nat_eq of_int_less_iff)
   815 
   816 lemma real_of_nat_less_numeral_iff [simp]: (* TODO: move *)
   817   "real (n::nat) < numeral w \<longleftrightarrow> n < numeral w"
   818   using of_nat_less_of_int_iff [of n "numeral w", where 'a=real]
   819   by (simp add: real_of_nat_def zless_nat_eq_int_zless [symmetric])
   820 
   821 lemma arg_unique:
   822   assumes "sgn z = cis x" and "-pi < x" and "x \<le> pi"
   823   shows "arg z = x"
   824 proof -
   825   from assms have "z \<noteq> 0" by auto
   826   have "(SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi) = x"
   827   proof
   828     fix a def d \<equiv> "a - x"
   829     assume a: "sgn z = cis a \<and> - pi < a \<and> a \<le> pi"
   830     from a assms have "- (2*pi) < d \<and> d < 2*pi"
   831       unfolding d_def by simp
   832     moreover from a assms have "cos a = cos x" and "sin a = sin x"
   833       by (simp_all add: complex_eq_iff)
   834     hence cos: "cos d = 1" unfolding d_def cos_diff by simp
   835     moreover from cos have "sin d = 0" by (rule cos_one_sin_zero)
   836     ultimately have "d = 0"
   837       unfolding sin_zero_iff even_mult_two_ex
   838       by (auto simp add: numeral_2_eq_2 less_Suc_eq)
   839     thus "a = x" unfolding d_def by simp
   840   qed (simp add: assms del: Re_sgn Im_sgn)
   841   with `z \<noteq> 0` show "arg z = x"
   842     unfolding arg_def by simp
   843 qed
   844 
   845 lemma arg_correct:
   846   assumes "z \<noteq> 0" shows "sgn z = cis (arg z) \<and> -pi < arg z \<and> arg z \<le> pi"
   847 proof (simp add: arg_def assms, rule someI_ex)
   848   obtain r a where z: "z = rcis r a" using rcis_Ex by fast
   849   with assms have "r \<noteq> 0" by auto
   850   def b \<equiv> "if 0 < r then a else a + pi"
   851   have b: "sgn z = cis b"
   852     unfolding z b_def rcis_def using `r \<noteq> 0`
   853     by (simp add: of_real_def sgn_scaleR sgn_if, simp add: cis_def)
   854   have cis_2pi_nat: "\<And>n. cis (2 * pi * real_of_nat n) = 1"
   855     by (induct_tac n, simp_all add: distrib_left cis_mult [symmetric],
   856       simp add: cis_def)
   857   have cis_2pi_int: "\<And>x. cis (2 * pi * real_of_int x) = 1"
   858     by (case_tac x rule: int_diff_cases,
   859       simp add: right_diff_distrib cis_divide [symmetric] cis_2pi_nat)
   860   def c \<equiv> "b - 2*pi * of_int \<lceil>(b - pi) / (2*pi)\<rceil>"
   861   have "sgn z = cis c"
   862     unfolding b c_def
   863     by (simp add: cis_divide [symmetric] cis_2pi_int)
   864   moreover have "- pi < c \<and> c \<le> pi"
   865     using ceiling_correct [of "(b - pi) / (2*pi)"]
   866     by (simp add: c_def less_divide_eq divide_le_eq algebra_simps)
   867   ultimately show "\<exists>a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi" by fast
   868 qed
   869 
   870 lemma arg_bounded: "- pi < arg z \<and> arg z \<le> pi"
   871   by (cases "z = 0", simp_all add: arg_zero arg_correct)
   872 
   873 lemma cis_arg: "z \<noteq> 0 \<Longrightarrow> cis (arg z) = sgn z"
   874   by (simp add: arg_correct)
   875 
   876 lemma rcis_cmod_arg: "rcis (cmod z) (arg z) = z"
   877   by (cases "z = 0", simp_all add: rcis_def cis_arg sgn_div_norm of_real_def)
   878 
   879 lemma cos_arg_i_mult_zero [simp]:
   880      "y \<noteq> 0 ==> cos (arg(Complex 0 y)) = 0"
   881   using cis_arg [of "Complex 0 y"] by (simp add: complex_eq_iff)
   882 
   883 text {* Legacy theorem names *}
   884 
   885 lemmas expand_complex_eq = complex_eq_iff
   886 lemmas complex_Re_Im_cancel_iff = complex_eq_iff
   887 lemmas complex_equality = complex_eqI
   888 
   889 end