src/Tools/induct.ML
author wenzelm
Fri Aug 28 21:04:03 2009 +0200 (2009-08-28)
changeset 32432 64f30bdd3ba1
parent 32188 005f9abae1e3
child 32861 105f40051387
permissions -rw-r--r--
modernized messages -- eliminated ctyp/cterm operations;
     1 (*  Title:      Tools/induct.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Proof by cases, induction, and coinduction.
     5 *)
     6 
     7 signature INDUCT_DATA =
     8 sig
     9   val cases_default: thm
    10   val atomize: thm list
    11   val rulify: thm list
    12   val rulify_fallback: thm list
    13 end;
    14 
    15 signature INDUCT =
    16 sig
    17   (*rule declarations*)
    18   val vars_of: term -> term list
    19   val dest_rules: Proof.context ->
    20     {type_cases: (string * thm) list, pred_cases: (string * thm) list,
    21       type_induct: (string * thm) list, pred_induct: (string * thm) list,
    22       type_coinduct: (string * thm) list, pred_coinduct: (string * thm) list}
    23   val print_rules: Proof.context -> unit
    24   val lookup_casesT: Proof.context -> string -> thm option
    25   val lookup_casesP: Proof.context -> string -> thm option
    26   val lookup_inductT: Proof.context -> string -> thm option
    27   val lookup_inductP: Proof.context -> string -> thm option
    28   val lookup_coinductT: Proof.context -> string -> thm option
    29   val lookup_coinductP: Proof.context -> string -> thm option
    30   val find_casesT: Proof.context -> typ -> thm list
    31   val find_casesP: Proof.context -> term -> thm list
    32   val find_inductT: Proof.context -> typ -> thm list
    33   val find_inductP: Proof.context -> term -> thm list
    34   val find_coinductT: Proof.context -> typ -> thm list
    35   val find_coinductP: Proof.context -> term -> thm list
    36   val cases_type: string -> attribute
    37   val cases_pred: string -> attribute
    38   val cases_del: attribute
    39   val induct_type: string -> attribute
    40   val induct_pred: string -> attribute
    41   val induct_del: attribute
    42   val coinduct_type: string -> attribute
    43   val coinduct_pred: string -> attribute
    44   val coinduct_del: attribute
    45   val casesN: string
    46   val inductN: string
    47   val coinductN: string
    48   val typeN: string
    49   val predN: string
    50   val setN: string
    51   (*proof methods*)
    52   val fix_tac: Proof.context -> int -> (string * typ) list -> int -> tactic
    53   val add_defs: (binding option * term) option list -> Proof.context ->
    54     (term option list * thm list) * Proof.context
    55   val atomize_term: theory -> term -> term
    56   val atomize_tac: int -> tactic
    57   val inner_atomize_tac: int -> tactic
    58   val rulified_term: thm -> theory * term
    59   val rulify_tac: int -> tactic
    60   val internalize: int -> thm -> thm
    61   val guess_instance: Proof.context -> thm -> int -> thm -> thm Seq.seq
    62   val cases_tac: Proof.context -> term option list list -> thm option ->
    63     thm list -> int -> cases_tactic
    64   val get_inductT: Proof.context -> term option list list -> thm list list
    65   val induct_tac: Proof.context -> (binding option * term) option list list ->
    66     (string * typ) list list -> term option list -> thm list option ->
    67     thm list -> int -> cases_tactic
    68   val coinduct_tac: Proof.context -> term option list -> term option list -> thm option ->
    69     thm list -> int -> cases_tactic
    70   val setup: theory -> theory
    71 end;
    72 
    73 functor Induct(Data: INDUCT_DATA): INDUCT =
    74 struct
    75 
    76 
    77 (** misc utils **)
    78 
    79 (* encode_type -- for indexing purposes *)
    80 
    81 fun encode_type (Type (c, Ts)) = Term.list_comb (Const (c, dummyT), map encode_type Ts)
    82   | encode_type (TFree (a, _)) = Free (a, dummyT)
    83   | encode_type (TVar (a, _)) = Var (a, dummyT);
    84 
    85 
    86 (* variables -- ordered left-to-right, preferring right *)
    87 
    88 fun vars_of tm =
    89   rev (distinct (op =) (Term.fold_aterms (fn (t as Var _) => cons t | _ => I) tm []));
    90 
    91 local
    92 
    93 val mk_var = encode_type o #2 o Term.dest_Var;
    94 
    95 fun concl_var which thm = mk_var (which (vars_of (Thm.concl_of thm))) handle Empty =>
    96   raise THM ("No variables in conclusion of rule", 0, [thm]);
    97 
    98 in
    99 
   100 fun left_var_prem thm = mk_var (hd (vars_of (hd (Thm.prems_of thm)))) handle Empty =>
   101   raise THM ("No variables in major premise of rule", 0, [thm]);
   102 
   103 val left_var_concl = concl_var hd;
   104 val right_var_concl = concl_var List.last;
   105 
   106 end;
   107 
   108 
   109 
   110 (** induct data **)
   111 
   112 (* rules *)
   113 
   114 type rules = (string * thm) Item_Net.T;
   115 
   116 val init_rules =
   117   Item_Net.init (fn ((s1: string, th1), (s2, th2)) => s1 = s2 andalso
   118     Thm.eq_thm_prop (th1, th2));
   119 
   120 fun filter_rules (rs: rules) th =
   121   filter (fn (_, th') => Thm.eq_thm_prop (th, th')) (Item_Net.content rs);
   122 
   123 fun lookup_rule (rs: rules) = AList.lookup (op =) (Item_Net.content rs);
   124 
   125 fun pretty_rules ctxt kind rs =
   126   let val thms = map snd (Item_Net.content rs)
   127   in Pretty.big_list kind (map (Display.pretty_thm ctxt) thms) end;
   128 
   129 
   130 (* context data *)
   131 
   132 structure InductData = GenericDataFun
   133 (
   134   type T = (rules * rules) * (rules * rules) * (rules * rules);
   135   val empty =
   136     ((init_rules (left_var_prem o #2), init_rules (Thm.major_prem_of o #2)),
   137      (init_rules (right_var_concl o #2), init_rules (Thm.major_prem_of o #2)),
   138      (init_rules (left_var_concl o #2), init_rules (Thm.concl_of o #2)));
   139   val extend = I;
   140   fun merge _ (((casesT1, casesP1), (inductT1, inductP1), (coinductT1, coinductP1)),
   141       ((casesT2, casesP2), (inductT2, inductP2), (coinductT2, coinductP2))) =
   142     ((Item_Net.merge (casesT1, casesT2), Item_Net.merge (casesP1, casesP2)),
   143       (Item_Net.merge (inductT1, inductT2), Item_Net.merge (inductP1, inductP2)),
   144       (Item_Net.merge (coinductT1, coinductT2), Item_Net.merge (coinductP1, coinductP2)));
   145 );
   146 
   147 val get_local = InductData.get o Context.Proof;
   148 
   149 fun dest_rules ctxt =
   150   let val ((casesT, casesP), (inductT, inductP), (coinductT, coinductP)) = get_local ctxt in
   151     {type_cases = Item_Net.content casesT,
   152      pred_cases = Item_Net.content casesP,
   153      type_induct = Item_Net.content inductT,
   154      pred_induct = Item_Net.content inductP,
   155      type_coinduct = Item_Net.content coinductT,
   156      pred_coinduct = Item_Net.content coinductP}
   157   end;
   158 
   159 fun print_rules ctxt =
   160   let val ((casesT, casesP), (inductT, inductP), (coinductT, coinductP)) = get_local ctxt in
   161    [pretty_rules ctxt "coinduct type:" coinductT,
   162     pretty_rules ctxt "coinduct pred:" coinductP,
   163     pretty_rules ctxt "induct type:" inductT,
   164     pretty_rules ctxt "induct pred:" inductP,
   165     pretty_rules ctxt "cases type:" casesT,
   166     pretty_rules ctxt "cases pred:" casesP]
   167     |> Pretty.chunks |> Pretty.writeln
   168   end;
   169 
   170 val _ =
   171   OuterSyntax.improper_command "print_induct_rules" "print induction and cases rules"
   172     OuterKeyword.diag (Scan.succeed (Toplevel.no_timing o Toplevel.unknown_context o
   173       Toplevel.keep (print_rules o Toplevel.context_of)));
   174 
   175 
   176 (* access rules *)
   177 
   178 val lookup_casesT = lookup_rule o #1 o #1 o get_local;
   179 val lookup_casesP = lookup_rule o #2 o #1 o get_local;
   180 val lookup_inductT = lookup_rule o #1 o #2 o get_local;
   181 val lookup_inductP = lookup_rule o #2 o #2 o get_local;
   182 val lookup_coinductT = lookup_rule o #1 o #3 o get_local;
   183 val lookup_coinductP = lookup_rule o #2 o #3 o get_local;
   184 
   185 
   186 fun find_rules which how ctxt x =
   187   map snd (Item_Net.retrieve (which (get_local ctxt)) (how x));
   188 
   189 val find_casesT = find_rules (#1 o #1) encode_type;
   190 val find_casesP = find_rules (#2 o #1) I;
   191 val find_inductT = find_rules (#1 o #2) encode_type;
   192 val find_inductP = find_rules (#2 o #2) I;
   193 val find_coinductT = find_rules (#1 o #3) encode_type;
   194 val find_coinductP = find_rules (#2 o #3) I;
   195 
   196 
   197 
   198 (** attributes **)
   199 
   200 local
   201 
   202 fun mk_att f g name arg =
   203   let val (x, thm) = g arg in (InductData.map (f (name, thm)) x, thm) end;
   204 
   205 fun del_att which = Thm.declaration_attribute (fn th => InductData.map (which (pairself (fn rs =>
   206   fold Item_Net.delete (filter_rules rs th) rs))));
   207 
   208 fun map1 f (x, y, z) = (f x, y, z);
   209 fun map2 f (x, y, z) = (x, f y, z);
   210 fun map3 f (x, y, z) = (x, y, f z);
   211 
   212 fun add_casesT rule x = map1 (apfst (Item_Net.insert rule)) x;
   213 fun add_casesP rule x = map1 (apsnd (Item_Net.insert rule)) x;
   214 fun add_inductT rule x = map2 (apfst (Item_Net.insert rule)) x;
   215 fun add_inductP rule x = map2 (apsnd (Item_Net.insert rule)) x;
   216 fun add_coinductT rule x = map3 (apfst (Item_Net.insert rule)) x;
   217 fun add_coinductP rule x = map3 (apsnd (Item_Net.insert rule)) x;
   218 
   219 val consumes0 = RuleCases.consumes_default 0;
   220 val consumes1 = RuleCases.consumes_default 1;
   221 
   222 in
   223 
   224 val cases_type = mk_att add_casesT consumes0;
   225 val cases_pred = mk_att add_casesP consumes1;
   226 val cases_del = del_att map1;
   227 
   228 val induct_type = mk_att add_inductT consumes0;
   229 val induct_pred = mk_att add_inductP consumes1;
   230 val induct_del = del_att map2;
   231 
   232 val coinduct_type = mk_att add_coinductT consumes0;
   233 val coinduct_pred = mk_att add_coinductP consumes1;
   234 val coinduct_del = del_att map3;
   235 
   236 end;
   237 
   238 
   239 
   240 (** attribute syntax **)
   241 
   242 val casesN = "cases";
   243 val inductN = "induct";
   244 val coinductN = "coinduct";
   245 
   246 val typeN = "type";
   247 val predN = "pred";
   248 val setN = "set";
   249 
   250 local
   251 
   252 fun spec k arg =
   253   Scan.lift (Args.$$$ k -- Args.colon) |-- arg ||
   254   Scan.lift (Args.$$$ k) >> K "";
   255 
   256 fun attrib add_type add_pred del =
   257   spec typeN Args.tyname >> add_type ||
   258   spec predN Args.const >> add_pred ||
   259   spec setN Args.const >> add_pred ||
   260   Scan.lift Args.del >> K del;
   261 
   262 in
   263 
   264 val attrib_setup =
   265   Attrib.setup @{binding cases} (attrib cases_type cases_pred cases_del)
   266     "declaration of cases rule" #>
   267   Attrib.setup @{binding induct} (attrib induct_type induct_pred induct_del)
   268     "declaration of induction rule" #>
   269   Attrib.setup @{binding coinduct} (attrib coinduct_type coinduct_pred coinduct_del)
   270     "declaration of coinduction rule";
   271 
   272 end;
   273 
   274 
   275 
   276 (** method utils **)
   277 
   278 (* alignment *)
   279 
   280 fun align_left msg xs ys =
   281   let val m = length xs and n = length ys
   282   in if m < n then error msg else (Library.take (n, xs) ~~ ys) end;
   283 
   284 fun align_right msg xs ys =
   285   let val m = length xs and n = length ys
   286   in if m < n then error msg else (Library.drop (m - n, xs) ~~ ys) end;
   287 
   288 
   289 (* prep_inst *)
   290 
   291 fun prep_inst ctxt align tune (tm, ts) =
   292   let
   293     val cert = Thm.cterm_of (ProofContext.theory_of ctxt);
   294     fun prep_var (x, SOME t) =
   295           let
   296             val cx = cert x;
   297             val xT = #T (Thm.rep_cterm cx);
   298             val ct = cert (tune t);
   299             val tT = #T (Thm.rep_cterm ct);
   300           in
   301             if Type.could_unify (tT, xT) then SOME (cx, ct)
   302             else error (Pretty.string_of (Pretty.block
   303              [Pretty.str "Ill-typed instantiation:", Pretty.fbrk,
   304               Syntax.pretty_term ctxt (Thm.term_of ct), Pretty.str " ::", Pretty.brk 1,
   305               Syntax.pretty_typ ctxt tT]))
   306           end
   307       | prep_var (_, NONE) = NONE;
   308     val xs = vars_of tm;
   309   in
   310     align "Rule has fewer variables than instantiations given" xs ts
   311     |> map_filter prep_var
   312   end;
   313 
   314 
   315 (* trace_rules *)
   316 
   317 fun trace_rules _ kind [] = error ("Unable to figure out " ^ kind ^ " rule")
   318   | trace_rules ctxt _ rules = Method.trace ctxt rules;
   319 
   320 
   321 
   322 (** cases method **)
   323 
   324 (*
   325   rule selection scheme:
   326           cases         - default case split
   327     `A t` cases ...     - predicate/set cases
   328           cases t       - type cases
   329     ...   cases ... r   - explicit rule
   330 *)
   331 
   332 local
   333 
   334 fun get_casesT ctxt ((SOME t :: _) :: _) = find_casesT ctxt (Term.fastype_of t)
   335   | get_casesT _ _ = [];
   336 
   337 fun get_casesP ctxt (fact :: _) = find_casesP ctxt (Thm.concl_of fact)
   338   | get_casesP _ _ = [];
   339 
   340 in
   341 
   342 fun cases_tac ctxt insts opt_rule facts =
   343   let
   344     val thy = ProofContext.theory_of ctxt;
   345 
   346     fun inst_rule r =
   347       if null insts then `RuleCases.get r
   348       else (align_left "Rule has fewer premises than arguments given" (Thm.prems_of r) insts
   349         |> maps (prep_inst ctxt align_left I)
   350         |> Drule.cterm_instantiate) r |> pair (RuleCases.get r);
   351 
   352     val ruleq =
   353       (case opt_rule of
   354         SOME r => Seq.single (inst_rule r)
   355       | NONE =>
   356           (get_casesP ctxt facts @ get_casesT ctxt insts @ [Data.cases_default])
   357           |> tap (trace_rules ctxt casesN)
   358           |> Seq.of_list |> Seq.maps (Seq.try inst_rule));
   359   in
   360     fn i => fn st =>
   361       ruleq
   362       |> Seq.maps (RuleCases.consume [] facts)
   363       |> Seq.maps (fn ((cases, (_, more_facts)), rule) =>
   364         CASES (RuleCases.make_common false (thy, Thm.prop_of rule) cases)
   365           (Method.insert_tac more_facts i THEN Tactic.rtac rule i) st)
   366   end;
   367 
   368 end;
   369 
   370 
   371 
   372 (** induct method **)
   373 
   374 val conjunction_congs = [@{thm Pure.all_conjunction}, @{thm imp_conjunction}];
   375 
   376 
   377 (* atomize *)
   378 
   379 fun atomize_term thy =
   380   MetaSimplifier.rewrite_term thy Data.atomize []
   381   #> ObjectLogic.drop_judgment thy;
   382 
   383 val atomize_cterm = MetaSimplifier.rewrite true Data.atomize;
   384 
   385 val atomize_tac = Simplifier.rewrite_goal_tac Data.atomize;
   386 
   387 val inner_atomize_tac =
   388   Simplifier.rewrite_goal_tac (map Thm.symmetric conjunction_congs) THEN' atomize_tac;
   389 
   390 
   391 (* rulify *)
   392 
   393 fun rulify_term thy =
   394   MetaSimplifier.rewrite_term thy (Data.rulify @ conjunction_congs) [] #>
   395   MetaSimplifier.rewrite_term thy Data.rulify_fallback [];
   396 
   397 fun rulified_term thm =
   398   let
   399     val thy = Thm.theory_of_thm thm;
   400     val rulify = rulify_term thy;
   401     val (As, B) = Logic.strip_horn (Thm.prop_of thm);
   402   in (thy, Logic.list_implies (map rulify As, rulify B)) end;
   403 
   404 val rulify_tac =
   405   Simplifier.rewrite_goal_tac (Data.rulify @ conjunction_congs) THEN'
   406   Simplifier.rewrite_goal_tac Data.rulify_fallback THEN'
   407   Goal.conjunction_tac THEN_ALL_NEW
   408   (Simplifier.rewrite_goal_tac [@{thm Pure.conjunction_imp}] THEN' Goal.norm_hhf_tac);
   409 
   410 
   411 (* prepare rule *)
   412 
   413 fun rule_instance ctxt inst rule =
   414   Drule.cterm_instantiate (prep_inst ctxt align_left I (Thm.prop_of rule, inst)) rule;
   415 
   416 fun internalize k th =
   417   th |> Thm.permute_prems 0 k
   418   |> Conv.fconv_rule (Conv.concl_conv (Thm.nprems_of th - k) atomize_cterm);
   419 
   420 
   421 (* guess rule instantiation -- cannot handle pending goal parameters *)
   422 
   423 local
   424 
   425 fun dest_env thy env =
   426   let
   427     val cert = Thm.cterm_of thy;
   428     val certT = Thm.ctyp_of thy;
   429     val pairs = Vartab.dest (Envir.term_env env);
   430     val types = Vartab.dest (Envir.type_env env);
   431     val ts = map (cert o Envir.norm_term env o #2 o #2) pairs;
   432     val xs = map2 (curry (cert o Var)) (map #1 pairs) (map (#T o Thm.rep_cterm) ts);
   433   in (map (fn (xi, (S, T)) => (certT (TVar (xi, S)), certT T)) types, xs ~~ ts) end;
   434 
   435 in
   436 
   437 fun guess_instance ctxt rule i st =
   438   let
   439     val thy = ProofContext.theory_of ctxt;
   440     val maxidx = Thm.maxidx_of st;
   441     val goal = Thm.term_of (Thm.cprem_of st i);  (*exception Subscript*)
   442     val params = rev (Term.rename_wrt_term goal (Logic.strip_params goal));
   443   in
   444     if not (null params) then
   445       (warning ("Cannot determine rule instantiation due to pending parameter(s): " ^
   446         commas_quote (map (Syntax.string_of_term ctxt o Syntax.mark_boundT) params));
   447       Seq.single rule)
   448     else
   449       let
   450         val rule' = Thm.incr_indexes (maxidx + 1) rule;
   451         val concl = Logic.strip_assums_concl goal;
   452       in
   453         Unify.smash_unifiers thy [(Thm.concl_of rule', concl)] (Envir.empty (Thm.maxidx_of rule'))
   454         |> Seq.map (fn env => Drule.instantiate (dest_env thy env) rule')
   455       end
   456   end handle Subscript => Seq.empty;
   457 
   458 end;
   459 
   460 
   461 (* special renaming of rule parameters *)
   462 
   463 fun special_rename_params ctxt [[SOME (Free (z, Type (T, _)))]] [thm] =
   464       let
   465         val x = Name.clean (ProofContext.revert_skolem ctxt z);
   466         fun index i [] = []
   467           | index i (y :: ys) =
   468               if x = y then x ^ string_of_int i :: index (i + 1) ys
   469               else y :: index i ys;
   470         fun rename_params [] = []
   471           | rename_params ((y, Type (U, _)) :: ys) =
   472               (if U = T then x else y) :: rename_params ys
   473           | rename_params ((y, _) :: ys) = y :: rename_params ys;
   474         fun rename_asm A =
   475           let
   476             val xs = rename_params (Logic.strip_params A);
   477             val xs' =
   478               (case filter (fn x' => x' = x) xs of
   479                 [] => xs | [_] => xs | _ => index 1 xs);
   480           in Logic.list_rename_params (xs', A) end;
   481         fun rename_prop p =
   482           let val (As, C) = Logic.strip_horn p
   483           in Logic.list_implies (map rename_asm As, C) end;
   484         val cp' = cterm_fun rename_prop (Thm.cprop_of thm);
   485         val thm' = Thm.equal_elim (Thm.reflexive cp') thm;
   486       in [RuleCases.save thm thm'] end
   487   | special_rename_params _ _ ths = ths;
   488 
   489 
   490 (* fix_tac *)
   491 
   492 local
   493 
   494 fun goal_prefix k ((c as Const ("all", _)) $ Abs (a, T, B)) = c $ Abs (a, T, goal_prefix k B)
   495   | goal_prefix 0 _ = Term.dummy_pattern propT
   496   | goal_prefix k ((c as Const ("==>", _)) $ A $ B) = c $ A $ goal_prefix (k - 1) B
   497   | goal_prefix _ _ = Term.dummy_pattern propT;
   498 
   499 fun goal_params k (Const ("all", _) $ Abs (_, _, B)) = goal_params k B + 1
   500   | goal_params 0 _ = 0
   501   | goal_params k (Const ("==>", _) $ _ $ B) = goal_params (k - 1) B
   502   | goal_params _ _ = 0;
   503 
   504 fun meta_spec_tac ctxt n (x, T) = SUBGOAL (fn (goal, i) =>
   505   let
   506     val thy = ProofContext.theory_of ctxt;
   507     val cert = Thm.cterm_of thy;
   508     val certT = Thm.ctyp_of thy;
   509 
   510     val v = Free (x, T);
   511     fun spec_rule prfx (xs, body) =
   512       @{thm Pure.meta_spec}
   513       |> Thm.rename_params_rule ([Name.clean (ProofContext.revert_skolem ctxt x)], 1)
   514       |> Thm.lift_rule (cert prfx)
   515       |> `(Thm.prop_of #> Logic.strip_assums_concl)
   516       |-> (fn pred $ arg =>
   517         Drule.cterm_instantiate
   518           [(cert (Term.head_of pred), cert (Logic.rlist_abs (xs, body))),
   519            (cert (Term.head_of arg), cert (Logic.rlist_abs (xs, v)))]);
   520 
   521     fun goal_concl k xs (Const ("all", _) $ Abs (a, T, B)) = goal_concl k ((a, T) :: xs) B
   522       | goal_concl 0 xs B =
   523           if not (Term.exists_subterm (fn t => t aconv v) B) then NONE
   524           else SOME (xs, Term.absfree (x, T, Term.incr_boundvars 1 B))
   525       | goal_concl k xs (Const ("==>", _) $ _ $ B) = goal_concl (k - 1) xs B
   526       | goal_concl _ _ _ = NONE;
   527   in
   528     (case goal_concl n [] goal of
   529       SOME concl =>
   530         (compose_tac (false, spec_rule (goal_prefix n goal) concl, 1) THEN' rtac asm_rl) i
   531     | NONE => all_tac)
   532   end);
   533 
   534 fun miniscope_tac p = CONVERSION o
   535   Conv.params_conv p (K (MetaSimplifier.rewrite true [Thm.symmetric Drule.norm_hhf_eq]));
   536 
   537 in
   538 
   539 fun fix_tac _ _ [] = K all_tac
   540   | fix_tac ctxt n xs = SUBGOAL (fn (goal, i) =>
   541      (EVERY' (map (meta_spec_tac ctxt n) xs) THEN'
   542       (miniscope_tac (goal_params n goal) ctxt)) i);
   543 
   544 end;
   545 
   546 
   547 (* add_defs *)
   548 
   549 fun add_defs def_insts =
   550   let
   551     fun add (SOME (SOME x, t)) ctxt =
   552           let val ([(lhs, (_, th))], ctxt') =
   553             LocalDefs.add_defs [((x, NoSyn), (Thm.empty_binding, t))] ctxt
   554           in ((SOME lhs, [th]), ctxt') end
   555       | add (SOME (NONE, t)) ctxt = ((SOME t, []), ctxt)
   556       | add NONE ctxt = ((NONE, []), ctxt);
   557   in fold_map add def_insts #> apfst (split_list #> apsnd flat) end;
   558 
   559 
   560 (* induct_tac *)
   561 
   562 (*
   563   rule selection scheme:
   564     `A x` induct ...     - predicate/set induction
   565           induct x       - type induction
   566     ...   induct ... r   - explicit rule
   567 *)
   568 
   569 fun get_inductT ctxt insts =
   570   fold_rev (map_product cons) (insts |> map
   571       ((fn [] => NONE | ts => List.last ts) #>
   572         (fn NONE => TVar (("'a", 0), []) | SOME t => Term.fastype_of t) #>
   573         find_inductT ctxt)) [[]]
   574   |> filter_out (forall Thm.is_internal);
   575 
   576 fun get_inductP ctxt (fact :: _) = map single (find_inductP ctxt (Thm.concl_of fact))
   577   | get_inductP _ _ = [];
   578 
   579 fun induct_tac ctxt def_insts arbitrary taking opt_rule facts =
   580   let
   581     val thy = ProofContext.theory_of ctxt;
   582     val cert = Thm.cterm_of thy;
   583 
   584     val ((insts, defs), defs_ctxt) = fold_map add_defs def_insts ctxt |>> split_list;
   585     val atomized_defs = map (map (Conv.fconv_rule ObjectLogic.atomize)) defs;
   586 
   587     fun inst_rule (concls, r) =
   588       (if null insts then `RuleCases.get r
   589        else (align_left "Rule has fewer conclusions than arguments given"
   590           (map Logic.strip_imp_concl (Logic.dest_conjunctions (Thm.concl_of r))) insts
   591         |> maps (prep_inst ctxt align_right (atomize_term thy))
   592         |> Drule.cterm_instantiate) r |> pair (RuleCases.get r))
   593       |> (fn ((cases, consumes), th) => (((cases, concls), consumes), th));
   594 
   595     val ruleq =
   596       (case opt_rule of
   597         SOME rs => Seq.single (inst_rule (RuleCases.strict_mutual_rule ctxt rs))
   598       | NONE =>
   599           (get_inductP ctxt facts @
   600             map (special_rename_params defs_ctxt insts) (get_inductT ctxt insts))
   601           |> map_filter (RuleCases.mutual_rule ctxt)
   602           |> tap (trace_rules ctxt inductN o map #2)
   603           |> Seq.of_list |> Seq.maps (Seq.try inst_rule));
   604 
   605     fun rule_cases rule =
   606       RuleCases.make_nested false (Thm.prop_of rule) (rulified_term rule);
   607   in
   608     (fn i => fn st =>
   609       ruleq
   610       |> Seq.maps (RuleCases.consume (flat defs) facts)
   611       |> Seq.maps (fn (((cases, concls), (more_consumes, more_facts)), rule) =>
   612         (PRECISE_CONJUNCTS (length concls) (ALLGOALS (fn j =>
   613           (CONJUNCTS (ALLGOALS
   614             (Method.insert_tac (more_facts @ nth_list atomized_defs (j - 1))
   615               THEN' fix_tac defs_ctxt
   616                 (nth concls (j - 1) + more_consumes)
   617                 (nth_list arbitrary (j - 1))))
   618           THEN' inner_atomize_tac) j))
   619         THEN' atomize_tac) i st |> Seq.maps (fn st' =>
   620             guess_instance ctxt (internalize more_consumes rule) i st'
   621             |> Seq.map (rule_instance ctxt (burrow_options (Variable.polymorphic ctxt) taking))
   622             |> Seq.maps (fn rule' =>
   623               CASES (rule_cases rule' cases)
   624                 (Tactic.rtac rule' i THEN
   625                   PRIMITIVE (singleton (ProofContext.export defs_ctxt ctxt))) st'))))
   626     THEN_ALL_NEW_CASES rulify_tac
   627   end;
   628 
   629 
   630 
   631 (** coinduct method **)
   632 
   633 (*
   634   rule selection scheme:
   635     goal "A x" coinduct ...   - predicate/set coinduction
   636                coinduct x     - type coinduction
   637                coinduct ... r - explicit rule
   638 *)
   639 
   640 local
   641 
   642 fun get_coinductT ctxt (SOME t :: _) = find_coinductT ctxt (Term.fastype_of t)
   643   | get_coinductT _ _ = [];
   644 
   645 fun get_coinductP ctxt goal = find_coinductP ctxt (Logic.strip_assums_concl goal);
   646 
   647 fun main_prop_of th =
   648   if RuleCases.get_consumes th > 0 then Thm.major_prem_of th else Thm.concl_of th;
   649 
   650 in
   651 
   652 fun coinduct_tac ctxt inst taking opt_rule facts =
   653   let
   654     val thy = ProofContext.theory_of ctxt;
   655     val cert = Thm.cterm_of thy;
   656 
   657     fun inst_rule r =
   658       if null inst then `RuleCases.get r
   659       else Drule.cterm_instantiate (prep_inst ctxt align_right I (main_prop_of r, inst)) r
   660         |> pair (RuleCases.get r);
   661 
   662     fun ruleq goal =
   663       (case opt_rule of
   664         SOME r => Seq.single (inst_rule r)
   665       | NONE =>
   666           (get_coinductP ctxt goal @ get_coinductT ctxt inst)
   667           |> tap (trace_rules ctxt coinductN)
   668           |> Seq.of_list |> Seq.maps (Seq.try inst_rule));
   669   in
   670     SUBGOAL_CASES (fn (goal, i) => fn st =>
   671       ruleq goal
   672       |> Seq.maps (RuleCases.consume [] facts)
   673       |> Seq.maps (fn ((cases, (_, more_facts)), rule) =>
   674         guess_instance ctxt rule i st
   675         |> Seq.map (rule_instance ctxt (burrow_options (Variable.polymorphic ctxt) taking))
   676         |> Seq.maps (fn rule' =>
   677           CASES (RuleCases.make_common false (thy, Thm.prop_of rule') cases)
   678             (Method.insert_tac more_facts i THEN Tactic.rtac rule' i) st)))
   679   end;
   680 
   681 end;
   682 
   683 
   684 
   685 (** concrete syntax **)
   686 
   687 structure P = OuterParse;
   688 
   689 val arbitraryN = "arbitrary";
   690 val takingN = "taking";
   691 val ruleN = "rule";
   692 
   693 local
   694 
   695 fun single_rule [rule] = rule
   696   | single_rule _ = error "Single rule expected";
   697 
   698 fun named_rule k arg get =
   699   Scan.lift (Args.$$$ k -- Args.colon) |-- Scan.repeat arg :|--
   700     (fn names => Scan.peek (fn context => Scan.succeed (names |> map (fn name =>
   701       (case get (Context.proof_of context) name of SOME x => x
   702       | NONE => error ("No rule for " ^ k ^ " " ^ quote name))))));
   703 
   704 fun rule get_type get_pred =
   705   named_rule typeN Args.tyname get_type ||
   706   named_rule predN Args.const get_pred ||
   707   named_rule setN Args.const get_pred ||
   708   Scan.lift (Args.$$$ ruleN -- Args.colon) |-- Attrib.thms;
   709 
   710 val cases_rule = rule lookup_casesT lookup_casesP >> single_rule;
   711 val induct_rule = rule lookup_inductT lookup_inductP;
   712 val coinduct_rule = rule lookup_coinductT lookup_coinductP >> single_rule;
   713 
   714 val inst = Scan.lift (Args.$$$ "_") >> K NONE || Args.term >> SOME;
   715 
   716 val def_inst =
   717   ((Scan.lift (Args.binding --| (Args.$$$ "\<equiv>" || Args.$$$ "==")) >> SOME)
   718       -- Args.term) >> SOME ||
   719     inst >> Option.map (pair NONE);
   720 
   721 val free = Args.context -- Args.term >> (fn (_, Free v) => v | (ctxt, t) =>
   722   error ("Bad free variable: " ^ Syntax.string_of_term ctxt t));
   723 
   724 fun unless_more_args scan = Scan.unless (Scan.lift
   725   ((Args.$$$ arbitraryN || Args.$$$ takingN || Args.$$$ typeN ||
   726     Args.$$$ predN || Args.$$$ setN || Args.$$$ ruleN) -- Args.colon)) scan;
   727 
   728 val arbitrary = Scan.optional (Scan.lift (Args.$$$ arbitraryN -- Args.colon) |--
   729   P.and_list1' (Scan.repeat (unless_more_args free))) [];
   730 
   731 val taking = Scan.optional (Scan.lift (Args.$$$ takingN -- Args.colon) |--
   732   Scan.repeat1 (unless_more_args inst)) [];
   733 
   734 in
   735 
   736 val cases_setup =
   737   Method.setup @{binding cases}
   738     (P.and_list' (Scan.repeat (unless_more_args inst)) -- Scan.option cases_rule >>
   739       (fn (insts, opt_rule) => fn ctxt =>
   740         METHOD_CASES (fn facts => Seq.DETERM (HEADGOAL (cases_tac ctxt insts opt_rule facts)))))
   741     "case analysis on types or predicates/sets";
   742 
   743 val induct_setup =
   744   Method.setup @{binding induct}
   745     (P.and_list' (Scan.repeat (unless_more_args def_inst)) --
   746       (arbitrary -- taking -- Scan.option induct_rule) >>
   747       (fn (insts, ((arbitrary, taking), opt_rule)) => fn ctxt =>
   748         RAW_METHOD_CASES (fn facts =>
   749           Seq.DETERM (HEADGOAL (induct_tac ctxt insts arbitrary taking opt_rule facts)))))
   750     "induction on types or predicates/sets";
   751 
   752 val coinduct_setup =
   753   Method.setup @{binding coinduct}
   754     (Scan.repeat (unless_more_args inst) -- taking -- Scan.option coinduct_rule >>
   755       (fn ((insts, taking), opt_rule) => fn ctxt =>
   756         RAW_METHOD_CASES (fn facts =>
   757           Seq.DETERM (HEADGOAL (coinduct_tac ctxt insts taking opt_rule facts)))))
   758     "coinduction on types or predicates/sets";
   759 
   760 end;
   761 
   762 
   763 
   764 (** theory setup **)
   765 
   766 val setup = attrib_setup #> cases_setup  #> induct_setup #> coinduct_setup;
   767 
   768 end;