src/Pure/tactic.ML
author bulwahn
Tue Aug 31 08:00:53 2010 +0200 (2010-08-31)
changeset 38950 62578950e748
parent 36944 dbf831a50e4a
child 42290 b1f544c84040
permissions -rw-r--r--
storing options for prolog code generation in the theory
     1 (*  Title:      Pure/tactic.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3 
     4 Fundamental tactics.
     5 *)
     6 
     7 signature BASIC_TACTIC =
     8 sig
     9   val trace_goalno_tac: (int -> tactic) -> int -> tactic
    10   val rule_by_tactic: Proof.context -> tactic -> thm -> thm
    11   val assume_tac: int -> tactic
    12   val eq_assume_tac: int -> tactic
    13   val compose_tac: (bool * thm * int) -> int -> tactic
    14   val make_elim: thm -> thm
    15   val biresolve_tac: (bool * thm) list -> int -> tactic
    16   val resolve_tac: thm list -> int -> tactic
    17   val eresolve_tac: thm list -> int -> tactic
    18   val forward_tac: thm list -> int -> tactic
    19   val dresolve_tac: thm list -> int -> tactic
    20   val atac: int -> tactic
    21   val rtac: thm -> int -> tactic
    22   val dtac: thm -> int -> tactic
    23   val etac: thm -> int -> tactic
    24   val ftac: thm -> int -> tactic
    25   val datac: thm -> int -> int -> tactic
    26   val eatac: thm -> int -> int -> tactic
    27   val fatac: thm -> int -> int -> tactic
    28   val ares_tac: thm list -> int -> tactic
    29   val solve_tac: thm list -> int -> tactic
    30   val bimatch_tac: (bool * thm) list -> int -> tactic
    31   val match_tac: thm list -> int -> tactic
    32   val ematch_tac: thm list -> int -> tactic
    33   val dmatch_tac: thm list -> int -> tactic
    34   val flexflex_tac: tactic
    35   val distinct_subgoal_tac: int -> tactic
    36   val distinct_subgoals_tac: tactic
    37   val metacut_tac: thm -> int -> tactic
    38   val cut_rules_tac: thm list -> int -> tactic
    39   val cut_facts_tac: thm list -> int -> tactic
    40   val filter_thms: (term * term -> bool) -> int * term * thm list -> thm list
    41   val biresolution_from_nets_tac: ('a list -> (bool * thm) list) ->
    42     bool -> 'a Net.net * 'a Net.net -> int -> tactic
    43   val biresolve_from_nets_tac: (int * (bool * thm)) Net.net * (int * (bool * thm)) Net.net ->
    44     int -> tactic
    45   val bimatch_from_nets_tac: (int * (bool * thm)) Net.net * (int * (bool * thm)) Net.net ->
    46     int -> tactic
    47   val net_biresolve_tac: (bool * thm) list -> int -> tactic
    48   val net_bimatch_tac: (bool * thm) list -> int -> tactic
    49   val filt_resolve_tac: thm list -> int -> int -> tactic
    50   val resolve_from_net_tac: (int * thm) Net.net -> int -> tactic
    51   val match_from_net_tac: (int * thm) Net.net -> int -> tactic
    52   val net_resolve_tac: thm list -> int -> tactic
    53   val net_match_tac: thm list -> int -> tactic
    54   val subgoals_of_brl: bool * thm -> int
    55   val lessb: (bool * thm) * (bool * thm) -> bool
    56   val rename_tac: string list -> int -> tactic
    57   val rotate_tac: int -> int -> tactic
    58   val defer_tac: int -> tactic
    59   val filter_prems_tac: (term -> bool) -> int -> tactic
    60 end;
    61 
    62 signature TACTIC =
    63 sig
    64   include BASIC_TACTIC
    65   val innermost_params: int -> thm -> (string * typ) list
    66   val insert_tagged_brl: 'a * (bool * thm) ->
    67     ('a * (bool * thm)) Net.net * ('a * (bool * thm)) Net.net ->
    68       ('a * (bool * thm)) Net.net * ('a * (bool * thm)) Net.net
    69   val build_netpair: (int * (bool * thm)) Net.net * (int * (bool * thm)) Net.net ->
    70     (bool * thm) list -> (int * (bool * thm)) Net.net * (int * (bool * thm)) Net.net
    71   val delete_tagged_brl: bool * thm ->
    72     ('a * (bool * thm)) Net.net * ('a * (bool * thm)) Net.net ->
    73       ('a * (bool * thm)) Net.net * ('a * (bool * thm)) Net.net
    74   val eq_kbrl: ('a * (bool * thm)) * ('a * (bool * thm)) -> bool
    75   val build_net: thm list -> (int * thm) Net.net
    76 end;
    77 
    78 structure Tactic: TACTIC =
    79 struct
    80 
    81 (*Discover which goal is chosen:  SOMEGOAL(trace_goalno_tac tac) *)
    82 fun trace_goalno_tac tac i st =
    83     case Seq.pull(tac i st) of
    84         NONE    => Seq.empty
    85       | seqcell => (tracing ("Subgoal " ^ string_of_int i ^ " selected");
    86                          Seq.make(fn()=> seqcell));
    87 
    88 (*Makes a rule by applying a tactic to an existing rule*)
    89 fun rule_by_tactic ctxt tac rl =
    90   let
    91     val ctxt' = Variable.declare_thm rl ctxt;
    92     val ((_, [st]), ctxt'') = Variable.import true [rl] ctxt';
    93   in
    94     (case Seq.pull (tac st) of
    95       NONE => raise THM ("rule_by_tactic", 0, [rl])
    96     | SOME (st', _) => zero_var_indexes (singleton (Variable.export ctxt'' ctxt') st'))
    97   end;
    98 
    99 
   100 (*** Basic tactics ***)
   101 
   102 (*** The following fail if the goal number is out of range:
   103      thus (REPEAT (resolve_tac rules i)) stops once subgoal i disappears. *)
   104 
   105 (*Solve subgoal i by assumption*)
   106 fun assume_tac i = PRIMSEQ (Thm.assumption i);
   107 
   108 (*Solve subgoal i by assumption, using no unification*)
   109 fun eq_assume_tac i = PRIMITIVE (Thm.eq_assumption i);
   110 
   111 
   112 (** Resolution/matching tactics **)
   113 
   114 (*The composition rule/state: no lifting or var renaming.
   115   The arg = (bires_flg, orule, m);  see Thm.bicompose for explanation.*)
   116 fun compose_tac arg i = PRIMSEQ (Thm.bicompose false arg i);
   117 
   118 (*Converts a "destruct" rule like P&Q==>P to an "elimination" rule
   119   like [| P&Q; P==>R |] ==> R *)
   120 fun make_elim rl = zero_var_indexes (rl RS revcut_rl);
   121 
   122 (*Attack subgoal i by resolution, using flags to indicate elimination rules*)
   123 fun biresolve_tac brules i = PRIMSEQ (Thm.biresolution false brules i);
   124 
   125 (*Resolution: the simple case, works for introduction rules*)
   126 fun resolve_tac rules = biresolve_tac (map (pair false) rules);
   127 
   128 (*Resolution with elimination rules only*)
   129 fun eresolve_tac rules = biresolve_tac (map (pair true) rules);
   130 
   131 (*Forward reasoning using destruction rules.*)
   132 fun forward_tac rls = resolve_tac (map make_elim rls) THEN' assume_tac;
   133 
   134 (*Like forward_tac, but deletes the assumption after use.*)
   135 fun dresolve_tac rls = eresolve_tac (map make_elim rls);
   136 
   137 (*Shorthand versions: for resolution with a single theorem*)
   138 val atac    =   assume_tac;
   139 fun rtac rl =  resolve_tac [rl];
   140 fun dtac rl = dresolve_tac [rl];
   141 fun etac rl = eresolve_tac [rl];
   142 fun ftac rl =  forward_tac [rl];
   143 fun datac thm j = EVERY' (dtac thm::replicate j atac);
   144 fun eatac thm j = EVERY' (etac thm::replicate j atac);
   145 fun fatac thm j = EVERY' (ftac thm::replicate j atac);
   146 
   147 (*Use an assumption or some rules ... A popular combination!*)
   148 fun ares_tac rules = assume_tac  ORELSE'  resolve_tac rules;
   149 
   150 fun solve_tac rules = resolve_tac rules THEN_ALL_NEW assume_tac;
   151 
   152 (*Matching tactics -- as above, but forbid updating of state*)
   153 fun bimatch_tac brules i = PRIMSEQ (Thm.biresolution true brules i);
   154 fun match_tac rules  = bimatch_tac (map (pair false) rules);
   155 fun ematch_tac rules = bimatch_tac (map (pair true) rules);
   156 fun dmatch_tac rls   = ematch_tac (map make_elim rls);
   157 
   158 (*Smash all flex-flex disagreement pairs in the proof state.*)
   159 val flexflex_tac = PRIMSEQ Thm.flexflex_rule;
   160 
   161 (*Remove duplicate subgoals.*)
   162 val perm_tac = PRIMITIVE oo Thm.permute_prems;
   163 
   164 fun distinct_tac (i, k) =
   165   perm_tac 0 (i - 1) THEN
   166   perm_tac 1 (k - 1) THEN
   167   DETERM (PRIMSEQ (fn st =>
   168     Thm.compose_no_flatten false (st, 0) 1
   169       (Drule.incr_indexes st Drule.distinct_prems_rl))) THEN
   170   perm_tac 1 (1 - k) THEN
   171   perm_tac 0 (1 - i);
   172 
   173 fun distinct_subgoal_tac i st =
   174   (case drop (i - 1) (Thm.prems_of st) of
   175     [] => no_tac st
   176   | A :: Bs =>
   177       st |> EVERY (fold (fn (B, k) =>
   178         if A aconv B then cons (distinct_tac (i, k)) else I) (Bs ~~ (1 upto length Bs)) []));
   179 
   180 fun distinct_subgoals_tac state =
   181   let
   182     val goals = Thm.prems_of state;
   183     val dups = distinct (eq_fst (op aconv)) (goals ~~ (1 upto length goals));
   184   in EVERY (rev (map (distinct_subgoal_tac o snd) dups)) state end;
   185 
   186 (*Determine print names of goal parameters (reversed)*)
   187 fun innermost_params i st =
   188   let val (_, _, Bi, _) = Thm.dest_state (st, i)
   189   in Term.rename_wrt_term Bi (Logic.strip_params Bi) end;
   190 
   191 
   192 (*** Applications of cut_rl ***)
   193 
   194 (*The conclusion of the rule gets assumed in subgoal i,
   195   while subgoal i+1,... are the premises of the rule.*)
   196 fun metacut_tac rule i = resolve_tac [cut_rl] i  THEN  biresolve_tac [(false, rule)] (i+1);
   197 
   198 (*"Cut" a list of rules into the goal.  Their premises will become new
   199   subgoals.*)
   200 fun cut_rules_tac ths i = EVERY (map (fn th => metacut_tac th i) ths);
   201 
   202 (*As above, but inserts only facts (unconditional theorems);
   203   generates no additional subgoals. *)
   204 fun cut_facts_tac ths = cut_rules_tac (filter Thm.no_prems ths);
   205 
   206 
   207 (**** Indexing and filtering of theorems ****)
   208 
   209 (*Returns the list of potentially resolvable theorems for the goal "prem",
   210         using the predicate  could(subgoal,concl).
   211   Resulting list is no longer than "limit"*)
   212 fun filter_thms could (limit, prem, ths) =
   213   let val pb = Logic.strip_assums_concl prem;   (*delete assumptions*)
   214       fun filtr (limit, []) = []
   215         | filtr (limit, th::ths) =
   216             if limit=0 then  []
   217             else if could(pb, concl_of th)  then th :: filtr(limit-1, ths)
   218             else filtr(limit,ths)
   219   in  filtr(limit,ths)  end;
   220 
   221 
   222 (*** biresolution and resolution using nets ***)
   223 
   224 (** To preserve the order of the rules, tag them with increasing integers **)
   225 
   226 (*insert one tagged brl into the pair of nets*)
   227 fun insert_tagged_brl (kbrl as (k, (eres, th))) (inet, enet) =
   228   if eres then
   229     (case try Thm.major_prem_of th of
   230       SOME prem => (inet, Net.insert_term (K false) (prem, kbrl) enet)
   231     | NONE => error "insert_tagged_brl: elimination rule with no premises")
   232   else (Net.insert_term (K false) (concl_of th, kbrl) inet, enet);
   233 
   234 (*build a pair of nets for biresolution*)
   235 fun build_netpair netpair brls =
   236     fold_rev insert_tagged_brl (tag_list 1 brls) netpair;
   237 
   238 (*delete one kbrl from the pair of nets*)
   239 fun eq_kbrl ((_, (_, th)), (_, (_, th'))) = Thm.eq_thm_prop (th, th')
   240 
   241 fun delete_tagged_brl (brl as (eres, th)) (inet, enet) =
   242   (if eres then
   243     (case try Thm.major_prem_of th of
   244       SOME prem => (inet, Net.delete_term eq_kbrl (prem, ((), brl)) enet)
   245     | NONE => (inet, enet))  (*no major premise: ignore*)
   246   else (Net.delete_term eq_kbrl (Thm.concl_of th, ((), brl)) inet, enet))
   247   handle Net.DELETE => (inet,enet);
   248 
   249 
   250 (*biresolution using a pair of nets rather than rules.
   251     function "order" must sort and possibly filter the list of brls.
   252     boolean "match" indicates matching or unification.*)
   253 fun biresolution_from_nets_tac order match (inet,enet) =
   254   SUBGOAL
   255     (fn (prem,i) =>
   256       let val hyps = Logic.strip_assums_hyp prem
   257           and concl = Logic.strip_assums_concl prem
   258           val kbrls = Net.unify_term inet concl @ maps (Net.unify_term enet) hyps
   259       in PRIMSEQ (Thm.biresolution match (order kbrls) i) end);
   260 
   261 (*versions taking pre-built nets.  No filtering of brls*)
   262 val biresolve_from_nets_tac = biresolution_from_nets_tac order_list false;
   263 val bimatch_from_nets_tac   = biresolution_from_nets_tac order_list true;
   264 
   265 (*fast versions using nets internally*)
   266 val net_biresolve_tac =
   267     biresolve_from_nets_tac o build_netpair(Net.empty,Net.empty);
   268 
   269 val net_bimatch_tac =
   270     bimatch_from_nets_tac o build_netpair(Net.empty,Net.empty);
   271 
   272 (*** Simpler version for resolve_tac -- only one net, and no hyps ***)
   273 
   274 (*insert one tagged rl into the net*)
   275 fun insert_krl (krl as (k,th)) =
   276   Net.insert_term (K false) (concl_of th, krl);
   277 
   278 (*build a net of rules for resolution*)
   279 fun build_net rls =
   280   fold_rev insert_krl (tag_list 1 rls) Net.empty;
   281 
   282 (*resolution using a net rather than rules; pred supports filt_resolve_tac*)
   283 fun filt_resolution_from_net_tac match pred net =
   284   SUBGOAL
   285     (fn (prem,i) =>
   286       let val krls = Net.unify_term net (Logic.strip_assums_concl prem)
   287       in
   288          if pred krls
   289          then PRIMSEQ
   290                 (Thm.biresolution match (map (pair false) (order_list krls)) i)
   291          else no_tac
   292       end);
   293 
   294 (*Resolve the subgoal using the rules (making a net) unless too flexible,
   295    which means more than maxr rules are unifiable.      *)
   296 fun filt_resolve_tac rules maxr =
   297     let fun pred krls = length krls <= maxr
   298     in  filt_resolution_from_net_tac false pred (build_net rules)  end;
   299 
   300 (*versions taking pre-built nets*)
   301 val resolve_from_net_tac = filt_resolution_from_net_tac false (K true);
   302 val match_from_net_tac = filt_resolution_from_net_tac true (K true);
   303 
   304 (*fast versions using nets internally*)
   305 val net_resolve_tac = resolve_from_net_tac o build_net;
   306 val net_match_tac = match_from_net_tac o build_net;
   307 
   308 
   309 (*** For Natural Deduction using (bires_flg, rule) pairs ***)
   310 
   311 (*The number of new subgoals produced by the brule*)
   312 fun subgoals_of_brl (true,rule)  = nprems_of rule - 1
   313   | subgoals_of_brl (false,rule) = nprems_of rule;
   314 
   315 (*Less-than test: for sorting to minimize number of new subgoals*)
   316 fun lessb (brl1,brl2) = subgoals_of_brl brl1 < subgoals_of_brl brl2;
   317 
   318 
   319 (*Renaming of parameters in a subgoal*)
   320 fun rename_tac xs i =
   321   case Library.find_first (not o Syntax.is_identifier) xs of
   322       SOME x => error ("Not an identifier: " ^ x)
   323     | NONE => PRIMITIVE (Thm.rename_params_rule (xs, i));
   324 
   325 (*rotate_tac n i: rotate the assumptions of subgoal i by n positions, from
   326   right to left if n is positive, and from left to right if n is negative.*)
   327 fun rotate_tac 0 i = all_tac
   328   | rotate_tac k i = PRIMITIVE (Thm.rotate_rule k i);
   329 
   330 (*Rotates the given subgoal to be the last.*)
   331 fun defer_tac i = PRIMITIVE (Thm.permute_prems (i - 1) 1);
   332 
   333 (* remove premises that do not satisfy p; fails if all prems satisfy p *)
   334 fun filter_prems_tac p =
   335   let fun Then NONE tac = SOME tac
   336         | Then (SOME tac) tac' = SOME(tac THEN' tac');
   337       fun thins H (tac,n) =
   338         if p H then (tac,n+1)
   339         else (Then tac (rotate_tac n THEN' etac thin_rl),0);
   340   in SUBGOAL(fn (subg,n) =>
   341        let val Hs = Logic.strip_assums_hyp subg
   342        in case fst(fold thins Hs (NONE,0)) of
   343             NONE => no_tac | SOME tac => tac n
   344        end)
   345   end;
   346 
   347 end;
   348 
   349 structure Basic_Tactic: BASIC_TACTIC = Tactic;
   350 open Basic_Tactic;