src/HOL/HOL.thy
author haftmann
Thu Jun 25 14:59:29 2009 +0200 (2009-06-25)
changeset 31804 627d142fce19
parent 31299 0c5baf034d0e
child 31902 862ae16a799d
permissions -rw-r--r--
arbitrary farewell
     1 (*  Title:      HOL/HOL.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     3 *)
     4 
     5 header {* The basis of Higher-Order Logic *}
     6 
     7 theory HOL
     8 imports Pure "~~/src/Tools/Code_Generator"
     9 uses
    10   ("Tools/hologic.ML")
    11   "~~/src/Tools/auto_solve.ML"
    12   "~~/src/Tools/IsaPlanner/zipper.ML"
    13   "~~/src/Tools/IsaPlanner/isand.ML"
    14   "~~/src/Tools/IsaPlanner/rw_tools.ML"
    15   "~~/src/Tools/IsaPlanner/rw_inst.ML"
    16   "~~/src/Tools/intuitionistic.ML"
    17   "~~/src/Tools/project_rule.ML"
    18   "~~/src/Provers/hypsubst.ML"
    19   "~~/src/Provers/splitter.ML"
    20   "~~/src/Provers/classical.ML"
    21   "~~/src/Provers/blast.ML"
    22   "~~/src/Provers/clasimp.ML"
    23   "~~/src/Tools/coherent.ML"
    24   "~~/src/Tools/eqsubst.ML"
    25   "~~/src/Provers/quantifier1.ML"
    26   ("Tools/simpdata.ML")
    27   "~~/src/Tools/random_word.ML"
    28   "~~/src/Tools/atomize_elim.ML"
    29   "~~/src/Tools/induct.ML"
    30   ("~~/src/Tools/induct_tacs.ML")
    31   ("Tools/recfun_codegen.ML")
    32 begin
    33 
    34 setup {* Intuitionistic.method_setup @{binding iprover} *}
    35 
    36 
    37 subsection {* Primitive logic *}
    38 
    39 subsubsection {* Core syntax *}
    40 
    41 classes type
    42 defaultsort type
    43 setup {* ObjectLogic.add_base_sort @{sort type} *}
    44 
    45 arities
    46   "fun" :: (type, type) type
    47   itself :: (type) type
    48 
    49 global
    50 
    51 typedecl bool
    52 
    53 judgment
    54   Trueprop      :: "bool => prop"                   ("(_)" 5)
    55 
    56 consts
    57   Not           :: "bool => bool"                   ("~ _" [40] 40)
    58   True          :: bool
    59   False         :: bool
    60 
    61   The           :: "('a => bool) => 'a"
    62   All           :: "('a => bool) => bool"           (binder "ALL " 10)
    63   Ex            :: "('a => bool) => bool"           (binder "EX " 10)
    64   Ex1           :: "('a => bool) => bool"           (binder "EX! " 10)
    65   Let           :: "['a, 'a => 'b] => 'b"
    66 
    67   "op ="        :: "['a, 'a] => bool"               (infixl "=" 50)
    68   "op &"        :: "[bool, bool] => bool"           (infixr "&" 35)
    69   "op |"        :: "[bool, bool] => bool"           (infixr "|" 30)
    70   "op -->"      :: "[bool, bool] => bool"           (infixr "-->" 25)
    71 
    72 local
    73 
    74 consts
    75   If            :: "[bool, 'a, 'a] => 'a"           ("(if (_)/ then (_)/ else (_))" 10)
    76 
    77 
    78 subsubsection {* Additional concrete syntax *}
    79 
    80 notation (output)
    81   "op ="  (infix "=" 50)
    82 
    83 abbreviation
    84   not_equal :: "['a, 'a] => bool"  (infixl "~=" 50) where
    85   "x ~= y == ~ (x = y)"
    86 
    87 notation (output)
    88   not_equal  (infix "~=" 50)
    89 
    90 notation (xsymbols)
    91   Not  ("\<not> _" [40] 40) and
    92   "op &"  (infixr "\<and>" 35) and
    93   "op |"  (infixr "\<or>" 30) and
    94   "op -->"  (infixr "\<longrightarrow>" 25) and
    95   not_equal  (infix "\<noteq>" 50)
    96 
    97 notation (HTML output)
    98   Not  ("\<not> _" [40] 40) and
    99   "op &"  (infixr "\<and>" 35) and
   100   "op |"  (infixr "\<or>" 30) and
   101   not_equal  (infix "\<noteq>" 50)
   102 
   103 abbreviation (iff)
   104   iff :: "[bool, bool] => bool"  (infixr "<->" 25) where
   105   "A <-> B == A = B"
   106 
   107 notation (xsymbols)
   108   iff  (infixr "\<longleftrightarrow>" 25)
   109 
   110 
   111 nonterminals
   112   letbinds  letbind
   113   case_syn  cases_syn
   114 
   115 syntax
   116   "_The"        :: "[pttrn, bool] => 'a"                 ("(3THE _./ _)" [0, 10] 10)
   117 
   118   "_bind"       :: "[pttrn, 'a] => letbind"              ("(2_ =/ _)" 10)
   119   ""            :: "letbind => letbinds"                 ("_")
   120   "_binds"      :: "[letbind, letbinds] => letbinds"     ("_;/ _")
   121   "_Let"        :: "[letbinds, 'a] => 'a"                ("(let (_)/ in (_))" 10)
   122 
   123   "_case_syntax":: "['a, cases_syn] => 'b"               ("(case _ of/ _)" 10)
   124   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ =>/ _)" 10)
   125   ""            :: "case_syn => cases_syn"               ("_")
   126   "_case2"      :: "[case_syn, cases_syn] => cases_syn"  ("_/ | _")
   127 
   128 translations
   129   "THE x. P"              == "The (%x. P)"
   130   "_Let (_binds b bs) e"  == "_Let b (_Let bs e)"
   131   "let x = a in e"        == "Let a (%x. e)"
   132 
   133 print_translation {*
   134 (* To avoid eta-contraction of body: *)
   135 [("The", fn [Abs abs] =>
   136      let val (x,t) = atomic_abs_tr' abs
   137      in Syntax.const "_The" $ x $ t end)]
   138 *}
   139 
   140 syntax (xsymbols)
   141   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ \<Rightarrow>/ _)" 10)
   142 
   143 notation (xsymbols)
   144   All  (binder "\<forall>" 10) and
   145   Ex  (binder "\<exists>" 10) and
   146   Ex1  (binder "\<exists>!" 10)
   147 
   148 notation (HTML output)
   149   All  (binder "\<forall>" 10) and
   150   Ex  (binder "\<exists>" 10) and
   151   Ex1  (binder "\<exists>!" 10)
   152 
   153 notation (HOL)
   154   All  (binder "! " 10) and
   155   Ex  (binder "? " 10) and
   156   Ex1  (binder "?! " 10)
   157 
   158 
   159 subsubsection {* Axioms and basic definitions *}
   160 
   161 axioms
   162   refl:           "t = (t::'a)"
   163   subst:          "s = t \<Longrightarrow> P s \<Longrightarrow> P t"
   164   ext:            "(!!x::'a. (f x ::'b) = g x) ==> (%x. f x) = (%x. g x)"
   165     -- {*Extensionality is built into the meta-logic, and this rule expresses
   166          a related property.  It is an eta-expanded version of the traditional
   167          rule, and similar to the ABS rule of HOL*}
   168 
   169   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   170 
   171   impI:           "(P ==> Q) ==> P-->Q"
   172   mp:             "[| P-->Q;  P |] ==> Q"
   173 
   174 
   175 defs
   176   True_def:     "True      == ((%x::bool. x) = (%x. x))"
   177   All_def:      "All(P)    == (P = (%x. True))"
   178   Ex_def:       "Ex(P)     == !Q. (!x. P x --> Q) --> Q"
   179   False_def:    "False     == (!P. P)"
   180   not_def:      "~ P       == P-->False"
   181   and_def:      "P & Q     == !R. (P-->Q-->R) --> R"
   182   or_def:       "P | Q     == !R. (P-->R) --> (Q-->R) --> R"
   183   Ex1_def:      "Ex1(P)    == ? x. P(x) & (! y. P(y) --> y=x)"
   184 
   185 axioms
   186   iff:          "(P-->Q) --> (Q-->P) --> (P=Q)"
   187   True_or_False:  "(P=True) | (P=False)"
   188 
   189 defs
   190   Let_def:      "Let s f == f(s)"
   191   if_def:       "If P x y == THE z::'a. (P=True --> z=x) & (P=False --> z=y)"
   192 
   193 finalconsts
   194   "op ="
   195   "op -->"
   196   The
   197 
   198 axiomatization
   199   undefined :: 'a
   200 
   201 
   202 subsubsection {* Generic classes and algebraic operations *}
   203 
   204 class default =
   205   fixes default :: 'a
   206 
   207 class zero = 
   208   fixes zero :: 'a  ("0")
   209 
   210 class one =
   211   fixes one  :: 'a  ("1")
   212 
   213 hide (open) const zero one
   214 
   215 class plus =
   216   fixes plus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "+" 65)
   217 
   218 class minus =
   219   fixes minus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "-" 65)
   220 
   221 class uminus =
   222   fixes uminus :: "'a \<Rightarrow> 'a"  ("- _" [81] 80)
   223 
   224 class times =
   225   fixes times :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "*" 70)
   226 
   227 class inverse =
   228   fixes inverse :: "'a \<Rightarrow> 'a"
   229     and divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "'/" 70)
   230 
   231 class abs =
   232   fixes abs :: "'a \<Rightarrow> 'a"
   233 begin
   234 
   235 notation (xsymbols)
   236   abs  ("\<bar>_\<bar>")
   237 
   238 notation (HTML output)
   239   abs  ("\<bar>_\<bar>")
   240 
   241 end
   242 
   243 class sgn =
   244   fixes sgn :: "'a \<Rightarrow> 'a"
   245 
   246 class ord =
   247   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   248     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   249 begin
   250 
   251 notation
   252   less_eq  ("op <=") and
   253   less_eq  ("(_/ <= _)" [51, 51] 50) and
   254   less  ("op <") and
   255   less  ("(_/ < _)"  [51, 51] 50)
   256   
   257 notation (xsymbols)
   258   less_eq  ("op \<le>") and
   259   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   260 
   261 notation (HTML output)
   262   less_eq  ("op \<le>") and
   263   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   264 
   265 abbreviation (input)
   266   greater_eq  (infix ">=" 50) where
   267   "x >= y \<equiv> y <= x"
   268 
   269 notation (input)
   270   greater_eq  (infix "\<ge>" 50)
   271 
   272 abbreviation (input)
   273   greater  (infix ">" 50) where
   274   "x > y \<equiv> y < x"
   275 
   276 end
   277 
   278 syntax
   279   "_index1"  :: index    ("\<^sub>1")
   280 translations
   281   (index) "\<^sub>1" => (index) "\<^bsub>\<struct>\<^esub>"
   282 
   283 typed_print_translation {*
   284 let
   285   fun tr' c = (c, fn show_sorts => fn T => fn ts =>
   286     if (not o null) ts orelse T = dummyT orelse not (! show_types) andalso can Term.dest_Type T then raise Match
   287     else Syntax.const Syntax.constrainC $ Syntax.const c $ Syntax.term_of_typ show_sorts T);
   288 in map tr' [@{const_syntax HOL.one}, @{const_syntax HOL.zero}] end;
   289 *} -- {* show types that are presumably too general *}
   290 
   291 
   292 subsection {* Fundamental rules *}
   293 
   294 subsubsection {* Equality *}
   295 
   296 lemma sym: "s = t ==> t = s"
   297   by (erule subst) (rule refl)
   298 
   299 lemma ssubst: "t = s ==> P s ==> P t"
   300   by (drule sym) (erule subst)
   301 
   302 lemma trans: "[| r=s; s=t |] ==> r=t"
   303   by (erule subst)
   304 
   305 lemma meta_eq_to_obj_eq: 
   306   assumes meq: "A == B"
   307   shows "A = B"
   308   by (unfold meq) (rule refl)
   309 
   310 text {* Useful with @{text erule} for proving equalities from known equalities. *}
   311      (* a = b
   312         |   |
   313         c = d   *)
   314 lemma box_equals: "[| a=b;  a=c;  b=d |] ==> c=d"
   315 apply (rule trans)
   316 apply (rule trans)
   317 apply (rule sym)
   318 apply assumption+
   319 done
   320 
   321 text {* For calculational reasoning: *}
   322 
   323 lemma forw_subst: "a = b ==> P b ==> P a"
   324   by (rule ssubst)
   325 
   326 lemma back_subst: "P a ==> a = b ==> P b"
   327   by (rule subst)
   328 
   329 
   330 subsubsection {*Congruence rules for application*}
   331 
   332 (*similar to AP_THM in Gordon's HOL*)
   333 lemma fun_cong: "(f::'a=>'b) = g ==> f(x)=g(x)"
   334 apply (erule subst)
   335 apply (rule refl)
   336 done
   337 
   338 (*similar to AP_TERM in Gordon's HOL and FOL's subst_context*)
   339 lemma arg_cong: "x=y ==> f(x)=f(y)"
   340 apply (erule subst)
   341 apply (rule refl)
   342 done
   343 
   344 lemma arg_cong2: "\<lbrakk> a = b; c = d \<rbrakk> \<Longrightarrow> f a c = f b d"
   345 apply (erule ssubst)+
   346 apply (rule refl)
   347 done
   348 
   349 lemma cong: "[| f = g; (x::'a) = y |] ==> f(x) = g(y)"
   350 apply (erule subst)+
   351 apply (rule refl)
   352 done
   353 
   354 
   355 subsubsection {*Equality of booleans -- iff*}
   356 
   357 lemma iffI: assumes "P ==> Q" and "Q ==> P" shows "P=Q"
   358   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
   359 
   360 lemma iffD2: "[| P=Q; Q |] ==> P"
   361   by (erule ssubst)
   362 
   363 lemma rev_iffD2: "[| Q; P=Q |] ==> P"
   364   by (erule iffD2)
   365 
   366 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
   367   by (drule sym) (rule iffD2)
   368 
   369 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
   370   by (drule sym) (rule rev_iffD2)
   371 
   372 lemma iffE:
   373   assumes major: "P=Q"
   374     and minor: "[| P --> Q; Q --> P |] ==> R"
   375   shows R
   376   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
   377 
   378 
   379 subsubsection {*True*}
   380 
   381 lemma TrueI: "True"
   382   unfolding True_def by (rule refl)
   383 
   384 lemma eqTrueI: "P ==> P = True"
   385   by (iprover intro: iffI TrueI)
   386 
   387 lemma eqTrueE: "P = True ==> P"
   388   by (erule iffD2) (rule TrueI)
   389 
   390 
   391 subsubsection {*Universal quantifier*}
   392 
   393 lemma allI: assumes "!!x::'a. P(x)" shows "ALL x. P(x)"
   394   unfolding All_def by (iprover intro: ext eqTrueI assms)
   395 
   396 lemma spec: "ALL x::'a. P(x) ==> P(x)"
   397 apply (unfold All_def)
   398 apply (rule eqTrueE)
   399 apply (erule fun_cong)
   400 done
   401 
   402 lemma allE:
   403   assumes major: "ALL x. P(x)"
   404     and minor: "P(x) ==> R"
   405   shows R
   406   by (iprover intro: minor major [THEN spec])
   407 
   408 lemma all_dupE:
   409   assumes major: "ALL x. P(x)"
   410     and minor: "[| P(x); ALL x. P(x) |] ==> R"
   411   shows R
   412   by (iprover intro: minor major major [THEN spec])
   413 
   414 
   415 subsubsection {* False *}
   416 
   417 text {*
   418   Depends upon @{text spec}; it is impossible to do propositional
   419   logic before quantifiers!
   420 *}
   421 
   422 lemma FalseE: "False ==> P"
   423   apply (unfold False_def)
   424   apply (erule spec)
   425   done
   426 
   427 lemma False_neq_True: "False = True ==> P"
   428   by (erule eqTrueE [THEN FalseE])
   429 
   430 
   431 subsubsection {* Negation *}
   432 
   433 lemma notI:
   434   assumes "P ==> False"
   435   shows "~P"
   436   apply (unfold not_def)
   437   apply (iprover intro: impI assms)
   438   done
   439 
   440 lemma False_not_True: "False ~= True"
   441   apply (rule notI)
   442   apply (erule False_neq_True)
   443   done
   444 
   445 lemma True_not_False: "True ~= False"
   446   apply (rule notI)
   447   apply (drule sym)
   448   apply (erule False_neq_True)
   449   done
   450 
   451 lemma notE: "[| ~P;  P |] ==> R"
   452   apply (unfold not_def)
   453   apply (erule mp [THEN FalseE])
   454   apply assumption
   455   done
   456 
   457 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
   458   by (erule notE [THEN notI]) (erule meta_mp)
   459 
   460 
   461 subsubsection {*Implication*}
   462 
   463 lemma impE:
   464   assumes "P-->Q" "P" "Q ==> R"
   465   shows "R"
   466 by (iprover intro: assms mp)
   467 
   468 (* Reduces Q to P-->Q, allowing substitution in P. *)
   469 lemma rev_mp: "[| P;  P --> Q |] ==> Q"
   470 by (iprover intro: mp)
   471 
   472 lemma contrapos_nn:
   473   assumes major: "~Q"
   474       and minor: "P==>Q"
   475   shows "~P"
   476 by (iprover intro: notI minor major [THEN notE])
   477 
   478 (*not used at all, but we already have the other 3 combinations *)
   479 lemma contrapos_pn:
   480   assumes major: "Q"
   481       and minor: "P ==> ~Q"
   482   shows "~P"
   483 by (iprover intro: notI minor major notE)
   484 
   485 lemma not_sym: "t ~= s ==> s ~= t"
   486   by (erule contrapos_nn) (erule sym)
   487 
   488 lemma eq_neq_eq_imp_neq: "[| x = a ; a ~= b; b = y |] ==> x ~= y"
   489   by (erule subst, erule ssubst, assumption)
   490 
   491 (*still used in HOLCF*)
   492 lemma rev_contrapos:
   493   assumes pq: "P ==> Q"
   494       and nq: "~Q"
   495   shows "~P"
   496 apply (rule nq [THEN contrapos_nn])
   497 apply (erule pq)
   498 done
   499 
   500 subsubsection {*Existential quantifier*}
   501 
   502 lemma exI: "P x ==> EX x::'a. P x"
   503 apply (unfold Ex_def)
   504 apply (iprover intro: allI allE impI mp)
   505 done
   506 
   507 lemma exE:
   508   assumes major: "EX x::'a. P(x)"
   509       and minor: "!!x. P(x) ==> Q"
   510   shows "Q"
   511 apply (rule major [unfolded Ex_def, THEN spec, THEN mp])
   512 apply (iprover intro: impI [THEN allI] minor)
   513 done
   514 
   515 
   516 subsubsection {*Conjunction*}
   517 
   518 lemma conjI: "[| P; Q |] ==> P&Q"
   519 apply (unfold and_def)
   520 apply (iprover intro: impI [THEN allI] mp)
   521 done
   522 
   523 lemma conjunct1: "[| P & Q |] ==> P"
   524 apply (unfold and_def)
   525 apply (iprover intro: impI dest: spec mp)
   526 done
   527 
   528 lemma conjunct2: "[| P & Q |] ==> Q"
   529 apply (unfold and_def)
   530 apply (iprover intro: impI dest: spec mp)
   531 done
   532 
   533 lemma conjE:
   534   assumes major: "P&Q"
   535       and minor: "[| P; Q |] ==> R"
   536   shows "R"
   537 apply (rule minor)
   538 apply (rule major [THEN conjunct1])
   539 apply (rule major [THEN conjunct2])
   540 done
   541 
   542 lemma context_conjI:
   543   assumes "P" "P ==> Q" shows "P & Q"
   544 by (iprover intro: conjI assms)
   545 
   546 
   547 subsubsection {*Disjunction*}
   548 
   549 lemma disjI1: "P ==> P|Q"
   550 apply (unfold or_def)
   551 apply (iprover intro: allI impI mp)
   552 done
   553 
   554 lemma disjI2: "Q ==> P|Q"
   555 apply (unfold or_def)
   556 apply (iprover intro: allI impI mp)
   557 done
   558 
   559 lemma disjE:
   560   assumes major: "P|Q"
   561       and minorP: "P ==> R"
   562       and minorQ: "Q ==> R"
   563   shows "R"
   564 by (iprover intro: minorP minorQ impI
   565                  major [unfolded or_def, THEN spec, THEN mp, THEN mp])
   566 
   567 
   568 subsubsection {*Classical logic*}
   569 
   570 lemma classical:
   571   assumes prem: "~P ==> P"
   572   shows "P"
   573 apply (rule True_or_False [THEN disjE, THEN eqTrueE])
   574 apply assumption
   575 apply (rule notI [THEN prem, THEN eqTrueI])
   576 apply (erule subst)
   577 apply assumption
   578 done
   579 
   580 lemmas ccontr = FalseE [THEN classical, standard]
   581 
   582 (*notE with premises exchanged; it discharges ~R so that it can be used to
   583   make elimination rules*)
   584 lemma rev_notE:
   585   assumes premp: "P"
   586       and premnot: "~R ==> ~P"
   587   shows "R"
   588 apply (rule ccontr)
   589 apply (erule notE [OF premnot premp])
   590 done
   591 
   592 (*Double negation law*)
   593 lemma notnotD: "~~P ==> P"
   594 apply (rule classical)
   595 apply (erule notE)
   596 apply assumption
   597 done
   598 
   599 lemma contrapos_pp:
   600   assumes p1: "Q"
   601       and p2: "~P ==> ~Q"
   602   shows "P"
   603 by (iprover intro: classical p1 p2 notE)
   604 
   605 
   606 subsubsection {*Unique existence*}
   607 
   608 lemma ex1I:
   609   assumes "P a" "!!x. P(x) ==> x=a"
   610   shows "EX! x. P(x)"
   611 by (unfold Ex1_def, iprover intro: assms exI conjI allI impI)
   612 
   613 text{*Sometimes easier to use: the premises have no shared variables.  Safe!*}
   614 lemma ex_ex1I:
   615   assumes ex_prem: "EX x. P(x)"
   616       and eq: "!!x y. [| P(x); P(y) |] ==> x=y"
   617   shows "EX! x. P(x)"
   618 by (iprover intro: ex_prem [THEN exE] ex1I eq)
   619 
   620 lemma ex1E:
   621   assumes major: "EX! x. P(x)"
   622       and minor: "!!x. [| P(x);  ALL y. P(y) --> y=x |] ==> R"
   623   shows "R"
   624 apply (rule major [unfolded Ex1_def, THEN exE])
   625 apply (erule conjE)
   626 apply (iprover intro: minor)
   627 done
   628 
   629 lemma ex1_implies_ex: "EX! x. P x ==> EX x. P x"
   630 apply (erule ex1E)
   631 apply (rule exI)
   632 apply assumption
   633 done
   634 
   635 
   636 subsubsection {*THE: definite description operator*}
   637 
   638 lemma the_equality:
   639   assumes prema: "P a"
   640       and premx: "!!x. P x ==> x=a"
   641   shows "(THE x. P x) = a"
   642 apply (rule trans [OF _ the_eq_trivial])
   643 apply (rule_tac f = "The" in arg_cong)
   644 apply (rule ext)
   645 apply (rule iffI)
   646  apply (erule premx)
   647 apply (erule ssubst, rule prema)
   648 done
   649 
   650 lemma theI:
   651   assumes "P a" and "!!x. P x ==> x=a"
   652   shows "P (THE x. P x)"
   653 by (iprover intro: assms the_equality [THEN ssubst])
   654 
   655 lemma theI': "EX! x. P x ==> P (THE x. P x)"
   656 apply (erule ex1E)
   657 apply (erule theI)
   658 apply (erule allE)
   659 apply (erule mp)
   660 apply assumption
   661 done
   662 
   663 (*Easier to apply than theI: only one occurrence of P*)
   664 lemma theI2:
   665   assumes "P a" "!!x. P x ==> x=a" "!!x. P x ==> Q x"
   666   shows "Q (THE x. P x)"
   667 by (iprover intro: assms theI)
   668 
   669 lemma the1I2: assumes "EX! x. P x" "\<And>x. P x \<Longrightarrow> Q x" shows "Q (THE x. P x)"
   670 by(iprover intro:assms(2) theI2[where P=P and Q=Q] ex1E[OF assms(1)]
   671            elim:allE impE)
   672 
   673 lemma the1_equality [elim?]: "[| EX!x. P x; P a |] ==> (THE x. P x) = a"
   674 apply (rule the_equality)
   675 apply  assumption
   676 apply (erule ex1E)
   677 apply (erule all_dupE)
   678 apply (drule mp)
   679 apply  assumption
   680 apply (erule ssubst)
   681 apply (erule allE)
   682 apply (erule mp)
   683 apply assumption
   684 done
   685 
   686 lemma the_sym_eq_trivial: "(THE y. x=y) = x"
   687 apply (rule the_equality)
   688 apply (rule refl)
   689 apply (erule sym)
   690 done
   691 
   692 
   693 subsubsection {*Classical intro rules for disjunction and existential quantifiers*}
   694 
   695 lemma disjCI:
   696   assumes "~Q ==> P" shows "P|Q"
   697 apply (rule classical)
   698 apply (iprover intro: assms disjI1 disjI2 notI elim: notE)
   699 done
   700 
   701 lemma excluded_middle: "~P | P"
   702 by (iprover intro: disjCI)
   703 
   704 text {*
   705   case distinction as a natural deduction rule.
   706   Note that @{term "~P"} is the second case, not the first
   707 *}
   708 lemma case_split [case_names True False]:
   709   assumes prem1: "P ==> Q"
   710       and prem2: "~P ==> Q"
   711   shows "Q"
   712 apply (rule excluded_middle [THEN disjE])
   713 apply (erule prem2)
   714 apply (erule prem1)
   715 done
   716 
   717 (*Classical implies (-->) elimination. *)
   718 lemma impCE:
   719   assumes major: "P-->Q"
   720       and minor: "~P ==> R" "Q ==> R"
   721   shows "R"
   722 apply (rule excluded_middle [of P, THEN disjE])
   723 apply (iprover intro: minor major [THEN mp])+
   724 done
   725 
   726 (*This version of --> elimination works on Q before P.  It works best for
   727   those cases in which P holds "almost everywhere".  Can't install as
   728   default: would break old proofs.*)
   729 lemma impCE':
   730   assumes major: "P-->Q"
   731       and minor: "Q ==> R" "~P ==> R"
   732   shows "R"
   733 apply (rule excluded_middle [of P, THEN disjE])
   734 apply (iprover intro: minor major [THEN mp])+
   735 done
   736 
   737 (*Classical <-> elimination. *)
   738 lemma iffCE:
   739   assumes major: "P=Q"
   740       and minor: "[| P; Q |] ==> R"  "[| ~P; ~Q |] ==> R"
   741   shows "R"
   742 apply (rule major [THEN iffE])
   743 apply (iprover intro: minor elim: impCE notE)
   744 done
   745 
   746 lemma exCI:
   747   assumes "ALL x. ~P(x) ==> P(a)"
   748   shows "EX x. P(x)"
   749 apply (rule ccontr)
   750 apply (iprover intro: assms exI allI notI notE [of "\<exists>x. P x"])
   751 done
   752 
   753 
   754 subsubsection {* Intuitionistic Reasoning *}
   755 
   756 lemma impE':
   757   assumes 1: "P --> Q"
   758     and 2: "Q ==> R"
   759     and 3: "P --> Q ==> P"
   760   shows R
   761 proof -
   762   from 3 and 1 have P .
   763   with 1 have Q by (rule impE)
   764   with 2 show R .
   765 qed
   766 
   767 lemma allE':
   768   assumes 1: "ALL x. P x"
   769     and 2: "P x ==> ALL x. P x ==> Q"
   770   shows Q
   771 proof -
   772   from 1 have "P x" by (rule spec)
   773   from this and 1 show Q by (rule 2)
   774 qed
   775 
   776 lemma notE':
   777   assumes 1: "~ P"
   778     and 2: "~ P ==> P"
   779   shows R
   780 proof -
   781   from 2 and 1 have P .
   782   with 1 show R by (rule notE)
   783 qed
   784 
   785 lemma TrueE: "True ==> P ==> P" .
   786 lemma notFalseE: "~ False ==> P ==> P" .
   787 
   788 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
   789   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
   790   and [Pure.elim 2] = allE notE' impE'
   791   and [Pure.intro] = exI disjI2 disjI1
   792 
   793 lemmas [trans] = trans
   794   and [sym] = sym not_sym
   795   and [Pure.elim?] = iffD1 iffD2 impE
   796 
   797 use "Tools/hologic.ML"
   798 
   799 
   800 subsubsection {* Atomizing meta-level connectives *}
   801 
   802 axiomatization where
   803   eq_reflection: "x = y \<Longrightarrow> x \<equiv> y" (*admissible axiom*)
   804 
   805 lemma atomize_all [atomize]: "(!!x. P x) == Trueprop (ALL x. P x)"
   806 proof
   807   assume "!!x. P x"
   808   then show "ALL x. P x" ..
   809 next
   810   assume "ALL x. P x"
   811   then show "!!x. P x" by (rule allE)
   812 qed
   813 
   814 lemma atomize_imp [atomize]: "(A ==> B) == Trueprop (A --> B)"
   815 proof
   816   assume r: "A ==> B"
   817   show "A --> B" by (rule impI) (rule r)
   818 next
   819   assume "A --> B" and A
   820   then show B by (rule mp)
   821 qed
   822 
   823 lemma atomize_not: "(A ==> False) == Trueprop (~A)"
   824 proof
   825   assume r: "A ==> False"
   826   show "~A" by (rule notI) (rule r)
   827 next
   828   assume "~A" and A
   829   then show False by (rule notE)
   830 qed
   831 
   832 lemma atomize_eq [atomize]: "(x == y) == Trueprop (x = y)"
   833 proof
   834   assume "x == y"
   835   show "x = y" by (unfold `x == y`) (rule refl)
   836 next
   837   assume "x = y"
   838   then show "x == y" by (rule eq_reflection)
   839 qed
   840 
   841 lemma atomize_conj [atomize]: "(A &&& B) == Trueprop (A & B)"
   842 proof
   843   assume conj: "A &&& B"
   844   show "A & B"
   845   proof (rule conjI)
   846     from conj show A by (rule conjunctionD1)
   847     from conj show B by (rule conjunctionD2)
   848   qed
   849 next
   850   assume conj: "A & B"
   851   show "A &&& B"
   852   proof -
   853     from conj show A ..
   854     from conj show B ..
   855   qed
   856 qed
   857 
   858 lemmas [symmetric, rulify] = atomize_all atomize_imp
   859   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
   860 
   861 
   862 subsubsection {* Atomizing elimination rules *}
   863 
   864 setup AtomizeElim.setup
   865 
   866 lemma atomize_exL[atomize_elim]: "(!!x. P x ==> Q) == ((EX x. P x) ==> Q)"
   867   by rule iprover+
   868 
   869 lemma atomize_conjL[atomize_elim]: "(A ==> B ==> C) == (A & B ==> C)"
   870   by rule iprover+
   871 
   872 lemma atomize_disjL[atomize_elim]: "((A ==> C) ==> (B ==> C) ==> C) == ((A | B ==> C) ==> C)"
   873   by rule iprover+
   874 
   875 lemma atomize_elimL[atomize_elim]: "(!!B. (A ==> B) ==> B) == Trueprop A" ..
   876 
   877 
   878 subsection {* Package setup *}
   879 
   880 subsubsection {* Classical Reasoner setup *}
   881 
   882 lemma imp_elim: "P --> Q ==> (~ R ==> P) ==> (Q ==> R) ==> R"
   883   by (rule classical) iprover
   884 
   885 lemma swap: "~ P ==> (~ R ==> P) ==> R"
   886   by (rule classical) iprover
   887 
   888 lemma thin_refl:
   889   "\<And>X. \<lbrakk> x=x; PROP W \<rbrakk> \<Longrightarrow> PROP W" .
   890 
   891 ML {*
   892 structure Hypsubst = HypsubstFun(
   893 struct
   894   structure Simplifier = Simplifier
   895   val dest_eq = HOLogic.dest_eq
   896   val dest_Trueprop = HOLogic.dest_Trueprop
   897   val dest_imp = HOLogic.dest_imp
   898   val eq_reflection = @{thm eq_reflection}
   899   val rev_eq_reflection = @{thm meta_eq_to_obj_eq}
   900   val imp_intr = @{thm impI}
   901   val rev_mp = @{thm rev_mp}
   902   val subst = @{thm subst}
   903   val sym = @{thm sym}
   904   val thin_refl = @{thm thin_refl};
   905   val prop_subst = @{lemma "PROP P t ==> PROP prop (x = t ==> PROP P x)"
   906                      by (unfold prop_def) (drule eq_reflection, unfold)}
   907 end);
   908 open Hypsubst;
   909 
   910 structure Classical = ClassicalFun(
   911 struct
   912   val imp_elim = @{thm imp_elim}
   913   val not_elim = @{thm notE}
   914   val swap = @{thm swap}
   915   val classical = @{thm classical}
   916   val sizef = Drule.size_of_thm
   917   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
   918 end);
   919 
   920 structure BasicClassical: BASIC_CLASSICAL = Classical; 
   921 open BasicClassical;
   922 
   923 ML_Antiquote.value "claset"
   924   (Scan.succeed "Classical.local_claset_of (ML_Context.the_local_context ())");
   925 
   926 structure ResAtpset = NamedThmsFun(val name = "atp" val description = "ATP rules");
   927 
   928 structure ResBlacklist = NamedThmsFun(val name = "noatp" val description = "theorems blacklisted for ATP");
   929 *}
   930 
   931 text {*ResBlacklist holds theorems blacklisted to sledgehammer. 
   932   These theorems typically produce clauses that are prolific (match too many equality or
   933   membership literals) and relate to seldom-used facts. Some duplicate other rules.*}
   934 
   935 setup {*
   936 let
   937   (*prevent substitution on bool*)
   938   fun hyp_subst_tac' i thm = if i <= Thm.nprems_of thm andalso
   939     Term.exists_Const (fn ("op =", Type (_, [T, _])) => T <> Type ("bool", []) | _ => false)
   940       (nth (Thm.prems_of thm) (i - 1)) then Hypsubst.hyp_subst_tac i thm else no_tac thm;
   941 in
   942   Hypsubst.hypsubst_setup
   943   #> ContextRules.addSWrapper (fn tac => hyp_subst_tac' ORELSE' tac)
   944   #> Classical.setup
   945   #> ResAtpset.setup
   946   #> ResBlacklist.setup
   947 end
   948 *}
   949 
   950 declare iffI [intro!]
   951   and notI [intro!]
   952   and impI [intro!]
   953   and disjCI [intro!]
   954   and conjI [intro!]
   955   and TrueI [intro!]
   956   and refl [intro!]
   957 
   958 declare iffCE [elim!]
   959   and FalseE [elim!]
   960   and impCE [elim!]
   961   and disjE [elim!]
   962   and conjE [elim!]
   963   and conjE [elim!]
   964 
   965 declare ex_ex1I [intro!]
   966   and allI [intro!]
   967   and the_equality [intro]
   968   and exI [intro]
   969 
   970 declare exE [elim!]
   971   allE [elim]
   972 
   973 ML {* val HOL_cs = @{claset} *}
   974 
   975 lemma contrapos_np: "~ Q ==> (~ P ==> Q) ==> P"
   976   apply (erule swap)
   977   apply (erule (1) meta_mp)
   978   done
   979 
   980 declare ex_ex1I [rule del, intro! 2]
   981   and ex1I [intro]
   982 
   983 lemmas [intro?] = ext
   984   and [elim?] = ex1_implies_ex
   985 
   986 (*Better then ex1E for classical reasoner: needs no quantifier duplication!*)
   987 lemma alt_ex1E [elim!]:
   988   assumes major: "\<exists>!x. P x"
   989       and prem: "\<And>x. \<lbrakk> P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y' \<rbrakk> \<Longrightarrow> R"
   990   shows R
   991 apply (rule ex1E [OF major])
   992 apply (rule prem)
   993 apply (tactic {* ares_tac @{thms allI} 1 *})+
   994 apply (tactic {* etac (Classical.dup_elim @{thm allE}) 1 *})
   995 apply iprover
   996 done
   997 
   998 ML {*
   999 structure Blast = BlastFun
  1000 (
  1001   type claset = Classical.claset
  1002   val equality_name = @{const_name "op ="}
  1003   val not_name = @{const_name Not}
  1004   val notE = @{thm notE}
  1005   val ccontr = @{thm ccontr}
  1006   val contr_tac = Classical.contr_tac
  1007   val dup_intr = Classical.dup_intr
  1008   val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
  1009   val rep_cs = Classical.rep_cs
  1010   val cla_modifiers = Classical.cla_modifiers
  1011   val cla_meth' = Classical.cla_meth'
  1012 );
  1013 val blast_tac = Blast.blast_tac;
  1014 *}
  1015 
  1016 setup Blast.setup
  1017 
  1018 
  1019 subsubsection {* Simplifier *}
  1020 
  1021 lemma eta_contract_eq: "(%s. f s) = f" ..
  1022 
  1023 lemma simp_thms:
  1024   shows not_not: "(~ ~ P) = P"
  1025   and Not_eq_iff: "((~P) = (~Q)) = (P = Q)"
  1026   and
  1027     "(P ~= Q) = (P = (~Q))"
  1028     "(P | ~P) = True"    "(~P | P) = True"
  1029     "(x = x) = True"
  1030   and not_True_eq_False: "(\<not> True) = False"
  1031   and not_False_eq_True: "(\<not> False) = True"
  1032   and
  1033     "(~P) ~= P"  "P ~= (~P)"
  1034     "(True=P) = P"
  1035   and eq_True: "(P = True) = P"
  1036   and "(False=P) = (~P)"
  1037   and eq_False: "(P = False) = (\<not> P)"
  1038   and
  1039     "(True --> P) = P"  "(False --> P) = True"
  1040     "(P --> True) = True"  "(P --> P) = True"
  1041     "(P --> False) = (~P)"  "(P --> ~P) = (~P)"
  1042     "(P & True) = P"  "(True & P) = P"
  1043     "(P & False) = False"  "(False & P) = False"
  1044     "(P & P) = P"  "(P & (P & Q)) = (P & Q)"
  1045     "(P & ~P) = False"    "(~P & P) = False"
  1046     "(P | True) = True"  "(True | P) = True"
  1047     "(P | False) = P"  "(False | P) = P"
  1048     "(P | P) = P"  "(P | (P | Q)) = (P | Q)" and
  1049     "(ALL x. P) = P"  "(EX x. P) = P"  "EX x. x=t"  "EX x. t=x"
  1050   and
  1051     "!!P. (EX x. x=t & P(x)) = P(t)"
  1052     "!!P. (EX x. t=x & P(x)) = P(t)"
  1053     "!!P. (ALL x. x=t --> P(x)) = P(t)"
  1054     "!!P. (ALL x. t=x --> P(x)) = P(t)"
  1055   by (blast, blast, blast, blast, blast, iprover+)
  1056 
  1057 lemma disj_absorb: "(A | A) = A"
  1058   by blast
  1059 
  1060 lemma disj_left_absorb: "(A | (A | B)) = (A | B)"
  1061   by blast
  1062 
  1063 lemma conj_absorb: "(A & A) = A"
  1064   by blast
  1065 
  1066 lemma conj_left_absorb: "(A & (A & B)) = (A & B)"
  1067   by blast
  1068 
  1069 lemma eq_ac:
  1070   shows eq_commute: "(a=b) = (b=a)"
  1071     and eq_left_commute: "(P=(Q=R)) = (Q=(P=R))"
  1072     and eq_assoc: "((P=Q)=R) = (P=(Q=R))" by (iprover, blast+)
  1073 lemma neq_commute: "(a~=b) = (b~=a)" by iprover
  1074 
  1075 lemma conj_comms:
  1076   shows conj_commute: "(P&Q) = (Q&P)"
  1077     and conj_left_commute: "(P&(Q&R)) = (Q&(P&R))" by iprover+
  1078 lemma conj_assoc: "((P&Q)&R) = (P&(Q&R))" by iprover
  1079 
  1080 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
  1081 
  1082 lemma disj_comms:
  1083   shows disj_commute: "(P|Q) = (Q|P)"
  1084     and disj_left_commute: "(P|(Q|R)) = (Q|(P|R))" by iprover+
  1085 lemma disj_assoc: "((P|Q)|R) = (P|(Q|R))" by iprover
  1086 
  1087 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
  1088 
  1089 lemma conj_disj_distribL: "(P&(Q|R)) = (P&Q | P&R)" by iprover
  1090 lemma conj_disj_distribR: "((P|Q)&R) = (P&R | Q&R)" by iprover
  1091 
  1092 lemma disj_conj_distribL: "(P|(Q&R)) = ((P|Q) & (P|R))" by iprover
  1093 lemma disj_conj_distribR: "((P&Q)|R) = ((P|R) & (Q|R))" by iprover
  1094 
  1095 lemma imp_conjR: "(P --> (Q&R)) = ((P-->Q) & (P-->R))" by iprover
  1096 lemma imp_conjL: "((P&Q) -->R)  = (P --> (Q --> R))" by iprover
  1097 lemma imp_disjL: "((P|Q) --> R) = ((P-->R)&(Q-->R))" by iprover
  1098 
  1099 text {* These two are specialized, but @{text imp_disj_not1} is useful in @{text "Auth/Yahalom"}. *}
  1100 lemma imp_disj_not1: "(P --> Q | R) = (~Q --> P --> R)" by blast
  1101 lemma imp_disj_not2: "(P --> Q | R) = (~R --> P --> Q)" by blast
  1102 
  1103 lemma imp_disj1: "((P-->Q)|R) = (P--> Q|R)" by blast
  1104 lemma imp_disj2: "(Q|(P-->R)) = (P--> Q|R)" by blast
  1105 
  1106 lemma imp_cong: "(P = P') ==> (P' ==> (Q = Q')) ==> ((P --> Q) = (P' --> Q'))"
  1107   by iprover
  1108 
  1109 lemma de_Morgan_disj: "(~(P | Q)) = (~P & ~Q)" by iprover
  1110 lemma de_Morgan_conj: "(~(P & Q)) = (~P | ~Q)" by blast
  1111 lemma not_imp: "(~(P --> Q)) = (P & ~Q)" by blast
  1112 lemma not_iff: "(P~=Q) = (P = (~Q))" by blast
  1113 lemma disj_not1: "(~P | Q) = (P --> Q)" by blast
  1114 lemma disj_not2: "(P | ~Q) = (Q --> P)"  -- {* changes orientation :-( *}
  1115   by blast
  1116 lemma imp_conv_disj: "(P --> Q) = ((~P) | Q)" by blast
  1117 
  1118 lemma iff_conv_conj_imp: "(P = Q) = ((P --> Q) & (Q --> P))" by iprover
  1119 
  1120 
  1121 lemma cases_simp: "((P --> Q) & (~P --> Q)) = Q"
  1122   -- {* Avoids duplication of subgoals after @{text split_if}, when the true and false *}
  1123   -- {* cases boil down to the same thing. *}
  1124   by blast
  1125 
  1126 lemma not_all: "(~ (! x. P(x))) = (? x.~P(x))" by blast
  1127 lemma imp_all: "((! x. P x) --> Q) = (? x. P x --> Q)" by blast
  1128 lemma not_ex: "(~ (? x. P(x))) = (! x.~P(x))" by iprover
  1129 lemma imp_ex: "((? x. P x) --> Q) = (! x. P x --> Q)" by iprover
  1130 lemma all_not_ex: "(ALL x. P x) = (~ (EX x. ~ P x ))" by blast
  1131 
  1132 declare All_def [noatp]
  1133 
  1134 lemma ex_disj_distrib: "(? x. P(x) | Q(x)) = ((? x. P(x)) | (? x. Q(x)))" by iprover
  1135 lemma all_conj_distrib: "(!x. P(x) & Q(x)) = ((! x. P(x)) & (! x. Q(x)))" by iprover
  1136 
  1137 text {*
  1138   \medskip The @{text "&"} congruence rule: not included by default!
  1139   May slow rewrite proofs down by as much as 50\% *}
  1140 
  1141 lemma conj_cong:
  1142     "(P = P') ==> (P' ==> (Q = Q')) ==> ((P & Q) = (P' & Q'))"
  1143   by iprover
  1144 
  1145 lemma rev_conj_cong:
  1146     "(Q = Q') ==> (Q' ==> (P = P')) ==> ((P & Q) = (P' & Q'))"
  1147   by iprover
  1148 
  1149 text {* The @{text "|"} congruence rule: not included by default! *}
  1150 
  1151 lemma disj_cong:
  1152     "(P = P') ==> (~P' ==> (Q = Q')) ==> ((P | Q) = (P' | Q'))"
  1153   by blast
  1154 
  1155 
  1156 text {* \medskip if-then-else rules *}
  1157 
  1158 lemma if_True: "(if True then x else y) = x"
  1159   by (unfold if_def) blast
  1160 
  1161 lemma if_False: "(if False then x else y) = y"
  1162   by (unfold if_def) blast
  1163 
  1164 lemma if_P: "P ==> (if P then x else y) = x"
  1165   by (unfold if_def) blast
  1166 
  1167 lemma if_not_P: "~P ==> (if P then x else y) = y"
  1168   by (unfold if_def) blast
  1169 
  1170 lemma split_if: "P (if Q then x else y) = ((Q --> P(x)) & (~Q --> P(y)))"
  1171   apply (rule case_split [of Q])
  1172    apply (simplesubst if_P)
  1173     prefer 3 apply (simplesubst if_not_P, blast+)
  1174   done
  1175 
  1176 lemma split_if_asm: "P (if Q then x else y) = (~((Q & ~P x) | (~Q & ~P y)))"
  1177 by (simplesubst split_if, blast)
  1178 
  1179 lemmas if_splits [noatp] = split_if split_if_asm
  1180 
  1181 lemma if_cancel: "(if c then x else x) = x"
  1182 by (simplesubst split_if, blast)
  1183 
  1184 lemma if_eq_cancel: "(if x = y then y else x) = x"
  1185 by (simplesubst split_if, blast)
  1186 
  1187 lemma if_bool_eq_conj: "(if P then Q else R) = ((P-->Q) & (~P-->R))"
  1188   -- {* This form is useful for expanding @{text "if"}s on the RIGHT of the @{text "==>"} symbol. *}
  1189   by (rule split_if)
  1190 
  1191 lemma if_bool_eq_disj: "(if P then Q else R) = ((P&Q) | (~P&R))"
  1192   -- {* And this form is useful for expanding @{text "if"}s on the LEFT. *}
  1193   apply (simplesubst split_if, blast)
  1194   done
  1195 
  1196 lemma Eq_TrueI: "P ==> P == True" by (unfold atomize_eq) iprover
  1197 lemma Eq_FalseI: "~P ==> P == False" by (unfold atomize_eq) iprover
  1198 
  1199 text {* \medskip let rules for simproc *}
  1200 
  1201 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow>  Let x f \<equiv> Let x g"
  1202   by (unfold Let_def)
  1203 
  1204 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow>  Let x f \<equiv> g"
  1205   by (unfold Let_def)
  1206 
  1207 text {*
  1208   The following copy of the implication operator is useful for
  1209   fine-tuning congruence rules.  It instructs the simplifier to simplify
  1210   its premise.
  1211 *}
  1212 
  1213 constdefs
  1214   simp_implies :: "[prop, prop] => prop"  (infixr "=simp=>" 1)
  1215   [code del]: "simp_implies \<equiv> op ==>"
  1216 
  1217 lemma simp_impliesI:
  1218   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
  1219   shows "PROP P =simp=> PROP Q"
  1220   apply (unfold simp_implies_def)
  1221   apply (rule PQ)
  1222   apply assumption
  1223   done
  1224 
  1225 lemma simp_impliesE:
  1226   assumes PQ: "PROP P =simp=> PROP Q"
  1227   and P: "PROP P"
  1228   and QR: "PROP Q \<Longrightarrow> PROP R"
  1229   shows "PROP R"
  1230   apply (rule QR)
  1231   apply (rule PQ [unfolded simp_implies_def])
  1232   apply (rule P)
  1233   done
  1234 
  1235 lemma simp_implies_cong:
  1236   assumes PP' :"PROP P == PROP P'"
  1237   and P'QQ': "PROP P' ==> (PROP Q == PROP Q')"
  1238   shows "(PROP P =simp=> PROP Q) == (PROP P' =simp=> PROP Q')"
  1239 proof (unfold simp_implies_def, rule equal_intr_rule)
  1240   assume PQ: "PROP P \<Longrightarrow> PROP Q"
  1241   and P': "PROP P'"
  1242   from PP' [symmetric] and P' have "PROP P"
  1243     by (rule equal_elim_rule1)
  1244   then have "PROP Q" by (rule PQ)
  1245   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
  1246 next
  1247   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
  1248   and P: "PROP P"
  1249   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
  1250   then have "PROP Q'" by (rule P'Q')
  1251   with P'QQ' [OF P', symmetric] show "PROP Q"
  1252     by (rule equal_elim_rule1)
  1253 qed
  1254 
  1255 lemma uncurry:
  1256   assumes "P \<longrightarrow> Q \<longrightarrow> R"
  1257   shows "P \<and> Q \<longrightarrow> R"
  1258   using assms by blast
  1259 
  1260 lemma iff_allI:
  1261   assumes "\<And>x. P x = Q x"
  1262   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
  1263   using assms by blast
  1264 
  1265 lemma iff_exI:
  1266   assumes "\<And>x. P x = Q x"
  1267   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
  1268   using assms by blast
  1269 
  1270 lemma all_comm:
  1271   "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
  1272   by blast
  1273 
  1274 lemma ex_comm:
  1275   "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
  1276   by blast
  1277 
  1278 use "Tools/simpdata.ML"
  1279 ML {* open Simpdata *}
  1280 
  1281 setup {*
  1282   Simplifier.method_setup Splitter.split_modifiers
  1283   #> Simplifier.map_simpset (K Simpdata.simpset_simprocs)
  1284   #> Splitter.setup
  1285   #> clasimp_setup
  1286   #> EqSubst.setup
  1287 *}
  1288 
  1289 text {* Simproc for proving @{text "(y = x) == False"} from premise @{text "~(x = y)"}: *}
  1290 
  1291 simproc_setup neq ("x = y") = {* fn _ =>
  1292 let
  1293   val neq_to_EQ_False = @{thm not_sym} RS @{thm Eq_FalseI};
  1294   fun is_neq eq lhs rhs thm =
  1295     (case Thm.prop_of thm of
  1296       _ $ (Not $ (eq' $ l' $ r')) =>
  1297         Not = HOLogic.Not andalso eq' = eq andalso
  1298         r' aconv lhs andalso l' aconv rhs
  1299     | _ => false);
  1300   fun proc ss ct =
  1301     (case Thm.term_of ct of
  1302       eq $ lhs $ rhs =>
  1303         (case find_first (is_neq eq lhs rhs) (Simplifier.prems_of_ss ss) of
  1304           SOME thm => SOME (thm RS neq_to_EQ_False)
  1305         | NONE => NONE)
  1306      | _ => NONE);
  1307 in proc end;
  1308 *}
  1309 
  1310 simproc_setup let_simp ("Let x f") = {*
  1311 let
  1312   val (f_Let_unfold, x_Let_unfold) =
  1313     let val [(_ $ (f $ x) $ _)] = prems_of @{thm Let_unfold}
  1314     in (cterm_of @{theory} f, cterm_of @{theory} x) end
  1315   val (f_Let_folded, x_Let_folded) =
  1316     let val [(_ $ (f $ x) $ _)] = prems_of @{thm Let_folded}
  1317     in (cterm_of @{theory} f, cterm_of @{theory} x) end;
  1318   val g_Let_folded =
  1319     let val [(_ $ _ $ (g $ _))] = prems_of @{thm Let_folded}
  1320     in cterm_of @{theory} g end;
  1321   fun count_loose (Bound i) k = if i >= k then 1 else 0
  1322     | count_loose (s $ t) k = count_loose s k + count_loose t k
  1323     | count_loose (Abs (_, _, t)) k = count_loose  t (k + 1)
  1324     | count_loose _ _ = 0;
  1325   fun is_trivial_let (Const (@{const_name Let}, _) $ x $ t) =
  1326    case t
  1327     of Abs (_, _, t') => count_loose t' 0 <= 1
  1328      | _ => true;
  1329 in fn _ => fn ss => fn ct => if is_trivial_let (Thm.term_of ct)
  1330   then SOME @{thm Let_def} (*no or one ocurrence of bound variable*)
  1331   else let (*Norbert Schirmer's case*)
  1332     val ctxt = Simplifier.the_context ss;
  1333     val thy = ProofContext.theory_of ctxt;
  1334     val t = Thm.term_of ct;
  1335     val ([t'], ctxt') = Variable.import_terms false [t] ctxt;
  1336   in Option.map (hd o Variable.export ctxt' ctxt o single)
  1337     (case t' of Const (@{const_name Let},_) $ x $ f => (* x and f are already in normal form *)
  1338       if is_Free x orelse is_Bound x orelse is_Const x
  1339       then SOME @{thm Let_def}
  1340       else
  1341         let
  1342           val n = case f of (Abs (x, _, _)) => x | _ => "x";
  1343           val cx = cterm_of thy x;
  1344           val {T = xT, ...} = rep_cterm cx;
  1345           val cf = cterm_of thy f;
  1346           val fx_g = Simplifier.rewrite ss (Thm.capply cf cx);
  1347           val (_ $ _ $ g) = prop_of fx_g;
  1348           val g' = abstract_over (x,g);
  1349         in (if (g aconv g')
  1350              then
  1351                 let
  1352                   val rl =
  1353                     cterm_instantiate [(f_Let_unfold, cf), (x_Let_unfold, cx)] @{thm Let_unfold};
  1354                 in SOME (rl OF [fx_g]) end
  1355              else if Term.betapply (f, x) aconv g then NONE (*avoid identity conversion*)
  1356              else let
  1357                    val abs_g'= Abs (n,xT,g');
  1358                    val g'x = abs_g'$x;
  1359                    val g_g'x = symmetric (beta_conversion false (cterm_of thy g'x));
  1360                    val rl = cterm_instantiate
  1361                              [(f_Let_folded, cterm_of thy f), (x_Let_folded, cx),
  1362                               (g_Let_folded, cterm_of thy abs_g')]
  1363                              @{thm Let_folded};
  1364                  in SOME (rl OF [transitive fx_g g_g'x])
  1365                  end)
  1366         end
  1367     | _ => NONE)
  1368   end
  1369 end *}
  1370 
  1371 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
  1372 proof
  1373   assume "True \<Longrightarrow> PROP P"
  1374   from this [OF TrueI] show "PROP P" .
  1375 next
  1376   assume "PROP P"
  1377   then show "PROP P" .
  1378 qed
  1379 
  1380 lemma ex_simps:
  1381   "!!P Q. (EX x. P x & Q)   = ((EX x. P x) & Q)"
  1382   "!!P Q. (EX x. P & Q x)   = (P & (EX x. Q x))"
  1383   "!!P Q. (EX x. P x | Q)   = ((EX x. P x) | Q)"
  1384   "!!P Q. (EX x. P | Q x)   = (P | (EX x. Q x))"
  1385   "!!P Q. (EX x. P x --> Q) = ((ALL x. P x) --> Q)"
  1386   "!!P Q. (EX x. P --> Q x) = (P --> (EX x. Q x))"
  1387   -- {* Miniscoping: pushing in existential quantifiers. *}
  1388   by (iprover | blast)+
  1389 
  1390 lemma all_simps:
  1391   "!!P Q. (ALL x. P x & Q)   = ((ALL x. P x) & Q)"
  1392   "!!P Q. (ALL x. P & Q x)   = (P & (ALL x. Q x))"
  1393   "!!P Q. (ALL x. P x | Q)   = ((ALL x. P x) | Q)"
  1394   "!!P Q. (ALL x. P | Q x)   = (P | (ALL x. Q x))"
  1395   "!!P Q. (ALL x. P x --> Q) = ((EX x. P x) --> Q)"
  1396   "!!P Q. (ALL x. P --> Q x) = (P --> (ALL x. Q x))"
  1397   -- {* Miniscoping: pushing in universal quantifiers. *}
  1398   by (iprover | blast)+
  1399 
  1400 lemmas [simp] =
  1401   triv_forall_equality (*prunes params*)
  1402   True_implies_equals  (*prune asms `True'*)
  1403   if_True
  1404   if_False
  1405   if_cancel
  1406   if_eq_cancel
  1407   imp_disjL
  1408   (*In general it seems wrong to add distributive laws by default: they
  1409     might cause exponential blow-up.  But imp_disjL has been in for a while
  1410     and cannot be removed without affecting existing proofs.  Moreover,
  1411     rewriting by "(P|Q --> R) = ((P-->R)&(Q-->R))" might be justified on the
  1412     grounds that it allows simplification of R in the two cases.*)
  1413   conj_assoc
  1414   disj_assoc
  1415   de_Morgan_conj
  1416   de_Morgan_disj
  1417   imp_disj1
  1418   imp_disj2
  1419   not_imp
  1420   disj_not1
  1421   not_all
  1422   not_ex
  1423   cases_simp
  1424   the_eq_trivial
  1425   the_sym_eq_trivial
  1426   ex_simps
  1427   all_simps
  1428   simp_thms
  1429 
  1430 lemmas [cong] = imp_cong simp_implies_cong
  1431 lemmas [split] = split_if
  1432 
  1433 ML {* val HOL_ss = @{simpset} *}
  1434 
  1435 text {* Simplifies x assuming c and y assuming ~c *}
  1436 lemma if_cong:
  1437   assumes "b = c"
  1438       and "c \<Longrightarrow> x = u"
  1439       and "\<not> c \<Longrightarrow> y = v"
  1440   shows "(if b then x else y) = (if c then u else v)"
  1441   unfolding if_def using assms by simp
  1442 
  1443 text {* Prevents simplification of x and y:
  1444   faster and allows the execution of functional programs. *}
  1445 lemma if_weak_cong [cong]:
  1446   assumes "b = c"
  1447   shows "(if b then x else y) = (if c then x else y)"
  1448   using assms by (rule arg_cong)
  1449 
  1450 text {* Prevents simplification of t: much faster *}
  1451 lemma let_weak_cong:
  1452   assumes "a = b"
  1453   shows "(let x = a in t x) = (let x = b in t x)"
  1454   using assms by (rule arg_cong)
  1455 
  1456 text {* To tidy up the result of a simproc.  Only the RHS will be simplified. *}
  1457 lemma eq_cong2:
  1458   assumes "u = u'"
  1459   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
  1460   using assms by simp
  1461 
  1462 lemma if_distrib:
  1463   "f (if c then x else y) = (if c then f x else f y)"
  1464   by simp
  1465 
  1466 text {* This lemma restricts the effect of the rewrite rule u=v to the left-hand
  1467   side of an equality.  Used in @{text "{Integ,Real}/simproc.ML"} *}
  1468 lemma restrict_to_left:
  1469   assumes "x = y"
  1470   shows "(x = z) = (y = z)"
  1471   using assms by simp
  1472 
  1473 
  1474 subsubsection {* Generic cases and induction *}
  1475 
  1476 text {* Rule projections: *}
  1477 
  1478 ML {*
  1479 structure ProjectRule = ProjectRuleFun
  1480 (
  1481   val conjunct1 = @{thm conjunct1}
  1482   val conjunct2 = @{thm conjunct2}
  1483   val mp = @{thm mp}
  1484 )
  1485 *}
  1486 
  1487 constdefs
  1488   induct_forall where "induct_forall P == \<forall>x. P x"
  1489   induct_implies where "induct_implies A B == A \<longrightarrow> B"
  1490   induct_equal where "induct_equal x y == x = y"
  1491   induct_conj where "induct_conj A B == A \<and> B"
  1492 
  1493 lemma induct_forall_eq: "(!!x. P x) == Trueprop (induct_forall (\<lambda>x. P x))"
  1494   by (unfold atomize_all induct_forall_def)
  1495 
  1496 lemma induct_implies_eq: "(A ==> B) == Trueprop (induct_implies A B)"
  1497   by (unfold atomize_imp induct_implies_def)
  1498 
  1499 lemma induct_equal_eq: "(x == y) == Trueprop (induct_equal x y)"
  1500   by (unfold atomize_eq induct_equal_def)
  1501 
  1502 lemma induct_conj_eq: "(A &&& B) == Trueprop (induct_conj A B)"
  1503   by (unfold atomize_conj induct_conj_def)
  1504 
  1505 lemmas induct_atomize = induct_forall_eq induct_implies_eq induct_equal_eq induct_conj_eq
  1506 lemmas induct_rulify [symmetric, standard] = induct_atomize
  1507 lemmas induct_rulify_fallback =
  1508   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
  1509 
  1510 
  1511 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
  1512     induct_conj (induct_forall A) (induct_forall B)"
  1513   by (unfold induct_forall_def induct_conj_def) iprover
  1514 
  1515 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
  1516     induct_conj (induct_implies C A) (induct_implies C B)"
  1517   by (unfold induct_implies_def induct_conj_def) iprover
  1518 
  1519 lemma induct_conj_curry: "(induct_conj A B ==> PROP C) == (A ==> B ==> PROP C)"
  1520 proof
  1521   assume r: "induct_conj A B ==> PROP C" and A B
  1522   show "PROP C" by (rule r) (simp add: induct_conj_def `A` `B`)
  1523 next
  1524   assume r: "A ==> B ==> PROP C" and "induct_conj A B"
  1525   show "PROP C" by (rule r) (simp_all add: `induct_conj A B` [unfolded induct_conj_def])
  1526 qed
  1527 
  1528 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
  1529 
  1530 hide const induct_forall induct_implies induct_equal induct_conj
  1531 
  1532 text {* Method setup. *}
  1533 
  1534 ML {*
  1535 structure Induct = InductFun
  1536 (
  1537   val cases_default = @{thm case_split}
  1538   val atomize = @{thms induct_atomize}
  1539   val rulify = @{thms induct_rulify}
  1540   val rulify_fallback = @{thms induct_rulify_fallback}
  1541 )
  1542 *}
  1543 
  1544 setup Induct.setup
  1545 
  1546 use "~~/src/Tools/induct_tacs.ML"
  1547 setup InductTacs.setup
  1548 
  1549 
  1550 subsubsection {* Coherent logic *}
  1551 
  1552 ML {*
  1553 structure Coherent = CoherentFun
  1554 (
  1555   val atomize_elimL = @{thm atomize_elimL}
  1556   val atomize_exL = @{thm atomize_exL}
  1557   val atomize_conjL = @{thm atomize_conjL}
  1558   val atomize_disjL = @{thm atomize_disjL}
  1559   val operator_names =
  1560     [@{const_name "op |"}, @{const_name "op &"}, @{const_name "Ex"}]
  1561 );
  1562 *}
  1563 
  1564 setup Coherent.setup
  1565 
  1566 
  1567 subsubsection {* Reorienting equalities *}
  1568 
  1569 ML {*
  1570 signature REORIENT_PROC =
  1571 sig
  1572   val init : theory -> theory
  1573   val add : (term -> bool) -> theory -> theory
  1574   val proc : morphism -> simpset -> cterm -> thm option
  1575 end;
  1576 
  1577 structure ReorientProc : REORIENT_PROC =
  1578 struct
  1579   structure Data = TheoryDataFun
  1580   (
  1581     type T = term -> bool;
  1582     val empty = (fn _ => false);
  1583     val copy = I;
  1584     val extend = I;
  1585     fun merge _ (m1, m2) = (fn t => m1 t orelse m2 t);
  1586   )
  1587 
  1588   val init = Data.init;
  1589   fun add m = Data.map (fn matches => fn t => matches t orelse m t);
  1590   val meta_reorient = @{thm eq_commute [THEN eq_reflection]};
  1591   fun proc phi ss ct =
  1592     let
  1593       val ctxt = Simplifier.the_context ss;
  1594       val thy = ProofContext.theory_of ctxt;
  1595       val matches = Data.get thy;
  1596     in
  1597       case Thm.term_of ct of
  1598         (_ $ t $ u) => if matches u then NONE else SOME meta_reorient
  1599       | _ => NONE
  1600     end;
  1601 end;
  1602 *}
  1603 
  1604 setup ReorientProc.init
  1605 
  1606 setup {*
  1607   ReorientProc.add
  1608     (fn Const(@{const_name HOL.zero}, _) => true
  1609       | Const(@{const_name HOL.one}, _) => true
  1610       | _ => false)
  1611 *}
  1612 
  1613 simproc_setup reorient_zero ("0 = x") = ReorientProc.proc
  1614 simproc_setup reorient_one ("1 = x") = ReorientProc.proc
  1615 
  1616 
  1617 subsection {* Other simple lemmas and lemma duplicates *}
  1618 
  1619 lemma Let_0 [simp]: "Let 0 f = f 0"
  1620   unfolding Let_def ..
  1621 
  1622 lemma Let_1 [simp]: "Let 1 f = f 1"
  1623   unfolding Let_def ..
  1624 
  1625 lemma ex1_eq [iff]: "EX! x. x = t" "EX! x. t = x"
  1626   by blast+
  1627 
  1628 lemma choice_eq: "(ALL x. EX! y. P x y) = (EX! f. ALL x. P x (f x))"
  1629   apply (rule iffI)
  1630   apply (rule_tac a = "%x. THE y. P x y" in ex1I)
  1631   apply (fast dest!: theI')
  1632   apply (fast intro: ext the1_equality [symmetric])
  1633   apply (erule ex1E)
  1634   apply (rule allI)
  1635   apply (rule ex1I)
  1636   apply (erule spec)
  1637   apply (erule_tac x = "%z. if z = x then y else f z" in allE)
  1638   apply (erule impE)
  1639   apply (rule allI)
  1640   apply (case_tac "xa = x")
  1641   apply (drule_tac [3] x = x in fun_cong, simp_all)
  1642   done
  1643 
  1644 lemma mk_left_commute:
  1645   fixes f (infix "\<otimes>" 60)
  1646   assumes a: "\<And>x y z. (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)" and
  1647           c: "\<And>x y. x \<otimes> y = y \<otimes> x"
  1648   shows "x \<otimes> (y \<otimes> z) = y \<otimes> (x \<otimes> z)"
  1649   by (rule trans [OF trans [OF c a] arg_cong [OF c, of "f y"]])
  1650 
  1651 lemmas eq_sym_conv = eq_commute
  1652 
  1653 lemma nnf_simps:
  1654   "(\<not>(P \<and> Q)) = (\<not> P \<or> \<not> Q)" "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)" 
  1655   "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not>(P = Q)) = ((P \<and> \<not> Q) \<or> (\<not>P \<and> Q))" 
  1656   "(\<not> \<not>(P)) = P"
  1657 by blast+
  1658 
  1659 
  1660 subsection {* Basic ML bindings *}
  1661 
  1662 ML {*
  1663 val FalseE = @{thm FalseE}
  1664 val Let_def = @{thm Let_def}
  1665 val TrueI = @{thm TrueI}
  1666 val allE = @{thm allE}
  1667 val allI = @{thm allI}
  1668 val all_dupE = @{thm all_dupE}
  1669 val arg_cong = @{thm arg_cong}
  1670 val box_equals = @{thm box_equals}
  1671 val ccontr = @{thm ccontr}
  1672 val classical = @{thm classical}
  1673 val conjE = @{thm conjE}
  1674 val conjI = @{thm conjI}
  1675 val conjunct1 = @{thm conjunct1}
  1676 val conjunct2 = @{thm conjunct2}
  1677 val disjCI = @{thm disjCI}
  1678 val disjE = @{thm disjE}
  1679 val disjI1 = @{thm disjI1}
  1680 val disjI2 = @{thm disjI2}
  1681 val eq_reflection = @{thm eq_reflection}
  1682 val ex1E = @{thm ex1E}
  1683 val ex1I = @{thm ex1I}
  1684 val ex1_implies_ex = @{thm ex1_implies_ex}
  1685 val exE = @{thm exE}
  1686 val exI = @{thm exI}
  1687 val excluded_middle = @{thm excluded_middle}
  1688 val ext = @{thm ext}
  1689 val fun_cong = @{thm fun_cong}
  1690 val iffD1 = @{thm iffD1}
  1691 val iffD2 = @{thm iffD2}
  1692 val iffI = @{thm iffI}
  1693 val impE = @{thm impE}
  1694 val impI = @{thm impI}
  1695 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
  1696 val mp = @{thm mp}
  1697 val notE = @{thm notE}
  1698 val notI = @{thm notI}
  1699 val not_all = @{thm not_all}
  1700 val not_ex = @{thm not_ex}
  1701 val not_iff = @{thm not_iff}
  1702 val not_not = @{thm not_not}
  1703 val not_sym = @{thm not_sym}
  1704 val refl = @{thm refl}
  1705 val rev_mp = @{thm rev_mp}
  1706 val spec = @{thm spec}
  1707 val ssubst = @{thm ssubst}
  1708 val subst = @{thm subst}
  1709 val sym = @{thm sym}
  1710 val trans = @{thm trans}
  1711 *}
  1712 
  1713 
  1714 subsection {* Code generator setup *}
  1715 
  1716 subsubsection {* SML code generator setup *}
  1717 
  1718 use "Tools/recfun_codegen.ML"
  1719 
  1720 setup {*
  1721   Codegen.setup
  1722   #> RecfunCodegen.setup
  1723 *}
  1724 
  1725 types_code
  1726   "bool"  ("bool")
  1727 attach (term_of) {*
  1728 fun term_of_bool b = if b then HOLogic.true_const else HOLogic.false_const;
  1729 *}
  1730 attach (test) {*
  1731 fun gen_bool i =
  1732   let val b = one_of [false, true]
  1733   in (b, fn () => term_of_bool b) end;
  1734 *}
  1735   "prop"  ("bool")
  1736 attach (term_of) {*
  1737 fun term_of_prop b =
  1738   HOLogic.mk_Trueprop (if b then HOLogic.true_const else HOLogic.false_const);
  1739 *}
  1740 
  1741 consts_code
  1742   "Trueprop" ("(_)")
  1743   "True"    ("true")
  1744   "False"   ("false")
  1745   "Not"     ("Bool.not")
  1746   "op |"    ("(_ orelse/ _)")
  1747   "op &"    ("(_ andalso/ _)")
  1748   "If"      ("(if _/ then _/ else _)")
  1749 
  1750 setup {*
  1751 let
  1752 
  1753 fun eq_codegen thy defs dep thyname b t gr =
  1754     (case strip_comb t of
  1755        (Const ("op =", Type (_, [Type ("fun", _), _])), _) => NONE
  1756      | (Const ("op =", _), [t, u]) =>
  1757           let
  1758             val (pt, gr') = Codegen.invoke_codegen thy defs dep thyname false t gr;
  1759             val (pu, gr'') = Codegen.invoke_codegen thy defs dep thyname false u gr';
  1760             val (_, gr''') = Codegen.invoke_tycodegen thy defs dep thyname false HOLogic.boolT gr'';
  1761           in
  1762             SOME (Codegen.parens
  1763               (Pretty.block [pt, Codegen.str " =", Pretty.brk 1, pu]), gr''')
  1764           end
  1765      | (t as Const ("op =", _), ts) => SOME (Codegen.invoke_codegen
  1766          thy defs dep thyname b (Codegen.eta_expand t ts 2) gr)
  1767      | _ => NONE);
  1768 
  1769 in
  1770   Codegen.add_codegen "eq_codegen" eq_codegen
  1771 end
  1772 *}
  1773 
  1774 subsubsection {* Generic code generator preprocessor setup *}
  1775 
  1776 setup {*
  1777   Code_Preproc.map_pre (K HOL_basic_ss)
  1778   #> Code_Preproc.map_post (K HOL_basic_ss)
  1779 *}
  1780 
  1781 subsubsection {* Equality *}
  1782 
  1783 class eq =
  1784   fixes eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
  1785   assumes eq_equals: "eq x y \<longleftrightarrow> x = y"
  1786 begin
  1787 
  1788 lemma eq [code unfold, code inline del]: "eq = (op =)"
  1789   by (rule ext eq_equals)+
  1790 
  1791 lemma eq_refl: "eq x x \<longleftrightarrow> True"
  1792   unfolding eq by rule+
  1793 
  1794 lemma equals_eq: "(op =) \<equiv> eq"
  1795   by (rule eq_reflection) (rule ext, rule ext, rule sym, rule eq_equals)
  1796 
  1797 declare equals_eq [symmetric, code post]
  1798 
  1799 end
  1800 
  1801 declare equals_eq [code]
  1802 
  1803 setup {*
  1804   Code_Preproc.map_pre (fn simpset =>
  1805     simpset addsimprocs [Simplifier.simproc_i @{theory} "eq" [@{term "op ="}]
  1806       (fn thy => fn _ => fn t as Const (_, T) => case strip_type T
  1807         of ((T as Type _) :: _, _) => SOME @{thm equals_eq}
  1808          | _ => NONE)])
  1809 *}
  1810 
  1811 
  1812 subsubsection {* Generic code generator foundation *}
  1813 
  1814 text {* Datatypes *}
  1815 
  1816 code_datatype True False
  1817 
  1818 code_datatype "TYPE('a\<Colon>{})"
  1819 
  1820 code_datatype Trueprop "prop"
  1821 
  1822 text {* Code equations *}
  1823 
  1824 lemma [code]:
  1825   shows "(True \<Longrightarrow> PROP P) \<equiv> PROP P" 
  1826     and "(False \<Longrightarrow> Q) \<equiv> Trueprop True" 
  1827     and "(PROP P \<Longrightarrow> True) \<equiv> Trueprop True" 
  1828     and "(Q \<Longrightarrow> False) \<equiv> Trueprop (\<not> Q)" by (auto intro!: equal_intr_rule)
  1829 
  1830 lemma [code]:
  1831   shows "False \<and> x \<longleftrightarrow> False"
  1832     and "True \<and> x \<longleftrightarrow> x"
  1833     and "x \<and> False \<longleftrightarrow> False"
  1834     and "x \<and> True \<longleftrightarrow> x" by simp_all
  1835 
  1836 lemma [code]:
  1837   shows "False \<or> x \<longleftrightarrow> x"
  1838     and "True \<or> x \<longleftrightarrow> True"
  1839     and "x \<or> False \<longleftrightarrow> x"
  1840     and "x \<or> True \<longleftrightarrow> True" by simp_all
  1841 
  1842 lemma [code]:
  1843   shows "\<not> True \<longleftrightarrow> False"
  1844     and "\<not> False \<longleftrightarrow> True" by (rule HOL.simp_thms)+
  1845 
  1846 lemmas [code] = Let_def if_True if_False
  1847 
  1848 lemmas [code, code unfold, symmetric, code post] = imp_conv_disj
  1849 
  1850 instantiation itself :: (type) eq
  1851 begin
  1852 
  1853 definition eq_itself :: "'a itself \<Rightarrow> 'a itself \<Rightarrow> bool" where
  1854   "eq_itself x y \<longleftrightarrow> x = y"
  1855 
  1856 instance proof
  1857 qed (fact eq_itself_def)
  1858 
  1859 end
  1860 
  1861 lemma eq_itself_code [code]:
  1862   "eq_class.eq TYPE('a) TYPE('a) \<longleftrightarrow> True"
  1863   by (simp add: eq)
  1864 
  1865 text {* Equality *}
  1866 
  1867 declare simp_thms(6) [code nbe]
  1868 
  1869 setup {*
  1870   Code.add_const_alias @{thm equals_eq}
  1871 *}
  1872 
  1873 hide (open) const eq
  1874 hide const eq
  1875 
  1876 text {* Cases *}
  1877 
  1878 lemma Let_case_cert:
  1879   assumes "CASE \<equiv> (\<lambda>x. Let x f)"
  1880   shows "CASE x \<equiv> f x"
  1881   using assms by simp_all
  1882 
  1883 lemma If_case_cert:
  1884   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
  1885   shows "(CASE True \<equiv> f) &&& (CASE False \<equiv> g)"
  1886   using assms by simp_all
  1887 
  1888 setup {*
  1889   Code.add_case @{thm Let_case_cert}
  1890   #> Code.add_case @{thm If_case_cert}
  1891   #> Code.add_undefined @{const_name undefined}
  1892 *}
  1893 
  1894 code_abort undefined
  1895 
  1896 subsubsection {* Generic code generator target languages *}
  1897 
  1898 text {* type bool *}
  1899 
  1900 code_type bool
  1901   (SML "bool")
  1902   (OCaml "bool")
  1903   (Haskell "Bool")
  1904 
  1905 code_const True and False and Not and "op &" and "op |" and If
  1906   (SML "true" and "false" and "not"
  1907     and infixl 1 "andalso" and infixl 0 "orelse"
  1908     and "!(if (_)/ then (_)/ else (_))")
  1909   (OCaml "true" and "false" and "not"
  1910     and infixl 4 "&&" and infixl 2 "||"
  1911     and "!(if (_)/ then (_)/ else (_))")
  1912   (Haskell "True" and "False" and "not"
  1913     and infixl 3 "&&" and infixl 2 "||"
  1914     and "!(if (_)/ then (_)/ else (_))")
  1915 
  1916 code_reserved SML
  1917   bool true false not
  1918 
  1919 code_reserved OCaml
  1920   bool not
  1921 
  1922 text {* using built-in Haskell equality *}
  1923 
  1924 code_class eq
  1925   (Haskell "Eq")
  1926 
  1927 code_const "eq_class.eq"
  1928   (Haskell infixl 4 "==")
  1929 
  1930 code_const "op ="
  1931   (Haskell infixl 4 "==")
  1932 
  1933 text {* undefined *}
  1934 
  1935 code_const undefined
  1936   (SML "!(raise/ Fail/ \"undefined\")")
  1937   (OCaml "failwith/ \"undefined\"")
  1938   (Haskell "error/ \"undefined\"")
  1939 
  1940 subsubsection {* Evaluation and normalization by evaluation *}
  1941 
  1942 setup {*
  1943   Value.add_evaluator ("SML", Codegen.eval_term o ProofContext.theory_of)
  1944 *}
  1945 
  1946 ML {*
  1947 structure Eval_Method =
  1948 struct
  1949 
  1950 val eval_ref : (unit -> bool) option ref = ref NONE;
  1951 
  1952 end;
  1953 *}
  1954 
  1955 oracle eval_oracle = {* fn ct =>
  1956   let
  1957     val thy = Thm.theory_of_cterm ct;
  1958     val t = Thm.term_of ct;
  1959     val dummy = @{cprop True};
  1960   in case try HOLogic.dest_Trueprop t
  1961    of SOME t' => if Code_ML.eval NONE
  1962          ("Eval_Method.eval_ref", Eval_Method.eval_ref) (K I) thy t' [] 
  1963        then Thm.capply (Thm.capply @{cterm "op \<equiv> \<Colon> prop \<Rightarrow> prop \<Rightarrow> prop"} ct) dummy
  1964        else dummy
  1965     | NONE => dummy
  1966   end
  1967 *}
  1968 
  1969 ML {*
  1970 fun gen_eval_method conv ctxt = SIMPLE_METHOD'
  1971   (CONVERSION (Conv.params_conv (~1) (K (Conv.concl_conv (~1) conv)) ctxt)
  1972     THEN' rtac TrueI)
  1973 *}
  1974 
  1975 method_setup eval = {* Scan.succeed (gen_eval_method eval_oracle) *}
  1976   "solve goal by evaluation"
  1977 
  1978 method_setup evaluation = {* Scan.succeed (gen_eval_method Codegen.evaluation_conv) *}
  1979   "solve goal by evaluation"
  1980 
  1981 method_setup normalization = {*
  1982   Scan.succeed (K (SIMPLE_METHOD' (CONVERSION Nbe.norm_conv THEN' (fn k => TRY (rtac TrueI k)))))
  1983 *} "solve goal by normalization"
  1984 
  1985 subsubsection {* Quickcheck *}
  1986 
  1987 ML {*
  1988 structure Quickcheck_RecFun_Simp_Thms = NamedThmsFun
  1989 (
  1990   val name = "quickcheck_recfun_simp"
  1991   val description = "simplification rules of recursive functions as needed by Quickcheck"
  1992 )
  1993 *}
  1994 
  1995 setup {*
  1996   Quickcheck_RecFun_Simp_Thms.setup
  1997 *}
  1998 
  1999 setup {*
  2000   Quickcheck.add_generator ("SML", Codegen.test_term)
  2001 *}
  2002 
  2003 quickcheck_params [size = 5, iterations = 50]
  2004 
  2005 
  2006 subsection {* Nitpick setup *}
  2007 
  2008 text {* This will be relocated once Nitpick is moved to HOL. *}
  2009 
  2010 ML {*
  2011 structure Nitpick_Const_Def_Thms = NamedThmsFun
  2012 (
  2013   val name = "nitpick_const_def"
  2014   val description = "alternative definitions of constants as needed by Nitpick"
  2015 )
  2016 structure Nitpick_Const_Simp_Thms = NamedThmsFun
  2017 (
  2018   val name = "nitpick_const_simp"
  2019   val description = "equational specification of constants as needed by Nitpick"
  2020 )
  2021 structure Nitpick_Const_Psimp_Thms = NamedThmsFun
  2022 (
  2023   val name = "nitpick_const_psimp"
  2024   val description = "partial equational specification of constants as needed by Nitpick"
  2025 )
  2026 structure Nitpick_Ind_Intro_Thms = NamedThmsFun
  2027 (
  2028   val name = "nitpick_ind_intro"
  2029   val description = "introduction rules for (co)inductive predicates as needed by Nitpick"
  2030 )
  2031 *}
  2032 
  2033 setup {*
  2034   Nitpick_Const_Def_Thms.setup
  2035   #> Nitpick_Const_Simp_Thms.setup
  2036   #> Nitpick_Const_Psimp_Thms.setup
  2037   #> Nitpick_Ind_Intro_Thms.setup
  2038 *}
  2039 
  2040 
  2041 subsection {* Legacy tactics and ML bindings *}
  2042 
  2043 ML {*
  2044 fun strip_tac i = REPEAT (resolve_tac [impI, allI] i);
  2045 
  2046 (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
  2047 local
  2048   fun wrong_prem (Const ("All", _) $ (Abs (_, _, t))) = wrong_prem t
  2049     | wrong_prem (Bound _) = true
  2050     | wrong_prem _ = false;
  2051   val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
  2052 in
  2053   fun smp i = funpow i (fn m => filter_right ([spec] RL m)) ([mp]);
  2054   fun smp_tac j = EVERY'[dresolve_tac (smp j), atac];
  2055 end;
  2056 
  2057 val all_conj_distrib = thm "all_conj_distrib";
  2058 val all_simps = thms "all_simps";
  2059 val atomize_not = thm "atomize_not";
  2060 val case_split = thm "case_split";
  2061 val cases_simp = thm "cases_simp";
  2062 val choice_eq = thm "choice_eq"
  2063 val cong = thm "cong"
  2064 val conj_comms = thms "conj_comms";
  2065 val conj_cong = thm "conj_cong";
  2066 val de_Morgan_conj = thm "de_Morgan_conj";
  2067 val de_Morgan_disj = thm "de_Morgan_disj";
  2068 val disj_assoc = thm "disj_assoc";
  2069 val disj_comms = thms "disj_comms";
  2070 val disj_cong = thm "disj_cong";
  2071 val eq_ac = thms "eq_ac";
  2072 val eq_cong2 = thm "eq_cong2"
  2073 val Eq_FalseI = thm "Eq_FalseI";
  2074 val Eq_TrueI = thm "Eq_TrueI";
  2075 val Ex1_def = thm "Ex1_def"
  2076 val ex_disj_distrib = thm "ex_disj_distrib";
  2077 val ex_simps = thms "ex_simps";
  2078 val if_cancel = thm "if_cancel";
  2079 val if_eq_cancel = thm "if_eq_cancel";
  2080 val if_False = thm "if_False";
  2081 val iff_conv_conj_imp = thm "iff_conv_conj_imp";
  2082 val iff = thm "iff"
  2083 val if_splits = thms "if_splits";
  2084 val if_True = thm "if_True";
  2085 val if_weak_cong = thm "if_weak_cong"
  2086 val imp_all = thm "imp_all";
  2087 val imp_cong = thm "imp_cong";
  2088 val imp_conjL = thm "imp_conjL";
  2089 val imp_conjR = thm "imp_conjR";
  2090 val imp_conv_disj = thm "imp_conv_disj";
  2091 val simp_implies_def = thm "simp_implies_def";
  2092 val simp_thms = thms "simp_thms";
  2093 val split_if = thm "split_if";
  2094 val the1_equality = thm "the1_equality"
  2095 val theI = thm "theI"
  2096 val theI' = thm "theI'"
  2097 val True_implies_equals = thm "True_implies_equals";
  2098 val nnf_conv = Simplifier.rewrite (HOL_basic_ss addsimps simp_thms @ @{thms "nnf_simps"})
  2099 
  2100 *}
  2101 
  2102 end