src/HOL/Probability/Projective_Family.thy
author haftmann
Sun Jun 23 21:16:07 2013 +0200 (2013-06-23)
changeset 52435 6646bb548c6b
parent 50252 4aa34bd43228
child 53015 a1119cf551e8
permissions -rw-r--r--
migration from code_(const|type|class|instance) to code_printing and from code_module to code_identifier
     1 (*  Title:      HOL/Probability/Projective_Family.thy
     2     Author:     Fabian Immler, TU München
     3     Author:     Johannes Hölzl, TU München
     4 *)
     5 
     6 header {*Projective Family*}
     7 
     8 theory Projective_Family
     9 imports Finite_Product_Measure Probability_Measure
    10 begin
    11 
    12 lemma (in product_prob_space) distr_restrict:
    13   assumes "J \<noteq> {}" "J \<subseteq> K" "finite K"
    14   shows "(\<Pi>\<^isub>M i\<in>J. M i) = distr (\<Pi>\<^isub>M i\<in>K. M i) (\<Pi>\<^isub>M i\<in>J. M i) (\<lambda>f. restrict f J)" (is "?P = ?D")
    15 proof (rule measure_eqI_generator_eq)
    16   have "finite J" using `J \<subseteq> K` `finite K` by (auto simp add: finite_subset)
    17   interpret J: finite_product_prob_space M J proof qed fact
    18   interpret K: finite_product_prob_space M K proof qed fact
    19 
    20   let ?J = "{Pi\<^isub>E J E | E. \<forall>i\<in>J. E i \<in> sets (M i)}"
    21   let ?F = "\<lambda>i. \<Pi>\<^isub>E k\<in>J. space (M k)"
    22   let ?\<Omega> = "(\<Pi>\<^isub>E k\<in>J. space (M k))"
    23   show "Int_stable ?J"
    24     by (rule Int_stable_PiE)
    25   show "range ?F \<subseteq> ?J" "(\<Union>i. ?F i) = ?\<Omega>"
    26     using `finite J` by (auto intro!: prod_algebraI_finite)
    27   { fix i show "emeasure ?P (?F i) \<noteq> \<infinity>" by simp }
    28   show "?J \<subseteq> Pow ?\<Omega>" by (auto simp: Pi_iff dest: sets.sets_into_space)
    29   show "sets (\<Pi>\<^isub>M i\<in>J. M i) = sigma_sets ?\<Omega> ?J" "sets ?D = sigma_sets ?\<Omega> ?J"
    30     using `finite J` by (simp_all add: sets_PiM prod_algebra_eq_finite Pi_iff)
    31 
    32   fix X assume "X \<in> ?J"
    33   then obtain E where [simp]: "X = Pi\<^isub>E J E" and E: "\<forall>i\<in>J. E i \<in> sets (M i)" by auto
    34   with `finite J` have X: "X \<in> sets (Pi\<^isub>M J M)"
    35     by simp
    36 
    37   have "emeasure ?P X = (\<Prod> i\<in>J. emeasure (M i) (E i))"
    38     using E by (simp add: J.measure_times)
    39   also have "\<dots> = (\<Prod> i\<in>J. emeasure (M i) (if i \<in> J then E i else space (M i)))"
    40     by simp
    41   also have "\<dots> = (\<Prod> i\<in>K. emeasure (M i) (if i \<in> J then E i else space (M i)))"
    42     using `finite K` `J \<subseteq> K`
    43     by (intro setprod_mono_one_left) (auto simp: M.emeasure_space_1)
    44   also have "\<dots> = emeasure (Pi\<^isub>M K M) (\<Pi>\<^isub>E i\<in>K. if i \<in> J then E i else space (M i))"
    45     using E by (simp add: K.measure_times)
    46   also have "(\<Pi>\<^isub>E i\<in>K. if i \<in> J then E i else space (M i)) = (\<lambda>f. restrict f J) -` Pi\<^isub>E J E \<inter> (\<Pi>\<^isub>E i\<in>K. space (M i))"
    47     using `J \<subseteq> K` sets.sets_into_space E by (force simp: Pi_iff PiE_def split: split_if_asm)
    48   finally show "emeasure (Pi\<^isub>M J M) X = emeasure ?D X"
    49     using X `J \<subseteq> K` apply (subst emeasure_distr)
    50     by (auto intro!: measurable_restrict_subset simp: space_PiM)
    51 qed
    52 
    53 lemma (in product_prob_space) emeasure_prod_emb[simp]:
    54   assumes L: "J \<noteq> {}" "J \<subseteq> L" "finite L" and X: "X \<in> sets (Pi\<^isub>M J M)"
    55   shows "emeasure (Pi\<^isub>M L M) (prod_emb L M J X) = emeasure (Pi\<^isub>M J M) X"
    56   by (subst distr_restrict[OF L])
    57      (simp add: prod_emb_def space_PiM emeasure_distr measurable_restrict_subset L X)
    58 
    59 definition
    60   limP :: "'i set \<Rightarrow> ('i \<Rightarrow> 'a measure) \<Rightarrow> ('i set \<Rightarrow> ('i \<Rightarrow> 'a) measure) \<Rightarrow> ('i \<Rightarrow> 'a) measure" where
    61   "limP I M P = extend_measure (\<Pi>\<^isub>E i\<in>I. space (M i))
    62     {(J, X). (J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> (\<Pi> j\<in>J. sets (M j))}
    63     (\<lambda>(J, X). prod_emb I M J (\<Pi>\<^isub>E j\<in>J. X j))
    64     (\<lambda>(J, X). emeasure (P J) (Pi\<^isub>E J X))"
    65 
    66 abbreviation "lim\<^isub>P \<equiv> limP"
    67 
    68 lemma space_limP[simp]: "space (limP I M P) = space (PiM I M)"
    69   by (auto simp add: limP_def space_PiM prod_emb_def intro!: space_extend_measure)
    70 
    71 lemma sets_limP[simp]: "sets (limP I M P) = sets (PiM I M)"
    72   by (auto simp add: limP_def sets_PiM prod_algebra_def prod_emb_def intro!: sets_extend_measure)
    73 
    74 lemma measurable_limP1[simp]: "measurable (limP I M P) M' = measurable (\<Pi>\<^isub>M i\<in>I. M i) M'"
    75   unfolding measurable_def by auto
    76 
    77 lemma measurable_limP2[simp]: "measurable M' (limP I M P) = measurable M' (\<Pi>\<^isub>M i\<in>I. M i)"
    78   unfolding measurable_def by auto
    79 
    80 locale projective_family =
    81   fixes I::"'i set" and P::"'i set \<Rightarrow> ('i \<Rightarrow> 'a) measure" and M::"('i \<Rightarrow> 'a measure)"
    82   assumes projective: "\<And>J H X. J \<noteq> {} \<Longrightarrow> J \<subseteq> H \<Longrightarrow> H \<subseteq> I \<Longrightarrow> finite H \<Longrightarrow> X \<in> sets (PiM J M) \<Longrightarrow>
    83      (P H) (prod_emb H M J X) = (P J) X"
    84   assumes proj_prob_space: "\<And>J. finite J \<Longrightarrow> prob_space (P J)"
    85   assumes proj_space: "\<And>J. finite J \<Longrightarrow> space (P J) = space (PiM J M)"
    86   assumes proj_sets: "\<And>J. finite J \<Longrightarrow> sets (P J) = sets (PiM J M)"
    87 begin
    88 
    89 lemma emeasure_limP:
    90   assumes "finite J"
    91   assumes "J \<subseteq> I"
    92   assumes A: "\<And>i. i\<in>J \<Longrightarrow> A i \<in> sets (M i)"
    93   shows "emeasure (limP J M P) (Pi\<^isub>E J A) = emeasure (P J) (Pi\<^isub>E J A)"
    94 proof -
    95   have "Pi\<^isub>E J (restrict A J) \<subseteq> (\<Pi>\<^isub>E i\<in>J. space (M i))"
    96     using sets.sets_into_space[OF A] by (auto simp: PiE_iff) blast
    97   hence "emeasure (limP J M P) (Pi\<^isub>E J A) =
    98     emeasure (limP J M P) (prod_emb J M J (Pi\<^isub>E J A))"
    99     using assms(1-3) sets.sets_into_space by (auto simp add: prod_emb_id PiE_def Pi_def)
   100   also have "\<dots> = emeasure (P J) (Pi\<^isub>E J A)"
   101   proof (rule emeasure_extend_measure_Pair[OF limP_def])
   102     show "positive (sets (limP J M P)) (P J)" unfolding positive_def by auto
   103     show "countably_additive (sets (limP J M P)) (P J)" unfolding countably_additive_def
   104       by (auto simp: suminf_emeasure proj_sets[OF `finite J`])
   105     show "(J \<noteq> {} \<or> J = {}) \<and> finite J \<and> J \<subseteq> J \<and> A \<in> (\<Pi> j\<in>J. sets (M j))"
   106       using assms by auto
   107     fix K and X::"'i \<Rightarrow> 'a set"
   108     show "prod_emb J M K (Pi\<^isub>E K X) \<in> Pow (\<Pi>\<^isub>E i\<in>J. space (M i))"
   109       by (auto simp: prod_emb_def)
   110     assume JX: "(K \<noteq> {} \<or> J = {}) \<and> finite K \<and> K \<subseteq> J \<and> X \<in> (\<Pi> j\<in>K. sets (M j))"
   111     thus "emeasure (P J) (prod_emb J M K (Pi\<^isub>E K X)) = emeasure (P K) (Pi\<^isub>E K X)"
   112       using assms
   113       apply (cases "J = {}")
   114       apply (simp add: prod_emb_id)
   115       apply (fastforce simp add: intro!: projective sets_PiM_I_finite)
   116       done
   117   qed
   118   finally show ?thesis .
   119 qed
   120 
   121 lemma limP_finite:
   122   assumes "finite J"
   123   assumes "J \<subseteq> I"
   124   shows "limP J M P = P J" (is "?P = _")
   125 proof (rule measure_eqI_generator_eq)
   126   let ?J = "{Pi\<^isub>E J E | E. \<forall>i\<in>J. E i \<in> sets (M i)}"
   127   let ?\<Omega> = "(\<Pi>\<^isub>E k\<in>J. space (M k))"
   128   interpret prob_space "P J" using proj_prob_space `finite J` by simp
   129   show "emeasure ?P (\<Pi>\<^isub>E k\<in>J. space (M k)) \<noteq> \<infinity>" using assms `finite J` by (auto simp: emeasure_limP)
   130   show "sets (limP J M P) = sigma_sets ?\<Omega> ?J" "sets (P J) = sigma_sets ?\<Omega> ?J"
   131     using `finite J` proj_sets by (simp_all add: sets_PiM prod_algebra_eq_finite Pi_iff)
   132   fix X assume "X \<in> ?J"
   133   then obtain E where X: "X = Pi\<^isub>E J E" and E: "\<forall>i\<in>J. E i \<in> sets (M i)" by auto
   134   with `finite J` have "X \<in> sets (limP J M P)" by simp
   135   have emb_self: "prod_emb J M J (Pi\<^isub>E J E) = Pi\<^isub>E J E"
   136     using E sets.sets_into_space
   137     by (auto intro!: prod_emb_PiE_same_index)
   138   show "emeasure (limP J M P) X = emeasure (P J) X"
   139     unfolding X using E
   140     by (intro emeasure_limP assms) simp
   141 qed (auto simp: Pi_iff dest: sets.sets_into_space intro: Int_stable_PiE)
   142 
   143 lemma emeasure_fun_emb[simp]:
   144   assumes L: "J \<noteq> {}" "J \<subseteq> L" "finite L" "L \<subseteq> I" and X: "X \<in> sets (PiM J M)"
   145   shows "emeasure (limP L M P) (prod_emb L M J X) = emeasure (limP J M P) X"
   146   using assms
   147   by (subst limP_finite) (auto simp: limP_finite finite_subset projective)
   148 
   149 abbreviation
   150   "emb L K X \<equiv> prod_emb L M K X"
   151 
   152 lemma prod_emb_injective:
   153   assumes "J \<subseteq> L" and sets: "X \<in> sets (Pi\<^isub>M J M)" "Y \<in> sets (Pi\<^isub>M J M)"
   154   assumes "emb L J X = emb L J Y"
   155   shows "X = Y"
   156 proof (rule injective_vimage_restrict)
   157   show "X \<subseteq> (\<Pi>\<^isub>E i\<in>J. space (M i))" "Y \<subseteq> (\<Pi>\<^isub>E i\<in>J. space (M i))"
   158     using sets[THEN sets.sets_into_space] by (auto simp: space_PiM)
   159   have "\<forall>i\<in>L. \<exists>x. x \<in> space (M i)"
   160   proof
   161     fix i assume "i \<in> L"
   162     interpret prob_space "P {i}" using proj_prob_space by simp
   163     from not_empty show "\<exists>x. x \<in> space (M i)" by (auto simp add: proj_space space_PiM)
   164   qed
   165   from bchoice[OF this]
   166   show "(\<Pi>\<^isub>E i\<in>L. space (M i)) \<noteq> {}" by (auto simp: PiE_def)
   167   show "(\<lambda>x. restrict x J) -` X \<inter> (\<Pi>\<^isub>E i\<in>L. space (M i)) = (\<lambda>x. restrict x J) -` Y \<inter> (\<Pi>\<^isub>E i\<in>L. space (M i))"
   168     using `prod_emb L M J X = prod_emb L M J Y` by (simp add: prod_emb_def)
   169 qed fact
   170 
   171 definition generator :: "('i \<Rightarrow> 'a) set set" where
   172   "generator = (\<Union>J\<in>{J. J \<noteq> {} \<and> finite J \<and> J \<subseteq> I}. emb I J ` sets (Pi\<^isub>M J M))"
   173 
   174 lemma generatorI':
   175   "J \<noteq> {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> X \<in> sets (Pi\<^isub>M J M) \<Longrightarrow> emb I J X \<in> generator"
   176   unfolding generator_def by auto
   177 
   178 lemma algebra_generator:
   179   assumes "I \<noteq> {}" shows "algebra (\<Pi>\<^isub>E i\<in>I. space (M i)) generator" (is "algebra ?\<Omega> ?G")
   180   unfolding algebra_def algebra_axioms_def ring_of_sets_iff
   181 proof (intro conjI ballI)
   182   let ?G = generator
   183   show "?G \<subseteq> Pow ?\<Omega>"
   184     by (auto simp: generator_def prod_emb_def)
   185   from `I \<noteq> {}` obtain i where "i \<in> I" by auto
   186   then show "{} \<in> ?G"
   187     by (auto intro!: exI[of _ "{i}"] image_eqI[where x="\<lambda>i. {}"]
   188              simp: sigma_sets.Empty generator_def prod_emb_def)
   189   from `i \<in> I` show "?\<Omega> \<in> ?G"
   190     by (auto intro!: exI[of _ "{i}"] image_eqI[where x="Pi\<^isub>E {i} (\<lambda>i. space (M i))"]
   191              simp: generator_def prod_emb_def)
   192   fix A assume "A \<in> ?G"
   193   then obtain JA XA where XA: "JA \<noteq> {}" "finite JA" "JA \<subseteq> I" "XA \<in> sets (Pi\<^isub>M JA M)" and A: "A = emb I JA XA"
   194     by (auto simp: generator_def)
   195   fix B assume "B \<in> ?G"
   196   then obtain JB XB where XB: "JB \<noteq> {}" "finite JB" "JB \<subseteq> I" "XB \<in> sets (Pi\<^isub>M JB M)" and B: "B = emb I JB XB"
   197     by (auto simp: generator_def)
   198   let ?RA = "emb (JA \<union> JB) JA XA"
   199   let ?RB = "emb (JA \<union> JB) JB XB"
   200   have *: "A - B = emb I (JA \<union> JB) (?RA - ?RB)" "A \<union> B = emb I (JA \<union> JB) (?RA \<union> ?RB)"
   201     using XA A XB B by auto
   202   show "A - B \<in> ?G" "A \<union> B \<in> ?G"
   203     unfolding * using XA XB by (safe intro!: generatorI') auto
   204 qed
   205 
   206 lemma sets_PiM_generator:
   207   "sets (PiM I M) = sigma_sets (\<Pi>\<^isub>E i\<in>I. space (M i)) generator"
   208 proof cases
   209   assume "I = {}" then show ?thesis
   210     unfolding generator_def
   211     by (auto simp: sets_PiM_empty sigma_sets_empty_eq cong: conj_cong)
   212 next
   213   assume "I \<noteq> {}"
   214   show ?thesis
   215   proof
   216     show "sets (Pi\<^isub>M I M) \<subseteq> sigma_sets (\<Pi>\<^isub>E i\<in>I. space (M i)) generator"
   217       unfolding sets_PiM
   218     proof (safe intro!: sigma_sets_subseteq)
   219       fix A assume "A \<in> prod_algebra I M" with `I \<noteq> {}` show "A \<in> generator"
   220         by (auto intro!: generatorI' sets_PiM_I_finite elim!: prod_algebraE)
   221     qed
   222   qed (auto simp: generator_def space_PiM[symmetric] intro!: sets.sigma_sets_subset)
   223 qed
   224 
   225 lemma generatorI:
   226   "J \<noteq> {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> X \<in> sets (Pi\<^isub>M J M) \<Longrightarrow> A = emb I J X \<Longrightarrow> A \<in> generator"
   227   unfolding generator_def by auto
   228 
   229 definition mu_G ("\<mu>G") where
   230   "\<mu>G A =
   231     (THE x. \<forall>J. J \<noteq> {} \<longrightarrow> finite J \<longrightarrow> J \<subseteq> I \<longrightarrow> (\<forall>X\<in>sets (Pi\<^isub>M J M). A = emb I J X \<longrightarrow> x = emeasure (limP J M P) X))"
   232 
   233 lemma mu_G_spec:
   234   assumes J: "J \<noteq> {}" "finite J" "J \<subseteq> I" "A = emb I J X" "X \<in> sets (Pi\<^isub>M J M)"
   235   shows "\<mu>G A = emeasure (limP J M P) X"
   236   unfolding mu_G_def
   237 proof (intro the_equality allI impI ballI)
   238   fix K Y assume K: "K \<noteq> {}" "finite K" "K \<subseteq> I" "A = emb I K Y" "Y \<in> sets (Pi\<^isub>M K M)"
   239   have "emeasure (limP K M P) Y = emeasure (limP (K \<union> J) M P) (emb (K \<union> J) K Y)"
   240     using K J by simp
   241   also have "emb (K \<union> J) K Y = emb (K \<union> J) J X"
   242     using K J by (simp add: prod_emb_injective[of "K \<union> J" I])
   243   also have "emeasure (limP (K \<union> J) M P) (emb (K \<union> J) J X) = emeasure (limP J M P) X"
   244     using K J by simp
   245   finally show "emeasure (limP J M P) X = emeasure (limP K M P) Y" ..
   246 qed (insert J, force)
   247 
   248 lemma mu_G_eq:
   249   "J \<noteq> {} \<Longrightarrow> finite J \<Longrightarrow> J \<subseteq> I \<Longrightarrow> X \<in> sets (Pi\<^isub>M J M) \<Longrightarrow> \<mu>G (emb I J X) = emeasure (limP J M P) X"
   250   by (intro mu_G_spec) auto
   251 
   252 lemma generator_Ex:
   253   assumes *: "A \<in> generator"
   254   shows "\<exists>J X. J \<noteq> {} \<and> finite J \<and> J \<subseteq> I \<and> X \<in> sets (Pi\<^isub>M J M) \<and> A = emb I J X \<and> \<mu>G A = emeasure (limP J M P) X"
   255 proof -
   256   from * obtain J X where J: "J \<noteq> {}" "finite J" "J \<subseteq> I" "A = emb I J X" "X \<in> sets (Pi\<^isub>M J M)"
   257     unfolding generator_def by auto
   258   with mu_G_spec[OF this] show ?thesis by auto
   259 qed
   260 
   261 lemma generatorE:
   262   assumes A: "A \<in> generator"
   263   obtains J X where "J \<noteq> {}" "finite J" "J \<subseteq> I" "X \<in> sets (Pi\<^isub>M J M)" "emb I J X = A" "\<mu>G A = emeasure (limP J M P) X"
   264   using generator_Ex[OF A] by atomize_elim auto
   265 
   266 lemma merge_sets:
   267   "J \<inter> K = {} \<Longrightarrow> A \<in> sets (Pi\<^isub>M (J \<union> K) M) \<Longrightarrow> x \<in> space (Pi\<^isub>M J M) \<Longrightarrow> (\<lambda>y. merge J K (x,y)) -` A \<inter> space (Pi\<^isub>M K M) \<in> sets (Pi\<^isub>M K M)"
   268   by simp
   269 
   270 lemma merge_emb:
   271   assumes "K \<subseteq> I" "J \<subseteq> I" and y: "y \<in> space (Pi\<^isub>M J M)"
   272   shows "((\<lambda>x. merge J (I - J) (y, x)) -` emb I K X \<inter> space (Pi\<^isub>M I M)) =
   273     emb I (K - J) ((\<lambda>x. merge J (K - J) (y, x)) -` emb (J \<union> K) K X \<inter> space (Pi\<^isub>M (K - J) M))"
   274 proof -
   275   have [simp]: "\<And>x J K L. merge J K (y, restrict x L) = merge J (K \<inter> L) (y, x)"
   276     by (auto simp: restrict_def merge_def)
   277   have [simp]: "\<And>x J K L. restrict (merge J K (y, x)) L = merge (J \<inter> L) (K \<inter> L) (y, x)"
   278     by (auto simp: restrict_def merge_def)
   279   have [simp]: "(I - J) \<inter> K = K - J" using `K \<subseteq> I` `J \<subseteq> I` by auto
   280   have [simp]: "(K - J) \<inter> (K \<union> J) = K - J" by auto
   281   have [simp]: "(K - J) \<inter> K = K - J" by auto
   282   from y `K \<subseteq> I` `J \<subseteq> I` show ?thesis
   283     by (simp split: split_merge add: prod_emb_def Pi_iff PiE_def extensional_merge_sub set_eq_iff space_PiM)
   284        auto
   285 qed
   286 
   287 lemma positive_mu_G:
   288   assumes "I \<noteq> {}"
   289   shows "positive generator \<mu>G"
   290 proof -
   291   interpret G!: algebra "\<Pi>\<^isub>E i\<in>I. space (M i)" generator by (rule algebra_generator) fact
   292   show ?thesis
   293   proof (intro positive_def[THEN iffD2] conjI ballI)
   294     from generatorE[OF G.empty_sets] guess J X . note this[simp]
   295     have "X = {}"
   296       by (rule prod_emb_injective[of J I]) simp_all
   297     then show "\<mu>G {} = 0" by simp
   298   next
   299     fix A assume "A \<in> generator"
   300     from generatorE[OF this] guess J X . note this[simp]
   301     show "0 \<le> \<mu>G A" by (simp add: emeasure_nonneg)
   302   qed
   303 qed
   304 
   305 lemma additive_mu_G:
   306   assumes "I \<noteq> {}"
   307   shows "additive generator \<mu>G"
   308 proof -
   309   interpret G!: algebra "\<Pi>\<^isub>E i\<in>I. space (M i)" generator by (rule algebra_generator) fact
   310   show ?thesis
   311   proof (intro additive_def[THEN iffD2] ballI impI)
   312     fix A assume "A \<in> generator" with generatorE guess J X . note J = this
   313     fix B assume "B \<in> generator" with generatorE guess K Y . note K = this
   314     assume "A \<inter> B = {}"
   315     have JK: "J \<union> K \<noteq> {}" "J \<union> K \<subseteq> I" "finite (J \<union> K)"
   316       using J K by auto
   317     have JK_disj: "emb (J \<union> K) J X \<inter> emb (J \<union> K) K Y = {}"
   318       apply (rule prod_emb_injective[of "J \<union> K" I])
   319       apply (insert `A \<inter> B = {}` JK J K)
   320       apply (simp_all add: sets.Int prod_emb_Int)
   321       done
   322     have AB: "A = emb I (J \<union> K) (emb (J \<union> K) J X)" "B = emb I (J \<union> K) (emb (J \<union> K) K Y)"
   323       using J K by simp_all
   324     then have "\<mu>G (A \<union> B) = \<mu>G (emb I (J \<union> K) (emb (J \<union> K) J X \<union> emb (J \<union> K) K Y))"
   325       by simp
   326     also have "\<dots> = emeasure (limP (J \<union> K) M P) (emb (J \<union> K) J X \<union> emb (J \<union> K) K Y)"
   327       using JK J(1, 4) K(1, 4) by (simp add: mu_G_eq sets.Un del: prod_emb_Un)
   328     also have "\<dots> = \<mu>G A + \<mu>G B"
   329       using J K JK_disj by (simp add: plus_emeasure[symmetric])
   330     finally show "\<mu>G (A \<union> B) = \<mu>G A + \<mu>G B" .
   331   qed
   332 qed
   333 
   334 end
   335 
   336 sublocale product_prob_space \<subseteq> projective_family I "\<lambda>J. PiM J M" M
   337 proof
   338   fix J::"'i set" assume "finite J"
   339   interpret f: finite_product_prob_space M J proof qed fact
   340   show "emeasure (Pi\<^isub>M J M) (space (Pi\<^isub>M J M)) \<noteq> \<infinity>" by simp
   341   show "\<exists>A. range A \<subseteq> sets (Pi\<^isub>M J M) \<and>
   342             (\<Union>i. A i) = space (Pi\<^isub>M J M) \<and>
   343             (\<forall>i. emeasure (Pi\<^isub>M J M) (A i) \<noteq> \<infinity>)" using sigma_finite[OF `finite J`]
   344     by (auto simp add: sigma_finite_measure_def)
   345   show "emeasure (Pi\<^isub>M J M) (space (Pi\<^isub>M J M)) = 1" by (rule f.emeasure_space_1)
   346 qed simp_all
   347 
   348 lemma (in product_prob_space) limP_PiM_finite[simp]:
   349   assumes "J \<noteq> {}" "finite J" "J \<subseteq> I" shows "limP J M (\<lambda>J. PiM J M) = PiM J M"
   350   using assms by (simp add: limP_finite)
   351 
   352 end