src/Pure/goal.ML
author bulwahn
Tue Aug 31 08:00:53 2010 +0200 (2010-08-31)
changeset 38950 62578950e748
parent 38236 d8c7be27e01d
child 38875 c7a66b584147
permissions -rw-r--r--
storing options for prolog code generation in the theory
     1 (*  Title:      Pure/goal.ML
     2     Author:     Makarius
     3 
     4 Goals in tactical theorem proving.
     5 *)
     6 
     7 signature BASIC_GOAL =
     8 sig
     9   val parallel_proofs: int Unsynchronized.ref
    10   val SELECT_GOAL: tactic -> int -> tactic
    11   val CONJUNCTS: tactic -> int -> tactic
    12   val PRECISE_CONJUNCTS: int -> tactic -> int -> tactic
    13   val PARALLEL_CHOICE: tactic list -> tactic
    14   val PARALLEL_GOALS: tactic -> tactic
    15 end;
    16 
    17 signature GOAL =
    18 sig
    19   include BASIC_GOAL
    20   val init: cterm -> thm
    21   val protect: thm -> thm
    22   val conclude: thm -> thm
    23   val check_finished: Proof.context -> thm -> unit
    24   val finish: Proof.context -> thm -> thm
    25   val norm_result: thm -> thm
    26   val fork: (unit -> 'a) -> 'a future
    27   val future_enabled: unit -> bool
    28   val local_future_enabled: unit -> bool
    29   val future_result: Proof.context -> thm future -> term -> thm
    30   val prove_internal: cterm list -> cterm -> (thm list -> tactic) -> thm
    31   val prove_multi: Proof.context -> string list -> term list -> term list ->
    32     ({prems: thm list, context: Proof.context} -> tactic) -> thm list
    33   val prove_future: Proof.context -> string list -> term list -> term ->
    34     ({prems: thm list, context: Proof.context} -> tactic) -> thm
    35   val prove: Proof.context -> string list -> term list -> term ->
    36     ({prems: thm list, context: Proof.context} -> tactic) -> thm
    37   val prove_global: theory -> string list -> term list -> term ->
    38     ({prems: thm list, context: Proof.context} -> tactic) -> thm
    39   val extract: int -> int -> thm -> thm Seq.seq
    40   val retrofit: int -> int -> thm -> thm -> thm Seq.seq
    41   val conjunction_tac: int -> tactic
    42   val precise_conjunction_tac: int -> int -> tactic
    43   val recover_conjunction_tac: tactic
    44   val norm_hhf_tac: int -> tactic
    45   val compose_hhf_tac: thm -> int -> tactic
    46   val assume_rule_tac: Proof.context -> int -> tactic
    47 end;
    48 
    49 structure Goal: GOAL =
    50 struct
    51 
    52 (** goals **)
    53 
    54 (*
    55   -------- (init)
    56   C ==> #C
    57 *)
    58 val init =
    59   let val A = #1 (Thm.dest_implies (Thm.cprop_of Drule.protectI))
    60   in fn C => Thm.instantiate ([], [(A, C)]) Drule.protectI end;
    61 
    62 (*
    63    C
    64   --- (protect)
    65   #C
    66 *)
    67 fun protect th = Drule.comp_no_flatten (th, 0) 1 Drule.protectI;
    68 
    69 (*
    70   A ==> ... ==> #C
    71   ---------------- (conclude)
    72   A ==> ... ==> C
    73 *)
    74 fun conclude th = Drule.comp_no_flatten (th, Thm.nprems_of th) 1 Drule.protectD;
    75 
    76 (*
    77   #C
    78   --- (finish)
    79    C
    80 *)
    81 fun check_finished ctxt th =
    82   (case Thm.nprems_of th of
    83     0 => ()
    84   | n => raise THM ("Proof failed.\n" ^
    85       Pretty.string_of (Pretty.chunks
    86         (Goal_Display.pretty_goals ctxt {total = true, main = true, maxgoals = n} th)) ^
    87       "\n" ^ string_of_int n ^ " unsolved goal(s)!", 0, [th]));
    88 
    89 fun finish ctxt th = (check_finished ctxt th; conclude th);
    90 
    91 
    92 
    93 (** results **)
    94 
    95 (* normal form *)
    96 
    97 val norm_result =
    98   Drule.flexflex_unique
    99   #> MetaSimplifier.norm_hhf_protect
   100   #> Thm.strip_shyps
   101   #> Drule.zero_var_indexes;
   102 
   103 
   104 (* parallel proofs *)
   105 
   106 fun fork e = Future.fork_pri ~1 (fn () => Future.status e);
   107 
   108 val parallel_proofs = Unsynchronized.ref 1;
   109 
   110 fun future_enabled () =
   111   Multithreading.enabled () andalso Future.is_worker () andalso ! parallel_proofs >= 1;
   112 
   113 fun local_future_enabled () = future_enabled () andalso ! parallel_proofs >= 2;
   114 
   115 
   116 (* future_result *)
   117 
   118 fun future_result ctxt result prop =
   119   let
   120     val thy = ProofContext.theory_of ctxt;
   121     val _ = Context.reject_draft thy;
   122     val cert = Thm.cterm_of thy;
   123     val certT = Thm.ctyp_of thy;
   124 
   125     val assms = Assumption.all_assms_of ctxt;
   126     val As = map Thm.term_of assms;
   127 
   128     val xs = map Free (fold Term.add_frees (prop :: As) []);
   129     val fixes = map cert xs;
   130 
   131     val tfrees = fold Term.add_tfrees (prop :: As) [];
   132     val instT = map (fn (a, S) => (certT (TVar ((a, 0), S)), certT (TFree (a, S)))) tfrees;
   133 
   134     val global_prop =
   135       cert (Term.map_types Logic.varifyT_global
   136         (fold_rev Logic.all xs (Logic.list_implies (As, prop))))
   137       |> Thm.weaken_sorts (Variable.sorts_of ctxt);
   138     val global_result = result |> Future.map
   139       (Drule.flexflex_unique #>
   140         Thm.adjust_maxidx_thm ~1 #>
   141         Drule.implies_intr_list assms #>
   142         Drule.forall_intr_list fixes #>
   143         Thm.generalize (map #1 tfrees, []) 0 #>
   144         Thm.strip_shyps);
   145     val local_result =
   146       Thm.future global_result global_prop
   147       |> Thm.instantiate (instT, [])
   148       |> Drule.forall_elim_list fixes
   149       |> fold (Thm.elim_implies o Thm.assume) assms;
   150   in local_result end;
   151 
   152 
   153 
   154 (** tactical theorem proving **)
   155 
   156 (* prove_internal -- minimal checks, no normalization of result! *)
   157 
   158 fun prove_internal casms cprop tac =
   159   (case SINGLE (tac (map Assumption.assume casms)) (init cprop) of
   160     SOME th => Drule.implies_intr_list casms
   161       (finish (Syntax.init_pretty_global (Thm.theory_of_thm th)) th)
   162   | NONE => error "Tactic failed.");
   163 
   164 
   165 (* prove_common etc. *)
   166 
   167 fun prove_common immediate ctxt xs asms props tac =
   168   let
   169     val thy = ProofContext.theory_of ctxt;
   170     val string_of_term = Syntax.string_of_term ctxt;
   171 
   172     val pos = Position.thread_data ();
   173     fun err msg = cat_error msg
   174       ("The error(s) above occurred for the goal statement:\n" ^
   175         string_of_term (Logic.list_implies (asms, Logic.mk_conjunction_list props)) ^
   176         (case Position.str_of pos of "" => "" | s => "\n" ^ s));
   177 
   178     fun cert_safe t = Thm.cterm_of thy (Envir.beta_norm (Term.no_dummy_patterns t))
   179       handle TERM (msg, _) => err msg | TYPE (msg, _, _) => err msg;
   180     val casms = map cert_safe asms;
   181     val cprops = map cert_safe props;
   182 
   183     val (prems, ctxt') = ctxt
   184       |> Variable.add_fixes_direct xs
   185       |> fold Variable.declare_term (asms @ props)
   186       |> Assumption.add_assumes casms
   187       ||> Variable.set_body true;
   188     val sorts = Variable.sorts_of ctxt';
   189 
   190     val stmt = Thm.weaken_sorts sorts (Conjunction.mk_conjunction_balanced cprops);
   191 
   192     fun result () =
   193       (case SINGLE (tac {prems = prems, context = ctxt'}) (init stmt) of
   194         NONE => err "Tactic failed."
   195       | SOME st =>
   196           let val res = finish ctxt' st handle THM (msg, _, _) => err msg in
   197             if Unify.matches_list thy [Thm.term_of stmt] [Thm.prop_of res]
   198             then Thm.check_shyps sorts res
   199             else err ("Proved a different theorem: " ^ string_of_term (Thm.prop_of res))
   200           end);
   201     val res =
   202       if immediate orelse #maxidx (Thm.rep_cterm stmt) >= 0 orelse not (future_enabled ())
   203       then result ()
   204       else future_result ctxt' (fork result) (Thm.term_of stmt);
   205   in
   206     Conjunction.elim_balanced (length props) res
   207     |> map (Assumption.export false ctxt' ctxt)
   208     |> Variable.export ctxt' ctxt
   209     |> map Drule.zero_var_indexes
   210   end;
   211 
   212 val prove_multi = prove_common true;
   213 
   214 fun prove_future ctxt xs asms prop tac = hd (prove_common false ctxt xs asms [prop] tac);
   215 fun prove ctxt xs asms prop tac = hd (prove_common true ctxt xs asms [prop] tac);
   216 
   217 fun prove_global thy xs asms prop tac =
   218   Drule.export_without_context (prove (ProofContext.init_global thy) xs asms prop tac);
   219 
   220 
   221 
   222 (** goal structure **)
   223 
   224 (* nested goals *)
   225 
   226 fun extract i n st =
   227   (if i < 1 orelse n < 1 orelse i + n - 1 > Thm.nprems_of st then Seq.empty
   228    else if n = 1 then Seq.single (Thm.cprem_of st i)
   229    else
   230      Seq.single (Conjunction.mk_conjunction_balanced (map (Thm.cprem_of st) (i upto i + n - 1))))
   231   |> Seq.map (Thm.adjust_maxidx_cterm ~1 #> init);
   232 
   233 fun retrofit i n st' st =
   234   (if n = 1 then st
   235    else st |> Drule.with_subgoal i (Conjunction.uncurry_balanced n))
   236   |> Thm.compose_no_flatten false (conclude st', Thm.nprems_of st') i;
   237 
   238 fun SELECT_GOAL tac i st =
   239   if Thm.nprems_of st = 1 andalso i = 1 then tac st
   240   else Seq.lifts (retrofit i 1) (Seq.maps tac (extract i 1 st)) st;
   241 
   242 
   243 (* multiple goals *)
   244 
   245 fun precise_conjunction_tac 0 i = eq_assume_tac i
   246   | precise_conjunction_tac 1 i = SUBGOAL (K all_tac) i
   247   | precise_conjunction_tac n i = PRIMITIVE (Drule.with_subgoal i (Conjunction.curry_balanced n));
   248 
   249 val adhoc_conjunction_tac = REPEAT_ALL_NEW
   250   (SUBGOAL (fn (goal, i) =>
   251     if can Logic.dest_conjunction goal then rtac Conjunction.conjunctionI i
   252     else no_tac));
   253 
   254 val conjunction_tac = SUBGOAL (fn (goal, i) =>
   255   precise_conjunction_tac (length (Logic.dest_conjunctions goal)) i ORELSE
   256   TRY (adhoc_conjunction_tac i));
   257 
   258 val recover_conjunction_tac = PRIMITIVE (fn th =>
   259   Conjunction.uncurry_balanced (Thm.nprems_of th) th);
   260 
   261 fun PRECISE_CONJUNCTS n tac =
   262   SELECT_GOAL (precise_conjunction_tac n 1
   263     THEN tac
   264     THEN recover_conjunction_tac);
   265 
   266 fun CONJUNCTS tac =
   267   SELECT_GOAL (conjunction_tac 1
   268     THEN tac
   269     THEN recover_conjunction_tac);
   270 
   271 
   272 (* hhf normal form *)
   273 
   274 val norm_hhf_tac =
   275   rtac Drule.asm_rl  (*cheap approximation -- thanks to builtin Logic.flatten_params*)
   276   THEN' SUBGOAL (fn (t, i) =>
   277     if Drule.is_norm_hhf t then all_tac
   278     else MetaSimplifier.rewrite_goal_tac Drule.norm_hhf_eqs i);
   279 
   280 fun compose_hhf_tac th i st =
   281   PRIMSEQ (Thm.bicompose false (false, Drule.lift_all (Thm.cprem_of st i) th, 0) i) st;
   282 
   283 
   284 (* non-atomic goal assumptions *)
   285 
   286 fun non_atomic (Const ("==>", _) $ _ $ _) = true
   287   | non_atomic (Const ("all", _) $ _) = true
   288   | non_atomic _ = false;
   289 
   290 fun assume_rule_tac ctxt = norm_hhf_tac THEN' CSUBGOAL (fn (goal, i) =>
   291   let
   292     val ((_, goal'), ctxt') = Variable.focus goal ctxt;
   293     val goal'' = Drule.cterm_rule (singleton (Variable.export ctxt' ctxt)) goal';
   294     val Rs = filter (non_atomic o Thm.term_of) (Drule.strip_imp_prems goal'');
   295     val tacs = Rs |> map (fn R =>
   296       Tactic.etac (MetaSimplifier.norm_hhf (Thm.trivial R)) THEN_ALL_NEW assume_tac);
   297   in fold_rev (curry op APPEND') tacs (K no_tac) i end);
   298 
   299 
   300 (* parallel tacticals *)
   301 
   302 (*parallel choice of single results*)
   303 fun PARALLEL_CHOICE tacs st =
   304   (case Par_List.get_some (fn tac => SINGLE tac st) tacs of
   305     NONE => Seq.empty
   306   | SOME st' => Seq.single st');
   307 
   308 (*parallel refinement of non-schematic goal by single results*)
   309 exception FAILED of unit;
   310 fun PARALLEL_GOALS tac st =
   311   let
   312     val st0 = Thm.adjust_maxidx_thm ~1 st;
   313     val _ = Thm.maxidx_of st0 >= 0 andalso
   314       raise THM ("PARALLEL_GOALS: schematic goal state", 0, [st]);
   315 
   316     fun try_tac g =
   317       (case SINGLE tac g of
   318         NONE => raise FAILED ()
   319       | SOME g' => g');
   320 
   321     val goals = Drule.strip_imp_prems (Thm.cprop_of st0);
   322     val results = Par_List.map (try_tac o init) goals;
   323   in ALLGOALS (fn i => retrofit i 1 (nth results (i - 1))) st0 end
   324   handle FAILED () => Seq.empty;
   325 
   326 end;
   327 
   328 structure Basic_Goal: BASIC_GOAL = Goal;
   329 open Basic_Goal;