src/HOL/Library/FuncSet.thy
author wenzelm
Tue Jan 17 11:26:21 2017 +0100 (2017-01-17)
changeset 64910 6108dddad9f0
parent 63092 a949b2a5f51d
child 64917 5db5b8cf6dc6
permissions -rw-r--r--
more symbols via abbrevs;
     1 (*  Title:      HOL/Library/FuncSet.thy
     2     Author:     Florian Kammueller and Lawrence C Paulson, Lukas Bulwahn
     3 *)
     4 
     5 section \<open>Pi and Function Sets\<close>
     6 
     7 theory FuncSet
     8   imports Hilbert_Choice Main
     9   abbrevs PiE = "Pi\<^sub>E"
    10     PIE = "\<Pi>\<^sub>E"
    11 begin
    12 
    13 definition Pi :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<Rightarrow> 'b) set"
    14   where "Pi A B = {f. \<forall>x. x \<in> A \<longrightarrow> f x \<in> B x}"
    15 
    16 definition extensional :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b) set"
    17   where "extensional A = {f. \<forall>x. x \<notin> A \<longrightarrow> f x = undefined}"
    18 
    19 definition "restrict" :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b"
    20   where "restrict f A = (\<lambda>x. if x \<in> A then f x else undefined)"
    21 
    22 abbreviation funcset :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  (infixr "\<rightarrow>" 60)
    23   where "A \<rightarrow> B \<equiv> Pi A (\<lambda>_. B)"
    24 
    25 syntax (ASCII)
    26   "_Pi"  :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3PI _:_./ _)" 10)
    27   "_lam" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> ('a \<Rightarrow> 'b)"  ("(3%_:_./ _)" [0,0,3] 3)
    28 syntax
    29   "_Pi" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    30   "_lam" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    31 translations
    32   "\<Pi> x\<in>A. B" \<rightleftharpoons> "CONST Pi A (\<lambda>x. B)"
    33   "\<lambda>x\<in>A. f" \<rightleftharpoons> "CONST restrict (\<lambda>x. f) A"
    34 
    35 definition "compose" :: "'a set \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'c)"
    36   where "compose A g f = (\<lambda>x\<in>A. g (f x))"
    37 
    38 
    39 subsection \<open>Basic Properties of @{term Pi}\<close>
    40 
    41 lemma Pi_I[intro!]: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> f \<in> Pi A B"
    42   by (simp add: Pi_def)
    43 
    44 lemma Pi_I'[simp]: "(\<And>x. x \<in> A \<longrightarrow> f x \<in> B x) \<Longrightarrow> f \<in> Pi A B"
    45   by (simp add:Pi_def)
    46 
    47 lemma funcsetI: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B) \<Longrightarrow> f \<in> A \<rightarrow> B"
    48   by (simp add: Pi_def)
    49 
    50 lemma Pi_mem: "f \<in> Pi A B \<Longrightarrow> x \<in> A \<Longrightarrow> f x \<in> B x"
    51   by (simp add: Pi_def)
    52 
    53 lemma Pi_iff: "f \<in> Pi I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i)"
    54   unfolding Pi_def by auto
    55 
    56 lemma PiE [elim]: "f \<in> Pi A B \<Longrightarrow> (f x \<in> B x \<Longrightarrow> Q) \<Longrightarrow> (x \<notin> A \<Longrightarrow> Q) \<Longrightarrow> Q"
    57   by (auto simp: Pi_def)
    58 
    59 lemma Pi_cong: "(\<And>w. w \<in> A \<Longrightarrow> f w = g w) \<Longrightarrow> f \<in> Pi A B \<longleftrightarrow> g \<in> Pi A B"
    60   by (auto simp: Pi_def)
    61 
    62 lemma funcset_id [simp]: "(\<lambda>x. x) \<in> A \<rightarrow> A"
    63   by auto
    64 
    65 lemma funcset_mem: "f \<in> A \<rightarrow> B \<Longrightarrow> x \<in> A \<Longrightarrow> f x \<in> B"
    66   by (simp add: Pi_def)
    67 
    68 lemma funcset_image: "f \<in> A \<rightarrow> B \<Longrightarrow> f ` A \<subseteq> B"
    69   by auto
    70 
    71 lemma image_subset_iff_funcset: "F ` A \<subseteq> B \<longleftrightarrow> F \<in> A \<rightarrow> B"
    72   by auto
    73 
    74 lemma Pi_eq_empty[simp]: "(\<Pi> x \<in> A. B x) = {} \<longleftrightarrow> (\<exists>x\<in>A. B x = {})"
    75   apply (simp add: Pi_def)
    76   apply auto
    77   txt \<open>Converse direction requires Axiom of Choice to exhibit a function
    78   picking an element from each non-empty @{term "B x"}\<close>
    79   apply (drule_tac x = "\<lambda>u. SOME y. y \<in> B u" in spec)
    80   apply auto
    81   apply (cut_tac P = "\<lambda>y. y \<in> B x" in some_eq_ex)
    82   apply auto
    83   done
    84 
    85 lemma Pi_empty [simp]: "Pi {} B = UNIV"
    86   by (simp add: Pi_def)
    87 
    88 lemma Pi_Int: "Pi I E \<inter> Pi I F = (\<Pi> i\<in>I. E i \<inter> F i)"
    89   by auto
    90 
    91 lemma Pi_UN:
    92   fixes A :: "nat \<Rightarrow> 'i \<Rightarrow> 'a set"
    93   assumes "finite I"
    94     and mono: "\<And>i n m. i \<in> I \<Longrightarrow> n \<le> m \<Longrightarrow> A n i \<subseteq> A m i"
    95   shows "(\<Union>n. Pi I (A n)) = (\<Pi> i\<in>I. \<Union>n. A n i)"
    96 proof (intro set_eqI iffI)
    97   fix f
    98   assume "f \<in> (\<Pi> i\<in>I. \<Union>n. A n i)"
    99   then have "\<forall>i\<in>I. \<exists>n. f i \<in> A n i"
   100     by auto
   101   from bchoice[OF this] obtain n where n: "f i \<in> A (n i) i" if "i \<in> I" for i
   102     by auto
   103   obtain k where k: "n i \<le> k" if "i \<in> I" for i
   104     using \<open>finite I\<close> finite_nat_set_iff_bounded_le[of "n`I"] by auto
   105   have "f \<in> Pi I (A k)"
   106   proof (intro Pi_I)
   107     fix i
   108     assume "i \<in> I"
   109     from mono[OF this, of "n i" k] k[OF this] n[OF this]
   110     show "f i \<in> A k i" by auto
   111   qed
   112   then show "f \<in> (\<Union>n. Pi I (A n))"
   113     by auto
   114 qed auto
   115 
   116 lemma Pi_UNIV [simp]: "A \<rightarrow> UNIV = UNIV"
   117   by (simp add: Pi_def)
   118 
   119 text \<open>Covariance of Pi-sets in their second argument\<close>
   120 lemma Pi_mono: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C x) \<Longrightarrow> Pi A B \<subseteq> Pi A C"
   121   by auto
   122 
   123 text \<open>Contravariance of Pi-sets in their first argument\<close>
   124 lemma Pi_anti_mono: "A' \<subseteq> A \<Longrightarrow> Pi A B \<subseteq> Pi A' B"
   125   by auto
   126 
   127 lemma prod_final:
   128   assumes 1: "fst \<circ> f \<in> Pi A B"
   129     and 2: "snd \<circ> f \<in> Pi A C"
   130   shows "f \<in> (\<Pi> z \<in> A. B z \<times> C z)"
   131 proof (rule Pi_I)
   132   fix z
   133   assume z: "z \<in> A"
   134   have "f z = (fst (f z), snd (f z))"
   135     by simp
   136   also have "\<dots> \<in> B z \<times> C z"
   137     by (metis SigmaI PiE o_apply 1 2 z)
   138   finally show "f z \<in> B z \<times> C z" .
   139 qed
   140 
   141 lemma Pi_split_domain[simp]: "x \<in> Pi (I \<union> J) X \<longleftrightarrow> x \<in> Pi I X \<and> x \<in> Pi J X"
   142   by (auto simp: Pi_def)
   143 
   144 lemma Pi_split_insert_domain[simp]: "x \<in> Pi (insert i I) X \<longleftrightarrow> x \<in> Pi I X \<and> x i \<in> X i"
   145   by (auto simp: Pi_def)
   146 
   147 lemma Pi_cancel_fupd_range[simp]: "i \<notin> I \<Longrightarrow> x \<in> Pi I (B(i := b)) \<longleftrightarrow> x \<in> Pi I B"
   148   by (auto simp: Pi_def)
   149 
   150 lemma Pi_cancel_fupd[simp]: "i \<notin> I \<Longrightarrow> x(i := a) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
   151   by (auto simp: Pi_def)
   152 
   153 lemma Pi_fupd_iff: "i \<in> I \<Longrightarrow> f \<in> Pi I (B(i := A)) \<longleftrightarrow> f \<in> Pi (I - {i}) B \<and> f i \<in> A"
   154   apply auto
   155   apply (drule_tac x=x in Pi_mem)
   156   apply (simp_all split: if_split_asm)
   157   apply (drule_tac x=i in Pi_mem)
   158   apply (auto dest!: Pi_mem)
   159   done
   160 
   161 
   162 subsection \<open>Composition With a Restricted Domain: @{term compose}\<close>
   163 
   164 lemma funcset_compose: "f \<in> A \<rightarrow> B \<Longrightarrow> g \<in> B \<rightarrow> C \<Longrightarrow> compose A g f \<in> A \<rightarrow> C"
   165   by (simp add: Pi_def compose_def restrict_def)
   166 
   167 lemma compose_assoc:
   168   assumes "f \<in> A \<rightarrow> B"
   169     and "g \<in> B \<rightarrow> C"
   170     and "h \<in> C \<rightarrow> D"
   171   shows "compose A h (compose A g f) = compose A (compose B h g) f"
   172   using assms by (simp add: fun_eq_iff Pi_def compose_def restrict_def)
   173 
   174 lemma compose_eq: "x \<in> A \<Longrightarrow> compose A g f x = g (f x)"
   175   by (simp add: compose_def restrict_def)
   176 
   177 lemma surj_compose: "f ` A = B \<Longrightarrow> g ` B = C \<Longrightarrow> compose A g f ` A = C"
   178   by (auto simp add: image_def compose_eq)
   179 
   180 
   181 subsection \<open>Bounded Abstraction: @{term restrict}\<close>
   182 
   183 lemma restrict_cong: "I = J \<Longrightarrow> (\<And>i. i \<in> J =simp=> f i = g i) \<Longrightarrow> restrict f I = restrict g J"
   184   by (auto simp: restrict_def fun_eq_iff simp_implies_def)
   185 
   186 lemma restrict_in_funcset: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B) \<Longrightarrow> (\<lambda>x\<in>A. f x) \<in> A \<rightarrow> B"
   187   by (simp add: Pi_def restrict_def)
   188 
   189 lemma restrictI[intro!]: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> (\<lambda>x\<in>A. f x) \<in> Pi A B"
   190   by (simp add: Pi_def restrict_def)
   191 
   192 lemma restrict_apply[simp]: "(\<lambda>y\<in>A. f y) x = (if x \<in> A then f x else undefined)"
   193   by (simp add: restrict_def)
   194 
   195 lemma restrict_apply': "x \<in> A \<Longrightarrow> (\<lambda>y\<in>A. f y) x = f x"
   196   by simp
   197 
   198 lemma restrict_ext: "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> (\<lambda>x\<in>A. f x) = (\<lambda>x\<in>A. g x)"
   199   by (simp add: fun_eq_iff Pi_def restrict_def)
   200 
   201 lemma restrict_UNIV: "restrict f UNIV = f"
   202   by (simp add: restrict_def)
   203 
   204 lemma inj_on_restrict_eq [simp]: "inj_on (restrict f A) A = inj_on f A"
   205   by (simp add: inj_on_def restrict_def)
   206 
   207 lemma Id_compose: "f \<in> A \<rightarrow> B \<Longrightarrow> f \<in> extensional A \<Longrightarrow> compose A (\<lambda>y\<in>B. y) f = f"
   208   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   209 
   210 lemma compose_Id: "g \<in> A \<rightarrow> B \<Longrightarrow> g \<in> extensional A \<Longrightarrow> compose A g (\<lambda>x\<in>A. x) = g"
   211   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   212 
   213 lemma image_restrict_eq [simp]: "(restrict f A) ` A = f ` A"
   214   by (auto simp add: restrict_def)
   215 
   216 lemma restrict_restrict[simp]: "restrict (restrict f A) B = restrict f (A \<inter> B)"
   217   unfolding restrict_def by (simp add: fun_eq_iff)
   218 
   219 lemma restrict_fupd[simp]: "i \<notin> I \<Longrightarrow> restrict (f (i := x)) I = restrict f I"
   220   by (auto simp: restrict_def)
   221 
   222 lemma restrict_upd[simp]: "i \<notin> I \<Longrightarrow> (restrict f I)(i := y) = restrict (f(i := y)) (insert i I)"
   223   by (auto simp: fun_eq_iff)
   224 
   225 lemma restrict_Pi_cancel: "restrict x I \<in> Pi I A \<longleftrightarrow> x \<in> Pi I A"
   226   by (auto simp: restrict_def Pi_def)
   227 
   228 
   229 subsection \<open>Bijections Between Sets\<close>
   230 
   231 text \<open>The definition of @{const bij_betw} is in \<open>Fun.thy\<close>, but most of
   232 the theorems belong here, or need at least @{term Hilbert_Choice}.\<close>
   233 
   234 lemma bij_betwI:
   235   assumes "f \<in> A \<rightarrow> B"
   236     and "g \<in> B \<rightarrow> A"
   237     and g_f: "\<And>x. x\<in>A \<Longrightarrow> g (f x) = x"
   238     and f_g: "\<And>y. y\<in>B \<Longrightarrow> f (g y) = y"
   239   shows "bij_betw f A B"
   240   unfolding bij_betw_def
   241 proof
   242   show "inj_on f A"
   243     by (metis g_f inj_on_def)
   244   have "f ` A \<subseteq> B"
   245     using \<open>f \<in> A \<rightarrow> B\<close> by auto
   246   moreover
   247   have "B \<subseteq> f ` A"
   248     by auto (metis Pi_mem \<open>g \<in> B \<rightarrow> A\<close> f_g image_iff)
   249   ultimately show "f ` A = B"
   250     by blast
   251 qed
   252 
   253 lemma bij_betw_imp_funcset: "bij_betw f A B \<Longrightarrow> f \<in> A \<rightarrow> B"
   254   by (auto simp add: bij_betw_def)
   255 
   256 lemma inj_on_compose: "bij_betw f A B \<Longrightarrow> inj_on g B \<Longrightarrow> inj_on (compose A g f) A"
   257   by (auto simp add: bij_betw_def inj_on_def compose_eq)
   258 
   259 lemma bij_betw_compose: "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (compose A g f) A C"
   260   apply (simp add: bij_betw_def compose_eq inj_on_compose)
   261   apply (auto simp add: compose_def image_def)
   262   done
   263 
   264 lemma bij_betw_restrict_eq [simp]: "bij_betw (restrict f A) A B = bij_betw f A B"
   265   by (simp add: bij_betw_def)
   266 
   267 
   268 subsection \<open>Extensionality\<close>
   269 
   270 lemma extensional_empty[simp]: "extensional {} = {\<lambda>x. undefined}"
   271   unfolding extensional_def by auto
   272 
   273 lemma extensional_arb: "f \<in> extensional A \<Longrightarrow> x \<notin> A \<Longrightarrow> f x = undefined"
   274   by (simp add: extensional_def)
   275 
   276 lemma restrict_extensional [simp]: "restrict f A \<in> extensional A"
   277   by (simp add: restrict_def extensional_def)
   278 
   279 lemma compose_extensional [simp]: "compose A f g \<in> extensional A"
   280   by (simp add: compose_def)
   281 
   282 lemma extensionalityI:
   283   assumes "f \<in> extensional A"
   284     and "g \<in> extensional A"
   285     and "\<And>x. x \<in> A \<Longrightarrow> f x = g x"
   286   shows "f = g"
   287   using assms by (force simp add: fun_eq_iff extensional_def)
   288 
   289 lemma extensional_restrict:  "f \<in> extensional A \<Longrightarrow> restrict f A = f"
   290   by (rule extensionalityI[OF restrict_extensional]) auto
   291 
   292 lemma extensional_subset: "f \<in> extensional A \<Longrightarrow> A \<subseteq> B \<Longrightarrow> f \<in> extensional B"
   293   unfolding extensional_def by auto
   294 
   295 lemma inv_into_funcset: "f ` A = B \<Longrightarrow> (\<lambda>x\<in>B. inv_into A f x) \<in> B \<rightarrow> A"
   296   by (unfold inv_into_def) (fast intro: someI2)
   297 
   298 lemma compose_inv_into_id: "bij_betw f A B \<Longrightarrow> compose A (\<lambda>y\<in>B. inv_into A f y) f = (\<lambda>x\<in>A. x)"
   299   apply (simp add: bij_betw_def compose_def)
   300   apply (rule restrict_ext, auto)
   301   done
   302 
   303 lemma compose_id_inv_into: "f ` A = B \<Longrightarrow> compose B f (\<lambda>y\<in>B. inv_into A f y) = (\<lambda>x\<in>B. x)"
   304   apply (simp add: compose_def)
   305   apply (rule restrict_ext)
   306   apply (simp add: f_inv_into_f)
   307   done
   308 
   309 lemma extensional_insert[intro, simp]:
   310   assumes "a \<in> extensional (insert i I)"
   311   shows "a(i := b) \<in> extensional (insert i I)"
   312   using assms unfolding extensional_def by auto
   313 
   314 lemma extensional_Int[simp]: "extensional I \<inter> extensional I' = extensional (I \<inter> I')"
   315   unfolding extensional_def by auto
   316 
   317 lemma extensional_UNIV[simp]: "extensional UNIV = UNIV"
   318   by (auto simp: extensional_def)
   319 
   320 lemma restrict_extensional_sub[intro]: "A \<subseteq> B \<Longrightarrow> restrict f A \<in> extensional B"
   321   unfolding restrict_def extensional_def by auto
   322 
   323 lemma extensional_insert_undefined[intro, simp]:
   324   "a \<in> extensional (insert i I) \<Longrightarrow> a(i := undefined) \<in> extensional I"
   325   unfolding extensional_def by auto
   326 
   327 lemma extensional_insert_cancel[intro, simp]:
   328   "a \<in> extensional I \<Longrightarrow> a \<in> extensional (insert i I)"
   329   unfolding extensional_def by auto
   330 
   331 
   332 subsection \<open>Cardinality\<close>
   333 
   334 lemma card_inj: "f \<in> A \<rightarrow> B \<Longrightarrow> inj_on f A \<Longrightarrow> finite B \<Longrightarrow> card A \<le> card B"
   335   by (rule card_inj_on_le) auto
   336 
   337 lemma card_bij:
   338   assumes "f \<in> A \<rightarrow> B" "inj_on f A"
   339     and "g \<in> B \<rightarrow> A" "inj_on g B"
   340     and "finite A" "finite B"
   341   shows "card A = card B"
   342   using assms by (blast intro: card_inj order_antisym)
   343 
   344 
   345 subsection \<open>Extensional Function Spaces\<close>
   346 
   347 definition PiE :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<Rightarrow> 'b) set"
   348   where "PiE S T = Pi S T \<inter> extensional S"
   349 
   350 abbreviation "Pi\<^sub>E A B \<equiv> PiE A B"
   351 
   352 syntax (ASCII)
   353   "_PiE" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3PIE _:_./ _)" 10)
   354 syntax
   355   "_PiE" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3\<Pi>\<^sub>E _\<in>_./ _)" 10)
   356 translations
   357   "\<Pi>\<^sub>E x\<in>A. B" \<rightleftharpoons> "CONST Pi\<^sub>E A (\<lambda>x. B)"
   358 
   359 abbreviation extensional_funcset :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set" (infixr "\<rightarrow>\<^sub>E" 60)
   360   where "A \<rightarrow>\<^sub>E B \<equiv> (\<Pi>\<^sub>E i\<in>A. B)"
   361 
   362 lemma extensional_funcset_def: "extensional_funcset S T = (S \<rightarrow> T) \<inter> extensional S"
   363   by (simp add: PiE_def)
   364 
   365 lemma PiE_empty_domain[simp]: "Pi\<^sub>E {} T = {\<lambda>x. undefined}"
   366   unfolding PiE_def by simp
   367 
   368 lemma PiE_UNIV_domain: "Pi\<^sub>E UNIV T = Pi UNIV T"
   369   unfolding PiE_def by simp
   370 
   371 lemma PiE_empty_range[simp]: "i \<in> I \<Longrightarrow> F i = {} \<Longrightarrow> (\<Pi>\<^sub>E i\<in>I. F i) = {}"
   372   unfolding PiE_def by auto
   373 
   374 lemma PiE_eq_empty_iff: "Pi\<^sub>E I F = {} \<longleftrightarrow> (\<exists>i\<in>I. F i = {})"
   375 proof
   376   assume "Pi\<^sub>E I F = {}"
   377   show "\<exists>i\<in>I. F i = {}"
   378   proof (rule ccontr)
   379     assume "\<not> ?thesis"
   380     then have "\<forall>i. \<exists>y. (i \<in> I \<longrightarrow> y \<in> F i) \<and> (i \<notin> I \<longrightarrow> y = undefined)"
   381       by auto
   382     from choice[OF this]
   383     obtain f where " \<forall>x. (x \<in> I \<longrightarrow> f x \<in> F x) \<and> (x \<notin> I \<longrightarrow> f x = undefined)" ..
   384     then have "f \<in> Pi\<^sub>E I F"
   385       by (auto simp: extensional_def PiE_def)
   386     with \<open>Pi\<^sub>E I F = {}\<close> show False
   387       by auto
   388   qed
   389 qed (auto simp: PiE_def)
   390 
   391 lemma PiE_arb: "f \<in> Pi\<^sub>E S T \<Longrightarrow> x \<notin> S \<Longrightarrow> f x = undefined"
   392   unfolding PiE_def by auto (auto dest!: extensional_arb)
   393 
   394 lemma PiE_mem: "f \<in> Pi\<^sub>E S T \<Longrightarrow> x \<in> S \<Longrightarrow> f x \<in> T x"
   395   unfolding PiE_def by auto
   396 
   397 lemma PiE_fun_upd: "y \<in> T x \<Longrightarrow> f \<in> Pi\<^sub>E S T \<Longrightarrow> f(x := y) \<in> Pi\<^sub>E (insert x S) T"
   398   unfolding PiE_def extensional_def by auto
   399 
   400 lemma fun_upd_in_PiE: "x \<notin> S \<Longrightarrow> f \<in> Pi\<^sub>E (insert x S) T \<Longrightarrow> f(x := undefined) \<in> Pi\<^sub>E S T"
   401   unfolding PiE_def extensional_def by auto
   402 
   403 lemma PiE_insert_eq: "Pi\<^sub>E (insert x S) T = (\<lambda>(y, g). g(x := y)) ` (T x \<times> Pi\<^sub>E S T)"
   404 proof -
   405   {
   406     fix f assume "f \<in> Pi\<^sub>E (insert x S) T" "x \<notin> S"
   407     then have "f \<in> (\<lambda>(y, g). g(x := y)) ` (T x \<times> Pi\<^sub>E S T)"
   408       by (auto intro!: image_eqI[where x="(f x, f(x := undefined))"] intro: fun_upd_in_PiE PiE_mem)
   409   }
   410   moreover
   411   {
   412     fix f assume "f \<in> Pi\<^sub>E (insert x S) T" "x \<in> S"
   413     then have "f \<in> (\<lambda>(y, g). g(x := y)) ` (T x \<times> Pi\<^sub>E S T)"
   414       by (auto intro!: image_eqI[where x="(f x, f)"] intro: fun_upd_in_PiE PiE_mem simp: insert_absorb)
   415   }
   416   ultimately show ?thesis
   417     by (auto intro: PiE_fun_upd)
   418 qed
   419 
   420 lemma PiE_Int: "Pi\<^sub>E I A \<inter> Pi\<^sub>E I B = Pi\<^sub>E I (\<lambda>x. A x \<inter> B x)"
   421   by (auto simp: PiE_def)
   422 
   423 lemma PiE_cong: "(\<And>i. i\<in>I \<Longrightarrow> A i = B i) \<Longrightarrow> Pi\<^sub>E I A = Pi\<^sub>E I B"
   424   unfolding PiE_def by (auto simp: Pi_cong)
   425 
   426 lemma PiE_E [elim]:
   427   assumes "f \<in> Pi\<^sub>E A B"
   428   obtains "x \<in> A" and "f x \<in> B x"
   429     | "x \<notin> A" and "f x = undefined"
   430   using assms by (auto simp: Pi_def PiE_def extensional_def)
   431 
   432 lemma PiE_I[intro!]:
   433   "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> (\<And>x. x \<notin> A \<Longrightarrow> f x = undefined) \<Longrightarrow> f \<in> Pi\<^sub>E A B"
   434   by (simp add: PiE_def extensional_def)
   435 
   436 lemma PiE_mono: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C x) \<Longrightarrow> Pi\<^sub>E A B \<subseteq> Pi\<^sub>E A C"
   437   by auto
   438 
   439 lemma PiE_iff: "f \<in> Pi\<^sub>E I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i) \<and> f \<in> extensional I"
   440   by (simp add: PiE_def Pi_iff)
   441 
   442 lemma PiE_restrict[simp]:  "f \<in> Pi\<^sub>E A B \<Longrightarrow> restrict f A = f"
   443   by (simp add: extensional_restrict PiE_def)
   444 
   445 lemma restrict_PiE[simp]: "restrict f I \<in> Pi\<^sub>E I S \<longleftrightarrow> f \<in> Pi I S"
   446   by (auto simp: PiE_iff)
   447 
   448 lemma PiE_eq_subset:
   449   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
   450     and eq: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   451     and "i \<in> I"
   452   shows "F i \<subseteq> F' i"
   453 proof
   454   fix x
   455   assume "x \<in> F i"
   456   with ne have "\<forall>j. \<exists>y. (j \<in> I \<longrightarrow> y \<in> F j \<and> (i = j \<longrightarrow> x = y)) \<and> (j \<notin> I \<longrightarrow> y = undefined)"
   457     by auto
   458   from choice[OF this] obtain f
   459     where f: " \<forall>j. (j \<in> I \<longrightarrow> f j \<in> F j \<and> (i = j \<longrightarrow> x = f j)) \<and> (j \<notin> I \<longrightarrow> f j = undefined)" ..
   460   then have "f \<in> Pi\<^sub>E I F"
   461     by (auto simp: extensional_def PiE_def)
   462   then have "f \<in> Pi\<^sub>E I F'"
   463     using assms by simp
   464   then show "x \<in> F' i"
   465     using f \<open>i \<in> I\<close> by (auto simp: PiE_def)
   466 qed
   467 
   468 lemma PiE_eq_iff_not_empty:
   469   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
   470   shows "Pi\<^sub>E I F = Pi\<^sub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i)"
   471 proof (intro iffI ballI)
   472   fix i
   473   assume eq: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   474   assume i: "i \<in> I"
   475   show "F i = F' i"
   476     using PiE_eq_subset[of I F F', OF ne eq i]
   477     using PiE_eq_subset[of I F' F, OF ne(2,1) eq[symmetric] i]
   478     by auto
   479 qed (auto simp: PiE_def)
   480 
   481 lemma PiE_eq_iff:
   482   "Pi\<^sub>E I F = Pi\<^sub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i) \<or> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
   483 proof (intro iffI disjCI)
   484   assume eq[simp]: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   485   assume "\<not> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
   486   then have "(\<forall>i\<in>I. F i \<noteq> {}) \<and> (\<forall>i\<in>I. F' i \<noteq> {})"
   487     using PiE_eq_empty_iff[of I F] PiE_eq_empty_iff[of I F'] by auto
   488   with PiE_eq_iff_not_empty[of I F F'] show "\<forall>i\<in>I. F i = F' i"
   489     by auto
   490 next
   491   assume "(\<forall>i\<in>I. F i = F' i) \<or> (\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {})"
   492   then show "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   493     using PiE_eq_empty_iff[of I F] PiE_eq_empty_iff[of I F'] by (auto simp: PiE_def)
   494 qed
   495 
   496 lemma extensional_funcset_fun_upd_restricts_rangeI:
   497   "\<forall>y \<in> S. f x \<noteq> f y \<Longrightarrow> f \<in> (insert x S) \<rightarrow>\<^sub>E T \<Longrightarrow> f(x := undefined) \<in> S \<rightarrow>\<^sub>E (T - {f x})"
   498   unfolding extensional_funcset_def extensional_def
   499   apply auto
   500   apply (case_tac "x = xa")
   501   apply auto
   502   done
   503 
   504 lemma extensional_funcset_fun_upd_extends_rangeI:
   505   assumes "a \<in> T" "f \<in> S \<rightarrow>\<^sub>E (T - {a})"
   506   shows "f(x := a) \<in> insert x S \<rightarrow>\<^sub>E  T"
   507   using assms unfolding extensional_funcset_def extensional_def by auto
   508 
   509 
   510 subsubsection \<open>Injective Extensional Function Spaces\<close>
   511 
   512 lemma extensional_funcset_fun_upd_inj_onI:
   513   assumes "f \<in> S \<rightarrow>\<^sub>E (T - {a})"
   514     and "inj_on f S"
   515   shows "inj_on (f(x := a)) S"
   516   using assms
   517   unfolding extensional_funcset_def by (auto intro!: inj_on_fun_updI)
   518 
   519 lemma extensional_funcset_extend_domain_inj_on_eq:
   520   assumes "x \<notin> S"
   521   shows "{f. f \<in> (insert x S) \<rightarrow>\<^sub>E T \<and> inj_on f (insert x S)} =
   522     (\<lambda>(y, g). g(x:=y)) ` {(y, g). y \<in> T \<and> g \<in> S \<rightarrow>\<^sub>E (T - {y}) \<and> inj_on g S}"
   523   using assms
   524   apply (auto del: PiE_I PiE_E)
   525   apply (auto intro: extensional_funcset_fun_upd_inj_onI
   526     extensional_funcset_fun_upd_extends_rangeI del: PiE_I PiE_E)
   527   apply (auto simp add: image_iff inj_on_def)
   528   apply (rule_tac x="xa x" in exI)
   529   apply (auto intro: PiE_mem del: PiE_I PiE_E)
   530   apply (rule_tac x="xa(x := undefined)" in exI)
   531   apply (auto intro!: extensional_funcset_fun_upd_restricts_rangeI)
   532   apply (auto dest!: PiE_mem split: if_split_asm)
   533   done
   534 
   535 lemma extensional_funcset_extend_domain_inj_onI:
   536   assumes "x \<notin> S"
   537   shows "inj_on (\<lambda>(y, g). g(x := y)) {(y, g). y \<in> T \<and> g \<in> S \<rightarrow>\<^sub>E (T - {y}) \<and> inj_on g S}"
   538   using assms
   539   apply (auto intro!: inj_onI)
   540   apply (metis fun_upd_same)
   541   apply (metis assms PiE_arb fun_upd_triv fun_upd_upd)
   542   done
   543 
   544 
   545 subsubsection \<open>Cardinality\<close>
   546 
   547 lemma finite_PiE: "finite S \<Longrightarrow> (\<And>i. i \<in> S \<Longrightarrow> finite (T i)) \<Longrightarrow> finite (\<Pi>\<^sub>E i \<in> S. T i)"
   548   by (induct S arbitrary: T rule: finite_induct) (simp_all add: PiE_insert_eq)
   549 
   550 lemma inj_combinator: "x \<notin> S \<Longrightarrow> inj_on (\<lambda>(y, g). g(x := y)) (T x \<times> Pi\<^sub>E S T)"
   551 proof (safe intro!: inj_onI ext)
   552   fix f y g z
   553   assume "x \<notin> S"
   554   assume fg: "f \<in> Pi\<^sub>E S T" "g \<in> Pi\<^sub>E S T"
   555   assume "f(x := y) = g(x := z)"
   556   then have *: "\<And>i. (f(x := y)) i = (g(x := z)) i"
   557     unfolding fun_eq_iff by auto
   558   from this[of x] show "y = z" by simp
   559   fix i from *[of i] \<open>x \<notin> S\<close> fg show "f i = g i"
   560     by (auto split: if_split_asm simp: PiE_def extensional_def)
   561 qed
   562 
   563 lemma card_PiE: "finite S \<Longrightarrow> card (\<Pi>\<^sub>E i \<in> S. T i) = (\<Prod> i\<in>S. card (T i))"
   564 proof (induct rule: finite_induct)
   565   case empty
   566   then show ?case by auto
   567 next
   568   case (insert x S)
   569   then show ?case
   570     by (simp add: PiE_insert_eq inj_combinator card_image card_cartesian_product)
   571 qed
   572 
   573 end