src/HOL/Tools/SMT/smt_translate.ML
author boehmes
Fri Oct 29 18:17:04 2010 +0200 (2010-10-29)
changeset 40274 6486c610a549
parent 40161 539d07b00e5f
child 40579 98ebd2300823
permissions -rw-r--r--
introduced SMT.distinct as a representation of the solvers' built-in predicate; check that SMT.distinct is always applied to an explicit list
     1 (*  Title:      HOL/Tools/SMT/smt_translate.ML
     2     Author:     Sascha Boehme, TU Muenchen
     3 
     4 Translate theorems into an SMT intermediate format and serialize them.
     5 *)
     6 
     7 signature SMT_TRANSLATE =
     8 sig
     9   (* intermediate term structure *)
    10   datatype squant = SForall | SExists
    11   datatype 'a spattern = SPat of 'a list | SNoPat of 'a list
    12   datatype sterm =
    13     SVar of int |
    14     SApp of string * sterm list |
    15     SLet of string * sterm * sterm |
    16     SQua of squant * string list * sterm spattern list * sterm
    17 
    18   (* configuration options *)
    19   type prefixes = {sort_prefix: string, func_prefix: string}
    20   type header = Proof.context -> term list -> string list
    21   type strict = {
    22     is_builtin_conn: string * typ -> bool,
    23     is_builtin_pred: Proof.context -> string * typ -> bool,
    24     is_builtin_distinct: bool}
    25   type builtins = {
    26     builtin_typ: Proof.context -> typ -> string option,
    27     builtin_num: Proof.context -> typ -> int -> string option,
    28     builtin_fun: Proof.context -> string * typ -> term list ->
    29       (string * term list) option,
    30     has_datatypes: bool }
    31   type sign = {
    32     header: string list,
    33     sorts: string list,
    34     dtyps: (string * (string * (string * string) list) list) list list,
    35     funcs: (string * (string list * string)) list }
    36   type config = {
    37     prefixes: prefixes,
    38     header: header,
    39     strict: strict option,
    40     builtins: builtins,
    41     serialize: string list -> sign -> sterm list -> string }
    42   type recon = {
    43     typs: typ Symtab.table,
    44     terms: term Symtab.table,
    45     unfolds: thm list,
    46     assms: (int * thm) list }
    47 
    48   val translate: config -> Proof.context -> string list -> (int * thm) list ->
    49     string * recon
    50 end
    51 
    52 structure SMT_Translate: SMT_TRANSLATE =
    53 struct
    54 
    55 (* intermediate term structure *)
    56 
    57 datatype squant = SForall | SExists
    58 
    59 datatype 'a spattern = SPat of 'a list | SNoPat of 'a list
    60 
    61 datatype sterm =
    62   SVar of int |
    63   SApp of string * sterm list |
    64   SLet of string * sterm * sterm |
    65   SQua of squant * string list * sterm spattern list * sterm
    66 
    67 
    68 
    69 (* configuration options *)
    70 
    71 type prefixes = {sort_prefix: string, func_prefix: string}
    72 
    73 type header = Proof.context -> term list -> string list
    74 
    75 type strict = {
    76   is_builtin_conn: string * typ -> bool,
    77   is_builtin_pred: Proof.context -> string * typ -> bool,
    78   is_builtin_distinct: bool}
    79 
    80 type builtins = {
    81   builtin_typ: Proof.context -> typ -> string option,
    82   builtin_num: Proof.context -> typ -> int -> string option,
    83   builtin_fun: Proof.context -> string * typ -> term list ->
    84     (string * term list) option,
    85   has_datatypes: bool }
    86 
    87 type sign = {
    88   header: string list,
    89   sorts: string list,
    90   dtyps: (string * (string * (string * string) list) list) list list,
    91   funcs: (string * (string list * string)) list }
    92 
    93 type config = {
    94   prefixes: prefixes,
    95   header: header,
    96   strict: strict option,
    97   builtins: builtins,
    98   serialize: string list -> sign -> sterm list -> string }
    99 
   100 type recon = {
   101   typs: typ Symtab.table,
   102   terms: term Symtab.table,
   103   unfolds: thm list,
   104   assms: (int * thm) list }
   105 
   106 
   107 
   108 (* utility functions *)
   109 
   110 val dest_funT =
   111   let
   112     fun dest Ts 0 T = (rev Ts, T)
   113       | dest Ts i (Type ("fun", [T, U])) = dest (T::Ts) (i-1) U
   114       | dest _ _ T = raise TYPE ("dest_funT", [T], [])
   115   in dest [] end
   116 
   117 val quantifier = (fn
   118     @{const_name All} => SOME SForall
   119   | @{const_name Ex} => SOME SExists
   120   | _ => NONE)
   121 
   122 fun group_quant qname Ts (t as Const (q, _) $ Abs (_, T, u)) =
   123       if q = qname then group_quant qname (T :: Ts) u else (Ts, t)
   124   | group_quant _ Ts t = (Ts, t)
   125 
   126 fun dest_pat (Const (@{const_name pat}, _) $ t) = (t, true)
   127   | dest_pat (Const (@{const_name nopat}, _) $ t) = (t, false)
   128   | dest_pat t = raise TERM ("dest_pat", [t])
   129 
   130 fun dest_pats [] = I
   131   | dest_pats ts =
   132       (case map dest_pat ts |> split_list ||> distinct (op =) of
   133         (ps, [true]) => cons (SPat ps)
   134       | (ps, [false]) => cons (SNoPat ps)
   135       | _ => raise TERM ("dest_pats", ts))
   136 
   137 fun dest_trigger (@{term trigger} $ tl $ t) =
   138       (rev (fold (dest_pats o HOLogic.dest_list) (HOLogic.dest_list tl) []), t)
   139   | dest_trigger t = ([], t)
   140 
   141 fun dest_quant qn T t = quantifier qn |> Option.map (fn q =>
   142   let
   143     val (Ts, u) = group_quant qn [T] t
   144     val (ps, b) = dest_trigger u
   145   in (q, rev Ts, ps, b) end)
   146 
   147 fun fold_map_pat f (SPat ts) = fold_map f ts #>> SPat
   148   | fold_map_pat f (SNoPat ts) = fold_map f ts #>> SNoPat
   149 
   150 fun prop_of thm = HOLogic.dest_Trueprop (Thm.prop_of thm)
   151 
   152 
   153 
   154 (* enforce a strict separation between formulas and terms *)
   155 
   156 val term_eq_rewr = @{lemma "term_eq x y == x = y" by (simp add: term_eq_def)}
   157 
   158 val term_bool = @{lemma "~(term_eq True False)" by (simp add: term_eq_def)}
   159 val term_bool' = Simplifier.rewrite_rule [term_eq_rewr] term_bool
   160 
   161 
   162 val needs_rewrite = Thm.prop_of #> Term.exists_subterm (fn
   163     Const (@{const_name Let}, _) => true
   164   | @{term "op = :: bool => _"} $ _ $ @{term True} => true
   165   | Const (@{const_name If}, _) $ _ $ @{term True} $ @{term False} => true
   166   | _ => false)
   167 
   168 val rewrite_rules = [
   169   Let_def,
   170   @{lemma "P = True == P" by (rule eq_reflection) simp},
   171   @{lemma "if P then True else False == P" by (rule eq_reflection) simp}]
   172 
   173 fun rewrite ctxt = Simplifier.full_rewrite
   174   (Simplifier.context ctxt empty_ss addsimps rewrite_rules)
   175 
   176 fun normalize ctxt thm =
   177   if needs_rewrite thm then Conv.fconv_rule (rewrite ctxt) thm else thm
   178 
   179 val unfold_rules = term_eq_rewr :: rewrite_rules
   180 
   181 
   182 val revert_types =
   183   let
   184     fun revert @{typ prop} = @{typ bool}
   185       | revert (Type (n, Ts)) = Type (n, map revert Ts)
   186       | revert T = T
   187   in Term.map_types revert end
   188 
   189 
   190 fun strictify {is_builtin_conn, is_builtin_pred, is_builtin_distinct} ctxt =
   191   let
   192     fun is_builtin_conn' (@{const_name True}, _) = false
   193       | is_builtin_conn' (@{const_name False}, _) = false
   194       | is_builtin_conn' c = is_builtin_conn c
   195 
   196     val propT = @{typ prop} and boolT = @{typ bool}
   197     val as_propT = (fn @{typ bool} => propT | T => T)
   198     fun mapTs f g = Term.strip_type #> (fn (Ts, T) => map f Ts ---> g T)
   199     fun conn (n, T) = (n, mapTs as_propT as_propT T)
   200     fun pred (n, T) = (n, mapTs I as_propT T)
   201 
   202     val term_eq = @{term "op = :: bool => _"} |> Term.dest_Const |> pred
   203     fun as_term t = Const term_eq $ t $ @{term True}
   204 
   205     val if_term = Const (@{const_name If}, [propT, boolT, boolT] ---> boolT)
   206     fun wrap_in_if t = if_term $ t $ @{term True} $ @{term False}
   207 
   208     fun in_list T f t = HOLogic.mk_list T (map f (HOLogic.dest_list t))
   209 
   210     fun in_term t =
   211       (case Term.strip_comb t of
   212         (c as Const (@{const_name If}, _), [t1, t2, t3]) =>
   213           c $ in_form t1 $ in_term t2 $ in_term t3
   214       | (h as Const c, ts) =>
   215           if is_builtin_conn' (conn c) orelse is_builtin_pred ctxt (pred c)
   216           then wrap_in_if (in_form t)
   217           else Term.list_comb (h, map in_term ts)
   218       | (h as Free _, ts) => Term.list_comb (h, map in_term ts)
   219       | _ => t)
   220 
   221     and in_pat ((c as Const (@{const_name pat}, _)) $ t) = c $ in_term t
   222       | in_pat ((c as Const (@{const_name nopat}, _)) $ t) = c $ in_term t
   223       | in_pat t = raise TERM ("in_pat", [t])
   224 
   225     and in_pats ps =
   226       in_list @{typ "pattern list"} (in_list @{typ pattern} in_pat) ps
   227 
   228     and in_trig ((c as @{term trigger}) $ p $ t) = c $ in_pats p $ in_form t
   229       | in_trig t = in_form t
   230 
   231     and in_form t =
   232       (case Term.strip_comb t of
   233         (q as Const (qn, _), [Abs (n, T, t')]) =>
   234           if is_some (quantifier qn) then q $ Abs (n, T, in_trig t')
   235           else as_term (in_term t)
   236       | (Const (c as (@{const_name SMT.distinct}, T)), [t']) =>
   237           if is_builtin_distinct then Const (pred c) $ in_list T in_term t'
   238           else as_term (in_term t)
   239       | (Const c, ts) =>
   240           if is_builtin_conn (conn c)
   241           then Term.list_comb (Const (conn c), map in_form ts)
   242           else if is_builtin_pred ctxt (pred c)
   243           then Term.list_comb (Const (pred c), map in_term ts)
   244           else as_term (in_term t)
   245       | _ => as_term (in_term t))
   246   in
   247     map (apsnd (normalize ctxt)) #> (fn irules =>
   248     ((unfold_rules, (~1, term_bool') :: irules),
   249      map (in_form o prop_of o snd) ((~1, term_bool) :: irules)))
   250   end
   251 
   252 
   253 
   254 (* translation from Isabelle terms into SMT intermediate terms *)
   255 
   256 val empty_context = (1, Typtab.empty, [], 1, Termtab.empty)
   257 
   258 fun make_sign header (_, typs, dtyps, _, terms) = {
   259   header = header,
   260   sorts = Typtab.fold (fn (_, (n, true)) => cons n | _ => I) typs [],
   261   funcs = Termtab.fold (fn (_, (n, SOME ss)) => cons (n,ss) | _ => I) terms [],
   262   dtyps = rev dtyps }
   263 
   264 fun make_recon (unfolds, assms) (_, typs, _, _, terms) = {
   265   typs = Symtab.make (map (apfst fst o swap) (Typtab.dest typs)),
   266     (*FIXME: don't drop the datatype information! *)
   267   terms = Symtab.make (map (fn (t, (n, _)) => (n, t)) (Termtab.dest terms)),
   268   unfolds = unfolds,
   269   assms = assms }
   270 
   271 fun string_of_index pre i = pre ^ string_of_int i
   272 
   273 fun new_typ sort_prefix proper T (Tidx, typs, dtyps, idx, terms) =
   274   let val s = string_of_index sort_prefix Tidx
   275   in (s, (Tidx+1, Typtab.update (T, (s, proper)) typs, dtyps, idx, terms)) end
   276 
   277 fun lookup_typ (_, typs, _, _, _) = Typtab.lookup typs
   278 
   279 fun fresh_typ T f cx =
   280   (case lookup_typ cx T of
   281     SOME (s, _) => (s, cx)
   282   | NONE => f T cx)
   283 
   284 fun new_fun func_prefix t ss (Tidx, typs, dtyps, idx, terms) =
   285   let
   286     val f = string_of_index func_prefix idx
   287     val terms' = Termtab.update (revert_types t, (f, ss)) terms
   288   in (f, (Tidx, typs, dtyps, idx+1, terms')) end
   289 
   290 fun fresh_fun func_prefix t ss (cx as (_, _, _, _, terms)) =
   291   (case Termtab.lookup terms t of
   292     SOME (f, _) => (f, cx)
   293   | NONE => new_fun func_prefix t ss cx)
   294 
   295 fun mk_type (_, Tfs) (d as Datatype.DtTFree _) = the (AList.lookup (op =) Tfs d)
   296   | mk_type Ts (Datatype.DtType (n, ds)) = Type (n, map (mk_type Ts) ds)
   297   | mk_type (Tds, _) (Datatype.DtRec i) = nth Tds i
   298 
   299 fun mk_selector ctxt Ts T n (i, d) =
   300   (case Datatype_Selectors.lookup_selector ctxt (n, i+1) of
   301     NONE => raise Fail ("missing selector for datatype constructor " ^ quote n)
   302   | SOME m => mk_type Ts d |> (fn U => (Const (m, T --> U), U)))
   303 
   304 fun mk_constructor ctxt Ts T (n, args) =
   305   let val (sels, Us) = split_list (map_index (mk_selector ctxt Ts T n) args)
   306   in (Const (n, Us ---> T), sels) end
   307 
   308 fun lookup_datatype ctxt n Ts =
   309   if member (op =) [@{type_name bool}, @{type_name nat}] n then NONE
   310   else
   311     Datatype.get_info (ProofContext.theory_of ctxt) n
   312     |> Option.map (fn {descr, ...} =>
   313          let
   314            val Tds = map (fn (_, (tn, _, _)) => Type (tn, Ts))
   315              (sort (int_ord o pairself fst) descr)
   316            val Tfs = (case hd descr of (_, (_, tfs, _)) => tfs ~~ Ts)
   317          in
   318            descr |> map (fn (i, (_, _, cs)) =>
   319              (nth Tds i, map (mk_constructor ctxt (Tds, Tfs) (nth Tds i)) cs))
   320          end)
   321 
   322 fun relaxed irules = (([], irules), map (prop_of o snd) irules)
   323 
   324 fun with_context header f (ths, ts) =
   325   let val (us, context) = fold_map f ts empty_context
   326   in ((make_sign (header ts) context, us), make_recon ths context) end
   327 
   328 
   329 fun translate {prefixes, strict, header, builtins, serialize} ctxt comments =
   330   let
   331     val {sort_prefix, func_prefix} = prefixes
   332     val {builtin_typ, builtin_num, builtin_fun, has_datatypes} = builtins
   333 
   334     fun transT (T as TFree _) = fresh_typ T (new_typ sort_prefix true)
   335       | transT (T as TVar _) = (fn _ => raise TYPE ("smt_translate", [T], []))
   336       | transT (T as Type (n, Ts)) =
   337           (case builtin_typ ctxt T of
   338             SOME n => pair n
   339           | NONE => fresh_typ T (fn _ => fn cx =>
   340               if not has_datatypes then new_typ sort_prefix true T cx
   341               else
   342                 (case lookup_datatype ctxt n Ts of
   343                   NONE => new_typ sort_prefix true T cx
   344                 | SOME dts =>
   345                     let val cx' = new_dtyps dts cx 
   346                     in (fst (the (lookup_typ cx' T)), cx') end)))
   347 
   348     and new_dtyps dts cx =
   349       let
   350         fun new_decl i t =
   351           let val (Ts, T) = dest_funT i (Term.fastype_of t)
   352           in
   353             fold_map transT Ts ##>> transT T ##>>
   354             new_fun func_prefix t NONE #>> swap
   355           end
   356         fun new_dtyp_decl (con, sels) =
   357           new_decl (length sels) con ##>> fold_map (new_decl 1) sels #>>
   358           (fn ((con', _), sels') => (con', map (apsnd snd) sels'))
   359       in
   360         cx
   361         |> fold_map (new_typ sort_prefix false o fst) dts
   362         ||>> fold_map (fold_map new_dtyp_decl o snd) dts
   363         |-> (fn (ss, decls) => fn (Tidx, typs, dtyps, idx, terms) =>
   364               (Tidx, typs, (ss ~~ decls) :: dtyps, idx, terms))
   365       end
   366 
   367     fun app n ts = SApp (n, ts)
   368 
   369     fun trans t =
   370       (case Term.strip_comb t of
   371         (Const (qn, _), [Abs (_, T, t1)]) =>
   372           (case dest_quant qn T t1 of
   373             SOME (q, Ts, ps, b) =>
   374               fold_map transT Ts ##>> fold_map (fold_map_pat trans) ps ##>>
   375               trans b #>> (fn ((Ts', ps'), b') => SQua (q, Ts', ps', b'))
   376           | NONE => raise TERM ("intermediate", [t]))
   377       | (Const (@{const_name Let}, _), [t1, Abs (_, T, t2)]) =>
   378           transT T ##>> trans t1 ##>> trans t2 #>>
   379           (fn ((U, u1), u2) => SLet (U, u1, u2))
   380       | (h as Const (c as (@{const_name SMT.distinct}, T)), [t1]) =>
   381           (case builtin_fun ctxt c (HOLogic.dest_list t1) of
   382             SOME (n, ts) => fold_map trans ts #>> app n
   383           | NONE => transs h T [t1])
   384       | (h as Const (c as (_, T)), ts) =>
   385           (case try HOLogic.dest_number t of
   386             SOME (T, i) =>
   387               (case builtin_num ctxt T i of
   388                 SOME n => pair (SApp (n, []))
   389               | NONE => transs t T [])
   390           | NONE =>
   391               (case builtin_fun ctxt c ts of
   392                 SOME (n, ts') => fold_map trans ts' #>> app n
   393               | NONE => transs h T ts))
   394       | (h as Free (_, T), ts) => transs h T ts
   395       | (Bound i, []) => pair (SVar i)
   396       | _ => raise TERM ("smt_translate", [t]))
   397 
   398     and transs t T ts =
   399       let val (Us, U) = dest_funT (length ts) T
   400       in
   401         fold_map transT Us ##>> transT U #-> (fn Up =>
   402         fresh_fun func_prefix t (SOME Up) ##>> fold_map trans ts #>> SApp)
   403       end
   404   in
   405     (case strict of SOME strct => strictify strct ctxt | NONE => relaxed) #>
   406     with_context (header ctxt) trans #>> uncurry (serialize comments)
   407   end
   408 
   409 end