src/Pure/theory.ML
author wenzelm
Tue Apr 15 18:49:23 2008 +0200 (2008-04-15)
changeset 26668 65023d4fd226
parent 26631 d6b6c74a8bcf
child 26939 1035c89b4c02
permissions -rw-r--r--
removed obsolete SIGN_THEORY -- no name aliases in structure Theory;
removed obsolete BASIC_THEORY;
     1 (*  Title:      Pure/theory.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical theory content: axioms, definitions, oracles.
     6 *)
     7 
     8 signature THEORY =
     9 sig
    10   val eq_thy: theory * theory -> bool
    11   val subthy: theory * theory -> bool
    12   val assert_super: theory -> theory -> theory
    13   val parents_of: theory -> theory list
    14   val ancestors_of: theory -> theory list
    15   val check_thy: theory -> theory_ref
    16   val deref: theory_ref -> theory
    17   val merge: theory * theory -> theory
    18   val merge_refs: theory_ref * theory_ref -> theory_ref
    19   val merge_list: theory list -> theory
    20   val checkpoint: theory -> theory
    21   val copy: theory -> theory
    22   val requires: theory -> string -> string -> unit
    23   val axiom_space: theory -> NameSpace.T
    24   val axiom_table: theory -> term Symtab.table
    25   val oracle_space: theory -> NameSpace.T
    26   val oracle_table: theory -> ((theory * Object.T -> term) * stamp) Symtab.table
    27   val axioms_of: theory -> (string * term) list
    28   val all_axioms_of: theory -> (string * term) list
    29   val defs_of: theory -> Defs.T
    30   val at_begin: (theory -> theory option) -> theory -> theory
    31   val at_end: (theory -> theory option) -> theory -> theory
    32   val begin_theory: string -> theory list -> theory
    33   val end_theory: theory -> theory
    34   val add_axioms: (bstring * string) list -> theory -> theory
    35   val add_axioms_i: (bstring * term) list -> theory -> theory
    36   val add_deps: string -> string * typ -> (string * typ) list -> theory -> theory
    37   val add_defs: bool -> bool -> (bstring * string) list -> theory -> theory
    38   val add_defs_i: bool -> bool -> (bstring * term) list -> theory -> theory
    39   val add_finals: bool -> string list -> theory -> theory
    40   val add_finals_i: bool -> term list -> theory -> theory
    41   val specify_const: Markup.property list -> bstring * typ * mixfix -> (string * typ) list ->
    42    theory -> term * theory
    43   val add_oracle: bstring * (theory * Object.T -> term) -> theory -> theory
    44 end
    45 
    46 structure Theory: THEORY =
    47 struct
    48 
    49 
    50 (** theory context operations **)
    51 
    52 val eq_thy = Context.eq_thy;
    53 val subthy = Context.subthy;
    54 
    55 fun assert_super thy1 thy2 =
    56   if subthy (thy1, thy2) then thy2
    57   else raise THEORY ("Not a super theory", [thy1, thy2]);
    58 
    59 val parents_of = Context.parents_of;
    60 val ancestors_of = Context.ancestors_of;
    61 
    62 val check_thy = Context.check_thy;
    63 val deref = Context.deref;
    64 
    65 val merge = Context.merge;
    66 val merge_refs = Context.merge_refs;
    67 
    68 fun merge_list [] = raise THEORY ("Empty merge of theories", [])
    69   | merge_list (thy :: thys) = Library.foldl merge (thy, thys);
    70 
    71 val checkpoint = Context.checkpoint_thy;
    72 val copy = Context.copy_thy;
    73 
    74 fun requires thy name what =
    75   if Context.exists_name name thy then ()
    76   else error ("Require theory " ^ quote name ^ " as an ancestor for " ^ what);
    77 
    78 
    79 
    80 (** datatype thy **)
    81 
    82 type wrapper = (theory -> theory option) * stamp;
    83 
    84 fun apply_wrappers (wrappers: wrapper list) =
    85   perhaps (perhaps_loop (perhaps_apply (map fst wrappers)));
    86 
    87 datatype thy = Thy of
    88  {axioms: term NameSpace.table,
    89   defs: Defs.T,
    90   oracles: ((theory * Object.T -> term) * stamp) NameSpace.table,
    91   wrappers: wrapper list * wrapper list};
    92 
    93 fun make_thy (axioms, defs, oracles, wrappers) =
    94   Thy {axioms = axioms, defs = defs, oracles = oracles, wrappers = wrappers};
    95 
    96 fun err_dup_axm dup = error ("Duplicate axiom: " ^ quote dup);
    97 fun err_dup_ora dup = error ("Duplicate oracle: " ^ quote dup);
    98 
    99 structure ThyData = TheoryDataFun
   100 (
   101   type T = thy;
   102   val empty = make_thy (NameSpace.empty_table, Defs.empty, NameSpace.empty_table, ([], []));
   103   val copy = I;
   104 
   105   fun extend (Thy {axioms, defs, oracles, wrappers}) =
   106     make_thy (NameSpace.empty_table, defs, oracles, wrappers);
   107 
   108   fun merge pp (thy1, thy2) =
   109     let
   110       val Thy {axioms = _, defs = defs1, oracles = oracles1, wrappers = (bgs1, ens1)} = thy1;
   111       val Thy {axioms = _, defs = defs2, oracles = oracles2, wrappers = (bgs2, ens2)} = thy2;
   112 
   113       val axioms' = NameSpace.empty_table;
   114       val defs' = Defs.merge pp (defs1, defs2);
   115       val oracles' = NameSpace.merge_tables (eq_snd (op =)) (oracles1, oracles2)
   116         handle Symtab.DUP dup => err_dup_ora dup;
   117       val bgs' = Library.merge (eq_snd op =) (bgs1, bgs2);
   118       val ens' = Library.merge (eq_snd op =) (ens1, ens2);
   119     in make_thy (axioms', defs', oracles', (bgs', ens')) end;
   120 );
   121 
   122 fun rep_theory thy = ThyData.get thy |> (fn Thy args => args);
   123 
   124 fun map_thy f = ThyData.map (fn (Thy {axioms, defs, oracles, wrappers}) =>
   125   make_thy (f (axioms, defs, oracles, wrappers)));
   126 
   127 
   128 fun map_axioms f = map_thy
   129   (fn (axioms, defs, oracles, wrappers) => (f axioms, defs, oracles, wrappers));
   130 
   131 fun map_defs f = map_thy
   132   (fn (axioms, defs, oracles, wrappers) => (axioms, f defs, oracles, wrappers));
   133 
   134 fun map_oracles f = map_thy
   135   (fn (axioms, defs, oracles, wrappers) => (axioms, defs, f oracles, wrappers));
   136 
   137 fun map_wrappers f = map_thy
   138   (fn (axioms, defs, oracles, wrappers) => (axioms, defs, oracles, f wrappers));
   139 
   140 
   141 (* basic operations *)
   142 
   143 val axiom_space = #1 o #axioms o rep_theory;
   144 val axiom_table = #2 o #axioms o rep_theory;
   145 
   146 val oracle_space = #1 o #oracles o rep_theory;
   147 val oracle_table = #2 o #oracles o rep_theory;
   148 
   149 val axioms_of = Symtab.dest o #2 o #axioms o rep_theory;
   150 fun all_axioms_of thy = maps axioms_of (thy :: ancestors_of thy);
   151 
   152 val defs_of = #defs o rep_theory;
   153 
   154 
   155 (* begin/end theory *)
   156 
   157 val begin_wrappers = rev o #1 o #wrappers o rep_theory;
   158 val end_wrappers = rev o #2 o #wrappers o rep_theory;
   159 
   160 fun at_begin f = map_wrappers (apfst (cons (f, stamp ())));
   161 fun at_end f = map_wrappers (apsnd (cons (f, stamp ())));
   162 
   163 fun begin_theory name imports =
   164   let
   165     val thy = Context.begin_thy Sign.pp name imports;
   166     val wrappers = begin_wrappers thy;
   167   in thy |> Sign.local_path |> apply_wrappers wrappers end;
   168 
   169 fun end_theory thy =
   170   thy |> apply_wrappers (end_wrappers thy) |> Context.finish_thy;
   171 
   172 
   173 
   174 (** add axioms **)
   175 
   176 (* prepare axioms *)
   177 
   178 fun err_in_axm msg name =
   179   cat_error msg ("The error(s) above occurred in axiom " ^ quote name);
   180 
   181 fun cert_axm thy (name, raw_tm) =
   182   let
   183     val (t, T, _) = Sign.certify_prop thy raw_tm
   184       handle TYPE (msg, _, _) => error msg
   185         | TERM (msg, _) => error msg;
   186   in
   187     Term.no_dummy_patterns t handle TERM (msg, _) => error msg;
   188     (name, Sign.no_vars (Sign.pp thy) t)
   189   end;
   190 
   191 fun read_axm thy (name, str) =
   192   cert_axm thy (name, Syntax.read_prop_global thy str)
   193     handle ERROR msg => err_in_axm msg name;
   194 
   195 
   196 (* add_axioms(_i) *)
   197 
   198 local
   199 
   200 fun gen_add_axioms prep_axm raw_axms thy = thy |> map_axioms (fn axioms =>
   201   let
   202     val axms = map (apsnd Logic.varify o prep_axm thy) raw_axms;
   203     val axioms' = NameSpace.extend_table (Sign.naming_of thy) axms axioms
   204       handle Symtab.DUP dup => err_dup_axm dup;
   205   in axioms' end);
   206 
   207 in
   208 
   209 val add_axioms = gen_add_axioms read_axm;
   210 val add_axioms_i = gen_add_axioms cert_axm;
   211 
   212 end;
   213 
   214 
   215 
   216 (** add constant definitions **)
   217 
   218 (* dependencies *)
   219 
   220 fun dependencies thy unchecked is_def name lhs rhs =
   221   let
   222     val pp = Sign.pp thy;
   223     val consts = Sign.consts_of thy;
   224     fun prep const =
   225       let val Const (c, T) = Sign.no_vars pp (Const const)
   226       in (c, Consts.typargs consts (c, Logic.varifyT T)) end;
   227 
   228     val lhs_vars = Term.add_tfreesT (#2 lhs) [];
   229     val rhs_extras = fold (#2 #> Term.fold_atyps (fn TFree v =>
   230       if member (op =) lhs_vars v then I else insert (op =) v | _ => I)) rhs [];
   231     val _ =
   232       if null rhs_extras then ()
   233       else error ("Specification depends on extra type variables: " ^
   234         commas_quote (map (Pretty.string_of_typ pp o TFree) rhs_extras) ^
   235         "\nThe error(s) above occurred in " ^ quote name);
   236   in Defs.define pp unchecked is_def name (prep lhs) (map prep rhs) end;
   237 
   238 fun add_deps a raw_lhs raw_rhs thy =
   239   let
   240     val lhs :: rhs = map (dest_Const o Sign.cert_term thy o Const) (raw_lhs :: raw_rhs);
   241     val name = if a = "" then (#1 lhs ^ " axiom") else a;
   242   in thy |> map_defs (dependencies thy false false name lhs rhs) end;
   243 
   244 fun specify_const tags decl deps thy =
   245   let val (t as Const const, thy') = Sign.declare_const tags decl thy
   246   in (t, add_deps "" const deps thy') end;
   247 
   248 
   249 (* check_overloading *)
   250 
   251 fun check_overloading thy overloaded (c, T) =
   252   let
   253     val declT = Sign.the_const_constraint thy c
   254       handle TYPE (msg, _, _) => error msg;
   255     val T' = Logic.varifyT T;
   256 
   257     fun message txt =
   258       [Pretty.block [Pretty.str "Specification of constant ",
   259         Pretty.str c, Pretty.str " ::", Pretty.brk 1, Pretty.quote (Sign.pretty_typ thy T)],
   260         Pretty.str txt] |> Pretty.chunks |> Pretty.string_of;
   261   in
   262     if Sign.typ_instance thy (declT, T') then ()
   263     else if Type.raw_instance (declT, T') then
   264       error (Library.setmp show_sorts true
   265         message "imposes additional sort constraints on the constant declaration")
   266     else if overloaded then ()
   267     else warning (message "is strictly less general than the declared type");
   268     (c, T)
   269   end;
   270 
   271 
   272 (* check_def *)
   273 
   274 fun check_def thy unchecked overloaded (bname, tm) defs =
   275   let
   276     val ctxt = ProofContext.init thy;
   277     val name = Sign.full_name thy bname;
   278     val (lhs_const, rhs) = Sign.cert_def ctxt tm;
   279     val rhs_consts = fold_aterms (fn Const const => insert (op =) const | _ => I) rhs [];
   280     val _ = check_overloading thy overloaded lhs_const;
   281   in defs |> dependencies thy unchecked true name lhs_const rhs_consts end
   282   handle ERROR msg => cat_error msg (Pretty.string_of (Pretty.block
   283    [Pretty.str ("The error(s) above occurred in definition " ^ quote bname ^ ":"),
   284     Pretty.fbrk, Pretty.quote (Sign.pretty_term thy tm)]));
   285 
   286 
   287 (* add_defs(_i) *)
   288 
   289 local
   290 
   291 fun gen_add_defs prep_axm unchecked overloaded raw_axms thy =
   292   let val axms = map (prep_axm thy) raw_axms in
   293     thy
   294     |> map_defs (fold (check_def thy unchecked overloaded) axms)
   295     |> add_axioms_i axms
   296   end;
   297 
   298 in
   299 
   300 val add_defs_i = gen_add_defs cert_axm;
   301 val add_defs = gen_add_defs read_axm;
   302 
   303 end;
   304 
   305 
   306 (* add_finals(_i) *)
   307 
   308 local
   309 
   310 fun gen_add_finals prep_term overloaded args thy =
   311   let
   312     fun const_of (Const const) = const
   313       | const_of (Free _) = error "Attempt to finalize variable (or undeclared constant)"
   314       | const_of _ = error "Attempt to finalize non-constant term";
   315     fun specify (c, T) = dependencies thy false false (c ^ " axiom") (c, T) [];
   316     val finalize = specify o check_overloading thy overloaded o const_of o
   317       Sign.cert_term thy o prep_term thy;
   318   in thy |> map_defs (fold finalize args) end;
   319 
   320 in
   321 
   322 val add_finals = gen_add_finals Syntax.read_term_global;
   323 val add_finals_i = gen_add_finals (K I);
   324 
   325 end;
   326 
   327 
   328 
   329 (** add oracle **)
   330 
   331 fun add_oracle (bname, oracle) thy = thy |> map_oracles (fn oracles =>
   332   NameSpace.extend_table (Sign.naming_of thy) [(bname, (oracle, stamp ()))] oracles
   333     handle Symtab.DUP dup => err_dup_ora dup);
   334 
   335 end;
   336