src/HOL/Library/RBT_Impl.thy
author wenzelm
Tue May 15 13:57:39 2018 +0200 (16 months ago)
changeset 68189 6163c90694ef
parent 68109 cebf36c14226
child 68450 41de07c7a0f3
permissions -rw-r--r--
tuned headers;
     1 (*  Title:      HOL/Library/RBT_Impl.thy
     2     Author:     Markus Reiter, TU Muenchen
     3     Author:     Alexander Krauss, TU Muenchen
     4 *)
     5 
     6 section \<open>Implementation of Red-Black Trees\<close>
     7 
     8 theory RBT_Impl
     9 imports Main
    10 begin
    11 
    12 text \<open>
    13   For applications, you should use theory \<open>RBT\<close> which defines
    14   an abstract type of red-black tree obeying the invariant.
    15 \<close>
    16 
    17 subsection \<open>Datatype of RB trees\<close>
    18 
    19 datatype color = R | B
    20 datatype ('a, 'b) rbt = Empty | Branch color "('a, 'b) rbt" 'a 'b "('a, 'b) rbt"
    21 
    22 lemma rbt_cases:
    23   obtains (Empty) "t = Empty" 
    24   | (Red) l k v r where "t = Branch R l k v r" 
    25   | (Black) l k v r where "t = Branch B l k v r"
    26 proof (cases t)
    27   case Empty with that show thesis by blast
    28 next
    29   case (Branch c) with that show thesis by (cases c) blast+
    30 qed
    31 
    32 subsection \<open>Tree properties\<close>
    33 
    34 subsubsection \<open>Content of a tree\<close>
    35 
    36 primrec entries :: "('a, 'b) rbt \<Rightarrow> ('a \<times> 'b) list"
    37 where 
    38   "entries Empty = []"
    39 | "entries (Branch _ l k v r) = entries l @ (k,v) # entries r"
    40 
    41 abbreviation (input) entry_in_tree :: "'a \<Rightarrow> 'b \<Rightarrow> ('a, 'b) rbt \<Rightarrow> bool"
    42 where
    43   "entry_in_tree k v t \<equiv> (k, v) \<in> set (entries t)"
    44 
    45 definition keys :: "('a, 'b) rbt \<Rightarrow> 'a list" where
    46   "keys t = map fst (entries t)"
    47 
    48 lemma keys_simps [simp, code]:
    49   "keys Empty = []"
    50   "keys (Branch c l k v r) = keys l @ k # keys r"
    51   by (simp_all add: keys_def)
    52 
    53 lemma entry_in_tree_keys:
    54   assumes "(k, v) \<in> set (entries t)"
    55   shows "k \<in> set (keys t)"
    56 proof -
    57   from assms have "fst (k, v) \<in> fst ` set (entries t)" by (rule imageI)
    58   then show ?thesis by (simp add: keys_def)
    59 qed
    60 
    61 lemma keys_entries:
    62   "k \<in> set (keys t) \<longleftrightarrow> (\<exists>v. (k, v) \<in> set (entries t))"
    63   by (auto intro: entry_in_tree_keys) (auto simp add: keys_def)
    64 
    65 lemma non_empty_rbt_keys: 
    66   "t \<noteq> rbt.Empty \<Longrightarrow> keys t \<noteq> []"
    67   by (cases t) simp_all
    68 
    69 subsubsection \<open>Search tree properties\<close>
    70 
    71 context ord begin
    72 
    73 definition rbt_less :: "'a \<Rightarrow> ('a, 'b) rbt \<Rightarrow> bool"
    74 where
    75   rbt_less_prop: "rbt_less k t \<longleftrightarrow> (\<forall>x\<in>set (keys t). x < k)"
    76 
    77 abbreviation rbt_less_symbol (infix "|\<guillemotleft>" 50)
    78 where "t |\<guillemotleft> x \<equiv> rbt_less x t"
    79 
    80 definition rbt_greater :: "'a \<Rightarrow> ('a, 'b) rbt \<Rightarrow> bool" (infix "\<guillemotleft>|" 50) 
    81 where
    82   rbt_greater_prop: "rbt_greater k t = (\<forall>x\<in>set (keys t). k < x)"
    83 
    84 lemma rbt_less_simps [simp]:
    85   "Empty |\<guillemotleft> k = True"
    86   "Branch c lt kt v rt |\<guillemotleft> k \<longleftrightarrow> kt < k \<and> lt |\<guillemotleft> k \<and> rt |\<guillemotleft> k"
    87   by (auto simp add: rbt_less_prop)
    88 
    89 lemma rbt_greater_simps [simp]:
    90   "k \<guillemotleft>| Empty = True"
    91   "k \<guillemotleft>| (Branch c lt kt v rt) \<longleftrightarrow> k < kt \<and> k \<guillemotleft>| lt \<and> k \<guillemotleft>| rt"
    92   by (auto simp add: rbt_greater_prop)
    93 
    94 lemmas rbt_ord_props = rbt_less_prop rbt_greater_prop
    95 
    96 lemmas rbt_greater_nit = rbt_greater_prop entry_in_tree_keys
    97 lemmas rbt_less_nit = rbt_less_prop entry_in_tree_keys
    98 
    99 lemma (in order)
   100   shows rbt_less_eq_trans: "l |\<guillemotleft> u \<Longrightarrow> u \<le> v \<Longrightarrow> l |\<guillemotleft> v"
   101   and rbt_less_trans: "t |\<guillemotleft> x \<Longrightarrow> x < y \<Longrightarrow> t |\<guillemotleft> y"
   102   and rbt_greater_eq_trans: "u \<le> v \<Longrightarrow> v \<guillemotleft>| r \<Longrightarrow> u \<guillemotleft>| r"
   103   and rbt_greater_trans: "x < y \<Longrightarrow> y \<guillemotleft>| t \<Longrightarrow> x \<guillemotleft>| t"
   104   by (auto simp: rbt_ord_props)
   105 
   106 primrec rbt_sorted :: "('a, 'b) rbt \<Rightarrow> bool"
   107 where
   108   "rbt_sorted Empty = True"
   109 | "rbt_sorted (Branch c l k v r) = (l |\<guillemotleft> k \<and> k \<guillemotleft>| r \<and> rbt_sorted l \<and> rbt_sorted r)"
   110 
   111 end
   112 
   113 context linorder begin
   114 
   115 lemma rbt_sorted_entries:
   116   "rbt_sorted t \<Longrightarrow> List.sorted (map fst (entries t))"
   117 by (induct t)  (force simp: sorted_append rbt_ord_props dest!: entry_in_tree_keys)+
   118 
   119 lemma distinct_entries:
   120   "rbt_sorted t \<Longrightarrow> distinct (map fst (entries t))"
   121 by (induct t) (force simp: sorted_append rbt_ord_props dest!: entry_in_tree_keys)+
   122 
   123 lemma distinct_keys:
   124   "rbt_sorted t \<Longrightarrow> distinct (keys t)"
   125   by (simp add: distinct_entries keys_def)
   126 
   127 
   128 subsubsection \<open>Tree lookup\<close>
   129 
   130 primrec (in ord) rbt_lookup :: "('a, 'b) rbt \<Rightarrow> 'a \<rightharpoonup> 'b"
   131 where
   132   "rbt_lookup Empty k = None"
   133 | "rbt_lookup (Branch _ l x y r) k = 
   134    (if k < x then rbt_lookup l k else if x < k then rbt_lookup r k else Some y)"
   135 
   136 lemma rbt_lookup_keys: "rbt_sorted t \<Longrightarrow> dom (rbt_lookup t) = set (keys t)"
   137   by (induct t) (auto simp: dom_def rbt_greater_prop rbt_less_prop)
   138 
   139 lemma dom_rbt_lookup_Branch: 
   140   "rbt_sorted (Branch c t1 k v t2) \<Longrightarrow> 
   141     dom (rbt_lookup (Branch c t1 k v t2)) 
   142     = Set.insert k (dom (rbt_lookup t1) \<union> dom (rbt_lookup t2))"
   143 proof -
   144   assume "rbt_sorted (Branch c t1 k v t2)"
   145   then show ?thesis by (simp add: rbt_lookup_keys)
   146 qed
   147 
   148 lemma finite_dom_rbt_lookup [simp, intro!]: "finite (dom (rbt_lookup t))"
   149 proof (induct t)
   150   case Empty then show ?case by simp
   151 next
   152   case (Branch color t1 a b t2)
   153   let ?A = "Set.insert a (dom (rbt_lookup t1) \<union> dom (rbt_lookup t2))"
   154   have "dom (rbt_lookup (Branch color t1 a b t2)) \<subseteq> ?A" by (auto split: if_split_asm)
   155   moreover from Branch have "finite (insert a (dom (rbt_lookup t1) \<union> dom (rbt_lookup t2)))" by simp
   156   ultimately show ?case by (rule finite_subset)
   157 qed 
   158 
   159 end
   160 
   161 context ord begin
   162 
   163 lemma rbt_lookup_rbt_less[simp]: "t |\<guillemotleft> k \<Longrightarrow> rbt_lookup t k = None" 
   164 by (induct t) auto
   165 
   166 lemma rbt_lookup_rbt_greater[simp]: "k \<guillemotleft>| t \<Longrightarrow> rbt_lookup t k = None"
   167 by (induct t) auto
   168 
   169 lemma rbt_lookup_Empty: "rbt_lookup Empty = empty"
   170 by (rule ext) simp
   171 
   172 end
   173 
   174 context linorder begin
   175 
   176 lemma map_of_entries:
   177   "rbt_sorted t \<Longrightarrow> map_of (entries t) = rbt_lookup t"
   178 proof (induct t)
   179   case Empty thus ?case by (simp add: rbt_lookup_Empty)
   180 next
   181   case (Branch c t1 k v t2)
   182   have "rbt_lookup (Branch c t1 k v t2) = rbt_lookup t2 ++ [k\<mapsto>v] ++ rbt_lookup t1"
   183   proof (rule ext)
   184     fix x
   185     from Branch have RBT_SORTED: "rbt_sorted (Branch c t1 k v t2)" by simp
   186     let ?thesis = "rbt_lookup (Branch c t1 k v t2) x = (rbt_lookup t2 ++ [k \<mapsto> v] ++ rbt_lookup t1) x"
   187 
   188     have DOM_T1: "!!k'. k'\<in>dom (rbt_lookup t1) \<Longrightarrow> k>k'"
   189     proof -
   190       fix k'
   191       from RBT_SORTED have "t1 |\<guillemotleft> k" by simp
   192       with rbt_less_prop have "\<forall>k'\<in>set (keys t1). k>k'" by auto
   193       moreover assume "k'\<in>dom (rbt_lookup t1)"
   194       ultimately show "k>k'" using rbt_lookup_keys RBT_SORTED by auto
   195     qed
   196     
   197     have DOM_T2: "!!k'. k'\<in>dom (rbt_lookup t2) \<Longrightarrow> k<k'"
   198     proof -
   199       fix k'
   200       from RBT_SORTED have "k \<guillemotleft>| t2" by simp
   201       with rbt_greater_prop have "\<forall>k'\<in>set (keys t2). k<k'" by auto
   202       moreover assume "k'\<in>dom (rbt_lookup t2)"
   203       ultimately show "k<k'" using rbt_lookup_keys RBT_SORTED by auto
   204     qed
   205     
   206     {
   207       assume C: "x<k"
   208       hence "rbt_lookup (Branch c t1 k v t2) x = rbt_lookup t1 x" by simp
   209       moreover from C have "x\<notin>dom [k\<mapsto>v]" by simp
   210       moreover have "x \<notin> dom (rbt_lookup t2)"
   211       proof
   212         assume "x \<in> dom (rbt_lookup t2)"
   213         with DOM_T2 have "k<x" by blast
   214         with C show False by simp
   215       qed
   216       ultimately have ?thesis by (simp add: map_add_upd_left map_add_dom_app_simps)
   217     } moreover {
   218       assume [simp]: "x=k"
   219       hence "rbt_lookup (Branch c t1 k v t2) x = [k \<mapsto> v] x" by simp
   220       moreover have "x \<notin> dom (rbt_lookup t1)" 
   221       proof
   222         assume "x \<in> dom (rbt_lookup t1)"
   223         with DOM_T1 have "k>x" by blast
   224         thus False by simp
   225       qed
   226       ultimately have ?thesis by (simp add: map_add_upd_left map_add_dom_app_simps)
   227     } moreover {
   228       assume C: "x>k"
   229       hence "rbt_lookup (Branch c t1 k v t2) x = rbt_lookup t2 x" by (simp add: less_not_sym[of k x])
   230       moreover from C have "x\<notin>dom [k\<mapsto>v]" by simp
   231       moreover have "x\<notin>dom (rbt_lookup t1)" proof
   232         assume "x\<in>dom (rbt_lookup t1)"
   233         with DOM_T1 have "k>x" by simp
   234         with C show False by simp
   235       qed
   236       ultimately have ?thesis by (simp add: map_add_upd_left map_add_dom_app_simps)
   237     } ultimately show ?thesis using less_linear by blast
   238   qed
   239   also from Branch 
   240   have "rbt_lookup t2 ++ [k \<mapsto> v] ++ rbt_lookup t1 = map_of (entries (Branch c t1 k v t2))" by simp
   241   finally show ?case by simp
   242 qed
   243 
   244 lemma rbt_lookup_in_tree: "rbt_sorted t \<Longrightarrow> rbt_lookup t k = Some v \<longleftrightarrow> (k, v) \<in> set (entries t)"
   245   by (simp add: map_of_entries [symmetric] distinct_entries)
   246 
   247 lemma set_entries_inject:
   248   assumes rbt_sorted: "rbt_sorted t1" "rbt_sorted t2" 
   249   shows "set (entries t1) = set (entries t2) \<longleftrightarrow> entries t1 = entries t2"
   250 proof -
   251   from rbt_sorted have "distinct (map fst (entries t1))"
   252     "distinct (map fst (entries t2))"
   253     by (auto intro: distinct_entries)
   254   with rbt_sorted show ?thesis
   255     by (auto intro: map_sorted_distinct_set_unique rbt_sorted_entries simp add: distinct_map)
   256 qed
   257 
   258 lemma entries_eqI:
   259   assumes rbt_sorted: "rbt_sorted t1" "rbt_sorted t2" 
   260   assumes rbt_lookup: "rbt_lookup t1 = rbt_lookup t2"
   261   shows "entries t1 = entries t2"
   262 proof -
   263   from rbt_sorted rbt_lookup have "map_of (entries t1) = map_of (entries t2)"
   264     by (simp add: map_of_entries)
   265   with rbt_sorted have "set (entries t1) = set (entries t2)"
   266     by (simp add: map_of_inject_set distinct_entries)
   267   with rbt_sorted show ?thesis by (simp add: set_entries_inject)
   268 qed
   269 
   270 lemma entries_rbt_lookup:
   271   assumes "rbt_sorted t1" "rbt_sorted t2" 
   272   shows "entries t1 = entries t2 \<longleftrightarrow> rbt_lookup t1 = rbt_lookup t2"
   273   using assms by (auto intro: entries_eqI simp add: map_of_entries [symmetric])
   274 
   275 lemma rbt_lookup_from_in_tree: 
   276   assumes "rbt_sorted t1" "rbt_sorted t2" 
   277   and "\<And>v. (k, v) \<in> set (entries t1) \<longleftrightarrow> (k, v) \<in> set (entries t2)" 
   278   shows "rbt_lookup t1 k = rbt_lookup t2 k"
   279 proof -
   280   from assms have "k \<in> dom (rbt_lookup t1) \<longleftrightarrow> k \<in> dom (rbt_lookup t2)"
   281     by (simp add: keys_entries rbt_lookup_keys)
   282   with assms show ?thesis by (auto simp add: rbt_lookup_in_tree [symmetric])
   283 qed
   284 
   285 end
   286 
   287 subsubsection \<open>Red-black properties\<close>
   288 
   289 primrec color_of :: "('a, 'b) rbt \<Rightarrow> color"
   290 where
   291   "color_of Empty = B"
   292 | "color_of (Branch c _ _ _ _) = c"
   293 
   294 primrec bheight :: "('a,'b) rbt \<Rightarrow> nat"
   295 where
   296   "bheight Empty = 0"
   297 | "bheight (Branch c lt k v rt) = (if c = B then Suc (bheight lt) else bheight lt)"
   298 
   299 primrec inv1 :: "('a, 'b) rbt \<Rightarrow> bool"
   300 where
   301   "inv1 Empty = True"
   302 | "inv1 (Branch c lt k v rt) \<longleftrightarrow> inv1 lt \<and> inv1 rt \<and> (c = B \<or> color_of lt = B \<and> color_of rt = B)"
   303 
   304 primrec inv1l :: "('a, 'b) rbt \<Rightarrow> bool" \<comment> \<open>Weaker version\<close>
   305 where
   306   "inv1l Empty = True"
   307 | "inv1l (Branch c l k v r) = (inv1 l \<and> inv1 r)"
   308 lemma [simp]: "inv1 t \<Longrightarrow> inv1l t" by (cases t) simp+
   309 
   310 primrec inv2 :: "('a, 'b) rbt \<Rightarrow> bool"
   311 where
   312   "inv2 Empty = True"
   313 | "inv2 (Branch c lt k v rt) = (inv2 lt \<and> inv2 rt \<and> bheight lt = bheight rt)"
   314 
   315 context ord begin
   316 
   317 definition is_rbt :: "('a, 'b) rbt \<Rightarrow> bool" where
   318   "is_rbt t \<longleftrightarrow> inv1 t \<and> inv2 t \<and> color_of t = B \<and> rbt_sorted t"
   319 
   320 lemma is_rbt_rbt_sorted [simp]:
   321   "is_rbt t \<Longrightarrow> rbt_sorted t" by (simp add: is_rbt_def)
   322 
   323 theorem Empty_is_rbt [simp]:
   324   "is_rbt Empty" by (simp add: is_rbt_def)
   325 
   326 end
   327 
   328 subsection \<open>Insertion\<close>
   329 
   330 text \<open>The function definitions are based on the book by Okasaki.\<close>
   331 
   332 fun (* slow, due to massive case splitting *)
   333   balance :: "('a,'b) rbt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> ('a,'b) rbt \<Rightarrow> ('a,'b) rbt"
   334 where
   335   "balance (Branch R a w x b) s t (Branch R c y z d) = Branch R (Branch B a w x b) s t (Branch B c y z d)" |
   336   "balance (Branch R (Branch R a w x b) s t c) y z d = Branch R (Branch B a w x b) s t (Branch B c y z d)" |
   337   "balance (Branch R a w x (Branch R b s t c)) y z d = Branch R (Branch B a w x b) s t (Branch B c y z d)" |
   338   "balance a w x (Branch R b s t (Branch R c y z d)) = Branch R (Branch B a w x b) s t (Branch B c y z d)" |
   339   "balance a w x (Branch R (Branch R b s t c) y z d) = Branch R (Branch B a w x b) s t (Branch B c y z d)" |
   340   "balance a s t b = Branch B a s t b"
   341 
   342 lemma balance_inv1: "\<lbrakk>inv1l l; inv1l r\<rbrakk> \<Longrightarrow> inv1 (balance l k v r)" 
   343   by (induct l k v r rule: balance.induct) auto
   344 
   345 lemma balance_bheight: "bheight l = bheight r \<Longrightarrow> bheight (balance l k v r) = Suc (bheight l)"
   346   by (induct l k v r rule: balance.induct) auto
   347 
   348 lemma balance_inv2: 
   349   assumes "inv2 l" "inv2 r" "bheight l = bheight r"
   350   shows "inv2 (balance l k v r)"
   351   using assms
   352   by (induct l k v r rule: balance.induct) auto
   353 
   354 context ord begin
   355 
   356 lemma balance_rbt_greater[simp]: "(v \<guillemotleft>| balance a k x b) = (v \<guillemotleft>| a \<and> v \<guillemotleft>| b \<and> v < k)" 
   357   by (induct a k x b rule: balance.induct) auto
   358 
   359 lemma balance_rbt_less[simp]: "(balance a k x b |\<guillemotleft> v) = (a |\<guillemotleft> v \<and> b |\<guillemotleft> v \<and> k < v)"
   360   by (induct a k x b rule: balance.induct) auto
   361 
   362 end
   363 
   364 lemma (in linorder) balance_rbt_sorted: 
   365   fixes k :: "'a"
   366   assumes "rbt_sorted l" "rbt_sorted r" "l |\<guillemotleft> k" "k \<guillemotleft>| r"
   367   shows "rbt_sorted (balance l k v r)"
   368 using assms proof (induct l k v r rule: balance.induct)
   369   case ("2_2" a x w b y t c z s va vb vd vc)
   370   hence "y < z \<and> z \<guillemotleft>| Branch B va vb vd vc" 
   371     by (auto simp add: rbt_ord_props)
   372   hence "y \<guillemotleft>| (Branch B va vb vd vc)" by (blast dest: rbt_greater_trans)
   373   with "2_2" show ?case by simp
   374 next
   375   case ("3_2" va vb vd vc x w b y s c z)
   376   from "3_2" have "x < y \<and> Branch B va vb vd vc |\<guillemotleft> x" 
   377     by simp
   378   hence "Branch B va vb vd vc |\<guillemotleft> y" by (blast dest: rbt_less_trans)
   379   with "3_2" show ?case by simp
   380 next
   381   case ("3_3" x w b y s c z t va vb vd vc)
   382   from "3_3" have "y < z \<and> z \<guillemotleft>| Branch B va vb vd vc" by simp
   383   hence "y \<guillemotleft>| Branch B va vb vd vc" by (blast dest: rbt_greater_trans)
   384   with "3_3" show ?case by simp
   385 next
   386   case ("3_4" vd ve vg vf x w b y s c z t va vb vii vc)
   387   hence "x < y \<and> Branch B vd ve vg vf |\<guillemotleft> x" by simp
   388   hence 1: "Branch B vd ve vg vf |\<guillemotleft> y" by (blast dest: rbt_less_trans)
   389   from "3_4" have "y < z \<and> z \<guillemotleft>| Branch B va vb vii vc" by simp
   390   hence "y \<guillemotleft>| Branch B va vb vii vc" by (blast dest: rbt_greater_trans)
   391   with 1 "3_4" show ?case by simp
   392 next
   393   case ("4_2" va vb vd vc x w b y s c z t dd)
   394   hence "x < y \<and> Branch B va vb vd vc |\<guillemotleft> x" by simp
   395   hence "Branch B va vb vd vc |\<guillemotleft> y" by (blast dest: rbt_less_trans)
   396   with "4_2" show ?case by simp
   397 next
   398   case ("5_2" x w b y s c z t va vb vd vc)
   399   hence "y < z \<and> z \<guillemotleft>| Branch B va vb vd vc" by simp
   400   hence "y \<guillemotleft>| Branch B va vb vd vc" by (blast dest: rbt_greater_trans)
   401   with "5_2" show ?case by simp
   402 next
   403   case ("5_3" va vb vd vc x w b y s c z t)
   404   hence "x < y \<and> Branch B va vb vd vc |\<guillemotleft> x" by simp
   405   hence "Branch B va vb vd vc |\<guillemotleft> y" by (blast dest: rbt_less_trans)
   406   with "5_3" show ?case by simp
   407 next
   408   case ("5_4" va vb vg vc x w b y s c z t vd ve vii vf)
   409   hence "x < y \<and> Branch B va vb vg vc |\<guillemotleft> x" by simp
   410   hence 1: "Branch B va vb vg vc |\<guillemotleft> y" by (blast dest: rbt_less_trans)
   411   from "5_4" have "y < z \<and> z \<guillemotleft>| Branch B vd ve vii vf" by simp
   412   hence "y \<guillemotleft>| Branch B vd ve vii vf" by (blast dest: rbt_greater_trans)
   413   with 1 "5_4" show ?case by simp
   414 qed simp+
   415 
   416 lemma entries_balance [simp]:
   417   "entries (balance l k v r) = entries l @ (k, v) # entries r"
   418   by (induct l k v r rule: balance.induct) auto
   419 
   420 lemma keys_balance [simp]: 
   421   "keys (balance l k v r) = keys l @ k # keys r"
   422   by (simp add: keys_def)
   423 
   424 lemma balance_in_tree:  
   425   "entry_in_tree k x (balance l v y r) \<longleftrightarrow> entry_in_tree k x l \<or> k = v \<and> x = y \<or> entry_in_tree k x r"
   426   by (auto simp add: keys_def)
   427 
   428 lemma (in linorder) rbt_lookup_balance[simp]: 
   429 fixes k :: "'a"
   430 assumes "rbt_sorted l" "rbt_sorted r" "l |\<guillemotleft> k" "k \<guillemotleft>| r"
   431 shows "rbt_lookup (balance l k v r) x = rbt_lookup (Branch B l k v r) x"
   432 by (rule rbt_lookup_from_in_tree) (auto simp:assms balance_in_tree balance_rbt_sorted)
   433 
   434 primrec paint :: "color \<Rightarrow> ('a,'b) rbt \<Rightarrow> ('a,'b) rbt"
   435 where
   436   "paint c Empty = Empty"
   437 | "paint c (Branch _ l k v r) = Branch c l k v r"
   438 
   439 lemma paint_inv1l[simp]: "inv1l t \<Longrightarrow> inv1l (paint c t)" by (cases t) auto
   440 lemma paint_inv1[simp]: "inv1l t \<Longrightarrow> inv1 (paint B t)" by (cases t) auto
   441 lemma paint_inv2[simp]: "inv2 t \<Longrightarrow> inv2 (paint c t)" by (cases t) auto
   442 lemma paint_color_of[simp]: "color_of (paint B t) = B" by (cases t) auto
   443 lemma paint_in_tree[simp]: "entry_in_tree k x (paint c t) = entry_in_tree k x t" by (cases t) auto
   444 
   445 context ord begin
   446 
   447 lemma paint_rbt_sorted[simp]: "rbt_sorted t \<Longrightarrow> rbt_sorted (paint c t)" by (cases t) auto
   448 lemma paint_rbt_lookup[simp]: "rbt_lookup (paint c t) = rbt_lookup t" by (rule ext) (cases t, auto)
   449 lemma paint_rbt_greater[simp]: "(v \<guillemotleft>| paint c t) = (v \<guillemotleft>| t)" by (cases t) auto
   450 lemma paint_rbt_less[simp]: "(paint c t |\<guillemotleft> v) = (t |\<guillemotleft> v)" by (cases t) auto
   451 
   452 fun
   453   rbt_ins :: "('a \<Rightarrow> 'b \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> ('a,'b) rbt \<Rightarrow> ('a,'b) rbt"
   454 where
   455   "rbt_ins f k v Empty = Branch R Empty k v Empty" |
   456   "rbt_ins f k v (Branch B l x y r) = (if k < x then balance (rbt_ins f k v l) x y r
   457                                        else if k > x then balance l x y (rbt_ins f k v r)
   458                                        else Branch B l x (f k y v) r)" |
   459   "rbt_ins f k v (Branch R l x y r) = (if k < x then Branch R (rbt_ins f k v l) x y r
   460                                        else if k > x then Branch R l x y (rbt_ins f k v r)
   461                                        else Branch R l x (f k y v) r)"
   462 
   463 lemma ins_inv1_inv2: 
   464   assumes "inv1 t" "inv2 t"
   465   shows "inv2 (rbt_ins f k x t)" "bheight (rbt_ins f k x t) = bheight t" 
   466   "color_of t = B \<Longrightarrow> inv1 (rbt_ins f k x t)" "inv1l (rbt_ins f k x t)"
   467   using assms
   468   by (induct f k x t rule: rbt_ins.induct) (auto simp: balance_inv1 balance_inv2 balance_bheight)
   469 
   470 end
   471 
   472 context linorder begin
   473 
   474 lemma ins_rbt_greater[simp]: "(v \<guillemotleft>| rbt_ins f (k :: 'a) x t) = (v \<guillemotleft>| t \<and> k > v)"
   475   by (induct f k x t rule: rbt_ins.induct) auto
   476 lemma ins_rbt_less[simp]: "(rbt_ins f k x t |\<guillemotleft> v) = (t |\<guillemotleft> v \<and> k < v)"
   477   by (induct f k x t rule: rbt_ins.induct) auto
   478 lemma ins_rbt_sorted[simp]: "rbt_sorted t \<Longrightarrow> rbt_sorted (rbt_ins f k x t)"
   479   by (induct f k x t rule: rbt_ins.induct) (auto simp: balance_rbt_sorted)
   480 
   481 lemma keys_ins: "set (keys (rbt_ins f k v t)) = { k } \<union> set (keys t)"
   482   by (induct f k v t rule: rbt_ins.induct) auto
   483 
   484 lemma rbt_lookup_ins: 
   485   fixes k :: "'a"
   486   assumes "rbt_sorted t"
   487   shows "rbt_lookup (rbt_ins f k v t) x = ((rbt_lookup t)(k |-> case rbt_lookup t k of None \<Rightarrow> v 
   488                                                                 | Some w \<Rightarrow> f k w v)) x"
   489 using assms by (induct f k v t rule: rbt_ins.induct) auto
   490 
   491 end
   492 
   493 context ord begin
   494 
   495 definition rbt_insert_with_key :: "('a \<Rightarrow> 'b \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> ('a,'b) rbt \<Rightarrow> ('a,'b) rbt"
   496 where "rbt_insert_with_key f k v t = paint B (rbt_ins f k v t)"
   497 
   498 definition rbt_insertw_def: "rbt_insert_with f = rbt_insert_with_key (\<lambda>_. f)"
   499 
   500 definition rbt_insert :: "'a \<Rightarrow> 'b \<Rightarrow> ('a, 'b) rbt \<Rightarrow> ('a, 'b) rbt" where
   501   "rbt_insert = rbt_insert_with_key (\<lambda>_ _ nv. nv)"
   502 
   503 end
   504 
   505 context linorder begin
   506 
   507 lemma rbt_insertwk_rbt_sorted: "rbt_sorted t \<Longrightarrow> rbt_sorted (rbt_insert_with_key f (k :: 'a) x t)"
   508   by (auto simp: rbt_insert_with_key_def)
   509 
   510 theorem rbt_insertwk_is_rbt: 
   511   assumes inv: "is_rbt t" 
   512   shows "is_rbt (rbt_insert_with_key f k x t)"
   513 using assms
   514 unfolding rbt_insert_with_key_def is_rbt_def
   515 by (auto simp: ins_inv1_inv2)
   516 
   517 lemma rbt_lookup_rbt_insertwk: 
   518   assumes "rbt_sorted t"
   519   shows "rbt_lookup (rbt_insert_with_key f k v t) x = ((rbt_lookup t)(k |-> case rbt_lookup t k of None \<Rightarrow> v 
   520                                                        | Some w \<Rightarrow> f k w v)) x"
   521 unfolding rbt_insert_with_key_def using assms
   522 by (simp add:rbt_lookup_ins)
   523 
   524 lemma rbt_insertw_rbt_sorted: "rbt_sorted t \<Longrightarrow> rbt_sorted (rbt_insert_with f k v t)" 
   525   by (simp add: rbt_insertwk_rbt_sorted rbt_insertw_def)
   526 theorem rbt_insertw_is_rbt: "is_rbt t \<Longrightarrow> is_rbt (rbt_insert_with f k v t)"
   527   by (simp add: rbt_insertwk_is_rbt rbt_insertw_def)
   528 
   529 lemma rbt_lookup_rbt_insertw:
   530   "is_rbt t \<Longrightarrow>
   531     rbt_lookup (rbt_insert_with f k v t) =
   532       (rbt_lookup t)(k \<mapsto> (if k \<in> dom (rbt_lookup t) then f (the (rbt_lookup t k)) v else v))"
   533   by (rule ext, cases "rbt_lookup t k") (auto simp: rbt_lookup_rbt_insertwk dom_def rbt_insertw_def)
   534 
   535 lemma rbt_insert_rbt_sorted: "rbt_sorted t \<Longrightarrow> rbt_sorted (rbt_insert k v t)"
   536   by (simp add: rbt_insertwk_rbt_sorted rbt_insert_def)
   537 theorem rbt_insert_is_rbt [simp]: "is_rbt t \<Longrightarrow> is_rbt (rbt_insert k v t)"
   538   by (simp add: rbt_insertwk_is_rbt rbt_insert_def)
   539 
   540 lemma rbt_lookup_rbt_insert: "is_rbt t \<Longrightarrow> rbt_lookup (rbt_insert k v t) = (rbt_lookup t)(k\<mapsto>v)"
   541   by (rule ext) (simp add: rbt_insert_def rbt_lookup_rbt_insertwk split: option.split)
   542 
   543 end
   544 
   545 subsection \<open>Deletion\<close>
   546 
   547 lemma bheight_paintR'[simp]: "color_of t = B \<Longrightarrow> bheight (paint R t) = bheight t - 1"
   548 by (cases t rule: rbt_cases) auto
   549 
   550 text \<open>
   551   The function definitions are based on the Haskell code by Stefan Kahrs
   552   at \<^url>\<open>http://www.cs.ukc.ac.uk/people/staff/smk/redblack/rb.html\<close>.
   553 \<close>
   554 
   555 fun
   556   balance_left :: "('a,'b) rbt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> ('a,'b) rbt \<Rightarrow> ('a,'b) rbt"
   557 where
   558   "balance_left (Branch R a k x b) s y c = Branch R (Branch B a k x b) s y c" |
   559   "balance_left bl k x (Branch B a s y b) = balance bl k x (Branch R a s y b)" |
   560   "balance_left bl k x (Branch R (Branch B a s y b) t z c) = Branch R (Branch B bl k x a) s y (balance b t z (paint R c))" |
   561   "balance_left t k x s = Empty"
   562 
   563 lemma balance_left_inv2_with_inv1:
   564   assumes "inv2 lt" "inv2 rt" "bheight lt + 1 = bheight rt" "inv1 rt"
   565   shows "bheight (balance_left lt k v rt) = bheight lt + 1"
   566   and   "inv2 (balance_left lt k v rt)"
   567 using assms 
   568 by (induct lt k v rt rule: balance_left.induct) (auto simp: balance_inv2 balance_bheight)
   569 
   570 lemma balance_left_inv2_app: 
   571   assumes "inv2 lt" "inv2 rt" "bheight lt + 1 = bheight rt" "color_of rt = B"
   572   shows "inv2 (balance_left lt k v rt)" 
   573         "bheight (balance_left lt k v rt) = bheight rt"
   574 using assms 
   575 by (induct lt k v rt rule: balance_left.induct) (auto simp add: balance_inv2 balance_bheight)+ 
   576 
   577 lemma balance_left_inv1: "\<lbrakk>inv1l a; inv1 b; color_of b = B\<rbrakk> \<Longrightarrow> inv1 (balance_left a k x b)"
   578   by (induct a k x b rule: balance_left.induct) (simp add: balance_inv1)+
   579 
   580 lemma balance_left_inv1l: "\<lbrakk> inv1l lt; inv1 rt \<rbrakk> \<Longrightarrow> inv1l (balance_left lt k x rt)"
   581 by (induct lt k x rt rule: balance_left.induct) (auto simp: balance_inv1)
   582 
   583 lemma (in linorder) balance_left_rbt_sorted: 
   584   "\<lbrakk> rbt_sorted l; rbt_sorted r; rbt_less k l; k \<guillemotleft>| r \<rbrakk> \<Longrightarrow> rbt_sorted (balance_left l k v r)"
   585 apply (induct l k v r rule: balance_left.induct)
   586 apply (auto simp: balance_rbt_sorted)
   587 apply (unfold rbt_greater_prop rbt_less_prop)
   588 by force+
   589 
   590 context order begin
   591 
   592 lemma balance_left_rbt_greater: 
   593   fixes k :: "'a"
   594   assumes "k \<guillemotleft>| a" "k \<guillemotleft>| b" "k < x" 
   595   shows "k \<guillemotleft>| balance_left a x t b"
   596 using assms 
   597 by (induct a x t b rule: balance_left.induct) auto
   598 
   599 lemma balance_left_rbt_less: 
   600   fixes k :: "'a"
   601   assumes "a |\<guillemotleft> k" "b |\<guillemotleft> k" "x < k" 
   602   shows "balance_left a x t b |\<guillemotleft> k"
   603 using assms
   604 by (induct a x t b rule: balance_left.induct) auto
   605 
   606 end
   607 
   608 lemma balance_left_in_tree: 
   609   assumes "inv1l l" "inv1 r" "bheight l + 1 = bheight r"
   610   shows "entry_in_tree k v (balance_left l a b r) = (entry_in_tree k v l \<or> k = a \<and> v = b \<or> entry_in_tree k v r)"
   611 using assms 
   612 by (induct l k v r rule: balance_left.induct) (auto simp: balance_in_tree)
   613 
   614 fun
   615   balance_right :: "('a,'b) rbt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> ('a,'b) rbt \<Rightarrow> ('a,'b) rbt"
   616 where
   617   "balance_right a k x (Branch R b s y c) = Branch R a k x (Branch B b s y c)" |
   618   "balance_right (Branch B a k x b) s y bl = balance (Branch R a k x b) s y bl" |
   619   "balance_right (Branch R a k x (Branch B b s y c)) t z bl = Branch R (balance (paint R a) k x b) s y (Branch B c t z bl)" |
   620   "balance_right t k x s = Empty"
   621 
   622 lemma balance_right_inv2_with_inv1:
   623   assumes "inv2 lt" "inv2 rt" "bheight lt = bheight rt + 1" "inv1 lt"
   624   shows "inv2 (balance_right lt k v rt) \<and> bheight (balance_right lt k v rt) = bheight lt"
   625 using assms
   626 by (induct lt k v rt rule: balance_right.induct) (auto simp: balance_inv2 balance_bheight)
   627 
   628 lemma balance_right_inv1: "\<lbrakk>inv1 a; inv1l b; color_of a = B\<rbrakk> \<Longrightarrow> inv1 (balance_right a k x b)"
   629 by (induct a k x b rule: balance_right.induct) (simp add: balance_inv1)+
   630 
   631 lemma balance_right_inv1l: "\<lbrakk> inv1 lt; inv1l rt \<rbrakk> \<Longrightarrow>inv1l (balance_right lt k x rt)"
   632 by (induct lt k x rt rule: balance_right.induct) (auto simp: balance_inv1)
   633 
   634 lemma (in linorder) balance_right_rbt_sorted:
   635   "\<lbrakk> rbt_sorted l; rbt_sorted r; rbt_less k l; k \<guillemotleft>| r \<rbrakk> \<Longrightarrow> rbt_sorted (balance_right l k v r)"
   636 apply (induct l k v r rule: balance_right.induct)
   637 apply (auto simp:balance_rbt_sorted)
   638 apply (unfold rbt_less_prop rbt_greater_prop)
   639 by force+
   640 
   641 context order begin
   642 
   643 lemma balance_right_rbt_greater: 
   644   fixes k :: "'a"
   645   assumes "k \<guillemotleft>| a" "k \<guillemotleft>| b" "k < x" 
   646   shows "k \<guillemotleft>| balance_right a x t b"
   647 using assms by (induct a x t b rule: balance_right.induct) auto
   648 
   649 lemma balance_right_rbt_less: 
   650   fixes k :: "'a"
   651   assumes "a |\<guillemotleft> k" "b |\<guillemotleft> k" "x < k" 
   652   shows "balance_right a x t b |\<guillemotleft> k"
   653 using assms by (induct a x t b rule: balance_right.induct) auto
   654 
   655 end
   656 
   657 lemma balance_right_in_tree:
   658   assumes "inv1 l" "inv1l r" "bheight l = bheight r + 1" "inv2 l" "inv2 r"
   659   shows "entry_in_tree x y (balance_right l k v r) = (entry_in_tree x y l \<or> x = k \<and> y = v \<or> entry_in_tree x y r)"
   660 using assms by (induct l k v r rule: balance_right.induct) (auto simp: balance_in_tree)
   661 
   662 fun
   663   combine :: "('a,'b) rbt \<Rightarrow> ('a,'b) rbt \<Rightarrow> ('a,'b) rbt"
   664 where
   665   "combine Empty x = x" 
   666 | "combine x Empty = x" 
   667 | "combine (Branch R a k x b) (Branch R c s y d) = (case (combine b c) of
   668                                     Branch R b2 t z c2 \<Rightarrow> (Branch R (Branch R a k x b2) t z (Branch R c2 s y d)) |
   669                                     bc \<Rightarrow> Branch R a k x (Branch R bc s y d))" 
   670 | "combine (Branch B a k x b) (Branch B c s y d) = (case (combine b c) of
   671                                     Branch R b2 t z c2 \<Rightarrow> Branch R (Branch B a k x b2) t z (Branch B c2 s y d) |
   672                                     bc \<Rightarrow> balance_left a k x (Branch B bc s y d))" 
   673 | "combine a (Branch R b k x c) = Branch R (combine a b) k x c" 
   674 | "combine (Branch R a k x b) c = Branch R a k x (combine b c)" 
   675 
   676 lemma combine_inv2:
   677   assumes "inv2 lt" "inv2 rt" "bheight lt = bheight rt"
   678   shows "bheight (combine lt rt) = bheight lt" "inv2 (combine lt rt)"
   679 using assms 
   680 by (induct lt rt rule: combine.induct) 
   681    (auto simp: balance_left_inv2_app split: rbt.splits color.splits)
   682 
   683 lemma combine_inv1: 
   684   assumes "inv1 lt" "inv1 rt"
   685   shows "color_of lt = B \<Longrightarrow> color_of rt = B \<Longrightarrow> inv1 (combine lt rt)"
   686          "inv1l (combine lt rt)"
   687 using assms 
   688 by (induct lt rt rule: combine.induct)
   689    (auto simp: balance_left_inv1 split: rbt.splits color.splits)
   690 
   691 context linorder begin
   692 
   693 lemma combine_rbt_greater[simp]: 
   694   fixes k :: "'a"
   695   assumes "k \<guillemotleft>| l" "k \<guillemotleft>| r" 
   696   shows "k \<guillemotleft>| combine l r"
   697 using assms 
   698 by (induct l r rule: combine.induct)
   699    (auto simp: balance_left_rbt_greater split:rbt.splits color.splits)
   700 
   701 lemma combine_rbt_less[simp]: 
   702   fixes k :: "'a"
   703   assumes "l |\<guillemotleft> k" "r |\<guillemotleft> k" 
   704   shows "combine l r |\<guillemotleft> k"
   705 using assms 
   706 by (induct l r rule: combine.induct)
   707    (auto simp: balance_left_rbt_less split:rbt.splits color.splits)
   708 
   709 lemma combine_rbt_sorted: 
   710   fixes k :: "'a"
   711   assumes "rbt_sorted l" "rbt_sorted r" "l |\<guillemotleft> k" "k \<guillemotleft>| r"
   712   shows "rbt_sorted (combine l r)"
   713 using assms proof (induct l r rule: combine.induct)
   714   case (3 a x v b c y w d)
   715   hence ineqs: "a |\<guillemotleft> x" "x \<guillemotleft>| b" "b |\<guillemotleft> k" "k \<guillemotleft>| c" "c |\<guillemotleft> y" "y \<guillemotleft>| d"
   716     by auto
   717   with 3
   718   show ?case
   719     by (cases "combine b c" rule: rbt_cases)
   720       (auto, (metis combine_rbt_greater combine_rbt_less ineqs ineqs rbt_less_simps(2) rbt_greater_simps(2) rbt_greater_trans rbt_less_trans)+)
   721 next
   722   case (4 a x v b c y w d)
   723   hence "x < k \<and> rbt_greater k c" by simp
   724   hence "rbt_greater x c" by (blast dest: rbt_greater_trans)
   725   with 4 have 2: "rbt_greater x (combine b c)" by (simp add: combine_rbt_greater)
   726   from 4 have "k < y \<and> rbt_less k b" by simp
   727   hence "rbt_less y b" by (blast dest: rbt_less_trans)
   728   with 4 have 3: "rbt_less y (combine b c)" by (simp add: combine_rbt_less)
   729   show ?case
   730   proof (cases "combine b c" rule: rbt_cases)
   731     case Empty
   732     from 4 have "x < y \<and> rbt_greater y d" by auto
   733     hence "rbt_greater x d" by (blast dest: rbt_greater_trans)
   734     with 4 Empty have "rbt_sorted a" and "rbt_sorted (Branch B Empty y w d)"
   735       and "rbt_less x a" and "rbt_greater x (Branch B Empty y w d)" by auto
   736     with Empty show ?thesis by (simp add: balance_left_rbt_sorted)
   737   next
   738     case (Red lta va ka rta)
   739     with 2 4 have "x < va \<and> rbt_less x a" by simp
   740     hence 5: "rbt_less va a" by (blast dest: rbt_less_trans)
   741     from Red 3 4 have "va < y \<and> rbt_greater y d" by simp
   742     hence "rbt_greater va d" by (blast dest: rbt_greater_trans)
   743     with Red 2 3 4 5 show ?thesis by simp
   744   next
   745     case (Black lta va ka rta)
   746     from 4 have "x < y \<and> rbt_greater y d" by auto
   747     hence "rbt_greater x d" by (blast dest: rbt_greater_trans)
   748     with Black 2 3 4 have "rbt_sorted a" and "rbt_sorted (Branch B (combine b c) y w d)" 
   749       and "rbt_less x a" and "rbt_greater x (Branch B (combine b c) y w d)" by auto
   750     with Black show ?thesis by (simp add: balance_left_rbt_sorted)
   751   qed
   752 next
   753   case (5 va vb vd vc b x w c)
   754   hence "k < x \<and> rbt_less k (Branch B va vb vd vc)" by simp
   755   hence "rbt_less x (Branch B va vb vd vc)" by (blast dest: rbt_less_trans)
   756   with 5 show ?case by (simp add: combine_rbt_less)
   757 next
   758   case (6 a x v b va vb vd vc)
   759   hence "x < k \<and> rbt_greater k (Branch B va vb vd vc)" by simp
   760   hence "rbt_greater x (Branch B va vb vd vc)" by (blast dest: rbt_greater_trans)
   761   with 6 show ?case by (simp add: combine_rbt_greater)
   762 qed simp+
   763 
   764 end
   765 
   766 lemma combine_in_tree: 
   767   assumes "inv2 l" "inv2 r" "bheight l = bheight r" "inv1 l" "inv1 r"
   768   shows "entry_in_tree k v (combine l r) = (entry_in_tree k v l \<or> entry_in_tree k v r)"
   769 using assms 
   770 proof (induct l r rule: combine.induct)
   771   case (4 _ _ _ b c)
   772   hence a: "bheight (combine b c) = bheight b" by (simp add: combine_inv2)
   773   from 4 have b: "inv1l (combine b c)" by (simp add: combine_inv1)
   774 
   775   show ?case
   776   proof (cases "combine b c" rule: rbt_cases)
   777     case Empty
   778     with 4 a show ?thesis by (auto simp: balance_left_in_tree)
   779   next
   780     case (Red lta ka va rta)
   781     with 4 show ?thesis by auto
   782   next
   783     case (Black lta ka va rta)
   784     with a b 4  show ?thesis by (auto simp: balance_left_in_tree)
   785   qed 
   786 qed (auto split: rbt.splits color.splits)
   787 
   788 context ord begin
   789 
   790 fun
   791   rbt_del_from_left :: "'a \<Rightarrow> ('a,'b) rbt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> ('a,'b) rbt \<Rightarrow> ('a,'b) rbt" and
   792   rbt_del_from_right :: "'a \<Rightarrow> ('a,'b) rbt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> ('a,'b) rbt \<Rightarrow> ('a,'b) rbt" and
   793   rbt_del :: "'a\<Rightarrow> ('a,'b) rbt \<Rightarrow> ('a,'b) rbt"
   794 where
   795   "rbt_del x Empty = Empty" |
   796   "rbt_del x (Branch c a y s b) = 
   797    (if x < y then rbt_del_from_left x a y s b 
   798     else (if x > y then rbt_del_from_right x a y s b else combine a b))" |
   799   "rbt_del_from_left x (Branch B lt z v rt) y s b = balance_left (rbt_del x (Branch B lt z v rt)) y s b" |
   800   "rbt_del_from_left x a y s b = Branch R (rbt_del x a) y s b" |
   801   "rbt_del_from_right x a y s (Branch B lt z v rt) = balance_right a y s (rbt_del x (Branch B lt z v rt))" | 
   802   "rbt_del_from_right x a y s b = Branch R a y s (rbt_del x b)"
   803 
   804 end
   805 
   806 context linorder begin
   807 
   808 lemma 
   809   assumes "inv2 lt" "inv1 lt"
   810   shows
   811   "\<lbrakk>inv2 rt; bheight lt = bheight rt; inv1 rt\<rbrakk> \<Longrightarrow>
   812    inv2 (rbt_del_from_left x lt k v rt) \<and> 
   813    bheight (rbt_del_from_left x lt k v rt) = bheight lt \<and> 
   814    (color_of lt = B \<and> color_of rt = B \<and> inv1 (rbt_del_from_left x lt k v rt) \<or> 
   815     (color_of lt \<noteq> B \<or> color_of rt \<noteq> B) \<and> inv1l (rbt_del_from_left x lt k v rt))"
   816   and "\<lbrakk>inv2 rt; bheight lt = bheight rt; inv1 rt\<rbrakk> \<Longrightarrow>
   817   inv2 (rbt_del_from_right x lt k v rt) \<and> 
   818   bheight (rbt_del_from_right x lt k v rt) = bheight lt \<and> 
   819   (color_of lt = B \<and> color_of rt = B \<and> inv1 (rbt_del_from_right x lt k v rt) \<or> 
   820    (color_of lt \<noteq> B \<or> color_of rt \<noteq> B) \<and> inv1l (rbt_del_from_right x lt k v rt))"
   821   and rbt_del_inv1_inv2: "inv2 (rbt_del x lt) \<and> (color_of lt = R \<and> bheight (rbt_del x lt) = bheight lt \<and> inv1 (rbt_del x lt) 
   822   \<or> color_of lt = B \<and> bheight (rbt_del x lt) = bheight lt - 1 \<and> inv1l (rbt_del x lt))"
   823 using assms
   824 proof (induct x lt k v rt and x lt k v rt and x lt rule: rbt_del_from_left_rbt_del_from_right_rbt_del.induct)
   825 case (2 y c _ y')
   826   have "y = y' \<or> y < y' \<or> y > y'" by auto
   827   thus ?case proof (elim disjE)
   828     assume "y = y'"
   829     with 2 show ?thesis by (cases c) (simp add: combine_inv2 combine_inv1)+
   830   next
   831     assume "y < y'"
   832     with 2 show ?thesis by (cases c) auto
   833   next
   834     assume "y' < y"
   835     with 2 show ?thesis by (cases c) auto
   836   qed
   837 next
   838   case (3 y lt z v rta y' ss bb) 
   839   thus ?case by (cases "color_of (Branch B lt z v rta) = B \<and> color_of bb = B") (simp add: balance_left_inv2_with_inv1 balance_left_inv1 balance_left_inv1l)+
   840 next
   841   case (5 y a y' ss lt z v rta)
   842   thus ?case by (cases "color_of a = B \<and> color_of (Branch B lt z v rta) = B") (simp add: balance_right_inv2_with_inv1 balance_right_inv1 balance_right_inv1l)+
   843 next
   844   case ("6_1" y a y' ss) thus ?case by (cases "color_of a = B \<and> color_of Empty = B") simp+
   845 qed auto
   846 
   847 lemma 
   848   rbt_del_from_left_rbt_less: "\<lbrakk> lt |\<guillemotleft> v; rt |\<guillemotleft> v; k < v\<rbrakk> \<Longrightarrow> rbt_del_from_left x lt k y rt |\<guillemotleft> v"
   849   and rbt_del_from_right_rbt_less: "\<lbrakk>lt |\<guillemotleft> v; rt |\<guillemotleft> v; k < v\<rbrakk> \<Longrightarrow> rbt_del_from_right x lt k y rt |\<guillemotleft> v"
   850   and rbt_del_rbt_less: "lt |\<guillemotleft> v \<Longrightarrow> rbt_del x lt |\<guillemotleft> v"
   851 by (induct x lt k y rt and x lt k y rt and x lt rule: rbt_del_from_left_rbt_del_from_right_rbt_del.induct) 
   852    (auto simp: balance_left_rbt_less balance_right_rbt_less)
   853 
   854 lemma rbt_del_from_left_rbt_greater: "\<lbrakk>v \<guillemotleft>| lt; v \<guillemotleft>| rt; k > v\<rbrakk> \<Longrightarrow> v \<guillemotleft>| rbt_del_from_left x lt k y rt"
   855   and rbt_del_from_right_rbt_greater: "\<lbrakk>v \<guillemotleft>| lt; v \<guillemotleft>| rt; k > v\<rbrakk> \<Longrightarrow> v \<guillemotleft>| rbt_del_from_right x lt k y rt"
   856   and rbt_del_rbt_greater: "v \<guillemotleft>| lt \<Longrightarrow> v \<guillemotleft>| rbt_del x lt"
   857 by (induct x lt k y rt and x lt k y rt and x lt rule: rbt_del_from_left_rbt_del_from_right_rbt_del.induct)
   858    (auto simp: balance_left_rbt_greater balance_right_rbt_greater)
   859 
   860 lemma "\<lbrakk>rbt_sorted lt; rbt_sorted rt; lt |\<guillemotleft> k; k \<guillemotleft>| rt\<rbrakk> \<Longrightarrow> rbt_sorted (rbt_del_from_left x lt k y rt)"
   861   and "\<lbrakk>rbt_sorted lt; rbt_sorted rt; lt |\<guillemotleft> k; k \<guillemotleft>| rt\<rbrakk> \<Longrightarrow> rbt_sorted (rbt_del_from_right x lt k y rt)"
   862   and rbt_del_rbt_sorted: "rbt_sorted lt \<Longrightarrow> rbt_sorted (rbt_del x lt)"
   863 proof (induct x lt k y rt and x lt k y rt and x lt rule: rbt_del_from_left_rbt_del_from_right_rbt_del.induct)
   864   case (3 x lta zz v rta yy ss bb)
   865   from 3 have "Branch B lta zz v rta |\<guillemotleft> yy" by simp
   866   hence "rbt_del x (Branch B lta zz v rta) |\<guillemotleft> yy" by (rule rbt_del_rbt_less)
   867   with 3 show ?case by (simp add: balance_left_rbt_sorted)
   868 next
   869   case ("4_2" x vaa vbb vdd vc yy ss bb)
   870   hence "Branch R vaa vbb vdd vc |\<guillemotleft> yy" by simp
   871   hence "rbt_del x (Branch R vaa vbb vdd vc) |\<guillemotleft> yy" by (rule rbt_del_rbt_less)
   872   with "4_2" show ?case by simp
   873 next
   874   case (5 x aa yy ss lta zz v rta) 
   875   hence "yy \<guillemotleft>| Branch B lta zz v rta" by simp
   876   hence "yy \<guillemotleft>| rbt_del x (Branch B lta zz v rta)" by (rule rbt_del_rbt_greater)
   877   with 5 show ?case by (simp add: balance_right_rbt_sorted)
   878 next
   879   case ("6_2" x aa yy ss vaa vbb vdd vc)
   880   hence "yy \<guillemotleft>| Branch R vaa vbb vdd vc" by simp
   881   hence "yy \<guillemotleft>| rbt_del x (Branch R vaa vbb vdd vc)" by (rule rbt_del_rbt_greater)
   882   with "6_2" show ?case by simp
   883 qed (auto simp: combine_rbt_sorted)
   884 
   885 lemma "\<lbrakk>rbt_sorted lt; rbt_sorted rt; lt |\<guillemotleft> kt; kt \<guillemotleft>| rt; inv1 lt; inv1 rt; inv2 lt; inv2 rt; bheight lt = bheight rt; x < kt\<rbrakk> \<Longrightarrow> entry_in_tree k v (rbt_del_from_left x lt kt y rt) = (False \<or> (x \<noteq> k \<and> entry_in_tree k v (Branch c lt kt y rt)))"
   886   and "\<lbrakk>rbt_sorted lt; rbt_sorted rt; lt |\<guillemotleft> kt; kt \<guillemotleft>| rt; inv1 lt; inv1 rt; inv2 lt; inv2 rt; bheight lt = bheight rt; x > kt\<rbrakk> \<Longrightarrow> entry_in_tree k v (rbt_del_from_right x lt kt y rt) = (False \<or> (x \<noteq> k \<and> entry_in_tree k v (Branch c lt kt y rt)))"
   887   and rbt_del_in_tree: "\<lbrakk>rbt_sorted t; inv1 t; inv2 t\<rbrakk> \<Longrightarrow> entry_in_tree k v (rbt_del x t) = (False \<or> (x \<noteq> k \<and> entry_in_tree k v t))"
   888 proof (induct x lt kt y rt and x lt kt y rt and x t rule: rbt_del_from_left_rbt_del_from_right_rbt_del.induct)
   889   case (2 xx c aa yy ss bb)
   890   have "xx = yy \<or> xx < yy \<or> xx > yy" by auto
   891   from this 2 show ?case proof (elim disjE)
   892     assume "xx = yy"
   893     with 2 show ?thesis proof (cases "xx = k")
   894       case True
   895       from 2 \<open>xx = yy\<close> \<open>xx = k\<close> have "rbt_sorted (Branch c aa yy ss bb) \<and> k = yy" by simp
   896       hence "\<not> entry_in_tree k v aa" "\<not> entry_in_tree k v bb" by (auto simp: rbt_less_nit rbt_greater_prop)
   897       with \<open>xx = yy\<close> 2 \<open>xx = k\<close> show ?thesis by (simp add: combine_in_tree)
   898     qed (simp add: combine_in_tree)
   899   qed simp+
   900 next    
   901   case (3 xx lta zz vv rta yy ss bb)
   902   define mt where [simp]: "mt = Branch B lta zz vv rta"
   903   from 3 have "inv2 mt \<and> inv1 mt" by simp
   904   hence "inv2 (rbt_del xx mt) \<and> (color_of mt = R \<and> bheight (rbt_del xx mt) = bheight mt \<and> inv1 (rbt_del xx mt) \<or> color_of mt = B \<and> bheight (rbt_del xx mt) = bheight mt - 1 \<and> inv1l (rbt_del xx mt))" by (blast dest: rbt_del_inv1_inv2)
   905   with 3 have 4: "entry_in_tree k v (rbt_del_from_left xx mt yy ss bb) = (False \<or> xx \<noteq> k \<and> entry_in_tree k v mt \<or> (k = yy \<and> v = ss) \<or> entry_in_tree k v bb)" by (simp add: balance_left_in_tree)
   906   thus ?case proof (cases "xx = k")
   907     case True
   908     from 3 True have "yy \<guillemotleft>| bb \<and> yy > k" by simp
   909     hence "k \<guillemotleft>| bb" by (blast dest: rbt_greater_trans)
   910     with 3 4 True show ?thesis by (auto simp: rbt_greater_nit)
   911   qed auto
   912 next
   913   case ("4_1" xx yy ss bb)
   914   show ?case proof (cases "xx = k")
   915     case True
   916     with "4_1" have "yy \<guillemotleft>| bb \<and> k < yy" by simp
   917     hence "k \<guillemotleft>| bb" by (blast dest: rbt_greater_trans)
   918     with "4_1" \<open>xx = k\<close> 
   919    have "entry_in_tree k v (Branch R Empty yy ss bb) = entry_in_tree k v Empty" by (auto simp: rbt_greater_nit)
   920     thus ?thesis by auto
   921   qed simp+
   922 next
   923   case ("4_2" xx vaa vbb vdd vc yy ss bb)
   924   thus ?case proof (cases "xx = k")
   925     case True
   926     with "4_2" have "k < yy \<and> yy \<guillemotleft>| bb" by simp
   927     hence "k \<guillemotleft>| bb" by (blast dest: rbt_greater_trans)
   928     with True "4_2" show ?thesis by (auto simp: rbt_greater_nit)
   929   qed auto
   930 next
   931   case (5 xx aa yy ss lta zz vv rta)
   932   define mt where [simp]: "mt = Branch B lta zz vv rta"
   933   from 5 have "inv2 mt \<and> inv1 mt" by simp
   934   hence "inv2 (rbt_del xx mt) \<and> (color_of mt = R \<and> bheight (rbt_del xx mt) = bheight mt \<and> inv1 (rbt_del xx mt) \<or> color_of mt = B \<and> bheight (rbt_del xx mt) = bheight mt - 1 \<and> inv1l (rbt_del xx mt))" by (blast dest: rbt_del_inv1_inv2)
   935   with 5 have 3: "entry_in_tree k v (rbt_del_from_right xx aa yy ss mt) = (entry_in_tree k v aa \<or> (k = yy \<and> v = ss) \<or> False \<or> xx \<noteq> k \<and> entry_in_tree k v mt)" by (simp add: balance_right_in_tree)
   936   thus ?case proof (cases "xx = k")
   937     case True
   938     from 5 True have "aa |\<guillemotleft> yy \<and> yy < k" by simp
   939     hence "aa |\<guillemotleft> k" by (blast dest: rbt_less_trans)
   940     with 3 5 True show ?thesis by (auto simp: rbt_less_nit)
   941   qed auto
   942 next
   943   case ("6_1" xx aa yy ss)
   944   show ?case proof (cases "xx = k")
   945     case True
   946     with "6_1" have "aa |\<guillemotleft> yy \<and> k > yy" by simp
   947     hence "aa |\<guillemotleft> k" by (blast dest: rbt_less_trans)
   948     with "6_1" \<open>xx = k\<close> show ?thesis by (auto simp: rbt_less_nit)
   949   qed simp
   950 next
   951   case ("6_2" xx aa yy ss vaa vbb vdd vc)
   952   thus ?case proof (cases "xx = k")
   953     case True
   954     with "6_2" have "k > yy \<and> aa |\<guillemotleft> yy" by simp
   955     hence "aa |\<guillemotleft> k" by (blast dest: rbt_less_trans)
   956     with True "6_2" show ?thesis by (auto simp: rbt_less_nit)
   957   qed auto
   958 qed simp
   959 
   960 definition (in ord) rbt_delete where
   961   "rbt_delete k t = paint B (rbt_del k t)"
   962 
   963 theorem rbt_delete_is_rbt [simp]: assumes "is_rbt t" shows "is_rbt (rbt_delete k t)"
   964 proof -
   965   from assms have "inv2 t" and "inv1 t" unfolding is_rbt_def by auto 
   966   hence "inv2 (rbt_del k t) \<and> (color_of t = R \<and> bheight (rbt_del k t) = bheight t \<and> inv1 (rbt_del k t) \<or> color_of t = B \<and> bheight (rbt_del k t) = bheight t - 1 \<and> inv1l (rbt_del k t))" by (rule rbt_del_inv1_inv2)
   967   hence "inv2 (rbt_del k t) \<and> inv1l (rbt_del k t)" by (cases "color_of t") auto
   968   with assms show ?thesis
   969     unfolding is_rbt_def rbt_delete_def
   970     by (auto intro: paint_rbt_sorted rbt_del_rbt_sorted)
   971 qed
   972 
   973 lemma rbt_delete_in_tree: 
   974   assumes "is_rbt t" 
   975   shows "entry_in_tree k v (rbt_delete x t) = (x \<noteq> k \<and> entry_in_tree k v t)"
   976   using assms unfolding is_rbt_def rbt_delete_def
   977   by (auto simp: rbt_del_in_tree)
   978 
   979 lemma rbt_lookup_rbt_delete:
   980   assumes is_rbt: "is_rbt t"
   981   shows "rbt_lookup (rbt_delete k t) = (rbt_lookup t)|`(-{k})"
   982 proof
   983   fix x
   984   show "rbt_lookup (rbt_delete k t) x = (rbt_lookup t |` (-{k})) x" 
   985   proof (cases "x = k")
   986     assume "x = k" 
   987     with is_rbt show ?thesis
   988       by (cases "rbt_lookup (rbt_delete k t) k") (auto simp: rbt_lookup_in_tree rbt_delete_in_tree)
   989   next
   990     assume "x \<noteq> k"
   991     thus ?thesis
   992       by auto (metis is_rbt rbt_delete_is_rbt rbt_delete_in_tree is_rbt_rbt_sorted rbt_lookup_from_in_tree)
   993   qed
   994 qed
   995 
   996 end
   997 
   998 subsection \<open>Modifying existing entries\<close>
   999 
  1000 context ord begin
  1001 
  1002 primrec
  1003   rbt_map_entry :: "'a \<Rightarrow> ('b \<Rightarrow> 'b) \<Rightarrow> ('a, 'b) rbt \<Rightarrow> ('a, 'b) rbt"
  1004 where
  1005   "rbt_map_entry k f Empty = Empty"
  1006 | "rbt_map_entry k f (Branch c lt x v rt) =
  1007     (if k < x then Branch c (rbt_map_entry k f lt) x v rt
  1008     else if k > x then (Branch c lt x v (rbt_map_entry k f rt))
  1009     else Branch c lt x (f v) rt)"
  1010 
  1011 
  1012 lemma rbt_map_entry_color_of: "color_of (rbt_map_entry k f t) = color_of t" by (induct t) simp+
  1013 lemma rbt_map_entry_inv1: "inv1 (rbt_map_entry k f t) = inv1 t" by (induct t) (simp add: rbt_map_entry_color_of)+
  1014 lemma rbt_map_entry_inv2: "inv2 (rbt_map_entry k f t) = inv2 t" "bheight (rbt_map_entry k f t) = bheight t" by (induct t) simp+
  1015 lemma rbt_map_entry_rbt_greater: "rbt_greater a (rbt_map_entry k f t) = rbt_greater a t" by (induct t) simp+
  1016 lemma rbt_map_entry_rbt_less: "rbt_less a (rbt_map_entry k f t) = rbt_less a t" by (induct t) simp+
  1017 lemma rbt_map_entry_rbt_sorted: "rbt_sorted (rbt_map_entry k f t) = rbt_sorted t"
  1018   by (induct t) (simp_all add: rbt_map_entry_rbt_less rbt_map_entry_rbt_greater)
  1019 
  1020 theorem rbt_map_entry_is_rbt [simp]: "is_rbt (rbt_map_entry k f t) = is_rbt t" 
  1021 unfolding is_rbt_def by (simp add: rbt_map_entry_inv2 rbt_map_entry_color_of rbt_map_entry_rbt_sorted rbt_map_entry_inv1 )
  1022 
  1023 end
  1024 
  1025 theorem (in linorder) rbt_lookup_rbt_map_entry:
  1026   "rbt_lookup (rbt_map_entry k f t) = (rbt_lookup t)(k := map_option f (rbt_lookup t k))"
  1027   by (induct t) (auto split: option.splits simp add: fun_eq_iff)
  1028 
  1029 subsection \<open>Mapping all entries\<close>
  1030 
  1031 primrec
  1032   map :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> ('a, 'b) rbt \<Rightarrow> ('a, 'c) rbt"
  1033 where
  1034   "map f Empty = Empty"
  1035 | "map f (Branch c lt k v rt) = Branch c (map f lt) k (f k v) (map f rt)"
  1036 
  1037 lemma map_entries [simp]: "entries (map f t) = List.map (\<lambda>(k, v). (k, f k v)) (entries t)"
  1038   by (induct t) auto
  1039 lemma map_keys [simp]: "keys (map f t) = keys t" by (simp add: keys_def split_def)
  1040 lemma map_color_of: "color_of (map f t) = color_of t" by (induct t) simp+
  1041 lemma map_inv1: "inv1 (map f t) = inv1 t" by (induct t) (simp add: map_color_of)+
  1042 lemma map_inv2: "inv2 (map f t) = inv2 t" "bheight (map f t) = bheight t" by (induct t) simp+
  1043 
  1044 context ord begin
  1045 
  1046 lemma map_rbt_greater: "rbt_greater k (map f t) = rbt_greater k t" by (induct t) simp+
  1047 lemma map_rbt_less: "rbt_less k (map f t) = rbt_less k t" by (induct t) simp+
  1048 lemma map_rbt_sorted: "rbt_sorted (map f t) = rbt_sorted t"  by (induct t) (simp add: map_rbt_less map_rbt_greater)+
  1049 theorem map_is_rbt [simp]: "is_rbt (map f t) = is_rbt t" 
  1050 unfolding is_rbt_def by (simp add: map_inv1 map_inv2 map_rbt_sorted map_color_of)
  1051 
  1052 end
  1053 
  1054 theorem (in linorder) rbt_lookup_map: "rbt_lookup (map f t) x = map_option (f x) (rbt_lookup t x)"
  1055   apply(induct t)
  1056   apply auto
  1057   apply(rename_tac a b c, subgoal_tac "x = a")
  1058   apply auto
  1059   done
  1060  (* FIXME: simproc "antisym less" does not work for linorder context, only for linorder type class
  1061     by (induct t) auto *)
  1062 
  1063 hide_const (open) map
  1064 
  1065 subsection \<open>Folding over entries\<close>
  1066 
  1067 definition fold :: "('a \<Rightarrow> 'b \<Rightarrow> 'c \<Rightarrow> 'c) \<Rightarrow> ('a, 'b) rbt \<Rightarrow> 'c \<Rightarrow> 'c" where
  1068   "fold f t = List.fold (case_prod f) (entries t)"
  1069 
  1070 lemma fold_simps [simp]:
  1071   "fold f Empty = id"
  1072   "fold f (Branch c lt k v rt) = fold f rt \<circ> f k v \<circ> fold f lt"
  1073   by (simp_all add: fold_def fun_eq_iff)
  1074 
  1075 lemma fold_code [code]:
  1076   "fold f Empty x = x"
  1077   "fold f (Branch c lt k v rt) x = fold f rt (f k v (fold f lt x))"
  1078 by(simp_all)
  1079 
  1080 \<comment> \<open>fold with continuation predicate\<close>
  1081 fun foldi :: "('c \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'b \<Rightarrow> 'c \<Rightarrow> 'c) \<Rightarrow> ('a :: linorder, 'b) rbt \<Rightarrow> 'c \<Rightarrow> 'c" 
  1082   where
  1083   "foldi c f Empty s = s" |
  1084   "foldi c f (Branch col l k v r) s = (
  1085     if (c s) then
  1086       let s' = foldi c f l s in
  1087         if (c s') then
  1088           foldi c f r (f k v s')
  1089         else s'
  1090     else 
  1091       s
  1092   )"
  1093 
  1094 subsection \<open>Bulkloading a tree\<close>
  1095 
  1096 definition (in ord) rbt_bulkload :: "('a \<times> 'b) list \<Rightarrow> ('a, 'b) rbt" where
  1097   "rbt_bulkload xs = foldr (\<lambda>(k, v). rbt_insert k v) xs Empty"
  1098 
  1099 context linorder begin
  1100 
  1101 lemma rbt_bulkload_is_rbt [simp, intro]:
  1102   "is_rbt (rbt_bulkload xs)"
  1103   unfolding rbt_bulkload_def by (induct xs) auto
  1104 
  1105 lemma rbt_lookup_rbt_bulkload:
  1106   "rbt_lookup (rbt_bulkload xs) = map_of xs"
  1107 proof -
  1108   obtain ys where "ys = rev xs" by simp
  1109   have "\<And>t. is_rbt t \<Longrightarrow>
  1110     rbt_lookup (List.fold (case_prod rbt_insert) ys t) = rbt_lookup t ++ map_of (rev ys)"
  1111       by (induct ys) (simp_all add: rbt_bulkload_def rbt_lookup_rbt_insert case_prod_beta)
  1112   from this Empty_is_rbt have
  1113     "rbt_lookup (List.fold (case_prod rbt_insert) (rev xs) Empty) = rbt_lookup Empty ++ map_of xs"
  1114      by (simp add: \<open>ys = rev xs\<close>)
  1115   then show ?thesis by (simp add: rbt_bulkload_def rbt_lookup_Empty foldr_conv_fold)
  1116 qed
  1117 
  1118 end
  1119 
  1120 
  1121 
  1122 subsection \<open>Building a RBT from a sorted list\<close>
  1123 
  1124 text \<open>
  1125   These functions have been adapted from 
  1126   Andrew W. Appel, Efficient Verified Red-Black Trees (September 2011) 
  1127 \<close>
  1128 
  1129 fun rbtreeify_f :: "nat \<Rightarrow> ('a \<times> 'b) list \<Rightarrow> ('a, 'b) rbt \<times> ('a \<times> 'b) list"
  1130   and rbtreeify_g :: "nat \<Rightarrow> ('a \<times> 'b) list \<Rightarrow> ('a, 'b) rbt \<times> ('a \<times> 'b) list"
  1131 where
  1132   "rbtreeify_f n kvs =
  1133    (if n = 0 then (Empty, kvs)
  1134     else if n = 1 then
  1135       case kvs of (k, v) # kvs' \<Rightarrow> (Branch R Empty k v Empty, kvs')
  1136     else if (n mod 2 = 0) then
  1137       case rbtreeify_f (n div 2) kvs of (t1, (k, v) # kvs') \<Rightarrow>
  1138         apfst (Branch B t1 k v) (rbtreeify_g (n div 2) kvs')
  1139     else case rbtreeify_f (n div 2) kvs of (t1, (k, v) # kvs') \<Rightarrow>
  1140         apfst (Branch B t1 k v) (rbtreeify_f (n div 2) kvs'))"
  1141 
  1142 | "rbtreeify_g n kvs =
  1143    (if n = 0 \<or> n = 1 then (Empty, kvs)
  1144     else if n mod 2 = 0 then
  1145       case rbtreeify_g (n div 2) kvs of (t1, (k, v) # kvs') \<Rightarrow>
  1146         apfst (Branch B t1 k v) (rbtreeify_g (n div 2) kvs')
  1147     else case rbtreeify_f (n div 2) kvs of (t1, (k, v) # kvs') \<Rightarrow>
  1148         apfst (Branch B t1 k v) (rbtreeify_g (n div 2) kvs'))"
  1149 
  1150 definition rbtreeify :: "('a \<times> 'b) list \<Rightarrow> ('a, 'b) rbt"
  1151 where "rbtreeify kvs = fst (rbtreeify_g (Suc (length kvs)) kvs)"
  1152 
  1153 declare rbtreeify_f.simps [simp del] rbtreeify_g.simps [simp del]
  1154 
  1155 lemma rbtreeify_f_code [code]:
  1156   "rbtreeify_f n kvs =
  1157    (if n = 0 then (Empty, kvs)
  1158     else if n = 1 then
  1159       case kvs of (k, v) # kvs' \<Rightarrow> 
  1160         (Branch R Empty k v Empty, kvs')
  1161     else let (n', r) = Divides.divmod_nat n 2 in
  1162       if r = 0 then
  1163         case rbtreeify_f n' kvs of (t1, (k, v) # kvs') \<Rightarrow>
  1164           apfst (Branch B t1 k v) (rbtreeify_g n' kvs')
  1165       else case rbtreeify_f n' kvs of (t1, (k, v) # kvs') \<Rightarrow>
  1166           apfst (Branch B t1 k v) (rbtreeify_f n' kvs'))"
  1167 by (subst rbtreeify_f.simps) (simp only: Let_def divmod_nat_def prod.case)
  1168 
  1169 lemma rbtreeify_g_code [code]:
  1170   "rbtreeify_g n kvs =
  1171    (if n = 0 \<or> n = 1 then (Empty, kvs)
  1172     else let (n', r) = Divides.divmod_nat n 2 in
  1173       if r = 0 then
  1174         case rbtreeify_g n' kvs of (t1, (k, v) # kvs') \<Rightarrow>
  1175           apfst (Branch B t1 k v) (rbtreeify_g n' kvs')
  1176       else case rbtreeify_f n' kvs of (t1, (k, v) # kvs') \<Rightarrow>
  1177           apfst (Branch B t1 k v) (rbtreeify_g n' kvs'))"
  1178 by(subst rbtreeify_g.simps)(simp only: Let_def divmod_nat_def prod.case)
  1179 
  1180 lemma Suc_double_half: "Suc (2 * n) div 2 = n"
  1181 by simp
  1182 
  1183 lemma div2_plus_div2: "n div 2 + n div 2 = (n :: nat) - n mod 2"
  1184 by arith
  1185 
  1186 lemma rbtreeify_f_rec_aux_lemma:
  1187   "\<lbrakk>k - n div 2 = Suc k'; n \<le> k; n mod 2 = Suc 0\<rbrakk>
  1188   \<Longrightarrow> k' - n div 2 = k - n"
  1189 apply(rule add_right_imp_eq[where a = "n - n div 2"])
  1190 apply(subst add_diff_assoc2, arith)
  1191 apply(simp add: div2_plus_div2)
  1192 done
  1193 
  1194 lemma rbtreeify_f_simps:
  1195   "rbtreeify_f 0 kvs = (Empty, kvs)"
  1196   "rbtreeify_f (Suc 0) ((k, v) # kvs) = 
  1197   (Branch R Empty k v Empty, kvs)"
  1198   "0 < n \<Longrightarrow> rbtreeify_f (2 * n) kvs =
  1199    (case rbtreeify_f n kvs of (t1, (k, v) # kvs') \<Rightarrow>
  1200      apfst (Branch B t1 k v) (rbtreeify_g n kvs'))"
  1201   "0 < n \<Longrightarrow> rbtreeify_f (Suc (2 * n)) kvs =
  1202    (case rbtreeify_f n kvs of (t1, (k, v) # kvs') \<Rightarrow> 
  1203      apfst (Branch B t1 k v) (rbtreeify_f n kvs'))"
  1204 by(subst (1) rbtreeify_f.simps, simp add: Suc_double_half)+
  1205 
  1206 lemma rbtreeify_g_simps:
  1207   "rbtreeify_g 0 kvs = (Empty, kvs)"
  1208   "rbtreeify_g (Suc 0) kvs = (Empty, kvs)"
  1209   "0 < n \<Longrightarrow> rbtreeify_g (2 * n) kvs =
  1210    (case rbtreeify_g n kvs of (t1, (k, v) # kvs') \<Rightarrow> 
  1211      apfst (Branch B t1 k v) (rbtreeify_g n kvs'))"
  1212   "0 < n \<Longrightarrow> rbtreeify_g (Suc (2 * n)) kvs =
  1213    (case rbtreeify_f n kvs of (t1, (k, v) # kvs') \<Rightarrow> 
  1214      apfst (Branch B t1 k v) (rbtreeify_g n kvs'))"
  1215 by(subst (1) rbtreeify_g.simps, simp add: Suc_double_half)+
  1216 
  1217 declare rbtreeify_f_simps[simp] rbtreeify_g_simps[simp]
  1218 
  1219 lemma length_rbtreeify_f: "n \<le> length kvs
  1220   \<Longrightarrow> length (snd (rbtreeify_f n kvs)) = length kvs - n"
  1221   and length_rbtreeify_g:"\<lbrakk> 0 < n; n \<le> Suc (length kvs) \<rbrakk>
  1222   \<Longrightarrow> length (snd (rbtreeify_g n kvs)) = Suc (length kvs) - n"
  1223 proof(induction n kvs and n kvs rule: rbtreeify_f_rbtreeify_g.induct)
  1224   case (1 n kvs)
  1225   show ?case
  1226   proof(cases "n \<le> 1")
  1227     case True thus ?thesis using "1.prems"
  1228       by(cases n kvs rule: nat.exhaust[case_product list.exhaust]) auto
  1229   next
  1230     case False
  1231     hence "n \<noteq> 0" "n \<noteq> 1" by simp_all
  1232     note IH = "1.IH"[OF this]
  1233     show ?thesis
  1234     proof(cases "n mod 2 = 0")
  1235       case True
  1236       hence "length (snd (rbtreeify_f n kvs)) = 
  1237         length (snd (rbtreeify_f (2 * (n div 2)) kvs))"
  1238         by(metis minus_nat.diff_0 minus_mod_eq_mult_div [symmetric])
  1239       also from "1.prems" False obtain k v kvs' 
  1240         where kvs: "kvs = (k, v) # kvs'" by(cases kvs) auto
  1241       also have "0 < n div 2" using False by(simp) 
  1242       note rbtreeify_f_simps(3)[OF this]
  1243       also note kvs[symmetric] 
  1244       also let ?rest1 = "snd (rbtreeify_f (n div 2) kvs)"
  1245       from "1.prems" have "n div 2 \<le> length kvs" by simp
  1246       with True have len: "length ?rest1 = length kvs - n div 2" by(rule IH)
  1247       with "1.prems" False obtain t1 k' v' kvs''
  1248         where kvs'': "rbtreeify_f (n div 2) kvs = (t1, (k', v') # kvs'')"
  1249          by(cases ?rest1)(auto simp add: snd_def split: prod.split_asm)
  1250       note this also note prod.case also note list.simps(5) 
  1251       also note prod.case also note snd_apfst
  1252       also have "0 < n div 2" "n div 2 \<le> Suc (length kvs'')" 
  1253         using len "1.prems" False unfolding kvs'' by simp_all
  1254       with True kvs''[symmetric] refl refl
  1255       have "length (snd (rbtreeify_g (n div 2) kvs'')) = 
  1256         Suc (length kvs'') - n div 2" by(rule IH)
  1257       finally show ?thesis using len[unfolded kvs''] "1.prems" True
  1258         by(simp add: Suc_diff_le[symmetric] mult_2[symmetric] minus_mod_eq_mult_div [symmetric])
  1259     next
  1260       case False
  1261       hence "length (snd (rbtreeify_f n kvs)) = 
  1262         length (snd (rbtreeify_f (Suc (2 * (n div 2))) kvs))"
  1263         by (simp add: mod_eq_0_iff_dvd)
  1264       also from "1.prems" \<open>\<not> n \<le> 1\<close> obtain k v kvs' 
  1265         where kvs: "kvs = (k, v) # kvs'" by(cases kvs) auto
  1266       also have "0 < n div 2" using \<open>\<not> n \<le> 1\<close> by(simp) 
  1267       note rbtreeify_f_simps(4)[OF this]
  1268       also note kvs[symmetric] 
  1269       also let ?rest1 = "snd (rbtreeify_f (n div 2) kvs)"
  1270       from "1.prems" have "n div 2 \<le> length kvs" by simp
  1271       with False have len: "length ?rest1 = length kvs - n div 2" by(rule IH)
  1272       with "1.prems" \<open>\<not> n \<le> 1\<close> obtain t1 k' v' kvs''
  1273         where kvs'': "rbtreeify_f (n div 2) kvs = (t1, (k', v') # kvs'')"
  1274         by(cases ?rest1)(auto simp add: snd_def split: prod.split_asm)
  1275       note this also note prod.case also note list.simps(5)
  1276       also note prod.case also note snd_apfst
  1277       also have "n div 2 \<le> length kvs''" 
  1278         using len "1.prems" False unfolding kvs'' by simp arith
  1279       with False kvs''[symmetric] refl refl
  1280       have "length (snd (rbtreeify_f (n div 2) kvs'')) = length kvs'' - n div 2"
  1281         by(rule IH)
  1282       finally show ?thesis using len[unfolded kvs''] "1.prems" False
  1283         by simp(rule rbtreeify_f_rec_aux_lemma[OF sym])
  1284     qed
  1285   qed
  1286 next
  1287   case (2 n kvs)
  1288   show ?case
  1289   proof(cases "n > 1")
  1290     case False with \<open>0 < n\<close> show ?thesis
  1291       by(cases n kvs rule: nat.exhaust[case_product list.exhaust]) simp_all
  1292   next
  1293     case True
  1294     hence "\<not> (n = 0 \<or> n = 1)" by simp
  1295     note IH = "2.IH"[OF this]
  1296     show ?thesis
  1297     proof(cases "n mod 2 = 0")
  1298       case True
  1299       hence "length (snd (rbtreeify_g n kvs)) =
  1300         length (snd (rbtreeify_g (2 * (n div 2)) kvs))"
  1301         by(metis minus_nat.diff_0 minus_mod_eq_mult_div [symmetric])
  1302       also from "2.prems" True obtain k v kvs' 
  1303         where kvs: "kvs = (k, v) # kvs'" by(cases kvs) auto
  1304       also have "0 < n div 2" using \<open>1 < n\<close> by(simp) 
  1305       note rbtreeify_g_simps(3)[OF this]
  1306       also note kvs[symmetric] 
  1307       also let ?rest1 = "snd (rbtreeify_g (n div 2) kvs)"
  1308       from "2.prems" \<open>1 < n\<close>
  1309       have "0 < n div 2" "n div 2 \<le> Suc (length kvs)" by simp_all
  1310       with True have len: "length ?rest1 = Suc (length kvs) - n div 2" by(rule IH)
  1311       with "2.prems" obtain t1 k' v' kvs''
  1312         where kvs'': "rbtreeify_g (n div 2) kvs = (t1, (k', v') # kvs'')"
  1313         by(cases ?rest1)(auto simp add: snd_def split: prod.split_asm)
  1314       note this also note prod.case also note list.simps(5) 
  1315       also note prod.case also note snd_apfst
  1316       also have "n div 2 \<le> Suc (length kvs'')" 
  1317         using len "2.prems" unfolding kvs'' by simp
  1318       with True kvs''[symmetric] refl refl \<open>0 < n div 2\<close>
  1319       have "length (snd (rbtreeify_g (n div 2) kvs'')) = Suc (length kvs'') - n div 2"
  1320         by(rule IH)
  1321       finally show ?thesis using len[unfolded kvs''] "2.prems" True
  1322         by(simp add: Suc_diff_le[symmetric] mult_2[symmetric] minus_mod_eq_mult_div [symmetric])
  1323     next
  1324       case False
  1325       hence "length (snd (rbtreeify_g n kvs)) = 
  1326         length (snd (rbtreeify_g (Suc (2 * (n div 2))) kvs))"
  1327         by (simp add: mod_eq_0_iff_dvd)
  1328       also from "2.prems" \<open>1 < n\<close> obtain k v kvs'
  1329         where kvs: "kvs = (k, v) # kvs'" by(cases kvs) auto
  1330       also have "0 < n div 2" using \<open>1 < n\<close> by(simp)
  1331       note rbtreeify_g_simps(4)[OF this]
  1332       also note kvs[symmetric] 
  1333       also let ?rest1 = "snd (rbtreeify_f (n div 2) kvs)"
  1334       from "2.prems" have "n div 2 \<le> length kvs" by simp
  1335       with False have len: "length ?rest1 = length kvs - n div 2" by(rule IH)
  1336       with "2.prems" \<open>1 < n\<close> False obtain t1 k' v' kvs'' 
  1337         where kvs'': "rbtreeify_f (n div 2) kvs = (t1, (k', v') # kvs'')"
  1338         by(cases ?rest1)(auto simp add: snd_def split: prod.split_asm, arith)
  1339       note this also note prod.case also note list.simps(5) 
  1340       also note prod.case also note snd_apfst
  1341       also have "n div 2 \<le> Suc (length kvs'')" 
  1342         using len "2.prems" False unfolding kvs'' by simp arith
  1343       with False kvs''[symmetric] refl refl \<open>0 < n div 2\<close>
  1344       have "length (snd (rbtreeify_g (n div 2) kvs'')) = Suc (length kvs'') - n div 2"
  1345         by(rule IH)
  1346       finally show ?thesis using len[unfolded kvs''] "2.prems" False
  1347         by(simp add: div2_plus_div2)
  1348     qed
  1349   qed
  1350 qed
  1351 
  1352 lemma rbtreeify_induct [consumes 1, case_names f_0 f_1 f_even f_odd g_0 g_1 g_even g_odd]:
  1353   fixes P Q
  1354   defines "f0 == (\<And>kvs. P 0 kvs)"
  1355   and "f1 == (\<And>k v kvs. P (Suc 0) ((k, v) # kvs))"
  1356   and "feven ==
  1357     (\<And>n kvs t k v kvs'. \<lbrakk> n > 0; n \<le> length kvs; P n kvs; 
  1358        rbtreeify_f n kvs = (t, (k, v) # kvs'); n \<le> Suc (length kvs'); Q n kvs' \<rbrakk> 
  1359      \<Longrightarrow> P (2 * n) kvs)"
  1360   and "fodd == 
  1361     (\<And>n kvs t k v kvs'. \<lbrakk> n > 0; n \<le> length kvs; P n kvs;
  1362        rbtreeify_f n kvs = (t, (k, v) # kvs'); n \<le> length kvs'; P n kvs' \<rbrakk> 
  1363     \<Longrightarrow> P (Suc (2 * n)) kvs)"
  1364   and "g0 == (\<And>kvs. Q 0 kvs)"
  1365   and "g1 == (\<And>kvs. Q (Suc 0) kvs)"
  1366   and "geven == 
  1367     (\<And>n kvs t k v kvs'. \<lbrakk> n > 0; n \<le> Suc (length kvs); Q n kvs; 
  1368        rbtreeify_g n kvs = (t, (k, v) # kvs'); n \<le> Suc (length kvs'); Q n kvs' \<rbrakk>
  1369     \<Longrightarrow> Q (2 * n) kvs)"
  1370   and "godd == 
  1371     (\<And>n kvs t k v kvs'. \<lbrakk> n > 0; n \<le> length kvs; P n kvs;
  1372        rbtreeify_f n kvs = (t, (k, v) # kvs'); n \<le> Suc (length kvs'); Q n kvs' \<rbrakk>
  1373     \<Longrightarrow> Q (Suc (2 * n)) kvs)"
  1374   shows "\<lbrakk> n \<le> length kvs; 
  1375            PROP f0; PROP f1; PROP feven; PROP fodd; 
  1376            PROP g0; PROP g1; PROP geven; PROP godd \<rbrakk>
  1377          \<Longrightarrow> P n kvs"
  1378   and "\<lbrakk> n \<le> Suc (length kvs);
  1379           PROP f0; PROP f1; PROP feven; PROP fodd; 
  1380           PROP g0; PROP g1; PROP geven; PROP godd \<rbrakk>
  1381        \<Longrightarrow> Q n kvs"
  1382 proof -
  1383   assume f0: "PROP f0" and f1: "PROP f1" and feven: "PROP feven" and fodd: "PROP fodd"
  1384     and g0: "PROP g0" and g1: "PROP g1" and geven: "PROP geven" and godd: "PROP godd"
  1385   show "n \<le> length kvs \<Longrightarrow> P n kvs" and "n \<le> Suc (length kvs) \<Longrightarrow> Q n kvs"
  1386   proof(induction rule: rbtreeify_f_rbtreeify_g.induct)
  1387     case (1 n kvs)
  1388     show ?case
  1389     proof(cases "n \<le> 1")
  1390       case True thus ?thesis using "1.prems"
  1391         by(cases n kvs rule: nat.exhaust[case_product list.exhaust])
  1392           (auto simp add: f0[unfolded f0_def] f1[unfolded f1_def])
  1393     next
  1394       case False 
  1395       hence ns: "n \<noteq> 0" "n \<noteq> 1" by simp_all
  1396       hence ge0: "n div 2 > 0" by simp
  1397       note IH = "1.IH"[OF ns]
  1398       show ?thesis
  1399       proof(cases "n mod 2 = 0")
  1400         case True note ge0 
  1401         moreover from "1.prems" have n2: "n div 2 \<le> length kvs" by simp
  1402         moreover from True n2 have "P (n div 2) kvs" by(rule IH)
  1403         moreover from length_rbtreeify_f[OF n2] ge0 "1.prems" obtain t k v kvs' 
  1404           where kvs': "rbtreeify_f (n div 2) kvs = (t, (k, v) # kvs')"
  1405           by(cases "snd (rbtreeify_f (n div 2) kvs)")
  1406             (auto simp add: snd_def split: prod.split_asm)
  1407         moreover from "1.prems" length_rbtreeify_f[OF n2] ge0
  1408         have n2': "n div 2 \<le> Suc (length kvs')" by(simp add: kvs')
  1409         moreover from True kvs'[symmetric] refl refl n2'
  1410         have "Q (n div 2) kvs'" by(rule IH)
  1411         moreover note feven[unfolded feven_def]
  1412           (* FIXME: why does by(rule feven[unfolded feven_def]) not work? *)
  1413         ultimately have "P (2 * (n div 2)) kvs" by -
  1414         thus ?thesis using True by (metis minus_mod_eq_div_mult [symmetric] minus_nat.diff_0 mult.commute)
  1415       next
  1416         case False note ge0
  1417         moreover from "1.prems" have n2: "n div 2 \<le> length kvs" by simp
  1418         moreover from False n2 have "P (n div 2) kvs" by(rule IH)
  1419         moreover from length_rbtreeify_f[OF n2] ge0 "1.prems" obtain t k v kvs' 
  1420           where kvs': "rbtreeify_f (n div 2) kvs = (t, (k, v) # kvs')"
  1421           by(cases "snd (rbtreeify_f (n div 2) kvs)")
  1422             (auto simp add: snd_def split: prod.split_asm)
  1423         moreover from "1.prems" length_rbtreeify_f[OF n2] ge0 False
  1424         have n2': "n div 2 \<le> length kvs'" by(simp add: kvs') arith
  1425         moreover from False kvs'[symmetric] refl refl n2' have "P (n div 2) kvs'" by(rule IH)
  1426         moreover note fodd[unfolded fodd_def]
  1427         ultimately have "P (Suc (2 * (n div 2))) kvs" by -
  1428         thus ?thesis using False 
  1429           by simp (metis One_nat_def Suc_eq_plus1_left le_add_diff_inverse mod_less_eq_dividend minus_mod_eq_mult_div [symmetric])
  1430       qed
  1431     qed
  1432   next
  1433     case (2 n kvs)
  1434     show ?case
  1435     proof(cases "n \<le> 1")
  1436       case True thus ?thesis using "2.prems"
  1437         by(cases n kvs rule: nat.exhaust[case_product list.exhaust])
  1438           (auto simp add: g0[unfolded g0_def] g1[unfolded g1_def])
  1439     next
  1440       case False 
  1441       hence ns: "\<not> (n = 0 \<or> n = 1)" by simp
  1442       hence ge0: "n div 2 > 0" by simp
  1443       note IH = "2.IH"[OF ns]
  1444       show ?thesis
  1445       proof(cases "n mod 2 = 0")
  1446         case True note ge0
  1447         moreover from "2.prems" have n2: "n div 2 \<le> Suc (length kvs)" by simp
  1448         moreover from True n2 have "Q (n div 2) kvs" by(rule IH)
  1449         moreover from length_rbtreeify_g[OF ge0 n2] ge0 "2.prems" obtain t k v kvs' 
  1450           where kvs': "rbtreeify_g (n div 2) kvs = (t, (k, v) # kvs')"
  1451           by(cases "snd (rbtreeify_g (n div 2) kvs)")
  1452             (auto simp add: snd_def split: prod.split_asm)
  1453         moreover from "2.prems" length_rbtreeify_g[OF ge0 n2] ge0
  1454         have n2': "n div 2 \<le> Suc (length kvs')" by(simp add: kvs')
  1455         moreover from True kvs'[symmetric] refl refl  n2'
  1456         have "Q (n div 2) kvs'" by(rule IH)
  1457         moreover note geven[unfolded geven_def]
  1458         ultimately have "Q (2 * (n div 2)) kvs" by -
  1459         thus ?thesis using True 
  1460           by(metis minus_mod_eq_div_mult [symmetric] minus_nat.diff_0 mult.commute)
  1461       next
  1462         case False note ge0
  1463         moreover from "2.prems" have n2: "n div 2 \<le> length kvs" by simp
  1464         moreover from False n2 have "P (n div 2) kvs" by(rule IH)
  1465         moreover from length_rbtreeify_f[OF n2] ge0 "2.prems" False obtain t k v kvs' 
  1466           where kvs': "rbtreeify_f (n div 2) kvs = (t, (k, v) # kvs')"
  1467           by(cases "snd (rbtreeify_f (n div 2) kvs)")
  1468             (auto simp add: snd_def split: prod.split_asm, arith)
  1469         moreover from "2.prems" length_rbtreeify_f[OF n2] ge0 False
  1470         have n2': "n div 2 \<le> Suc (length kvs')" by(simp add: kvs') arith
  1471         moreover from False kvs'[symmetric] refl refl n2'
  1472         have "Q (n div 2) kvs'" by(rule IH)
  1473         moreover note godd[unfolded godd_def]
  1474         ultimately have "Q (Suc (2 * (n div 2))) kvs" by -
  1475         thus ?thesis using False 
  1476           by simp (metis One_nat_def Suc_eq_plus1_left le_add_diff_inverse mod_less_eq_dividend minus_mod_eq_mult_div [symmetric])
  1477       qed
  1478     qed
  1479   qed
  1480 qed
  1481 
  1482 lemma inv1_rbtreeify_f: "n \<le> length kvs 
  1483   \<Longrightarrow> inv1 (fst (rbtreeify_f n kvs))"
  1484   and inv1_rbtreeify_g: "n \<le> Suc (length kvs)
  1485   \<Longrightarrow> inv1 (fst (rbtreeify_g n kvs))"
  1486 by(induct n kvs and n kvs rule: rbtreeify_induct) simp_all
  1487 
  1488 fun plog2 :: "nat \<Rightarrow> nat" 
  1489 where "plog2 n = (if n \<le> 1 then 0 else plog2 (n div 2) + 1)"
  1490 
  1491 declare plog2.simps [simp del]
  1492 
  1493 lemma plog2_simps [simp]:
  1494   "plog2 0 = 0" "plog2 (Suc 0) = 0"
  1495   "0 < n \<Longrightarrow> plog2 (2 * n) = 1 + plog2 n"
  1496   "0 < n \<Longrightarrow> plog2 (Suc (2 * n)) = 1 + plog2 n"
  1497 by(subst plog2.simps, simp add: Suc_double_half)+
  1498 
  1499 lemma bheight_rbtreeify_f: "n \<le> length kvs
  1500   \<Longrightarrow> bheight (fst (rbtreeify_f n kvs)) = plog2 n"
  1501   and bheight_rbtreeify_g: "n \<le> Suc (length kvs)
  1502   \<Longrightarrow> bheight (fst (rbtreeify_g n kvs)) = plog2 n"
  1503 by(induct n kvs and n kvs rule: rbtreeify_induct) simp_all
  1504 
  1505 lemma bheight_rbtreeify_f_eq_plog2I:
  1506   "\<lbrakk> rbtreeify_f n kvs = (t, kvs'); n \<le> length kvs \<rbrakk> 
  1507   \<Longrightarrow> bheight t = plog2 n"
  1508 using bheight_rbtreeify_f[of n kvs] by simp
  1509 
  1510 lemma bheight_rbtreeify_g_eq_plog2I: 
  1511   "\<lbrakk> rbtreeify_g n kvs = (t, kvs'); n \<le> Suc (length kvs) \<rbrakk>
  1512   \<Longrightarrow> bheight t = plog2 n"
  1513 using bheight_rbtreeify_g[of n kvs] by simp
  1514 
  1515 hide_const (open) plog2
  1516 
  1517 lemma inv2_rbtreeify_f: "n \<le> length kvs
  1518   \<Longrightarrow> inv2 (fst (rbtreeify_f n kvs))"
  1519   and inv2_rbtreeify_g: "n \<le> Suc (length kvs)
  1520   \<Longrightarrow> inv2 (fst (rbtreeify_g n kvs))"
  1521 by(induct n kvs and n kvs rule: rbtreeify_induct)
  1522   (auto simp add: bheight_rbtreeify_f bheight_rbtreeify_g 
  1523         intro: bheight_rbtreeify_f_eq_plog2I bheight_rbtreeify_g_eq_plog2I)
  1524 
  1525 lemma "n \<le> length kvs \<Longrightarrow> True"
  1526   and color_of_rbtreeify_g:
  1527   "\<lbrakk> n \<le> Suc (length kvs); 0 < n \<rbrakk> 
  1528   \<Longrightarrow> color_of (fst (rbtreeify_g n kvs)) = B"
  1529 by(induct n kvs and n kvs rule: rbtreeify_induct) simp_all
  1530 
  1531 lemma entries_rbtreeify_f_append:
  1532   "n \<le> length kvs 
  1533   \<Longrightarrow> entries (fst (rbtreeify_f n kvs)) @ snd (rbtreeify_f n kvs) = kvs"
  1534   and entries_rbtreeify_g_append: 
  1535   "n \<le> Suc (length kvs) 
  1536   \<Longrightarrow> entries (fst (rbtreeify_g n kvs)) @ snd (rbtreeify_g n kvs) = kvs"
  1537 by(induction rule: rbtreeify_induct) simp_all
  1538 
  1539 lemma length_entries_rbtreeify_f:
  1540   "n \<le> length kvs \<Longrightarrow> length (entries (fst (rbtreeify_f n kvs))) = n"
  1541   and length_entries_rbtreeify_g: 
  1542   "n \<le> Suc (length kvs) \<Longrightarrow> length (entries (fst (rbtreeify_g n kvs))) = n - 1"
  1543 by(induct rule: rbtreeify_induct) simp_all
  1544 
  1545 lemma rbtreeify_f_conv_drop: 
  1546   "n \<le> length kvs \<Longrightarrow> snd (rbtreeify_f n kvs) = drop n kvs"
  1547 using entries_rbtreeify_f_append[of n kvs]
  1548 by(simp add: append_eq_conv_conj length_entries_rbtreeify_f)
  1549 
  1550 lemma rbtreeify_g_conv_drop: 
  1551   "n \<le> Suc (length kvs) \<Longrightarrow> snd (rbtreeify_g n kvs) = drop (n - 1) kvs"
  1552 using entries_rbtreeify_g_append[of n kvs]
  1553 by(simp add: append_eq_conv_conj length_entries_rbtreeify_g)
  1554 
  1555 lemma entries_rbtreeify_f [simp]:
  1556   "n \<le> length kvs \<Longrightarrow> entries (fst (rbtreeify_f n kvs)) = take n kvs"
  1557 using entries_rbtreeify_f_append[of n kvs]
  1558 by(simp add: append_eq_conv_conj length_entries_rbtreeify_f)
  1559 
  1560 lemma entries_rbtreeify_g [simp]:
  1561   "n \<le> Suc (length kvs) \<Longrightarrow> 
  1562   entries (fst (rbtreeify_g n kvs)) = take (n - 1) kvs"
  1563 using entries_rbtreeify_g_append[of n kvs]
  1564 by(simp add: append_eq_conv_conj length_entries_rbtreeify_g)
  1565 
  1566 lemma keys_rbtreeify_f [simp]: "n \<le> length kvs
  1567   \<Longrightarrow> keys (fst (rbtreeify_f n kvs)) = take n (map fst kvs)"
  1568 by(simp add: keys_def take_map)
  1569 
  1570 lemma keys_rbtreeify_g [simp]: "n \<le> Suc (length kvs)
  1571   \<Longrightarrow> keys (fst (rbtreeify_g n kvs)) = take (n - 1) (map fst kvs)"
  1572 by(simp add: keys_def take_map)
  1573 
  1574 lemma rbtreeify_fD: 
  1575   "\<lbrakk> rbtreeify_f n kvs = (t, kvs'); n \<le> length kvs \<rbrakk> 
  1576   \<Longrightarrow> entries t = take n kvs \<and> kvs' = drop n kvs"
  1577 using rbtreeify_f_conv_drop[of n kvs] entries_rbtreeify_f[of n kvs] by simp
  1578 
  1579 lemma rbtreeify_gD: 
  1580   "\<lbrakk> rbtreeify_g n kvs = (t, kvs'); n \<le> Suc (length kvs) \<rbrakk>
  1581   \<Longrightarrow> entries t = take (n - 1) kvs \<and> kvs' = drop (n - 1) kvs"
  1582 using rbtreeify_g_conv_drop[of n kvs] entries_rbtreeify_g[of n kvs] by simp
  1583 
  1584 lemma entries_rbtreeify [simp]: "entries (rbtreeify kvs) = kvs"
  1585 by(simp add: rbtreeify_def entries_rbtreeify_g)
  1586 
  1587 context linorder begin
  1588 
  1589 lemma rbt_sorted_rbtreeify_f: 
  1590   "\<lbrakk> n \<le> length kvs; sorted (map fst kvs); distinct (map fst kvs) \<rbrakk> 
  1591   \<Longrightarrow> rbt_sorted (fst (rbtreeify_f n kvs))"
  1592   and rbt_sorted_rbtreeify_g: 
  1593   "\<lbrakk> n \<le> Suc (length kvs); sorted (map fst kvs); distinct (map fst kvs) \<rbrakk>
  1594   \<Longrightarrow> rbt_sorted (fst (rbtreeify_g n kvs))"
  1595 proof(induction n kvs and n kvs rule: rbtreeify_induct)
  1596   case (f_even n kvs t k v kvs')
  1597   from rbtreeify_fD[OF \<open>rbtreeify_f n kvs = (t, (k, v) # kvs')\<close> \<open>n \<le> length kvs\<close>]
  1598   have "entries t = take n kvs"
  1599     and kvs': "drop n kvs = (k, v) # kvs'" by simp_all
  1600   hence unfold: "kvs = take n kvs @ (k, v) # kvs'" by(metis append_take_drop_id)
  1601   from \<open>sorted (map fst kvs)\<close> kvs'
  1602   have "(\<forall>(x, y) \<in> set (take n kvs). x \<le> k) \<and> (\<forall>(x, y) \<in> set kvs'. k \<le> x)"
  1603     by(subst (asm) unfold)(auto simp add: sorted_append)
  1604   moreover from \<open>distinct (map fst kvs)\<close> kvs'
  1605   have "(\<forall>(x, y) \<in> set (take n kvs). x \<noteq> k) \<and> (\<forall>(x, y) \<in> set kvs'. x \<noteq> k)"
  1606     by(subst (asm) unfold)(auto intro: rev_image_eqI)
  1607   ultimately have "(\<forall>(x, y) \<in> set (take n kvs). x < k) \<and> (\<forall>(x, y) \<in> set kvs'. k < x)"
  1608     by fastforce
  1609   hence "fst (rbtreeify_f n kvs) |\<guillemotleft> k" "k \<guillemotleft>| fst (rbtreeify_g n kvs')"
  1610     using \<open>n \<le> Suc (length kvs')\<close> \<open>n \<le> length kvs\<close> set_take_subset[of "n - 1" kvs']
  1611     by(auto simp add: ord.rbt_greater_prop ord.rbt_less_prop take_map split_def)
  1612   moreover from \<open>sorted (map fst kvs)\<close> \<open>distinct (map fst kvs)\<close>
  1613   have "rbt_sorted (fst (rbtreeify_f n kvs))" by(rule f_even.IH)
  1614   moreover have "sorted (map fst kvs')" "distinct (map fst kvs')"
  1615     using \<open>sorted (map fst kvs)\<close> \<open>distinct (map fst kvs)\<close>
  1616     by(subst (asm) (1 2) unfold, simp add: sorted_append)+
  1617   hence "rbt_sorted (fst (rbtreeify_g n kvs'))" by(rule f_even.IH)
  1618   ultimately show ?case
  1619     using \<open>0 < n\<close> \<open>rbtreeify_f n kvs = (t, (k, v) # kvs')\<close> by simp
  1620 next
  1621   case (f_odd n kvs t k v kvs')
  1622   from rbtreeify_fD[OF \<open>rbtreeify_f n kvs = (t, (k, v) # kvs')\<close> \<open>n \<le> length kvs\<close>]
  1623   have "entries t = take n kvs" 
  1624     and kvs': "drop n kvs = (k, v) # kvs'" by simp_all
  1625   hence unfold: "kvs = take n kvs @ (k, v) # kvs'" by(metis append_take_drop_id)
  1626   from \<open>sorted (map fst kvs)\<close> kvs'
  1627   have "(\<forall>(x, y) \<in> set (take n kvs). x \<le> k) \<and> (\<forall>(x, y) \<in> set kvs'. k \<le> x)"
  1628     by(subst (asm) unfold)(auto simp add: sorted_append)
  1629   moreover from \<open>distinct (map fst kvs)\<close> kvs'
  1630   have "(\<forall>(x, y) \<in> set (take n kvs). x \<noteq> k) \<and> (\<forall>(x, y) \<in> set kvs'. x \<noteq> k)"
  1631     by(subst (asm) unfold)(auto intro: rev_image_eqI)
  1632   ultimately have "(\<forall>(x, y) \<in> set (take n kvs). x < k) \<and> (\<forall>(x, y) \<in> set kvs'. k < x)"
  1633     by fastforce
  1634   hence "fst (rbtreeify_f n kvs) |\<guillemotleft> k" "k \<guillemotleft>| fst (rbtreeify_f n kvs')"
  1635     using \<open>n \<le> length kvs'\<close> \<open>n \<le> length kvs\<close> set_take_subset[of n kvs']
  1636     by(auto simp add: rbt_greater_prop rbt_less_prop take_map split_def)
  1637   moreover from \<open>sorted (map fst kvs)\<close> \<open>distinct (map fst kvs)\<close>
  1638   have "rbt_sorted (fst (rbtreeify_f n kvs))" by(rule f_odd.IH)
  1639   moreover have "sorted (map fst kvs')" "distinct (map fst kvs')"
  1640     using \<open>sorted (map fst kvs)\<close> \<open>distinct (map fst kvs)\<close>
  1641     by(subst (asm) (1 2) unfold, simp add: sorted_append)+
  1642   hence "rbt_sorted (fst (rbtreeify_f n kvs'))" by(rule f_odd.IH)
  1643   ultimately show ?case 
  1644     using \<open>0 < n\<close> \<open>rbtreeify_f n kvs = (t, (k, v) # kvs')\<close> by simp
  1645 next
  1646   case (g_even n kvs t k v kvs')
  1647   from rbtreeify_gD[OF \<open>rbtreeify_g n kvs = (t, (k, v) # kvs')\<close> \<open>n \<le> Suc (length kvs)\<close>]
  1648   have t: "entries t = take (n - 1) kvs" 
  1649     and kvs': "drop (n - 1) kvs = (k, v) # kvs'" by simp_all
  1650   hence unfold: "kvs = take (n - 1) kvs @ (k, v) # kvs'" by(metis append_take_drop_id)
  1651   from \<open>sorted (map fst kvs)\<close> kvs'
  1652   have "(\<forall>(x, y) \<in> set (take (n - 1) kvs). x \<le> k) \<and> (\<forall>(x, y) \<in> set kvs'. k \<le> x)"
  1653     by(subst (asm) unfold)(auto simp add: sorted_append)
  1654   moreover from \<open>distinct (map fst kvs)\<close> kvs'
  1655   have "(\<forall>(x, y) \<in> set (take (n - 1) kvs). x \<noteq> k) \<and> (\<forall>(x, y) \<in> set kvs'. x \<noteq> k)"
  1656     by(subst (asm) unfold)(auto intro: rev_image_eqI)
  1657   ultimately have "(\<forall>(x, y) \<in> set (take (n - 1) kvs). x < k) \<and> (\<forall>(x, y) \<in> set kvs'. k < x)"
  1658     by fastforce
  1659   hence "fst (rbtreeify_g n kvs) |\<guillemotleft> k" "k \<guillemotleft>| fst (rbtreeify_g n kvs')"
  1660     using \<open>n \<le> Suc (length kvs')\<close> \<open>n \<le> Suc (length kvs)\<close> set_take_subset[of "n - 1" kvs']
  1661     by(auto simp add: rbt_greater_prop rbt_less_prop take_map split_def)
  1662   moreover from \<open>sorted (map fst kvs)\<close> \<open>distinct (map fst kvs)\<close>
  1663   have "rbt_sorted (fst (rbtreeify_g n kvs))" by(rule g_even.IH)
  1664   moreover have "sorted (map fst kvs')" "distinct (map fst kvs')"
  1665     using \<open>sorted (map fst kvs)\<close> \<open>distinct (map fst kvs)\<close>
  1666     by(subst (asm) (1 2) unfold, simp add: sorted_append)+
  1667   hence "rbt_sorted (fst (rbtreeify_g n kvs'))" by(rule g_even.IH)
  1668   ultimately show ?case using \<open>0 < n\<close> \<open>rbtreeify_g n kvs = (t, (k, v) # kvs')\<close> by simp
  1669 next
  1670   case (g_odd n kvs t k v kvs')
  1671   from rbtreeify_fD[OF \<open>rbtreeify_f n kvs = (t, (k, v) # kvs')\<close> \<open>n \<le> length kvs\<close>]
  1672   have "entries t = take n kvs"
  1673     and kvs': "drop n kvs = (k, v) # kvs'" by simp_all
  1674   hence unfold: "kvs = take n kvs @ (k, v) # kvs'" by(metis append_take_drop_id)
  1675   from \<open>sorted (map fst kvs)\<close> kvs'
  1676   have "(\<forall>(x, y) \<in> set (take n kvs). x \<le> k) \<and> (\<forall>(x, y) \<in> set kvs'. k \<le> x)"
  1677     by(subst (asm) unfold)(auto simp add: sorted_append)
  1678   moreover from \<open>distinct (map fst kvs)\<close> kvs'
  1679   have "(\<forall>(x, y) \<in> set (take n kvs). x \<noteq> k) \<and> (\<forall>(x, y) \<in> set kvs'. x \<noteq> k)"
  1680     by(subst (asm) unfold)(auto intro: rev_image_eqI)
  1681   ultimately have "(\<forall>(x, y) \<in> set (take n kvs). x < k) \<and> (\<forall>(x, y) \<in> set kvs'. k < x)"
  1682     by fastforce
  1683   hence "fst (rbtreeify_f n kvs) |\<guillemotleft> k" "k \<guillemotleft>| fst (rbtreeify_g n kvs')"
  1684     using \<open>n \<le> Suc (length kvs')\<close> \<open>n \<le> length kvs\<close> set_take_subset[of "n - 1" kvs']
  1685     by(auto simp add: rbt_greater_prop rbt_less_prop take_map split_def)
  1686   moreover from \<open>sorted (map fst kvs)\<close> \<open>distinct (map fst kvs)\<close>
  1687   have "rbt_sorted (fst (rbtreeify_f n kvs))" by(rule g_odd.IH)
  1688   moreover have "sorted (map fst kvs')" "distinct (map fst kvs')"
  1689     using \<open>sorted (map fst kvs)\<close> \<open>distinct (map fst kvs)\<close>
  1690     by(subst (asm) (1 2) unfold, simp add: sorted_append)+
  1691   hence "rbt_sorted (fst (rbtreeify_g n kvs'))" by(rule g_odd.IH)
  1692   ultimately show ?case
  1693     using \<open>0 < n\<close> \<open>rbtreeify_f n kvs = (t, (k, v) # kvs')\<close> by simp
  1694 qed simp_all
  1695 
  1696 lemma rbt_sorted_rbtreeify: 
  1697   "\<lbrakk> sorted (map fst kvs); distinct (map fst kvs) \<rbrakk> \<Longrightarrow> rbt_sorted (rbtreeify kvs)"
  1698 by(simp add: rbtreeify_def rbt_sorted_rbtreeify_g)
  1699 
  1700 lemma is_rbt_rbtreeify: 
  1701   "\<lbrakk> sorted (map fst kvs); distinct (map fst kvs) \<rbrakk>
  1702   \<Longrightarrow> is_rbt (rbtreeify kvs)"
  1703 by(simp add: is_rbt_def rbtreeify_def inv1_rbtreeify_g inv2_rbtreeify_g rbt_sorted_rbtreeify_g color_of_rbtreeify_g)
  1704 
  1705 lemma rbt_lookup_rbtreeify:
  1706   "\<lbrakk> sorted (map fst kvs); distinct (map fst kvs) \<rbrakk> \<Longrightarrow> 
  1707   rbt_lookup (rbtreeify kvs) = map_of kvs"
  1708 by(simp add: map_of_entries[symmetric] rbt_sorted_rbtreeify)
  1709 
  1710 end
  1711 
  1712 text \<open>
  1713   Functions to compare the height of two rbt trees, taken from 
  1714   Andrew W. Appel, Efficient Verified Red-Black Trees (September 2011)
  1715 \<close>
  1716 
  1717 fun skip_red :: "('a, 'b) rbt \<Rightarrow> ('a, 'b) rbt"
  1718 where
  1719   "skip_red (Branch color.R l k v r) = l"
  1720 | "skip_red t = t"
  1721 
  1722 definition skip_black :: "('a, 'b) rbt \<Rightarrow> ('a, 'b) rbt"
  1723 where
  1724   "skip_black t = (let t' = skip_red t in case t' of Branch color.B l k v r \<Rightarrow> l | _ \<Rightarrow> t')"
  1725 
  1726 datatype compare = LT | GT | EQ
  1727 
  1728 partial_function (tailrec) compare_height :: "('a, 'b) rbt \<Rightarrow> ('a, 'b) rbt \<Rightarrow> ('a, 'b) rbt \<Rightarrow> ('a, 'b) rbt \<Rightarrow> compare"
  1729 where
  1730   "compare_height sx s t tx =
  1731   (case (skip_red sx, skip_red s, skip_red t, skip_red tx) of
  1732      (Branch _ sx' _ _ _, Branch _ s' _ _ _, Branch _ t' _ _ _, Branch _ tx' _ _ _) \<Rightarrow> 
  1733        compare_height (skip_black sx') s' t' (skip_black tx')
  1734    | (_, rbt.Empty, _, Branch _ _ _ _ _) \<Rightarrow> LT
  1735    | (Branch _ _ _ _ _, _, rbt.Empty, _) \<Rightarrow> GT
  1736    | (Branch _ sx' _ _ _, Branch _ s' _ _ _, Branch _ t' _ _ _, rbt.Empty) \<Rightarrow>
  1737        compare_height (skip_black sx') s' t' rbt.Empty
  1738    | (rbt.Empty, Branch _ s' _ _ _, Branch _ t' _ _ _, Branch _ tx' _ _ _) \<Rightarrow>
  1739        compare_height rbt.Empty s' t' (skip_black tx')
  1740    | _ \<Rightarrow> EQ)"
  1741 
  1742 declare compare_height.simps [code]
  1743 
  1744 hide_type (open) compare
  1745 hide_const (open)
  1746   compare_height skip_black skip_red LT GT EQ case_compare rec_compare
  1747   Abs_compare Rep_compare
  1748 hide_fact (open)
  1749   Abs_compare_cases Abs_compare_induct Abs_compare_inject Abs_compare_inverse
  1750   Rep_compare Rep_compare_cases Rep_compare_induct Rep_compare_inject Rep_compare_inverse
  1751   compare.simps compare.exhaust compare.induct compare.rec compare.simps
  1752   compare.size compare.case_cong compare.case_cong_weak compare.case
  1753   compare.nchotomy compare.split compare.split_asm compare.eq.refl compare.eq.simps
  1754   equal_compare_def
  1755   skip_red.simps skip_red.cases skip_red.induct 
  1756   skip_black_def
  1757   compare_height.simps
  1758 
  1759 subsection \<open>union and intersection of sorted associative lists\<close>
  1760 
  1761 context ord begin
  1762 
  1763 function sunion_with :: "('a \<Rightarrow> 'b \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> ('a \<times> 'b) list \<Rightarrow> ('a \<times> 'b) list \<Rightarrow> ('a \<times> 'b) list" 
  1764 where
  1765   "sunion_with f ((k, v) # as) ((k', v') # bs) =
  1766    (if k > k' then (k', v') # sunion_with f ((k, v) # as) bs
  1767     else if k < k' then (k, v) # sunion_with f as ((k', v') # bs)
  1768     else (k, f k v v') # sunion_with f as bs)"
  1769 | "sunion_with f [] bs = bs"
  1770 | "sunion_with f as [] = as"
  1771 by pat_completeness auto
  1772 termination by lexicographic_order
  1773 
  1774 function sinter_with :: "('a \<Rightarrow> 'b \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> ('a \<times> 'b) list \<Rightarrow> ('a \<times> 'b) list \<Rightarrow> ('a \<times> 'b) list"
  1775 where
  1776   "sinter_with f ((k, v) # as) ((k', v') # bs) =
  1777   (if k > k' then sinter_with f ((k, v) # as) bs
  1778    else if k < k' then sinter_with f as ((k', v') # bs)
  1779    else (k, f k v v') # sinter_with f as bs)"
  1780 | "sinter_with f [] _ = []"
  1781 | "sinter_with f _ [] = []"
  1782 by pat_completeness auto
  1783 termination by lexicographic_order
  1784 
  1785 end
  1786 
  1787 declare ord.sunion_with.simps [code] ord.sinter_with.simps[code]
  1788 
  1789 context linorder begin
  1790 
  1791 lemma set_fst_sunion_with: 
  1792   "set (map fst (sunion_with f xs ys)) = set (map fst xs) \<union> set (map fst ys)"
  1793 by(induct f xs ys rule: sunion_with.induct) auto
  1794 
  1795 lemma sorted_sunion_with [simp]:
  1796   "\<lbrakk> sorted (map fst xs); sorted (map fst ys) \<rbrakk> 
  1797   \<Longrightarrow> sorted (map fst (sunion_with f xs ys))"
  1798 by(induct f xs ys rule: sunion_with.induct)
  1799   (auto simp add: set_fst_sunion_with simp del: set_map)
  1800 
  1801 lemma distinct_sunion_with [simp]:
  1802   "\<lbrakk> distinct (map fst xs); distinct (map fst ys); sorted (map fst xs); sorted (map fst ys) \<rbrakk>
  1803   \<Longrightarrow> distinct (map fst (sunion_with f xs ys))"
  1804 proof(induct f xs ys rule: sunion_with.induct)
  1805   case (1 f k v xs k' v' ys)
  1806   have "\<lbrakk> \<not> k < k'; \<not> k' < k \<rbrakk> \<Longrightarrow> k = k'" by simp
  1807   thus ?case using "1"
  1808     by(auto simp add: set_fst_sunion_with simp del: set_map)
  1809 qed simp_all
  1810 
  1811 lemma map_of_sunion_with: 
  1812   "\<lbrakk> sorted (map fst xs); sorted (map fst ys) \<rbrakk>
  1813   \<Longrightarrow> map_of (sunion_with f xs ys) k = 
  1814   (case map_of xs k of None \<Rightarrow> map_of ys k 
  1815   | Some v \<Rightarrow> case map_of ys k of None \<Rightarrow> Some v 
  1816               | Some w \<Rightarrow> Some (f k v w))"
  1817 by(induct f xs ys rule: sunion_with.induct)(auto split: option.split dest: map_of_SomeD bspec)
  1818 
  1819 lemma set_fst_sinter_with [simp]:
  1820   "\<lbrakk> sorted (map fst xs); sorted (map fst ys) \<rbrakk>
  1821   \<Longrightarrow> set (map fst (sinter_with f xs ys)) = set (map fst xs) \<inter> set (map fst ys)"
  1822 by(induct f xs ys rule: sinter_with.induct)(auto simp del: set_map)
  1823 
  1824 lemma set_fst_sinter_with_subset1:
  1825   "set (map fst (sinter_with f xs ys)) \<subseteq> set (map fst xs)"
  1826 by(induct f xs ys rule: sinter_with.induct) auto
  1827 
  1828 lemma set_fst_sinter_with_subset2:
  1829   "set (map fst (sinter_with f xs ys)) \<subseteq> set (map fst ys)"
  1830 by(induct f xs ys rule: sinter_with.induct)(auto simp del: set_map)
  1831 
  1832 lemma sorted_sinter_with [simp]:
  1833   "\<lbrakk> sorted (map fst xs); sorted (map fst ys) \<rbrakk>
  1834   \<Longrightarrow> sorted (map fst (sinter_with f xs ys))"
  1835 by(induct f xs ys rule: sinter_with.induct)(auto simp del: set_map)
  1836 
  1837 lemma distinct_sinter_with [simp]:
  1838   "\<lbrakk> distinct (map fst xs); distinct (map fst ys) \<rbrakk>
  1839   \<Longrightarrow> distinct (map fst (sinter_with f xs ys))"
  1840 proof(induct f xs ys rule: sinter_with.induct)
  1841   case (1 f k v as k' v' bs)
  1842   have "\<lbrakk> \<not> k < k'; \<not> k' < k \<rbrakk> \<Longrightarrow> k = k'" by simp
  1843   thus ?case using "1" set_fst_sinter_with_subset1[of f as bs]
  1844     set_fst_sinter_with_subset2[of f as bs]
  1845     by(auto simp del: set_map)
  1846 qed simp_all
  1847 
  1848 lemma map_of_sinter_with:
  1849   "\<lbrakk> sorted (map fst xs); sorted (map fst ys) \<rbrakk>
  1850   \<Longrightarrow> map_of (sinter_with f xs ys) k = 
  1851   (case map_of xs k of None \<Rightarrow> None | Some v \<Rightarrow> map_option (f k v) (map_of ys k))"
  1852 apply(induct f xs ys rule: sinter_with.induct)
  1853 apply(auto simp add: map_option_case split: option.splits dest: map_of_SomeD bspec)
  1854 done
  1855 
  1856 end
  1857 
  1858 lemma distinct_map_of_rev: "distinct (map fst xs) \<Longrightarrow> map_of (rev xs) = map_of xs"
  1859 by(induct xs)(auto 4 3 simp add: map_add_def intro!: ext split: option.split intro: rev_image_eqI)
  1860 
  1861 lemma map_map_filter: 
  1862   "map f (List.map_filter g xs) = List.map_filter (map_option f \<circ> g) xs"
  1863 by(auto simp add: List.map_filter_def)
  1864 
  1865 lemma map_filter_map_option_const: 
  1866   "List.map_filter (\<lambda>x. map_option (\<lambda>y. f x) (g (f x))) xs = filter (\<lambda>x. g x \<noteq> None) (map f xs)"
  1867 by(auto simp add: map_filter_def filter_map o_def)
  1868 
  1869 lemma set_map_filter: "set (List.map_filter P xs) = the ` (P ` set xs - {None})"
  1870 by(auto simp add: List.map_filter_def intro: rev_image_eqI)
  1871 
  1872 context ord begin
  1873 
  1874 definition rbt_union_with_key :: "('a \<Rightarrow> 'b \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> ('a, 'b) rbt \<Rightarrow> ('a, 'b) rbt \<Rightarrow> ('a, 'b) rbt"
  1875 where
  1876   "rbt_union_with_key f t1 t2 =
  1877   (case RBT_Impl.compare_height t1 t1 t2 t2
  1878    of compare.EQ \<Rightarrow> rbtreeify (sunion_with f (entries t1) (entries t2))
  1879     | compare.LT \<Rightarrow> fold (rbt_insert_with_key (\<lambda>k v w. f k w v)) t1 t2
  1880     | compare.GT \<Rightarrow> fold (rbt_insert_with_key f) t2 t1)"
  1881 
  1882 definition rbt_union_with where
  1883   "rbt_union_with f = rbt_union_with_key (\<lambda>_. f)"
  1884 
  1885 definition rbt_union where
  1886   "rbt_union = rbt_union_with_key (%_ _ rv. rv)"
  1887 
  1888 definition rbt_inter_with_key :: "('a \<Rightarrow> 'b \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> ('a, 'b) rbt \<Rightarrow> ('a, 'b) rbt \<Rightarrow> ('a, 'b) rbt"
  1889 where
  1890   "rbt_inter_with_key f t1 t2 =
  1891   (case RBT_Impl.compare_height t1 t1 t2 t2 
  1892    of compare.EQ \<Rightarrow> rbtreeify (sinter_with f (entries t1) (entries t2))
  1893     | compare.LT \<Rightarrow> rbtreeify (List.map_filter (\<lambda>(k, v). map_option (\<lambda>w. (k, f k v w)) (rbt_lookup t2 k)) (entries t1))
  1894     | compare.GT \<Rightarrow> rbtreeify (List.map_filter (\<lambda>(k, v). map_option (\<lambda>w. (k, f k w v)) (rbt_lookup t1 k)) (entries t2)))"
  1895 
  1896 definition rbt_inter_with where
  1897   "rbt_inter_with f = rbt_inter_with_key (\<lambda>_. f)"
  1898 
  1899 definition rbt_inter where
  1900   "rbt_inter = rbt_inter_with_key (\<lambda>_ _ rv. rv)"
  1901 
  1902 end
  1903 
  1904 context linorder begin
  1905 
  1906 lemma rbt_sorted_entries_right_unique:
  1907   "\<lbrakk> (k, v) \<in> set (entries t); (k, v') \<in> set (entries t); 
  1908      rbt_sorted t \<rbrakk> \<Longrightarrow> v = v'"
  1909 by(auto dest!: distinct_entries inj_onD[where x="(k, v)" and y="(k, v')"] simp add: distinct_map)
  1910 
  1911 lemma rbt_sorted_fold_rbt_insertwk:
  1912   "rbt_sorted t \<Longrightarrow> rbt_sorted (List.fold (\<lambda>(k, v). rbt_insert_with_key f k v) xs t)"
  1913 by(induct xs rule: rev_induct)(auto simp add: rbt_insertwk_rbt_sorted)
  1914 
  1915 lemma is_rbt_fold_rbt_insertwk:
  1916   assumes "is_rbt t1"
  1917   shows "is_rbt (fold (rbt_insert_with_key f) t2 t1)"
  1918 proof -
  1919   define xs where "xs = entries t2"
  1920   from assms show ?thesis unfolding fold_def xs_def[symmetric]
  1921     by(induct xs rule: rev_induct)(auto simp add: rbt_insertwk_is_rbt)
  1922 qed
  1923 
  1924 lemma rbt_lookup_fold_rbt_insertwk:
  1925   assumes t1: "rbt_sorted t1" and t2: "rbt_sorted t2"
  1926   shows "rbt_lookup (fold (rbt_insert_with_key f) t1 t2) k =
  1927   (case rbt_lookup t1 k of None \<Rightarrow> rbt_lookup t2 k
  1928    | Some v \<Rightarrow> case rbt_lookup t2 k of None \<Rightarrow> Some v
  1929                | Some w \<Rightarrow> Some (f k w v))"
  1930 proof -
  1931   define xs where "xs = entries t1"
  1932   hence dt1: "distinct (map fst xs)" using t1 by(simp add: distinct_entries)
  1933   with t2 show ?thesis
  1934     unfolding fold_def map_of_entries[OF t1, symmetric]
  1935       xs_def[symmetric] distinct_map_of_rev[OF dt1, symmetric]
  1936     apply(induct xs rule: rev_induct)
  1937     apply(auto simp add: rbt_lookup_rbt_insertwk rbt_sorted_fold_rbt_insertwk split: option.splits)
  1938     apply(auto simp add: distinct_map_of_rev intro: rev_image_eqI)
  1939     done
  1940 qed
  1941 
  1942 lemma is_rbt_rbt_unionwk [simp]:
  1943   "\<lbrakk> is_rbt t1; is_rbt t2 \<rbrakk> \<Longrightarrow> is_rbt (rbt_union_with_key f t1 t2)"
  1944 by(simp add: rbt_union_with_key_def Let_def is_rbt_fold_rbt_insertwk is_rbt_rbtreeify rbt_sorted_entries distinct_entries split: compare.split)
  1945 
  1946 lemma rbt_lookup_rbt_unionwk:
  1947   "\<lbrakk> rbt_sorted t1; rbt_sorted t2 \<rbrakk> 
  1948   \<Longrightarrow> rbt_lookup (rbt_union_with_key f t1 t2) k = 
  1949   (case rbt_lookup t1 k of None \<Rightarrow> rbt_lookup t2 k 
  1950    | Some v \<Rightarrow> case rbt_lookup t2 k of None \<Rightarrow> Some v 
  1951               | Some w \<Rightarrow> Some (f k v w))"
  1952 by(auto simp add: rbt_union_with_key_def Let_def rbt_lookup_fold_rbt_insertwk rbt_sorted_entries distinct_entries map_of_sunion_with map_of_entries rbt_lookup_rbtreeify split: option.split compare.split)
  1953 
  1954 lemma rbt_unionw_is_rbt: "\<lbrakk> is_rbt lt; is_rbt rt \<rbrakk> \<Longrightarrow> is_rbt (rbt_union_with f lt rt)"
  1955 by(simp add: rbt_union_with_def)
  1956 
  1957 lemma rbt_union_is_rbt: "\<lbrakk> is_rbt lt; is_rbt rt \<rbrakk> \<Longrightarrow> is_rbt (rbt_union lt rt)"
  1958 by(simp add: rbt_union_def)
  1959 
  1960 lemma rbt_lookup_rbt_union:
  1961   "\<lbrakk> rbt_sorted s; rbt_sorted t \<rbrakk> \<Longrightarrow>
  1962   rbt_lookup (rbt_union s t) = rbt_lookup s ++ rbt_lookup t"
  1963 by(rule ext)(simp add: rbt_lookup_rbt_unionwk rbt_union_def map_add_def split: option.split)
  1964 
  1965 lemma rbt_interwk_is_rbt [simp]:
  1966   "\<lbrakk> rbt_sorted t1; rbt_sorted t2 \<rbrakk> \<Longrightarrow> is_rbt (rbt_inter_with_key f t1 t2)"
  1967 by(auto simp add: rbt_inter_with_key_def Let_def map_map_filter split_def o_def option.map_comp map_filter_map_option_const sorted_filter[where f=id, simplified] rbt_sorted_entries distinct_entries intro: is_rbt_rbtreeify split: compare.split)
  1968 
  1969 lemma rbt_interw_is_rbt:
  1970   "\<lbrakk> rbt_sorted t1; rbt_sorted t2 \<rbrakk> \<Longrightarrow> is_rbt (rbt_inter_with f t1 t2)"
  1971 by(simp add: rbt_inter_with_def)
  1972 
  1973 lemma rbt_inter_is_rbt:
  1974   "\<lbrakk> rbt_sorted t1; rbt_sorted t2 \<rbrakk> \<Longrightarrow> is_rbt (rbt_inter t1 t2)"
  1975 by(simp add: rbt_inter_def)
  1976 
  1977 lemma rbt_lookup_rbt_interwk:
  1978   "\<lbrakk> rbt_sorted t1; rbt_sorted t2 \<rbrakk>
  1979   \<Longrightarrow> rbt_lookup (rbt_inter_with_key f t1 t2) k =
  1980   (case rbt_lookup t1 k of None \<Rightarrow> None 
  1981    | Some v \<Rightarrow> case rbt_lookup t2 k of None \<Rightarrow> None
  1982                | Some w \<Rightarrow> Some (f k v w))"
  1983 by(auto 4 3 simp add: rbt_inter_with_key_def Let_def map_of_entries[symmetric] rbt_lookup_rbtreeify map_map_filter split_def o_def option.map_comp map_filter_map_option_const sorted_filter[where f=id, simplified] rbt_sorted_entries distinct_entries map_of_sinter_with map_of_eq_None_iff set_map_filter split: option.split compare.split intro: rev_image_eqI dest: rbt_sorted_entries_right_unique)
  1984 
  1985 lemma rbt_lookup_rbt_inter:
  1986   "\<lbrakk> rbt_sorted t1; rbt_sorted t2 \<rbrakk>
  1987   \<Longrightarrow> rbt_lookup (rbt_inter t1 t2) = rbt_lookup t2 |` dom (rbt_lookup t1)"
  1988 by(auto simp add: rbt_inter_def rbt_lookup_rbt_interwk restrict_map_def split: option.split)
  1989 
  1990 end
  1991 
  1992 
  1993 subsection \<open>Code generator setup\<close>
  1994 
  1995 lemmas [code] =
  1996   ord.rbt_less_prop
  1997   ord.rbt_greater_prop
  1998   ord.rbt_sorted.simps
  1999   ord.rbt_lookup.simps
  2000   ord.is_rbt_def
  2001   ord.rbt_ins.simps
  2002   ord.rbt_insert_with_key_def
  2003   ord.rbt_insertw_def
  2004   ord.rbt_insert_def
  2005   ord.rbt_del_from_left.simps
  2006   ord.rbt_del_from_right.simps
  2007   ord.rbt_del.simps
  2008   ord.rbt_delete_def
  2009   ord.sunion_with.simps
  2010   ord.sinter_with.simps
  2011   ord.rbt_union_with_key_def
  2012   ord.rbt_union_with_def
  2013   ord.rbt_union_def
  2014   ord.rbt_inter_with_key_def
  2015   ord.rbt_inter_with_def
  2016   ord.rbt_inter_def
  2017   ord.rbt_map_entry.simps
  2018   ord.rbt_bulkload_def
  2019 
  2020 text \<open>More efficient implementations for @{term entries} and @{term keys}\<close>
  2021 
  2022 definition gen_entries :: 
  2023   "(('a \<times> 'b) \<times> ('a, 'b) rbt) list \<Rightarrow> ('a, 'b) rbt \<Rightarrow> ('a \<times> 'b) list"
  2024 where
  2025   "gen_entries kvts t = entries t @ concat (map (\<lambda>(kv, t). kv # entries t) kvts)"
  2026 
  2027 lemma gen_entries_simps [simp, code]:
  2028   "gen_entries [] Empty = []"
  2029   "gen_entries ((kv, t) # kvts) Empty = kv # gen_entries kvts t"
  2030   "gen_entries kvts (Branch c l k v r) = gen_entries (((k, v), r) # kvts) l"
  2031 by(simp_all add: gen_entries_def)
  2032 
  2033 lemma entries_code [code]:
  2034   "entries = gen_entries []"
  2035 by(simp add: gen_entries_def fun_eq_iff)
  2036 
  2037 definition gen_keys :: "('a \<times> ('a, 'b) rbt) list \<Rightarrow> ('a, 'b) rbt \<Rightarrow> 'a list"
  2038 where "gen_keys kts t = RBT_Impl.keys t @ concat (List.map (\<lambda>(k, t). k # keys t) kts)"
  2039 
  2040 lemma gen_keys_simps [simp, code]:
  2041   "gen_keys [] Empty = []"
  2042   "gen_keys ((k, t) # kts) Empty = k # gen_keys kts t"
  2043   "gen_keys kts (Branch c l k v r) = gen_keys ((k, r) # kts) l"
  2044 by(simp_all add: gen_keys_def)
  2045 
  2046 lemma keys_code [code]:
  2047   "keys = gen_keys []"
  2048 by(simp add: gen_keys_def fun_eq_iff)
  2049 
  2050 text \<open>Restore original type constraints for constants\<close>
  2051 setup \<open>
  2052   fold Sign.add_const_constraint
  2053     [(@{const_name rbt_less}, SOME @{typ "('a :: order) \<Rightarrow> ('a, 'b) rbt \<Rightarrow> bool"}),
  2054      (@{const_name rbt_greater}, SOME @{typ "('a :: order) \<Rightarrow> ('a, 'b) rbt \<Rightarrow> bool"}),
  2055      (@{const_name rbt_sorted}, SOME @{typ "('a :: linorder, 'b) rbt \<Rightarrow> bool"}),
  2056      (@{const_name rbt_lookup}, SOME @{typ "('a :: linorder, 'b) rbt \<Rightarrow> 'a \<rightharpoonup> 'b"}),
  2057      (@{const_name is_rbt}, SOME @{typ "('a :: linorder, 'b) rbt \<Rightarrow> bool"}),
  2058      (@{const_name rbt_ins}, SOME @{typ "('a::linorder \<Rightarrow> 'b \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> ('a,'b) rbt \<Rightarrow> ('a,'b) rbt"}),
  2059      (@{const_name rbt_insert_with_key}, SOME @{typ "('a::linorder \<Rightarrow> 'b \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> ('a,'b) rbt \<Rightarrow> ('a,'b) rbt"}),
  2060      (@{const_name rbt_insert_with}, SOME @{typ "('b \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> ('a :: linorder) \<Rightarrow> 'b \<Rightarrow> ('a,'b) rbt \<Rightarrow> ('a,'b) rbt"}),
  2061      (@{const_name rbt_insert}, SOME @{typ "('a :: linorder) \<Rightarrow> 'b \<Rightarrow> ('a,'b) rbt \<Rightarrow> ('a,'b) rbt"}),
  2062      (@{const_name rbt_del_from_left}, SOME @{typ "('a::linorder) \<Rightarrow> ('a,'b) rbt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> ('a,'b) rbt \<Rightarrow> ('a,'b) rbt"}),
  2063      (@{const_name rbt_del_from_right}, SOME @{typ "('a::linorder) \<Rightarrow> ('a,'b) rbt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> ('a,'b) rbt \<Rightarrow> ('a,'b) rbt"}),
  2064      (@{const_name rbt_del}, SOME @{typ "('a::linorder) \<Rightarrow> ('a,'b) rbt \<Rightarrow> ('a,'b) rbt"}),
  2065      (@{const_name rbt_delete}, SOME @{typ "('a::linorder) \<Rightarrow> ('a,'b) rbt \<Rightarrow> ('a,'b) rbt"}),
  2066      (@{const_name rbt_union_with_key}, SOME @{typ "('a::linorder \<Rightarrow> 'b \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> ('a,'b) rbt \<Rightarrow> ('a,'b) rbt \<Rightarrow> ('a,'b) rbt"}),
  2067      (@{const_name rbt_union_with}, SOME @{typ "('b \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> ('a::linorder,'b) rbt \<Rightarrow> ('a,'b) rbt \<Rightarrow> ('a,'b) rbt"}),
  2068      (@{const_name rbt_union}, SOME @{typ "('a::linorder,'b) rbt \<Rightarrow> ('a,'b) rbt \<Rightarrow> ('a,'b) rbt"}),
  2069      (@{const_name rbt_map_entry}, SOME @{typ "'a::linorder \<Rightarrow> ('b \<Rightarrow> 'b) \<Rightarrow> ('a,'b) rbt \<Rightarrow> ('a,'b) rbt"}),
  2070      (@{const_name rbt_bulkload}, SOME @{typ "('a \<times> 'b) list \<Rightarrow> ('a::linorder,'b) rbt"})]
  2071 \<close>
  2072 
  2073 hide_const (open) R B Empty entries keys fold gen_keys gen_entries
  2074 
  2075 end