src/HOL/Nat.thy
author haftmann
Sun Jun 23 21:16:07 2013 +0200 (2013-06-23)
changeset 52435 6646bb548c6b
parent 52289 83ce5d2841e7
child 52729 412c9e0381a1
permissions -rw-r--r--
migration from code_(const|type|class|instance) to code_printing and from code_module to code_identifier
     1 (*  Title:      HOL/Nat.thy
     2     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     3 
     4 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     5 and * (for div and mod, see theory Divides).
     6 *)
     7 
     8 header {* Natural numbers *}
     9 
    10 theory Nat
    11 imports Inductive Typedef Fun Fields
    12 begin
    13 
    14 ML_file "~~/src/Tools/rat.ML"
    15 ML_file "Tools/arith_data.ML"
    16 ML_file "~~/src/Provers/Arith/fast_lin_arith.ML"
    17 
    18 
    19 subsection {* Type @{text ind} *}
    20 
    21 typedecl ind
    22 
    23 axiomatization Zero_Rep :: ind and Suc_Rep :: "ind => ind" where
    24   -- {* the axiom of infinity in 2 parts *}
    25   Suc_Rep_inject:       "Suc_Rep x = Suc_Rep y ==> x = y" and
    26   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    27 
    28 subsection {* Type nat *}
    29 
    30 text {* Type definition *}
    31 
    32 inductive Nat :: "ind \<Rightarrow> bool" where
    33   Zero_RepI: "Nat Zero_Rep"
    34 | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    35 
    36 typedef nat = "{n. Nat n}"
    37   morphisms Rep_Nat Abs_Nat
    38   using Nat.Zero_RepI by auto
    39 
    40 lemma Nat_Rep_Nat:
    41   "Nat (Rep_Nat n)"
    42   using Rep_Nat by simp
    43 
    44 lemma Nat_Abs_Nat_inverse:
    45   "Nat n \<Longrightarrow> Rep_Nat (Abs_Nat n) = n"
    46   using Abs_Nat_inverse by simp
    47 
    48 lemma Nat_Abs_Nat_inject:
    49   "Nat n \<Longrightarrow> Nat m \<Longrightarrow> Abs_Nat n = Abs_Nat m \<longleftrightarrow> n = m"
    50   using Abs_Nat_inject by simp
    51 
    52 instantiation nat :: zero
    53 begin
    54 
    55 definition Zero_nat_def:
    56   "0 = Abs_Nat Zero_Rep"
    57 
    58 instance ..
    59 
    60 end
    61 
    62 definition Suc :: "nat \<Rightarrow> nat" where
    63   "Suc n = Abs_Nat (Suc_Rep (Rep_Nat n))"
    64 
    65 lemma Suc_not_Zero: "Suc m \<noteq> 0"
    66   by (simp add: Zero_nat_def Suc_def Suc_RepI Zero_RepI Nat_Abs_Nat_inject Suc_Rep_not_Zero_Rep Nat_Rep_Nat)
    67 
    68 lemma Zero_not_Suc: "0 \<noteq> Suc m"
    69   by (rule not_sym, rule Suc_not_Zero not_sym)
    70 
    71 lemma Suc_Rep_inject': "Suc_Rep x = Suc_Rep y \<longleftrightarrow> x = y"
    72   by (rule iffI, rule Suc_Rep_inject) simp_all
    73 
    74 rep_datatype "0 \<Colon> nat" Suc
    75   apply (unfold Zero_nat_def Suc_def)
    76   apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    77    apply (erule Nat_Rep_Nat [THEN Nat.induct])
    78    apply (iprover elim: Nat_Abs_Nat_inverse [THEN subst])
    79     apply (simp_all add: Nat_Abs_Nat_inject Nat_Rep_Nat
    80       Suc_RepI Zero_RepI Suc_Rep_not_Zero_Rep
    81       Suc_Rep_not_Zero_Rep [symmetric]
    82       Suc_Rep_inject' Rep_Nat_inject)
    83   done
    84 
    85 lemma nat_induct [case_names 0 Suc, induct type: nat]:
    86   -- {* for backward compatibility -- names of variables differ *}
    87   fixes n
    88   assumes "P 0"
    89     and "\<And>n. P n \<Longrightarrow> P (Suc n)"
    90   shows "P n"
    91   using assms by (rule nat.induct)
    92 
    93 declare nat.exhaust [case_names 0 Suc, cases type: nat]
    94 
    95 lemmas nat_rec_0 = nat.recs(1)
    96   and nat_rec_Suc = nat.recs(2)
    97 
    98 lemmas nat_case_0 = nat.cases(1)
    99   and nat_case_Suc = nat.cases(2)
   100    
   101 
   102 text {* Injectiveness and distinctness lemmas *}
   103 
   104 lemma inj_Suc[simp]: "inj_on Suc N"
   105   by (simp add: inj_on_def)
   106 
   107 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   108 by (rule notE, rule Suc_not_Zero)
   109 
   110 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   111 by (rule Suc_neq_Zero, erule sym)
   112 
   113 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   114 by (rule inj_Suc [THEN injD])
   115 
   116 lemma n_not_Suc_n: "n \<noteq> Suc n"
   117 by (induct n) simp_all
   118 
   119 lemma Suc_n_not_n: "Suc n \<noteq> n"
   120 by (rule not_sym, rule n_not_Suc_n)
   121 
   122 text {* A special form of induction for reasoning
   123   about @{term "m < n"} and @{term "m - n"} *}
   124 
   125 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   126     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   127   apply (rule_tac x = m in spec)
   128   apply (induct n)
   129   prefer 2
   130   apply (rule allI)
   131   apply (induct_tac x, iprover+)
   132   done
   133 
   134 
   135 subsection {* Arithmetic operators *}
   136 
   137 instantiation nat :: comm_monoid_diff
   138 begin
   139 
   140 primrec plus_nat where
   141   add_0:      "0 + n = (n\<Colon>nat)"
   142 | add_Suc:  "Suc m + n = Suc (m + n)"
   143 
   144 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   145   by (induct m) simp_all
   146 
   147 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   148   by (induct m) simp_all
   149 
   150 declare add_0 [code]
   151 
   152 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   153   by simp
   154 
   155 primrec minus_nat where
   156   diff_0 [code]: "m - 0 = (m\<Colon>nat)"
   157 | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   158 
   159 declare diff_Suc [simp del]
   160 
   161 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   162   by (induct n) (simp_all add: diff_Suc)
   163 
   164 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   165   by (induct n) (simp_all add: diff_Suc)
   166 
   167 instance proof
   168   fix n m q :: nat
   169   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   170   show "n + m = m + n" by (induct n) simp_all
   171   show "0 + n = n" by simp
   172   show "n - 0 = n" by simp
   173   show "0 - n = 0" by simp
   174   show "(q + n) - (q + m) = n - m" by (induct q) simp_all
   175   show "n - m - q = n - (m + q)" by (induct q) (simp_all add: diff_Suc)
   176 qed
   177 
   178 end
   179 
   180 hide_fact (open) add_0 add_0_right diff_0
   181 
   182 instantiation nat :: comm_semiring_1_cancel
   183 begin
   184 
   185 definition
   186   One_nat_def [simp]: "1 = Suc 0"
   187 
   188 primrec times_nat where
   189   mult_0:     "0 * n = (0\<Colon>nat)"
   190 | mult_Suc: "Suc m * n = n + (m * n)"
   191 
   192 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   193   by (induct m) simp_all
   194 
   195 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   196   by (induct m) (simp_all add: add_left_commute)
   197 
   198 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   199   by (induct m) (simp_all add: add_assoc)
   200 
   201 instance proof
   202   fix n m q :: nat
   203   show "0 \<noteq> (1::nat)" unfolding One_nat_def by simp
   204   show "1 * n = n" unfolding One_nat_def by simp
   205   show "n * m = m * n" by (induct n) simp_all
   206   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   207   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   208   assume "n + m = n + q" thus "m = q" by (induct n) simp_all
   209 qed
   210 
   211 end
   212 
   213 subsubsection {* Addition *}
   214 
   215 lemma nat_add_assoc: "(m + n) + k = m + ((n + k)::nat)"
   216   by (rule add_assoc)
   217 
   218 lemma nat_add_commute: "m + n = n + (m::nat)"
   219   by (rule add_commute)
   220 
   221 lemma nat_add_left_commute: "x + (y + z) = y + ((x + z)::nat)"
   222   by (rule add_left_commute)
   223 
   224 lemma nat_add_left_cancel [simp]: "(k + m = k + n) = (m = (n::nat))"
   225   by (rule add_left_cancel)
   226 
   227 lemma nat_add_right_cancel [simp]: "(m + k = n + k) = (m=(n::nat))"
   228   by (rule add_right_cancel)
   229 
   230 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   231 
   232 lemma add_is_0 [iff]:
   233   fixes m n :: nat
   234   shows "(m + n = 0) = (m = 0 & n = 0)"
   235   by (cases m) simp_all
   236 
   237 lemma add_is_1:
   238   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   239   by (cases m) simp_all
   240 
   241 lemma one_is_add:
   242   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   243   by (rule trans, rule eq_commute, rule add_is_1)
   244 
   245 lemma add_eq_self_zero:
   246   fixes m n :: nat
   247   shows "m + n = m \<Longrightarrow> n = 0"
   248   by (induct m) simp_all
   249 
   250 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   251   apply (induct k)
   252    apply simp
   253   apply(drule comp_inj_on[OF _ inj_Suc])
   254   apply (simp add:o_def)
   255   done
   256 
   257 lemma Suc_eq_plus1: "Suc n = n + 1"
   258   unfolding One_nat_def by simp
   259 
   260 lemma Suc_eq_plus1_left: "Suc n = 1 + n"
   261   unfolding One_nat_def by simp
   262 
   263 
   264 subsubsection {* Difference *}
   265 
   266 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   267   by (induct m) simp_all
   268 
   269 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   270   by (induct i j rule: diff_induct) simp_all
   271 
   272 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   273   by (simp add: diff_diff_left)
   274 
   275 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   276   by (simp add: diff_diff_left add_commute)
   277 
   278 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   279   by (induct n) simp_all
   280 
   281 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   282   by (simp add: diff_add_inverse add_commute [of m n])
   283 
   284 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   285   by (induct k) simp_all
   286 
   287 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   288   by (simp add: diff_cancel add_commute)
   289 
   290 lemma diff_add_0: "n - (n + m) = (0::nat)"
   291   by (induct n) simp_all
   292 
   293 lemma diff_Suc_1 [simp]: "Suc n - 1 = n"
   294   unfolding One_nat_def by simp
   295 
   296 text {* Difference distributes over multiplication *}
   297 
   298 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   299 by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   300 
   301 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   302 by (simp add: diff_mult_distrib mult_commute [of k])
   303   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   304 
   305 
   306 subsubsection {* Multiplication *}
   307 
   308 lemma nat_mult_assoc: "(m * n) * k = m * ((n * k)::nat)"
   309   by (rule mult_assoc)
   310 
   311 lemma nat_mult_commute: "m * n = n * (m::nat)"
   312   by (rule mult_commute)
   313 
   314 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   315   by (rule distrib_left)
   316 
   317 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   318   by (induct m) auto
   319 
   320 lemmas nat_distrib =
   321   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   322 
   323 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = Suc 0 & n = Suc 0)"
   324   apply (induct m)
   325    apply simp
   326   apply (induct n)
   327    apply auto
   328   done
   329 
   330 lemma one_eq_mult_iff [simp,no_atp]: "(Suc 0 = m * n) = (m = Suc 0 & n = Suc 0)"
   331   apply (rule trans)
   332   apply (rule_tac [2] mult_eq_1_iff, fastforce)
   333   done
   334 
   335 lemma nat_mult_eq_1_iff [simp]: "m * n = (1::nat) \<longleftrightarrow> m = 1 \<and> n = 1"
   336   unfolding One_nat_def by (rule mult_eq_1_iff)
   337 
   338 lemma nat_1_eq_mult_iff [simp]: "(1::nat) = m * n \<longleftrightarrow> m = 1 \<and> n = 1"
   339   unfolding One_nat_def by (rule one_eq_mult_iff)
   340 
   341 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   342 proof -
   343   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   344   proof (induct n arbitrary: m)
   345     case 0 then show "m = 0" by simp
   346   next
   347     case (Suc n) then show "m = Suc n"
   348       by (cases m) (simp_all add: eq_commute [of "0"])
   349   qed
   350   then show ?thesis by auto
   351 qed
   352 
   353 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   354   by (simp add: mult_commute)
   355 
   356 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   357   by (subst mult_cancel1) simp
   358 
   359 
   360 subsection {* Orders on @{typ nat} *}
   361 
   362 subsubsection {* Operation definition *}
   363 
   364 instantiation nat :: linorder
   365 begin
   366 
   367 primrec less_eq_nat where
   368   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   369 | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   370 
   371 declare less_eq_nat.simps [simp del]
   372 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by (simp add: less_eq_nat.simps)
   373 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   374 
   375 definition less_nat where
   376   less_eq_Suc_le: "n < m \<longleftrightarrow> Suc n \<le> m"
   377 
   378 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   379   by (simp add: less_eq_nat.simps(2))
   380 
   381 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   382   unfolding less_eq_Suc_le ..
   383 
   384 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   385   by (induct n) (simp_all add: less_eq_nat.simps(2))
   386 
   387 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   388   by (simp add: less_eq_Suc_le)
   389 
   390 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   391   by simp
   392 
   393 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   394   by (simp add: less_eq_Suc_le)
   395 
   396 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   397   by (simp add: less_eq_Suc_le)
   398 
   399 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   400   by (induct m arbitrary: n)
   401     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   402 
   403 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   404   by (cases n) (auto intro: le_SucI)
   405 
   406 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   407   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   408 
   409 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   410   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   411 
   412 instance
   413 proof
   414   fix n m :: nat
   415   show "n < m \<longleftrightarrow> n \<le> m \<and> \<not> m \<le> n" 
   416   proof (induct n arbitrary: m)
   417     case 0 then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   418   next
   419     case (Suc n) then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   420   qed
   421 next
   422   fix n :: nat show "n \<le> n" by (induct n) simp_all
   423 next
   424   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   425   then show "n = m"
   426     by (induct n arbitrary: m)
   427       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   428 next
   429   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   430   then show "n \<le> q"
   431   proof (induct n arbitrary: m q)
   432     case 0 show ?case by simp
   433   next
   434     case (Suc n) then show ?case
   435       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   436         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   437         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   438   qed
   439 next
   440   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   441     by (induct n arbitrary: m)
   442       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   443 qed
   444 
   445 end
   446 
   447 instantiation nat :: bot
   448 begin
   449 
   450 definition bot_nat :: nat where
   451   "bot_nat = 0"
   452 
   453 instance proof
   454 qed (simp add: bot_nat_def)
   455 
   456 end
   457 
   458 instance nat :: no_top
   459   by default (auto intro: less_Suc_eq_le [THEN iffD2])
   460 
   461 
   462 subsubsection {* Introduction properties *}
   463 
   464 lemma lessI [iff]: "n < Suc n"
   465   by (simp add: less_Suc_eq_le)
   466 
   467 lemma zero_less_Suc [iff]: "0 < Suc n"
   468   by (simp add: less_Suc_eq_le)
   469 
   470 
   471 subsubsection {* Elimination properties *}
   472 
   473 lemma less_not_refl: "~ n < (n::nat)"
   474   by (rule order_less_irrefl)
   475 
   476 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   477   by (rule not_sym) (rule less_imp_neq) 
   478 
   479 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   480   by (rule less_imp_neq)
   481 
   482 lemma less_irrefl_nat: "(n::nat) < n ==> R"
   483   by (rule notE, rule less_not_refl)
   484 
   485 lemma less_zeroE: "(n::nat) < 0 ==> R"
   486   by (rule notE) (rule not_less0)
   487 
   488 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   489   unfolding less_Suc_eq_le le_less ..
   490 
   491 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   492   by (simp add: less_Suc_eq)
   493 
   494 lemma less_one [iff, no_atp]: "(n < (1::nat)) = (n = 0)"
   495   unfolding One_nat_def by (rule less_Suc0)
   496 
   497 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   498   by simp
   499 
   500 text {* "Less than" is antisymmetric, sort of *}
   501 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   502   unfolding not_less less_Suc_eq_le by (rule antisym)
   503 
   504 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   505   by (rule linorder_neq_iff)
   506 
   507 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   508   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   509   shows "P n m"
   510   apply (rule less_linear [THEN disjE])
   511   apply (erule_tac [2] disjE)
   512   apply (erule lessCase)
   513   apply (erule sym [THEN eqCase])
   514   apply (erule major)
   515   done
   516 
   517 
   518 subsubsection {* Inductive (?) properties *}
   519 
   520 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   521   unfolding less_eq_Suc_le [of m] le_less by simp 
   522 
   523 lemma lessE:
   524   assumes major: "i < k"
   525   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   526   shows P
   527 proof -
   528   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   529     unfolding less_eq_Suc_le by (induct k) simp_all
   530   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   531     by (clarsimp simp add: less_le)
   532   with p1 p2 show P by auto
   533 qed
   534 
   535 lemma less_SucE: assumes major: "m < Suc n"
   536   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   537   apply (rule major [THEN lessE])
   538   apply (rule eq, blast)
   539   apply (rule less, blast)
   540   done
   541 
   542 lemma Suc_lessE: assumes major: "Suc i < k"
   543   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   544   apply (rule major [THEN lessE])
   545   apply (erule lessI [THEN minor])
   546   apply (erule Suc_lessD [THEN minor], assumption)
   547   done
   548 
   549 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   550   by simp
   551 
   552 lemma less_trans_Suc:
   553   assumes le: "i < j" shows "j < k ==> Suc i < k"
   554   apply (induct k, simp_all)
   555   apply (insert le)
   556   apply (simp add: less_Suc_eq)
   557   apply (blast dest: Suc_lessD)
   558   done
   559 
   560 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   561 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   562   unfolding not_less less_Suc_eq_le ..
   563 
   564 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   565   unfolding not_le Suc_le_eq ..
   566 
   567 text {* Properties of "less than or equal" *}
   568 
   569 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   570   unfolding less_Suc_eq_le .
   571 
   572 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   573   unfolding not_le less_Suc_eq_le ..
   574 
   575 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   576   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   577 
   578 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   579   by (drule le_Suc_eq [THEN iffD1], iprover+)
   580 
   581 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   582   unfolding Suc_le_eq .
   583 
   584 text {* Stronger version of @{text Suc_leD} *}
   585 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   586   unfolding Suc_le_eq .
   587 
   588 lemma less_imp_le_nat: "m < n ==> m \<le> (n::nat)"
   589   unfolding less_eq_Suc_le by (rule Suc_leD)
   590 
   591 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   592 lemmas le_simps = less_imp_le_nat less_Suc_eq_le Suc_le_eq
   593 
   594 
   595 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   596 
   597 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   598   unfolding le_less .
   599 
   600 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   601   by (rule le_less)
   602 
   603 text {* Useful with @{text blast}. *}
   604 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   605   by auto
   606 
   607 lemma le_refl: "n \<le> (n::nat)"
   608   by simp
   609 
   610 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   611   by (rule order_trans)
   612 
   613 lemma le_antisym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   614   by (rule antisym)
   615 
   616 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   617   by (rule less_le)
   618 
   619 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   620   unfolding less_le ..
   621 
   622 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   623   by (rule linear)
   624 
   625 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   626 
   627 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   628   unfolding less_Suc_eq_le by auto
   629 
   630 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   631   unfolding not_less by (rule le_less_Suc_eq)
   632 
   633 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   634 
   635 text {* These two rules ease the use of primitive recursion.
   636 NOTE USE OF @{text "=="} *}
   637 lemma def_nat_rec_0: "(!!n. f n == nat_rec c h n) ==> f 0 = c"
   638 by simp
   639 
   640 lemma def_nat_rec_Suc: "(!!n. f n == nat_rec c h n) ==> f (Suc n) = h n (f n)"
   641 by simp
   642 
   643 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   644 by (cases n) simp_all
   645 
   646 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   647 by (cases n) simp_all
   648 
   649 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   650 by (cases n) simp_all
   651 
   652 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   653 by (cases n) simp_all
   654 
   655 text {* This theorem is useful with @{text blast} *}
   656 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   657 by (rule neq0_conv[THEN iffD1], iprover)
   658 
   659 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   660 by (fast intro: not0_implies_Suc)
   661 
   662 lemma not_gr0 [iff,no_atp]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   663 using neq0_conv by blast
   664 
   665 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   666 by (induct m') simp_all
   667 
   668 text {* Useful in certain inductive arguments *}
   669 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   670 by (cases m) simp_all
   671 
   672 
   673 subsubsection {* Monotonicity of Addition *}
   674 
   675 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   676 by (simp add: diff_Suc split: nat.split)
   677 
   678 lemma Suc_diff_1 [simp]: "0 < n ==> Suc (n - 1) = n"
   679 unfolding One_nat_def by (rule Suc_pred)
   680 
   681 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   682 by (induct k) simp_all
   683 
   684 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   685 by (induct k) simp_all
   686 
   687 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   688 by(auto dest:gr0_implies_Suc)
   689 
   690 text {* strict, in 1st argument *}
   691 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   692 by (induct k) simp_all
   693 
   694 text {* strict, in both arguments *}
   695 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   696   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   697   apply (induct j, simp_all)
   698   done
   699 
   700 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   701 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   702   apply (induct n)
   703   apply (simp_all add: order_le_less)
   704   apply (blast elim!: less_SucE
   705                intro!: Nat.add_0_right [symmetric] add_Suc_right [symmetric])
   706   done
   707 
   708 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   709 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   710 apply(auto simp: gr0_conv_Suc)
   711 apply (induct_tac m)
   712 apply (simp_all add: add_less_mono)
   713 done
   714 
   715 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   716 instance nat :: linordered_semidom
   717 proof
   718   show "0 < (1::nat)" by simp
   719   show "\<And>m n q :: nat. m \<le> n \<Longrightarrow> q + m \<le> q + n" by simp
   720   show "\<And>m n q :: nat. m < n \<Longrightarrow> 0 < q \<Longrightarrow> q * m < q * n" by (simp add: mult_less_mono2)
   721 qed
   722 
   723 instance nat :: no_zero_divisors
   724 proof
   725   fix a::nat and b::nat show "a ~= 0 \<Longrightarrow> b ~= 0 \<Longrightarrow> a * b ~= 0" by auto
   726 qed
   727 
   728 
   729 subsubsection {* @{term min} and @{term max} *}
   730 
   731 lemma mono_Suc: "mono Suc"
   732 by (rule monoI) simp
   733 
   734 lemma min_0L [simp]: "min 0 n = (0::nat)"
   735 by (rule min_absorb1) simp
   736 
   737 lemma min_0R [simp]: "min n 0 = (0::nat)"
   738 by (rule min_absorb2) simp
   739 
   740 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   741 by (simp add: mono_Suc min_of_mono)
   742 
   743 lemma min_Suc1:
   744    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   745 by (simp split: nat.split)
   746 
   747 lemma min_Suc2:
   748    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   749 by (simp split: nat.split)
   750 
   751 lemma max_0L [simp]: "max 0 n = (n::nat)"
   752 by (rule max_absorb2) simp
   753 
   754 lemma max_0R [simp]: "max n 0 = (n::nat)"
   755 by (rule max_absorb1) simp
   756 
   757 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   758 by (simp add: mono_Suc max_of_mono)
   759 
   760 lemma max_Suc1:
   761    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   762 by (simp split: nat.split)
   763 
   764 lemma max_Suc2:
   765    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   766 by (simp split: nat.split)
   767 
   768 lemma nat_mult_min_left:
   769   fixes m n q :: nat
   770   shows "min m n * q = min (m * q) (n * q)"
   771   by (simp add: min_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   772 
   773 lemma nat_mult_min_right:
   774   fixes m n q :: nat
   775   shows "m * min n q = min (m * n) (m * q)"
   776   by (simp add: min_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   777 
   778 lemma nat_add_max_left:
   779   fixes m n q :: nat
   780   shows "max m n + q = max (m + q) (n + q)"
   781   by (simp add: max_def)
   782 
   783 lemma nat_add_max_right:
   784   fixes m n q :: nat
   785   shows "m + max n q = max (m + n) (m + q)"
   786   by (simp add: max_def)
   787 
   788 lemma nat_mult_max_left:
   789   fixes m n q :: nat
   790   shows "max m n * q = max (m * q) (n * q)"
   791   by (simp add: max_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   792 
   793 lemma nat_mult_max_right:
   794   fixes m n q :: nat
   795   shows "m * max n q = max (m * n) (m * q)"
   796   by (simp add: max_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   797 
   798 
   799 subsubsection {* Additional theorems about @{term "op \<le>"} *}
   800 
   801 text {* Complete induction, aka course-of-values induction *}
   802 
   803 instance nat :: wellorder proof
   804   fix P and n :: nat
   805   assume step: "\<And>n::nat. (\<And>m. m < n \<Longrightarrow> P m) \<Longrightarrow> P n"
   806   have "\<And>q. q \<le> n \<Longrightarrow> P q"
   807   proof (induct n)
   808     case (0 n)
   809     have "P 0" by (rule step) auto
   810     thus ?case using 0 by auto
   811   next
   812     case (Suc m n)
   813     then have "n \<le> m \<or> n = Suc m" by (simp add: le_Suc_eq)
   814     thus ?case
   815     proof
   816       assume "n \<le> m" thus "P n" by (rule Suc(1))
   817     next
   818       assume n: "n = Suc m"
   819       show "P n"
   820         by (rule step) (rule Suc(1), simp add: n le_simps)
   821     qed
   822   qed
   823   then show "P n" by auto
   824 qed
   825 
   826 lemma Least_Suc:
   827      "[| P n; ~ P 0 |] ==> (LEAST n. P n) = Suc (LEAST m. P(Suc m))"
   828   apply (cases n, auto)
   829   apply (frule LeastI)
   830   apply (drule_tac P = "%x. P (Suc x) " in LeastI)
   831   apply (subgoal_tac " (LEAST x. P x) \<le> Suc (LEAST x. P (Suc x))")
   832   apply (erule_tac [2] Least_le)
   833   apply (cases "LEAST x. P x", auto)
   834   apply (drule_tac P = "%x. P (Suc x) " in Least_le)
   835   apply (blast intro: order_antisym)
   836   done
   837 
   838 lemma Least_Suc2:
   839    "[|P n; Q m; ~P 0; !k. P (Suc k) = Q k|] ==> Least P = Suc (Least Q)"
   840   apply (erule (1) Least_Suc [THEN ssubst])
   841   apply simp
   842   done
   843 
   844 lemma ex_least_nat_le: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k\<le>n. (\<forall>i<k. \<not>P i) & P(k)"
   845   apply (cases n)
   846    apply blast
   847   apply (rule_tac x="LEAST k. P(k)" in exI)
   848   apply (blast intro: Least_le dest: not_less_Least intro: LeastI_ex)
   849   done
   850 
   851 lemma ex_least_nat_less: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k<n. (\<forall>i\<le>k. \<not>P i) & P(k+1)"
   852   unfolding One_nat_def
   853   apply (cases n)
   854    apply blast
   855   apply (frule (1) ex_least_nat_le)
   856   apply (erule exE)
   857   apply (case_tac k)
   858    apply simp
   859   apply (rename_tac k1)
   860   apply (rule_tac x=k1 in exI)
   861   apply (auto simp add: less_eq_Suc_le)
   862   done
   863 
   864 lemma nat_less_induct:
   865   assumes "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   866   using assms less_induct by blast
   867 
   868 lemma measure_induct_rule [case_names less]:
   869   fixes f :: "'a \<Rightarrow> nat"
   870   assumes step: "\<And>x. (\<And>y. f y < f x \<Longrightarrow> P y) \<Longrightarrow> P x"
   871   shows "P a"
   872 by (induct m\<equiv>"f a" arbitrary: a rule: less_induct) (auto intro: step)
   873 
   874 text {* old style induction rules: *}
   875 lemma measure_induct:
   876   fixes f :: "'a \<Rightarrow> nat"
   877   shows "(\<And>x. \<forall>y. f y < f x \<longrightarrow> P y \<Longrightarrow> P x) \<Longrightarrow> P a"
   878   by (rule measure_induct_rule [of f P a]) iprover
   879 
   880 lemma full_nat_induct:
   881   assumes step: "(!!n. (ALL m. Suc m <= n --> P m) ==> P n)"
   882   shows "P n"
   883   by (rule less_induct) (auto intro: step simp:le_simps)
   884 
   885 text{*An induction rule for estabilishing binary relations*}
   886 lemma less_Suc_induct:
   887   assumes less:  "i < j"
   888      and  step:  "!!i. P i (Suc i)"
   889      and  trans: "!!i j k. i < j ==> j < k ==>  P i j ==> P j k ==> P i k"
   890   shows "P i j"
   891 proof -
   892   from less obtain k where j: "j = Suc (i + k)" by (auto dest: less_imp_Suc_add)
   893   have "P i (Suc (i + k))"
   894   proof (induct k)
   895     case 0
   896     show ?case by (simp add: step)
   897   next
   898     case (Suc k)
   899     have "0 + i < Suc k + i" by (rule add_less_mono1) simp
   900     hence "i < Suc (i + k)" by (simp add: add_commute)
   901     from trans[OF this lessI Suc step]
   902     show ?case by simp
   903   qed
   904   thus "P i j" by (simp add: j)
   905 qed
   906 
   907 text {* The method of infinite descent, frequently used in number theory.
   908 Provided by Roelof Oosterhuis.
   909 $P(n)$ is true for all $n\in\mathbb{N}$ if
   910 \begin{itemize}
   911   \item case ``0'': given $n=0$ prove $P(n)$,
   912   \item case ``smaller'': given $n>0$ and $\neg P(n)$ prove there exists
   913         a smaller integer $m$ such that $\neg P(m)$.
   914 \end{itemize} *}
   915 
   916 text{* A compact version without explicit base case: *}
   917 lemma infinite_descent:
   918   "\<lbrakk> !!n::nat. \<not> P n \<Longrightarrow>  \<exists>m<n. \<not>  P m \<rbrakk> \<Longrightarrow>  P n"
   919 by (induct n rule: less_induct) auto
   920 
   921 lemma infinite_descent0[case_names 0 smaller]: 
   922   "\<lbrakk> P 0; !!n. n>0 \<Longrightarrow> \<not> P n \<Longrightarrow> (\<exists>m::nat. m < n \<and> \<not>P m) \<rbrakk> \<Longrightarrow> P n"
   923 by (rule infinite_descent) (case_tac "n>0", auto)
   924 
   925 text {*
   926 Infinite descent using a mapping to $\mathbb{N}$:
   927 $P(x)$ is true for all $x\in D$ if there exists a $V: D \to \mathbb{N}$ and
   928 \begin{itemize}
   929 \item case ``0'': given $V(x)=0$ prove $P(x)$,
   930 \item case ``smaller'': given $V(x)>0$ and $\neg P(x)$ prove there exists a $y \in D$ such that $V(y)<V(x)$ and $~\neg P(y)$.
   931 \end{itemize}
   932 NB: the proof also shows how to use the previous lemma. *}
   933 
   934 corollary infinite_descent0_measure [case_names 0 smaller]:
   935   assumes A0: "!!x. V x = (0::nat) \<Longrightarrow> P x"
   936     and   A1: "!!x. V x > 0 \<Longrightarrow> \<not>P x \<Longrightarrow> (\<exists>y. V y < V x \<and> \<not>P y)"
   937   shows "P x"
   938 proof -
   939   obtain n where "n = V x" by auto
   940   moreover have "\<And>x. V x = n \<Longrightarrow> P x"
   941   proof (induct n rule: infinite_descent0)
   942     case 0 -- "i.e. $V(x) = 0$"
   943     with A0 show "P x" by auto
   944   next -- "now $n>0$ and $P(x)$ does not hold for some $x$ with $V(x)=n$"
   945     case (smaller n)
   946     then obtain x where vxn: "V x = n " and "V x > 0 \<and> \<not> P x" by auto
   947     with A1 obtain y where "V y < V x \<and> \<not> P y" by auto
   948     with vxn obtain m where "m = V y \<and> m<n \<and> \<not> P y" by auto
   949     then show ?case by auto
   950   qed
   951   ultimately show "P x" by auto
   952 qed
   953 
   954 text{* Again, without explicit base case: *}
   955 lemma infinite_descent_measure:
   956 assumes "!!x. \<not> P x \<Longrightarrow> \<exists>y. (V::'a\<Rightarrow>nat) y < V x \<and> \<not> P y" shows "P x"
   957 proof -
   958   from assms obtain n where "n = V x" by auto
   959   moreover have "!!x. V x = n \<Longrightarrow> P x"
   960   proof (induct n rule: infinite_descent, auto)
   961     fix x assume "\<not> P x"
   962     with assms show "\<exists>m < V x. \<exists>y. V y = m \<and> \<not> P y" by auto
   963   qed
   964   ultimately show "P x" by auto
   965 qed
   966 
   967 text {* A [clumsy] way of lifting @{text "<"}
   968   monotonicity to @{text "\<le>"} monotonicity *}
   969 lemma less_mono_imp_le_mono:
   970   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
   971 by (simp add: order_le_less) (blast)
   972 
   973 
   974 text {* non-strict, in 1st argument *}
   975 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
   976 by (rule add_right_mono)
   977 
   978 text {* non-strict, in both arguments *}
   979 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
   980 by (rule add_mono)
   981 
   982 lemma le_add2: "n \<le> ((m + n)::nat)"
   983 by (insert add_right_mono [of 0 m n], simp)
   984 
   985 lemma le_add1: "n \<le> ((n + m)::nat)"
   986 by (simp add: add_commute, rule le_add2)
   987 
   988 lemma less_add_Suc1: "i < Suc (i + m)"
   989 by (rule le_less_trans, rule le_add1, rule lessI)
   990 
   991 lemma less_add_Suc2: "i < Suc (m + i)"
   992 by (rule le_less_trans, rule le_add2, rule lessI)
   993 
   994 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
   995 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
   996 
   997 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
   998 by (rule le_trans, assumption, rule le_add1)
   999 
  1000 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
  1001 by (rule le_trans, assumption, rule le_add2)
  1002 
  1003 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
  1004 by (rule less_le_trans, assumption, rule le_add1)
  1005 
  1006 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
  1007 by (rule less_le_trans, assumption, rule le_add2)
  1008 
  1009 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
  1010 apply (rule le_less_trans [of _ "i+j"])
  1011 apply (simp_all add: le_add1)
  1012 done
  1013 
  1014 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
  1015 apply (rule notI)
  1016 apply (drule add_lessD1)
  1017 apply (erule less_irrefl [THEN notE])
  1018 done
  1019 
  1020 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
  1021 by (simp add: add_commute)
  1022 
  1023 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
  1024 apply (rule order_trans [of _ "m+k"])
  1025 apply (simp_all add: le_add1)
  1026 done
  1027 
  1028 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
  1029 apply (simp add: add_commute)
  1030 apply (erule add_leD1)
  1031 done
  1032 
  1033 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
  1034 by (blast dest: add_leD1 add_leD2)
  1035 
  1036 text {* needs @{text "!!k"} for @{text add_ac} to work *}
  1037 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
  1038 by (force simp del: add_Suc_right
  1039     simp add: less_iff_Suc_add add_Suc_right [symmetric] add_ac)
  1040 
  1041 
  1042 subsubsection {* More results about difference *}
  1043 
  1044 text {* Addition is the inverse of subtraction:
  1045   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
  1046 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
  1047 by (induct m n rule: diff_induct) simp_all
  1048 
  1049 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
  1050 by (simp add: add_diff_inverse linorder_not_less)
  1051 
  1052 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
  1053 by (simp add: add_commute)
  1054 
  1055 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
  1056 by (induct m n rule: diff_induct) simp_all
  1057 
  1058 lemma diff_less_Suc: "m - n < Suc m"
  1059 apply (induct m n rule: diff_induct)
  1060 apply (erule_tac [3] less_SucE)
  1061 apply (simp_all add: less_Suc_eq)
  1062 done
  1063 
  1064 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
  1065 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
  1066 
  1067 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
  1068   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
  1069 
  1070 instance nat :: ordered_cancel_comm_monoid_diff
  1071 proof
  1072   show "\<And>m n :: nat. m \<le> n \<longleftrightarrow> (\<exists>q. n = m + q)" by (fact le_iff_add)
  1073 qed
  1074 
  1075 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
  1076 by (rule le_less_trans, rule diff_le_self)
  1077 
  1078 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
  1079 by (cases n) (auto simp add: le_simps)
  1080 
  1081 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
  1082 by (induct j k rule: diff_induct) simp_all
  1083 
  1084 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
  1085 by (simp add: add_commute diff_add_assoc)
  1086 
  1087 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
  1088 by (auto simp add: diff_add_inverse2)
  1089 
  1090 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
  1091 by (induct m n rule: diff_induct) simp_all
  1092 
  1093 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
  1094 by (rule iffD2, rule diff_is_0_eq)
  1095 
  1096 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
  1097 by (induct m n rule: diff_induct) simp_all
  1098 
  1099 lemma less_imp_add_positive:
  1100   assumes "i < j"
  1101   shows "\<exists>k::nat. 0 < k & i + k = j"
  1102 proof
  1103   from assms show "0 < j - i & i + (j - i) = j"
  1104     by (simp add: order_less_imp_le)
  1105 qed
  1106 
  1107 text {* a nice rewrite for bounded subtraction *}
  1108 lemma nat_minus_add_max:
  1109   fixes n m :: nat
  1110   shows "n - m + m = max n m"
  1111     by (simp add: max_def not_le order_less_imp_le)
  1112 
  1113 lemma nat_diff_split:
  1114   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
  1115     -- {* elimination of @{text -} on @{text nat} *}
  1116 by (cases "a < b")
  1117   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
  1118     not_less le_less dest!: sym [of a] sym [of b] add_eq_self_zero)
  1119 
  1120 lemma nat_diff_split_asm:
  1121   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
  1122     -- {* elimination of @{text -} on @{text nat} in assumptions *}
  1123 by (auto split: nat_diff_split)
  1124 
  1125 lemma Suc_pred': "0 < n ==> n = Suc(n - 1)"
  1126   by simp
  1127 
  1128 lemma add_eq_if: "(m::nat) + n = (if m=0 then n else Suc ((m - 1) + n))"
  1129   unfolding One_nat_def by (cases m) simp_all
  1130 
  1131 lemma mult_eq_if: "(m::nat) * n = (if m=0 then 0 else n + ((m - 1) * n))"
  1132   unfolding One_nat_def by (cases m) simp_all
  1133 
  1134 lemma Suc_diff_eq_diff_pred: "0 < n ==> Suc m - n = m - (n - 1)"
  1135   unfolding One_nat_def by (cases n) simp_all
  1136 
  1137 lemma diff_Suc_eq_diff_pred: "m - Suc n = (m - 1) - n"
  1138   unfolding One_nat_def by (cases m) simp_all
  1139 
  1140 lemma Let_Suc [simp]: "Let (Suc n) f == f (Suc n)"
  1141   by (fact Let_def)
  1142 
  1143 
  1144 subsubsection {* Monotonicity of Multiplication *}
  1145 
  1146 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
  1147 by (simp add: mult_right_mono)
  1148 
  1149 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
  1150 by (simp add: mult_left_mono)
  1151 
  1152 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
  1153 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
  1154 by (simp add: mult_mono)
  1155 
  1156 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
  1157 by (simp add: mult_strict_right_mono)
  1158 
  1159 text{*Differs from the standard @{text zero_less_mult_iff} in that
  1160       there are no negative numbers.*}
  1161 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
  1162   apply (induct m)
  1163    apply simp
  1164   apply (case_tac n)
  1165    apply simp_all
  1166   done
  1167 
  1168 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (Suc 0 \<le> m & Suc 0 \<le> n)"
  1169   apply (induct m)
  1170    apply simp
  1171   apply (case_tac n)
  1172    apply simp_all
  1173   done
  1174 
  1175 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
  1176   apply (safe intro!: mult_less_mono1)
  1177   apply (cases k, auto)
  1178   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
  1179   apply (blast intro: mult_le_mono1)
  1180   done
  1181 
  1182 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
  1183 by (simp add: mult_commute [of k])
  1184 
  1185 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
  1186 by (simp add: linorder_not_less [symmetric], auto)
  1187 
  1188 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
  1189 by (simp add: linorder_not_less [symmetric], auto)
  1190 
  1191 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1192 by (subst mult_less_cancel1) simp
  1193 
  1194 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1195 by (subst mult_le_cancel1) simp
  1196 
  1197 lemma le_square: "m \<le> m * (m::nat)"
  1198   by (cases m) (auto intro: le_add1)
  1199 
  1200 lemma le_cube: "(m::nat) \<le> m * (m * m)"
  1201   by (cases m) (auto intro: le_add1)
  1202 
  1203 text {* Lemma for @{text gcd} *}
  1204 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1205   apply (drule sym)
  1206   apply (rule disjCI)
  1207   apply (rule nat_less_cases, erule_tac [2] _)
  1208    apply (drule_tac [2] mult_less_mono2)
  1209     apply (auto)
  1210   done
  1211 
  1212 lemma mono_times_nat:
  1213   fixes n :: nat
  1214   assumes "n > 0"
  1215   shows "mono (times n)"
  1216 proof
  1217   fix m q :: nat
  1218   assume "m \<le> q"
  1219   with assms show "n * m \<le> n * q" by simp
  1220 qed
  1221 
  1222 text {* the lattice order on @{typ nat} *}
  1223 
  1224 instantiation nat :: distrib_lattice
  1225 begin
  1226 
  1227 definition
  1228   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
  1229 
  1230 definition
  1231   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1232 
  1233 instance by intro_classes
  1234   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1235     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1236 
  1237 end
  1238 
  1239 
  1240 subsection {* Natural operation of natural numbers on functions *}
  1241 
  1242 text {*
  1243   We use the same logical constant for the power operations on
  1244   functions and relations, in order to share the same syntax.
  1245 *}
  1246 
  1247 consts compow :: "nat \<Rightarrow> 'a \<Rightarrow> 'a"
  1248 
  1249 abbreviation compower :: "'a \<Rightarrow> nat \<Rightarrow> 'a" (infixr "^^" 80) where
  1250   "f ^^ n \<equiv> compow n f"
  1251 
  1252 notation (latex output)
  1253   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1254 
  1255 notation (HTML output)
  1256   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1257 
  1258 text {* @{text "f ^^ n = f o ... o f"}, the n-fold composition of @{text f} *}
  1259 
  1260 overloading
  1261   funpow == "compow :: nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> ('a \<Rightarrow> 'a)"
  1262 begin
  1263 
  1264 primrec funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1265   "funpow 0 f = id"
  1266 | "funpow (Suc n) f = f o funpow n f"
  1267 
  1268 end
  1269 
  1270 lemma funpow_Suc_right:
  1271   "f ^^ Suc n = f ^^ n \<circ> f"
  1272 proof (induct n)
  1273   case 0 then show ?case by simp
  1274 next
  1275   fix n
  1276   assume "f ^^ Suc n = f ^^ n \<circ> f"
  1277   then show "f ^^ Suc (Suc n) = f ^^ Suc n \<circ> f"
  1278     by (simp add: o_assoc)
  1279 qed
  1280 
  1281 lemmas funpow_simps_right = funpow.simps(1) funpow_Suc_right
  1282 
  1283 text {* for code generation *}
  1284 
  1285 definition funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1286   funpow_code_def [code_abbrev]: "funpow = compow"
  1287 
  1288 lemma [code]:
  1289   "funpow (Suc n) f = f o funpow n f"
  1290   "funpow 0 f = id"
  1291   by (simp_all add: funpow_code_def)
  1292 
  1293 hide_const (open) funpow
  1294 
  1295 lemma funpow_add:
  1296   "f ^^ (m + n) = f ^^ m \<circ> f ^^ n"
  1297   by (induct m) simp_all
  1298 
  1299 lemma funpow_mult:
  1300   fixes f :: "'a \<Rightarrow> 'a"
  1301   shows "(f ^^ m) ^^ n = f ^^ (m * n)"
  1302   by (induct n) (simp_all add: funpow_add)
  1303 
  1304 lemma funpow_swap1:
  1305   "f ((f ^^ n) x) = (f ^^ n) (f x)"
  1306 proof -
  1307   have "f ((f ^^ n) x) = (f ^^ (n + 1)) x" by simp
  1308   also have "\<dots>  = (f ^^ n o f ^^ 1) x" by (simp only: funpow_add)
  1309   also have "\<dots> = (f ^^ n) (f x)" by simp
  1310   finally show ?thesis .
  1311 qed
  1312 
  1313 lemma comp_funpow:
  1314   fixes f :: "'a \<Rightarrow> 'a"
  1315   shows "comp f ^^ n = comp (f ^^ n)"
  1316   by (induct n) simp_all
  1317 
  1318 
  1319 subsection {* Kleene iteration *}
  1320 
  1321 lemma Kleene_iter_lpfp: assumes "mono f" and "f p \<le> p" shows "(f^^k) bot \<le> p"
  1322 proof(induction k)
  1323   case 0 show ?case by simp
  1324 next
  1325   case Suc
  1326   from monoD[OF assms(1) Suc] assms(2)
  1327   show ?case by simp
  1328 qed
  1329 
  1330 lemma lfp_Kleene_iter: assumes "mono f" and "(f^^Suc k) bot = (f^^k) bot"
  1331 shows "lfp f = (f^^k) bot"
  1332 proof(rule antisym)
  1333   show "lfp f \<le> (f^^k) bot"
  1334   proof(rule lfp_lowerbound)
  1335     show "f ((f^^k) bot) \<le> (f^^k) bot" using assms(2) by simp
  1336   qed
  1337 next
  1338   show "(f^^k) bot \<le> lfp f"
  1339     using Kleene_iter_lpfp[OF assms(1)] lfp_unfold[OF assms(1)] by simp
  1340 qed
  1341 
  1342 
  1343 subsection {* Embedding of the Naturals into any @{text semiring_1}: @{term of_nat} *}
  1344 
  1345 context semiring_1
  1346 begin
  1347 
  1348 definition of_nat :: "nat \<Rightarrow> 'a" where
  1349   "of_nat n = (plus 1 ^^ n) 0"
  1350 
  1351 lemma of_nat_simps [simp]:
  1352   shows of_nat_0: "of_nat 0 = 0"
  1353     and of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1354   by (simp_all add: of_nat_def)
  1355 
  1356 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1357   by (simp add: of_nat_def)
  1358 
  1359 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1360   by (induct m) (simp_all add: add_ac)
  1361 
  1362 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1363   by (induct m) (simp_all add: add_ac distrib_right)
  1364 
  1365 primrec of_nat_aux :: "('a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'a" where
  1366   "of_nat_aux inc 0 i = i"
  1367 | "of_nat_aux inc (Suc n) i = of_nat_aux inc n (inc i)" -- {* tail recursive *}
  1368 
  1369 lemma of_nat_code:
  1370   "of_nat n = of_nat_aux (\<lambda>i. i + 1) n 0"
  1371 proof (induct n)
  1372   case 0 then show ?case by simp
  1373 next
  1374   case (Suc n)
  1375   have "\<And>i. of_nat_aux (\<lambda>i. i + 1) n (i + 1) = of_nat_aux (\<lambda>i. i + 1) n i + 1"
  1376     by (induct n) simp_all
  1377   from this [of 0] have "of_nat_aux (\<lambda>i. i + 1) n 1 = of_nat_aux (\<lambda>i. i + 1) n 0 + 1"
  1378     by simp
  1379   with Suc show ?case by (simp add: add_commute)
  1380 qed
  1381 
  1382 end
  1383 
  1384 declare of_nat_code [code]
  1385 
  1386 text{*Class for unital semirings with characteristic zero.
  1387  Includes non-ordered rings like the complex numbers.*}
  1388 
  1389 class semiring_char_0 = semiring_1 +
  1390   assumes inj_of_nat: "inj of_nat"
  1391 begin
  1392 
  1393 lemma of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1394   by (auto intro: inj_of_nat injD)
  1395 
  1396 text{*Special cases where either operand is zero*}
  1397 
  1398 lemma of_nat_0_eq_iff [simp, no_atp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1399   by (fact of_nat_eq_iff [of 0 n, unfolded of_nat_0])
  1400 
  1401 lemma of_nat_eq_0_iff [simp, no_atp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1402   by (fact of_nat_eq_iff [of m 0, unfolded of_nat_0])
  1403 
  1404 end
  1405 
  1406 context linordered_semidom
  1407 begin
  1408 
  1409 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1410   by (induct n) simp_all
  1411 
  1412 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1413   by (simp add: not_less)
  1414 
  1415 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1416   by (induct m n rule: diff_induct, simp_all add: add_pos_nonneg)
  1417 
  1418 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1419   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1420 
  1421 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1422   by simp
  1423 
  1424 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1425   by simp
  1426 
  1427 text{*Every @{text linordered_semidom} has characteristic zero.*}
  1428 
  1429 subclass semiring_char_0 proof
  1430 qed (auto intro!: injI simp add: eq_iff)
  1431 
  1432 text{*Special cases where either operand is zero*}
  1433 
  1434 lemma of_nat_le_0_iff [simp, no_atp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1435   by (rule of_nat_le_iff [of _ 0, simplified])
  1436 
  1437 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1438   by (rule of_nat_less_iff [of 0, simplified])
  1439 
  1440 end
  1441 
  1442 context ring_1
  1443 begin
  1444 
  1445 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1446 by (simp add: algebra_simps of_nat_add [symmetric])
  1447 
  1448 end
  1449 
  1450 context linordered_idom
  1451 begin
  1452 
  1453 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1454   unfolding abs_if by auto
  1455 
  1456 end
  1457 
  1458 lemma of_nat_id [simp]: "of_nat n = n"
  1459   by (induct n) simp_all
  1460 
  1461 lemma of_nat_eq_id [simp]: "of_nat = id"
  1462   by (auto simp add: fun_eq_iff)
  1463 
  1464 
  1465 subsection {* The Set of Natural Numbers *}
  1466 
  1467 context semiring_1
  1468 begin
  1469 
  1470 definition Nats  :: "'a set" where
  1471   "Nats = range of_nat"
  1472 
  1473 notation (xsymbols)
  1474   Nats  ("\<nat>")
  1475 
  1476 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1477   by (simp add: Nats_def)
  1478 
  1479 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1480 apply (simp add: Nats_def)
  1481 apply (rule range_eqI)
  1482 apply (rule of_nat_0 [symmetric])
  1483 done
  1484 
  1485 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1486 apply (simp add: Nats_def)
  1487 apply (rule range_eqI)
  1488 apply (rule of_nat_1 [symmetric])
  1489 done
  1490 
  1491 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1492 apply (auto simp add: Nats_def)
  1493 apply (rule range_eqI)
  1494 apply (rule of_nat_add [symmetric])
  1495 done
  1496 
  1497 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1498 apply (auto simp add: Nats_def)
  1499 apply (rule range_eqI)
  1500 apply (rule of_nat_mult [symmetric])
  1501 done
  1502 
  1503 lemma Nats_cases [cases set: Nats]:
  1504   assumes "x \<in> \<nat>"
  1505   obtains (of_nat) n where "x = of_nat n"
  1506   unfolding Nats_def
  1507 proof -
  1508   from `x \<in> \<nat>` have "x \<in> range of_nat" unfolding Nats_def .
  1509   then obtain n where "x = of_nat n" ..
  1510   then show thesis ..
  1511 qed
  1512 
  1513 lemma Nats_induct [case_names of_nat, induct set: Nats]:
  1514   "x \<in> \<nat> \<Longrightarrow> (\<And>n. P (of_nat n)) \<Longrightarrow> P x"
  1515   by (rule Nats_cases) auto
  1516 
  1517 end
  1518 
  1519 
  1520 subsection {* Further Arithmetic Facts Concerning the Natural Numbers *}
  1521 
  1522 lemma subst_equals:
  1523   assumes 1: "t = s" and 2: "u = t"
  1524   shows "u = s"
  1525   using 2 1 by (rule trans)
  1526 
  1527 setup Arith_Data.setup
  1528 
  1529 ML_file "Tools/nat_arith.ML"
  1530 
  1531 simproc_setup nateq_cancel_sums
  1532   ("(l::nat) + m = n" | "(l::nat) = m + n" | "Suc m = n" | "m = Suc n") =
  1533   {* fn phi => fn ss => try Nat_Arith.cancel_eq_conv *}
  1534 
  1535 simproc_setup natless_cancel_sums
  1536   ("(l::nat) + m < n" | "(l::nat) < m + n" | "Suc m < n" | "m < Suc n") =
  1537   {* fn phi => fn ss => try Nat_Arith.cancel_less_conv *}
  1538 
  1539 simproc_setup natle_cancel_sums
  1540   ("(l::nat) + m \<le> n" | "(l::nat) \<le> m + n" | "Suc m \<le> n" | "m \<le> Suc n") =
  1541   {* fn phi => fn ss => try Nat_Arith.cancel_le_conv *}
  1542 
  1543 simproc_setup natdiff_cancel_sums
  1544   ("(l::nat) + m - n" | "(l::nat) - (m + n)" | "Suc m - n" | "m - Suc n") =
  1545   {* fn phi => fn ss => try Nat_Arith.cancel_diff_conv *}
  1546 
  1547 ML_file "Tools/lin_arith.ML"
  1548 setup {* Lin_Arith.global_setup *}
  1549 declaration {* K Lin_Arith.setup *}
  1550 
  1551 simproc_setup fast_arith_nat ("(m::nat) < n" | "(m::nat) <= n" | "(m::nat) = n") =
  1552   {* fn _ => fn ss => fn ct => Lin_Arith.simproc ss (term_of ct) *}
  1553 (* Because of this simproc, the arithmetic solver is really only
  1554 useful to detect inconsistencies among the premises for subgoals which are
  1555 *not* themselves (in)equalities, because the latter activate
  1556 fast_nat_arith_simproc anyway. However, it seems cheaper to activate the
  1557 solver all the time rather than add the additional check. *)
  1558 
  1559 
  1560 lemmas [arith_split] = nat_diff_split split_min split_max
  1561 
  1562 context order
  1563 begin
  1564 
  1565 lemma lift_Suc_mono_le:
  1566   assumes mono: "!!n. f n \<le> f(Suc n)" and "n\<le>n'"
  1567   shows "f n \<le> f n'"
  1568 proof (cases "n < n'")
  1569   case True
  1570   thus ?thesis
  1571     by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1572 qed (insert `n \<le> n'`, auto) -- {*trivial for @{prop "n = n'"} *}
  1573 
  1574 lemma lift_Suc_mono_less:
  1575   assumes mono: "!!n. f n < f(Suc n)" and "n < n'"
  1576   shows "f n < f n'"
  1577 using `n < n'`
  1578 by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1579 
  1580 lemma lift_Suc_mono_less_iff:
  1581   "(!!n. f n < f(Suc n)) \<Longrightarrow> f(n) < f(m) \<longleftrightarrow> n<m"
  1582 by(blast intro: less_asym' lift_Suc_mono_less[of f]
  1583          dest: linorder_not_less[THEN iffD1] le_eq_less_or_eq[THEN iffD1])
  1584 
  1585 end
  1586 
  1587 lemma mono_iff_le_Suc: "mono f = (\<forall>n. f n \<le> f (Suc n))"
  1588   unfolding mono_def by (auto intro: lift_Suc_mono_le [of f])
  1589 
  1590 lemma mono_nat_linear_lb:
  1591   "(!!m n::nat. m<n \<Longrightarrow> f m < f n) \<Longrightarrow> f(m)+k \<le> f(m+k)"
  1592 apply(induct_tac k)
  1593  apply simp
  1594 apply(erule_tac x="m+n" in meta_allE)
  1595 apply(erule_tac x="Suc(m+n)" in meta_allE)
  1596 apply simp
  1597 done
  1598 
  1599 
  1600 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1601 
  1602 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1603 by arith
  1604 
  1605 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1606 by arith
  1607 
  1608 lemma less_diff_conv2:
  1609   fixes j k i :: nat
  1610   assumes "k \<le> j"
  1611   shows "j - k < i \<longleftrightarrow> j < i + k"
  1612   using assms by arith
  1613 
  1614 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1615 by arith
  1616 
  1617 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1618 by arith
  1619 
  1620 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1621 by arith
  1622 
  1623 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1624 by arith
  1625 
  1626 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1627   second premise n\<le>m*)
  1628 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1629 by arith
  1630 
  1631 text {* Simplification of relational expressions involving subtraction *}
  1632 
  1633 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1634 by (simp split add: nat_diff_split)
  1635 
  1636 hide_fact (open) diff_diff_eq
  1637 
  1638 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1639 by (auto split add: nat_diff_split)
  1640 
  1641 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1642 by (auto split add: nat_diff_split)
  1643 
  1644 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1645 by (auto split add: nat_diff_split)
  1646 
  1647 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1648 
  1649 (* Monotonicity of subtraction in first argument *)
  1650 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1651 by (simp split add: nat_diff_split)
  1652 
  1653 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1654 by (simp split add: nat_diff_split)
  1655 
  1656 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1657 by (simp split add: nat_diff_split)
  1658 
  1659 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1660 by (simp split add: nat_diff_split)
  1661 
  1662 lemma min_diff: "min (m - (i::nat)) (n - i) = min m n - i"
  1663 by auto
  1664 
  1665 lemma inj_on_diff_nat: 
  1666   assumes k_le_n: "\<forall>n \<in> N. k \<le> (n::nat)"
  1667   shows "inj_on (\<lambda>n. n - k) N"
  1668 proof (rule inj_onI)
  1669   fix x y
  1670   assume a: "x \<in> N" "y \<in> N" "x - k = y - k"
  1671   with k_le_n have "x - k + k = y - k + k" by auto
  1672   with a k_le_n show "x = y" by auto
  1673 qed
  1674 
  1675 text{*Rewriting to pull differences out*}
  1676 
  1677 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1678 by arith
  1679 
  1680 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1681 by arith
  1682 
  1683 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1684 by arith
  1685 
  1686 lemma Suc_diff_Suc: "n < m \<Longrightarrow> Suc (m - Suc n) = m - n"
  1687 by simp
  1688 
  1689 (*The others are
  1690       i - j - k = i - (j + k),
  1691       k \<le> j ==> j - k + i = j + i - k,
  1692       k \<le> j ==> i + (j - k) = i + j - k *)
  1693 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1694 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1695 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1696 
  1697 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1698 Least_Suc}, since there appears to be no need.*}
  1699 
  1700 text{*Lemmas for ex/Factorization*}
  1701 
  1702 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1703 by (cases m) auto
  1704 
  1705 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1706 by (cases m) auto
  1707 
  1708 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1709 by (cases m) auto
  1710 
  1711 text {* Specialized induction principles that work "backwards": *}
  1712 
  1713 lemma inc_induct[consumes 1, case_names base step]:
  1714   assumes less: "i <= j"
  1715   assumes base: "P j"
  1716   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1717   shows "P i"
  1718   using less
  1719 proof (induct d=="j - i" arbitrary: i)
  1720   case (0 i)
  1721   hence "i = j" by simp
  1722   with base show ?case by simp
  1723 next
  1724   case (Suc d i)
  1725   hence "i < j" "P (Suc i)"
  1726     by simp_all
  1727   thus "P i" by (rule step)
  1728 qed
  1729 
  1730 lemma strict_inc_induct[consumes 1, case_names base step]:
  1731   assumes less: "i < j"
  1732   assumes base: "!!i. j = Suc i ==> P i"
  1733   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1734   shows "P i"
  1735   using less
  1736 proof (induct d=="j - i - 1" arbitrary: i)
  1737   case (0 i)
  1738   with `i < j` have "j = Suc i" by simp
  1739   with base show ?case by simp
  1740 next
  1741   case (Suc d i)
  1742   hence "i < j" "P (Suc i)"
  1743     by simp_all
  1744   thus "P i" by (rule step)
  1745 qed
  1746 
  1747 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1748   using inc_induct[of "k - i" k P, simplified] by blast
  1749 
  1750 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1751   using inc_induct[of 0 k P] by blast
  1752 
  1753 text {* Further induction rule similar to @{thm inc_induct} *}
  1754 
  1755 lemma dec_induct[consumes 1, case_names base step]:
  1756   "i \<le> j \<Longrightarrow> P i \<Longrightarrow> (\<And>n. i \<le> n \<Longrightarrow> P n \<Longrightarrow> P (Suc n)) \<Longrightarrow> P j"
  1757   by (induct j arbitrary: i) (auto simp: le_Suc_eq)
  1758 
  1759  
  1760 subsection {* The divides relation on @{typ nat} *}
  1761 
  1762 lemma dvd_1_left [iff]: "Suc 0 dvd k"
  1763 unfolding dvd_def by simp
  1764 
  1765 lemma dvd_1_iff_1 [simp]: "(m dvd Suc 0) = (m = Suc 0)"
  1766 by (simp add: dvd_def)
  1767 
  1768 lemma nat_dvd_1_iff_1 [simp]: "m dvd (1::nat) \<longleftrightarrow> m = 1"
  1769 by (simp add: dvd_def)
  1770 
  1771 lemma dvd_antisym: "[| m dvd n; n dvd m |] ==> m = (n::nat)"
  1772   unfolding dvd_def
  1773   by (force dest: mult_eq_self_implies_10 simp add: mult_assoc)
  1774 
  1775 text {* @{term "op dvd"} is a partial order *}
  1776 
  1777 interpretation dvd: order "op dvd" "\<lambda>n m \<Colon> nat. n dvd m \<and> \<not> m dvd n"
  1778   proof qed (auto intro: dvd_refl dvd_trans dvd_antisym)
  1779 
  1780 lemma dvd_diff_nat[simp]: "[| k dvd m; k dvd n |] ==> k dvd (m-n :: nat)"
  1781 unfolding dvd_def
  1782 by (blast intro: diff_mult_distrib2 [symmetric])
  1783 
  1784 lemma dvd_diffD: "[| k dvd m-n; k dvd n; n\<le>m |] ==> k dvd (m::nat)"
  1785   apply (erule linorder_not_less [THEN iffD2, THEN add_diff_inverse, THEN subst])
  1786   apply (blast intro: dvd_add)
  1787   done
  1788 
  1789 lemma dvd_diffD1: "[| k dvd m-n; k dvd m; n\<le>m |] ==> k dvd (n::nat)"
  1790 by (drule_tac m = m in dvd_diff_nat, auto)
  1791 
  1792 lemma dvd_reduce: "(k dvd n + k) = (k dvd (n::nat))"
  1793   apply (rule iffI)
  1794    apply (erule_tac [2] dvd_add)
  1795    apply (rule_tac [2] dvd_refl)
  1796   apply (subgoal_tac "n = (n+k) -k")
  1797    prefer 2 apply simp
  1798   apply (erule ssubst)
  1799   apply (erule dvd_diff_nat)
  1800   apply (rule dvd_refl)
  1801   done
  1802 
  1803 lemma dvd_mult_cancel: "!!k::nat. [| k*m dvd k*n; 0<k |] ==> m dvd n"
  1804   unfolding dvd_def
  1805   apply (erule exE)
  1806   apply (simp add: mult_ac)
  1807   done
  1808 
  1809 lemma dvd_mult_cancel1: "0<m ==> (m*n dvd m) = (n = (1::nat))"
  1810   apply auto
  1811    apply (subgoal_tac "m*n dvd m*1")
  1812    apply (drule dvd_mult_cancel, auto)
  1813   done
  1814 
  1815 lemma dvd_mult_cancel2: "0<m ==> (n*m dvd m) = (n = (1::nat))"
  1816   apply (subst mult_commute)
  1817   apply (erule dvd_mult_cancel1)
  1818   done
  1819 
  1820 lemma dvd_imp_le: "[| k dvd n; 0 < n |] ==> k \<le> (n::nat)"
  1821 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1822 
  1823 lemma nat_dvd_not_less:
  1824   fixes m n :: nat
  1825   shows "0 < m \<Longrightarrow> m < n \<Longrightarrow> \<not> n dvd m"
  1826 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1827 
  1828 lemma dvd_plusE:
  1829   fixes m n q :: nat
  1830   assumes "m dvd n + q" "m dvd n"
  1831   obtains "m dvd q"
  1832 proof (cases "m = 0")
  1833   case True with assms that show thesis by simp
  1834 next
  1835   case False then have "m > 0" by simp
  1836   from assms obtain r s where "n = m * r" and "n + q = m * s" by (blast elim: dvdE)
  1837   then have *: "m * r + q = m * s" by simp
  1838   show thesis proof (cases "r \<le> s")
  1839     case False then have "s < r" by (simp add: not_le)
  1840     with * have "m * r + q - m * s = m * s - m * s" by simp
  1841     then have "m * r + q - m * s = 0" by simp
  1842     with `m > 0` `s < r` have "m * r - m * s + q = 0" by simp
  1843     then have "m * (r - s) + q = 0" by auto
  1844     then have "m * (r - s) = 0" by simp
  1845     then have "m = 0 \<or> r - s = 0" by simp
  1846     with `s < r` have "m = 0" by arith
  1847     with `m > 0` show thesis by auto
  1848   next
  1849     case True with * have "m * r + q - m * r = m * s - m * r" by simp
  1850     with `m > 0` `r \<le> s` have "m * r - m * r + q = m * s - m * r" by simp
  1851     then have "q = m * (s - r)" by (simp add: diff_mult_distrib2)
  1852     with assms that show thesis by (auto intro: dvdI)
  1853   qed
  1854 qed
  1855 
  1856 lemma dvd_plus_eq_right:
  1857   fixes m n q :: nat
  1858   assumes "m dvd n"
  1859   shows "m dvd n + q \<longleftrightarrow> m dvd q"
  1860   using assms by (auto elim: dvd_plusE)
  1861 
  1862 lemma dvd_plus_eq_left:
  1863   fixes m n q :: nat
  1864   assumes "m dvd q"
  1865   shows "m dvd n + q \<longleftrightarrow> m dvd n"
  1866   using assms by (simp add: dvd_plus_eq_right add_commute [of n])
  1867 
  1868 lemma less_dvd_minus:
  1869   fixes m n :: nat
  1870   assumes "m < n"
  1871   shows "m dvd n \<longleftrightarrow> m dvd (n - m)"
  1872 proof -
  1873   from assms have "n = m + (n - m)" by arith
  1874   then obtain q where "n = m + q" ..
  1875   then show ?thesis by (simp add: dvd_reduce add_commute [of m])
  1876 qed
  1877 
  1878 lemma dvd_minus_self:
  1879   fixes m n :: nat
  1880   shows "m dvd n - m \<longleftrightarrow> n < m \<or> m dvd n"
  1881   by (cases "n < m") (auto elim!: dvdE simp add: not_less le_imp_diff_is_add)
  1882 
  1883 lemma dvd_minus_add:
  1884   fixes m n q r :: nat
  1885   assumes "q \<le> n" "q \<le> r * m"
  1886   shows "m dvd n - q \<longleftrightarrow> m dvd n + (r * m - q)"
  1887 proof -
  1888   have "m dvd n - q \<longleftrightarrow> m dvd r * m + (n - q)"
  1889     by (auto elim: dvd_plusE)
  1890   also with assms have "\<dots> \<longleftrightarrow> m dvd r * m + n - q" by simp
  1891   also with assms have "\<dots> \<longleftrightarrow> m dvd (r * m - q) + n" by simp
  1892   also have "\<dots> \<longleftrightarrow> m dvd n + (r * m - q)" by (simp add: add_commute)
  1893   finally show ?thesis .
  1894 qed
  1895 
  1896 
  1897 subsection {* aliasses *}
  1898 
  1899 lemma nat_mult_1: "(1::nat) * n = n"
  1900   by simp
  1901  
  1902 lemma nat_mult_1_right: "n * (1::nat) = n"
  1903   by simp
  1904 
  1905 
  1906 subsection {* size of a datatype value *}
  1907 
  1908 class size =
  1909   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded} *}
  1910 
  1911 
  1912 subsection {* code module namespace *}
  1913 
  1914 code_identifier
  1915   code_module Nat \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
  1916 
  1917 hide_const (open) of_nat_aux
  1918 
  1919 end
  1920