src/Pure/PIDE/document.ML
author wenzelm
Fri Aug 19 17:39:37 2011 +0200 (2011-08-19)
changeset 44301 65f60d9ac4bf
parent 44300 349cc426d929
child 44302 0a1934c5c104
permissions -rw-r--r--
tuned signature (again);
tuned;
     1 (*  Title:      Pure/PIDE/document.ML
     2     Author:     Makarius
     3 
     4 Document as collection of named nodes, each consisting of an editable
     5 list of commands, associated with asynchronous execution process.
     6 *)
     7 
     8 signature DOCUMENT =
     9 sig
    10   type id = int
    11   type version_id = id
    12   type command_id = id
    13   type exec_id = id
    14   val no_id: id
    15   val new_id: unit -> id
    16   val parse_id: string -> id
    17   val print_id: id -> string
    18   type node_header = (string * string list * (string * bool) list) Exn.result
    19   datatype node_edit =
    20     Clear |
    21     Edits of (command_id option * command_id option) list |
    22     Header of node_header
    23   type edit = string * node_edit
    24   type state
    25   val init_state: state
    26   val join_commands: state -> unit
    27   val cancel_execution: state -> Future.task list
    28   val define_command: command_id -> string -> state -> state
    29   val edit: version_id -> version_id -> edit list -> state -> (command_id * exec_id) list * state
    30   val execute: version_id -> state -> state
    31   val state: unit -> state
    32   val change_state: (state -> state) -> unit
    33 end;
    34 
    35 structure Document: DOCUMENT =
    36 struct
    37 
    38 (* unique identifiers *)
    39 
    40 type id = int;
    41 type version_id = id;
    42 type command_id = id;
    43 type exec_id = id;
    44 
    45 val no_id = 0;
    46 val new_id = Synchronized.counter ();
    47 
    48 val parse_id = Markup.parse_int;
    49 val print_id = Markup.print_int;
    50 
    51 fun err_dup kind id = error ("Duplicate " ^ kind ^ ": " ^ print_id id);
    52 fun err_undef kind id = error ("Undefined " ^ kind ^ ": " ^ print_id id);
    53 
    54 
    55 
    56 (** document structure **)
    57 
    58 type node_header = (string * string list * (string * bool) list) Exn.result;
    59 structure Entries = Linear_Set(type key = command_id val ord = int_ord);
    60 
    61 abstype node = Node of
    62  {header: node_header,
    63   entries: exec_id option Entries.T,  (*command entries with excecutions*)
    64   result: Toplevel.state lazy}
    65 and version = Version of node Graph.T  (*development graph wrt. static imports*)
    66 with
    67 
    68 fun make_node (header, entries, result) =
    69   Node {header = header, entries = entries, result = result};
    70 
    71 fun map_node f (Node {header, entries, result}) =
    72   make_node (f (header, entries, result));
    73 
    74 fun get_header (Node {header, ...}) = header;
    75 fun set_header header = map_node (fn (_, entries, result) => (header, entries, result));
    76 
    77 fun map_entries f (Node {header, entries, result}) = make_node (header, f entries, result);
    78 fun fold_entries start f (Node {entries, ...}) = Entries.fold start f entries;
    79 fun first_entry start P (Node {entries, ...}) = Entries.get_first start P entries;
    80 
    81 fun get_theory pos (Node {result, ...}) = Toplevel.end_theory pos (Lazy.get_finished result);
    82 fun set_result result = map_node (fn (header, entries, _) => (header, entries, result));
    83 
    84 val empty_exec = Lazy.value Toplevel.toplevel;
    85 val empty_node = make_node (Exn.Exn (ERROR "Bad theory header"), Entries.empty, empty_exec);
    86 val clear_node = map_node (fn (header, _, _) => (header, Entries.empty, empty_exec));
    87 
    88 fun get_node nodes name = Graph.get_node nodes name handle Graph.UNDEF _ => empty_node;
    89 fun default_node name = Graph.default_node (name, empty_node);
    90 fun update_node name f = default_node name #> Graph.map_node name f;
    91 
    92 
    93 (* node edits and associated executions *)
    94 
    95 datatype node_edit =
    96   Clear |
    97   Edits of (command_id option * command_id option) list |
    98   Header of node_header;
    99 
   100 type edit = string * node_edit;
   101 
   102 fun the_entry (Node {entries, ...}) id =
   103   (case Entries.lookup entries id of
   104     NONE => err_undef "command entry" id
   105   | SOME entry => entry);
   106 
   107 fun update_entry (id, exec_id) =
   108   map_entries (Entries.update (id, SOME exec_id));
   109 
   110 fun reset_after id entries =
   111   (case Entries.get_after entries id of
   112     NONE => entries
   113   | SOME next => Entries.update (next, NONE) entries);
   114 
   115 val edit_node = map_entries o fold
   116   (fn (id, SOME id2) => Entries.insert_after id (id2, NONE)
   117     | (id, NONE) => Entries.delete_after id #> reset_after id);
   118 
   119 
   120 (* version operations *)
   121 
   122 val empty_version = Version Graph.empty;
   123 
   124 fun nodes_of (Version nodes) = nodes;
   125 val node_of = get_node o nodes_of;
   126 
   127 fun cycle_msg names = "Cyclic dependency of " ^ space_implode " via " (map quote names);
   128 
   129 fun touch_descendants name nodes =
   130   fold (fn desc => desc <> name ? update_node desc (map_entries (reset_after NONE)))
   131     (Graph.all_succs nodes [name]) nodes;
   132 
   133 fun edit_nodes (name, node_edit) (Version nodes) =
   134   Version
   135     (touch_descendants name
   136       (case node_edit of
   137         Clear => update_node name clear_node nodes
   138       | Edits edits =>
   139           nodes
   140           |> update_node name (edit_node edits)
   141       | Header header =>
   142           let
   143             val parents = (case header of Exn.Res (_, parents, _) => parents | _ => []);
   144             val nodes1 = nodes
   145               |> default_node name
   146               |> fold default_node parents;
   147             val nodes2 = nodes1
   148               |> fold (fn dep => Graph.del_edge (dep, name)) (Graph.imm_preds nodes1 name);
   149             val (header', nodes3) =
   150               (header, Graph.add_deps_acyclic (name, parents) nodes2)
   151                 handle Graph.CYCLES cs => (Exn.Exn (ERROR (cat_lines (map cycle_msg cs))), nodes2);
   152           in Graph.map_node name (set_header header') nodes3 end));
   153 
   154 fun put_node (name, node) (Version nodes) =
   155   Version (update_node name (K node) nodes);
   156 
   157 end;
   158 
   159 
   160 
   161 (** global state -- document structure and execution process **)
   162 
   163 abstype state = State of
   164  {versions: version Inttab.table,  (*version_id -> document content*)
   165   commands: Toplevel.transition future Inttab.table,  (*command_id -> transition (future parsing)*)
   166   execs: Toplevel.state lazy Inttab.table,  (*exec_id -> execution process*)
   167   execution: Future.group}  (*global execution process*)
   168 with
   169 
   170 fun make_state (versions, commands, execs, execution) =
   171   State {versions = versions, commands = commands, execs = execs, execution = execution};
   172 
   173 fun map_state f (State {versions, commands, execs, execution}) =
   174   make_state (f (versions, commands, execs, execution));
   175 
   176 val init_state =
   177   make_state (Inttab.make [(no_id, empty_version)],
   178     Inttab.make [(no_id, Future.value Toplevel.empty)],
   179     Inttab.make [(no_id, empty_exec)],
   180     Future.new_group NONE);
   181 
   182 
   183 (* document versions *)
   184 
   185 fun define_version (id: version_id) version =
   186   map_state (fn (versions, commands, execs, execution) =>
   187     let val versions' = Inttab.update_new (id, version) versions
   188       handle Inttab.DUP dup => err_dup "document version" dup
   189     in (versions', commands, execs, execution) end);
   190 
   191 fun the_version (State {versions, ...}) (id: version_id) =
   192   (case Inttab.lookup versions id of
   193     NONE => err_undef "document version" id
   194   | SOME version => version);
   195 
   196 
   197 (* commands *)
   198 
   199 fun define_command (id: command_id) text =
   200   map_state (fn (versions, commands, execs, execution) =>
   201     let
   202       val id_string = print_id id;
   203       val tr = Future.fork_pri 2 (fn () =>
   204         Position.setmp_thread_data (Position.id_only id_string)
   205           (fn () => Outer_Syntax.prepare_command (Position.id id_string) text) ());
   206       val commands' =
   207         Inttab.update_new (id, tr) commands
   208           handle Inttab.DUP dup => err_dup "command" dup;
   209     in (versions, commands', execs, execution) end);
   210 
   211 fun the_command (State {commands, ...}) (id: command_id) =
   212   (case Inttab.lookup commands id of
   213     NONE => err_undef "command" id
   214   | SOME tr => tr);
   215 
   216 fun join_commands (State {commands, ...}) =
   217   Inttab.fold (fn (_, tr) => fn () => ignore (Future.join_result tr)) commands ();
   218 
   219 
   220 (* command executions *)
   221 
   222 fun define_exec (exec_id, exec) =
   223   map_state (fn (versions, commands, execs, execution) =>
   224     let val execs' = Inttab.update_new (exec_id, exec) execs
   225       handle Inttab.DUP dup => err_dup "command execution" dup
   226     in (versions, commands, execs', execution) end);
   227 
   228 fun the_exec (State {execs, ...}) exec_id =
   229   (case Inttab.lookup execs exec_id of
   230     NONE => err_undef "command execution" exec_id
   231   | SOME exec => exec);
   232 
   233 
   234 (* document execution *)
   235 
   236 fun cancel_execution (State {execution, ...}) = Future.cancel_group execution;
   237 
   238 end;
   239 
   240 
   241 
   242 (* toplevel transactions *)
   243 
   244 local
   245 
   246 fun timing tr t = Toplevel.status tr (Markup.timing t);
   247 
   248 fun proof_status tr st =
   249   (case try Toplevel.proof_of st of
   250     SOME prf => Toplevel.status tr (Proof.status_markup prf)
   251   | NONE => ());
   252 
   253 fun async_state tr st =
   254   ignore
   255     (singleton
   256       (Future.forks {name = "Document.async_state",
   257         group = SOME (Future.new_group NONE),
   258         deps = [], pri = 0, interrupts = true})
   259       (fn () =>
   260         Toplevel.setmp_thread_position tr
   261           (fn () => Toplevel.print_state false st) ()));
   262 
   263 fun run int tr st =
   264   (case Toplevel.transition int tr st of
   265     SOME (st', NONE) => ([], SOME st')
   266   | SOME (_, SOME (exn, _)) =>
   267       (case ML_Compiler.exn_messages exn of
   268         [] => Exn.interrupt ()
   269       | errs => (errs, NONE))
   270   | NONE => ([(serial (), ML_Compiler.exn_message Runtime.TERMINATE)], NONE));
   271 
   272 in
   273 
   274 fun run_command tr st =
   275   let
   276     val is_init = Toplevel.is_init tr;
   277     val is_proof = Keyword.is_proof (Toplevel.name_of tr);
   278     val do_print = not is_init andalso (Toplevel.print_of tr orelse is_proof);
   279 
   280     val start = Timing.start ();
   281     val (errs, result) =
   282       if Toplevel.is_toplevel st andalso not is_init then ([], SOME st)
   283       else run (is_init orelse is_proof) (Toplevel.set_print false tr) st;
   284     val _ = timing tr (Timing.result start);
   285     val _ = List.app (Toplevel.error_msg tr) errs;
   286   in
   287     (case result of
   288       NONE => (Toplevel.status tr Markup.failed; st)
   289     | SOME st' =>
   290        (Toplevel.status tr Markup.finished;
   291         proof_status tr st';
   292         if do_print then async_state tr st' else ();
   293         st'))
   294   end;
   295 
   296 end;
   297 
   298 
   299 
   300 
   301 (** editing **)
   302 
   303 (* edit *)
   304 
   305 local
   306 
   307 fun is_changed node' ((_, id), exec) =
   308   (case try (the_entry node') id of
   309     NONE => true
   310   | SOME exec' => exec' <> exec);
   311 
   312 fun new_exec (command_id, command) (assigns, execs, exec) =
   313   let
   314     val exec_id' = new_id ();
   315     val exec' =
   316       Lazy.lazy (fn () =>
   317         let
   318           val tr = Toplevel.put_id (print_id exec_id') (Future.get_finished command);
   319           val st = Lazy.get_finished exec;
   320         in run_command tr st end);
   321   in ((command_id, exec_id') :: assigns, (exec_id', exec') :: execs, exec') end;
   322 
   323 in
   324 
   325 fun edit (old_id: version_id) (new_id: version_id) edits state =
   326   let
   327     val old_version = the_version state old_id;
   328     val _ = Time.now ();  (* FIXME odd workaround for polyml-5.4.0/x86_64 *)
   329     val new_version = fold edit_nodes edits old_version;
   330 
   331     val updates =
   332       nodes_of new_version |> Graph.schedule
   333         (fn deps => fn (name, node) =>
   334           (case first_entry NONE (is_changed (node_of old_version name)) node of
   335             NONE => Future.value (([], [], []), node)
   336           | SOME ((prev, id), _) =>
   337               let
   338                 fun init () =
   339                   let
   340                     val (thy_name, imports, uses) = Exn.release (get_header node);
   341                     (* FIXME provide files via Scala layer *)
   342                     val (dir, files) =
   343                       if ML_System.platform_is_cygwin then (Path.current, [])
   344                       else (Path.dir (Path.explode name), map (apfst Path.explode) uses);
   345 
   346                     val parents =
   347                       imports |> map (fn import =>
   348                         (case Thy_Info.lookup_theory import of
   349                           SOME thy => thy
   350                         | NONE =>
   351                             get_theory (Position.file_only import)
   352                               (#2 (Future.join (the (AList.lookup (op =) deps import))))));
   353                   in Thy_Load.begin_theory dir thy_name imports files parents end
   354                 fun get_command id =
   355                   (id, the_command state id |> Future.map (Toplevel.modify_init init));
   356               in
   357                 singleton
   358                   (Future.forks {name = "Document.edit", group = NONE,
   359                     deps = map (Future.task_of o #2) deps, pri = 2, interrupts = false})
   360                   (fn () =>
   361                     let
   362                       val prev_exec =
   363                         (case prev of
   364                           NONE => no_id
   365                         | SOME prev_id => the_default no_id (the_entry node prev_id));
   366                       val (assigns, execs, result) =
   367                         fold_entries (SOME id) (new_exec o get_command o #2 o #1)
   368                           node ([], [], the_exec state prev_exec);
   369                       val node' = node
   370                         |> fold update_entry assigns
   371                         |> set_result result;
   372                     in ((assigns, execs, [(name, node')]), node') end)
   373               end))
   374       |> Future.join_results |> Par_Exn.release_all |> map #1;
   375 
   376     val state' = state
   377       |> fold (fold define_exec o #2) updates
   378       |> define_version new_id (fold (fold put_node o #3) updates new_version);
   379 
   380   in (maps #1 (rev updates), state') end;
   381 
   382 end;
   383 
   384 
   385 (* execute *)
   386 
   387 fun execute version_id state =
   388   state |> map_state (fn (versions, commands, execs, _) =>
   389     let
   390       val version = the_version state version_id;
   391 
   392       fun force_exec NONE = ()
   393         | force_exec (SOME exec_id) = ignore (Lazy.force (the_exec state exec_id));
   394 
   395       val execution = Future.new_group NONE;
   396       val _ =
   397         nodes_of version |> Graph.schedule
   398           (fn deps => fn (name, node) =>
   399             singleton
   400               (Future.forks
   401                 {name = "theory:" ^ name, group = SOME (Future.new_group (SOME execution)),
   402                   deps = map (Future.task_of o #2) deps,
   403                   pri = 1, interrupts = true})
   404               (fold_entries NONE (fn (_, exec) => fn () => force_exec exec) node));
   405 
   406     in (versions, commands, execs, execution) end);
   407 
   408 
   409 
   410 (** global state **)
   411 
   412 val global_state = Synchronized.var "Document" init_state;
   413 
   414 fun state () = Synchronized.value global_state;
   415 val change_state = Synchronized.change global_state;
   416 
   417 end;
   418