src/HOL/Algebra/Group.thy
 author haftmann Sun Jun 23 21:16:07 2013 +0200 (2013-06-23) changeset 52435 6646bb548c6b parent 47108 2a1953f0d20d child 55415 05f5fdb8d093 permissions -rw-r--r--
migration from code_(const|type|class|instance) to code_printing and from code_module to code_identifier
1 (*  Title:      HOL/Algebra/Group.thy
2     Author:     Clemens Ballarin, started 4 February 2003
4 Based on work by Florian Kammueller, L C Paulson and Markus Wenzel.
5 *)
7 theory Group
8 imports Lattice "~~/src/HOL/Library/FuncSet"
9 begin
11 section {* Monoids and Groups *}
13 subsection {* Definitions *}
15 text {*
16   Definitions follow \cite{Jacobson:1985}.
17 *}
19 record 'a monoid =  "'a partial_object" +
20   mult    :: "['a, 'a] \<Rightarrow> 'a" (infixl "\<otimes>\<index>" 70)
21   one     :: 'a ("\<one>\<index>")
23 definition
24   m_inv :: "('a, 'b) monoid_scheme => 'a => 'a" ("inv\<index> _"  80)
25   where "inv\<^bsub>G\<^esub> x = (THE y. y \<in> carrier G & x \<otimes>\<^bsub>G\<^esub> y = \<one>\<^bsub>G\<^esub> & y \<otimes>\<^bsub>G\<^esub> x = \<one>\<^bsub>G\<^esub>)"
27 definition
28   Units :: "_ => 'a set"
29   --{*The set of invertible elements*}
30   where "Units G = {y. y \<in> carrier G & (\<exists>x \<in> carrier G. x \<otimes>\<^bsub>G\<^esub> y = \<one>\<^bsub>G\<^esub> & y \<otimes>\<^bsub>G\<^esub> x = \<one>\<^bsub>G\<^esub>)}"
32 consts
33   pow :: "[('a, 'm) monoid_scheme, 'a, 'b::semiring_1] => 'a"  (infixr "'(^')\<index>" 75)
35 overloading nat_pow == "pow :: [_, 'a, nat] => 'a"
36 begin
37   definition "nat_pow G a n = nat_rec \<one>\<^bsub>G\<^esub> (%u b. b \<otimes>\<^bsub>G\<^esub> a) n"
38 end
40 overloading int_pow == "pow :: [_, 'a, int] => 'a"
41 begin
42   definition "int_pow G a z =
43    (let p = nat_rec \<one>\<^bsub>G\<^esub> (%u b. b \<otimes>\<^bsub>G\<^esub> a)
44     in if z < 0 then inv\<^bsub>G\<^esub> (p (nat (-z))) else p (nat z))"
45 end
47 locale monoid =
48   fixes G (structure)
49   assumes m_closed [intro, simp]:
50          "\<lbrakk>x \<in> carrier G; y \<in> carrier G\<rbrakk> \<Longrightarrow> x \<otimes> y \<in> carrier G"
51       and m_assoc:
52          "\<lbrakk>x \<in> carrier G; y \<in> carrier G; z \<in> carrier G\<rbrakk>
53           \<Longrightarrow> (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)"
54       and one_closed [intro, simp]: "\<one> \<in> carrier G"
55       and l_one [simp]: "x \<in> carrier G \<Longrightarrow> \<one> \<otimes> x = x"
56       and r_one [simp]: "x \<in> carrier G \<Longrightarrow> x \<otimes> \<one> = x"
58 lemma monoidI:
59   fixes G (structure)
60   assumes m_closed:
61       "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==> x \<otimes> y \<in> carrier G"
62     and one_closed: "\<one> \<in> carrier G"
63     and m_assoc:
64       "!!x y z. [| x \<in> carrier G; y \<in> carrier G; z \<in> carrier G |] ==>
65       (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)"
66     and l_one: "!!x. x \<in> carrier G ==> \<one> \<otimes> x = x"
67     and r_one: "!!x. x \<in> carrier G ==> x \<otimes> \<one> = x"
68   shows "monoid G"
69   by (fast intro!: monoid.intro intro: assms)
71 lemma (in monoid) Units_closed [dest]:
72   "x \<in> Units G ==> x \<in> carrier G"
73   by (unfold Units_def) fast
75 lemma (in monoid) inv_unique:
76   assumes eq: "y \<otimes> x = \<one>"  "x \<otimes> y' = \<one>"
77     and G: "x \<in> carrier G"  "y \<in> carrier G"  "y' \<in> carrier G"
78   shows "y = y'"
79 proof -
80   from G eq have "y = y \<otimes> (x \<otimes> y')" by simp
81   also from G have "... = (y \<otimes> x) \<otimes> y'" by (simp add: m_assoc)
82   also from G eq have "... = y'" by simp
83   finally show ?thesis .
84 qed
86 lemma (in monoid) Units_m_closed [intro, simp]:
87   assumes x: "x \<in> Units G" and y: "y \<in> Units G"
88   shows "x \<otimes> y \<in> Units G"
89 proof -
90   from x obtain x' where x: "x \<in> carrier G" "x' \<in> carrier G" and xinv: "x \<otimes> x' = \<one>" "x' \<otimes> x = \<one>"
91     unfolding Units_def by fast
92   from y obtain y' where y: "y \<in> carrier G" "y' \<in> carrier G" and yinv: "y \<otimes> y' = \<one>" "y' \<otimes> y = \<one>"
93     unfolding Units_def by fast
94   from x y xinv yinv have "y' \<otimes> (x' \<otimes> x) \<otimes> y = \<one>" by simp
95   moreover from x y xinv yinv have "x \<otimes> (y \<otimes> y') \<otimes> x' = \<one>" by simp
96   moreover note x y
97   ultimately show ?thesis unfolding Units_def
98     -- "Must avoid premature use of @{text hyp_subst_tac}."
99     apply (rule_tac CollectI)
100     apply (rule)
101     apply (fast)
102     apply (rule bexI [where x = "y' \<otimes> x'"])
103     apply (auto simp: m_assoc)
104     done
105 qed
107 lemma (in monoid) Units_one_closed [intro, simp]:
108   "\<one> \<in> Units G"
109   by (unfold Units_def) auto
111 lemma (in monoid) Units_inv_closed [intro, simp]:
112   "x \<in> Units G ==> inv x \<in> carrier G"
113   apply (unfold Units_def m_inv_def, auto)
114   apply (rule theI2, fast)
115    apply (fast intro: inv_unique, fast)
116   done
118 lemma (in monoid) Units_l_inv_ex:
119   "x \<in> Units G ==> \<exists>y \<in> carrier G. y \<otimes> x = \<one>"
120   by (unfold Units_def) auto
122 lemma (in monoid) Units_r_inv_ex:
123   "x \<in> Units G ==> \<exists>y \<in> carrier G. x \<otimes> y = \<one>"
124   by (unfold Units_def) auto
126 lemma (in monoid) Units_l_inv [simp]:
127   "x \<in> Units G ==> inv x \<otimes> x = \<one>"
128   apply (unfold Units_def m_inv_def, auto)
129   apply (rule theI2, fast)
130    apply (fast intro: inv_unique, fast)
131   done
133 lemma (in monoid) Units_r_inv [simp]:
134   "x \<in> Units G ==> x \<otimes> inv x = \<one>"
135   apply (unfold Units_def m_inv_def, auto)
136   apply (rule theI2, fast)
137    apply (fast intro: inv_unique, fast)
138   done
140 lemma (in monoid) Units_inv_Units [intro, simp]:
141   "x \<in> Units G ==> inv x \<in> Units G"
142 proof -
143   assume x: "x \<in> Units G"
144   show "inv x \<in> Units G"
145     by (auto simp add: Units_def
146       intro: Units_l_inv Units_r_inv x Units_closed [OF x])
147 qed
149 lemma (in monoid) Units_l_cancel [simp]:
150   "[| x \<in> Units G; y \<in> carrier G; z \<in> carrier G |] ==>
151    (x \<otimes> y = x \<otimes> z) = (y = z)"
152 proof
153   assume eq: "x \<otimes> y = x \<otimes> z"
154     and G: "x \<in> Units G"  "y \<in> carrier G"  "z \<in> carrier G"
155   then have "(inv x \<otimes> x) \<otimes> y = (inv x \<otimes> x) \<otimes> z"
156     by (simp add: m_assoc Units_closed del: Units_l_inv)
157   with G show "y = z" by simp
158 next
159   assume eq: "y = z"
160     and G: "x \<in> Units G"  "y \<in> carrier G"  "z \<in> carrier G"
161   then show "x \<otimes> y = x \<otimes> z" by simp
162 qed
164 lemma (in monoid) Units_inv_inv [simp]:
165   "x \<in> Units G ==> inv (inv x) = x"
166 proof -
167   assume x: "x \<in> Units G"
168   then have "inv x \<otimes> inv (inv x) = inv x \<otimes> x" by simp
169   with x show ?thesis by (simp add: Units_closed del: Units_l_inv Units_r_inv)
170 qed
172 lemma (in monoid) inv_inj_on_Units:
173   "inj_on (m_inv G) (Units G)"
174 proof (rule inj_onI)
175   fix x y
176   assume G: "x \<in> Units G"  "y \<in> Units G" and eq: "inv x = inv y"
177   then have "inv (inv x) = inv (inv y)" by simp
178   with G show "x = y" by simp
179 qed
181 lemma (in monoid) Units_inv_comm:
182   assumes inv: "x \<otimes> y = \<one>"
183     and G: "x \<in> Units G"  "y \<in> Units G"
184   shows "y \<otimes> x = \<one>"
185 proof -
186   from G have "x \<otimes> y \<otimes> x = x \<otimes> \<one>" by (auto simp add: inv Units_closed)
187   with G show ?thesis by (simp del: r_one add: m_assoc Units_closed)
188 qed
190 text {* Power *}
192 lemma (in monoid) nat_pow_closed [intro, simp]:
193   "x \<in> carrier G ==> x (^) (n::nat) \<in> carrier G"
194   by (induct n) (simp_all add: nat_pow_def)
196 lemma (in monoid) nat_pow_0 [simp]:
197   "x (^) (0::nat) = \<one>"
198   by (simp add: nat_pow_def)
200 lemma (in monoid) nat_pow_Suc [simp]:
201   "x (^) (Suc n) = x (^) n \<otimes> x"
202   by (simp add: nat_pow_def)
204 lemma (in monoid) nat_pow_one [simp]:
205   "\<one> (^) (n::nat) = \<one>"
206   by (induct n) simp_all
208 lemma (in monoid) nat_pow_mult:
209   "x \<in> carrier G ==> x (^) (n::nat) \<otimes> x (^) m = x (^) (n + m)"
210   by (induct m) (simp_all add: m_assoc [THEN sym])
212 lemma (in monoid) nat_pow_pow:
213   "x \<in> carrier G ==> (x (^) n) (^) m = x (^) (n * m::nat)"
214   by (induct m) (simp, simp add: nat_pow_mult add_commute)
217 (* Jacobson defines submonoid here. *)
218 (* Jacobson defines the order of a monoid here. *)
221 subsection {* Groups *}
223 text {*
224   A group is a monoid all of whose elements are invertible.
225 *}
227 locale group = monoid +
228   assumes Units: "carrier G <= Units G"
230 lemma (in group) is_group: "group G" by (rule group_axioms)
232 theorem groupI:
233   fixes G (structure)
234   assumes m_closed [simp]:
235       "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==> x \<otimes> y \<in> carrier G"
236     and one_closed [simp]: "\<one> \<in> carrier G"
237     and m_assoc:
238       "!!x y z. [| x \<in> carrier G; y \<in> carrier G; z \<in> carrier G |] ==>
239       (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)"
240     and l_one [simp]: "!!x. x \<in> carrier G ==> \<one> \<otimes> x = x"
241     and l_inv_ex: "!!x. x \<in> carrier G ==> \<exists>y \<in> carrier G. y \<otimes> x = \<one>"
242   shows "group G"
243 proof -
244   have l_cancel [simp]:
245     "!!x y z. [| x \<in> carrier G; y \<in> carrier G; z \<in> carrier G |] ==>
246     (x \<otimes> y = x \<otimes> z) = (y = z)"
247   proof
248     fix x y z
249     assume eq: "x \<otimes> y = x \<otimes> z"
250       and G: "x \<in> carrier G"  "y \<in> carrier G"  "z \<in> carrier G"
251     with l_inv_ex obtain x_inv where xG: "x_inv \<in> carrier G"
252       and l_inv: "x_inv \<otimes> x = \<one>" by fast
253     from G eq xG have "(x_inv \<otimes> x) \<otimes> y = (x_inv \<otimes> x) \<otimes> z"
254       by (simp add: m_assoc)
255     with G show "y = z" by (simp add: l_inv)
256   next
257     fix x y z
258     assume eq: "y = z"
259       and G: "x \<in> carrier G"  "y \<in> carrier G"  "z \<in> carrier G"
260     then show "x \<otimes> y = x \<otimes> z" by simp
261   qed
262   have r_one:
263     "!!x. x \<in> carrier G ==> x \<otimes> \<one> = x"
264   proof -
265     fix x
266     assume x: "x \<in> carrier G"
267     with l_inv_ex obtain x_inv where xG: "x_inv \<in> carrier G"
268       and l_inv: "x_inv \<otimes> x = \<one>" by fast
269     from x xG have "x_inv \<otimes> (x \<otimes> \<one>) = x_inv \<otimes> x"
270       by (simp add: m_assoc [symmetric] l_inv)
271     with x xG show "x \<otimes> \<one> = x" by simp
272   qed
273   have inv_ex:
274     "!!x. x \<in> carrier G ==> \<exists>y \<in> carrier G. y \<otimes> x = \<one> & x \<otimes> y = \<one>"
275   proof -
276     fix x
277     assume x: "x \<in> carrier G"
278     with l_inv_ex obtain y where y: "y \<in> carrier G"
279       and l_inv: "y \<otimes> x = \<one>" by fast
280     from x y have "y \<otimes> (x \<otimes> y) = y \<otimes> \<one>"
281       by (simp add: m_assoc [symmetric] l_inv r_one)
282     with x y have r_inv: "x \<otimes> y = \<one>"
283       by simp
284     from x y show "\<exists>y \<in> carrier G. y \<otimes> x = \<one> & x \<otimes> y = \<one>"
285       by (fast intro: l_inv r_inv)
286   qed
287   then have carrier_subset_Units: "carrier G <= Units G"
288     by (unfold Units_def) fast
289   show ?thesis by default (auto simp: r_one m_assoc carrier_subset_Units)
290 qed
292 lemma (in monoid) group_l_invI:
293   assumes l_inv_ex:
294     "!!x. x \<in> carrier G ==> \<exists>y \<in> carrier G. y \<otimes> x = \<one>"
295   shows "group G"
296   by (rule groupI) (auto intro: m_assoc l_inv_ex)
298 lemma (in group) Units_eq [simp]:
299   "Units G = carrier G"
300 proof
301   show "Units G <= carrier G" by fast
302 next
303   show "carrier G <= Units G" by (rule Units)
304 qed
306 lemma (in group) inv_closed [intro, simp]:
307   "x \<in> carrier G ==> inv x \<in> carrier G"
308   using Units_inv_closed by simp
310 lemma (in group) l_inv_ex [simp]:
311   "x \<in> carrier G ==> \<exists>y \<in> carrier G. y \<otimes> x = \<one>"
312   using Units_l_inv_ex by simp
314 lemma (in group) r_inv_ex [simp]:
315   "x \<in> carrier G ==> \<exists>y \<in> carrier G. x \<otimes> y = \<one>"
316   using Units_r_inv_ex by simp
318 lemma (in group) l_inv [simp]:
319   "x \<in> carrier G ==> inv x \<otimes> x = \<one>"
320   using Units_l_inv by simp
323 subsection {* Cancellation Laws and Basic Properties *}
325 lemma (in group) l_cancel [simp]:
326   "[| x \<in> carrier G; y \<in> carrier G; z \<in> carrier G |] ==>
327    (x \<otimes> y = x \<otimes> z) = (y = z)"
328   using Units_l_inv by simp
330 lemma (in group) r_inv [simp]:
331   "x \<in> carrier G ==> x \<otimes> inv x = \<one>"
332 proof -
333   assume x: "x \<in> carrier G"
334   then have "inv x \<otimes> (x \<otimes> inv x) = inv x \<otimes> \<one>"
335     by (simp add: m_assoc [symmetric])
336   with x show ?thesis by (simp del: r_one)
337 qed
339 lemma (in group) r_cancel [simp]:
340   "[| x \<in> carrier G; y \<in> carrier G; z \<in> carrier G |] ==>
341    (y \<otimes> x = z \<otimes> x) = (y = z)"
342 proof
343   assume eq: "y \<otimes> x = z \<otimes> x"
344     and G: "x \<in> carrier G"  "y \<in> carrier G"  "z \<in> carrier G"
345   then have "y \<otimes> (x \<otimes> inv x) = z \<otimes> (x \<otimes> inv x)"
346     by (simp add: m_assoc [symmetric] del: r_inv Units_r_inv)
347   with G show "y = z" by simp
348 next
349   assume eq: "y = z"
350     and G: "x \<in> carrier G"  "y \<in> carrier G"  "z \<in> carrier G"
351   then show "y \<otimes> x = z \<otimes> x" by simp
352 qed
354 lemma (in group) inv_one [simp]:
355   "inv \<one> = \<one>"
356 proof -
357   have "inv \<one> = \<one> \<otimes> (inv \<one>)" by (simp del: r_inv Units_r_inv)
358   moreover have "... = \<one>" by simp
359   finally show ?thesis .
360 qed
362 lemma (in group) inv_inv [simp]:
363   "x \<in> carrier G ==> inv (inv x) = x"
364   using Units_inv_inv by simp
366 lemma (in group) inv_inj:
367   "inj_on (m_inv G) (carrier G)"
368   using inv_inj_on_Units by simp
370 lemma (in group) inv_mult_group:
371   "[| x \<in> carrier G; y \<in> carrier G |] ==> inv (x \<otimes> y) = inv y \<otimes> inv x"
372 proof -
373   assume G: "x \<in> carrier G"  "y \<in> carrier G"
374   then have "inv (x \<otimes> y) \<otimes> (x \<otimes> y) = (inv y \<otimes> inv x) \<otimes> (x \<otimes> y)"
375     by (simp add: m_assoc) (simp add: m_assoc [symmetric])
376   with G show ?thesis by (simp del: l_inv Units_l_inv)
377 qed
379 lemma (in group) inv_comm:
380   "[| x \<otimes> y = \<one>; x \<in> carrier G; y \<in> carrier G |] ==> y \<otimes> x = \<one>"
381   by (rule Units_inv_comm) auto
383 lemma (in group) inv_equality:
384      "[|y \<otimes> x = \<one>; x \<in> carrier G; y \<in> carrier G|] ==> inv x = y"
385 apply (simp add: m_inv_def)
386 apply (rule the_equality)
387  apply (simp add: inv_comm [of y x])
388 apply (rule r_cancel [THEN iffD1], auto)
389 done
391 text {* Power *}
393 lemma (in group) int_pow_def2:
394   "a (^) (z::int) = (if z < 0 then inv (a (^) (nat (-z))) else a (^) (nat z))"
395   by (simp add: int_pow_def nat_pow_def Let_def)
397 lemma (in group) int_pow_0 [simp]:
398   "x (^) (0::int) = \<one>"
399   by (simp add: int_pow_def2)
401 lemma (in group) int_pow_one [simp]:
402   "\<one> (^) (z::int) = \<one>"
403   by (simp add: int_pow_def2)
406 subsection {* Subgroups *}
408 locale subgroup =
409   fixes H and G (structure)
410   assumes subset: "H \<subseteq> carrier G"
411     and m_closed [intro, simp]: "\<lbrakk>x \<in> H; y \<in> H\<rbrakk> \<Longrightarrow> x \<otimes> y \<in> H"
412     and one_closed [simp]: "\<one> \<in> H"
413     and m_inv_closed [intro,simp]: "x \<in> H \<Longrightarrow> inv x \<in> H"
415 lemma (in subgroup) is_subgroup:
416   "subgroup H G" by (rule subgroup_axioms)
418 declare (in subgroup) group.intro [intro]
420 lemma (in subgroup) mem_carrier [simp]:
421   "x \<in> H \<Longrightarrow> x \<in> carrier G"
422   using subset by blast
424 lemma subgroup_imp_subset:
425   "subgroup H G \<Longrightarrow> H \<subseteq> carrier G"
426   by (rule subgroup.subset)
428 lemma (in subgroup) subgroup_is_group [intro]:
429   assumes "group G"
430   shows "group (G\<lparr>carrier := H\<rparr>)"
431 proof -
432   interpret group G by fact
433   show ?thesis
434     apply (rule monoid.group_l_invI)
435     apply (unfold_locales) 
436     apply (auto intro: m_assoc l_inv mem_carrier)
437     done
438 qed
440 text {*
441   Since @{term H} is nonempty, it contains some element @{term x}.  Since
442   it is closed under inverse, it contains @{text "inv x"}.  Since
443   it is closed under product, it contains @{text "x \<otimes> inv x = \<one>"}.
444 *}
446 lemma (in group) one_in_subset:
447   "[| H \<subseteq> carrier G; H \<noteq> {}; \<forall>a \<in> H. inv a \<in> H; \<forall>a\<in>H. \<forall>b\<in>H. a \<otimes> b \<in> H |]
448    ==> \<one> \<in> H"
449 by force
451 text {* A characterization of subgroups: closed, non-empty subset. *}
453 lemma (in group) subgroupI:
454   assumes subset: "H \<subseteq> carrier G" and non_empty: "H \<noteq> {}"
455     and inv: "!!a. a \<in> H \<Longrightarrow> inv a \<in> H"
456     and mult: "!!a b. \<lbrakk>a \<in> H; b \<in> H\<rbrakk> \<Longrightarrow> a \<otimes> b \<in> H"
457   shows "subgroup H G"
458 proof (simp add: subgroup_def assms)
459   show "\<one> \<in> H" by (rule one_in_subset) (auto simp only: assms)
460 qed
462 declare monoid.one_closed [iff] group.inv_closed [simp]
463   monoid.l_one [simp] monoid.r_one [simp] group.inv_inv [simp]
465 lemma subgroup_nonempty:
466   "~ subgroup {} G"
467   by (blast dest: subgroup.one_closed)
469 lemma (in subgroup) finite_imp_card_positive:
470   "finite (carrier G) ==> 0 < card H"
471 proof (rule classical)
472   assume "finite (carrier G)" and a: "~ 0 < card H"
473   then have "finite H" by (blast intro: finite_subset [OF subset])
474   with is_subgroup a have "subgroup {} G" by simp
475   with subgroup_nonempty show ?thesis by contradiction
476 qed
478 (*
479 lemma (in monoid) Units_subgroup:
480   "subgroup (Units G) G"
481 *)
484 subsection {* Direct Products *}
486 definition
487   DirProd :: "_ \<Rightarrow> _ \<Rightarrow> ('a \<times> 'b) monoid" (infixr "\<times>\<times>" 80) where
488   "G \<times>\<times> H =
489     \<lparr>carrier = carrier G \<times> carrier H,
490      mult = (\<lambda>(g, h) (g', h'). (g \<otimes>\<^bsub>G\<^esub> g', h \<otimes>\<^bsub>H\<^esub> h')),
491      one = (\<one>\<^bsub>G\<^esub>, \<one>\<^bsub>H\<^esub>)\<rparr>"
493 lemma DirProd_monoid:
494   assumes "monoid G" and "monoid H"
495   shows "monoid (G \<times>\<times> H)"
496 proof -
497   interpret G: monoid G by fact
498   interpret H: monoid H by fact
499   from assms
500   show ?thesis by (unfold monoid_def DirProd_def, auto)
501 qed
504 text{*Does not use the previous result because it's easier just to use auto.*}
505 lemma DirProd_group:
506   assumes "group G" and "group H"
507   shows "group (G \<times>\<times> H)"
508 proof -
509   interpret G: group G by fact
510   interpret H: group H by fact
511   show ?thesis by (rule groupI)
512      (auto intro: G.m_assoc H.m_assoc G.l_inv H.l_inv
513            simp add: DirProd_def)
514 qed
516 lemma carrier_DirProd [simp]:
517      "carrier (G \<times>\<times> H) = carrier G \<times> carrier H"
518   by (simp add: DirProd_def)
520 lemma one_DirProd [simp]:
521      "\<one>\<^bsub>G \<times>\<times> H\<^esub> = (\<one>\<^bsub>G\<^esub>, \<one>\<^bsub>H\<^esub>)"
522   by (simp add: DirProd_def)
524 lemma mult_DirProd [simp]:
525      "(g, h) \<otimes>\<^bsub>(G \<times>\<times> H)\<^esub> (g', h') = (g \<otimes>\<^bsub>G\<^esub> g', h \<otimes>\<^bsub>H\<^esub> h')"
526   by (simp add: DirProd_def)
528 lemma inv_DirProd [simp]:
529   assumes "group G" and "group H"
530   assumes g: "g \<in> carrier G"
531       and h: "h \<in> carrier H"
532   shows "m_inv (G \<times>\<times> H) (g, h) = (inv\<^bsub>G\<^esub> g, inv\<^bsub>H\<^esub> h)"
533 proof -
534   interpret G: group G by fact
535   interpret H: group H by fact
536   interpret Prod: group "G \<times>\<times> H"
537     by (auto intro: DirProd_group group.intro group.axioms assms)
538   show ?thesis by (simp add: Prod.inv_equality g h)
539 qed
542 subsection {* Homomorphisms and Isomorphisms *}
544 definition
545   hom :: "_ => _ => ('a => 'b) set" where
546   "hom G H =
547     {h. h \<in> carrier G -> carrier H &
548       (\<forall>x \<in> carrier G. \<forall>y \<in> carrier G. h (x \<otimes>\<^bsub>G\<^esub> y) = h x \<otimes>\<^bsub>H\<^esub> h y)}"
550 lemma (in group) hom_compose:
551   "[|h \<in> hom G H; i \<in> hom H I|] ==> compose (carrier G) i h \<in> hom G I"
552 by (fastforce simp add: hom_def compose_def)
554 definition
555   iso :: "_ => _ => ('a => 'b) set" (infixr "\<cong>" 60)
556   where "G \<cong> H = {h. h \<in> hom G H & bij_betw h (carrier G) (carrier H)}"
558 lemma iso_refl: "(%x. x) \<in> G \<cong> G"
559 by (simp add: iso_def hom_def inj_on_def bij_betw_def Pi_def)
561 lemma (in group) iso_sym:
562      "h \<in> G \<cong> H \<Longrightarrow> inv_into (carrier G) h \<in> H \<cong> G"
563 apply (simp add: iso_def bij_betw_inv_into)
564 apply (subgoal_tac "inv_into (carrier G) h \<in> carrier H \<rightarrow> carrier G")
565  prefer 2 apply (simp add: bij_betw_imp_funcset [OF bij_betw_inv_into])
566 apply (simp add: hom_def bij_betw_def inv_into_f_eq f_inv_into_f Pi_def)
567 done
569 lemma (in group) iso_trans:
570      "[|h \<in> G \<cong> H; i \<in> H \<cong> I|] ==> (compose (carrier G) i h) \<in> G \<cong> I"
571 by (auto simp add: iso_def hom_compose bij_betw_compose)
573 lemma DirProd_commute_iso:
574   shows "(\<lambda>(x,y). (y,x)) \<in> (G \<times>\<times> H) \<cong> (H \<times>\<times> G)"
575 by (auto simp add: iso_def hom_def inj_on_def bij_betw_def)
577 lemma DirProd_assoc_iso:
578   shows "(\<lambda>(x,y,z). (x,(y,z))) \<in> (G \<times>\<times> H \<times>\<times> I) \<cong> (G \<times>\<times> (H \<times>\<times> I))"
579 by (auto simp add: iso_def hom_def inj_on_def bij_betw_def)
582 text{*Basis for homomorphism proofs: we assume two groups @{term G} and
583   @{term H}, with a homomorphism @{term h} between them*}
584 locale group_hom = G: group G + H: group H for G (structure) and H (structure) +
585   fixes h
586   assumes homh: "h \<in> hom G H"
588 lemma (in group_hom) hom_mult [simp]:
589   "[| x \<in> carrier G; y \<in> carrier G |] ==> h (x \<otimes>\<^bsub>G\<^esub> y) = h x \<otimes>\<^bsub>H\<^esub> h y"
590 proof -
591   assume "x \<in> carrier G" "y \<in> carrier G"
592   with homh [unfolded hom_def] show ?thesis by simp
593 qed
595 lemma (in group_hom) hom_closed [simp]:
596   "x \<in> carrier G ==> h x \<in> carrier H"
597 proof -
598   assume "x \<in> carrier G"
599   with homh [unfolded hom_def] show ?thesis by auto
600 qed
602 lemma (in group_hom) one_closed [simp]:
603   "h \<one> \<in> carrier H"
604   by simp
606 lemma (in group_hom) hom_one [simp]:
607   "h \<one> = \<one>\<^bsub>H\<^esub>"
608 proof -
609   have "h \<one> \<otimes>\<^bsub>H\<^esub> \<one>\<^bsub>H\<^esub> = h \<one> \<otimes>\<^bsub>H\<^esub> h \<one>"
610     by (simp add: hom_mult [symmetric] del: hom_mult)
611   then show ?thesis by (simp del: r_one)
612 qed
614 lemma (in group_hom) inv_closed [simp]:
615   "x \<in> carrier G ==> h (inv x) \<in> carrier H"
616   by simp
618 lemma (in group_hom) hom_inv [simp]:
619   "x \<in> carrier G ==> h (inv x) = inv\<^bsub>H\<^esub> (h x)"
620 proof -
621   assume x: "x \<in> carrier G"
622   then have "h x \<otimes>\<^bsub>H\<^esub> h (inv x) = \<one>\<^bsub>H\<^esub>"
623     by (simp add: hom_mult [symmetric] del: hom_mult)
624   also from x have "... = h x \<otimes>\<^bsub>H\<^esub> inv\<^bsub>H\<^esub> (h x)"
625     by (simp add: hom_mult [symmetric] del: hom_mult)
626   finally have "h x \<otimes>\<^bsub>H\<^esub> h (inv x) = h x \<otimes>\<^bsub>H\<^esub> inv\<^bsub>H\<^esub> (h x)" .
627   with x show ?thesis by (simp del: H.r_inv H.Units_r_inv)
628 qed
631 subsection {* Commutative Structures *}
633 text {*
634   Naming convention: multiplicative structures that are commutative
635   are called \emph{commutative}, additive structures are called
636   \emph{Abelian}.
637 *}
639 locale comm_monoid = monoid +
640   assumes m_comm: "\<lbrakk>x \<in> carrier G; y \<in> carrier G\<rbrakk> \<Longrightarrow> x \<otimes> y = y \<otimes> x"
642 lemma (in comm_monoid) m_lcomm:
643   "\<lbrakk>x \<in> carrier G; y \<in> carrier G; z \<in> carrier G\<rbrakk> \<Longrightarrow>
644    x \<otimes> (y \<otimes> z) = y \<otimes> (x \<otimes> z)"
645 proof -
646   assume xyz: "x \<in> carrier G"  "y \<in> carrier G"  "z \<in> carrier G"
647   from xyz have "x \<otimes> (y \<otimes> z) = (x \<otimes> y) \<otimes> z" by (simp add: m_assoc)
648   also from xyz have "... = (y \<otimes> x) \<otimes> z" by (simp add: m_comm)
649   also from xyz have "... = y \<otimes> (x \<otimes> z)" by (simp add: m_assoc)
650   finally show ?thesis .
651 qed
653 lemmas (in comm_monoid) m_ac = m_assoc m_comm m_lcomm
655 lemma comm_monoidI:
656   fixes G (structure)
657   assumes m_closed:
658       "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==> x \<otimes> y \<in> carrier G"
659     and one_closed: "\<one> \<in> carrier G"
660     and m_assoc:
661       "!!x y z. [| x \<in> carrier G; y \<in> carrier G; z \<in> carrier G |] ==>
662       (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)"
663     and l_one: "!!x. x \<in> carrier G ==> \<one> \<otimes> x = x"
664     and m_comm:
665       "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==> x \<otimes> y = y \<otimes> x"
666   shows "comm_monoid G"
667   using l_one
668     by (auto intro!: comm_monoid.intro comm_monoid_axioms.intro monoid.intro
669              intro: assms simp: m_closed one_closed m_comm)
671 lemma (in monoid) monoid_comm_monoidI:
672   assumes m_comm:
673       "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==> x \<otimes> y = y \<otimes> x"
674   shows "comm_monoid G"
675   by (rule comm_monoidI) (auto intro: m_assoc m_comm)
677 (*lemma (in comm_monoid) r_one [simp]:
678   "x \<in> carrier G ==> x \<otimes> \<one> = x"
679 proof -
680   assume G: "x \<in> carrier G"
681   then have "x \<otimes> \<one> = \<one> \<otimes> x" by (simp add: m_comm)
682   also from G have "... = x" by simp
683   finally show ?thesis .
684 qed*)
686 lemma (in comm_monoid) nat_pow_distr:
687   "[| x \<in> carrier G; y \<in> carrier G |] ==>
688   (x \<otimes> y) (^) (n::nat) = x (^) n \<otimes> y (^) n"
689   by (induct n) (simp, simp add: m_ac)
691 locale comm_group = comm_monoid + group
693 lemma (in group) group_comm_groupI:
694   assumes m_comm: "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==>
695       x \<otimes> y = y \<otimes> x"
696   shows "comm_group G"
697   by default (simp_all add: m_comm)
699 lemma comm_groupI:
700   fixes G (structure)
701   assumes m_closed:
702       "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==> x \<otimes> y \<in> carrier G"
703     and one_closed: "\<one> \<in> carrier G"
704     and m_assoc:
705       "!!x y z. [| x \<in> carrier G; y \<in> carrier G; z \<in> carrier G |] ==>
706       (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)"
707     and m_comm:
708       "!!x y. [| x \<in> carrier G; y \<in> carrier G |] ==> x \<otimes> y = y \<otimes> x"
709     and l_one: "!!x. x \<in> carrier G ==> \<one> \<otimes> x = x"
710     and l_inv_ex: "!!x. x \<in> carrier G ==> \<exists>y \<in> carrier G. y \<otimes> x = \<one>"
711   shows "comm_group G"
712   by (fast intro: group.group_comm_groupI groupI assms)
714 lemma (in comm_group) inv_mult:
715   "[| x \<in> carrier G; y \<in> carrier G |] ==> inv (x \<otimes> y) = inv x \<otimes> inv y"
716   by (simp add: m_ac inv_mult_group)
719 subsection {* The Lattice of Subgroups of a Group *}
721 text_raw {* \label{sec:subgroup-lattice} *}
723 theorem (in group) subgroups_partial_order:
724   "partial_order (| carrier = {H. subgroup H G}, eq = op =, le = op \<subseteq> |)"
725   by default simp_all
727 lemma (in group) subgroup_self:
728   "subgroup (carrier G) G"
729   by (rule subgroupI) auto
731 lemma (in group) subgroup_imp_group:
732   "subgroup H G ==> group (G(| carrier := H |))"
733   by (erule subgroup.subgroup_is_group) (rule group_axioms)
735 lemma (in group) is_monoid [intro, simp]:
736   "monoid G"
737   by (auto intro: monoid.intro m_assoc)
739 lemma (in group) subgroup_inv_equality:
740   "[| subgroup H G; x \<in> H |] ==> m_inv (G (| carrier := H |)) x = inv x"
741 apply (rule_tac inv_equality [THEN sym])
742   apply (rule group.l_inv [OF subgroup_imp_group, simplified], assumption+)
743  apply (rule subsetD [OF subgroup.subset], assumption+)
744 apply (rule subsetD [OF subgroup.subset], assumption)
745 apply (rule_tac group.inv_closed [OF subgroup_imp_group, simplified], assumption+)
746 done
748 theorem (in group) subgroups_Inter:
749   assumes subgr: "(!!H. H \<in> A ==> subgroup H G)"
750     and not_empty: "A ~= {}"
751   shows "subgroup (\<Inter>A) G"
752 proof (rule subgroupI)
753   from subgr [THEN subgroup.subset] and not_empty
754   show "\<Inter>A \<subseteq> carrier G" by blast
755 next
756   from subgr [THEN subgroup.one_closed]
757   show "\<Inter>A ~= {}" by blast
758 next
759   fix x assume "x \<in> \<Inter>A"
760   with subgr [THEN subgroup.m_inv_closed]
761   show "inv x \<in> \<Inter>A" by blast
762 next
763   fix x y assume "x \<in> \<Inter>A" "y \<in> \<Inter>A"
764   with subgr [THEN subgroup.m_closed]
765   show "x \<otimes> y \<in> \<Inter>A" by blast
766 qed
768 theorem (in group) subgroups_complete_lattice:
769   "complete_lattice (| carrier = {H. subgroup H G}, eq = op =, le = op \<subseteq> |)"
770     (is "complete_lattice ?L")
771 proof (rule partial_order.complete_lattice_criterion1)
772   show "partial_order ?L" by (rule subgroups_partial_order)
773 next
774   have "greatest ?L (carrier G) (carrier ?L)"
775     by (unfold greatest_def) (simp add: subgroup.subset subgroup_self)
776   then show "\<exists>G. greatest ?L G (carrier ?L)" ..
777 next
778   fix A
779   assume L: "A \<subseteq> carrier ?L" and non_empty: "A ~= {}"
780   then have Int_subgroup: "subgroup (\<Inter>A) G"
781     by (fastforce intro: subgroups_Inter)
782   have "greatest ?L (\<Inter>A) (Lower ?L A)" (is "greatest _ ?Int _")
783   proof (rule greatest_LowerI)
784     fix H
785     assume H: "H \<in> A"
786     with L have subgroupH: "subgroup H G" by auto
787     from subgroupH have groupH: "group (G (| carrier := H |))" (is "group ?H")
788       by (rule subgroup_imp_group)
789     from groupH have monoidH: "monoid ?H"
790       by (rule group.is_monoid)
791     from H have Int_subset: "?Int \<subseteq> H" by fastforce
792     then show "le ?L ?Int H" by simp
793   next
794     fix H
795     assume H: "H \<in> Lower ?L A"
796     with L Int_subgroup show "le ?L H ?Int"
797       by (fastforce simp: Lower_def intro: Inter_greatest)
798   next
799     show "A \<subseteq> carrier ?L" by (rule L)
800   next
801     show "?Int \<in> carrier ?L" by simp (rule Int_subgroup)
802   qed
803   then show "\<exists>I. greatest ?L I (Lower ?L A)" ..
804 qed
806 end