src/Pure/context.ML
author wenzelm
Wed Jun 29 15:13:23 2005 +0200 (2005-06-29)
changeset 16594 5d73fbf4eb1e
parent 16533 f1152f75f6fc
child 16719 5c5eb939f6eb
permissions -rw-r--r--
added joinable;
     1 (*  Title:      Pure/context.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Generic theory contexts with unique identity, arbitrarily typed data,
     6 development graph and history support.  Implicit theory contexts in ML.
     7 Generic proof contexts with arbitrarily typed data.
     8 *)
     9 
    10 signature BASIC_CONTEXT =
    11 sig
    12   type theory
    13   type theory_ref
    14   exception THEORY of string * theory list
    15   val context: theory -> unit
    16   val the_context: unit -> theory
    17 end;
    18 
    19 signature CONTEXT =
    20 sig
    21   include BASIC_CONTEXT
    22   exception DATA_FAIL of exn * string
    23   (*theory context*)
    24   val theory_name: theory -> string
    25   val parents_of: theory -> theory list
    26   val ancestors_of: theory -> theory list
    27   val is_stale: theory -> bool
    28   val ProtoPureN: string
    29   val PureN: string
    30   val CPureN: string
    31   val draftN: string
    32   val exists_name: string -> theory -> bool
    33   val names_of: theory -> string list
    34   val pretty_thy: theory -> Pretty.T
    35   val string_of_thy: theory -> string
    36   val pprint_thy: theory -> pprint_args -> unit
    37   val pretty_abbrev_thy: theory -> Pretty.T
    38   val str_of_thy: theory -> string
    39   val check_thy: string -> theory -> theory
    40   val eq_thy: theory * theory -> bool
    41   val subthy: theory * theory -> bool
    42   val joinable: theory * theory -> bool
    43   val merge: theory * theory -> theory                     (*exception TERM*)
    44   val merge_refs: theory_ref * theory_ref -> theory_ref    (*exception TERM*)
    45   val self_ref: theory -> theory_ref
    46   val deref: theory_ref -> theory
    47   val copy_thy: theory -> theory
    48   val checkpoint_thy: theory -> theory
    49   val finish_thy: theory -> theory
    50   val theory_data_of: theory -> string list
    51   val pre_pure_thy: theory
    52   val begin_thy: (theory -> Pretty.pp) -> string -> theory list -> theory
    53   (*ML theory context*)
    54   val get_context: unit -> theory option
    55   val set_context: theory option -> unit
    56   val reset_context: unit -> unit
    57   val setmp: theory option -> ('a -> 'b) -> 'a -> 'b
    58   val pass: theory option -> ('a -> 'b) -> 'a -> 'b * theory option
    59   val pass_theory: theory -> ('a -> 'b) -> 'a -> 'b * theory
    60   val save: ('a -> 'b) -> 'a -> 'b
    61   val >> : (theory -> theory) -> unit
    62   val ml_output: (string -> unit) * (string -> unit)
    63   val use_mltext: string -> bool -> theory option -> unit
    64   val use_mltext_theory: string -> bool -> theory -> theory
    65   val use_let: string -> string -> string -> theory -> theory
    66   val add_setup: (theory -> theory) list -> unit
    67   val setup: unit -> (theory -> theory) list
    68   (*proof context*)
    69   type proof
    70   val theory_of_proof: proof -> theory
    71   val init_proof: theory -> proof
    72   val proof_data_of: theory -> string list
    73   (*generic context*)
    74   datatype context = Theory of theory | Proof of proof
    75   val theory_of: context -> theory
    76   val proof_of: context -> proof
    77 end;
    78 
    79 signature PRIVATE_CONTEXT =
    80 sig
    81   include CONTEXT
    82   structure TheoryData:
    83   sig
    84     val declare: string -> Object.T -> (Object.T -> Object.T) -> (Object.T -> Object.T) ->
    85       (Pretty.pp -> Object.T * Object.T -> Object.T) -> serial
    86     val init: serial -> theory -> theory
    87     val get: serial -> (Object.T -> 'a) -> theory -> 'a
    88     val put: serial -> ('a -> Object.T) -> 'a -> theory -> theory
    89   end
    90   structure ProofData:
    91   sig
    92     val declare: string -> (theory -> Object.T) -> serial
    93     val init: serial -> theory -> theory
    94     val get: serial -> (Object.T -> 'a) -> proof -> 'a
    95     val put: serial -> ('a -> Object.T) -> 'a -> proof -> proof
    96   end
    97 end;
    98 
    99 structure Context: PRIVATE_CONTEXT =
   100 struct
   101 
   102 (*** theory context ***)
   103 
   104 (** theory data **)
   105 
   106 (* data kinds and access methods *)
   107 
   108 exception DATA_FAIL of exn * string;
   109 
   110 local
   111 
   112 type kind =
   113  {name: string,
   114   empty: Object.T,
   115   copy: Object.T -> Object.T,
   116   extend: Object.T -> Object.T,
   117   merge: Pretty.pp -> Object.T * Object.T -> Object.T};
   118 
   119 val kinds = ref (Inttab.empty: kind Inttab.table);
   120 
   121 fun invoke meth_name meth_fn k =
   122   (case Inttab.lookup (! kinds, k) of
   123     SOME kind => meth_fn kind |> transform_failure (fn exn =>
   124       DATA_FAIL (exn, "Theory data method " ^ #name kind ^ "." ^ meth_name ^ " failed"))
   125   | NONE => sys_error ("Invalid theory data identifier " ^ string_of_int k));
   126 
   127 in
   128 
   129 fun invoke_name k    = invoke "name" (K o #name) k ();
   130 fun invoke_empty k   = invoke "empty" (K o #empty) k ();
   131 val invoke_copy      = invoke "copy" #copy;
   132 val invoke_extend    = invoke "extend" #extend;
   133 fun invoke_merge pp  = invoke "merge" (fn kind => #merge kind pp);
   134 
   135 fun declare_theory_data name empty copy extend merge =
   136   let
   137     val k = serial ();
   138     val kind = {name = name, empty = empty, copy = copy, extend = extend, merge = merge};
   139     val _ = conditional (Inttab.exists (equal name o #name o #2) (! kinds)) (fn () =>
   140       warning ("Duplicate declaration of theory data " ^ quote name));
   141     val _ = kinds := Inttab.update ((k, kind), ! kinds);
   142   in k end;
   143 
   144 val copy_data = Inttab.map' invoke_copy;
   145 val extend_data = Inttab.map' invoke_extend;
   146 fun merge_data pp = Inttab.join (SOME oo invoke_merge pp) o pairself extend_data;
   147 
   148 end;
   149 
   150 
   151 
   152 (** datatype theory **)
   153 
   154 datatype theory =
   155   Theory of
   156    (*identity*)
   157    {self: theory ref option,            (*dynamic self reference -- follows theory changes*)
   158     id: serial * string,                (*identifier of this theory*)
   159     ids: string Inttab.table,           (*identifiers of ancestors*)
   160     iids: string Inttab.table} *        (*identifiers of intermediate checkpoints*)
   161    (*data*)
   162    {theory: Object.T Inttab.table,      (*theory data record*)
   163     proof: unit Inttab.table} *         (*proof data kinds*)
   164    (*ancestry*)
   165    {parents: theory list,               (*immediate predecessors*)
   166     ancestors: theory list} *           (*all predecessors*)
   167    (*history*)
   168    {name: string,                       (*prospective name of finished theory*)
   169     version: int,                       (*checkpoint counter*)
   170     intermediates: theory list};        (*intermediate checkpoints*)
   171 
   172 exception THEORY of string * theory list;
   173 
   174 fun rep_theory (Theory args) = args;
   175 
   176 val identity_of = #1 o rep_theory;
   177 val data_of     = #2 o rep_theory;
   178 val ancestry_of = #3 o rep_theory;
   179 val history_of  = #4 o rep_theory;
   180 
   181 fun make_identity self id ids iids = {self = self, id = id, ids = ids, iids = iids};
   182 fun make_data theory proof = {theory = theory, proof = proof};
   183 fun make_ancestry parents ancestors = {parents = parents, ancestors = ancestors};
   184 fun make_history name vers ints = {name = name, version = vers, intermediates = ints};
   185 
   186 fun map_theory f {theory, proof} = make_data (f theory) proof;
   187 fun map_proof f {theory, proof} = make_data theory (f proof);
   188 
   189 val the_self = the o #self o identity_of;
   190 val parents_of = #parents o ancestry_of;
   191 val ancestors_of = #ancestors o ancestry_of;
   192 val theory_name = #name o history_of;
   193 
   194 
   195 (* staleness *)
   196 
   197 fun eq_id ((i: int, _), (j, _)) = (i = j);
   198 
   199 fun is_stale
   200     (Theory ({self = SOME (ref (Theory ({id = id', ...}, _, _, _))), id, ...}, _, _, _)) =
   201       not (eq_id (id, id'))
   202   | is_stale (Theory ({self = NONE, ...}, _, _, _)) = true;
   203 
   204 fun vitalize (thy as Theory ({self = SOME r, ...}, _, _, _)) = (r := thy; thy)
   205   | vitalize (thy as Theory ({self = NONE, id, ids, iids}, data, ancestry, history)) =
   206       let
   207         val r = ref thy;
   208         val thy' = Theory (make_identity (SOME r) id ids iids, data, ancestry, history);
   209       in r := thy'; thy' end;
   210 
   211 
   212 (* names *)
   213 
   214 val ProtoPureN = "ProtoPure";
   215 val PureN = "Pure";
   216 val CPureN = "CPure";
   217 
   218 val draftN = "#";
   219 fun draft_id (_, name) = (name = draftN);
   220 val is_draft = draft_id o #id o identity_of;
   221 
   222 fun exists_name name (Theory ({id, ids, iids, ...}, _, _, _)) =
   223   name = #2 id orelse
   224   Inttab.exists (equal name o #2) ids orelse
   225   Inttab.exists (equal name o #2) iids;
   226 
   227 fun names_of (Theory ({id, ids, iids, ...}, _, _, _)) =
   228   rev (#2 id :: Inttab.fold (cons o #2) iids (Inttab.fold (cons o #2) ids []));
   229 
   230 fun pretty_thy thy =
   231   Pretty.str_list "{" "}" (names_of thy @ (if is_stale thy then ["!"] else []));
   232 
   233 val string_of_thy = Pretty.string_of o pretty_thy;
   234 val pprint_thy = Pretty.pprint o pretty_thy;
   235 
   236 fun pretty_abbrev_thy thy =
   237   let
   238     val names = names_of thy;
   239     val n = length names;
   240     val abbrev = if n > 5 then "..." :: List.drop (names, n - 5) else names;
   241   in Pretty.str_list "{" "}" abbrev end;
   242 
   243 val str_of_thy = Pretty.str_of o pretty_abbrev_thy;
   244 
   245 
   246 (* consistency *)    (*exception TERM*)
   247 
   248 fun check_thy pos thy =
   249   if is_stale thy then
   250     raise TERM ("Stale theory encountered (in " ^ pos ^ "):\n" ^ string_of_thy thy, [])
   251   else thy;
   252 
   253 fun check_ins id ids =
   254   if draft_id id orelse is_some (Inttab.lookup (ids, #1 id)) then ids
   255   else if Inttab.exists (equal (#2 id) o #2) ids then
   256     raise TERM ("Different versions of theory component " ^ quote (#2 id), [])
   257   else Inttab.update (id, ids);
   258 
   259 fun check_insert intermediate id (ids, iids) =
   260   let val ids' = check_ins id ids and iids' = check_ins id iids
   261   in if intermediate then (ids, iids') else (ids', iids) end;
   262 
   263 fun check_merge
   264     (Theory ({id = id1, ids = ids1, iids = iids1, ...}, _, _, history1))
   265     (Theory ({id = id2, ids = ids2, iids = iids2, ...}, _, _, history2)) =
   266   (Inttab.fold check_ins ids2 ids1, Inttab.fold check_ins iids2 iids1)
   267   |> check_insert (#version history1 > 0) id1
   268   |> check_insert (#version history2 > 0) id2;
   269 
   270 
   271 (* equality and inclusion *)
   272 
   273 val eq_thy = eq_id o pairself (#id o identity_of o check_thy "Context.eq_thy");
   274 
   275 fun proper_subthy
   276   (thy1 as Theory ({id = (i, _), ...}, _, _, _),
   277     thy2 as Theory ({ids, iids, ...}, _, _, _)) =
   278   (pairself (check_thy "Context.proper_subthy") (thy1, thy2);
   279     is_some (Inttab.lookup (ids, i)) orelse is_some (Inttab.lookup (iids, i)));
   280 
   281 fun subthy thys = eq_thy thys orelse proper_subthy thys;
   282 
   283 fun joinable (thy1, thy2) = subthy (thy1, thy2) orelse subthy (thy2, thy1);
   284 
   285 
   286 (* theory references *)
   287 
   288 (*theory_ref provides a safe way to store dynamic references to a
   289   theory in external data structures -- a plain theory value would
   290   become stale as the self reference moves on*)
   291 
   292 datatype theory_ref = TheoryRef of theory ref;
   293 
   294 val self_ref = TheoryRef o the_self o check_thy "Context.self_ref";
   295 fun deref (TheoryRef (ref thy)) = thy;
   296 
   297 
   298 (* trivial merge *)    (*exception TERM*)
   299 
   300 fun merge (thy1, thy2) =
   301   if subthy (thy2, thy1) then thy1
   302   else if subthy (thy1, thy2) then thy2
   303   else (check_merge thy1 thy2;
   304     raise TERM (cat_lines ["Attempt to perform non-trivial merge of theories:",
   305       str_of_thy thy1, str_of_thy thy2], []));
   306 
   307 fun merge_refs (ref1, ref2) = self_ref (merge (deref ref1, deref ref2));
   308 
   309 
   310 
   311 (** build theories **)
   312 
   313 (* primitives *)
   314 
   315 fun create_thy name self id ids iids data ancestry history =
   316   let
   317     val intermediate = #version history > 0;
   318     val (ids', iids') = check_insert intermediate id (ids, iids);
   319     val id' = (serial (), name);
   320     val _ = check_insert intermediate id' (ids', iids');
   321     val identity' = make_identity self id' ids' iids';
   322   in vitalize (Theory (identity', data, ancestry, history)) end;
   323 
   324 fun change_thy name f (thy as Theory ({self, id, ids, iids}, data, ancestry, history)) =
   325   let
   326     val _ = check_thy "Context.change_thy" thy;
   327     val (self', data', ancestry') =
   328       if is_draft thy then (self, data, ancestry)    (*destructive change!*)
   329       else if #version history > 0
   330       then (NONE, map_theory copy_data data, ancestry)
   331       else (NONE, map_theory extend_data data, make_ancestry [thy] (thy :: #ancestors ancestry));
   332     val data'' = f data';
   333   in create_thy name self' id ids iids data'' ancestry' history end;
   334 
   335 fun name_thy name = change_thy name I;
   336 val modify_thy = change_thy draftN;
   337 val extend_thy = modify_thy I;
   338 
   339 fun copy_thy (thy as Theory ({id, ids, iids, ...}, data, ancestry, history)) =
   340   (check_thy "Context.copy_thy" thy;
   341     create_thy draftN NONE id ids iids (map_theory copy_data data) ancestry history);
   342 
   343 val pre_pure_thy = create_thy draftN NONE (serial (), draftN) Inttab.empty Inttab.empty
   344   (make_data Inttab.empty Inttab.empty) (make_ancestry [] []) (make_history ProtoPureN 0 []);
   345 
   346 
   347 (* named theory nodes *)
   348 
   349 fun merge_thys pp (thy1, thy2) =
   350   if exists_name CPureN thy1 <> exists_name CPureN thy2 then
   351     error "Cannot merge Pure and CPure developments"
   352   else
   353     let
   354       val (ids, iids) = check_merge thy1 thy2;
   355       val data1 = data_of thy1 and data2 = data_of thy2;
   356       val data = make_data
   357         (merge_data (pp thy1) (#theory data1, #theory data2))
   358         (Inttab.merge (K true) (#proof data1, #proof data2));
   359       val ancestry = make_ancestry [] [];
   360       val history = make_history "" 0 [];
   361     in create_thy draftN NONE (serial (), draftN) ids iids data ancestry history end;
   362 
   363 fun maximal_thys thys =
   364   thys |> filter (fn thy => not (exists (fn thy' => proper_subthy (thy, thy')) thys));
   365 
   366 fun begin_thy pp name imports =
   367   if name = draftN then error ("Illegal theory name: " ^ quote draftN)
   368   else
   369     let
   370       val parents =
   371         maximal_thys (gen_distinct eq_thy (map (check_thy "Context.begin_thy") imports));
   372       val ancestors = gen_distinct eq_thy (parents @ List.concat (map ancestors_of parents));
   373       val Theory ({id, ids, iids, ...}, data, _, _) =
   374         (case parents of
   375           [] => error "No parent theories"
   376         | [thy] => extend_thy thy
   377         | thy :: thys => Library.foldl (merge_thys pp) (thy, thys));
   378       val ancestry = make_ancestry parents ancestors;
   379       val history = make_history name 0 [];
   380     in create_thy draftN NONE id ids iids data ancestry history end;
   381 
   382 
   383 (* undoable checkpoints *)
   384 
   385 fun checkpoint_thy thy =
   386   if not (is_draft thy) then thy
   387   else
   388     let
   389       val {name, version, intermediates} = history_of thy;
   390       val thy' as Theory (identity', data', ancestry', _) =
   391         name_thy (name ^ ":" ^ string_of_int version) thy;
   392       val history' = make_history name (version + 1) (thy' :: intermediates);
   393     in vitalize (Theory (identity', data', ancestry', history')) end;
   394 
   395 fun finish_thy thy =
   396   let
   397     val {name, version, intermediates} = history_of thy;
   398     val rs = map (the_self o check_thy "Context.finish_thy") intermediates;
   399     val thy' as Theory ({self, id, ids, ...}, data', ancestry', _) = name_thy name thy;
   400     val identity' = make_identity self id ids Inttab.empty;
   401     val history' = make_history name 0 [];
   402     val thy'' = vitalize (Theory (identity', data', ancestry', history'));
   403     val _ = List.app (fn r => r := thy'') rs;
   404   in thy'' end;
   405 
   406 
   407 (* theory data *)
   408 
   409 fun dest_data name_of tab =
   410   map name_of (Inttab.keys tab)
   411   |> map (rpair ()) |> Symtab.make_multi |> Symtab.dest
   412   |> map (apsnd length)
   413   |> map (fn (name, 1) => name | (name, n) => name ^ enclose "[" "]" (string_of_int n));
   414 
   415 val theory_data_of = dest_data invoke_name o #theory o data_of;
   416 
   417 structure TheoryData =
   418 struct
   419 
   420 val declare = declare_theory_data;
   421 
   422 fun get k dest thy =
   423   (case Inttab.lookup (#theory (data_of thy), k) of
   424     SOME x => (dest x handle Match =>
   425       error ("Failed to access theory data " ^ quote (invoke_name k)))
   426   | NONE => error ("Uninitialized theory data " ^ quote (invoke_name k)));
   427 
   428 fun put k mk x = modify_thy (map_theory (curry Inttab.update (k, mk x)));
   429 fun init k = put k I (invoke_empty k);
   430 
   431 end;
   432 
   433 
   434 
   435 (*** ML theory context ***)
   436 
   437 local
   438   val current_theory = ref (NONE: theory option);
   439 in
   440   fun get_context () = ! current_theory;
   441   fun set_context opt_thy = current_theory := opt_thy;
   442   fun setmp opt_thy f x = Library.setmp current_theory opt_thy f x;
   443 end;
   444 
   445 fun the_context () =
   446   (case get_context () of
   447     SOME thy => thy
   448   | _ => error "Unknown theory context");
   449 
   450 fun context thy = set_context (SOME thy);
   451 fun reset_context () = set_context NONE;
   452 
   453 fun pass opt_thy f x =
   454   setmp opt_thy (fn x => let val y = f x in (y, get_context ()) end) x;
   455 
   456 fun pass_theory thy f x =
   457   (case pass (SOME thy) f x of
   458     (y, SOME thy') => (y, thy')
   459   | (_, NONE) => error "Lost theory context in ML");
   460 
   461 fun save f x = setmp (get_context ()) f x;
   462 
   463 
   464 (* map context *)
   465 
   466 nonfix >>;
   467 fun >> f = set_context (SOME (f (the_context ())));
   468 
   469 
   470 (* use ML text *)
   471 
   472 val ml_output = (writeln, error_msg);
   473 
   474 fun use_output verb txt = use_text ml_output verb (Symbol.escape txt);
   475 
   476 fun use_mltext txt verb opt_thy = setmp opt_thy (fn () => use_output verb txt) ();
   477 fun use_mltext_theory txt verb thy = #2 (pass_theory thy (use_output verb) txt);
   478 
   479 fun use_context txt = use_mltext_theory ("Context.>> (" ^ txt ^ ");") false;
   480 
   481 fun use_let bind body txt =
   482   use_context ("let " ^ bind ^ " = " ^ txt ^ " in\n" ^ body ^ " end");
   483 
   484 
   485 (* delayed theory setup *)
   486 
   487 local
   488   val setup_fns = ref ([]: (theory -> theory) list);
   489 in
   490   fun add_setup fns = setup_fns := ! setup_fns @ fns;
   491   fun setup () = let val fns = ! setup_fns in setup_fns := []; fns end;
   492 end;
   493 
   494 
   495 
   496 (*** proof context ***)
   497 
   498 (* datatype proof *)
   499 
   500 datatype proof = Proof of theory * Object.T Inttab.table;
   501 
   502 fun theory_of_proof (Proof (thy, _)) = thy;
   503 fun data_of_proof (Proof (_, data)) = data;
   504 fun map_prf f (Proof (thy, data)) = Proof (thy, f data);
   505 
   506 
   507 (* proof data kinds *)
   508 
   509 local
   510 
   511 type kind =
   512  {name: string,
   513   init: theory -> Object.T};
   514 
   515 val kinds = ref (Inttab.empty: kind Inttab.table);
   516 
   517 fun invoke meth_name meth_fn k =
   518   (case Inttab.lookup (! kinds, k) of
   519     SOME kind => meth_fn kind |> transform_failure (fn exn =>
   520       DATA_FAIL (exn, "Proof data method " ^ #name kind ^ "." ^ meth_name ^ " failed"))
   521   | NONE => sys_error ("Invalid proof data identifier " ^ string_of_int k));
   522 
   523 fun invoke_name k = invoke "name" (K o #name) k ();
   524 val invoke_init   = invoke "init" #init;
   525 
   526 in
   527 
   528 val proof_data_of = dest_data invoke_name o #proof o data_of;
   529 
   530 fun init_proof thy =
   531   Proof (thy, Inttab.map' (fn k => fn _ => invoke_init k thy) (#proof (data_of thy)));
   532 
   533 structure ProofData =
   534 struct
   535 
   536 fun declare name init =
   537   let
   538     val k = serial ();
   539     val kind = {name = name, init = init};
   540     val _ = conditional (Inttab.exists (equal name o #name o #2) (! kinds)) (fn () =>
   541       warning ("Duplicate declaration of proof data " ^ quote name));
   542     val _ = kinds := Inttab.update ((k, kind), ! kinds);
   543   in k end;
   544 
   545 fun init k = modify_thy (map_proof (curry Inttab.update (k, ())));
   546 
   547 fun get k dest prf =
   548   (case Inttab.lookup (data_of_proof prf, k) of
   549     SOME x => (dest x handle Match =>
   550       error ("Failed to access proof data " ^ quote (invoke_name k)))
   551   | NONE => error ("Uninitialized proof data " ^ quote (invoke_name k)));
   552 
   553 fun put k mk x = map_prf (curry Inttab.update (k, mk x));
   554 
   555 end;
   556 
   557 end;
   558 
   559 
   560 (*** generic context ***)
   561 
   562 datatype context = Theory of theory | Proof of proof;
   563 
   564 fun theory_of (Theory thy) = thy
   565   | theory_of (Proof prf) = theory_of_proof prf;
   566 
   567 fun proof_of (Theory thy) = init_proof thy
   568   | proof_of (Proof prf) = prf;
   569 
   570 end;
   571 
   572 structure BasicContext: BASIC_CONTEXT = Context;
   573 open BasicContext;
   574 
   575 
   576 
   577 (*** type-safe interfaces for data declarations ***)
   578 
   579 (** theory data **)
   580 
   581 signature THEORY_DATA_ARGS =
   582 sig
   583   val name: string
   584   type T
   585   val empty: T
   586   val copy: T -> T
   587   val extend: T -> T
   588   val merge: Pretty.pp -> T * T -> T
   589   val print: theory -> T -> unit
   590 end;
   591 
   592 signature THEORY_DATA =
   593 sig
   594   type T
   595   val init: theory -> theory
   596   val print: theory -> unit
   597   val get: theory -> T
   598   val get_sg: theory -> T    (*obsolete*)
   599   val put: T -> theory -> theory
   600   val map: (T -> T) -> theory -> theory
   601 end;
   602 
   603 functor TheoryDataFun(Data: THEORY_DATA_ARGS): THEORY_DATA =
   604 struct
   605 
   606 structure TheoryData = Context.TheoryData;
   607 
   608 type T = Data.T;
   609 exception Data of T;
   610 
   611 val kind = TheoryData.declare Data.name
   612   (Data Data.empty)
   613   (fn Data x => Data (Data.copy x))
   614   (fn Data x => Data (Data.extend x))
   615   (fn pp => fn (Data x1, Data x2) => Data (Data.merge pp (x1, x2)));
   616 
   617 val init = TheoryData.init kind;
   618 val get = TheoryData.get kind (fn Data x => x);
   619 val get_sg = get;
   620 fun print thy = Data.print thy (get thy);
   621 val put = TheoryData.put kind Data;
   622 fun map f thy = put (f (get thy)) thy;
   623 
   624 end;
   625 
   626 
   627 
   628 (** proof data **)
   629 
   630 signature PROOF_DATA_ARGS =
   631 sig
   632   val name: string
   633   type T
   634   val init: theory -> T
   635   val print: Context.proof -> T -> unit
   636 end;
   637 
   638 signature PROOF_DATA =
   639 sig
   640   type T
   641   val init: theory -> theory
   642   val print: Context.proof -> unit
   643   val get: Context.proof -> T
   644   val put: T -> Context.proof -> Context.proof
   645   val map: (T -> T) -> Context.proof -> Context.proof
   646 end;
   647 
   648 functor ProofDataFun(Data: PROOF_DATA_ARGS): PROOF_DATA =
   649 struct
   650 
   651 structure ProofData = Context.ProofData;
   652 
   653 type T = Data.T;
   654 exception Data of T;
   655 
   656 val kind = ProofData.declare Data.name (Data o Data.init);
   657 
   658 val init = ProofData.init kind;
   659 val get = ProofData.get kind (fn Data x => x);
   660 fun print prf = Data.print prf (get prf);
   661 val put = ProofData.put kind Data;
   662 fun map f prf = put (f (get prf)) prf;
   663 
   664 end;
   665 
   666 (*hide private interface*)
   667 structure Context: CONTEXT = Context;