src/HOL/Rat.thy
author haftmann
Sun Jun 23 21:16:07 2013 +0200 (2013-06-23)
changeset 52435 6646bb548c6b
parent 52146 ceb31e1ded30
child 53012 cb82606b8215
child 53015 a1119cf551e8
permissions -rw-r--r--
migration from code_(const|type|class|instance) to code_printing and from code_module to code_identifier
     1 (*  Title:  HOL/Rat.thy
     2     Author: Markus Wenzel, TU Muenchen
     3 *)
     4 
     5 header {* Rational numbers *}
     6 
     7 theory Rat
     8 imports GCD Archimedean_Field
     9 begin
    10 
    11 subsection {* Rational numbers as quotient *}
    12 
    13 subsubsection {* Construction of the type of rational numbers *}
    14 
    15 definition
    16   ratrel :: "(int \<times> int) \<Rightarrow> (int \<times> int) \<Rightarrow> bool" where
    17   "ratrel = (\<lambda>x y. snd x \<noteq> 0 \<and> snd y \<noteq> 0 \<and> fst x * snd y = fst y * snd x)"
    18 
    19 lemma ratrel_iff [simp]:
    20   "ratrel x y \<longleftrightarrow> snd x \<noteq> 0 \<and> snd y \<noteq> 0 \<and> fst x * snd y = fst y * snd x"
    21   by (simp add: ratrel_def)
    22 
    23 lemma exists_ratrel_refl: "\<exists>x. ratrel x x"
    24   by (auto intro!: one_neq_zero)
    25 
    26 lemma symp_ratrel: "symp ratrel"
    27   by (simp add: ratrel_def symp_def)
    28 
    29 lemma transp_ratrel: "transp ratrel"
    30 proof (rule transpI, unfold split_paired_all)
    31   fix a b a' b' a'' b'' :: int
    32   assume A: "ratrel (a, b) (a', b')"
    33   assume B: "ratrel (a', b') (a'', b'')"
    34   have "b' * (a * b'') = b'' * (a * b')" by simp
    35   also from A have "a * b' = a' * b" by auto
    36   also have "b'' * (a' * b) = b * (a' * b'')" by simp
    37   also from B have "a' * b'' = a'' * b'" by auto
    38   also have "b * (a'' * b') = b' * (a'' * b)" by simp
    39   finally have "b' * (a * b'') = b' * (a'' * b)" .
    40   moreover from B have "b' \<noteq> 0" by auto
    41   ultimately have "a * b'' = a'' * b" by simp
    42   with A B show "ratrel (a, b) (a'', b'')" by auto
    43 qed
    44 
    45 lemma part_equivp_ratrel: "part_equivp ratrel"
    46   by (rule part_equivpI [OF exists_ratrel_refl symp_ratrel transp_ratrel])
    47 
    48 quotient_type rat = "int \<times> int" / partial: "ratrel"
    49   morphisms Rep_Rat Abs_Rat
    50   by (rule part_equivp_ratrel)
    51 
    52 lemma Domainp_cr_rat [transfer_domain_rule]: "Domainp cr_rat = (\<lambda>x. snd x \<noteq> 0)"
    53 by (simp add: rat.domain)
    54 
    55 subsubsection {* Representation and basic operations *}
    56 
    57 lift_definition Fract :: "int \<Rightarrow> int \<Rightarrow> rat"
    58   is "\<lambda>a b. if b = 0 then (0, 1) else (a, b)"
    59   by simp
    60 
    61 lemma eq_rat:
    62   shows "\<And>a b c d. b \<noteq> 0 \<Longrightarrow> d \<noteq> 0 \<Longrightarrow> Fract a b = Fract c d \<longleftrightarrow> a * d = c * b"
    63   and "\<And>a. Fract a 0 = Fract 0 1"
    64   and "\<And>a c. Fract 0 a = Fract 0 c"
    65   by (transfer, simp)+
    66 
    67 lemma Rat_cases [case_names Fract, cases type: rat]:
    68   assumes "\<And>a b. q = Fract a b \<Longrightarrow> b > 0 \<Longrightarrow> coprime a b \<Longrightarrow> C"
    69   shows C
    70 proof -
    71   obtain a b :: int where "q = Fract a b" and "b \<noteq> 0"
    72     by transfer simp
    73   let ?a = "a div gcd a b"
    74   let ?b = "b div gcd a b"
    75   from `b \<noteq> 0` have "?b * gcd a b = b"
    76     by (simp add: dvd_div_mult_self)
    77   with `b \<noteq> 0` have "?b \<noteq> 0" by auto
    78   from `q = Fract a b` `b \<noteq> 0` `?b \<noteq> 0` have q: "q = Fract ?a ?b"
    79     by (simp add: eq_rat dvd_div_mult mult_commute [of a])
    80   from `b \<noteq> 0` have coprime: "coprime ?a ?b"
    81     by (auto intro: div_gcd_coprime_int)
    82   show C proof (cases "b > 0")
    83     case True
    84     note assms
    85     moreover note q
    86     moreover from True have "?b > 0" by (simp add: nonneg1_imp_zdiv_pos_iff)
    87     moreover note coprime
    88     ultimately show C .
    89   next
    90     case False
    91     note assms
    92     moreover have "q = Fract (- ?a) (- ?b)" unfolding q by transfer simp
    93     moreover from False `b \<noteq> 0` have "- ?b > 0" by (simp add: pos_imp_zdiv_neg_iff)
    94     moreover from coprime have "coprime (- ?a) (- ?b)" by simp
    95     ultimately show C .
    96   qed
    97 qed
    98 
    99 lemma Rat_induct [case_names Fract, induct type: rat]:
   100   assumes "\<And>a b. b > 0 \<Longrightarrow> coprime a b \<Longrightarrow> P (Fract a b)"
   101   shows "P q"
   102   using assms by (cases q) simp
   103 
   104 instantiation rat :: field_inverse_zero
   105 begin
   106 
   107 lift_definition zero_rat :: "rat" is "(0, 1)"
   108   by simp
   109 
   110 lift_definition one_rat :: "rat" is "(1, 1)"
   111   by simp
   112 
   113 lemma Zero_rat_def: "0 = Fract 0 1"
   114   by transfer simp
   115 
   116 lemma One_rat_def: "1 = Fract 1 1"
   117   by transfer simp
   118 
   119 lift_definition plus_rat :: "rat \<Rightarrow> rat \<Rightarrow> rat"
   120   is "\<lambda>x y. (fst x * snd y + fst y * snd x, snd x * snd y)"
   121   by (clarsimp, simp add: distrib_right, simp add: mult_ac)
   122 
   123 lemma add_rat [simp]:
   124   assumes "b \<noteq> 0" and "d \<noteq> 0"
   125   shows "Fract a b + Fract c d = Fract (a * d + c * b) (b * d)"
   126   using assms by transfer simp
   127 
   128 lift_definition uminus_rat :: "rat \<Rightarrow> rat" is "\<lambda>x. (- fst x, snd x)"
   129   by simp
   130 
   131 lemma minus_rat [simp]: "- Fract a b = Fract (- a) b"
   132   by transfer simp
   133 
   134 lemma minus_rat_cancel [simp]: "Fract (- a) (- b) = Fract a b"
   135   by (cases "b = 0") (simp_all add: eq_rat)
   136 
   137 definition
   138   diff_rat_def: "q - r = q + - (r::rat)"
   139 
   140 lemma diff_rat [simp]:
   141   assumes "b \<noteq> 0" and "d \<noteq> 0"
   142   shows "Fract a b - Fract c d = Fract (a * d - c * b) (b * d)"
   143   using assms by (simp add: diff_rat_def)
   144 
   145 lift_definition times_rat :: "rat \<Rightarrow> rat \<Rightarrow> rat"
   146   is "\<lambda>x y. (fst x * fst y, snd x * snd y)"
   147   by (simp add: mult_ac)
   148 
   149 lemma mult_rat [simp]: "Fract a b * Fract c d = Fract (a * c) (b * d)"
   150   by transfer simp
   151 
   152 lemma mult_rat_cancel:
   153   assumes "c \<noteq> 0"
   154   shows "Fract (c * a) (c * b) = Fract a b"
   155   using assms by transfer simp
   156 
   157 lift_definition inverse_rat :: "rat \<Rightarrow> rat"
   158   is "\<lambda>x. if fst x = 0 then (0, 1) else (snd x, fst x)"
   159   by (auto simp add: mult_commute)
   160 
   161 lemma inverse_rat [simp]: "inverse (Fract a b) = Fract b a"
   162   by transfer simp
   163 
   164 definition
   165   divide_rat_def: "q / r = q * inverse (r::rat)"
   166 
   167 lemma divide_rat [simp]: "Fract a b / Fract c d = Fract (a * d) (b * c)"
   168   by (simp add: divide_rat_def)
   169 
   170 instance proof
   171   fix q r s :: rat
   172   show "(q * r) * s = q * (r * s)"
   173     by transfer simp
   174   show "q * r = r * q"
   175     by transfer simp
   176   show "1 * q = q"
   177     by transfer simp
   178   show "(q + r) + s = q + (r + s)"
   179     by transfer (simp add: algebra_simps)
   180   show "q + r = r + q"
   181     by transfer simp
   182   show "0 + q = q"
   183     by transfer simp
   184   show "- q + q = 0"
   185     by transfer simp
   186   show "q - r = q + - r"
   187     by (fact diff_rat_def)
   188   show "(q + r) * s = q * s + r * s"
   189     by transfer (simp add: algebra_simps)
   190   show "(0::rat) \<noteq> 1"
   191     by transfer simp
   192   { assume "q \<noteq> 0" thus "inverse q * q = 1"
   193     by transfer simp }
   194   show "q / r = q * inverse r"
   195     by (fact divide_rat_def)
   196   show "inverse 0 = (0::rat)"
   197     by transfer simp
   198 qed
   199 
   200 end
   201 
   202 lemma of_nat_rat: "of_nat k = Fract (of_nat k) 1"
   203   by (induct k) (simp_all add: Zero_rat_def One_rat_def)
   204 
   205 lemma of_int_rat: "of_int k = Fract k 1"
   206   by (cases k rule: int_diff_cases) (simp add: of_nat_rat)
   207 
   208 lemma Fract_of_nat_eq: "Fract (of_nat k) 1 = of_nat k"
   209   by (rule of_nat_rat [symmetric])
   210 
   211 lemma Fract_of_int_eq: "Fract k 1 = of_int k"
   212   by (rule of_int_rat [symmetric])
   213 
   214 lemma rat_number_collapse:
   215   "Fract 0 k = 0"
   216   "Fract 1 1 = 1"
   217   "Fract (numeral w) 1 = numeral w"
   218   "Fract (neg_numeral w) 1 = neg_numeral w"
   219   "Fract k 0 = 0"
   220   using Fract_of_int_eq [of "numeral w"]
   221   using Fract_of_int_eq [of "neg_numeral w"]
   222   by (simp_all add: Zero_rat_def One_rat_def eq_rat)
   223 
   224 lemma rat_number_expand:
   225   "0 = Fract 0 1"
   226   "1 = Fract 1 1"
   227   "numeral k = Fract (numeral k) 1"
   228   "neg_numeral k = Fract (neg_numeral k) 1"
   229   by (simp_all add: rat_number_collapse)
   230 
   231 lemma Rat_cases_nonzero [case_names Fract 0]:
   232   assumes Fract: "\<And>a b. q = Fract a b \<Longrightarrow> b > 0 \<Longrightarrow> a \<noteq> 0 \<Longrightarrow> coprime a b \<Longrightarrow> C"
   233   assumes 0: "q = 0 \<Longrightarrow> C"
   234   shows C
   235 proof (cases "q = 0")
   236   case True then show C using 0 by auto
   237 next
   238   case False
   239   then obtain a b where "q = Fract a b" and "b > 0" and "coprime a b" by (cases q) auto
   240   moreover with False have "0 \<noteq> Fract a b" by simp
   241   with `b > 0` have "a \<noteq> 0" by (simp add: Zero_rat_def eq_rat)
   242   with Fract `q = Fract a b` `b > 0` `coprime a b` show C by blast
   243 qed
   244 
   245 subsubsection {* Function @{text normalize} *}
   246 
   247 lemma Fract_coprime: "Fract (a div gcd a b) (b div gcd a b) = Fract a b"
   248 proof (cases "b = 0")
   249   case True then show ?thesis by (simp add: eq_rat)
   250 next
   251   case False
   252   moreover have "b div gcd a b * gcd a b = b"
   253     by (rule dvd_div_mult_self) simp
   254   ultimately have "b div gcd a b \<noteq> 0" by auto
   255   with False show ?thesis by (simp add: eq_rat dvd_div_mult mult_commute [of a])
   256 qed
   257 
   258 definition normalize :: "int \<times> int \<Rightarrow> int \<times> int" where
   259   "normalize p = (if snd p > 0 then (let a = gcd (fst p) (snd p) in (fst p div a, snd p div a))
   260     else if snd p = 0 then (0, 1)
   261     else (let a = - gcd (fst p) (snd p) in (fst p div a, snd p div a)))"
   262 
   263 lemma normalize_crossproduct:
   264   assumes "q \<noteq> 0" "s \<noteq> 0"
   265   assumes "normalize (p, q) = normalize (r, s)"
   266   shows "p * s = r * q"
   267 proof -
   268   have aux: "p * gcd r s = sgn (q * s) * r * gcd p q \<Longrightarrow> q * gcd r s = sgn (q * s) * s * gcd p q \<Longrightarrow> p * s = q * r"
   269   proof -
   270     assume "p * gcd r s = sgn (q * s) * r * gcd p q" and "q * gcd r s = sgn (q * s) * s * gcd p q"
   271     then have "(p * gcd r s) * (sgn (q * s) * s * gcd p q) = (q * gcd r s) * (sgn (q * s) * r * gcd p q)" by simp
   272     with assms show "p * s = q * r" by (auto simp add: mult_ac sgn_times sgn_0_0)
   273   qed
   274   from assms show ?thesis
   275     by (auto simp add: normalize_def Let_def dvd_div_div_eq_mult mult_commute sgn_times split: if_splits intro: aux)
   276 qed
   277 
   278 lemma normalize_eq: "normalize (a, b) = (p, q) \<Longrightarrow> Fract p q = Fract a b"
   279   by (auto simp add: normalize_def Let_def Fract_coprime dvd_div_neg rat_number_collapse
   280     split:split_if_asm)
   281 
   282 lemma normalize_denom_pos: "normalize r = (p, q) \<Longrightarrow> q > 0"
   283   by (auto simp add: normalize_def Let_def dvd_div_neg pos_imp_zdiv_neg_iff nonneg1_imp_zdiv_pos_iff
   284     split:split_if_asm)
   285 
   286 lemma normalize_coprime: "normalize r = (p, q) \<Longrightarrow> coprime p q"
   287   by (auto simp add: normalize_def Let_def dvd_div_neg div_gcd_coprime_int
   288     split:split_if_asm)
   289 
   290 lemma normalize_stable [simp]:
   291   "q > 0 \<Longrightarrow> coprime p q \<Longrightarrow> normalize (p, q) = (p, q)"
   292   by (simp add: normalize_def)
   293 
   294 lemma normalize_denom_zero [simp]:
   295   "normalize (p, 0) = (0, 1)"
   296   by (simp add: normalize_def)
   297 
   298 lemma normalize_negative [simp]:
   299   "q < 0 \<Longrightarrow> normalize (p, q) = normalize (- p, - q)"
   300   by (simp add: normalize_def Let_def dvd_div_neg dvd_neg_div)
   301 
   302 text{*
   303   Decompose a fraction into normalized, i.e. coprime numerator and denominator:
   304 *}
   305 
   306 definition quotient_of :: "rat \<Rightarrow> int \<times> int" where
   307   "quotient_of x = (THE pair. x = Fract (fst pair) (snd pair) &
   308                    snd pair > 0 & coprime (fst pair) (snd pair))"
   309 
   310 lemma quotient_of_unique:
   311   "\<exists>!p. r = Fract (fst p) (snd p) \<and> snd p > 0 \<and> coprime (fst p) (snd p)"
   312 proof (cases r)
   313   case (Fract a b)
   314   then have "r = Fract (fst (a, b)) (snd (a, b)) \<and> snd (a, b) > 0 \<and> coprime (fst (a, b)) (snd (a, b))" by auto
   315   then show ?thesis proof (rule ex1I)
   316     fix p
   317     obtain c d :: int where p: "p = (c, d)" by (cases p)
   318     assume "r = Fract (fst p) (snd p) \<and> snd p > 0 \<and> coprime (fst p) (snd p)"
   319     with p have Fract': "r = Fract c d" "d > 0" "coprime c d" by simp_all
   320     have "c = a \<and> d = b"
   321     proof (cases "a = 0")
   322       case True with Fract Fract' show ?thesis by (simp add: eq_rat)
   323     next
   324       case False
   325       with Fract Fract' have *: "c * b = a * d" and "c \<noteq> 0" by (auto simp add: eq_rat)
   326       then have "c * b > 0 \<longleftrightarrow> a * d > 0" by auto
   327       with `b > 0` `d > 0` have "a > 0 \<longleftrightarrow> c > 0" by (simp add: zero_less_mult_iff)
   328       with `a \<noteq> 0` `c \<noteq> 0` have sgn: "sgn a = sgn c" by (auto simp add: not_less)
   329       from `coprime a b` `coprime c d` have "\<bar>a\<bar> * \<bar>d\<bar> = \<bar>c\<bar> * \<bar>b\<bar> \<longleftrightarrow> \<bar>a\<bar> = \<bar>c\<bar> \<and> \<bar>d\<bar> = \<bar>b\<bar>"
   330         by (simp add: coprime_crossproduct_int)
   331       with `b > 0` `d > 0` have "\<bar>a\<bar> * d = \<bar>c\<bar> * b \<longleftrightarrow> \<bar>a\<bar> = \<bar>c\<bar> \<and> d = b" by simp
   332       then have "a * sgn a * d = c * sgn c * b \<longleftrightarrow> a * sgn a = c * sgn c \<and> d = b" by (simp add: abs_sgn)
   333       with sgn * show ?thesis by (auto simp add: sgn_0_0)
   334     qed
   335     with p show "p = (a, b)" by simp
   336   qed
   337 qed
   338 
   339 lemma quotient_of_Fract [code]:
   340   "quotient_of (Fract a b) = normalize (a, b)"
   341 proof -
   342   have "Fract a b = Fract (fst (normalize (a, b))) (snd (normalize (a, b)))" (is ?Fract)
   343     by (rule sym) (auto intro: normalize_eq)
   344   moreover have "0 < snd (normalize (a, b))" (is ?denom_pos)
   345     by (cases "normalize (a, b)") (rule normalize_denom_pos, simp)
   346   moreover have "coprime (fst (normalize (a, b))) (snd (normalize (a, b)))" (is ?coprime)
   347     by (rule normalize_coprime) simp
   348   ultimately have "?Fract \<and> ?denom_pos \<and> ?coprime" by blast
   349   with quotient_of_unique have
   350     "(THE p. Fract a b = Fract (fst p) (snd p) \<and> 0 < snd p \<and> coprime (fst p) (snd p)) = normalize (a, b)"
   351     by (rule the1_equality)
   352   then show ?thesis by (simp add: quotient_of_def)
   353 qed
   354 
   355 lemma quotient_of_number [simp]:
   356   "quotient_of 0 = (0, 1)"
   357   "quotient_of 1 = (1, 1)"
   358   "quotient_of (numeral k) = (numeral k, 1)"
   359   "quotient_of (neg_numeral k) = (neg_numeral k, 1)"
   360   by (simp_all add: rat_number_expand quotient_of_Fract)
   361 
   362 lemma quotient_of_eq: "quotient_of (Fract a b) = (p, q) \<Longrightarrow> Fract p q = Fract a b"
   363   by (simp add: quotient_of_Fract normalize_eq)
   364 
   365 lemma quotient_of_denom_pos: "quotient_of r = (p, q) \<Longrightarrow> q > 0"
   366   by (cases r) (simp add: quotient_of_Fract normalize_denom_pos)
   367 
   368 lemma quotient_of_coprime: "quotient_of r = (p, q) \<Longrightarrow> coprime p q"
   369   by (cases r) (simp add: quotient_of_Fract normalize_coprime)
   370 
   371 lemma quotient_of_inject:
   372   assumes "quotient_of a = quotient_of b"
   373   shows "a = b"
   374 proof -
   375   obtain p q r s where a: "a = Fract p q"
   376     and b: "b = Fract r s"
   377     and "q > 0" and "s > 0" by (cases a, cases b)
   378   with assms show ?thesis by (simp add: eq_rat quotient_of_Fract normalize_crossproduct)
   379 qed
   380 
   381 lemma quotient_of_inject_eq:
   382   "quotient_of a = quotient_of b \<longleftrightarrow> a = b"
   383   by (auto simp add: quotient_of_inject)
   384 
   385 
   386 subsubsection {* Various *}
   387 
   388 lemma Fract_of_int_quotient: "Fract k l = of_int k / of_int l"
   389   by (simp add: Fract_of_int_eq [symmetric])
   390 
   391 lemma Fract_add_one: "n \<noteq> 0 ==> Fract (m + n) n = Fract m n + 1"
   392   by (simp add: rat_number_expand)
   393 
   394 lemma quotient_of_div:
   395   assumes r: "quotient_of r = (n,d)"
   396   shows "r = of_int n / of_int d"
   397 proof -
   398   from theI'[OF quotient_of_unique[of r], unfolded r[unfolded quotient_of_def]]
   399   have "r = Fract n d" by simp
   400   thus ?thesis using Fract_of_int_quotient by simp
   401 qed
   402 
   403 subsubsection {* The ordered field of rational numbers *}
   404 
   405 lift_definition positive :: "rat \<Rightarrow> bool"
   406   is "\<lambda>x. 0 < fst x * snd x"
   407 proof (clarsimp)
   408   fix a b c d :: int
   409   assume "b \<noteq> 0" and "d \<noteq> 0" and "a * d = c * b"
   410   hence "a * d * b * d = c * b * b * d"
   411     by simp
   412   hence "a * b * d\<twosuperior> = c * d * b\<twosuperior>"
   413     unfolding power2_eq_square by (simp add: mult_ac)
   414   hence "0 < a * b * d\<twosuperior> \<longleftrightarrow> 0 < c * d * b\<twosuperior>"
   415     by simp
   416   thus "0 < a * b \<longleftrightarrow> 0 < c * d"
   417     using `b \<noteq> 0` and `d \<noteq> 0`
   418     by (simp add: zero_less_mult_iff)
   419 qed
   420 
   421 lemma positive_zero: "\<not> positive 0"
   422   by transfer simp
   423 
   424 lemma positive_add:
   425   "positive x \<Longrightarrow> positive y \<Longrightarrow> positive (x + y)"
   426 apply transfer
   427 apply (simp add: zero_less_mult_iff)
   428 apply (elim disjE, simp_all add: add_pos_pos add_neg_neg
   429   mult_pos_pos mult_pos_neg mult_neg_pos mult_neg_neg)
   430 done
   431 
   432 lemma positive_mult:
   433   "positive x \<Longrightarrow> positive y \<Longrightarrow> positive (x * y)"
   434 by transfer (drule (1) mult_pos_pos, simp add: mult_ac)
   435 
   436 lemma positive_minus:
   437   "\<not> positive x \<Longrightarrow> x \<noteq> 0 \<Longrightarrow> positive (- x)"
   438 by transfer (force simp: neq_iff zero_less_mult_iff mult_less_0_iff)
   439 
   440 instantiation rat :: linordered_field_inverse_zero
   441 begin
   442 
   443 definition
   444   "x < y \<longleftrightarrow> positive (y - x)"
   445 
   446 definition
   447   "x \<le> (y::rat) \<longleftrightarrow> x < y \<or> x = y"
   448 
   449 definition
   450   "abs (a::rat) = (if a < 0 then - a else a)"
   451 
   452 definition
   453   "sgn (a::rat) = (if a = 0 then 0 else if 0 < a then 1 else - 1)"
   454 
   455 instance proof
   456   fix a b c :: rat
   457   show "\<bar>a\<bar> = (if a < 0 then - a else a)"
   458     by (rule abs_rat_def)
   459   show "a < b \<longleftrightarrow> a \<le> b \<and> \<not> b \<le> a"
   460     unfolding less_eq_rat_def less_rat_def
   461     by (auto, drule (1) positive_add, simp_all add: positive_zero)
   462   show "a \<le> a"
   463     unfolding less_eq_rat_def by simp
   464   show "a \<le> b \<Longrightarrow> b \<le> c \<Longrightarrow> a \<le> c"
   465     unfolding less_eq_rat_def less_rat_def
   466     by (auto, drule (1) positive_add, simp add: algebra_simps)
   467   show "a \<le> b \<Longrightarrow> b \<le> a \<Longrightarrow> a = b"
   468     unfolding less_eq_rat_def less_rat_def
   469     by (auto, drule (1) positive_add, simp add: positive_zero)
   470   show "a \<le> b \<Longrightarrow> c + a \<le> c + b"
   471     unfolding less_eq_rat_def less_rat_def by (auto simp: diff_minus)
   472   show "sgn a = (if a = 0 then 0 else if 0 < a then 1 else - 1)"
   473     by (rule sgn_rat_def)
   474   show "a \<le> b \<or> b \<le> a"
   475     unfolding less_eq_rat_def less_rat_def
   476     by (auto dest!: positive_minus)
   477   show "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   478     unfolding less_rat_def
   479     by (drule (1) positive_mult, simp add: algebra_simps)
   480 qed
   481 
   482 end
   483 
   484 instantiation rat :: distrib_lattice
   485 begin
   486 
   487 definition
   488   "(inf :: rat \<Rightarrow> rat \<Rightarrow> rat) = min"
   489 
   490 definition
   491   "(sup :: rat \<Rightarrow> rat \<Rightarrow> rat) = max"
   492 
   493 instance proof
   494 qed (auto simp add: inf_rat_def sup_rat_def min_max.sup_inf_distrib1)
   495 
   496 end
   497 
   498 lemma positive_rat: "positive (Fract a b) \<longleftrightarrow> 0 < a * b"
   499   by transfer simp
   500 
   501 lemma less_rat [simp]:
   502   assumes "b \<noteq> 0" and "d \<noteq> 0"
   503   shows "Fract a b < Fract c d \<longleftrightarrow> (a * d) * (b * d) < (c * b) * (b * d)"
   504   using assms unfolding less_rat_def
   505   by (simp add: positive_rat algebra_simps)
   506 
   507 lemma le_rat [simp]:
   508   assumes "b \<noteq> 0" and "d \<noteq> 0"
   509   shows "Fract a b \<le> Fract c d \<longleftrightarrow> (a * d) * (b * d) \<le> (c * b) * (b * d)"
   510   using assms unfolding le_less by (simp add: eq_rat)
   511 
   512 lemma abs_rat [simp, code]: "\<bar>Fract a b\<bar> = Fract \<bar>a\<bar> \<bar>b\<bar>"
   513   by (auto simp add: abs_rat_def zabs_def Zero_rat_def not_less le_less eq_rat zero_less_mult_iff)
   514 
   515 lemma sgn_rat [simp, code]: "sgn (Fract a b) = of_int (sgn a * sgn b)"
   516   unfolding Fract_of_int_eq
   517   by (auto simp: zsgn_def sgn_rat_def Zero_rat_def eq_rat)
   518     (auto simp: rat_number_collapse not_less le_less zero_less_mult_iff)
   519 
   520 lemma Rat_induct_pos [case_names Fract, induct type: rat]:
   521   assumes step: "\<And>a b. 0 < b \<Longrightarrow> P (Fract a b)"
   522   shows "P q"
   523 proof (cases q)
   524   have step': "\<And>a b. b < 0 \<Longrightarrow> P (Fract a b)"
   525   proof -
   526     fix a::int and b::int
   527     assume b: "b < 0"
   528     hence "0 < -b" by simp
   529     hence "P (Fract (-a) (-b))" by (rule step)
   530     thus "P (Fract a b)" by (simp add: order_less_imp_not_eq [OF b])
   531   qed
   532   case (Fract a b)
   533   thus "P q" by (force simp add: linorder_neq_iff step step')
   534 qed
   535 
   536 lemma zero_less_Fract_iff:
   537   "0 < b \<Longrightarrow> 0 < Fract a b \<longleftrightarrow> 0 < a"
   538   by (simp add: Zero_rat_def zero_less_mult_iff)
   539 
   540 lemma Fract_less_zero_iff:
   541   "0 < b \<Longrightarrow> Fract a b < 0 \<longleftrightarrow> a < 0"
   542   by (simp add: Zero_rat_def mult_less_0_iff)
   543 
   544 lemma zero_le_Fract_iff:
   545   "0 < b \<Longrightarrow> 0 \<le> Fract a b \<longleftrightarrow> 0 \<le> a"
   546   by (simp add: Zero_rat_def zero_le_mult_iff)
   547 
   548 lemma Fract_le_zero_iff:
   549   "0 < b \<Longrightarrow> Fract a b \<le> 0 \<longleftrightarrow> a \<le> 0"
   550   by (simp add: Zero_rat_def mult_le_0_iff)
   551 
   552 lemma one_less_Fract_iff:
   553   "0 < b \<Longrightarrow> 1 < Fract a b \<longleftrightarrow> b < a"
   554   by (simp add: One_rat_def mult_less_cancel_right_disj)
   555 
   556 lemma Fract_less_one_iff:
   557   "0 < b \<Longrightarrow> Fract a b < 1 \<longleftrightarrow> a < b"
   558   by (simp add: One_rat_def mult_less_cancel_right_disj)
   559 
   560 lemma one_le_Fract_iff:
   561   "0 < b \<Longrightarrow> 1 \<le> Fract a b \<longleftrightarrow> b \<le> a"
   562   by (simp add: One_rat_def mult_le_cancel_right)
   563 
   564 lemma Fract_le_one_iff:
   565   "0 < b \<Longrightarrow> Fract a b \<le> 1 \<longleftrightarrow> a \<le> b"
   566   by (simp add: One_rat_def mult_le_cancel_right)
   567 
   568 
   569 subsubsection {* Rationals are an Archimedean field *}
   570 
   571 lemma rat_floor_lemma:
   572   shows "of_int (a div b) \<le> Fract a b \<and> Fract a b < of_int (a div b + 1)"
   573 proof -
   574   have "Fract a b = of_int (a div b) + Fract (a mod b) b"
   575     by (cases "b = 0", simp, simp add: of_int_rat)
   576   moreover have "0 \<le> Fract (a mod b) b \<and> Fract (a mod b) b < 1"
   577     unfolding Fract_of_int_quotient
   578     by (rule linorder_cases [of b 0]) (simp add: divide_nonpos_neg, simp, simp add: divide_nonneg_pos)
   579   ultimately show ?thesis by simp
   580 qed
   581 
   582 instance rat :: archimedean_field
   583 proof
   584   fix r :: rat
   585   show "\<exists>z. r \<le> of_int z"
   586   proof (induct r)
   587     case (Fract a b)
   588     have "Fract a b \<le> of_int (a div b + 1)"
   589       using rat_floor_lemma [of a b] by simp
   590     then show "\<exists>z. Fract a b \<le> of_int z" ..
   591   qed
   592 qed
   593 
   594 instantiation rat :: floor_ceiling
   595 begin
   596 
   597 definition [code del]:
   598   "floor (x::rat) = (THE z. of_int z \<le> x \<and> x < of_int (z + 1))"
   599 
   600 instance proof
   601   fix x :: rat
   602   show "of_int (floor x) \<le> x \<and> x < of_int (floor x + 1)"
   603     unfolding floor_rat_def using floor_exists1 by (rule theI')
   604 qed
   605 
   606 end
   607 
   608 lemma floor_Fract: "floor (Fract a b) = a div b"
   609   using rat_floor_lemma [of a b]
   610   by (simp add: floor_unique)
   611 
   612 
   613 subsection {* Linear arithmetic setup *}
   614 
   615 declaration {*
   616   K (Lin_Arith.add_inj_thms [@{thm of_nat_le_iff} RS iffD2, @{thm of_nat_eq_iff} RS iffD2]
   617     (* not needed because x < (y::nat) can be rewritten as Suc x <= y: of_nat_less_iff RS iffD2 *)
   618   #> Lin_Arith.add_inj_thms [@{thm of_int_le_iff} RS iffD2, @{thm of_int_eq_iff} RS iffD2]
   619     (* not needed because x < (y::int) can be rewritten as x + 1 <= y: of_int_less_iff RS iffD2 *)
   620   #> Lin_Arith.add_simps [@{thm neg_less_iff_less},
   621       @{thm True_implies_equals},
   622       read_instantiate @{context} [(("a", 0), "(numeral ?v)")] @{thm distrib_left},
   623       read_instantiate @{context} [(("a", 0), "(neg_numeral ?v)")] @{thm distrib_left},
   624       @{thm divide_1}, @{thm divide_zero_left},
   625       @{thm times_divide_eq_right}, @{thm times_divide_eq_left},
   626       @{thm minus_divide_left} RS sym, @{thm minus_divide_right} RS sym,
   627       @{thm of_int_minus}, @{thm of_int_diff},
   628       @{thm of_int_of_nat_eq}]
   629   #> Lin_Arith.add_simprocs Numeral_Simprocs.field_cancel_numeral_factors
   630   #> Lin_Arith.add_inj_const (@{const_name of_nat}, @{typ "nat => rat"})
   631   #> Lin_Arith.add_inj_const (@{const_name of_int}, @{typ "int => rat"}))
   632 *}
   633 
   634 
   635 subsection {* Embedding from Rationals to other Fields *}
   636 
   637 class field_char_0 = field + ring_char_0
   638 
   639 subclass (in linordered_field) field_char_0 ..
   640 
   641 context field_char_0
   642 begin
   643 
   644 lift_definition of_rat :: "rat \<Rightarrow> 'a"
   645   is "\<lambda>x. of_int (fst x) / of_int (snd x)"
   646 apply (clarsimp simp add: nonzero_divide_eq_eq nonzero_eq_divide_eq)
   647 apply (simp only: of_int_mult [symmetric])
   648 done
   649 
   650 end
   651 
   652 lemma of_rat_rat: "b \<noteq> 0 \<Longrightarrow> of_rat (Fract a b) = of_int a / of_int b"
   653   by transfer simp
   654 
   655 lemma of_rat_0 [simp]: "of_rat 0 = 0"
   656   by transfer simp
   657 
   658 lemma of_rat_1 [simp]: "of_rat 1 = 1"
   659   by transfer simp
   660 
   661 lemma of_rat_add: "of_rat (a + b) = of_rat a + of_rat b"
   662   by transfer (simp add: add_frac_eq)
   663 
   664 lemma of_rat_minus: "of_rat (- a) = - of_rat a"
   665   by transfer simp
   666 
   667 lemma of_rat_diff: "of_rat (a - b) = of_rat a - of_rat b"
   668 by (simp only: diff_minus of_rat_add of_rat_minus)
   669 
   670 lemma of_rat_mult: "of_rat (a * b) = of_rat a * of_rat b"
   671 apply transfer
   672 apply (simp add: divide_inverse nonzero_inverse_mult_distrib mult_ac)
   673 done
   674 
   675 lemma nonzero_of_rat_inverse:
   676   "a \<noteq> 0 \<Longrightarrow> of_rat (inverse a) = inverse (of_rat a)"
   677 apply (rule inverse_unique [symmetric])
   678 apply (simp add: of_rat_mult [symmetric])
   679 done
   680 
   681 lemma of_rat_inverse:
   682   "(of_rat (inverse a)::'a::{field_char_0, field_inverse_zero}) =
   683    inverse (of_rat a)"
   684 by (cases "a = 0", simp_all add: nonzero_of_rat_inverse)
   685 
   686 lemma nonzero_of_rat_divide:
   687   "b \<noteq> 0 \<Longrightarrow> of_rat (a / b) = of_rat a / of_rat b"
   688 by (simp add: divide_inverse of_rat_mult nonzero_of_rat_inverse)
   689 
   690 lemma of_rat_divide:
   691   "(of_rat (a / b)::'a::{field_char_0, field_inverse_zero})
   692    = of_rat a / of_rat b"
   693 by (cases "b = 0") (simp_all add: nonzero_of_rat_divide)
   694 
   695 lemma of_rat_power:
   696   "(of_rat (a ^ n)::'a::field_char_0) = of_rat a ^ n"
   697 by (induct n) (simp_all add: of_rat_mult)
   698 
   699 lemma of_rat_eq_iff [simp]: "(of_rat a = of_rat b) = (a = b)"
   700 apply transfer
   701 apply (simp add: nonzero_divide_eq_eq nonzero_eq_divide_eq)
   702 apply (simp only: of_int_mult [symmetric] of_int_eq_iff)
   703 done
   704 
   705 lemma of_rat_less:
   706   "(of_rat r :: 'a::linordered_field) < of_rat s \<longleftrightarrow> r < s"
   707 proof (induct r, induct s)
   708   fix a b c d :: int
   709   assume not_zero: "b > 0" "d > 0"
   710   then have "b * d > 0" by (rule mult_pos_pos)
   711   have of_int_divide_less_eq:
   712     "(of_int a :: 'a) / of_int b < of_int c / of_int d
   713       \<longleftrightarrow> (of_int a :: 'a) * of_int d < of_int c * of_int b"
   714     using not_zero by (simp add: pos_less_divide_eq pos_divide_less_eq)
   715   show "(of_rat (Fract a b) :: 'a::linordered_field) < of_rat (Fract c d)
   716     \<longleftrightarrow> Fract a b < Fract c d"
   717     using not_zero `b * d > 0`
   718     by (simp add: of_rat_rat of_int_divide_less_eq of_int_mult [symmetric] del: of_int_mult)
   719 qed
   720 
   721 lemma of_rat_less_eq:
   722   "(of_rat r :: 'a::linordered_field) \<le> of_rat s \<longleftrightarrow> r \<le> s"
   723   unfolding le_less by (auto simp add: of_rat_less)
   724 
   725 lemmas of_rat_eq_0_iff [simp] = of_rat_eq_iff [of _ 0, simplified]
   726 
   727 lemma of_rat_eq_id [simp]: "of_rat = id"
   728 proof
   729   fix a
   730   show "of_rat a = id a"
   731   by (induct a)
   732      (simp add: of_rat_rat Fract_of_int_eq [symmetric])
   733 qed
   734 
   735 text{*Collapse nested embeddings*}
   736 lemma of_rat_of_nat_eq [simp]: "of_rat (of_nat n) = of_nat n"
   737 by (induct n) (simp_all add: of_rat_add)
   738 
   739 lemma of_rat_of_int_eq [simp]: "of_rat (of_int z) = of_int z"
   740 by (cases z rule: int_diff_cases) (simp add: of_rat_diff)
   741 
   742 lemma of_rat_numeral_eq [simp]:
   743   "of_rat (numeral w) = numeral w"
   744 using of_rat_of_int_eq [of "numeral w"] by simp
   745 
   746 lemma of_rat_neg_numeral_eq [simp]:
   747   "of_rat (neg_numeral w) = neg_numeral w"
   748 using of_rat_of_int_eq [of "neg_numeral w"] by simp
   749 
   750 lemmas zero_rat = Zero_rat_def
   751 lemmas one_rat = One_rat_def
   752 
   753 abbreviation
   754   rat_of_nat :: "nat \<Rightarrow> rat"
   755 where
   756   "rat_of_nat \<equiv> of_nat"
   757 
   758 abbreviation
   759   rat_of_int :: "int \<Rightarrow> rat"
   760 where
   761   "rat_of_int \<equiv> of_int"
   762 
   763 subsection {* The Set of Rational Numbers *}
   764 
   765 context field_char_0
   766 begin
   767 
   768 definition
   769   Rats  :: "'a set" where
   770   "Rats = range of_rat"
   771 
   772 notation (xsymbols)
   773   Rats  ("\<rat>")
   774 
   775 end
   776 
   777 lemma Rats_of_rat [simp]: "of_rat r \<in> Rats"
   778 by (simp add: Rats_def)
   779 
   780 lemma Rats_of_int [simp]: "of_int z \<in> Rats"
   781 by (subst of_rat_of_int_eq [symmetric], rule Rats_of_rat)
   782 
   783 lemma Rats_of_nat [simp]: "of_nat n \<in> Rats"
   784 by (subst of_rat_of_nat_eq [symmetric], rule Rats_of_rat)
   785 
   786 lemma Rats_number_of [simp]: "numeral w \<in> Rats"
   787 by (subst of_rat_numeral_eq [symmetric], rule Rats_of_rat)
   788 
   789 lemma Rats_neg_number_of [simp]: "neg_numeral w \<in> Rats"
   790 by (subst of_rat_neg_numeral_eq [symmetric], rule Rats_of_rat)
   791 
   792 lemma Rats_0 [simp]: "0 \<in> Rats"
   793 apply (unfold Rats_def)
   794 apply (rule range_eqI)
   795 apply (rule of_rat_0 [symmetric])
   796 done
   797 
   798 lemma Rats_1 [simp]: "1 \<in> Rats"
   799 apply (unfold Rats_def)
   800 apply (rule range_eqI)
   801 apply (rule of_rat_1 [symmetric])
   802 done
   803 
   804 lemma Rats_add [simp]: "\<lbrakk>a \<in> Rats; b \<in> Rats\<rbrakk> \<Longrightarrow> a + b \<in> Rats"
   805 apply (auto simp add: Rats_def)
   806 apply (rule range_eqI)
   807 apply (rule of_rat_add [symmetric])
   808 done
   809 
   810 lemma Rats_minus [simp]: "a \<in> Rats \<Longrightarrow> - a \<in> Rats"
   811 apply (auto simp add: Rats_def)
   812 apply (rule range_eqI)
   813 apply (rule of_rat_minus [symmetric])
   814 done
   815 
   816 lemma Rats_diff [simp]: "\<lbrakk>a \<in> Rats; b \<in> Rats\<rbrakk> \<Longrightarrow> a - b \<in> Rats"
   817 apply (auto simp add: Rats_def)
   818 apply (rule range_eqI)
   819 apply (rule of_rat_diff [symmetric])
   820 done
   821 
   822 lemma Rats_mult [simp]: "\<lbrakk>a \<in> Rats; b \<in> Rats\<rbrakk> \<Longrightarrow> a * b \<in> Rats"
   823 apply (auto simp add: Rats_def)
   824 apply (rule range_eqI)
   825 apply (rule of_rat_mult [symmetric])
   826 done
   827 
   828 lemma nonzero_Rats_inverse:
   829   fixes a :: "'a::field_char_0"
   830   shows "\<lbrakk>a \<in> Rats; a \<noteq> 0\<rbrakk> \<Longrightarrow> inverse a \<in> Rats"
   831 apply (auto simp add: Rats_def)
   832 apply (rule range_eqI)
   833 apply (erule nonzero_of_rat_inverse [symmetric])
   834 done
   835 
   836 lemma Rats_inverse [simp]:
   837   fixes a :: "'a::{field_char_0, field_inverse_zero}"
   838   shows "a \<in> Rats \<Longrightarrow> inverse a \<in> Rats"
   839 apply (auto simp add: Rats_def)
   840 apply (rule range_eqI)
   841 apply (rule of_rat_inverse [symmetric])
   842 done
   843 
   844 lemma nonzero_Rats_divide:
   845   fixes a b :: "'a::field_char_0"
   846   shows "\<lbrakk>a \<in> Rats; b \<in> Rats; b \<noteq> 0\<rbrakk> \<Longrightarrow> a / b \<in> Rats"
   847 apply (auto simp add: Rats_def)
   848 apply (rule range_eqI)
   849 apply (erule nonzero_of_rat_divide [symmetric])
   850 done
   851 
   852 lemma Rats_divide [simp]:
   853   fixes a b :: "'a::{field_char_0, field_inverse_zero}"
   854   shows "\<lbrakk>a \<in> Rats; b \<in> Rats\<rbrakk> \<Longrightarrow> a / b \<in> Rats"
   855 apply (auto simp add: Rats_def)
   856 apply (rule range_eqI)
   857 apply (rule of_rat_divide [symmetric])
   858 done
   859 
   860 lemma Rats_power [simp]:
   861   fixes a :: "'a::field_char_0"
   862   shows "a \<in> Rats \<Longrightarrow> a ^ n \<in> Rats"
   863 apply (auto simp add: Rats_def)
   864 apply (rule range_eqI)
   865 apply (rule of_rat_power [symmetric])
   866 done
   867 
   868 lemma Rats_cases [cases set: Rats]:
   869   assumes "q \<in> \<rat>"
   870   obtains (of_rat) r where "q = of_rat r"
   871 proof -
   872   from `q \<in> \<rat>` have "q \<in> range of_rat" unfolding Rats_def .
   873   then obtain r where "q = of_rat r" ..
   874   then show thesis ..
   875 qed
   876 
   877 lemma Rats_induct [case_names of_rat, induct set: Rats]:
   878   "q \<in> \<rat> \<Longrightarrow> (\<And>r. P (of_rat r)) \<Longrightarrow> P q"
   879   by (rule Rats_cases) auto
   880 
   881 
   882 subsection {* Implementation of rational numbers as pairs of integers *}
   883 
   884 text {* Formal constructor *}
   885 
   886 definition Frct :: "int \<times> int \<Rightarrow> rat" where
   887   [simp]: "Frct p = Fract (fst p) (snd p)"
   888 
   889 lemma [code abstype]:
   890   "Frct (quotient_of q) = q"
   891   by (cases q) (auto intro: quotient_of_eq)
   892 
   893 
   894 text {* Numerals *}
   895 
   896 declare quotient_of_Fract [code abstract]
   897 
   898 definition of_int :: "int \<Rightarrow> rat"
   899 where
   900   [code_abbrev]: "of_int = Int.of_int"
   901 hide_const (open) of_int
   902 
   903 lemma quotient_of_int [code abstract]:
   904   "quotient_of (Rat.of_int a) = (a, 1)"
   905   by (simp add: of_int_def of_int_rat quotient_of_Fract)
   906 
   907 lemma [code_unfold]:
   908   "numeral k = Rat.of_int (numeral k)"
   909   by (simp add: Rat.of_int_def)
   910 
   911 lemma [code_unfold]:
   912   "neg_numeral k = Rat.of_int (neg_numeral k)"
   913   by (simp add: Rat.of_int_def)
   914 
   915 lemma Frct_code_post [code_post]:
   916   "Frct (0, a) = 0"
   917   "Frct (a, 0) = 0"
   918   "Frct (1, 1) = 1"
   919   "Frct (numeral k, 1) = numeral k"
   920   "Frct (neg_numeral k, 1) = neg_numeral k"
   921   "Frct (1, numeral k) = 1 / numeral k"
   922   "Frct (1, neg_numeral k) = 1 / neg_numeral k"
   923   "Frct (numeral k, numeral l) = numeral k / numeral l"
   924   "Frct (numeral k, neg_numeral l) = numeral k / neg_numeral l"
   925   "Frct (neg_numeral k, numeral l) = neg_numeral k / numeral l"
   926   "Frct (neg_numeral k, neg_numeral l) = neg_numeral k / neg_numeral l"
   927   by (simp_all add: Fract_of_int_quotient)
   928 
   929 
   930 text {* Operations *}
   931 
   932 lemma rat_zero_code [code abstract]:
   933   "quotient_of 0 = (0, 1)"
   934   by (simp add: Zero_rat_def quotient_of_Fract normalize_def)
   935 
   936 lemma rat_one_code [code abstract]:
   937   "quotient_of 1 = (1, 1)"
   938   by (simp add: One_rat_def quotient_of_Fract normalize_def)
   939 
   940 lemma rat_plus_code [code abstract]:
   941   "quotient_of (p + q) = (let (a, c) = quotient_of p; (b, d) = quotient_of q
   942      in normalize (a * d + b * c, c * d))"
   943   by (cases p, cases q) (simp add: quotient_of_Fract)
   944 
   945 lemma rat_uminus_code [code abstract]:
   946   "quotient_of (- p) = (let (a, b) = quotient_of p in (- a, b))"
   947   by (cases p) (simp add: quotient_of_Fract)
   948 
   949 lemma rat_minus_code [code abstract]:
   950   "quotient_of (p - q) = (let (a, c) = quotient_of p; (b, d) = quotient_of q
   951      in normalize (a * d - b * c, c * d))"
   952   by (cases p, cases q) (simp add: quotient_of_Fract)
   953 
   954 lemma rat_times_code [code abstract]:
   955   "quotient_of (p * q) = (let (a, c) = quotient_of p; (b, d) = quotient_of q
   956      in normalize (a * b, c * d))"
   957   by (cases p, cases q) (simp add: quotient_of_Fract)
   958 
   959 lemma rat_inverse_code [code abstract]:
   960   "quotient_of (inverse p) = (let (a, b) = quotient_of p
   961     in if a = 0 then (0, 1) else (sgn a * b, \<bar>a\<bar>))"
   962 proof (cases p)
   963   case (Fract a b) then show ?thesis
   964     by (cases "0::int" a rule: linorder_cases) (simp_all add: quotient_of_Fract gcd_int.commute)
   965 qed
   966 
   967 lemma rat_divide_code [code abstract]:
   968   "quotient_of (p / q) = (let (a, c) = quotient_of p; (b, d) = quotient_of q
   969      in normalize (a * d, c * b))"
   970   by (cases p, cases q) (simp add: quotient_of_Fract)
   971 
   972 lemma rat_abs_code [code abstract]:
   973   "quotient_of \<bar>p\<bar> = (let (a, b) = quotient_of p in (\<bar>a\<bar>, b))"
   974   by (cases p) (simp add: quotient_of_Fract)
   975 
   976 lemma rat_sgn_code [code abstract]:
   977   "quotient_of (sgn p) = (sgn (fst (quotient_of p)), 1)"
   978 proof (cases p)
   979   case (Fract a b) then show ?thesis
   980   by (cases "0::int" a rule: linorder_cases) (simp_all add: quotient_of_Fract)
   981 qed
   982 
   983 lemma rat_floor_code [code]:
   984   "floor p = (let (a, b) = quotient_of p in a div b)"
   985 by (cases p) (simp add: quotient_of_Fract floor_Fract)
   986 
   987 instantiation rat :: equal
   988 begin
   989 
   990 definition [code]:
   991   "HOL.equal a b \<longleftrightarrow> quotient_of a = quotient_of b"
   992 
   993 instance proof
   994 qed (simp add: equal_rat_def quotient_of_inject_eq)
   995 
   996 lemma rat_eq_refl [code nbe]:
   997   "HOL.equal (r::rat) r \<longleftrightarrow> True"
   998   by (rule equal_refl)
   999 
  1000 end
  1001 
  1002 lemma rat_less_eq_code [code]:
  1003   "p \<le> q \<longleftrightarrow> (let (a, c) = quotient_of p; (b, d) = quotient_of q in a * d \<le> c * b)"
  1004   by (cases p, cases q) (simp add: quotient_of_Fract mult.commute)
  1005 
  1006 lemma rat_less_code [code]:
  1007   "p < q \<longleftrightarrow> (let (a, c) = quotient_of p; (b, d) = quotient_of q in a * d < c * b)"
  1008   by (cases p, cases q) (simp add: quotient_of_Fract mult.commute)
  1009 
  1010 lemma [code]:
  1011   "of_rat p = (let (a, b) = quotient_of p in of_int a / of_int b)"
  1012   by (cases p) (simp add: quotient_of_Fract of_rat_rat)
  1013 
  1014 
  1015 text {* Quickcheck *}
  1016 
  1017 definition (in term_syntax)
  1018   valterm_fract :: "int \<times> (unit \<Rightarrow> Code_Evaluation.term) \<Rightarrow> int \<times> (unit \<Rightarrow> Code_Evaluation.term) \<Rightarrow> rat \<times> (unit \<Rightarrow> Code_Evaluation.term)" where
  1019   [code_unfold]: "valterm_fract k l = Code_Evaluation.valtermify Fract {\<cdot>} k {\<cdot>} l"
  1020 
  1021 notation fcomp (infixl "\<circ>>" 60)
  1022 notation scomp (infixl "\<circ>\<rightarrow>" 60)
  1023 
  1024 instantiation rat :: random
  1025 begin
  1026 
  1027 definition
  1028   "Quickcheck_Random.random i = Quickcheck_Random.random i \<circ>\<rightarrow> (\<lambda>num. Random.range i \<circ>\<rightarrow> (\<lambda>denom. Pair (
  1029      let j = int_of_integer (integer_of_natural (denom + 1))
  1030      in valterm_fract num (j, \<lambda>u. Code_Evaluation.term_of j))))"
  1031 
  1032 instance ..
  1033 
  1034 end
  1035 
  1036 no_notation fcomp (infixl "\<circ>>" 60)
  1037 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
  1038 
  1039 instantiation rat :: exhaustive
  1040 begin
  1041 
  1042 definition
  1043   "exhaustive_rat f d = Quickcheck_Exhaustive.exhaustive
  1044     (\<lambda>l. Quickcheck_Exhaustive.exhaustive (\<lambda>k. f (Fract k (int_of_integer (integer_of_natural l) + 1))) d) d"
  1045 
  1046 instance ..
  1047 
  1048 end
  1049 
  1050 instantiation rat :: full_exhaustive
  1051 begin
  1052 
  1053 definition
  1054   "full_exhaustive_rat f d = Quickcheck_Exhaustive.full_exhaustive (%(l, _). Quickcheck_Exhaustive.full_exhaustive (%k.
  1055      f (let j = int_of_integer (integer_of_natural l) + 1
  1056         in valterm_fract k (j, %_. Code_Evaluation.term_of j))) d) d"
  1057 
  1058 instance ..
  1059 
  1060 end
  1061 
  1062 instantiation rat :: partial_term_of
  1063 begin
  1064 
  1065 instance ..
  1066 
  1067 end
  1068 
  1069 lemma [code]:
  1070   "partial_term_of (ty :: rat itself) (Quickcheck_Narrowing.Narrowing_variable p tt) == Code_Evaluation.Free (STR ''_'') (Typerep.Typerep (STR ''Rat.rat'') [])"
  1071   "partial_term_of (ty :: rat itself) (Quickcheck_Narrowing.Narrowing_constructor 0 [l, k]) ==
  1072      Code_Evaluation.App (Code_Evaluation.Const (STR ''Rat.Frct'')
  1073      (Typerep.Typerep (STR ''fun'') [Typerep.Typerep (STR ''Product_Type.prod'') [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''Int.int'') []],
  1074         Typerep.Typerep (STR ''Rat.rat'') []])) (Code_Evaluation.App (Code_Evaluation.App (Code_Evaluation.Const (STR ''Product_Type.Pair'') (Typerep.Typerep (STR ''fun'') [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''fun'') [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''Product_Type.prod'') [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''Int.int'') []]]])) (partial_term_of (TYPE(int)) l)) (partial_term_of (TYPE(int)) k))"
  1075 by (rule partial_term_of_anything)+
  1076 
  1077 instantiation rat :: narrowing
  1078 begin
  1079 
  1080 definition
  1081   "narrowing = Quickcheck_Narrowing.apply (Quickcheck_Narrowing.apply
  1082     (Quickcheck_Narrowing.cons (%nom denom. Fract nom denom)) narrowing) narrowing"
  1083 
  1084 instance ..
  1085 
  1086 end
  1087 
  1088 
  1089 subsection {* Setup for Nitpick *}
  1090 
  1091 declaration {*
  1092   Nitpick_HOL.register_frac_type @{type_name rat}
  1093    [(@{const_name zero_rat_inst.zero_rat}, @{const_name Nitpick.zero_frac}),
  1094     (@{const_name one_rat_inst.one_rat}, @{const_name Nitpick.one_frac}),
  1095     (@{const_name plus_rat_inst.plus_rat}, @{const_name Nitpick.plus_frac}),
  1096     (@{const_name times_rat_inst.times_rat}, @{const_name Nitpick.times_frac}),
  1097     (@{const_name uminus_rat_inst.uminus_rat}, @{const_name Nitpick.uminus_frac}),
  1098     (@{const_name inverse_rat_inst.inverse_rat}, @{const_name Nitpick.inverse_frac}),
  1099     (@{const_name ord_rat_inst.less_rat}, @{const_name Nitpick.less_frac}),
  1100     (@{const_name ord_rat_inst.less_eq_rat}, @{const_name Nitpick.less_eq_frac}),
  1101     (@{const_name field_char_0_class.of_rat}, @{const_name Nitpick.of_frac})]
  1102 *}
  1103 
  1104 lemmas [nitpick_unfold] = inverse_rat_inst.inverse_rat
  1105   one_rat_inst.one_rat ord_rat_inst.less_rat
  1106   ord_rat_inst.less_eq_rat plus_rat_inst.plus_rat times_rat_inst.times_rat
  1107   uminus_rat_inst.uminus_rat zero_rat_inst.zero_rat
  1108 
  1109 
  1110 subsection {* Float syntax *}
  1111 
  1112 syntax "_Float" :: "float_const \<Rightarrow> 'a"    ("_")
  1113 
  1114 parse_translation {*
  1115   let
  1116     fun mk_number i =
  1117       let
  1118         fun mk 1 = Syntax.const @{const_syntax Num.One}
  1119           | mk i =
  1120               let val (q, r) = Integer.div_mod i 2
  1121               in HOLogic.mk_bit r $ (mk q) end;
  1122       in
  1123         if i = 0 then Syntax.const @{const_syntax Groups.zero}
  1124         else if i > 0 then Syntax.const @{const_syntax Num.numeral} $ mk i
  1125         else Syntax.const @{const_syntax Num.neg_numeral} $ mk (~i)
  1126       end;
  1127 
  1128     fun mk_frac str =
  1129       let
  1130         val {mant = i, exp = n} = Lexicon.read_float str;
  1131         val exp = Syntax.const @{const_syntax Power.power};
  1132         val ten = mk_number 10;
  1133         val exp10 = if n = 1 then ten else exp $ ten $ mk_number n;
  1134       in Syntax.const @{const_syntax divide} $ mk_number i $ exp10 end;
  1135 
  1136     fun float_tr [(c as Const (@{syntax_const "_constrain"}, _)) $ t $ u] = c $ float_tr [t] $ u
  1137       | float_tr [t as Const (str, _)] = mk_frac str
  1138       | float_tr ts = raise TERM ("float_tr", ts);
  1139   in [(@{syntax_const "_Float"}, K float_tr)] end
  1140 *}
  1141 
  1142 text{* Test: *}
  1143 lemma "123.456 = -111.111 + 200 + 30 + 4 + 5/10 + 6/100 + (7/1000::rat)"
  1144   by simp
  1145 
  1146 
  1147 hide_const (open) normalize positive
  1148 
  1149 lemmas [transfer_rule del] =
  1150   rat.rel_eq_transfer
  1151   Fract.transfer zero_rat.transfer one_rat.transfer plus_rat.transfer
  1152   uminus_rat.transfer times_rat.transfer inverse_rat.transfer
  1153   positive.transfer of_rat.transfer rat.right_unique rat.right_total
  1154 
  1155 lemmas [transfer_domain_rule del] = Domainp_cr_rat rat.domain
  1156 
  1157 text {* De-register @{text "rat"} as a quotient type: *}
  1158 
  1159 declare Quotient_rat[quot_del]
  1160 
  1161 end
  1162