src/HOL/Orderings.thy
author wenzelm
Sat Mar 05 19:58:56 2016 +0100 (2016-03-05)
changeset 62521 6383440f41a8
parent 61955 e96292f32c3c
child 63172 d4f459eb7ed0
permissions -rw-r--r--
old HOL syntax is for input only;
     1 (*  Title:      HOL/Orderings.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     3 *)
     4 
     5 section \<open>Abstract orderings\<close>
     6 
     7 theory Orderings
     8 imports HOL
     9 keywords "print_orders" :: diag
    10 begin
    11 
    12 ML_file "~~/src/Provers/order.ML"
    13 ML_file "~~/src/Provers/quasi.ML"  (* FIXME unused? *)
    14 
    15 subsection \<open>Abstract ordering\<close>
    16 
    17 locale ordering =
    18   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infix "\<preceq>" 50)
    19    and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infix "\<prec>" 50)
    20   assumes strict_iff_order: "a \<prec> b \<longleftrightarrow> a \<preceq> b \<and> a \<noteq> b"
    21   assumes refl: "a \<preceq> a" \<comment> \<open>not \<open>iff\<close>: makes problems due to multiple (dual) interpretations\<close>
    22     and antisym: "a \<preceq> b \<Longrightarrow> b \<preceq> a \<Longrightarrow> a = b"
    23     and trans: "a \<preceq> b \<Longrightarrow> b \<preceq> c \<Longrightarrow> a \<preceq> c"
    24 begin
    25 
    26 lemma strict_implies_order:
    27   "a \<prec> b \<Longrightarrow> a \<preceq> b"
    28   by (simp add: strict_iff_order)
    29 
    30 lemma strict_implies_not_eq:
    31   "a \<prec> b \<Longrightarrow> a \<noteq> b"
    32   by (simp add: strict_iff_order)
    33 
    34 lemma not_eq_order_implies_strict:
    35   "a \<noteq> b \<Longrightarrow> a \<preceq> b \<Longrightarrow> a \<prec> b"
    36   by (simp add: strict_iff_order)
    37 
    38 lemma order_iff_strict:
    39   "a \<preceq> b \<longleftrightarrow> a \<prec> b \<or> a = b"
    40   by (auto simp add: strict_iff_order refl)
    41 
    42 lemma irrefl: \<comment> \<open>not \<open>iff\<close>: makes problems due to multiple (dual) interpretations\<close>
    43   "\<not> a \<prec> a"
    44   by (simp add: strict_iff_order)
    45 
    46 lemma asym:
    47   "a \<prec> b \<Longrightarrow> b \<prec> a \<Longrightarrow> False"
    48   by (auto simp add: strict_iff_order intro: antisym)
    49 
    50 lemma strict_trans1:
    51   "a \<preceq> b \<Longrightarrow> b \<prec> c \<Longrightarrow> a \<prec> c"
    52   by (auto simp add: strict_iff_order intro: trans antisym)
    53 
    54 lemma strict_trans2:
    55   "a \<prec> b \<Longrightarrow> b \<preceq> c \<Longrightarrow> a \<prec> c"
    56   by (auto simp add: strict_iff_order intro: trans antisym)
    57 
    58 lemma strict_trans:
    59   "a \<prec> b \<Longrightarrow> b \<prec> c \<Longrightarrow> a \<prec> c"
    60   by (auto intro: strict_trans1 strict_implies_order)
    61 
    62 end
    63 
    64 locale ordering_top = ordering +
    65   fixes top :: "'a"
    66   assumes extremum [simp]: "a \<preceq> top"
    67 begin
    68 
    69 lemma extremum_uniqueI:
    70   "top \<preceq> a \<Longrightarrow> a = top"
    71   by (rule antisym) auto
    72 
    73 lemma extremum_unique:
    74   "top \<preceq> a \<longleftrightarrow> a = top"
    75   by (auto intro: antisym)
    76 
    77 lemma extremum_strict [simp]:
    78   "\<not> (top \<prec> a)"
    79   using extremum [of a] by (auto simp add: order_iff_strict intro: asym irrefl)
    80 
    81 lemma not_eq_extremum:
    82   "a \<noteq> top \<longleftrightarrow> a \<prec> top"
    83   by (auto simp add: order_iff_strict intro: not_eq_order_implies_strict extremum)
    84 
    85 end
    86 
    87 
    88 subsection \<open>Syntactic orders\<close>
    89 
    90 class ord =
    91   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
    92     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
    93 begin
    94 
    95 notation
    96   less_eq  ("op \<le>") and
    97   less_eq  ("(_/ \<le> _)"  [51, 51] 50) and
    98   less  ("op <") and
    99   less  ("(_/ < _)"  [51, 51] 50)
   100 
   101 abbreviation (input)
   102   greater_eq  (infix "\<ge>" 50)
   103   where "x \<ge> y \<equiv> y \<le> x"
   104 
   105 abbreviation (input)
   106   greater  (infix ">" 50)
   107   where "x > y \<equiv> y < x"
   108 
   109 notation (ASCII)
   110   less_eq  ("op <=") and
   111   less_eq  ("(_/ <= _)" [51, 51] 50)
   112 
   113 notation (input)
   114   greater_eq  (infix ">=" 50)
   115 
   116 end
   117 
   118 
   119 subsection \<open>Quasi orders\<close>
   120 
   121 class preorder = ord +
   122   assumes less_le_not_le: "x < y \<longleftrightarrow> x \<le> y \<and> \<not> (y \<le> x)"
   123   and order_refl [iff]: "x \<le> x"
   124   and order_trans: "x \<le> y \<Longrightarrow> y \<le> z \<Longrightarrow> x \<le> z"
   125 begin
   126 
   127 text \<open>Reflexivity.\<close>
   128 
   129 lemma eq_refl: "x = y \<Longrightarrow> x \<le> y"
   130     \<comment> \<open>This form is useful with the classical reasoner.\<close>
   131 by (erule ssubst) (rule order_refl)
   132 
   133 lemma less_irrefl [iff]: "\<not> x < x"
   134 by (simp add: less_le_not_le)
   135 
   136 lemma less_imp_le: "x < y \<Longrightarrow> x \<le> y"
   137 unfolding less_le_not_le by blast
   138 
   139 
   140 text \<open>Asymmetry.\<close>
   141 
   142 lemma less_not_sym: "x < y \<Longrightarrow> \<not> (y < x)"
   143 by (simp add: less_le_not_le)
   144 
   145 lemma less_asym: "x < y \<Longrightarrow> (\<not> P \<Longrightarrow> y < x) \<Longrightarrow> P"
   146 by (drule less_not_sym, erule contrapos_np) simp
   147 
   148 
   149 text \<open>Transitivity.\<close>
   150 
   151 lemma less_trans: "x < y \<Longrightarrow> y < z \<Longrightarrow> x < z"
   152 by (auto simp add: less_le_not_le intro: order_trans)
   153 
   154 lemma le_less_trans: "x \<le> y \<Longrightarrow> y < z \<Longrightarrow> x < z"
   155 by (auto simp add: less_le_not_le intro: order_trans)
   156 
   157 lemma less_le_trans: "x < y \<Longrightarrow> y \<le> z \<Longrightarrow> x < z"
   158 by (auto simp add: less_le_not_le intro: order_trans)
   159 
   160 
   161 text \<open>Useful for simplification, but too risky to include by default.\<close>
   162 
   163 lemma less_imp_not_less: "x < y \<Longrightarrow> (\<not> y < x) \<longleftrightarrow> True"
   164 by (blast elim: less_asym)
   165 
   166 lemma less_imp_triv: "x < y \<Longrightarrow> (y < x \<longrightarrow> P) \<longleftrightarrow> True"
   167 by (blast elim: less_asym)
   168 
   169 
   170 text \<open>Transitivity rules for calculational reasoning\<close>
   171 
   172 lemma less_asym': "a < b \<Longrightarrow> b < a \<Longrightarrow> P"
   173 by (rule less_asym)
   174 
   175 
   176 text \<open>Dual order\<close>
   177 
   178 lemma dual_preorder:
   179   "class.preorder (op \<ge>) (op >)"
   180 proof qed (auto simp add: less_le_not_le intro: order_trans)
   181 
   182 end
   183 
   184 
   185 subsection \<open>Partial orders\<close>
   186 
   187 class order = preorder +
   188   assumes antisym: "x \<le> y \<Longrightarrow> y \<le> x \<Longrightarrow> x = y"
   189 begin
   190 
   191 lemma less_le: "x < y \<longleftrightarrow> x \<le> y \<and> x \<noteq> y"
   192   by (auto simp add: less_le_not_le intro: antisym)
   193 
   194 sublocale order: ordering less_eq less +  dual_order: ordering greater_eq greater
   195   by standard (auto intro: antisym order_trans simp add: less_le)
   196 
   197 
   198 text \<open>Reflexivity.\<close>
   199 
   200 lemma le_less: "x \<le> y \<longleftrightarrow> x < y \<or> x = y"
   201     \<comment> \<open>NOT suitable for iff, since it can cause PROOF FAILED.\<close>
   202 by (fact order.order_iff_strict)
   203 
   204 lemma le_imp_less_or_eq: "x \<le> y \<Longrightarrow> x < y \<or> x = y"
   205 unfolding less_le by blast
   206 
   207 
   208 text \<open>Useful for simplification, but too risky to include by default.\<close>
   209 
   210 lemma less_imp_not_eq: "x < y \<Longrightarrow> (x = y) \<longleftrightarrow> False"
   211 by auto
   212 
   213 lemma less_imp_not_eq2: "x < y \<Longrightarrow> (y = x) \<longleftrightarrow> False"
   214 by auto
   215 
   216 
   217 text \<open>Transitivity rules for calculational reasoning\<close>
   218 
   219 lemma neq_le_trans: "a \<noteq> b \<Longrightarrow> a \<le> b \<Longrightarrow> a < b"
   220 by (fact order.not_eq_order_implies_strict)
   221 
   222 lemma le_neq_trans: "a \<le> b \<Longrightarrow> a \<noteq> b \<Longrightarrow> a < b"
   223 by (rule order.not_eq_order_implies_strict)
   224 
   225 
   226 text \<open>Asymmetry.\<close>
   227 
   228 lemma eq_iff: "x = y \<longleftrightarrow> x \<le> y \<and> y \<le> x"
   229 by (blast intro: antisym)
   230 
   231 lemma antisym_conv: "y \<le> x \<Longrightarrow> x \<le> y \<longleftrightarrow> x = y"
   232 by (blast intro: antisym)
   233 
   234 lemma less_imp_neq: "x < y \<Longrightarrow> x \<noteq> y"
   235 by (fact order.strict_implies_not_eq)
   236 
   237 
   238 text \<open>Least value operator\<close>
   239 
   240 definition (in ord)
   241   Least :: "('a \<Rightarrow> bool) \<Rightarrow> 'a" (binder "LEAST " 10) where
   242   "Least P = (THE x. P x \<and> (\<forall>y. P y \<longrightarrow> x \<le> y))"
   243 
   244 lemma Least_equality:
   245   assumes "P x"
   246     and "\<And>y. P y \<Longrightarrow> x \<le> y"
   247   shows "Least P = x"
   248 unfolding Least_def by (rule the_equality)
   249   (blast intro: assms antisym)+
   250 
   251 lemma LeastI2_order:
   252   assumes "P x"
   253     and "\<And>y. P y \<Longrightarrow> x \<le> y"
   254     and "\<And>x. P x \<Longrightarrow> \<forall>y. P y \<longrightarrow> x \<le> y \<Longrightarrow> Q x"
   255   shows "Q (Least P)"
   256 unfolding Least_def by (rule theI2)
   257   (blast intro: assms antisym)+
   258 
   259 text \<open>Dual order\<close>
   260 
   261 lemma dual_order:
   262   "class.order (op \<ge>) (op >)"
   263 by (intro_locales, rule dual_preorder) (unfold_locales, rule antisym)
   264 
   265 end
   266 
   267 
   268 text \<open>Alternative introduction rule with bias towards strict order\<close>
   269 
   270 lemma order_strictI:
   271   fixes less (infix "\<sqsubset>" 50)
   272     and less_eq (infix "\<sqsubseteq>" 50)
   273   assumes less_eq_less: "\<And>a b. a \<sqsubseteq> b \<longleftrightarrow> a \<sqsubset> b \<or> a = b"
   274     assumes asym: "\<And>a b. a \<sqsubset> b \<Longrightarrow> \<not> b \<sqsubset> a"
   275   assumes irrefl: "\<And>a. \<not> a \<sqsubset> a"
   276   assumes trans: "\<And>a b c. a \<sqsubset> b \<Longrightarrow> b \<sqsubset> c \<Longrightarrow> a \<sqsubset> c"
   277   shows "class.order less_eq less"
   278 proof
   279   fix a b
   280   show "a \<sqsubset> b \<longleftrightarrow> a \<sqsubseteq> b \<and> \<not> b \<sqsubseteq> a"
   281     by (auto simp add: less_eq_less asym irrefl)
   282 next
   283   fix a
   284   show "a \<sqsubseteq> a"
   285     by (auto simp add: less_eq_less)
   286 next
   287   fix a b c
   288   assume "a \<sqsubseteq> b" and "b \<sqsubseteq> c" then show "a \<sqsubseteq> c"
   289     by (auto simp add: less_eq_less intro: trans)
   290 next
   291   fix a b
   292   assume "a \<sqsubseteq> b" and "b \<sqsubseteq> a" then show "a = b"
   293     by (auto simp add: less_eq_less asym)
   294 qed
   295 
   296 
   297 subsection \<open>Linear (total) orders\<close>
   298 
   299 class linorder = order +
   300   assumes linear: "x \<le> y \<or> y \<le> x"
   301 begin
   302 
   303 lemma less_linear: "x < y \<or> x = y \<or> y < x"
   304 unfolding less_le using less_le linear by blast
   305 
   306 lemma le_less_linear: "x \<le> y \<or> y < x"
   307 by (simp add: le_less less_linear)
   308 
   309 lemma le_cases [case_names le ge]:
   310   "(x \<le> y \<Longrightarrow> P) \<Longrightarrow> (y \<le> x \<Longrightarrow> P) \<Longrightarrow> P"
   311 using linear by blast
   312 
   313 lemma (in linorder) le_cases3:
   314   "\<lbrakk>\<lbrakk>x \<le> y; y \<le> z\<rbrakk> \<Longrightarrow> P; \<lbrakk>y \<le> x; x \<le> z\<rbrakk> \<Longrightarrow> P; \<lbrakk>x \<le> z; z \<le> y\<rbrakk> \<Longrightarrow> P;
   315     \<lbrakk>z \<le> y; y \<le> x\<rbrakk> \<Longrightarrow> P; \<lbrakk>y \<le> z; z \<le> x\<rbrakk> \<Longrightarrow> P; \<lbrakk>z \<le> x; x \<le> y\<rbrakk> \<Longrightarrow> P\<rbrakk> \<Longrightarrow> P"
   316 by (blast intro: le_cases)
   317 
   318 lemma linorder_cases [case_names less equal greater]:
   319   "(x < y \<Longrightarrow> P) \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> (y < x \<Longrightarrow> P) \<Longrightarrow> P"
   320 using less_linear by blast
   321 
   322 lemma linorder_wlog[case_names le sym]:
   323   "(\<And>a b. a \<le> b \<Longrightarrow> P a b) \<Longrightarrow> (\<And>a b. P b a \<Longrightarrow> P a b) \<Longrightarrow> P a b"
   324   by (cases rule: le_cases[of a b]) blast+
   325 
   326 lemma not_less: "\<not> x < y \<longleftrightarrow> y \<le> x"
   327 apply (simp add: less_le)
   328 using linear apply (blast intro: antisym)
   329 done
   330 
   331 lemma not_less_iff_gr_or_eq:
   332  "\<not>(x < y) \<longleftrightarrow> (x > y | x = y)"
   333 apply(simp add:not_less le_less)
   334 apply blast
   335 done
   336 
   337 lemma not_le: "\<not> x \<le> y \<longleftrightarrow> y < x"
   338 apply (simp add: less_le)
   339 using linear apply (blast intro: antisym)
   340 done
   341 
   342 lemma neq_iff: "x \<noteq> y \<longleftrightarrow> x < y \<or> y < x"
   343 by (cut_tac x = x and y = y in less_linear, auto)
   344 
   345 lemma neqE: "x \<noteq> y \<Longrightarrow> (x < y \<Longrightarrow> R) \<Longrightarrow> (y < x \<Longrightarrow> R) \<Longrightarrow> R"
   346 by (simp add: neq_iff) blast
   347 
   348 lemma antisym_conv1: "\<not> x < y \<Longrightarrow> x \<le> y \<longleftrightarrow> x = y"
   349 by (blast intro: antisym dest: not_less [THEN iffD1])
   350 
   351 lemma antisym_conv2: "x \<le> y \<Longrightarrow> \<not> x < y \<longleftrightarrow> x = y"
   352 by (blast intro: antisym dest: not_less [THEN iffD1])
   353 
   354 lemma antisym_conv3: "\<not> y < x \<Longrightarrow> \<not> x < y \<longleftrightarrow> x = y"
   355 by (blast intro: antisym dest: not_less [THEN iffD1])
   356 
   357 lemma leI: "\<not> x < y \<Longrightarrow> y \<le> x"
   358 unfolding not_less .
   359 
   360 lemma leD: "y \<le> x \<Longrightarrow> \<not> x < y"
   361 unfolding not_less .
   362 
   363 lemma not_le_imp_less: "\<not> y \<le> x \<Longrightarrow> x < y"
   364 unfolding not_le .
   365 
   366 text \<open>Dual order\<close>
   367 
   368 lemma dual_linorder:
   369   "class.linorder (op \<ge>) (op >)"
   370 by (rule class.linorder.intro, rule dual_order) (unfold_locales, rule linear)
   371 
   372 end
   373 
   374 
   375 text \<open>Alternative introduction rule with bias towards strict order\<close>
   376 
   377 lemma linorder_strictI:
   378   fixes less (infix "\<sqsubset>" 50)
   379     and less_eq (infix "\<sqsubseteq>" 50)
   380   assumes "class.order less_eq less"
   381   assumes trichotomy: "\<And>a b. a \<sqsubset> b \<or> a = b \<or> b \<sqsubset> a"
   382   shows "class.linorder less_eq less"
   383 proof -
   384   interpret order less_eq less
   385     by (fact \<open>class.order less_eq less\<close>)
   386   show ?thesis
   387   proof
   388     fix a b
   389     show "a \<sqsubseteq> b \<or> b \<sqsubseteq> a"
   390       using trichotomy by (auto simp add: le_less)
   391   qed
   392 qed
   393 
   394 
   395 subsection \<open>Reasoning tools setup\<close>
   396 
   397 ML \<open>
   398 signature ORDERS =
   399 sig
   400   val print_structures: Proof.context -> unit
   401   val order_tac: Proof.context -> thm list -> int -> tactic
   402   val add_struct: string * term list -> string -> attribute
   403   val del_struct: string * term list -> attribute
   404 end;
   405 
   406 structure Orders: ORDERS =
   407 struct
   408 
   409 (* context data *)
   410 
   411 fun struct_eq ((s1: string, ts1), (s2, ts2)) =
   412   s1 = s2 andalso eq_list (op aconv) (ts1, ts2);
   413 
   414 structure Data = Generic_Data
   415 (
   416   type T = ((string * term list) * Order_Tac.less_arith) list;
   417     (* Order structures:
   418        identifier of the structure, list of operations and record of theorems
   419        needed to set up the transitivity reasoner,
   420        identifier and operations identify the structure uniquely. *)
   421   val empty = [];
   422   val extend = I;
   423   fun merge data = AList.join struct_eq (K fst) data;
   424 );
   425 
   426 fun print_structures ctxt =
   427   let
   428     val structs = Data.get (Context.Proof ctxt);
   429     fun pretty_term t = Pretty.block
   430       [Pretty.quote (Syntax.pretty_term ctxt t), Pretty.brk 1,
   431         Pretty.str "::", Pretty.brk 1,
   432         Pretty.quote (Syntax.pretty_typ ctxt (type_of t))];
   433     fun pretty_struct ((s, ts), _) = Pretty.block
   434       [Pretty.str s, Pretty.str ":", Pretty.brk 1,
   435        Pretty.enclose "(" ")" (Pretty.breaks (map pretty_term ts))];
   436   in
   437     Pretty.writeln (Pretty.big_list "order structures:" (map pretty_struct structs))
   438   end;
   439 
   440 val _ =
   441   Outer_Syntax.command @{command_keyword print_orders}
   442     "print order structures available to transitivity reasoner"
   443     (Scan.succeed (Toplevel.keep (print_structures o Toplevel.context_of)));
   444 
   445 
   446 (* tactics *)
   447 
   448 fun struct_tac ((s, ops), thms) ctxt facts =
   449   let
   450     val [eq, le, less] = ops;
   451     fun decomp thy (@{const Trueprop} $ t) =
   452           let
   453             fun excluded t =
   454               (* exclude numeric types: linear arithmetic subsumes transitivity *)
   455               let val T = type_of t
   456               in
   457                 T = HOLogic.natT orelse T = HOLogic.intT orelse T = HOLogic.realT
   458               end;
   459             fun rel (bin_op $ t1 $ t2) =
   460                   if excluded t1 then NONE
   461                   else if Pattern.matches thy (eq, bin_op) then SOME (t1, "=", t2)
   462                   else if Pattern.matches thy (le, bin_op) then SOME (t1, "<=", t2)
   463                   else if Pattern.matches thy (less, bin_op) then SOME (t1, "<", t2)
   464                   else NONE
   465               | rel _ = NONE;
   466             fun dec (Const (@{const_name Not}, _) $ t) =
   467                   (case rel t of NONE =>
   468                     NONE
   469                   | SOME (t1, rel, t2) => SOME (t1, "~" ^ rel, t2))
   470               | dec x = rel x;
   471           in dec t end
   472       | decomp _ _ = NONE;
   473   in
   474     (case s of
   475       "order" => Order_Tac.partial_tac decomp thms ctxt facts
   476     | "linorder" => Order_Tac.linear_tac decomp thms ctxt facts
   477     | _ => error ("Unknown order kind " ^ quote s ^ " encountered in transitivity reasoner"))
   478   end
   479 
   480 fun order_tac ctxt facts =
   481   FIRST' (map (fn s => CHANGED o struct_tac s ctxt facts) (Data.get (Context.Proof ctxt)));
   482 
   483 
   484 (* attributes *)
   485 
   486 fun add_struct s tag =
   487   Thm.declaration_attribute
   488     (fn thm => Data.map (AList.map_default struct_eq (s, Order_Tac.empty TrueI) (Order_Tac.update tag thm)));
   489 fun del_struct s =
   490   Thm.declaration_attribute
   491     (fn _ => Data.map (AList.delete struct_eq s));
   492 
   493 end;
   494 \<close>
   495 
   496 attribute_setup order = \<open>
   497   Scan.lift ((Args.add -- Args.name >> (fn (_, s) => SOME s) || Args.del >> K NONE) --|
   498     Args.colon (* FIXME || Scan.succeed true *) ) -- Scan.lift Args.name --
   499     Scan.repeat Args.term
   500     >> (fn ((SOME tag, n), ts) => Orders.add_struct (n, ts) tag
   501          | ((NONE, n), ts) => Orders.del_struct (n, ts))
   502 \<close> "theorems controlling transitivity reasoner"
   503 
   504 method_setup order = \<open>
   505   Scan.succeed (fn ctxt => SIMPLE_METHOD' (Orders.order_tac ctxt []))
   506 \<close> "transitivity reasoner"
   507 
   508 
   509 text \<open>Declarations to set up transitivity reasoner of partial and linear orders.\<close>
   510 
   511 context order
   512 begin
   513 
   514 (* The type constraint on @{term op =} below is necessary since the operation
   515    is not a parameter of the locale. *)
   516 
   517 declare less_irrefl [THEN notE, order add less_reflE: order "op = :: 'a \<Rightarrow> 'a \<Rightarrow> bool" "op <=" "op <"]
   518 
   519 declare order_refl  [order add le_refl: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   520 
   521 declare less_imp_le [order add less_imp_le: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   522 
   523 declare antisym [order add eqI: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   524 
   525 declare eq_refl [order add eqD1: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   526 
   527 declare sym [THEN eq_refl, order add eqD2: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   528 
   529 declare less_trans [order add less_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   530 
   531 declare less_le_trans [order add less_le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   532 
   533 declare le_less_trans [order add le_less_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   534 
   535 declare order_trans [order add le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   536 
   537 declare le_neq_trans [order add le_neq_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   538 
   539 declare neq_le_trans [order add neq_le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   540 
   541 declare less_imp_neq [order add less_imp_neq: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   542 
   543 declare eq_neq_eq_imp_neq [order add eq_neq_eq_imp_neq: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   544 
   545 declare not_sym [order add not_sym: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   546 
   547 end
   548 
   549 context linorder
   550 begin
   551 
   552 declare [[order del: order "op = :: 'a => 'a => bool" "op <=" "op <"]]
   553 
   554 declare less_irrefl [THEN notE, order add less_reflE: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   555 
   556 declare order_refl [order add le_refl: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   557 
   558 declare less_imp_le [order add less_imp_le: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   559 
   560 declare not_less [THEN iffD2, order add not_lessI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   561 
   562 declare not_le [THEN iffD2, order add not_leI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   563 
   564 declare not_less [THEN iffD1, order add not_lessD: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   565 
   566 declare not_le [THEN iffD1, order add not_leD: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   567 
   568 declare antisym [order add eqI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   569 
   570 declare eq_refl [order add eqD1: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   571 
   572 declare sym [THEN eq_refl, order add eqD2: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   573 
   574 declare less_trans [order add less_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   575 
   576 declare less_le_trans [order add less_le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   577 
   578 declare le_less_trans [order add le_less_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   579 
   580 declare order_trans [order add le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   581 
   582 declare le_neq_trans [order add le_neq_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   583 
   584 declare neq_le_trans [order add neq_le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   585 
   586 declare less_imp_neq [order add less_imp_neq: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   587 
   588 declare eq_neq_eq_imp_neq [order add eq_neq_eq_imp_neq: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   589 
   590 declare not_sym [order add not_sym: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   591 
   592 end
   593 
   594 setup \<open>
   595   map_theory_simpset (fn ctxt0 => ctxt0 addSolver
   596     mk_solver "Transitivity" (fn ctxt => Orders.order_tac ctxt (Simplifier.prems_of ctxt)))
   597   (*Adding the transitivity reasoners also as safe solvers showed a slight
   598     speed up, but the reasoning strength appears to be not higher (at least
   599     no breaking of additional proofs in the entire HOL distribution, as
   600     of 5 March 2004, was observed).*)
   601 \<close>
   602 
   603 ML \<open>
   604 local
   605   fun prp t thm = Thm.prop_of thm = t;  (* FIXME proper aconv!? *)
   606 in
   607 
   608 fun antisym_le_simproc ctxt ct =
   609   (case Thm.term_of ct of
   610     (le as Const (_, T)) $ r $ s =>
   611      (let
   612         val prems = Simplifier.prems_of ctxt;
   613         val less = Const (@{const_name less}, T);
   614         val t = HOLogic.mk_Trueprop(le $ s $ r);
   615       in
   616         (case find_first (prp t) prems of
   617           NONE =>
   618             let val t = HOLogic.mk_Trueprop(HOLogic.Not $ (less $ r $ s)) in
   619               (case find_first (prp t) prems of
   620                 NONE => NONE
   621               | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv1})))
   622              end
   623          | SOME thm => SOME (mk_meta_eq (thm RS @{thm order_class.antisym_conv})))
   624       end handle THM _ => NONE)
   625   | _ => NONE);
   626 
   627 fun antisym_less_simproc ctxt ct =
   628   (case Thm.term_of ct of
   629     NotC $ ((less as Const(_,T)) $ r $ s) =>
   630      (let
   631        val prems = Simplifier.prems_of ctxt;
   632        val le = Const (@{const_name less_eq}, T);
   633        val t = HOLogic.mk_Trueprop(le $ r $ s);
   634       in
   635         (case find_first (prp t) prems of
   636           NONE =>
   637             let val t = HOLogic.mk_Trueprop (NotC $ (less $ s $ r)) in
   638               (case find_first (prp t) prems of
   639                 NONE => NONE
   640               | SOME thm => SOME (mk_meta_eq(thm RS @{thm linorder_class.antisym_conv3})))
   641             end
   642         | SOME thm => SOME (mk_meta_eq (thm RS @{thm linorder_class.antisym_conv2})))
   643       end handle THM _ => NONE)
   644   | _ => NONE);
   645 
   646 end;
   647 \<close>
   648 
   649 simproc_setup antisym_le ("(x::'a::order) \<le> y") = "K antisym_le_simproc"
   650 simproc_setup antisym_less ("\<not> (x::'a::linorder) < y") = "K antisym_less_simproc"
   651 
   652 
   653 subsection \<open>Bounded quantifiers\<close>
   654 
   655 syntax (ASCII)
   656   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   657   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3EX _<_./ _)"  [0, 0, 10] 10)
   658   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   659   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _<=_./ _)" [0, 0, 10] 10)
   660 
   661   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3ALL _>_./ _)"  [0, 0, 10] 10)
   662   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3EX _>_./ _)"  [0, 0, 10] 10)
   663   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _>=_./ _)" [0, 0, 10] 10)
   664   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _>=_./ _)" [0, 0, 10] 10)
   665 
   666 syntax
   667   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   668   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   669   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   670   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   671 
   672   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   673   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   674   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   675   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   676 
   677 syntax (input)
   678   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3! _<_./ _)"  [0, 0, 10] 10)
   679   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3? _<_./ _)"  [0, 0, 10] 10)
   680   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3! _<=_./ _)" [0, 0, 10] 10)
   681   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3? _<=_./ _)" [0, 0, 10] 10)
   682 
   683 translations
   684   "ALL x<y. P"   =>  "ALL x. x < y \<longrightarrow> P"
   685   "EX x<y. P"    =>  "EX x. x < y \<and> P"
   686   "ALL x<=y. P"  =>  "ALL x. x <= y \<longrightarrow> P"
   687   "EX x<=y. P"   =>  "EX x. x <= y \<and> P"
   688   "ALL x>y. P"   =>  "ALL x. x > y \<longrightarrow> P"
   689   "EX x>y. P"    =>  "EX x. x > y \<and> P"
   690   "ALL x>=y. P"  =>  "ALL x. x >= y \<longrightarrow> P"
   691   "EX x>=y. P"   =>  "EX x. x >= y \<and> P"
   692 
   693 print_translation \<open>
   694 let
   695   val All_binder = Mixfix.binder_name @{const_syntax All};
   696   val Ex_binder = Mixfix.binder_name @{const_syntax Ex};
   697   val impl = @{const_syntax HOL.implies};
   698   val conj = @{const_syntax HOL.conj};
   699   val less = @{const_syntax less};
   700   val less_eq = @{const_syntax less_eq};
   701 
   702   val trans =
   703    [((All_binder, impl, less),
   704     (@{syntax_const "_All_less"}, @{syntax_const "_All_greater"})),
   705     ((All_binder, impl, less_eq),
   706     (@{syntax_const "_All_less_eq"}, @{syntax_const "_All_greater_eq"})),
   707     ((Ex_binder, conj, less),
   708     (@{syntax_const "_Ex_less"}, @{syntax_const "_Ex_greater"})),
   709     ((Ex_binder, conj, less_eq),
   710     (@{syntax_const "_Ex_less_eq"}, @{syntax_const "_Ex_greater_eq"}))];
   711 
   712   fun matches_bound v t =
   713     (case t of
   714       Const (@{syntax_const "_bound"}, _) $ Free (v', _) => v = v'
   715     | _ => false);
   716   fun contains_var v = Term.exists_subterm (fn Free (x, _) => x = v | _ => false);
   717   fun mk x c n P = Syntax.const c $ Syntax_Trans.mark_bound_body x $ n $ P;
   718 
   719   fun tr' q = (q, fn _ =>
   720     (fn [Const (@{syntax_const "_bound"}, _) $ Free (v, T),
   721         Const (c, _) $ (Const (d, _) $ t $ u) $ P] =>
   722         (case AList.lookup (op =) trans (q, c, d) of
   723           NONE => raise Match
   724         | SOME (l, g) =>
   725             if matches_bound v t andalso not (contains_var v u) then mk (v, T) l u P
   726             else if matches_bound v u andalso not (contains_var v t) then mk (v, T) g t P
   727             else raise Match)
   728       | _ => raise Match));
   729 in [tr' All_binder, tr' Ex_binder] end
   730 \<close>
   731 
   732 
   733 subsection \<open>Transitivity reasoning\<close>
   734 
   735 context ord
   736 begin
   737 
   738 lemma ord_le_eq_trans: "a \<le> b \<Longrightarrow> b = c \<Longrightarrow> a \<le> c"
   739   by (rule subst)
   740 
   741 lemma ord_eq_le_trans: "a = b \<Longrightarrow> b \<le> c \<Longrightarrow> a \<le> c"
   742   by (rule ssubst)
   743 
   744 lemma ord_less_eq_trans: "a < b \<Longrightarrow> b = c \<Longrightarrow> a < c"
   745   by (rule subst)
   746 
   747 lemma ord_eq_less_trans: "a = b \<Longrightarrow> b < c \<Longrightarrow> a < c"
   748   by (rule ssubst)
   749 
   750 end
   751 
   752 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
   753   (!!x y. x < y ==> f x < f y) ==> f a < c"
   754 proof -
   755   assume r: "!!x y. x < y ==> f x < f y"
   756   assume "a < b" hence "f a < f b" by (rule r)
   757   also assume "f b < c"
   758   finally (less_trans) show ?thesis .
   759 qed
   760 
   761 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
   762   (!!x y. x < y ==> f x < f y) ==> a < f c"
   763 proof -
   764   assume r: "!!x y. x < y ==> f x < f y"
   765   assume "a < f b"
   766   also assume "b < c" hence "f b < f c" by (rule r)
   767   finally (less_trans) show ?thesis .
   768 qed
   769 
   770 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
   771   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
   772 proof -
   773   assume r: "!!x y. x <= y ==> f x <= f y"
   774   assume "a <= b" hence "f a <= f b" by (rule r)
   775   also assume "f b < c"
   776   finally (le_less_trans) show ?thesis .
   777 qed
   778 
   779 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
   780   (!!x y. x < y ==> f x < f y) ==> a < f c"
   781 proof -
   782   assume r: "!!x y. x < y ==> f x < f y"
   783   assume "a <= f b"
   784   also assume "b < c" hence "f b < f c" by (rule r)
   785   finally (le_less_trans) show ?thesis .
   786 qed
   787 
   788 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
   789   (!!x y. x < y ==> f x < f y) ==> f a < c"
   790 proof -
   791   assume r: "!!x y. x < y ==> f x < f y"
   792   assume "a < b" hence "f a < f b" by (rule r)
   793   also assume "f b <= c"
   794   finally (less_le_trans) show ?thesis .
   795 qed
   796 
   797 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
   798   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
   799 proof -
   800   assume r: "!!x y. x <= y ==> f x <= f y"
   801   assume "a < f b"
   802   also assume "b <= c" hence "f b <= f c" by (rule r)
   803   finally (less_le_trans) show ?thesis .
   804 qed
   805 
   806 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
   807   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   808 proof -
   809   assume r: "!!x y. x <= y ==> f x <= f y"
   810   assume "a <= f b"
   811   also assume "b <= c" hence "f b <= f c" by (rule r)
   812   finally (order_trans) show ?thesis .
   813 qed
   814 
   815 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
   816   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   817 proof -
   818   assume r: "!!x y. x <= y ==> f x <= f y"
   819   assume "a <= b" hence "f a <= f b" by (rule r)
   820   also assume "f b <= c"
   821   finally (order_trans) show ?thesis .
   822 qed
   823 
   824 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
   825   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   826 proof -
   827   assume r: "!!x y. x <= y ==> f x <= f y"
   828   assume "a <= b" hence "f a <= f b" by (rule r)
   829   also assume "f b = c"
   830   finally (ord_le_eq_trans) show ?thesis .
   831 qed
   832 
   833 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
   834   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   835 proof -
   836   assume r: "!!x y. x <= y ==> f x <= f y"
   837   assume "a = f b"
   838   also assume "b <= c" hence "f b <= f c" by (rule r)
   839   finally (ord_eq_le_trans) show ?thesis .
   840 qed
   841 
   842 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
   843   (!!x y. x < y ==> f x < f y) ==> f a < c"
   844 proof -
   845   assume r: "!!x y. x < y ==> f x < f y"
   846   assume "a < b" hence "f a < f b" by (rule r)
   847   also assume "f b = c"
   848   finally (ord_less_eq_trans) show ?thesis .
   849 qed
   850 
   851 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
   852   (!!x y. x < y ==> f x < f y) ==> a < f c"
   853 proof -
   854   assume r: "!!x y. x < y ==> f x < f y"
   855   assume "a = f b"
   856   also assume "b < c" hence "f b < f c" by (rule r)
   857   finally (ord_eq_less_trans) show ?thesis .
   858 qed
   859 
   860 text \<open>
   861   Note that this list of rules is in reverse order of priorities.
   862 \<close>
   863 
   864 lemmas [trans] =
   865   order_less_subst2
   866   order_less_subst1
   867   order_le_less_subst2
   868   order_le_less_subst1
   869   order_less_le_subst2
   870   order_less_le_subst1
   871   order_subst2
   872   order_subst1
   873   ord_le_eq_subst
   874   ord_eq_le_subst
   875   ord_less_eq_subst
   876   ord_eq_less_subst
   877   forw_subst
   878   back_subst
   879   rev_mp
   880   mp
   881 
   882 lemmas (in order) [trans] =
   883   neq_le_trans
   884   le_neq_trans
   885 
   886 lemmas (in preorder) [trans] =
   887   less_trans
   888   less_asym'
   889   le_less_trans
   890   less_le_trans
   891   order_trans
   892 
   893 lemmas (in order) [trans] =
   894   antisym
   895 
   896 lemmas (in ord) [trans] =
   897   ord_le_eq_trans
   898   ord_eq_le_trans
   899   ord_less_eq_trans
   900   ord_eq_less_trans
   901 
   902 lemmas [trans] =
   903   trans
   904 
   905 lemmas order_trans_rules =
   906   order_less_subst2
   907   order_less_subst1
   908   order_le_less_subst2
   909   order_le_less_subst1
   910   order_less_le_subst2
   911   order_less_le_subst1
   912   order_subst2
   913   order_subst1
   914   ord_le_eq_subst
   915   ord_eq_le_subst
   916   ord_less_eq_subst
   917   ord_eq_less_subst
   918   forw_subst
   919   back_subst
   920   rev_mp
   921   mp
   922   neq_le_trans
   923   le_neq_trans
   924   less_trans
   925   less_asym'
   926   le_less_trans
   927   less_le_trans
   928   order_trans
   929   antisym
   930   ord_le_eq_trans
   931   ord_eq_le_trans
   932   ord_less_eq_trans
   933   ord_eq_less_trans
   934   trans
   935 
   936 text \<open>These support proving chains of decreasing inequalities
   937     a >= b >= c ... in Isar proofs.\<close>
   938 
   939 lemma xt1 [no_atp]:
   940   "a = b ==> b > c ==> a > c"
   941   "a > b ==> b = c ==> a > c"
   942   "a = b ==> b >= c ==> a >= c"
   943   "a >= b ==> b = c ==> a >= c"
   944   "(x::'a::order) >= y ==> y >= x ==> x = y"
   945   "(x::'a::order) >= y ==> y >= z ==> x >= z"
   946   "(x::'a::order) > y ==> y >= z ==> x > z"
   947   "(x::'a::order) >= y ==> y > z ==> x > z"
   948   "(a::'a::order) > b ==> b > a ==> P"
   949   "(x::'a::order) > y ==> y > z ==> x > z"
   950   "(a::'a::order) >= b ==> a ~= b ==> a > b"
   951   "(a::'a::order) ~= b ==> a >= b ==> a > b"
   952   "a = f b ==> b > c ==> (!!x y. x > y ==> f x > f y) ==> a > f c"
   953   "a > b ==> f b = c ==> (!!x y. x > y ==> f x > f y) ==> f a > c"
   954   "a = f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   955   "a >= b ==> f b = c ==> (!! x y. x >= y ==> f x >= f y) ==> f a >= c"
   956   by auto
   957 
   958 lemma xt2 [no_atp]:
   959   "(a::'a::order) >= f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   960 by (subgoal_tac "f b >= f c", force, force)
   961 
   962 lemma xt3 [no_atp]: "(a::'a::order) >= b ==> (f b::'b::order) >= c ==>
   963     (!!x y. x >= y ==> f x >= f y) ==> f a >= c"
   964 by (subgoal_tac "f a >= f b", force, force)
   965 
   966 lemma xt4 [no_atp]: "(a::'a::order) > f b ==> (b::'b::order) >= c ==>
   967   (!!x y. x >= y ==> f x >= f y) ==> a > f c"
   968 by (subgoal_tac "f b >= f c", force, force)
   969 
   970 lemma xt5 [no_atp]: "(a::'a::order) > b ==> (f b::'b::order) >= c==>
   971     (!!x y. x > y ==> f x > f y) ==> f a > c"
   972 by (subgoal_tac "f a > f b", force, force)
   973 
   974 lemma xt6 [no_atp]: "(a::'a::order) >= f b ==> b > c ==>
   975     (!!x y. x > y ==> f x > f y) ==> a > f c"
   976 by (subgoal_tac "f b > f c", force, force)
   977 
   978 lemma xt7 [no_atp]: "(a::'a::order) >= b ==> (f b::'b::order) > c ==>
   979     (!!x y. x >= y ==> f x >= f y) ==> f a > c"
   980 by (subgoal_tac "f a >= f b", force, force)
   981 
   982 lemma xt8 [no_atp]: "(a::'a::order) > f b ==> (b::'b::order) > c ==>
   983     (!!x y. x > y ==> f x > f y) ==> a > f c"
   984 by (subgoal_tac "f b > f c", force, force)
   985 
   986 lemma xt9 [no_atp]: "(a::'a::order) > b ==> (f b::'b::order) > c ==>
   987     (!!x y. x > y ==> f x > f y) ==> f a > c"
   988 by (subgoal_tac "f a > f b", force, force)
   989 
   990 lemmas xtrans = xt1 xt2 xt3 xt4 xt5 xt6 xt7 xt8 xt9
   991 
   992 (*
   993   Since "a >= b" abbreviates "b <= a", the abbreviation "..." stands
   994   for the wrong thing in an Isar proof.
   995 
   996   The extra transitivity rules can be used as follows:
   997 
   998 lemma "(a::'a::order) > z"
   999 proof -
  1000   have "a >= b" (is "_ >= ?rhs")
  1001     sorry
  1002   also have "?rhs >= c" (is "_ >= ?rhs")
  1003     sorry
  1004   also (xtrans) have "?rhs = d" (is "_ = ?rhs")
  1005     sorry
  1006   also (xtrans) have "?rhs >= e" (is "_ >= ?rhs")
  1007     sorry
  1008   also (xtrans) have "?rhs > f" (is "_ > ?rhs")
  1009     sorry
  1010   also (xtrans) have "?rhs > z"
  1011     sorry
  1012   finally (xtrans) show ?thesis .
  1013 qed
  1014 
  1015   Alternatively, one can use "declare xtrans [trans]" and then
  1016   leave out the "(xtrans)" above.
  1017 *)
  1018 
  1019 
  1020 subsection \<open>Monotonicity\<close>
  1021 
  1022 context order
  1023 begin
  1024 
  1025 definition mono :: "('a \<Rightarrow> 'b::order) \<Rightarrow> bool" where
  1026   "mono f \<longleftrightarrow> (\<forall>x y. x \<le> y \<longrightarrow> f x \<le> f y)"
  1027 
  1028 lemma monoI [intro?]:
  1029   fixes f :: "'a \<Rightarrow> 'b::order"
  1030   shows "(\<And>x y. x \<le> y \<Longrightarrow> f x \<le> f y) \<Longrightarrow> mono f"
  1031   unfolding mono_def by iprover
  1032 
  1033 lemma monoD [dest?]:
  1034   fixes f :: "'a \<Rightarrow> 'b::order"
  1035   shows "mono f \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1036   unfolding mono_def by iprover
  1037 
  1038 lemma monoE:
  1039   fixes f :: "'a \<Rightarrow> 'b::order"
  1040   assumes "mono f"
  1041   assumes "x \<le> y"
  1042   obtains "f x \<le> f y"
  1043 proof
  1044   from assms show "f x \<le> f y" by (simp add: mono_def)
  1045 qed
  1046 
  1047 definition antimono :: "('a \<Rightarrow> 'b::order) \<Rightarrow> bool" where
  1048   "antimono f \<longleftrightarrow> (\<forall>x y. x \<le> y \<longrightarrow> f x \<ge> f y)"
  1049 
  1050 lemma antimonoI [intro?]:
  1051   fixes f :: "'a \<Rightarrow> 'b::order"
  1052   shows "(\<And>x y. x \<le> y \<Longrightarrow> f x \<ge> f y) \<Longrightarrow> antimono f"
  1053   unfolding antimono_def by iprover
  1054 
  1055 lemma antimonoD [dest?]:
  1056   fixes f :: "'a \<Rightarrow> 'b::order"
  1057   shows "antimono f \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<ge> f y"
  1058   unfolding antimono_def by iprover
  1059 
  1060 lemma antimonoE:
  1061   fixes f :: "'a \<Rightarrow> 'b::order"
  1062   assumes "antimono f"
  1063   assumes "x \<le> y"
  1064   obtains "f x \<ge> f y"
  1065 proof
  1066   from assms show "f x \<ge> f y" by (simp add: antimono_def)
  1067 qed
  1068 
  1069 definition strict_mono :: "('a \<Rightarrow> 'b::order) \<Rightarrow> bool" where
  1070   "strict_mono f \<longleftrightarrow> (\<forall>x y. x < y \<longrightarrow> f x < f y)"
  1071 
  1072 lemma strict_monoI [intro?]:
  1073   assumes "\<And>x y. x < y \<Longrightarrow> f x < f y"
  1074   shows "strict_mono f"
  1075   using assms unfolding strict_mono_def by auto
  1076 
  1077 lemma strict_monoD [dest?]:
  1078   "strict_mono f \<Longrightarrow> x < y \<Longrightarrow> f x < f y"
  1079   unfolding strict_mono_def by auto
  1080 
  1081 lemma strict_mono_mono [dest?]:
  1082   assumes "strict_mono f"
  1083   shows "mono f"
  1084 proof (rule monoI)
  1085   fix x y
  1086   assume "x \<le> y"
  1087   show "f x \<le> f y"
  1088   proof (cases "x = y")
  1089     case True then show ?thesis by simp
  1090   next
  1091     case False with \<open>x \<le> y\<close> have "x < y" by simp
  1092     with assms strict_monoD have "f x < f y" by auto
  1093     then show ?thesis by simp
  1094   qed
  1095 qed
  1096 
  1097 end
  1098 
  1099 context linorder
  1100 begin
  1101 
  1102 lemma mono_invE:
  1103   fixes f :: "'a \<Rightarrow> 'b::order"
  1104   assumes "mono f"
  1105   assumes "f x < f y"
  1106   obtains "x \<le> y"
  1107 proof
  1108   show "x \<le> y"
  1109   proof (rule ccontr)
  1110     assume "\<not> x \<le> y"
  1111     then have "y \<le> x" by simp
  1112     with \<open>mono f\<close> obtain "f y \<le> f x" by (rule monoE)
  1113     with \<open>f x < f y\<close> show False by simp
  1114   qed
  1115 qed
  1116 
  1117 lemma strict_mono_eq:
  1118   assumes "strict_mono f"
  1119   shows "f x = f y \<longleftrightarrow> x = y"
  1120 proof
  1121   assume "f x = f y"
  1122   show "x = y" proof (cases x y rule: linorder_cases)
  1123     case less with assms strict_monoD have "f x < f y" by auto
  1124     with \<open>f x = f y\<close> show ?thesis by simp
  1125   next
  1126     case equal then show ?thesis .
  1127   next
  1128     case greater with assms strict_monoD have "f y < f x" by auto
  1129     with \<open>f x = f y\<close> show ?thesis by simp
  1130   qed
  1131 qed simp
  1132 
  1133 lemma strict_mono_less_eq:
  1134   assumes "strict_mono f"
  1135   shows "f x \<le> f y \<longleftrightarrow> x \<le> y"
  1136 proof
  1137   assume "x \<le> y"
  1138   with assms strict_mono_mono monoD show "f x \<le> f y" by auto
  1139 next
  1140   assume "f x \<le> f y"
  1141   show "x \<le> y" proof (rule ccontr)
  1142     assume "\<not> x \<le> y" then have "y < x" by simp
  1143     with assms strict_monoD have "f y < f x" by auto
  1144     with \<open>f x \<le> f y\<close> show False by simp
  1145   qed
  1146 qed
  1147 
  1148 lemma strict_mono_less:
  1149   assumes "strict_mono f"
  1150   shows "f x < f y \<longleftrightarrow> x < y"
  1151   using assms
  1152     by (auto simp add: less_le Orderings.less_le strict_mono_eq strict_mono_less_eq)
  1153 
  1154 end
  1155 
  1156 
  1157 subsection \<open>min and max -- fundamental\<close>
  1158 
  1159 definition (in ord) min :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
  1160   "min a b = (if a \<le> b then a else b)"
  1161 
  1162 definition (in ord) max :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
  1163   "max a b = (if a \<le> b then b else a)"
  1164 
  1165 lemma min_absorb1: "x \<le> y \<Longrightarrow> min x y = x"
  1166   by (simp add: min_def)
  1167 
  1168 lemma max_absorb2: "x \<le> y \<Longrightarrow> max x y = y"
  1169   by (simp add: max_def)
  1170 
  1171 lemma min_absorb2: "(y::'a::order) \<le> x \<Longrightarrow> min x y = y"
  1172   by (simp add:min_def)
  1173 
  1174 lemma max_absorb1: "(y::'a::order) \<le> x \<Longrightarrow> max x y = x"
  1175   by (simp add: max_def)
  1176 
  1177 lemma max_min_same [simp]:
  1178   fixes x y :: "'a :: linorder"
  1179   shows "max x (min x y) = x" "max (min x y) x = x" "max (min x y) y = y" "max y (min x y) = y"
  1180 by(auto simp add: max_def min_def)
  1181 
  1182 subsection \<open>(Unique) top and bottom elements\<close>
  1183 
  1184 class bot =
  1185   fixes bot :: 'a ("\<bottom>")
  1186 
  1187 class order_bot = order + bot +
  1188   assumes bot_least: "\<bottom> \<le> a"
  1189 begin
  1190 
  1191 sublocale bot: ordering_top greater_eq greater bot
  1192   by standard (fact bot_least)
  1193 
  1194 lemma le_bot:
  1195   "a \<le> \<bottom> \<Longrightarrow> a = \<bottom>"
  1196   by (fact bot.extremum_uniqueI)
  1197 
  1198 lemma bot_unique:
  1199   "a \<le> \<bottom> \<longleftrightarrow> a = \<bottom>"
  1200   by (fact bot.extremum_unique)
  1201 
  1202 lemma not_less_bot:
  1203   "\<not> a < \<bottom>"
  1204   by (fact bot.extremum_strict)
  1205 
  1206 lemma bot_less:
  1207   "a \<noteq> \<bottom> \<longleftrightarrow> \<bottom> < a"
  1208   by (fact bot.not_eq_extremum)
  1209 
  1210 end
  1211 
  1212 class top =
  1213   fixes top :: 'a ("\<top>")
  1214 
  1215 class order_top = order + top +
  1216   assumes top_greatest: "a \<le> \<top>"
  1217 begin
  1218 
  1219 sublocale top: ordering_top less_eq less top
  1220   by standard (fact top_greatest)
  1221 
  1222 lemma top_le:
  1223   "\<top> \<le> a \<Longrightarrow> a = \<top>"
  1224   by (fact top.extremum_uniqueI)
  1225 
  1226 lemma top_unique:
  1227   "\<top> \<le> a \<longleftrightarrow> a = \<top>"
  1228   by (fact top.extremum_unique)
  1229 
  1230 lemma not_top_less:
  1231   "\<not> \<top> < a"
  1232   by (fact top.extremum_strict)
  1233 
  1234 lemma less_top:
  1235   "a \<noteq> \<top> \<longleftrightarrow> a < \<top>"
  1236   by (fact top.not_eq_extremum)
  1237 
  1238 end
  1239 
  1240 
  1241 subsection \<open>Dense orders\<close>
  1242 
  1243 class dense_order = order +
  1244   assumes dense: "x < y \<Longrightarrow> (\<exists>z. x < z \<and> z < y)"
  1245 
  1246 class dense_linorder = linorder + dense_order
  1247 begin
  1248 
  1249 lemma dense_le:
  1250   fixes y z :: 'a
  1251   assumes "\<And>x. x < y \<Longrightarrow> x \<le> z"
  1252   shows "y \<le> z"
  1253 proof (rule ccontr)
  1254   assume "\<not> ?thesis"
  1255   hence "z < y" by simp
  1256   from dense[OF this]
  1257   obtain x where "x < y" and "z < x" by safe
  1258   moreover have "x \<le> z" using assms[OF \<open>x < y\<close>] .
  1259   ultimately show False by auto
  1260 qed
  1261 
  1262 lemma dense_le_bounded:
  1263   fixes x y z :: 'a
  1264   assumes "x < y"
  1265   assumes *: "\<And>w. \<lbrakk> x < w ; w < y \<rbrakk> \<Longrightarrow> w \<le> z"
  1266   shows "y \<le> z"
  1267 proof (rule dense_le)
  1268   fix w assume "w < y"
  1269   from dense[OF \<open>x < y\<close>] obtain u where "x < u" "u < y" by safe
  1270   from linear[of u w]
  1271   show "w \<le> z"
  1272   proof (rule disjE)
  1273     assume "u \<le> w"
  1274     from less_le_trans[OF \<open>x < u\<close> \<open>u \<le> w\<close>] \<open>w < y\<close>
  1275     show "w \<le> z" by (rule *)
  1276   next
  1277     assume "w \<le> u"
  1278     from \<open>w \<le> u\<close> *[OF \<open>x < u\<close> \<open>u < y\<close>]
  1279     show "w \<le> z" by (rule order_trans)
  1280   qed
  1281 qed
  1282 
  1283 lemma dense_ge:
  1284   fixes y z :: 'a
  1285   assumes "\<And>x. z < x \<Longrightarrow> y \<le> x"
  1286   shows "y \<le> z"
  1287 proof (rule ccontr)
  1288   assume "\<not> ?thesis"
  1289   hence "z < y" by simp
  1290   from dense[OF this]
  1291   obtain x where "x < y" and "z < x" by safe
  1292   moreover have "y \<le> x" using assms[OF \<open>z < x\<close>] .
  1293   ultimately show False by auto
  1294 qed
  1295 
  1296 lemma dense_ge_bounded:
  1297   fixes x y z :: 'a
  1298   assumes "z < x"
  1299   assumes *: "\<And>w. \<lbrakk> z < w ; w < x \<rbrakk> \<Longrightarrow> y \<le> w"
  1300   shows "y \<le> z"
  1301 proof (rule dense_ge)
  1302   fix w assume "z < w"
  1303   from dense[OF \<open>z < x\<close>] obtain u where "z < u" "u < x" by safe
  1304   from linear[of u w]
  1305   show "y \<le> w"
  1306   proof (rule disjE)
  1307     assume "w \<le> u"
  1308     from \<open>z < w\<close> le_less_trans[OF \<open>w \<le> u\<close> \<open>u < x\<close>]
  1309     show "y \<le> w" by (rule *)
  1310   next
  1311     assume "u \<le> w"
  1312     from *[OF \<open>z < u\<close> \<open>u < x\<close>] \<open>u \<le> w\<close>
  1313     show "y \<le> w" by (rule order_trans)
  1314   qed
  1315 qed
  1316 
  1317 end
  1318 
  1319 class no_top = order +
  1320   assumes gt_ex: "\<exists>y. x < y"
  1321 
  1322 class no_bot = order +
  1323   assumes lt_ex: "\<exists>y. y < x"
  1324 
  1325 class unbounded_dense_linorder = dense_linorder + no_top + no_bot
  1326 
  1327 
  1328 subsection \<open>Wellorders\<close>
  1329 
  1330 class wellorder = linorder +
  1331   assumes less_induct [case_names less]: "(\<And>x. (\<And>y. y < x \<Longrightarrow> P y) \<Longrightarrow> P x) \<Longrightarrow> P a"
  1332 begin
  1333 
  1334 lemma wellorder_Least_lemma:
  1335   fixes k :: 'a
  1336   assumes "P k"
  1337   shows LeastI: "P (LEAST x. P x)" and Least_le: "(LEAST x. P x) \<le> k"
  1338 proof -
  1339   have "P (LEAST x. P x) \<and> (LEAST x. P x) \<le> k"
  1340   using assms proof (induct k rule: less_induct)
  1341     case (less x) then have "P x" by simp
  1342     show ?case proof (rule classical)
  1343       assume assm: "\<not> (P (LEAST a. P a) \<and> (LEAST a. P a) \<le> x)"
  1344       have "\<And>y. P y \<Longrightarrow> x \<le> y"
  1345       proof (rule classical)
  1346         fix y
  1347         assume "P y" and "\<not> x \<le> y"
  1348         with less have "P (LEAST a. P a)" and "(LEAST a. P a) \<le> y"
  1349           by (auto simp add: not_le)
  1350         with assm have "x < (LEAST a. P a)" and "(LEAST a. P a) \<le> y"
  1351           by auto
  1352         then show "x \<le> y" by auto
  1353       qed
  1354       with \<open>P x\<close> have Least: "(LEAST a. P a) = x"
  1355         by (rule Least_equality)
  1356       with \<open>P x\<close> show ?thesis by simp
  1357     qed
  1358   qed
  1359   then show "P (LEAST x. P x)" and "(LEAST x. P x) \<le> k" by auto
  1360 qed
  1361 
  1362 \<comment> "The following 3 lemmas are due to Brian Huffman"
  1363 lemma LeastI_ex: "\<exists>x. P x \<Longrightarrow> P (Least P)"
  1364   by (erule exE) (erule LeastI)
  1365 
  1366 lemma LeastI2:
  1367   "P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (Least P)"
  1368   by (blast intro: LeastI)
  1369 
  1370 lemma LeastI2_ex:
  1371   "\<exists>a. P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (Least P)"
  1372   by (blast intro: LeastI_ex)
  1373 
  1374 lemma LeastI2_wellorder:
  1375   assumes "P a"
  1376   and "\<And>a. \<lbrakk> P a; \<forall>b. P b \<longrightarrow> a \<le> b \<rbrakk> \<Longrightarrow> Q a"
  1377   shows "Q (Least P)"
  1378 proof (rule LeastI2_order)
  1379   show "P (Least P)" using \<open>P a\<close> by (rule LeastI)
  1380 next
  1381   fix y assume "P y" thus "Least P \<le> y" by (rule Least_le)
  1382 next
  1383   fix x assume "P x" "\<forall>y. P y \<longrightarrow> x \<le> y" thus "Q x" by (rule assms(2))
  1384 qed
  1385 
  1386 lemma LeastI2_wellorder_ex:
  1387   assumes "\<exists>x. P x"
  1388   and "\<And>a. \<lbrakk> P a; \<forall>b. P b \<longrightarrow> a \<le> b \<rbrakk> \<Longrightarrow> Q a"
  1389   shows "Q (Least P)"
  1390 using assms by clarify (blast intro!: LeastI2_wellorder)
  1391 
  1392 lemma not_less_Least: "k < (LEAST x. P x) \<Longrightarrow> \<not> P k"
  1393 apply (simp add: not_le [symmetric])
  1394 apply (erule contrapos_nn)
  1395 apply (erule Least_le)
  1396 done
  1397 
  1398 end
  1399 
  1400 
  1401 subsection \<open>Order on @{typ bool}\<close>
  1402 
  1403 instantiation bool :: "{order_bot, order_top, linorder}"
  1404 begin
  1405 
  1406 definition
  1407   le_bool_def [simp]: "P \<le> Q \<longleftrightarrow> P \<longrightarrow> Q"
  1408 
  1409 definition
  1410   [simp]: "(P::bool) < Q \<longleftrightarrow> \<not> P \<and> Q"
  1411 
  1412 definition
  1413   [simp]: "\<bottom> \<longleftrightarrow> False"
  1414 
  1415 definition
  1416   [simp]: "\<top> \<longleftrightarrow> True"
  1417 
  1418 instance proof
  1419 qed auto
  1420 
  1421 end
  1422 
  1423 lemma le_boolI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<le> Q"
  1424   by simp
  1425 
  1426 lemma le_boolI': "P \<longrightarrow> Q \<Longrightarrow> P \<le> Q"
  1427   by simp
  1428 
  1429 lemma le_boolE: "P \<le> Q \<Longrightarrow> P \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
  1430   by simp
  1431 
  1432 lemma le_boolD: "P \<le> Q \<Longrightarrow> P \<longrightarrow> Q"
  1433   by simp
  1434 
  1435 lemma bot_boolE: "\<bottom> \<Longrightarrow> P"
  1436   by simp
  1437 
  1438 lemma top_boolI: \<top>
  1439   by simp
  1440 
  1441 lemma [code]:
  1442   "False \<le> b \<longleftrightarrow> True"
  1443   "True \<le> b \<longleftrightarrow> b"
  1444   "False < b \<longleftrightarrow> b"
  1445   "True < b \<longleftrightarrow> False"
  1446   by simp_all
  1447 
  1448 
  1449 subsection \<open>Order on @{typ "_ \<Rightarrow> _"}\<close>
  1450 
  1451 instantiation "fun" :: (type, ord) ord
  1452 begin
  1453 
  1454 definition
  1455   le_fun_def: "f \<le> g \<longleftrightarrow> (\<forall>x. f x \<le> g x)"
  1456 
  1457 definition
  1458   "(f::'a \<Rightarrow> 'b) < g \<longleftrightarrow> f \<le> g \<and> \<not> (g \<le> f)"
  1459 
  1460 instance ..
  1461 
  1462 end
  1463 
  1464 instance "fun" :: (type, preorder) preorder proof
  1465 qed (auto simp add: le_fun_def less_fun_def
  1466   intro: order_trans antisym)
  1467 
  1468 instance "fun" :: (type, order) order proof
  1469 qed (auto simp add: le_fun_def intro: antisym)
  1470 
  1471 instantiation "fun" :: (type, bot) bot
  1472 begin
  1473 
  1474 definition
  1475   "\<bottom> = (\<lambda>x. \<bottom>)"
  1476 
  1477 instance ..
  1478 
  1479 end
  1480 
  1481 instantiation "fun" :: (type, order_bot) order_bot
  1482 begin
  1483 
  1484 lemma bot_apply [simp, code]:
  1485   "\<bottom> x = \<bottom>"
  1486   by (simp add: bot_fun_def)
  1487 
  1488 instance proof
  1489 qed (simp add: le_fun_def)
  1490 
  1491 end
  1492 
  1493 instantiation "fun" :: (type, top) top
  1494 begin
  1495 
  1496 definition
  1497   [no_atp]: "\<top> = (\<lambda>x. \<top>)"
  1498 
  1499 instance ..
  1500 
  1501 end
  1502 
  1503 instantiation "fun" :: (type, order_top) order_top
  1504 begin
  1505 
  1506 lemma top_apply [simp, code]:
  1507   "\<top> x = \<top>"
  1508   by (simp add: top_fun_def)
  1509 
  1510 instance proof
  1511 qed (simp add: le_fun_def)
  1512 
  1513 end
  1514 
  1515 lemma le_funI: "(\<And>x. f x \<le> g x) \<Longrightarrow> f \<le> g"
  1516   unfolding le_fun_def by simp
  1517 
  1518 lemma le_funE: "f \<le> g \<Longrightarrow> (f x \<le> g x \<Longrightarrow> P) \<Longrightarrow> P"
  1519   unfolding le_fun_def by simp
  1520 
  1521 lemma le_funD: "f \<le> g \<Longrightarrow> f x \<le> g x"
  1522   by (rule le_funE)
  1523 
  1524 lemma mono_compose: "mono Q \<Longrightarrow> mono (\<lambda>i x. Q i (f x))"
  1525   unfolding mono_def le_fun_def by auto
  1526 
  1527 
  1528 subsection \<open>Order on unary and binary predicates\<close>
  1529 
  1530 lemma predicate1I:
  1531   assumes PQ: "\<And>x. P x \<Longrightarrow> Q x"
  1532   shows "P \<le> Q"
  1533   apply (rule le_funI)
  1534   apply (rule le_boolI)
  1535   apply (rule PQ)
  1536   apply assumption
  1537   done
  1538 
  1539 lemma predicate1D:
  1540   "P \<le> Q \<Longrightarrow> P x \<Longrightarrow> Q x"
  1541   apply (erule le_funE)
  1542   apply (erule le_boolE)
  1543   apply assumption+
  1544   done
  1545 
  1546 lemma rev_predicate1D:
  1547   "P x \<Longrightarrow> P \<le> Q \<Longrightarrow> Q x"
  1548   by (rule predicate1D)
  1549 
  1550 lemma predicate2I:
  1551   assumes PQ: "\<And>x y. P x y \<Longrightarrow> Q x y"
  1552   shows "P \<le> Q"
  1553   apply (rule le_funI)+
  1554   apply (rule le_boolI)
  1555   apply (rule PQ)
  1556   apply assumption
  1557   done
  1558 
  1559 lemma predicate2D:
  1560   "P \<le> Q \<Longrightarrow> P x y \<Longrightarrow> Q x y"
  1561   apply (erule le_funE)+
  1562   apply (erule le_boolE)
  1563   apply assumption+
  1564   done
  1565 
  1566 lemma rev_predicate2D:
  1567   "P x y \<Longrightarrow> P \<le> Q \<Longrightarrow> Q x y"
  1568   by (rule predicate2D)
  1569 
  1570 lemma bot1E [no_atp]: "\<bottom> x \<Longrightarrow> P"
  1571   by (simp add: bot_fun_def)
  1572 
  1573 lemma bot2E: "\<bottom> x y \<Longrightarrow> P"
  1574   by (simp add: bot_fun_def)
  1575 
  1576 lemma top1I: "\<top> x"
  1577   by (simp add: top_fun_def)
  1578 
  1579 lemma top2I: "\<top> x y"
  1580   by (simp add: top_fun_def)
  1581 
  1582 
  1583 subsection \<open>Name duplicates\<close>
  1584 
  1585 lemmas order_eq_refl = preorder_class.eq_refl
  1586 lemmas order_less_irrefl = preorder_class.less_irrefl
  1587 lemmas order_less_imp_le = preorder_class.less_imp_le
  1588 lemmas order_less_not_sym = preorder_class.less_not_sym
  1589 lemmas order_less_asym = preorder_class.less_asym
  1590 lemmas order_less_trans = preorder_class.less_trans
  1591 lemmas order_le_less_trans = preorder_class.le_less_trans
  1592 lemmas order_less_le_trans = preorder_class.less_le_trans
  1593 lemmas order_less_imp_not_less = preorder_class.less_imp_not_less
  1594 lemmas order_less_imp_triv = preorder_class.less_imp_triv
  1595 lemmas order_less_asym' = preorder_class.less_asym'
  1596 
  1597 lemmas order_less_le = order_class.less_le
  1598 lemmas order_le_less = order_class.le_less
  1599 lemmas order_le_imp_less_or_eq = order_class.le_imp_less_or_eq
  1600 lemmas order_less_imp_not_eq = order_class.less_imp_not_eq
  1601 lemmas order_less_imp_not_eq2 = order_class.less_imp_not_eq2
  1602 lemmas order_neq_le_trans = order_class.neq_le_trans
  1603 lemmas order_le_neq_trans = order_class.le_neq_trans
  1604 lemmas order_antisym = order_class.antisym
  1605 lemmas order_eq_iff = order_class.eq_iff
  1606 lemmas order_antisym_conv = order_class.antisym_conv
  1607 
  1608 lemmas linorder_linear = linorder_class.linear
  1609 lemmas linorder_less_linear = linorder_class.less_linear
  1610 lemmas linorder_le_less_linear = linorder_class.le_less_linear
  1611 lemmas linorder_le_cases = linorder_class.le_cases
  1612 lemmas linorder_not_less = linorder_class.not_less
  1613 lemmas linorder_not_le = linorder_class.not_le
  1614 lemmas linorder_neq_iff = linorder_class.neq_iff
  1615 lemmas linorder_neqE = linorder_class.neqE
  1616 lemmas linorder_antisym_conv1 = linorder_class.antisym_conv1
  1617 lemmas linorder_antisym_conv2 = linorder_class.antisym_conv2
  1618 lemmas linorder_antisym_conv3 = linorder_class.antisym_conv3
  1619 
  1620 end