src/Pure/context.ML
author bulwahn
Tue Aug 31 08:00:53 2010 +0200 (2010-08-31)
changeset 38950 62578950e748
parent 37871 c7ce7685e087
child 39020 ac0f24f850c9
permissions -rw-r--r--
storing options for prolog code generation in the theory
     1 (*  Title:      Pure/context.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Generic theory contexts with unique identity, arbitrarily typed data,
     5 monotonic development graph and history support.  Generic proof
     6 contexts with arbitrarily typed data.
     7 
     8 Firm naming conventions:
     9    thy, thy', thy1, thy2: theory
    10    ctxt, ctxt', ctxt1, ctxt2: Proof.context
    11    context: Context.generic
    12 *)
    13 
    14 signature BASIC_CONTEXT =
    15 sig
    16   type theory
    17   type theory_ref
    18   exception THEORY of string * theory list
    19   structure Proof: sig type context end
    20   structure ProofContext:
    21   sig
    22     val theory_of: Proof.context -> theory
    23     val init_global: theory -> Proof.context
    24   end
    25 end;
    26 
    27 signature CONTEXT =
    28 sig
    29   include BASIC_CONTEXT
    30   (*theory context*)
    31   val parents_of: theory -> theory list
    32   val ancestors_of: theory -> theory list
    33   val theory_name: theory -> string
    34   val is_stale: theory -> bool
    35   val is_draft: theory -> bool
    36   val reject_draft: theory -> theory
    37   val PureN: string
    38   val display_names: theory -> string list
    39   val pretty_thy: theory -> Pretty.T
    40   val string_of_thy: theory -> string
    41   val pretty_abbrev_thy: theory -> Pretty.T
    42   val str_of_thy: theory -> string
    43   val get_theory: theory -> string -> theory
    44   val this_theory: theory -> string -> theory
    45   val deref: theory_ref -> theory
    46   val check_thy: theory -> theory_ref
    47   val eq_thy: theory * theory -> bool
    48   val subthy: theory * theory -> bool
    49   val joinable: theory * theory -> bool
    50   val merge: theory * theory -> theory
    51   val merge_refs: theory_ref * theory_ref -> theory_ref
    52   val copy_thy: theory -> theory
    53   val checkpoint_thy: theory -> theory
    54   val finish_thy: theory -> theory
    55   val begin_thy: (theory -> Pretty.pp) -> string -> theory list -> theory
    56   (*proof context*)
    57   val raw_transfer: theory -> Proof.context -> Proof.context
    58   (*generic context*)
    59   datatype generic = Theory of theory | Proof of Proof.context
    60   val cases: (theory -> 'a) -> (Proof.context -> 'a) -> generic -> 'a
    61   val mapping: (theory -> theory) -> (Proof.context -> Proof.context) -> generic -> generic
    62   val mapping_result: (theory -> 'a * theory) -> (Proof.context -> 'a * Proof.context) ->
    63     generic -> 'a * generic
    64   val the_theory: generic -> theory
    65   val the_proof: generic -> Proof.context
    66   val map_theory: (theory -> theory) -> generic -> generic
    67   val map_proof: (Proof.context -> Proof.context) -> generic -> generic
    68   val map_theory_result: (theory -> 'a * theory) -> generic -> 'a * generic
    69   val map_proof_result: (Proof.context -> 'a * Proof.context) -> generic -> 'a * generic
    70   val theory_map: (generic -> generic) -> theory -> theory
    71   val proof_map: (generic -> generic) -> Proof.context -> Proof.context
    72   val theory_of: generic -> theory  (*total*)
    73   val proof_of: generic -> Proof.context  (*total*)
    74   (*thread data*)
    75   val thread_data: unit -> generic option
    76   val the_thread_data: unit -> generic
    77   val set_thread_data: generic option -> unit
    78   val setmp_thread_data: generic option -> ('a -> 'b) -> 'a -> 'b
    79   val >> : (generic -> generic) -> unit
    80   val >>> : (generic -> 'a * generic) -> 'a
    81 end;
    82 
    83 signature PRIVATE_CONTEXT =
    84 sig
    85   include CONTEXT
    86   structure Theory_Data:
    87   sig
    88     val declare: Object.T -> (Object.T -> Object.T) ->
    89       (Pretty.pp -> Object.T * Object.T -> Object.T) -> serial
    90     val get: serial -> (Object.T -> 'a) -> theory -> 'a
    91     val put: serial -> ('a -> Object.T) -> 'a -> theory -> theory
    92   end
    93   structure Proof_Data:
    94   sig
    95     val declare: (theory -> Object.T) -> serial
    96     val get: serial -> (Object.T -> 'a) -> Proof.context -> 'a
    97     val put: serial -> ('a -> Object.T) -> 'a -> Proof.context -> Proof.context
    98   end
    99 end;
   100 
   101 structure Context: PRIVATE_CONTEXT =
   102 struct
   103 
   104 (*** theory context ***)
   105 
   106 (** theory data **)
   107 
   108 (* data kinds and access methods *)
   109 
   110 (*private copy avoids potential conflict of table exceptions*)
   111 structure Datatab = Table(type key = int val ord = int_ord);
   112 
   113 local
   114 
   115 type kind =
   116  {empty: Object.T,
   117   extend: Object.T -> Object.T,
   118   merge: Pretty.pp -> Object.T * Object.T -> Object.T};
   119 
   120 val kinds = Unsynchronized.ref (Datatab.empty: kind Datatab.table);
   121 
   122 fun invoke f k =
   123   (case Datatab.lookup (! kinds) k of
   124     SOME kind => f kind
   125   | NONE => raise Fail "Invalid theory data identifier");
   126 
   127 in
   128 
   129 fun invoke_empty k = invoke (K o #empty) k ();
   130 val invoke_extend = invoke #extend;
   131 fun invoke_merge pp = invoke (fn kind => #merge kind pp);
   132 
   133 fun declare_theory_data empty extend merge =
   134   let
   135     val k = serial ();
   136     val kind = {empty = empty, extend = extend, merge = merge};
   137     val _ = CRITICAL (fn () => Unsynchronized.change kinds (Datatab.update (k, kind)));
   138   in k end;
   139 
   140 val extend_data = Datatab.map' invoke_extend;
   141 
   142 fun merge_data pp (data1, data2) =
   143   Datatab.keys (Datatab.merge (K true) (data1, data2))
   144   |> Par_List.map (fn k =>
   145     (case (Datatab.lookup data1 k, Datatab.lookup data2 k) of
   146       (SOME x, NONE) => (k, invoke_extend k x)
   147     | (NONE, SOME y) => (k, invoke_extend k y)
   148     | (SOME x, SOME y) => (k, invoke_merge pp k (invoke_extend k x, invoke_extend k y))))
   149   |> Datatab.make;
   150 
   151 end;
   152 
   153 
   154 
   155 (** datatype theory **)
   156 
   157 datatype theory =
   158   Theory of
   159    (*identity*)
   160    {self: theory Unsynchronized.ref option,  (*dynamic self reference -- follows theory changes*)
   161     draft: bool,                  (*draft mode -- linear destructive changes*)
   162     id: serial,                   (*identifier*)
   163     ids: unit Inttab.table} *     (*cumulative identifiers of non-drafts -- symbolic body content*)
   164    (*data*)
   165    Object.T Datatab.table *       (*body content*)
   166    (*ancestry*)
   167    {parents: theory list,         (*immediate predecessors*)
   168     ancestors: theory list} *     (*all predecessors -- canonical reverse order*)
   169    (*history*)
   170    {name: string,                 (*official theory name*)
   171     stage: int};                  (*checkpoint counter*)
   172 
   173 exception THEORY of string * theory list;
   174 
   175 fun rep_theory (Theory args) = args;
   176 
   177 val identity_of = #1 o rep_theory;
   178 val data_of = #2 o rep_theory;
   179 val ancestry_of = #3 o rep_theory;
   180 val history_of = #4 o rep_theory;
   181 
   182 fun make_identity self draft id ids = {self = self, draft = draft, id = id, ids = ids};
   183 fun make_ancestry parents ancestors = {parents = parents, ancestors = ancestors};
   184 fun make_history name stage = {name = name, stage = stage};
   185 
   186 val the_self = the o #self o identity_of;
   187 val parents_of = #parents o ancestry_of;
   188 val ancestors_of = #ancestors o ancestry_of;
   189 val theory_name = #name o history_of;
   190 
   191 
   192 (* staleness *)
   193 
   194 fun eq_id (i: int, j) = i = j;
   195 
   196 fun is_stale
   197     (Theory ({self =
   198         SOME (Unsynchronized.ref (Theory ({id = id', ...}, _, _, _))), id, ...}, _, _, _)) =
   199       not (eq_id (id, id'))
   200   | is_stale (Theory ({self = NONE, ...}, _, _, _)) = true;
   201 
   202 fun vitalize (thy as Theory ({self = SOME r, ...}, _, _, _)) = (r := thy; thy)
   203   | vitalize (thy as Theory ({self = NONE, draft, id, ids}, data, ancestry, history)) =
   204       let
   205         val r = Unsynchronized.ref thy;
   206         val thy' = Theory (make_identity (SOME r) draft id ids, data, ancestry, history);
   207       in r := thy'; thy' end;
   208 
   209 
   210 (* draft mode *)
   211 
   212 val is_draft = #draft o identity_of;
   213 
   214 fun reject_draft thy =
   215   if is_draft thy then
   216     raise THEORY ("Illegal draft theory -- stable checkpoint required", [thy])
   217   else thy;
   218 
   219 
   220 (* names *)
   221 
   222 val PureN = "Pure";
   223 val draftN = "#";
   224 val finished = ~1;
   225 
   226 fun display_names thy =
   227   let
   228     val draft = if is_draft thy then [draftN] else [];
   229     val {stage, ...} = history_of thy;
   230     val name =
   231       if stage = finished then theory_name thy
   232       else theory_name thy ^ ":" ^ string_of_int stage;
   233     val ancestor_names = map theory_name (ancestors_of thy);
   234     val stale = if is_stale thy then ["!"] else [];
   235   in rev (stale @ draft @ [name] @ ancestor_names) end;
   236 
   237 val pretty_thy = Pretty.str_list "{" "}" o display_names;
   238 val string_of_thy = Pretty.string_of o pretty_thy;
   239 
   240 fun pretty_abbrev_thy thy =
   241   let
   242     val names = display_names thy;
   243     val n = length names;
   244     val abbrev = if n > 5 then "..." :: List.drop (names, n - 5) else names;
   245   in Pretty.str_list "{" "}" abbrev end;
   246 
   247 val str_of_thy = Pretty.str_of o pretty_abbrev_thy;
   248 
   249 fun get_theory thy name =
   250   if theory_name thy <> name then
   251     (case find_first (fn thy' => theory_name thy' = name) (ancestors_of thy) of
   252       SOME thy' => thy'
   253     | NONE => error ("Unknown ancestor theory " ^ quote name))
   254   else if #stage (history_of thy) = finished then thy
   255   else error ("Unfinished theory " ^ quote name);
   256 
   257 fun this_theory thy name =
   258   if theory_name thy = name then thy
   259   else get_theory thy name;
   260 
   261 
   262 (* theory references *)
   263 
   264 (*theory_ref provides a safe way to store dynamic references to a
   265   theory in external data structures -- a plain theory value would
   266   become stale as the self reference moves on*)
   267 
   268 datatype theory_ref = Theory_Ref of theory Unsynchronized.ref;
   269 
   270 fun deref (Theory_Ref (Unsynchronized.ref thy)) = thy;
   271 
   272 fun check_thy thy =  (*thread-safe version*)
   273   let val thy_ref = Theory_Ref (the_self thy) in
   274     if is_stale thy then error ("Stale theory encountered:\n" ^ string_of_thy thy)
   275     else thy_ref
   276   end;
   277 
   278 
   279 (* build ids *)
   280 
   281 fun insert_id draft id ids =
   282   if draft then ids
   283   else Inttab.update (id, ()) ids;
   284 
   285 fun merge_ids
   286     (Theory ({draft = draft1, id = id1, ids = ids1, ...}, _, _, _))
   287     (Theory ({draft = draft2, id = id2, ids = ids2, ...}, _, _, _)) =
   288   Inttab.merge (K true) (ids1, ids2)
   289   |> insert_id draft1 id1
   290   |> insert_id draft2 id2;
   291 
   292 
   293 (* equality and inclusion *)
   294 
   295 val eq_thy = eq_id o pairself (#id o identity_of);
   296 
   297 fun proper_subthy (Theory ({id, ...}, _, _, _), Theory ({ids, ...}, _, _, _)) =
   298   Inttab.defined ids id;
   299 
   300 fun subthy thys = eq_thy thys orelse proper_subthy thys;
   301 
   302 fun joinable (thy1, thy2) = subthy (thy1, thy2) orelse subthy (thy2, thy1);
   303 
   304 
   305 (* consistent ancestors *)
   306 
   307 fun extend_ancestors thy thys =
   308   if member eq_thy thys thy then
   309     raise THEORY ("Duplicate theory node", thy :: thys)
   310   else thy :: thys;
   311 
   312 fun extend_ancestors_of thy = extend_ancestors thy (ancestors_of thy);
   313 
   314 val merge_ancestors = merge (fn (thy1, thy2) =>
   315   eq_thy (thy1, thy2) orelse
   316     theory_name thy1 = theory_name thy2 andalso
   317       raise THEORY ("Inconsistent theory versions", [thy1, thy2]));
   318 
   319 
   320 (* trivial merge *)
   321 
   322 fun merge (thy1, thy2) =
   323   if eq_thy (thy1, thy2) then thy1
   324   else if proper_subthy (thy2, thy1) then thy1
   325   else if proper_subthy (thy1, thy2) then thy2
   326   else error (cat_lines ["Attempt to perform non-trivial merge of theories:",
   327     str_of_thy thy1, str_of_thy thy2]);
   328 
   329 fun merge_refs (ref1, ref2) =
   330   if ref1 = ref2 then ref1
   331   else check_thy (merge (deref ref1, deref ref2));
   332 
   333 
   334 
   335 (** build theories **)
   336 
   337 (* primitives *)
   338 
   339 local
   340   val lock = Mutex.mutex ();
   341 in
   342   fun SYNCHRONIZED e = Simple_Thread.synchronized "theory" lock e;
   343 end;
   344 
   345 fun create_thy self draft ids data ancestry history =
   346   let val identity = make_identity self draft (serial ()) ids;
   347   in vitalize (Theory (identity, data, ancestry, history)) end;
   348 
   349 fun change_thy draft' f thy =
   350   let
   351     val Theory ({self, draft, id, ids}, data, ancestry, history) = thy;
   352     val (self', data', ancestry') =
   353       if draft then (self, data, ancestry)    (*destructive change!*)
   354       else if #stage history > 0
   355       then (NONE, data, ancestry)
   356       else (NONE, extend_data data, make_ancestry [thy] (extend_ancestors_of thy));
   357     val ids' = insert_id draft id ids;
   358     val data'' = f data';
   359     val thy' = SYNCHRONIZED (fn () =>
   360       (check_thy thy; create_thy self' draft' ids' data'' ancestry' history));
   361   in thy' end;
   362 
   363 val name_thy = change_thy false I;
   364 val extend_thy = change_thy true I;
   365 val modify_thy = change_thy true;
   366 
   367 fun copy_thy thy =
   368   let
   369     val Theory ({draft, id, ids, ...}, data, ancestry, history) = thy;
   370     val ids' = insert_id draft id ids;
   371     val thy' = SYNCHRONIZED (fn () =>
   372       (check_thy thy; create_thy NONE true ids' data ancestry history));
   373   in thy' end;
   374 
   375 val pre_pure_thy = create_thy NONE true Inttab.empty
   376   Datatab.empty (make_ancestry [] []) (make_history PureN 0);
   377 
   378 
   379 (* named theory nodes *)
   380 
   381 fun merge_thys pp (thy1, thy2) =
   382   let
   383     val ids = merge_ids thy1 thy2;
   384     val data = merge_data (pp thy1) (data_of thy1, data_of thy2);
   385     val ancestry = make_ancestry [] [];
   386     val history = make_history "" 0;
   387     val thy' = SYNCHRONIZED (fn () =>
   388      (check_thy thy1; check_thy thy2; create_thy NONE true ids data ancestry history));
   389   in thy' end;
   390 
   391 fun maximal_thys thys =
   392   thys |> filter_out (fn thy => exists (fn thy' => proper_subthy (thy, thy')) thys);
   393 
   394 fun begin_thy pp name imports =
   395   if name = "" orelse name = draftN then error ("Bad theory name: " ^ quote name)
   396   else
   397     let
   398       val parents = maximal_thys (distinct eq_thy imports);
   399       val ancestors =
   400         Library.foldl merge_ancestors ([], map ancestors_of parents)
   401         |> fold extend_ancestors parents;
   402 
   403       val Theory ({ids, ...}, data, _, _) =
   404         (case parents of
   405           [] => error "No parent theories"
   406         | [thy] => extend_thy thy
   407         | thy :: thys => Library.foldl (merge_thys pp) (thy, thys));
   408 
   409       val ancestry = make_ancestry parents ancestors;
   410       val history = make_history name 0;
   411       val thy' = SYNCHRONIZED (fn () =>
   412         (map check_thy imports; create_thy NONE true ids data ancestry history));
   413     in thy' end;
   414 
   415 
   416 (* history stages *)
   417 
   418 fun history_stage f thy =
   419   let
   420     val {name, stage} = history_of thy;
   421     val _ = stage = finished andalso raise THEORY ("Theory already finished", [thy]);
   422     val history' = make_history name (f stage);
   423     val thy' as Theory (identity', data', ancestry', _) = name_thy thy;
   424     val thy'' = SYNCHRONIZED (fn () =>
   425       (check_thy thy'; vitalize (Theory (identity', data', ancestry', history'))));
   426   in thy'' end;
   427 
   428 fun checkpoint_thy thy =
   429   if is_draft thy then history_stage (fn stage => stage + 1) thy
   430   else thy;
   431 
   432 val finish_thy = history_stage (fn _ => finished);
   433 
   434 
   435 (* theory data *)
   436 
   437 structure Theory_Data =
   438 struct
   439 
   440 val declare = declare_theory_data;
   441 
   442 fun get k dest thy =
   443   (case Datatab.lookup (data_of thy) k of
   444     SOME x => x
   445   | NONE => invoke_empty k) |> dest;
   446 
   447 fun put k mk x = modify_thy (Datatab.update (k, mk x));
   448 
   449 end;
   450 
   451 
   452 
   453 (*** proof context ***)
   454 
   455 (* datatype Proof.context *)
   456 
   457 structure Proof =
   458 struct
   459   datatype context = Context of Object.T Datatab.table * theory_ref;
   460 end;
   461 
   462 fun theory_of_proof (Proof.Context (_, thy_ref)) = deref thy_ref;
   463 fun data_of_proof (Proof.Context (data, _)) = data;
   464 fun map_prf f (Proof.Context (data, thy_ref)) = Proof.Context (f data, thy_ref);
   465 
   466 
   467 (* proof data kinds *)
   468 
   469 local
   470 
   471 val kinds = Unsynchronized.ref (Datatab.empty: (theory -> Object.T) Datatab.table);
   472 
   473 fun invoke_init k =
   474   (case Datatab.lookup (! kinds) k of
   475     SOME init => init
   476   | NONE => raise Fail "Invalid proof data identifier");
   477 
   478 fun init_data thy =
   479   Datatab.map' (fn k => fn _ => invoke_init k thy) (! kinds);
   480 
   481 fun init_new_data data thy =
   482   Datatab.merge (K true) (data, init_data thy);
   483 
   484 in
   485 
   486 fun raw_transfer thy' (Proof.Context (data, thy_ref)) =
   487   let
   488     val thy = deref thy_ref;
   489     val _ = subthy (thy, thy') orelse error "transfer proof context: not a super theory";
   490     val _ = check_thy thy;
   491     val data' = init_new_data data thy';
   492     val thy_ref' = check_thy thy';
   493   in Proof.Context (data', thy_ref') end;
   494 
   495 structure ProofContext =
   496 struct
   497   val theory_of = theory_of_proof;
   498   fun init_global thy = Proof.Context (init_data thy, check_thy thy);
   499 end;
   500 
   501 structure Proof_Data =
   502 struct
   503 
   504 fun declare init =
   505   let
   506     val k = serial ();
   507     val _ = CRITICAL (fn () => Unsynchronized.change kinds (Datatab.update (k, init)));
   508   in k end;
   509 
   510 fun get k dest prf =
   511   dest (case Datatab.lookup (data_of_proof prf) k of
   512     SOME x => x
   513   | NONE => invoke_init k (ProofContext.theory_of prf));   (*adhoc value*)
   514 
   515 fun put k mk x = map_prf (Datatab.update (k, mk x));
   516 
   517 end;
   518 
   519 end;
   520 
   521 
   522 
   523 (*** generic context ***)
   524 
   525 datatype generic = Theory of theory | Proof of Proof.context;
   526 
   527 fun cases f _ (Theory thy) = f thy
   528   | cases _ g (Proof prf) = g prf;
   529 
   530 fun mapping f g = cases (Theory o f) (Proof o g);
   531 fun mapping_result f g = cases (apsnd Theory o f) (apsnd Proof o g);
   532 
   533 val the_theory = cases I (fn _ => error "Ill-typed context: theory expected");
   534 val the_proof = cases (fn _ => error "Ill-typed context: proof expected") I;
   535 
   536 fun map_theory f = Theory o f o the_theory;
   537 fun map_proof f = Proof o f o the_proof;
   538 
   539 fun map_theory_result f = apsnd Theory o f o the_theory;
   540 fun map_proof_result f = apsnd Proof o f o the_proof;
   541 
   542 fun theory_map f = the_theory o f o Theory;
   543 fun proof_map f = the_proof o f o Proof;
   544 
   545 val theory_of = cases I ProofContext.theory_of;
   546 val proof_of = cases ProofContext.init_global I;
   547 
   548 
   549 
   550 (** thread data **)
   551 
   552 local val tag = Universal.tag () : generic option Universal.tag in
   553 
   554 fun thread_data () =
   555   (case Thread.getLocal tag of
   556     SOME (SOME context) => SOME context
   557   | _ => NONE);
   558 
   559 fun the_thread_data () =
   560   (case thread_data () of
   561     SOME context => context
   562   | _ => error "Unknown context");
   563 
   564 fun set_thread_data context = Thread.setLocal (tag, context);
   565 fun setmp_thread_data context = Library.setmp_thread_data tag (thread_data ()) context;
   566 
   567 end;
   568 
   569 fun >>> f =
   570   let
   571     val (res, context') = f (the_thread_data ());
   572     val _ = set_thread_data (SOME context');
   573   in res end;
   574 
   575 nonfix >>;
   576 fun >> f = >>> (fn context => ((), f context));
   577 
   578 val _ = set_thread_data (SOME (Theory pre_pure_thy));
   579 
   580 end;
   581 
   582 structure Basic_Context: BASIC_CONTEXT = Context;
   583 open Basic_Context;
   584 
   585 
   586 
   587 (*** type-safe interfaces for data declarations ***)
   588 
   589 (** theory data **)
   590 
   591 signature THEORY_DATA_PP_ARGS =
   592 sig
   593   type T
   594   val empty: T
   595   val extend: T -> T
   596   val merge: Pretty.pp -> T * T -> T
   597 end;
   598 
   599 signature THEORY_DATA_ARGS =
   600 sig
   601   type T
   602   val empty: T
   603   val extend: T -> T
   604   val merge: T * T -> T
   605 end;
   606 
   607 signature THEORY_DATA =
   608 sig
   609   type T
   610   val get: theory -> T
   611   val put: T -> theory -> theory
   612   val map: (T -> T) -> theory -> theory
   613 end;
   614 
   615 functor Theory_Data_PP(Data: THEORY_DATA_PP_ARGS): THEORY_DATA =
   616 struct
   617 
   618 type T = Data.T;
   619 exception Data of T;
   620 
   621 val kind = Context.Theory_Data.declare
   622   (Data Data.empty)
   623   (fn Data x => Data (Data.extend x))
   624   (fn pp => fn (Data x1, Data x2) => Data (Data.merge pp (x1, x2)));
   625 
   626 val get = Context.Theory_Data.get kind (fn Data x => x);
   627 val put = Context.Theory_Data.put kind Data;
   628 fun map f thy = put (f (get thy)) thy;
   629 
   630 end;
   631 
   632 functor Theory_Data(Data: THEORY_DATA_ARGS): THEORY_DATA =
   633   Theory_Data_PP
   634   (
   635     type T = Data.T;
   636     val empty = Data.empty;
   637     val extend = Data.extend;
   638     fun merge _ = Data.merge;
   639   );
   640 
   641 
   642 
   643 (** proof data **)
   644 
   645 signature PROOF_DATA_ARGS =
   646 sig
   647   type T
   648   val init: theory -> T
   649 end;
   650 
   651 signature PROOF_DATA =
   652 sig
   653   type T
   654   val get: Proof.context -> T
   655   val put: T -> Proof.context -> Proof.context
   656   val map: (T -> T) -> Proof.context -> Proof.context
   657 end;
   658 
   659 functor Proof_Data(Data: PROOF_DATA_ARGS): PROOF_DATA =
   660 struct
   661 
   662 type T = Data.T;
   663 exception Data of T;
   664 
   665 val kind = Context.Proof_Data.declare (Data o Data.init);
   666 
   667 val get = Context.Proof_Data.get kind (fn Data x => x);
   668 val put = Context.Proof_Data.put kind Data;
   669 fun map f prf = put (f (get prf)) prf;
   670 
   671 end;
   672 
   673 
   674 
   675 (** generic data **)
   676 
   677 signature GENERIC_DATA_ARGS =
   678 sig
   679   type T
   680   val empty: T
   681   val extend: T -> T
   682   val merge: T * T -> T
   683 end;
   684 
   685 signature GENERIC_DATA =
   686 sig
   687   type T
   688   val get: Context.generic -> T
   689   val put: T -> Context.generic -> Context.generic
   690   val map: (T -> T) -> Context.generic -> Context.generic
   691 end;
   692 
   693 functor Generic_Data(Data: GENERIC_DATA_ARGS): GENERIC_DATA =
   694 struct
   695 
   696 structure Thy_Data = Theory_Data(Data);
   697 structure Prf_Data = Proof_Data(type T = Data.T val init = Thy_Data.get);
   698 
   699 type T = Data.T;
   700 
   701 fun get (Context.Theory thy) = Thy_Data.get thy
   702   | get (Context.Proof prf) = Prf_Data.get prf;
   703 
   704 fun put x (Context.Theory thy) = Context.Theory (Thy_Data.put x thy)
   705   | put x (Context.Proof prf) = Context.Proof (Prf_Data.put x prf);
   706 
   707 fun map f ctxt = put (f (get ctxt)) ctxt;
   708 
   709 end;
   710 
   711 (*hide private interface*)
   712 structure Context: CONTEXT = Context;
   713