src/HOL/Probability/Projective_Family.thy
author immler@in.tum.de
Wed Nov 07 14:41:49 2012 +0100 (2012-11-07)
changeset 50040 5da32dc55cd8
parent 50039 bfd5198cbe40
child 50041 afe886a04198
permissions -rw-r--r--
assume probability spaces; allow empty index set
     1 theory Projective_Family
     2 imports Finite_Product_Measure Probability_Measure
     3 begin
     4 
     5 definition
     6   PiP :: "'i set \<Rightarrow> ('i \<Rightarrow> 'a measure) \<Rightarrow> ('i set \<Rightarrow> ('i \<Rightarrow> 'a) measure) \<Rightarrow> ('i \<Rightarrow> 'a) measure" where
     7   "PiP I M P = extend_measure (\<Pi>\<^isub>E i\<in>I. space (M i))
     8     {(J, X). (J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))}
     9     (\<lambda>(J, X). prod_emb I M J (\<Pi>\<^isub>E j\<in>J. X j))
    10     (\<lambda>(J, X). emeasure (P J) (Pi\<^isub>E J X))"
    11 
    12 lemma space_PiP[simp]: "space (PiP I M P) = space (PiM I M)"
    13   by (auto simp add: PiP_def space_PiM prod_emb_def intro!: space_extend_measure)
    14 
    15 lemma sets_PiP[simp]: "sets (PiP I M P) = sets (PiM I M)"
    16   by (auto simp add: PiP_def sets_PiM prod_algebra_def prod_emb_def intro!: sets_extend_measure)
    17 
    18 lemma measurable_PiP1[simp]: "measurable (PiP I M P) M' = measurable (\<Pi>\<^isub>M i\<in>I. M i) M'"
    19   unfolding measurable_def by auto
    20 
    21 lemma measurable_PiP2[simp]: "measurable M' (PiP I M P) = measurable M' (\<Pi>\<^isub>M i\<in>I. M i)"
    22   unfolding measurable_def by auto
    23 
    24 locale projective_family =
    25   fixes I::"'i set" and P::"'i set \<Rightarrow> ('i \<Rightarrow> 'a) measure" and M::"('i \<Rightarrow> 'a measure)"
    26   assumes projective: "\<And>J H X. J \<noteq> {} \<Longrightarrow> J \<subseteq> H \<Longrightarrow> H \<subseteq> I \<Longrightarrow> finite H \<Longrightarrow> X \<in> sets (PiM J M) \<Longrightarrow>
    27      (P H) (prod_emb H M J X) = (P J) X"
    28   assumes prob_space: "\<And>J. finite J \<Longrightarrow> prob_space (P J)"
    29   assumes proj_space: "\<And>J. finite J \<Longrightarrow> space (P J) = space (PiM J M)"
    30   assumes proj_sets: "\<And>J. finite J \<Longrightarrow> sets (P J) = sets (PiM J M)"
    31   assumes proj_finite_measure: "\<And>J. finite J \<Longrightarrow> emeasure (P J) (space (PiM J M)) \<noteq> \<infinity>"
    32   assumes measure_space: "\<And>i. prob_space (M i)"
    33 begin
    34 
    35 lemma emeasure_PiP:
    36   assumes "finite J"
    37   assumes "J \<subseteq> I"
    38   assumes A: "\<And>i. i\<in>J \<Longrightarrow> A i \<in> sets (M i)"
    39   shows "emeasure (PiP J M P) (Pi\<^isub>E J A) = emeasure (P J) (Pi\<^isub>E J A)"
    40 proof -
    41   have "Pi\<^isub>E J (restrict A J) \<subseteq> (\<Pi>\<^isub>E i\<in>J. space (M i))"
    42   proof safe
    43     fix x j assume "x \<in> Pi J (restrict A J)" "j \<in> J"
    44     hence "x j \<in> restrict A J j" by (auto simp: Pi_def)
    45     also have "\<dots> \<subseteq> space (M j)" using sets_into_space A `j \<in> J` by auto
    46     finally show "x j \<in> space (M j)" .
    47   qed
    48   hence "emeasure (PiP J M P) (Pi\<^isub>E J A) =
    49     emeasure (PiP J M P) (prod_emb J M J (Pi\<^isub>E J A))"
    50     using assms(1-3) sets_into_space by (auto simp add: prod_emb_id Pi_def)
    51   also have "\<dots> = emeasure (P J) (Pi\<^isub>E J A)"
    52   proof (rule emeasure_extend_measure_Pair[OF PiP_def])
    53     show "positive (sets (PiP J M P)) (P J)" unfolding positive_def by auto
    54     show "countably_additive (sets (PiP J M P)) (P J)" unfolding countably_additive_def
    55       by (auto simp: suminf_emeasure proj_sets[OF `finite J`])
    56     show "(J \<noteq> {} \<or> J = {}) \<and> finite J \<and> J \<subseteq> J \<and> A \<in> (\<Pi> j\<in>J. sets (M j))"
    57       using assms by auto
    58     fix K and X::"'i \<Rightarrow> 'a set"
    59     show "prod_emb J M K (Pi\<^isub>E K X) \<in> Pow (\<Pi>\<^isub>E i\<in>J. space (M i))"
    60       by (auto simp: prod_emb_def)
    61     assume JX: "(K \<noteq> {} \<or> J = {}) \<and> finite K \<and> K \<subseteq> J \<and> X \<in> (\<Pi> j\<in>K. sets (M j))"
    62     thus "emeasure (P J) (prod_emb J M K (Pi\<^isub>E K X)) = emeasure (P K) (Pi\<^isub>E K X)"
    63       using assms
    64       apply (cases "J = {}")
    65       apply (simp add: prod_emb_id)
    66       apply (fastforce simp add: intro!: projective sets_PiM_I_finite)
    67       done
    68   qed
    69   finally show ?thesis .
    70 qed
    71 
    72 lemma PiP_finite:
    73   assumes "finite J"
    74   assumes "J \<subseteq> I"
    75   shows "PiP J M P = P J" (is "?P = _")
    76 proof (rule measure_eqI_generator_eq)
    77   let ?J = "{Pi\<^isub>E J E | E. \<forall>i\<in>J. E i \<in> sets (M i)}"
    78   let ?F = "\<lambda>i. \<Pi>\<^isub>E k\<in>J. space (M k)"
    79   let ?\<Omega> = "(\<Pi>\<^isub>E k\<in>J. space (M k))"
    80   show "Int_stable ?J"
    81     by (rule Int_stable_PiE)
    82   interpret finite_measure "P J" using proj_finite_measure `finite J`
    83     by (intro finite_measureI) (simp add: proj_space)
    84   show "emeasure ?P (?F _) \<noteq> \<infinity>" using assms `finite J` by (auto simp: emeasure_PiP)
    85   show "?J \<subseteq> Pow ?\<Omega>" by (auto simp: Pi_iff dest: sets_into_space)
    86   show "sets (PiP J M P) = sigma_sets ?\<Omega> ?J" "sets (P J) = sigma_sets ?\<Omega> ?J"
    87     using `finite J` proj_sets by (simp_all add: sets_PiM prod_algebra_eq_finite Pi_iff)
    88   fix X assume "X \<in> ?J"
    89   then obtain E where X: "X = Pi\<^isub>E J E" and E: "\<forall>i\<in>J. E i \<in> sets (M i)" by auto
    90   with `finite J` have "X \<in> sets (PiP J M P)" by simp
    91   have emb_self: "prod_emb J M J (Pi\<^isub>E J E) = Pi\<^isub>E J E"
    92     using E sets_into_space
    93     by (auto intro!: prod_emb_PiE_same_index)
    94   show "emeasure (PiP J M P) X = emeasure (P J) X"
    95     unfolding X using E
    96     by (intro emeasure_PiP assms) simp
    97 qed (insert `finite J`, auto intro!: prod_algebraI_finite)
    98 
    99 lemma emeasure_fun_emb[simp]:
   100   assumes L: "J \<noteq> {}" "J \<subseteq> L" "finite L" "L \<subseteq> I" and X: "X \<in> sets (PiM J M)"
   101   shows "emeasure (PiP L M P) (prod_emb L M J X) = emeasure (PiP J M P) X"
   102   using assms
   103   by (subst PiP_finite) (auto simp: PiP_finite finite_subset projective)
   104 
   105 end
   106 
   107 sublocale projective_family \<subseteq> M: prob_space "M i" for i
   108   by (rule measure_space)
   109 
   110 end