src/HOL/Data_Structures/RBT_Set.thy
author nipkow
Tue Oct 13 17:06:37 2015 +0200 (2015-10-13)
changeset 61428 5e1938107371
parent 61231 cc6969542f8d
child 61581 00d9682e8dd7
permissions -rw-r--r--
added invar empty
     1 (* Author: Tobias Nipkow *)
     2 
     3 section \<open>Red-Black Tree Implementation of Sets\<close>
     4 
     5 theory RBT_Set
     6 imports
     7   RBT
     8   Isin2
     9 begin
    10 
    11 fun insert :: "'a::linorder \<Rightarrow> 'a rbt \<Rightarrow> 'a rbt" where
    12 "insert x Leaf = R Leaf x Leaf" |
    13 "insert x (B l a r) =
    14   (if x < a then bal (insert x l) a r else
    15    if x > a then bal l a (insert x r) else B l a r)" |
    16 "insert x (R l a r) =
    17   (if x < a then R (insert x l) a r
    18    else if x > a then R l a (insert x r) else R l a r)"
    19 
    20 fun delete :: "'a::linorder \<Rightarrow> 'a rbt \<Rightarrow> 'a rbt"
    21 and deleteL :: "'a::linorder \<Rightarrow> 'a rbt \<Rightarrow> 'a \<Rightarrow> 'a rbt \<Rightarrow> 'a rbt"
    22 and deleteR :: "'a::linorder \<Rightarrow> 'a rbt \<Rightarrow> 'a \<Rightarrow> 'a rbt \<Rightarrow> 'a rbt"
    23 where
    24 "delete x Leaf = Leaf" |
    25 "delete x (Node _ l a r) = 
    26   (if x < a then deleteL x l a r 
    27    else if x > a then deleteR x l a r else combine l r)" |
    28 "deleteL x (B t1 a t2) b t3 = balL (delete x (B t1 a t2)) b t3" |
    29 "deleteL x l a r = R (delete x l) a r" |
    30 "deleteR x t1 a (B t2 b t3) = balR t1 a (delete x (B t2 b t3))" | 
    31 "deleteR x l a r = R l a (delete x r)"
    32 
    33 
    34 subsection "Functional Correctness Proofs"
    35 
    36 lemma inorder_bal:
    37   "inorder(bal l a r) = inorder l @ a # inorder r"
    38 by(induction l a r rule: bal.induct) (auto)
    39 
    40 lemma inorder_insert:
    41   "sorted(inorder t) \<Longrightarrow> inorder(insert a t) = ins_list a (inorder t)"
    42 by(induction a t rule: insert.induct) (auto simp: ins_list_simps inorder_bal)
    43 
    44 lemma inorder_red: "inorder(red t) = inorder t"
    45 by(induction t) (auto)
    46 
    47 lemma inorder_balL:
    48   "inorder(balL l a r) = inorder l @ a # inorder r"
    49 by(induction l a r rule: balL.induct)(auto simp: inorder_bal inorder_red)
    50 
    51 lemma inorder_balR:
    52   "inorder(balR l a r) = inorder l @ a # inorder r"
    53 by(induction l a r rule: balR.induct) (auto simp: inorder_bal inorder_red)
    54 
    55 lemma inorder_combine:
    56   "inorder(combine l r) = inorder l @ inorder r"
    57 by(induction l r rule: combine.induct)
    58   (auto simp: inorder_balL inorder_balR split: tree.split color.split)
    59 
    60 lemma inorder_delete:
    61  "sorted(inorder t) \<Longrightarrow>  inorder(delete x t) = del_list x (inorder t)" and
    62  "sorted(inorder l) \<Longrightarrow>  inorder(deleteL x l a r) =
    63     del_list x (inorder l) @ a # inorder r" and
    64  "sorted(inorder r) \<Longrightarrow>  inorder(deleteR x l a r) =
    65     inorder l @ a # del_list x (inorder r)"
    66 by(induction x t and x l a r and x l a r rule: delete_deleteL_deleteR.induct)
    67   (auto simp: del_list_simps inorder_combine inorder_balL inorder_balR)
    68 
    69 interpretation Set_by_Ordered
    70 where empty = Leaf and isin = isin and insert = insert and delete = delete
    71 and inorder = inorder and wf = "\<lambda>_. True"
    72 proof (standard, goal_cases)
    73   case 1 show ?case by simp
    74 next
    75   case 2 thus ?case by(simp add: isin_set)
    76 next
    77   case 3 thus ?case by(simp add: inorder_insert)
    78 next
    79   case 4 thus ?case by(simp add: inorder_delete)
    80 qed (rule TrueI)+
    81 
    82 end