author hoelzl
Wed Oct 10 12:12:23 2012 +0200 (2012-10-10)
changeset 49784 5e5b2da42a69
parent 49780 92a58f80b20c
child 49804 ace9b5a83e60
permissions -rw-r--r--
remove incseq assumption from measure_eqI_generator_eq
     1 (*  Title:      HOL/Probability/Infinite_Product_Measure.thy
     2     Author:     Johannes Hölzl, TU München
     3 *)
     5 header {*Infinite Product Measure*}
     7 theory Infinite_Product_Measure
     8   imports Probability_Measure Caratheodory
     9 begin
    11 lemma restrict_extensional_sub[intro]: "A \<subseteq> B \<Longrightarrow> restrict f A \<in> extensional B"
    12   unfolding restrict_def extensional_def by auto
    14 lemma restrict_restrict[simp]: "restrict (restrict f A) B = restrict f (A \<inter> B)"
    15   unfolding restrict_def by (simp add: fun_eq_iff)
    17 lemma split_merge: "P (merge I J (x,y) i) \<longleftrightarrow> (i \<in> I \<longrightarrow> P (x i)) \<and> (i \<in> J - I \<longrightarrow> P (y i)) \<and> (i \<notin> I \<union> J \<longrightarrow> P undefined)"
    18   unfolding merge_def by auto
    20 lemma extensional_merge_sub: "I \<union> J \<subseteq> K \<Longrightarrow> merge I J (x, y) \<in> extensional K"
    21   unfolding merge_def extensional_def by auto
    23 lemma injective_vimage_restrict:
    24   assumes J: "J \<subseteq> I"
    25   and sets: "A \<subseteq> (\<Pi>\<^isub>E i\<in>J. S i)" "B \<subseteq> (\<Pi>\<^isub>E i\<in>J. S i)" and ne: "(\<Pi>\<^isub>E i\<in>I. S i) \<noteq> {}"
    26   and eq: "(\<lambda>x. restrict x J) -` A \<inter> (\<Pi>\<^isub>E i\<in>I. S i) = (\<lambda>x. restrict x J) -` B \<inter> (\<Pi>\<^isub>E i\<in>I. S i)"
    27   shows "A = B"
    28 proof  (intro set_eqI)
    29   fix x
    30   from ne obtain y where y: "\<And>i. i \<in> I \<Longrightarrow> y i \<in> S i" by auto
    31   have "J \<inter> (I - J) = {}" by auto
    32   show "x \<in> A \<longleftrightarrow> x \<in> B"
    33   proof cases
    34     assume x: "x \<in> (\<Pi>\<^isub>E i\<in>J. S i)"
    35     have "x \<in> A \<longleftrightarrow> merge J (I - J) (x,y) \<in> (\<lambda>x. restrict x J) -` A \<inter> (\<Pi>\<^isub>E i\<in>I. S i)"
    36       using y x `J \<subseteq> I` by (auto simp add: Pi_iff extensional_restrict extensional_merge_sub split: split_merge)
    37     then show "x \<in> A \<longleftrightarrow> x \<in> B"
    38       using y x `J \<subseteq> I` by (auto simp add: Pi_iff extensional_restrict extensional_merge_sub eq split: split_merge)
    39   next
    40     assume "x \<notin> (\<Pi>\<^isub>E i\<in>J. S i)" with sets show "x \<in> A \<longleftrightarrow> x \<in> B" by auto
    41   qed
    42 qed
    44 lemma prod_algebraI_finite:
    45   "finite I \<Longrightarrow> (\<forall>i\<in>I. E i \<in> sets (M i)) \<Longrightarrow> (Pi\<^isub>E I E) \<in> prod_algebra I M"
    46   using prod_algebraI[of I I E M] prod_emb_PiE_same_index[of I E M, OF sets_into_space] by simp
    48 lemma Int_stable_PiE: "Int_stable {Pi\<^isub>E J E | E. \<forall>i\<in>I. E i \<in> sets (M i)}"
    49 proof (safe intro!: Int_stableI)
    50   fix E F assume "\<forall>i\<in>I. E i \<in> sets (M i)" "\<forall>i\<in>I. F i \<in> sets (M i)"
    51   then show "\<exists>G. Pi\<^isub>E J E \<inter> Pi\<^isub>E J F = Pi\<^isub>E J G \<and> (\<forall>i\<in>I. G i \<in> sets (M i))"
    52     by (auto intro!: exI[of _ "\<lambda>i. E i \<inter> F i"])
    53 qed
    55 lemma prod_emb_trans[simp]:
    56   "J \<subseteq> K \<Longrightarrow> K \<subseteq> L \<Longrightarrow> prod_emb L M K (prod_emb K M J X) = prod_emb L M J X"
    57   by (auto simp add: Int_absorb1 prod_emb_def)
    59 lemma prod_emb_Pi:
    60   assumes "X \<in> (\<Pi> j\<in>J. sets (M j))" "J \<subseteq> K"
    61   shows "prod_emb K M J (Pi\<^isub>E J X) = (\<Pi>\<^isub>E i\<in>K. if i \<in> J then X i else space (M i))"
    62   using assms space_closed
    63   by (auto simp: prod_emb_def Pi_iff split: split_if_asm) blast+
    65 lemma prod_emb_id:
    66   "B \<subseteq> (\<Pi>\<^isub>E i\<in>L. space (M i)) \<Longrightarrow> prod_emb L M L B = B"
    67   by (auto simp: prod_emb_def Pi_iff subset_eq extensional_restrict)
    69 lemma measurable_prod_emb[intro, simp]:
    70   "J \<subseteq> L \<Longrightarrow> X \<in> sets (Pi\<^isub>M J M) \<Longrightarrow> prod_emb L M J X \<in> sets (Pi\<^isub>M L M)"
    71   unfolding prod_emb_def space_PiM[symmetric]
    72   by (auto intro!: measurable_sets measurable_restrict measurable_component_singleton)
    74 lemma measurable_restrict_subset: "J \<subseteq> L \<Longrightarrow> (\<lambda>f. restrict f J) \<in> measurable (Pi\<^isub>M L M) (Pi\<^isub>M J M)"
    75   by (intro measurable_restrict measurable_component_singleton) auto
    77 lemma (in product_prob_space) distr_restrict:
    78   assumes "J \<noteq> {}" "J \<subseteq> K" "finite K"
    79   shows "(\<Pi>\<^isub>M i\<in>J. M i) = distr (\<Pi>\<^isub>M i\<in>K. M i) (\<Pi>\<^isub>M i\<in>J. M i) (\<lambda>f. restrict f J)" (is "?P = ?D")
    80 proof (rule measure_eqI_generator_eq)
    81   have "finite J" using `J \<subseteq> K` `finite K` by (auto simp add: finite_subset)
    82   interpret J: finite_product_prob_space M J proof qed fact
    83   interpret K: finite_product_prob_space M K proof qed fact
    85   let ?J = "{Pi\<^isub>E J E | E. \<forall>i\<in>J. E i \<in> sets (M i)}"
    86   let ?F = "\<lambda>i. \<Pi>\<^isub>E k\<in>J. space (M k)"
    87   let ?\<Omega> = "(\<Pi>\<^isub>E k\<in>J. space (M k))"
    88   show "Int_stable ?J"
    89     by (rule Int_stable_PiE)
    90   show "range ?F \<subseteq> ?J" "(\<Union>i. ?F i) = ?\<Omega>"
    91     using `finite J` by (auto intro!: prod_algebraI_finite)
    92   { fix i show "emeasure ?P (?F i) \<noteq> \<infinity>" by simp }
    93   show "?J \<subseteq> Pow ?\<Omega>" by (auto simp: Pi_iff dest: sets_into_space)
    94   show "sets (\<Pi>\<^isub>M i\<in>J. M i) = sigma_sets ?\<Omega> ?J" "sets ?D = sigma_sets ?\<Omega> ?J"
    95     using `finite J` by (simp_all add: sets_PiM prod_algebra_eq_finite Pi_iff)
    97   fix X assume "X \<in> ?J"
    98   then obtain E where [simp]: "X = Pi\<^isub>E J E" and E: "\<forall>i\<in>J. E i \<in> sets (M i)" by auto
    99   with `finite J` have X: "X \<in> sets (Pi\<^isub>M J M)" by auto
   101   have "emeasure ?P X = (\<Prod> i\<in>J. emeasure (M i) (E i))"
   102     using E by (simp add: J.measure_times)
   103   also have "\<dots> = (\<Prod> i\<in>J. emeasure (M i) (if i \<in> J then E i else space (M i)))"
   104     by simp
   105   also have "\<dots> = (\<Prod> i\<in>K. emeasure (M i) (if i \<in> J then E i else space (M i)))"
   106     using `finite K` `J \<subseteq> K`
   107     by (intro setprod_mono_one_left) (auto simp: M.emeasure_space_1)
   108   also have "\<dots> = emeasure (Pi\<^isub>M K M) (\<Pi>\<^isub>E i\<in>K. if i \<in> J then E i else space (M i))"
   109     using E by (simp add: K.measure_times)
   110   also have "(\<Pi>\<^isub>E i\<in>K. if i \<in> J then E i else space (M i)) = (\<lambda>f. restrict f J) -` Pi\<^isub>E J E \<inter> (\<Pi>\<^isub>E i\<in>K. space (M i))"
   111     using `J \<subseteq> K` sets_into_space E by (force simp:  Pi_iff split: split_if_asm)
   112   finally show "emeasure (Pi\<^isub>M J M) X = emeasure ?D X"
   113     using X `J \<subseteq> K` apply (subst emeasure_distr)
   114     by (auto intro!: measurable_restrict_subset simp: space_PiM)
   115 qed
   117 abbreviation (in product_prob_space)
   118   "emb L K X \<equiv> prod_emb L M K X"
   120 lemma (in product_prob_space) emeasure_prod_emb[simp]:
   121   assumes L: "J \<noteq> {}" "J \<subseteq> L" "finite L" and X: "X \<in> sets (Pi\<^isub>M J M)"
   122   shows "emeasure (Pi\<^isub>M L M) (emb L J X) = emeasure (Pi\<^isub>M J M) X"
   123   by (subst distr_restrict[OF L])
   124      (simp add: prod_emb_def space_PiM emeasure_distr measurable_restrict_subset L X)
   126 lemma (in product_prob_space) prod_emb_injective:
   127   assumes "J \<noteq> {}" "J \<subseteq> L" "finite J" and sets: "X \<in> sets (Pi\<^isub>M J M)" "Y \<in> sets (Pi\<^isub>M J M)"
   128   assumes "prod_emb L M J X = prod_emb L M J Y"
   129   shows "X = Y"
   130 proof (rule injective_vimage_restrict)
   131   show "X \<subseteq> (\<Pi>\<^isub>E i\<in>J. space (M i))" "Y \<subseteq> (\<Pi>\<^isub>E i\<in>J. space (M i))"
   132     using sets[THEN sets_into_space] by (auto simp: space_PiM)
   133   have "\<forall>i\<in>L. \<exists>x. x \<in> space (M i)"
   134       using M.not_empty by auto
   135   from bchoice[OF this]
   136   show "(\<Pi>\<^isub>E i\<in>L. space (M i)) \<noteq> {}" by auto
   137   show "(\<lambda>x. restrict x J) -` X \<inter> (\<Pi>\<^isub>E i\<in>L. space (M i)) = (\<lambda>x. restrict x J) -` Y \<inter> (\<Pi>\<^isub>E i\<in>L. space (M i))"
   138     using `prod_emb L M J X = prod_emb L M J Y` by (simp add: prod_emb_def)
   139 qed fact
   141 definition (in product_prob_space) generator :: "('i \<Rightarrow> 'a) set set" where
   142   "generator = (\<Union>J\<in>{J. J \<noteq> {} \<and> finite J \<and> J \<subseteq> I}. emb I J ` sets (Pi\<^isub>M J M))"
   144 lemma (in product_prob_space) generatorI':
   145   "J \<noteq> {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> X \<in> sets (Pi\<^isub>M J M) \<Longrightarrow> emb I J X \<in> generator"
   146   unfolding generator_def by auto
   148 lemma (in product_prob_space) algebra_generator:
   149   assumes "I \<noteq> {}" shows "algebra (\<Pi>\<^isub>E i\<in>I. space (M i)) generator" (is "algebra ?\<Omega> ?G")
   150   unfolding algebra_def algebra_axioms_def ring_of_sets_iff
   151 proof (intro conjI ballI)
   152   let ?G = generator
   153   show "?G \<subseteq> Pow ?\<Omega>"
   154     by (auto simp: generator_def prod_emb_def)
   155   from `I \<noteq> {}` obtain i where "i \<in> I" by auto
   156   then show "{} \<in> ?G"
   157     by (auto intro!: exI[of _ "{i}"] image_eqI[where x="\<lambda>i. {}"]
   158              simp: sigma_sets.Empty generator_def prod_emb_def)
   159   from `i \<in> I` show "?\<Omega> \<in> ?G"
   160     by (auto intro!: exI[of _ "{i}"] image_eqI[where x="Pi\<^isub>E {i} (\<lambda>i. space (M i))"]
   161              simp: generator_def prod_emb_def)
   162   fix A assume "A \<in> ?G"
   163   then obtain JA XA where XA: "JA \<noteq> {}" "finite JA" "JA \<subseteq> I" "XA \<in> sets (Pi\<^isub>M JA M)" and A: "A = emb I JA XA"
   164     by (auto simp: generator_def)
   165   fix B assume "B \<in> ?G"
   166   then obtain JB XB where XB: "JB \<noteq> {}" "finite JB" "JB \<subseteq> I" "XB \<in> sets (Pi\<^isub>M JB M)" and B: "B = emb I JB XB"
   167     by (auto simp: generator_def)
   168   let ?RA = "emb (JA \<union> JB) JA XA"
   169   let ?RB = "emb (JA \<union> JB) JB XB"
   170   have *: "A - B = emb I (JA \<union> JB) (?RA - ?RB)" "A \<union> B = emb I (JA \<union> JB) (?RA \<union> ?RB)"
   171     using XA A XB B by auto
   172   show "A - B \<in> ?G" "A \<union> B \<in> ?G"
   173     unfolding * using XA XB by (safe intro!: generatorI') auto
   174 qed
   176 lemma (in product_prob_space) sets_PiM_generator:
   177   assumes "I \<noteq> {}" shows "sets (PiM I M) = sigma_sets (\<Pi>\<^isub>E i\<in>I. space (M i)) generator"
   178 proof
   179   show "sets (Pi\<^isub>M I M) \<subseteq> sigma_sets (\<Pi>\<^isub>E i\<in>I. space (M i)) generator"
   180     unfolding sets_PiM
   181   proof (safe intro!: sigma_sets_subseteq)
   182     fix A assume "A \<in> prod_algebra I M" with `I \<noteq> {}` show "A \<in> generator"
   183       by (auto intro!: generatorI' elim!: prod_algebraE)
   184   qed
   185 qed (auto simp: generator_def space_PiM[symmetric] intro!: sigma_sets_subset)
   187 lemma (in product_prob_space) generatorI:
   188   "J \<noteq> {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> X \<in> sets (Pi\<^isub>M J M) \<Longrightarrow> A = emb I J X \<Longrightarrow> A \<in> generator"
   189   unfolding generator_def by auto
   191 definition (in product_prob_space)
   192   "\<mu>G A =
   193     (THE x. \<forall>J. J \<noteq> {} \<longrightarrow> finite J \<longrightarrow> J \<subseteq> I \<longrightarrow> (\<forall>X\<in>sets (Pi\<^isub>M J M). A = emb I J X \<longrightarrow> x = emeasure (Pi\<^isub>M J M) X))"
   195 lemma (in product_prob_space) \<mu>G_spec:
   196   assumes J: "J \<noteq> {}" "finite J" "J \<subseteq> I" "A = emb I J X" "X \<in> sets (Pi\<^isub>M J M)"
   197   shows "\<mu>G A = emeasure (Pi\<^isub>M J M) X"
   198   unfolding \<mu>G_def
   199 proof (intro the_equality allI impI ballI)
   200   fix K Y assume K: "K \<noteq> {}" "finite K" "K \<subseteq> I" "A = emb I K Y" "Y \<in> sets (Pi\<^isub>M K M)"
   201   have "emeasure (Pi\<^isub>M K M) Y = emeasure (Pi\<^isub>M (K \<union> J) M) (emb (K \<union> J) K Y)"
   202     using K J by simp
   203   also have "emb (K \<union> J) K Y = emb (K \<union> J) J X"
   204     using K J by (simp add: prod_emb_injective[of "K \<union> J" I])
   205   also have "emeasure (Pi\<^isub>M (K \<union> J) M) (emb (K \<union> J) J X) = emeasure (Pi\<^isub>M J M) X"
   206     using K J by simp
   207   finally show "emeasure (Pi\<^isub>M J M) X = emeasure (Pi\<^isub>M K M) Y" ..
   208 qed (insert J, force)
   210 lemma (in product_prob_space) \<mu>G_eq:
   211   "J \<noteq> {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> X \<in> sets (Pi\<^isub>M J M) \<Longrightarrow> \<mu>G (emb I J X) = emeasure (Pi\<^isub>M J M) X"
   212   by (intro \<mu>G_spec) auto
   214 lemma (in product_prob_space) generator_Ex:
   215   assumes *: "A \<in> generator"
   216   shows "\<exists>J X. J \<noteq> {} \<and> finite J \<and> J \<subseteq> I \<and> X \<in> sets (Pi\<^isub>M J M) \<and> A = emb I J X \<and> \<mu>G A = emeasure (Pi\<^isub>M J M) X"
   217 proof -
   218   from * obtain J X where J: "J \<noteq> {}" "finite J" "J \<subseteq> I" "A = emb I J X" "X \<in> sets (Pi\<^isub>M J M)"
   219     unfolding generator_def by auto
   220   with \<mu>G_spec[OF this] show ?thesis by auto
   221 qed
   223 lemma (in product_prob_space) generatorE:
   224   assumes A: "A \<in> generator"
   225   obtains J X where "J \<noteq> {}" "finite J" "J \<subseteq> I" "X \<in> sets (Pi\<^isub>M J M)" "emb I J X = A" "\<mu>G A = emeasure (Pi\<^isub>M J M) X"
   226 proof -
   227   from generator_Ex[OF A] obtain X J where "J \<noteq> {}" "finite J" "J \<subseteq> I" "X \<in> sets (Pi\<^isub>M J M)" "emb I J X = A"
   228     "\<mu>G A = emeasure (Pi\<^isub>M J M) X" by auto
   229   then show thesis by (intro that) auto
   230 qed
   232 lemma (in product_prob_space) merge_sets:
   233   assumes "J \<inter> K = {}" and A: "A \<in> sets (Pi\<^isub>M (J \<union> K) M)" and x: "x \<in> space (Pi\<^isub>M J M)"
   234   shows "(\<lambda>y. merge J K (x,y)) -` A \<inter> space (Pi\<^isub>M K M) \<in> sets (Pi\<^isub>M K M)"
   235   by (rule measurable_sets[OF _ A] measurable_compose[OF measurable_Pair measurable_merge]  
   236            measurable_const x measurable_ident)+
   238 lemma (in product_prob_space) merge_emb:
   239   assumes "K \<subseteq> I" "J \<subseteq> I" and y: "y \<in> space (Pi\<^isub>M J M)"
   240   shows "((\<lambda>x. merge J (I - J) (y, x)) -` emb I K X \<inter> space (Pi\<^isub>M I M)) =
   241     emb I (K - J) ((\<lambda>x. merge J (K - J) (y, x)) -` emb (J \<union> K) K X \<inter> space (Pi\<^isub>M (K - J) M))"
   242 proof -
   243   have [simp]: "\<And>x J K L. merge J K (y, restrict x L) = merge J (K \<inter> L) (y, x)"
   244     by (auto simp: restrict_def merge_def)
   245   have [simp]: "\<And>x J K L. restrict (merge J K (y, x)) L = merge (J \<inter> L) (K \<inter> L) (y, x)"
   246     by (auto simp: restrict_def merge_def)
   247   have [simp]: "(I - J) \<inter> K = K - J" using `K \<subseteq> I` `J \<subseteq> I` by auto
   248   have [simp]: "(K - J) \<inter> (K \<union> J) = K - J" by auto
   249   have [simp]: "(K - J) \<inter> K = K - J" by auto
   250   from y `K \<subseteq> I` `J \<subseteq> I` show ?thesis
   251     by (simp split: split_merge add: prod_emb_def Pi_iff extensional_merge_sub set_eq_iff space_PiM)
   252        auto
   253 qed
   255 lemma (in product_prob_space) positive_\<mu>G: 
   256   assumes "I \<noteq> {}"
   257   shows "positive generator \<mu>G"
   258 proof -
   259   interpret G!: algebra "\<Pi>\<^isub>E i\<in>I. space (M i)" generator by (rule algebra_generator) fact
   260   show ?thesis
   261   proof (intro positive_def[THEN iffD2] conjI ballI)
   262     from generatorE[OF G.empty_sets] guess J X . note this[simp]
   263     interpret J: finite_product_sigma_finite M J by default fact
   264     have "X = {}"
   265       by (rule prod_emb_injective[of J I]) simp_all
   266     then show "\<mu>G {} = 0" by simp
   267   next
   268     fix A assume "A \<in> generator"
   269     from generatorE[OF this] guess J X . note this[simp]
   270     interpret J: finite_product_sigma_finite M J by default fact
   271     show "0 \<le> \<mu>G A" by (simp add: emeasure_nonneg)
   272   qed
   273 qed
   275 lemma (in product_prob_space) additive_\<mu>G: 
   276   assumes "I \<noteq> {}"
   277   shows "additive generator \<mu>G"
   278 proof -
   279   interpret G!: algebra "\<Pi>\<^isub>E i\<in>I. space (M i)" generator by (rule algebra_generator) fact
   280   show ?thesis
   281   proof (intro additive_def[THEN iffD2] ballI impI)
   282     fix A assume "A \<in> generator" with generatorE guess J X . note J = this
   283     fix B assume "B \<in> generator" with generatorE guess K Y . note K = this
   284     assume "A \<inter> B = {}"
   285     have JK: "J \<union> K \<noteq> {}" "J \<union> K \<subseteq> I" "finite (J \<union> K)"
   286       using J K by auto
   287     interpret JK: finite_product_sigma_finite M "J \<union> K" by default fact
   288     have JK_disj: "emb (J \<union> K) J X \<inter> emb (J \<union> K) K Y = {}"
   289       apply (rule prod_emb_injective[of "J \<union> K" I])
   290       apply (insert `A \<inter> B = {}` JK J K)
   291       apply (simp_all add: Int prod_emb_Int)
   292       done
   293     have AB: "A = emb I (J \<union> K) (emb (J \<union> K) J X)" "B = emb I (J \<union> K) (emb (J \<union> K) K Y)"
   294       using J K by simp_all
   295     then have "\<mu>G (A \<union> B) = \<mu>G (emb I (J \<union> K) (emb (J \<union> K) J X \<union> emb (J \<union> K) K Y))"
   296       by simp
   297     also have "\<dots> = emeasure (Pi\<^isub>M (J \<union> K) M) (emb (J \<union> K) J X \<union> emb (J \<union> K) K Y)"
   298       using JK J(1, 4) K(1, 4) by (simp add: \<mu>G_eq Un del: prod_emb_Un)
   299     also have "\<dots> = \<mu>G A + \<mu>G B"
   300       using J K JK_disj by (simp add: plus_emeasure[symmetric])
   301     finally show "\<mu>G (A \<union> B) = \<mu>G A + \<mu>G B" .
   302   qed
   303 qed
   305 lemma (in product_prob_space) emeasure_PiM_emb_not_empty:
   306   assumes X: "J \<noteq> {}" "J \<subseteq> I" "finite J" "\<forall>i\<in>J. X i \<in> sets (M i)"
   307   shows "emeasure (Pi\<^isub>M I M) (emb I J (Pi\<^isub>E J X)) = emeasure (Pi\<^isub>M J M) (Pi\<^isub>E J X)"
   308 proof cases
   309   assume "finite I" with X show ?thesis by simp
   310 next
   311   let ?\<Omega> = "\<Pi>\<^isub>E i\<in>I. space (M i)"
   312   let ?G = generator
   313   assume "\<not> finite I"
   314   then have I_not_empty: "I \<noteq> {}" by auto
   315   interpret G!: algebra ?\<Omega> generator by (rule algebra_generator) fact
   316   note \<mu>G_mono =
   317     G.additive_increasing[OF positive_\<mu>G[OF I_not_empty] additive_\<mu>G[OF I_not_empty], THEN increasingD]
   319   { fix Z J assume J: "J \<noteq> {}" "finite J" "J \<subseteq> I" and Z: "Z \<in> ?G"
   321     from `infinite I` `finite J` obtain k where k: "k \<in> I" "k \<notin> J"
   322       by (metis rev_finite_subset subsetI)
   323     moreover from Z guess K' X' by (rule generatorE)
   324     moreover def K \<equiv> "insert k K'"
   325     moreover def X \<equiv> "emb K K' X'"
   326     ultimately have K: "K \<noteq> {}" "finite K" "K \<subseteq> I" "X \<in> sets (Pi\<^isub>M K M)" "Z = emb I K X"
   327       "K - J \<noteq> {}" "K - J \<subseteq> I" "\<mu>G Z = emeasure (Pi\<^isub>M K M) X"
   328       by (auto simp: subset_insertI)
   330     let ?M = "\<lambda>y. (\<lambda>x. merge J (K - J) (y, x)) -` emb (J \<union> K) K X \<inter> space (Pi\<^isub>M (K - J) M)"
   331     { fix y assume y: "y \<in> space (Pi\<^isub>M J M)"
   332       note * = merge_emb[OF `K \<subseteq> I` `J \<subseteq> I` y, of X]
   333       moreover
   334       have **: "?M y \<in> sets (Pi\<^isub>M (K - J) M)"
   335         using J K y by (intro merge_sets) auto
   336       ultimately
   337       have ***: "((\<lambda>x. merge J (I - J) (y, x)) -` Z \<inter> space (Pi\<^isub>M I M)) \<in> ?G"
   338         using J K by (intro generatorI) auto
   339       have "\<mu>G ((\<lambda>x. merge J (I - J) (y, x)) -` emb I K X \<inter> space (Pi\<^isub>M I M)) = emeasure (Pi\<^isub>M (K - J) M) (?M y)"
   340         unfolding * using K J by (subst \<mu>G_eq[OF _ _ _ **]) auto
   341       note * ** *** this }
   342     note merge_in_G = this
   344     have "finite (K - J)" using K by auto
   346     interpret J: finite_product_prob_space M J by default fact+
   347     interpret KmJ: finite_product_prob_space M "K - J" by default fact+
   349     have "\<mu>G Z = emeasure (Pi\<^isub>M (J \<union> (K - J)) M) (emb (J \<union> (K - J)) K X)"
   350       using K J by simp
   351     also have "\<dots> = (\<integral>\<^isup>+ x. emeasure (Pi\<^isub>M (K - J) M) (?M x) \<partial>Pi\<^isub>M J M)"
   352       using K J by (subst emeasure_fold_integral) auto
   353     also have "\<dots> = (\<integral>\<^isup>+ y. \<mu>G ((\<lambda>x. merge J (I - J) (y, x)) -` Z \<inter> space (Pi\<^isub>M I M)) \<partial>Pi\<^isub>M J M)"
   354       (is "_ = (\<integral>\<^isup>+x. \<mu>G (?MZ x) \<partial>Pi\<^isub>M J M)")
   355     proof (intro positive_integral_cong)
   356       fix x assume x: "x \<in> space (Pi\<^isub>M J M)"
   357       with K merge_in_G(2)[OF this]
   358       show "emeasure (Pi\<^isub>M (K - J) M) (?M x) = \<mu>G (?MZ x)"
   359         unfolding `Z = emb I K X` merge_in_G(1)[OF x] by (subst \<mu>G_eq) auto
   360     qed
   361     finally have fold: "\<mu>G Z = (\<integral>\<^isup>+x. \<mu>G (?MZ x) \<partial>Pi\<^isub>M J M)" .
   363     { fix x assume x: "x \<in> space (Pi\<^isub>M J M)"
   364       then have "\<mu>G (?MZ x) \<le> 1"
   365         unfolding merge_in_G(4)[OF x] `Z = emb I K X`
   366         by (intro KmJ.measure_le_1 merge_in_G(2)[OF x]) }
   367     note le_1 = this
   369     let ?q = "\<lambda>y. \<mu>G ((\<lambda>x. merge J (I - J) (y,x)) -` Z \<inter> space (Pi\<^isub>M I M))"
   370     have "?q \<in> borel_measurable (Pi\<^isub>M J M)"
   371       unfolding `Z = emb I K X` using J K merge_in_G(3)
   372       by (simp add: merge_in_G  \<mu>G_eq emeasure_fold_measurable cong: measurable_cong)
   373     note this fold le_1 merge_in_G(3) }
   374   note fold = this
   376   have "\<exists>\<mu>. (\<forall>s\<in>?G. \<mu> s = \<mu>G s) \<and> measure_space ?\<Omega> (sigma_sets ?\<Omega> ?G) \<mu>"
   377   proof (rule G.caratheodory_empty_continuous[OF positive_\<mu>G additive_\<mu>G])
   378     fix A assume "A \<in> ?G"
   379     with generatorE guess J X . note JX = this
   380     interpret JK: finite_product_prob_space M J by default fact+
   381     from JX show "\<mu>G A \<noteq> \<infinity>" by simp
   382   next
   383     fix A assume A: "range A \<subseteq> ?G" "decseq A" "(\<Inter>i. A i) = {}"
   384     then have "decseq (\<lambda>i. \<mu>G (A i))"
   385       by (auto intro!: \<mu>G_mono simp: decseq_def)
   386     moreover
   387     have "(INF i. \<mu>G (A i)) = 0"
   388     proof (rule ccontr)
   389       assume "(INF i. \<mu>G (A i)) \<noteq> 0" (is "?a \<noteq> 0")
   390       moreover have "0 \<le> ?a"
   391         using A positive_\<mu>G[OF I_not_empty] by (auto intro!: INF_greatest simp: positive_def)
   392       ultimately have "0 < ?a" by auto
   394       have "\<forall>n. \<exists>J X. J \<noteq> {} \<and> finite J \<and> J \<subseteq> I \<and> X \<in> sets (Pi\<^isub>M J M) \<and> A n = emb I J X \<and> \<mu>G (A n) = emeasure (Pi\<^isub>M J M) X"
   395         using A by (intro allI generator_Ex) auto
   396       then obtain J' X' where J': "\<And>n. J' n \<noteq> {}" "\<And>n. finite (J' n)" "\<And>n. J' n \<subseteq> I" "\<And>n. X' n \<in> sets (Pi\<^isub>M (J' n) M)"
   397         and A': "\<And>n. A n = emb I (J' n) (X' n)"
   398         unfolding choice_iff by blast
   399       moreover def J \<equiv> "\<lambda>n. (\<Union>i\<le>n. J' i)"
   400       moreover def X \<equiv> "\<lambda>n. emb (J n) (J' n) (X' n)"
   401       ultimately have J: "\<And>n. J n \<noteq> {}" "\<And>n. finite (J n)" "\<And>n. J n \<subseteq> I" "\<And>n. X n \<in> sets (Pi\<^isub>M (J n) M)"
   402         by auto
   403       with A' have A_eq: "\<And>n. A n = emb I (J n) (X n)" "\<And>n. A n \<in> ?G"
   404         unfolding J_def X_def by (subst prod_emb_trans) (insert A, auto)
   406       have J_mono: "\<And>n m. n \<le> m \<Longrightarrow> J n \<subseteq> J m"
   407         unfolding J_def by force
   409       interpret J: finite_product_prob_space M "J i" for i by default fact+
   411       have a_le_1: "?a \<le> 1"
   412         using \<mu>G_spec[of "J 0" "A 0" "X 0"] J A_eq
   413         by (auto intro!: INF_lower2[of 0] J.measure_le_1)
   415       let ?M = "\<lambda>K Z y. (\<lambda>x. merge K (I - K) (y, x)) -` Z \<inter> space (Pi\<^isub>M I M)"
   417       { fix Z k assume Z: "range Z \<subseteq> ?G" "decseq Z" "\<forall>n. ?a / 2^k \<le> \<mu>G (Z n)"
   418         then have Z_sets: "\<And>n. Z n \<in> ?G" by auto
   419         fix J' assume J': "J' \<noteq> {}" "finite J'" "J' \<subseteq> I"
   420         interpret J': finite_product_prob_space M J' by default fact+
   422         let ?q = "\<lambda>n y. \<mu>G (?M J' (Z n) y)"
   423         let ?Q = "\<lambda>n. ?q n -` {?a / 2^(k+1) ..} \<inter> space (Pi\<^isub>M J' M)"
   424         { fix n
   425           have "?q n \<in> borel_measurable (Pi\<^isub>M J' M)"
   426             using Z J' by (intro fold(1)) auto
   427           then have "?Q n \<in> sets (Pi\<^isub>M J' M)"
   428             by (rule measurable_sets) auto }
   429         note Q_sets = this
   431         have "?a / 2^(k+1) \<le> (INF n. emeasure (Pi\<^isub>M J' M) (?Q n))"
   432         proof (intro INF_greatest)
   433           fix n
   434           have "?a / 2^k \<le> \<mu>G (Z n)" using Z by auto
   435           also have "\<dots> \<le> (\<integral>\<^isup>+ x. indicator (?Q n) x + ?a / 2^(k+1) \<partial>Pi\<^isub>M J' M)"
   436             unfolding fold(2)[OF J' `Z n \<in> ?G`]
   437           proof (intro positive_integral_mono)
   438             fix x assume x: "x \<in> space (Pi\<^isub>M J' M)"
   439             then have "?q n x \<le> 1 + 0"
   440               using J' Z fold(3) Z_sets by auto
   441             also have "\<dots> \<le> 1 + ?a / 2^(k+1)"
   442               using `0 < ?a` by (intro add_mono) auto
   443             finally have "?q n x \<le> 1 + ?a / 2^(k+1)" .
   444             with x show "?q n x \<le> indicator (?Q n) x + ?a / 2^(k+1)"
   445               by (auto split: split_indicator simp del: power_Suc)
   446           qed
   447           also have "\<dots> = emeasure (Pi\<^isub>M J' M) (?Q n) + ?a / 2^(k+1)"
   448             using `0 \<le> ?a` Q_sets J'.emeasure_space_1
   449             by (subst positive_integral_add) auto
   450           finally show "?a / 2^(k+1) \<le> emeasure (Pi\<^isub>M J' M) (?Q n)" using `?a \<le> 1`
   451             by (cases rule: ereal2_cases[of ?a "emeasure (Pi\<^isub>M J' M) (?Q n)"])
   452                (auto simp: field_simps)
   453         qed
   454         also have "\<dots> = emeasure (Pi\<^isub>M J' M) (\<Inter>n. ?Q n)"
   455         proof (intro INF_emeasure_decseq)
   456           show "range ?Q \<subseteq> sets (Pi\<^isub>M J' M)" using Q_sets by auto
   457           show "decseq ?Q"
   458             unfolding decseq_def
   459           proof (safe intro!: vimageI[OF refl])
   460             fix m n :: nat assume "m \<le> n"
   461             fix x assume x: "x \<in> space (Pi\<^isub>M J' M)"
   462             assume "?a / 2^(k+1) \<le> ?q n x"
   463             also have "?q n x \<le> ?q m x"
   464             proof (rule \<mu>G_mono)
   465               from fold(4)[OF J', OF Z_sets x]
   466               show "?M J' (Z n) x \<in> ?G" "?M J' (Z m) x \<in> ?G" by auto
   467               show "?M J' (Z n) x \<subseteq> ?M J' (Z m) x"
   468                 using `decseq Z`[THEN decseqD, OF `m \<le> n`] by auto
   469             qed
   470             finally show "?a / 2^(k+1) \<le> ?q m x" .
   471           qed
   472         qed simp
   473         finally have "(\<Inter>n. ?Q n) \<noteq> {}"
   474           using `0 < ?a` `?a \<le> 1` by (cases ?a) (auto simp: divide_le_0_iff power_le_zero_eq)
   475         then have "\<exists>w\<in>space (Pi\<^isub>M J' M). \<forall>n. ?a / 2 ^ (k + 1) \<le> ?q n w" by auto }
   476       note Ex_w = this
   478       let ?q = "\<lambda>k n y. \<mu>G (?M (J k) (A n) y)"
   480       have "\<forall>n. ?a / 2 ^ 0 \<le> \<mu>G (A n)" by (auto intro: INF_lower)
   481       from Ex_w[OF A(1,2) this J(1-3), of 0] guess w0 .. note w0 = this
   483       let ?P =
   484         "\<lambda>k wk w. w \<in> space (Pi\<^isub>M (J (Suc k)) M) \<and> restrict w (J k) = wk \<and>
   485           (\<forall>n. ?a / 2 ^ (Suc k + 1) \<le> ?q (Suc k) n w)"
   486       def w \<equiv> "nat_rec w0 (\<lambda>k wk. Eps (?P k wk))"
   488       { fix k have w: "w k \<in> space (Pi\<^isub>M (J k) M) \<and>
   489           (\<forall>n. ?a / 2 ^ (k + 1) \<le> ?q k n (w k)) \<and> (k \<noteq> 0 \<longrightarrow> restrict (w k) (J (k - 1)) = w (k - 1))"
   490         proof (induct k)
   491           case 0 with w0 show ?case
   492             unfolding w_def nat_rec_0 by auto
   493         next
   494           case (Suc k)
   495           then have wk: "w k \<in> space (Pi\<^isub>M (J k) M)" by auto
   496           have "\<exists>w'. ?P k (w k) w'"
   497           proof cases
   498             assume [simp]: "J k = J (Suc k)"
   499             show ?thesis
   500             proof (intro exI[of _ "w k"] conjI allI)
   501               fix n
   502               have "?a / 2 ^ (Suc k + 1) \<le> ?a / 2 ^ (k + 1)"
   503                 using `0 < ?a` `?a \<le> 1` by (cases ?a) (auto simp: field_simps)
   504               also have "\<dots> \<le> ?q k n (w k)" using Suc by auto
   505               finally show "?a / 2 ^ (Suc k + 1) \<le> ?q (Suc k) n (w k)" by simp
   506             next
   507               show "w k \<in> space (Pi\<^isub>M (J (Suc k)) M)"
   508                 using Suc by simp
   509               then show "restrict (w k) (J k) = w k"
   510                 by (simp add: extensional_restrict space_PiM)
   511             qed
   512           next
   513             assume "J k \<noteq> J (Suc k)"
   514             with J_mono[of k "Suc k"] have "J (Suc k) - J k \<noteq> {}" (is "?D \<noteq> {}") by auto
   515             have "range (\<lambda>n. ?M (J k) (A n) (w k)) \<subseteq> ?G"
   516               "decseq (\<lambda>n. ?M (J k) (A n) (w k))"
   517               "\<forall>n. ?a / 2 ^ (k + 1) \<le> \<mu>G (?M (J k) (A n) (w k))"
   518               using `decseq A` fold(4)[OF J(1-3) A_eq(2), of "w k" k] Suc
   519               by (auto simp: decseq_def)
   520             from Ex_w[OF this `?D \<noteq> {}`] J[of "Suc k"]
   521             obtain w' where w': "w' \<in> space (Pi\<^isub>M ?D M)"
   522               "\<forall>n. ?a / 2 ^ (Suc k + 1) \<le> \<mu>G (?M ?D (?M (J k) (A n) (w k)) w')" by auto
   523             let ?w = "merge (J k) ?D (w k, w')"
   524             have [simp]: "\<And>x. merge (J k) (I - J k) (w k, merge ?D (I - ?D) (w', x)) =
   525               merge (J (Suc k)) (I - (J (Suc k))) (?w, x)"
   526               using J(3)[of "Suc k"] J(3)[of k] J_mono[of k "Suc k"]
   527               by (auto intro!: ext split: split_merge)
   528             have *: "\<And>n. ?M ?D (?M (J k) (A n) (w k)) w' = ?M (J (Suc k)) (A n) ?w"
   529               using w'(1) J(3)[of "Suc k"]
   530               by (auto simp: space_PiM split: split_merge intro!: extensional_merge_sub) force+
   531             show ?thesis
   532               apply (rule exI[of _ ?w])
   533               using w' J_mono[of k "Suc k"] wk unfolding *
   534               apply (auto split: split_merge intro!: extensional_merge_sub ext simp: space_PiM)
   535               apply (force simp: extensional_def)
   536               done
   537           qed
   538           then have "?P k (w k) (w (Suc k))"
   539             unfolding w_def nat_rec_Suc unfolding w_def[symmetric]
   540             by (rule someI_ex)
   541           then show ?case by auto
   542         qed
   543         moreover
   544         then have "w k \<in> space (Pi\<^isub>M (J k) M)" by auto
   545         moreover
   546         from w have "?a / 2 ^ (k + 1) \<le> ?q k k (w k)" by auto
   547         then have "?M (J k) (A k) (w k) \<noteq> {}"
   548           using positive_\<mu>G[OF I_not_empty, unfolded positive_def] `0 < ?a` `?a \<le> 1`
   549           by (cases ?a) (auto simp: divide_le_0_iff power_le_zero_eq)
   550         then obtain x where "x \<in> ?M (J k) (A k) (w k)" by auto
   551         then have "merge (J k) (I - J k) (w k, x) \<in> A k" by auto
   552         then have "\<exists>x\<in>A k. restrict x (J k) = w k"
   553           using `w k \<in> space (Pi\<^isub>M (J k) M)`
   554           by (intro rev_bexI) (auto intro!: ext simp: extensional_def space_PiM)
   555         ultimately have "w k \<in> space (Pi\<^isub>M (J k) M)"
   556           "\<exists>x\<in>A k. restrict x (J k) = w k"
   557           "k \<noteq> 0 \<Longrightarrow> restrict (w k) (J (k - 1)) = w (k - 1)"
   558           by auto }
   559       note w = this
   561       { fix k l i assume "k \<le> l" "i \<in> J k"
   562         { fix l have "w k i = w (k + l) i"
   563           proof (induct l)
   564             case (Suc l)
   565             from `i \<in> J k` J_mono[of k "k + l"] have "i \<in> J (k + l)" by auto
   566             with w(3)[of "k + Suc l"]
   567             have "w (k + l) i = w (k + Suc l) i"
   568               by (auto simp: restrict_def fun_eq_iff split: split_if_asm)
   569             with Suc show ?case by simp
   570           qed simp }
   571         from this[of "l - k"] `k \<le> l` have "w l i = w k i" by simp }
   572       note w_mono = this
   574       def w' \<equiv> "\<lambda>i. if i \<in> (\<Union>k. J k) then w (LEAST k. i \<in> J k) i else if i \<in> I then (SOME x. x \<in> space (M i)) else undefined"
   575       { fix i k assume k: "i \<in> J k"
   576         have "w k i = w (LEAST k. i \<in> J k) i"
   577           by (intro w_mono Least_le k LeastI[of _ k])
   578         then have "w' i = w k i"
   579           unfolding w'_def using k by auto }
   580       note w'_eq = this
   581       have w'_simps1: "\<And>i. i \<notin> I \<Longrightarrow> w' i = undefined"
   582         using J by (auto simp: w'_def)
   583       have w'_simps2: "\<And>i. i \<notin> (\<Union>k. J k) \<Longrightarrow> i \<in> I \<Longrightarrow> w' i \<in> space (M i)"
   584         using J by (auto simp: w'_def intro!: someI_ex[OF M.not_empty[unfolded ex_in_conv[symmetric]]])
   585       { fix i assume "i \<in> I" then have "w' i \<in> space (M i)"
   586           using w(1) by (cases "i \<in> (\<Union>k. J k)") (force simp: w'_simps2 w'_eq space_PiM)+ }
   587       note w'_simps[simp] = w'_eq w'_simps1 w'_simps2 this
   589       have w': "w' \<in> space (Pi\<^isub>M I M)"
   590         using w(1) by (auto simp add: Pi_iff extensional_def space_PiM)
   592       { fix n
   593         have "restrict w' (J n) = w n" using w(1)
   594           by (auto simp add: fun_eq_iff restrict_def Pi_iff extensional_def space_PiM)
   595         with w[of n] obtain x where "x \<in> A n" "restrict x (J n) = restrict w' (J n)" by auto
   596         then have "w' \<in> A n" unfolding A_eq using w' by (auto simp: prod_emb_def space_PiM) }
   597       then have "w' \<in> (\<Inter>i. A i)" by auto
   598       with `(\<Inter>i. A i) = {}` show False by auto
   599     qed
   600     ultimately show "(\<lambda>i. \<mu>G (A i)) ----> 0"
   601       using LIMSEQ_ereal_INFI[of "\<lambda>i. \<mu>G (A i)"] by simp
   602   qed fact+
   603   then guess \<mu> .. note \<mu> = this
   604   show ?thesis
   605   proof (subst emeasure_extend_measure_Pair[OF PiM_def, of I M \<mu> J X])
   606     from assms show "(J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))"
   607       by (simp add: Pi_iff)
   608   next
   609     fix J X assume J: "(J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))"
   610     then show "emb I J (Pi\<^isub>E J X) \<in> Pow (\<Pi>\<^isub>E i\<in>I. space (M i))"
   611       by (auto simp: Pi_iff prod_emb_def dest: sets_into_space)
   612     have "emb I J (Pi\<^isub>E J X) \<in> generator"
   613       using J `I \<noteq> {}` by (intro generatorI') auto
   614     then have "\<mu> (emb I J (Pi\<^isub>E J X)) = \<mu>G (emb I J (Pi\<^isub>E J X))"
   615       using \<mu> by simp
   616     also have "\<dots> = (\<Prod> j\<in>J. if j \<in> J then emeasure (M j) (X j) else emeasure (M j) (space (M j)))"
   617       using J  `I \<noteq> {}` by (subst \<mu>G_spec[OF _ _ _ refl]) (auto simp: emeasure_PiM Pi_iff)
   618     also have "\<dots> = (\<Prod>j\<in>J \<union> {i \<in> I. emeasure (M i) (space (M i)) \<noteq> 1}.
   619       if j \<in> J then emeasure (M j) (X j) else emeasure (M j) (space (M j)))"
   620       using J `I \<noteq> {}` by (intro setprod_mono_one_right) (auto simp: M.emeasure_space_1)
   621     finally show "\<mu> (emb I J (Pi\<^isub>E J X)) = \<dots>" .
   622   next
   623     let ?F = "\<lambda>j. if j \<in> J then emeasure (M j) (X j) else emeasure (M j) (space (M j))"
   624     have "(\<Prod>j\<in>J \<union> {i \<in> I. emeasure (M i) (space (M i)) \<noteq> 1}. ?F j) = (\<Prod>j\<in>J. ?F j)"
   625       using X `I \<noteq> {}` by (intro setprod_mono_one_right) (auto simp: M.emeasure_space_1)
   626     then show "(\<Prod>j\<in>J \<union> {i \<in> I. emeasure (M i) (space (M i)) \<noteq> 1}. ?F j) =
   627       emeasure (Pi\<^isub>M J M) (Pi\<^isub>E J X)"
   628       using X by (auto simp add: emeasure_PiM) 
   629   next
   630     show "positive (sets (Pi\<^isub>M I M)) \<mu>" "countably_additive (sets (Pi\<^isub>M I M)) \<mu>"
   631       using \<mu> unfolding sets_PiM_generator[OF `I \<noteq> {}`] by (auto simp: measure_space_def)
   632   qed
   633 qed
   635 sublocale product_prob_space \<subseteq> P: prob_space "Pi\<^isub>M I M"
   636 proof
   637   show "emeasure (Pi\<^isub>M I M) (space (Pi\<^isub>M I M)) = 1"
   638   proof cases
   639     assume "I = {}" then show ?thesis by (simp add: space_PiM_empty)
   640   next
   641     assume "I \<noteq> {}"
   642     then obtain i where "i \<in> I" by auto
   643     moreover then have "emb I {i} (\<Pi>\<^isub>E i\<in>{i}. space (M i)) = (space (Pi\<^isub>M I M))"
   644       by (auto simp: prod_emb_def space_PiM)
   645     ultimately show ?thesis
   646       using emeasure_PiM_emb_not_empty[of "{i}" "\<lambda>i. space (M i)"]
   647       by (simp add: emeasure_PiM emeasure_space_1)
   648   qed
   649 qed
   651 lemma (in product_prob_space) emeasure_PiM_emb:
   652   assumes X: "J \<subseteq> I" "finite J" "\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)"
   653   shows "emeasure (Pi\<^isub>M I M) (emb I J (Pi\<^isub>E J X)) = (\<Prod> i\<in>J. emeasure (M i) (X i))"
   654 proof cases
   655   assume "J = {}"
   656   moreover have "emb I {} {\<lambda>x. undefined} = space (Pi\<^isub>M I M)"
   657     by (auto simp: space_PiM prod_emb_def)
   658   ultimately show ?thesis
   659     by (simp add: space_PiM_empty P.emeasure_space_1)
   660 next
   661   assume "J \<noteq> {}" with X show ?thesis
   662     by (subst emeasure_PiM_emb_not_empty) (auto simp: emeasure_PiM)
   663 qed
   665 lemma (in product_prob_space) measure_PiM_emb:
   666   assumes "J \<subseteq> I" "finite J" "\<And>i. i \<in> J \<Longrightarrow> X i \<in> sets (M i)"
   667   shows "measure (PiM I M) (emb I J (Pi\<^isub>E J X)) = (\<Prod> i\<in>J. measure (M i) (X i))"
   668   using emeasure_PiM_emb[OF assms]
   669   unfolding emeasure_eq_measure M.emeasure_eq_measure by (simp add: setprod_ereal)
   671 lemma (in finite_product_prob_space) finite_measure_PiM_emb:
   672   "(\<And>i. i \<in> I \<Longrightarrow> A i \<in> sets (M i)) \<Longrightarrow> measure (PiM I M) (Pi\<^isub>E I A) = (\<Prod>i\<in>I. measure (M i) (A i))"
   673   using measure_PiM_emb[of I A] finite_index prod_emb_PiE_same_index[OF sets_into_space, of I A M]
   674   by auto
   676 subsection {* Sequence space *}
   678 locale sequence_space = product_prob_space M "UNIV :: nat set" for M
   680 lemma (in sequence_space) infprod_in_sets[intro]:
   681   fixes E :: "nat \<Rightarrow> 'a set" assumes E: "\<And>i. E i \<in> sets (M i)"
   682   shows "Pi UNIV E \<in> sets (Pi\<^isub>M UNIV M)"
   683 proof -
   684   have "Pi UNIV E = (\<Inter>i. emb UNIV {..i} (\<Pi>\<^isub>E j\<in>{..i}. E j))"
   685     using E E[THEN sets_into_space]
   686     by (auto simp: prod_emb_def Pi_iff extensional_def) blast
   687   with E show ?thesis by auto
   688 qed
   690 lemma (in sequence_space) measure_PiM_countable:
   691   fixes E :: "nat \<Rightarrow> 'a set" assumes E: "\<And>i. E i \<in> sets (M i)"
   692   shows "(\<lambda>n. \<Prod>i\<le>n. measure (M i) (E i)) ----> measure (Pi\<^isub>M UNIV M) (Pi UNIV E)"
   693 proof -
   694   let ?E = "\<lambda>n. emb UNIV {..n} (Pi\<^isub>E {.. n} E)"
   695   have "\<And>n. (\<Prod>i\<le>n. measure (M i) (E i)) = measure (Pi\<^isub>M UNIV M) (?E n)"
   696     using E by (simp add: measure_PiM_emb)
   697   moreover have "Pi UNIV E = (\<Inter>n. ?E n)"
   698     using E E[THEN sets_into_space]
   699     by (auto simp: prod_emb_def extensional_def Pi_iff) blast
   700   moreover have "range ?E \<subseteq> sets (Pi\<^isub>M UNIV M)"
   701     using E by auto
   702   moreover have "decseq ?E"
   703     by (auto simp: prod_emb_def Pi_iff decseq_def)
   704   ultimately show ?thesis
   705     by (simp add: finite_Lim_measure_decseq)
   706 qed
   708 end