src/HOL/Orderings.thy
author wenzelm
Wed Feb 28 22:05:43 2007 +0100 (2007-02-28)
changeset 22377 61610b1beedf
parent 22348 ab505d281015
child 22384 33a46e6c7f04
permissions -rw-r--r--
tuned ML setup;
     1 (*  Title:      HOL/Orderings.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     4 *)
     5 
     6 header {* Syntactic and abstract orders *}
     7 
     8 theory Orderings
     9 imports HOL
    10 begin
    11 
    12 subsection {* Order syntax *}
    13 
    14 class ord =
    15   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"  (infix "\<sqsubseteq>" 50)
    16     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"  (infix "\<sqsubset>" 50)
    17 begin
    18 
    19 notation
    20   less_eq  ("op \<^loc><=") and
    21   less_eq  ("(_/ \<^loc><= _)" [51, 51] 50) and
    22   less  ("op \<^loc><") and
    23   less  ("(_/ \<^loc>< _)"  [51, 51] 50)
    24   
    25 notation (xsymbols)
    26   less_eq  ("op \<^loc>\<le>") and
    27   less_eq  ("(_/ \<^loc>\<le> _)"  [51, 51] 50)
    28 
    29 notation (HTML output)
    30   less_eq  ("op \<^loc>\<le>") and
    31   less_eq  ("(_/ \<^loc>\<le> _)"  [51, 51] 50)
    32 
    33 abbreviation (input)
    34   greater  (infix "\<^loc>>" 50) where
    35   "x \<^loc>> y \<equiv> y \<^loc>< x"
    36 
    37 abbreviation (input)
    38   greater_eq  (infix "\<^loc>>=" 50) where
    39   "x \<^loc>>= y \<equiv> y \<^loc><= x"
    40 
    41 notation (input)
    42   greater_eq  (infix "\<^loc>\<ge>" 50)
    43 
    44 end
    45 
    46 notation
    47   less_eq  ("op <=") and
    48   less_eq  ("(_/ <= _)" [51, 51] 50) and
    49   less  ("op <") and
    50   less  ("(_/ < _)"  [51, 51] 50)
    51   
    52 notation (xsymbols)
    53   less_eq  ("op \<le>") and
    54   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
    55 
    56 notation (HTML output)
    57   less_eq  ("op \<le>") and
    58   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
    59 
    60 abbreviation (input)
    61   greater  (infix ">" 50) where
    62   "x > y \<equiv> y < x"
    63 
    64 abbreviation (input)
    65   greater_eq  (infix ">=" 50) where
    66   "x >= y \<equiv> y <= x"
    67 
    68 notation (input)
    69   greater_eq  (infix "\<ge>" 50)
    70 
    71 
    72 subsection {* Quasiorders (preorders) *}
    73 
    74 class preorder = ord +
    75   assumes less_le: "x \<sqsubset> y \<longleftrightarrow> x \<sqsubseteq> y \<and> x \<noteq> y"
    76   and refl [iff]: "x \<sqsubseteq> x"
    77   and trans: "x \<sqsubseteq> y \<Longrightarrow> y \<sqsubseteq> z \<Longrightarrow> x \<sqsubseteq> z"
    78 begin
    79 
    80 text {* Reflexivity. *}
    81 
    82 lemma eq_refl: "x = y \<Longrightarrow> x \<sqsubseteq> y"
    83     -- {* This form is useful with the classical reasoner. *}
    84   by (erule ssubst) (rule refl)
    85 
    86 lemma less_irrefl [iff]: "\<not> x \<sqsubset> x"
    87   by (simp add: less_le)
    88 
    89 lemma le_less: "x \<sqsubseteq> y \<longleftrightarrow> x \<sqsubset> y \<or> x = y"
    90     -- {* NOT suitable for iff, since it can cause PROOF FAILED. *}
    91   by (simp add: less_le) blast
    92 
    93 lemma le_imp_less_or_eq: "x \<sqsubseteq> y \<Longrightarrow> x \<sqsubset> y \<or> x = y"
    94   unfolding less_le by blast
    95 
    96 lemma less_imp_le: "x \<sqsubset> y \<Longrightarrow> x \<sqsubseteq> y"
    97   unfolding less_le by blast
    98 
    99 lemma less_imp_neq: "x \<sqsubset> y \<Longrightarrow> x \<noteq> y"
   100   by (erule contrapos_pn, erule subst, rule less_irrefl)
   101 
   102 
   103 text {* Useful for simplification, but too risky to include by default. *}
   104 
   105 lemma less_imp_not_eq: "x \<sqsubset> y \<Longrightarrow> (x = y) \<longleftrightarrow> False"
   106   by auto
   107 
   108 lemma less_imp_not_eq2: "x \<sqsubset> y \<Longrightarrow> (y = x) \<longleftrightarrow> False"
   109   by auto
   110 
   111 
   112 text {* Transitivity rules for calculational reasoning *}
   113 
   114 lemma neq_le_trans: "\<lbrakk> a \<noteq> b; a \<sqsubseteq> b \<rbrakk> \<Longrightarrow> a \<sqsubset> b"
   115   by (simp add: less_le)
   116 
   117 lemma le_neq_trans: "\<lbrakk> a \<sqsubseteq> b; a \<noteq> b \<rbrakk> \<Longrightarrow> a \<sqsubset> b"
   118   by (simp add: less_le)
   119 
   120 end
   121 
   122 
   123 subsection {* Partial orderings *}
   124 
   125 class order = preorder + 
   126   assumes antisym: "x \<sqsubseteq> y \<Longrightarrow> y \<sqsubseteq> x \<Longrightarrow> x = y"
   127 begin
   128 
   129 text {* Asymmetry. *}
   130 
   131 lemma less_not_sym: "x \<sqsubset> y \<Longrightarrow> \<not> (y \<sqsubset> x)"
   132   by (simp add: less_le antisym)
   133 
   134 lemma less_asym: "x \<sqsubset> y \<Longrightarrow> (\<not> P \<Longrightarrow> y \<sqsubset> x) \<Longrightarrow> P"
   135   by (drule less_not_sym, erule contrapos_np) simp
   136 
   137 lemma eq_iff: "x = y \<longleftrightarrow> x \<sqsubseteq> y \<and> y \<sqsubseteq> x"
   138   by (blast intro: antisym)
   139 
   140 lemma antisym_conv: "y \<sqsubseteq> x \<Longrightarrow> x \<sqsubseteq> y \<longleftrightarrow> x = y"
   141   by (blast intro: antisym)
   142 
   143 lemma less_imp_neq: "x \<sqsubset> y \<Longrightarrow> x \<noteq> y"
   144   by (erule contrapos_pn, erule subst, rule less_irrefl)
   145 
   146 
   147 text {* Transitivity. *}
   148 
   149 lemma less_trans: "\<lbrakk> x \<sqsubset> y; y \<sqsubset> z \<rbrakk> \<Longrightarrow> x \<sqsubset> z"
   150   by (simp add: less_le) (blast intro: trans antisym)
   151 
   152 lemma le_less_trans: "\<lbrakk> x \<sqsubseteq> y; y \<sqsubset> z \<rbrakk> \<Longrightarrow> x \<sqsubset> z"
   153   by (simp add: less_le) (blast intro: trans antisym)
   154 
   155 lemma less_le_trans: "\<lbrakk> x \<sqsubset> y; y \<sqsubseteq> z \<rbrakk> \<Longrightarrow> x \<sqsubset> z"
   156   by (simp add: less_le) (blast intro: trans antisym)
   157 
   158 
   159 text {* Useful for simplification, but too risky to include by default. *}
   160 
   161 lemma less_imp_not_less: "x \<sqsubset> y \<Longrightarrow> (\<not> y \<sqsubset> x) \<longleftrightarrow> True"
   162   by (blast elim: less_asym)
   163 
   164 lemma less_imp_triv: "x \<sqsubset> y \<Longrightarrow> (y \<sqsubset> x \<longrightarrow> P) \<longleftrightarrow> True"
   165   by (blast elim: less_asym)
   166 
   167 
   168 text {* Transitivity rules for calculational reasoning *}
   169 
   170 lemma less_asym': "\<lbrakk> a \<sqsubset> b; b \<sqsubset> a \<rbrakk> \<Longrightarrow> P"
   171   by (rule less_asym)
   172 
   173 end
   174 
   175 
   176 subsection {* Linear (total) orders *}
   177 
   178 class linorder = order +
   179   assumes linear: "x \<sqsubseteq> y \<or> y \<sqsubseteq> x"
   180 begin
   181 
   182 lemma less_linear: "x \<sqsubset> y \<or> x = y \<or> y \<sqsubset> x"
   183   unfolding less_le using less_le linear by blast 
   184 
   185 lemma le_less_linear: "x \<sqsubseteq> y \<or> y \<sqsubset> x"
   186   by (simp add: le_less less_linear)
   187 
   188 lemma le_cases [case_names le ge]:
   189   "\<lbrakk> x \<sqsubseteq> y \<Longrightarrow> P; y \<sqsubseteq> x \<Longrightarrow> P\<rbrakk> \<Longrightarrow> P"
   190   using linear by blast
   191 
   192 lemma cases [case_names less equal greater]:
   193     "\<lbrakk> x \<sqsubset> y \<Longrightarrow> P; x = y \<Longrightarrow> P; y \<sqsubset> x \<Longrightarrow> P\<rbrakk> \<Longrightarrow> P"
   194   using less_linear by blast
   195 
   196 lemma not_less: "\<not> x \<sqsubset> y \<longleftrightarrow> y \<sqsubseteq> x"
   197   apply (simp add: less_le)
   198   using linear apply (blast intro: antisym)
   199   done
   200 
   201 lemma not_le: "\<not> x \<sqsubseteq> y \<longleftrightarrow> y \<sqsubset> x"
   202   apply (simp add: less_le)
   203   using linear apply (blast intro: antisym)
   204   done
   205 
   206 lemma neq_iff: "x \<noteq> y \<longleftrightarrow> x \<sqsubset> y \<or> y \<sqsubset> x"
   207   by (cut_tac x = x and y = y in less_linear, auto)
   208 
   209 lemma neqE: "\<lbrakk> x \<noteq> y; x \<sqsubset> y \<Longrightarrow> R; y \<sqsubset> x \<Longrightarrow> R\<rbrakk> \<Longrightarrow> R"
   210   by (simp add: neq_iff) blast
   211 
   212 lemma antisym_conv1: "\<not> x \<sqsubset> y \<Longrightarrow> x \<sqsubseteq> y \<longleftrightarrow> x = y"
   213   by (blast intro: antisym dest: not_less [THEN iffD1])
   214 
   215 lemma antisym_conv2: "x \<sqsubseteq> y \<Longrightarrow> \<not> x \<sqsubset> y \<longleftrightarrow> x = y"
   216   by (blast intro: antisym dest: not_less [THEN iffD1])
   217 
   218 lemma antisym_conv3: "\<not> y \<sqsubset> x \<Longrightarrow> \<not> x \<sqsubset> y \<longleftrightarrow> x = y"
   219   by (blast intro: antisym dest: not_less [THEN iffD1])
   220 
   221 text{*Replacing the old Nat.leI*}
   222 lemma leI: "\<not> x \<sqsubset> y \<Longrightarrow> y \<sqsubseteq> x"
   223   unfolding not_less .
   224 
   225 lemma leD: "y \<sqsubseteq> x \<Longrightarrow> \<not> x \<sqsubset> y"
   226   unfolding not_less .
   227 
   228 (*FIXME inappropriate name (or delete altogether)*)
   229 lemma not_leE: "\<not> y \<sqsubseteq> x \<Longrightarrow> x \<sqsubset> y"
   230   unfolding not_le .
   231 
   232 (* min/max *)
   233 
   234 definition
   235   min :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   236   "min a b = (if a \<sqsubseteq> b then a else b)"
   237 
   238 definition
   239   max :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   240   "max a b = (if a \<sqsubseteq> b then b else a)"
   241 
   242 lemma min_le_iff_disj:
   243   "min x y \<sqsubseteq> z \<longleftrightarrow> x \<sqsubseteq> z \<or> y \<sqsubseteq> z"
   244   unfolding min_def using linear by (auto intro: trans)
   245 
   246 lemma le_max_iff_disj:
   247   "z \<sqsubseteq> max x y \<longleftrightarrow> z \<sqsubseteq> x \<or> z \<sqsubseteq> y"
   248   unfolding max_def using linear by (auto intro: trans)
   249 
   250 lemma min_less_iff_disj:
   251   "min x y \<sqsubset> z \<longleftrightarrow> x \<sqsubset> z \<or> y \<sqsubset> z"
   252   unfolding min_def le_less using less_linear by (auto intro: less_trans)
   253 
   254 lemma less_max_iff_disj:
   255   "z \<sqsubset> max x y \<longleftrightarrow> z \<sqsubset> x \<or> z \<sqsubset> y"
   256   unfolding max_def le_less using less_linear by (auto intro: less_trans)
   257 
   258 lemma min_less_iff_conj [simp]:
   259   "z \<sqsubset> min x y \<longleftrightarrow> z \<sqsubset> x \<and> z \<sqsubset> y"
   260   unfolding min_def le_less using less_linear by (auto intro: less_trans)
   261 
   262 lemma max_less_iff_conj [simp]:
   263   "max x y \<sqsubset> z \<longleftrightarrow> x \<sqsubset> z \<and> y \<sqsubset> z"
   264   unfolding max_def le_less using less_linear by (auto intro: less_trans)
   265 
   266 lemma split_min:
   267   "P (min i j) \<longleftrightarrow> (i \<sqsubseteq> j \<longrightarrow> P i) \<and> (\<not> i \<sqsubseteq> j \<longrightarrow> P j)"
   268   by (simp add: min_def)
   269 
   270 lemma split_max:
   271   "P (max i j) \<longleftrightarrow> (i \<sqsubseteq> j \<longrightarrow> P j) \<and> (\<not> i \<sqsubseteq> j \<longrightarrow> P i)"
   272   by (simp add: max_def)
   273 
   274 end
   275 
   276 
   277 subsection {* Name duplicates *}
   278 
   279 lemmas order_refl [iff] = preorder_class.refl
   280 lemmas order_trans = preorder_class.trans
   281 lemmas order_less_le = preorder_class.less_le
   282 lemmas order_eq_refl = preorder_class.eq_refl
   283 lemmas order_less_irrefl = preorder_class.less_irrefl
   284 lemmas order_le_less = preorder_class.le_less
   285 lemmas order_le_imp_less_or_eq = preorder_class.le_imp_less_or_eq
   286 lemmas order_less_imp_le = preorder_class.less_imp_le
   287 lemmas order_less_imp_not_eq = preorder_class.less_imp_not_eq
   288 lemmas order_less_imp_not_eq2 = preorder_class.less_imp_not_eq2
   289 lemmas order_neq_le_trans = preorder_class.neq_le_trans
   290 lemmas order_le_neq_trans = preorder_class.le_neq_trans
   291 
   292 lemmas order_antisym = order_class.antisym
   293 lemmas order_less_not_sym = order_class.less_not_sym
   294 lemmas order_less_asym = order_class.less_asym
   295 lemmas order_eq_iff = order_class.eq_iff
   296 lemmas order_antisym_conv = order_class.antisym_conv
   297 lemmas less_imp_neq = order_class.less_imp_neq
   298 lemmas order_less_trans = order_class.less_trans
   299 lemmas order_le_less_trans = order_class.le_less_trans
   300 lemmas order_less_le_trans = order_class.less_le_trans
   301 lemmas order_less_imp_not_less = order_class.less_imp_not_less
   302 lemmas order_less_imp_triv = order_class.less_imp_triv
   303 lemmas order_less_asym' = order_class.less_asym'
   304 
   305 lemmas linorder_linear = linorder_class.linear
   306 lemmas linorder_less_linear = linorder_class.less_linear
   307 lemmas linorder_le_less_linear = linorder_class.le_less_linear
   308 lemmas linorder_le_cases = linorder_class.le_cases
   309 lemmas linorder_cases = linorder_class.cases
   310 lemmas linorder_not_less = linorder_class.not_less
   311 lemmas linorder_not_le = linorder_class.not_le
   312 lemmas linorder_neq_iff = linorder_class.neq_iff
   313 lemmas linorder_neqE = linorder_class.neqE
   314 lemmas linorder_antisym_conv1 = linorder_class.antisym_conv1
   315 lemmas linorder_antisym_conv2 = linorder_class.antisym_conv2
   316 lemmas linorder_antisym_conv3 = linorder_class.antisym_conv3
   317 lemmas leI = linorder_class.leI
   318 lemmas leD = linorder_class.leD
   319 lemmas not_leE = linorder_class.not_leE
   320 
   321 
   322 subsection {* Reasoning tools setup *}
   323 
   324 ML {*
   325 local
   326 
   327 fun decomp_gen sort thy (Trueprop $ t) =
   328   let
   329     fun of_sort t =
   330       let
   331         val T = type_of t
   332       in
   333         (* exclude numeric types: linear arithmetic subsumes transitivity *)
   334         T <> HOLogic.natT andalso T <> HOLogic.intT
   335           andalso T <> HOLogic.realT andalso Sign.of_sort thy (T, sort)
   336       end;
   337     fun dec (Const ("Not", _) $ t) = (case dec t
   338           of NONE => NONE
   339            | SOME (t1, rel, t2) => SOME (t1, "~" ^ rel, t2))
   340       | dec (Const ("op =",  _) $ t1 $ t2) =
   341           if of_sort t1
   342           then SOME (t1, "=", t2)
   343           else NONE
   344       | dec (Const ("Orderings.less_eq",  _) $ t1 $ t2) =
   345           if of_sort t1
   346           then SOME (t1, "<=", t2)
   347           else NONE
   348       | dec (Const ("Orderings.less",  _) $ t1 $ t2) =
   349           if of_sort t1
   350           then SOME (t1, "<", t2)
   351           else NONE
   352       | dec _ = NONE;
   353   in dec t end;
   354 
   355 in
   356 
   357 (* The setting up of Quasi_Tac serves as a demo.  Since there is no
   358    class for quasi orders, the tactics Quasi_Tac.trans_tac and
   359    Quasi_Tac.quasi_tac are not of much use. *)
   360 
   361 structure Quasi_Tac = Quasi_Tac_Fun (
   362 struct
   363   val le_trans = thm "order_trans";
   364   val le_refl = thm "order_refl";
   365   val eqD1 = thm "order_eq_refl";
   366   val eqD2 = thm "sym" RS thm "order_eq_refl";
   367   val less_reflE = thm "order_less_irrefl" RS thm "notE";
   368   val less_imp_le = thm "order_less_imp_le";
   369   val le_neq_trans = thm "order_le_neq_trans";
   370   val neq_le_trans = thm "order_neq_le_trans";
   371   val less_imp_neq = thm "less_imp_neq";
   372   val decomp_trans = decomp_gen ["Orderings.order"];
   373   val decomp_quasi = decomp_gen ["Orderings.order"];
   374 end);
   375 
   376 structure Order_Tac = Order_Tac_Fun (
   377 struct
   378   val less_reflE = thm "order_less_irrefl" RS thm "notE";
   379   val le_refl = thm "order_refl";
   380   val less_imp_le = thm "order_less_imp_le";
   381   val not_lessI = thm "linorder_not_less" RS thm "iffD2";
   382   val not_leI = thm "linorder_not_le" RS thm "iffD2";
   383   val not_lessD = thm "linorder_not_less" RS thm "iffD1";
   384   val not_leD = thm "linorder_not_le" RS thm "iffD1";
   385   val eqI = thm "order_antisym";
   386   val eqD1 = thm "order_eq_refl";
   387   val eqD2 = thm "sym" RS thm "order_eq_refl";
   388   val less_trans = thm "order_less_trans";
   389   val less_le_trans = thm "order_less_le_trans";
   390   val le_less_trans = thm "order_le_less_trans";
   391   val le_trans = thm "order_trans";
   392   val le_neq_trans = thm "order_le_neq_trans";
   393   val neq_le_trans = thm "order_neq_le_trans";
   394   val less_imp_neq = thm "less_imp_neq";
   395   val eq_neq_eq_imp_neq = thm "eq_neq_eq_imp_neq";
   396   val not_sym = thm "not_sym";
   397   val decomp_part = decomp_gen ["Orderings.order"];
   398   val decomp_lin = decomp_gen ["Orderings.linorder"];
   399 end);
   400 
   401 end;
   402 *}
   403 
   404 setup {*
   405 let
   406 
   407 val order_antisym_conv = thm "order_antisym_conv"
   408 val linorder_antisym_conv1 = thm "linorder_antisym_conv1"
   409 val linorder_antisym_conv2 = thm "linorder_antisym_conv2"
   410 val linorder_antisym_conv3 = thm "linorder_antisym_conv3"
   411 
   412 fun prp t thm = (#prop (rep_thm thm) = t);
   413 
   414 fun prove_antisym_le sg ss ((le as Const(_,T)) $ r $ s) =
   415   let val prems = prems_of_ss ss;
   416       val less = Const("Orderings.less",T);
   417       val t = HOLogic.mk_Trueprop(le $ s $ r);
   418   in case find_first (prp t) prems of
   419        NONE =>
   420          let val t = HOLogic.mk_Trueprop(HOLogic.Not $ (less $ r $ s))
   421          in case find_first (prp t) prems of
   422               NONE => NONE
   423             | SOME thm => SOME(mk_meta_eq(thm RS linorder_antisym_conv1))
   424          end
   425      | SOME thm => SOME(mk_meta_eq(thm RS order_antisym_conv))
   426   end
   427   handle THM _ => NONE;
   428 
   429 fun prove_antisym_less sg ss (NotC $ ((less as Const(_,T)) $ r $ s)) =
   430   let val prems = prems_of_ss ss;
   431       val le = Const("Orderings.less_eq",T);
   432       val t = HOLogic.mk_Trueprop(le $ r $ s);
   433   in case find_first (prp t) prems of
   434        NONE =>
   435          let val t = HOLogic.mk_Trueprop(NotC $ (less $ s $ r))
   436          in case find_first (prp t) prems of
   437               NONE => NONE
   438             | SOME thm => SOME(mk_meta_eq(thm RS linorder_antisym_conv3))
   439          end
   440      | SOME thm => SOME(mk_meta_eq(thm RS linorder_antisym_conv2))
   441   end
   442   handle THM _ => NONE;
   443 
   444 fun add_simprocs procs thy =
   445   (Simplifier.change_simpset_of thy (fn ss => ss
   446     addsimprocs (map (fn (name, raw_ts, proc) =>
   447       Simplifier.simproc thy name raw_ts proc)) procs); thy);
   448 fun add_solver name tac thy =
   449   (Simplifier.change_simpset_of thy (fn ss => ss addSolver
   450     (mk_solver name (K tac))); thy);
   451 
   452 in
   453   add_simprocs [
   454        ("antisym le", ["(x::'a::order) <= y"], prove_antisym_le),
   455        ("antisym less", ["~ (x::'a::linorder) < y"], prove_antisym_less)
   456      ]
   457   #> add_solver "Trans_linear" Order_Tac.linear_tac
   458   #> add_solver "Trans_partial" Order_Tac.partial_tac
   459   (* Adding the transitivity reasoners also as safe solvers showed a slight
   460      speed up, but the reasoning strength appears to be not higher (at least
   461      no breaking of additional proofs in the entire HOL distribution, as
   462      of 5 March 2004, was observed). *)
   463 end
   464 *}
   465 
   466 
   467 subsection {* Bounded quantifiers *}
   468 
   469 syntax
   470   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   471   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3EX _<_./ _)"  [0, 0, 10] 10)
   472   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   473   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _<=_./ _)" [0, 0, 10] 10)
   474 
   475   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3ALL _>_./ _)"  [0, 0, 10] 10)
   476   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3EX _>_./ _)"  [0, 0, 10] 10)
   477   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _>=_./ _)" [0, 0, 10] 10)
   478   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _>=_./ _)" [0, 0, 10] 10)
   479 
   480 syntax (xsymbols)
   481   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   482   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   483   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   484   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   485 
   486   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   487   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   488   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   489   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   490 
   491 syntax (HOL)
   492   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3! _<_./ _)"  [0, 0, 10] 10)
   493   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3? _<_./ _)"  [0, 0, 10] 10)
   494   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3! _<=_./ _)" [0, 0, 10] 10)
   495   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3? _<=_./ _)" [0, 0, 10] 10)
   496 
   497 syntax (HTML output)
   498   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   499   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   500   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   501   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   502 
   503   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   504   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   505   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   506   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   507 
   508 translations
   509   "ALL x<y. P"   =>  "ALL x. x < y \<longrightarrow> P"
   510   "EX x<y. P"    =>  "EX x. x < y \<and> P"
   511   "ALL x<=y. P"  =>  "ALL x. x <= y \<longrightarrow> P"
   512   "EX x<=y. P"   =>  "EX x. x <= y \<and> P"
   513   "ALL x>y. P"   =>  "ALL x. x > y \<longrightarrow> P"
   514   "EX x>y. P"    =>  "EX x. x > y \<and> P"
   515   "ALL x>=y. P"  =>  "ALL x. x >= y \<longrightarrow> P"
   516   "EX x>=y. P"   =>  "EX x. x >= y \<and> P"
   517 
   518 print_translation {*
   519 let
   520   val All_binder = Syntax.binder_name @{const_syntax "All"};
   521   val Ex_binder = Syntax.binder_name @{const_syntax "Ex"};
   522   val impl = @{const_syntax "op -->"};
   523   val conj = @{const_syntax "op &"};
   524   val less = @{const_syntax "less"};
   525   val less_eq = @{const_syntax "less_eq"};
   526 
   527   val trans =
   528    [((All_binder, impl, less), ("_All_less", "_All_greater")),
   529     ((All_binder, impl, less_eq), ("_All_less_eq", "_All_greater_eq")),
   530     ((Ex_binder, conj, less), ("_Ex_less", "_Ex_greater")),
   531     ((Ex_binder, conj, less_eq), ("_Ex_less_eq", "_Ex_greater_eq"))];
   532 
   533   fun matches_bound v t = 
   534      case t of (Const ("_bound", _) $ Free (v', _)) => (v = v')
   535               | _ => false
   536   fun contains_var v = Term.exists_subterm (fn Free (x, _) => x = v | _ => false)
   537   fun mk v c n P = Syntax.const c $ Syntax.mark_bound v $ n $ P
   538 
   539   fun tr' q = (q,
   540     fn [Const ("_bound", _) $ Free (v, _), Const (c, _) $ (Const (d, _) $ t $ u) $ P] =>
   541       (case AList.lookup (op =) trans (q, c, d) of
   542         NONE => raise Match
   543       | SOME (l, g) =>
   544           if matches_bound v t andalso not (contains_var v u) then mk v l u P
   545           else if matches_bound v u andalso not (contains_var v t) then mk v g t P
   546           else raise Match)
   547      | _ => raise Match);
   548 in [tr' All_binder, tr' Ex_binder] end
   549 *}
   550 
   551 
   552 subsection {* Transitivity reasoning *}
   553 
   554 lemma ord_le_eq_trans: "a <= b ==> b = c ==> a <= c"
   555   by (rule subst)
   556 
   557 lemma ord_eq_le_trans: "a = b ==> b <= c ==> a <= c"
   558   by (rule ssubst)
   559 
   560 lemma ord_less_eq_trans: "a < b ==> b = c ==> a < c"
   561   by (rule subst)
   562 
   563 lemma ord_eq_less_trans: "a = b ==> b < c ==> a < c"
   564   by (rule ssubst)
   565 
   566 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
   567   (!!x y. x < y ==> f x < f y) ==> f a < c"
   568 proof -
   569   assume r: "!!x y. x < y ==> f x < f y"
   570   assume "a < b" hence "f a < f b" by (rule r)
   571   also assume "f b < c"
   572   finally (order_less_trans) show ?thesis .
   573 qed
   574 
   575 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
   576   (!!x y. x < y ==> f x < f y) ==> a < f c"
   577 proof -
   578   assume r: "!!x y. x < y ==> f x < f y"
   579   assume "a < f b"
   580   also assume "b < c" hence "f b < f c" by (rule r)
   581   finally (order_less_trans) show ?thesis .
   582 qed
   583 
   584 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
   585   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
   586 proof -
   587   assume r: "!!x y. x <= y ==> f x <= f y"
   588   assume "a <= b" hence "f a <= f b" by (rule r)
   589   also assume "f b < c"
   590   finally (order_le_less_trans) show ?thesis .
   591 qed
   592 
   593 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
   594   (!!x y. x < y ==> f x < f y) ==> a < f c"
   595 proof -
   596   assume r: "!!x y. x < y ==> f x < f y"
   597   assume "a <= f b"
   598   also assume "b < c" hence "f b < f c" by (rule r)
   599   finally (order_le_less_trans) show ?thesis .
   600 qed
   601 
   602 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
   603   (!!x y. x < y ==> f x < f y) ==> f a < c"
   604 proof -
   605   assume r: "!!x y. x < y ==> f x < f y"
   606   assume "a < b" hence "f a < f b" by (rule r)
   607   also assume "f b <= c"
   608   finally (order_less_le_trans) show ?thesis .
   609 qed
   610 
   611 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
   612   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
   613 proof -
   614   assume r: "!!x y. x <= y ==> f x <= f y"
   615   assume "a < f b"
   616   also assume "b <= c" hence "f b <= f c" by (rule r)
   617   finally (order_less_le_trans) show ?thesis .
   618 qed
   619 
   620 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
   621   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   622 proof -
   623   assume r: "!!x y. x <= y ==> f x <= f y"
   624   assume "a <= f b"
   625   also assume "b <= c" hence "f b <= f c" by (rule r)
   626   finally (order_trans) show ?thesis .
   627 qed
   628 
   629 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
   630   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   631 proof -
   632   assume r: "!!x y. x <= y ==> f x <= f y"
   633   assume "a <= b" hence "f a <= f b" by (rule r)
   634   also assume "f b <= c"
   635   finally (order_trans) show ?thesis .
   636 qed
   637 
   638 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
   639   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   640 proof -
   641   assume r: "!!x y. x <= y ==> f x <= f y"
   642   assume "a <= b" hence "f a <= f b" by (rule r)
   643   also assume "f b = c"
   644   finally (ord_le_eq_trans) show ?thesis .
   645 qed
   646 
   647 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
   648   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   649 proof -
   650   assume r: "!!x y. x <= y ==> f x <= f y"
   651   assume "a = f b"
   652   also assume "b <= c" hence "f b <= f c" by (rule r)
   653   finally (ord_eq_le_trans) show ?thesis .
   654 qed
   655 
   656 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
   657   (!!x y. x < y ==> f x < f y) ==> f a < c"
   658 proof -
   659   assume r: "!!x y. x < y ==> f x < f y"
   660   assume "a < b" hence "f a < f b" by (rule r)
   661   also assume "f b = c"
   662   finally (ord_less_eq_trans) show ?thesis .
   663 qed
   664 
   665 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
   666   (!!x y. x < y ==> f x < f y) ==> a < f c"
   667 proof -
   668   assume r: "!!x y. x < y ==> f x < f y"
   669   assume "a = f b"
   670   also assume "b < c" hence "f b < f c" by (rule r)
   671   finally (ord_eq_less_trans) show ?thesis .
   672 qed
   673 
   674 text {*
   675   Note that this list of rules is in reverse order of priorities.
   676 *}
   677 
   678 lemmas order_trans_rules [trans] =
   679   order_less_subst2
   680   order_less_subst1
   681   order_le_less_subst2
   682   order_le_less_subst1
   683   order_less_le_subst2
   684   order_less_le_subst1
   685   order_subst2
   686   order_subst1
   687   ord_le_eq_subst
   688   ord_eq_le_subst
   689   ord_less_eq_subst
   690   ord_eq_less_subst
   691   forw_subst
   692   back_subst
   693   rev_mp
   694   mp
   695   order_neq_le_trans
   696   order_le_neq_trans
   697   order_less_trans
   698   order_less_asym'
   699   order_le_less_trans
   700   order_less_le_trans
   701   order_trans
   702   order_antisym
   703   ord_le_eq_trans
   704   ord_eq_le_trans
   705   ord_less_eq_trans
   706   ord_eq_less_trans
   707   trans
   708 
   709 
   710 (* FIXME cleanup *)
   711 
   712 text {* These support proving chains of decreasing inequalities
   713     a >= b >= c ... in Isar proofs. *}
   714 
   715 lemma xt1:
   716   "a = b ==> b > c ==> a > c"
   717   "a > b ==> b = c ==> a > c"
   718   "a = b ==> b >= c ==> a >= c"
   719   "a >= b ==> b = c ==> a >= c"
   720   "(x::'a::order) >= y ==> y >= x ==> x = y"
   721   "(x::'a::order) >= y ==> y >= z ==> x >= z"
   722   "(x::'a::order) > y ==> y >= z ==> x > z"
   723   "(x::'a::order) >= y ==> y > z ==> x > z"
   724   "(a::'a::order) > b ==> b > a ==> ?P"
   725   "(x::'a::order) > y ==> y > z ==> x > z"
   726   "(a::'a::order) >= b ==> a ~= b ==> a > b"
   727   "(a::'a::order) ~= b ==> a >= b ==> a > b"
   728   "a = f b ==> b > c ==> (!!x y. x > y ==> f x > f y) ==> a > f c" 
   729   "a > b ==> f b = c ==> (!!x y. x > y ==> f x > f y) ==> f a > c"
   730   "a = f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   731   "a >= b ==> f b = c ==> (!! x y. x >= y ==> f x >= f y) ==> f a >= c"
   732 by auto
   733 
   734 lemma xt2:
   735   "(a::'a::order) >= f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   736 by (subgoal_tac "f b >= f c", force, force)
   737 
   738 lemma xt3: "(a::'a::order) >= b ==> (f b::'b::order) >= c ==> 
   739     (!!x y. x >= y ==> f x >= f y) ==> f a >= c"
   740 by (subgoal_tac "f a >= f b", force, force)
   741 
   742 lemma xt4: "(a::'a::order) > f b ==> (b::'b::order) >= c ==>
   743   (!!x y. x >= y ==> f x >= f y) ==> a > f c"
   744 by (subgoal_tac "f b >= f c", force, force)
   745 
   746 lemma xt5: "(a::'a::order) > b ==> (f b::'b::order) >= c==>
   747     (!!x y. x > y ==> f x > f y) ==> f a > c"
   748 by (subgoal_tac "f a > f b", force, force)
   749 
   750 lemma xt6: "(a::'a::order) >= f b ==> b > c ==>
   751     (!!x y. x > y ==> f x > f y) ==> a > f c"
   752 by (subgoal_tac "f b > f c", force, force)
   753 
   754 lemma xt7: "(a::'a::order) >= b ==> (f b::'b::order) > c ==>
   755     (!!x y. x >= y ==> f x >= f y) ==> f a > c"
   756 by (subgoal_tac "f a >= f b", force, force)
   757 
   758 lemma xt8: "(a::'a::order) > f b ==> (b::'b::order) > c ==>
   759     (!!x y. x > y ==> f x > f y) ==> a > f c"
   760 by (subgoal_tac "f b > f c", force, force)
   761 
   762 lemma xt9: "(a::'a::order) > b ==> (f b::'b::order) > c ==>
   763     (!!x y. x > y ==> f x > f y) ==> f a > c"
   764 by (subgoal_tac "f a > f b", force, force)
   765 
   766 lemmas xtrans = xt1 xt2 xt3 xt4 xt5 xt6 xt7 xt8 xt9
   767 
   768 (* 
   769   Since "a >= b" abbreviates "b <= a", the abbreviation "..." stands
   770   for the wrong thing in an Isar proof.
   771 
   772   The extra transitivity rules can be used as follows: 
   773 
   774 lemma "(a::'a::order) > z"
   775 proof -
   776   have "a >= b" (is "_ >= ?rhs")
   777     sorry
   778   also have "?rhs >= c" (is "_ >= ?rhs")
   779     sorry
   780   also (xtrans) have "?rhs = d" (is "_ = ?rhs")
   781     sorry
   782   also (xtrans) have "?rhs >= e" (is "_ >= ?rhs")
   783     sorry
   784   also (xtrans) have "?rhs > f" (is "_ > ?rhs")
   785     sorry
   786   also (xtrans) have "?rhs > z"
   787     sorry
   788   finally (xtrans) show ?thesis .
   789 qed
   790 
   791   Alternatively, one can use "declare xtrans [trans]" and then
   792   leave out the "(xtrans)" above.
   793 *)
   794 
   795 subsection {* Order on bool *}
   796 
   797 instance bool :: linorder 
   798   le_bool_def: "P \<le> Q \<equiv> P \<longrightarrow> Q"
   799   less_bool_def: "P < Q \<equiv> P \<le> Q \<and> P \<noteq> Q"
   800   by default (auto simp add: le_bool_def less_bool_def)
   801 
   802 lemma le_boolI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<le> Q"
   803   by (simp add: le_bool_def)
   804 
   805 lemma le_boolI': "P \<longrightarrow> Q \<Longrightarrow> P \<le> Q"
   806   by (simp add: le_bool_def)
   807 
   808 lemma le_boolE: "P \<le> Q \<Longrightarrow> P \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
   809   by (simp add: le_bool_def)
   810 
   811 lemma le_boolD: "P \<le> Q \<Longrightarrow> P \<longrightarrow> Q"
   812   by (simp add: le_bool_def)
   813 
   814 lemma [code func]:
   815   "False \<le> b \<longleftrightarrow> True"
   816   "True \<le> b \<longleftrightarrow> b"
   817   "False < b \<longleftrightarrow> b"
   818   "True < b \<longleftrightarrow> False"
   819   unfolding le_bool_def less_bool_def by simp_all
   820 
   821 subsection {* Monotonicity, syntactic least value operator and min/max *}
   822 
   823 locale mono =
   824   fixes f
   825   assumes mono: "A \<le> B \<Longrightarrow> f A \<le> f B"
   826 
   827 lemmas monoI [intro?] = mono.intro
   828   and monoD [dest?] = mono.mono
   829 
   830 constdefs
   831   Least :: "('a::ord => bool) => 'a"               (binder "LEAST " 10)
   832   "Least P == THE x. P x & (ALL y. P y --> x <= y)"
   833     -- {* We can no longer use LeastM because the latter requires Hilbert-AC. *}
   834 
   835 lemma LeastI2_order:
   836   "[| P (x::'a::order);
   837       !!y. P y ==> x <= y;
   838       !!x. [| P x; ALL y. P y --> x \<le> y |] ==> Q x |]
   839    ==> Q (Least P)"
   840   apply (unfold Least_def)
   841   apply (rule theI2)
   842     apply (blast intro: order_antisym)+
   843   done
   844 
   845 lemma Least_equality:
   846     "[| P (k::'a::order); !!x. P x ==> k <= x |] ==> (LEAST x. P x) = k"
   847   apply (simp add: Least_def)
   848   apply (rule the_equality)
   849   apply (auto intro!: order_antisym)
   850   done
   851 
   852 constdefs
   853   min :: "['a::ord, 'a] => 'a"
   854   "min a b == (if a <= b then a else b)"
   855   max :: "['a::ord, 'a] => 'a"
   856   "max a b == (if a <= b then b else a)"
   857 
   858 lemma min_linorder:
   859   "linorder.min (op \<le> \<Colon> 'a\<Colon>linorder \<Rightarrow> 'a \<Rightarrow> bool) = min"
   860   by rule+ (simp add: min_def linorder_class.min_def)
   861 
   862 lemma max_linorder:
   863   "linorder.max (op \<le> \<Colon> 'a\<Colon>linorder \<Rightarrow> 'a \<Rightarrow> bool) = max"
   864   by rule+ (simp add: max_def linorder_class.max_def)
   865 
   866 lemmas min_le_iff_disj = linorder_class.min_le_iff_disj [unfolded min_linorder]
   867 lemmas le_max_iff_disj = linorder_class.le_max_iff_disj [unfolded max_linorder]
   868 lemmas min_less_iff_disj = linorder_class.min_less_iff_disj [unfolded min_linorder]
   869 lemmas less_max_iff_disj = linorder_class.less_max_iff_disj [unfolded max_linorder]
   870 lemmas min_less_iff_conj [simp] = linorder_class.min_less_iff_conj [unfolded min_linorder]
   871 lemmas max_less_iff_conj [simp] = linorder_class.max_less_iff_conj [unfolded max_linorder]
   872 lemmas split_min = linorder_class.split_min [unfolded min_linorder]
   873 lemmas split_max = linorder_class.split_max [unfolded max_linorder]
   874 
   875 lemma min_leastL: "(!!x. least <= x) ==> min least x = least"
   876   by (simp add: min_def)
   877 
   878 lemma max_leastL: "(!!x. least <= x) ==> max least x = x"
   879   by (simp add: max_def)
   880 
   881 lemma min_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> min x least = least"
   882   apply (simp add: min_def)
   883   apply (blast intro: order_antisym)
   884   done
   885 
   886 lemma max_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> max x least = x"
   887   apply (simp add: max_def)
   888   apply (blast intro: order_antisym)
   889   done
   890 
   891 lemma min_of_mono:
   892     "(!!x y. (f x <= f y) = (x <= y)) ==> min (f m) (f n) = f (min m n)"
   893   by (simp add: min_def)
   894 
   895 lemma max_of_mono:
   896     "(!!x y. (f x <= f y) = (x <= y)) ==> max (f m) (f n) = f (max m n)"
   897   by (simp add: max_def)
   898 
   899 
   900 subsection {* Basic ML bindings *}
   901 
   902 ML {*
   903 val leD = thm "leD";
   904 val leI = thm "leI";
   905 val linorder_neqE = thm "linorder_neqE";
   906 val linorder_neq_iff = thm "linorder_neq_iff";
   907 val linorder_not_le = thm "linorder_not_le";
   908 val linorder_not_less = thm "linorder_not_less";
   909 val monoD = thm "monoD";
   910 val monoI = thm "monoI";
   911 val order_antisym = thm "order_antisym";
   912 val order_less_irrefl = thm "order_less_irrefl";
   913 val order_refl = thm "order_refl";
   914 val order_trans = thm "order_trans";
   915 val split_max = thm "split_max";
   916 val split_min = thm "split_min";
   917 *}
   918 
   919 ML {*
   920 structure HOL =
   921 struct
   922   val thy = theory "HOL";
   923 end;
   924 *}  -- "belongs to theory HOL"
   925 
   926 end