src/HOL/Power.thy
author paulson <lp15@cam.ac.uk>
Tue Nov 17 12:32:08 2015 +0000 (2015-11-17)
changeset 61694 6571c78c9667
parent 61649 268d88ec9087
child 61799 4cf66f21b764
permissions -rw-r--r--
Removed some legacy theorems; minor adjustments to simplification rules; new material on homotopic paths
     1 (*  Title:      HOL/Power.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1997  University of Cambridge
     4 *)
     5 
     6 section \<open>Exponentiation\<close>
     7 
     8 theory Power
     9 imports Num Equiv_Relations
    10 begin
    11 
    12 context linordered_ring (* TODO: move *)
    13 begin
    14 
    15 lemma sum_squares_ge_zero:
    16   "0 \<le> x * x + y * y"
    17   by (intro add_nonneg_nonneg zero_le_square)
    18 
    19 lemma not_sum_squares_lt_zero:
    20   "\<not> x * x + y * y < 0"
    21   by (simp add: not_less sum_squares_ge_zero)
    22 
    23 end
    24 
    25 subsection \<open>Powers for Arbitrary Monoids\<close>
    26 
    27 class power = one + times
    28 begin
    29 
    30 primrec power :: "'a \<Rightarrow> nat \<Rightarrow> 'a" (infixr "^" 80) where
    31     power_0: "a ^ 0 = 1"
    32   | power_Suc: "a ^ Suc n = a * a ^ n"
    33 
    34 notation (latex output)
    35   power ("(_\<^bsup>_\<^esup>)" [1000] 1000)
    36 
    37 text \<open>Special syntax for squares.\<close>
    38 
    39 abbreviation (xsymbols)
    40   power2 :: "'a \<Rightarrow> 'a"  ("(_\<^sup>2)" [1000] 999) where
    41   "x\<^sup>2 \<equiv> x ^ 2"
    42 
    43 notation (latex output)
    44   power2  ("(_\<^sup>2)" [1000] 999)
    45 
    46 end
    47 
    48 context monoid_mult
    49 begin
    50 
    51 subclass power .
    52 
    53 lemma power_one [simp]:
    54   "1 ^ n = 1"
    55   by (induct n) simp_all
    56 
    57 lemma power_one_right [simp]:
    58   "a ^ 1 = a"
    59   by simp
    60 
    61 lemma power_Suc0_right [simp]:
    62   "a ^ Suc 0 = a"
    63   by simp
    64 
    65 lemma power_commutes:
    66   "a ^ n * a = a * a ^ n"
    67   by (induct n) (simp_all add: mult.assoc)
    68 
    69 lemma power_Suc2:
    70   "a ^ Suc n = a ^ n * a"
    71   by (simp add: power_commutes)
    72 
    73 lemma power_add:
    74   "a ^ (m + n) = a ^ m * a ^ n"
    75   by (induct m) (simp_all add: algebra_simps)
    76 
    77 lemma power_mult:
    78   "a ^ (m * n) = (a ^ m) ^ n"
    79   by (induct n) (simp_all add: power_add)
    80 
    81 lemma power2_eq_square: "a\<^sup>2 = a * a"
    82   by (simp add: numeral_2_eq_2)
    83 
    84 lemma power3_eq_cube: "a ^ 3 = a * a * a"
    85   by (simp add: numeral_3_eq_3 mult.assoc)
    86 
    87 lemma power_even_eq:
    88   "a ^ (2 * n) = (a ^ n)\<^sup>2"
    89   by (subst mult.commute) (simp add: power_mult)
    90 
    91 lemma power_odd_eq:
    92   "a ^ Suc (2*n) = a * (a ^ n)\<^sup>2"
    93   by (simp add: power_even_eq)
    94 
    95 lemma power_numeral_even:
    96   "z ^ numeral (Num.Bit0 w) = (let w = z ^ (numeral w) in w * w)"
    97   unfolding numeral_Bit0 power_add Let_def ..
    98 
    99 lemma power_numeral_odd:
   100   "z ^ numeral (Num.Bit1 w) = (let w = z ^ (numeral w) in z * w * w)"
   101   unfolding numeral_Bit1 One_nat_def add_Suc_right add_0_right
   102   unfolding power_Suc power_add Let_def mult.assoc ..
   103 
   104 lemma funpow_times_power:
   105   "(times x ^^ f x) = times (x ^ f x)"
   106 proof (induct "f x" arbitrary: f)
   107   case 0 then show ?case by (simp add: fun_eq_iff)
   108 next
   109   case (Suc n)
   110   def g \<equiv> "\<lambda>x. f x - 1"
   111   with Suc have "n = g x" by simp
   112   with Suc have "times x ^^ g x = times (x ^ g x)" by simp
   113   moreover from Suc g_def have "f x = g x + 1" by simp
   114   ultimately show ?case by (simp add: power_add funpow_add fun_eq_iff mult.assoc)
   115 qed
   116 
   117 lemma power_commuting_commutes:
   118   assumes "x * y = y * x"
   119   shows "x ^ n * y = y * x ^n"
   120 proof (induct n)
   121   case (Suc n)
   122   have "x ^ Suc n * y = x ^ n * y * x"
   123     by (subst power_Suc2) (simp add: assms ac_simps)
   124   also have "\<dots> = y * x ^ Suc n"
   125     unfolding Suc power_Suc2
   126     by (simp add: ac_simps)
   127   finally show ?case .
   128 qed simp
   129 
   130 end
   131 
   132 context comm_monoid_mult
   133 begin
   134 
   135 lemma power_mult_distrib [field_simps]:
   136   "(a * b) ^ n = (a ^ n) * (b ^ n)"
   137   by (induct n) (simp_all add: ac_simps)
   138 
   139 end
   140 
   141 text\<open>Extract constant factors from powers\<close>
   142 declare power_mult_distrib [where a = "numeral w" for w, simp]
   143 declare power_mult_distrib [where b = "numeral w" for w, simp]
   144 
   145 lemma power_add_numeral [simp]:
   146   fixes a :: "'a :: monoid_mult"
   147   shows "a^numeral m * a^numeral n = a^numeral (m + n)"
   148   by (simp add: power_add [symmetric])
   149 
   150 lemma power_add_numeral2 [simp]:
   151   fixes a :: "'a :: monoid_mult"
   152   shows "a^numeral m * (a^numeral n * b) = a^numeral (m + n) * b"
   153   by (simp add: mult.assoc [symmetric])
   154 
   155 lemma power_mult_numeral [simp]:
   156   fixes a :: "'a :: monoid_mult"
   157   shows"(a^numeral m)^numeral n = a^numeral (m * n)"
   158   by (simp only: numeral_mult power_mult)
   159 
   160 context semiring_numeral
   161 begin
   162 
   163 lemma numeral_sqr: "numeral (Num.sqr k) = numeral k * numeral k"
   164   by (simp only: sqr_conv_mult numeral_mult)
   165 
   166 lemma numeral_pow: "numeral (Num.pow k l) = numeral k ^ numeral l"
   167   by (induct l, simp_all only: numeral_class.numeral.simps pow.simps
   168     numeral_sqr numeral_mult power_add power_one_right)
   169 
   170 lemma power_numeral [simp]: "numeral k ^ numeral l = numeral (Num.pow k l)"
   171   by (rule numeral_pow [symmetric])
   172 
   173 end
   174 
   175 context semiring_1
   176 begin
   177 
   178 lemma of_nat_power [simp]:
   179   "of_nat (m ^ n) = of_nat m ^ n"
   180   by (induct n) (simp_all add: of_nat_mult)
   181 
   182 lemma zero_power:
   183   "0 < n \<Longrightarrow> 0 ^ n = 0"
   184   by (cases n) simp_all
   185 
   186 lemma power_zero_numeral [simp]:
   187   "0 ^ numeral k = 0"
   188   by (simp add: numeral_eq_Suc)
   189 
   190 lemma zero_power2: "0\<^sup>2 = 0" (* delete? *)
   191   by (rule power_zero_numeral)
   192 
   193 lemma one_power2: "1\<^sup>2 = 1" (* delete? *)
   194   by (rule power_one)
   195 
   196 lemma power_0_Suc [simp]:
   197   "0 ^ Suc n = 0"
   198   by simp
   199 
   200 text\<open>It looks plausible as a simprule, but its effect can be strange.\<close>
   201 lemma power_0_left:
   202   "0 ^ n = (if n = 0 then 1 else 0)"
   203   by (cases n) simp_all
   204 
   205 end
   206 
   207 context comm_semiring_1
   208 begin
   209 
   210 text \<open>The divides relation\<close>
   211 
   212 lemma le_imp_power_dvd:
   213   assumes "m \<le> n" shows "a ^ m dvd a ^ n"
   214 proof
   215   have "a ^ n = a ^ (m + (n - m))"
   216     using \<open>m \<le> n\<close> by simp
   217   also have "\<dots> = a ^ m * a ^ (n - m)"
   218     by (rule power_add)
   219   finally show "a ^ n = a ^ m * a ^ (n - m)" .
   220 qed
   221 
   222 lemma power_le_dvd:
   223   "a ^ n dvd b \<Longrightarrow> m \<le> n \<Longrightarrow> a ^ m dvd b"
   224   by (rule dvd_trans [OF le_imp_power_dvd])
   225 
   226 lemma dvd_power_same:
   227   "x dvd y \<Longrightarrow> x ^ n dvd y ^ n"
   228   by (induct n) (auto simp add: mult_dvd_mono)
   229 
   230 lemma dvd_power_le:
   231   "x dvd y \<Longrightarrow> m \<ge> n \<Longrightarrow> x ^ n dvd y ^ m"
   232   by (rule power_le_dvd [OF dvd_power_same])
   233 
   234 lemma dvd_power [simp]:
   235   assumes "n > (0::nat) \<or> x = 1"
   236   shows "x dvd (x ^ n)"
   237 using assms proof
   238   assume "0 < n"
   239   then have "x ^ n = x ^ Suc (n - 1)" by simp
   240   then show "x dvd (x ^ n)" by simp
   241 next
   242   assume "x = 1"
   243   then show "x dvd (x ^ n)" by simp
   244 qed
   245 
   246 end
   247 
   248 class semiring_1_no_zero_divisors = semiring_1 + semiring_no_zero_divisors
   249 begin
   250 
   251 subclass power .
   252 
   253 lemma power_eq_0_iff [simp]:
   254   "a ^ n = 0 \<longleftrightarrow> a = 0 \<and> n > 0"
   255   by (induct n) auto
   256 
   257 lemma power_not_zero:
   258   "a \<noteq> 0 \<Longrightarrow> a ^ n \<noteq> 0"
   259   by (induct n) auto
   260 
   261 lemma zero_eq_power2 [simp]:
   262   "a\<^sup>2 = 0 \<longleftrightarrow> a = 0"
   263   unfolding power2_eq_square by simp
   264 
   265 end
   266 
   267 context semidom
   268 begin
   269 
   270 subclass semiring_1_no_zero_divisors ..
   271 
   272 end
   273 
   274 context ring_1
   275 begin
   276 
   277 lemma power_minus:
   278   "(- a) ^ n = (- 1) ^ n * a ^ n"
   279 proof (induct n)
   280   case 0 show ?case by simp
   281 next
   282   case (Suc n) then show ?case
   283     by (simp del: power_Suc add: power_Suc2 mult.assoc)
   284 qed
   285 
   286 lemma power_minus': "NO_MATCH 1 x \<Longrightarrow> (-x) ^ n = (-1)^n * x ^ n"
   287   by (rule power_minus)
   288 
   289 lemma power_minus_Bit0:
   290   "(- x) ^ numeral (Num.Bit0 k) = x ^ numeral (Num.Bit0 k)"
   291   by (induct k, simp_all only: numeral_class.numeral.simps power_add
   292     power_one_right mult_minus_left mult_minus_right minus_minus)
   293 
   294 lemma power_minus_Bit1:
   295   "(- x) ^ numeral (Num.Bit1 k) = - (x ^ numeral (Num.Bit1 k))"
   296   by (simp only: eval_nat_numeral(3) power_Suc power_minus_Bit0 mult_minus_left)
   297 
   298 lemma power2_minus [simp]:
   299   "(- a)\<^sup>2 = a\<^sup>2"
   300   by (fact power_minus_Bit0)
   301 
   302 lemma power_minus1_even [simp]:
   303   "(- 1) ^ (2*n) = 1"
   304 proof (induct n)
   305   case 0 show ?case by simp
   306 next
   307   case (Suc n) then show ?case by (simp add: power_add power2_eq_square)
   308 qed
   309 
   310 lemma power_minus1_odd:
   311   "(- 1) ^ Suc (2*n) = -1"
   312   by simp
   313 
   314 lemma power_minus_even [simp]:
   315   "(-a) ^ (2*n) = a ^ (2*n)"
   316   by (simp add: power_minus [of a])
   317 
   318 end
   319 
   320 context ring_1_no_zero_divisors
   321 begin
   322 
   323 subclass semiring_1_no_zero_divisors ..
   324 
   325 lemma power2_eq_1_iff:
   326   "a\<^sup>2 = 1 \<longleftrightarrow> a = 1 \<or> a = - 1"
   327   using square_eq_1_iff [of a] by (simp add: power2_eq_square)
   328 
   329 end
   330 
   331 context idom
   332 begin
   333 
   334 lemma power2_eq_iff: "x\<^sup>2 = y\<^sup>2 \<longleftrightarrow> x = y \<or> x = - y"
   335   unfolding power2_eq_square by (rule square_eq_iff)
   336 
   337 end
   338 
   339 context algebraic_semidom
   340 begin
   341 
   342 lemma div_power:
   343   assumes "b dvd a"
   344   shows "(a div b) ^ n = a ^ n div b ^ n"
   345   using assms by (induct n) (simp_all add: div_mult_div_if_dvd dvd_power_same)
   346 
   347 end
   348 
   349 context normalization_semidom
   350 begin
   351 
   352 lemma normalize_power:
   353   "normalize (a ^ n) = normalize a ^ n"
   354   by (induct n) (simp_all add: normalize_mult)
   355 
   356 lemma unit_factor_power:
   357   "unit_factor (a ^ n) = unit_factor a ^ n"
   358   by (induct n) (simp_all add: unit_factor_mult)
   359 
   360 end
   361 
   362 context division_ring
   363 begin
   364 
   365 text\<open>Perhaps these should be simprules.\<close>
   366 lemma power_inverse [field_simps, divide_simps]:
   367   "inverse a ^ n = inverse (a ^ n)"
   368 proof (cases "a = 0")
   369   case True then show ?thesis by (simp add: power_0_left)
   370 next
   371   case False then have "inverse (a ^ n) = inverse a ^ n"
   372     by (induct n) (simp_all add: nonzero_inverse_mult_distrib power_commutes)
   373   then show ?thesis by simp
   374 qed
   375 
   376 lemma power_one_over [field_simps, divide_simps]:
   377   "(1 / a) ^ n = 1 / a ^ n"
   378   using power_inverse [of a] by (simp add: divide_inverse)
   379 
   380 end
   381 
   382 context field
   383 begin
   384 
   385 lemma power_diff:
   386   assumes nz: "a \<noteq> 0"
   387   shows "n \<le> m \<Longrightarrow> a ^ (m - n) = a ^ m / a ^ n"
   388   by (induct m n rule: diff_induct) (simp_all add: nz power_not_zero)
   389 
   390 lemma power_divide [field_simps, divide_simps]:
   391   "(a / b) ^ n = a ^ n / b ^ n"
   392   by (induct n) simp_all
   393 
   394 end
   395 
   396 
   397 subsection \<open>Exponentiation on ordered types\<close>
   398 
   399 context linordered_semidom
   400 begin
   401 
   402 lemma zero_less_power [simp]:
   403   "0 < a \<Longrightarrow> 0 < a ^ n"
   404   by (induct n) simp_all
   405 
   406 lemma zero_le_power [simp]:
   407   "0 \<le> a \<Longrightarrow> 0 \<le> a ^ n"
   408   by (induct n) simp_all
   409 
   410 lemma power_mono:
   411   "a \<le> b \<Longrightarrow> 0 \<le> a \<Longrightarrow> a ^ n \<le> b ^ n"
   412   by (induct n) (auto intro: mult_mono order_trans [of 0 a b])
   413 
   414 lemma one_le_power [simp]: "1 \<le> a \<Longrightarrow> 1 \<le> a ^ n"
   415   using power_mono [of 1 a n] by simp
   416 
   417 lemma power_le_one: "\<lbrakk>0 \<le> a; a \<le> 1\<rbrakk> \<Longrightarrow> a ^ n \<le> 1"
   418   using power_mono [of a 1 n] by simp
   419 
   420 lemma power_gt1_lemma:
   421   assumes gt1: "1 < a"
   422   shows "1 < a * a ^ n"
   423 proof -
   424   from gt1 have "0 \<le> a"
   425     by (fact order_trans [OF zero_le_one less_imp_le])
   426   have "1 * 1 < a * 1" using gt1 by simp
   427   also have "\<dots> \<le> a * a ^ n" using gt1
   428     by (simp only: mult_mono \<open>0 \<le> a\<close> one_le_power order_less_imp_le
   429         zero_le_one order_refl)
   430   finally show ?thesis by simp
   431 qed
   432 
   433 lemma power_gt1:
   434   "1 < a \<Longrightarrow> 1 < a ^ Suc n"
   435   by (simp add: power_gt1_lemma)
   436 
   437 lemma one_less_power [simp]:
   438   "1 < a \<Longrightarrow> 0 < n \<Longrightarrow> 1 < a ^ n"
   439   by (cases n) (simp_all add: power_gt1_lemma)
   440 
   441 lemma power_le_imp_le_exp:
   442   assumes gt1: "1 < a"
   443   shows "a ^ m \<le> a ^ n \<Longrightarrow> m \<le> n"
   444 proof (induct m arbitrary: n)
   445   case 0
   446   show ?case by simp
   447 next
   448   case (Suc m)
   449   show ?case
   450   proof (cases n)
   451     case 0
   452     with Suc.prems Suc.hyps have "a * a ^ m \<le> 1" by simp
   453     with gt1 show ?thesis
   454       by (force simp only: power_gt1_lemma
   455           not_less [symmetric])
   456   next
   457     case (Suc n)
   458     with Suc.prems Suc.hyps show ?thesis
   459       by (force dest: mult_left_le_imp_le
   460           simp add: less_trans [OF zero_less_one gt1])
   461   qed
   462 qed
   463 
   464 lemma of_nat_zero_less_power_iff [simp]:
   465   "of_nat x ^ n > 0 \<longleftrightarrow> x > 0 \<or> n = 0"
   466   by (induct n) auto
   467 
   468 text\<open>Surely we can strengthen this? It holds for @{text "0<a<1"} too.\<close>
   469 lemma power_inject_exp [simp]:
   470   "1 < a \<Longrightarrow> a ^ m = a ^ n \<longleftrightarrow> m = n"
   471   by (force simp add: order_antisym power_le_imp_le_exp)
   472 
   473 text\<open>Can relax the first premise to @{term "0<a"} in the case of the
   474 natural numbers.\<close>
   475 lemma power_less_imp_less_exp:
   476   "1 < a \<Longrightarrow> a ^ m < a ^ n \<Longrightarrow> m < n"
   477   by (simp add: order_less_le [of m n] less_le [of "a^m" "a^n"]
   478     power_le_imp_le_exp)
   479 
   480 lemma power_strict_mono [rule_format]:
   481   "a < b \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 < n \<longrightarrow> a ^ n < b ^ n"
   482   by (induct n)
   483    (auto simp add: mult_strict_mono le_less_trans [of 0 a b])
   484 
   485 text\<open>Lemma for @{text power_strict_decreasing}\<close>
   486 lemma power_Suc_less:
   487   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a * a ^ n < a ^ n"
   488   by (induct n)
   489     (auto simp add: mult_strict_left_mono)
   490 
   491 lemma power_strict_decreasing [rule_format]:
   492   "n < N \<Longrightarrow> 0 < a \<Longrightarrow> a < 1 \<longrightarrow> a ^ N < a ^ n"
   493 proof (induct N)
   494   case 0 then show ?case by simp
   495 next
   496   case (Suc N) then show ?case
   497   apply (auto simp add: power_Suc_less less_Suc_eq)
   498   apply (subgoal_tac "a * a^N < 1 * a^n")
   499   apply simp
   500   apply (rule mult_strict_mono) apply auto
   501   done
   502 qed
   503 
   504 text\<open>Proof resembles that of @{text power_strict_decreasing}\<close>
   505 lemma power_decreasing [rule_format]:
   506   "n \<le> N \<Longrightarrow> 0 \<le> a \<Longrightarrow> a \<le> 1 \<longrightarrow> a ^ N \<le> a ^ n"
   507 proof (induct N)
   508   case 0 then show ?case by simp
   509 next
   510   case (Suc N) then show ?case
   511   apply (auto simp add: le_Suc_eq)
   512   apply (subgoal_tac "a * a^N \<le> 1 * a^n", simp)
   513   apply (rule mult_mono) apply auto
   514   done
   515 qed
   516 
   517 lemma power_Suc_less_one:
   518   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a ^ Suc n < 1"
   519   using power_strict_decreasing [of 0 "Suc n" a] by simp
   520 
   521 text\<open>Proof again resembles that of @{text power_strict_decreasing}\<close>
   522 lemma power_increasing [rule_format]:
   523   "n \<le> N \<Longrightarrow> 1 \<le> a \<Longrightarrow> a ^ n \<le> a ^ N"
   524 proof (induct N)
   525   case 0 then show ?case by simp
   526 next
   527   case (Suc N) then show ?case
   528   apply (auto simp add: le_Suc_eq)
   529   apply (subgoal_tac "1 * a^n \<le> a * a^N", simp)
   530   apply (rule mult_mono) apply (auto simp add: order_trans [OF zero_le_one])
   531   done
   532 qed
   533 
   534 text\<open>Lemma for @{text power_strict_increasing}\<close>
   535 lemma power_less_power_Suc:
   536   "1 < a \<Longrightarrow> a ^ n < a * a ^ n"
   537   by (induct n) (auto simp add: mult_strict_left_mono less_trans [OF zero_less_one])
   538 
   539 lemma power_strict_increasing [rule_format]:
   540   "n < N \<Longrightarrow> 1 < a \<longrightarrow> a ^ n < a ^ N"
   541 proof (induct N)
   542   case 0 then show ?case by simp
   543 next
   544   case (Suc N) then show ?case
   545   apply (auto simp add: power_less_power_Suc less_Suc_eq)
   546   apply (subgoal_tac "1 * a^n < a * a^N", simp)
   547   apply (rule mult_strict_mono) apply (auto simp add: less_trans [OF zero_less_one] less_imp_le)
   548   done
   549 qed
   550 
   551 lemma power_increasing_iff [simp]:
   552   "1 < b \<Longrightarrow> b ^ x \<le> b ^ y \<longleftrightarrow> x \<le> y"
   553   by (blast intro: power_le_imp_le_exp power_increasing less_imp_le)
   554 
   555 lemma power_strict_increasing_iff [simp]:
   556   "1 < b \<Longrightarrow> b ^ x < b ^ y \<longleftrightarrow> x < y"
   557 by (blast intro: power_less_imp_less_exp power_strict_increasing)
   558 
   559 lemma power_le_imp_le_base:
   560   assumes le: "a ^ Suc n \<le> b ^ Suc n"
   561     and ynonneg: "0 \<le> b"
   562   shows "a \<le> b"
   563 proof (rule ccontr)
   564   assume "~ a \<le> b"
   565   then have "b < a" by (simp only: linorder_not_le)
   566   then have "b ^ Suc n < a ^ Suc n"
   567     by (simp only: assms power_strict_mono)
   568   from le and this show False
   569     by (simp add: linorder_not_less [symmetric])
   570 qed
   571 
   572 lemma power_less_imp_less_base:
   573   assumes less: "a ^ n < b ^ n"
   574   assumes nonneg: "0 \<le> b"
   575   shows "a < b"
   576 proof (rule contrapos_pp [OF less])
   577   assume "~ a < b"
   578   hence "b \<le> a" by (simp only: linorder_not_less)
   579   hence "b ^ n \<le> a ^ n" using nonneg by (rule power_mono)
   580   thus "\<not> a ^ n < b ^ n" by (simp only: linorder_not_less)
   581 qed
   582 
   583 lemma power_inject_base:
   584   "a ^ Suc n = b ^ Suc n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> a = b"
   585 by (blast intro: power_le_imp_le_base antisym eq_refl sym)
   586 
   587 lemma power_eq_imp_eq_base:
   588   "a ^ n = b ^ n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 < n \<Longrightarrow> a = b"
   589   by (cases n) (simp_all del: power_Suc, rule power_inject_base)
   590 
   591 lemma power2_le_imp_le:
   592   "x\<^sup>2 \<le> y\<^sup>2 \<Longrightarrow> 0 \<le> y \<Longrightarrow> x \<le> y"
   593   unfolding numeral_2_eq_2 by (rule power_le_imp_le_base)
   594 
   595 lemma power2_less_imp_less:
   596   "x\<^sup>2 < y\<^sup>2 \<Longrightarrow> 0 \<le> y \<Longrightarrow> x < y"
   597   by (rule power_less_imp_less_base)
   598 
   599 lemma power2_eq_imp_eq:
   600   "x\<^sup>2 = y\<^sup>2 \<Longrightarrow> 0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> x = y"
   601   unfolding numeral_2_eq_2 by (erule (2) power_eq_imp_eq_base) simp
   602 
   603 end
   604 
   605 context linordered_ring_strict
   606 begin
   607 
   608 lemma sum_squares_eq_zero_iff:
   609   "x * x + y * y = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   610   by (simp add: add_nonneg_eq_0_iff)
   611 
   612 lemma sum_squares_le_zero_iff:
   613   "x * x + y * y \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   614   by (simp add: le_less not_sum_squares_lt_zero sum_squares_eq_zero_iff)
   615 
   616 lemma sum_squares_gt_zero_iff:
   617   "0 < x * x + y * y \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   618   by (simp add: not_le [symmetric] sum_squares_le_zero_iff)
   619 
   620 end
   621 
   622 context linordered_idom
   623 begin
   624 
   625 lemma power_abs:
   626   "abs (a ^ n) = abs a ^ n"
   627   by (induct n) (auto simp add: abs_mult)
   628 
   629 lemma abs_power_minus [simp]:
   630   "abs ((-a) ^ n) = abs (a ^ n)"
   631   by (simp add: power_abs)
   632 
   633 lemma zero_less_power_abs_iff [simp]:
   634   "0 < abs a ^ n \<longleftrightarrow> a \<noteq> 0 \<or> n = 0"
   635 proof (induct n)
   636   case 0 show ?case by simp
   637 next
   638   case (Suc n) show ?case by (auto simp add: Suc zero_less_mult_iff)
   639 qed
   640 
   641 lemma zero_le_power_abs [simp]:
   642   "0 \<le> abs a ^ n"
   643   by (rule zero_le_power [OF abs_ge_zero])
   644 
   645 lemma zero_le_power2 [simp]:
   646   "0 \<le> a\<^sup>2"
   647   by (simp add: power2_eq_square)
   648 
   649 lemma zero_less_power2 [simp]:
   650   "0 < a\<^sup>2 \<longleftrightarrow> a \<noteq> 0"
   651   by (force simp add: power2_eq_square zero_less_mult_iff linorder_neq_iff)
   652 
   653 lemma power2_less_0 [simp]:
   654   "\<not> a\<^sup>2 < 0"
   655   by (force simp add: power2_eq_square mult_less_0_iff)
   656 
   657 lemma power2_less_eq_zero_iff [simp]:
   658   "a\<^sup>2 \<le> 0 \<longleftrightarrow> a = 0"
   659   by (simp add: le_less)
   660 
   661 lemma abs_power2 [simp]:
   662   "abs (a\<^sup>2) = a\<^sup>2"
   663   by (simp add: power2_eq_square abs_mult abs_mult_self)
   664 
   665 lemma power2_abs [simp]:
   666   "(abs a)\<^sup>2 = a\<^sup>2"
   667   by (simp add: power2_eq_square abs_mult_self)
   668 
   669 lemma odd_power_less_zero:
   670   "a < 0 \<Longrightarrow> a ^ Suc (2*n) < 0"
   671 proof (induct n)
   672   case 0
   673   then show ?case by simp
   674 next
   675   case (Suc n)
   676   have "a ^ Suc (2 * Suc n) = (a*a) * a ^ Suc(2*n)"
   677     by (simp add: ac_simps power_add power2_eq_square)
   678   thus ?case
   679     by (simp del: power_Suc add: Suc mult_less_0_iff mult_neg_neg)
   680 qed
   681 
   682 lemma odd_0_le_power_imp_0_le:
   683   "0 \<le> a ^ Suc (2*n) \<Longrightarrow> 0 \<le> a"
   684   using odd_power_less_zero [of a n]
   685     by (force simp add: linorder_not_less [symmetric])
   686 
   687 lemma zero_le_even_power'[simp]:
   688   "0 \<le> a ^ (2*n)"
   689 proof (induct n)
   690   case 0
   691     show ?case by simp
   692 next
   693   case (Suc n)
   694     have "a ^ (2 * Suc n) = (a*a) * a ^ (2*n)"
   695       by (simp add: ac_simps power_add power2_eq_square)
   696     thus ?case
   697       by (simp add: Suc zero_le_mult_iff)
   698 qed
   699 
   700 lemma sum_power2_ge_zero:
   701   "0 \<le> x\<^sup>2 + y\<^sup>2"
   702   by (intro add_nonneg_nonneg zero_le_power2)
   703 
   704 lemma not_sum_power2_lt_zero:
   705   "\<not> x\<^sup>2 + y\<^sup>2 < 0"
   706   unfolding not_less by (rule sum_power2_ge_zero)
   707 
   708 lemma sum_power2_eq_zero_iff:
   709   "x\<^sup>2 + y\<^sup>2 = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   710   unfolding power2_eq_square by (simp add: add_nonneg_eq_0_iff)
   711 
   712 lemma sum_power2_le_zero_iff:
   713   "x\<^sup>2 + y\<^sup>2 \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   714   by (simp add: le_less sum_power2_eq_zero_iff not_sum_power2_lt_zero)
   715 
   716 lemma sum_power2_gt_zero_iff:
   717   "0 < x\<^sup>2 + y\<^sup>2 \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   718   unfolding not_le [symmetric] by (simp add: sum_power2_le_zero_iff)
   719 
   720 lemma abs_le_square_iff:
   721    "\<bar>x\<bar> \<le> \<bar>y\<bar> \<longleftrightarrow> x\<^sup>2 \<le> y\<^sup>2"
   722 proof
   723   assume "\<bar>x\<bar> \<le> \<bar>y\<bar>"
   724   then have "\<bar>x\<bar>\<^sup>2 \<le> \<bar>y\<bar>\<^sup>2" by (rule power_mono, simp)
   725   then show "x\<^sup>2 \<le> y\<^sup>2" by simp
   726 next
   727   assume "x\<^sup>2 \<le> y\<^sup>2"
   728   then show "\<bar>x\<bar> \<le> \<bar>y\<bar>"
   729     by (auto intro!: power2_le_imp_le [OF _ abs_ge_zero])
   730 qed
   731 
   732 lemma abs_square_le_1:"x\<^sup>2 \<le> 1 \<longleftrightarrow> abs(x) \<le> 1"
   733   using abs_le_square_iff [of x 1]
   734   by simp
   735 
   736 lemma abs_square_eq_1: "x\<^sup>2 = 1 \<longleftrightarrow> abs(x) = 1"
   737   by (auto simp add: abs_if power2_eq_1_iff)
   738 
   739 lemma abs_square_less_1: "x\<^sup>2 < 1 \<longleftrightarrow> abs(x) < 1"
   740   using  abs_square_eq_1 [of x] abs_square_le_1 [of x]
   741   by (auto simp add: le_less)
   742 
   743 end
   744 
   745 
   746 subsection \<open>Miscellaneous rules\<close>
   747 
   748 lemma (in linordered_semidom) self_le_power:
   749   "1 \<le> a \<Longrightarrow> 0 < n \<Longrightarrow> a \<le> a ^ n"
   750   using power_increasing [of 1 n a] power_one_right [of a] by auto
   751 
   752 lemma (in power) power_eq_if:
   753   "p ^ m = (if m=0 then 1 else p * (p ^ (m - 1)))"
   754   unfolding One_nat_def by (cases m) simp_all
   755 
   756 lemma (in comm_semiring_1) power2_sum:
   757   "(x + y)\<^sup>2 = x\<^sup>2 + y\<^sup>2 + 2 * x * y"
   758   by (simp add: algebra_simps power2_eq_square mult_2_right)
   759 
   760 lemma (in comm_ring_1) power2_diff:
   761   "(x - y)\<^sup>2 = x\<^sup>2 + y\<^sup>2 - 2 * x * y"
   762   by (simp add: algebra_simps power2_eq_square mult_2_right)
   763 
   764 lemma (in comm_ring_1) power2_commute:
   765   "(x - y)\<^sup>2 = (y - x)\<^sup>2"
   766   by (simp add: algebra_simps power2_eq_square)
   767 
   768 
   769 text \<open>Simprules for comparisons where common factors can be cancelled.\<close>
   770 
   771 lemmas zero_compare_simps =
   772     add_strict_increasing add_strict_increasing2 add_increasing
   773     zero_le_mult_iff zero_le_divide_iff
   774     zero_less_mult_iff zero_less_divide_iff
   775     mult_le_0_iff divide_le_0_iff
   776     mult_less_0_iff divide_less_0_iff
   777     zero_le_power2 power2_less_0
   778 
   779 
   780 subsection \<open>Exponentiation for the Natural Numbers\<close>
   781 
   782 lemma nat_one_le_power [simp]:
   783   "Suc 0 \<le> i \<Longrightarrow> Suc 0 \<le> i ^ n"
   784   by (rule one_le_power [of i n, unfolded One_nat_def])
   785 
   786 lemma nat_zero_less_power_iff [simp]:
   787   "x ^ n > 0 \<longleftrightarrow> x > (0::nat) \<or> n = 0"
   788   by (induct n) auto
   789 
   790 lemma nat_power_eq_Suc_0_iff [simp]:
   791   "x ^ m = Suc 0 \<longleftrightarrow> m = 0 \<or> x = Suc 0"
   792   by (induct m) auto
   793 
   794 lemma power_Suc_0 [simp]:
   795   "Suc 0 ^ n = Suc 0"
   796   by simp
   797 
   798 text\<open>Valid for the naturals, but what if @{text"0<i<1"}?
   799 Premises cannot be weakened: consider the case where @{term "i=0"},
   800 @{term "m=1"} and @{term "n=0"}.\<close>
   801 lemma nat_power_less_imp_less:
   802   assumes nonneg: "0 < (i::nat)"
   803   assumes less: "i ^ m < i ^ n"
   804   shows "m < n"
   805 proof (cases "i = 1")
   806   case True with less power_one [where 'a = nat] show ?thesis by simp
   807 next
   808   case False with nonneg have "1 < i" by auto
   809   from power_strict_increasing_iff [OF this] less show ?thesis ..
   810 qed
   811 
   812 lemma power_dvd_imp_le:
   813   "i ^ m dvd i ^ n \<Longrightarrow> (1::nat) < i \<Longrightarrow> m \<le> n"
   814   apply (rule power_le_imp_le_exp, assumption)
   815   apply (erule dvd_imp_le, simp)
   816   done
   817 
   818 lemma power2_nat_le_eq_le:
   819   fixes m n :: nat
   820   shows "m\<^sup>2 \<le> n\<^sup>2 \<longleftrightarrow> m \<le> n"
   821   by (auto intro: power2_le_imp_le power_mono)
   822 
   823 lemma power2_nat_le_imp_le:
   824   fixes m n :: nat
   825   assumes "m\<^sup>2 \<le> n"
   826   shows "m \<le> n"
   827 proof (cases m)
   828   case 0 then show ?thesis by simp
   829 next
   830   case (Suc k)
   831   show ?thesis
   832   proof (rule ccontr)
   833     assume "\<not> m \<le> n"
   834     then have "n < m" by simp
   835     with assms Suc show False
   836       by (simp add: power2_eq_square)
   837   qed
   838 qed
   839 
   840 subsubsection \<open>Cardinality of the Powerset\<close>
   841 
   842 lemma card_UNIV_bool [simp]: "card (UNIV :: bool set) = 2"
   843   unfolding UNIV_bool by simp
   844 
   845 lemma card_Pow: "finite A \<Longrightarrow> card (Pow A) = 2 ^ card A"
   846 proof (induct rule: finite_induct)
   847   case empty
   848     show ?case by auto
   849 next
   850   case (insert x A)
   851   then have "inj_on (insert x) (Pow A)"
   852     unfolding inj_on_def by (blast elim!: equalityE)
   853   then have "card (Pow A) + card (insert x ` Pow A) = 2 * 2 ^ card A"
   854     by (simp add: mult_2 card_image Pow_insert insert.hyps)
   855   then show ?case using insert
   856     apply (simp add: Pow_insert)
   857     apply (subst card_Un_disjoint, auto)
   858     done
   859 qed
   860 
   861 
   862 subsubsection \<open>Generalized sum over a set\<close>
   863 
   864 lemma setsum_zero_power [simp]:
   865   fixes c :: "nat \<Rightarrow> 'a::division_ring"
   866   shows "(\<Sum>i\<in>A. c i * 0^i) = (if finite A \<and> 0 \<in> A then c 0 else 0)"
   867 apply (cases "finite A")
   868   by (induction A rule: finite_induct) auto
   869 
   870 lemma setsum_zero_power' [simp]:
   871   fixes c :: "nat \<Rightarrow> 'a::field"
   872   shows "(\<Sum>i\<in>A. c i * 0^i / d i) = (if finite A \<and> 0 \<in> A then c 0 / d 0 else 0)"
   873   using setsum_zero_power [of "\<lambda>i. c i / d i" A]
   874   by auto
   875 
   876 
   877 subsubsection \<open>Generalized product over a set\<close>
   878 
   879 lemma setprod_constant: "finite A ==> (\<Prod>x\<in> A. (y::'a::{comm_monoid_mult})) = y^(card A)"
   880 apply (erule finite_induct)
   881 apply auto
   882 done
   883 
   884 lemma setprod_power_distrib:
   885   fixes f :: "'a \<Rightarrow> 'b::comm_semiring_1"
   886   shows "setprod f A ^ n = setprod (\<lambda>x. (f x) ^ n) A"
   887 proof (cases "finite A")
   888   case True then show ?thesis
   889     by (induct A rule: finite_induct) (auto simp add: power_mult_distrib)
   890 next
   891   case False then show ?thesis
   892     by simp
   893 qed
   894 
   895 lemma power_setsum:
   896   "c ^ (\<Sum>a\<in>A. f a) = (\<Prod>a\<in>A. c ^ f a)"
   897   by (induct A rule: infinite_finite_induct) (simp_all add: power_add)
   898 
   899 lemma setprod_gen_delta:
   900   assumes fS: "finite S"
   901   shows "setprod (\<lambda>k. if k=a then b k else c) S = (if a \<in> S then (b a ::'a::comm_monoid_mult) * c^ (card S - 1) else c^ card S)"
   902 proof-
   903   let ?f = "(\<lambda>k. if k=a then b k else c)"
   904   {assume a: "a \<notin> S"
   905     hence "\<forall> k\<in> S. ?f k = c" by simp
   906     hence ?thesis  using a setprod_constant[OF fS, of c] by simp }
   907   moreover
   908   {assume a: "a \<in> S"
   909     let ?A = "S - {a}"
   910     let ?B = "{a}"
   911     have eq: "S = ?A \<union> ?B" using a by blast
   912     have dj: "?A \<inter> ?B = {}" by simp
   913     from fS have fAB: "finite ?A" "finite ?B" by auto
   914     have fA0:"setprod ?f ?A = setprod (\<lambda>i. c) ?A"
   915       apply (rule setprod.cong) by auto
   916     have cA: "card ?A = card S - 1" using fS a by auto
   917     have fA1: "setprod ?f ?A = c ^ card ?A"  unfolding fA0 apply (rule setprod_constant) using fS by auto
   918     have "setprod ?f ?A * setprod ?f ?B = setprod ?f S"
   919       using setprod.union_disjoint[OF fAB dj, of ?f, unfolded eq[symmetric]]
   920       by simp
   921     then have ?thesis using a cA
   922       by (simp add: fA1 field_simps cong add: setprod.cong cong del: if_weak_cong)}
   923   ultimately show ?thesis by blast
   924 qed
   925 
   926 subsection \<open>Code generator tweak\<close>
   927 
   928 code_identifier
   929   code_module Power \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
   930 
   931 end