src/HOL/HOL.thy
author haftmann
Fri Oct 24 17:48:34 2008 +0200 (2008-10-24)
changeset 28682 5de9fc98ad96
parent 28663 bd8438543bf2
child 28699 32b6a8f12c1c
permissions -rw-r--r--
"arbitrary" merely abbreviates undefined
     1 (*  Title:      HOL/HOL.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     4 *)
     5 
     6 header {* The basis of Higher-Order Logic *}
     7 
     8 theory HOL
     9 imports Pure
    10 uses
    11   ("hologic.ML")
    12   "~~/src/Tools/IsaPlanner/zipper.ML"
    13   "~~/src/Tools/IsaPlanner/isand.ML"
    14   "~~/src/Tools/IsaPlanner/rw_tools.ML"
    15   "~~/src/Tools/IsaPlanner/rw_inst.ML"
    16   "~~/src/Provers/project_rule.ML"
    17   "~~/src/Provers/hypsubst.ML"
    18   "~~/src/Provers/splitter.ML"
    19   "~~/src/Provers/classical.ML"
    20   "~~/src/Provers/blast.ML"
    21   "~~/src/Provers/clasimp.ML"
    22   "~~/src/Provers/coherent.ML"
    23   "~~/src/Provers/eqsubst.ML"
    24   "~~/src/Provers/quantifier1.ML"
    25   ("simpdata.ML")
    26   "~~/src/Tools/random_word.ML"
    27   "~~/src/Tools/atomize_elim.ML"
    28   "~~/src/Tools/induct.ML"
    29   ("~~/src/Tools/induct_tacs.ML")
    30   "~~/src/Tools/code/code_name.ML"
    31   "~~/src/Tools/code/code_funcgr.ML"
    32   "~~/src/Tools/code/code_thingol.ML"
    33   "~~/src/Tools/code/code_printer.ML"
    34   "~~/src/Tools/code/code_target.ML"
    35   "~~/src/Tools/code/code_ml.ML"
    36   "~~/src/Tools/code/code_haskell.ML"
    37   "~~/src/Tools/nbe.ML"
    38   ("~~/src/HOL/Tools/recfun_codegen.ML")
    39 begin
    40 
    41 subsection {* Primitive logic *}
    42 
    43 subsubsection {* Core syntax *}
    44 
    45 classes type
    46 defaultsort type
    47 setup {* ObjectLogic.add_base_sort @{sort type} *}
    48 
    49 arities
    50   "fun" :: (type, type) type
    51   itself :: (type) type
    52 
    53 global
    54 
    55 typedecl bool
    56 
    57 judgment
    58   Trueprop      :: "bool => prop"                   ("(_)" 5)
    59 
    60 consts
    61   Not           :: "bool => bool"                   ("~ _" [40] 40)
    62   True          :: bool
    63   False         :: bool
    64 
    65   The           :: "('a => bool) => 'a"
    66   All           :: "('a => bool) => bool"           (binder "ALL " 10)
    67   Ex            :: "('a => bool) => bool"           (binder "EX " 10)
    68   Ex1           :: "('a => bool) => bool"           (binder "EX! " 10)
    69   Let           :: "['a, 'a => 'b] => 'b"
    70 
    71   "op ="        :: "['a, 'a] => bool"               (infixl "=" 50)
    72   "op &"        :: "[bool, bool] => bool"           (infixr "&" 35)
    73   "op |"        :: "[bool, bool] => bool"           (infixr "|" 30)
    74   "op -->"      :: "[bool, bool] => bool"           (infixr "-->" 25)
    75 
    76 local
    77 
    78 consts
    79   If            :: "[bool, 'a, 'a] => 'a"           ("(if (_)/ then (_)/ else (_))" 10)
    80 
    81 
    82 subsubsection {* Additional concrete syntax *}
    83 
    84 notation (output)
    85   "op ="  (infix "=" 50)
    86 
    87 abbreviation
    88   not_equal :: "['a, 'a] => bool"  (infixl "~=" 50) where
    89   "x ~= y == ~ (x = y)"
    90 
    91 notation (output)
    92   not_equal  (infix "~=" 50)
    93 
    94 notation (xsymbols)
    95   Not  ("\<not> _" [40] 40) and
    96   "op &"  (infixr "\<and>" 35) and
    97   "op |"  (infixr "\<or>" 30) and
    98   "op -->"  (infixr "\<longrightarrow>" 25) and
    99   not_equal  (infix "\<noteq>" 50)
   100 
   101 notation (HTML output)
   102   Not  ("\<not> _" [40] 40) and
   103   "op &"  (infixr "\<and>" 35) and
   104   "op |"  (infixr "\<or>" 30) and
   105   not_equal  (infix "\<noteq>" 50)
   106 
   107 abbreviation (iff)
   108   iff :: "[bool, bool] => bool"  (infixr "<->" 25) where
   109   "A <-> B == A = B"
   110 
   111 notation (xsymbols)
   112   iff  (infixr "\<longleftrightarrow>" 25)
   113 
   114 
   115 nonterminals
   116   letbinds  letbind
   117   case_syn  cases_syn
   118 
   119 syntax
   120   "_The"        :: "[pttrn, bool] => 'a"                 ("(3THE _./ _)" [0, 10] 10)
   121 
   122   "_bind"       :: "[pttrn, 'a] => letbind"              ("(2_ =/ _)" 10)
   123   ""            :: "letbind => letbinds"                 ("_")
   124   "_binds"      :: "[letbind, letbinds] => letbinds"     ("_;/ _")
   125   "_Let"        :: "[letbinds, 'a] => 'a"                ("(let (_)/ in (_))" 10)
   126 
   127   "_case_syntax":: "['a, cases_syn] => 'b"               ("(case _ of/ _)" 10)
   128   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ =>/ _)" 10)
   129   ""            :: "case_syn => cases_syn"               ("_")
   130   "_case2"      :: "[case_syn, cases_syn] => cases_syn"  ("_/ | _")
   131 
   132 translations
   133   "THE x. P"              == "The (%x. P)"
   134   "_Let (_binds b bs) e"  == "_Let b (_Let bs e)"
   135   "let x = a in e"        == "Let a (%x. e)"
   136 
   137 print_translation {*
   138 (* To avoid eta-contraction of body: *)
   139 [("The", fn [Abs abs] =>
   140      let val (x,t) = atomic_abs_tr' abs
   141      in Syntax.const "_The" $ x $ t end)]
   142 *}
   143 
   144 syntax (xsymbols)
   145   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ \<Rightarrow>/ _)" 10)
   146 
   147 notation (xsymbols)
   148   All  (binder "\<forall>" 10) and
   149   Ex  (binder "\<exists>" 10) and
   150   Ex1  (binder "\<exists>!" 10)
   151 
   152 notation (HTML output)
   153   All  (binder "\<forall>" 10) and
   154   Ex  (binder "\<exists>" 10) and
   155   Ex1  (binder "\<exists>!" 10)
   156 
   157 notation (HOL)
   158   All  (binder "! " 10) and
   159   Ex  (binder "? " 10) and
   160   Ex1  (binder "?! " 10)
   161 
   162 
   163 subsubsection {* Axioms and basic definitions *}
   164 
   165 axioms
   166   refl:           "t = (t::'a)"
   167   subst:          "s = t \<Longrightarrow> P s \<Longrightarrow> P t"
   168   ext:            "(!!x::'a. (f x ::'b) = g x) ==> (%x. f x) = (%x. g x)"
   169     -- {*Extensionality is built into the meta-logic, and this rule expresses
   170          a related property.  It is an eta-expanded version of the traditional
   171          rule, and similar to the ABS rule of HOL*}
   172 
   173   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   174 
   175   impI:           "(P ==> Q) ==> P-->Q"
   176   mp:             "[| P-->Q;  P |] ==> Q"
   177 
   178 
   179 defs
   180   True_def:     "True      == ((%x::bool. x) = (%x. x))"
   181   All_def:      "All(P)    == (P = (%x. True))"
   182   Ex_def:       "Ex(P)     == !Q. (!x. P x --> Q) --> Q"
   183   False_def:    "False     == (!P. P)"
   184   not_def:      "~ P       == P-->False"
   185   and_def:      "P & Q     == !R. (P-->Q-->R) --> R"
   186   or_def:       "P | Q     == !R. (P-->R) --> (Q-->R) --> R"
   187   Ex1_def:      "Ex1(P)    == ? x. P(x) & (! y. P(y) --> y=x)"
   188 
   189 axioms
   190   iff:          "(P-->Q) --> (Q-->P) --> (P=Q)"
   191   True_or_False:  "(P=True) | (P=False)"
   192 
   193 defs
   194   Let_def:      "Let s f == f(s)"
   195   if_def:       "If P x y == THE z::'a. (P=True --> z=x) & (P=False --> z=y)"
   196 
   197 finalconsts
   198   "op ="
   199   "op -->"
   200   The
   201 
   202 axiomatization
   203   undefined :: 'a
   204 
   205 abbreviation (input)
   206   "arbitrary \<equiv> undefined"
   207 
   208 
   209 subsubsection {* Generic classes and algebraic operations *}
   210 
   211 class default = type +
   212   fixes default :: 'a
   213 
   214 class zero = type + 
   215   fixes zero :: 'a  ("0")
   216 
   217 class one = type +
   218   fixes one  :: 'a  ("1")
   219 
   220 hide (open) const zero one
   221 
   222 class plus = type +
   223   fixes plus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "+" 65)
   224 
   225 class minus = type +
   226   fixes minus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "-" 65)
   227 
   228 class uminus = type +
   229   fixes uminus :: "'a \<Rightarrow> 'a"  ("- _" [81] 80)
   230 
   231 class times = type +
   232   fixes times :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "*" 70)
   233 
   234 class inverse = type +
   235   fixes inverse :: "'a \<Rightarrow> 'a"
   236     and divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "'/" 70)
   237 
   238 class abs = type +
   239   fixes abs :: "'a \<Rightarrow> 'a"
   240 begin
   241 
   242 notation (xsymbols)
   243   abs  ("\<bar>_\<bar>")
   244 
   245 notation (HTML output)
   246   abs  ("\<bar>_\<bar>")
   247 
   248 end
   249 
   250 class sgn = type +
   251   fixes sgn :: "'a \<Rightarrow> 'a"
   252 
   253 class ord = type +
   254   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   255     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   256 begin
   257 
   258 notation
   259   less_eq  ("op <=") and
   260   less_eq  ("(_/ <= _)" [51, 51] 50) and
   261   less  ("op <") and
   262   less  ("(_/ < _)"  [51, 51] 50)
   263   
   264 notation (xsymbols)
   265   less_eq  ("op \<le>") and
   266   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   267 
   268 notation (HTML output)
   269   less_eq  ("op \<le>") and
   270   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   271 
   272 abbreviation (input)
   273   greater_eq  (infix ">=" 50) where
   274   "x >= y \<equiv> y <= x"
   275 
   276 notation (input)
   277   greater_eq  (infix "\<ge>" 50)
   278 
   279 abbreviation (input)
   280   greater  (infix ">" 50) where
   281   "x > y \<equiv> y < x"
   282 
   283 end
   284 
   285 syntax
   286   "_index1"  :: index    ("\<^sub>1")
   287 translations
   288   (index) "\<^sub>1" => (index) "\<^bsub>\<struct>\<^esub>"
   289 
   290 typed_print_translation {*
   291 let
   292   fun tr' c = (c, fn show_sorts => fn T => fn ts =>
   293     if T = dummyT orelse not (! show_types) andalso can Term.dest_Type T then raise Match
   294     else Syntax.const Syntax.constrainC $ Syntax.const c $ Syntax.term_of_typ show_sorts T);
   295 in map tr' [@{const_syntax HOL.one}, @{const_syntax HOL.zero}] end;
   296 *} -- {* show types that are presumably too general *}
   297 
   298 
   299 subsection {* Fundamental rules *}
   300 
   301 subsubsection {* Equality *}
   302 
   303 lemma sym: "s = t ==> t = s"
   304   by (erule subst) (rule refl)
   305 
   306 lemma ssubst: "t = s ==> P s ==> P t"
   307   by (drule sym) (erule subst)
   308 
   309 lemma trans: "[| r=s; s=t |] ==> r=t"
   310   by (erule subst)
   311 
   312 lemma meta_eq_to_obj_eq: 
   313   assumes meq: "A == B"
   314   shows "A = B"
   315   by (unfold meq) (rule refl)
   316 
   317 text {* Useful with @{text erule} for proving equalities from known equalities. *}
   318      (* a = b
   319         |   |
   320         c = d   *)
   321 lemma box_equals: "[| a=b;  a=c;  b=d |] ==> c=d"
   322 apply (rule trans)
   323 apply (rule trans)
   324 apply (rule sym)
   325 apply assumption+
   326 done
   327 
   328 text {* For calculational reasoning: *}
   329 
   330 lemma forw_subst: "a = b ==> P b ==> P a"
   331   by (rule ssubst)
   332 
   333 lemma back_subst: "P a ==> a = b ==> P b"
   334   by (rule subst)
   335 
   336 
   337 subsubsection {*Congruence rules for application*}
   338 
   339 (*similar to AP_THM in Gordon's HOL*)
   340 lemma fun_cong: "(f::'a=>'b) = g ==> f(x)=g(x)"
   341 apply (erule subst)
   342 apply (rule refl)
   343 done
   344 
   345 (*similar to AP_TERM in Gordon's HOL and FOL's subst_context*)
   346 lemma arg_cong: "x=y ==> f(x)=f(y)"
   347 apply (erule subst)
   348 apply (rule refl)
   349 done
   350 
   351 lemma arg_cong2: "\<lbrakk> a = b; c = d \<rbrakk> \<Longrightarrow> f a c = f b d"
   352 apply (erule ssubst)+
   353 apply (rule refl)
   354 done
   355 
   356 lemma cong: "[| f = g; (x::'a) = y |] ==> f(x) = g(y)"
   357 apply (erule subst)+
   358 apply (rule refl)
   359 done
   360 
   361 
   362 subsubsection {*Equality of booleans -- iff*}
   363 
   364 lemma iffI: assumes "P ==> Q" and "Q ==> P" shows "P=Q"
   365   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
   366 
   367 lemma iffD2: "[| P=Q; Q |] ==> P"
   368   by (erule ssubst)
   369 
   370 lemma rev_iffD2: "[| Q; P=Q |] ==> P"
   371   by (erule iffD2)
   372 
   373 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
   374   by (drule sym) (rule iffD2)
   375 
   376 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
   377   by (drule sym) (rule rev_iffD2)
   378 
   379 lemma iffE:
   380   assumes major: "P=Q"
   381     and minor: "[| P --> Q; Q --> P |] ==> R"
   382   shows R
   383   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
   384 
   385 
   386 subsubsection {*True*}
   387 
   388 lemma TrueI: "True"
   389   unfolding True_def by (rule refl)
   390 
   391 lemma eqTrueI: "P ==> P = True"
   392   by (iprover intro: iffI TrueI)
   393 
   394 lemma eqTrueE: "P = True ==> P"
   395   by (erule iffD2) (rule TrueI)
   396 
   397 
   398 subsubsection {*Universal quantifier*}
   399 
   400 lemma allI: assumes "!!x::'a. P(x)" shows "ALL x. P(x)"
   401   unfolding All_def by (iprover intro: ext eqTrueI assms)
   402 
   403 lemma spec: "ALL x::'a. P(x) ==> P(x)"
   404 apply (unfold All_def)
   405 apply (rule eqTrueE)
   406 apply (erule fun_cong)
   407 done
   408 
   409 lemma allE:
   410   assumes major: "ALL x. P(x)"
   411     and minor: "P(x) ==> R"
   412   shows R
   413   by (iprover intro: minor major [THEN spec])
   414 
   415 lemma all_dupE:
   416   assumes major: "ALL x. P(x)"
   417     and minor: "[| P(x); ALL x. P(x) |] ==> R"
   418   shows R
   419   by (iprover intro: minor major major [THEN spec])
   420 
   421 
   422 subsubsection {* False *}
   423 
   424 text {*
   425   Depends upon @{text spec}; it is impossible to do propositional
   426   logic before quantifiers!
   427 *}
   428 
   429 lemma FalseE: "False ==> P"
   430   apply (unfold False_def)
   431   apply (erule spec)
   432   done
   433 
   434 lemma False_neq_True: "False = True ==> P"
   435   by (erule eqTrueE [THEN FalseE])
   436 
   437 
   438 subsubsection {* Negation *}
   439 
   440 lemma notI:
   441   assumes "P ==> False"
   442   shows "~P"
   443   apply (unfold not_def)
   444   apply (iprover intro: impI assms)
   445   done
   446 
   447 lemma False_not_True: "False ~= True"
   448   apply (rule notI)
   449   apply (erule False_neq_True)
   450   done
   451 
   452 lemma True_not_False: "True ~= False"
   453   apply (rule notI)
   454   apply (drule sym)
   455   apply (erule False_neq_True)
   456   done
   457 
   458 lemma notE: "[| ~P;  P |] ==> R"
   459   apply (unfold not_def)
   460   apply (erule mp [THEN FalseE])
   461   apply assumption
   462   done
   463 
   464 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
   465   by (erule notE [THEN notI]) (erule meta_mp)
   466 
   467 
   468 subsubsection {*Implication*}
   469 
   470 lemma impE:
   471   assumes "P-->Q" "P" "Q ==> R"
   472   shows "R"
   473 by (iprover intro: assms mp)
   474 
   475 (* Reduces Q to P-->Q, allowing substitution in P. *)
   476 lemma rev_mp: "[| P;  P --> Q |] ==> Q"
   477 by (iprover intro: mp)
   478 
   479 lemma contrapos_nn:
   480   assumes major: "~Q"
   481       and minor: "P==>Q"
   482   shows "~P"
   483 by (iprover intro: notI minor major [THEN notE])
   484 
   485 (*not used at all, but we already have the other 3 combinations *)
   486 lemma contrapos_pn:
   487   assumes major: "Q"
   488       and minor: "P ==> ~Q"
   489   shows "~P"
   490 by (iprover intro: notI minor major notE)
   491 
   492 lemma not_sym: "t ~= s ==> s ~= t"
   493   by (erule contrapos_nn) (erule sym)
   494 
   495 lemma eq_neq_eq_imp_neq: "[| x = a ; a ~= b; b = y |] ==> x ~= y"
   496   by (erule subst, erule ssubst, assumption)
   497 
   498 (*still used in HOLCF*)
   499 lemma rev_contrapos:
   500   assumes pq: "P ==> Q"
   501       and nq: "~Q"
   502   shows "~P"
   503 apply (rule nq [THEN contrapos_nn])
   504 apply (erule pq)
   505 done
   506 
   507 subsubsection {*Existential quantifier*}
   508 
   509 lemma exI: "P x ==> EX x::'a. P x"
   510 apply (unfold Ex_def)
   511 apply (iprover intro: allI allE impI mp)
   512 done
   513 
   514 lemma exE:
   515   assumes major: "EX x::'a. P(x)"
   516       and minor: "!!x. P(x) ==> Q"
   517   shows "Q"
   518 apply (rule major [unfolded Ex_def, THEN spec, THEN mp])
   519 apply (iprover intro: impI [THEN allI] minor)
   520 done
   521 
   522 
   523 subsubsection {*Conjunction*}
   524 
   525 lemma conjI: "[| P; Q |] ==> P&Q"
   526 apply (unfold and_def)
   527 apply (iprover intro: impI [THEN allI] mp)
   528 done
   529 
   530 lemma conjunct1: "[| P & Q |] ==> P"
   531 apply (unfold and_def)
   532 apply (iprover intro: impI dest: spec mp)
   533 done
   534 
   535 lemma conjunct2: "[| P & Q |] ==> Q"
   536 apply (unfold and_def)
   537 apply (iprover intro: impI dest: spec mp)
   538 done
   539 
   540 lemma conjE:
   541   assumes major: "P&Q"
   542       and minor: "[| P; Q |] ==> R"
   543   shows "R"
   544 apply (rule minor)
   545 apply (rule major [THEN conjunct1])
   546 apply (rule major [THEN conjunct2])
   547 done
   548 
   549 lemma context_conjI:
   550   assumes "P" "P ==> Q" shows "P & Q"
   551 by (iprover intro: conjI assms)
   552 
   553 
   554 subsubsection {*Disjunction*}
   555 
   556 lemma disjI1: "P ==> P|Q"
   557 apply (unfold or_def)
   558 apply (iprover intro: allI impI mp)
   559 done
   560 
   561 lemma disjI2: "Q ==> P|Q"
   562 apply (unfold or_def)
   563 apply (iprover intro: allI impI mp)
   564 done
   565 
   566 lemma disjE:
   567   assumes major: "P|Q"
   568       and minorP: "P ==> R"
   569       and minorQ: "Q ==> R"
   570   shows "R"
   571 by (iprover intro: minorP minorQ impI
   572                  major [unfolded or_def, THEN spec, THEN mp, THEN mp])
   573 
   574 
   575 subsubsection {*Classical logic*}
   576 
   577 lemma classical:
   578   assumes prem: "~P ==> P"
   579   shows "P"
   580 apply (rule True_or_False [THEN disjE, THEN eqTrueE])
   581 apply assumption
   582 apply (rule notI [THEN prem, THEN eqTrueI])
   583 apply (erule subst)
   584 apply assumption
   585 done
   586 
   587 lemmas ccontr = FalseE [THEN classical, standard]
   588 
   589 (*notE with premises exchanged; it discharges ~R so that it can be used to
   590   make elimination rules*)
   591 lemma rev_notE:
   592   assumes premp: "P"
   593       and premnot: "~R ==> ~P"
   594   shows "R"
   595 apply (rule ccontr)
   596 apply (erule notE [OF premnot premp])
   597 done
   598 
   599 (*Double negation law*)
   600 lemma notnotD: "~~P ==> P"
   601 apply (rule classical)
   602 apply (erule notE)
   603 apply assumption
   604 done
   605 
   606 lemma contrapos_pp:
   607   assumes p1: "Q"
   608       and p2: "~P ==> ~Q"
   609   shows "P"
   610 by (iprover intro: classical p1 p2 notE)
   611 
   612 
   613 subsubsection {*Unique existence*}
   614 
   615 lemma ex1I:
   616   assumes "P a" "!!x. P(x) ==> x=a"
   617   shows "EX! x. P(x)"
   618 by (unfold Ex1_def, iprover intro: assms exI conjI allI impI)
   619 
   620 text{*Sometimes easier to use: the premises have no shared variables.  Safe!*}
   621 lemma ex_ex1I:
   622   assumes ex_prem: "EX x. P(x)"
   623       and eq: "!!x y. [| P(x); P(y) |] ==> x=y"
   624   shows "EX! x. P(x)"
   625 by (iprover intro: ex_prem [THEN exE] ex1I eq)
   626 
   627 lemma ex1E:
   628   assumes major: "EX! x. P(x)"
   629       and minor: "!!x. [| P(x);  ALL y. P(y) --> y=x |] ==> R"
   630   shows "R"
   631 apply (rule major [unfolded Ex1_def, THEN exE])
   632 apply (erule conjE)
   633 apply (iprover intro: minor)
   634 done
   635 
   636 lemma ex1_implies_ex: "EX! x. P x ==> EX x. P x"
   637 apply (erule ex1E)
   638 apply (rule exI)
   639 apply assumption
   640 done
   641 
   642 
   643 subsubsection {*THE: definite description operator*}
   644 
   645 lemma the_equality:
   646   assumes prema: "P a"
   647       and premx: "!!x. P x ==> x=a"
   648   shows "(THE x. P x) = a"
   649 apply (rule trans [OF _ the_eq_trivial])
   650 apply (rule_tac f = "The" in arg_cong)
   651 apply (rule ext)
   652 apply (rule iffI)
   653  apply (erule premx)
   654 apply (erule ssubst, rule prema)
   655 done
   656 
   657 lemma theI:
   658   assumes "P a" and "!!x. P x ==> x=a"
   659   shows "P (THE x. P x)"
   660 by (iprover intro: assms the_equality [THEN ssubst])
   661 
   662 lemma theI': "EX! x. P x ==> P (THE x. P x)"
   663 apply (erule ex1E)
   664 apply (erule theI)
   665 apply (erule allE)
   666 apply (erule mp)
   667 apply assumption
   668 done
   669 
   670 (*Easier to apply than theI: only one occurrence of P*)
   671 lemma theI2:
   672   assumes "P a" "!!x. P x ==> x=a" "!!x. P x ==> Q x"
   673   shows "Q (THE x. P x)"
   674 by (iprover intro: assms theI)
   675 
   676 lemma the1I2: assumes "EX! x. P x" "\<And>x. P x \<Longrightarrow> Q x" shows "Q (THE x. P x)"
   677 by(iprover intro:assms(2) theI2[where P=P and Q=Q] ex1E[OF assms(1)]
   678            elim:allE impE)
   679 
   680 lemma the1_equality [elim?]: "[| EX!x. P x; P a |] ==> (THE x. P x) = a"
   681 apply (rule the_equality)
   682 apply  assumption
   683 apply (erule ex1E)
   684 apply (erule all_dupE)
   685 apply (drule mp)
   686 apply  assumption
   687 apply (erule ssubst)
   688 apply (erule allE)
   689 apply (erule mp)
   690 apply assumption
   691 done
   692 
   693 lemma the_sym_eq_trivial: "(THE y. x=y) = x"
   694 apply (rule the_equality)
   695 apply (rule refl)
   696 apply (erule sym)
   697 done
   698 
   699 
   700 subsubsection {*Classical intro rules for disjunction and existential quantifiers*}
   701 
   702 lemma disjCI:
   703   assumes "~Q ==> P" shows "P|Q"
   704 apply (rule classical)
   705 apply (iprover intro: assms disjI1 disjI2 notI elim: notE)
   706 done
   707 
   708 lemma excluded_middle: "~P | P"
   709 by (iprover intro: disjCI)
   710 
   711 text {*
   712   case distinction as a natural deduction rule.
   713   Note that @{term "~P"} is the second case, not the first
   714 *}
   715 lemma case_split [case_names True False]:
   716   assumes prem1: "P ==> Q"
   717       and prem2: "~P ==> Q"
   718   shows "Q"
   719 apply (rule excluded_middle [THEN disjE])
   720 apply (erule prem2)
   721 apply (erule prem1)
   722 done
   723 
   724 (*Classical implies (-->) elimination. *)
   725 lemma impCE:
   726   assumes major: "P-->Q"
   727       and minor: "~P ==> R" "Q ==> R"
   728   shows "R"
   729 apply (rule excluded_middle [of P, THEN disjE])
   730 apply (iprover intro: minor major [THEN mp])+
   731 done
   732 
   733 (*This version of --> elimination works on Q before P.  It works best for
   734   those cases in which P holds "almost everywhere".  Can't install as
   735   default: would break old proofs.*)
   736 lemma impCE':
   737   assumes major: "P-->Q"
   738       and minor: "Q ==> R" "~P ==> R"
   739   shows "R"
   740 apply (rule excluded_middle [of P, THEN disjE])
   741 apply (iprover intro: minor major [THEN mp])+
   742 done
   743 
   744 (*Classical <-> elimination. *)
   745 lemma iffCE:
   746   assumes major: "P=Q"
   747       and minor: "[| P; Q |] ==> R"  "[| ~P; ~Q |] ==> R"
   748   shows "R"
   749 apply (rule major [THEN iffE])
   750 apply (iprover intro: minor elim: impCE notE)
   751 done
   752 
   753 lemma exCI:
   754   assumes "ALL x. ~P(x) ==> P(a)"
   755   shows "EX x. P(x)"
   756 apply (rule ccontr)
   757 apply (iprover intro: assms exI allI notI notE [of "\<exists>x. P x"])
   758 done
   759 
   760 
   761 subsubsection {* Intuitionistic Reasoning *}
   762 
   763 lemma impE':
   764   assumes 1: "P --> Q"
   765     and 2: "Q ==> R"
   766     and 3: "P --> Q ==> P"
   767   shows R
   768 proof -
   769   from 3 and 1 have P .
   770   with 1 have Q by (rule impE)
   771   with 2 show R .
   772 qed
   773 
   774 lemma allE':
   775   assumes 1: "ALL x. P x"
   776     and 2: "P x ==> ALL x. P x ==> Q"
   777   shows Q
   778 proof -
   779   from 1 have "P x" by (rule spec)
   780   from this and 1 show Q by (rule 2)
   781 qed
   782 
   783 lemma notE':
   784   assumes 1: "~ P"
   785     and 2: "~ P ==> P"
   786   shows R
   787 proof -
   788   from 2 and 1 have P .
   789   with 1 show R by (rule notE)
   790 qed
   791 
   792 lemma TrueE: "True ==> P ==> P" .
   793 lemma notFalseE: "~ False ==> P ==> P" .
   794 
   795 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
   796   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
   797   and [Pure.elim 2] = allE notE' impE'
   798   and [Pure.intro] = exI disjI2 disjI1
   799 
   800 lemmas [trans] = trans
   801   and [sym] = sym not_sym
   802   and [Pure.elim?] = iffD1 iffD2 impE
   803 
   804 use "hologic.ML"
   805 
   806 
   807 subsubsection {* Atomizing meta-level connectives *}
   808 
   809 axiomatization where
   810   eq_reflection: "x = y \<Longrightarrow> x \<equiv> y" (*admissible axiom*)
   811 
   812 lemma atomize_all [atomize]: "(!!x. P x) == Trueprop (ALL x. P x)"
   813 proof
   814   assume "!!x. P x"
   815   then show "ALL x. P x" ..
   816 next
   817   assume "ALL x. P x"
   818   then show "!!x. P x" by (rule allE)
   819 qed
   820 
   821 lemma atomize_imp [atomize]: "(A ==> B) == Trueprop (A --> B)"
   822 proof
   823   assume r: "A ==> B"
   824   show "A --> B" by (rule impI) (rule r)
   825 next
   826   assume "A --> B" and A
   827   then show B by (rule mp)
   828 qed
   829 
   830 lemma atomize_not: "(A ==> False) == Trueprop (~A)"
   831 proof
   832   assume r: "A ==> False"
   833   show "~A" by (rule notI) (rule r)
   834 next
   835   assume "~A" and A
   836   then show False by (rule notE)
   837 qed
   838 
   839 lemma atomize_eq [atomize]: "(x == y) == Trueprop (x = y)"
   840 proof
   841   assume "x == y"
   842   show "x = y" by (unfold `x == y`) (rule refl)
   843 next
   844   assume "x = y"
   845   then show "x == y" by (rule eq_reflection)
   846 qed
   847 
   848 lemma atomize_conj [atomize]:
   849   includes meta_conjunction_syntax
   850   shows "(A && B) == Trueprop (A & B)"
   851 proof
   852   assume conj: "A && B"
   853   show "A & B"
   854   proof (rule conjI)
   855     from conj show A by (rule conjunctionD1)
   856     from conj show B by (rule conjunctionD2)
   857   qed
   858 next
   859   assume conj: "A & B"
   860   show "A && B"
   861   proof -
   862     from conj show A ..
   863     from conj show B ..
   864   qed
   865 qed
   866 
   867 lemmas [symmetric, rulify] = atomize_all atomize_imp
   868   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
   869 
   870 
   871 subsubsection {* Atomizing elimination rules *}
   872 
   873 setup AtomizeElim.setup
   874 
   875 lemma atomize_exL[atomize_elim]: "(!!x. P x ==> Q) == ((EX x. P x) ==> Q)"
   876   by rule iprover+
   877 
   878 lemma atomize_conjL[atomize_elim]: "(A ==> B ==> C) == (A & B ==> C)"
   879   by rule iprover+
   880 
   881 lemma atomize_disjL[atomize_elim]: "((A ==> C) ==> (B ==> C) ==> C) == ((A | B ==> C) ==> C)"
   882   by rule iprover+
   883 
   884 lemma atomize_elimL[atomize_elim]: "(!!B. (A ==> B) ==> B) == Trueprop A" ..
   885 
   886 
   887 subsection {* Package setup *}
   888 
   889 subsubsection {* Classical Reasoner setup *}
   890 
   891 lemma imp_elim: "P --> Q ==> (~ R ==> P) ==> (Q ==> R) ==> R"
   892   by (rule classical) iprover
   893 
   894 lemma swap: "~ P ==> (~ R ==> P) ==> R"
   895   by (rule classical) iprover
   896 
   897 lemma thin_refl:
   898   "\<And>X. \<lbrakk> x=x; PROP W \<rbrakk> \<Longrightarrow> PROP W" .
   899 
   900 ML {*
   901 structure Hypsubst = HypsubstFun(
   902 struct
   903   structure Simplifier = Simplifier
   904   val dest_eq = HOLogic.dest_eq
   905   val dest_Trueprop = HOLogic.dest_Trueprop
   906   val dest_imp = HOLogic.dest_imp
   907   val eq_reflection = @{thm eq_reflection}
   908   val rev_eq_reflection = @{thm meta_eq_to_obj_eq}
   909   val imp_intr = @{thm impI}
   910   val rev_mp = @{thm rev_mp}
   911   val subst = @{thm subst}
   912   val sym = @{thm sym}
   913   val thin_refl = @{thm thin_refl};
   914   val prop_subst = @{lemma "PROP P t ==> PROP prop (x = t ==> PROP P x)"
   915                      by (unfold prop_def) (drule eq_reflection, unfold)}
   916 end);
   917 open Hypsubst;
   918 
   919 structure Classical = ClassicalFun(
   920 struct
   921   val imp_elim = @{thm imp_elim}
   922   val not_elim = @{thm notE}
   923   val swap = @{thm swap}
   924   val classical = @{thm classical}
   925   val sizef = Drule.size_of_thm
   926   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
   927 end);
   928 
   929 structure BasicClassical: BASIC_CLASSICAL = Classical; 
   930 open BasicClassical;
   931 
   932 ML_Antiquote.value "claset"
   933   (Scan.succeed "Classical.local_claset_of (ML_Context.the_local_context ())");
   934 
   935 structure ResAtpset = NamedThmsFun(val name = "atp" val description = "ATP rules");
   936 
   937 structure ResBlacklist = NamedThmsFun(val name = "noatp" val description = "Theorems blacklisted for ATP");
   938 *}
   939 
   940 text {*ResBlacklist holds theorems blacklisted to sledgehammer. 
   941   These theorems typically produce clauses that are prolific (match too many equality or
   942   membership literals) and relate to seldom-used facts. Some duplicate other rules.*}
   943 
   944 setup {*
   945 let
   946   (*prevent substitution on bool*)
   947   fun hyp_subst_tac' i thm = if i <= Thm.nprems_of thm andalso
   948     Term.exists_Const (fn ("op =", Type (_, [T, _])) => T <> Type ("bool", []) | _ => false)
   949       (nth (Thm.prems_of thm) (i - 1)) then Hypsubst.hyp_subst_tac i thm else no_tac thm;
   950 in
   951   Hypsubst.hypsubst_setup
   952   #> ContextRules.addSWrapper (fn tac => hyp_subst_tac' ORELSE' tac)
   953   #> Classical.setup
   954   #> ResAtpset.setup
   955   #> ResBlacklist.setup
   956 end
   957 *}
   958 
   959 declare iffI [intro!]
   960   and notI [intro!]
   961   and impI [intro!]
   962   and disjCI [intro!]
   963   and conjI [intro!]
   964   and TrueI [intro!]
   965   and refl [intro!]
   966 
   967 declare iffCE [elim!]
   968   and FalseE [elim!]
   969   and impCE [elim!]
   970   and disjE [elim!]
   971   and conjE [elim!]
   972   and conjE [elim!]
   973 
   974 declare ex_ex1I [intro!]
   975   and allI [intro!]
   976   and the_equality [intro]
   977   and exI [intro]
   978 
   979 declare exE [elim!]
   980   allE [elim]
   981 
   982 ML {* val HOL_cs = @{claset} *}
   983 
   984 lemma contrapos_np: "~ Q ==> (~ P ==> Q) ==> P"
   985   apply (erule swap)
   986   apply (erule (1) meta_mp)
   987   done
   988 
   989 declare ex_ex1I [rule del, intro! 2]
   990   and ex1I [intro]
   991 
   992 lemmas [intro?] = ext
   993   and [elim?] = ex1_implies_ex
   994 
   995 (*Better then ex1E for classical reasoner: needs no quantifier duplication!*)
   996 lemma alt_ex1E [elim!]:
   997   assumes major: "\<exists>!x. P x"
   998       and prem: "\<And>x. \<lbrakk> P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y' \<rbrakk> \<Longrightarrow> R"
   999   shows R
  1000 apply (rule ex1E [OF major])
  1001 apply (rule prem)
  1002 apply (tactic {* ares_tac @{thms allI} 1 *})+
  1003 apply (tactic {* etac (Classical.dup_elim @{thm allE}) 1 *})
  1004 apply iprover
  1005 done
  1006 
  1007 ML {*
  1008 structure Blast = BlastFun
  1009 (
  1010   type claset = Classical.claset
  1011   val equality_name = @{const_name "op ="}
  1012   val not_name = @{const_name Not}
  1013   val notE = @{thm notE}
  1014   val ccontr = @{thm ccontr}
  1015   val contr_tac = Classical.contr_tac
  1016   val dup_intr = Classical.dup_intr
  1017   val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
  1018   val claset = Classical.claset
  1019   val rep_cs = Classical.rep_cs
  1020   val cla_modifiers = Classical.cla_modifiers
  1021   val cla_meth' = Classical.cla_meth'
  1022 );
  1023 val Blast_tac = Blast.Blast_tac;
  1024 val blast_tac = Blast.blast_tac;
  1025 *}
  1026 
  1027 setup Blast.setup
  1028 
  1029 
  1030 subsubsection {* Simplifier *}
  1031 
  1032 lemma eta_contract_eq: "(%s. f s) = f" ..
  1033 
  1034 lemma simp_thms:
  1035   shows not_not: "(~ ~ P) = P"
  1036   and Not_eq_iff: "((~P) = (~Q)) = (P = Q)"
  1037   and
  1038     "(P ~= Q) = (P = (~Q))"
  1039     "(P | ~P) = True"    "(~P | P) = True"
  1040     "(x = x) = True"
  1041   and not_True_eq_False: "(\<not> True) = False"
  1042   and not_False_eq_True: "(\<not> False) = True"
  1043   and
  1044     "(~P) ~= P"  "P ~= (~P)"
  1045     "(True=P) = P"
  1046   and eq_True: "(P = True) = P"
  1047   and "(False=P) = (~P)"
  1048   and eq_False: "(P = False) = (\<not> P)"
  1049   and
  1050     "(True --> P) = P"  "(False --> P) = True"
  1051     "(P --> True) = True"  "(P --> P) = True"
  1052     "(P --> False) = (~P)"  "(P --> ~P) = (~P)"
  1053     "(P & True) = P"  "(True & P) = P"
  1054     "(P & False) = False"  "(False & P) = False"
  1055     "(P & P) = P"  "(P & (P & Q)) = (P & Q)"
  1056     "(P & ~P) = False"    "(~P & P) = False"
  1057     "(P | True) = True"  "(True | P) = True"
  1058     "(P | False) = P"  "(False | P) = P"
  1059     "(P | P) = P"  "(P | (P | Q)) = (P | Q)" and
  1060     "(ALL x. P) = P"  "(EX x. P) = P"  "EX x. x=t"  "EX x. t=x"
  1061     -- {* needed for the one-point-rule quantifier simplification procs *}
  1062     -- {* essential for termination!! *} and
  1063     "!!P. (EX x. x=t & P(x)) = P(t)"
  1064     "!!P. (EX x. t=x & P(x)) = P(t)"
  1065     "!!P. (ALL x. x=t --> P(x)) = P(t)"
  1066     "!!P. (ALL x. t=x --> P(x)) = P(t)"
  1067   by (blast, blast, blast, blast, blast, iprover+)
  1068 
  1069 lemma disj_absorb: "(A | A) = A"
  1070   by blast
  1071 
  1072 lemma disj_left_absorb: "(A | (A | B)) = (A | B)"
  1073   by blast
  1074 
  1075 lemma conj_absorb: "(A & A) = A"
  1076   by blast
  1077 
  1078 lemma conj_left_absorb: "(A & (A & B)) = (A & B)"
  1079   by blast
  1080 
  1081 lemma eq_ac:
  1082   shows eq_commute: "(a=b) = (b=a)"
  1083     and eq_left_commute: "(P=(Q=R)) = (Q=(P=R))"
  1084     and eq_assoc: "((P=Q)=R) = (P=(Q=R))" by (iprover, blast+)
  1085 lemma neq_commute: "(a~=b) = (b~=a)" by iprover
  1086 
  1087 lemma conj_comms:
  1088   shows conj_commute: "(P&Q) = (Q&P)"
  1089     and conj_left_commute: "(P&(Q&R)) = (Q&(P&R))" by iprover+
  1090 lemma conj_assoc: "((P&Q)&R) = (P&(Q&R))" by iprover
  1091 
  1092 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
  1093 
  1094 lemma disj_comms:
  1095   shows disj_commute: "(P|Q) = (Q|P)"
  1096     and disj_left_commute: "(P|(Q|R)) = (Q|(P|R))" by iprover+
  1097 lemma disj_assoc: "((P|Q)|R) = (P|(Q|R))" by iprover
  1098 
  1099 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
  1100 
  1101 lemma conj_disj_distribL: "(P&(Q|R)) = (P&Q | P&R)" by iprover
  1102 lemma conj_disj_distribR: "((P|Q)&R) = (P&R | Q&R)" by iprover
  1103 
  1104 lemma disj_conj_distribL: "(P|(Q&R)) = ((P|Q) & (P|R))" by iprover
  1105 lemma disj_conj_distribR: "((P&Q)|R) = ((P|R) & (Q|R))" by iprover
  1106 
  1107 lemma imp_conjR: "(P --> (Q&R)) = ((P-->Q) & (P-->R))" by iprover
  1108 lemma imp_conjL: "((P&Q) -->R)  = (P --> (Q --> R))" by iprover
  1109 lemma imp_disjL: "((P|Q) --> R) = ((P-->R)&(Q-->R))" by iprover
  1110 
  1111 text {* These two are specialized, but @{text imp_disj_not1} is useful in @{text "Auth/Yahalom"}. *}
  1112 lemma imp_disj_not1: "(P --> Q | R) = (~Q --> P --> R)" by blast
  1113 lemma imp_disj_not2: "(P --> Q | R) = (~R --> P --> Q)" by blast
  1114 
  1115 lemma imp_disj1: "((P-->Q)|R) = (P--> Q|R)" by blast
  1116 lemma imp_disj2: "(Q|(P-->R)) = (P--> Q|R)" by blast
  1117 
  1118 lemma imp_cong: "(P = P') ==> (P' ==> (Q = Q')) ==> ((P --> Q) = (P' --> Q'))"
  1119   by iprover
  1120 
  1121 lemma de_Morgan_disj: "(~(P | Q)) = (~P & ~Q)" by iprover
  1122 lemma de_Morgan_conj: "(~(P & Q)) = (~P | ~Q)" by blast
  1123 lemma not_imp: "(~(P --> Q)) = (P & ~Q)" by blast
  1124 lemma not_iff: "(P~=Q) = (P = (~Q))" by blast
  1125 lemma disj_not1: "(~P | Q) = (P --> Q)" by blast
  1126 lemma disj_not2: "(P | ~Q) = (Q --> P)"  -- {* changes orientation :-( *}
  1127   by blast
  1128 lemma imp_conv_disj: "(P --> Q) = ((~P) | Q)" by blast
  1129 
  1130 lemma iff_conv_conj_imp: "(P = Q) = ((P --> Q) & (Q --> P))" by iprover
  1131 
  1132 
  1133 lemma cases_simp: "((P --> Q) & (~P --> Q)) = Q"
  1134   -- {* Avoids duplication of subgoals after @{text split_if}, when the true and false *}
  1135   -- {* cases boil down to the same thing. *}
  1136   by blast
  1137 
  1138 lemma not_all: "(~ (! x. P(x))) = (? x.~P(x))" by blast
  1139 lemma imp_all: "((! x. P x) --> Q) = (? x. P x --> Q)" by blast
  1140 lemma not_ex: "(~ (? x. P(x))) = (! x.~P(x))" by iprover
  1141 lemma imp_ex: "((? x. P x) --> Q) = (! x. P x --> Q)" by iprover
  1142 lemma all_not_ex: "(ALL x. P x) = (~ (EX x. ~ P x ))" by blast
  1143 
  1144 declare All_def [noatp]
  1145 
  1146 lemma ex_disj_distrib: "(? x. P(x) | Q(x)) = ((? x. P(x)) | (? x. Q(x)))" by iprover
  1147 lemma all_conj_distrib: "(!x. P(x) & Q(x)) = ((! x. P(x)) & (! x. Q(x)))" by iprover
  1148 
  1149 text {*
  1150   \medskip The @{text "&"} congruence rule: not included by default!
  1151   May slow rewrite proofs down by as much as 50\% *}
  1152 
  1153 lemma conj_cong:
  1154     "(P = P') ==> (P' ==> (Q = Q')) ==> ((P & Q) = (P' & Q'))"
  1155   by iprover
  1156 
  1157 lemma rev_conj_cong:
  1158     "(Q = Q') ==> (Q' ==> (P = P')) ==> ((P & Q) = (P' & Q'))"
  1159   by iprover
  1160 
  1161 text {* The @{text "|"} congruence rule: not included by default! *}
  1162 
  1163 lemma disj_cong:
  1164     "(P = P') ==> (~P' ==> (Q = Q')) ==> ((P | Q) = (P' | Q'))"
  1165   by blast
  1166 
  1167 
  1168 text {* \medskip if-then-else rules *}
  1169 
  1170 lemma if_True: "(if True then x else y) = x"
  1171   by (unfold if_def) blast
  1172 
  1173 lemma if_False: "(if False then x else y) = y"
  1174   by (unfold if_def) blast
  1175 
  1176 lemma if_P: "P ==> (if P then x else y) = x"
  1177   by (unfold if_def) blast
  1178 
  1179 lemma if_not_P: "~P ==> (if P then x else y) = y"
  1180   by (unfold if_def) blast
  1181 
  1182 lemma split_if: "P (if Q then x else y) = ((Q --> P(x)) & (~Q --> P(y)))"
  1183   apply (rule case_split [of Q])
  1184    apply (simplesubst if_P)
  1185     prefer 3 apply (simplesubst if_not_P, blast+)
  1186   done
  1187 
  1188 lemma split_if_asm: "P (if Q then x else y) = (~((Q & ~P x) | (~Q & ~P y)))"
  1189 by (simplesubst split_if, blast)
  1190 
  1191 lemmas if_splits [noatp] = split_if split_if_asm
  1192 
  1193 lemma if_cancel: "(if c then x else x) = x"
  1194 by (simplesubst split_if, blast)
  1195 
  1196 lemma if_eq_cancel: "(if x = y then y else x) = x"
  1197 by (simplesubst split_if, blast)
  1198 
  1199 lemma if_bool_eq_conj: "(if P then Q else R) = ((P-->Q) & (~P-->R))"
  1200   -- {* This form is useful for expanding @{text "if"}s on the RIGHT of the @{text "==>"} symbol. *}
  1201   by (rule split_if)
  1202 
  1203 lemma if_bool_eq_disj: "(if P then Q else R) = ((P&Q) | (~P&R))"
  1204   -- {* And this form is useful for expanding @{text "if"}s on the LEFT. *}
  1205   apply (simplesubst split_if, blast)
  1206   done
  1207 
  1208 lemma Eq_TrueI: "P ==> P == True" by (unfold atomize_eq) iprover
  1209 lemma Eq_FalseI: "~P ==> P == False" by (unfold atomize_eq) iprover
  1210 
  1211 text {* \medskip let rules for simproc *}
  1212 
  1213 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow>  Let x f \<equiv> Let x g"
  1214   by (unfold Let_def)
  1215 
  1216 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow>  Let x f \<equiv> g"
  1217   by (unfold Let_def)
  1218 
  1219 text {*
  1220   The following copy of the implication operator is useful for
  1221   fine-tuning congruence rules.  It instructs the simplifier to simplify
  1222   its premise.
  1223 *}
  1224 
  1225 constdefs
  1226   simp_implies :: "[prop, prop] => prop"  (infixr "=simp=>" 1)
  1227   [code del]: "simp_implies \<equiv> op ==>"
  1228 
  1229 lemma simp_impliesI:
  1230   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
  1231   shows "PROP P =simp=> PROP Q"
  1232   apply (unfold simp_implies_def)
  1233   apply (rule PQ)
  1234   apply assumption
  1235   done
  1236 
  1237 lemma simp_impliesE:
  1238   assumes PQ: "PROP P =simp=> PROP Q"
  1239   and P: "PROP P"
  1240   and QR: "PROP Q \<Longrightarrow> PROP R"
  1241   shows "PROP R"
  1242   apply (rule QR)
  1243   apply (rule PQ [unfolded simp_implies_def])
  1244   apply (rule P)
  1245   done
  1246 
  1247 lemma simp_implies_cong:
  1248   assumes PP' :"PROP P == PROP P'"
  1249   and P'QQ': "PROP P' ==> (PROP Q == PROP Q')"
  1250   shows "(PROP P =simp=> PROP Q) == (PROP P' =simp=> PROP Q')"
  1251 proof (unfold simp_implies_def, rule equal_intr_rule)
  1252   assume PQ: "PROP P \<Longrightarrow> PROP Q"
  1253   and P': "PROP P'"
  1254   from PP' [symmetric] and P' have "PROP P"
  1255     by (rule equal_elim_rule1)
  1256   then have "PROP Q" by (rule PQ)
  1257   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
  1258 next
  1259   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
  1260   and P: "PROP P"
  1261   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
  1262   then have "PROP Q'" by (rule P'Q')
  1263   with P'QQ' [OF P', symmetric] show "PROP Q"
  1264     by (rule equal_elim_rule1)
  1265 qed
  1266 
  1267 lemma uncurry:
  1268   assumes "P \<longrightarrow> Q \<longrightarrow> R"
  1269   shows "P \<and> Q \<longrightarrow> R"
  1270   using assms by blast
  1271 
  1272 lemma iff_allI:
  1273   assumes "\<And>x. P x = Q x"
  1274   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
  1275   using assms by blast
  1276 
  1277 lemma iff_exI:
  1278   assumes "\<And>x. P x = Q x"
  1279   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
  1280   using assms by blast
  1281 
  1282 lemma all_comm:
  1283   "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
  1284   by blast
  1285 
  1286 lemma ex_comm:
  1287   "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
  1288   by blast
  1289 
  1290 use "simpdata.ML"
  1291 ML {* open Simpdata *}
  1292 
  1293 setup {*
  1294   Simplifier.method_setup Splitter.split_modifiers
  1295   #> Simplifier.map_simpset (K Simpdata.simpset_simprocs)
  1296   #> Splitter.setup
  1297   #> clasimp_setup
  1298   #> EqSubst.setup
  1299 *}
  1300 
  1301 text {* Simproc for proving @{text "(y = x) == False"} from premise @{text "~(x = y)"}: *}
  1302 
  1303 simproc_setup neq ("x = y") = {* fn _ =>
  1304 let
  1305   val neq_to_EQ_False = @{thm not_sym} RS @{thm Eq_FalseI};
  1306   fun is_neq eq lhs rhs thm =
  1307     (case Thm.prop_of thm of
  1308       _ $ (Not $ (eq' $ l' $ r')) =>
  1309         Not = HOLogic.Not andalso eq' = eq andalso
  1310         r' aconv lhs andalso l' aconv rhs
  1311     | _ => false);
  1312   fun proc ss ct =
  1313     (case Thm.term_of ct of
  1314       eq $ lhs $ rhs =>
  1315         (case find_first (is_neq eq lhs rhs) (Simplifier.prems_of_ss ss) of
  1316           SOME thm => SOME (thm RS neq_to_EQ_False)
  1317         | NONE => NONE)
  1318      | _ => NONE);
  1319 in proc end;
  1320 *}
  1321 
  1322 simproc_setup let_simp ("Let x f") = {*
  1323 let
  1324   val (f_Let_unfold, x_Let_unfold) =
  1325     let val [(_$(f$x)$_)] = prems_of @{thm Let_unfold}
  1326     in (cterm_of @{theory} f, cterm_of @{theory} x) end
  1327   val (f_Let_folded, x_Let_folded) =
  1328     let val [(_$(f$x)$_)] = prems_of @{thm Let_folded}
  1329     in (cterm_of @{theory} f, cterm_of @{theory} x) end;
  1330   val g_Let_folded =
  1331     let val [(_$_$(g$_))] = prems_of @{thm Let_folded} in cterm_of @{theory} g end;
  1332 
  1333   fun proc _ ss ct =
  1334     let
  1335       val ctxt = Simplifier.the_context ss;
  1336       val thy = ProofContext.theory_of ctxt;
  1337       val t = Thm.term_of ct;
  1338       val ([t'], ctxt') = Variable.import_terms false [t] ctxt;
  1339     in Option.map (hd o Variable.export ctxt' ctxt o single)
  1340       (case t' of Const ("Let",_) $ x $ f => (* x and f are already in normal form *)
  1341         if is_Free x orelse is_Bound x orelse is_Const x
  1342         then SOME @{thm Let_def}
  1343         else
  1344           let
  1345             val n = case f of (Abs (x,_,_)) => x | _ => "x";
  1346             val cx = cterm_of thy x;
  1347             val {T=xT,...} = rep_cterm cx;
  1348             val cf = cterm_of thy f;
  1349             val fx_g = Simplifier.rewrite ss (Thm.capply cf cx);
  1350             val (_$_$g) = prop_of fx_g;
  1351             val g' = abstract_over (x,g);
  1352           in (if (g aconv g')
  1353                then
  1354                   let
  1355                     val rl =
  1356                       cterm_instantiate [(f_Let_unfold,cf),(x_Let_unfold,cx)] @{thm Let_unfold};
  1357                   in SOME (rl OF [fx_g]) end
  1358                else if Term.betapply (f,x) aconv g then NONE (*avoid identity conversion*)
  1359                else let
  1360                      val abs_g'= Abs (n,xT,g');
  1361                      val g'x = abs_g'$x;
  1362                      val g_g'x = symmetric (beta_conversion false (cterm_of thy g'x));
  1363                      val rl = cterm_instantiate
  1364                                [(f_Let_folded,cterm_of thy f),(x_Let_folded,cx),
  1365                                 (g_Let_folded,cterm_of thy abs_g')]
  1366                                @{thm Let_folded};
  1367                    in SOME (rl OF [transitive fx_g g_g'x])
  1368                    end)
  1369           end
  1370       | _ => NONE)
  1371     end
  1372 in proc end *}
  1373 
  1374 
  1375 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
  1376 proof
  1377   assume "True \<Longrightarrow> PROP P"
  1378   from this [OF TrueI] show "PROP P" .
  1379 next
  1380   assume "PROP P"
  1381   then show "PROP P" .
  1382 qed
  1383 
  1384 lemma ex_simps:
  1385   "!!P Q. (EX x. P x & Q)   = ((EX x. P x) & Q)"
  1386   "!!P Q. (EX x. P & Q x)   = (P & (EX x. Q x))"
  1387   "!!P Q. (EX x. P x | Q)   = ((EX x. P x) | Q)"
  1388   "!!P Q. (EX x. P | Q x)   = (P | (EX x. Q x))"
  1389   "!!P Q. (EX x. P x --> Q) = ((ALL x. P x) --> Q)"
  1390   "!!P Q. (EX x. P --> Q x) = (P --> (EX x. Q x))"
  1391   -- {* Miniscoping: pushing in existential quantifiers. *}
  1392   by (iprover | blast)+
  1393 
  1394 lemma all_simps:
  1395   "!!P Q. (ALL x. P x & Q)   = ((ALL x. P x) & Q)"
  1396   "!!P Q. (ALL x. P & Q x)   = (P & (ALL x. Q x))"
  1397   "!!P Q. (ALL x. P x | Q)   = ((ALL x. P x) | Q)"
  1398   "!!P Q. (ALL x. P | Q x)   = (P | (ALL x. Q x))"
  1399   "!!P Q. (ALL x. P x --> Q) = ((EX x. P x) --> Q)"
  1400   "!!P Q. (ALL x. P --> Q x) = (P --> (ALL x. Q x))"
  1401   -- {* Miniscoping: pushing in universal quantifiers. *}
  1402   by (iprover | blast)+
  1403 
  1404 lemmas [simp] =
  1405   triv_forall_equality (*prunes params*)
  1406   True_implies_equals  (*prune asms `True'*)
  1407   if_True
  1408   if_False
  1409   if_cancel
  1410   if_eq_cancel
  1411   imp_disjL
  1412   (*In general it seems wrong to add distributive laws by default: they
  1413     might cause exponential blow-up.  But imp_disjL has been in for a while
  1414     and cannot be removed without affecting existing proofs.  Moreover,
  1415     rewriting by "(P|Q --> R) = ((P-->R)&(Q-->R))" might be justified on the
  1416     grounds that it allows simplification of R in the two cases.*)
  1417   conj_assoc
  1418   disj_assoc
  1419   de_Morgan_conj
  1420   de_Morgan_disj
  1421   imp_disj1
  1422   imp_disj2
  1423   not_imp
  1424   disj_not1
  1425   not_all
  1426   not_ex
  1427   cases_simp
  1428   the_eq_trivial
  1429   the_sym_eq_trivial
  1430   ex_simps
  1431   all_simps
  1432   simp_thms
  1433 
  1434 lemmas [cong] = imp_cong simp_implies_cong
  1435 lemmas [split] = split_if
  1436 
  1437 ML {* val HOL_ss = @{simpset} *}
  1438 
  1439 text {* Simplifies x assuming c and y assuming ~c *}
  1440 lemma if_cong:
  1441   assumes "b = c"
  1442       and "c \<Longrightarrow> x = u"
  1443       and "\<not> c \<Longrightarrow> y = v"
  1444   shows "(if b then x else y) = (if c then u else v)"
  1445   unfolding if_def using assms by simp
  1446 
  1447 text {* Prevents simplification of x and y:
  1448   faster and allows the execution of functional programs. *}
  1449 lemma if_weak_cong [cong]:
  1450   assumes "b = c"
  1451   shows "(if b then x else y) = (if c then x else y)"
  1452   using assms by (rule arg_cong)
  1453 
  1454 text {* Prevents simplification of t: much faster *}
  1455 lemma let_weak_cong:
  1456   assumes "a = b"
  1457   shows "(let x = a in t x) = (let x = b in t x)"
  1458   using assms by (rule arg_cong)
  1459 
  1460 text {* To tidy up the result of a simproc.  Only the RHS will be simplified. *}
  1461 lemma eq_cong2:
  1462   assumes "u = u'"
  1463   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
  1464   using assms by simp
  1465 
  1466 lemma if_distrib:
  1467   "f (if c then x else y) = (if c then f x else f y)"
  1468   by simp
  1469 
  1470 text {* This lemma restricts the effect of the rewrite rule u=v to the left-hand
  1471   side of an equality.  Used in @{text "{Integ,Real}/simproc.ML"} *}
  1472 lemma restrict_to_left:
  1473   assumes "x = y"
  1474   shows "(x = z) = (y = z)"
  1475   using assms by simp
  1476 
  1477 
  1478 subsubsection {* Generic cases and induction *}
  1479 
  1480 text {* Rule projections: *}
  1481 
  1482 ML {*
  1483 structure ProjectRule = ProjectRuleFun
  1484 (
  1485   val conjunct1 = @{thm conjunct1}
  1486   val conjunct2 = @{thm conjunct2}
  1487   val mp = @{thm mp}
  1488 )
  1489 *}
  1490 
  1491 constdefs
  1492   induct_forall where "induct_forall P == \<forall>x. P x"
  1493   induct_implies where "induct_implies A B == A \<longrightarrow> B"
  1494   induct_equal where "induct_equal x y == x = y"
  1495   induct_conj where "induct_conj A B == A \<and> B"
  1496 
  1497 lemma induct_forall_eq: "(!!x. P x) == Trueprop (induct_forall (\<lambda>x. P x))"
  1498   by (unfold atomize_all induct_forall_def)
  1499 
  1500 lemma induct_implies_eq: "(A ==> B) == Trueprop (induct_implies A B)"
  1501   by (unfold atomize_imp induct_implies_def)
  1502 
  1503 lemma induct_equal_eq: "(x == y) == Trueprop (induct_equal x y)"
  1504   by (unfold atomize_eq induct_equal_def)
  1505 
  1506 lemma induct_conj_eq:
  1507   includes meta_conjunction_syntax
  1508   shows "(A && B) == Trueprop (induct_conj A B)"
  1509   by (unfold atomize_conj induct_conj_def)
  1510 
  1511 lemmas induct_atomize = induct_forall_eq induct_implies_eq induct_equal_eq induct_conj_eq
  1512 lemmas induct_rulify [symmetric, standard] = induct_atomize
  1513 lemmas induct_rulify_fallback =
  1514   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
  1515 
  1516 
  1517 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
  1518     induct_conj (induct_forall A) (induct_forall B)"
  1519   by (unfold induct_forall_def induct_conj_def) iprover
  1520 
  1521 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
  1522     induct_conj (induct_implies C A) (induct_implies C B)"
  1523   by (unfold induct_implies_def induct_conj_def) iprover
  1524 
  1525 lemma induct_conj_curry: "(induct_conj A B ==> PROP C) == (A ==> B ==> PROP C)"
  1526 proof
  1527   assume r: "induct_conj A B ==> PROP C" and A B
  1528   show "PROP C" by (rule r) (simp add: induct_conj_def `A` `B`)
  1529 next
  1530   assume r: "A ==> B ==> PROP C" and "induct_conj A B"
  1531   show "PROP C" by (rule r) (simp_all add: `induct_conj A B` [unfolded induct_conj_def])
  1532 qed
  1533 
  1534 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
  1535 
  1536 hide const induct_forall induct_implies induct_equal induct_conj
  1537 
  1538 text {* Method setup. *}
  1539 
  1540 ML {*
  1541 structure Induct = InductFun
  1542 (
  1543   val cases_default = @{thm case_split}
  1544   val atomize = @{thms induct_atomize}
  1545   val rulify = @{thms induct_rulify}
  1546   val rulify_fallback = @{thms induct_rulify_fallback}
  1547 )
  1548 *}
  1549 
  1550 setup Induct.setup
  1551 
  1552 use "~~/src/Tools/induct_tacs.ML"
  1553 setup InductTacs.setup
  1554 
  1555 
  1556 subsubsection {* Coherent logic *}
  1557 
  1558 ML {*
  1559 structure Coherent = CoherentFun
  1560 (
  1561   val atomize_elimL = @{thm atomize_elimL}
  1562   val atomize_exL = @{thm atomize_exL}
  1563   val atomize_conjL = @{thm atomize_conjL}
  1564   val atomize_disjL = @{thm atomize_disjL}
  1565   val operator_names =
  1566     [@{const_name "op |"}, @{const_name "op &"}, @{const_name "Ex"}]
  1567 );
  1568 *}
  1569 
  1570 setup Coherent.setup
  1571 
  1572 
  1573 subsection {* Other simple lemmas and lemma duplicates *}
  1574 
  1575 lemma Let_0 [simp]: "Let 0 f = f 0"
  1576   unfolding Let_def ..
  1577 
  1578 lemma Let_1 [simp]: "Let 1 f = f 1"
  1579   unfolding Let_def ..
  1580 
  1581 lemma ex1_eq [iff]: "EX! x. x = t" "EX! x. t = x"
  1582   by blast+
  1583 
  1584 lemma choice_eq: "(ALL x. EX! y. P x y) = (EX! f. ALL x. P x (f x))"
  1585   apply (rule iffI)
  1586   apply (rule_tac a = "%x. THE y. P x y" in ex1I)
  1587   apply (fast dest!: theI')
  1588   apply (fast intro: ext the1_equality [symmetric])
  1589   apply (erule ex1E)
  1590   apply (rule allI)
  1591   apply (rule ex1I)
  1592   apply (erule spec)
  1593   apply (erule_tac x = "%z. if z = x then y else f z" in allE)
  1594   apply (erule impE)
  1595   apply (rule allI)
  1596   apply (case_tac "xa = x")
  1597   apply (drule_tac [3] x = x in fun_cong, simp_all)
  1598   done
  1599 
  1600 lemma mk_left_commute:
  1601   fixes f (infix "\<otimes>" 60)
  1602   assumes a: "\<And>x y z. (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)" and
  1603           c: "\<And>x y. x \<otimes> y = y \<otimes> x"
  1604   shows "x \<otimes> (y \<otimes> z) = y \<otimes> (x \<otimes> z)"
  1605   by (rule trans [OF trans [OF c a] arg_cong [OF c, of "f y"]])
  1606 
  1607 lemmas eq_sym_conv = eq_commute
  1608 
  1609 lemma nnf_simps:
  1610   "(\<not>(P \<and> Q)) = (\<not> P \<or> \<not> Q)" "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)" 
  1611   "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not>(P = Q)) = ((P \<and> \<not> Q) \<or> (\<not>P \<and> Q))" 
  1612   "(\<not> \<not>(P)) = P"
  1613 by blast+
  1614 
  1615 
  1616 subsection {* Basic ML bindings *}
  1617 
  1618 ML {*
  1619 val FalseE = @{thm FalseE}
  1620 val Let_def = @{thm Let_def}
  1621 val TrueI = @{thm TrueI}
  1622 val allE = @{thm allE}
  1623 val allI = @{thm allI}
  1624 val all_dupE = @{thm all_dupE}
  1625 val arg_cong = @{thm arg_cong}
  1626 val box_equals = @{thm box_equals}
  1627 val ccontr = @{thm ccontr}
  1628 val classical = @{thm classical}
  1629 val conjE = @{thm conjE}
  1630 val conjI = @{thm conjI}
  1631 val conjunct1 = @{thm conjunct1}
  1632 val conjunct2 = @{thm conjunct2}
  1633 val disjCI = @{thm disjCI}
  1634 val disjE = @{thm disjE}
  1635 val disjI1 = @{thm disjI1}
  1636 val disjI2 = @{thm disjI2}
  1637 val eq_reflection = @{thm eq_reflection}
  1638 val ex1E = @{thm ex1E}
  1639 val ex1I = @{thm ex1I}
  1640 val ex1_implies_ex = @{thm ex1_implies_ex}
  1641 val exE = @{thm exE}
  1642 val exI = @{thm exI}
  1643 val excluded_middle = @{thm excluded_middle}
  1644 val ext = @{thm ext}
  1645 val fun_cong = @{thm fun_cong}
  1646 val iffD1 = @{thm iffD1}
  1647 val iffD2 = @{thm iffD2}
  1648 val iffI = @{thm iffI}
  1649 val impE = @{thm impE}
  1650 val impI = @{thm impI}
  1651 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
  1652 val mp = @{thm mp}
  1653 val notE = @{thm notE}
  1654 val notI = @{thm notI}
  1655 val not_all = @{thm not_all}
  1656 val not_ex = @{thm not_ex}
  1657 val not_iff = @{thm not_iff}
  1658 val not_not = @{thm not_not}
  1659 val not_sym = @{thm not_sym}
  1660 val refl = @{thm refl}
  1661 val rev_mp = @{thm rev_mp}
  1662 val spec = @{thm spec}
  1663 val ssubst = @{thm ssubst}
  1664 val subst = @{thm subst}
  1665 val sym = @{thm sym}
  1666 val trans = @{thm trans}
  1667 *}
  1668 
  1669 
  1670 subsection {* Code generator basics -- see further theory @{text "Code_Setup"} *}
  1671 
  1672 text {* Equality *}
  1673 
  1674 class eq = type +
  1675   fixes eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
  1676   assumes eq_equals: "eq x y \<longleftrightarrow> x = y"
  1677 begin
  1678 
  1679 lemma eq: "eq = (op =)"
  1680   by (rule ext eq_equals)+
  1681 
  1682 lemma eq_refl: "eq x x \<longleftrightarrow> True"
  1683   unfolding eq by rule+
  1684 
  1685 end
  1686 
  1687 text {* Module setup *}
  1688 
  1689 use "~~/src/HOL/Tools/recfun_codegen.ML"
  1690 
  1691 setup {*
  1692   Code_ML.setup
  1693   #> Code_Haskell.setup
  1694   #> Nbe.setup
  1695   #> Codegen.setup
  1696   #> RecfunCodegen.setup
  1697 *}
  1698 
  1699 
  1700 subsection {* Legacy tactics and ML bindings *}
  1701 
  1702 ML {*
  1703 fun strip_tac i = REPEAT (resolve_tac [impI, allI] i);
  1704 
  1705 (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
  1706 local
  1707   fun wrong_prem (Const ("All", _) $ (Abs (_, _, t))) = wrong_prem t
  1708     | wrong_prem (Bound _) = true
  1709     | wrong_prem _ = false;
  1710   val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
  1711 in
  1712   fun smp i = funpow i (fn m => filter_right ([spec] RL m)) ([mp]);
  1713   fun smp_tac j = EVERY'[dresolve_tac (smp j), atac];
  1714 end;
  1715 
  1716 val all_conj_distrib = thm "all_conj_distrib";
  1717 val all_simps = thms "all_simps";
  1718 val atomize_not = thm "atomize_not";
  1719 val case_split = thm "case_split";
  1720 val cases_simp = thm "cases_simp";
  1721 val choice_eq = thm "choice_eq"
  1722 val cong = thm "cong"
  1723 val conj_comms = thms "conj_comms";
  1724 val conj_cong = thm "conj_cong";
  1725 val de_Morgan_conj = thm "de_Morgan_conj";
  1726 val de_Morgan_disj = thm "de_Morgan_disj";
  1727 val disj_assoc = thm "disj_assoc";
  1728 val disj_comms = thms "disj_comms";
  1729 val disj_cong = thm "disj_cong";
  1730 val eq_ac = thms "eq_ac";
  1731 val eq_cong2 = thm "eq_cong2"
  1732 val Eq_FalseI = thm "Eq_FalseI";
  1733 val Eq_TrueI = thm "Eq_TrueI";
  1734 val Ex1_def = thm "Ex1_def"
  1735 val ex_disj_distrib = thm "ex_disj_distrib";
  1736 val ex_simps = thms "ex_simps";
  1737 val if_cancel = thm "if_cancel";
  1738 val if_eq_cancel = thm "if_eq_cancel";
  1739 val if_False = thm "if_False";
  1740 val iff_conv_conj_imp = thm "iff_conv_conj_imp";
  1741 val iff = thm "iff"
  1742 val if_splits = thms "if_splits";
  1743 val if_True = thm "if_True";
  1744 val if_weak_cong = thm "if_weak_cong"
  1745 val imp_all = thm "imp_all";
  1746 val imp_cong = thm "imp_cong";
  1747 val imp_conjL = thm "imp_conjL";
  1748 val imp_conjR = thm "imp_conjR";
  1749 val imp_conv_disj = thm "imp_conv_disj";
  1750 val simp_implies_def = thm "simp_implies_def";
  1751 val simp_thms = thms "simp_thms";
  1752 val split_if = thm "split_if";
  1753 val the1_equality = thm "the1_equality"
  1754 val theI = thm "theI"
  1755 val theI' = thm "theI'"
  1756 val True_implies_equals = thm "True_implies_equals";
  1757 val nnf_conv = Simplifier.rewrite (HOL_basic_ss addsimps simp_thms @ @{thms "nnf_simps"})
  1758 
  1759 *}
  1760 
  1761 end