src/Pure/library.ML
author wenzelm
Thu Nov 23 00:52:07 2006 +0100 (2006-11-23)
changeset 21479 63e7eb863ae6
parent 21395 f34ac19659ae
child 21565 bd28361f4c5b
permissions -rw-r--r--
moved string_of_pair/list/option to structure ML_Syntax;
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, balanced trees, orders, current directory, misc.
     8 
     9 See also General/basics.ML for the most fundamental concepts.
    10 *)
    11 
    12 infix 1 |>>>
    13 infix 2 ?
    14 infix 3 o oo ooo oooo
    15 infix 4 ~~ upto downto
    16 infix orf andf \ \\ mem mem_int mem_string union union_int
    17   union_string inter inter_int inter_string subset subset_int subset_string
    18 
    19 signature BASIC_LIBRARY =
    20 sig
    21   (*functions*)
    22   val I: 'a -> 'a
    23   val K: 'a -> 'b -> 'a
    24   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    25   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    26   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    27   val ? : ('a -> bool) * ('a -> 'a) -> 'a -> 'a
    28   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    29   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    30   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    31   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    32 
    33   (*exceptions*)
    34   exception EXCEPTION of exn * string
    35   val do_transform_failure: bool ref
    36   val transform_failure: (exn -> exn) -> ('a -> 'b) -> 'a -> 'b
    37   datatype 'a result = Result of 'a | Exn of exn
    38   val capture: ('a -> 'b) -> 'a -> 'b result
    39   val release: 'a result -> 'a
    40   val get_result: 'a result -> 'a option
    41   val get_exn: 'a result -> exn option
    42 
    43   (*errors*)
    44   exception SYS_ERROR of string
    45   val sys_error: string -> 'a
    46   exception ERROR of string
    47   val error: string -> 'a
    48   val cat_error: string -> string -> 'a
    49   val assert: bool -> string -> unit
    50   val deny: bool -> string -> unit
    51   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    52 
    53   (*pairs*)
    54   val pair: 'a -> 'b -> 'a * 'b
    55   val rpair: 'a -> 'b -> 'b * 'a
    56   val fst: 'a * 'b -> 'a
    57   val snd: 'a * 'b -> 'b
    58   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    59   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    60   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    61   val swap: 'a * 'b -> 'b * 'a
    62   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    63   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    64   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    65 
    66   (*booleans*)
    67   val equal: ''a -> ''a -> bool
    68   val not_equal: ''a -> ''a -> bool
    69   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    70   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    71   val exists: ('a -> bool) -> 'a list -> bool
    72   val forall: ('a -> bool) -> 'a list -> bool
    73   val set: bool ref -> bool
    74   val reset: bool ref -> bool
    75   val toggle: bool ref -> bool
    76   val change: 'a ref -> ('a -> 'a) -> unit
    77   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    78   val conditional: bool -> (unit -> unit) -> unit
    79 
    80   (*lists*)
    81   exception UnequalLengths
    82   val single: 'a -> 'a list
    83   val the_single: 'a list -> 'a
    84   val singleton: ('a list -> 'b list) -> 'a -> 'b
    85   val apply: ('a -> 'a) list -> 'a -> 'a
    86   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    87   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    88   val flat: 'a list list -> 'a list
    89   val unflat: 'a list list -> 'b list -> 'b list list
    90   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    91   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    92   val maps: ('a -> 'b list) -> 'a list -> 'b list
    93   val chop: int -> 'a list -> 'a list * 'a list
    94   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    95   val nth: 'a list -> int -> 'a
    96   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    97   val nth_list: 'a list list -> int -> 'a list
    98   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    99   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
   100   val split_last: 'a list -> 'a list * 'a
   101   val find_index: ('a -> bool) -> 'a list -> int
   102   val find_index_eq: ''a -> ''a list -> int
   103   val find_first: ('a -> bool) -> 'a list -> 'a option
   104   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
   105   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   106   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   107   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   108   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   109   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   110   val ~~ : 'a list * 'b list -> ('a * 'b) list
   111   val split_list: ('a * 'b) list -> 'a list * 'b list
   112   val separate: 'a -> 'a list -> 'a list
   113   val replicate: int -> 'a -> 'a list
   114   val multiply: 'a list -> 'a list list -> 'a list list
   115   val product: 'a list -> 'b list -> ('a * 'b) list
   116   val filter: ('a -> bool) -> 'a list -> 'a list
   117   val filter_out: ('a -> bool) -> 'a list -> 'a list
   118   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
   119   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   120   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   121   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   122   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   123   val prefixes1: 'a list -> 'a list list
   124   val prefixes: 'a list -> 'a list list
   125   val suffixes1: 'a list -> 'a list list
   126   val suffixes: 'a list -> 'a list list
   127 
   128   (*integers*)
   129   val gcd: IntInf.int * IntInf.int -> IntInf.int
   130   val lcm: IntInf.int * IntInf.int -> IntInf.int
   131   val inc: int ref -> int
   132   val dec: int ref -> int
   133   val upto: int * int -> int list
   134   val downto: int * int -> int list
   135   val downto0: int list * int -> bool
   136   val radixpand: int * int -> int list
   137   val radixstring: int * string * int -> string
   138   val string_of_int: int -> string
   139   val string_of_indexname: string * int -> string
   140   val read_intinf: int -> string list -> IntInf.int * string list
   141   val read_int: string list -> int * string list
   142   val oct_char: string -> string
   143 
   144   (*strings*)
   145   val nth_string: string -> int -> string
   146   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   147   val exists_string: (string -> bool) -> string -> bool
   148   val forall_string: (string -> bool) -> string -> bool
   149   val enclose: string -> string -> string -> string
   150   val unenclose: string -> string
   151   val quote: string -> string
   152   val space_implode: string -> string list -> string
   153   val commas: string list -> string
   154   val commas_quote: string list -> string
   155   val cat_lines: string list -> string
   156   val space_explode: string -> string -> string list
   157   val split_lines: string -> string list
   158   val prefix_lines: string -> string -> string
   159   val untabify: string list -> string list
   160   val prefix: string -> string -> string
   161   val suffix: string -> string -> string
   162   val unprefix: string -> string -> string
   163   val unsuffix: string -> string -> string
   164   val replicate_string: int -> string -> string
   165   val translate_string: (string -> string) -> string -> string
   166 
   167   (*lists as sets -- see also Pure/General/ord_list.ML*)
   168   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   169   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   170   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   171   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   172   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   173   val mem: ''a * ''a list -> bool
   174   val mem_int: int * int list -> bool
   175   val mem_string: string * string list -> bool
   176   val union: ''a list * ''a list -> ''a list
   177   val union_int: int list * int list -> int list
   178   val union_string: string list * string list -> string list
   179   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   180   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   181   val inter: ''a list * ''a list -> ''a list
   182   val inter_int: int list * int list -> int list
   183   val inter_string: string list * string list -> string list
   184   val subset: ''a list * ''a list -> bool
   185   val subset_int: int list * int list -> bool
   186   val subset_string: string list * string list -> bool
   187   val eq_set: ''a list * ''a list -> bool
   188   val eq_set_string: string list * string list -> bool
   189   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   190   val gen_eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   191   val \ : ''a list * ''a -> ''a list
   192   val \\ : ''a list * ''a list -> ''a list
   193   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   194   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   195   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   196 
   197   (*lists as tables -- see also Pure/General/alist.ML*)
   198   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   199   val merge_lists: ''a list -> ''a list -> ''a list
   200   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   201 
   202   (*balanced trees*)
   203   exception Balance
   204   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   205   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   206   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   207 
   208   (*orders*)
   209   val is_equal: order -> bool
   210   val rev_order: order -> order
   211   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   212   val int_ord: int * int -> order
   213   val string_ord: string * string -> order
   214   val fast_string_ord: string * string -> order
   215   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   216   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   217   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   218   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   219   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   220   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   221   val sort_strings: string list -> string list
   222   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   223 
   224   (*random numbers*)
   225   exception RANDOM
   226   val random: unit -> real
   227   val random_range: int -> int -> int
   228   val one_of: 'a list -> 'a
   229   val frequency: (int * 'a) list -> 'a
   230 
   231   (*current directory*)
   232   val cd: string -> unit
   233   val pwd: unit -> string
   234 
   235   (*misc*)
   236   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   237   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   238   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   239   val gensym: string -> string
   240   val scanwords: (string -> bool) -> string list -> string list
   241   type stamp
   242   val stamp: unit -> stamp
   243   type serial
   244   val serial: unit -> serial
   245   val serial_string: unit -> string
   246   structure Object: sig type T end
   247 end;
   248 
   249 signature LIBRARY =
   250 sig
   251   include BASIC_LIBRARY
   252   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   253   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   254   val take: int * 'a list -> 'a list
   255   val drop: int * 'a list -> 'a list
   256   val last_elem: 'a list -> 'a
   257   val seq: ('a -> unit) -> 'a list -> unit
   258 end;
   259 
   260 structure Library: LIBRARY =
   261 struct
   262 
   263 (* functions *)
   264 
   265 fun I x = x;
   266 fun K x = fn _ => x;
   267 fun curry f x y = f (x, y);
   268 fun uncurry f (x, y) = f x y;
   269 
   270 (*application and structured results -- old version*)
   271 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   272 
   273 (*conditional application*)
   274 fun b ? f = fn x => if b x then f x else x;
   275 
   276 (*composition with multiple args*)
   277 fun (f oo g) x y = f (g x y);
   278 fun (f ooo g) x y z = f (g x y z);
   279 fun (f oooo g) x y z w = f (g x y z w);
   280 
   281 (*function exponentiation: f(...(f x)...) with n applications of f*)
   282 fun funpow n f x =
   283   let fun rep (0, x) = x
   284         | rep (n, x) = rep (n - 1, f x)
   285   in rep (n, x) end;
   286 
   287 
   288 (* exceptions *)
   289 
   290 val do_transform_failure = ref true;
   291 
   292 fun transform_failure exn f x =
   293   if ! do_transform_failure then
   294     f x handle Interrupt => raise Interrupt | e => raise exn e
   295   else f x;
   296 
   297 exception EXCEPTION of exn * string;
   298 
   299 datatype 'a result =
   300   Result of 'a |
   301   Exn of exn;
   302 
   303 fun capture f x = Result (f x) handle e => Exn e;
   304 
   305 fun release (Result y) = y
   306   | release (Exn e) = raise e;
   307 
   308 fun get_result (Result x) = SOME x
   309   | get_result _ = NONE;
   310 
   311 fun get_exn (Exn exn) = SOME exn
   312   | get_exn _ = NONE;
   313 
   314 
   315 (* errors *)
   316 
   317 exception SYS_ERROR of string;
   318 fun sys_error msg = raise SYS_ERROR msg;
   319 
   320 exception ERROR of string;
   321 fun error msg = raise ERROR msg;
   322 
   323 fun cat_error "" msg = error msg
   324   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   325 
   326 fun assert p msg = if p then () else error msg;
   327 fun deny p msg = if p then error msg else ();
   328 
   329 fun assert_all pred list msg =
   330   let
   331     fun ass [] = ()
   332       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   333   in ass list end;
   334 
   335 
   336 (* pairs *)
   337 
   338 fun pair x y = (x, y);
   339 fun rpair x y = (y, x);
   340 
   341 fun fst (x, y) = x;
   342 fun snd (x, y) = y;
   343 
   344 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   345 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   346 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   347 
   348 fun swap (x, y) = (y, x);
   349 
   350 (*apply function to components*)
   351 fun apfst f (x, y) = (f x, y);
   352 fun apsnd f (x, y) = (x, f y);
   353 fun pairself f (x, y) = (f x, f y);
   354 
   355 
   356 (* booleans *)
   357 
   358 (*polymorphic equality*)
   359 fun equal x y = x = y;
   360 fun not_equal x y = x <> y;
   361 
   362 (*combining predicates*)
   363 fun p orf q = fn x => p x orelse q x;
   364 fun p andf q = fn x => p x andalso q x;
   365 
   366 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   367 fun exists (pred: 'a -> bool) : 'a list -> bool =
   368   let fun boolf [] = false
   369         | boolf (x :: xs) = pred x orelse boolf xs
   370   in boolf end;
   371 
   372 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   373 fun forall (pred: 'a -> bool) : 'a list -> bool =
   374   let fun boolf [] = true
   375         | boolf (x :: xs) = pred x andalso boolf xs
   376   in boolf end;
   377 
   378 
   379 (* flags *)
   380 
   381 fun set flag = (flag := true; true);
   382 fun reset flag = (flag := false; false);
   383 fun toggle flag = (flag := not (! flag); ! flag);
   384 
   385 fun change r f = r := f (! r);
   386 
   387 (*temporarily set flag during execution*)
   388 fun setmp flag value f x =
   389   let
   390     val orig_value = ! flag;
   391     val _ = flag := value;
   392     val result = capture f x;
   393     val _ = flag := orig_value;
   394   in release result end;
   395 
   396 
   397 (* conditional execution *)
   398 
   399 fun conditional b f = if b then f () else ();
   400 
   401 
   402 
   403 (** lists **)
   404 
   405 exception UnequalLengths;
   406 
   407 fun single x = [x];
   408 
   409 fun the_single [x] = x
   410   | the_single _ = raise Empty;
   411 
   412 fun singleton f x = the_single (f [x]);
   413 
   414 fun apply [] x = x
   415   | apply (f :: fs) x = apply fs (f x);
   416 
   417 
   418 (* fold -- old versions *)
   419 
   420 (*the following versions of fold are designed to fit nicely with infixes*)
   421 
   422 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   423     for operators that associate to the left (TAIL RECURSIVE)*)
   424 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   425   let fun itl (e, [])  = e
   426         | itl (e, a::l) = itl (f(e, a), l)
   427   in  itl end;
   428 
   429 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   430     for operators that associate to the right (not tail recursive)*)
   431 fun foldr f (l, e) =
   432   let fun itr [] = e
   433         | itr (a::l) = f(a, itr l)
   434   in  itr l  end;
   435 
   436 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   437     for n > 0, operators that associate to the right (not tail recursive)*)
   438 fun foldr1 f [] = raise Empty
   439   | foldr1 f l =
   440       let fun itr [x] = x
   441             | itr (x::l) = f(x, itr l)
   442       in  itr l  end;
   443 
   444 fun foldl_map f =
   445   let
   446     fun fold_aux (x, []) = (x, [])
   447       | fold_aux (x, y :: ys) =
   448           let
   449             val (x', y') = f (x, y);
   450             val (x'', ys') = fold_aux (x', ys);
   451           in (x'', y' :: ys') end;
   452   in fold_aux end;
   453 
   454 
   455 (* basic list functions *)
   456 
   457 fun eq_list eq (list1, list2) =
   458   let
   459     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   460       | eq_lst _ = true;
   461   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   462 
   463 fun maps f [] = []
   464   | maps f (x :: xs) = f x @ maps f xs;
   465 
   466 fun chop n xs = unfold_rev n dest xs;
   467 
   468 (*take the first n elements from a list*)
   469 fun take (n, []) = []
   470   | take (n, x :: xs) =
   471       if n > 0 then x :: take (n - 1, xs) else [];
   472 
   473 (*drop the first n elements from a list*)
   474 fun drop (n, []) = []
   475   | drop (n, x :: xs) =
   476       if n > 0 then drop (n - 1, xs) else x :: xs;
   477 
   478 fun dropwhile P [] = []
   479   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   480 
   481 (*return nth element of a list, where 0 designates the first element;
   482   raise Subscript if list too short*)
   483 fun nth xs i = List.nth (xs, i);
   484 
   485 fun nth_list xss i = nth xss i handle Subscript => [];
   486 
   487 fun nth_map 0 f (x :: xs) = f x :: xs
   488   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   489   | nth_map _ _ [] = raise Subscript;
   490 
   491 fun map_index f =
   492   let
   493     fun mapp _ [] = []
   494       | mapp i (x :: xs) = f (i, x) :: mapp (i+1) xs
   495   in mapp 0 end;
   496 
   497 fun fold_index f =
   498   let
   499     fun fold_aux _ [] y = y
   500       | fold_aux i (x :: xs) y = fold_aux (i+1) xs (f (i, x) y);
   501   in fold_aux 0 end;
   502 
   503 val last_elem = List.last;
   504 
   505 (*rear decomposition*)
   506 fun split_last [] = raise Empty
   507   | split_last [x] = ([], x)
   508   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   509 
   510 (*find the position of an element in a list*)
   511 fun find_index pred =
   512   let fun find _ [] = ~1
   513         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   514   in find 0 end;
   515 
   516 fun find_index_eq x = find_index (equal x);
   517 
   518 (*find first element satisfying predicate*)
   519 fun find_first _ [] = NONE
   520   | find_first pred (x :: xs) =
   521       if pred x then SOME x else find_first pred xs;
   522 
   523 (*get first element by lookup function*)
   524 fun get_first _ [] = NONE
   525   | get_first f (x :: xs) =
   526       (case f x of
   527         NONE => get_first f xs
   528       | some => some);
   529 
   530 fun get_index f =
   531   let
   532     fun get _ [] = NONE
   533       | get i (x :: xs) =
   534           case f x
   535            of NONE => get (i + 1) xs
   536             | SOME y => SOME (i, y)
   537   in get 0 end;
   538 
   539 val flat = List.concat;
   540 
   541 fun unflat (xs :: xss) ys =
   542       let val (ps, qs) = chop (length xs) ys
   543       in ps :: unflat xss qs end
   544   | unflat [] [] = []
   545   | unflat _ _ = raise UnequalLengths;
   546 
   547 fun burrow f xss = unflat xss (f (flat xss));
   548 
   549 fun fold_burrow f xss s =
   550   apfst (unflat xss) (f (flat xss) s);
   551 
   552 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   553   (proc x1; ...; proc xn) for side effects*)
   554 val seq = List.app;
   555 
   556 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   557 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   558   | separate _ xs = xs;
   559 
   560 (*make the list [x, x, ..., x] of length n*)
   561 fun replicate n (x: 'a) : 'a list =
   562   let fun rep (0, xs) = xs
   563         | rep (n, xs) = rep (n - 1, x :: xs)
   564   in
   565     if n < 0 then raise Subscript
   566     else rep (n, [])
   567   end;
   568 
   569 fun translate_string f = String.translate (f o String.str);
   570 
   571 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   572 fun multiply [] _ = []
   573   | multiply (x :: xs) yss = map (cons x) yss @ multiply xs yss;
   574 
   575 (*direct product*)
   576 fun product _ [] = []
   577   | product [] _ = []
   578   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   579 
   580 
   581 (* filter *)
   582 
   583 (*copy the list preserving elements that satisfy the predicate*)
   584 val filter = List.filter;
   585 fun filter_out f = filter (not o f);
   586 val map_filter = List.mapPartial;
   587 
   588 
   589 (* lists of pairs *)
   590 
   591 exception UnequalLengths;
   592 
   593 fun map2 _ [] [] = []
   594   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   595   | map2 _ _ _ = raise UnequalLengths;
   596 
   597 fun fold2 f =
   598   let
   599     fun fold_aux [] [] z = z
   600       | fold_aux (x :: xs) (y :: ys) z = fold_aux xs ys (f x y z)
   601       | fold_aux _ _ _ = raise UnequalLengths;
   602   in fold_aux end;
   603 
   604 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   605   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   606   | zip_options _ [] = []
   607   | zip_options [] _ = raise UnequalLengths;
   608 
   609 (*combine two lists forming a list of pairs:
   610   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   611 fun [] ~~ [] = []
   612   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   613   | _ ~~ _ = raise UnequalLengths;
   614 
   615 (*inverse of ~~; the old 'split':
   616   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   617 val split_list = ListPair.unzip;
   618 
   619 
   620 (* prefixes, suffixes *)
   621 
   622 fun is_prefix _ [] _ = true
   623   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   624   | is_prefix eq _ _ = false;
   625 
   626 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   627    where xi is the first element that does not satisfy the predicate*)
   628 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   629   let fun take (rxs, []) = (rev rxs, [])
   630         | take (rxs, x :: xs) =
   631             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   632   in  take([], xs)  end;
   633 
   634 fun chop_prefix eq ([], ys) = ([], ([], ys))
   635   | chop_prefix eq (xs, []) = ([], (xs, []))
   636   | chop_prefix eq (xs as x::xs', ys as y::ys') =
   637       if eq (x, y) then
   638         let val (ps', xys'') = chop_prefix eq (xs', ys')
   639         in (x::ps', xys'') end
   640       else ([], (xs, ys));
   641 
   642 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   643    where xi is the last element that does not satisfy the predicate*)
   644 fun take_suffix _ [] = ([], [])
   645   | take_suffix pred (x :: xs) =
   646       (case take_suffix pred xs of
   647         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   648       | (prfx, sffx) => (x :: prfx, sffx));
   649 
   650 fun prefixes1 [] = []
   651   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   652 
   653 fun prefixes xs = [] :: prefixes1 xs;
   654 
   655 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   656 fun suffixes xs = [] :: suffixes1 xs;
   657 
   658 
   659 (** integers **)
   660 
   661 fun gcd (x, y) =
   662   let fun gxd x y : IntInf.int =
   663     if y = 0 then x else gxd y (x mod y)
   664   in if x < y then gxd y x else gxd x y end;
   665 
   666 fun lcm (x, y) = (x * y) div gcd (x, y);
   667 
   668 fun inc i = (i := ! i + 1; ! i);
   669 fun dec i = (i := ! i - 1; ! i);
   670 
   671 
   672 (* lists of integers *)
   673 
   674 (*make the list [from, from + 1, ..., to]*)
   675 fun (from upto to) =
   676   if from > to then [] else from :: ((from + 1) upto to);
   677 
   678 (*make the list [from, from - 1, ..., to]*)
   679 fun (from downto to) =
   680   if from < to then [] else from :: ((from - 1) downto to);
   681 
   682 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   683 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   684   | downto0 ([], n) = n = ~1;
   685 
   686 
   687 (* convert integers to strings *)
   688 
   689 (*expand the number in the given base;
   690   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   691 fun radixpand (base, num) : int list =
   692   let
   693     fun radix (n, tail) =
   694       if n < base then n :: tail
   695       else radix (n div base, (n mod base) :: tail)
   696   in radix (num, []) end;
   697 
   698 (*expands a number into a string of characters starting from "zerochar";
   699   example: radixstring (2, "0", 8) gives "1000"*)
   700 fun radixstring (base, zerochar, num) =
   701   let val offset = ord zerochar;
   702       fun chrof n = chr (offset + n)
   703   in implode (map chrof (radixpand (base, num))) end;
   704 
   705 
   706 val string_of_int = Int.toString;
   707 
   708 fun string_of_indexname (a,0) = a
   709   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   710 
   711 
   712 (* read integers *)
   713 
   714 fun read_intinf radix cs =
   715   let
   716     val zero = ord "0";
   717     val limit = zero + radix;
   718     fun scan (num, []) = (num, [])
   719       | scan (num, c :: cs) =
   720         if zero <= ord c andalso ord c < limit then
   721           scan (IntInf.fromInt radix * num + IntInf.fromInt (ord c - zero), cs)
   722         else (num, c :: cs);
   723   in scan (0, cs) end;
   724 
   725 fun read_int cs = apfst IntInf.toInt (read_intinf 10 cs);
   726 
   727 fun oct_char s = chr (IntInf.toInt (#1 (read_intinf 8 (explode s))));
   728 
   729 
   730 
   731 (** strings **)
   732 
   733 (* functions tuned for strings, avoiding explode *)
   734 
   735 fun nth_string str i =
   736   (case try String.substring (str, i, 1) of
   737     SOME s => s
   738   | NONE => raise Subscript);
   739 
   740 fun fold_string f str x0 =
   741   let
   742     val n = size str;
   743     fun iter (x, i) =
   744       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   745   in iter (x0, 0) end;
   746 
   747 fun exists_string pred str =
   748   let
   749     val n = size str;
   750     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   751   in ex 0 end;
   752 
   753 fun forall_string pred = not o exists_string (not o pred);
   754 
   755 (*enclose in brackets*)
   756 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   757 fun unenclose str = String.substring (str, 1, size str - 2);
   758 
   759 (*simple quoting (does not escape special chars)*)
   760 val quote = enclose "\"" "\"";
   761 
   762 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   763 fun space_implode a bs = implode (separate a bs);
   764 
   765 val commas = space_implode ", ";
   766 val commas_quote = commas o map quote;
   767 
   768 (*concatenate messages, one per line, into a string*)
   769 val cat_lines = space_implode "\n";
   770 
   771 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   772 fun space_explode _ "" = []
   773   | space_explode sep str =
   774       let
   775         fun expl chs =
   776           (case take_prefix (fn s => s <> sep) chs of
   777             (cs, []) => [implode cs]
   778           | (cs, _ :: cs') => implode cs :: expl cs');
   779       in expl (explode str) end;
   780 
   781 val split_lines = space_explode "\n";
   782 
   783 fun prefix_lines "" txt = txt
   784   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   785 
   786 fun untabify chs =
   787   let
   788     val tab_width = 8;
   789 
   790     fun untab (_, "\n") = (0, ["\n"])
   791       | untab (pos, "\t") =
   792           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   793       | untab (pos, c) = (pos + 1, [c]);
   794   in
   795     if not (exists (fn c => c = "\t") chs) then chs
   796     else flat (#2 (foldl_map untab (0, chs)))
   797   end;
   798 
   799 fun prefix prfx s = prfx ^ s;
   800 fun suffix sffx s = s ^ sffx;
   801 
   802 fun unprefix prfx s =
   803   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   804   else raise Fail "unprefix";
   805 
   806 fun unsuffix sffx s =
   807   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   808   else raise Fail "unsuffix";
   809 
   810 fun replicate_string 0 _ = ""
   811   | replicate_string 1 a = a
   812   | replicate_string k a =
   813       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   814       else replicate_string (k div 2) (a ^ a) ^ a;
   815 
   816 
   817 
   818 (** lists as sets -- see also Pure/General/ord_list.ML **)
   819 
   820 (*canonical member, insert, remove*)
   821 fun member eq list x =
   822   let
   823     fun memb [] = false
   824       | memb (y :: ys) = eq (x, y) orelse memb ys;
   825   in memb list end;
   826 
   827 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   828 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   829 
   830 fun subtract eq = fold (remove eq);
   831 
   832 fun merge _ ([], ys) = ys
   833   | merge eq (xs, ys) = fold_rev (insert eq) ys xs;
   834 
   835 (*old-style infixes*)
   836 fun x mem xs = member (op =) xs x;
   837 fun (x: int) mem_int xs = member (op =) xs x;
   838 fun (x: string) mem_string xs = member (op =) xs x;
   839 
   840 
   841 (*union of sets represented as lists: no repetitions*)
   842 fun xs union [] = xs
   843   | [] union ys = ys
   844   | (x :: xs) union ys = xs union (insert (op =) x ys);
   845 
   846 (*union of sets, optimized version for ints*)
   847 fun (xs:int list) union_int [] = xs
   848   | [] union_int ys = ys
   849   | (x :: xs) union_int ys = xs union_int (insert (op =) x ys);
   850 
   851 (*union of sets, optimized version for strings*)
   852 fun (xs:string list) union_string [] = xs
   853   | [] union_string ys = ys
   854   | (x :: xs) union_string ys = xs union_string (insert (op =) x ys);
   855 
   856 (*generalized union*)
   857 fun gen_union eq (xs, []) = xs
   858   | gen_union eq ([], ys) = ys
   859   | gen_union eq (x :: xs, ys) = gen_union eq (xs, insert eq x ys);
   860 
   861 
   862 (*intersection*)
   863 fun [] inter ys = []
   864   | (x :: xs) inter ys =
   865       if x mem ys then x :: (xs inter ys) else xs inter ys;
   866 
   867 (*intersection, optimized version for ints*)
   868 fun ([]:int list) inter_int ys = []
   869   | (x :: xs) inter_int ys =
   870       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   871 
   872 (*intersection, optimized version for strings *)
   873 fun ([]:string list) inter_string ys = []
   874   | (x :: xs) inter_string ys =
   875       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   876 
   877 (*generalized intersection*)
   878 fun gen_inter eq ([], ys) = []
   879   | gen_inter eq (x::xs, ys) =
   880       if member eq ys x then x :: gen_inter eq (xs, ys)
   881       else gen_inter eq (xs, ys);
   882 
   883 
   884 (*subset*)
   885 fun [] subset ys = true
   886   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   887 
   888 (*subset, optimized version for ints*)
   889 fun ([]: int list) subset_int ys = true
   890   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   891 
   892 (*subset, optimized version for strings*)
   893 fun ([]: string list) subset_string ys = true
   894   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   895 
   896 (*set equality*)
   897 fun eq_set (xs, ys) =
   898   xs = ys orelse (xs subset ys andalso ys subset xs);
   899 
   900 (*set equality for strings*)
   901 fun eq_set_string ((xs: string list), ys) =
   902   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   903 
   904 fun gen_subset eq (xs, ys) = forall (member eq ys) xs;
   905 
   906 fun gen_eq_set eq (xs, ys) =
   907   eq_list eq (xs, ys) orelse
   908     (gen_subset eq (xs, ys) andalso gen_subset (eq o swap) (ys, xs));
   909 
   910 
   911 (*removing an element from a list WITHOUT duplicates*)
   912 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   913   | [] \ x = [];
   914 fun ys \\ xs = foldl (op \) (ys,xs);
   915 
   916 
   917 (*makes a list of the distinct members of the input; preserves order, takes
   918   first of equal elements*)
   919 fun distinct eq lst =
   920   let
   921     fun dist (rev_seen, []) = rev rev_seen
   922       | dist (rev_seen, x :: xs) =
   923           if member eq rev_seen x then dist (rev_seen, xs)
   924           else dist (x :: rev_seen, xs);
   925   in dist ([], lst) end;
   926 
   927 (*returns a list containing all repeated elements exactly once; preserves
   928   order, takes first of equal elements*)
   929 fun duplicates eq lst =
   930   let
   931     fun dups (rev_dups, []) = rev rev_dups
   932       | dups (rev_dups, x :: xs) =
   933           if member eq rev_dups x orelse not (member eq xs x) then
   934             dups (rev_dups, xs)
   935           else dups (x :: rev_dups, xs);
   936   in dups ([], lst) end;
   937 
   938 fun has_duplicates eq =
   939   let
   940     fun dups [] = false
   941       | dups (x :: xs) = member eq xs x orelse dups xs;
   942   in dups end;
   943 
   944 
   945 (** association lists -- legacy operations **)
   946 
   947 fun gen_merge_lists _ xs [] = xs
   948   | gen_merge_lists _ [] ys = ys
   949   | gen_merge_lists eq xs ys = xs @ filter_out (member eq xs) ys;
   950 
   951 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
   952 fun merge_alists xs = gen_merge_lists (eq_fst (op =)) xs;
   953 
   954 
   955 (** balanced trees **)
   956 
   957 exception Balance;      (*indicates non-positive argument to balancing fun*)
   958 
   959 (*balanced folding; avoids deep nesting*)
   960 fun fold_bal f [x] = x
   961   | fold_bal f [] = raise Balance
   962   | fold_bal f xs =
   963       let val (ps, qs) = chop (length xs div 2) xs
   964       in  f (fold_bal f ps, fold_bal f qs)  end;
   965 
   966 (*construct something of the form f(...g(...(x)...)) for balanced access*)
   967 fun access_bal (f, g, x) n i =
   968   let fun acc n i =     (*1<=i<=n*)
   969           if n=1 then x else
   970           let val n2 = n div 2
   971           in  if i<=n2 then f (acc n2 i)
   972                        else g (acc (n-n2) (i-n2))
   973           end
   974   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
   975 
   976 (*construct ALL such accesses; could try harder to share recursive calls!*)
   977 fun accesses_bal (f, g, x) n =
   978   let fun acc n =
   979           if n=1 then [x] else
   980           let val n2 = n div 2
   981               val acc2 = acc n2
   982           in  if n-n2=n2 then map f acc2 @ map g acc2
   983                          else map f acc2 @ map g (acc (n-n2)) end
   984   in  if 1<=n then acc n else raise Balance  end;
   985 
   986 
   987 
   988 (** orders **)
   989 
   990 fun is_equal EQUAL = true
   991   | is_equal _ = false;
   992 
   993 fun rev_order LESS = GREATER
   994   | rev_order EQUAL = EQUAL
   995   | rev_order GREATER = LESS;
   996 
   997 (*assume rel is a linear strict order*)
   998 fun make_ord rel (x, y) =
   999   if rel (x, y) then LESS
  1000   else if rel (y, x) then GREATER
  1001   else EQUAL;
  1002 
  1003 val int_ord = Int.compare;
  1004 val string_ord = String.compare;
  1005 
  1006 fun fast_string_ord (s1, s2) =
  1007   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
  1008 
  1009 fun option_ord ord (SOME x, SOME y) = ord (x, y)
  1010   | option_ord _ (NONE, NONE) = EQUAL
  1011   | option_ord _ (NONE, SOME _) = LESS
  1012   | option_ord _ (SOME _, NONE) = GREATER;
  1013 
  1014 (*lexicographic product*)
  1015 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1016   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1017 
  1018 (*dictionary order -- in general NOT well-founded!*)
  1019 fun dict_ord elem_ord (x :: xs, y :: ys) =
  1020       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
  1021   | dict_ord _ ([], []) = EQUAL
  1022   | dict_ord _ ([], _ :: _) = LESS
  1023   | dict_ord _ (_ :: _, []) = GREATER;
  1024 
  1025 (*lexicographic product of lists*)
  1026 fun list_ord elem_ord (xs, ys) =
  1027   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1028 
  1029 
  1030 (* sorting *)
  1031 
  1032 (*quicksort -- stable, i.e. does not reorder equal elements*)
  1033 fun quicksort unique ord =
  1034   let
  1035     fun qsort [] = []
  1036       | qsort (xs as [_]) = xs
  1037       | qsort (xs as [x, y]) =
  1038           (case ord (x, y) of
  1039             LESS => xs
  1040           | EQUAL => if unique then [x] else xs
  1041           | GREATER => [y, x])
  1042       | qsort xs =
  1043           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
  1044           in qsort lts @ eqs @ qsort gts end
  1045     and part _ [] = ([], [], [])
  1046       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1047     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1048       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
  1049       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
  1050       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1051   in qsort end;
  1052 
  1053 fun sort ord = quicksort false ord;
  1054 fun sort_distinct ord = quicksort true ord;
  1055 
  1056 val sort_strings = sort string_ord;
  1057 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1058 
  1059 
  1060 
  1061 (** random numbers **)
  1062 
  1063 exception RANDOM;
  1064 
  1065 fun rmod x y = x - y * Real.realFloor (x / y);
  1066 
  1067 local
  1068   val a = 16807.0;
  1069   val m = 2147483647.0;
  1070   val random_seed = ref 1.0;
  1071 in
  1072 
  1073 fun random () =
  1074   let val r = rmod (a * !random_seed) m
  1075   in (random_seed := r; r) end;
  1076 
  1077 end;
  1078 
  1079 fun random_range l h =
  1080   if h < l orelse l < 0 then raise RANDOM
  1081   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1082 
  1083 fun one_of xs = nth xs (random_range 0 (length xs - 1));
  1084 
  1085 fun frequency xs =
  1086   let
  1087     val sum = foldl op + (0, map fst xs);
  1088     fun pick n ((k: int, x) :: xs) =
  1089       if n <= k then x else pick (n - k) xs
  1090   in pick (random_range 1 sum) xs end;
  1091 
  1092 
  1093 (** current directory **)
  1094 
  1095 val cd = OS.FileSys.chDir;
  1096 val pwd = OS.FileSys.getDir;
  1097 
  1098 
  1099 
  1100 (** misc **)
  1101 
  1102 fun divide_and_conquer decomp x =
  1103   let val (ys, recomb) = decomp x
  1104   in recomb (map (divide_and_conquer decomp) ys) end;
  1105 
  1106 
  1107 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1108    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1109 fun partition_list p i j =
  1110   let fun part k xs =
  1111             if k>j then
  1112               (case xs of [] => []
  1113                          | _ => raise Fail "partition_list")
  1114             else
  1115             let val (ns, rest) = List.partition (p k) xs;
  1116             in  ns :: part(k+1)rest  end
  1117   in  part i end;
  1118 
  1119 fun partition_eq (eq:'a * 'a -> bool) =
  1120   let
  1121     fun part [] = []
  1122       | part (x :: ys) =
  1123           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1124           in (x::xs)::(part xs') end
  1125   in part end;
  1126 
  1127 
  1128 
  1129 (* generating identifiers *)
  1130 
  1131 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1132 local
  1133 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1134 fun char i =      if i<26 then chr (ord "A" + i)
  1135              else if i<52 then chr (ord "a" + i - 26)
  1136              else if i<62 then chr (ord"0" + i - 52)
  1137              else if i=62 then "_"
  1138              else  (*i=63*)    "'";
  1139 
  1140 val charVec = Vector.tabulate (64, char);
  1141 
  1142 fun newid n =
  1143   let
  1144   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1145 
  1146 val seedr = ref 0;
  1147 
  1148 in
  1149 
  1150 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1151 
  1152 end;
  1153 
  1154 
  1155 (* lexical scanning *)
  1156 
  1157 (*scan a list of characters into "words" composed of "letters" (recognized by
  1158   is_let) and separated by any number of non-"letters"*)
  1159 fun scanwords is_let cs =
  1160   let fun scan1 [] = []
  1161         | scan1 cs =
  1162             let val (lets, rest) = take_prefix is_let cs
  1163             in implode lets :: scanwords is_let rest end;
  1164   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1165 
  1166 
  1167 (* stamps and serial numbers *)
  1168 
  1169 type stamp = unit ref;
  1170 val stamp: unit -> stamp = ref;
  1171 
  1172 type serial = int;
  1173 local val count = ref 0
  1174 in fun serial () = inc count end;
  1175 
  1176 val serial_string = string_of_int o serial;
  1177 
  1178 
  1179 (* generic objects *)
  1180 
  1181 (*note that the builtin exception datatype may be extended by new
  1182   constructors at any time*)
  1183 structure Object = struct type T = exn end;
  1184 
  1185 end;
  1186 
  1187 structure BasicLibrary: BASIC_LIBRARY = Library;
  1188 open BasicLibrary;