src/Tools/Code/code_thingol.ML
author wenzelm
Sun Oct 25 20:54:21 2009 +0100 (2009-10-25)
changeset 33172 61ee96bc9895
parent 33029 2fefe039edf1
child 33187 616be6d7997e
permissions -rw-r--r--
maintain theory name via name space, not tags;
AxClass.thynames_of_arity: explicit theory name, not tags;
     1 (*  Title:      Tools/code/code_thingol.ML
     2     Author:     Florian Haftmann, TU Muenchen
     3 
     4 Intermediate language ("Thin-gol") representing executable code.
     5 Representation and translation.
     6 *)
     7 
     8 infix 8 `%%;
     9 infix 4 `$;
    10 infix 4 `$$;
    11 infixr 3 `|=>;
    12 infixr 3 `|==>;
    13 
    14 signature BASIC_CODE_THINGOL =
    15 sig
    16   type vname = string;
    17   datatype dict =
    18       DictConst of string * dict list list
    19     | DictVar of string list * (vname * (int * int));
    20   datatype itype =
    21       `%% of string * itype list
    22     | ITyVar of vname;
    23   type const = string * ((itype list * dict list list) * itype list (*types of arguments*))
    24   datatype iterm =
    25       IConst of const
    26     | IVar of vname option
    27     | `$ of iterm * iterm
    28     | `|=> of (vname option * itype) * iterm
    29     | ICase of ((iterm * itype) * (iterm * iterm) list) * iterm;
    30         (*((term, type), [(selector pattern, body term )]), primitive term)*)
    31   val `$$ : iterm * iterm list -> iterm;
    32   val `|==> : (vname option * itype) list * iterm -> iterm;
    33   type typscheme = (vname * sort) list * itype;
    34 end;
    35 
    36 signature CODE_THINGOL =
    37 sig
    38   include BASIC_CODE_THINGOL
    39   val unfoldl: ('a -> ('a * 'b) option) -> 'a -> 'a * 'b list
    40   val unfoldr: ('a -> ('b * 'a) option) -> 'a -> 'b list * 'a
    41   val unfold_fun: itype -> itype list * itype
    42   val unfold_app: iterm -> iterm * iterm list
    43   val unfold_abs: iterm -> (vname option * itype) list * iterm
    44   val split_let: iterm -> (((iterm * itype) * iterm) * iterm) option
    45   val unfold_let: iterm -> ((iterm * itype) * iterm) list * iterm
    46   val split_pat_abs: iterm -> ((iterm * itype) * iterm) option
    47   val unfold_pat_abs: iterm -> (iterm * itype) list * iterm
    48   val unfold_const_app: iterm -> (const * iterm list) option
    49   val is_IVar: iterm -> bool
    50   val eta_expand: int -> const * iterm list -> iterm
    51   val contains_dictvar: iterm -> bool
    52   val locally_monomorphic: iterm -> bool
    53   val add_constnames: iterm -> string list -> string list
    54   val add_tyconames: iterm -> string list -> string list
    55   val fold_varnames: (string -> 'a -> 'a) -> iterm -> 'a -> 'a
    56 
    57   type naming
    58   val empty_naming: naming
    59   val lookup_class: naming -> class -> string option
    60   val lookup_classrel: naming -> class * class -> string option
    61   val lookup_tyco: naming -> string -> string option
    62   val lookup_instance: naming -> class * string -> string option
    63   val lookup_const: naming -> string -> string option
    64   val ensure_declared_const: theory -> string -> naming -> string * naming
    65 
    66   datatype stmt =
    67       NoStmt
    68     | Fun of string * (typscheme * ((iterm list * iterm) * (thm * bool)) list)
    69     | Datatype of string * ((vname * sort) list * (string * itype list) list)
    70     | Datatypecons of string * string
    71     | Class of class * (vname * ((class * string) list * (string * itype) list))
    72     | Classrel of class * class
    73     | Classparam of string * class
    74     | Classinst of (class * (string * (vname * sort) list))
    75           * ((class * (string * (string * dict list list))) list
    76         * ((string * const) * (thm * bool)) list)
    77   type program = stmt Graph.T
    78   val empty_funs: program -> string list
    79   val map_terms_bottom_up: (iterm -> iterm) -> iterm -> iterm
    80   val map_terms_stmt: (iterm -> iterm) -> stmt -> stmt
    81   val is_cons: program -> string -> bool
    82   val contr_classparam_typs: program -> string -> itype option list
    83   val labelled_name: theory -> program -> string -> string
    84   val group_stmts: theory -> program
    85     -> ((string * stmt) list * (string * stmt) list
    86       * ((string * stmt) list * (string * stmt) list)) list
    87 
    88   val expand_eta: theory -> int -> thm -> thm
    89   val canonize_thms: theory -> thm list -> thm list
    90   val read_const_exprs: theory -> string list -> string list * string list
    91   val consts_program: theory -> string list -> string list * (naming * program)
    92   val cached_program: theory -> naming * program
    93   val eval_conv: theory
    94     -> (naming -> program -> ((string * sort) list * typscheme) * iterm -> string list -> cterm -> thm)
    95     -> cterm -> thm
    96   val eval: theory -> ((term -> term) -> 'a -> 'a)
    97     -> (naming -> program -> ((string * sort) list * typscheme) * iterm -> string list -> 'a)
    98     -> term -> 'a
    99 end;
   100 
   101 structure Code_Thingol: CODE_THINGOL =
   102 struct
   103 
   104 (** auxiliary **)
   105 
   106 fun unfoldl dest x =
   107   case dest x
   108    of NONE => (x, [])
   109     | SOME (x1, x2) =>
   110         let val (x', xs') = unfoldl dest x1 in (x', xs' @ [x2]) end;
   111 
   112 fun unfoldr dest x =
   113   case dest x
   114    of NONE => ([], x)
   115     | SOME (x1, x2) =>
   116         let val (xs', x') = unfoldr dest x2 in (x1::xs', x') end;
   117 
   118 
   119 (** language core - types, terms **)
   120 
   121 type vname = string;
   122 
   123 datatype dict =
   124     DictConst of string * dict list list
   125   | DictVar of string list * (vname * (int * int));
   126 
   127 datatype itype =
   128     `%% of string * itype list
   129   | ITyVar of vname;
   130 
   131 type const = string * ((itype list * dict list list) * itype list (*types of arguments*))
   132 
   133 datatype iterm =
   134     IConst of const
   135   | IVar of vname option
   136   | `$ of iterm * iterm
   137   | `|=> of (vname option * itype) * iterm
   138   | ICase of ((iterm * itype) * (iterm * iterm) list) * iterm;
   139     (*see also signature*)
   140 
   141 fun is_IVar (IVar _) = true
   142   | is_IVar _ = false;
   143 
   144 val op `$$ = Library.foldl (op `$);
   145 val op `|==> = Library.foldr (op `|=>);
   146 
   147 val unfold_app = unfoldl
   148   (fn op `$ t => SOME t
   149     | _ => NONE);
   150 
   151 val unfold_abs = unfoldr
   152   (fn op `|=> t => SOME t
   153     | _ => NONE);
   154 
   155 val split_let = 
   156   (fn ICase (((td, ty), [(p, t)]), _) => SOME (((p, ty), td), t)
   157     | _ => NONE);
   158 
   159 val unfold_let = unfoldr split_let;
   160 
   161 fun unfold_const_app t =
   162  case unfold_app t
   163   of (IConst c, ts) => SOME (c, ts)
   164    | _ => NONE;
   165 
   166 fun fold_constexprs f =
   167   let
   168     fun fold' (IConst c) = f c
   169       | fold' (IVar _) = I
   170       | fold' (t1 `$ t2) = fold' t1 #> fold' t2
   171       | fold' (_ `|=> t) = fold' t
   172       | fold' (ICase (((t, _), ds), _)) = fold' t
   173           #> fold (fn (pat, body) => fold' pat #> fold' body) ds
   174   in fold' end;
   175 
   176 val add_constnames = fold_constexprs (fn (c, _) => insert (op =) c);
   177 
   178 fun add_tycos (tyco `%% tys) = insert (op =) tyco #> fold add_tycos tys
   179   | add_tycos (ITyVar _) = I;
   180 
   181 val add_tyconames = fold_constexprs (fn (_, ((tys, _), _)) => fold add_tycos tys);
   182 
   183 fun fold_varnames f =
   184   let
   185     fun fold_aux add f =
   186       let
   187         fun fold_term _ (IConst _) = I
   188           | fold_term vs (IVar (SOME v)) = if member (op =) vs v then I else f v
   189           | fold_term _ (IVar NONE) = I
   190           | fold_term vs (t1 `$ t2) = fold_term vs t1 #> fold_term vs t2
   191           | fold_term vs ((SOME v, _) `|=> t) = fold_term (insert (op =) v vs) t
   192           | fold_term vs ((NONE, _) `|=> t) = fold_term vs t
   193           | fold_term vs (ICase (((t, _), ds), _)) = fold_term vs t #> fold (fold_case vs) ds
   194         and fold_case vs (p, t) = fold_term (add p vs) t;
   195       in fold_term [] end;
   196     fun add t = fold_aux add (insert (op =)) t;
   197   in fold_aux add f end;
   198 
   199 fun exists_var t v = fold_varnames (fn w => fn b => v = w orelse b) t false;
   200 
   201 fun split_pat_abs ((NONE, ty) `|=> t) = SOME ((IVar NONE, ty), t)
   202   | split_pat_abs ((SOME v, ty) `|=> t) = SOME (case t
   203      of ICase (((IVar (SOME w), _), [(p, t')]), _) =>
   204           if v = w andalso (exists_var p v orelse not (exists_var t' v))
   205           then ((p, ty), t')
   206           else ((IVar (SOME v), ty), t)
   207       | _ => ((IVar (SOME v), ty), t))
   208   | split_pat_abs _ = NONE;
   209 
   210 val unfold_pat_abs = unfoldr split_pat_abs;
   211 
   212 fun unfold_abs_eta [] t = ([], t)
   213   | unfold_abs_eta (_ :: tys) (v_ty `|=> t) =
   214       let
   215         val (vs_tys, t') = unfold_abs_eta tys t;
   216       in (v_ty :: vs_tys, t') end
   217   | unfold_abs_eta tys t =
   218       let
   219         val ctxt = fold_varnames Name.declare t Name.context;
   220         val vs_tys = (map o apfst) SOME (Name.names ctxt "a" tys);
   221       in (vs_tys, t `$$ map (IVar o fst) vs_tys) end;
   222 
   223 fun eta_expand k (c as (_, (_, tys)), ts) =
   224   let
   225     val j = length ts;
   226     val l = k - j;
   227     val ctxt = (fold o fold_varnames) Name.declare ts Name.context;
   228     val vs_tys = (map o apfst) SOME
   229       (Name.names ctxt "a" ((curry Library.take l o curry Library.drop j) tys));
   230   in vs_tys `|==> IConst c `$$ ts @ map (IVar o fst) vs_tys end;
   231 
   232 fun contains_dictvar t =
   233   let
   234     fun cont_dict (DictConst (_, dss)) = (exists o exists) cont_dict dss
   235       | cont_dict (DictVar _) = true;
   236     fun cont_term (IConst (_, ((_, dss), _))) = (exists o exists) cont_dict dss
   237       | cont_term (IVar _) = false
   238       | cont_term (t1 `$ t2) = cont_term t1 orelse cont_term t2
   239       | cont_term (_ `|=> t) = cont_term t
   240       | cont_term (ICase (_, t)) = cont_term t;
   241   in cont_term t end;
   242   
   243 fun locally_monomorphic (IConst _) = false
   244   | locally_monomorphic (IVar _) = true
   245   | locally_monomorphic (t `$ _) = locally_monomorphic t
   246   | locally_monomorphic (_ `|=> t) = locally_monomorphic t
   247   | locally_monomorphic (ICase ((_, ds), _)) = exists (locally_monomorphic o snd) ds;
   248 
   249 
   250 (** namings **)
   251 
   252 (* policies *)
   253 
   254 local
   255   fun thyname_of_class thy = #theory_name o Name_Space.the_entry (Sign.class_space thy);
   256   fun thyname_of_instance thy inst = case AxClass.thynames_of_arity thy inst
   257    of [] => error ("No such instance: " ^ quote (snd inst ^ " :: " ^ fst inst))
   258     | thyname :: _ => thyname;
   259   fun thyname_of_const thy c = case AxClass.class_of_param thy c
   260    of SOME class => thyname_of_class thy class
   261     | NONE => (case Code.get_datatype_of_constr thy c
   262        of SOME dtco => Codegen.thyname_of_type thy dtco
   263         | NONE => Codegen.thyname_of_const thy c);
   264   fun purify_base "op &" = "and"
   265     | purify_base "op |" = "or"
   266     | purify_base "op -->" = "implies"
   267     | purify_base "op :" = "member"
   268     | purify_base "op =" = "eq"
   269     | purify_base "*" = "product"
   270     | purify_base "+" = "sum"
   271     | purify_base s = Name.desymbolize false s;
   272   fun namify thy get_basename get_thyname name =
   273     let
   274       val prefix = get_thyname thy name;
   275       val base = (purify_base o get_basename) name;
   276     in Long_Name.append prefix base end;
   277 in
   278 
   279 fun namify_class thy = namify thy Long_Name.base_name thyname_of_class;
   280 fun namify_classrel thy = namify thy (fn (class1, class2) => 
   281     Long_Name.base_name class2 ^ "_" ^ Long_Name.base_name class1)
   282   (fn thy => thyname_of_class thy o fst);
   283   (*order fits nicely with composed projections*)
   284 fun namify_tyco thy "fun" = "Pure.fun"
   285   | namify_tyco thy tyco = namify thy Long_Name.base_name Codegen.thyname_of_type tyco;
   286 fun namify_instance thy = namify thy (fn (class, tyco) => 
   287   Long_Name.base_name class ^ "_" ^ Long_Name.base_name tyco) thyname_of_instance;
   288 fun namify_const thy = namify thy Long_Name.base_name thyname_of_const;
   289 
   290 end; (* local *)
   291 
   292 
   293 (* data *)
   294 
   295 datatype naming = Naming of {
   296   class: class Symtab.table * Name.context,
   297   classrel: string Symreltab.table * Name.context,
   298   tyco: string Symtab.table * Name.context,
   299   instance: string Symreltab.table * Name.context,
   300   const: string Symtab.table * Name.context
   301 }
   302 
   303 fun dest_Naming (Naming naming) = naming;
   304 
   305 val empty_naming = Naming {
   306   class = (Symtab.empty, Name.context),
   307   classrel = (Symreltab.empty, Name.context),
   308   tyco = (Symtab.empty, Name.context),
   309   instance = (Symreltab.empty, Name.context),
   310   const = (Symtab.empty, Name.context)
   311 };
   312 
   313 local
   314   fun mk_naming (class, classrel, tyco, instance, const) =
   315     Naming { class = class, classrel = classrel,
   316       tyco = tyco, instance = instance, const = const };
   317   fun map_naming f (Naming { class, classrel, tyco, instance, const }) =
   318     mk_naming (f (class, classrel, tyco, instance, const));
   319 in
   320   fun map_class f = map_naming
   321     (fn (class, classrel, tyco, inst, const) =>
   322       (f class, classrel, tyco, inst, const));
   323   fun map_classrel f = map_naming
   324     (fn (class, classrel, tyco, inst, const) =>
   325       (class, f classrel, tyco, inst, const));
   326   fun map_tyco f = map_naming
   327     (fn (class, classrel, tyco, inst, const) =>
   328       (class, classrel, f tyco, inst, const));
   329   fun map_instance f = map_naming
   330     (fn (class, classrel, tyco, inst, const) =>
   331       (class, classrel, tyco, f inst, const));
   332   fun map_const f = map_naming
   333     (fn (class, classrel, tyco, inst, const) =>
   334       (class, classrel, tyco, inst, f const));
   335 end; (*local*)
   336 
   337 fun add_variant update (thing, name) (tab, used) =
   338   let
   339     val (name', used') = yield_singleton Name.variants name used;
   340     val tab' = update (thing, name') tab;
   341   in (tab', used') end;
   342 
   343 fun declare thy mapp lookup update namify thing =
   344   mapp (add_variant update (thing, namify thy thing))
   345   #> `(fn naming => the (lookup naming thing));
   346 
   347 
   348 (* lookup and declare *)
   349 
   350 local
   351 
   352 val suffix_class = "class";
   353 val suffix_classrel = "classrel"
   354 val suffix_tyco = "tyco";
   355 val suffix_instance = "inst";
   356 val suffix_const = "const";
   357 
   358 fun add_suffix nsp NONE = NONE
   359   | add_suffix nsp (SOME name) = SOME (Long_Name.append name nsp);
   360 
   361 in
   362 
   363 val lookup_class = add_suffix suffix_class
   364   oo Symtab.lookup o fst o #class o dest_Naming;
   365 val lookup_classrel = add_suffix suffix_classrel
   366   oo Symreltab.lookup o fst o #classrel o dest_Naming;
   367 val lookup_tyco = add_suffix suffix_tyco
   368   oo Symtab.lookup o fst o #tyco o dest_Naming;
   369 val lookup_instance = add_suffix suffix_instance
   370   oo Symreltab.lookup o fst o #instance o dest_Naming;
   371 val lookup_const = add_suffix suffix_const
   372   oo Symtab.lookup o fst o #const o dest_Naming;
   373 
   374 fun declare_class thy = declare thy map_class
   375   lookup_class Symtab.update_new namify_class;
   376 fun declare_classrel thy = declare thy map_classrel
   377   lookup_classrel Symreltab.update_new namify_classrel;
   378 fun declare_tyco thy = declare thy map_tyco
   379   lookup_tyco Symtab.update_new namify_tyco;
   380 fun declare_instance thy = declare thy map_instance
   381   lookup_instance Symreltab.update_new namify_instance;
   382 fun declare_const thy = declare thy map_const
   383   lookup_const Symtab.update_new namify_const;
   384 
   385 fun ensure_declared_const thy const naming =
   386   case lookup_const naming const
   387    of SOME const' => (const', naming)
   388     | NONE => declare_const thy const naming;
   389 
   390 val unfold_fun = unfoldr
   391   (fn "Pure.fun.tyco" `%% [ty1, ty2] => SOME (ty1, ty2)
   392     | _ => NONE); (*depends on suffix_tyco and namify_tyco!*)
   393 
   394 end; (* local *)
   395 
   396 
   397 (** technical transformations of code equations **)
   398 
   399 fun expand_eta thy k thm =
   400   let
   401     val (lhs, rhs) = (Logic.dest_equals o Thm.plain_prop_of) thm;
   402     val (head, args) = strip_comb lhs;
   403     val l = if k = ~1
   404       then (length o fst o strip_abs) rhs
   405       else Int.max (0, k - length args);
   406     val (raw_vars, _) = Term.strip_abs_eta l rhs;
   407     val vars = burrow_fst (Name.variant_list (map (fst o fst) (Term.add_vars lhs [])))
   408       raw_vars;
   409     fun expand (v, ty) thm = Drule.fun_cong_rule thm
   410       (Thm.cterm_of thy (Var ((v, 0), ty)));
   411   in
   412     thm
   413     |> fold expand vars
   414     |> Conv.fconv_rule Drule.beta_eta_conversion
   415   end;
   416 
   417 fun same_arity thy thms =
   418   let
   419     val num_args_of = length o snd o strip_comb o fst o Logic.dest_equals;
   420     val k = fold (Integer.max o num_args_of o Thm.prop_of) thms 0;
   421   in map (expand_eta thy k) thms end;
   422 
   423 fun mk_desymbolization pre post mk vs =
   424   let
   425     val names = map (pre o fst o fst) vs
   426       |> map (Name.desymbolize false)
   427       |> Name.variant_list []
   428       |> map post;
   429   in map_filter (fn (((v, i), x), v') =>
   430     if v = v' andalso i = 0 then NONE
   431     else SOME (((v, i), x), mk ((v', 0), x))) (vs ~~ names)
   432   end;
   433 
   434 fun desymbolize_tvars thy thms =
   435   let
   436     val tvs = fold (Term.add_tvars o Thm.prop_of) thms [];
   437     val tvar_subst = mk_desymbolization (unprefix "'") (prefix "'") TVar tvs;
   438   in map (Thm.certify_instantiate (tvar_subst, [])) thms end;
   439 
   440 fun desymbolize_vars thy thm =
   441   let
   442     val vs = Term.add_vars (Thm.prop_of thm) [];
   443     val var_subst = mk_desymbolization I I Var vs;
   444   in Thm.certify_instantiate ([], var_subst) thm end;
   445 
   446 fun canonize_thms thy = map (Thm.transfer thy)
   447   #> Code.standard_typscheme thy #> desymbolize_tvars thy
   448   #> same_arity thy #> map (desymbolize_vars thy);
   449 
   450 
   451 (** statements, abstract programs **)
   452 
   453 type typscheme = (vname * sort) list * itype;
   454 datatype stmt =
   455     NoStmt
   456   | Fun of string * (typscheme * ((iterm list * iterm) * (thm * bool)) list)
   457   | Datatype of string * ((vname * sort) list * (string * itype list) list)
   458   | Datatypecons of string * string
   459   | Class of class * (vname * ((class * string) list * (string * itype) list))
   460   | Classrel of class * class
   461   | Classparam of string * class
   462   | Classinst of (class * (string * (vname * sort) list))
   463         * ((class * (string * (string * dict list list))) list
   464       * ((string * const) * (thm * bool)) list);
   465 
   466 type program = stmt Graph.T;
   467 
   468 fun empty_funs program =
   469   Graph.fold (fn (name, (Fun (c, (_, [])), _)) => cons c
   470                | _ => I) program [];
   471 
   472 fun map_terms_bottom_up f (t as IConst _) = f t
   473   | map_terms_bottom_up f (t as IVar _) = f t
   474   | map_terms_bottom_up f (t1 `$ t2) = f
   475       (map_terms_bottom_up f t1 `$ map_terms_bottom_up f t2)
   476   | map_terms_bottom_up f ((v, ty) `|=> t) = f
   477       ((v, ty) `|=> map_terms_bottom_up f t)
   478   | map_terms_bottom_up f (ICase (((t, ty), ps), t0)) = f
   479       (ICase (((map_terms_bottom_up f t, ty), (map o pairself)
   480         (map_terms_bottom_up f) ps), map_terms_bottom_up f t0));
   481 
   482 fun map_terms_stmt f NoStmt = NoStmt
   483   | map_terms_stmt f (Fun (c, (tysm, eqs))) = Fun (c, (tysm, (map o apfst)
   484       (fn (ts, t) => (map f ts, f t)) eqs))
   485   | map_terms_stmt f (stmt as Datatype _) = stmt
   486   | map_terms_stmt f (stmt as Datatypecons _) = stmt
   487   | map_terms_stmt f (stmt as Class _) = stmt
   488   | map_terms_stmt f (stmt as Classrel _) = stmt
   489   | map_terms_stmt f (stmt as Classparam _) = stmt
   490   | map_terms_stmt f (Classinst (arity, (superarities, classparms))) =
   491       Classinst (arity, (superarities, (map o apfst o apsnd) (fn const =>
   492         case f (IConst const) of IConst const' => const') classparms));
   493 
   494 fun is_cons program name = case Graph.get_node program name
   495  of Datatypecons _ => true
   496   | _ => false;
   497 
   498 fun contr_classparam_typs program name = case Graph.get_node program name
   499  of Classparam (_, class) => let
   500         val Class (_, (_, (_, params))) = Graph.get_node program class;
   501         val SOME ty = AList.lookup (op =) params name;
   502         val (tys, res_ty) = unfold_fun ty;
   503         fun no_tyvar (_ `%% tys) = forall no_tyvar tys
   504           | no_tyvar (ITyVar _) = false;
   505       in if no_tyvar res_ty
   506         then map (fn ty => if no_tyvar ty then NONE else SOME ty) tys
   507         else []
   508       end
   509   | _ => [];
   510 
   511 fun labelled_name thy program name = case Graph.get_node program name
   512  of Fun (c, _) => quote (Code.string_of_const thy c)
   513   | Datatype (tyco, _) => "type " ^ quote (Sign.extern_type thy tyco)
   514   | Datatypecons (c, _) => quote (Code.string_of_const thy c)
   515   | Class (class, _) => "class " ^ quote (Sign.extern_class thy class)
   516   | Classrel (sub, super) => let
   517         val Class (sub, _) = Graph.get_node program sub
   518         val Class (super, _) = Graph.get_node program super
   519       in quote (Sign.extern_class thy sub ^ " < " ^ Sign.extern_class thy super) end
   520   | Classparam (c, _) => quote (Code.string_of_const thy c)
   521   | Classinst ((class, (tyco, _)), _) => let
   522         val Class (class, _) = Graph.get_node program class
   523         val Datatype (tyco, _) = Graph.get_node program tyco
   524       in quote (Sign.extern_type thy tyco ^ " :: " ^ Sign.extern_class thy class) end
   525 
   526 fun group_stmts thy program =
   527   let
   528     fun is_fun (_, Fun _) = true | is_fun _ = false;
   529     fun is_datatypecons (_, Datatypecons _) = true | is_datatypecons _ = false;
   530     fun is_datatype (_, Datatype _) = true | is_datatype _ = false;
   531     fun is_class (_, Class _) = true | is_class _ = false;
   532     fun is_classrel (_, Classrel _) = true | is_classrel _ = false;
   533     fun is_classparam (_, Classparam _) = true | is_classparam _ = false;
   534     fun is_classinst (_, Classinst _) = true | is_classinst _ = false;
   535     fun group stmts =
   536       if forall (is_datatypecons orf is_datatype) stmts
   537       then (filter is_datatype stmts, [], ([], []))
   538       else if forall (is_class orf is_classrel orf is_classparam) stmts
   539       then ([], filter is_class stmts, ([], []))
   540       else if forall (is_fun orf is_classinst) stmts
   541       then ([], [], List.partition is_fun stmts)
   542       else error ("Illegal mutual dependencies: " ^
   543         (commas o map (labelled_name thy program o fst)) stmts)
   544   in
   545     rev (Graph.strong_conn program)
   546     |> map (AList.make (Graph.get_node program))
   547     |> map group
   548   end;
   549 
   550 
   551 (** translation kernel **)
   552 
   553 (* generic mechanisms *)
   554 
   555 fun ensure_stmt lookup declare generate thing (dep, (naming, program)) =
   556   let
   557     fun add_dep name = case dep of NONE => I
   558       | SOME dep => Graph.add_edge (dep, name);
   559     val (name, naming') = case lookup naming thing
   560      of SOME name => (name, naming)
   561       | NONE => declare thing naming;
   562   in case try (Graph.get_node program) name
   563    of SOME stmt => program
   564         |> add_dep name
   565         |> pair naming'
   566         |> pair dep
   567         |> pair name
   568     | NONE => program
   569         |> Graph.default_node (name, NoStmt)
   570         |> add_dep name
   571         |> pair naming'
   572         |> curry generate (SOME name)
   573         ||> snd
   574         |-> (fn stmt => (apsnd o Graph.map_node name) (K stmt))
   575         |> pair dep
   576         |> pair name
   577   end;
   578 
   579 fun not_wellsorted thy thm ty sort e =
   580   let
   581     val err_class = Sorts.class_error (Syntax.pp_global thy) e;
   582     val err_thm = case thm
   583      of SOME thm => "\n(in code equation " ^ Display.string_of_thm_global thy thm ^ ")" | NONE => "";
   584     val err_typ = "Type " ^ Syntax.string_of_typ_global thy ty ^ " not of sort "
   585       ^ Syntax.string_of_sort_global thy sort;
   586   in error ("Wellsortedness error" ^ err_thm ^ ":\n" ^ err_typ ^ "\n" ^ err_class) end;
   587 
   588 
   589 (* translation *)
   590 
   591 fun ensure_tyco thy algbr eqngr tyco =
   592   let
   593     val stmt_datatype =
   594       let
   595         val (vs, cos) = Code.get_datatype thy tyco;
   596       in
   597         fold_map (translate_tyvar_sort thy algbr eqngr) vs
   598         ##>> fold_map (fn (c, tys) =>
   599           ensure_const thy algbr eqngr c
   600           ##>> fold_map (translate_typ thy algbr eqngr) tys) cos
   601         #>> (fn info => Datatype (tyco, info))
   602       end;
   603   in ensure_stmt lookup_tyco (declare_tyco thy) stmt_datatype tyco end
   604 and ensure_const thy algbr eqngr c =
   605   let
   606     fun stmt_datatypecons tyco =
   607       ensure_tyco thy algbr eqngr tyco
   608       #>> (fn tyco => Datatypecons (c, tyco));
   609     fun stmt_classparam class =
   610       ensure_class thy algbr eqngr class
   611       #>> (fn class => Classparam (c, class));
   612     fun stmt_fun raw_eqns =
   613       let
   614         val eqns = burrow_fst (canonize_thms thy) raw_eqns;
   615         val (vs, ty) = Code.typscheme_eqns thy c (map fst eqns);
   616       in
   617         fold_map (translate_tyvar_sort thy algbr eqngr) vs
   618         ##>> translate_typ thy algbr eqngr ty
   619         ##>> fold_map (translate_eqn thy algbr eqngr) eqns
   620         #>> (fn info => Fun (c, info))
   621       end;
   622     val stmt_const = case Code.get_datatype_of_constr thy c
   623      of SOME tyco => stmt_datatypecons tyco
   624       | NONE => (case AxClass.class_of_param thy c
   625          of SOME class => stmt_classparam class
   626           | NONE => stmt_fun (Code_Preproc.eqns eqngr c))
   627   in ensure_stmt lookup_const (declare_const thy) stmt_const c end
   628 and ensure_class thy (algbr as (_, algebra)) eqngr class =
   629   let
   630     val superclasses = (Sorts.minimize_sort algebra o Sorts.super_classes algebra) class;
   631     val cs = #params (AxClass.get_info thy class);
   632     val stmt_class =
   633       fold_map (fn superclass => ensure_class thy algbr eqngr superclass
   634         ##>> ensure_classrel thy algbr eqngr (class, superclass)) superclasses
   635       ##>> fold_map (fn (c, ty) => ensure_const thy algbr eqngr c
   636         ##>> translate_typ thy algbr eqngr ty) cs
   637       #>> (fn info => Class (class, (unprefix "'" Name.aT, info)))
   638   in ensure_stmt lookup_class (declare_class thy) stmt_class class end
   639 and ensure_classrel thy algbr eqngr (subclass, superclass) =
   640   let
   641     val stmt_classrel =
   642       ensure_class thy algbr eqngr subclass
   643       ##>> ensure_class thy algbr eqngr superclass
   644       #>> Classrel;
   645   in ensure_stmt lookup_classrel (declare_classrel thy) stmt_classrel (subclass, superclass) end
   646 and ensure_inst thy (algbr as (_, algebra)) eqngr (class, tyco) =
   647   let
   648     val superclasses = (Sorts.minimize_sort algebra o Sorts.super_classes algebra) class;
   649     val classparams = these (try (#params o AxClass.get_info thy) class);
   650     val vs = Name.names Name.context "'a" (Sorts.mg_domain algebra tyco [class]);
   651     val sorts' = Sorts.mg_domain (Sign.classes_of thy) tyco [class];
   652     val vs' = map2 (fn (v, sort1) => fn sort2 => (v,
   653       Sorts.inter_sort (Sign.classes_of thy) (sort1, sort2))) vs sorts';
   654     val arity_typ = Type (tyco, map TFree vs);
   655     val arity_typ' = Type (tyco, map (fn (v, sort) => TVar ((v, 0), sort)) vs');
   656     fun translate_superarity superclass =
   657       ensure_class thy algbr eqngr superclass
   658       ##>> ensure_classrel thy algbr eqngr (class, superclass)
   659       ##>> translate_dicts thy algbr eqngr NONE (arity_typ, [superclass])
   660       #>> (fn ((superclass, classrel), [DictConst (inst, dss)]) =>
   661             (superclass, (classrel, (inst, dss))));
   662     fun translate_classparam_inst (c, ty) =
   663       let
   664         val c_inst = Const (c, map_type_tfree (K arity_typ') ty);
   665         val thm = AxClass.unoverload_conv thy (Thm.cterm_of thy c_inst);
   666         val c_ty = (apsnd Logic.unvarifyT o dest_Const o snd
   667           o Logic.dest_equals o Thm.prop_of) thm;
   668       in
   669         ensure_const thy algbr eqngr c
   670         ##>> translate_const thy algbr eqngr (SOME thm) c_ty
   671         #>> (fn (c, IConst c_inst) => ((c, c_inst), (thm, true)))
   672       end;
   673     val stmt_inst =
   674       ensure_class thy algbr eqngr class
   675       ##>> ensure_tyco thy algbr eqngr tyco
   676       ##>> fold_map (translate_tyvar_sort thy algbr eqngr) vs
   677       ##>> fold_map translate_superarity superclasses
   678       ##>> fold_map translate_classparam_inst classparams
   679       #>> (fn ((((class, tyco), arity), superarities), classparams) =>
   680              Classinst ((class, (tyco, arity)), (superarities, classparams)));
   681   in ensure_stmt lookup_instance (declare_instance thy) stmt_inst (class, tyco) end
   682 and translate_typ thy algbr eqngr (TFree (v, _)) =
   683       pair (ITyVar (unprefix "'" v))
   684   | translate_typ thy algbr eqngr (Type (tyco, tys)) =
   685       ensure_tyco thy algbr eqngr tyco
   686       ##>> fold_map (translate_typ thy algbr eqngr) tys
   687       #>> (fn (tyco, tys) => tyco `%% tys)
   688 and translate_term thy algbr eqngr thm (Const (c, ty)) =
   689       translate_app thy algbr eqngr thm ((c, ty), [])
   690   | translate_term thy algbr eqngr thm (Free (v, _)) =
   691       pair (IVar (SOME v))
   692   | translate_term thy algbr eqngr thm (Abs (v, ty, t)) =
   693       let
   694         val (v', t') = Syntax.variant_abs (Name.desymbolize false v, ty, t);
   695         val v'' = if member (op =) (Term.add_free_names t' []) v'
   696           then SOME v' else NONE
   697       in
   698         translate_typ thy algbr eqngr ty
   699         ##>> translate_term thy algbr eqngr thm t'
   700         #>> (fn (ty, t) => (v'', ty) `|=> t)
   701       end
   702   | translate_term thy algbr eqngr thm (t as _ $ _) =
   703       case strip_comb t
   704        of (Const (c, ty), ts) =>
   705             translate_app thy algbr eqngr thm ((c, ty), ts)
   706         | (t', ts) =>
   707             translate_term thy algbr eqngr thm t'
   708             ##>> fold_map (translate_term thy algbr eqngr thm) ts
   709             #>> (fn (t, ts) => t `$$ ts)
   710 and translate_eqn thy algbr eqngr (thm, proper) =
   711   let
   712     val (args, rhs) = (apfst (snd o strip_comb) o Logic.dest_equals
   713       o Logic.unvarify o prop_of) thm;
   714   in
   715     fold_map (translate_term thy algbr eqngr (SOME thm)) args
   716     ##>> translate_term thy algbr eqngr (SOME thm) rhs
   717     #>> rpair (thm, proper)
   718   end
   719 and translate_const thy algbr eqngr thm (c, ty) =
   720   let
   721     val tys = Sign.const_typargs thy (c, ty);
   722     val sorts = Code_Preproc.sortargs eqngr c;
   723     val tys_args = (fst o Term.strip_type) ty;
   724   in
   725     ensure_const thy algbr eqngr c
   726     ##>> fold_map (translate_typ thy algbr eqngr) tys
   727     ##>> fold_map (translate_dicts thy algbr eqngr thm) (tys ~~ sorts)
   728     ##>> fold_map (translate_typ thy algbr eqngr) tys_args
   729     #>> (fn (((c, tys), iss), tys_args) => IConst (c, ((tys, iss), tys_args)))
   730   end
   731 and translate_app_const thy algbr eqngr thm (c_ty, ts) =
   732   translate_const thy algbr eqngr thm c_ty
   733   ##>> fold_map (translate_term thy algbr eqngr thm) ts
   734   #>> (fn (t, ts) => t `$$ ts)
   735 and translate_case thy algbr eqngr thm (num_args, (t_pos, case_pats)) (c_ty, ts) =
   736   let
   737     fun arg_types num_args ty = (fst o chop num_args o fst o strip_type) ty;
   738     val tys = arg_types num_args (snd c_ty);
   739     val ty = nth tys t_pos;
   740     fun mk_constr c t = let val n = Code.args_number thy c
   741       in ((c, arg_types n (fastype_of t) ---> ty), n) end;
   742     val constrs = if null case_pats then []
   743       else map2 mk_constr case_pats (nth_drop t_pos ts);
   744     fun casify naming constrs ty ts =
   745       let
   746         val undefineds = map_filter (lookup_const naming) (Code.undefineds thy);
   747         fun collapse_clause vs_map ts body =
   748           let
   749           in case body
   750            of IConst (c, _) => if member (op =) undefineds c
   751                 then []
   752                 else [(ts, body)]
   753             | ICase (((IVar (SOME v), _), subclauses), _) =>
   754                 if forall (fn (pat', body') => exists_var pat' v
   755                   orelse not (exists_var body' v)) subclauses
   756                 then case AList.lookup (op =) vs_map v
   757                  of SOME i => maps (fn (pat', body') =>
   758                       collapse_clause (AList.delete (op =) v vs_map)
   759                         (nth_map i (K pat') ts) body') subclauses
   760                   | NONE => [(ts, body)]
   761                 else [(ts, body)]
   762             | _ => [(ts, body)]
   763           end;
   764         fun mk_clause mk tys t =
   765           let
   766             val (vs, body) = unfold_abs_eta tys t;
   767             val vs_map = fold_index (fn (i, (SOME v, _)) => cons (v, i) | _ => I) vs [];
   768             val ts = map (IVar o fst) vs;
   769           in map mk (collapse_clause vs_map ts body) end;
   770         val t = nth ts t_pos;
   771         val ts_clause = nth_drop t_pos ts;
   772         val clauses = if null case_pats
   773           then mk_clause (fn ([t], body) => (t, body)) [ty] (the_single ts_clause)
   774           else maps (fn ((constr as IConst (_, (_, tys)), n), t) =>
   775             mk_clause (fn (ts, body) => (constr `$$ ts, body)) (curry Library.take n tys) t)
   776               (constrs ~~ ts_clause);
   777       in ((t, ty), clauses) end;
   778   in
   779     translate_const thy algbr eqngr thm c_ty
   780     ##>> fold_map (fn (constr, n) => translate_const thy algbr eqngr thm constr #>> rpair n) constrs
   781     ##>> translate_typ thy algbr eqngr ty
   782     ##>> fold_map (translate_term thy algbr eqngr thm) ts
   783     #-> (fn (((t, constrs), ty), ts) =>
   784       `(fn (_, (naming, _)) => ICase (casify naming constrs ty ts, t `$$ ts)))
   785   end
   786 and translate_app_case thy algbr eqngr thm (case_scheme as (num_args, _)) ((c, ty), ts) =
   787   if length ts < num_args then
   788     let
   789       val k = length ts;
   790       val tys = (curry Library.take (num_args - k) o curry Library.drop k o fst o strip_type) ty;
   791       val ctxt = (fold o fold_aterms) Term.declare_term_frees ts Name.context;
   792       val vs = Name.names ctxt "a" tys;
   793     in
   794       fold_map (translate_typ thy algbr eqngr) tys
   795       ##>> translate_case thy algbr eqngr thm case_scheme ((c, ty), ts @ map Free vs)
   796       #>> (fn (tys, t) => map2 (fn (v, _) => pair (SOME v)) vs tys `|==> t)
   797     end
   798   else if length ts > num_args then
   799     translate_case thy algbr eqngr thm case_scheme ((c, ty), Library.take (num_args, ts))
   800     ##>> fold_map (translate_term thy algbr eqngr thm) (Library.drop (num_args, ts))
   801     #>> (fn (t, ts) => t `$$ ts)
   802   else
   803     translate_case thy algbr eqngr thm case_scheme ((c, ty), ts)
   804 and translate_app thy algbr eqngr thm (c_ty_ts as ((c, _), _)) =
   805   case Code.get_case_scheme thy c
   806    of SOME case_scheme => translate_app_case thy algbr eqngr thm case_scheme c_ty_ts
   807     | NONE => translate_app_const thy algbr eqngr thm c_ty_ts
   808 and translate_tyvar_sort thy (algbr as (proj_sort, _)) eqngr (v, sort) =
   809   fold_map (ensure_class thy algbr eqngr) (proj_sort sort)
   810   #>> (fn sort => (unprefix "'" v, sort))
   811 and translate_dicts thy (algbr as (proj_sort, algebra)) eqngr thm (ty, sort) =
   812   let
   813     datatype typarg =
   814         Global of (class * string) * typarg list list
   815       | Local of (class * class) list * (string * (int * sort));
   816     fun class_relation (Global ((_, tyco), yss), _) class =
   817           Global ((class, tyco), yss)
   818       | class_relation (Local (classrels, v), subclass) superclass =
   819           Local ((subclass, superclass) :: classrels, v);
   820     fun type_constructor tyco yss class =
   821       Global ((class, tyco), (map o map) fst yss);
   822     fun type_variable (TFree (v, sort)) =
   823       let
   824         val sort' = proj_sort sort;
   825       in map_index (fn (n, class) => (Local ([], (v, (n, sort'))), class)) sort' end;
   826     val typargs = Sorts.of_sort_derivation algebra
   827       {class_relation = class_relation, type_constructor = type_constructor,
   828        type_variable = type_variable} (ty, proj_sort sort)
   829       handle Sorts.CLASS_ERROR e => not_wellsorted thy thm ty sort e;
   830     fun mk_dict (Global (inst, yss)) =
   831           ensure_inst thy algbr eqngr inst
   832           ##>> (fold_map o fold_map) mk_dict yss
   833           #>> (fn (inst, dss) => DictConst (inst, dss))
   834       | mk_dict (Local (classrels, (v, (n, sort)))) =
   835           fold_map (ensure_classrel thy algbr eqngr) classrels
   836           #>> (fn classrels => DictVar (classrels, (unprefix "'" v, (n, length sort))))
   837   in fold_map mk_dict typargs end;
   838 
   839 
   840 (* store *)
   841 
   842 structure Program = Code_Data_Fun
   843 (
   844   type T = naming * program;
   845   val empty = (empty_naming, Graph.empty);
   846   fun purge thy cs (naming, program) =
   847     let
   848       val names_delete = cs
   849         |> map_filter (lookup_const naming)
   850         |> filter (can (Graph.get_node program))
   851         |> Graph.all_preds program;
   852       val program' = Graph.del_nodes names_delete program;
   853     in (naming, program') end;
   854 );
   855 
   856 val cached_program = Program.get;
   857 
   858 fun invoke_generation thy (algebra, eqngr) f name =
   859   Program.change_yield thy (fn naming_program => (NONE, naming_program)
   860     |> f thy algebra eqngr name
   861     |-> (fn name => fn (_, naming_program) => (name, naming_program)));
   862 
   863 
   864 (* program generation *)
   865 
   866 fun consts_program thy cs =
   867   let
   868     fun project_consts cs (naming, program) =
   869       let
   870         val cs_all = Graph.all_succs program cs;
   871       in (cs, (naming, Graph.subgraph (member (op =) cs_all) program)) end;
   872     fun generate_consts thy algebra eqngr =
   873       fold_map (ensure_const thy algebra eqngr);
   874   in
   875     invoke_generation thy (Code_Preproc.obtain thy cs []) generate_consts cs
   876     |-> project_consts
   877   end;
   878 
   879 
   880 (* value evaluation *)
   881 
   882 fun ensure_value thy algbr eqngr t =
   883   let
   884     val ty = fastype_of t;
   885     val vs = fold_term_types (K (fold_atyps (insert (eq_fst op =)
   886       o dest_TFree))) t [];
   887     val stmt_value =
   888       fold_map (translate_tyvar_sort thy algbr eqngr) vs
   889       ##>> translate_typ thy algbr eqngr ty
   890       ##>> translate_term thy algbr eqngr NONE t
   891       #>> (fn ((vs, ty), t) => Fun
   892         (Term.dummy_patternN, ((vs, ty), [(([], t), (Drule.dummy_thm, true))])));
   893     fun term_value (dep, (naming, program1)) =
   894       let
   895         val Fun (_, (vs_ty, [(([], t), _)])) =
   896           Graph.get_node program1 Term.dummy_patternN;
   897         val deps = Graph.imm_succs program1 Term.dummy_patternN;
   898         val program2 = Graph.del_nodes [Term.dummy_patternN] program1;
   899         val deps_all = Graph.all_succs program2 deps;
   900         val program3 = Graph.subgraph (member (op =) deps_all) program2;
   901       in (((naming, program3), ((vs_ty, t), deps)), (dep, (naming, program2))) end;
   902   in
   903     ensure_stmt ((K o K) NONE) pair stmt_value Term.dummy_patternN
   904     #> snd
   905     #> term_value
   906   end;
   907 
   908 fun base_evaluator thy evaluator algebra eqngr vs t =
   909   let
   910     val (((naming, program), (((vs', ty'), t'), deps)), _) =
   911       invoke_generation thy (algebra, eqngr) ensure_value t;
   912     val vs'' = map (fn (v, _) => (v, (the o AList.lookup (op =) vs o prefix "'") v)) vs';
   913   in evaluator naming program ((vs'', (vs', ty')), t') deps end;
   914 
   915 fun eval_conv thy = Code_Preproc.eval_conv thy o base_evaluator thy;
   916 fun eval thy postproc = Code_Preproc.eval thy postproc o base_evaluator thy;
   917 
   918 
   919 (** diagnostic commands **)
   920 
   921 fun read_const_exprs thy =
   922   let
   923     fun consts_of some_thyname =
   924       let
   925         val thy' = case some_thyname
   926          of SOME thyname => ThyInfo.the_theory thyname thy
   927           | NONE => thy;
   928         val cs = Symtab.fold (fn (c, (_, NONE)) => cons c | _ => I)
   929           ((snd o #constants o Consts.dest o #consts o Sign.rep_sg) thy') [];
   930         fun belongs_here c =
   931           not (exists (fn thy'' => Sign.declared_const thy'' c) (Theory.parents_of thy'))
   932       in case some_thyname
   933        of NONE => cs
   934         | SOME thyname => filter belongs_here cs
   935       end;
   936     fun read_const_expr "*" = ([], consts_of NONE)
   937       | read_const_expr s = if String.isSuffix ".*" s
   938           then ([], consts_of (SOME (unsuffix ".*" s)))
   939           else ([Code.read_const thy s], []);
   940   in pairself flat o split_list o map read_const_expr end;
   941 
   942 fun code_depgr thy consts =
   943   let
   944     val (_, eqngr) = Code_Preproc.obtain thy consts [];
   945     val select = Graph.all_succs eqngr consts;
   946   in
   947     eqngr
   948     |> not (null consts) ? Graph.subgraph (member (op =) select) 
   949     |> Graph.map_nodes ((apsnd o map o apfst) (AxClass.overload thy))
   950   end;
   951 
   952 fun code_thms thy = Pretty.writeln o Code_Preproc.pretty thy o code_depgr thy;
   953 
   954 fun code_deps thy consts =
   955   let
   956     val eqngr = code_depgr thy consts;
   957     val constss = Graph.strong_conn eqngr;
   958     val mapping = Symtab.empty |> fold (fn consts => fold (fn const =>
   959       Symtab.update (const, consts)) consts) constss;
   960     fun succs consts = consts
   961       |> maps (Graph.imm_succs eqngr)
   962       |> subtract (op =) consts
   963       |> map (the o Symtab.lookup mapping)
   964       |> distinct (op =);
   965     val conn = [] |> fold (fn consts => cons (consts, succs consts)) constss;
   966     fun namify consts = map (Code.string_of_const thy) consts
   967       |> commas;
   968     val prgr = map (fn (consts, constss) =>
   969       { name = namify consts, ID = namify consts, dir = "", unfold = true,
   970         path = "", parents = map namify constss }) conn;
   971   in Present.display_graph prgr end;
   972 
   973 local
   974 
   975 structure P = OuterParse
   976 and K = OuterKeyword
   977 
   978 fun code_thms_cmd thy = code_thms thy o op @ o read_const_exprs thy;
   979 fun code_deps_cmd thy = code_deps thy o op @ o read_const_exprs thy;
   980 
   981 in
   982 
   983 val _ =
   984   OuterSyntax.improper_command "code_thms" "print system of code equations for code" OuterKeyword.diag
   985     (Scan.repeat P.term_group
   986       >> (fn cs => Toplevel.no_timing o Toplevel.unknown_theory
   987         o Toplevel.keep ((fn thy => code_thms_cmd thy cs) o Toplevel.theory_of)));
   988 
   989 val _ =
   990   OuterSyntax.improper_command "code_deps" "visualize dependencies of code equations for code" OuterKeyword.diag
   991     (Scan.repeat P.term_group
   992       >> (fn cs => Toplevel.no_timing o Toplevel.unknown_theory
   993         o Toplevel.keep ((fn thy => code_deps_cmd thy cs) o Toplevel.theory_of)));
   994 
   995 end;
   996 
   997 end; (*struct*)
   998 
   999 
  1000 structure Basic_Code_Thingol: BASIC_CODE_THINGOL = Code_Thingol;