src/Pure/drule.ML
author wenzelm
Mon Jun 12 21:19:00 2006 +0200 (2006-06-12)
changeset 19861 620d90091788
parent 19842 04120bdac80e
child 19878 51ae6677dd5f
permissions -rw-r--r--
tuned Seq/Envir/Unify interfaces;
     1 (*  Title:      Pure/drule.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Derived rules and other operations on theorems.
     7 *)
     8 
     9 infix 0 RS RSN RL RLN MRS MRL OF COMP;
    10 
    11 signature BASIC_DRULE =
    12 sig
    13   val mk_implies: cterm * cterm -> cterm
    14   val list_implies: cterm list * cterm -> cterm
    15   val dest_implies: cterm -> cterm * cterm
    16   val dest_equals: cterm -> cterm * cterm
    17   val strip_imp_prems: cterm -> cterm list
    18   val strip_imp_concl: cterm -> cterm
    19   val cprems_of: thm -> cterm list
    20   val cterm_fun: (term -> term) -> (cterm -> cterm)
    21   val ctyp_fun: (typ -> typ) -> (ctyp -> ctyp)
    22   val read_insts: theory -> (indexname -> typ option) * (indexname -> sort option) ->
    23     (indexname -> typ option) * (indexname -> sort option) -> string list ->
    24     (indexname * string) list -> (ctyp * ctyp) list * (cterm * cterm) list
    25   val types_sorts: thm -> (indexname-> typ option) * (indexname-> sort option)
    26   val strip_shyps_warning: thm -> thm
    27   val forall_intr_list: cterm list -> thm -> thm
    28   val forall_intr_frees: thm -> thm
    29   val forall_intr_vars: thm -> thm
    30   val forall_elim_list: cterm list -> thm -> thm
    31   val forall_elim_var: int -> thm -> thm
    32   val forall_elim_vars: int -> thm -> thm
    33   val gen_all: thm -> thm
    34   val lift_all: cterm -> thm -> thm
    35   val freeze_thaw: thm -> thm * (thm -> thm)
    36   val freeze_thaw_robust: thm -> thm * (int -> thm -> thm)
    37   val implies_elim_list: thm -> thm list -> thm
    38   val implies_intr_list: cterm list -> thm -> thm
    39   val instantiate: (ctyp * ctyp) list * (cterm * cterm) list -> thm -> thm
    40   val zero_var_indexes: thm -> thm
    41   val implies_intr_hyps: thm -> thm
    42   val standard: thm -> thm
    43   val standard': thm -> thm
    44   val rotate_prems: int -> thm -> thm
    45   val rearrange_prems: int list -> thm -> thm
    46   val assume_ax: theory -> string -> thm
    47   val RSN: thm * (int * thm) -> thm
    48   val RS: thm * thm -> thm
    49   val RLN: thm list * (int * thm list) -> thm list
    50   val RL: thm list * thm list -> thm list
    51   val MRS: thm list * thm -> thm
    52   val MRL: thm list list * thm list -> thm list
    53   val OF: thm * thm list -> thm
    54   val compose: thm * int * thm -> thm list
    55   val COMP: thm * thm -> thm
    56   val read_instantiate_sg: theory -> (string*string)list -> thm -> thm
    57   val read_instantiate: (string*string)list -> thm -> thm
    58   val cterm_instantiate: (cterm*cterm)list -> thm -> thm
    59   val eq_thm_thy: thm * thm -> bool
    60   val eq_thm_prop: thm * thm -> bool
    61   val weak_eq_thm: thm * thm -> bool
    62   val size_of_thm: thm -> int
    63   val reflexive_thm: thm
    64   val symmetric_thm: thm
    65   val transitive_thm: thm
    66   val symmetric_fun: thm -> thm
    67   val extensional: thm -> thm
    68   val equals_cong: thm
    69   val imp_cong: thm
    70   val swap_prems_eq: thm
    71   val equal_abs_elim: cterm  -> thm -> thm
    72   val equal_abs_elim_list: cterm list -> thm -> thm
    73   val asm_rl: thm
    74   val cut_rl: thm
    75   val revcut_rl: thm
    76   val thin_rl: thm
    77   val triv_forall_equality: thm
    78   val distinct_prems_rl: thm
    79   val swap_prems_rl: thm
    80   val equal_intr_rule: thm
    81   val equal_elim_rule1: thm
    82   val equal_elim_rule2: thm
    83   val inst: string -> string -> thm -> thm
    84   val instantiate': ctyp option list -> cterm option list -> thm -> thm
    85 end;
    86 
    87 signature DRULE =
    88 sig
    89   include BASIC_DRULE
    90   val dest_binop: cterm -> cterm * cterm
    91   val list_comb: cterm * cterm list -> cterm
    92   val strip_comb: cterm -> cterm * cterm list
    93   val strip_type: ctyp -> ctyp list * ctyp
    94   val beta_conv: cterm -> cterm -> cterm
    95   val plain_prop_of: thm -> term
    96   val add_used: thm -> string list -> string list
    97   val flexflex_unique: thm -> thm
    98   val close_derivation: thm -> thm
    99   val local_standard: thm -> thm
   100   val store_thm: bstring -> thm -> thm
   101   val store_standard_thm: bstring -> thm -> thm
   102   val store_thm_open: bstring -> thm -> thm
   103   val store_standard_thm_open: bstring -> thm -> thm
   104   val compose_single: thm * int * thm -> thm
   105   val add_rule: thm -> thm list -> thm list
   106   val del_rule: thm -> thm list -> thm list
   107   val merge_rules: thm list * thm list -> thm list
   108   val imp_cong_rule: thm -> thm -> thm
   109   val beta_eta_conversion: cterm -> thm
   110   val eta_long_conversion: cterm -> thm
   111   val forall_conv: int -> (cterm -> thm) -> cterm -> thm
   112   val concl_conv: int -> (cterm -> thm) -> cterm -> thm
   113   val prems_conv: int -> (int -> cterm -> thm) -> cterm -> thm
   114   val goals_conv: (int -> bool) -> (cterm -> thm) -> cterm -> thm
   115   val fconv_rule: (cterm -> thm) -> thm -> thm
   116   val norm_hhf_eq: thm
   117   val is_norm_hhf: term -> bool
   118   val norm_hhf: theory -> term -> term
   119   val protect: cterm -> cterm
   120   val protectI: thm
   121   val protectD: thm
   122   val protect_cong: thm
   123   val implies_intr_protected: cterm list -> thm -> thm
   124   val termI: thm
   125   val mk_term: cterm -> thm
   126   val dest_term: thm -> cterm
   127   val freeze_all: thm -> thm
   128   val tvars_of_terms: term list -> (indexname * sort) list
   129   val vars_of_terms: term list -> (indexname * typ) list
   130   val tvars_of: thm -> (indexname * sort) list
   131   val vars_of: thm -> (indexname * typ) list
   132   val tfrees_of: thm -> (string * sort) list
   133   val frees_of: thm -> (string * typ) list
   134   val sort_triv: theory -> typ * sort -> thm list
   135   val unconstrainTs: thm -> thm
   136   val fold_terms: (term -> 'a -> 'a) -> thm -> 'a -> 'a
   137   val rename_bvars: (string * string) list -> thm -> thm
   138   val rename_bvars': string option list -> thm -> thm
   139   val unvarifyT: thm -> thm
   140   val unvarify: thm -> thm
   141   val tvars_intr_list: string list -> thm -> (string * (indexname * sort)) list * thm
   142   val incr_indexes: thm -> thm -> thm
   143   val incr_indexes2: thm -> thm -> thm -> thm
   144   val remdups_rl: thm
   145   val multi_resolve: thm list -> thm -> thm Seq.seq
   146   val multi_resolves: thm list -> thm list -> thm Seq.seq
   147   val abs_def: thm -> thm
   148   val read_instantiate_sg': theory -> (indexname * string) list -> thm -> thm
   149   val read_instantiate': (indexname * string) list -> thm -> thm
   150 end;
   151 
   152 structure Drule: DRULE =
   153 struct
   154 
   155 
   156 (** some cterm->cterm operations: faster than calling cterm_of! **)
   157 
   158 fun dest_binop ct =
   159   let val (ct1, ct2) = Thm.dest_comb ct
   160   in (#2 (Thm.dest_comb ct1), ct2) end;
   161 
   162 fun dest_implies ct =
   163   (case Thm.term_of ct of
   164     (Const ("==>", _) $ _ $ _) => dest_binop ct
   165   | _ => raise TERM ("dest_implies", [term_of ct]));
   166 
   167 fun dest_equals ct =
   168   (case Thm.term_of ct of
   169     (Const ("==", _) $ _ $ _) => dest_binop ct
   170     | _ => raise TERM ("dest_equals", [term_of ct]));
   171 
   172 (* A1==>...An==>B  goes to  [A1,...,An], where B is not an implication *)
   173 fun strip_imp_prems ct =
   174     let val (cA,cB) = dest_implies ct
   175     in  cA :: strip_imp_prems cB  end
   176     handle TERM _ => [];
   177 
   178 (* A1==>...An==>B  goes to B, where B is not an implication *)
   179 fun strip_imp_concl ct =
   180     case term_of ct of (Const("==>", _) $ _ $ _) =>
   181         strip_imp_concl (#2 (Thm.dest_comb ct))
   182   | _ => ct;
   183 
   184 (*The premises of a theorem, as a cterm list*)
   185 val cprems_of = strip_imp_prems o cprop_of;
   186 
   187 fun cterm_fun f ct =
   188   let val {t, thy, ...} = Thm.rep_cterm ct
   189   in Thm.cterm_of thy (f t) end;
   190 
   191 fun ctyp_fun f cT =
   192   let val {T, thy, ...} = Thm.rep_ctyp cT
   193   in Thm.ctyp_of thy (f T) end;
   194 
   195 val cert = cterm_of ProtoPure.thy;
   196 
   197 val implies = cert Term.implies;
   198 fun mk_implies (A, B) = Thm.capply (Thm.capply implies A) B;
   199 
   200 (*cterm version of list_implies: [A1,...,An], B  goes to [|A1;==>;An|]==>B *)
   201 fun list_implies([], B) = B
   202   | list_implies(A::AS, B) = mk_implies (A, list_implies(AS,B));
   203 
   204 (*cterm version of list_comb: maps  (f, [t1,...,tn])  to  f(t1,...,tn) *)
   205 fun list_comb (f, []) = f
   206   | list_comb (f, t::ts) = list_comb (Thm.capply f t, ts);
   207 
   208 (*cterm version of strip_comb: maps  f(t1,...,tn)  to  (f, [t1,...,tn]) *)
   209 fun strip_comb ct =
   210   let
   211     fun stripc (p as (ct, cts)) =
   212       let val (ct1, ct2) = Thm.dest_comb ct
   213       in stripc (ct1, ct2 :: cts) end handle CTERM _ => p
   214   in stripc (ct, []) end;
   215 
   216 (* cterm version of strip_type: maps  [T1,...,Tn]--->T  to   ([T1,T2,...,Tn], T) *)
   217 fun strip_type cT = (case Thm.typ_of cT of
   218     Type ("fun", _) =>
   219       let
   220         val [cT1, cT2] = Thm.dest_ctyp cT;
   221         val (cTs, cT') = strip_type cT2
   222       in (cT1 :: cTs, cT') end
   223   | _ => ([], cT));
   224 
   225 (*Beta-conversion for cterms, where x is an abstraction. Simply returns the rhs
   226   of the meta-equality returned by the beta_conversion rule.*)
   227 fun beta_conv x y =
   228     #2 (Thm.dest_comb (cprop_of (Thm.beta_conversion false (Thm.capply x y))));
   229 
   230 fun plain_prop_of raw_thm =
   231   let
   232     val thm = Thm.strip_shyps raw_thm;
   233     fun err msg = raise THM ("plain_prop_of: " ^ msg, 0, [thm]);
   234     val {hyps, prop, tpairs, ...} = Thm.rep_thm thm;
   235   in
   236     if not (null hyps) then
   237       err "theorem may not contain hypotheses"
   238     else if not (null (Thm.extra_shyps thm)) then
   239       err "theorem may not contain sort hypotheses"
   240     else if not (null tpairs) then
   241       err "theorem may not contain flex-flex pairs"
   242     else prop
   243   end;
   244 
   245 
   246 
   247 (** reading of instantiations **)
   248 
   249 fun absent ixn =
   250   error("No such variable in term: " ^ Syntax.string_of_vname ixn);
   251 
   252 fun inst_failure ixn =
   253   error("Instantiation of " ^ Syntax.string_of_vname ixn ^ " fails");
   254 
   255 fun read_insts thy (rtypes,rsorts) (types,sorts) used insts =
   256 let
   257     fun is_tv ((a, _), _) =
   258       (case Symbol.explode a of "'" :: _ => true | _ => false);
   259     val (tvs, vs) = List.partition is_tv insts;
   260     fun sort_of ixn = case rsorts ixn of SOME S => S | NONE => absent ixn;
   261     fun readT (ixn, st) =
   262         let val S = sort_of ixn;
   263             val T = Sign.read_typ (thy,sorts) st;
   264         in if Sign.typ_instance thy (T, TVar(ixn,S)) then (ixn,T)
   265            else inst_failure ixn
   266         end
   267     val tye = map readT tvs;
   268     fun mkty(ixn,st) = (case rtypes ixn of
   269                           SOME T => (ixn,(st,typ_subst_TVars tye T))
   270                         | NONE => absent ixn);
   271     val ixnsTs = map mkty vs;
   272     val ixns = map fst ixnsTs
   273     and sTs  = map snd ixnsTs
   274     val (cts,tye2) = read_def_cterms(thy,types,sorts) used false sTs;
   275     fun mkcVar(ixn,T) =
   276         let val U = typ_subst_TVars tye2 T
   277         in cterm_of thy (Var(ixn,U)) end
   278     val ixnTs = ListPair.zip(ixns, map snd sTs)
   279 in (map (fn (ixn, T) => (ctyp_of thy (TVar (ixn, sort_of ixn)),
   280       ctyp_of thy T)) (tye2 @ tye),
   281     ListPair.zip(map mkcVar ixnTs,cts))
   282 end;
   283 
   284 
   285 (*** Find the type (sort) associated with a (T)Var or (T)Free in a term
   286      Used for establishing default types (of variables) and sorts (of
   287      type variables) when reading another term.
   288      Index -1 indicates that a (T)Free rather than a (T)Var is wanted.
   289 ***)
   290 
   291 fun types_sorts thm =
   292     let val {prop, hyps, tpairs, ...} = Thm.rep_thm thm;
   293         (* bogus term! *)
   294         val big = Term.list_comb
   295                     (Term.list_comb (prop, hyps), Thm.terms_of_tpairs tpairs);
   296         val vars = map dest_Var (term_vars big);
   297         val frees = map dest_Free (term_frees big);
   298         val tvars = term_tvars big;
   299         val tfrees = term_tfrees big;
   300         fun typ(a,i) = if i<0 then AList.lookup (op =) frees a else AList.lookup (op =) vars (a,i);
   301         fun sort(a,i) = if i<0 then AList.lookup (op =) tfrees a else AList.lookup (op =) tvars (a,i);
   302     in (typ,sort) end;
   303 
   304 fun add_used thm used =
   305   let val {prop, hyps, tpairs, ...} = Thm.rep_thm thm in
   306     add_term_tvarnames (prop, used)
   307     |> fold (curry add_term_tvarnames) hyps
   308     |> fold (curry add_term_tvarnames) (Thm.terms_of_tpairs tpairs)
   309   end;
   310 
   311 
   312 
   313 (** Standardization of rules **)
   314 
   315 (*vars in left-to-right order*)
   316 fun tvars_of_terms ts = rev (fold Term.add_tvars ts []);
   317 fun vars_of_terms ts = rev (fold Term.add_vars ts []);
   318 fun tvars_of thm = tvars_of_terms [Thm.full_prop_of thm];
   319 fun vars_of thm = vars_of_terms [Thm.full_prop_of thm];
   320 
   321 fun fold_terms f th =
   322   let val {hyps, tpairs, prop, ...} = Thm.rep_thm th
   323   in f prop #> fold (fn (t, u) => f t #> f u) tpairs #> fold f hyps end;
   324 
   325 fun tfrees_of th = rev (fold_terms Term.add_tfrees th []);
   326 fun frees_of th = rev (fold_terms Term.add_frees th []);
   327 
   328 
   329 (* type classes and sorts *)
   330 
   331 fun sort_triv thy (T, S) =
   332   let
   333     val certT = Thm.ctyp_of thy;
   334     val cT = certT T;
   335     fun class_triv c =
   336       Thm.class_triv thy c
   337       |> Thm.instantiate ([(certT (TVar (("'a", 0), [c])), cT)], []);
   338   in map class_triv S end;
   339 
   340 fun unconstrainTs th =
   341   fold_rev (Thm.unconstrainT o Thm.ctyp_of (Thm.theory_of_thm th) o TVar) (tvars_of th) th;
   342 
   343 fun strip_shyps_warning thm =
   344   let
   345     val str_of_sort = Pretty.str_of o Sign.pretty_sort (Thm.theory_of_thm thm);
   346     val thm' = Thm.strip_shyps thm;
   347     val xshyps = Thm.extra_shyps thm';
   348   in
   349     if null xshyps then ()
   350     else warning ("Pending sort hypotheses: " ^ commas (map str_of_sort xshyps));
   351     thm'
   352   end;
   353 
   354 (*Generalization over a list of variables*)
   355 val forall_intr_list = fold_rev forall_intr;
   356 
   357 (*Generalization over all suitable Free variables*)
   358 fun forall_intr_frees th =
   359     let
   360       val {prop, hyps, tpairs, thy,...} = rep_thm th;
   361       val fixed = fold Term.add_frees (Thm.terms_of_tpairs tpairs @ hyps) [];
   362       val frees = Term.fold_aterms (fn Free v =>
   363         if member (op =) fixed v then I else insert (op =) v | _ => I) prop [];
   364     in fold (forall_intr o cterm_of thy o Free) frees th end;
   365 
   366 (*Generalization over Vars -- canonical order*)
   367 fun forall_intr_vars th =
   368   let val cert = Thm.cterm_of (Thm.theory_of_thm th)
   369   in forall_intr_list (map (cert o Var) (vars_of th)) th end;
   370 
   371 val forall_elim_var = PureThy.forall_elim_var;
   372 val forall_elim_vars = PureThy.forall_elim_vars;
   373 
   374 fun outer_params t =
   375   let
   376     val vs = Term.strip_all_vars t;
   377     val clean_name = perhaps (try Syntax.dest_skolem) #> perhaps (try Syntax.dest_internal);
   378   in Term.variantlist (map (clean_name o #1) vs, []) ~~ map #2 vs end;
   379 
   380 (*generalize outermost parameters*)
   381 fun gen_all th =
   382   let
   383     val {thy, prop, maxidx, ...} = Thm.rep_thm th;
   384     val cert = Thm.cterm_of thy;
   385     fun elim (x, T) = Thm.forall_elim (cert (Var ((x, maxidx + 1), T)));
   386   in fold elim (outer_params prop) th end;
   387 
   388 (*lift vars wrt. outermost goal parameters
   389   -- reverses the effect of gen_all modulo higher-order unification*)
   390 fun lift_all goal th =
   391   let
   392     val thy = Theory.merge (Thm.theory_of_cterm goal, Thm.theory_of_thm th);
   393     val cert = Thm.cterm_of thy;
   394     val maxidx = Thm.maxidx_of th;
   395     val ps = outer_params (Thm.term_of goal)
   396       |> map (fn (x, T) => Var ((x, maxidx + 1), Logic.incr_tvar (maxidx + 1) T));
   397     val Ts = map Term.fastype_of ps;
   398     val inst = vars_of th |> map (fn (xi, T) =>
   399       (cert (Var (xi, T)), cert (Term.list_comb (Var (xi, Ts ---> T), ps))));
   400   in
   401     th |> Thm.instantiate ([], inst)
   402     |> fold_rev (Thm.forall_intr o cert) ps
   403   end;
   404 
   405 
   406 (*specialization over a list of cterms*)
   407 val forall_elim_list = fold forall_elim;
   408 
   409 (*maps A1,...,An |- B  to  [| A1;...;An |] ==> B*)
   410 val implies_intr_list = fold_rev implies_intr;
   411 
   412 (*maps [| A1;...;An |] ==> B and [A1,...,An]  to  B*)
   413 fun implies_elim_list impth ths = Library.foldl (uncurry implies_elim) (impth,ths);
   414 
   415 (*Reset Var indexes to zero, renaming to preserve distinctness*)
   416 fun zero_var_indexes th =
   417   let
   418     val thy = Thm.theory_of_thm th;
   419     val certT = Thm.ctyp_of thy and cert = Thm.cterm_of thy;
   420     val (instT, inst) = Term.zero_var_indexes_inst (Thm.full_prop_of th);
   421     val cinstT = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   422     val cinst = map (fn (v, t) => (cert (Var v), cert t)) inst;
   423   in Thm.adjust_maxidx_thm (Thm.instantiate (cinstT, cinst) th) end;
   424 
   425 
   426 (** Standard form of object-rule: no hypotheses, flexflex constraints,
   427     Frees, or outer quantifiers; all generality expressed by Vars of index 0.**)
   428 
   429 (*Discharge all hypotheses.*)
   430 fun implies_intr_hyps th =
   431   fold Thm.implies_intr (#hyps (Thm.crep_thm th)) th;
   432 
   433 (*Squash a theorem's flexflex constraints provided it can be done uniquely.
   434   This step can lose information.*)
   435 fun flexflex_unique th =
   436   if null (tpairs_of th) then th else
   437     case Seq.chop 2 (flexflex_rule th) of
   438       ([th],_) => th
   439     | ([],_)   => raise THM("flexflex_unique: impossible constraints", 0, [th])
   440     |      _   => raise THM("flexflex_unique: multiple unifiers", 0, [th]);
   441 
   442 fun close_derivation thm =
   443   if Thm.get_name_tags thm = ("", []) then Thm.name_thm ("", thm)
   444   else thm;
   445 
   446 val standard' =
   447   implies_intr_hyps
   448   #> forall_intr_frees
   449   #> `Thm.maxidx_of
   450   #-> (fn maxidx =>
   451     forall_elim_vars (maxidx + 1)
   452     #> strip_shyps_warning
   453     #> zero_var_indexes
   454     #> Thm.varifyT
   455     #> Thm.compress);
   456 
   457 val standard =
   458   flexflex_unique
   459   #> standard'
   460   #> close_derivation;
   461 
   462 val local_standard =
   463   strip_shyps
   464   #> zero_var_indexes
   465   #> Thm.compress
   466   #> close_derivation;
   467 
   468 
   469 (*Convert all Vars in a theorem to Frees.  Also return a function for
   470   reversing that operation.  DOES NOT WORK FOR TYPE VARIABLES.
   471   Similar code in type/freeze_thaw*)
   472 
   473 fun freeze_thaw_robust th =
   474  let val fth = freezeT th
   475      val {prop, tpairs, thy, ...} = rep_thm fth
   476  in
   477    case foldr add_term_vars [] (prop :: Thm.terms_of_tpairs tpairs) of
   478        [] => (fth, fn i => fn x => x)   (*No vars: nothing to do!*)
   479      | vars =>
   480          let fun newName (Var(ix,_)) = (ix, gensym (string_of_indexname ix))
   481              val alist = map newName vars
   482              fun mk_inst (Var(v,T)) =
   483                  (cterm_of thy (Var(v,T)),
   484                   cterm_of thy (Free(((the o AList.lookup (op =) alist) v), T)))
   485              val insts = map mk_inst vars
   486              fun thaw i th' = (*i is non-negative increment for Var indexes*)
   487                  th' |> forall_intr_list (map #2 insts)
   488                      |> forall_elim_list (map (Thm.cterm_incr_indexes i o #1) insts)
   489          in  (Thm.instantiate ([],insts) fth, thaw)  end
   490  end;
   491 
   492 (*Basic version of the function above. No option to rename Vars apart in thaw.
   493   The Frees created from Vars have nice names. FIXME: does not check for 
   494   clashes with variables in the assumptions, so delete and use freeze_thaw_robust instead?*)
   495 fun freeze_thaw th =
   496  let val fth = freezeT th
   497      val {prop, tpairs, thy, ...} = rep_thm fth
   498  in
   499    case foldr add_term_vars [] (prop :: Thm.terms_of_tpairs tpairs) of
   500        [] => (fth, fn x => x)
   501      | vars =>
   502          let fun newName (Var(ix,_), (pairs,used)) =
   503                    let val v = variant used (string_of_indexname ix)
   504                    in  ((ix,v)::pairs, v::used)  end;
   505              val (alist, _) = foldr newName ([], Library.foldr add_term_names
   506                (prop :: Thm.terms_of_tpairs tpairs, [])) vars
   507              fun mk_inst (Var(v,T)) =
   508                  (cterm_of thy (Var(v,T)),
   509                   cterm_of thy (Free(((the o AList.lookup (op =) alist) v), T)))
   510              val insts = map mk_inst vars
   511              fun thaw th' =
   512                  th' |> forall_intr_list (map #2 insts)
   513                      |> forall_elim_list (map #1 insts)
   514          in  (Thm.instantiate ([],insts) fth, thaw)  end
   515  end;
   516 
   517 (*Rotates a rule's premises to the left by k*)
   518 val rotate_prems = permute_prems 0;
   519 
   520 (* permute prems, where the i-th position in the argument list (counting from 0)
   521    gives the position within the original thm to be transferred to position i.
   522    Any remaining trailing positions are left unchanged. *)
   523 val rearrange_prems = let
   524   fun rearr new []      thm = thm
   525   |   rearr new (p::ps) thm = rearr (new+1)
   526      (map (fn q => if new<=q andalso q<p then q+1 else q) ps)
   527      (permute_prems (new+1) (new-p) (permute_prems new (p-new) thm))
   528   in rearr 0 end;
   529 
   530 (*Assume a new formula, read following the same conventions as axioms.
   531   Generalizes over Free variables,
   532   creates the assumption, and then strips quantifiers.
   533   Example is [| ALL x:?A. ?P(x) |] ==> [| ?P(?a) |]
   534              [ !(A,P,a)[| ALL x:A. P(x) |] ==> [| P(a) |] ]    *)
   535 fun assume_ax thy sP =
   536   let val prop = Logic.close_form (term_of (read_cterm thy (sP, propT)))
   537   in forall_elim_vars 0 (Thm.assume (cterm_of thy prop)) end;
   538 
   539 (*Resolution: exactly one resolvent must be produced.*)
   540 fun tha RSN (i,thb) =
   541   case Seq.chop 2 (biresolution false [(false,tha)] i thb) of
   542       ([th],_) => th
   543     | ([],_)   => raise THM("RSN: no unifiers", i, [tha,thb])
   544     |      _   => raise THM("RSN: multiple unifiers", i, [tha,thb]);
   545 
   546 (*resolution: P==>Q, Q==>R gives P==>R. *)
   547 fun tha RS thb = tha RSN (1,thb);
   548 
   549 (*For joining lists of rules*)
   550 fun thas RLN (i,thbs) =
   551   let val resolve = biresolution false (map (pair false) thas) i
   552       fun resb thb = Seq.list_of (resolve thb) handle THM _ => []
   553   in maps resb thbs end;
   554 
   555 fun thas RL thbs = thas RLN (1,thbs);
   556 
   557 (*Resolve a list of rules against bottom_rl from right to left;
   558   makes proof trees*)
   559 fun rls MRS bottom_rl =
   560   let fun rs_aux i [] = bottom_rl
   561         | rs_aux i (rl::rls) = rl RSN (i, rs_aux (i+1) rls)
   562   in  rs_aux 1 rls  end;
   563 
   564 (*As above, but for rule lists*)
   565 fun rlss MRL bottom_rls =
   566   let fun rs_aux i [] = bottom_rls
   567         | rs_aux i (rls::rlss) = rls RLN (i, rs_aux (i+1) rlss)
   568   in  rs_aux 1 rlss  end;
   569 
   570 (*A version of MRS with more appropriate argument order*)
   571 fun bottom_rl OF rls = rls MRS bottom_rl;
   572 
   573 (*compose Q and [...,Qi,Q(i+1),...]==>R to [...,Q(i+1),...]==>R
   574   with no lifting or renaming!  Q may contain ==> or meta-quants
   575   ALWAYS deletes premise i *)
   576 fun compose(tha,i,thb) =
   577     Seq.list_of (bicompose false (false,tha,0) i thb);
   578 
   579 fun compose_single (tha,i,thb) =
   580   (case compose (tha,i,thb) of
   581     [th] => th
   582   | _ => raise THM ("compose: unique result expected", i, [tha,thb]));
   583 
   584 (*compose Q and [Q1,Q2,...,Qk]==>R to [Q2,...,Qk]==>R getting unique result*)
   585 fun tha COMP thb =
   586     case compose(tha,1,thb) of
   587         [th] => th
   588       | _ =>   raise THM("COMP", 1, [tha,thb]);
   589 
   590 
   591 (** theorem equality **)
   592 
   593 (*True if the two theorems have the same theory.*)
   594 val eq_thm_thy = eq_thy o pairself Thm.theory_of_thm;
   595 
   596 (*True if the two theorems have the same prop field, ignoring hyps, der, etc.*)
   597 val eq_thm_prop = op aconv o pairself Thm.full_prop_of;
   598 
   599 (*Useful "distance" function for BEST_FIRST*)
   600 val size_of_thm = size_of_term o Thm.full_prop_of;
   601 
   602 (*maintain lists of theorems --- preserving canonical order*)
   603 val del_rule = remove eq_thm_prop;
   604 fun add_rule th = cons th o del_rule th;
   605 val merge_rules = Library.merge eq_thm_prop;
   606 
   607 (*weak_eq_thm: ignores variable renaming and (some) type variable renaming*)
   608 val weak_eq_thm = Thm.eq_thm o pairself (forall_intr_vars o freezeT);
   609 
   610 
   611 (*** Meta-Rewriting Rules ***)
   612 
   613 fun read_prop s = read_cterm ProtoPure.thy (s, propT);
   614 
   615 fun store_thm name thm = hd (PureThy.smart_store_thms (name, [thm]));
   616 fun store_standard_thm name thm = store_thm name (standard thm);
   617 fun store_thm_open name thm = hd (PureThy.smart_store_thms_open (name, [thm]));
   618 fun store_standard_thm_open name thm = store_thm_open name (standard' thm);
   619 
   620 val reflexive_thm =
   621   let val cx = cert (Var(("x",0),TVar(("'a",0),[])))
   622   in store_standard_thm_open "reflexive" (Thm.reflexive cx) end;
   623 
   624 val symmetric_thm =
   625   let val xy = read_prop "x == y"
   626   in store_standard_thm_open "symmetric" (Thm.implies_intr xy (Thm.symmetric (Thm.assume xy))) end;
   627 
   628 val transitive_thm =
   629   let val xy = read_prop "x == y"
   630       val yz = read_prop "y == z"
   631       val xythm = Thm.assume xy and yzthm = Thm.assume yz
   632   in store_standard_thm_open "transitive" (Thm.implies_intr yz (Thm.transitive xythm yzthm)) end;
   633 
   634 fun symmetric_fun thm = thm RS symmetric_thm;
   635 
   636 fun extensional eq =
   637   let val eq' =
   638     abstract_rule "x" (snd (Thm.dest_comb (fst (dest_equals (cprop_of eq))))) eq
   639   in equal_elim (eta_conversion (cprop_of eq')) eq' end;
   640 
   641 val equals_cong =
   642   store_standard_thm_open "equals_cong" (Thm.reflexive (read_prop "x == y"));
   643 
   644 val imp_cong =
   645   let
   646     val ABC = read_prop "PROP A ==> PROP B == PROP C"
   647     val AB = read_prop "PROP A ==> PROP B"
   648     val AC = read_prop "PROP A ==> PROP C"
   649     val A = read_prop "PROP A"
   650   in
   651     store_standard_thm_open "imp_cong" (implies_intr ABC (equal_intr
   652       (implies_intr AB (implies_intr A
   653         (equal_elim (implies_elim (assume ABC) (assume A))
   654           (implies_elim (assume AB) (assume A)))))
   655       (implies_intr AC (implies_intr A
   656         (equal_elim (symmetric (implies_elim (assume ABC) (assume A)))
   657           (implies_elim (assume AC) (assume A)))))))
   658   end;
   659 
   660 val swap_prems_eq =
   661   let
   662     val ABC = read_prop "PROP A ==> PROP B ==> PROP C"
   663     val BAC = read_prop "PROP B ==> PROP A ==> PROP C"
   664     val A = read_prop "PROP A"
   665     val B = read_prop "PROP B"
   666   in
   667     store_standard_thm_open "swap_prems_eq" (equal_intr
   668       (implies_intr ABC (implies_intr B (implies_intr A
   669         (implies_elim (implies_elim (assume ABC) (assume A)) (assume B)))))
   670       (implies_intr BAC (implies_intr A (implies_intr B
   671         (implies_elim (implies_elim (assume BAC) (assume B)) (assume A))))))
   672   end;
   673 
   674 val imp_cong_rule = combination o combination (reflexive implies);
   675 
   676 local
   677   val dest_eq = dest_equals o cprop_of
   678   val rhs_of = snd o dest_eq
   679 in
   680 fun beta_eta_conversion t =
   681   let val thm = beta_conversion true t
   682   in transitive thm (eta_conversion (rhs_of thm)) end
   683 end;
   684 
   685 fun eta_long_conversion ct = transitive (beta_eta_conversion ct)
   686   (symmetric (beta_eta_conversion (cterm_fun (Pattern.eta_long []) ct)));
   687 
   688 val abs_def =
   689   let
   690     fun contract_lhs th =
   691       Thm.transitive (Thm.symmetric (beta_eta_conversion (fst (dest_equals (cprop_of th))))) th;
   692     fun abstract cx th = Thm.abstract_rule
   693         (case Thm.term_of cx of Var ((x, _), _) => x | Free (x, _) => x | _ => "x") cx th
   694       handle THM _ => raise THM ("Malformed definitional equation", 0, [th]);
   695   in
   696     contract_lhs
   697     #> `(snd o strip_comb o fst o dest_equals o cprop_of)
   698     #-> fold_rev abstract
   699     #> contract_lhs
   700   end;
   701 
   702 (*rewrite B in !!x1 ... xn. B*)
   703 fun forall_conv 0 cv ct = cv ct
   704   | forall_conv n cv ct =
   705       (case try Thm.dest_comb ct of
   706         NONE => cv ct
   707       | SOME (A, B) =>
   708           (case (term_of A, term_of B) of
   709             (Const ("all", _), Abs (x, _, _)) =>
   710               let val (v, B') = Thm.dest_abs (SOME (gensym "all_")) B in
   711                 Thm.combination (Thm.reflexive A)
   712                   (Thm.abstract_rule x v (forall_conv (n - 1) cv B'))
   713               end
   714           | _ => cv ct));
   715 
   716 (*rewrite B in A1 ==> ... ==> An ==> B*)
   717 fun concl_conv 0 cv ct = cv ct
   718   | concl_conv n cv ct =
   719       (case try dest_implies ct of
   720         NONE => cv ct
   721       | SOME (A, B) => imp_cong_rule (reflexive A) (concl_conv (n - 1) cv B));
   722 
   723 (*rewrite the A's in A1 ==> ... ==> An ==> B*)
   724 fun prems_conv 0 _ = reflexive
   725   | prems_conv n cv =
   726       let
   727         fun conv i ct =
   728           if i = n + 1 then reflexive ct
   729           else
   730             (case try dest_implies ct of
   731               NONE => reflexive ct
   732             | SOME (A, B) => imp_cong_rule (cv i A) (conv (i + 1) B));
   733   in conv 1 end;
   734 
   735 fun goals_conv pred cv = prems_conv ~1 (fn i => if pred i then cv else reflexive);
   736 fun fconv_rule cv th = equal_elim (cv (cprop_of th)) th;
   737 
   738 
   739 (*** Some useful meta-theorems ***)
   740 
   741 (*The rule V/V, obtains assumption solving for eresolve_tac*)
   742 val asm_rl = store_standard_thm_open "asm_rl" (Thm.trivial (read_prop "PROP ?psi"));
   743 val _ = store_thm "_" asm_rl;
   744 
   745 (*Meta-level cut rule: [| V==>W; V |] ==> W *)
   746 val cut_rl =
   747   store_standard_thm_open "cut_rl"
   748     (Thm.trivial (read_prop "PROP ?psi ==> PROP ?theta"));
   749 
   750 (*Generalized elim rule for one conclusion; cut_rl with reversed premises:
   751      [| PROP V;  PROP V ==> PROP W |] ==> PROP W *)
   752 val revcut_rl =
   753   let val V = read_prop "PROP V"
   754       and VW = read_prop "PROP V ==> PROP W";
   755   in
   756     store_standard_thm_open "revcut_rl"
   757       (implies_intr V (implies_intr VW (implies_elim (assume VW) (assume V))))
   758   end;
   759 
   760 (*for deleting an unwanted assumption*)
   761 val thin_rl =
   762   let val V = read_prop "PROP V"
   763       and W = read_prop "PROP W";
   764   in store_standard_thm_open "thin_rl" (implies_intr V (implies_intr W (assume W))) end;
   765 
   766 (* (!!x. PROP ?V) == PROP ?V       Allows removal of redundant parameters*)
   767 val triv_forall_equality =
   768   let val V  = read_prop "PROP V"
   769       and QV = read_prop "!!x::'a. PROP V"
   770       and x  = cert (Free ("x", Term.aT []));
   771   in
   772     store_standard_thm_open "triv_forall_equality"
   773       (equal_intr (implies_intr QV (forall_elim x (assume QV)))
   774         (implies_intr V  (forall_intr x (assume V))))
   775   end;
   776 
   777 (* (PROP ?Phi ==> PROP ?Phi ==> PROP ?Psi) ==>
   778    (PROP ?Phi ==> PROP ?Psi)
   779 *)
   780 val distinct_prems_rl =
   781   let
   782     val AAB = read_prop "PROP Phi ==> PROP Phi ==> PROP Psi"
   783     val A = read_prop "PROP Phi";
   784   in
   785     store_standard_thm_open "distinct_prems_rl"
   786       (implies_intr_list [AAB, A] (implies_elim_list (assume AAB) [assume A, assume A]))
   787   end;
   788 
   789 (* (PROP ?PhiA ==> PROP ?PhiB ==> PROP ?Psi) ==>
   790    (PROP ?PhiB ==> PROP ?PhiA ==> PROP ?Psi)
   791    `thm COMP swap_prems_rl' swaps the first two premises of `thm'
   792 *)
   793 val swap_prems_rl =
   794   let val cmajor = read_prop "PROP PhiA ==> PROP PhiB ==> PROP Psi";
   795       val major = assume cmajor;
   796       val cminor1 = read_prop "PROP PhiA";
   797       val minor1 = assume cminor1;
   798       val cminor2 = read_prop "PROP PhiB";
   799       val minor2 = assume cminor2;
   800   in store_standard_thm_open "swap_prems_rl"
   801        (implies_intr cmajor (implies_intr cminor2 (implies_intr cminor1
   802          (implies_elim (implies_elim major minor1) minor2))))
   803   end;
   804 
   805 (* [| PROP ?phi ==> PROP ?psi; PROP ?psi ==> PROP ?phi |]
   806    ==> PROP ?phi == PROP ?psi
   807    Introduction rule for == as a meta-theorem.
   808 *)
   809 val equal_intr_rule =
   810   let val PQ = read_prop "PROP phi ==> PROP psi"
   811       and QP = read_prop "PROP psi ==> PROP phi"
   812   in
   813     store_standard_thm_open "equal_intr_rule"
   814       (implies_intr PQ (implies_intr QP (equal_intr (assume PQ) (assume QP))))
   815   end;
   816 
   817 (* PROP ?phi == PROP ?psi ==> PROP ?phi ==> PROP ?psi *)
   818 val equal_elim_rule1 =
   819   let val eq = read_prop "PROP phi == PROP psi"
   820       and P = read_prop "PROP phi"
   821   in store_standard_thm_open "equal_elim_rule1"
   822     (Thm.equal_elim (assume eq) (assume P) |> implies_intr_list [eq, P])
   823   end;
   824 
   825 (* PROP ?psi == PROP ?phi ==> PROP ?phi ==> PROP ?psi *)
   826 val equal_elim_rule2 =
   827   store_standard_thm_open "equal_elim_rule2" (symmetric_thm RS equal_elim_rule1);
   828 
   829 (* "[| PROP ?phi; PROP ?phi; PROP ?psi |] ==> PROP ?psi" *)
   830 val remdups_rl =
   831   let val P = read_prop "PROP phi" and Q = read_prop "PROP psi";
   832   in store_standard_thm_open "remdups_rl" (implies_intr_list [P, P, Q] (Thm.assume Q)) end;
   833 
   834 
   835 (*(PROP ?phi ==> (!!x. PROP ?psi(x))) == (!!x. PROP ?phi ==> PROP ?psi(x))
   836   Rewrite rule for HHF normalization.*)
   837 
   838 val norm_hhf_eq =
   839   let
   840     val aT = TFree ("'a", []);
   841     val all = Term.all aT;
   842     val x = Free ("x", aT);
   843     val phi = Free ("phi", propT);
   844     val psi = Free ("psi", aT --> propT);
   845 
   846     val cx = cert x;
   847     val cphi = cert phi;
   848     val lhs = cert (Logic.mk_implies (phi, all $ Abs ("x", aT, psi $ Bound 0)));
   849     val rhs = cert (all $ Abs ("x", aT, Logic.mk_implies (phi, psi $ Bound 0)));
   850   in
   851     Thm.equal_intr
   852       (Thm.implies_elim (Thm.assume lhs) (Thm.assume cphi)
   853         |> Thm.forall_elim cx
   854         |> Thm.implies_intr cphi
   855         |> Thm.forall_intr cx
   856         |> Thm.implies_intr lhs)
   857       (Thm.implies_elim
   858           (Thm.assume rhs |> Thm.forall_elim cx) (Thm.assume cphi)
   859         |> Thm.forall_intr cx
   860         |> Thm.implies_intr cphi
   861         |> Thm.implies_intr rhs)
   862     |> store_standard_thm_open "norm_hhf_eq"
   863   end;
   864 
   865 val norm_hhf_prop = Logic.dest_equals (Thm.prop_of norm_hhf_eq);
   866 
   867 fun is_norm_hhf tm =
   868   let
   869     fun is_norm (Const ("==>", _) $ _ $ (Const ("all", _) $ _)) = false
   870       | is_norm (t $ u) = is_norm t andalso is_norm u
   871       | is_norm (Abs (_, _, t)) = is_norm t
   872       | is_norm _ = true;
   873   in is_norm (Envir.beta_eta_contract tm) end;
   874 
   875 fun norm_hhf thy t =
   876   if is_norm_hhf t then t
   877   else Pattern.rewrite_term thy [norm_hhf_prop] [] t;
   878 
   879 
   880 
   881 (*** Instantiate theorem th, reading instantiations in theory thy ****)
   882 
   883 (*Version that normalizes the result: Thm.instantiate no longer does that*)
   884 fun instantiate instpair th = Thm.instantiate instpair th  COMP   asm_rl;
   885 
   886 fun read_instantiate_sg' thy sinsts th =
   887     let val ts = types_sorts th;
   888         val used = add_used th [];
   889     in  instantiate (read_insts thy ts ts used sinsts) th  end;
   890 
   891 fun read_instantiate_sg thy sinsts th =
   892   read_instantiate_sg' thy (map (apfst Syntax.indexname) sinsts) th;
   893 
   894 (*Instantiate theorem th, reading instantiations under theory of th*)
   895 fun read_instantiate sinsts th =
   896     read_instantiate_sg (Thm.theory_of_thm th) sinsts th;
   897 
   898 fun read_instantiate' sinsts th =
   899     read_instantiate_sg' (Thm.theory_of_thm th) sinsts th;
   900 
   901 
   902 (*Left-to-right replacements: tpairs = [...,(vi,ti),...].
   903   Instantiates distinct Vars by terms, inferring type instantiations. *)
   904 local
   905   fun add_types ((ct,cu), (thy,tye,maxidx)) =
   906     let val {thy=thyt, t=t, T= T, maxidx=maxt,...} = rep_cterm ct
   907         and {thy=thyu, t=u, T= U, maxidx=maxu,...} = rep_cterm cu;
   908         val maxi = Int.max(maxidx, Int.max(maxt, maxu));
   909         val thy' = Theory.merge(thy, Theory.merge(thyt, thyu))
   910         val (tye',maxi') = Sign.typ_unify thy' (T, U) (tye, maxi)
   911           handle Type.TUNIFY => raise TYPE("Ill-typed instantiation", [T,U], [t,u])
   912     in  (thy', tye', maxi')  end;
   913 in
   914 fun cterm_instantiate ctpairs0 th =
   915   let val (thy,tye,_) = foldr add_types (Thm.theory_of_thm th, Vartab.empty, 0) ctpairs0
   916       fun instT(ct,cu) =
   917         let val inst = cterm_of thy o Envir.subst_TVars tye o term_of
   918         in (inst ct, inst cu) end
   919       fun ctyp2 (ixn, (S, T)) = (ctyp_of thy (TVar (ixn, S)), ctyp_of thy T)
   920   in  instantiate (map ctyp2 (Vartab.dest tye), map instT ctpairs0) th  end
   921   handle TERM _ =>
   922            raise THM("cterm_instantiate: incompatible theories",0,[th])
   923        | TYPE (msg, _, _) => raise THM(msg, 0, [th])
   924 end;
   925 
   926 
   927 (** Derived rules mainly for METAHYPS **)
   928 
   929 (*Given the term "a", takes (%x.t)==(%x.u) to t[a/x]==u[a/x]*)
   930 fun equal_abs_elim ca eqth =
   931   let val {thy=thya, t=a, ...} = rep_cterm ca
   932       and combth = combination eqth (reflexive ca)
   933       val {thy,prop,...} = rep_thm eqth
   934       val (abst,absu) = Logic.dest_equals prop
   935       val cert = cterm_of (Theory.merge (thy,thya))
   936   in  transitive (symmetric (beta_conversion false (cert (abst$a))))
   937            (transitive combth (beta_conversion false (cert (absu$a))))
   938   end
   939   handle THM _ => raise THM("equal_abs_elim", 0, [eqth]);
   940 
   941 (*Calling equal_abs_elim with multiple terms*)
   942 fun equal_abs_elim_list cts th = foldr (uncurry equal_abs_elim) th (rev cts);
   943 
   944 
   945 (** protected propositions and embedded terms **)
   946 
   947 local
   948   val A = cert (Free ("A", propT));
   949   val prop_def = #1 (freeze_thaw ProtoPure.prop_def);
   950   val term_def = #1 (freeze_thaw ProtoPure.term_def);
   951 in
   952   val protect = Thm.capply (cert Logic.protectC);
   953   val protectI = store_thm "protectI" (PureThy.kind_rule PureThy.internalK (standard
   954       (Thm.equal_elim (Thm.symmetric prop_def) (Thm.assume A))));
   955   val protectD = store_thm "protectD" (PureThy.kind_rule PureThy.internalK (standard
   956       (Thm.equal_elim prop_def (Thm.assume (protect A)))));
   957   val protect_cong = store_standard_thm_open "protect_cong" (Thm.reflexive (protect A));
   958 
   959   val termI = store_thm "termI" (PureThy.kind_rule PureThy.internalK (standard
   960       (Thm.equal_elim (Thm.symmetric term_def) (Thm.forall_intr A (Thm.trivial A)))));
   961 end;
   962 
   963 fun implies_intr_protected asms th =
   964   let val asms' = map protect asms in
   965     implies_elim_list
   966       (implies_intr_list asms th)
   967       (map (fn asm' => Thm.assume asm' RS protectD) asms')
   968     |> implies_intr_list asms'
   969   end;
   970 
   971 fun mk_term ct =
   972   let
   973     val {thy, T, ...} = Thm.rep_cterm ct;
   974     val cert = Thm.cterm_of thy;
   975     val certT = Thm.ctyp_of thy;
   976     val a = certT (TVar (("'a", 0), []));
   977     val x = cert (Var (("x", 0), T));
   978   in Thm.instantiate ([(a, certT T)], [(x, ct)]) termI end;
   979 
   980 fun dest_term th =
   981   let val cprop = Thm.cprop_of th in
   982     if can Logic.dest_term (Thm.term_of cprop) then
   983       #2 (Thm.dest_comb cprop)
   984     else raise THM ("dest_term", 0, [th])
   985   end;
   986 
   987 
   988 
   989 (** variations on instantiate **)
   990 
   991 (*shorthand for instantiating just one variable in the current theory*)
   992 fun inst x t = read_instantiate_sg (the_context()) [(x,t)];
   993 
   994 
   995 (* instantiate by left-to-right occurrence of variables *)
   996 
   997 fun instantiate' cTs cts thm =
   998   let
   999     fun err msg =
  1000       raise TYPE ("instantiate': " ^ msg,
  1001         map_filter (Option.map Thm.typ_of) cTs,
  1002         map_filter (Option.map Thm.term_of) cts);
  1003 
  1004     fun inst_of (v, ct) =
  1005       (Thm.cterm_of (Thm.theory_of_cterm ct) (Var v), ct)
  1006         handle TYPE (msg, _, _) => err msg;
  1007 
  1008     fun tyinst_of (v, cT) =
  1009       (Thm.ctyp_of (Thm.theory_of_ctyp cT) (TVar v), cT)
  1010         handle TYPE (msg, _, _) => err msg;
  1011 
  1012     fun zip_vars _ [] = []
  1013       | zip_vars (_ :: vs) (NONE :: opt_ts) = zip_vars vs opt_ts
  1014       | zip_vars (v :: vs) (SOME t :: opt_ts) = (v, t) :: zip_vars vs opt_ts
  1015       | zip_vars [] _ = err "more instantiations than variables in thm";
  1016 
  1017     (*instantiate types first!*)
  1018     val thm' =
  1019       if forall is_none cTs then thm
  1020       else Thm.instantiate (map tyinst_of (zip_vars (tvars_of thm) cTs), []) thm;
  1021     in
  1022       if forall is_none cts then thm'
  1023       else Thm.instantiate ([], map inst_of (zip_vars (vars_of thm') cts)) thm'
  1024     end;
  1025 
  1026 
  1027 
  1028 (** renaming of bound variables **)
  1029 
  1030 (* replace bound variables x_i in thm by y_i *)
  1031 (* where vs = [(x_1, y_1), ..., (x_n, y_n)]  *)
  1032 
  1033 fun rename_bvars [] thm = thm
  1034   | rename_bvars vs thm =
  1035     let
  1036       val {thy, prop, ...} = rep_thm thm;
  1037       fun ren (Abs (x, T, t)) = Abs (AList.lookup (op =) vs x |> the_default x, T, ren t)
  1038         | ren (t $ u) = ren t $ ren u
  1039         | ren t = t;
  1040     in equal_elim (reflexive (cterm_of thy (ren prop))) thm end;
  1041 
  1042 
  1043 (* renaming in left-to-right order *)
  1044 
  1045 fun rename_bvars' xs thm =
  1046   let
  1047     val {thy, prop, ...} = rep_thm thm;
  1048     fun rename [] t = ([], t)
  1049       | rename (x' :: xs) (Abs (x, T, t)) =
  1050           let val (xs', t') = rename xs t
  1051           in (xs', Abs (the_default x x', T, t')) end
  1052       | rename xs (t $ u) =
  1053           let
  1054             val (xs', t') = rename xs t;
  1055             val (xs'', u') = rename xs' u
  1056           in (xs'', t' $ u') end
  1057       | rename xs t = (xs, t);
  1058   in case rename xs prop of
  1059       ([], prop') => equal_elim (reflexive (cterm_of thy prop')) thm
  1060     | _ => error "More names than abstractions in theorem"
  1061   end;
  1062 
  1063 
  1064 
  1065 (* unvarify(T) *)
  1066 
  1067 (*assume thm in standard form, i.e. no frees, 0 var indexes*)
  1068 
  1069 fun unvarifyT thm =
  1070   let
  1071     val cT = Thm.ctyp_of (Thm.theory_of_thm thm);
  1072     val tfrees = map (fn ((x, _), S) => SOME (cT (TFree (x, S)))) (tvars_of thm);
  1073   in instantiate' tfrees [] thm end;
  1074 
  1075 fun unvarify raw_thm =
  1076   let
  1077     val thm = unvarifyT raw_thm;
  1078     val ct = Thm.cterm_of (Thm.theory_of_thm thm);
  1079     val frees = map (fn ((x, _), T) => SOME (ct (Free (x, T)))) (vars_of thm);
  1080   in instantiate' [] frees thm end;
  1081 
  1082 
  1083 (* tvars_intr_list *)
  1084 
  1085 fun tvars_intr_list tfrees thm =
  1086   apfst (map (fn ((s, S), ixn) => (s, (ixn, S)))) (Thm.varifyT'
  1087     (gen_rems (op = o apfst fst) (tfrees_of thm, tfrees)) thm);
  1088 
  1089 
  1090 (* increment var indexes *)
  1091 
  1092 fun incr_indexes th = Thm.incr_indexes (Thm.maxidx_of th + 1);
  1093 
  1094 fun incr_indexes2 th1 th2 =
  1095   Thm.incr_indexes (Int.max (Thm.maxidx_of th1, Thm.maxidx_of th2) + 1);
  1096 
  1097 
  1098 (* freeze_all *)
  1099 
  1100 (*freeze all (T)Vars; assumes thm in standard form*)
  1101 
  1102 fun freeze_all_TVars thm =
  1103   (case tvars_of thm of
  1104     [] => thm
  1105   | tvars =>
  1106       let val cert = Thm.ctyp_of (Thm.theory_of_thm thm)
  1107       in instantiate' (map (fn ((x, _), S) => SOME (cert (TFree (x, S)))) tvars) [] thm end);
  1108 
  1109 fun freeze_all_Vars thm =
  1110   (case vars_of thm of
  1111     [] => thm
  1112   | vars =>
  1113       let val cert = Thm.cterm_of (Thm.theory_of_thm thm)
  1114       in instantiate' [] (map (fn ((x, _), T) => SOME (cert (Free (x, T)))) vars) thm end);
  1115 
  1116 val freeze_all = freeze_all_Vars o freeze_all_TVars;
  1117 
  1118 
  1119 
  1120 (** multi_resolve **)
  1121 
  1122 local
  1123 
  1124 fun res th i rule =
  1125   Thm.biresolution false [(false, th)] i rule handle THM _ => Seq.empty;
  1126 
  1127 fun multi_res _ [] rule = Seq.single rule
  1128   | multi_res i (th :: ths) rule = Seq.maps (res th i) (multi_res (i + 1) ths rule);
  1129 
  1130 in
  1131 
  1132 val multi_resolve = multi_res 1;
  1133 fun multi_resolves facts rules = Seq.maps (multi_resolve facts) (Seq.of_list rules);
  1134 
  1135 end;
  1136 
  1137 end;
  1138 
  1139 structure BasicDrule: BASIC_DRULE = Drule;
  1140 open BasicDrule;