src/HOL/Limits.thy
author hoelzl
Mon Dec 03 18:19:04 2012 +0100 (2012-12-03)
changeset 50325 5e40ad9f212a
parent 50324 0a1242d5e7d4
child 50326 b5afeccab2db
permissions -rw-r--r--
add filterlim rules for inverse and at_infinity
     1 (*  Title       : Limits.thy
     2     Author      : Brian Huffman
     3 *)
     4 
     5 header {* Filters and Limits *}
     6 
     7 theory Limits
     8 imports RealVector
     9 begin
    10 
    11 subsection {* Filters *}
    12 
    13 text {*
    14   This definition also allows non-proper filters.
    15 *}
    16 
    17 locale is_filter =
    18   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
    19   assumes True: "F (\<lambda>x. True)"
    20   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
    21   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
    22 
    23 typedef 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
    24 proof
    25   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
    26 qed
    27 
    28 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
    29   using Rep_filter [of F] by simp
    30 
    31 lemma Abs_filter_inverse':
    32   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
    33   using assms by (simp add: Abs_filter_inverse)
    34 
    35 
    36 subsection {* Eventually *}
    37 
    38 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
    39   where "eventually P F \<longleftrightarrow> Rep_filter F P"
    40 
    41 lemma eventually_Abs_filter:
    42   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
    43   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
    44 
    45 lemma filter_eq_iff:
    46   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
    47   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
    48 
    49 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
    50   unfolding eventually_def
    51   by (rule is_filter.True [OF is_filter_Rep_filter])
    52 
    53 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
    54 proof -
    55   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
    56   thus "eventually P F" by simp
    57 qed
    58 
    59 lemma eventually_mono:
    60   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P F \<Longrightarrow> eventually Q F"
    61   unfolding eventually_def
    62   by (rule is_filter.mono [OF is_filter_Rep_filter])
    63 
    64 lemma eventually_conj:
    65   assumes P: "eventually (\<lambda>x. P x) F"
    66   assumes Q: "eventually (\<lambda>x. Q x) F"
    67   shows "eventually (\<lambda>x. P x \<and> Q x) F"
    68   using assms unfolding eventually_def
    69   by (rule is_filter.conj [OF is_filter_Rep_filter])
    70 
    71 lemma eventually_mp:
    72   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    73   assumes "eventually (\<lambda>x. P x) F"
    74   shows "eventually (\<lambda>x. Q x) F"
    75 proof (rule eventually_mono)
    76   show "\<forall>x. (P x \<longrightarrow> Q x) \<and> P x \<longrightarrow> Q x" by simp
    77   show "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
    78     using assms by (rule eventually_conj)
    79 qed
    80 
    81 lemma eventually_rev_mp:
    82   assumes "eventually (\<lambda>x. P x) F"
    83   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    84   shows "eventually (\<lambda>x. Q x) F"
    85 using assms(2) assms(1) by (rule eventually_mp)
    86 
    87 lemma eventually_conj_iff:
    88   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
    89   by (auto intro: eventually_conj elim: eventually_rev_mp)
    90 
    91 lemma eventually_elim1:
    92   assumes "eventually (\<lambda>i. P i) F"
    93   assumes "\<And>i. P i \<Longrightarrow> Q i"
    94   shows "eventually (\<lambda>i. Q i) F"
    95   using assms by (auto elim!: eventually_rev_mp)
    96 
    97 lemma eventually_elim2:
    98   assumes "eventually (\<lambda>i. P i) F"
    99   assumes "eventually (\<lambda>i. Q i) F"
   100   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   101   shows "eventually (\<lambda>i. R i) F"
   102   using assms by (auto elim!: eventually_rev_mp)
   103 
   104 lemma eventually_subst:
   105   assumes "eventually (\<lambda>n. P n = Q n) F"
   106   shows "eventually P F = eventually Q F" (is "?L = ?R")
   107 proof -
   108   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   109       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
   110     by (auto elim: eventually_elim1)
   111   then show ?thesis by (auto elim: eventually_elim2)
   112 qed
   113 
   114 ML {*
   115   fun eventually_elim_tac ctxt thms thm =
   116     let
   117       val thy = Proof_Context.theory_of ctxt
   118       val mp_thms = thms RL [@{thm eventually_rev_mp}]
   119       val raw_elim_thm =
   120         (@{thm allI} RS @{thm always_eventually})
   121         |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
   122         |> fold (fn _ => fn thm => @{thm impI} RS thm) thms
   123       val cases_prop = prop_of (raw_elim_thm RS thm)
   124       val cases = (Rule_Cases.make_common (thy, cases_prop) [(("elim", []), [])])
   125     in
   126       CASES cases (rtac raw_elim_thm 1) thm
   127     end
   128 *}
   129 
   130 method_setup eventually_elim = {*
   131   Scan.succeed (fn ctxt => METHOD_CASES (eventually_elim_tac ctxt))
   132 *} "elimination of eventually quantifiers"
   133 
   134 
   135 subsection {* Finer-than relation *}
   136 
   137 text {* @{term "F \<le> F'"} means that filter @{term F} is finer than
   138 filter @{term F'}. *}
   139 
   140 instantiation filter :: (type) complete_lattice
   141 begin
   142 
   143 definition le_filter_def:
   144   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
   145 
   146 definition
   147   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   148 
   149 definition
   150   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
   151 
   152 definition
   153   "bot = Abs_filter (\<lambda>P. True)"
   154 
   155 definition
   156   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
   157 
   158 definition
   159   "inf F F' = Abs_filter
   160       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   161 
   162 definition
   163   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
   164 
   165 definition
   166   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
   167 
   168 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   169   unfolding top_filter_def
   170   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
   171 
   172 lemma eventually_bot [simp]: "eventually P bot"
   173   unfolding bot_filter_def
   174   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
   175 
   176 lemma eventually_sup:
   177   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
   178   unfolding sup_filter_def
   179   by (rule eventually_Abs_filter, rule is_filter.intro)
   180      (auto elim!: eventually_rev_mp)
   181 
   182 lemma eventually_inf:
   183   "eventually P (inf F F') \<longleftrightarrow>
   184    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   185   unfolding inf_filter_def
   186   apply (rule eventually_Abs_filter, rule is_filter.intro)
   187   apply (fast intro: eventually_True)
   188   apply clarify
   189   apply (intro exI conjI)
   190   apply (erule (1) eventually_conj)
   191   apply (erule (1) eventually_conj)
   192   apply simp
   193   apply auto
   194   done
   195 
   196 lemma eventually_Sup:
   197   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
   198   unfolding Sup_filter_def
   199   apply (rule eventually_Abs_filter, rule is_filter.intro)
   200   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   201   done
   202 
   203 instance proof
   204   fix F F' F'' :: "'a filter" and S :: "'a filter set"
   205   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   206     by (rule less_filter_def) }
   207   { show "F \<le> F"
   208     unfolding le_filter_def by simp }
   209   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
   210     unfolding le_filter_def by simp }
   211   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
   212     unfolding le_filter_def filter_eq_iff by fast }
   213   { show "F \<le> top"
   214     unfolding le_filter_def eventually_top by (simp add: always_eventually) }
   215   { show "bot \<le> F"
   216     unfolding le_filter_def by simp }
   217   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
   218     unfolding le_filter_def eventually_sup by simp_all }
   219   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
   220     unfolding le_filter_def eventually_sup by simp }
   221   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
   222     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
   223   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
   224     unfolding le_filter_def eventually_inf
   225     by (auto elim!: eventually_mono intro: eventually_conj) }
   226   { assume "F \<in> S" thus "F \<le> Sup S"
   227     unfolding le_filter_def eventually_Sup by simp }
   228   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
   229     unfolding le_filter_def eventually_Sup by simp }
   230   { assume "F'' \<in> S" thus "Inf S \<le> F''"
   231     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   232   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
   233     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   234 qed
   235 
   236 end
   237 
   238 lemma filter_leD:
   239   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
   240   unfolding le_filter_def by simp
   241 
   242 lemma filter_leI:
   243   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
   244   unfolding le_filter_def by simp
   245 
   246 lemma eventually_False:
   247   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
   248   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
   249 
   250 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
   251   where "trivial_limit F \<equiv> F = bot"
   252 
   253 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
   254   by (rule eventually_False [symmetric])
   255 
   256 
   257 subsection {* Map function for filters *}
   258 
   259 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
   260   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
   261 
   262 lemma eventually_filtermap:
   263   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
   264   unfolding filtermap_def
   265   apply (rule eventually_Abs_filter)
   266   apply (rule is_filter.intro)
   267   apply (auto elim!: eventually_rev_mp)
   268   done
   269 
   270 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
   271   by (simp add: filter_eq_iff eventually_filtermap)
   272 
   273 lemma filtermap_filtermap:
   274   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
   275   by (simp add: filter_eq_iff eventually_filtermap)
   276 
   277 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
   278   unfolding le_filter_def eventually_filtermap by simp
   279 
   280 lemma filtermap_bot [simp]: "filtermap f bot = bot"
   281   by (simp add: filter_eq_iff eventually_filtermap)
   282 
   283 subsection {* Order filters *}
   284 
   285 definition at_top :: "('a::order) filter"
   286   where "at_top = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
   287 
   288 lemma eventually_at_top_linorder: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::linorder. \<forall>n\<ge>N. P n)"
   289   unfolding at_top_def
   290 proof (rule eventually_Abs_filter, rule is_filter.intro)
   291   fix P Q :: "'a \<Rightarrow> bool"
   292   assume "\<exists>i. \<forall>n\<ge>i. P n" and "\<exists>j. \<forall>n\<ge>j. Q n"
   293   then obtain i j where "\<forall>n\<ge>i. P n" and "\<forall>n\<ge>j. Q n" by auto
   294   then have "\<forall>n\<ge>max i j. P n \<and> Q n" by simp
   295   then show "\<exists>k. \<forall>n\<ge>k. P n \<and> Q n" ..
   296 qed auto
   297 
   298 lemma eventually_at_top_dense: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::dense_linorder. \<forall>n>N. P n)"
   299   unfolding eventually_at_top_linorder
   300 proof safe
   301   fix N assume "\<forall>n\<ge>N. P n" then show "\<exists>N. \<forall>n>N. P n" by (auto intro!: exI[of _ N])
   302 next
   303   fix N assume "\<forall>n>N. P n"
   304   moreover from gt_ex[of N] guess y ..
   305   ultimately show "\<exists>N. \<forall>n\<ge>N. P n" by (auto intro!: exI[of _ y])
   306 qed
   307 
   308 definition at_bot :: "('a::order) filter"
   309   where "at_bot = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<le>k. P n)"
   310 
   311 lemma eventually_at_bot_linorder:
   312   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n\<le>N. P n)"
   313   unfolding at_bot_def
   314 proof (rule eventually_Abs_filter, rule is_filter.intro)
   315   fix P Q :: "'a \<Rightarrow> bool"
   316   assume "\<exists>i. \<forall>n\<le>i. P n" and "\<exists>j. \<forall>n\<le>j. Q n"
   317   then obtain i j where "\<forall>n\<le>i. P n" and "\<forall>n\<le>j. Q n" by auto
   318   then have "\<forall>n\<le>min i j. P n \<and> Q n" by simp
   319   then show "\<exists>k. \<forall>n\<le>k. P n \<and> Q n" ..
   320 qed auto
   321 
   322 lemma eventually_at_bot_dense:
   323   fixes P :: "'a::dense_linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n<N. P n)"
   324   unfolding eventually_at_bot_linorder
   325 proof safe
   326   fix N assume "\<forall>n\<le>N. P n" then show "\<exists>N. \<forall>n<N. P n" by (auto intro!: exI[of _ N])
   327 next
   328   fix N assume "\<forall>n<N. P n" 
   329   moreover from lt_ex[of N] guess y ..
   330   ultimately show "\<exists>N. \<forall>n\<le>N. P n" by (auto intro!: exI[of _ y])
   331 qed
   332 
   333 subsection {* Sequentially *}
   334 
   335 abbreviation sequentially :: "nat filter"
   336   where "sequentially == at_top"
   337 
   338 lemma sequentially_def: "sequentially = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
   339   unfolding at_top_def by simp
   340 
   341 lemma eventually_sequentially:
   342   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   343   by (rule eventually_at_top_linorder)
   344 
   345 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
   346   unfolding filter_eq_iff eventually_sequentially by auto
   347 
   348 lemmas trivial_limit_sequentially = sequentially_bot
   349 
   350 lemma eventually_False_sequentially [simp]:
   351   "\<not> eventually (\<lambda>n. False) sequentially"
   352   by (simp add: eventually_False)
   353 
   354 lemma le_sequentially:
   355   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
   356   unfolding le_filter_def eventually_sequentially
   357   by (safe, fast, drule_tac x=N in spec, auto elim: eventually_rev_mp)
   358 
   359 lemma eventually_sequentiallyI:
   360   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   361   shows "eventually P sequentially"
   362 using assms by (auto simp: eventually_sequentially)
   363 
   364 
   365 subsection {* Standard filters *}
   366 
   367 definition within :: "'a filter \<Rightarrow> 'a set \<Rightarrow> 'a filter" (infixr "within" 70)
   368   where "F within S = Abs_filter (\<lambda>P. eventually (\<lambda>x. x \<in> S \<longrightarrow> P x) F)"
   369 
   370 definition (in topological_space) nhds :: "'a \<Rightarrow> 'a filter"
   371   where "nhds a = Abs_filter (\<lambda>P. \<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   372 
   373 definition (in topological_space) at :: "'a \<Rightarrow> 'a filter"
   374   where "at a = nhds a within - {a}"
   375 
   376 definition at_infinity :: "'a::real_normed_vector filter" where
   377   "at_infinity = Abs_filter (\<lambda>P. \<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x)"
   378 
   379 lemma eventually_within:
   380   "eventually P (F within S) = eventually (\<lambda>x. x \<in> S \<longrightarrow> P x) F"
   381   unfolding within_def
   382   by (rule eventually_Abs_filter, rule is_filter.intro)
   383      (auto elim!: eventually_rev_mp)
   384 
   385 lemma within_UNIV [simp]: "F within UNIV = F"
   386   unfolding filter_eq_iff eventually_within by simp
   387 
   388 lemma within_empty [simp]: "F within {} = bot"
   389   unfolding filter_eq_iff eventually_within by simp
   390 
   391 lemma within_le: "F within S \<le> F"
   392   unfolding le_filter_def eventually_within by (auto elim: eventually_elim1)
   393 
   394 lemma le_withinI: "F \<le> F' \<Longrightarrow> eventually (\<lambda>x. x \<in> S) F \<Longrightarrow> F \<le> F' within S"
   395   unfolding le_filter_def eventually_within by (auto elim: eventually_elim2)
   396 
   397 lemma le_within_iff: "eventually (\<lambda>x. x \<in> S) F \<Longrightarrow> F \<le> F' within S \<longleftrightarrow> F \<le> F'"
   398   by (blast intro: within_le le_withinI order_trans)
   399 
   400 lemma eventually_nhds:
   401   "eventually P (nhds a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   402 unfolding nhds_def
   403 proof (rule eventually_Abs_filter, rule is_filter.intro)
   404   have "open UNIV \<and> a \<in> UNIV \<and> (\<forall>x\<in>UNIV. True)" by simp
   405   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. True)" ..
   406 next
   407   fix P Q
   408   assume "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   409      and "\<exists>T. open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)"
   410   then obtain S T where
   411     "open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   412     "open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)" by auto
   413   hence "open (S \<inter> T) \<and> a \<in> S \<inter> T \<and> (\<forall>x\<in>(S \<inter> T). P x \<and> Q x)"
   414     by (simp add: open_Int)
   415   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x \<and> Q x)" ..
   416 qed auto
   417 
   418 lemma eventually_nhds_metric:
   419   "eventually P (nhds a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. dist x a < d \<longrightarrow> P x)"
   420 unfolding eventually_nhds open_dist
   421 apply safe
   422 apply fast
   423 apply (rule_tac x="{x. dist x a < d}" in exI, simp)
   424 apply clarsimp
   425 apply (rule_tac x="d - dist x a" in exI, clarsimp)
   426 apply (simp only: less_diff_eq)
   427 apply (erule le_less_trans [OF dist_triangle])
   428 done
   429 
   430 lemma nhds_neq_bot [simp]: "nhds a \<noteq> bot"
   431   unfolding trivial_limit_def eventually_nhds by simp
   432 
   433 lemma eventually_at_topological:
   434   "eventually P (at a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> P x))"
   435 unfolding at_def eventually_within eventually_nhds by simp
   436 
   437 lemma eventually_at:
   438   fixes a :: "'a::metric_space"
   439   shows "eventually P (at a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> P x)"
   440 unfolding at_def eventually_within eventually_nhds_metric by auto
   441 
   442 lemma at_eq_bot_iff: "at a = bot \<longleftrightarrow> open {a}"
   443   unfolding trivial_limit_def eventually_at_topological
   444   by (safe, case_tac "S = {a}", simp, fast, fast)
   445 
   446 lemma at_neq_bot [simp]: "at (a::'a::perfect_space) \<noteq> bot"
   447   by (simp add: at_eq_bot_iff not_open_singleton)
   448 
   449 lemma eventually_at_infinity:
   450   "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> P x)"
   451 unfolding at_infinity_def
   452 proof (rule eventually_Abs_filter, rule is_filter.intro)
   453   fix P Q :: "'a \<Rightarrow> bool"
   454   assume "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<exists>s. \<forall>x. s \<le> norm x \<longrightarrow> Q x"
   455   then obtain r s where
   456     "\<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<forall>x. s \<le> norm x \<longrightarrow> Q x" by auto
   457   then have "\<forall>x. max r s \<le> norm x \<longrightarrow> P x \<and> Q x" by simp
   458   then show "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x \<and> Q x" ..
   459 qed auto
   460 
   461 lemma at_infinity_eq_at_top_bot:
   462   "(at_infinity \<Colon> real filter) = sup at_top at_bot"
   463   unfolding sup_filter_def at_infinity_def eventually_at_top_linorder eventually_at_bot_linorder
   464 proof (intro arg_cong[where f=Abs_filter] ext iffI)
   465   fix P :: "real \<Rightarrow> bool" assume "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x"
   466   then guess r ..
   467   then have "(\<forall>x\<ge>r. P x) \<and> (\<forall>x\<le>-r. P x)" by auto
   468   then show "(\<exists>r. \<forall>x\<ge>r. P x) \<and> (\<exists>r. \<forall>x\<le>r. P x)" by auto
   469 next
   470   fix P :: "real \<Rightarrow> bool" assume "(\<exists>r. \<forall>x\<ge>r. P x) \<and> (\<exists>r. \<forall>x\<le>r. P x)"
   471   then obtain p q where "\<forall>x\<ge>p. P x" "\<forall>x\<le>q. P x" by auto
   472   then show "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x"
   473     by (intro exI[of _ "max p (-q)"])
   474        (auto simp: abs_real_def)
   475 qed
   476 
   477 lemma at_top_le_at_infinity:
   478   "at_top \<le> (at_infinity :: real filter)"
   479   unfolding at_infinity_eq_at_top_bot by simp
   480 
   481 lemma at_bot_le_at_infinity:
   482   "at_bot \<le> (at_infinity :: real filter)"
   483   unfolding at_infinity_eq_at_top_bot by simp
   484 
   485 subsection {* Boundedness *}
   486 
   487 definition Bfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   488   where "Bfun f F = (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
   489 
   490 lemma BfunI:
   491   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F" shows "Bfun f F"
   492 unfolding Bfun_def
   493 proof (intro exI conjI allI)
   494   show "0 < max K 1" by simp
   495 next
   496   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
   497     using K by (rule eventually_elim1, simp)
   498 qed
   499 
   500 lemma BfunE:
   501   assumes "Bfun f F"
   502   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
   503 using assms unfolding Bfun_def by fast
   504 
   505 
   506 subsection {* Convergence to Zero *}
   507 
   508 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   509   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
   510 
   511 lemma ZfunI:
   512   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
   513   unfolding Zfun_def by simp
   514 
   515 lemma ZfunD:
   516   "\<lbrakk>Zfun f F; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
   517   unfolding Zfun_def by simp
   518 
   519 lemma Zfun_ssubst:
   520   "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
   521   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   522 
   523 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
   524   unfolding Zfun_def by simp
   525 
   526 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
   527   unfolding Zfun_def by simp
   528 
   529 lemma Zfun_imp_Zfun:
   530   assumes f: "Zfun f F"
   531   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
   532   shows "Zfun (\<lambda>x. g x) F"
   533 proof (cases)
   534   assume K: "0 < K"
   535   show ?thesis
   536   proof (rule ZfunI)
   537     fix r::real assume "0 < r"
   538     hence "0 < r / K"
   539       using K by (rule divide_pos_pos)
   540     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
   541       using ZfunD [OF f] by fast
   542     with g show "eventually (\<lambda>x. norm (g x) < r) F"
   543     proof eventually_elim
   544       case (elim x)
   545       hence "norm (f x) * K < r"
   546         by (simp add: pos_less_divide_eq K)
   547       thus ?case
   548         by (simp add: order_le_less_trans [OF elim(1)])
   549     qed
   550   qed
   551 next
   552   assume "\<not> 0 < K"
   553   hence K: "K \<le> 0" by (simp only: not_less)
   554   show ?thesis
   555   proof (rule ZfunI)
   556     fix r :: real
   557     assume "0 < r"
   558     from g show "eventually (\<lambda>x. norm (g x) < r) F"
   559     proof eventually_elim
   560       case (elim x)
   561       also have "norm (f x) * K \<le> norm (f x) * 0"
   562         using K norm_ge_zero by (rule mult_left_mono)
   563       finally show ?case
   564         using `0 < r` by simp
   565     qed
   566   qed
   567 qed
   568 
   569 lemma Zfun_le: "\<lbrakk>Zfun g F; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f F"
   570   by (erule_tac K="1" in Zfun_imp_Zfun, simp)
   571 
   572 lemma Zfun_add:
   573   assumes f: "Zfun f F" and g: "Zfun g F"
   574   shows "Zfun (\<lambda>x. f x + g x) F"
   575 proof (rule ZfunI)
   576   fix r::real assume "0 < r"
   577   hence r: "0 < r / 2" by simp
   578   have "eventually (\<lambda>x. norm (f x) < r/2) F"
   579     using f r by (rule ZfunD)
   580   moreover
   581   have "eventually (\<lambda>x. norm (g x) < r/2) F"
   582     using g r by (rule ZfunD)
   583   ultimately
   584   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
   585   proof eventually_elim
   586     case (elim x)
   587     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   588       by (rule norm_triangle_ineq)
   589     also have "\<dots> < r/2 + r/2"
   590       using elim by (rule add_strict_mono)
   591     finally show ?case
   592       by simp
   593   qed
   594 qed
   595 
   596 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
   597   unfolding Zfun_def by simp
   598 
   599 lemma Zfun_diff: "\<lbrakk>Zfun f F; Zfun g F\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
   600   by (simp only: diff_minus Zfun_add Zfun_minus)
   601 
   602 lemma (in bounded_linear) Zfun:
   603   assumes g: "Zfun g F"
   604   shows "Zfun (\<lambda>x. f (g x)) F"
   605 proof -
   606   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   607     using bounded by fast
   608   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
   609     by simp
   610   with g show ?thesis
   611     by (rule Zfun_imp_Zfun)
   612 qed
   613 
   614 lemma (in bounded_bilinear) Zfun:
   615   assumes f: "Zfun f F"
   616   assumes g: "Zfun g F"
   617   shows "Zfun (\<lambda>x. f x ** g x) F"
   618 proof (rule ZfunI)
   619   fix r::real assume r: "0 < r"
   620   obtain K where K: "0 < K"
   621     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   622     using pos_bounded by fast
   623   from K have K': "0 < inverse K"
   624     by (rule positive_imp_inverse_positive)
   625   have "eventually (\<lambda>x. norm (f x) < r) F"
   626     using f r by (rule ZfunD)
   627   moreover
   628   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
   629     using g K' by (rule ZfunD)
   630   ultimately
   631   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
   632   proof eventually_elim
   633     case (elim x)
   634     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   635       by (rule norm_le)
   636     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   637       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero elim K)
   638     also from K have "r * inverse K * K = r"
   639       by simp
   640     finally show ?case .
   641   qed
   642 qed
   643 
   644 lemma (in bounded_bilinear) Zfun_left:
   645   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
   646   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   647 
   648 lemma (in bounded_bilinear) Zfun_right:
   649   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
   650   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   651 
   652 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
   653 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
   654 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
   655 
   656 
   657 subsection {* Limits *}
   658 
   659 definition filterlim :: "('a \<Rightarrow> 'b) \<Rightarrow> 'b filter \<Rightarrow> 'a filter \<Rightarrow> bool" where
   660   "filterlim f F2 F1 \<longleftrightarrow> filtermap f F1 \<le> F2"
   661 
   662 syntax
   663   "_LIM" :: "pttrns \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> bool" ("(3LIM (_)/ (_)./ (_) :> (_))" [1000, 10, 0, 10] 10)
   664 
   665 translations
   666   "LIM x F1. f :> F2"   == "CONST filterlim (%x. f) F2 F1"
   667 
   668 lemma filterlim_iff:
   669   "(LIM x F1. f x :> F2) \<longleftrightarrow> (\<forall>P. eventually P F2 \<longrightarrow> eventually (\<lambda>x. P (f x)) F1)"
   670   unfolding filterlim_def le_filter_def eventually_filtermap ..
   671 
   672 lemma filterlim_compose: 
   673   "filterlim g F3 F2 \<Longrightarrow> filterlim f F2 F1 \<Longrightarrow> filterlim (\<lambda>x. g (f x)) F3 F1"
   674   unfolding filterlim_def filtermap_filtermap[symmetric] by (metis filtermap_mono order_trans)
   675 
   676 lemma filterlim_mono: 
   677   "filterlim f F2 F1 \<Longrightarrow> F2 \<le> F2' \<Longrightarrow> F1' \<le> F1 \<Longrightarrow> filterlim f F2' F1'"
   678   unfolding filterlim_def by (metis filtermap_mono order_trans)
   679 
   680 lemma filterlim_within:
   681   "(LIM x F1. f x :> F2 within S) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> S) F1 \<and> (LIM x F1. f x :> F2))"
   682   unfolding filterlim_def
   683 proof safe
   684   assume "filtermap f F1 \<le> F2 within S" then show "eventually (\<lambda>x. f x \<in> S) F1"
   685     by (auto simp: le_filter_def eventually_filtermap eventually_within elim!: allE[of _ "\<lambda>x. x \<in> S"])
   686 qed (auto intro: within_le order_trans simp: le_within_iff eventually_filtermap)
   687 
   688 abbreviation (in topological_space)
   689   tendsto :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b filter \<Rightarrow> bool" (infixr "--->" 55) where
   690   "(f ---> l) F \<equiv> filterlim f (nhds l) F"
   691 
   692 ML {*
   693 structure Tendsto_Intros = Named_Thms
   694 (
   695   val name = @{binding tendsto_intros}
   696   val description = "introduction rules for tendsto"
   697 )
   698 *}
   699 
   700 setup Tendsto_Intros.setup
   701 
   702 lemma tendsto_def: "(f ---> l) F \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) F)"
   703   unfolding filterlim_def
   704 proof safe
   705   fix S assume "open S" "l \<in> S" "filtermap f F \<le> nhds l"
   706   then show "eventually (\<lambda>x. f x \<in> S) F"
   707     unfolding eventually_nhds eventually_filtermap le_filter_def
   708     by (auto elim!: allE[of _ "\<lambda>x. x \<in> S"] eventually_rev_mp)
   709 qed (auto elim!: eventually_rev_mp simp: eventually_nhds eventually_filtermap le_filter_def)
   710 
   711 lemma filterlim_at:
   712   "(LIM x F. f x :> at b) \<longleftrightarrow> (eventually (\<lambda>x. f x \<noteq> b) F \<and> (f ---> b) F)"
   713   by (simp add: at_def filterlim_within)
   714 
   715 lemma tendsto_mono: "F \<le> F' \<Longrightarrow> (f ---> l) F' \<Longrightarrow> (f ---> l) F"
   716   unfolding tendsto_def le_filter_def by fast
   717 
   718 lemma topological_tendstoI:
   719   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F)
   720     \<Longrightarrow> (f ---> l) F"
   721   unfolding tendsto_def by auto
   722 
   723 lemma topological_tendstoD:
   724   "(f ---> l) F \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F"
   725   unfolding tendsto_def by auto
   726 
   727 lemma tendstoI:
   728   assumes "\<And>e. 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
   729   shows "(f ---> l) F"
   730   apply (rule topological_tendstoI)
   731   apply (simp add: open_dist)
   732   apply (drule (1) bspec, clarify)
   733   apply (drule assms)
   734   apply (erule eventually_elim1, simp)
   735   done
   736 
   737 lemma tendstoD:
   738   "(f ---> l) F \<Longrightarrow> 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
   739   apply (drule_tac S="{x. dist x l < e}" in topological_tendstoD)
   740   apply (clarsimp simp add: open_dist)
   741   apply (rule_tac x="e - dist x l" in exI, clarsimp)
   742   apply (simp only: less_diff_eq)
   743   apply (erule le_less_trans [OF dist_triangle])
   744   apply simp
   745   apply simp
   746   done
   747 
   748 lemma tendsto_iff:
   749   "(f ---> l) F \<longleftrightarrow> (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) F)"
   750   using tendstoI tendstoD by fast
   751 
   752 lemma tendsto_Zfun_iff: "(f ---> a) F = Zfun (\<lambda>x. f x - a) F"
   753   by (simp only: tendsto_iff Zfun_def dist_norm)
   754 
   755 lemma tendsto_bot [simp]: "(f ---> a) bot"
   756   unfolding tendsto_def by simp
   757 
   758 lemma tendsto_ident_at [tendsto_intros]: "((\<lambda>x. x) ---> a) (at a)"
   759   unfolding tendsto_def eventually_at_topological by auto
   760 
   761 lemma tendsto_ident_at_within [tendsto_intros]:
   762   "((\<lambda>x. x) ---> a) (at a within S)"
   763   unfolding tendsto_def eventually_within eventually_at_topological by auto
   764 
   765 lemma tendsto_const [tendsto_intros]: "((\<lambda>x. k) ---> k) F"
   766   by (simp add: tendsto_def)
   767 
   768 lemma tendsto_unique:
   769   fixes f :: "'a \<Rightarrow> 'b::t2_space"
   770   assumes "\<not> trivial_limit F" and "(f ---> a) F" and "(f ---> b) F"
   771   shows "a = b"
   772 proof (rule ccontr)
   773   assume "a \<noteq> b"
   774   obtain U V where "open U" "open V" "a \<in> U" "b \<in> V" "U \<inter> V = {}"
   775     using hausdorff [OF `a \<noteq> b`] by fast
   776   have "eventually (\<lambda>x. f x \<in> U) F"
   777     using `(f ---> a) F` `open U` `a \<in> U` by (rule topological_tendstoD)
   778   moreover
   779   have "eventually (\<lambda>x. f x \<in> V) F"
   780     using `(f ---> b) F` `open V` `b \<in> V` by (rule topological_tendstoD)
   781   ultimately
   782   have "eventually (\<lambda>x. False) F"
   783   proof eventually_elim
   784     case (elim x)
   785     hence "f x \<in> U \<inter> V" by simp
   786     with `U \<inter> V = {}` show ?case by simp
   787   qed
   788   with `\<not> trivial_limit F` show "False"
   789     by (simp add: trivial_limit_def)
   790 qed
   791 
   792 lemma tendsto_const_iff:
   793   fixes a b :: "'a::t2_space"
   794   assumes "\<not> trivial_limit F" shows "((\<lambda>x. a) ---> b) F \<longleftrightarrow> a = b"
   795   by (safe intro!: tendsto_const tendsto_unique [OF assms tendsto_const])
   796 
   797 lemma tendsto_at_iff_tendsto_nhds:
   798   "(g ---> g l) (at l) \<longleftrightarrow> (g ---> g l) (nhds l)"
   799   unfolding tendsto_def at_def eventually_within
   800   by (intro ext all_cong imp_cong) (auto elim!: eventually_elim1)
   801 
   802 lemma tendsto_compose:
   803   "(g ---> g l) (at l) \<Longrightarrow> (f ---> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> g l) F"
   804   unfolding tendsto_at_iff_tendsto_nhds by (rule filterlim_compose[of g])
   805 
   806 lemma tendsto_compose_eventually:
   807   "(g ---> m) (at l) \<Longrightarrow> (f ---> l) F \<Longrightarrow> eventually (\<lambda>x. f x \<noteq> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> m) F"
   808   by (rule filterlim_compose[of g _ "at l"]) (auto simp add: filterlim_at)
   809 
   810 lemma metric_tendsto_imp_tendsto:
   811   assumes f: "(f ---> a) F"
   812   assumes le: "eventually (\<lambda>x. dist (g x) b \<le> dist (f x) a) F"
   813   shows "(g ---> b) F"
   814 proof (rule tendstoI)
   815   fix e :: real assume "0 < e"
   816   with f have "eventually (\<lambda>x. dist (f x) a < e) F" by (rule tendstoD)
   817   with le show "eventually (\<lambda>x. dist (g x) b < e) F"
   818     using le_less_trans by (rule eventually_elim2)
   819 qed
   820 
   821 subsubsection {* Distance and norms *}
   822 
   823 lemma tendsto_dist [tendsto_intros]:
   824   assumes f: "(f ---> l) F" and g: "(g ---> m) F"
   825   shows "((\<lambda>x. dist (f x) (g x)) ---> dist l m) F"
   826 proof (rule tendstoI)
   827   fix e :: real assume "0 < e"
   828   hence e2: "0 < e/2" by simp
   829   from tendstoD [OF f e2] tendstoD [OF g e2]
   830   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) F"
   831   proof (eventually_elim)
   832     case (elim x)
   833     then show "dist (dist (f x) (g x)) (dist l m) < e"
   834       unfolding dist_real_def
   835       using dist_triangle2 [of "f x" "g x" "l"]
   836       using dist_triangle2 [of "g x" "l" "m"]
   837       using dist_triangle3 [of "l" "m" "f x"]
   838       using dist_triangle [of "f x" "m" "g x"]
   839       by arith
   840   qed
   841 qed
   842 
   843 lemma norm_conv_dist: "norm x = dist x 0"
   844   unfolding dist_norm by simp
   845 
   846 lemma tendsto_norm [tendsto_intros]:
   847   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> norm a) F"
   848   unfolding norm_conv_dist by (intro tendsto_intros)
   849 
   850 lemma tendsto_norm_zero:
   851   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> 0) F"
   852   by (drule tendsto_norm, simp)
   853 
   854 lemma tendsto_norm_zero_cancel:
   855   "((\<lambda>x. norm (f x)) ---> 0) F \<Longrightarrow> (f ---> 0) F"
   856   unfolding tendsto_iff dist_norm by simp
   857 
   858 lemma tendsto_norm_zero_iff:
   859   "((\<lambda>x. norm (f x)) ---> 0) F \<longleftrightarrow> (f ---> 0) F"
   860   unfolding tendsto_iff dist_norm by simp
   861 
   862 lemma tendsto_rabs [tendsto_intros]:
   863   "(f ---> (l::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> \<bar>l\<bar>) F"
   864   by (fold real_norm_def, rule tendsto_norm)
   865 
   866 lemma tendsto_rabs_zero:
   867   "(f ---> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> 0) F"
   868   by (fold real_norm_def, rule tendsto_norm_zero)
   869 
   870 lemma tendsto_rabs_zero_cancel:
   871   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<Longrightarrow> (f ---> 0) F"
   872   by (fold real_norm_def, rule tendsto_norm_zero_cancel)
   873 
   874 lemma tendsto_rabs_zero_iff:
   875   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<longleftrightarrow> (f ---> 0) F"
   876   by (fold real_norm_def, rule tendsto_norm_zero_iff)
   877 
   878 subsubsection {* Addition and subtraction *}
   879 
   880 lemma tendsto_add [tendsto_intros]:
   881   fixes a b :: "'a::real_normed_vector"
   882   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> a + b) F"
   883   by (simp only: tendsto_Zfun_iff add_diff_add Zfun_add)
   884 
   885 lemma tendsto_add_zero:
   886   fixes f g :: "'a::type \<Rightarrow> 'b::real_normed_vector"
   887   shows "\<lbrakk>(f ---> 0) F; (g ---> 0) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> 0) F"
   888   by (drule (1) tendsto_add, simp)
   889 
   890 lemma tendsto_minus [tendsto_intros]:
   891   fixes a :: "'a::real_normed_vector"
   892   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. - f x) ---> - a) F"
   893   by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
   894 
   895 lemma tendsto_minus_cancel:
   896   fixes a :: "'a::real_normed_vector"
   897   shows "((\<lambda>x. - f x) ---> - a) F \<Longrightarrow> (f ---> a) F"
   898   by (drule tendsto_minus, simp)
   899 
   900 lemma tendsto_diff [tendsto_intros]:
   901   fixes a b :: "'a::real_normed_vector"
   902   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) ---> a - b) F"
   903   by (simp add: diff_minus tendsto_add tendsto_minus)
   904 
   905 lemma tendsto_setsum [tendsto_intros]:
   906   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::real_normed_vector"
   907   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> a i) F"
   908   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) ---> (\<Sum>i\<in>S. a i)) F"
   909 proof (cases "finite S")
   910   assume "finite S" thus ?thesis using assms
   911     by (induct, simp add: tendsto_const, simp add: tendsto_add)
   912 next
   913   assume "\<not> finite S" thus ?thesis
   914     by (simp add: tendsto_const)
   915 qed
   916 
   917 lemma real_tendsto_sandwich:
   918   fixes f g h :: "'a \<Rightarrow> real"
   919   assumes ev: "eventually (\<lambda>n. f n \<le> g n) net" "eventually (\<lambda>n. g n \<le> h n) net"
   920   assumes lim: "(f ---> c) net" "(h ---> c) net"
   921   shows "(g ---> c) net"
   922 proof -
   923   have "((\<lambda>n. g n - f n) ---> 0) net"
   924   proof (rule metric_tendsto_imp_tendsto)
   925     show "eventually (\<lambda>n. dist (g n - f n) 0 \<le> dist (h n - f n) 0) net"
   926       using ev by (rule eventually_elim2) (simp add: dist_real_def)
   927     show "((\<lambda>n. h n - f n) ---> 0) net"
   928       using tendsto_diff[OF lim(2,1)] by simp
   929   qed
   930   from tendsto_add[OF this lim(1)] show ?thesis by simp
   931 qed
   932 
   933 subsubsection {* Linear operators and multiplication *}
   934 
   935 lemma (in bounded_linear) tendsto:
   936   "(g ---> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> f a) F"
   937   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   938 
   939 lemma (in bounded_linear) tendsto_zero:
   940   "(g ---> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> 0) F"
   941   by (drule tendsto, simp only: zero)
   942 
   943 lemma (in bounded_bilinear) tendsto:
   944   "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) ---> a ** b) F"
   945   by (simp only: tendsto_Zfun_iff prod_diff_prod
   946                  Zfun_add Zfun Zfun_left Zfun_right)
   947 
   948 lemma (in bounded_bilinear) tendsto_zero:
   949   assumes f: "(f ---> 0) F"
   950   assumes g: "(g ---> 0) F"
   951   shows "((\<lambda>x. f x ** g x) ---> 0) F"
   952   using tendsto [OF f g] by (simp add: zero_left)
   953 
   954 lemma (in bounded_bilinear) tendsto_left_zero:
   955   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) ---> 0) F"
   956   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
   957 
   958 lemma (in bounded_bilinear) tendsto_right_zero:
   959   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) ---> 0) F"
   960   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
   961 
   962 lemmas tendsto_of_real [tendsto_intros] =
   963   bounded_linear.tendsto [OF bounded_linear_of_real]
   964 
   965 lemmas tendsto_scaleR [tendsto_intros] =
   966   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
   967 
   968 lemmas tendsto_mult [tendsto_intros] =
   969   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
   970 
   971 lemmas tendsto_mult_zero =
   972   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
   973 
   974 lemmas tendsto_mult_left_zero =
   975   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
   976 
   977 lemmas tendsto_mult_right_zero =
   978   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
   979 
   980 lemma tendsto_power [tendsto_intros]:
   981   fixes f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
   982   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) ---> a ^ n) F"
   983   by (induct n) (simp_all add: tendsto_const tendsto_mult)
   984 
   985 lemma tendsto_setprod [tendsto_intros]:
   986   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   987   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> L i) F"
   988   shows "((\<lambda>x. \<Prod>i\<in>S. f i x) ---> (\<Prod>i\<in>S. L i)) F"
   989 proof (cases "finite S")
   990   assume "finite S" thus ?thesis using assms
   991     by (induct, simp add: tendsto_const, simp add: tendsto_mult)
   992 next
   993   assume "\<not> finite S" thus ?thesis
   994     by (simp add: tendsto_const)
   995 qed
   996 
   997 subsubsection {* Inverse and division *}
   998 
   999 lemma (in bounded_bilinear) Zfun_prod_Bfun:
  1000   assumes f: "Zfun f F"
  1001   assumes g: "Bfun g F"
  1002   shows "Zfun (\<lambda>x. f x ** g x) F"
  1003 proof -
  1004   obtain K where K: "0 \<le> K"
  1005     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
  1006     using nonneg_bounded by fast
  1007   obtain B where B: "0 < B"
  1008     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
  1009     using g by (rule BfunE)
  1010   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
  1011   using norm_g proof eventually_elim
  1012     case (elim x)
  1013     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
  1014       by (rule norm_le)
  1015     also have "\<dots> \<le> norm (f x) * B * K"
  1016       by (intro mult_mono' order_refl norm_g norm_ge_zero
  1017                 mult_nonneg_nonneg K elim)
  1018     also have "\<dots> = norm (f x) * (B * K)"
  1019       by (rule mult_assoc)
  1020     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
  1021   qed
  1022   with f show ?thesis
  1023     by (rule Zfun_imp_Zfun)
  1024 qed
  1025 
  1026 lemma (in bounded_bilinear) flip:
  1027   "bounded_bilinear (\<lambda>x y. y ** x)"
  1028   apply default
  1029   apply (rule add_right)
  1030   apply (rule add_left)
  1031   apply (rule scaleR_right)
  1032   apply (rule scaleR_left)
  1033   apply (subst mult_commute)
  1034   using bounded by fast
  1035 
  1036 lemma (in bounded_bilinear) Bfun_prod_Zfun:
  1037   assumes f: "Bfun f F"
  1038   assumes g: "Zfun g F"
  1039   shows "Zfun (\<lambda>x. f x ** g x) F"
  1040   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
  1041 
  1042 lemma Bfun_inverse_lemma:
  1043   fixes x :: "'a::real_normed_div_algebra"
  1044   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
  1045   apply (subst nonzero_norm_inverse, clarsimp)
  1046   apply (erule (1) le_imp_inverse_le)
  1047   done
  1048 
  1049 lemma Bfun_inverse:
  1050   fixes a :: "'a::real_normed_div_algebra"
  1051   assumes f: "(f ---> a) F"
  1052   assumes a: "a \<noteq> 0"
  1053   shows "Bfun (\<lambda>x. inverse (f x)) F"
  1054 proof -
  1055   from a have "0 < norm a" by simp
  1056   hence "\<exists>r>0. r < norm a" by (rule dense)
  1057   then obtain r where r1: "0 < r" and r2: "r < norm a" by fast
  1058   have "eventually (\<lambda>x. dist (f x) a < r) F"
  1059     using tendstoD [OF f r1] by fast
  1060   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
  1061   proof eventually_elim
  1062     case (elim x)
  1063     hence 1: "norm (f x - a) < r"
  1064       by (simp add: dist_norm)
  1065     hence 2: "f x \<noteq> 0" using r2 by auto
  1066     hence "norm (inverse (f x)) = inverse (norm (f x))"
  1067       by (rule nonzero_norm_inverse)
  1068     also have "\<dots> \<le> inverse (norm a - r)"
  1069     proof (rule le_imp_inverse_le)
  1070       show "0 < norm a - r" using r2 by simp
  1071     next
  1072       have "norm a - norm (f x) \<le> norm (a - f x)"
  1073         by (rule norm_triangle_ineq2)
  1074       also have "\<dots> = norm (f x - a)"
  1075         by (rule norm_minus_commute)
  1076       also have "\<dots> < r" using 1 .
  1077       finally show "norm a - r \<le> norm (f x)" by simp
  1078     qed
  1079     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
  1080   qed
  1081   thus ?thesis by (rule BfunI)
  1082 qed
  1083 
  1084 lemma tendsto_inverse [tendsto_intros]:
  1085   fixes a :: "'a::real_normed_div_algebra"
  1086   assumes f: "(f ---> a) F"
  1087   assumes a: "a \<noteq> 0"
  1088   shows "((\<lambda>x. inverse (f x)) ---> inverse a) F"
  1089 proof -
  1090   from a have "0 < norm a" by simp
  1091   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
  1092     by (rule tendstoD)
  1093   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
  1094     unfolding dist_norm by (auto elim!: eventually_elim1)
  1095   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
  1096     - (inverse (f x) * (f x - a) * inverse a)) F"
  1097     by (auto elim!: eventually_elim1 simp: inverse_diff_inverse)
  1098   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
  1099     by (intro Zfun_minus Zfun_mult_left
  1100       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
  1101       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
  1102   ultimately show ?thesis
  1103     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
  1104 qed
  1105 
  1106 lemma tendsto_divide [tendsto_intros]:
  1107   fixes a b :: "'a::real_normed_field"
  1108   shows "\<lbrakk>(f ---> a) F; (g ---> b) F; b \<noteq> 0\<rbrakk>
  1109     \<Longrightarrow> ((\<lambda>x. f x / g x) ---> a / b) F"
  1110   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
  1111 
  1112 lemma tendsto_sgn [tendsto_intros]:
  1113   fixes l :: "'a::real_normed_vector"
  1114   shows "\<lbrakk>(f ---> l) F; l \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. sgn (f x)) ---> sgn l) F"
  1115   unfolding sgn_div_norm by (simp add: tendsto_intros)
  1116 
  1117 subsection {* Limits to @{const at_top} and @{const at_bot} *}
  1118 
  1119 lemma filterlim_at_top:
  1120   fixes f :: "'a \<Rightarrow> ('b::dense_linorder)"
  1121   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z < f x) F)"
  1122   by (auto simp: filterlim_iff eventually_at_top_dense elim!: eventually_elim1)
  1123 
  1124 lemma filterlim_at_top_gt:
  1125   fixes f :: "'a \<Rightarrow> ('b::dense_linorder)" and c :: "'b"
  1126   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z>c. eventually (\<lambda>x. Z < f x) F)"
  1127   unfolding filterlim_at_top
  1128 proof safe
  1129   fix Z assume *: "\<forall>Z>c. eventually (\<lambda>x. Z < f x) F"
  1130   from gt_ex[of "max Z c"] guess x ..
  1131   with *[THEN spec, of x] show "eventually (\<lambda>x. Z < f x) F"
  1132     by (auto elim!: eventually_elim1)
  1133 qed simp
  1134 
  1135 lemma filterlim_at_bot: 
  1136   fixes f :: "'a \<Rightarrow> ('b::dense_linorder)"
  1137   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x < Z) F)"
  1138   by (auto simp: filterlim_iff eventually_at_bot_dense elim!: eventually_elim1)
  1139 
  1140 lemma filterlim_at_bot_lt:
  1141   fixes f :: "'a \<Rightarrow> ('b::dense_linorder)" and c :: "'b"
  1142   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z<c. eventually (\<lambda>x. Z > f x) F)"
  1143   unfolding filterlim_at_bot
  1144 proof safe
  1145   fix Z assume *: "\<forall>Z<c. eventually (\<lambda>x. Z > f x) F"
  1146   from lt_ex[of "min Z c"] guess x ..
  1147   with *[THEN spec, of x] show "eventually (\<lambda>x. Z > f x) F"
  1148     by (auto elim!: eventually_elim1)
  1149 qed simp
  1150 
  1151 lemma filterlim_at_infinity:
  1152   fixes f :: "_ \<Rightarrow> 'a\<Colon>real_normed_vector"
  1153   assumes "0 \<le> c"
  1154   shows "(LIM x F. f x :> at_infinity) \<longleftrightarrow> (\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F)"
  1155   unfolding filterlim_iff eventually_at_infinity
  1156 proof safe
  1157   fix P :: "'a \<Rightarrow> bool" and b
  1158   assume *: "\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F"
  1159     and P: "\<forall>x. b \<le> norm x \<longrightarrow> P x"
  1160   have "max b (c + 1) > c" by auto
  1161   with * have "eventually (\<lambda>x. max b (c + 1) \<le> norm (f x)) F"
  1162     by auto
  1163   then show "eventually (\<lambda>x. P (f x)) F"
  1164   proof eventually_elim
  1165     fix x assume "max b (c + 1) \<le> norm (f x)"
  1166     with P show "P (f x)" by auto
  1167   qed
  1168 qed force
  1169 
  1170 lemma filterlim_real_sequentially: "LIM x sequentially. real x :> at_top"
  1171   unfolding filterlim_at_top
  1172   apply (intro allI)
  1173   apply (rule_tac c="natceiling (Z + 1)" in eventually_sequentiallyI)
  1174   apply (auto simp: natceiling_le_eq)
  1175   done
  1176 
  1177 lemma filterlim_inverse_at_top_pos:
  1178   "LIM x (nhds 0 within {0::real <..}). inverse x :> at_top"
  1179   unfolding filterlim_at_top_gt[where c=0] eventually_within
  1180 proof safe
  1181   fix Z :: real assume [arith]: "0 < Z"
  1182   then have "eventually (\<lambda>x. x < inverse Z) (nhds 0)"
  1183     by (auto simp add: eventually_nhds_metric dist_real_def intro!: exI[of _ "\<bar>inverse Z\<bar>"])
  1184   then show "eventually (\<lambda>x. x \<in> {0<..} \<longrightarrow> Z < inverse x) (nhds 0)"
  1185     by (auto elim!: eventually_elim1 simp: inverse_eq_divide field_simps)
  1186 qed
  1187 
  1188 lemma filterlim_inverse_at_top:
  1189   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. 0 < f x) F \<Longrightarrow> LIM x F. inverse (f x) :> at_top"
  1190   by (intro filterlim_compose[OF filterlim_inverse_at_top_pos])
  1191      (simp add: filterlim_def eventually_filtermap le_within_iff)
  1192 
  1193 lemma filterlim_inverse_at_bot_neg:
  1194   "LIM x (nhds 0 within {..< 0::real}). inverse x :> at_bot"
  1195   unfolding filterlim_at_bot_lt[where c=0] eventually_within
  1196 proof safe
  1197   fix Z :: real assume [arith]: "Z < 0"
  1198   have "eventually (\<lambda>x. inverse Z < x) (nhds 0)"
  1199     by (auto simp add: eventually_nhds_metric dist_real_def intro!: exI[of _ "\<bar>inverse Z\<bar>"])
  1200   then show "eventually (\<lambda>x. x \<in> {..< 0} \<longrightarrow> inverse x < Z) (nhds 0)"
  1201     by (auto elim!: eventually_elim1 simp: inverse_eq_divide field_simps)
  1202 qed
  1203 
  1204 lemma filterlim_inverse_at_bot:
  1205   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. f x < 0) F \<Longrightarrow> LIM x F. inverse (f x) :> at_bot"
  1206   by (intro filterlim_compose[OF filterlim_inverse_at_bot_neg])
  1207      (simp add: filterlim_def eventually_filtermap le_within_iff)
  1208 
  1209 lemma filterlim_uminus_at_top_at_bot: "LIM x at_bot. - x :: real :> at_top"
  1210   unfolding filterlim_at_top eventually_at_bot_dense
  1211   by (blast intro: less_minus_iff[THEN iffD1])
  1212 
  1213 lemma filterlim_uminus_at_top: "LIM x F. f x :> at_bot \<Longrightarrow> LIM x F. - (f x) :: real :> at_top"
  1214   by (rule filterlim_compose[OF filterlim_uminus_at_top_at_bot])
  1215 
  1216 lemma filterlim_uminus_at_bot_at_top: "LIM x at_top. - x :: real :> at_bot"
  1217   unfolding filterlim_at_bot eventually_at_top_dense
  1218   by (blast intro: minus_less_iff[THEN iffD1])
  1219 
  1220 lemma filterlim_uminus_at_bot: "LIM x F. f x :> at_top \<Longrightarrow> LIM x F. - (f x) :: real :> at_bot"
  1221   by (rule filterlim_compose[OF filterlim_uminus_at_bot_at_top])
  1222 
  1223 lemma tendsto_inverse_0:
  1224   fixes x :: "_ \<Rightarrow> 'a\<Colon>real_normed_div_algebra"
  1225   shows "(inverse ---> (0::'a)) at_infinity"
  1226   unfolding tendsto_Zfun_iff diff_0_right Zfun_def eventually_at_infinity
  1227 proof safe
  1228   fix r :: real assume "0 < r"
  1229   show "\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> norm (inverse x :: 'a) < r"
  1230   proof (intro exI[of _ "inverse (r / 2)"] allI impI)
  1231     fix x :: 'a
  1232     from `0 < r` have "0 < inverse (r / 2)" by simp
  1233     also assume *: "inverse (r / 2) \<le> norm x"
  1234     finally show "norm (inverse x) < r"
  1235       using * `0 < r` by (subst nonzero_norm_inverse) (simp_all add: inverse_eq_divide field_simps)
  1236   qed
  1237 qed
  1238 
  1239 lemma filterlim_inverse_at_infinity:
  1240   fixes x :: "_ \<Rightarrow> 'a\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
  1241   shows "filterlim inverse at_infinity (at (0::'a))"
  1242   unfolding filterlim_at_infinity[OF order_refl]
  1243 proof safe
  1244   fix r :: real assume "0 < r"
  1245   then show "eventually (\<lambda>x::'a. r \<le> norm (inverse x)) (at 0)"
  1246     unfolding eventually_at norm_inverse
  1247     by (intro exI[of _ "inverse r"])
  1248        (auto simp: norm_conv_dist[symmetric] field_simps inverse_eq_divide)
  1249 qed
  1250 
  1251 lemma filterlim_inverse_at_iff:
  1252   fixes g :: "'a \<Rightarrow> 'b\<Colon>{real_normed_div_algebra, division_ring_inverse_zero}"
  1253   shows "(LIM x F. inverse (g x) :> at 0) \<longleftrightarrow> (LIM x F. g x :> at_infinity)"
  1254   unfolding filterlim_def filtermap_filtermap[symmetric]
  1255 proof
  1256   assume "filtermap g F \<le> at_infinity"
  1257   then have "filtermap inverse (filtermap g F) \<le> filtermap inverse at_infinity"
  1258     by (rule filtermap_mono)
  1259   also have "\<dots> \<le> at 0"
  1260     using tendsto_inverse_0
  1261     by (auto intro!: le_withinI exI[of _ 1]
  1262              simp: eventually_filtermap eventually_at_infinity filterlim_def at_def)
  1263   finally show "filtermap inverse (filtermap g F) \<le> at 0" .
  1264 next
  1265   assume "filtermap inverse (filtermap g F) \<le> at 0"
  1266   then have "filtermap inverse (filtermap inverse (filtermap g F)) \<le> filtermap inverse (at 0)"
  1267     by (rule filtermap_mono)
  1268   with filterlim_inverse_at_infinity show "filtermap g F \<le> at_infinity"
  1269     by (auto intro: order_trans simp: filterlim_def filtermap_filtermap)
  1270 qed
  1271 
  1272 text {*
  1273 
  1274 We only show rules for multiplication and addition when the functions are either against a real
  1275 value or against infinity. Further rules are easy to derive by using @{thm filterlim_uminus_at_top}.
  1276 
  1277 *}
  1278 
  1279 lemma filterlim_tendsto_pos_mult_at_top: 
  1280   assumes f: "(f ---> c) F" and c: "0 < c"
  1281   assumes g: "LIM x F. g x :> at_top"
  1282   shows "LIM x F. (f x * g x :: real) :> at_top"
  1283   unfolding filterlim_at_top_gt[where c=0]
  1284 proof safe
  1285   fix Z :: real assume "0 < Z"
  1286   from f `0 < c` have "eventually (\<lambda>x. c / 2 < f x) F"
  1287     by (auto dest!: tendstoD[where e="c / 2"] elim!: eventually_elim1
  1288              simp: dist_real_def abs_real_def split: split_if_asm)
  1289   moreover from g have "eventually (\<lambda>x. (Z / c * 2) < g x) F"
  1290     unfolding filterlim_at_top by auto
  1291   ultimately show "eventually (\<lambda>x. Z < f x * g x) F"
  1292   proof eventually_elim
  1293     fix x assume "c / 2 < f x" "Z / c * 2 < g x"
  1294     with `0 < Z` `0 < c` have "c / 2 * (Z / c * 2) < f x * g x"
  1295       by (intro mult_strict_mono) (auto simp: zero_le_divide_iff)
  1296     with `0 < c` show "Z < f x * g x"
  1297        by simp
  1298   qed
  1299 qed
  1300 
  1301 lemma filterlim_at_top_mult_at_top: 
  1302   assumes f: "LIM x F. f x :> at_top"
  1303   assumes g: "LIM x F. g x :> at_top"
  1304   shows "LIM x F. (f x * g x :: real) :> at_top"
  1305   unfolding filterlim_at_top_gt[where c=0]
  1306 proof safe
  1307   fix Z :: real assume "0 < Z"
  1308   from f have "eventually (\<lambda>x. 1 < f x) F"
  1309     unfolding filterlim_at_top by auto
  1310   moreover from g have "eventually (\<lambda>x. Z < g x) F"
  1311     unfolding filterlim_at_top by auto
  1312   ultimately show "eventually (\<lambda>x. Z < f x * g x) F"
  1313   proof eventually_elim
  1314     fix x assume "1 < f x" "Z < g x"
  1315     with `0 < Z` have "1 * Z < f x * g x"
  1316       by (intro mult_strict_mono) (auto simp: zero_le_divide_iff)
  1317     then show "Z < f x * g x"
  1318        by simp
  1319   qed
  1320 qed
  1321 
  1322 lemma filterlim_tendsto_add_at_top: 
  1323   assumes f: "(f ---> c) F"
  1324   assumes g: "LIM x F. g x :> at_top"
  1325   shows "LIM x F. (f x + g x :: real) :> at_top"
  1326   unfolding filterlim_at_top_gt[where c=0]
  1327 proof safe
  1328   fix Z :: real assume "0 < Z"
  1329   from f have "eventually (\<lambda>x. c - 1 < f x) F"
  1330     by (auto dest!: tendstoD[where e=1] elim!: eventually_elim1 simp: dist_real_def)
  1331   moreover from g have "eventually (\<lambda>x. Z - (c - 1) < g x) F"
  1332     unfolding filterlim_at_top by auto
  1333   ultimately show "eventually (\<lambda>x. Z < f x + g x) F"
  1334     by eventually_elim simp
  1335 qed
  1336 
  1337 lemma filterlim_at_top_add_at_top: 
  1338   assumes f: "LIM x F. f x :> at_top"
  1339   assumes g: "LIM x F. g x :> at_top"
  1340   shows "LIM x F. (f x + g x :: real) :> at_top"
  1341   unfolding filterlim_at_top_gt[where c=0]
  1342 proof safe
  1343   fix Z :: real assume "0 < Z"
  1344   from f have "eventually (\<lambda>x. 0 < f x) F"
  1345     unfolding filterlim_at_top by auto
  1346   moreover from g have "eventually (\<lambda>x. Z < g x) F"
  1347     unfolding filterlim_at_top by auto
  1348   ultimately show "eventually (\<lambda>x. Z < f x + g x) F"
  1349     by eventually_elim simp
  1350 qed
  1351 
  1352 end
  1353