src/HOL/Rings.thy
author haftmann
Sat Nov 08 16:53:26 2014 +0100 (2014-11-08)
changeset 58952 5d82cdef6c1b
parent 58889 5b7a9633cfa8
child 59000 6eb0725503fc
permissions -rw-r--r--
equivalence rules for structures without zero divisors
     1 (*  Title:      HOL/Rings.thy
     2     Author:     Gertrud Bauer
     3     Author:     Steven Obua
     4     Author:     Tobias Nipkow
     5     Author:     Lawrence C Paulson
     6     Author:     Markus Wenzel
     7     Author:     Jeremy Avigad
     8 *)
     9 
    10 section {* Rings *}
    11 
    12 theory Rings
    13 imports Groups
    14 begin
    15 
    16 class semiring = ab_semigroup_add + semigroup_mult +
    17   assumes distrib_right[algebra_simps]: "(a + b) * c = a * c + b * c"
    18   assumes distrib_left[algebra_simps]: "a * (b + c) = a * b + a * c"
    19 begin
    20 
    21 text{*For the @{text combine_numerals} simproc*}
    22 lemma combine_common_factor:
    23   "a * e + (b * e + c) = (a + b) * e + c"
    24 by (simp add: distrib_right ac_simps)
    25 
    26 end
    27 
    28 class mult_zero = times + zero +
    29   assumes mult_zero_left [simp]: "0 * a = 0"
    30   assumes mult_zero_right [simp]: "a * 0 = 0"
    31 begin
    32 
    33 lemma mult_not_zero:
    34   "a * b \<noteq> 0 \<Longrightarrow> a \<noteq> 0 \<and> b \<noteq> 0"
    35   by auto
    36 
    37 end
    38 
    39 class semiring_0 = semiring + comm_monoid_add + mult_zero
    40 
    41 class semiring_0_cancel = semiring + cancel_comm_monoid_add
    42 begin
    43 
    44 subclass semiring_0
    45 proof
    46   fix a :: 'a
    47   have "0 * a + 0 * a = 0 * a + 0" by (simp add: distrib_right [symmetric])
    48   thus "0 * a = 0" by (simp only: add_left_cancel)
    49 next
    50   fix a :: 'a
    51   have "a * 0 + a * 0 = a * 0 + 0" by (simp add: distrib_left [symmetric])
    52   thus "a * 0 = 0" by (simp only: add_left_cancel)
    53 qed
    54 
    55 end
    56 
    57 class comm_semiring = ab_semigroup_add + ab_semigroup_mult +
    58   assumes distrib: "(a + b) * c = a * c + b * c"
    59 begin
    60 
    61 subclass semiring
    62 proof
    63   fix a b c :: 'a
    64   show "(a + b) * c = a * c + b * c" by (simp add: distrib)
    65   have "a * (b + c) = (b + c) * a" by (simp add: ac_simps)
    66   also have "... = b * a + c * a" by (simp only: distrib)
    67   also have "... = a * b + a * c" by (simp add: ac_simps)
    68   finally show "a * (b + c) = a * b + a * c" by blast
    69 qed
    70 
    71 end
    72 
    73 class comm_semiring_0 = comm_semiring + comm_monoid_add + mult_zero
    74 begin
    75 
    76 subclass semiring_0 ..
    77 
    78 end
    79 
    80 class comm_semiring_0_cancel = comm_semiring + cancel_comm_monoid_add
    81 begin
    82 
    83 subclass semiring_0_cancel ..
    84 
    85 subclass comm_semiring_0 ..
    86 
    87 end
    88 
    89 class zero_neq_one = zero + one +
    90   assumes zero_neq_one [simp]: "0 \<noteq> 1"
    91 begin
    92 
    93 lemma one_neq_zero [simp]: "1 \<noteq> 0"
    94 by (rule not_sym) (rule zero_neq_one)
    95 
    96 definition of_bool :: "bool \<Rightarrow> 'a"
    97 where
    98   "of_bool p = (if p then 1 else 0)" 
    99 
   100 lemma of_bool_eq [simp, code]:
   101   "of_bool False = 0"
   102   "of_bool True = 1"
   103   by (simp_all add: of_bool_def)
   104 
   105 lemma of_bool_eq_iff:
   106   "of_bool p = of_bool q \<longleftrightarrow> p = q"
   107   by (simp add: of_bool_def)
   108 
   109 lemma split_of_bool [split]:
   110   "P (of_bool p) \<longleftrightarrow> (p \<longrightarrow> P 1) \<and> (\<not> p \<longrightarrow> P 0)"
   111   by (cases p) simp_all
   112 
   113 lemma split_of_bool_asm:
   114   "P (of_bool p) \<longleftrightarrow> \<not> (p \<and> \<not> P 1 \<or> \<not> p \<and> \<not> P 0)"
   115   by (cases p) simp_all
   116   
   117 end  
   118 
   119 class semiring_1 = zero_neq_one + semiring_0 + monoid_mult
   120 
   121 text {* Abstract divisibility *}
   122 
   123 class dvd = times
   124 begin
   125 
   126 definition dvd :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infix "dvd" 50) where
   127   "b dvd a \<longleftrightarrow> (\<exists>k. a = b * k)"
   128 
   129 lemma dvdI [intro?]: "a = b * k \<Longrightarrow> b dvd a"
   130   unfolding dvd_def ..
   131 
   132 lemma dvdE [elim?]: "b dvd a \<Longrightarrow> (\<And>k. a = b * k \<Longrightarrow> P) \<Longrightarrow> P"
   133   unfolding dvd_def by blast 
   134 
   135 end
   136 
   137 class comm_semiring_1 = zero_neq_one + comm_semiring_0 + comm_monoid_mult + dvd
   138   (*previously almost_semiring*)
   139 begin
   140 
   141 subclass semiring_1 ..
   142 
   143 lemma dvd_refl[simp]: "a dvd a"
   144 proof
   145   show "a = a * 1" by simp
   146 qed
   147 
   148 lemma dvd_trans:
   149   assumes "a dvd b" and "b dvd c"
   150   shows "a dvd c"
   151 proof -
   152   from assms obtain v where "b = a * v" by (auto elim!: dvdE)
   153   moreover from assms obtain w where "c = b * w" by (auto elim!: dvdE)
   154   ultimately have "c = a * (v * w)" by (simp add: mult.assoc)
   155   then show ?thesis ..
   156 qed
   157 
   158 lemma dvd_0_left_iff [simp]: "0 dvd a \<longleftrightarrow> a = 0"
   159 by (auto intro: dvd_refl elim!: dvdE)
   160 
   161 lemma dvd_0_right [iff]: "a dvd 0"
   162 proof
   163   show "0 = a * 0" by simp
   164 qed
   165 
   166 lemma one_dvd [simp]: "1 dvd a"
   167 by (auto intro!: dvdI)
   168 
   169 lemma dvd_mult[simp]: "a dvd c \<Longrightarrow> a dvd (b * c)"
   170 by (auto intro!: mult.left_commute dvdI elim!: dvdE)
   171 
   172 lemma dvd_mult2[simp]: "a dvd b \<Longrightarrow> a dvd (b * c)"
   173   apply (subst mult.commute)
   174   apply (erule dvd_mult)
   175   done
   176 
   177 lemma dvd_triv_right [simp]: "a dvd b * a"
   178 by (rule dvd_mult) (rule dvd_refl)
   179 
   180 lemma dvd_triv_left [simp]: "a dvd a * b"
   181 by (rule dvd_mult2) (rule dvd_refl)
   182 
   183 lemma mult_dvd_mono:
   184   assumes "a dvd b"
   185     and "c dvd d"
   186   shows "a * c dvd b * d"
   187 proof -
   188   from `a dvd b` obtain b' where "b = a * b'" ..
   189   moreover from `c dvd d` obtain d' where "d = c * d'" ..
   190   ultimately have "b * d = (a * c) * (b' * d')" by (simp add: ac_simps)
   191   then show ?thesis ..
   192 qed
   193 
   194 lemma dvd_mult_left: "a * b dvd c \<Longrightarrow> a dvd c"
   195 by (simp add: dvd_def mult.assoc, blast)
   196 
   197 lemma dvd_mult_right: "a * b dvd c \<Longrightarrow> b dvd c"
   198   unfolding mult.commute [of a] by (rule dvd_mult_left)
   199 
   200 lemma dvd_0_left: "0 dvd a \<Longrightarrow> a = 0"
   201 by simp
   202 
   203 lemma dvd_add[simp]:
   204   assumes "a dvd b" and "a dvd c" shows "a dvd (b + c)"
   205 proof -
   206   from `a dvd b` obtain b' where "b = a * b'" ..
   207   moreover from `a dvd c` obtain c' where "c = a * c'" ..
   208   ultimately have "b + c = a * (b' + c')" by (simp add: distrib_left)
   209   then show ?thesis ..
   210 qed
   211 
   212 end
   213 
   214 class semiring_dvd = comm_semiring_1 +
   215   assumes dvd_add_times_triv_left_iff [simp]: "a dvd c * a + b \<longleftrightarrow> a dvd b"
   216   assumes dvd_addD: "a dvd b + c \<Longrightarrow> a dvd b \<Longrightarrow> a dvd c"
   217 begin
   218 
   219 lemma dvd_add_times_triv_right_iff [simp]:
   220   "a dvd b + c * a \<longleftrightarrow> a dvd b"
   221   using dvd_add_times_triv_left_iff [of a c b] by (simp add: ac_simps)
   222 
   223 lemma dvd_add_triv_left_iff [simp]:
   224   "a dvd a + b \<longleftrightarrow> a dvd b"
   225   using dvd_add_times_triv_left_iff [of a 1 b] by simp
   226 
   227 lemma dvd_add_triv_right_iff [simp]:
   228   "a dvd b + a \<longleftrightarrow> a dvd b"
   229   using dvd_add_times_triv_right_iff [of a b 1] by simp
   230 
   231 lemma dvd_add_right_iff:
   232   assumes "a dvd b"
   233   shows "a dvd b + c \<longleftrightarrow> a dvd c"
   234   using assms by (auto dest: dvd_addD)
   235 
   236 lemma dvd_add_left_iff:
   237   assumes "a dvd c"
   238   shows "a dvd b + c \<longleftrightarrow> a dvd b"
   239   using assms dvd_add_right_iff [of a c b] by (simp add: ac_simps)
   240 
   241 end
   242 
   243 class no_zero_divisors = zero + times +
   244   assumes no_zero_divisors: "a \<noteq> 0 \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> a * b \<noteq> 0"
   245 begin
   246 
   247 lemma divisors_zero:
   248   assumes "a * b = 0"
   249   shows "a = 0 \<or> b = 0"
   250 proof (rule classical)
   251   assume "\<not> (a = 0 \<or> b = 0)"
   252   then have "a \<noteq> 0" and "b \<noteq> 0" by auto
   253   with no_zero_divisors have "a * b \<noteq> 0" by blast
   254   with assms show ?thesis by simp
   255 qed
   256 
   257 end
   258 
   259 class semiring_1_cancel = semiring + cancel_comm_monoid_add
   260   + zero_neq_one + monoid_mult
   261 begin
   262 
   263 subclass semiring_0_cancel ..
   264 
   265 subclass semiring_1 ..
   266 
   267 end
   268 
   269 class comm_semiring_1_cancel = comm_semiring + cancel_comm_monoid_add
   270   + zero_neq_one + comm_monoid_mult
   271 begin
   272 
   273 subclass semiring_1_cancel ..
   274 subclass comm_semiring_0_cancel ..
   275 subclass comm_semiring_1 ..
   276 
   277 end
   278 
   279 class ring = semiring + ab_group_add
   280 begin
   281 
   282 subclass semiring_0_cancel ..
   283 
   284 text {* Distribution rules *}
   285 
   286 lemma minus_mult_left: "- (a * b) = - a * b"
   287 by (rule minus_unique) (simp add: distrib_right [symmetric]) 
   288 
   289 lemma minus_mult_right: "- (a * b) = a * - b"
   290 by (rule minus_unique) (simp add: distrib_left [symmetric]) 
   291 
   292 text{*Extract signs from products*}
   293 lemmas mult_minus_left [simp] = minus_mult_left [symmetric]
   294 lemmas mult_minus_right [simp] = minus_mult_right [symmetric]
   295 
   296 lemma minus_mult_minus [simp]: "- a * - b = a * b"
   297 by simp
   298 
   299 lemma minus_mult_commute: "- a * b = a * - b"
   300 by simp
   301 
   302 lemma right_diff_distrib [algebra_simps]:
   303   "a * (b - c) = a * b - a * c"
   304   using distrib_left [of a b "-c "] by simp
   305 
   306 lemma left_diff_distrib [algebra_simps]:
   307   "(a - b) * c = a * c - b * c"
   308   using distrib_right [of a "- b" c] by simp
   309 
   310 lemmas ring_distribs =
   311   distrib_left distrib_right left_diff_distrib right_diff_distrib
   312 
   313 lemma eq_add_iff1:
   314   "a * e + c = b * e + d \<longleftrightarrow> (a - b) * e + c = d"
   315 by (simp add: algebra_simps)
   316 
   317 lemma eq_add_iff2:
   318   "a * e + c = b * e + d \<longleftrightarrow> c = (b - a) * e + d"
   319 by (simp add: algebra_simps)
   320 
   321 end
   322 
   323 lemmas ring_distribs =
   324   distrib_left distrib_right left_diff_distrib right_diff_distrib
   325 
   326 class comm_ring = comm_semiring + ab_group_add
   327 begin
   328 
   329 subclass ring ..
   330 subclass comm_semiring_0_cancel ..
   331 
   332 lemma square_diff_square_factored:
   333   "x * x - y * y = (x + y) * (x - y)"
   334   by (simp add: algebra_simps)
   335 
   336 end
   337 
   338 class ring_1 = ring + zero_neq_one + monoid_mult
   339 begin
   340 
   341 subclass semiring_1_cancel ..
   342 
   343 lemma square_diff_one_factored:
   344   "x * x - 1 = (x + 1) * (x - 1)"
   345   by (simp add: algebra_simps)
   346 
   347 end
   348 
   349 class comm_ring_1 = comm_ring + zero_neq_one + comm_monoid_mult
   350   (*previously ring*)
   351 begin
   352 
   353 subclass ring_1 ..
   354 subclass comm_semiring_1_cancel ..
   355 
   356 subclass semiring_dvd
   357 proof
   358   fix a b c
   359   show "a dvd c * a + b \<longleftrightarrow> a dvd b" (is "?P \<longleftrightarrow> ?Q")
   360   proof
   361     assume ?Q then show ?P by simp
   362   next
   363     assume ?P then obtain d where "c * a + b = a * d" ..
   364     then have "b = a * (d - c)" by (simp add: algebra_simps)
   365     then show ?Q ..
   366   qed
   367   assume "a dvd b + c" and "a dvd b"
   368   show "a dvd c"
   369   proof -
   370     from `a dvd b` obtain d where "b = a * d" ..
   371     moreover from `a dvd b + c` obtain e where "b + c = a * e" ..
   372     ultimately have "a * d + c = a * e" by simp
   373     then have "c = a * (e - d)" by (simp add: algebra_simps)
   374     then show "a dvd c" ..
   375   qed
   376 qed
   377 
   378 lemma dvd_minus_iff [simp]: "x dvd - y \<longleftrightarrow> x dvd y"
   379 proof
   380   assume "x dvd - y"
   381   then have "x dvd - 1 * - y" by (rule dvd_mult)
   382   then show "x dvd y" by simp
   383 next
   384   assume "x dvd y"
   385   then have "x dvd - 1 * y" by (rule dvd_mult)
   386   then show "x dvd - y" by simp
   387 qed
   388 
   389 lemma minus_dvd_iff [simp]: "- x dvd y \<longleftrightarrow> x dvd y"
   390 proof
   391   assume "- x dvd y"
   392   then obtain k where "y = - x * k" ..
   393   then have "y = x * - k" by simp
   394   then show "x dvd y" ..
   395 next
   396   assume "x dvd y"
   397   then obtain k where "y = x * k" ..
   398   then have "y = - x * - k" by simp
   399   then show "- x dvd y" ..
   400 qed
   401 
   402 lemma dvd_diff [simp]:
   403   "x dvd y \<Longrightarrow> x dvd z \<Longrightarrow> x dvd (y - z)"
   404   using dvd_add [of x y "- z"] by simp
   405 
   406 end
   407 
   408 class semiring_no_zero_divisors = semiring_0 + no_zero_divisors
   409 begin
   410 
   411 lemma mult_eq_0_iff [simp]:
   412   shows "a * b = 0 \<longleftrightarrow> a = 0 \<or> b = 0"
   413 proof (cases "a = 0 \<or> b = 0")
   414   case False then have "a \<noteq> 0" and "b \<noteq> 0" by auto
   415     then show ?thesis using no_zero_divisors by simp
   416 next
   417   case True then show ?thesis by auto
   418 qed
   419 
   420 end
   421 
   422 class ring_no_zero_divisors = ring + semiring_no_zero_divisors
   423 begin
   424 
   425 text{*Cancellation of equalities with a common factor*}
   426 lemma mult_cancel_right [simp]:
   427   "a * c = b * c \<longleftrightarrow> c = 0 \<or> a = b"
   428 proof -
   429   have "(a * c = b * c) = ((a - b) * c = 0)"
   430     by (simp add: algebra_simps)
   431   thus ?thesis by (simp add: disj_commute)
   432 qed
   433 
   434 lemma mult_cancel_left [simp]:
   435   "c * a = c * b \<longleftrightarrow> c = 0 \<or> a = b"
   436 proof -
   437   have "(c * a = c * b) = (c * (a - b) = 0)"
   438     by (simp add: algebra_simps)
   439   thus ?thesis by simp
   440 qed
   441 
   442 lemma mult_left_cancel:
   443   "c \<noteq> 0 \<Longrightarrow> c * a = c * b \<longleftrightarrow> a = b"
   444   by simp 
   445 
   446 lemma mult_right_cancel:
   447   "c \<noteq> 0 \<Longrightarrow> a * c = b * c \<longleftrightarrow> a = b"
   448   by simp 
   449 
   450 end
   451 
   452 class ring_1_no_zero_divisors = ring_1 + ring_no_zero_divisors
   453 begin
   454 
   455 lemma square_eq_1_iff:
   456   "x * x = 1 \<longleftrightarrow> x = 1 \<or> x = - 1"
   457 proof -
   458   have "(x - 1) * (x + 1) = x * x - 1"
   459     by (simp add: algebra_simps)
   460   hence "x * x = 1 \<longleftrightarrow> (x - 1) * (x + 1) = 0"
   461     by simp
   462   thus ?thesis
   463     by (simp add: eq_neg_iff_add_eq_0)
   464 qed
   465 
   466 lemma mult_cancel_right1 [simp]:
   467   "c = b * c \<longleftrightarrow> c = 0 \<or> b = 1"
   468 by (insert mult_cancel_right [of 1 c b], force)
   469 
   470 lemma mult_cancel_right2 [simp]:
   471   "a * c = c \<longleftrightarrow> c = 0 \<or> a = 1"
   472 by (insert mult_cancel_right [of a c 1], simp)
   473  
   474 lemma mult_cancel_left1 [simp]:
   475   "c = c * b \<longleftrightarrow> c = 0 \<or> b = 1"
   476 by (insert mult_cancel_left [of c 1 b], force)
   477 
   478 lemma mult_cancel_left2 [simp]:
   479   "c * a = c \<longleftrightarrow> c = 0 \<or> a = 1"
   480 by (insert mult_cancel_left [of c a 1], simp)
   481 
   482 end
   483 
   484 class idom = comm_ring_1 + no_zero_divisors
   485 begin
   486 
   487 subclass ring_1_no_zero_divisors ..
   488 
   489 lemma square_eq_iff: "a * a = b * b \<longleftrightarrow> (a = b \<or> a = - b)"
   490 proof
   491   assume "a * a = b * b"
   492   then have "(a - b) * (a + b) = 0"
   493     by (simp add: algebra_simps)
   494   then show "a = b \<or> a = - b"
   495     by (simp add: eq_neg_iff_add_eq_0)
   496 next
   497   assume "a = b \<or> a = - b"
   498   then show "a * a = b * b" by auto
   499 qed
   500 
   501 lemma dvd_mult_cancel_right [simp]:
   502   "a * c dvd b * c \<longleftrightarrow> c = 0 \<or> a dvd b"
   503 proof -
   504   have "a * c dvd b * c \<longleftrightarrow> (\<exists>k. b * c = (a * k) * c)"
   505     unfolding dvd_def by (simp add: ac_simps)
   506   also have "(\<exists>k. b * c = (a * k) * c) \<longleftrightarrow> c = 0 \<or> a dvd b"
   507     unfolding dvd_def by simp
   508   finally show ?thesis .
   509 qed
   510 
   511 lemma dvd_mult_cancel_left [simp]:
   512   "c * a dvd c * b \<longleftrightarrow> c = 0 \<or> a dvd b"
   513 proof -
   514   have "c * a dvd c * b \<longleftrightarrow> (\<exists>k. b * c = (a * k) * c)"
   515     unfolding dvd_def by (simp add: ac_simps)
   516   also have "(\<exists>k. b * c = (a * k) * c) \<longleftrightarrow> c = 0 \<or> a dvd b"
   517     unfolding dvd_def by simp
   518   finally show ?thesis .
   519 qed
   520 
   521 end
   522 
   523 text {*
   524   The theory of partially ordered rings is taken from the books:
   525   \begin{itemize}
   526   \item \emph{Lattice Theory} by Garret Birkhoff, American Mathematical Society 1979 
   527   \item \emph{Partially Ordered Algebraic Systems}, Pergamon Press 1963
   528   \end{itemize}
   529   Most of the used notions can also be looked up in 
   530   \begin{itemize}
   531   \item @{url "http://www.mathworld.com"} by Eric Weisstein et. al.
   532   \item \emph{Algebra I} by van der Waerden, Springer.
   533   \end{itemize}
   534 *}
   535 
   536 class ordered_semiring = semiring + comm_monoid_add + ordered_ab_semigroup_add +
   537   assumes mult_left_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> c * a \<le> c * b"
   538   assumes mult_right_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * c"
   539 begin
   540 
   541 lemma mult_mono:
   542   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * d"
   543 apply (erule mult_right_mono [THEN order_trans], assumption)
   544 apply (erule mult_left_mono, assumption)
   545 done
   546 
   547 lemma mult_mono':
   548   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * d"
   549 apply (rule mult_mono)
   550 apply (fast intro: order_trans)+
   551 done
   552 
   553 end
   554 
   555 class ordered_cancel_semiring = ordered_semiring + cancel_comm_monoid_add
   556 begin
   557 
   558 subclass semiring_0_cancel ..
   559 
   560 lemma mult_nonneg_nonneg[simp]: "0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> a * b"
   561 using mult_left_mono [of 0 b a] by simp
   562 
   563 lemma mult_nonneg_nonpos: "0 \<le> a \<Longrightarrow> b \<le> 0 \<Longrightarrow> a * b \<le> 0"
   564 using mult_left_mono [of b 0 a] by simp
   565 
   566 lemma mult_nonpos_nonneg: "a \<le> 0 \<Longrightarrow> 0 \<le> b \<Longrightarrow> a * b \<le> 0"
   567 using mult_right_mono [of a 0 b] by simp
   568 
   569 text {* Legacy - use @{text mult_nonpos_nonneg} *}
   570 lemma mult_nonneg_nonpos2: "0 \<le> a \<Longrightarrow> b \<le> 0 \<Longrightarrow> b * a \<le> 0" 
   571 by (drule mult_right_mono [of b 0], auto)
   572 
   573 lemma split_mult_neg_le: "(0 \<le> a & b \<le> 0) | (a \<le> 0 & 0 \<le> b) \<Longrightarrow> a * b \<le> 0" 
   574 by (auto simp add: mult_nonneg_nonpos mult_nonneg_nonpos2)
   575 
   576 end
   577 
   578 class linordered_semiring = ordered_semiring + linordered_cancel_ab_semigroup_add
   579 begin
   580 
   581 subclass ordered_cancel_semiring ..
   582 
   583 subclass ordered_comm_monoid_add ..
   584 
   585 lemma mult_left_less_imp_less:
   586   "c * a < c * b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a < b"
   587 by (force simp add: mult_left_mono not_le [symmetric])
   588  
   589 lemma mult_right_less_imp_less:
   590   "a * c < b * c \<Longrightarrow> 0 \<le> c \<Longrightarrow> a < b"
   591 by (force simp add: mult_right_mono not_le [symmetric])
   592 
   593 end
   594 
   595 class linordered_semiring_1 = linordered_semiring + semiring_1
   596 begin
   597 
   598 lemma convex_bound_le:
   599   assumes "x \<le> a" "y \<le> a" "0 \<le> u" "0 \<le> v" "u + v = 1"
   600   shows "u * x + v * y \<le> a"
   601 proof-
   602   from assms have "u * x + v * y \<le> u * a + v * a"
   603     by (simp add: add_mono mult_left_mono)
   604   thus ?thesis using assms unfolding distrib_right[symmetric] by simp
   605 qed
   606 
   607 end
   608 
   609 class linordered_semiring_strict = semiring + comm_monoid_add + linordered_cancel_ab_semigroup_add +
   610   assumes mult_strict_left_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   611   assumes mult_strict_right_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> a * c < b * c"
   612 begin
   613 
   614 subclass semiring_0_cancel ..
   615 
   616 subclass linordered_semiring
   617 proof
   618   fix a b c :: 'a
   619   assume A: "a \<le> b" "0 \<le> c"
   620   from A show "c * a \<le> c * b"
   621     unfolding le_less
   622     using mult_strict_left_mono by (cases "c = 0") auto
   623   from A show "a * c \<le> b * c"
   624     unfolding le_less
   625     using mult_strict_right_mono by (cases "c = 0") auto
   626 qed
   627 
   628 lemma mult_left_le_imp_le:
   629   "c * a \<le> c * b \<Longrightarrow> 0 < c \<Longrightarrow> a \<le> b"
   630 by (force simp add: mult_strict_left_mono _not_less [symmetric])
   631  
   632 lemma mult_right_le_imp_le:
   633   "a * c \<le> b * c \<Longrightarrow> 0 < c \<Longrightarrow> a \<le> b"
   634 by (force simp add: mult_strict_right_mono not_less [symmetric])
   635 
   636 lemma mult_pos_pos[simp]: "0 < a \<Longrightarrow> 0 < b \<Longrightarrow> 0 < a * b"
   637 using mult_strict_left_mono [of 0 b a] by simp
   638 
   639 lemma mult_pos_neg: "0 < a \<Longrightarrow> b < 0 \<Longrightarrow> a * b < 0"
   640 using mult_strict_left_mono [of b 0 a] by simp
   641 
   642 lemma mult_neg_pos: "a < 0 \<Longrightarrow> 0 < b \<Longrightarrow> a * b < 0"
   643 using mult_strict_right_mono [of a 0 b] by simp
   644 
   645 text {* Legacy - use @{text mult_neg_pos} *}
   646 lemma mult_pos_neg2: "0 < a \<Longrightarrow> b < 0 \<Longrightarrow> b * a < 0" 
   647 by (drule mult_strict_right_mono [of b 0], auto)
   648 
   649 lemma zero_less_mult_pos:
   650   "0 < a * b \<Longrightarrow> 0 < a \<Longrightarrow> 0 < b"
   651 apply (cases "b\<le>0")
   652  apply (auto simp add: le_less not_less)
   653 apply (drule_tac mult_pos_neg [of a b])
   654  apply (auto dest: less_not_sym)
   655 done
   656 
   657 lemma zero_less_mult_pos2:
   658   "0 < b * a \<Longrightarrow> 0 < a \<Longrightarrow> 0 < b"
   659 apply (cases "b\<le>0")
   660  apply (auto simp add: le_less not_less)
   661 apply (drule_tac mult_pos_neg2 [of a b])
   662  apply (auto dest: less_not_sym)
   663 done
   664 
   665 text{*Strict monotonicity in both arguments*}
   666 lemma mult_strict_mono:
   667   assumes "a < b" and "c < d" and "0 < b" and "0 \<le> c"
   668   shows "a * c < b * d"
   669   using assms apply (cases "c=0")
   670   apply (simp)
   671   apply (erule mult_strict_right_mono [THEN less_trans])
   672   apply (force simp add: le_less)
   673   apply (erule mult_strict_left_mono, assumption)
   674   done
   675 
   676 text{*This weaker variant has more natural premises*}
   677 lemma mult_strict_mono':
   678   assumes "a < b" and "c < d" and "0 \<le> a" and "0 \<le> c"
   679   shows "a * c < b * d"
   680 by (rule mult_strict_mono) (insert assms, auto)
   681 
   682 lemma mult_less_le_imp_less:
   683   assumes "a < b" and "c \<le> d" and "0 \<le> a" and "0 < c"
   684   shows "a * c < b * d"
   685   using assms apply (subgoal_tac "a * c < b * c")
   686   apply (erule less_le_trans)
   687   apply (erule mult_left_mono)
   688   apply simp
   689   apply (erule mult_strict_right_mono)
   690   apply assumption
   691   done
   692 
   693 lemma mult_le_less_imp_less:
   694   assumes "a \<le> b" and "c < d" and "0 < a" and "0 \<le> c"
   695   shows "a * c < b * d"
   696   using assms apply (subgoal_tac "a * c \<le> b * c")
   697   apply (erule le_less_trans)
   698   apply (erule mult_strict_left_mono)
   699   apply simp
   700   apply (erule mult_right_mono)
   701   apply simp
   702   done
   703 
   704 lemma mult_less_imp_less_left:
   705   assumes less: "c * a < c * b" and nonneg: "0 \<le> c"
   706   shows "a < b"
   707 proof (rule ccontr)
   708   assume "\<not>  a < b"
   709   hence "b \<le> a" by (simp add: linorder_not_less)
   710   hence "c * b \<le> c * a" using nonneg by (rule mult_left_mono)
   711   with this and less show False by (simp add: not_less [symmetric])
   712 qed
   713 
   714 lemma mult_less_imp_less_right:
   715   assumes less: "a * c < b * c" and nonneg: "0 \<le> c"
   716   shows "a < b"
   717 proof (rule ccontr)
   718   assume "\<not> a < b"
   719   hence "b \<le> a" by (simp add: linorder_not_less)
   720   hence "b * c \<le> a * c" using nonneg by (rule mult_right_mono)
   721   with this and less show False by (simp add: not_less [symmetric])
   722 qed  
   723 
   724 end
   725 
   726 class linordered_semiring_1_strict = linordered_semiring_strict + semiring_1
   727 begin
   728 
   729 subclass linordered_semiring_1 ..
   730 
   731 lemma convex_bound_lt:
   732   assumes "x < a" "y < a" "0 \<le> u" "0 \<le> v" "u + v = 1"
   733   shows "u * x + v * y < a"
   734 proof -
   735   from assms have "u * x + v * y < u * a + v * a"
   736     by (cases "u = 0")
   737        (auto intro!: add_less_le_mono mult_strict_left_mono mult_left_mono)
   738   thus ?thesis using assms unfolding distrib_right[symmetric] by simp
   739 qed
   740 
   741 end
   742 
   743 class ordered_comm_semiring = comm_semiring_0 + ordered_ab_semigroup_add + 
   744   assumes comm_mult_left_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> c * a \<le> c * b"
   745 begin
   746 
   747 subclass ordered_semiring
   748 proof
   749   fix a b c :: 'a
   750   assume "a \<le> b" "0 \<le> c"
   751   thus "c * a \<le> c * b" by (rule comm_mult_left_mono)
   752   thus "a * c \<le> b * c" by (simp only: mult.commute)
   753 qed
   754 
   755 end
   756 
   757 class ordered_cancel_comm_semiring = ordered_comm_semiring + cancel_comm_monoid_add
   758 begin
   759 
   760 subclass comm_semiring_0_cancel ..
   761 subclass ordered_comm_semiring ..
   762 subclass ordered_cancel_semiring ..
   763 
   764 end
   765 
   766 class linordered_comm_semiring_strict = comm_semiring_0 + linordered_cancel_ab_semigroup_add +
   767   assumes comm_mult_strict_left_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   768 begin
   769 
   770 subclass linordered_semiring_strict
   771 proof
   772   fix a b c :: 'a
   773   assume "a < b" "0 < c"
   774   thus "c * a < c * b" by (rule comm_mult_strict_left_mono)
   775   thus "a * c < b * c" by (simp only: mult.commute)
   776 qed
   777 
   778 subclass ordered_cancel_comm_semiring
   779 proof
   780   fix a b c :: 'a
   781   assume "a \<le> b" "0 \<le> c"
   782   thus "c * a \<le> c * b"
   783     unfolding le_less
   784     using mult_strict_left_mono by (cases "c = 0") auto
   785 qed
   786 
   787 end
   788 
   789 class ordered_ring = ring + ordered_cancel_semiring 
   790 begin
   791 
   792 subclass ordered_ab_group_add ..
   793 
   794 lemma less_add_iff1:
   795   "a * e + c < b * e + d \<longleftrightarrow> (a - b) * e + c < d"
   796 by (simp add: algebra_simps)
   797 
   798 lemma less_add_iff2:
   799   "a * e + c < b * e + d \<longleftrightarrow> c < (b - a) * e + d"
   800 by (simp add: algebra_simps)
   801 
   802 lemma le_add_iff1:
   803   "a * e + c \<le> b * e + d \<longleftrightarrow> (a - b) * e + c \<le> d"
   804 by (simp add: algebra_simps)
   805 
   806 lemma le_add_iff2:
   807   "a * e + c \<le> b * e + d \<longleftrightarrow> c \<le> (b - a) * e + d"
   808 by (simp add: algebra_simps)
   809 
   810 lemma mult_left_mono_neg:
   811   "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> c * a \<le> c * b"
   812   apply (drule mult_left_mono [of _ _ "- c"])
   813   apply simp_all
   814   done
   815 
   816 lemma mult_right_mono_neg:
   817   "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> a * c \<le> b * c"
   818   apply (drule mult_right_mono [of _ _ "- c"])
   819   apply simp_all
   820   done
   821 
   822 lemma mult_nonpos_nonpos: "a \<le> 0 \<Longrightarrow> b \<le> 0 \<Longrightarrow> 0 \<le> a * b"
   823 using mult_right_mono_neg [of a 0 b] by simp
   824 
   825 lemma split_mult_pos_le:
   826   "(0 \<le> a \<and> 0 \<le> b) \<or> (a \<le> 0 \<and> b \<le> 0) \<Longrightarrow> 0 \<le> a * b"
   827 by (auto simp add: mult_nonpos_nonpos)
   828 
   829 end
   830 
   831 class linordered_ring = ring + linordered_semiring + linordered_ab_group_add + abs_if
   832 begin
   833 
   834 subclass ordered_ring ..
   835 
   836 subclass ordered_ab_group_add_abs
   837 proof
   838   fix a b
   839   show "\<bar>a + b\<bar> \<le> \<bar>a\<bar> + \<bar>b\<bar>"
   840     by (auto simp add: abs_if not_le not_less algebra_simps simp del: add.commute dest: add_neg_neg add_nonneg_nonneg)
   841 qed (auto simp add: abs_if)
   842 
   843 lemma zero_le_square [simp]: "0 \<le> a * a"
   844   using linear [of 0 a]
   845   by (auto simp add: mult_nonpos_nonpos)
   846 
   847 lemma not_square_less_zero [simp]: "\<not> (a * a < 0)"
   848   by (simp add: not_less)
   849 
   850 end
   851 
   852 (* The "strict" suffix can be seen as describing the combination of linordered_ring and no_zero_divisors.
   853    Basically, linordered_ring + no_zero_divisors = linordered_ring_strict.
   854  *)
   855 class linordered_ring_strict = ring + linordered_semiring_strict
   856   + ordered_ab_group_add + abs_if
   857 begin
   858 
   859 subclass linordered_ring ..
   860 
   861 lemma mult_strict_left_mono_neg: "b < a \<Longrightarrow> c < 0 \<Longrightarrow> c * a < c * b"
   862 using mult_strict_left_mono [of b a "- c"] by simp
   863 
   864 lemma mult_strict_right_mono_neg: "b < a \<Longrightarrow> c < 0 \<Longrightarrow> a * c < b * c"
   865 using mult_strict_right_mono [of b a "- c"] by simp
   866 
   867 lemma mult_neg_neg: "a < 0 \<Longrightarrow> b < 0 \<Longrightarrow> 0 < a * b"
   868 using mult_strict_right_mono_neg [of a 0 b] by simp
   869 
   870 subclass ring_no_zero_divisors
   871 proof
   872   fix a b
   873   assume "a \<noteq> 0" then have A: "a < 0 \<or> 0 < a" by (simp add: neq_iff)
   874   assume "b \<noteq> 0" then have B: "b < 0 \<or> 0 < b" by (simp add: neq_iff)
   875   have "a * b < 0 \<or> 0 < a * b"
   876   proof (cases "a < 0")
   877     case True note A' = this
   878     show ?thesis proof (cases "b < 0")
   879       case True with A'
   880       show ?thesis by (auto dest: mult_neg_neg)
   881     next
   882       case False with B have "0 < b" by auto
   883       with A' show ?thesis by (auto dest: mult_strict_right_mono)
   884     qed
   885   next
   886     case False with A have A': "0 < a" by auto
   887     show ?thesis proof (cases "b < 0")
   888       case True with A'
   889       show ?thesis by (auto dest: mult_strict_right_mono_neg)
   890     next
   891       case False with B have "0 < b" by auto
   892       with A' show ?thesis by auto
   893     qed
   894   qed
   895   then show "a * b \<noteq> 0" by (simp add: neq_iff)
   896 qed
   897 
   898 lemma zero_less_mult_iff: "0 < a * b \<longleftrightarrow> 0 < a \<and> 0 < b \<or> a < 0 \<and> b < 0"
   899   by (cases a 0 b 0 rule: linorder_cases[case_product linorder_cases])
   900      (auto simp add: mult_neg_neg not_less le_less dest: zero_less_mult_pos zero_less_mult_pos2)
   901 
   902 lemma zero_le_mult_iff: "0 \<le> a * b \<longleftrightarrow> 0 \<le> a \<and> 0 \<le> b \<or> a \<le> 0 \<and> b \<le> 0"
   903   by (auto simp add: eq_commute [of 0] le_less not_less zero_less_mult_iff)
   904 
   905 lemma mult_less_0_iff:
   906   "a * b < 0 \<longleftrightarrow> 0 < a \<and> b < 0 \<or> a < 0 \<and> 0 < b"
   907   apply (insert zero_less_mult_iff [of "-a" b])
   908   apply force
   909   done
   910 
   911 lemma mult_le_0_iff:
   912   "a * b \<le> 0 \<longleftrightarrow> 0 \<le> a \<and> b \<le> 0 \<or> a \<le> 0 \<and> 0 \<le> b"
   913   apply (insert zero_le_mult_iff [of "-a" b]) 
   914   apply force
   915   done
   916 
   917 text{*Cancellation laws for @{term "c*a < c*b"} and @{term "a*c < b*c"},
   918    also with the relations @{text "\<le>"} and equality.*}
   919 
   920 text{*These ``disjunction'' versions produce two cases when the comparison is
   921  an assumption, but effectively four when the comparison is a goal.*}
   922 
   923 lemma mult_less_cancel_right_disj:
   924   "a * c < b * c \<longleftrightarrow> 0 < c \<and> a < b \<or> c < 0 \<and>  b < a"
   925   apply (cases "c = 0")
   926   apply (auto simp add: neq_iff mult_strict_right_mono 
   927                       mult_strict_right_mono_neg)
   928   apply (auto simp add: not_less 
   929                       not_le [symmetric, of "a*c"]
   930                       not_le [symmetric, of a])
   931   apply (erule_tac [!] notE)
   932   apply (auto simp add: less_imp_le mult_right_mono 
   933                       mult_right_mono_neg)
   934   done
   935 
   936 lemma mult_less_cancel_left_disj:
   937   "c * a < c * b \<longleftrightarrow> 0 < c \<and> a < b \<or> c < 0 \<and>  b < a"
   938   apply (cases "c = 0")
   939   apply (auto simp add: neq_iff mult_strict_left_mono 
   940                       mult_strict_left_mono_neg)
   941   apply (auto simp add: not_less 
   942                       not_le [symmetric, of "c*a"]
   943                       not_le [symmetric, of a])
   944   apply (erule_tac [!] notE)
   945   apply (auto simp add: less_imp_le mult_left_mono 
   946                       mult_left_mono_neg)
   947   done
   948 
   949 text{*The ``conjunction of implication'' lemmas produce two cases when the
   950 comparison is a goal, but give four when the comparison is an assumption.*}
   951 
   952 lemma mult_less_cancel_right:
   953   "a * c < b * c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < b) \<and> (c \<le> 0 \<longrightarrow> b < a)"
   954   using mult_less_cancel_right_disj [of a c b] by auto
   955 
   956 lemma mult_less_cancel_left:
   957   "c * a < c * b \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < b) \<and> (c \<le> 0 \<longrightarrow> b < a)"
   958   using mult_less_cancel_left_disj [of c a b] by auto
   959 
   960 lemma mult_le_cancel_right:
   961    "a * c \<le> b * c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
   962 by (simp add: not_less [symmetric] mult_less_cancel_right_disj)
   963 
   964 lemma mult_le_cancel_left:
   965   "c * a \<le> c * b \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
   966 by (simp add: not_less [symmetric] mult_less_cancel_left_disj)
   967 
   968 lemma mult_le_cancel_left_pos:
   969   "0 < c \<Longrightarrow> c * a \<le> c * b \<longleftrightarrow> a \<le> b"
   970 by (auto simp: mult_le_cancel_left)
   971 
   972 lemma mult_le_cancel_left_neg:
   973   "c < 0 \<Longrightarrow> c * a \<le> c * b \<longleftrightarrow> b \<le> a"
   974 by (auto simp: mult_le_cancel_left)
   975 
   976 lemma mult_less_cancel_left_pos:
   977   "0 < c \<Longrightarrow> c * a < c * b \<longleftrightarrow> a < b"
   978 by (auto simp: mult_less_cancel_left)
   979 
   980 lemma mult_less_cancel_left_neg:
   981   "c < 0 \<Longrightarrow> c * a < c * b \<longleftrightarrow> b < a"
   982 by (auto simp: mult_less_cancel_left)
   983 
   984 end
   985 
   986 lemmas mult_sign_intros =
   987   mult_nonneg_nonneg mult_nonneg_nonpos
   988   mult_nonpos_nonneg mult_nonpos_nonpos
   989   mult_pos_pos mult_pos_neg
   990   mult_neg_pos mult_neg_neg
   991 
   992 class ordered_comm_ring = comm_ring + ordered_comm_semiring
   993 begin
   994 
   995 subclass ordered_ring ..
   996 subclass ordered_cancel_comm_semiring ..
   997 
   998 end
   999 
  1000 class linordered_semidom = comm_semiring_1_cancel + linordered_comm_semiring_strict +
  1001   (*previously linordered_semiring*)
  1002   assumes zero_less_one [simp]: "0 < 1"
  1003 begin
  1004 
  1005 lemma pos_add_strict:
  1006   shows "0 < a \<Longrightarrow> b < c \<Longrightarrow> b < a + c"
  1007   using add_strict_mono [of 0 a b c] by simp
  1008 
  1009 lemma zero_le_one [simp]: "0 \<le> 1"
  1010 by (rule zero_less_one [THEN less_imp_le]) 
  1011 
  1012 lemma not_one_le_zero [simp]: "\<not> 1 \<le> 0"
  1013 by (simp add: not_le) 
  1014 
  1015 lemma not_one_less_zero [simp]: "\<not> 1 < 0"
  1016 by (simp add: not_less) 
  1017 
  1018 lemma less_1_mult:
  1019   assumes "1 < m" and "1 < n"
  1020   shows "1 < m * n"
  1021   using assms mult_strict_mono [of 1 m 1 n]
  1022     by (simp add:  less_trans [OF zero_less_one]) 
  1023 
  1024 end
  1025 
  1026 class linordered_idom = comm_ring_1 +
  1027   linordered_comm_semiring_strict + ordered_ab_group_add +
  1028   abs_if + sgn_if
  1029   (*previously linordered_ring*)
  1030 begin
  1031 
  1032 subclass linordered_semiring_1_strict ..
  1033 subclass linordered_ring_strict ..
  1034 subclass ordered_comm_ring ..
  1035 subclass idom ..
  1036 
  1037 subclass linordered_semidom
  1038 proof
  1039   have "0 \<le> 1 * 1" by (rule zero_le_square)
  1040   thus "0 < 1" by (simp add: le_less)
  1041 qed 
  1042 
  1043 lemma linorder_neqE_linordered_idom:
  1044   assumes "x \<noteq> y" obtains "x < y" | "y < x"
  1045   using assms by (rule neqE)
  1046 
  1047 text {* These cancellation simprules also produce two cases when the comparison is a goal. *}
  1048 
  1049 lemma mult_le_cancel_right1:
  1050   "c \<le> b * c \<longleftrightarrow> (0 < c \<longrightarrow> 1 \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> 1)"
  1051 by (insert mult_le_cancel_right [of 1 c b], simp)
  1052 
  1053 lemma mult_le_cancel_right2:
  1054   "a * c \<le> c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> 1) \<and> (c < 0 \<longrightarrow> 1 \<le> a)"
  1055 by (insert mult_le_cancel_right [of a c 1], simp)
  1056 
  1057 lemma mult_le_cancel_left1:
  1058   "c \<le> c * b \<longleftrightarrow> (0 < c \<longrightarrow> 1 \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> 1)"
  1059 by (insert mult_le_cancel_left [of c 1 b], simp)
  1060 
  1061 lemma mult_le_cancel_left2:
  1062   "c * a \<le> c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> 1) \<and> (c < 0 \<longrightarrow> 1 \<le> a)"
  1063 by (insert mult_le_cancel_left [of c a 1], simp)
  1064 
  1065 lemma mult_less_cancel_right1:
  1066   "c < b * c \<longleftrightarrow> (0 \<le> c \<longrightarrow> 1 < b) \<and> (c \<le> 0 \<longrightarrow> b < 1)"
  1067 by (insert mult_less_cancel_right [of 1 c b], simp)
  1068 
  1069 lemma mult_less_cancel_right2:
  1070   "a * c < c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < 1) \<and> (c \<le> 0 \<longrightarrow> 1 < a)"
  1071 by (insert mult_less_cancel_right [of a c 1], simp)
  1072 
  1073 lemma mult_less_cancel_left1:
  1074   "c < c * b \<longleftrightarrow> (0 \<le> c \<longrightarrow> 1 < b) \<and> (c \<le> 0 \<longrightarrow> b < 1)"
  1075 by (insert mult_less_cancel_left [of c 1 b], simp)
  1076 
  1077 lemma mult_less_cancel_left2:
  1078   "c * a < c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < 1) \<and> (c \<le> 0 \<longrightarrow> 1 < a)"
  1079 by (insert mult_less_cancel_left [of c a 1], simp)
  1080 
  1081 lemma sgn_sgn [simp]:
  1082   "sgn (sgn a) = sgn a"
  1083 unfolding sgn_if by simp
  1084 
  1085 lemma sgn_0_0:
  1086   "sgn a = 0 \<longleftrightarrow> a = 0"
  1087 unfolding sgn_if by simp
  1088 
  1089 lemma sgn_1_pos:
  1090   "sgn a = 1 \<longleftrightarrow> a > 0"
  1091 unfolding sgn_if by simp
  1092 
  1093 lemma sgn_1_neg:
  1094   "sgn a = - 1 \<longleftrightarrow> a < 0"
  1095 unfolding sgn_if by auto
  1096 
  1097 lemma sgn_pos [simp]:
  1098   "0 < a \<Longrightarrow> sgn a = 1"
  1099 unfolding sgn_1_pos .
  1100 
  1101 lemma sgn_neg [simp]:
  1102   "a < 0 \<Longrightarrow> sgn a = - 1"
  1103 unfolding sgn_1_neg .
  1104 
  1105 lemma sgn_times:
  1106   "sgn (a * b) = sgn a * sgn b"
  1107 by (auto simp add: sgn_if zero_less_mult_iff)
  1108 
  1109 lemma abs_sgn: "\<bar>k\<bar> = k * sgn k"
  1110 unfolding sgn_if abs_if by auto
  1111 
  1112 lemma sgn_greater [simp]:
  1113   "0 < sgn a \<longleftrightarrow> 0 < a"
  1114   unfolding sgn_if by auto
  1115 
  1116 lemma sgn_less [simp]:
  1117   "sgn a < 0 \<longleftrightarrow> a < 0"
  1118   unfolding sgn_if by auto
  1119 
  1120 lemma abs_dvd_iff [simp]: "\<bar>m\<bar> dvd k \<longleftrightarrow> m dvd k"
  1121   by (simp add: abs_if)
  1122 
  1123 lemma dvd_abs_iff [simp]: "m dvd \<bar>k\<bar> \<longleftrightarrow> m dvd k"
  1124   by (simp add: abs_if)
  1125 
  1126 lemma dvd_if_abs_eq:
  1127   "\<bar>l\<bar> = \<bar>k\<bar> \<Longrightarrow> l dvd k"
  1128 by(subst abs_dvd_iff[symmetric]) simp
  1129 
  1130 text {* The following lemmas can be proven in more general structures, but
  1131 are dangerous as simp rules in absence of @{thm neg_equal_zero}, 
  1132 @{thm neg_less_pos}, @{thm neg_less_eq_nonneg}. *}
  1133 
  1134 lemma equation_minus_iff_1 [simp, no_atp]:
  1135   "1 = - a \<longleftrightarrow> a = - 1"
  1136   by (fact equation_minus_iff)
  1137 
  1138 lemma minus_equation_iff_1 [simp, no_atp]:
  1139   "- a = 1 \<longleftrightarrow> a = - 1"
  1140   by (subst minus_equation_iff, auto)
  1141 
  1142 lemma le_minus_iff_1 [simp, no_atp]:
  1143   "1 \<le> - b \<longleftrightarrow> b \<le> - 1"
  1144   by (fact le_minus_iff)
  1145 
  1146 lemma minus_le_iff_1 [simp, no_atp]:
  1147   "- a \<le> 1 \<longleftrightarrow> - 1 \<le> a"
  1148   by (fact minus_le_iff)
  1149 
  1150 lemma less_minus_iff_1 [simp, no_atp]:
  1151   "1 < - b \<longleftrightarrow> b < - 1"
  1152   by (fact less_minus_iff)
  1153 
  1154 lemma minus_less_iff_1 [simp, no_atp]:
  1155   "- a < 1 \<longleftrightarrow> - 1 < a"
  1156   by (fact minus_less_iff)
  1157 
  1158 end
  1159 
  1160 text {* Simprules for comparisons where common factors can be cancelled. *}
  1161 
  1162 lemmas mult_compare_simps =
  1163     mult_le_cancel_right mult_le_cancel_left
  1164     mult_le_cancel_right1 mult_le_cancel_right2
  1165     mult_le_cancel_left1 mult_le_cancel_left2
  1166     mult_less_cancel_right mult_less_cancel_left
  1167     mult_less_cancel_right1 mult_less_cancel_right2
  1168     mult_less_cancel_left1 mult_less_cancel_left2
  1169     mult_cancel_right mult_cancel_left
  1170     mult_cancel_right1 mult_cancel_right2
  1171     mult_cancel_left1 mult_cancel_left2
  1172 
  1173 text {* Reasoning about inequalities with division *}
  1174 
  1175 context linordered_semidom
  1176 begin
  1177 
  1178 lemma less_add_one: "a < a + 1"
  1179 proof -
  1180   have "a + 0 < a + 1"
  1181     by (blast intro: zero_less_one add_strict_left_mono)
  1182   thus ?thesis by simp
  1183 qed
  1184 
  1185 lemma zero_less_two: "0 < 1 + 1"
  1186 by (blast intro: less_trans zero_less_one less_add_one)
  1187 
  1188 end
  1189 
  1190 context linordered_idom
  1191 begin
  1192 
  1193 lemma mult_right_le_one_le:
  1194   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> y \<le> 1 \<Longrightarrow> x * y \<le> x"
  1195   by (auto simp add: mult_le_cancel_left2)
  1196 
  1197 lemma mult_left_le_one_le:
  1198   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> y \<le> 1 \<Longrightarrow> y * x \<le> x"
  1199   by (auto simp add: mult_le_cancel_right2)
  1200 
  1201 end
  1202 
  1203 text {* Absolute Value *}
  1204 
  1205 context linordered_idom
  1206 begin
  1207 
  1208 lemma mult_sgn_abs:
  1209   "sgn x * \<bar>x\<bar> = x"
  1210   unfolding abs_if sgn_if by auto
  1211 
  1212 lemma abs_one [simp]:
  1213   "\<bar>1\<bar> = 1"
  1214   by (simp add: abs_if)
  1215 
  1216 end
  1217 
  1218 class ordered_ring_abs = ordered_ring + ordered_ab_group_add_abs +
  1219   assumes abs_eq_mult:
  1220     "(0 \<le> a \<or> a \<le> 0) \<and> (0 \<le> b \<or> b \<le> 0) \<Longrightarrow> \<bar>a * b\<bar> = \<bar>a\<bar> * \<bar>b\<bar>"
  1221 
  1222 context linordered_idom
  1223 begin
  1224 
  1225 subclass ordered_ring_abs proof
  1226 qed (auto simp add: abs_if not_less mult_less_0_iff)
  1227 
  1228 lemma abs_mult:
  1229   "\<bar>a * b\<bar> = \<bar>a\<bar> * \<bar>b\<bar>" 
  1230   by (rule abs_eq_mult) auto
  1231 
  1232 lemma abs_mult_self:
  1233   "\<bar>a\<bar> * \<bar>a\<bar> = a * a"
  1234   by (simp add: abs_if) 
  1235 
  1236 lemma abs_mult_less:
  1237   "\<bar>a\<bar> < c \<Longrightarrow> \<bar>b\<bar> < d \<Longrightarrow> \<bar>a\<bar> * \<bar>b\<bar> < c * d"
  1238 proof -
  1239   assume ac: "\<bar>a\<bar> < c"
  1240   hence cpos: "0<c" by (blast intro: le_less_trans abs_ge_zero)
  1241   assume "\<bar>b\<bar> < d"
  1242   thus ?thesis by (simp add: ac cpos mult_strict_mono) 
  1243 qed
  1244 
  1245 lemma abs_less_iff:
  1246   "\<bar>a\<bar> < b \<longleftrightarrow> a < b \<and> - a < b" 
  1247   by (simp add: less_le abs_le_iff) (auto simp add: abs_if)
  1248 
  1249 lemma abs_mult_pos:
  1250   "0 \<le> x \<Longrightarrow> \<bar>y\<bar> * x = \<bar>y * x\<bar>"
  1251   by (simp add: abs_mult)
  1252 
  1253 lemma abs_diff_less_iff:
  1254   "\<bar>x - a\<bar> < r \<longleftrightarrow> a - r < x \<and> x < a + r"
  1255   by (auto simp add: diff_less_eq ac_simps abs_less_iff)
  1256 
  1257 end
  1258 
  1259 code_identifier
  1260   code_module Rings \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
  1261 
  1262 end
  1263