src/HOL/FunDef.thy
author haftmann
Sun Jun 23 21:16:07 2013 +0200 (2013-06-23)
changeset 52435 6646bb548c6b
parent 49989 34d0ac1bdac6
child 53603 59ef06cda7b9
permissions -rw-r--r--
migration from code_(const|type|class|instance) to code_printing and from code_module to code_identifier
     1 (*  Title:      HOL/FunDef.thy
     2     Author:     Alexander Krauss, TU Muenchen
     3 *)
     4 
     5 header {* Function Definitions and Termination Proofs *}
     6 
     7 theory FunDef
     8 imports Partial_Function SAT Wellfounded
     9 keywords "function" "termination" :: thy_goal and "fun" :: thy_decl
    10 begin
    11 
    12 subsection {* Definitions with default value. *}
    13 
    14 definition
    15   THE_default :: "'a \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> 'a" where
    16   "THE_default d P = (if (\<exists>!x. P x) then (THE x. P x) else d)"
    17 
    18 lemma THE_defaultI': "\<exists>!x. P x \<Longrightarrow> P (THE_default d P)"
    19   by (simp add: theI' THE_default_def)
    20 
    21 lemma THE_default1_equality:
    22     "\<lbrakk>\<exists>!x. P x; P a\<rbrakk> \<Longrightarrow> THE_default d P = a"
    23   by (simp add: the1_equality THE_default_def)
    24 
    25 lemma THE_default_none:
    26     "\<not>(\<exists>!x. P x) \<Longrightarrow> THE_default d P = d"
    27   by (simp add:THE_default_def)
    28 
    29 
    30 lemma fundef_ex1_existence:
    31   assumes f_def: "f == (\<lambda>x::'a. THE_default (d x) (\<lambda>y. G x y))"
    32   assumes ex1: "\<exists>!y. G x y"
    33   shows "G x (f x)"
    34   apply (simp only: f_def)
    35   apply (rule THE_defaultI')
    36   apply (rule ex1)
    37   done
    38 
    39 lemma fundef_ex1_uniqueness:
    40   assumes f_def: "f == (\<lambda>x::'a. THE_default (d x) (\<lambda>y. G x y))"
    41   assumes ex1: "\<exists>!y. G x y"
    42   assumes elm: "G x (h x)"
    43   shows "h x = f x"
    44   apply (simp only: f_def)
    45   apply (rule THE_default1_equality [symmetric])
    46    apply (rule ex1)
    47   apply (rule elm)
    48   done
    49 
    50 lemma fundef_ex1_iff:
    51   assumes f_def: "f == (\<lambda>x::'a. THE_default (d x) (\<lambda>y. G x y))"
    52   assumes ex1: "\<exists>!y. G x y"
    53   shows "(G x y) = (f x = y)"
    54   apply (auto simp:ex1 f_def THE_default1_equality)
    55   apply (rule THE_defaultI')
    56   apply (rule ex1)
    57   done
    58 
    59 lemma fundef_default_value:
    60   assumes f_def: "f == (\<lambda>x::'a. THE_default (d x) (\<lambda>y. G x y))"
    61   assumes graph: "\<And>x y. G x y \<Longrightarrow> D x"
    62   assumes "\<not> D x"
    63   shows "f x = d x"
    64 proof -
    65   have "\<not>(\<exists>y. G x y)"
    66   proof
    67     assume "\<exists>y. G x y"
    68     hence "D x" using graph ..
    69     with `\<not> D x` show False ..
    70   qed
    71   hence "\<not>(\<exists>!y. G x y)" by blast
    72 
    73   thus ?thesis
    74     unfolding f_def
    75     by (rule THE_default_none)
    76 qed
    77 
    78 definition in_rel_def[simp]:
    79   "in_rel R x y == (x, y) \<in> R"
    80 
    81 lemma wf_in_rel:
    82   "wf R \<Longrightarrow> wfP (in_rel R)"
    83   by (simp add: wfP_def)
    84 
    85 ML_file "Tools/Function/function_common.ML"
    86 ML_file "Tools/Function/context_tree.ML"
    87 ML_file "Tools/Function/function_core.ML"
    88 ML_file "Tools/Function/sum_tree.ML"
    89 ML_file "Tools/Function/mutual.ML"
    90 ML_file "Tools/Function/pattern_split.ML"
    91 ML_file "Tools/Function/relation.ML"
    92 
    93 method_setup relation = {*
    94   Args.term >> (fn t => fn ctxt => SIMPLE_METHOD' (Function_Relation.relation_infer_tac ctxt t))
    95 *} "prove termination using a user-specified wellfounded relation"
    96 
    97 ML_file "Tools/Function/function.ML"
    98 ML_file "Tools/Function/pat_completeness.ML"
    99 
   100 method_setup pat_completeness = {*
   101   Scan.succeed (SIMPLE_METHOD' o Pat_Completeness.pat_completeness_tac)
   102 *} "prove completeness of datatype patterns"
   103 
   104 ML_file "Tools/Function/fun.ML"
   105 ML_file "Tools/Function/induction_schema.ML"
   106 
   107 method_setup induction_schema = {*
   108   Scan.succeed (RAW_METHOD o Induction_Schema.induction_schema_tac)
   109 *} "prove an induction principle"
   110 
   111 setup {*
   112   Function.setup
   113   #> Function_Fun.setup
   114 *}
   115 
   116 subsection {* Measure Functions *}
   117 
   118 inductive is_measure :: "('a \<Rightarrow> nat) \<Rightarrow> bool"
   119 where is_measure_trivial: "is_measure f"
   120 
   121 ML_file "Tools/Function/measure_functions.ML"
   122 setup MeasureFunctions.setup
   123 
   124 lemma measure_size[measure_function]: "is_measure size"
   125 by (rule is_measure_trivial)
   126 
   127 lemma measure_fst[measure_function]: "is_measure f \<Longrightarrow> is_measure (\<lambda>p. f (fst p))"
   128 by (rule is_measure_trivial)
   129 lemma measure_snd[measure_function]: "is_measure f \<Longrightarrow> is_measure (\<lambda>p. f (snd p))"
   130 by (rule is_measure_trivial)
   131 
   132 ML_file "Tools/Function/lexicographic_order.ML"
   133 
   134 method_setup lexicographic_order = {*
   135   Method.sections clasimp_modifiers >>
   136   (K (SIMPLE_METHOD o Lexicographic_Order.lexicographic_order_tac false))
   137 *} "termination prover for lexicographic orderings"
   138 
   139 setup Lexicographic_Order.setup
   140 
   141 
   142 subsection {* Congruence Rules *}
   143 
   144 lemma let_cong [fundef_cong]:
   145   "M = N \<Longrightarrow> (\<And>x. x = N \<Longrightarrow> f x = g x) \<Longrightarrow> Let M f = Let N g"
   146   unfolding Let_def by blast
   147 
   148 lemmas [fundef_cong] =
   149   if_cong image_cong INT_cong UN_cong
   150   bex_cong ball_cong imp_cong Option.map_cong Option.bind_cong
   151 
   152 lemma split_cong [fundef_cong]:
   153   "(\<And>x y. (x, y) = q \<Longrightarrow> f x y = g x y) \<Longrightarrow> p = q
   154     \<Longrightarrow> split f p = split g q"
   155   by (auto simp: split_def)
   156 
   157 lemma comp_cong [fundef_cong]:
   158   "f (g x) = f' (g' x') \<Longrightarrow> (f o g) x = (f' o g') x'"
   159   unfolding o_apply .
   160 
   161 subsection {* Simp rules for termination proofs *}
   162 
   163 lemma termination_basic_simps[termination_simp]:
   164   "x < (y::nat) \<Longrightarrow> x < y + z"
   165   "x < z \<Longrightarrow> x < y + z"
   166   "x \<le> y \<Longrightarrow> x \<le> y + (z::nat)"
   167   "x \<le> z \<Longrightarrow> x \<le> y + (z::nat)"
   168   "x < y \<Longrightarrow> x \<le> (y::nat)"
   169 by arith+
   170 
   171 declare le_imp_less_Suc[termination_simp]
   172 
   173 lemma prod_size_simp[termination_simp]:
   174   "prod_size f g p = f (fst p) + g (snd p) + Suc 0"
   175 by (induct p) auto
   176 
   177 subsection {* Decomposition *}
   178 
   179 lemma less_by_empty:
   180   "A = {} \<Longrightarrow> A \<subseteq> B"
   181 and  union_comp_emptyL:
   182   "\<lbrakk> A O C = {}; B O C = {} \<rbrakk> \<Longrightarrow> (A \<union> B) O C = {}"
   183 and union_comp_emptyR:
   184   "\<lbrakk> A O B = {}; A O C = {} \<rbrakk> \<Longrightarrow> A O (B \<union> C) = {}"
   185 and wf_no_loop:
   186   "R O R = {} \<Longrightarrow> wf R"
   187 by (auto simp add: wf_comp_self[of R])
   188 
   189 
   190 subsection {* Reduction Pairs *}
   191 
   192 definition
   193   "reduction_pair P = (wf (fst P) \<and> fst P O snd P \<subseteq> fst P)"
   194 
   195 lemma reduction_pairI[intro]: "wf R \<Longrightarrow> R O S \<subseteq> R \<Longrightarrow> reduction_pair (R, S)"
   196 unfolding reduction_pair_def by auto
   197 
   198 lemma reduction_pair_lemma:
   199   assumes rp: "reduction_pair P"
   200   assumes "R \<subseteq> fst P"
   201   assumes "S \<subseteq> snd P"
   202   assumes "wf S"
   203   shows "wf (R \<union> S)"
   204 proof -
   205   from rp `S \<subseteq> snd P` have "wf (fst P)" "fst P O S \<subseteq> fst P"
   206     unfolding reduction_pair_def by auto
   207   with `wf S` have "wf (fst P \<union> S)"
   208     by (auto intro: wf_union_compatible)
   209   moreover from `R \<subseteq> fst P` have "R \<union> S \<subseteq> fst P \<union> S" by auto
   210   ultimately show ?thesis by (rule wf_subset)
   211 qed
   212 
   213 definition
   214   "rp_inv_image = (\<lambda>(R,S) f. (inv_image R f, inv_image S f))"
   215 
   216 lemma rp_inv_image_rp:
   217   "reduction_pair P \<Longrightarrow> reduction_pair (rp_inv_image P f)"
   218   unfolding reduction_pair_def rp_inv_image_def split_def
   219   by force
   220 
   221 
   222 subsection {* Concrete orders for SCNP termination proofs *}
   223 
   224 definition "pair_less = less_than <*lex*> less_than"
   225 definition "pair_leq = pair_less^="
   226 definition "max_strict = max_ext pair_less"
   227 definition "max_weak = max_ext pair_leq \<union> {({}, {})}"
   228 definition "min_strict = min_ext pair_less"
   229 definition "min_weak = min_ext pair_leq \<union> {({}, {})}"
   230 
   231 lemma wf_pair_less[simp]: "wf pair_less"
   232   by (auto simp: pair_less_def)
   233 
   234 text {* Introduction rules for @{text pair_less}/@{text pair_leq} *}
   235 lemma pair_leqI1: "a < b \<Longrightarrow> ((a, s), (b, t)) \<in> pair_leq"
   236   and pair_leqI2: "a \<le> b \<Longrightarrow> s \<le> t \<Longrightarrow> ((a, s), (b, t)) \<in> pair_leq"
   237   and pair_lessI1: "a < b  \<Longrightarrow> ((a, s), (b, t)) \<in> pair_less"
   238   and pair_lessI2: "a \<le> b \<Longrightarrow> s < t \<Longrightarrow> ((a, s), (b, t)) \<in> pair_less"
   239   unfolding pair_leq_def pair_less_def by auto
   240 
   241 text {* Introduction rules for max *}
   242 lemma smax_emptyI:
   243   "finite Y \<Longrightarrow> Y \<noteq> {} \<Longrightarrow> ({}, Y) \<in> max_strict"
   244   and smax_insertI:
   245   "\<lbrakk>y \<in> Y; (x, y) \<in> pair_less; (X, Y) \<in> max_strict\<rbrakk> \<Longrightarrow> (insert x X, Y) \<in> max_strict"
   246   and wmax_emptyI:
   247   "finite X \<Longrightarrow> ({}, X) \<in> max_weak"
   248   and wmax_insertI:
   249   "\<lbrakk>y \<in> YS; (x, y) \<in> pair_leq; (XS, YS) \<in> max_weak\<rbrakk> \<Longrightarrow> (insert x XS, YS) \<in> max_weak"
   250 unfolding max_strict_def max_weak_def by (auto elim!: max_ext.cases)
   251 
   252 text {* Introduction rules for min *}
   253 lemma smin_emptyI:
   254   "X \<noteq> {} \<Longrightarrow> (X, {}) \<in> min_strict"
   255   and smin_insertI:
   256   "\<lbrakk>x \<in> XS; (x, y) \<in> pair_less; (XS, YS) \<in> min_strict\<rbrakk> \<Longrightarrow> (XS, insert y YS) \<in> min_strict"
   257   and wmin_emptyI:
   258   "(X, {}) \<in> min_weak"
   259   and wmin_insertI:
   260   "\<lbrakk>x \<in> XS; (x, y) \<in> pair_leq; (XS, YS) \<in> min_weak\<rbrakk> \<Longrightarrow> (XS, insert y YS) \<in> min_weak"
   261 by (auto simp: min_strict_def min_weak_def min_ext_def)
   262 
   263 text {* Reduction Pairs *}
   264 
   265 lemma max_ext_compat:
   266   assumes "R O S \<subseteq> R"
   267   shows "max_ext R O (max_ext S \<union> {({},{})}) \<subseteq> max_ext R"
   268 using assms
   269 apply auto
   270 apply (elim max_ext.cases)
   271 apply rule
   272 apply auto[3]
   273 apply (drule_tac x=xa in meta_spec)
   274 apply simp
   275 apply (erule bexE)
   276 apply (drule_tac x=xb in meta_spec)
   277 by auto
   278 
   279 lemma max_rpair_set: "reduction_pair (max_strict, max_weak)"
   280   unfolding max_strict_def max_weak_def
   281 apply (intro reduction_pairI max_ext_wf)
   282 apply simp
   283 apply (rule max_ext_compat)
   284 by (auto simp: pair_less_def pair_leq_def)
   285 
   286 lemma min_ext_compat:
   287   assumes "R O S \<subseteq> R"
   288   shows "min_ext R O  (min_ext S \<union> {({},{})}) \<subseteq> min_ext R"
   289 using assms
   290 apply (auto simp: min_ext_def)
   291 apply (drule_tac x=ya in bspec, assumption)
   292 apply (erule bexE)
   293 apply (drule_tac x=xc in bspec)
   294 apply assumption
   295 by auto
   296 
   297 lemma min_rpair_set: "reduction_pair (min_strict, min_weak)"
   298   unfolding min_strict_def min_weak_def
   299 apply (intro reduction_pairI min_ext_wf)
   300 apply simp
   301 apply (rule min_ext_compat)
   302 by (auto simp: pair_less_def pair_leq_def)
   303 
   304 
   305 subsection {* Tool setup *}
   306 
   307 ML_file "Tools/Function/termination.ML"
   308 ML_file "Tools/Function/scnp_solve.ML"
   309 ML_file "Tools/Function/scnp_reconstruct.ML"
   310 
   311 setup {* ScnpReconstruct.setup *}
   312 
   313 ML_val -- "setup inactive"
   314 {*
   315   Context.theory_map (Function_Common.set_termination_prover
   316     (ScnpReconstruct.decomp_scnp_tac [ScnpSolve.MAX, ScnpSolve.MIN, ScnpSolve.MS]))
   317 *}
   318 
   319 end