src/HOL/Tools/hologic.ML
author haftmann
Wed Jul 29 16:48:34 2009 +0200 (2009-07-29)
changeset 32287 65d5c5b30747
parent 32264 0be31453f698
child 32339 40612b7ace87
permissions -rw-r--r--
cleaned up abstract tuple operations and named them consistently
     1 (*  Title:      HOL/hologic.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Abstract syntax operations for HOL.
     5 *)
     6 
     7 signature HOLOGIC =
     8 sig
     9   val typeS: sort
    10   val typeT: typ
    11   val boolN: string
    12   val boolT: typ
    13   val Trueprop: term
    14   val mk_Trueprop: term -> term
    15   val dest_Trueprop: term -> term
    16   val true_const: term
    17   val false_const: term
    18   val mk_setT: typ -> typ
    19   val dest_setT: typ -> typ
    20   val Collect_const: typ -> term
    21   val mk_Collect: string * typ * term -> term
    22   val mk_mem: term * term -> term
    23   val dest_mem: term -> term * term
    24   val mk_set: typ -> term list -> term
    25   val dest_set: term -> term list
    26   val mk_UNIV: typ -> term
    27   val conj_intr: thm -> thm -> thm
    28   val conj_elim: thm -> thm * thm
    29   val conj_elims: thm -> thm list
    30   val conj: term
    31   val disj: term
    32   val imp: term
    33   val Not: term
    34   val mk_conj: term * term -> term
    35   val mk_disj: term * term -> term
    36   val mk_imp: term * term -> term
    37   val mk_not: term -> term
    38   val dest_conj: term -> term list
    39   val dest_disj: term -> term list
    40   val disjuncts: term -> term list
    41   val dest_imp: term -> term * term
    42   val dest_not: term -> term
    43   val eq_const: typ -> term
    44   val mk_eq: term * term -> term
    45   val dest_eq: term -> term * term
    46   val all_const: typ -> term
    47   val mk_all: string * typ * term -> term
    48   val list_all: (string * typ) list * term -> term
    49   val exists_const: typ -> term
    50   val mk_exists: string * typ * term -> term
    51   val choice_const: typ -> term
    52   val class_eq: string
    53   val mk_binop: string -> term * term -> term
    54   val mk_binrel: string -> term * term -> term
    55   val dest_bin: string -> typ -> term -> term * term
    56   val unitT: typ
    57   val is_unitT: typ -> bool
    58   val unit: term
    59   val is_unit: term -> bool
    60   val mk_prodT: typ * typ -> typ
    61   val dest_prodT: typ -> typ * typ
    62   val pair_const: typ -> typ -> term
    63   val mk_prod: term * term -> term
    64   val dest_prod: term -> term * term
    65   val mk_fst: term -> term
    66   val mk_snd: term -> term
    67   val split_const: typ * typ * typ -> term
    68   val mk_split: term -> term
    69   val flatten_tupleT: typ -> typ list
    70   val mk_tupleT: int list list -> typ list -> typ
    71   val strip_tupleT: int list list -> typ -> typ list
    72   val flat_tupleT_paths: typ -> int list list
    73   val mk_tuple: int list list -> typ -> term list -> term
    74   val dest_tuple: int list list -> term -> term list
    75   val flat_tuple_paths: term -> int list list
    76   val mk_splits: int list list -> typ -> typ -> term -> term
    77   val strip_splits: term -> term * typ list * int list list
    78   val natT: typ
    79   val zero: term
    80   val is_zero: term -> bool
    81   val mk_Suc: term -> term
    82   val dest_Suc: term -> term
    83   val Suc_zero: term
    84   val mk_nat: int -> term
    85   val dest_nat: term -> int
    86   val class_size: string
    87   val size_const: typ -> term
    88   val code_numeralT: typ
    89   val intT: typ
    90   val pls_const: term
    91   val min_const: term
    92   val bit0_const: term
    93   val bit1_const: term
    94   val mk_bit: int -> term
    95   val dest_bit: term -> int
    96   val mk_numeral: int -> term
    97   val dest_numeral: term -> int
    98   val number_of_const: typ -> term
    99   val add_numerals: term -> (term * typ) list -> (term * typ) list
   100   val mk_number: typ -> int -> term
   101   val dest_number: term -> typ * int
   102   val realT: typ
   103   val nibbleT: typ
   104   val mk_nibble: int -> term
   105   val dest_nibble: term -> int
   106   val charT: typ
   107   val mk_char: int -> term
   108   val dest_char: term -> int
   109   val listT: typ -> typ
   110   val nil_const: typ -> term
   111   val cons_const: typ -> term
   112   val mk_list: typ -> term list -> term
   113   val dest_list: term -> term list
   114   val stringT: typ
   115   val mk_string: string -> term
   116   val dest_string: term -> string
   117   val literalT: typ
   118   val mk_literal: string -> term
   119   val dest_literal: term -> string
   120   val mk_typerep: typ -> term
   121   val mk_term_of: typ -> term -> term
   122   val reflect_term: term -> term
   123   val mk_valtermify_app: string -> (string * typ) list -> typ -> term
   124   val mk_return: typ -> typ -> term -> term
   125   val mk_ST: ((term * typ) * (string * typ) option)  list -> term -> typ -> typ option * typ -> term
   126   val mk_random: typ -> term -> term
   127 end;
   128 
   129 structure HOLogic: HOLOGIC =
   130 struct
   131 
   132 (* HOL syntax *)
   133 
   134 val typeS: sort = ["HOL.type"];
   135 val typeT = TypeInfer.anyT typeS;
   136 
   137 
   138 (* bool and set *)
   139 
   140 val boolN = "bool";
   141 val boolT = Type (boolN, []);
   142 
   143 val true_const =  Const ("True", boolT);
   144 val false_const = Const ("False", boolT);
   145 
   146 fun mk_setT T = T --> boolT;
   147 
   148 fun dest_setT (Type ("fun", [T, Type ("bool", [])])) = T
   149   | dest_setT T = raise TYPE ("dest_setT: set type expected", [T], []);
   150 
   151 fun mk_set T ts =
   152   let
   153     val sT = mk_setT T;
   154     val empty = Const ("Orderings.bot_class.bot", sT);
   155     fun insert t u = Const ("Set.insert", T --> sT --> sT) $ t $ u;
   156   in fold_rev insert ts empty end;
   157 
   158 fun mk_UNIV T = Const ("Orderings.top_class.top", mk_setT T);
   159 
   160 fun dest_set (Const ("Orderings.bot_class.bot", _)) = []
   161   | dest_set (Const ("Set.insert", _) $ t $ u) = t :: dest_set u
   162   | dest_set t = raise TERM ("dest_set", [t]);
   163 
   164 fun Collect_const T = Const ("Collect", (T --> boolT) --> mk_setT T);
   165 fun mk_Collect (a, T, t) = Collect_const T $ absfree (a, T, t);
   166 
   167 fun mk_mem (x, A) =
   168   let val setT = fastype_of A in
   169     Const ("op :", dest_setT setT --> setT --> boolT) $ x $ A
   170   end;
   171 
   172 fun dest_mem (Const ("op :", _) $ x $ A) = (x, A)
   173   | dest_mem t = raise TERM ("dest_mem", [t]);
   174 
   175 
   176 (* logic *)
   177 
   178 val Trueprop = Const ("Trueprop", boolT --> propT);
   179 
   180 fun mk_Trueprop P = Trueprop $ P;
   181 
   182 fun dest_Trueprop (Const ("Trueprop", _) $ P) = P
   183   | dest_Trueprop t = raise TERM ("dest_Trueprop", [t]);
   184 
   185 fun conj_intr thP thQ =
   186   let
   187     val (P, Q) = pairself (ObjectLogic.dest_judgment o Thm.cprop_of) (thP, thQ)
   188       handle CTERM (msg, _) => raise THM (msg, 0, [thP, thQ]);
   189     val inst = Thm.instantiate ([], [(@{cpat "?P::bool"}, P), (@{cpat "?Q::bool"}, Q)]);
   190   in Drule.implies_elim_list (inst @{thm conjI}) [thP, thQ] end;
   191 
   192 fun conj_elim thPQ =
   193   let
   194     val (P, Q) = Thm.dest_binop (ObjectLogic.dest_judgment (Thm.cprop_of thPQ))
   195       handle CTERM (msg, _) => raise THM (msg, 0, [thPQ]);
   196     val inst = Thm.instantiate ([], [(@{cpat "?P::bool"}, P), (@{cpat "?Q::bool"}, Q)]);
   197     val thP = Thm.implies_elim (inst @{thm conjunct1}) thPQ;
   198     val thQ = Thm.implies_elim (inst @{thm conjunct2}) thPQ;
   199   in (thP, thQ) end;
   200 
   201 fun conj_elims th =
   202   let val (th1, th2) = conj_elim th
   203   in conj_elims th1 @ conj_elims th2 end handle THM _ => [th];
   204 
   205 val conj = @{term "op &"}
   206 and disj = @{term "op |"}
   207 and imp = @{term "op -->"}
   208 and Not = @{term "Not"};
   209 
   210 fun mk_conj (t1, t2) = conj $ t1 $ t2
   211 and mk_disj (t1, t2) = disj $ t1 $ t2
   212 and mk_imp (t1, t2) = imp $ t1 $ t2
   213 and mk_not t = Not $ t;
   214 
   215 fun dest_conj (Const ("op &", _) $ t $ t') = t :: dest_conj t'
   216   | dest_conj t = [t];
   217 
   218 fun dest_disj (Const ("op |", _) $ t $ t') = t :: dest_disj t'
   219   | dest_disj t = [t];
   220 
   221 (*Like dest_disj, but flattens disjunctions however nested*)
   222 fun disjuncts_aux (Const ("op |", _) $ t $ t') disjs = disjuncts_aux t (disjuncts_aux t' disjs)
   223   | disjuncts_aux t disjs = t::disjs;
   224 
   225 fun disjuncts t = disjuncts_aux t [];
   226 
   227 fun dest_imp (Const("op -->",_) $ A $ B) = (A, B)
   228   | dest_imp  t = raise TERM ("dest_imp", [t]);
   229 
   230 fun dest_not (Const ("Not", _) $ t) = t
   231   | dest_not t = raise TERM ("dest_not", [t]);
   232 
   233 fun eq_const T = Const ("op =", [T, T] ---> boolT);
   234 fun mk_eq (t, u) = eq_const (fastype_of t) $ t $ u;
   235 
   236 fun dest_eq (Const ("op =", _) $ lhs $ rhs) = (lhs, rhs)
   237   | dest_eq t = raise TERM ("dest_eq", [t])
   238 
   239 fun all_const T = Const ("All", [T --> boolT] ---> boolT);
   240 fun mk_all (x, T, P) = all_const T $ absfree (x, T, P);
   241 fun list_all (xs, t) = fold_rev (fn (x, T) => fn P => all_const T $ Abs (x, T, P)) xs t;
   242 
   243 fun exists_const T = Const ("Ex", [T --> boolT] ---> boolT);
   244 fun mk_exists (x, T, P) = exists_const T $ absfree (x, T, P);
   245 
   246 fun choice_const T = Const("Hilbert_Choice.Eps", (T --> boolT) --> T);
   247 
   248 val class_eq = "HOL.eq";
   249 
   250 
   251 (* binary operations and relations *)
   252 
   253 fun mk_binop c (t, u) =
   254   let val T = fastype_of t in
   255     Const (c, [T, T] ---> T) $ t $ u
   256   end;
   257 
   258 fun mk_binrel c (t, u) =
   259   let val T = fastype_of t in
   260     Const (c, [T, T] ---> boolT) $ t $ u
   261   end;
   262 
   263 (*destruct the application of a binary operator. The dummyT case is a crude
   264   way of handling polymorphic operators.*)
   265 fun dest_bin c T (tm as Const (c', Type ("fun", [T', _])) $ t $ u) =
   266       if c = c' andalso (T=T' orelse T=dummyT) then (t, u)
   267       else raise TERM ("dest_bin " ^ c, [tm])
   268   | dest_bin c _ tm = raise TERM ("dest_bin " ^ c, [tm]);
   269 
   270 
   271 (* unit *)
   272 
   273 val unitT = Type ("Product_Type.unit", []);
   274 
   275 fun is_unitT (Type ("Product_Type.unit", [])) = true
   276   | is_unitT _ = false;
   277 
   278 val unit = Const ("Product_Type.Unity", unitT);
   279 
   280 fun is_unit (Const ("Product_Type.Unity", _)) = true
   281   | is_unit _ = false;
   282 
   283 
   284 (* prod *)
   285 
   286 fun mk_prodT (T1, T2) = Type ("*", [T1, T2]);
   287 
   288 fun dest_prodT (Type ("*", [T1, T2])) = (T1, T2)
   289   | dest_prodT T = raise TYPE ("dest_prodT", [T], []);
   290 
   291 fun pair_const T1 T2 = Const ("Pair", [T1, T2] ---> mk_prodT (T1, T2));
   292 
   293 fun mk_prod (t1, t2) =
   294   let val T1 = fastype_of t1 and T2 = fastype_of t2 in
   295     pair_const T1 T2 $ t1 $ t2
   296   end;
   297 
   298 fun dest_prod (Const ("Pair", _) $ t1 $ t2) = (t1, t2)
   299   | dest_prod t = raise TERM ("dest_prod", [t]);
   300 
   301 fun mk_fst p =
   302   let val pT = fastype_of p in
   303     Const ("fst", pT --> fst (dest_prodT pT)) $ p
   304   end;
   305 
   306 fun mk_snd p =
   307   let val pT = fastype_of p in
   308     Const ("snd", pT --> snd (dest_prodT pT)) $ p
   309   end;
   310 
   311 fun split_const (A, B, C) =
   312   Const ("split", (A --> B --> C) --> mk_prodT (A, B) --> C);
   313 
   314 fun mk_split t =
   315   (case Term.fastype_of t of
   316     T as (Type ("fun", [A, Type ("fun", [B, C])])) =>
   317       Const ("split", T --> mk_prodT (A, B) --> C) $ t
   318   | _ => raise TERM ("mk_split: bad body type", [t]));
   319 
   320 (*Maps the type T1 * ... * Tn to [T1, ..., Tn], however nested*)
   321 fun flatten_tupleT (Type ("*", [T1, T2])) = flatten_tupleT T1 @ flatten_tupleT T2
   322   | flatten_tupleT T = [T];
   323 
   324 (* tuples with specific arities
   325 
   326   an "arity" of a tuple is a list of lists of integers
   327   ("factors"), denoting paths to subterms that are pairs
   328 *)
   329 
   330 fun prod_err s = raise TERM (s ^ ": inconsistent use of products", []);
   331 
   332 fun mk_tupleT ps =
   333   let
   334     fun mk p Ts =
   335       if p mem ps then
   336         let
   337           val (T, Ts') = mk (1::p) Ts;
   338           val (U, Ts'') = mk (2::p) Ts'
   339         in (mk_prodT (T, U), Ts'') end
   340       else (hd Ts, tl Ts)
   341   in fst o mk [] end;
   342 
   343 fun strip_tupleT ps =
   344   let
   345     fun factors p T = if p mem ps then (case T of
   346         Type ("*", [T1, T2]) =>
   347           factors (1::p) T1 @ factors (2::p) T2
   348       | _ => prod_err "strip_tupleT") else [T]
   349   in factors [] end;
   350 
   351 val flat_tupleT_paths =
   352   let
   353     fun factors p (Type ("*", [T1, T2])) =
   354           p :: factors (1::p) T1 @ factors (2::p) T2
   355       | factors p _ = []
   356   in factors [] end;
   357 
   358 fun mk_tuple ps =
   359   let
   360     fun mk p T ts =
   361       if p mem ps then (case T of
   362           Type ("*", [T1, T2]) =>
   363             let
   364               val (t, ts') = mk (1::p) T1 ts;
   365               val (u, ts'') = mk (2::p) T2 ts'
   366             in (pair_const T1 T2 $ t $ u, ts'') end
   367         | _ => prod_err "mk_tuple")
   368       else (hd ts, tl ts)
   369   in fst oo mk [] end;
   370 
   371 fun dest_tuple ps =
   372   let
   373     fun dest p t = if p mem ps then (case t of
   374         Const ("Pair", _) $ t $ u =>
   375           dest (1::p) t @ dest (2::p) u
   376       | _ => prod_err "dest_tuple") else [t]
   377   in dest [] end;
   378 
   379 val flat_tuple_paths =
   380   let
   381     fun factors p (Const ("Pair", _) $ t $ u) =
   382           p :: factors (1::p) t @ factors (2::p) u
   383       | factors p _ = []
   384   in factors [] end;
   385 
   386 (*In mk_splits ps S T u, term u expects separate arguments for the factors of S,
   387   with result type T.  The call creates a new term expecting one argument
   388   of type S.*)
   389 fun mk_splits ps T T3 u =
   390   let
   391     fun ap ((p, T) :: pTs) =
   392           if p mem ps then (case T of
   393               Type ("*", [T1, T2]) =>
   394                 split_const (T1, T2, map snd pTs ---> T3) $
   395                   ap ((1::p, T1) :: (2::p, T2) :: pTs)
   396             | _ => prod_err "mk_splits")
   397           else Abs ("x", T, ap pTs)
   398       | ap [] =
   399           let val k = length ps
   400           in list_comb (incr_boundvars (k + 1) u, map Bound (k downto 0)) end
   401   in ap [([], T)] end;
   402 
   403 val strip_splits =
   404   let
   405     fun strip [] qs Ts t = (t, Ts, qs)
   406       | strip (p :: ps) qs Ts (Const ("split", _) $ t) =
   407           strip ((1 :: p) :: (2 :: p) :: ps) (p :: qs) Ts t
   408       | strip (p :: ps) qs Ts (Abs (s, T, t)) = strip ps qs (T :: Ts) t
   409       | strip (p :: ps) qs Ts t = strip ps qs
   410           (hd (binder_types (fastype_of1 (Ts, t))) :: Ts)
   411           (incr_boundvars 1 t $ Bound 0)
   412   in strip [[]] [] [] end;
   413 
   414 
   415 (* nat *)
   416 
   417 val natT = Type ("nat", []);
   418 
   419 val zero = Const ("HOL.zero_class.zero", natT);
   420 
   421 fun is_zero (Const ("HOL.zero_class.zero", _)) = true
   422   | is_zero _ = false;
   423 
   424 fun mk_Suc t = Const ("Suc", natT --> natT) $ t;
   425 
   426 fun dest_Suc (Const ("Suc", _) $ t) = t
   427   | dest_Suc t = raise TERM ("dest_Suc", [t]);
   428 
   429 val Suc_zero = mk_Suc zero;
   430 
   431 fun mk_nat n =
   432   let
   433     fun mk 0 = zero
   434       | mk n = mk_Suc (mk (n - 1));
   435   in if n < 0 then raise TERM ("mk_nat: negative number", []) else mk n end;
   436 
   437 fun dest_nat (Const ("HOL.zero_class.zero", _)) = 0
   438   | dest_nat (Const ("Suc", _) $ t) = dest_nat t + 1
   439   | dest_nat t = raise TERM ("dest_nat", [t]);
   440 
   441 val class_size = "Nat.size";
   442 
   443 fun size_const T = Const ("Nat.size_class.size", T --> natT);
   444 
   445 
   446 (* code numeral *)
   447 
   448 val code_numeralT = Type ("Code_Numeral.code_numeral", []);
   449 
   450 
   451 (* binary numerals and int -- non-unique representation due to leading zeros/ones! *)
   452 
   453 val intT = Type ("Int.int", []);
   454 
   455 val pls_const = Const ("Int.Pls", intT)
   456 and min_const = Const ("Int.Min", intT)
   457 and bit0_const = Const ("Int.Bit0", intT --> intT)
   458 and bit1_const = Const ("Int.Bit1", intT --> intT);
   459 
   460 fun mk_bit 0 = bit0_const
   461   | mk_bit 1 = bit1_const
   462   | mk_bit _ = raise TERM ("mk_bit", []);
   463 
   464 fun dest_bit (Const ("Int.Bit0", _)) = 0
   465   | dest_bit (Const ("Int.Bit1", _)) = 1
   466   | dest_bit t = raise TERM ("dest_bit", [t]);
   467 
   468 fun mk_numeral 0 = pls_const
   469   | mk_numeral ~1 = min_const
   470   | mk_numeral i =
   471       let val (q, r) = Integer.div_mod i 2;
   472       in mk_bit r $ mk_numeral q end;
   473 
   474 fun dest_numeral (Const ("Int.Pls", _)) = 0
   475   | dest_numeral (Const ("Int.Min", _)) = ~1
   476   | dest_numeral (Const ("Int.Bit0", _) $ bs) = 2 * dest_numeral bs
   477   | dest_numeral (Const ("Int.Bit1", _) $ bs) = 2 * dest_numeral bs + 1
   478   | dest_numeral t = raise TERM ("dest_numeral", [t]);
   479 
   480 fun number_of_const T = Const ("Int.number_class.number_of", intT --> T);
   481 
   482 fun add_numerals (Const ("Int.number_class.number_of", Type (_, [_, T])) $ t) = cons (t, T)
   483   | add_numerals (t $ u) = add_numerals t #> add_numerals u
   484   | add_numerals (Abs (_, _, t)) = add_numerals t
   485   | add_numerals _ = I;
   486 
   487 fun mk_number T 0 = Const ("HOL.zero_class.zero", T)
   488   | mk_number T 1 = Const ("HOL.one_class.one", T)
   489   | mk_number T i = number_of_const T $ mk_numeral i;
   490 
   491 fun dest_number (Const ("HOL.zero_class.zero", T)) = (T, 0)
   492   | dest_number (Const ("HOL.one_class.one", T)) = (T, 1)
   493   | dest_number (Const ("Int.number_class.number_of", Type ("fun", [_, T])) $ t) =
   494       (T, dest_numeral t)
   495   | dest_number t = raise TERM ("dest_number", [t]);
   496 
   497 
   498 (* real *)
   499 
   500 val realT = Type ("RealDef.real", []);
   501 
   502 
   503 (* list *)
   504 
   505 fun listT T = Type ("List.list", [T]);
   506 
   507 fun nil_const T = Const ("List.list.Nil", listT T);
   508 
   509 fun cons_const T =
   510   let val lT = listT T
   511   in Const ("List.list.Cons", T --> lT --> lT) end;
   512 
   513 fun mk_list T ts =
   514   let
   515     val lT = listT T;
   516     val Nil = Const ("List.list.Nil", lT);
   517     fun Cons t u = Const ("List.list.Cons", T --> lT --> lT) $ t $ u;
   518   in fold_rev Cons ts Nil end;
   519 
   520 fun dest_list (Const ("List.list.Nil", _)) = []
   521   | dest_list (Const ("List.list.Cons", _) $ t $ u) = t :: dest_list u
   522   | dest_list t = raise TERM ("dest_list", [t]);
   523 
   524 
   525 (* nibble *)
   526 
   527 val nibbleT = Type ("String.nibble", []);
   528 
   529 fun mk_nibble n =
   530   let val s =
   531     if 0 <= n andalso n <= 9 then chr (n + ord "0")
   532     else if 10 <= n andalso n <= 15 then chr (n + ord "A" - 10)
   533     else raise TERM ("mk_nibble", [])
   534   in Const ("String.nibble.Nibble" ^ s, nibbleT) end;
   535 
   536 fun dest_nibble t =
   537   let fun err () = raise TERM ("dest_nibble", [t]) in
   538     (case try (unprefix "String.nibble.Nibble" o fst o Term.dest_Const) t of
   539       NONE => err ()
   540     | SOME c =>
   541         if size c <> 1 then err ()
   542         else if "0" <= c andalso c <= "9" then ord c - ord "0"
   543         else if "A" <= c andalso c <= "F" then ord c - ord "A" + 10
   544         else err ())
   545   end;
   546 
   547 
   548 (* char *)
   549 
   550 val charT = Type ("String.char", []);
   551 
   552 fun mk_char n =
   553   if 0 <= n andalso n <= 255 then
   554     Const ("String.char.Char", nibbleT --> nibbleT --> charT) $
   555       mk_nibble (n div 16) $ mk_nibble (n mod 16)
   556   else raise TERM ("mk_char", []);
   557 
   558 fun dest_char (Const ("String.char.Char", _) $ t $ u) =
   559       dest_nibble t * 16 + dest_nibble u
   560   | dest_char t = raise TERM ("dest_char", [t]);
   561 
   562 
   563 (* string *)
   564 
   565 val stringT = Type ("String.string", []);
   566 
   567 val mk_string = mk_list charT o map (mk_char o ord) o explode;
   568 val dest_string = implode o map (chr o dest_char) o dest_list;
   569 
   570 
   571 (* literal *)
   572 
   573 val literalT = Type ("String.literal", []);
   574 
   575 fun mk_literal s = Const ("String.literal.STR", stringT --> literalT)
   576       $ mk_string s;
   577 fun dest_literal (Const ("String.literal.STR", _) $ t) =
   578       dest_string t
   579   | dest_literal t = raise TERM ("dest_literal", [t]);
   580 
   581 
   582 (* typerep and term *)
   583 
   584 val typerepT = Type ("Typerep.typerep", []);
   585 
   586 fun mk_typerep (Type (tyco, Ts)) = Const ("Typerep.typerep.Typerep",
   587       literalT --> listT typerepT --> typerepT) $ mk_literal tyco
   588         $ mk_list typerepT (map mk_typerep Ts)
   589   | mk_typerep (T as TFree _) = Const ("Typerep.typerep_class.typerep",
   590       Term.itselfT T --> typerepT) $ Logic.mk_type T;
   591 
   592 val termT = Type ("Code_Eval.term", []);
   593 
   594 fun mk_term_of T t = Const ("Code_Eval.term_of_class.term_of", T --> termT) $ t;
   595 
   596 fun reflect_term (Const (c, T)) =
   597       Const ("Code_Eval.Const", literalT --> typerepT --> termT)
   598         $ mk_literal c $ mk_typerep T
   599   | reflect_term (t1 $ t2) =
   600       Const ("Code_Eval.App", termT --> termT --> termT)
   601         $ reflect_term t1 $ reflect_term t2
   602   | reflect_term (Abs (v, _, t)) = Abs (v, termT, reflect_term t)
   603   | reflect_term t = t;
   604 
   605 fun mk_valtermify_app c vs T =
   606   let
   607     fun termifyT T = mk_prodT (T, unitT --> termT);
   608     fun valapp T T' = Const ("Code_Eval.valapp",
   609       termifyT (T --> T') --> termifyT T --> termifyT T');
   610     fun mk_fTs [] _ = []
   611       | mk_fTs (_ :: Ts) T = (Ts ---> T) :: mk_fTs Ts T;
   612     val Ts = map snd vs;
   613     val t = Const (c, Ts ---> T);
   614     val tt = mk_prod (t, Abs ("u", unitT, reflect_term t));
   615     fun app (t, (fT, (v, T))) = valapp T fT $ t $ Free (v, termifyT T);
   616   in Library.foldl app (tt, mk_fTs Ts T ~~ vs) end;
   617 
   618 
   619 (* open state monads *)
   620 
   621 fun mk_return T U x = pair_const T U $ x;
   622 
   623 fun mk_ST clauses t U (someT, V) =
   624   let
   625     val R = case someT of SOME T => mk_prodT (T, V) | NONE => V
   626     fun mk_clause ((t, U), SOME (v, T)) (t', U') =
   627           (Const ("Product_Type.scomp", (U --> mk_prodT (T, U')) --> (T --> U' --> R) --> U --> R)
   628             $ t $ lambda (Free (v, T)) t', U)
   629       | mk_clause ((t, U), NONE) (t', U') =
   630           (Const ("Product_Type.fcomp", (U --> U') --> (U' --> R) --> U --> R)
   631             $ t $ t', U)
   632   in fold_rev mk_clause clauses (t, U) |> fst end;
   633 
   634 val code_numeralT = Type ("Code_Numeral.code_numeral", []);
   635 val random_seedT = mk_prodT (code_numeralT, code_numeralT);
   636 
   637 fun mk_random T t = Const ("Quickcheck.random_class.random", code_numeralT
   638   --> random_seedT --> mk_prodT (mk_prodT (T, unitT --> termT), random_seedT)) $ t;
   639 
   640 end;