src/HOL/Divides.thy
author bulwahn
Mon Feb 20 15:17:03 2012 +0100 (2012-02-20)
changeset 46552 5d33a3269029
parent 46551 866bce5442a3
child 46560 8e252a608765
permissions -rw-r--r--
removing some unnecessary premises from Divides
     1 (*  Title:      HOL/Divides.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1999  University of Cambridge
     4 *)
     5 
     6 header {* The division operators div and mod *}
     7 
     8 theory Divides
     9 imports Nat_Numeral Nat_Transfer
    10 uses "~~/src/Provers/Arith/cancel_div_mod.ML"
    11 begin
    12 
    13 subsection {* Syntactic division operations *}
    14 
    15 class div = dvd +
    16   fixes div :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "div" 70)
    17     and mod :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "mod" 70)
    18 
    19 
    20 subsection {* Abstract division in commutative semirings. *}
    21 
    22 class semiring_div = comm_semiring_1_cancel + no_zero_divisors + div +
    23   assumes mod_div_equality: "a div b * b + a mod b = a"
    24     and div_by_0 [simp]: "a div 0 = 0"
    25     and div_0 [simp]: "0 div a = 0"
    26     and div_mult_self1 [simp]: "b \<noteq> 0 \<Longrightarrow> (a + c * b) div b = c + a div b"
    27     and div_mult_mult1 [simp]: "c \<noteq> 0 \<Longrightarrow> (c * a) div (c * b) = a div b"
    28 begin
    29 
    30 text {* @{const div} and @{const mod} *}
    31 
    32 lemma mod_div_equality2: "b * (a div b) + a mod b = a"
    33   unfolding mult_commute [of b]
    34   by (rule mod_div_equality)
    35 
    36 lemma mod_div_equality': "a mod b + a div b * b = a"
    37   using mod_div_equality [of a b]
    38   by (simp only: add_ac)
    39 
    40 lemma div_mod_equality: "((a div b) * b + a mod b) + c = a + c"
    41   by (simp add: mod_div_equality)
    42 
    43 lemma div_mod_equality2: "(b * (a div b) + a mod b) + c = a + c"
    44   by (simp add: mod_div_equality2)
    45 
    46 lemma mod_by_0 [simp]: "a mod 0 = a"
    47   using mod_div_equality [of a zero] by simp
    48 
    49 lemma mod_0 [simp]: "0 mod a = 0"
    50   using mod_div_equality [of zero a] div_0 by simp
    51 
    52 lemma div_mult_self2 [simp]:
    53   assumes "b \<noteq> 0"
    54   shows "(a + b * c) div b = c + a div b"
    55   using assms div_mult_self1 [of b a c] by (simp add: mult_commute)
    56 
    57 lemma mod_mult_self1 [simp]: "(a + c * b) mod b = a mod b"
    58 proof (cases "b = 0")
    59   case True then show ?thesis by simp
    60 next
    61   case False
    62   have "a + c * b = (a + c * b) div b * b + (a + c * b) mod b"
    63     by (simp add: mod_div_equality)
    64   also from False div_mult_self1 [of b a c] have
    65     "\<dots> = (c + a div b) * b + (a + c * b) mod b"
    66       by (simp add: algebra_simps)
    67   finally have "a = a div b * b + (a + c * b) mod b"
    68     by (simp add: add_commute [of a] add_assoc left_distrib)
    69   then have "a div b * b + (a + c * b) mod b = a div b * b + a mod b"
    70     by (simp add: mod_div_equality)
    71   then show ?thesis by simp
    72 qed
    73 
    74 lemma mod_mult_self2 [simp]: "(a + b * c) mod b = a mod b"
    75   by (simp add: mult_commute [of b])
    76 
    77 lemma div_mult_self1_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> b * a div b = a"
    78   using div_mult_self2 [of b 0 a] by simp
    79 
    80 lemma div_mult_self2_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> a * b div b = a"
    81   using div_mult_self1 [of b 0 a] by simp
    82 
    83 lemma mod_mult_self1_is_0 [simp]: "b * a mod b = 0"
    84   using mod_mult_self2 [of 0 b a] by simp
    85 
    86 lemma mod_mult_self2_is_0 [simp]: "a * b mod b = 0"
    87   using mod_mult_self1 [of 0 a b] by simp
    88 
    89 lemma div_by_1 [simp]: "a div 1 = a"
    90   using div_mult_self2_is_id [of 1 a] zero_neq_one by simp
    91 
    92 lemma mod_by_1 [simp]: "a mod 1 = 0"
    93 proof -
    94   from mod_div_equality [of a one] div_by_1 have "a + a mod 1 = a" by simp
    95   then have "a + a mod 1 = a + 0" by simp
    96   then show ?thesis by (rule add_left_imp_eq)
    97 qed
    98 
    99 lemma mod_self [simp]: "a mod a = 0"
   100   using mod_mult_self2_is_0 [of 1] by simp
   101 
   102 lemma div_self [simp]: "a \<noteq> 0 \<Longrightarrow> a div a = 1"
   103   using div_mult_self2_is_id [of _ 1] by simp
   104 
   105 lemma div_add_self1 [simp]:
   106   assumes "b \<noteq> 0"
   107   shows "(b + a) div b = a div b + 1"
   108   using assms div_mult_self1 [of b a 1] by (simp add: add_commute)
   109 
   110 lemma div_add_self2 [simp]:
   111   assumes "b \<noteq> 0"
   112   shows "(a + b) div b = a div b + 1"
   113   using assms div_add_self1 [of b a] by (simp add: add_commute)
   114 
   115 lemma mod_add_self1 [simp]:
   116   "(b + a) mod b = a mod b"
   117   using mod_mult_self1 [of a 1 b] by (simp add: add_commute)
   118 
   119 lemma mod_add_self2 [simp]:
   120   "(a + b) mod b = a mod b"
   121   using mod_mult_self1 [of a 1 b] by simp
   122 
   123 lemma mod_div_decomp:
   124   fixes a b
   125   obtains q r where "q = a div b" and "r = a mod b"
   126     and "a = q * b + r"
   127 proof -
   128   from mod_div_equality have "a = a div b * b + a mod b" by simp
   129   moreover have "a div b = a div b" ..
   130   moreover have "a mod b = a mod b" ..
   131   note that ultimately show thesis by blast
   132 qed
   133 
   134 lemma dvd_eq_mod_eq_0 [code]: "a dvd b \<longleftrightarrow> b mod a = 0"
   135 proof
   136   assume "b mod a = 0"
   137   with mod_div_equality [of b a] have "b div a * a = b" by simp
   138   then have "b = a * (b div a)" unfolding mult_commute ..
   139   then have "\<exists>c. b = a * c" ..
   140   then show "a dvd b" unfolding dvd_def .
   141 next
   142   assume "a dvd b"
   143   then have "\<exists>c. b = a * c" unfolding dvd_def .
   144   then obtain c where "b = a * c" ..
   145   then have "b mod a = a * c mod a" by simp
   146   then have "b mod a = c * a mod a" by (simp add: mult_commute)
   147   then show "b mod a = 0" by simp
   148 qed
   149 
   150 lemma mod_div_trivial [simp]: "a mod b div b = 0"
   151 proof (cases "b = 0")
   152   assume "b = 0"
   153   thus ?thesis by simp
   154 next
   155   assume "b \<noteq> 0"
   156   hence "a div b + a mod b div b = (a mod b + a div b * b) div b"
   157     by (rule div_mult_self1 [symmetric])
   158   also have "\<dots> = a div b"
   159     by (simp only: mod_div_equality')
   160   also have "\<dots> = a div b + 0"
   161     by simp
   162   finally show ?thesis
   163     by (rule add_left_imp_eq)
   164 qed
   165 
   166 lemma mod_mod_trivial [simp]: "a mod b mod b = a mod b"
   167 proof -
   168   have "a mod b mod b = (a mod b + a div b * b) mod b"
   169     by (simp only: mod_mult_self1)
   170   also have "\<dots> = a mod b"
   171     by (simp only: mod_div_equality')
   172   finally show ?thesis .
   173 qed
   174 
   175 lemma dvd_imp_mod_0: "a dvd b \<Longrightarrow> b mod a = 0"
   176 by (rule dvd_eq_mod_eq_0[THEN iffD1])
   177 
   178 lemma dvd_div_mult_self: "a dvd b \<Longrightarrow> (b div a) * a = b"
   179 by (subst (2) mod_div_equality [of b a, symmetric]) (simp add:dvd_imp_mod_0)
   180 
   181 lemma dvd_mult_div_cancel: "a dvd b \<Longrightarrow> a * (b div a) = b"
   182 by (drule dvd_div_mult_self) (simp add: mult_commute)
   183 
   184 lemma dvd_div_mult: "a dvd b \<Longrightarrow> (b div a) * c = b * c div a"
   185 apply (cases "a = 0")
   186  apply simp
   187 apply (auto simp: dvd_def mult_assoc)
   188 done
   189 
   190 lemma div_dvd_div[simp]:
   191   "a dvd b \<Longrightarrow> a dvd c \<Longrightarrow> (b div a dvd c div a) = (b dvd c)"
   192 apply (cases "a = 0")
   193  apply simp
   194 apply (unfold dvd_def)
   195 apply auto
   196  apply(blast intro:mult_assoc[symmetric])
   197 apply(fastforce simp add: mult_assoc)
   198 done
   199 
   200 lemma dvd_mod_imp_dvd: "[| k dvd m mod n;  k dvd n |] ==> k dvd m"
   201   apply (subgoal_tac "k dvd (m div n) *n + m mod n")
   202    apply (simp add: mod_div_equality)
   203   apply (simp only: dvd_add dvd_mult)
   204   done
   205 
   206 text {* Addition respects modular equivalence. *}
   207 
   208 lemma mod_add_left_eq: "(a + b) mod c = (a mod c + b) mod c"
   209 proof -
   210   have "(a + b) mod c = (a div c * c + a mod c + b) mod c"
   211     by (simp only: mod_div_equality)
   212   also have "\<dots> = (a mod c + b + a div c * c) mod c"
   213     by (simp only: add_ac)
   214   also have "\<dots> = (a mod c + b) mod c"
   215     by (rule mod_mult_self1)
   216   finally show ?thesis .
   217 qed
   218 
   219 lemma mod_add_right_eq: "(a + b) mod c = (a + b mod c) mod c"
   220 proof -
   221   have "(a + b) mod c = (a + (b div c * c + b mod c)) mod c"
   222     by (simp only: mod_div_equality)
   223   also have "\<dots> = (a + b mod c + b div c * c) mod c"
   224     by (simp only: add_ac)
   225   also have "\<dots> = (a + b mod c) mod c"
   226     by (rule mod_mult_self1)
   227   finally show ?thesis .
   228 qed
   229 
   230 lemma mod_add_eq: "(a + b) mod c = (a mod c + b mod c) mod c"
   231 by (rule trans [OF mod_add_left_eq mod_add_right_eq])
   232 
   233 lemma mod_add_cong:
   234   assumes "a mod c = a' mod c"
   235   assumes "b mod c = b' mod c"
   236   shows "(a + b) mod c = (a' + b') mod c"
   237 proof -
   238   have "(a mod c + b mod c) mod c = (a' mod c + b' mod c) mod c"
   239     unfolding assms ..
   240   thus ?thesis
   241     by (simp only: mod_add_eq [symmetric])
   242 qed
   243 
   244 lemma div_add [simp]: "z dvd x \<Longrightarrow> z dvd y
   245   \<Longrightarrow> (x + y) div z = x div z + y div z"
   246 by (cases "z = 0", simp, unfold dvd_def, auto simp add: algebra_simps)
   247 
   248 text {* Multiplication respects modular equivalence. *}
   249 
   250 lemma mod_mult_left_eq: "(a * b) mod c = ((a mod c) * b) mod c"
   251 proof -
   252   have "(a * b) mod c = ((a div c * c + a mod c) * b) mod c"
   253     by (simp only: mod_div_equality)
   254   also have "\<dots> = (a mod c * b + a div c * b * c) mod c"
   255     by (simp only: algebra_simps)
   256   also have "\<dots> = (a mod c * b) mod c"
   257     by (rule mod_mult_self1)
   258   finally show ?thesis .
   259 qed
   260 
   261 lemma mod_mult_right_eq: "(a * b) mod c = (a * (b mod c)) mod c"
   262 proof -
   263   have "(a * b) mod c = (a * (b div c * c + b mod c)) mod c"
   264     by (simp only: mod_div_equality)
   265   also have "\<dots> = (a * (b mod c) + a * (b div c) * c) mod c"
   266     by (simp only: algebra_simps)
   267   also have "\<dots> = (a * (b mod c)) mod c"
   268     by (rule mod_mult_self1)
   269   finally show ?thesis .
   270 qed
   271 
   272 lemma mod_mult_eq: "(a * b) mod c = ((a mod c) * (b mod c)) mod c"
   273 by (rule trans [OF mod_mult_left_eq mod_mult_right_eq])
   274 
   275 lemma mod_mult_cong:
   276   assumes "a mod c = a' mod c"
   277   assumes "b mod c = b' mod c"
   278   shows "(a * b) mod c = (a' * b') mod c"
   279 proof -
   280   have "(a mod c * (b mod c)) mod c = (a' mod c * (b' mod c)) mod c"
   281     unfolding assms ..
   282   thus ?thesis
   283     by (simp only: mod_mult_eq [symmetric])
   284 qed
   285 
   286 lemma mod_mod_cancel:
   287   assumes "c dvd b"
   288   shows "a mod b mod c = a mod c"
   289 proof -
   290   from `c dvd b` obtain k where "b = c * k"
   291     by (rule dvdE)
   292   have "a mod b mod c = a mod (c * k) mod c"
   293     by (simp only: `b = c * k`)
   294   also have "\<dots> = (a mod (c * k) + a div (c * k) * k * c) mod c"
   295     by (simp only: mod_mult_self1)
   296   also have "\<dots> = (a div (c * k) * (c * k) + a mod (c * k)) mod c"
   297     by (simp only: add_ac mult_ac)
   298   also have "\<dots> = a mod c"
   299     by (simp only: mod_div_equality)
   300   finally show ?thesis .
   301 qed
   302 
   303 lemma div_mult_div_if_dvd:
   304   "y dvd x \<Longrightarrow> z dvd w \<Longrightarrow> (x div y) * (w div z) = (x * w) div (y * z)"
   305   apply (cases "y = 0", simp)
   306   apply (cases "z = 0", simp)
   307   apply (auto elim!: dvdE simp add: algebra_simps)
   308   apply (subst mult_assoc [symmetric])
   309   apply (simp add: no_zero_divisors)
   310   done
   311 
   312 lemma div_mult_swap:
   313   assumes "c dvd b"
   314   shows "a * (b div c) = (a * b) div c"
   315 proof -
   316   from assms have "b div c * (a div 1) = b * a div (c * 1)"
   317     by (simp only: div_mult_div_if_dvd one_dvd)
   318   then show ?thesis by (simp add: mult_commute)
   319 qed
   320    
   321 lemma div_mult_mult2 [simp]:
   322   "c \<noteq> 0 \<Longrightarrow> (a * c) div (b * c) = a div b"
   323   by (drule div_mult_mult1) (simp add: mult_commute)
   324 
   325 lemma div_mult_mult1_if [simp]:
   326   "(c * a) div (c * b) = (if c = 0 then 0 else a div b)"
   327   by simp_all
   328 
   329 lemma mod_mult_mult1:
   330   "(c * a) mod (c * b) = c * (a mod b)"
   331 proof (cases "c = 0")
   332   case True then show ?thesis by simp
   333 next
   334   case False
   335   from mod_div_equality
   336   have "((c * a) div (c * b)) * (c * b) + (c * a) mod (c * b) = c * a" .
   337   with False have "c * ((a div b) * b + a mod b) + (c * a) mod (c * b)
   338     = c * a + c * (a mod b)" by (simp add: algebra_simps)
   339   with mod_div_equality show ?thesis by simp 
   340 qed
   341   
   342 lemma mod_mult_mult2:
   343   "(a * c) mod (b * c) = (a mod b) * c"
   344   using mod_mult_mult1 [of c a b] by (simp add: mult_commute)
   345 
   346 lemma dvd_mod: "k dvd m \<Longrightarrow> k dvd n \<Longrightarrow> k dvd (m mod n)"
   347   unfolding dvd_def by (auto simp add: mod_mult_mult1)
   348 
   349 lemma dvd_mod_iff: "k dvd n \<Longrightarrow> k dvd (m mod n) \<longleftrightarrow> k dvd m"
   350 by (blast intro: dvd_mod_imp_dvd dvd_mod)
   351 
   352 lemma div_power:
   353   "y dvd x \<Longrightarrow> (x div y) ^ n = x ^ n div y ^ n"
   354 apply (induct n)
   355  apply simp
   356 apply(simp add: div_mult_div_if_dvd dvd_power_same)
   357 done
   358 
   359 lemma dvd_div_eq_mult:
   360   assumes "a \<noteq> 0" and "a dvd b"  
   361   shows "b div a = c \<longleftrightarrow> b = c * a"
   362 proof
   363   assume "b = c * a"
   364   then show "b div a = c" by (simp add: assms)
   365 next
   366   assume "b div a = c"
   367   then have "b div a * a = c * a" by simp
   368   moreover from `a dvd b` have "b div a * a = b" by (simp add: dvd_div_mult_self)
   369   ultimately show "b = c * a" by simp
   370 qed
   371    
   372 lemma dvd_div_div_eq_mult:
   373   assumes "a \<noteq> 0" "c \<noteq> 0" and "a dvd b" "c dvd d"
   374   shows "b div a = d div c \<longleftrightarrow> b * c = a * d"
   375   using assms by (auto simp add: mult_commute [of _ a] dvd_div_mult_self dvd_div_eq_mult div_mult_swap intro: sym)
   376 
   377 end
   378 
   379 class ring_div = semiring_div + comm_ring_1
   380 begin
   381 
   382 subclass ring_1_no_zero_divisors ..
   383 
   384 text {* Negation respects modular equivalence. *}
   385 
   386 lemma mod_minus_eq: "(- a) mod b = (- (a mod b)) mod b"
   387 proof -
   388   have "(- a) mod b = (- (a div b * b + a mod b)) mod b"
   389     by (simp only: mod_div_equality)
   390   also have "\<dots> = (- (a mod b) + - (a div b) * b) mod b"
   391     by (simp only: minus_add_distrib minus_mult_left add_ac)
   392   also have "\<dots> = (- (a mod b)) mod b"
   393     by (rule mod_mult_self1)
   394   finally show ?thesis .
   395 qed
   396 
   397 lemma mod_minus_cong:
   398   assumes "a mod b = a' mod b"
   399   shows "(- a) mod b = (- a') mod b"
   400 proof -
   401   have "(- (a mod b)) mod b = (- (a' mod b)) mod b"
   402     unfolding assms ..
   403   thus ?thesis
   404     by (simp only: mod_minus_eq [symmetric])
   405 qed
   406 
   407 text {* Subtraction respects modular equivalence. *}
   408 
   409 lemma mod_diff_left_eq: "(a - b) mod c = (a mod c - b) mod c"
   410   unfolding diff_minus
   411   by (intro mod_add_cong mod_minus_cong) simp_all
   412 
   413 lemma mod_diff_right_eq: "(a - b) mod c = (a - b mod c) mod c"
   414   unfolding diff_minus
   415   by (intro mod_add_cong mod_minus_cong) simp_all
   416 
   417 lemma mod_diff_eq: "(a - b) mod c = (a mod c - b mod c) mod c"
   418   unfolding diff_minus
   419   by (intro mod_add_cong mod_minus_cong) simp_all
   420 
   421 lemma mod_diff_cong:
   422   assumes "a mod c = a' mod c"
   423   assumes "b mod c = b' mod c"
   424   shows "(a - b) mod c = (a' - b') mod c"
   425   unfolding diff_minus using assms
   426   by (intro mod_add_cong mod_minus_cong)
   427 
   428 lemma dvd_neg_div: "y dvd x \<Longrightarrow> -x div y = - (x div y)"
   429 apply (case_tac "y = 0") apply simp
   430 apply (auto simp add: dvd_def)
   431 apply (subgoal_tac "-(y * k) = y * - k")
   432  apply (erule ssubst)
   433  apply (erule div_mult_self1_is_id)
   434 apply simp
   435 done
   436 
   437 lemma dvd_div_neg: "y dvd x \<Longrightarrow> x div -y = - (x div y)"
   438 apply (case_tac "y = 0") apply simp
   439 apply (auto simp add: dvd_def)
   440 apply (subgoal_tac "y * k = -y * -k")
   441  apply (erule ssubst)
   442  apply (rule div_mult_self1_is_id)
   443  apply simp
   444 apply simp
   445 done
   446 
   447 end
   448 
   449 
   450 subsection {* Division on @{typ nat} *}
   451 
   452 text {*
   453   We define @{const div} and @{const mod} on @{typ nat} by means
   454   of a characteristic relation with two input arguments
   455   @{term "m\<Colon>nat"}, @{term "n\<Colon>nat"} and two output arguments
   456   @{term "q\<Colon>nat"}(uotient) and @{term "r\<Colon>nat"}(emainder).
   457 *}
   458 
   459 definition divmod_nat_rel :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat \<Rightarrow> bool" where
   460   "divmod_nat_rel m n qr \<longleftrightarrow>
   461     m = fst qr * n + snd qr \<and>
   462       (if n = 0 then fst qr = 0 else if n > 0 then 0 \<le> snd qr \<and> snd qr < n else n < snd qr \<and> snd qr \<le> 0)"
   463 
   464 text {* @{const divmod_nat_rel} is total: *}
   465 
   466 lemma divmod_nat_rel_ex:
   467   obtains q r where "divmod_nat_rel m n (q, r)"
   468 proof (cases "n = 0")
   469   case True  with that show thesis
   470     by (auto simp add: divmod_nat_rel_def)
   471 next
   472   case False
   473   have "\<exists>q r. m = q * n + r \<and> r < n"
   474   proof (induct m)
   475     case 0 with `n \<noteq> 0`
   476     have "(0\<Colon>nat) = 0 * n + 0 \<and> 0 < n" by simp
   477     then show ?case by blast
   478   next
   479     case (Suc m) then obtain q' r'
   480       where m: "m = q' * n + r'" and n: "r' < n" by auto
   481     then show ?case proof (cases "Suc r' < n")
   482       case True
   483       from m n have "Suc m = q' * n + Suc r'" by simp
   484       with True show ?thesis by blast
   485     next
   486       case False then have "n \<le> Suc r'" by auto
   487       moreover from n have "Suc r' \<le> n" by auto
   488       ultimately have "n = Suc r'" by auto
   489       with m have "Suc m = Suc q' * n + 0" by simp
   490       with `n \<noteq> 0` show ?thesis by blast
   491     qed
   492   qed
   493   with that show thesis
   494     using `n \<noteq> 0` by (auto simp add: divmod_nat_rel_def)
   495 qed
   496 
   497 text {* @{const divmod_nat_rel} is injective: *}
   498 
   499 lemma divmod_nat_rel_unique:
   500   assumes "divmod_nat_rel m n qr"
   501     and "divmod_nat_rel m n qr'"
   502   shows "qr = qr'"
   503 proof (cases "n = 0")
   504   case True with assms show ?thesis
   505     by (cases qr, cases qr')
   506       (simp add: divmod_nat_rel_def)
   507 next
   508   case False
   509   have aux: "\<And>q r q' r'. q' * n + r' = q * n + r \<Longrightarrow> r < n \<Longrightarrow> q' \<le> (q\<Colon>nat)"
   510   apply (rule leI)
   511   apply (subst less_iff_Suc_add)
   512   apply (auto simp add: add_mult_distrib)
   513   done
   514   from `n \<noteq> 0` assms have "fst qr = fst qr'"
   515     by (auto simp add: divmod_nat_rel_def intro: order_antisym dest: aux sym)
   516   moreover from this assms have "snd qr = snd qr'"
   517     by (simp add: divmod_nat_rel_def)
   518   ultimately show ?thesis by (cases qr, cases qr') simp
   519 qed
   520 
   521 text {*
   522   We instantiate divisibility on the natural numbers by
   523   means of @{const divmod_nat_rel}:
   524 *}
   525 
   526 definition divmod_nat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat" where
   527   "divmod_nat m n = (THE qr. divmod_nat_rel m n qr)"
   528 
   529 lemma divmod_nat_rel_divmod_nat:
   530   "divmod_nat_rel m n (divmod_nat m n)"
   531 proof -
   532   from divmod_nat_rel_ex
   533     obtain qr where rel: "divmod_nat_rel m n qr" .
   534   then show ?thesis
   535   by (auto simp add: divmod_nat_def intro: theI elim: divmod_nat_rel_unique)
   536 qed
   537 
   538 lemma divmod_nat_eq:
   539   assumes "divmod_nat_rel m n qr" 
   540   shows "divmod_nat m n = qr"
   541   using assms by (auto intro: divmod_nat_rel_unique divmod_nat_rel_divmod_nat)
   542 
   543 instantiation nat :: semiring_div
   544 begin
   545 
   546 definition div_nat where
   547   "m div n = fst (divmod_nat m n)"
   548 
   549 lemma fst_divmod_nat [simp]:
   550   "fst (divmod_nat m n) = m div n"
   551   by (simp add: div_nat_def)
   552 
   553 definition mod_nat where
   554   "m mod n = snd (divmod_nat m n)"
   555 
   556 lemma snd_divmod_nat [simp]:
   557   "snd (divmod_nat m n) = m mod n"
   558   by (simp add: mod_nat_def)
   559 
   560 lemma divmod_nat_div_mod:
   561   "divmod_nat m n = (m div n, m mod n)"
   562   by (simp add: prod_eq_iff)
   563 
   564 lemma div_eq:
   565   assumes "divmod_nat_rel m n (q, r)" 
   566   shows "m div n = q"
   567   using assms by (auto dest!: divmod_nat_eq simp add: prod_eq_iff)
   568 
   569 lemma mod_eq:
   570   assumes "divmod_nat_rel m n (q, r)" 
   571   shows "m mod n = r"
   572   using assms by (auto dest!: divmod_nat_eq simp add: prod_eq_iff)
   573 
   574 lemma divmod_nat_rel: "divmod_nat_rel m n (m div n, m mod n)"
   575   using divmod_nat_rel_divmod_nat by (simp add: divmod_nat_div_mod)
   576 
   577 lemma divmod_nat_zero:
   578   "divmod_nat m 0 = (0, m)"
   579 proof -
   580   from divmod_nat_rel [of m 0] show ?thesis
   581     unfolding divmod_nat_div_mod divmod_nat_rel_def by simp
   582 qed
   583 
   584 lemma divmod_nat_base:
   585   assumes "m < n"
   586   shows "divmod_nat m n = (0, m)"
   587 proof -
   588   from divmod_nat_rel [of m n] show ?thesis
   589     unfolding divmod_nat_div_mod divmod_nat_rel_def
   590     using assms by (cases "m div n = 0")
   591       (auto simp add: gr0_conv_Suc [of "m div n"])
   592 qed
   593 
   594 lemma divmod_nat_step:
   595   assumes "0 < n" and "n \<le> m"
   596   shows "divmod_nat m n = (Suc ((m - n) div n), (m - n) mod n)"
   597 proof -
   598   from divmod_nat_rel have divmod_nat_m_n: "divmod_nat_rel m n (m div n, m mod n)" .
   599   with assms have m_div_n: "m div n \<ge> 1"
   600     by (cases "m div n") (auto simp add: divmod_nat_rel_def)
   601   have "divmod_nat_rel (m - n) n (m div n - Suc 0, m mod n)"
   602   proof -
   603     from assms have
   604       "n \<noteq> 0"
   605       "\<And>k. m = Suc k * n + m mod n ==> m - n = (Suc k - Suc 0) * n + m mod n"
   606       by simp_all
   607     then show ?thesis using assms divmod_nat_m_n 
   608       by (cases "m div n")
   609          (simp_all only: divmod_nat_rel_def fst_conv snd_conv, simp_all)
   610   qed
   611   with divmod_nat_eq have "divmod_nat (m - n) n = (m div n - Suc 0, m mod n)" by simp
   612   moreover from divmod_nat_div_mod have "divmod_nat (m - n) n = ((m - n) div n, (m - n) mod n)" .
   613   ultimately have "m div n = Suc ((m - n) div n)"
   614     and "m mod n = (m - n) mod n" using m_div_n by simp_all
   615   then show ?thesis using divmod_nat_div_mod by simp
   616 qed
   617 
   618 text {* The ''recursion'' equations for @{const div} and @{const mod} *}
   619 
   620 lemma div_less [simp]:
   621   fixes m n :: nat
   622   assumes "m < n"
   623   shows "m div n = 0"
   624   using assms divmod_nat_base by (simp add: prod_eq_iff)
   625 
   626 lemma le_div_geq:
   627   fixes m n :: nat
   628   assumes "0 < n" and "n \<le> m"
   629   shows "m div n = Suc ((m - n) div n)"
   630   using assms divmod_nat_step by (simp add: prod_eq_iff)
   631 
   632 lemma mod_less [simp]:
   633   fixes m n :: nat
   634   assumes "m < n"
   635   shows "m mod n = m"
   636   using assms divmod_nat_base by (simp add: prod_eq_iff)
   637 
   638 lemma le_mod_geq:
   639   fixes m n :: nat
   640   assumes "n \<le> m"
   641   shows "m mod n = (m - n) mod n"
   642   using assms divmod_nat_step by (cases "n = 0") (simp_all add: prod_eq_iff)
   643 
   644 instance proof -
   645   have [simp]: "\<And>n::nat. n div 0 = 0"
   646     by (simp add: div_nat_def divmod_nat_zero)
   647   have [simp]: "\<And>n::nat. 0 div n = 0"
   648   proof -
   649     fix n :: nat
   650     show "0 div n = 0"
   651       by (cases "n = 0") simp_all
   652   qed
   653   show "OFCLASS(nat, semiring_div_class)" proof
   654     fix m n :: nat
   655     show "m div n * n + m mod n = m"
   656       using divmod_nat_rel [of m n] by (simp add: divmod_nat_rel_def)
   657   next
   658     fix m n q :: nat
   659     assume "n \<noteq> 0"
   660     then show "(q + m * n) div n = m + q div n"
   661       by (induct m) (simp_all add: le_div_geq)
   662   next
   663     fix m n q :: nat
   664     assume "m \<noteq> 0"
   665     then show "(m * n) div (m * q) = n div q"
   666     proof (cases "n \<noteq> 0 \<and> q \<noteq> 0")
   667       case False then show ?thesis by auto
   668     next
   669       case True with `m \<noteq> 0`
   670         have "m > 0" and "n > 0" and "q > 0" by auto
   671       then have "\<And>a b. divmod_nat_rel n q (a, b) \<Longrightarrow> divmod_nat_rel (m * n) (m * q) (a, m * b)"
   672         by (auto simp add: divmod_nat_rel_def) (simp_all add: algebra_simps)
   673       moreover from divmod_nat_rel have "divmod_nat_rel n q (n div q, n mod q)" .
   674       ultimately have "divmod_nat_rel (m * n) (m * q) (n div q, m * (n mod q))" .
   675       then show ?thesis by (simp add: div_eq)
   676     qed
   677   qed simp_all
   678 qed
   679 
   680 end
   681 
   682 lemma divmod_nat_if [code]: "divmod_nat m n = (if n = 0 \<or> m < n then (0, m) else
   683   let (q, r) = divmod_nat (m - n) n in (Suc q, r))"
   684   by (simp add: prod_eq_iff prod_case_beta not_less le_div_geq le_mod_geq)
   685 
   686 text {* Simproc for cancelling @{const div} and @{const mod} *}
   687 
   688 ML {*
   689 structure Cancel_Div_Mod_Nat = Cancel_Div_Mod
   690 (
   691   val div_name = @{const_name div};
   692   val mod_name = @{const_name mod};
   693   val mk_binop = HOLogic.mk_binop;
   694   val mk_sum = Nat_Arith.mk_sum;
   695   val dest_sum = Nat_Arith.dest_sum;
   696 
   697   val div_mod_eqs = map mk_meta_eq [@{thm div_mod_equality}, @{thm div_mod_equality2}];
   698 
   699   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac
   700     (@{thm add_0_left} :: @{thm add_0_right} :: @{thms add_ac}))
   701 )
   702 *}
   703 
   704 simproc_setup cancel_div_mod_nat ("(m::nat) + n") = {* K Cancel_Div_Mod_Nat.proc *}
   705 
   706 
   707 subsubsection {* Quotient *}
   708 
   709 lemma div_geq: "0 < n \<Longrightarrow>  \<not> m < n \<Longrightarrow> m div n = Suc ((m - n) div n)"
   710 by (simp add: le_div_geq linorder_not_less)
   711 
   712 lemma div_if: "0 < n \<Longrightarrow> m div n = (if m < n then 0 else Suc ((m - n) div n))"
   713 by (simp add: div_geq)
   714 
   715 lemma div_mult_self_is_m [simp]: "0<n ==> (m*n) div n = (m::nat)"
   716 by simp
   717 
   718 lemma div_mult_self1_is_m [simp]: "0<n ==> (n*m) div n = (m::nat)"
   719 by simp
   720 
   721 
   722 subsubsection {* Remainder *}
   723 
   724 lemma mod_less_divisor [simp]:
   725   fixes m n :: nat
   726   assumes "n > 0"
   727   shows "m mod n < (n::nat)"
   728   using assms divmod_nat_rel [of m n] unfolding divmod_nat_rel_def by auto
   729 
   730 lemma mod_less_eq_dividend [simp]:
   731   fixes m n :: nat
   732   shows "m mod n \<le> m"
   733 proof (rule add_leD2)
   734   from mod_div_equality have "m div n * n + m mod n = m" .
   735   then show "m div n * n + m mod n \<le> m" by auto
   736 qed
   737 
   738 lemma mod_geq: "\<not> m < (n\<Colon>nat) \<Longrightarrow> m mod n = (m - n) mod n"
   739 by (simp add: le_mod_geq linorder_not_less)
   740 
   741 lemma mod_if: "m mod (n\<Colon>nat) = (if m < n then m else (m - n) mod n)"
   742 by (simp add: le_mod_geq)
   743 
   744 lemma mod_1 [simp]: "m mod Suc 0 = 0"
   745 by (induct m) (simp_all add: mod_geq)
   746 
   747 lemma mod_mult_distrib: "(m mod n) * (k\<Colon>nat) = (m * k) mod (n * k)"
   748   apply (cases "n = 0", simp)
   749   apply (cases "k = 0", simp)
   750   apply (induct m rule: nat_less_induct)
   751   apply (subst mod_if, simp)
   752   apply (simp add: mod_geq diff_mult_distrib)
   753   done
   754 
   755 lemma mod_mult_distrib2: "(k::nat) * (m mod n) = (k*m) mod (k*n)"
   756 by (simp add: mult_commute [of k] mod_mult_distrib)
   757 
   758 (* a simple rearrangement of mod_div_equality: *)
   759 lemma mult_div_cancel: "(n::nat) * (m div n) = m - (m mod n)"
   760 by (cut_tac a = m and b = n in mod_div_equality2, arith)
   761 
   762 lemma mod_le_divisor[simp]: "0 < n \<Longrightarrow> m mod n \<le> (n::nat)"
   763   apply (drule mod_less_divisor [where m = m])
   764   apply simp
   765   done
   766 
   767 subsubsection {* Quotient and Remainder *}
   768 
   769 lemma divmod_nat_rel_mult1_eq:
   770   "divmod_nat_rel b c (q, r)
   771    \<Longrightarrow> divmod_nat_rel (a * b) c (a * q + a * r div c, a * r mod c)"
   772 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   773 
   774 lemma div_mult1_eq:
   775   "(a * b) div c = a * (b div c) + a * (b mod c) div (c::nat)"
   776 by (blast intro: divmod_nat_rel [THEN divmod_nat_rel_mult1_eq, THEN div_eq])
   777 
   778 lemma divmod_nat_rel_add1_eq:
   779   "divmod_nat_rel a c (aq, ar) \<Longrightarrow> divmod_nat_rel b c (bq, br)
   780    \<Longrightarrow> divmod_nat_rel (a + b) c (aq + bq + (ar + br) div c, (ar + br) mod c)"
   781 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   782 
   783 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
   784 lemma div_add1_eq:
   785   "(a+b) div (c::nat) = a div c + b div c + ((a mod c + b mod c) div c)"
   786 by (blast intro: divmod_nat_rel_add1_eq [THEN div_eq] divmod_nat_rel)
   787 
   788 lemma mod_lemma: "[| (0::nat) < c; r < b |] ==> b * (q mod c) + r < b * c"
   789   apply (cut_tac m = q and n = c in mod_less_divisor)
   790   apply (drule_tac [2] m = "q mod c" in less_imp_Suc_add, auto)
   791   apply (erule_tac P = "%x. ?lhs < ?rhs x" in ssubst)
   792   apply (simp add: add_mult_distrib2)
   793   done
   794 
   795 lemma divmod_nat_rel_mult2_eq:
   796   "divmod_nat_rel a b (q, r)
   797    \<Longrightarrow> divmod_nat_rel a (b * c) (q div c, b *(q mod c) + r)"
   798 by (auto simp add: mult_ac divmod_nat_rel_def add_mult_distrib2 [symmetric] mod_lemma)
   799 
   800 lemma div_mult2_eq: "a div (b*c) = (a div b) div (c::nat)"
   801 by (force simp add: divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN div_eq])
   802 
   803 lemma mod_mult2_eq: "a mod (b*c) = b*(a div b mod c) + a mod (b::nat)"
   804 by (auto simp add: mult_commute divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN mod_eq])
   805 
   806 
   807 subsubsection {* Further Facts about Quotient and Remainder *}
   808 
   809 lemma div_1 [simp]: "m div Suc 0 = m"
   810 by (induct m) (simp_all add: div_geq)
   811 
   812 (* Monotonicity of div in first argument *)
   813 lemma div_le_mono [rule_format (no_asm)]:
   814     "\<forall>m::nat. m \<le> n --> (m div k) \<le> (n div k)"
   815 apply (case_tac "k=0", simp)
   816 apply (induct "n" rule: nat_less_induct, clarify)
   817 apply (case_tac "n<k")
   818 (* 1  case n<k *)
   819 apply simp
   820 (* 2  case n >= k *)
   821 apply (case_tac "m<k")
   822 (* 2.1  case m<k *)
   823 apply simp
   824 (* 2.2  case m>=k *)
   825 apply (simp add: div_geq diff_le_mono)
   826 done
   827 
   828 (* Antimonotonicity of div in second argument *)
   829 lemma div_le_mono2: "!!m::nat. [| 0<m; m\<le>n |] ==> (k div n) \<le> (k div m)"
   830 apply (subgoal_tac "0<n")
   831  prefer 2 apply simp
   832 apply (induct_tac k rule: nat_less_induct)
   833 apply (rename_tac "k")
   834 apply (case_tac "k<n", simp)
   835 apply (subgoal_tac "~ (k<m) ")
   836  prefer 2 apply simp
   837 apply (simp add: div_geq)
   838 apply (subgoal_tac "(k-n) div n \<le> (k-m) div n")
   839  prefer 2
   840  apply (blast intro: div_le_mono diff_le_mono2)
   841 apply (rule le_trans, simp)
   842 apply (simp)
   843 done
   844 
   845 lemma div_le_dividend [simp]: "m div n \<le> (m::nat)"
   846 apply (case_tac "n=0", simp)
   847 apply (subgoal_tac "m div n \<le> m div 1", simp)
   848 apply (rule div_le_mono2)
   849 apply (simp_all (no_asm_simp))
   850 done
   851 
   852 (* Similar for "less than" *)
   853 lemma div_less_dividend [rule_format]:
   854      "!!n::nat. 1<n ==> 0 < m --> m div n < m"
   855 apply (induct_tac m rule: nat_less_induct)
   856 apply (rename_tac "m")
   857 apply (case_tac "m<n", simp)
   858 apply (subgoal_tac "0<n")
   859  prefer 2 apply simp
   860 apply (simp add: div_geq)
   861 apply (case_tac "n<m")
   862  apply (subgoal_tac "(m-n) div n < (m-n) ")
   863   apply (rule impI less_trans_Suc)+
   864 apply assumption
   865   apply (simp_all)
   866 done
   867 
   868 declare div_less_dividend [simp]
   869 
   870 text{*A fact for the mutilated chess board*}
   871 lemma mod_Suc: "Suc(m) mod n = (if Suc(m mod n) = n then 0 else Suc(m mod n))"
   872 apply (case_tac "n=0", simp)
   873 apply (induct "m" rule: nat_less_induct)
   874 apply (case_tac "Suc (na) <n")
   875 (* case Suc(na) < n *)
   876 apply (frule lessI [THEN less_trans], simp add: less_not_refl3)
   877 (* case n \<le> Suc(na) *)
   878 apply (simp add: linorder_not_less le_Suc_eq mod_geq)
   879 apply (auto simp add: Suc_diff_le le_mod_geq)
   880 done
   881 
   882 lemma mod_eq_0_iff: "(m mod d = 0) = (\<exists>q::nat. m = d*q)"
   883 by (auto simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
   884 
   885 lemmas mod_eq_0D [dest!] = mod_eq_0_iff [THEN iffD1]
   886 
   887 (*Loses information, namely we also have r<d provided d is nonzero*)
   888 lemma mod_eqD: "(m mod d = r) ==> \<exists>q::nat. m = r + q*d"
   889   apply (cut_tac a = m in mod_div_equality)
   890   apply (simp only: add_ac)
   891   apply (blast intro: sym)
   892   done
   893 
   894 lemma split_div:
   895  "P(n div k :: nat) =
   896  ((k = 0 \<longrightarrow> P 0) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P i)))"
   897  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   898 proof
   899   assume P: ?P
   900   show ?Q
   901   proof (cases)
   902     assume "k = 0"
   903     with P show ?Q by simp
   904   next
   905     assume not0: "k \<noteq> 0"
   906     thus ?Q
   907     proof (simp, intro allI impI)
   908       fix i j
   909       assume n: "n = k*i + j" and j: "j < k"
   910       show "P i"
   911       proof (cases)
   912         assume "i = 0"
   913         with n j P show "P i" by simp
   914       next
   915         assume "i \<noteq> 0"
   916         with not0 n j P show "P i" by(simp add:add_ac)
   917       qed
   918     qed
   919   qed
   920 next
   921   assume Q: ?Q
   922   show ?P
   923   proof (cases)
   924     assume "k = 0"
   925     with Q show ?P by simp
   926   next
   927     assume not0: "k \<noteq> 0"
   928     with Q have R: ?R by simp
   929     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   930     show ?P by simp
   931   qed
   932 qed
   933 
   934 lemma split_div_lemma:
   935   assumes "0 < n"
   936   shows "n * q \<le> m \<and> m < n * Suc q \<longleftrightarrow> q = ((m\<Colon>nat) div n)" (is "?lhs \<longleftrightarrow> ?rhs")
   937 proof
   938   assume ?rhs
   939   with mult_div_cancel have nq: "n * q = m - (m mod n)" by simp
   940   then have A: "n * q \<le> m" by simp
   941   have "n - (m mod n) > 0" using mod_less_divisor assms by auto
   942   then have "m < m + (n - (m mod n))" by simp
   943   then have "m < n + (m - (m mod n))" by simp
   944   with nq have "m < n + n * q" by simp
   945   then have B: "m < n * Suc q" by simp
   946   from A B show ?lhs ..
   947 next
   948   assume P: ?lhs
   949   then have "divmod_nat_rel m n (q, m - n * q)"
   950     unfolding divmod_nat_rel_def by (auto simp add: mult_ac)
   951   with divmod_nat_rel_unique divmod_nat_rel [of m n]
   952   have "(q, m - n * q) = (m div n, m mod n)" by auto
   953   then show ?rhs by simp
   954 qed
   955 
   956 theorem split_div':
   957   "P ((m::nat) div n) = ((n = 0 \<and> P 0) \<or>
   958    (\<exists>q. (n * q \<le> m \<and> m < n * (Suc q)) \<and> P q))"
   959   apply (case_tac "0 < n")
   960   apply (simp only: add: split_div_lemma)
   961   apply simp_all
   962   done
   963 
   964 lemma split_mod:
   965  "P(n mod k :: nat) =
   966  ((k = 0 \<longrightarrow> P n) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P j)))"
   967  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   968 proof
   969   assume P: ?P
   970   show ?Q
   971   proof (cases)
   972     assume "k = 0"
   973     with P show ?Q by simp
   974   next
   975     assume not0: "k \<noteq> 0"
   976     thus ?Q
   977     proof (simp, intro allI impI)
   978       fix i j
   979       assume "n = k*i + j" "j < k"
   980       thus "P j" using not0 P by(simp add:add_ac mult_ac)
   981     qed
   982   qed
   983 next
   984   assume Q: ?Q
   985   show ?P
   986   proof (cases)
   987     assume "k = 0"
   988     with Q show ?P by simp
   989   next
   990     assume not0: "k \<noteq> 0"
   991     with Q have R: ?R by simp
   992     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   993     show ?P by simp
   994   qed
   995 qed
   996 
   997 theorem mod_div_equality': "(m::nat) mod n = m - (m div n) * n"
   998   apply (rule_tac P="%x. m mod n = x - (m div n) * n" in
   999     subst [OF mod_div_equality [of _ n]])
  1000   apply arith
  1001   done
  1002 
  1003 lemma div_mod_equality':
  1004   fixes m n :: nat
  1005   shows "m div n * n = m - m mod n"
  1006 proof -
  1007   have "m mod n \<le> m mod n" ..
  1008   from div_mod_equality have 
  1009     "m div n * n + m mod n - m mod n = m - m mod n" by simp
  1010   with diff_add_assoc [OF `m mod n \<le> m mod n`, of "m div n * n"] have
  1011     "m div n * n + (m mod n - m mod n) = m - m mod n"
  1012     by simp
  1013   then show ?thesis by simp
  1014 qed
  1015 
  1016 
  1017 subsubsection {* An ``induction'' law for modulus arithmetic. *}
  1018 
  1019 lemma mod_induct_0:
  1020   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
  1021   and base: "P i" and i: "i<p"
  1022   shows "P 0"
  1023 proof (rule ccontr)
  1024   assume contra: "\<not>(P 0)"
  1025   from i have p: "0<p" by simp
  1026   have "\<forall>k. 0<k \<longrightarrow> \<not> P (p-k)" (is "\<forall>k. ?A k")
  1027   proof
  1028     fix k
  1029     show "?A k"
  1030     proof (induct k)
  1031       show "?A 0" by simp  -- "by contradiction"
  1032     next
  1033       fix n
  1034       assume ih: "?A n"
  1035       show "?A (Suc n)"
  1036       proof (clarsimp)
  1037         assume y: "P (p - Suc n)"
  1038         have n: "Suc n < p"
  1039         proof (rule ccontr)
  1040           assume "\<not>(Suc n < p)"
  1041           hence "p - Suc n = 0"
  1042             by simp
  1043           with y contra show "False"
  1044             by simp
  1045         qed
  1046         hence n2: "Suc (p - Suc n) = p-n" by arith
  1047         from p have "p - Suc n < p" by arith
  1048         with y step have z: "P ((Suc (p - Suc n)) mod p)"
  1049           by blast
  1050         show "False"
  1051         proof (cases "n=0")
  1052           case True
  1053           with z n2 contra show ?thesis by simp
  1054         next
  1055           case False
  1056           with p have "p-n < p" by arith
  1057           with z n2 False ih show ?thesis by simp
  1058         qed
  1059       qed
  1060     qed
  1061   qed
  1062   moreover
  1063   from i obtain k where "0<k \<and> i+k=p"
  1064     by (blast dest: less_imp_add_positive)
  1065   hence "0<k \<and> i=p-k" by auto
  1066   moreover
  1067   note base
  1068   ultimately
  1069   show "False" by blast
  1070 qed
  1071 
  1072 lemma mod_induct:
  1073   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
  1074   and base: "P i" and i: "i<p" and j: "j<p"
  1075   shows "P j"
  1076 proof -
  1077   have "\<forall>j<p. P j"
  1078   proof
  1079     fix j
  1080     show "j<p \<longrightarrow> P j" (is "?A j")
  1081     proof (induct j)
  1082       from step base i show "?A 0"
  1083         by (auto elim: mod_induct_0)
  1084     next
  1085       fix k
  1086       assume ih: "?A k"
  1087       show "?A (Suc k)"
  1088       proof
  1089         assume suc: "Suc k < p"
  1090         hence k: "k<p" by simp
  1091         with ih have "P k" ..
  1092         with step k have "P (Suc k mod p)"
  1093           by blast
  1094         moreover
  1095         from suc have "Suc k mod p = Suc k"
  1096           by simp
  1097         ultimately
  1098         show "P (Suc k)" by simp
  1099       qed
  1100     qed
  1101   qed
  1102   with j show ?thesis by blast
  1103 qed
  1104 
  1105 lemma div2_Suc_Suc [simp]: "Suc (Suc m) div 2 = Suc (m div 2)"
  1106 by (auto simp add: numeral_2_eq_2 le_div_geq)
  1107 
  1108 lemma add_self_div_2 [simp]: "(m + m) div 2 = (m::nat)"
  1109 by (simp add: nat_mult_2 [symmetric])
  1110 
  1111 lemma mod2_Suc_Suc [simp]: "Suc(Suc(m)) mod 2 = m mod 2"
  1112 apply (subgoal_tac "m mod 2 < 2")
  1113 apply (erule less_2_cases [THEN disjE])
  1114 apply (simp_all (no_asm_simp) add: Let_def mod_Suc)
  1115 done
  1116 
  1117 lemma mod2_gr_0 [simp]: "0 < (m\<Colon>nat) mod 2 \<longleftrightarrow> m mod 2 = 1"
  1118 proof -
  1119   { fix n :: nat have  "(n::nat) < 2 \<Longrightarrow> n = 0 \<or> n = 1" by (cases n) simp_all }
  1120   moreover have "m mod 2 < 2" by simp
  1121   ultimately have "m mod 2 = 0 \<or> m mod 2 = 1" .
  1122   then show ?thesis by auto
  1123 qed
  1124 
  1125 text{*These lemmas collapse some needless occurrences of Suc:
  1126     at least three Sucs, since two and fewer are rewritten back to Suc again!
  1127     We already have some rules to simplify operands smaller than 3.*}
  1128 
  1129 lemma div_Suc_eq_div_add3 [simp]: "m div (Suc (Suc (Suc n))) = m div (3+n)"
  1130 by (simp add: Suc3_eq_add_3)
  1131 
  1132 lemma mod_Suc_eq_mod_add3 [simp]: "m mod (Suc (Suc (Suc n))) = m mod (3+n)"
  1133 by (simp add: Suc3_eq_add_3)
  1134 
  1135 lemma Suc_div_eq_add3_div: "(Suc (Suc (Suc m))) div n = (3+m) div n"
  1136 by (simp add: Suc3_eq_add_3)
  1137 
  1138 lemma Suc_mod_eq_add3_mod: "(Suc (Suc (Suc m))) mod n = (3+m) mod n"
  1139 by (simp add: Suc3_eq_add_3)
  1140 
  1141 lemmas Suc_div_eq_add3_div_number_of [simp] = Suc_div_eq_add3_div [of _ "number_of v"] for v
  1142 lemmas Suc_mod_eq_add3_mod_number_of [simp] = Suc_mod_eq_add3_mod [of _ "number_of v"] for v
  1143 
  1144 
  1145 lemma Suc_times_mod_eq: "1<k ==> Suc (k * m) mod k = 1" 
  1146 apply (induct "m")
  1147 apply (simp_all add: mod_Suc)
  1148 done
  1149 
  1150 declare Suc_times_mod_eq [of "number_of w", simp] for w
  1151 
  1152 lemma [simp]: "n div k \<le> (Suc n) div k"
  1153 by (simp add: div_le_mono) 
  1154 
  1155 lemma Suc_n_div_2_gt_zero [simp]: "(0::nat) < n ==> 0 < (n + 1) div 2"
  1156 by (cases n) simp_all
  1157 
  1158 lemma div_2_gt_zero [simp]: assumes A: "(1::nat) < n" shows "0 < n div 2"
  1159 proof -
  1160   from A have B: "0 < n - 1" and C: "n - 1 + 1 = n" by simp_all
  1161   from Suc_n_div_2_gt_zero [OF B] C show ?thesis by simp 
  1162 qed
  1163 
  1164   (* Potential use of algebra : Equality modulo n*)
  1165 lemma mod_mult_self3 [simp]: "(k*n + m) mod n = m mod (n::nat)"
  1166 by (simp add: mult_ac add_ac)
  1167 
  1168 lemma mod_mult_self4 [simp]: "Suc (k*n + m) mod n = Suc m mod n"
  1169 proof -
  1170   have "Suc (k * n + m) mod n = (k * n + Suc m) mod n" by simp
  1171   also have "... = Suc m mod n" by (rule mod_mult_self3) 
  1172   finally show ?thesis .
  1173 qed
  1174 
  1175 lemma mod_Suc_eq_Suc_mod: "Suc m mod n = Suc (m mod n) mod n"
  1176 apply (subst mod_Suc [of m]) 
  1177 apply (subst mod_Suc [of "m mod n"], simp) 
  1178 done
  1179 
  1180 
  1181 subsection {* Division on @{typ int} *}
  1182 
  1183 definition divmod_int_rel :: "int \<Rightarrow> int \<Rightarrow> int \<times> int \<Rightarrow> bool" where
  1184     --{*definition of quotient and remainder*}
  1185     [code]: "divmod_int_rel a b = (\<lambda>(q, r). a = b * q + r \<and>
  1186                (if 0 < b then 0 \<le> r \<and> r < b else b < r \<and> r \<le> 0))"
  1187 
  1188 definition adjust :: "int \<Rightarrow> int \<times> int \<Rightarrow> int \<times> int" where
  1189     --{*for the division algorithm*}
  1190     [code]: "adjust b = (\<lambda>(q, r). if 0 \<le> r - b then (2 * q + 1, r - b)
  1191                          else (2 * q, r))"
  1192 
  1193 text{*algorithm for the case @{text "a\<ge>0, b>0"}*}
  1194 function posDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1195   "posDivAlg a b = (if a < b \<or>  b \<le> 0 then (0, a)
  1196      else adjust b (posDivAlg a (2 * b)))"
  1197 by auto
  1198 termination by (relation "measure (\<lambda>(a, b). nat (a - b + 1))")
  1199   (auto simp add: mult_2)
  1200 
  1201 text{*algorithm for the case @{text "a<0, b>0"}*}
  1202 function negDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1203   "negDivAlg a b = (if 0 \<le>a + b \<or> b \<le> 0  then (-1, a + b)
  1204      else adjust b (negDivAlg a (2 * b)))"
  1205 by auto
  1206 termination by (relation "measure (\<lambda>(a, b). nat (- a - b))")
  1207   (auto simp add: mult_2)
  1208 
  1209 text{*algorithm for the general case @{term "b\<noteq>0"}*}
  1210 definition negateSnd :: "int \<times> int \<Rightarrow> int \<times> int" where
  1211   [code_unfold]: "negateSnd = apsnd uminus"
  1212 
  1213 definition divmod_int :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1214     --{*The full division algorithm considers all possible signs for a, b
  1215        including the special case @{text "a=0, b<0"} because 
  1216        @{term negDivAlg} requires @{term "a<0"}.*}
  1217   "divmod_int a b = (if 0 \<le> a then if 0 \<le> b then posDivAlg a b
  1218                   else if a = 0 then (0, 0)
  1219                        else negateSnd (negDivAlg (-a) (-b))
  1220                else 
  1221                   if 0 < b then negDivAlg a b
  1222                   else negateSnd (posDivAlg (-a) (-b)))"
  1223 
  1224 instantiation int :: Divides.div
  1225 begin
  1226 
  1227 definition div_int where
  1228   "a div b = fst (divmod_int a b)"
  1229 
  1230 lemma fst_divmod_int [simp]:
  1231   "fst (divmod_int a b) = a div b"
  1232   by (simp add: div_int_def)
  1233 
  1234 definition mod_int where
  1235  "a mod b = snd (divmod_int a b)"
  1236 
  1237 lemma snd_divmod_int [simp]:
  1238   "snd (divmod_int a b) = a mod b"
  1239   by (simp add: mod_int_def)
  1240 
  1241 instance ..
  1242 
  1243 end
  1244 
  1245 lemma divmod_int_mod_div:
  1246   "divmod_int p q = (p div q, p mod q)"
  1247   by (simp add: prod_eq_iff)
  1248 
  1249 text{*
  1250 Here is the division algorithm in ML:
  1251 
  1252 \begin{verbatim}
  1253     fun posDivAlg (a,b) =
  1254       if a<b then (0,a)
  1255       else let val (q,r) = posDivAlg(a, 2*b)
  1256                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1257            end
  1258 
  1259     fun negDivAlg (a,b) =
  1260       if 0\<le>a+b then (~1,a+b)
  1261       else let val (q,r) = negDivAlg(a, 2*b)
  1262                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1263            end;
  1264 
  1265     fun negateSnd (q,r:int) = (q,~r);
  1266 
  1267     fun divmod (a,b) = if 0\<le>a then 
  1268                           if b>0 then posDivAlg (a,b) 
  1269                            else if a=0 then (0,0)
  1270                                 else negateSnd (negDivAlg (~a,~b))
  1271                        else 
  1272                           if 0<b then negDivAlg (a,b)
  1273                           else        negateSnd (posDivAlg (~a,~b));
  1274 \end{verbatim}
  1275 *}
  1276 
  1277 
  1278 subsubsection {* Uniqueness and Monotonicity of Quotients and Remainders *}
  1279 
  1280 lemma unique_quotient_lemma:
  1281      "[| b*q' + r'  \<le> b*q + r;  0 \<le> r';  r' < b;  r < b |]  
  1282       ==> q' \<le> (q::int)"
  1283 apply (subgoal_tac "r' + b * (q'-q) \<le> r")
  1284  prefer 2 apply (simp add: right_diff_distrib)
  1285 apply (subgoal_tac "0 < b * (1 + q - q') ")
  1286 apply (erule_tac [2] order_le_less_trans)
  1287  prefer 2 apply (simp add: right_diff_distrib right_distrib)
  1288 apply (subgoal_tac "b * q' < b * (1 + q) ")
  1289  prefer 2 apply (simp add: right_diff_distrib right_distrib)
  1290 apply (simp add: mult_less_cancel_left)
  1291 done
  1292 
  1293 lemma unique_quotient_lemma_neg:
  1294      "[| b*q' + r' \<le> b*q + r;  r \<le> 0;  b < r;  b < r' |]  
  1295       ==> q \<le> (q'::int)"
  1296 by (rule_tac b = "-b" and r = "-r'" and r' = "-r" in unique_quotient_lemma, 
  1297     auto)
  1298 
  1299 lemma unique_quotient:
  1300      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r') |]  
  1301       ==> q = q'"
  1302 apply (simp add: divmod_int_rel_def linorder_neq_iff split: split_if_asm)
  1303 apply (blast intro: order_antisym
  1304              dest: order_eq_refl [THEN unique_quotient_lemma] 
  1305              order_eq_refl [THEN unique_quotient_lemma_neg] sym)+
  1306 done
  1307 
  1308 
  1309 lemma unique_remainder:
  1310      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r') |]  
  1311       ==> r = r'"
  1312 apply (subgoal_tac "q = q'")
  1313  apply (simp add: divmod_int_rel_def)
  1314 apply (blast intro: unique_quotient)
  1315 done
  1316 
  1317 
  1318 subsubsection {* Correctness of @{term posDivAlg}, the Algorithm for Non-Negative Dividends *}
  1319 
  1320 text{*And positive divisors*}
  1321 
  1322 lemma adjust_eq [simp]:
  1323      "adjust b (q,r) = 
  1324       (let diff = r-b in  
  1325         if 0 \<le> diff then (2*q + 1, diff)   
  1326                      else (2*q, r))"
  1327 by (simp add: Let_def adjust_def)
  1328 
  1329 declare posDivAlg.simps [simp del]
  1330 
  1331 text{*use with a simproc to avoid repeatedly proving the premise*}
  1332 lemma posDivAlg_eqn:
  1333      "0 < b ==>  
  1334       posDivAlg a b = (if a<b then (0,a) else adjust b (posDivAlg a (2*b)))"
  1335 by (rule posDivAlg.simps [THEN trans], simp)
  1336 
  1337 text{*Correctness of @{term posDivAlg}: it computes quotients correctly*}
  1338 theorem posDivAlg_correct:
  1339   assumes "0 \<le> a" and "0 < b"
  1340   shows "divmod_int_rel a b (posDivAlg a b)"
  1341   using assms
  1342   apply (induct a b rule: posDivAlg.induct)
  1343   apply auto
  1344   apply (simp add: divmod_int_rel_def)
  1345   apply (subst posDivAlg_eqn, simp add: right_distrib)
  1346   apply (case_tac "a < b")
  1347   apply simp_all
  1348   apply (erule splitE)
  1349   apply (auto simp add: right_distrib Let_def mult_ac mult_2_right)
  1350   done
  1351 
  1352 
  1353 subsubsection {* Correctness of @{term negDivAlg}, the Algorithm for Negative Dividends *}
  1354 
  1355 text{*And positive divisors*}
  1356 
  1357 declare negDivAlg.simps [simp del]
  1358 
  1359 text{*use with a simproc to avoid repeatedly proving the premise*}
  1360 lemma negDivAlg_eqn:
  1361      "0 < b ==>  
  1362       negDivAlg a b =       
  1363        (if 0\<le>a+b then (-1,a+b) else adjust b (negDivAlg a (2*b)))"
  1364 by (rule negDivAlg.simps [THEN trans], simp)
  1365 
  1366 (*Correctness of negDivAlg: it computes quotients correctly
  1367   It doesn't work if a=0 because the 0/b equals 0, not -1*)
  1368 lemma negDivAlg_correct:
  1369   assumes "a < 0" and "b > 0"
  1370   shows "divmod_int_rel a b (negDivAlg a b)"
  1371   using assms
  1372   apply (induct a b rule: negDivAlg.induct)
  1373   apply (auto simp add: linorder_not_le)
  1374   apply (simp add: divmod_int_rel_def)
  1375   apply (subst negDivAlg_eqn, assumption)
  1376   apply (case_tac "a + b < (0\<Colon>int)")
  1377   apply simp_all
  1378   apply (erule splitE)
  1379   apply (auto simp add: right_distrib Let_def mult_ac mult_2_right)
  1380   done
  1381 
  1382 
  1383 subsubsection {* Existence Shown by Proving the Division Algorithm to be Correct *}
  1384 
  1385 (*the case a=0*)
  1386 lemma divmod_int_rel_0: "b \<noteq> 0 ==> divmod_int_rel 0 b (0, 0)"
  1387 by (auto simp add: divmod_int_rel_def linorder_neq_iff)
  1388 
  1389 lemma posDivAlg_0 [simp]: "posDivAlg 0 b = (0, 0)"
  1390 by (subst posDivAlg.simps, auto)
  1391 
  1392 lemma negDivAlg_minus1 [simp]: "negDivAlg -1 b = (-1, b - 1)"
  1393 by (subst negDivAlg.simps, auto)
  1394 
  1395 lemma negateSnd_eq [simp]: "negateSnd(q,r) = (q,-r)"
  1396 by (simp add: negateSnd_def)
  1397 
  1398 lemma divmod_int_rel_neg: "divmod_int_rel (-a) (-b) qr ==> divmod_int_rel a b (negateSnd qr)"
  1399 by (auto simp add: split_ifs divmod_int_rel_def)
  1400 
  1401 lemma divmod_int_correct: "b \<noteq> 0 ==> divmod_int_rel a b (divmod_int a b)"
  1402 by (force simp add: linorder_neq_iff divmod_int_rel_0 divmod_int_def divmod_int_rel_neg
  1403                     posDivAlg_correct negDivAlg_correct)
  1404 
  1405 text{*Arbitrary definitions for division by zero.  Useful to simplify 
  1406     certain equations.*}
  1407 
  1408 lemma DIVISION_BY_ZERO [simp]: "a div (0::int) = 0 & a mod (0::int) = a"
  1409 by (simp add: div_int_def mod_int_def divmod_int_def posDivAlg.simps)  
  1410 
  1411 
  1412 text{*Basic laws about division and remainder*}
  1413 
  1414 lemma zmod_zdiv_equality: "(a::int) = b * (a div b) + (a mod b)"
  1415 apply (case_tac "b = 0", simp)
  1416 apply (cut_tac a = a and b = b in divmod_int_correct)
  1417 apply (auto simp add: divmod_int_rel_def prod_eq_iff)
  1418 done
  1419 
  1420 lemma zdiv_zmod_equality: "(b * (a div b) + (a mod b)) + k = (a::int)+k"
  1421 by(simp add: zmod_zdiv_equality[symmetric])
  1422 
  1423 lemma zdiv_zmod_equality2: "((a div b) * b + (a mod b)) + k = (a::int)+k"
  1424 by(simp add: mult_commute zmod_zdiv_equality[symmetric])
  1425 
  1426 text {* Tool setup *}
  1427 
  1428 ML {*
  1429 structure Cancel_Div_Mod_Int = Cancel_Div_Mod
  1430 (
  1431   val div_name = @{const_name div};
  1432   val mod_name = @{const_name mod};
  1433   val mk_binop = HOLogic.mk_binop;
  1434   val mk_sum = Arith_Data.mk_sum HOLogic.intT;
  1435   val dest_sum = Arith_Data.dest_sum;
  1436 
  1437   val div_mod_eqs = map mk_meta_eq [@{thm zdiv_zmod_equality}, @{thm zdiv_zmod_equality2}];
  1438 
  1439   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac 
  1440     (@{thm diff_minus} :: @{thms add_0s} @ @{thms add_ac}))
  1441 )
  1442 *}
  1443 
  1444 simproc_setup cancel_div_mod_int ("(k::int) + l") = {* K Cancel_Div_Mod_Int.proc *}
  1445 
  1446 lemma pos_mod_conj : "(0::int) < b ==> 0 \<le> a mod b & a mod b < b"
  1447 apply (cut_tac a = a and b = b in divmod_int_correct)
  1448 apply (auto simp add: divmod_int_rel_def prod_eq_iff)
  1449 done
  1450 
  1451 lemmas pos_mod_sign [simp] = pos_mod_conj [THEN conjunct1]
  1452    and pos_mod_bound [simp] = pos_mod_conj [THEN conjunct2]
  1453 
  1454 lemma neg_mod_conj : "b < (0::int) ==> a mod b \<le> 0 & b < a mod b"
  1455 apply (cut_tac a = a and b = b in divmod_int_correct)
  1456 apply (auto simp add: divmod_int_rel_def prod_eq_iff)
  1457 done
  1458 
  1459 lemmas neg_mod_sign [simp] = neg_mod_conj [THEN conjunct1]
  1460    and neg_mod_bound [simp] = neg_mod_conj [THEN conjunct2]
  1461 
  1462 
  1463 subsubsection {* General Properties of div and mod *}
  1464 
  1465 lemma divmod_int_rel_div_mod: "b \<noteq> 0 ==> divmod_int_rel a b (a div b, a mod b)"
  1466 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1467 apply (force simp add: divmod_int_rel_def linorder_neq_iff)
  1468 done
  1469 
  1470 lemma divmod_int_rel_div: "[| divmod_int_rel a b (q, r) |] ==> a div b = q"
  1471 apply (cases "b = 0")
  1472 apply (simp add: divmod_int_rel_def)
  1473 by (simp add: divmod_int_rel_div_mod [THEN unique_quotient])
  1474 
  1475 lemma divmod_int_rel_mod: "[| divmod_int_rel a b (q, r) |] ==> a mod b = r"
  1476 apply (cases "b = 0")
  1477 apply (simp add: divmod_int_rel_def)
  1478 by (simp add: divmod_int_rel_div_mod [THEN unique_remainder])
  1479 
  1480 lemma div_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a div b = 0"
  1481 apply (rule divmod_int_rel_div)
  1482 apply (auto simp add: divmod_int_rel_def)
  1483 done
  1484 
  1485 lemma div_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a div b = 0"
  1486 apply (rule divmod_int_rel_div)
  1487 apply (auto simp add: divmod_int_rel_def)
  1488 done
  1489 
  1490 lemma div_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a div b = -1"
  1491 apply (rule divmod_int_rel_div)
  1492 apply (auto simp add: divmod_int_rel_def)
  1493 done
  1494 
  1495 (*There is no div_neg_pos_trivial because  0 div b = 0 would supersede it*)
  1496 
  1497 lemma mod_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a mod b = a"
  1498 apply (rule_tac q = 0 in divmod_int_rel_mod)
  1499 apply (auto simp add: divmod_int_rel_def)
  1500 done
  1501 
  1502 lemma mod_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a mod b = a"
  1503 apply (rule_tac q = 0 in divmod_int_rel_mod)
  1504 apply (auto simp add: divmod_int_rel_def)
  1505 done
  1506 
  1507 lemma mod_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a mod b = a+b"
  1508 apply (rule_tac q = "-1" in divmod_int_rel_mod)
  1509 apply (auto simp add: divmod_int_rel_def)
  1510 done
  1511 
  1512 text{*There is no @{text mod_neg_pos_trivial}.*}
  1513 
  1514 
  1515 (*Simpler laws such as -a div b = -(a div b) FAIL, but see just below*)
  1516 lemma zdiv_zminus_zminus [simp]: "(-a) div (-b) = a div (b::int)"
  1517 apply (case_tac "b = 0", simp)
  1518 apply (simp add: divmod_int_rel_div_mod [THEN divmod_int_rel_neg, simplified, 
  1519                                  THEN divmod_int_rel_div, THEN sym])
  1520 
  1521 done
  1522 
  1523 (*Simpler laws such as -a mod b = -(a mod b) FAIL, but see just below*)
  1524 lemma zmod_zminus_zminus [simp]: "(-a) mod (-b) = - (a mod (b::int))"
  1525 apply (case_tac "b = 0", simp)
  1526 apply (subst divmod_int_rel_div_mod [THEN divmod_int_rel_neg, simplified, THEN divmod_int_rel_mod],
  1527        auto)
  1528 done
  1529 
  1530 
  1531 subsubsection {* Laws for div and mod with Unary Minus *}
  1532 
  1533 lemma zminus1_lemma:
  1534      "divmod_int_rel a b (q, r)
  1535       ==> divmod_int_rel (-a) b (if r=0 then -q else -q - 1,  
  1536                           if r=0 then 0 else b-r)"
  1537 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_diff_distrib)
  1538 
  1539 
  1540 lemma zdiv_zminus1_eq_if:
  1541      "b \<noteq> (0::int)  
  1542       ==> (-a) div b =  
  1543           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1544 by (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN divmod_int_rel_div])
  1545 
  1546 lemma zmod_zminus1_eq_if:
  1547      "(-a::int) mod b = (if a mod b = 0 then 0 else  b - (a mod b))"
  1548 apply (case_tac "b = 0", simp)
  1549 apply (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN divmod_int_rel_mod])
  1550 done
  1551 
  1552 lemma zmod_zminus1_not_zero:
  1553   fixes k l :: int
  1554   shows "- k mod l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1555   unfolding zmod_zminus1_eq_if by auto
  1556 
  1557 lemma zdiv_zminus2: "a div (-b) = (-a::int) div b"
  1558 by (cut_tac a = "-a" in zdiv_zminus_zminus, auto)
  1559 
  1560 lemma zmod_zminus2: "a mod (-b) = - ((-a::int) mod b)"
  1561 by (cut_tac a = "-a" and b = b in zmod_zminus_zminus, auto)
  1562 
  1563 lemma zdiv_zminus2_eq_if:
  1564      "b \<noteq> (0::int)  
  1565       ==> a div (-b) =  
  1566           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1567 by (simp add: zdiv_zminus1_eq_if zdiv_zminus2)
  1568 
  1569 lemma zmod_zminus2_eq_if:
  1570      "a mod (-b::int) = (if a mod b = 0 then 0 else  (a mod b) - b)"
  1571 by (simp add: zmod_zminus1_eq_if zmod_zminus2)
  1572 
  1573 lemma zmod_zminus2_not_zero:
  1574   fixes k l :: int
  1575   shows "k mod - l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1576   unfolding zmod_zminus2_eq_if by auto 
  1577 
  1578 
  1579 subsubsection {* Division of a Number by Itself *}
  1580 
  1581 lemma self_quotient_aux1: "[| (0::int) < a; a = r + a*q; r < a |] ==> 1 \<le> q"
  1582 apply (subgoal_tac "0 < a*q")
  1583  apply (simp add: zero_less_mult_iff, arith)
  1584 done
  1585 
  1586 lemma self_quotient_aux2: "[| (0::int) < a; a = r + a*q; 0 \<le> r |] ==> q \<le> 1"
  1587 apply (subgoal_tac "0 \<le> a* (1-q) ")
  1588  apply (simp add: zero_le_mult_iff)
  1589 apply (simp add: right_diff_distrib)
  1590 done
  1591 
  1592 lemma self_quotient: "[| divmod_int_rel a a (q, r) |] ==> q = 1"
  1593 apply (simp add: split_ifs divmod_int_rel_def linorder_neq_iff)
  1594 apply (rule order_antisym, safe, simp_all)
  1595 apply (rule_tac [3] a = "-a" and r = "-r" in self_quotient_aux1)
  1596 apply (rule_tac a = "-a" and r = "-r" in self_quotient_aux2)
  1597 apply (force intro: self_quotient_aux1 self_quotient_aux2 simp add: add_commute)+
  1598 done
  1599 
  1600 lemma self_remainder: "[| divmod_int_rel a a (q, r) |] ==> r = 0"
  1601 apply (frule self_quotient)
  1602 apply (simp add: divmod_int_rel_def)
  1603 done
  1604 
  1605 lemma zdiv_self [simp]: "a \<noteq> 0 ==> a div a = (1::int)"
  1606 by (simp add: divmod_int_rel_div_mod [THEN self_quotient])
  1607 
  1608 (*Here we have 0 mod 0 = 0, also assumed by Knuth (who puts m mod 0 = 0) *)
  1609 lemma zmod_self [simp]: "a mod a = (0::int)"
  1610 apply (case_tac "a = 0", simp)
  1611 apply (simp add: divmod_int_rel_div_mod [THEN self_remainder])
  1612 done
  1613 
  1614 
  1615 subsubsection {* Computation of Division and Remainder *}
  1616 
  1617 lemma zdiv_zero [simp]: "(0::int) div b = 0"
  1618 by (simp add: div_int_def divmod_int_def)
  1619 
  1620 lemma div_eq_minus1: "(0::int) < b ==> -1 div b = -1"
  1621 by (simp add: div_int_def divmod_int_def)
  1622 
  1623 lemma zmod_zero [simp]: "(0::int) mod b = 0"
  1624 by (simp add: mod_int_def divmod_int_def)
  1625 
  1626 lemma zmod_minus1: "(0::int) < b ==> -1 mod b = b - 1"
  1627 by (simp add: mod_int_def divmod_int_def)
  1628 
  1629 text{*a positive, b positive *}
  1630 
  1631 lemma div_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a div b = fst (posDivAlg a b)"
  1632 by (simp add: div_int_def divmod_int_def)
  1633 
  1634 lemma mod_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a mod b = snd (posDivAlg a b)"
  1635 by (simp add: mod_int_def divmod_int_def)
  1636 
  1637 text{*a negative, b positive *}
  1638 
  1639 lemma div_neg_pos: "[| a < 0;  0 < b |] ==> a div b = fst (negDivAlg a b)"
  1640 by (simp add: div_int_def divmod_int_def)
  1641 
  1642 lemma mod_neg_pos: "[| a < 0;  0 < b |] ==> a mod b = snd (negDivAlg a b)"
  1643 by (simp add: mod_int_def divmod_int_def)
  1644 
  1645 text{*a positive, b negative *}
  1646 
  1647 lemma div_pos_neg:
  1648      "[| 0 < a;  b < 0 |] ==> a div b = fst (negateSnd (negDivAlg (-a) (-b)))"
  1649 by (simp add: div_int_def divmod_int_def)
  1650 
  1651 lemma mod_pos_neg:
  1652      "[| 0 < a;  b < 0 |] ==> a mod b = snd (negateSnd (negDivAlg (-a) (-b)))"
  1653 by (simp add: mod_int_def divmod_int_def)
  1654 
  1655 text{*a negative, b negative *}
  1656 
  1657 lemma div_neg_neg:
  1658      "[| a < 0;  b \<le> 0 |] ==> a div b = fst (negateSnd (posDivAlg (-a) (-b)))"
  1659 by (simp add: div_int_def divmod_int_def)
  1660 
  1661 lemma mod_neg_neg:
  1662      "[| a < 0;  b \<le> 0 |] ==> a mod b = snd (negateSnd (posDivAlg (-a) (-b)))"
  1663 by (simp add: mod_int_def divmod_int_def)
  1664 
  1665 text {*Simplify expresions in which div and mod combine numerical constants*}
  1666 
  1667 lemma int_div_pos_eq: "\<lbrakk>(a::int) = b * q + r; 0 \<le> r; r < b\<rbrakk> \<Longrightarrow> a div b = q"
  1668   by (rule divmod_int_rel_div [of a b q r]) (simp add: divmod_int_rel_def)
  1669 
  1670 lemma int_div_neg_eq: "\<lbrakk>(a::int) = b * q + r; r \<le> 0; b < r\<rbrakk> \<Longrightarrow> a div b = q"
  1671   by (rule divmod_int_rel_div [of a b q r],
  1672     simp add: divmod_int_rel_def)
  1673 
  1674 lemma int_mod_pos_eq: "\<lbrakk>(a::int) = b * q + r; 0 \<le> r; r < b\<rbrakk> \<Longrightarrow> a mod b = r"
  1675   by (rule divmod_int_rel_mod [of a b q r],
  1676     simp add: divmod_int_rel_def)
  1677 
  1678 lemma int_mod_neg_eq: "\<lbrakk>(a::int) = b * q + r; r \<le> 0; b < r\<rbrakk> \<Longrightarrow> a mod b = r"
  1679   by (rule divmod_int_rel_mod [of a b q r],
  1680     simp add: divmod_int_rel_def)
  1681 
  1682 lemmas arithmetic_simps =
  1683   arith_simps
  1684   add_special
  1685   add_0_left
  1686   add_0_right
  1687   mult_zero_left
  1688   mult_zero_right
  1689   mult_1_left
  1690   mult_1_right
  1691 
  1692 (* simprocs adapted from HOL/ex/Binary.thy *)
  1693 ML {*
  1694 local
  1695   val mk_number = HOLogic.mk_number HOLogic.intT
  1696   val plus = @{term "plus :: int \<Rightarrow> int \<Rightarrow> int"}
  1697   val times = @{term "times :: int \<Rightarrow> int \<Rightarrow> int"}
  1698   val zero = @{term "0 :: int"}
  1699   val less = @{term "op < :: int \<Rightarrow> int \<Rightarrow> bool"}
  1700   val le = @{term "op \<le> :: int \<Rightarrow> int \<Rightarrow> bool"}
  1701   val simps = @{thms arith_simps} @ @{thms rel_simps} @
  1702     map (fn th => th RS sym) [@{thm numeral_0_eq_0}, @{thm numeral_1_eq_1}]
  1703   fun prove ctxt goal = Goal.prove ctxt [] [] (HOLogic.mk_Trueprop goal)
  1704     (K (ALLGOALS (full_simp_tac (HOL_basic_ss addsimps simps))));
  1705   fun binary_proc proc ss ct =
  1706     (case Thm.term_of ct of
  1707       _ $ t $ u =>
  1708       (case try (pairself (`(snd o HOLogic.dest_number))) (t, u) of
  1709         SOME args => proc (Simplifier.the_context ss) args
  1710       | NONE => NONE)
  1711     | _ => NONE);
  1712 in
  1713   fun divmod_proc posrule negrule =
  1714     binary_proc (fn ctxt => fn ((a, t), (b, u)) =>
  1715       if b = 0 then NONE else let
  1716         val (q, r) = pairself mk_number (Integer.div_mod a b)
  1717         val goal1 = HOLogic.mk_eq (t, plus $ (times $ u $ q) $ r)
  1718         val (goal2, goal3, rule) = if b > 0
  1719           then (le $ zero $ r, less $ r $ u, posrule RS eq_reflection)
  1720           else (le $ r $ zero, less $ u $ r, negrule RS eq_reflection)
  1721       in SOME (rule OF map (prove ctxt) [goal1, goal2, goal3]) end)
  1722 end
  1723 *}
  1724 
  1725 simproc_setup binary_int_div ("number_of m div number_of n :: int") =
  1726   {* K (divmod_proc @{thm int_div_pos_eq} @{thm int_div_neg_eq}) *}
  1727 
  1728 simproc_setup binary_int_mod ("number_of m mod number_of n :: int") =
  1729   {* K (divmod_proc @{thm int_mod_pos_eq} @{thm int_mod_neg_eq}) *}
  1730 
  1731 lemmas posDivAlg_eqn_number_of [simp] = posDivAlg_eqn [of "number_of v" "number_of w"] for v w
  1732 lemmas negDivAlg_eqn_number_of [simp] = negDivAlg_eqn [of "number_of v" "number_of w"] for v w
  1733 
  1734 
  1735 text{*Special-case simplification *}
  1736 
  1737 lemma zmod_minus1_right [simp]: "a mod (-1::int) = 0"
  1738 apply (cut_tac a = a and b = "-1" in neg_mod_sign)
  1739 apply (cut_tac [2] a = a and b = "-1" in neg_mod_bound)
  1740 apply (auto simp del: neg_mod_sign neg_mod_bound)
  1741 done
  1742 
  1743 lemma zdiv_minus1_right [simp]: "a div (-1::int) = -a"
  1744 by (cut_tac a = a and b = "-1" in zmod_zdiv_equality, auto)
  1745 
  1746 (** The last remaining special cases for constant arithmetic:
  1747     1 div z and 1 mod z **)
  1748 
  1749 lemmas div_pos_pos_1_number_of [simp] = div_pos_pos [OF zero_less_one, of "number_of w"] for w
  1750 lemmas div_pos_neg_1_number_of [simp] = div_pos_neg [OF zero_less_one, of "number_of w"] for w
  1751 lemmas mod_pos_pos_1_number_of [simp] = mod_pos_pos [OF zero_less_one, of "number_of w"] for w
  1752 lemmas mod_pos_neg_1_number_of [simp] = mod_pos_neg [OF zero_less_one, of "number_of w"] for w
  1753 lemmas posDivAlg_eqn_1_number_of [simp] = posDivAlg_eqn [of concl: 1 "number_of w"] for w
  1754 lemmas negDivAlg_eqn_1_number_of [simp] = negDivAlg_eqn [of concl: 1 "number_of w"] for w
  1755 
  1756 
  1757 subsubsection {* Monotonicity in the First Argument (Dividend) *}
  1758 
  1759 lemma zdiv_mono1: "[| a \<le> a';  0 < (b::int) |] ==> a div b \<le> a' div b"
  1760 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1761 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1762 apply (rule unique_quotient_lemma)
  1763 apply (erule subst)
  1764 apply (erule subst, simp_all)
  1765 done
  1766 
  1767 lemma zdiv_mono1_neg: "[| a \<le> a';  (b::int) < 0 |] ==> a' div b \<le> a div b"
  1768 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1769 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1770 apply (rule unique_quotient_lemma_neg)
  1771 apply (erule subst)
  1772 apply (erule subst, simp_all)
  1773 done
  1774 
  1775 
  1776 subsubsection {* Monotonicity in the Second Argument (Divisor) *}
  1777 
  1778 lemma q_pos_lemma:
  1779      "[| 0 \<le> b'*q' + r'; r' < b';  0 < b' |] ==> 0 \<le> (q'::int)"
  1780 apply (subgoal_tac "0 < b'* (q' + 1) ")
  1781  apply (simp add: zero_less_mult_iff)
  1782 apply (simp add: right_distrib)
  1783 done
  1784 
  1785 lemma zdiv_mono2_lemma:
  1786      "[| b*q + r = b'*q' + r';  0 \<le> b'*q' + r';   
  1787          r' < b';  0 \<le> r;  0 < b';  b' \<le> b |]   
  1788       ==> q \<le> (q'::int)"
  1789 apply (frule q_pos_lemma, assumption+) 
  1790 apply (subgoal_tac "b*q < b* (q' + 1) ")
  1791  apply (simp add: mult_less_cancel_left)
  1792 apply (subgoal_tac "b*q = r' - r + b'*q'")
  1793  prefer 2 apply simp
  1794 apply (simp (no_asm_simp) add: right_distrib)
  1795 apply (subst add_commute, rule add_less_le_mono, arith)
  1796 apply (rule mult_right_mono, auto)
  1797 done
  1798 
  1799 lemma zdiv_mono2:
  1800      "[| (0::int) \<le> a;  0 < b';  b' \<le> b |] ==> a div b \<le> a div b'"
  1801 apply (subgoal_tac "b \<noteq> 0")
  1802  prefer 2 apply arith
  1803 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1804 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1805 apply (rule zdiv_mono2_lemma)
  1806 apply (erule subst)
  1807 apply (erule subst, simp_all)
  1808 done
  1809 
  1810 lemma q_neg_lemma:
  1811      "[| b'*q' + r' < 0;  0 \<le> r';  0 < b' |] ==> q' \<le> (0::int)"
  1812 apply (subgoal_tac "b'*q' < 0")
  1813  apply (simp add: mult_less_0_iff, arith)
  1814 done
  1815 
  1816 lemma zdiv_mono2_neg_lemma:
  1817      "[| b*q + r = b'*q' + r';  b'*q' + r' < 0;   
  1818          r < b;  0 \<le> r';  0 < b';  b' \<le> b |]   
  1819       ==> q' \<le> (q::int)"
  1820 apply (frule q_neg_lemma, assumption+) 
  1821 apply (subgoal_tac "b*q' < b* (q + 1) ")
  1822  apply (simp add: mult_less_cancel_left)
  1823 apply (simp add: right_distrib)
  1824 apply (subgoal_tac "b*q' \<le> b'*q'")
  1825  prefer 2 apply (simp add: mult_right_mono_neg, arith)
  1826 done
  1827 
  1828 lemma zdiv_mono2_neg:
  1829      "[| a < (0::int);  0 < b';  b' \<le> b |] ==> a div b' \<le> a div b"
  1830 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1831 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1832 apply (rule zdiv_mono2_neg_lemma)
  1833 apply (erule subst)
  1834 apply (erule subst, simp_all)
  1835 done
  1836 
  1837 
  1838 subsubsection {* More Algebraic Laws for div and mod *}
  1839 
  1840 text{*proving (a*b) div c = a * (b div c) + a * (b mod c) *}
  1841 
  1842 lemma zmult1_lemma:
  1843      "[| divmod_int_rel b c (q, r) |]  
  1844       ==> divmod_int_rel (a * b) c (a*q + a*r div c, a*r mod c)"
  1845 by (auto simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_distrib mult_ac)
  1846 
  1847 lemma zdiv_zmult1_eq: "(a*b) div c = a*(b div c) + a*(b mod c) div (c::int)"
  1848 apply (case_tac "c = 0", simp)
  1849 apply (blast intro: divmod_int_rel_div_mod [THEN zmult1_lemma, THEN divmod_int_rel_div])
  1850 done
  1851 
  1852 lemma zmod_zmult1_eq: "(a*b) mod c = a*(b mod c) mod (c::int)"
  1853 apply (case_tac "c = 0", simp)
  1854 apply (blast intro: divmod_int_rel_div_mod [THEN zmult1_lemma, THEN divmod_int_rel_mod])
  1855 done
  1856 
  1857 lemma zmod_zdiv_trivial: "(a mod b) div b = (0::int)"
  1858 apply (case_tac "b = 0", simp)
  1859 apply (auto simp add: linorder_neq_iff div_pos_pos_trivial div_neg_neg_trivial)
  1860 done
  1861 
  1862 text{*proving (a+b) div c = a div c + b div c + ((a mod c + b mod c) div c) *}
  1863 
  1864 lemma zadd1_lemma:
  1865      "[| divmod_int_rel a c (aq, ar);  divmod_int_rel b c (bq, br) |]  
  1866       ==> divmod_int_rel (a+b) c (aq + bq + (ar+br) div c, (ar+br) mod c)"
  1867 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_distrib)
  1868 
  1869 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
  1870 lemma zdiv_zadd1_eq:
  1871      "(a+b) div (c::int) = a div c + b div c + ((a mod c + b mod c) div c)"
  1872 apply (case_tac "c = 0", simp)
  1873 apply (blast intro: zadd1_lemma [OF divmod_int_rel_div_mod divmod_int_rel_div_mod] divmod_int_rel_div)
  1874 done
  1875 
  1876 instance int :: ring_div
  1877 proof
  1878   fix a b c :: int
  1879   assume not0: "b \<noteq> 0"
  1880   show "(a + c * b) div b = c + a div b"
  1881     unfolding zdiv_zadd1_eq [of a "c * b"] using not0 
  1882       by (simp add: zmod_zmult1_eq zmod_zdiv_trivial zdiv_zmult1_eq)
  1883 next
  1884   fix a b c :: int
  1885   assume "a \<noteq> 0"
  1886   then show "(a * b) div (a * c) = b div c"
  1887   proof (cases "b \<noteq> 0 \<and> c \<noteq> 0")
  1888     case False then show ?thesis by auto
  1889   next
  1890     case True then have "b \<noteq> 0" and "c \<noteq> 0" by auto
  1891     with `a \<noteq> 0`
  1892     have "\<And>q r. divmod_int_rel b c (q, r) \<Longrightarrow> divmod_int_rel (a * b) (a * c) (q, a * r)"
  1893       apply (auto simp add: divmod_int_rel_def) 
  1894       apply (auto simp add: algebra_simps)
  1895       apply (auto simp add: zero_less_mult_iff zero_le_mult_iff mult_le_0_iff mult_commute [of a] mult_less_cancel_right)
  1896       done
  1897     moreover with `c \<noteq> 0` divmod_int_rel_div_mod have "divmod_int_rel b c (b div c, b mod c)" by auto
  1898     ultimately have "divmod_int_rel (a * b) (a * c) (b div c, a * (b mod c))" .
  1899     from this show ?thesis by (rule divmod_int_rel_div)
  1900   qed
  1901 qed auto
  1902 
  1903 lemma posDivAlg_div_mod:
  1904   assumes "k \<ge> 0"
  1905   and "l \<ge> 0"
  1906   shows "posDivAlg k l = (k div l, k mod l)"
  1907 proof (cases "l = 0")
  1908   case True then show ?thesis by (simp add: posDivAlg.simps)
  1909 next
  1910   case False with assms posDivAlg_correct
  1911     have "divmod_int_rel k l (fst (posDivAlg k l), snd (posDivAlg k l))"
  1912     by simp
  1913   from divmod_int_rel_div [OF this] divmod_int_rel_mod [OF this]
  1914   show ?thesis by simp
  1915 qed
  1916 
  1917 lemma negDivAlg_div_mod:
  1918   assumes "k < 0"
  1919   and "l > 0"
  1920   shows "negDivAlg k l = (k div l, k mod l)"
  1921 proof -
  1922   from assms have "l \<noteq> 0" by simp
  1923   from assms negDivAlg_correct
  1924     have "divmod_int_rel k l (fst (negDivAlg k l), snd (negDivAlg k l))"
  1925     by simp
  1926   from divmod_int_rel_div [OF this] divmod_int_rel_mod [OF this]
  1927   show ?thesis by simp
  1928 qed
  1929 
  1930 lemma zmod_eq_0_iff: "(m mod d = 0) = (EX q::int. m = d*q)"
  1931 by (simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
  1932 
  1933 (* REVISIT: should this be generalized to all semiring_div types? *)
  1934 lemmas zmod_eq_0D [dest!] = zmod_eq_0_iff [THEN iffD1]
  1935 
  1936 
  1937 subsubsection {* Proving  @{term "a div (b*c) = (a div b) div c"} *}
  1938 
  1939 (*The condition c>0 seems necessary.  Consider that 7 div ~6 = ~2 but
  1940   7 div 2 div ~3 = 3 div ~3 = ~1.  The subcase (a div b) mod c = 0 seems
  1941   to cause particular problems.*)
  1942 
  1943 text{*first, four lemmas to bound the remainder for the cases b<0 and b>0 *}
  1944 
  1945 lemma zmult2_lemma_aux1: "[| (0::int) < c;  b < r;  r \<le> 0 |] ==> b*c < b*(q mod c) + r"
  1946 apply (subgoal_tac "b * (c - q mod c) < r * 1")
  1947  apply (simp add: algebra_simps)
  1948 apply (rule order_le_less_trans)
  1949  apply (erule_tac [2] mult_strict_right_mono)
  1950  apply (rule mult_left_mono_neg)
  1951   using add1_zle_eq[of "q mod c"]apply(simp add: algebra_simps)
  1952  apply (simp)
  1953 apply (simp)
  1954 done
  1955 
  1956 lemma zmult2_lemma_aux2:
  1957      "[| (0::int) < c;   b < r;  r \<le> 0 |] ==> b * (q mod c) + r \<le> 0"
  1958 apply (subgoal_tac "b * (q mod c) \<le> 0")
  1959  apply arith
  1960 apply (simp add: mult_le_0_iff)
  1961 done
  1962 
  1963 lemma zmult2_lemma_aux3: "[| (0::int) < c;  0 \<le> r;  r < b |] ==> 0 \<le> b * (q mod c) + r"
  1964 apply (subgoal_tac "0 \<le> b * (q mod c) ")
  1965 apply arith
  1966 apply (simp add: zero_le_mult_iff)
  1967 done
  1968 
  1969 lemma zmult2_lemma_aux4: "[| (0::int) < c; 0 \<le> r; r < b |] ==> b * (q mod c) + r < b * c"
  1970 apply (subgoal_tac "r * 1 < b * (c - q mod c) ")
  1971  apply (simp add: right_diff_distrib)
  1972 apply (rule order_less_le_trans)
  1973  apply (erule mult_strict_right_mono)
  1974  apply (rule_tac [2] mult_left_mono)
  1975   apply simp
  1976  using add1_zle_eq[of "q mod c"] apply (simp add: algebra_simps)
  1977 apply simp
  1978 done
  1979 
  1980 lemma zmult2_lemma: "[| divmod_int_rel a b (q, r); 0 < c |]  
  1981       ==> divmod_int_rel a (b * c) (q div c, b*(q mod c) + r)"
  1982 by (auto simp add: mult_ac divmod_int_rel_def linorder_neq_iff
  1983                    zero_less_mult_iff right_distrib [symmetric] 
  1984                    zmult2_lemma_aux1 zmult2_lemma_aux2 zmult2_lemma_aux3 zmult2_lemma_aux4)
  1985 
  1986 lemma zdiv_zmult2_eq: "(0::int) < c ==> a div (b*c) = (a div b) div c"
  1987 apply (case_tac "b = 0", simp)
  1988 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN divmod_int_rel_div])
  1989 done
  1990 
  1991 lemma zmod_zmult2_eq:
  1992      "(0::int) < c ==> a mod (b*c) = b*(a div b mod c) + a mod b"
  1993 apply (case_tac "b = 0", simp)
  1994 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN divmod_int_rel_mod])
  1995 done
  1996 
  1997 
  1998 subsubsection {* Splitting Rules for div and mod *}
  1999 
  2000 text{*The proofs of the two lemmas below are essentially identical*}
  2001 
  2002 lemma split_pos_lemma:
  2003  "0<k ==> 
  2004     P(n div k :: int)(n mod k) = (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i j)"
  2005 apply (rule iffI, clarify)
  2006  apply (erule_tac P="P ?x ?y" in rev_mp)  
  2007  apply (subst mod_add_eq) 
  2008  apply (subst zdiv_zadd1_eq) 
  2009  apply (simp add: div_pos_pos_trivial mod_pos_pos_trivial)  
  2010 txt{*converse direction*}
  2011 apply (drule_tac x = "n div k" in spec) 
  2012 apply (drule_tac x = "n mod k" in spec, simp)
  2013 done
  2014 
  2015 lemma split_neg_lemma:
  2016  "k<0 ==>
  2017     P(n div k :: int)(n mod k) = (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i j)"
  2018 apply (rule iffI, clarify)
  2019  apply (erule_tac P="P ?x ?y" in rev_mp)  
  2020  apply (subst mod_add_eq) 
  2021  apply (subst zdiv_zadd1_eq) 
  2022  apply (simp add: div_neg_neg_trivial mod_neg_neg_trivial)  
  2023 txt{*converse direction*}
  2024 apply (drule_tac x = "n div k" in spec) 
  2025 apply (drule_tac x = "n mod k" in spec, simp)
  2026 done
  2027 
  2028 lemma split_zdiv:
  2029  "P(n div k :: int) =
  2030   ((k = 0 --> P 0) & 
  2031    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i)) & 
  2032    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i)))"
  2033 apply (case_tac "k=0", simp)
  2034 apply (simp only: linorder_neq_iff)
  2035 apply (erule disjE) 
  2036  apply (simp_all add: split_pos_lemma [of concl: "%x y. P x"] 
  2037                       split_neg_lemma [of concl: "%x y. P x"])
  2038 done
  2039 
  2040 lemma split_zmod:
  2041  "P(n mod k :: int) =
  2042   ((k = 0 --> P n) & 
  2043    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P j)) & 
  2044    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P j)))"
  2045 apply (case_tac "k=0", simp)
  2046 apply (simp only: linorder_neq_iff)
  2047 apply (erule disjE) 
  2048  apply (simp_all add: split_pos_lemma [of concl: "%x y. P y"] 
  2049                       split_neg_lemma [of concl: "%x y. P y"])
  2050 done
  2051 
  2052 text {* Enable (lin)arith to deal with @{const div} and @{const mod}
  2053   when these are applied to some constant that is of the form
  2054   @{term "number_of k"}: *}
  2055 declare split_zdiv [of _ _ "number_of k", arith_split] for k
  2056 declare split_zmod [of _ _ "number_of k", arith_split] for k
  2057 
  2058 
  2059 subsubsection {* Speeding up the Division Algorithm with Shifting *}
  2060 
  2061 text{*computing div by shifting *}
  2062 
  2063 lemma pos_zdiv_mult_2: "(0::int) \<le> a ==> (1 + 2*b) div (2*a) = b div a"
  2064 proof cases
  2065   assume "a=0"
  2066     thus ?thesis by simp
  2067 next
  2068   assume "a\<noteq>0" and le_a: "0\<le>a"   
  2069   hence a_pos: "1 \<le> a" by arith
  2070   hence one_less_a2: "1 < 2 * a" by arith
  2071   hence le_2a: "2 * (1 + b mod a) \<le> 2 * a"
  2072     unfolding mult_le_cancel_left
  2073     by (simp add: add1_zle_eq add_commute [of 1])
  2074   with a_pos have "0 \<le> b mod a" by simp
  2075   hence le_addm: "0 \<le> 1 mod (2*a) + 2*(b mod a)"
  2076     by (simp add: mod_pos_pos_trivial one_less_a2)
  2077   with  le_2a
  2078   have "(1 mod (2*a) + 2*(b mod a)) div (2*a) = 0"
  2079     by (simp add: div_pos_pos_trivial le_addm mod_pos_pos_trivial one_less_a2
  2080                   right_distrib) 
  2081   thus ?thesis
  2082     by (subst zdiv_zadd1_eq,
  2083         simp add: mod_mult_mult1 one_less_a2
  2084                   div_pos_pos_trivial)
  2085 qed
  2086 
  2087 lemma neg_zdiv_mult_2: 
  2088   assumes A: "a \<le> (0::int)" shows "(1 + 2*b) div (2*a) = (b+1) div a"
  2089 proof -
  2090   have R: "1 + - (2 * (b + 1)) = - (1 + 2 * b)" by simp
  2091   have "(1 + 2 * (-b - 1)) div (2 * (-a)) = (-b - 1) div (-a)"
  2092     by (rule pos_zdiv_mult_2, simp add: A)
  2093   thus ?thesis
  2094     by (simp only: R zdiv_zminus_zminus diff_minus
  2095       minus_add_distrib [symmetric] mult_minus_right)
  2096 qed
  2097 
  2098 lemma zdiv_number_of_Bit0 [simp]:
  2099      "number_of (Int.Bit0 v) div number_of (Int.Bit0 w) =  
  2100           number_of v div (number_of w :: int)"
  2101 by (simp only: number_of_eq numeral_simps) (simp add: mult_2 [symmetric])
  2102 
  2103 lemma zdiv_number_of_Bit1 [simp]:
  2104      "number_of (Int.Bit1 v) div number_of (Int.Bit0 w) =  
  2105           (if (0::int) \<le> number_of w                    
  2106            then number_of v div (number_of w)     
  2107            else (number_of v + (1::int)) div (number_of w))"
  2108 apply (simp only: number_of_eq numeral_simps UNIV_I split: split_if) 
  2109 apply (simp add: pos_zdiv_mult_2 neg_zdiv_mult_2 add_ac mult_2 [symmetric])
  2110 done
  2111 
  2112 
  2113 subsubsection {* Computing mod by Shifting (proofs resemble those for div) *}
  2114 
  2115 lemma pos_zmod_mult_2:
  2116   fixes a b :: int
  2117   assumes "0 \<le> a"
  2118   shows "(1 + 2 * b) mod (2 * a) = 1 + 2 * (b mod a)"
  2119 proof (cases "0 < a")
  2120   case False with assms show ?thesis by simp
  2121 next
  2122   case True
  2123   then have "b mod a < a" by (rule pos_mod_bound)
  2124   then have "1 + b mod a \<le> a" by simp
  2125   then have A: "2 * (1 + b mod a) \<le> 2 * a" by simp
  2126   from `0 < a` have "0 \<le> b mod a" by (rule pos_mod_sign)
  2127   then have B: "0 \<le> 1 + 2 * (b mod a)" by simp
  2128   have "((1\<Colon>int) mod ((2\<Colon>int) * a) + (2\<Colon>int) * b mod ((2\<Colon>int) * a)) mod ((2\<Colon>int) * a) = (1\<Colon>int) + (2\<Colon>int) * (b mod a)"
  2129     using `0 < a` and A
  2130     by (auto simp add: mod_mult_mult1 mod_pos_pos_trivial ring_distribs intro!: mod_pos_pos_trivial B)
  2131   then show ?thesis by (subst mod_add_eq)
  2132 qed
  2133 
  2134 lemma neg_zmod_mult_2:
  2135   fixes a b :: int
  2136   assumes "a \<le> 0"
  2137   shows "(1 + 2 * b) mod (2 * a) = 2 * ((b + 1) mod a) - 1"
  2138 proof -
  2139   from assms have "0 \<le> - a" by auto
  2140   then have "(1 + 2 * (- b - 1)) mod (2 * (- a)) = 1 + 2 * ((- b - 1) mod (- a))"
  2141     by (rule pos_zmod_mult_2)
  2142   then show ?thesis by (simp add: zmod_zminus2 algebra_simps)
  2143      (simp add: diff_minus add_ac)
  2144 qed
  2145 
  2146 lemma zmod_number_of_Bit0 [simp]:
  2147      "number_of (Int.Bit0 v) mod number_of (Int.Bit0 w) =  
  2148       (2::int) * (number_of v mod number_of w)"
  2149 apply (simp only: number_of_eq numeral_simps) 
  2150 apply (simp add: mod_mult_mult1 pos_zmod_mult_2 
  2151                  neg_zmod_mult_2 add_ac mult_2 [symmetric])
  2152 done
  2153 
  2154 lemma zmod_number_of_Bit1 [simp]:
  2155      "number_of (Int.Bit1 v) mod number_of (Int.Bit0 w) =  
  2156       (if (0::int) \<le> number_of w  
  2157                 then 2 * (number_of v mod number_of w) + 1     
  2158                 else 2 * ((number_of v + (1::int)) mod number_of w) - 1)"
  2159 apply (simp only: number_of_eq numeral_simps) 
  2160 apply (simp add: mod_mult_mult1 pos_zmod_mult_2 
  2161                  neg_zmod_mult_2 add_ac mult_2 [symmetric])
  2162 done
  2163 
  2164 
  2165 lemma zdiv_eq_0_iff:
  2166  "(i::int) div k = 0 \<longleftrightarrow> k=0 \<or> 0\<le>i \<and> i<k \<or> i\<le>0 \<and> k<i" (is "?L = ?R")
  2167 proof
  2168   assume ?L
  2169   have "?L \<longrightarrow> ?R" by (rule split_zdiv[THEN iffD2]) simp
  2170   with `?L` show ?R by blast
  2171 next
  2172   assume ?R thus ?L
  2173     by(auto simp: div_pos_pos_trivial div_neg_neg_trivial)
  2174 qed
  2175 
  2176 
  2177 subsubsection {* Quotients of Signs *}
  2178 
  2179 lemma div_neg_pos_less0: "[| a < (0::int);  0 < b |] ==> a div b < 0"
  2180 apply (subgoal_tac "a div b \<le> -1", force)
  2181 apply (rule order_trans)
  2182 apply (rule_tac a' = "-1" in zdiv_mono1)
  2183 apply (auto simp add: div_eq_minus1)
  2184 done
  2185 
  2186 lemma div_nonneg_neg_le0: "[| (0::int) \<le> a; b < 0 |] ==> a div b \<le> 0"
  2187 by (drule zdiv_mono1_neg, auto)
  2188 
  2189 lemma div_nonpos_pos_le0: "[| (a::int) \<le> 0; b > 0 |] ==> a div b \<le> 0"
  2190 by (drule zdiv_mono1, auto)
  2191 
  2192 text{* Now for some equivalences of the form @{text"a div b >=< 0 \<longleftrightarrow> \<dots>"}
  2193 conditional upon the sign of @{text a} or @{text b}. There are many more.
  2194 They should all be simp rules unless that causes too much search. *}
  2195 
  2196 lemma pos_imp_zdiv_nonneg_iff: "(0::int) < b ==> (0 \<le> a div b) = (0 \<le> a)"
  2197 apply auto
  2198 apply (drule_tac [2] zdiv_mono1)
  2199 apply (auto simp add: linorder_neq_iff)
  2200 apply (simp (no_asm_use) add: linorder_not_less [symmetric])
  2201 apply (blast intro: div_neg_pos_less0)
  2202 done
  2203 
  2204 lemma neg_imp_zdiv_nonneg_iff:
  2205   "b < (0::int) ==> (0 \<le> a div b) = (a \<le> (0::int))"
  2206 apply (subst zdiv_zminus_zminus [symmetric])
  2207 apply (subst pos_imp_zdiv_nonneg_iff, auto)
  2208 done
  2209 
  2210 (*But not (a div b \<le> 0 iff a\<le>0); consider a=1, b=2 when a div b = 0.*)
  2211 lemma pos_imp_zdiv_neg_iff: "(0::int) < b ==> (a div b < 0) = (a < 0)"
  2212 by (simp add: linorder_not_le [symmetric] pos_imp_zdiv_nonneg_iff)
  2213 
  2214 lemma pos_imp_zdiv_pos_iff:
  2215   "0<k \<Longrightarrow> 0 < (i::int) div k \<longleftrightarrow> k \<le> i"
  2216 using pos_imp_zdiv_nonneg_iff[of k i] zdiv_eq_0_iff[of i k]
  2217 by arith
  2218 
  2219 (*Again the law fails for \<le>: consider a = -1, b = -2 when a div b = 0*)
  2220 lemma neg_imp_zdiv_neg_iff: "b < (0::int) ==> (a div b < 0) = (0 < a)"
  2221 by (simp add: linorder_not_le [symmetric] neg_imp_zdiv_nonneg_iff)
  2222 
  2223 lemma nonneg1_imp_zdiv_pos_iff:
  2224   "(0::int) <= a \<Longrightarrow> (a div b > 0) = (a >= b & b>0)"
  2225 apply rule
  2226  apply rule
  2227   using div_pos_pos_trivial[of a b]apply arith
  2228  apply(cases "b=0")apply simp
  2229  using div_nonneg_neg_le0[of a b]apply arith
  2230 using int_one_le_iff_zero_less[of "a div b"] zdiv_mono1[of b a b]apply simp
  2231 done
  2232 
  2233 lemma zmod_le_nonneg_dividend: "(m::int) \<ge> 0 ==> m mod k \<le> m"
  2234 apply (rule split_zmod[THEN iffD2])
  2235 apply(fastforce dest: q_pos_lemma intro: split_mult_pos_le)
  2236 done
  2237 
  2238 
  2239 subsubsection {* The Divides Relation *}
  2240 
  2241 lemmas zdvd_iff_zmod_eq_0_number_of [simp] =
  2242   dvd_eq_mod_eq_0 [of "number_of x" "number_of y"] for x y :: int
  2243 
  2244 lemma zdvd_zmod: "f dvd m ==> f dvd (n::int) ==> f dvd m mod n"
  2245   by (rule dvd_mod) (* TODO: remove *)
  2246 
  2247 lemma zdvd_zmod_imp_zdvd: "k dvd m mod n ==> k dvd n ==> k dvd (m::int)"
  2248   by (rule dvd_mod_imp_dvd) (* TODO: remove *)
  2249 
  2250 lemma zmult_div_cancel: "(n::int) * (m div n) = m - (m mod n)"
  2251   using zmod_zdiv_equality[where a="m" and b="n"]
  2252   by (simp add: algebra_simps)
  2253 
  2254 lemma zpower_zmod: "((x::int) mod m)^y mod m = x^y mod m"
  2255 apply (induct "y", auto)
  2256 apply (rule zmod_zmult1_eq [THEN trans])
  2257 apply (simp (no_asm_simp))
  2258 apply (rule mod_mult_eq [symmetric])
  2259 done
  2260 
  2261 lemma zdiv_int: "int (a div b) = (int a) div (int b)"
  2262 apply (subst split_div, auto)
  2263 apply (subst split_zdiv, auto)
  2264 apply (rule_tac a="int (b * i) + int j" and b="int b" and r="int j" and r'=ja in unique_quotient)
  2265 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2266 done
  2267 
  2268 lemma zmod_int: "int (a mod b) = (int a) mod (int b)"
  2269 apply (subst split_mod, auto)
  2270 apply (subst split_zmod, auto)
  2271 apply (rule_tac a="int (b * i) + int j" and b="int b" and q="int i" and q'=ia 
  2272        in unique_remainder)
  2273 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2274 done
  2275 
  2276 lemma abs_div: "(y::int) dvd x \<Longrightarrow> abs (x div y) = abs x div abs y"
  2277 by (unfold dvd_def, cases "y=0", auto simp add: abs_mult)
  2278 
  2279 lemma zdvd_mult_div_cancel:"(n::int) dvd m \<Longrightarrow> n * (m div n) = m"
  2280 apply (subgoal_tac "m mod n = 0")
  2281  apply (simp add: zmult_div_cancel)
  2282 apply (simp only: dvd_eq_mod_eq_0)
  2283 done
  2284 
  2285 text{*Suggested by Matthias Daum*}
  2286 lemma int_power_div_base:
  2287      "\<lbrakk>0 < m; 0 < k\<rbrakk> \<Longrightarrow> k ^ m div k = (k::int) ^ (m - Suc 0)"
  2288 apply (subgoal_tac "k ^ m = k ^ ((m - Suc 0) + Suc 0)")
  2289  apply (erule ssubst)
  2290  apply (simp only: power_add)
  2291  apply simp_all
  2292 done
  2293 
  2294 text {* by Brian Huffman *}
  2295 lemma zminus_zmod: "- ((x::int) mod m) mod m = - x mod m"
  2296 by (rule mod_minus_eq [symmetric])
  2297 
  2298 lemma zdiff_zmod_left: "(x mod m - y) mod m = (x - y) mod (m::int)"
  2299 by (rule mod_diff_left_eq [symmetric])
  2300 
  2301 lemma zdiff_zmod_right: "(x - y mod m) mod m = (x - y) mod (m::int)"
  2302 by (rule mod_diff_right_eq [symmetric])
  2303 
  2304 lemmas zmod_simps =
  2305   mod_add_left_eq  [symmetric]
  2306   mod_add_right_eq [symmetric]
  2307   zmod_zmult1_eq   [symmetric]
  2308   mod_mult_left_eq [symmetric]
  2309   zpower_zmod
  2310   zminus_zmod zdiff_zmod_left zdiff_zmod_right
  2311 
  2312 text {* Distributive laws for function @{text nat}. *}
  2313 
  2314 lemma nat_div_distrib: "0 \<le> x \<Longrightarrow> nat (x div y) = nat x div nat y"
  2315 apply (rule linorder_cases [of y 0])
  2316 apply (simp add: div_nonneg_neg_le0)
  2317 apply simp
  2318 apply (simp add: nat_eq_iff pos_imp_zdiv_nonneg_iff zdiv_int)
  2319 done
  2320 
  2321 (*Fails if y<0: the LHS collapses to (nat z) but the RHS doesn't*)
  2322 lemma nat_mod_distrib:
  2323   "\<lbrakk>0 \<le> x; 0 \<le> y\<rbrakk> \<Longrightarrow> nat (x mod y) = nat x mod nat y"
  2324 apply (case_tac "y = 0", simp)
  2325 apply (simp add: nat_eq_iff zmod_int)
  2326 done
  2327 
  2328 text  {* transfer setup *}
  2329 
  2330 lemma transfer_nat_int_functions:
  2331     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) div (nat y) = nat (x div y)"
  2332     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) mod (nat y) = nat (x mod y)"
  2333   by (auto simp add: nat_div_distrib nat_mod_distrib)
  2334 
  2335 lemma transfer_nat_int_function_closures:
  2336     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x div y >= 0"
  2337     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x mod y >= 0"
  2338   apply (cases "y = 0")
  2339   apply (auto simp add: pos_imp_zdiv_nonneg_iff)
  2340   apply (cases "y = 0")
  2341   apply auto
  2342 done
  2343 
  2344 declare transfer_morphism_nat_int [transfer add return:
  2345   transfer_nat_int_functions
  2346   transfer_nat_int_function_closures
  2347 ]
  2348 
  2349 lemma transfer_int_nat_functions:
  2350     "(int x) div (int y) = int (x div y)"
  2351     "(int x) mod (int y) = int (x mod y)"
  2352   by (auto simp add: zdiv_int zmod_int)
  2353 
  2354 lemma transfer_int_nat_function_closures:
  2355     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x div y)"
  2356     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x mod y)"
  2357   by (simp_all only: is_nat_def transfer_nat_int_function_closures)
  2358 
  2359 declare transfer_morphism_int_nat [transfer add return:
  2360   transfer_int_nat_functions
  2361   transfer_int_nat_function_closures
  2362 ]
  2363 
  2364 text{*Suggested by Matthias Daum*}
  2365 lemma int_div_less_self: "\<lbrakk>0 < x; 1 < k\<rbrakk> \<Longrightarrow> x div k < (x::int)"
  2366 apply (subgoal_tac "nat x div nat k < nat x")
  2367  apply (simp add: nat_div_distrib [symmetric])
  2368 apply (rule Divides.div_less_dividend, simp_all)
  2369 done
  2370 
  2371 lemma zmod_eq_dvd_iff: "(x::int) mod n = y mod n \<longleftrightarrow> n dvd x - y"
  2372 proof
  2373   assume H: "x mod n = y mod n"
  2374   hence "x mod n - y mod n = 0" by simp
  2375   hence "(x mod n - y mod n) mod n = 0" by simp 
  2376   hence "(x - y) mod n = 0" by (simp add: mod_diff_eq[symmetric])
  2377   thus "n dvd x - y" by (simp add: dvd_eq_mod_eq_0)
  2378 next
  2379   assume H: "n dvd x - y"
  2380   then obtain k where k: "x-y = n*k" unfolding dvd_def by blast
  2381   hence "x = n*k + y" by simp
  2382   hence "x mod n = (n*k + y) mod n" by simp
  2383   thus "x mod n = y mod n" by (simp add: mod_add_left_eq)
  2384 qed
  2385 
  2386 lemma nat_mod_eq_lemma: assumes xyn: "(x::nat) mod n = y  mod n" and xy:"y \<le> x"
  2387   shows "\<exists>q. x = y + n * q"
  2388 proof-
  2389   from xy have th: "int x - int y = int (x - y)" by simp 
  2390   from xyn have "int x mod int n = int y mod int n" 
  2391     by (simp add: zmod_int [symmetric])
  2392   hence "int n dvd int x - int y" by (simp only: zmod_eq_dvd_iff[symmetric]) 
  2393   hence "n dvd x - y" by (simp add: th zdvd_int)
  2394   then show ?thesis using xy unfolding dvd_def apply clarsimp apply (rule_tac x="k" in exI) by arith
  2395 qed
  2396 
  2397 lemma nat_mod_eq_iff: "(x::nat) mod n = y mod n \<longleftrightarrow> (\<exists>q1 q2. x + n * q1 = y + n * q2)" 
  2398   (is "?lhs = ?rhs")
  2399 proof
  2400   assume H: "x mod n = y mod n"
  2401   {assume xy: "x \<le> y"
  2402     from H have th: "y mod n = x mod n" by simp
  2403     from nat_mod_eq_lemma[OF th xy] have ?rhs 
  2404       apply clarify  apply (rule_tac x="q" in exI) by (rule exI[where x="0"], simp)}
  2405   moreover
  2406   {assume xy: "y \<le> x"
  2407     from nat_mod_eq_lemma[OF H xy] have ?rhs 
  2408       apply clarify  apply (rule_tac x="0" in exI) by (rule_tac x="q" in exI, simp)}
  2409   ultimately  show ?rhs using linear[of x y] by blast  
  2410 next
  2411   assume ?rhs then obtain q1 q2 where q12: "x + n * q1 = y + n * q2" by blast
  2412   hence "(x + n * q1) mod n = (y + n * q2) mod n" by simp
  2413   thus  ?lhs by simp
  2414 qed
  2415 
  2416 lemma div_nat_number_of [simp]:
  2417      "(number_of v :: nat)  div  number_of v' =  
  2418           (if neg (number_of v :: int) then 0  
  2419            else nat (number_of v div number_of v'))"
  2420   unfolding nat_number_of_def number_of_is_id neg_def
  2421   by (simp add: nat_div_distrib)
  2422 
  2423 lemma one_div_nat_number_of [simp]:
  2424      "Suc 0 div number_of v' = nat (1 div number_of v')" 
  2425   by (simp del: semiring_numeral_1_eq_1 add: numeral_1_eq_Suc_0 [symmetric] semiring_numeral_1_eq_1 [symmetric]) 
  2426 
  2427 lemma mod_nat_number_of [simp]:
  2428      "(number_of v :: nat)  mod  number_of v' =  
  2429         (if neg (number_of v :: int) then 0  
  2430          else if neg (number_of v' :: int) then number_of v  
  2431          else nat (number_of v mod number_of v'))"
  2432   unfolding nat_number_of_def number_of_is_id neg_def
  2433   by (simp add: nat_mod_distrib)
  2434 
  2435 lemma one_mod_nat_number_of [simp]:
  2436      "Suc 0 mod number_of v' =  
  2437         (if neg (number_of v' :: int) then Suc 0
  2438          else nat (1 mod number_of v'))"
  2439 by (simp del: semiring_numeral_1_eq_1 add: numeral_1_eq_Suc_0 [symmetric] semiring_numeral_1_eq_1 [symmetric]) 
  2440 
  2441 lemmas dvd_eq_mod_eq_0_number_of [simp] =
  2442   dvd_eq_mod_eq_0 [of "number_of x" "number_of y"] for x y
  2443 
  2444 
  2445 subsubsection {* Nitpick *}
  2446 
  2447 lemma zmod_zdiv_equality':
  2448 "(m\<Colon>int) mod n = m - (m div n) * n"
  2449 by (rule_tac P="%x. m mod n = x - (m div n) * n"
  2450     in subst [OF mod_div_equality [of _ n]])
  2451    arith
  2452 
  2453 lemmas [nitpick_unfold] = dvd_eq_mod_eq_0 mod_div_equality' zmod_zdiv_equality'
  2454 
  2455 
  2456 subsubsection {* Code generation *}
  2457 
  2458 definition pdivmod :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  2459   "pdivmod k l = (\<bar>k\<bar> div \<bar>l\<bar>, \<bar>k\<bar> mod \<bar>l\<bar>)"
  2460 
  2461 lemma pdivmod_posDivAlg [code]:
  2462   "pdivmod k l = (if l = 0 then (0, \<bar>k\<bar>) else posDivAlg \<bar>k\<bar> \<bar>l\<bar>)"
  2463 by (subst posDivAlg_div_mod) (simp_all add: pdivmod_def)
  2464 
  2465 lemma divmod_int_pdivmod: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2466   apsnd ((op *) (sgn l)) (if 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0
  2467     then pdivmod k l
  2468     else (let (r, s) = pdivmod k l in
  2469       if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2470 proof -
  2471   have aux: "\<And>q::int. - k = l * q \<longleftrightarrow> k = l * - q" by auto
  2472   show ?thesis
  2473     by (simp add: divmod_int_mod_div pdivmod_def)
  2474       (auto simp add: aux not_less not_le zdiv_zminus1_eq_if
  2475       zmod_zminus1_eq_if zdiv_zminus2_eq_if zmod_zminus2_eq_if)
  2476 qed
  2477 
  2478 lemma divmod_int_code [code]: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2479   apsnd ((op *) (sgn l)) (if sgn k = sgn l
  2480     then pdivmod k l
  2481     else (let (r, s) = pdivmod k l in
  2482       if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2483 proof -
  2484   have "k \<noteq> 0 \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0 \<longleftrightarrow> sgn k = sgn l"
  2485     by (auto simp add: not_less sgn_if)
  2486   then show ?thesis by (simp add: divmod_int_pdivmod)
  2487 qed
  2488 
  2489 context ring_1
  2490 begin
  2491 
  2492 lemma of_int_num [code]:
  2493   "of_int k = (if k = 0 then 0 else if k < 0 then
  2494      - of_int (- k) else let
  2495        (l, m) = divmod_int k 2;
  2496        l' = of_int l
  2497      in if m = 0 then l' + l' else l' + l' + 1)"
  2498 proof -
  2499   have aux1: "k mod (2\<Colon>int) \<noteq> (0\<Colon>int) \<Longrightarrow> 
  2500     of_int k = of_int (k div 2 * 2 + 1)"
  2501   proof -
  2502     have "k mod 2 < 2" by (auto intro: pos_mod_bound)
  2503     moreover have "0 \<le> k mod 2" by (auto intro: pos_mod_sign)
  2504     moreover assume "k mod 2 \<noteq> 0"
  2505     ultimately have "k mod 2 = 1" by arith
  2506     moreover have "of_int k = of_int (k div 2 * 2 + k mod 2)" by simp
  2507     ultimately show ?thesis by auto
  2508   qed
  2509   have aux2: "\<And>x. of_int 2 * x = x + x"
  2510   proof -
  2511     fix x
  2512     have int2: "(2::int) = 1 + 1" by arith
  2513     show "of_int 2 * x = x + x"
  2514     unfolding int2 of_int_add left_distrib by simp
  2515   qed
  2516   have aux3: "\<And>x. x * of_int 2 = x + x"
  2517   proof -
  2518     fix x
  2519     have int2: "(2::int) = 1 + 1" by arith
  2520     show "x * of_int 2 = x + x" 
  2521     unfolding int2 of_int_add right_distrib by simp
  2522   qed
  2523   from aux1 show ?thesis by (auto simp add: divmod_int_mod_div Let_def aux2 aux3)
  2524 qed
  2525 
  2526 end
  2527 
  2528 code_modulename SML
  2529   Divides Arith
  2530 
  2531 code_modulename OCaml
  2532   Divides Arith
  2533 
  2534 code_modulename Haskell
  2535   Divides Arith
  2536 
  2537 end