src/Pure/goal.ML
author wenzelm
Tue Jul 03 17:17:11 2007 +0200 (2007-07-03)
changeset 23536 60a1672e298e
parent 23418 c195f6f13769
child 25301 24e027f55f45
permissions -rw-r--r--
moved (asm_)rewrite_goal_tac from goal.ML to meta_simplifier.ML (no longer depends on SELECT_GOAL);
     1 (*  Title:      Pure/goal.ML
     2     ID:         $Id$
     3     Author:     Makarius and Lawrence C Paulson
     4 
     5 Goals in tactical theorem proving.
     6 *)
     7 
     8 signature BASIC_GOAL =
     9 sig
    10   val SELECT_GOAL: tactic -> int -> tactic
    11   val CONJUNCTS: tactic -> int -> tactic
    12   val PRECISE_CONJUNCTS: int -> tactic -> int -> tactic
    13 end;
    14 
    15 signature GOAL =
    16 sig
    17   include BASIC_GOAL
    18   val init: cterm -> thm
    19   val protect: thm -> thm
    20   val conclude: thm -> thm
    21   val finish: thm -> thm
    22   val norm_result: thm -> thm
    23   val close_result: thm -> thm
    24   val prove_internal: cterm list -> cterm -> (thm list -> tactic) -> thm
    25   val prove_multi: Proof.context -> string list -> term list -> term list ->
    26     ({prems: thm list, context: Proof.context} -> tactic) -> thm list
    27   val prove: Proof.context -> string list -> term list -> term ->
    28     ({prems: thm list, context: Proof.context} -> tactic) -> thm
    29   val prove_global: theory -> string list -> term list -> term -> (thm list -> tactic) -> thm
    30   val extract: int -> int -> thm -> thm Seq.seq
    31   val retrofit: int -> int -> thm -> thm -> thm Seq.seq
    32   val conjunction_tac: int -> tactic
    33   val precise_conjunction_tac: int -> int -> tactic
    34   val recover_conjunction_tac: tactic
    35   val norm_hhf_tac: int -> tactic
    36   val compose_hhf: thm -> int -> thm -> thm Seq.seq
    37   val compose_hhf_tac: thm -> int -> tactic
    38   val comp_hhf: thm -> thm -> thm
    39   val assume_rule_tac: Proof.context -> int -> tactic
    40 end;
    41 
    42 structure Goal: GOAL =
    43 struct
    44 
    45 (** goals **)
    46 
    47 (*
    48   -------- (init)
    49   C ==> #C
    50 *)
    51 val init =
    52   let val A = #1 (Thm.dest_implies (Thm.cprop_of Drule.protectI))
    53   in fn C => Thm.instantiate ([], [(A, C)]) Drule.protectI end;
    54 
    55 (*
    56    C
    57   --- (protect)
    58   #C
    59 *)
    60 fun protect th = th COMP_INCR Drule.protectI;
    61 
    62 (*
    63   A ==> ... ==> #C
    64   ---------------- (conclude)
    65   A ==> ... ==> C
    66 *)
    67 fun conclude th =
    68   (case SINGLE (Thm.compose_no_flatten false (th, Thm.nprems_of th) 1)
    69       (Drule.incr_indexes th Drule.protectD) of
    70     SOME th' => th'
    71   | NONE => raise THM ("Failed to conclude goal", 0, [th]));
    72 
    73 (*
    74   #C
    75   --- (finish)
    76    C
    77 *)
    78 fun finish th =
    79   (case Thm.nprems_of th of
    80     0 => conclude th
    81   | n => raise THM ("Proof failed.\n" ^
    82       Pretty.string_of (Pretty.chunks (Display.pretty_goals n th)) ^
    83       ("\n" ^ string_of_int n ^ " unsolved goal(s)!"), 0, [th]));
    84 
    85 
    86 
    87 (** results **)
    88 
    89 (* normal form *)
    90 
    91 val norm_result =
    92   Drule.flexflex_unique
    93   #> MetaSimplifier.norm_hhf_protect
    94   #> Thm.strip_shyps
    95   #> Drule.zero_var_indexes;
    96 
    97 val close_result =
    98   Thm.compress
    99   #> Drule.close_derivation;
   100 
   101 
   102 
   103 (** tactical theorem proving **)
   104 
   105 (* prove_internal -- minimal checks, no normalization of result! *)
   106 
   107 fun prove_internal casms cprop tac =
   108   (case SINGLE (tac (map Assumption.assume casms)) (init cprop) of
   109     SOME th => Drule.implies_intr_list casms (finish th)
   110   | NONE => error "Tactic failed.");
   111 
   112 
   113 (* prove_multi *)
   114 
   115 fun prove_multi ctxt xs asms props tac =
   116   let
   117     val thy = ProofContext.theory_of ctxt;
   118     val string_of_term = Sign.string_of_term thy;
   119 
   120     fun err msg = cat_error msg
   121       ("The error(s) above occurred for the goal statement:\n" ^
   122         string_of_term (Logic.list_implies (asms, Logic.mk_conjunction_list props)));
   123 
   124     fun cert_safe t = Thm.cterm_of thy (Envir.beta_norm (Term.no_dummy_patterns t))
   125       handle TERM (msg, _) => err msg | TYPE (msg, _, _) => err msg;
   126     val casms = map cert_safe asms;
   127     val cprops = map cert_safe props;
   128 
   129     val (prems, ctxt') = ctxt
   130       |> Variable.add_fixes_direct xs
   131       |> fold Variable.declare_internal (asms @ props)
   132       |> Assumption.add_assumes casms;
   133 
   134     val goal = init (Conjunction.mk_conjunction_balanced cprops);
   135     val res =
   136       (case SINGLE (tac {prems = prems, context = ctxt'}) goal of
   137         NONE => err "Tactic failed."
   138       | SOME res => res);
   139     val results = Conjunction.elim_balanced (length props) (finish res)
   140       handle THM (msg, _, _) => err msg;
   141     val _ = Unify.matches_list thy (map Thm.term_of cprops) (map Thm.prop_of results)
   142       orelse err ("Proved a different theorem: " ^ string_of_term (Thm.prop_of res));
   143   in
   144     results
   145     |> map (Assumption.export false ctxt' ctxt)
   146     |> Variable.export ctxt' ctxt
   147     |> map Drule.zero_var_indexes
   148   end;
   149 
   150 
   151 (* prove *)
   152 
   153 fun prove ctxt xs asms prop tac = hd (prove_multi ctxt xs asms [prop] tac);
   154 
   155 fun prove_global thy xs asms prop tac =
   156   Drule.standard (prove (ProofContext.init thy) xs asms prop (fn {prems, ...} => tac prems));
   157 
   158 
   159 
   160 (** goal structure **)
   161 
   162 (* nested goals *)
   163 
   164 fun extract i n st =
   165   (if i < 1 orelse n < 1 orelse i + n - 1 > Thm.nprems_of st then Seq.empty
   166    else if n = 1 then Seq.single (Thm.cprem_of st i)
   167    else
   168      Seq.single (Conjunction.mk_conjunction_balanced (map (Thm.cprem_of st) (i upto i + n - 1))))
   169   |> Seq.map (Thm.adjust_maxidx_cterm ~1 #> init);
   170 
   171 fun retrofit i n st' st =
   172   (if n = 1 then st
   173    else st |> Drule.with_subgoal i (Conjunction.uncurry_balanced n))
   174   |> Thm.compose_no_flatten false (conclude st', Thm.nprems_of st') i;
   175 
   176 fun SELECT_GOAL tac i st =
   177   if Thm.nprems_of st = 1 andalso i = 1 then tac st
   178   else Seq.lifts (retrofit i 1) (Seq.maps tac (extract i 1 st)) st;
   179 
   180 
   181 (* multiple goals *)
   182 
   183 fun precise_conjunction_tac 0 i = eq_assume_tac i
   184   | precise_conjunction_tac 1 i = SUBGOAL (K all_tac) i
   185   | precise_conjunction_tac n i = PRIMITIVE (Drule.with_subgoal i (Conjunction.curry_balanced n));
   186 
   187 val adhoc_conjunction_tac = REPEAT_ALL_NEW
   188   (SUBGOAL (fn (goal, i) =>
   189     if can Logic.dest_conjunction goal then rtac Conjunction.conjunctionI i
   190     else no_tac));
   191 
   192 val conjunction_tac = SUBGOAL (fn (goal, i) =>
   193   precise_conjunction_tac (length (Logic.dest_conjunctions goal)) i ORELSE
   194   TRY (adhoc_conjunction_tac i));
   195 
   196 val recover_conjunction_tac = PRIMITIVE (fn th =>
   197   Conjunction.uncurry_balanced (Thm.nprems_of th) th);
   198 
   199 fun PRECISE_CONJUNCTS n tac =
   200   SELECT_GOAL (precise_conjunction_tac n 1
   201     THEN tac
   202     THEN recover_conjunction_tac);
   203 
   204 fun CONJUNCTS tac =
   205   SELECT_GOAL (conjunction_tac 1
   206     THEN tac
   207     THEN recover_conjunction_tac);
   208 
   209 
   210 (* hhf normal form *)
   211 
   212 val norm_hhf_tac =
   213   rtac Drule.asm_rl  (*cheap approximation -- thanks to builtin Logic.flatten_params*)
   214   THEN' SUBGOAL (fn (t, i) =>
   215     if Drule.is_norm_hhf t then all_tac
   216     else MetaSimplifier.rewrite_goal_tac [Drule.norm_hhf_eq] i);
   217 
   218 fun compose_hhf tha i thb =
   219   Thm.bicompose false (false, Drule.lift_all (Thm.cprem_of thb i) tha, 0) i thb;
   220 
   221 fun compose_hhf_tac th i = PRIMSEQ (compose_hhf th i);
   222 
   223 fun comp_hhf tha thb =
   224   (case Seq.chop 2 (compose_hhf tha 1 thb) of
   225     ([th], _) => th
   226   | ([], _) => raise THM ("comp_hhf: no unifiers", 1, [tha, thb])
   227   | _  => raise THM ("comp_hhf: multiple unifiers", 1, [tha, thb]));
   228 
   229 
   230 (* non-atomic goal assumptions *)
   231 
   232 fun non_atomic (Const ("==>", _) $ _ $ _) = true
   233   | non_atomic (Const ("all", _) $ _) = true
   234   | non_atomic _ = false;
   235 
   236 fun assume_rule_tac ctxt = norm_hhf_tac THEN' CSUBGOAL (fn (goal, i) =>
   237   let
   238     val ((_, goal'), ctxt') = Variable.focus goal ctxt;
   239     val goal'' = Drule.cterm_rule (singleton (Variable.export ctxt' ctxt)) goal';
   240     val Rs = filter (non_atomic o Thm.term_of) (Drule.strip_imp_prems goal'');
   241     val tacs = Rs |> map (fn R =>
   242       Tactic.etac (MetaSimplifier.norm_hhf (Thm.trivial R)) THEN_ALL_NEW assume_tac);
   243   in fold_rev (curry op APPEND') tacs (K no_tac) i end);
   244 
   245 end;
   246 
   247 structure BasicGoal: BASIC_GOAL = Goal;
   248 open BasicGoal;