src/HOL/Library/Quotient_List.thy
 author Manuel Eberl Mon Mar 26 16:14:16 2018 +0200 (18 months ago) changeset 67951 655aa11359dc parent 67399 eab6ce8368fa permissions -rw-r--r--
Removed some uses of deprecated _tac methods. (Patch from Viorel Preoteasa)
1 (*  Title:      HOL/Library/Quotient_List.thy
2     Author:     Cezary Kaliszyk and Christian Urban
3 *)
5 section \<open>Quotient infrastructure for the list type\<close>
7 theory Quotient_List
8 imports Quotient_Set Quotient_Product Quotient_Option
9 begin
11 subsection \<open>Rules for the Quotient package\<close>
13 lemma map_id [id_simps]:
14   "map id = id"
15   by (fact List.map.id)
17 lemma list_all2_eq [id_simps]:
18   "list_all2 (=) = (=)"
19 proof (rule ext)+
20   fix xs ys
21   show "list_all2 (=) xs ys \<longleftrightarrow> xs = ys"
22     by (induct xs ys rule: list_induct2') simp_all
23 qed
25 lemma reflp_list_all2:
26   assumes "reflp R"
27   shows "reflp (list_all2 R)"
28 proof (rule reflpI)
29   from assms have *: "\<And>xs. R xs xs" by (rule reflpE)
30   fix xs
31   show "list_all2 R xs xs"
32     by (induct xs) (simp_all add: *)
33 qed
35 lemma list_symp:
36   assumes "symp R"
37   shows "symp (list_all2 R)"
38 proof (rule sympI)
39   from assms have *: "\<And>xs ys. R xs ys \<Longrightarrow> R ys xs" by (rule sympE)
40   fix xs ys
41   assume "list_all2 R xs ys"
42   then show "list_all2 R ys xs"
43     by (induct xs ys rule: list_induct2') (simp_all add: *)
44 qed
46 lemma list_transp:
47   assumes "transp R"
48   shows "transp (list_all2 R)"
49 proof (rule transpI)
50   from assms have *: "\<And>xs ys zs. R xs ys \<Longrightarrow> R ys zs \<Longrightarrow> R xs zs" by (rule transpE)
51   fix xs ys zs
52   assume "list_all2 R xs ys" and "list_all2 R ys zs"
53   then show "list_all2 R xs zs"
54     by (induct arbitrary: zs) (auto simp: list_all2_Cons1 intro: *)
55 qed
57 lemma list_equivp [quot_equiv]:
58   "equivp R \<Longrightarrow> equivp (list_all2 R)"
59   by (blast intro: equivpI reflp_list_all2 list_symp list_transp elim: equivpE)
61 lemma list_quotient3 [quot_thm]:
62   assumes "Quotient3 R Abs Rep"
63   shows "Quotient3 (list_all2 R) (map Abs) (map Rep)"
64 proof (rule Quotient3I)
65   from assms have "\<And>x. Abs (Rep x) = x" by (rule Quotient3_abs_rep)
66   then show "\<And>xs. map Abs (map Rep xs) = xs" by (simp add: comp_def)
67 next
68   from assms have "\<And>x y. R (Rep x) (Rep y) \<longleftrightarrow> x = y" by (rule Quotient3_rel_rep)
69   then show "\<And>xs. list_all2 R (map Rep xs) (map Rep xs)"
70     by (simp add: list_all2_map1 list_all2_map2 list_all2_eq)
71 next
72   fix xs ys
73   from assms have "\<And>x y. R x x \<and> R y y \<and> Abs x = Abs y \<longleftrightarrow> R x y" by (rule Quotient3_rel)
74   then show "list_all2 R xs ys \<longleftrightarrow> list_all2 R xs xs \<and> list_all2 R ys ys \<and> map Abs xs = map Abs ys"
75     by (induct xs ys rule: list_induct2') auto
76 qed
78 declare [[mapQ3 list = (list_all2, list_quotient3)]]
80 lemma cons_prs [quot_preserve]:
81   assumes q: "Quotient3 R Abs Rep"
82   shows "(Rep ---> (map Rep) ---> (map Abs)) (#) = (#)"
83   by (auto simp add: fun_eq_iff comp_def Quotient3_abs_rep [OF q])
85 lemma cons_rsp [quot_respect]:
86   assumes q: "Quotient3 R Abs Rep"
87   shows "(R ===> list_all2 R ===> list_all2 R) (#) (#)"
88   by auto
90 lemma nil_prs [quot_preserve]:
91   assumes q: "Quotient3 R Abs Rep"
92   shows "map Abs [] = []"
93   by simp
95 lemma nil_rsp [quot_respect]:
96   assumes q: "Quotient3 R Abs Rep"
97   shows "list_all2 R [] []"
98   by simp
100 lemma map_prs_aux:
101   assumes a: "Quotient3 R1 abs1 rep1"
102   and     b: "Quotient3 R2 abs2 rep2"
103   shows "(map abs2) (map ((abs1 ---> rep2) f) (map rep1 l)) = map f l"
104   by (induct l)
105      (simp_all add: Quotient3_abs_rep[OF a] Quotient3_abs_rep[OF b])
107 lemma map_prs [quot_preserve]:
108   assumes a: "Quotient3 R1 abs1 rep1"
109   and     b: "Quotient3 R2 abs2 rep2"
110   shows "((abs1 ---> rep2) ---> (map rep1) ---> (map abs2)) map = map"
111   and   "((abs1 ---> id) ---> map rep1 ---> id) map = map"
112   by (simp_all only: fun_eq_iff map_prs_aux[OF a b] comp_def)
113     (simp_all add: Quotient3_abs_rep[OF a] Quotient3_abs_rep[OF b])
115 lemma map_rsp [quot_respect]:
116   assumes q1: "Quotient3 R1 Abs1 Rep1"
117   and     q2: "Quotient3 R2 Abs2 Rep2"
118   shows "((R1 ===> R2) ===> (list_all2 R1) ===> list_all2 R2) map map"
119   and   "((R1 ===> (=)) ===> (list_all2 R1) ===> (=)) map map"
120   unfolding list_all2_eq [symmetric] by (rule list.map_transfer)+
122 lemma foldr_prs_aux:
123   assumes a: "Quotient3 R1 abs1 rep1"
124   and     b: "Quotient3 R2 abs2 rep2"
125   shows "abs2 (foldr ((abs1 ---> abs2 ---> rep2) f) (map rep1 l) (rep2 e)) = foldr f l e"
126   by (induct l) (simp_all add: Quotient3_abs_rep[OF a] Quotient3_abs_rep[OF b])
128 lemma foldr_prs [quot_preserve]:
129   assumes a: "Quotient3 R1 abs1 rep1"
130   and     b: "Quotient3 R2 abs2 rep2"
131   shows "((abs1 ---> abs2 ---> rep2) ---> (map rep1) ---> rep2 ---> abs2) foldr = foldr"
132   apply (simp add: fun_eq_iff)
133   by (simp only: fun_eq_iff foldr_prs_aux[OF a b])
134      (simp)
136 lemma foldl_prs_aux:
137   assumes a: "Quotient3 R1 abs1 rep1"
138   and     b: "Quotient3 R2 abs2 rep2"
139   shows "abs1 (foldl ((abs1 ---> abs2 ---> rep1) f) (rep1 e) (map rep2 l)) = foldl f e l"
140   by (induct l arbitrary:e) (simp_all add: Quotient3_abs_rep[OF a] Quotient3_abs_rep[OF b])
142 lemma foldl_prs [quot_preserve]:
143   assumes a: "Quotient3 R1 abs1 rep1"
144   and     b: "Quotient3 R2 abs2 rep2"
145   shows "((abs1 ---> abs2 ---> rep1) ---> rep1 ---> (map rep2) ---> abs1) foldl = foldl"
146   by (simp add: fun_eq_iff foldl_prs_aux [OF a b])
148 lemma foldl_rsp[quot_respect]:
149   assumes q1: "Quotient3 R1 Abs1 Rep1"
150   and     q2: "Quotient3 R2 Abs2 Rep2"
151   shows "((R1 ===> R2 ===> R1) ===> R1 ===> list_all2 R2 ===> R1) foldl foldl"
152   by (rule foldl_transfer)
154 lemma foldr_rsp[quot_respect]:
155   assumes q1: "Quotient3 R1 Abs1 Rep1"
156   and     q2: "Quotient3 R2 Abs2 Rep2"
157   shows "((R1 ===> R2 ===> R2) ===> list_all2 R1 ===> R2 ===> R2) foldr foldr"
158   by (rule foldr_transfer)
160 lemma list_all2_rsp:
161   assumes r: "\<forall>x y. R x y \<longrightarrow> (\<forall>a b. R a b \<longrightarrow> S x a = T y b)"
162   and l1: "list_all2 R x y"
163   and l2: "list_all2 R a b"
164   shows "list_all2 S x a = list_all2 T y b"
165   using l1 l2
166   by (induct arbitrary: a b rule: list_all2_induct,
167     auto simp: list_all2_Cons1 list_all2_Cons2 r)
169 lemma [quot_respect]:
170   "((R ===> R ===> (=)) ===> list_all2 R ===> list_all2 R ===> (=)) list_all2 list_all2"
171   by (rule list.rel_transfer)
173 lemma [quot_preserve]:
174   assumes a: "Quotient3 R abs1 rep1"
175   shows "((abs1 ---> abs1 ---> id) ---> map rep1 ---> map rep1 ---> id) list_all2 = list_all2"
176   apply (simp add: fun_eq_iff)
177   apply clarify
178   apply (induct_tac xa xb rule: list_induct2')
179   apply (simp_all add: Quotient3_abs_rep[OF a])
180   done
182 lemma [quot_preserve]:
183   assumes a: "Quotient3 R abs1 rep1"
184   shows "(list_all2 ((rep1 ---> rep1 ---> id) R) l m) = (l = m)"
185   by (induct l m rule: list_induct2') (simp_all add: Quotient3_rel_rep[OF a])
187 lemma list_all2_find_element:
188   assumes a: "x \<in> set a"
189   and b: "list_all2 R a b"
190   shows "\<exists>y. (y \<in> set b \<and> R x y)"
191   using b a by induct auto
193 lemma list_all2_refl:
194   assumes a: "\<And>x y. R x y = (R x = R y)"
195   shows "list_all2 R x x"
196   by (induct x) (auto simp add: a)
198 end