src/HOL/Map.thy
author haftmann
Wed Nov 28 09:01:39 2007 +0100 (2007-11-28)
changeset 25483 65de74f62874
parent 24331 76f7a8c6e842
child 25490 e8ab1c42c14f
permissions -rw-r--r--
dropped legacy unnamed infix
     1 (*  Title:      HOL/Map.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, based on a theory by David von Oheimb
     4     Copyright   1997-2003 TU Muenchen
     5 
     6 The datatype of `maps' (written ~=>); strongly resembles maps in VDM.
     7 *)
     8 
     9 header {* Maps *}
    10 
    11 theory Map
    12 imports List
    13 begin
    14 
    15 types ('a,'b) map = "'a => 'b option"  (infixr "~=>" 0)
    16 translations (type) "a ~=> b " <= (type) "a => b option"
    17 
    18 syntax (xsymbols)
    19   map :: "type \<Rightarrow> type \<Rightarrow> type"  (infixr "\<rightharpoonup>" 0)
    20 
    21 abbreviation
    22   empty :: "'a ~=> 'b" where
    23   "empty == %x. None"
    24 
    25 definition
    26   map_comp :: "('b ~=> 'c)  => ('a ~=> 'b) => ('a ~=> 'c)"  (infixl "o'_m" 55) where
    27   "f o_m g = (\<lambda>k. case g k of None \<Rightarrow> None | Some v \<Rightarrow> f v)"
    28 
    29 notation (xsymbols)
    30   map_comp  (infixl "\<circ>\<^sub>m" 55)
    31 
    32 definition
    33   map_add :: "('a ~=> 'b) => ('a ~=> 'b) => ('a ~=> 'b)"  (infixl "++" 100) where
    34   "m1 ++ m2 = (\<lambda>x. case m2 x of None => m1 x | Some y => Some y)"
    35 
    36 definition
    37   restrict_map :: "('a ~=> 'b) => 'a set => ('a ~=> 'b)"  (infixl "|`"  110) where
    38   "m|`A = (\<lambda>x. if x : A then m x else None)"
    39 
    40 notation (latex output)
    41   restrict_map  ("_\<restriction>\<^bsub>_\<^esub>" [111,110] 110)
    42 
    43 definition
    44   dom :: "('a ~=> 'b) => 'a set" where
    45   "dom m = {a. m a ~= None}"
    46 
    47 definition
    48   ran :: "('a ~=> 'b) => 'b set" where
    49   "ran m = {b. EX a. m a = Some b}"
    50 
    51 definition
    52   map_le :: "('a ~=> 'b) => ('a ~=> 'b) => bool"  (infix "\<subseteq>\<^sub>m" 50) where
    53   "(m\<^isub>1 \<subseteq>\<^sub>m m\<^isub>2) = (\<forall>a \<in> dom m\<^isub>1. m\<^isub>1 a = m\<^isub>2 a)"
    54 
    55 consts
    56   map_of :: "('a * 'b) list => 'a ~=> 'b"
    57   map_upds :: "('a ~=> 'b) => 'a list => 'b list => ('a ~=> 'b)"
    58 
    59 nonterminals
    60   maplets maplet
    61 
    62 syntax
    63   "_maplet"  :: "['a, 'a] => maplet"             ("_ /|->/ _")
    64   "_maplets" :: "['a, 'a] => maplet"             ("_ /[|->]/ _")
    65   ""         :: "maplet => maplets"             ("_")
    66   "_Maplets" :: "[maplet, maplets] => maplets" ("_,/ _")
    67   "_MapUpd"  :: "['a ~=> 'b, maplets] => 'a ~=> 'b" ("_/'(_')" [900,0]900)
    68   "_Map"     :: "maplets => 'a ~=> 'b"            ("(1[_])")
    69 
    70 syntax (xsymbols)
    71   "_maplet"  :: "['a, 'a] => maplet"             ("_ /\<mapsto>/ _")
    72   "_maplets" :: "['a, 'a] => maplet"             ("_ /[\<mapsto>]/ _")
    73 
    74 translations
    75   "_MapUpd m (_Maplets xy ms)"  == "_MapUpd (_MapUpd m xy) ms"
    76   "_MapUpd m (_maplet  x y)"    == "m(x:=Some y)"
    77   "_MapUpd m (_maplets x y)"    == "map_upds m x y"
    78   "_Map ms"                     == "_MapUpd (CONST empty) ms"
    79   "_Map (_Maplets ms1 ms2)"     <= "_MapUpd (_Map ms1) ms2"
    80   "_Maplets ms1 (_Maplets ms2 ms3)" <= "_Maplets (_Maplets ms1 ms2) ms3"
    81 
    82 primrec
    83   "map_of [] = empty"
    84   "map_of (p#ps) = (map_of ps)(fst p |-> snd p)"
    85 
    86 defs
    87   map_upds_def [code func]: "m(xs [|->] ys) == m ++ map_of (rev(zip xs ys))"
    88 
    89 
    90 subsection {* @{term [source] empty} *}
    91 
    92 lemma empty_upd_none [simp]: "empty(x := None) = empty"
    93 by (rule ext) simp
    94 
    95 
    96 subsection {* @{term [source] map_upd} *}
    97 
    98 lemma map_upd_triv: "t k = Some x ==> t(k|->x) = t"
    99 by (rule ext) simp
   100 
   101 lemma map_upd_nonempty [simp]: "t(k|->x) ~= empty"
   102 proof
   103   assume "t(k \<mapsto> x) = empty"
   104   then have "(t(k \<mapsto> x)) k = None" by simp
   105   then show False by simp
   106 qed
   107 
   108 lemma map_upd_eqD1:
   109   assumes "m(a\<mapsto>x) = n(a\<mapsto>y)"
   110   shows "x = y"
   111 proof -
   112   from prems have "(m(a\<mapsto>x)) a = (n(a\<mapsto>y)) a" by simp
   113   then show ?thesis by simp
   114 qed
   115 
   116 lemma map_upd_Some_unfold:
   117   "((m(a|->b)) x = Some y) = (x = a \<and> b = y \<or> x \<noteq> a \<and> m x = Some y)"
   118 by auto
   119 
   120 lemma image_map_upd [simp]: "x \<notin> A \<Longrightarrow> m(x \<mapsto> y) ` A = m ` A"
   121 by auto
   122 
   123 lemma finite_range_updI: "finite (range f) ==> finite (range (f(a|->b)))"
   124 unfolding image_def
   125 apply (simp (no_asm_use) add:full_SetCompr_eq)
   126 apply (rule finite_subset)
   127  prefer 2 apply assumption
   128 apply (auto)
   129 done
   130 
   131 
   132 subsection {* @{term [source] map_of} *}
   133 
   134 lemma map_of_eq_None_iff:
   135   "(map_of xys x = None) = (x \<notin> fst ` (set xys))"
   136 by (induct xys) simp_all
   137 
   138 lemma map_of_is_SomeD: "map_of xys x = Some y \<Longrightarrow> (x,y) \<in> set xys"
   139 apply (induct xys)
   140  apply simp
   141 apply (clarsimp split: if_splits)
   142 done
   143 
   144 lemma map_of_eq_Some_iff [simp]:
   145   "distinct(map fst xys) \<Longrightarrow> (map_of xys x = Some y) = ((x,y) \<in> set xys)"
   146 apply (induct xys)
   147  apply simp
   148 apply (auto simp: map_of_eq_None_iff [symmetric])
   149 done
   150 
   151 lemma Some_eq_map_of_iff [simp]:
   152   "distinct(map fst xys) \<Longrightarrow> (Some y = map_of xys x) = ((x,y) \<in> set xys)"
   153 by (auto simp del:map_of_eq_Some_iff simp add: map_of_eq_Some_iff [symmetric])
   154 
   155 lemma map_of_is_SomeI [simp]: "\<lbrakk> distinct(map fst xys); (x,y) \<in> set xys \<rbrakk>
   156     \<Longrightarrow> map_of xys x = Some y"
   157 apply (induct xys)
   158  apply simp
   159 apply force
   160 done
   161 
   162 lemma map_of_zip_is_None [simp]:
   163   "length xs = length ys \<Longrightarrow> (map_of (zip xs ys) x = None) = (x \<notin> set xs)"
   164 by (induct rule: list_induct2) simp_all
   165 
   166 lemma finite_range_map_of: "finite (range (map_of xys))"
   167 apply (induct xys)
   168  apply (simp_all add: image_constant)
   169 apply (rule finite_subset)
   170  prefer 2 apply assumption
   171 apply auto
   172 done
   173 
   174 lemma map_of_SomeD: "map_of xs k = Some y \<Longrightarrow> (k, y) \<in> set xs"
   175 by (induct xs) (simp, atomize (full), auto)
   176 
   177 lemma map_of_mapk_SomeI:
   178   "inj f ==> map_of t k = Some x ==>
   179    map_of (map (split (%k. Pair (f k))) t) (f k) = Some x"
   180 by (induct t) (auto simp add: inj_eq)
   181 
   182 lemma weak_map_of_SomeI: "(k, x) : set l ==> \<exists>x. map_of l k = Some x"
   183 by (induct l) auto
   184 
   185 lemma map_of_filter_in:
   186   "map_of xs k = Some z \<Longrightarrow> P k z \<Longrightarrow> map_of (filter (split P) xs) k = Some z"
   187 by (induct xs) auto
   188 
   189 lemma map_of_map: "map_of (map (%(a,b). (a,f b)) xs) x = option_map f (map_of xs x)"
   190 by (induct xs) auto
   191 
   192 
   193 subsection {* @{term [source] option_map} related *}
   194 
   195 lemma option_map_o_empty [simp]: "option_map f o empty = empty"
   196 by (rule ext) simp
   197 
   198 lemma option_map_o_map_upd [simp]:
   199   "option_map f o m(a|->b) = (option_map f o m)(a|->f b)"
   200 by (rule ext) simp
   201 
   202 
   203 subsection {* @{term [source] map_comp} related *}
   204 
   205 lemma map_comp_empty [simp]:
   206   "m \<circ>\<^sub>m empty = empty"
   207   "empty \<circ>\<^sub>m m = empty"
   208 by (auto simp add: map_comp_def intro: ext split: option.splits)
   209 
   210 lemma map_comp_simps [simp]:
   211   "m2 k = None \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = None"
   212   "m2 k = Some k' \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = m1 k'"
   213 by (auto simp add: map_comp_def)
   214 
   215 lemma map_comp_Some_iff:
   216   "((m1 \<circ>\<^sub>m m2) k = Some v) = (\<exists>k'. m2 k = Some k' \<and> m1 k' = Some v)"
   217 by (auto simp add: map_comp_def split: option.splits)
   218 
   219 lemma map_comp_None_iff:
   220   "((m1 \<circ>\<^sub>m m2) k = None) = (m2 k = None \<or> (\<exists>k'. m2 k = Some k' \<and> m1 k' = None)) "
   221 by (auto simp add: map_comp_def split: option.splits)
   222 
   223 
   224 subsection {* @{text "++"} *}
   225 
   226 lemma map_add_empty[simp]: "m ++ empty = m"
   227 by(simp add: map_add_def)
   228 
   229 lemma empty_map_add[simp]: "empty ++ m = m"
   230 by (rule ext) (simp add: map_add_def split: option.split)
   231 
   232 lemma map_add_assoc[simp]: "m1 ++ (m2 ++ m3) = (m1 ++ m2) ++ m3"
   233 by (rule ext) (simp add: map_add_def split: option.split)
   234 
   235 lemma map_add_Some_iff:
   236   "((m ++ n) k = Some x) = (n k = Some x | n k = None & m k = Some x)"
   237 by (simp add: map_add_def split: option.split)
   238 
   239 lemma map_add_SomeD [dest!]:
   240   "(m ++ n) k = Some x \<Longrightarrow> n k = Some x \<or> n k = None \<and> m k = Some x"
   241 by (rule map_add_Some_iff [THEN iffD1])
   242 
   243 lemma map_add_find_right [simp]: "!!xx. n k = Some xx ==> (m ++ n) k = Some xx"
   244 by (subst map_add_Some_iff) fast
   245 
   246 lemma map_add_None [iff]: "((m ++ n) k = None) = (n k = None & m k = None)"
   247 by (simp add: map_add_def split: option.split)
   248 
   249 lemma map_add_upd[simp]: "f ++ g(x|->y) = (f ++ g)(x|->y)"
   250 by (rule ext) (simp add: map_add_def)
   251 
   252 lemma map_add_upds[simp]: "m1 ++ (m2(xs[\<mapsto>]ys)) = (m1++m2)(xs[\<mapsto>]ys)"
   253 by (simp add: map_upds_def)
   254 
   255 lemma map_of_append[simp]: "map_of (xs @ ys) = map_of ys ++ map_of xs"
   256 unfolding map_add_def
   257 apply (induct xs)
   258  apply simp
   259 apply (rule ext)
   260 apply (simp split add: option.split)
   261 done
   262 
   263 lemma finite_range_map_of_map_add:
   264   "finite (range f) ==> finite (range (f ++ map_of l))"
   265 apply (induct l)
   266  apply (auto simp del: fun_upd_apply)
   267 apply (erule finite_range_updI)
   268 done
   269 
   270 lemma inj_on_map_add_dom [iff]:
   271   "inj_on (m ++ m') (dom m') = inj_on m' (dom m')"
   272 by (fastsimp simp: map_add_def dom_def inj_on_def split: option.splits)
   273 
   274 
   275 subsection {* @{term [source] restrict_map} *}
   276 
   277 lemma restrict_map_to_empty [simp]: "m|`{} = empty"
   278 by (simp add: restrict_map_def)
   279 
   280 lemma restrict_map_empty [simp]: "empty|`D = empty"
   281 by (simp add: restrict_map_def)
   282 
   283 lemma restrict_in [simp]: "x \<in> A \<Longrightarrow> (m|`A) x = m x"
   284 by (simp add: restrict_map_def)
   285 
   286 lemma restrict_out [simp]: "x \<notin> A \<Longrightarrow> (m|`A) x = None"
   287 by (simp add: restrict_map_def)
   288 
   289 lemma ran_restrictD: "y \<in> ran (m|`A) \<Longrightarrow> \<exists>x\<in>A. m x = Some y"
   290 by (auto simp: restrict_map_def ran_def split: split_if_asm)
   291 
   292 lemma dom_restrict [simp]: "dom (m|`A) = dom m \<inter> A"
   293 by (auto simp: restrict_map_def dom_def split: split_if_asm)
   294 
   295 lemma restrict_upd_same [simp]: "m(x\<mapsto>y)|`(-{x}) = m|`(-{x})"
   296 by (rule ext) (auto simp: restrict_map_def)
   297 
   298 lemma restrict_restrict [simp]: "m|`A|`B = m|`(A\<inter>B)"
   299 by (rule ext) (auto simp: restrict_map_def)
   300 
   301 lemma restrict_fun_upd [simp]:
   302   "m(x := y)|`D = (if x \<in> D then (m|`(D-{x}))(x := y) else m|`D)"
   303 by (simp add: restrict_map_def expand_fun_eq)
   304 
   305 lemma fun_upd_None_restrict [simp]:
   306   "(m|`D)(x := None) = (if x:D then m|`(D - {x}) else m|`D)"
   307 by (simp add: restrict_map_def expand_fun_eq)
   308 
   309 lemma fun_upd_restrict: "(m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   310 by (simp add: restrict_map_def expand_fun_eq)
   311 
   312 lemma fun_upd_restrict_conv [simp]:
   313   "x \<in> D \<Longrightarrow> (m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   314 by (simp add: restrict_map_def expand_fun_eq)
   315 
   316 
   317 subsection {* @{term [source] map_upds} *}
   318 
   319 lemma map_upds_Nil1 [simp]: "m([] [|->] bs) = m"
   320 by (simp add: map_upds_def)
   321 
   322 lemma map_upds_Nil2 [simp]: "m(as [|->] []) = m"
   323 by (simp add:map_upds_def)
   324 
   325 lemma map_upds_Cons [simp]: "m(a#as [|->] b#bs) = (m(a|->b))(as[|->]bs)"
   326 by (simp add:map_upds_def)
   327 
   328 lemma map_upds_append1 [simp]: "\<And>ys m. size xs < size ys \<Longrightarrow>
   329   m(xs@[x] [\<mapsto>] ys) = m(xs [\<mapsto>] ys)(x \<mapsto> ys!size xs)"
   330 apply(induct xs)
   331  apply (clarsimp simp add: neq_Nil_conv)
   332 apply (case_tac ys)
   333  apply simp
   334 apply simp
   335 done
   336 
   337 lemma map_upds_list_update2_drop [simp]:
   338   "\<lbrakk>size xs \<le> i; i < size ys\<rbrakk>
   339     \<Longrightarrow> m(xs[\<mapsto>]ys[i:=y]) = m(xs[\<mapsto>]ys)"
   340 apply (induct xs arbitrary: m ys i)
   341  apply simp
   342 apply (case_tac ys)
   343  apply simp
   344 apply (simp split: nat.split)
   345 done
   346 
   347 lemma map_upd_upds_conv_if:
   348   "(f(x|->y))(xs [|->] ys) =
   349    (if x : set(take (length ys) xs) then f(xs [|->] ys)
   350                                     else (f(xs [|->] ys))(x|->y))"
   351 apply (induct xs arbitrary: x y ys f)
   352  apply simp
   353 apply (case_tac ys)
   354  apply (auto split: split_if simp: fun_upd_twist)
   355 done
   356 
   357 lemma map_upds_twist [simp]:
   358   "a ~: set as ==> m(a|->b)(as[|->]bs) = m(as[|->]bs)(a|->b)"
   359 using set_take_subset by (fastsimp simp add: map_upd_upds_conv_if)
   360 
   361 lemma map_upds_apply_nontin [simp]:
   362   "x ~: set xs ==> (f(xs[|->]ys)) x = f x"
   363 apply (induct xs arbitrary: ys)
   364  apply simp
   365 apply (case_tac ys)
   366  apply (auto simp: map_upd_upds_conv_if)
   367 done
   368 
   369 lemma fun_upds_append_drop [simp]:
   370   "size xs = size ys \<Longrightarrow> m(xs@zs[\<mapsto>]ys) = m(xs[\<mapsto>]ys)"
   371 apply (induct xs arbitrary: m ys)
   372  apply simp
   373 apply (case_tac ys)
   374  apply simp_all
   375 done
   376 
   377 lemma fun_upds_append2_drop [simp]:
   378   "size xs = size ys \<Longrightarrow> m(xs[\<mapsto>]ys@zs) = m(xs[\<mapsto>]ys)"
   379 apply (induct xs arbitrary: m ys)
   380  apply simp
   381 apply (case_tac ys)
   382  apply simp_all
   383 done
   384 
   385 
   386 lemma restrict_map_upds[simp]:
   387   "\<lbrakk> length xs = length ys; set xs \<subseteq> D \<rbrakk>
   388     \<Longrightarrow> m(xs [\<mapsto>] ys)|`D = (m|`(D - set xs))(xs [\<mapsto>] ys)"
   389 apply (induct xs arbitrary: m ys)
   390  apply simp
   391 apply (case_tac ys)
   392  apply simp
   393 apply (simp add: Diff_insert [symmetric] insert_absorb)
   394 apply (simp add: map_upd_upds_conv_if)
   395 done
   396 
   397 
   398 subsection {* @{term [source] dom} *}
   399 
   400 lemma domI: "m a = Some b ==> a : dom m"
   401 by(simp add:dom_def)
   402 (* declare domI [intro]? *)
   403 
   404 lemma domD: "a : dom m ==> \<exists>b. m a = Some b"
   405 by (cases "m a") (auto simp add: dom_def)
   406 
   407 lemma domIff [iff, simp del]: "(a : dom m) = (m a ~= None)"
   408 by(simp add:dom_def)
   409 
   410 lemma dom_empty [simp]: "dom empty = {}"
   411 by(simp add:dom_def)
   412 
   413 lemma dom_fun_upd [simp]:
   414   "dom(f(x := y)) = (if y=None then dom f - {x} else insert x (dom f))"
   415 by(auto simp add:dom_def)
   416 
   417 lemma dom_map_of: "dom(map_of xys) = {x. \<exists>y. (x,y) : set xys}"
   418 by (induct xys) (auto simp del: fun_upd_apply)
   419 
   420 lemma dom_map_of_conv_image_fst:
   421   "dom(map_of xys) = fst ` (set xys)"
   422 by(force simp: dom_map_of)
   423 
   424 lemma dom_map_of_zip [simp]: "[| length xs = length ys; distinct xs |] ==>
   425   dom(map_of(zip xs ys)) = set xs"
   426 by (induct rule: list_induct2) simp_all
   427 
   428 lemma finite_dom_map_of: "finite (dom (map_of l))"
   429 by (induct l) (auto simp add: dom_def insert_Collect [symmetric])
   430 
   431 lemma dom_map_upds [simp]:
   432   "dom(m(xs[|->]ys)) = set(take (length ys) xs) Un dom m"
   433 apply (induct xs arbitrary: m ys)
   434  apply simp
   435 apply (case_tac ys)
   436  apply auto
   437 done
   438 
   439 lemma dom_map_add [simp]: "dom(m++n) = dom n Un dom m"
   440 by(auto simp:dom_def)
   441 
   442 lemma dom_override_on [simp]:
   443   "dom(override_on f g A) =
   444     (dom f  - {a. a : A - dom g}) Un {a. a : A Int dom g}"
   445 by(auto simp: dom_def override_on_def)
   446 
   447 lemma map_add_comm: "dom m1 \<inter> dom m2 = {} \<Longrightarrow> m1++m2 = m2++m1"
   448 by (rule ext) (force simp: map_add_def dom_def split: option.split)
   449 
   450 (* Due to John Matthews - could be rephrased with dom *)
   451 lemma finite_map_freshness:
   452   "finite (dom (f :: 'a \<rightharpoonup> 'b)) \<Longrightarrow> \<not> finite (UNIV :: 'a set) \<Longrightarrow>
   453    \<exists>x. f x = None"
   454 by(bestsimp dest:ex_new_if_finite)
   455 
   456 subsection {* @{term [source] ran} *}
   457 
   458 lemma ranI: "m a = Some b ==> b : ran m"
   459 by(auto simp: ran_def)
   460 (* declare ranI [intro]? *)
   461 
   462 lemma ran_empty [simp]: "ran empty = {}"
   463 by(auto simp: ran_def)
   464 
   465 lemma ran_map_upd [simp]: "m a = None ==> ran(m(a|->b)) = insert b (ran m)"
   466 unfolding ran_def
   467 apply auto
   468 apply (subgoal_tac "aa ~= a")
   469  apply auto
   470 done
   471 
   472 
   473 subsection {* @{text "map_le"} *}
   474 
   475 lemma map_le_empty [simp]: "empty \<subseteq>\<^sub>m g"
   476 by (simp add: map_le_def)
   477 
   478 lemma upd_None_map_le [simp]: "f(x := None) \<subseteq>\<^sub>m f"
   479 by (force simp add: map_le_def)
   480 
   481 lemma map_le_upd[simp]: "f \<subseteq>\<^sub>m g ==> f(a := b) \<subseteq>\<^sub>m g(a := b)"
   482 by (fastsimp simp add: map_le_def)
   483 
   484 lemma map_le_imp_upd_le [simp]: "m1 \<subseteq>\<^sub>m m2 \<Longrightarrow> m1(x := None) \<subseteq>\<^sub>m m2(x \<mapsto> y)"
   485 by (force simp add: map_le_def)
   486 
   487 lemma map_le_upds [simp]:
   488   "f \<subseteq>\<^sub>m g ==> f(as [|->] bs) \<subseteq>\<^sub>m g(as [|->] bs)"
   489 apply (induct as arbitrary: f g bs)
   490  apply simp
   491 apply (case_tac bs)
   492  apply auto
   493 done
   494 
   495 lemma map_le_implies_dom_le: "(f \<subseteq>\<^sub>m g) \<Longrightarrow> (dom f \<subseteq> dom g)"
   496 by (fastsimp simp add: map_le_def dom_def)
   497 
   498 lemma map_le_refl [simp]: "f \<subseteq>\<^sub>m f"
   499 by (simp add: map_le_def)
   500 
   501 lemma map_le_trans[trans]: "\<lbrakk> m1 \<subseteq>\<^sub>m m2; m2 \<subseteq>\<^sub>m m3\<rbrakk> \<Longrightarrow> m1 \<subseteq>\<^sub>m m3"
   502 by (auto simp add: map_le_def dom_def)
   503 
   504 lemma map_le_antisym: "\<lbrakk> f \<subseteq>\<^sub>m g; g \<subseteq>\<^sub>m f \<rbrakk> \<Longrightarrow> f = g"
   505 unfolding map_le_def
   506 apply (rule ext)
   507 apply (case_tac "x \<in> dom f", simp)
   508 apply (case_tac "x \<in> dom g", simp, fastsimp)
   509 done
   510 
   511 lemma map_le_map_add [simp]: "f \<subseteq>\<^sub>m (g ++ f)"
   512 by (fastsimp simp add: map_le_def)
   513 
   514 lemma map_le_iff_map_add_commute: "(f \<subseteq>\<^sub>m f ++ g) = (f++g = g++f)"
   515 by(fastsimp simp: map_add_def map_le_def expand_fun_eq split: option.splits)
   516 
   517 lemma map_add_le_mapE: "f++g \<subseteq>\<^sub>m h \<Longrightarrow> g \<subseteq>\<^sub>m h"
   518 by (fastsimp simp add: map_le_def map_add_def dom_def)
   519 
   520 lemma map_add_le_mapI: "\<lbrakk> f \<subseteq>\<^sub>m h; g \<subseteq>\<^sub>m h; f \<subseteq>\<^sub>m f++g \<rbrakk> \<Longrightarrow> f++g \<subseteq>\<^sub>m h"
   521 by (clarsimp simp add: map_le_def map_add_def dom_def split: option.splits)
   522 
   523 end