src/HOL/Relation.thy
author noschinl
Mon Mar 12 15:11:24 2012 +0100 (2012-03-12)
changeset 46882 6242b4bc05bc
parent 46833 85619a872ab5
child 46883 eec472dae593
permissions -rw-r--r--
tuned simpset
     1 (*  Title:      HOL/Relation.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory; Stefan Berghofer, TU Muenchen
     3 *)
     4 
     5 header {* Relations – as sets of pairs, and binary predicates *}
     6 
     7 theory Relation
     8 imports Datatype Finite_Set
     9 begin
    10 
    11 text {* A preliminary: classical rules for reasoning on predicates *}
    12 
    13 declare predicate1I [Pure.intro!, intro!]
    14 declare predicate1D [Pure.dest, dest]
    15 declare predicate2I [Pure.intro!, intro!]
    16 declare predicate2D [Pure.dest, dest]
    17 declare bot1E [elim!] 
    18 declare bot2E [elim!]
    19 declare top1I [intro!]
    20 declare top2I [intro!]
    21 declare inf1I [intro!]
    22 declare inf2I [intro!]
    23 declare inf1E [elim!]
    24 declare inf2E [elim!]
    25 declare sup1I1 [intro?]
    26 declare sup2I1 [intro?]
    27 declare sup1I2 [intro?]
    28 declare sup2I2 [intro?]
    29 declare sup1E [elim!]
    30 declare sup2E [elim!]
    31 declare sup1CI [intro!]
    32 declare sup2CI [intro!]
    33 declare INF1_I [intro!]
    34 declare INF2_I [intro!]
    35 declare INF1_D [elim]
    36 declare INF2_D [elim]
    37 declare INF1_E [elim]
    38 declare INF2_E [elim]
    39 declare SUP1_I [intro]
    40 declare SUP2_I [intro]
    41 declare SUP1_E [elim!]
    42 declare SUP2_E [elim!]
    43 
    44 subsection {* Fundamental *}
    45 
    46 subsubsection {* Relations as sets of pairs *}
    47 
    48 type_synonym 'a rel = "('a * 'a) set"
    49 
    50 lemma subrelI: -- {* Version of @{thm [source] subsetI} for binary relations *}
    51   "(\<And>x y. (x, y) \<in> r \<Longrightarrow> (x, y) \<in> s) \<Longrightarrow> r \<subseteq> s"
    52   by auto
    53 
    54 lemma lfp_induct2: -- {* Version of @{thm [source] lfp_induct} for binary relations *}
    55   "(a, b) \<in> lfp f \<Longrightarrow> mono f \<Longrightarrow>
    56     (\<And>a b. (a, b) \<in> f (lfp f \<inter> {(x, y). P x y}) \<Longrightarrow> P a b) \<Longrightarrow> P a b"
    57   using lfp_induct_set [of "(a, b)" f "prod_case P"] by auto
    58 
    59 
    60 subsubsection {* Conversions between set and predicate relations *}
    61 
    62 lemma pred_equals_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) = (\<lambda>x. x \<in> S) \<longleftrightarrow> R = S"
    63   by (simp add: set_eq_iff fun_eq_iff)
    64 
    65 lemma pred_equals_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) = (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R = S"
    66   by (simp add: set_eq_iff fun_eq_iff)
    67 
    68 lemma pred_subset_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<le> (\<lambda>x. x \<in> S) \<longleftrightarrow> R \<subseteq> S"
    69   by (simp add: subset_iff le_fun_def)
    70 
    71 lemma pred_subset_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<le> (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R \<subseteq> S"
    72   by (simp add: subset_iff le_fun_def)
    73 
    74 lemma bot_empty_eq (* CANDIDATE [pred_set_conv] *): "\<bottom> = (\<lambda>x. x \<in> {})"
    75   by (auto simp add: fun_eq_iff)
    76 
    77 lemma bot_empty_eq2 (* CANDIDATE [pred_set_conv] *): "\<bottom> = (\<lambda>x y. (x, y) \<in> {})"
    78   by (auto simp add: fun_eq_iff)
    79 
    80 (* CANDIDATE lemma top_empty_eq [pred_set_conv]: "\<top> = (\<lambda>x. x \<in> UNIV)"
    81   by (auto simp add: fun_eq_iff) *)
    82 
    83 (* CANDIDATE lemma top_empty_eq2 [pred_set_conv]: "\<top> = (\<lambda>x y. (x, y) \<in> UNIV)"
    84   by (auto simp add: fun_eq_iff) *)
    85 
    86 lemma inf_Int_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<sqinter> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<inter> S)"
    87   by (simp add: inf_fun_def)
    88 
    89 lemma inf_Int_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<sqinter> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<inter> S)"
    90   by (simp add: inf_fun_def)
    91 
    92 lemma sup_Un_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<squnion> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<union> S)"
    93   by (simp add: sup_fun_def)
    94 
    95 lemma sup_Un_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<squnion> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<union> S)"
    96   by (simp add: sup_fun_def)
    97 
    98 lemma Inf_INT_eq [pred_set_conv]: "\<Sqinter>S = (\<lambda>x. x \<in> INTER S Collect)"
    99   by (simp add: fun_eq_iff Inf_apply)
   100 
   101 (* CANDIDATE
   102 lemma INF_Int_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Inter>S)"
   103   by (simp add: fun_eq_iff INF_apply)
   104 
   105 lemma Inf_INT_eq2 [pred_set_conv]: "\<Sqinter>S = (\<lambda>x y. (x, y) \<in> INTER (prod_case ` S) Collect)"
   106   by (simp add: fun_eq_iff Inf_apply INF_apply)
   107 
   108 lemma INF_Int_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Inter>S)"
   109   by (simp add: fun_eq_iff INF_apply)
   110 
   111 lemma Sup_SUP_eq [pred_set_conv]: "\<Squnion>S = (\<lambda>x. x \<in> UNION S Collect)"
   112   by (simp add: fun_eq_iff Sup_apply)
   113 
   114 lemma SUP_Sup_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Union>S)"
   115   by (simp add: fun_eq_iff SUP_apply)
   116 
   117 lemma Sup_SUP_eq2 [pred_set_conv]: "\<Squnion>S = (\<lambda>x y. (x, y) \<in> UNION (prod_case ` S) Collect)"
   118   by (simp add: fun_eq_iff Sup_apply SUP_apply)
   119 
   120 lemma SUP_Sup_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Union>S)"
   121   by (simp add: fun_eq_iff SUP_apply)
   122 *)
   123 
   124 (* CANDIDATE prefer those generalized versions:
   125 lemma INF_INT_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Inter>i\<in>S. r i))"
   126   by (simp add: INF_apply fun_eq_iff)
   127 
   128 lemma INF_INT_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Inter>i\<in>S. r i))"
   129   by (simp add: INF_apply fun_eq_iff)
   130 *)
   131 
   132 lemma INF_INT_eq (* CANDIDATE [pred_set_conv] *): "(\<Sqinter>i. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Inter>i. r i))"
   133   by (simp add: INF_apply fun_eq_iff)
   134 
   135 lemma INF_INT_eq2 (* CANDIDATE [pred_set_conv] *): "(\<Sqinter>i. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Inter>i. r i))"
   136   by (simp add: INF_apply fun_eq_iff)
   137 
   138 (* CANDIDATE prefer those generalized versions:
   139 lemma SUP_UN_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Union>i\<in>S. r i))"
   140   by (simp add: SUP_apply fun_eq_iff)
   141 
   142 lemma SUP_UN_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Union>i\<in>S. r i))"
   143   by (simp add: SUP_apply fun_eq_iff)
   144 *)
   145 
   146 lemma SUP_UN_eq [pred_set_conv]: "(\<Squnion>i. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Union>i. r i))"
   147   by (simp add: SUP_apply fun_eq_iff)
   148 
   149 lemma SUP_UN_eq2 [pred_set_conv]: "(\<Squnion>i. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Union>i. r i))"
   150   by (simp add: SUP_apply fun_eq_iff)
   151 
   152 
   153 subsection {* Properties of relations *}
   154 
   155 subsubsection {* Reflexivity *}
   156 
   157 definition refl_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   158 where
   159   "refl_on A r \<longleftrightarrow> r \<subseteq> A \<times> A \<and> (\<forall>x\<in>A. (x, x) \<in> r)"
   160 
   161 abbreviation refl :: "'a rel \<Rightarrow> bool"
   162 where -- {* reflexivity over a type *}
   163   "refl \<equiv> refl_on UNIV"
   164 
   165 definition reflp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   166 where
   167   "reflp r \<longleftrightarrow> refl {(x, y). r x y}"
   168 
   169 lemma reflp_refl_eq [pred_set_conv]:
   170   "reflp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> refl r" 
   171   by (simp add: refl_on_def reflp_def)
   172 
   173 lemma refl_onI: "r \<subseteq> A \<times> A ==> (!!x. x : A ==> (x, x) : r) ==> refl_on A r"
   174   by (unfold refl_on_def) (iprover intro!: ballI)
   175 
   176 lemma refl_onD: "refl_on A r ==> a : A ==> (a, a) : r"
   177   by (unfold refl_on_def) blast
   178 
   179 lemma refl_onD1: "refl_on A r ==> (x, y) : r ==> x : A"
   180   by (unfold refl_on_def) blast
   181 
   182 lemma refl_onD2: "refl_on A r ==> (x, y) : r ==> y : A"
   183   by (unfold refl_on_def) blast
   184 
   185 lemma reflpI:
   186   "(\<And>x. r x x) \<Longrightarrow> reflp r"
   187   by (auto intro: refl_onI simp add: reflp_def)
   188 
   189 lemma reflpE:
   190   assumes "reflp r"
   191   obtains "r x x"
   192   using assms by (auto dest: refl_onD simp add: reflp_def)
   193 
   194 lemma refl_on_Int: "refl_on A r ==> refl_on B s ==> refl_on (A \<inter> B) (r \<inter> s)"
   195   by (unfold refl_on_def) blast
   196 
   197 lemma reflp_inf:
   198   "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<sqinter> s)"
   199   by (auto intro: reflpI elim: reflpE)
   200 
   201 lemma refl_on_Un: "refl_on A r ==> refl_on B s ==> refl_on (A \<union> B) (r \<union> s)"
   202   by (unfold refl_on_def) blast
   203 
   204 lemma reflp_sup:
   205   "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<squnion> s)"
   206   by (auto intro: reflpI elim: reflpE)
   207 
   208 lemma refl_on_INTER:
   209   "ALL x:S. refl_on (A x) (r x) ==> refl_on (INTER S A) (INTER S r)"
   210   by (unfold refl_on_def) fast
   211 
   212 lemma refl_on_UNION:
   213   "ALL x:S. refl_on (A x) (r x) \<Longrightarrow> refl_on (UNION S A) (UNION S r)"
   214   by (unfold refl_on_def) blast
   215 
   216 lemma refl_on_empty [simp]: "refl_on {} {}"
   217   by (simp add:refl_on_def)
   218 
   219 lemma refl_on_def' [nitpick_unfold, code]:
   220   "refl_on A r \<longleftrightarrow> (\<forall>(x, y) \<in> r. x \<in> A \<and> y \<in> A) \<and> (\<forall>x \<in> A. (x, x) \<in> r)"
   221   by (auto intro: refl_onI dest: refl_onD refl_onD1 refl_onD2)
   222 
   223 
   224 subsubsection {* Irreflexivity *}
   225 
   226 definition irrefl :: "'a rel \<Rightarrow> bool"
   227 where
   228   "irrefl r \<longleftrightarrow> (\<forall>x. (x, x) \<notin> r)"
   229 
   230 lemma irrefl_distinct [code]:
   231   "irrefl r \<longleftrightarrow> (\<forall>(x, y) \<in> r. x \<noteq> y)"
   232   by (auto simp add: irrefl_def)
   233 
   234 
   235 subsubsection {* Symmetry *}
   236 
   237 definition sym :: "'a rel \<Rightarrow> bool"
   238 where
   239   "sym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r)"
   240 
   241 definition symp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   242 where
   243   "symp r \<longleftrightarrow> (\<forall>x y. r x y \<longrightarrow> r y x)"
   244 
   245 lemma symp_sym_eq [pred_set_conv]:
   246   "symp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> sym r" 
   247   by (simp add: sym_def symp_def)
   248 
   249 lemma symI:
   250   "(\<And>a b. (a, b) \<in> r \<Longrightarrow> (b, a) \<in> r) \<Longrightarrow> sym r"
   251   by (unfold sym_def) iprover
   252 
   253 lemma sympI:
   254   "(\<And>a b. r a b \<Longrightarrow> r b a) \<Longrightarrow> symp r"
   255   by (fact symI [to_pred])
   256 
   257 lemma symE:
   258   assumes "sym r" and "(b, a) \<in> r"
   259   obtains "(a, b) \<in> r"
   260   using assms by (simp add: sym_def)
   261 
   262 lemma sympE:
   263   assumes "symp r" and "r b a"
   264   obtains "r a b"
   265   using assms by (rule symE [to_pred])
   266 
   267 lemma symD:
   268   assumes "sym r" and "(b, a) \<in> r"
   269   shows "(a, b) \<in> r"
   270   using assms by (rule symE)
   271 
   272 lemma sympD:
   273   assumes "symp r" and "r b a"
   274   shows "r a b"
   275   using assms by (rule symD [to_pred])
   276 
   277 lemma sym_Int:
   278   "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<inter> s)"
   279   by (fast intro: symI elim: symE)
   280 
   281 lemma symp_inf:
   282   "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<sqinter> s)"
   283   by (fact sym_Int [to_pred])
   284 
   285 lemma sym_Un:
   286   "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<union> s)"
   287   by (fast intro: symI elim: symE)
   288 
   289 lemma symp_sup:
   290   "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<squnion> s)"
   291   by (fact sym_Un [to_pred])
   292 
   293 lemma sym_INTER:
   294   "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (INTER S r)"
   295   by (fast intro: symI elim: symE)
   296 
   297 (* FIXME thm sym_INTER [to_pred] *)
   298 
   299 lemma sym_UNION:
   300   "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (UNION S r)"
   301   by (fast intro: symI elim: symE)
   302 
   303 (* FIXME thm sym_UNION [to_pred] *)
   304 
   305 
   306 subsubsection {* Antisymmetry *}
   307 
   308 definition antisym :: "'a rel \<Rightarrow> bool"
   309 where
   310   "antisym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r \<longrightarrow> x = y)"
   311 
   312 abbreviation antisymP :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   313 where
   314   "antisymP r \<equiv> antisym {(x, y). r x y}"
   315 
   316 lemma antisymI:
   317   "(!!x y. (x, y) : r ==> (y, x) : r ==> x=y) ==> antisym r"
   318   by (unfold antisym_def) iprover
   319 
   320 lemma antisymD: "antisym r ==> (a, b) : r ==> (b, a) : r ==> a = b"
   321   by (unfold antisym_def) iprover
   322 
   323 lemma antisym_subset: "r \<subseteq> s ==> antisym s ==> antisym r"
   324   by (unfold antisym_def) blast
   325 
   326 lemma antisym_empty [simp]: "antisym {}"
   327   by (unfold antisym_def) blast
   328 
   329 
   330 subsubsection {* Transitivity *}
   331 
   332 definition trans :: "'a rel \<Rightarrow> bool"
   333 where
   334   "trans r \<longleftrightarrow> (\<forall>x y z. (x, y) \<in> r \<longrightarrow> (y, z) \<in> r \<longrightarrow> (x, z) \<in> r)"
   335 
   336 definition transp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   337 where
   338   "transp r \<longleftrightarrow> (\<forall>x y z. r x y \<longrightarrow> r y z \<longrightarrow> r x z)"
   339 
   340 lemma transp_trans_eq [pred_set_conv]:
   341   "transp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> trans r" 
   342   by (simp add: trans_def transp_def)
   343 
   344 abbreviation transP :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   345 where -- {* FIXME drop *}
   346   "transP r \<equiv> trans {(x, y). r x y}"
   347 
   348 lemma transI:
   349   "(\<And>x y z. (x, y) \<in> r \<Longrightarrow> (y, z) \<in> r \<Longrightarrow> (x, z) \<in> r) \<Longrightarrow> trans r"
   350   by (unfold trans_def) iprover
   351 
   352 lemma transpI:
   353   "(\<And>x y z. r x y \<Longrightarrow> r y z \<Longrightarrow> r x z) \<Longrightarrow> transp r"
   354   by (fact transI [to_pred])
   355 
   356 lemma transE:
   357   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   358   obtains "(x, z) \<in> r"
   359   using assms by (unfold trans_def) iprover
   360 
   361 lemma transpE:
   362   assumes "transp r" and "r x y" and "r y z"
   363   obtains "r x z"
   364   using assms by (rule transE [to_pred])
   365 
   366 lemma transD:
   367   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   368   shows "(x, z) \<in> r"
   369   using assms by (rule transE)
   370 
   371 lemma transpD:
   372   assumes "transp r" and "r x y" and "r y z"
   373   shows "r x z"
   374   using assms by (rule transD [to_pred])
   375 
   376 lemma trans_Int:
   377   "trans r \<Longrightarrow> trans s \<Longrightarrow> trans (r \<inter> s)"
   378   by (fast intro: transI elim: transE)
   379 
   380 lemma transp_inf:
   381   "transp r \<Longrightarrow> transp s \<Longrightarrow> transp (r \<sqinter> s)"
   382   by (fact trans_Int [to_pred])
   383 
   384 lemma trans_INTER:
   385   "\<forall>x\<in>S. trans (r x) \<Longrightarrow> trans (INTER S r)"
   386   by (fast intro: transI elim: transD)
   387 
   388 (* FIXME thm trans_INTER [to_pred] *)
   389 
   390 lemma trans_join [code]:
   391   "trans r \<longleftrightarrow> (\<forall>(x, y1) \<in> r. \<forall>(y2, z) \<in> r. y1 = y2 \<longrightarrow> (x, z) \<in> r)"
   392   by (auto simp add: trans_def)
   393 
   394 lemma transp_trans:
   395   "transp r \<longleftrightarrow> trans {(x, y). r x y}"
   396   by (simp add: trans_def transp_def)
   397 
   398 
   399 subsubsection {* Totality *}
   400 
   401 definition total_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   402 where
   403   "total_on A r \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. x \<noteq> y \<longrightarrow> (x, y) \<in> r \<or> (y, x) \<in> r)"
   404 
   405 abbreviation "total \<equiv> total_on UNIV"
   406 
   407 lemma total_on_empty [simp]: "total_on {} r"
   408   by (simp add: total_on_def)
   409 
   410 
   411 subsubsection {* Single valued relations *}
   412 
   413 definition single_valued :: "('a \<times> 'b) set \<Rightarrow> bool"
   414 where
   415   "single_valued r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (\<forall>z. (x, z) \<in> r \<longrightarrow> y = z))"
   416 
   417 abbreviation single_valuedP :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool" where
   418   "single_valuedP r \<equiv> single_valued {(x, y). r x y}"
   419 
   420 lemma single_valuedI:
   421   "ALL x y. (x,y):r --> (ALL z. (x,z):r --> y=z) ==> single_valued r"
   422   by (unfold single_valued_def)
   423 
   424 lemma single_valuedD:
   425   "single_valued r ==> (x, y) : r ==> (x, z) : r ==> y = z"
   426   by (simp add: single_valued_def)
   427 
   428 lemma single_valued_subset:
   429   "r \<subseteq> s ==> single_valued s ==> single_valued r"
   430   by (unfold single_valued_def) blast
   431 
   432 
   433 subsection {* Relation operations *}
   434 
   435 subsubsection {* The identity relation *}
   436 
   437 definition Id :: "'a rel"
   438 where
   439   "Id = {p. \<exists>x. p = (x, x)}"
   440 
   441 lemma IdI [intro]: "(a, a) : Id"
   442   by (simp add: Id_def)
   443 
   444 lemma IdE [elim!]: "p : Id ==> (!!x. p = (x, x) ==> P) ==> P"
   445   by (unfold Id_def) (iprover elim: CollectE)
   446 
   447 lemma pair_in_Id_conv [iff]: "((a, b) : Id) = (a = b)"
   448   by (unfold Id_def) blast
   449 
   450 lemma refl_Id: "refl Id"
   451   by (simp add: refl_on_def)
   452 
   453 lemma antisym_Id: "antisym Id"
   454   -- {* A strange result, since @{text Id} is also symmetric. *}
   455   by (simp add: antisym_def)
   456 
   457 lemma sym_Id: "sym Id"
   458   by (simp add: sym_def)
   459 
   460 lemma trans_Id: "trans Id"
   461   by (simp add: trans_def)
   462 
   463 lemma single_valued_Id [simp]: "single_valued Id"
   464   by (unfold single_valued_def) blast
   465 
   466 lemma irrefl_diff_Id [simp]: "irrefl (r - Id)"
   467   by (simp add:irrefl_def)
   468 
   469 lemma trans_diff_Id: "trans r \<Longrightarrow> antisym r \<Longrightarrow> trans (r - Id)"
   470   unfolding antisym_def trans_def by blast
   471 
   472 lemma total_on_diff_Id [simp]: "total_on A (r - Id) = total_on A r"
   473   by (simp add: total_on_def)
   474 
   475 
   476 subsubsection {* Diagonal: identity over a set *}
   477 
   478 definition Id_on  :: "'a set \<Rightarrow> 'a rel"
   479 where
   480   "Id_on A = (\<Union>x\<in>A. {(x, x)})"
   481 
   482 lemma Id_on_empty [simp]: "Id_on {} = {}"
   483   by (simp add: Id_on_def) 
   484 
   485 lemma Id_on_eqI: "a = b ==> a : A ==> (a, b) : Id_on A"
   486   by (simp add: Id_on_def)
   487 
   488 lemma Id_onI [intro!,no_atp]: "a : A ==> (a, a) : Id_on A"
   489   by (rule Id_on_eqI) (rule refl)
   490 
   491 lemma Id_onE [elim!]:
   492   "c : Id_on A ==> (!!x. x : A ==> c = (x, x) ==> P) ==> P"
   493   -- {* The general elimination rule. *}
   494   by (unfold Id_on_def) (iprover elim!: UN_E singletonE)
   495 
   496 lemma Id_on_iff: "((x, y) : Id_on A) = (x = y & x : A)"
   497   by blast
   498 
   499 lemma Id_on_def' [nitpick_unfold]:
   500   "Id_on {x. A x} = Collect (\<lambda>(x, y). x = y \<and> A x)"
   501   by auto
   502 
   503 lemma Id_on_subset_Times: "Id_on A \<subseteq> A \<times> A"
   504   by blast
   505 
   506 lemma refl_on_Id_on: "refl_on A (Id_on A)"
   507   by (rule refl_onI [OF Id_on_subset_Times Id_onI])
   508 
   509 lemma antisym_Id_on [simp]: "antisym (Id_on A)"
   510   by (unfold antisym_def) blast
   511 
   512 lemma sym_Id_on [simp]: "sym (Id_on A)"
   513   by (rule symI) clarify
   514 
   515 lemma trans_Id_on [simp]: "trans (Id_on A)"
   516   by (fast intro: transI elim: transD)
   517 
   518 lemma single_valued_Id_on [simp]: "single_valued (Id_on A)"
   519   by (unfold single_valued_def) blast
   520 
   521 
   522 subsubsection {* Composition *}
   523 
   524 inductive_set rel_comp  :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'c) set \<Rightarrow> ('a \<times> 'c) set" (infixr "O" 75)
   525   for r :: "('a \<times> 'b) set" and s :: "('b \<times> 'c) set"
   526 where
   527   rel_compI [intro]: "(a, b) \<in> r \<Longrightarrow> (b, c) \<in> s \<Longrightarrow> (a, c) \<in> r O s"
   528 
   529 abbreviation pred_comp (infixr "OO" 75) where
   530   "pred_comp \<equiv> rel_compp"
   531 
   532 lemmas pred_compI = rel_compp.intros
   533 
   534 text {*
   535   For historic reasons, the elimination rules are not wholly corresponding.
   536   Feel free to consolidate this.
   537 *}
   538 
   539 inductive_cases rel_compEpair: "(a, c) \<in> r O s"
   540 inductive_cases pred_compE [elim!]: "(r OO s) a c"
   541 
   542 lemma rel_compE [elim!]: "xz \<in> r O s \<Longrightarrow>
   543   (\<And>x y z. xz = (x, z) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> (y, z) \<in> s  \<Longrightarrow> P) \<Longrightarrow> P"
   544   by (cases xz) (simp, erule rel_compEpair, iprover)
   545 
   546 lemmas pred_comp_rel_comp_eq = rel_compp_rel_comp_eq
   547 
   548 lemma R_O_Id [simp]:
   549   "R O Id = R"
   550   by fast
   551 
   552 lemma Id_O_R [simp]:
   553   "Id O R = R"
   554   by fast
   555 
   556 lemma rel_comp_empty1 [simp]:
   557   "{} O R = {}"
   558   by blast
   559 
   560 (* CANDIDATE lemma pred_comp_bot1 [simp]:
   561   ""
   562   by (fact rel_comp_empty1 [to_pred]) *)
   563 
   564 lemma rel_comp_empty2 [simp]:
   565   "R O {} = {}"
   566   by blast
   567 
   568 (* CANDIDATE lemma pred_comp_bot2 [simp]:
   569   ""
   570   by (fact rel_comp_empty2 [to_pred]) *)
   571 
   572 lemma O_assoc:
   573   "(R O S) O T = R O (S O T)"
   574   by blast
   575 
   576 lemma pred_comp_assoc:
   577   "(r OO s) OO t = r OO (s OO t)"
   578   by (fact O_assoc [to_pred])
   579 
   580 lemma trans_O_subset:
   581   "trans r \<Longrightarrow> r O r \<subseteq> r"
   582   by (unfold trans_def) blast
   583 
   584 lemma transp_pred_comp_less_eq:
   585   "transp r \<Longrightarrow> r OO r \<le> r "
   586   by (fact trans_O_subset [to_pred])
   587 
   588 lemma rel_comp_mono:
   589   "r' \<subseteq> r \<Longrightarrow> s' \<subseteq> s \<Longrightarrow> r' O s' \<subseteq> r O s"
   590   by blast
   591 
   592 lemma pred_comp_mono:
   593   "r' \<le> r \<Longrightarrow> s' \<le> s \<Longrightarrow> r' OO s' \<le> r OO s "
   594   by (fact rel_comp_mono [to_pred])
   595 
   596 lemma rel_comp_subset_Sigma:
   597   "r \<subseteq> A \<times> B \<Longrightarrow> s \<subseteq> B \<times> C \<Longrightarrow> r O s \<subseteq> A \<times> C"
   598   by blast
   599 
   600 lemma rel_comp_distrib [simp]:
   601   "R O (S \<union> T) = (R O S) \<union> (R O T)" 
   602   by auto
   603 
   604 lemma pred_comp_distrib [simp]:
   605   "R OO (S \<squnion> T) = R OO S \<squnion> R OO T"
   606   by (fact rel_comp_distrib [to_pred])
   607 
   608 lemma rel_comp_distrib2 [simp]:
   609   "(S \<union> T) O R = (S O R) \<union> (T O R)"
   610   by auto
   611 
   612 lemma pred_comp_distrib2 [simp]:
   613   "(S \<squnion> T) OO R = S OO R \<squnion> T OO R"
   614   by (fact rel_comp_distrib2 [to_pred])
   615 
   616 lemma rel_comp_UNION_distrib:
   617   "s O UNION I r = (\<Union>i\<in>I. s O r i) "
   618   by auto
   619 
   620 (* FIXME thm rel_comp_UNION_distrib [to_pred] *)
   621 
   622 lemma rel_comp_UNION_distrib2:
   623   "UNION I r O s = (\<Union>i\<in>I. r i O s) "
   624   by auto
   625 
   626 (* FIXME thm rel_comp_UNION_distrib2 [to_pred] *)
   627 
   628 lemma single_valued_rel_comp:
   629   "single_valued r \<Longrightarrow> single_valued s \<Longrightarrow> single_valued (r O s)"
   630   by (unfold single_valued_def) blast
   631 
   632 lemma rel_comp_unfold:
   633   "r O s = {(x, z). \<exists>y. (x, y) \<in> r \<and> (y, z) \<in> s}"
   634   by (auto simp add: set_eq_iff)
   635 
   636 
   637 subsubsection {* Converse *}
   638 
   639 inductive_set converse :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'a) set" ("(_^-1)" [1000] 999)
   640   for r :: "('a \<times> 'b) set"
   641 where
   642   "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r^-1"
   643 
   644 notation (xsymbols)
   645   converse  ("(_\<inverse>)" [1000] 999)
   646 
   647 notation
   648   conversep ("(_^--1)" [1000] 1000)
   649 
   650 notation (xsymbols)
   651   conversep  ("(_\<inverse>\<inverse>)" [1000] 1000)
   652 
   653 lemma converseI [sym]:
   654   "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r\<inverse>"
   655   by (fact converse.intros)
   656 
   657 lemma conversepI (* CANDIDATE [sym] *):
   658   "r a b \<Longrightarrow> r\<inverse>\<inverse> b a"
   659   by (fact conversep.intros)
   660 
   661 lemma converseD [sym]:
   662   "(a, b) \<in> r\<inverse> \<Longrightarrow> (b, a) \<in> r"
   663   by (erule converse.cases) iprover
   664 
   665 lemma conversepD (* CANDIDATE [sym] *):
   666   "r\<inverse>\<inverse> b a \<Longrightarrow> r a b"
   667   by (fact converseD [to_pred])
   668 
   669 lemma converseE [elim!]:
   670   -- {* More general than @{text converseD}, as it ``splits'' the member of the relation. *}
   671   "yx \<in> r\<inverse> \<Longrightarrow> (\<And>x y. yx = (y, x) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> P) \<Longrightarrow> P"
   672   by (cases yx) (simp, erule converse.cases, iprover)
   673 
   674 lemmas conversepE [elim!] = conversep.cases
   675 
   676 lemma converse_iff [iff]:
   677   "(a, b) \<in> r\<inverse> \<longleftrightarrow> (b, a) \<in> r"
   678   by (auto intro: converseI)
   679 
   680 lemma conversep_iff [iff]:
   681   "r\<inverse>\<inverse> a b = r b a"
   682   by (fact converse_iff [to_pred])
   683 
   684 lemma converse_converse [simp]:
   685   "(r\<inverse>)\<inverse> = r"
   686   by (simp add: set_eq_iff)
   687 
   688 lemma conversep_conversep [simp]:
   689   "(r\<inverse>\<inverse>)\<inverse>\<inverse> = r"
   690   by (fact converse_converse [to_pred])
   691 
   692 lemma converse_rel_comp: "(r O s)^-1 = s^-1 O r^-1"
   693   by blast
   694 
   695 lemma converse_pred_comp: "(r OO s)^--1 = s^--1 OO r^--1"
   696   by (iprover intro: order_antisym conversepI pred_compI
   697     elim: pred_compE dest: conversepD)
   698 
   699 lemma converse_Int: "(r \<inter> s)^-1 = r^-1 \<inter> s^-1"
   700   by blast
   701 
   702 lemma converse_meet: "(r \<sqinter> s)^--1 = r^--1 \<sqinter> s^--1"
   703   by (simp add: inf_fun_def) (iprover intro: conversepI ext dest: conversepD)
   704 
   705 lemma converse_Un: "(r \<union> s)^-1 = r^-1 \<union> s^-1"
   706   by blast
   707 
   708 lemma converse_join: "(r \<squnion> s)^--1 = r^--1 \<squnion> s^--1"
   709   by (simp add: sup_fun_def) (iprover intro: conversepI ext dest: conversepD)
   710 
   711 lemma converse_INTER: "(INTER S r)^-1 = (INT x:S. (r x)^-1)"
   712   by fast
   713 
   714 lemma converse_UNION: "(UNION S r)^-1 = (UN x:S. (r x)^-1)"
   715   by blast
   716 
   717 lemma converse_Id [simp]: "Id^-1 = Id"
   718   by blast
   719 
   720 lemma converse_Id_on [simp]: "(Id_on A)^-1 = Id_on A"
   721   by blast
   722 
   723 lemma refl_on_converse [simp]: "refl_on A (converse r) = refl_on A r"
   724   by (unfold refl_on_def) auto
   725 
   726 lemma sym_converse [simp]: "sym (converse r) = sym r"
   727   by (unfold sym_def) blast
   728 
   729 lemma antisym_converse [simp]: "antisym (converse r) = antisym r"
   730   by (unfold antisym_def) blast
   731 
   732 lemma trans_converse [simp]: "trans (converse r) = trans r"
   733   by (unfold trans_def) blast
   734 
   735 lemma sym_conv_converse_eq: "sym r = (r^-1 = r)"
   736   by (unfold sym_def) fast
   737 
   738 lemma sym_Un_converse: "sym (r \<union> r^-1)"
   739   by (unfold sym_def) blast
   740 
   741 lemma sym_Int_converse: "sym (r \<inter> r^-1)"
   742   by (unfold sym_def) blast
   743 
   744 lemma total_on_converse [simp]: "total_on A (r^-1) = total_on A r"
   745   by (auto simp: total_on_def)
   746 
   747 lemma finite_converse [iff]: "finite (r^-1) = finite r"
   748   apply (subgoal_tac "r^-1 = (%(x,y). (y,x))`r")
   749    apply simp
   750    apply (rule iffI)
   751     apply (erule finite_imageD [unfolded inj_on_def])
   752     apply (simp split add: split_split)
   753    apply (erule finite_imageI)
   754   apply (simp add: set_eq_iff image_def, auto)
   755   apply (rule bexI)
   756    prefer 2 apply assumption
   757   apply simp
   758   done
   759 
   760 lemma conversep_noteq [simp]: "(op \<noteq>)^--1 = op \<noteq>"
   761   by (auto simp add: fun_eq_iff)
   762 
   763 lemma conversep_eq [simp]: "(op =)^--1 = op ="
   764   by (auto simp add: fun_eq_iff)
   765 
   766 lemma converse_unfold:
   767   "r\<inverse> = {(y, x). (x, y) \<in> r}"
   768   by (simp add: set_eq_iff)
   769 
   770 
   771 subsubsection {* Domain, range and field *}
   772 
   773 inductive_set Domain :: "('a \<times> 'b) set \<Rightarrow> 'a set"
   774   for r :: "('a \<times> 'b) set"
   775 where
   776   DomainI [intro]: "(a, b) \<in> r \<Longrightarrow> a \<in> Domain r"
   777 
   778 abbreviation (input) "DomainP \<equiv> Domainp"
   779 
   780 lemmas DomainPI = Domainp.DomainI
   781 
   782 inductive_cases DomainE [elim!]: "a \<in> Domain r"
   783 inductive_cases DomainpE [elim!]: "Domainp r a"
   784 
   785 inductive_set Range :: "('a \<times> 'b) set \<Rightarrow> 'b set"
   786   for r :: "('a \<times> 'b) set"
   787 where
   788   RangeI [intro]: "(a, b) \<in> r \<Longrightarrow> b \<in> Range r"
   789 
   790 abbreviation (input) "RangeP \<equiv> Rangep"
   791 
   792 lemmas RangePI = Rangep.RangeI
   793 
   794 inductive_cases RangeE [elim!]: "b \<in> Range r"
   795 inductive_cases RangepE [elim!]: "Rangep r b"
   796 
   797 definition Field :: "'a rel \<Rightarrow> 'a set"
   798 where
   799   "Field r = Domain r \<union> Range r"
   800 
   801 lemma Domain_fst [code]:
   802   "Domain r = fst ` r"
   803   by force
   804 
   805 lemma Range_snd [code]:
   806   "Range r = snd ` r"
   807   by force
   808 
   809 lemma fst_eq_Domain: "fst ` R = Domain R"
   810   by force
   811 
   812 lemma snd_eq_Range: "snd ` R = Range R"
   813   by force
   814 
   815 lemma Domain_empty [simp]: "Domain {} = {}"
   816   by auto
   817 
   818 lemma Range_empty [simp]: "Range {} = {}"
   819   by auto
   820 
   821 lemma Field_empty [simp]: "Field {} = {}"
   822   by (simp add: Field_def)
   823 
   824 lemma Domain_empty_iff: "Domain r = {} \<longleftrightarrow> r = {}"
   825   by auto
   826 
   827 lemma Range_empty_iff: "Range r = {} \<longleftrightarrow> r = {}"
   828   by auto
   829 
   830 lemma Domain_insert [simp]: "Domain (insert (a, b) r) = insert a (Domain r)"
   831   by blast
   832 
   833 lemma Range_insert [simp]: "Range (insert (a, b) r) = insert b (Range r)"
   834   by blast
   835 
   836 lemma Field_insert [simp]: "Field (insert (a, b) r) = {a, b} \<union> Field r"
   837   by (auto simp add: Field_def Domain_insert Range_insert)
   838 
   839 lemma Domain_iff: "a \<in> Domain r \<longleftrightarrow> (\<exists>y. (a, y) \<in> r)"
   840   by blast
   841 
   842 lemma Range_iff: "a \<in> Range r \<longleftrightarrow> (\<exists>y. (y, a) \<in> r)"
   843   by blast
   844 
   845 lemma Domain_Id [simp]: "Domain Id = UNIV"
   846   by blast
   847 
   848 lemma Range_Id [simp]: "Range Id = UNIV"
   849   by blast
   850 
   851 lemma Domain_Id_on [simp]: "Domain (Id_on A) = A"
   852   by blast
   853 
   854 lemma Range_Id_on [simp]: "Range (Id_on A) = A"
   855   by blast
   856 
   857 lemma Domain_Un_eq: "Domain (A \<union> B) = Domain A \<union> Domain B"
   858   by blast
   859 
   860 lemma Range_Un_eq: "Range (A \<union> B) = Range A \<union> Range B"
   861   by blast
   862 
   863 lemma Field_Un [simp]: "Field (r \<union> s) = Field r \<union> Field s"
   864   by (auto simp: Field_def)
   865 
   866 lemma Domain_Int_subset: "Domain (A \<inter> B) \<subseteq> Domain A \<inter> Domain B"
   867   by blast
   868 
   869 lemma Range_Int_subset: "Range (A \<inter> B) \<subseteq> Range A \<inter> Range B"
   870   by blast
   871 
   872 lemma Domain_Diff_subset: "Domain A - Domain B \<subseteq> Domain (A - B)"
   873   by blast
   874 
   875 lemma Range_Diff_subset: "Range A - Range B \<subseteq> Range (A - B)"
   876   by blast
   877 
   878 lemma Domain_Union: "Domain (\<Union>S) = (\<Union>A\<in>S. Domain A)"
   879   by blast
   880 
   881 lemma Range_Union: "Range (\<Union>S) = (\<Union>A\<in>S. Range A)"
   882   by blast
   883 
   884 lemma Field_Union [simp]: "Field (\<Union>R) = \<Union>(Field ` R)"
   885   by (auto simp: Field_def)
   886 
   887 lemma Domain_converse [simp]: "Domain (r\<inverse>) = Range r"
   888   by auto
   889 
   890 lemma Range_converse [simp]: "Range (r\<inverse>) = Domain r"
   891   by blast
   892 
   893 lemma Field_converse [simp]: "Field (r\<inverse>) = Field r"
   894   by (auto simp: Field_def)
   895 
   896 lemma Domain_Collect_split [simp]: "Domain {(x, y). P x y} = {x. EX y. P x y}"
   897   by auto
   898 
   899 lemma Range_Collect_split [simp]: "Range {(x, y). P x y} = {y. EX x. P x y}"
   900   by auto
   901 
   902 lemma finite_Domain: "finite r \<Longrightarrow> finite (Domain r)"
   903   by (induct set: finite) (auto simp add: Domain_insert)
   904 
   905 lemma finite_Range: "finite r \<Longrightarrow> finite (Range r)"
   906   by (induct set: finite) (auto simp add: Range_insert)
   907 
   908 lemma finite_Field: "finite r \<Longrightarrow> finite (Field r)"
   909   by (simp add: Field_def finite_Domain finite_Range)
   910 
   911 lemma Domain_mono: "r \<subseteq> s \<Longrightarrow> Domain r \<subseteq> Domain s"
   912   by blast
   913 
   914 lemma Range_mono: "r \<subseteq> s \<Longrightarrow> Range r \<subseteq> Range s"
   915   by blast
   916 
   917 lemma mono_Field: "r \<subseteq> s \<Longrightarrow> Field r \<subseteq> Field s"
   918   by (auto simp: Field_def Domain_def Range_def)
   919 
   920 lemma Domain_unfold:
   921   "Domain r = {x. \<exists>y. (x, y) \<in> r}"
   922   by blast
   923 
   924 lemma Domain_dprod [simp]: "Domain (dprod r s) = uprod (Domain r) (Domain s)"
   925   by auto
   926 
   927 lemma Domain_dsum [simp]: "Domain (dsum r s) = usum (Domain r) (Domain s)"
   928   by auto
   929 
   930 
   931 subsubsection {* Image of a set under a relation *}
   932 
   933 definition Image :: "('a \<times> 'b) set \<Rightarrow> 'a set \<Rightarrow> 'b set" (infixl "``" 90)
   934 where
   935   "r `` s = {y. \<exists>x\<in>s. (x, y) \<in> r}"
   936 
   937 declare Image_def [no_atp]
   938 
   939 lemma Image_iff: "(b : r``A) = (EX x:A. (x, b) : r)"
   940   by (simp add: Image_def)
   941 
   942 lemma Image_singleton: "r``{a} = {b. (a, b) : r}"
   943   by (simp add: Image_def)
   944 
   945 lemma Image_singleton_iff [iff]: "(b : r``{a}) = ((a, b) : r)"
   946   by (rule Image_iff [THEN trans]) simp
   947 
   948 lemma ImageI [intro,no_atp]: "(a, b) : r ==> a : A ==> b : r``A"
   949   by (unfold Image_def) blast
   950 
   951 lemma ImageE [elim!]:
   952   "b : r `` A ==> (!!x. (x, b) : r ==> x : A ==> P) ==> P"
   953   by (unfold Image_def) (iprover elim!: CollectE bexE)
   954 
   955 lemma rev_ImageI: "a : A ==> (a, b) : r ==> b : r `` A"
   956   -- {* This version's more effective when we already have the required @{text a} *}
   957   by blast
   958 
   959 lemma Image_empty [simp]: "R``{} = {}"
   960   by blast
   961 
   962 lemma Image_Id [simp]: "Id `` A = A"
   963   by blast
   964 
   965 lemma Image_Id_on [simp]: "Id_on A `` B = A \<inter> B"
   966   by blast
   967 
   968 lemma Image_Int_subset: "R `` (A \<inter> B) \<subseteq> R `` A \<inter> R `` B"
   969   by blast
   970 
   971 lemma Image_Int_eq:
   972   "single_valued (converse R) ==> R `` (A \<inter> B) = R `` A \<inter> R `` B"
   973   by (simp add: single_valued_def, blast) 
   974 
   975 lemma Image_Un: "R `` (A \<union> B) = R `` A \<union> R `` B"
   976   by blast
   977 
   978 lemma Un_Image: "(R \<union> S) `` A = R `` A \<union> S `` A"
   979   by blast
   980 
   981 lemma Image_subset: "r \<subseteq> A \<times> B ==> r``C \<subseteq> B"
   982   by (iprover intro!: subsetI elim!: ImageE dest!: subsetD SigmaD2)
   983 
   984 lemma Image_eq_UN: "r``B = (\<Union>y\<in> B. r``{y})"
   985   -- {* NOT suitable for rewriting *}
   986   by blast
   987 
   988 lemma Image_mono: "r' \<subseteq> r ==> A' \<subseteq> A ==> (r' `` A') \<subseteq> (r `` A)"
   989   by blast
   990 
   991 lemma Image_UN: "(r `` (UNION A B)) = (\<Union>x\<in>A. r `` (B x))"
   992   by blast
   993 
   994 lemma Image_INT_subset: "(r `` INTER A B) \<subseteq> (\<Inter>x\<in>A. r `` (B x))"
   995   by blast
   996 
   997 text{*Converse inclusion requires some assumptions*}
   998 lemma Image_INT_eq:
   999      "[|single_valued (r\<inverse>); A\<noteq>{}|] ==> r `` INTER A B = (\<Inter>x\<in>A. r `` B x)"
  1000 apply (rule equalityI)
  1001  apply (rule Image_INT_subset) 
  1002 apply  (simp add: single_valued_def, blast)
  1003 done
  1004 
  1005 lemma Image_subset_eq: "(r``A \<subseteq> B) = (A \<subseteq> - ((r^-1) `` (-B)))"
  1006   by blast
  1007 
  1008 lemma Image_Collect_split [simp]: "{(x, y). P x y} `` A = {y. EX x:A. P x y}"
  1009   by auto
  1010 
  1011 
  1012 subsubsection {* Inverse image *}
  1013 
  1014 definition inv_image :: "'b rel \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a rel"
  1015 where
  1016   "inv_image r f = {(x, y). (f x, f y) \<in> r}"
  1017 
  1018 definition inv_imagep :: "('b \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
  1019 where
  1020   "inv_imagep r f = (\<lambda>x y. r (f x) (f y))"
  1021 
  1022 lemma [pred_set_conv]: "inv_imagep (\<lambda>x y. (x, y) \<in> r) f = (\<lambda>x y. (x, y) \<in> inv_image r f)"
  1023   by (simp add: inv_image_def inv_imagep_def)
  1024 
  1025 lemma sym_inv_image: "sym r ==> sym (inv_image r f)"
  1026   by (unfold sym_def inv_image_def) blast
  1027 
  1028 lemma trans_inv_image: "trans r ==> trans (inv_image r f)"
  1029   apply (unfold trans_def inv_image_def)
  1030   apply (simp (no_asm))
  1031   apply blast
  1032   done
  1033 
  1034 lemma in_inv_image[simp]: "((x,y) : inv_image r f) = ((f x, f y) : r)"
  1035   by (auto simp:inv_image_def)
  1036 
  1037 lemma converse_inv_image[simp]: "(inv_image R f)^-1 = inv_image (R^-1) f"
  1038   unfolding inv_image_def converse_unfold by auto
  1039 
  1040 lemma in_inv_imagep [simp]: "inv_imagep r f x y = r (f x) (f y)"
  1041   by (simp add: inv_imagep_def)
  1042 
  1043 
  1044 subsubsection {* Powerset *}
  1045 
  1046 definition Powp :: "('a \<Rightarrow> bool) \<Rightarrow> 'a set \<Rightarrow> bool"
  1047 where
  1048   "Powp A = (\<lambda>B. \<forall>x \<in> B. A x)"
  1049 
  1050 lemma Powp_Pow_eq [pred_set_conv]: "Powp (\<lambda>x. x \<in> A) = (\<lambda>x. x \<in> Pow A)"
  1051   by (auto simp add: Powp_def fun_eq_iff)
  1052 
  1053 lemmas Powp_mono [mono] = Pow_mono [to_pred]
  1054 
  1055 end
  1056