src/HOL/Relation.thy
author haftmann
Sun Jun 23 21:16:07 2013 +0200 (2013-06-23)
changeset 52435 6646bb548c6b
parent 52392 ee996ca08de3
child 52730 6bf02eb4ddf7
permissions -rw-r--r--
migration from code_(const|type|class|instance) to code_printing and from code_module to code_identifier
     1 (*  Title:      HOL/Relation.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory; Stefan Berghofer, TU Muenchen
     3 *)
     4 
     5 header {* Relations – as sets of pairs, and binary predicates *}
     6 
     7 theory Relation
     8 imports Datatype Finite_Set
     9 begin
    10 
    11 text {* A preliminary: classical rules for reasoning on predicates *}
    12 
    13 declare predicate1I [Pure.intro!, intro!]
    14 declare predicate1D [Pure.dest, dest]
    15 declare predicate2I [Pure.intro!, intro!]
    16 declare predicate2D [Pure.dest, dest]
    17 declare bot1E [elim!] 
    18 declare bot2E [elim!]
    19 declare top1I [intro!]
    20 declare top2I [intro!]
    21 declare inf1I [intro!]
    22 declare inf2I [intro!]
    23 declare inf1E [elim!]
    24 declare inf2E [elim!]
    25 declare sup1I1 [intro?]
    26 declare sup2I1 [intro?]
    27 declare sup1I2 [intro?]
    28 declare sup2I2 [intro?]
    29 declare sup1E [elim!]
    30 declare sup2E [elim!]
    31 declare sup1CI [intro!]
    32 declare sup2CI [intro!]
    33 declare INF1_I [intro!]
    34 declare INF2_I [intro!]
    35 declare INF1_D [elim]
    36 declare INF2_D [elim]
    37 declare INF1_E [elim]
    38 declare INF2_E [elim]
    39 declare SUP1_I [intro]
    40 declare SUP2_I [intro]
    41 declare SUP1_E [elim!]
    42 declare SUP2_E [elim!]
    43 
    44 subsection {* Fundamental *}
    45 
    46 subsubsection {* Relations as sets of pairs *}
    47 
    48 type_synonym 'a rel = "('a * 'a) set"
    49 
    50 lemma subrelI: -- {* Version of @{thm [source] subsetI} for binary relations *}
    51   "(\<And>x y. (x, y) \<in> r \<Longrightarrow> (x, y) \<in> s) \<Longrightarrow> r \<subseteq> s"
    52   by auto
    53 
    54 lemma lfp_induct2: -- {* Version of @{thm [source] lfp_induct} for binary relations *}
    55   "(a, b) \<in> lfp f \<Longrightarrow> mono f \<Longrightarrow>
    56     (\<And>a b. (a, b) \<in> f (lfp f \<inter> {(x, y). P x y}) \<Longrightarrow> P a b) \<Longrightarrow> P a b"
    57   using lfp_induct_set [of "(a, b)" f "prod_case P"] by auto
    58 
    59 
    60 subsubsection {* Conversions between set and predicate relations *}
    61 
    62 lemma pred_equals_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) = (\<lambda>x. x \<in> S) \<longleftrightarrow> R = S"
    63   by (simp add: set_eq_iff fun_eq_iff)
    64 
    65 lemma pred_equals_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) = (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R = S"
    66   by (simp add: set_eq_iff fun_eq_iff)
    67 
    68 lemma pred_subset_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<le> (\<lambda>x. x \<in> S) \<longleftrightarrow> R \<subseteq> S"
    69   by (simp add: subset_iff le_fun_def)
    70 
    71 lemma pred_subset_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<le> (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R \<subseteq> S"
    72   by (simp add: subset_iff le_fun_def)
    73 
    74 lemma bot_empty_eq [pred_set_conv]: "\<bottom> = (\<lambda>x. x \<in> {})"
    75   by (auto simp add: fun_eq_iff)
    76 
    77 lemma bot_empty_eq2 [pred_set_conv]: "\<bottom> = (\<lambda>x y. (x, y) \<in> {})"
    78   by (auto simp add: fun_eq_iff)
    79 
    80 lemma top_empty_eq [pred_set_conv]: "\<top> = (\<lambda>x. x \<in> UNIV)"
    81   by (auto simp add: fun_eq_iff)
    82 
    83 lemma top_empty_eq2 [pred_set_conv]: "\<top> = (\<lambda>x y. (x, y) \<in> UNIV)"
    84   by (auto simp add: fun_eq_iff)
    85 
    86 lemma inf_Int_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<sqinter> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<inter> S)"
    87   by (simp add: inf_fun_def)
    88 
    89 lemma inf_Int_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<sqinter> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<inter> S)"
    90   by (simp add: inf_fun_def)
    91 
    92 lemma sup_Un_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<squnion> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<union> S)"
    93   by (simp add: sup_fun_def)
    94 
    95 lemma sup_Un_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<squnion> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<union> S)"
    96   by (simp add: sup_fun_def)
    97 
    98 lemma INF_INT_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Inter>i\<in>S. r i))"
    99   by (simp add: fun_eq_iff)
   100 
   101 lemma INF_INT_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Inter>i\<in>S. r i))"
   102   by (simp add: fun_eq_iff)
   103 
   104 lemma SUP_UN_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Union>i\<in>S. r i))"
   105   by (simp add: fun_eq_iff)
   106 
   107 lemma SUP_UN_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Union>i\<in>S. r i))"
   108   by (simp add: fun_eq_iff)
   109 
   110 lemma Inf_INT_eq [pred_set_conv]: "\<Sqinter>S = (\<lambda>x. x \<in> INTER S Collect)"
   111   by (simp add: fun_eq_iff)
   112 
   113 lemma INF_Int_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Inter>S)"
   114   by (simp add: fun_eq_iff)
   115 
   116 lemma Inf_INT_eq2 [pred_set_conv]: "\<Sqinter>S = (\<lambda>x y. (x, y) \<in> INTER (prod_case ` S) Collect)"
   117   by (simp add: fun_eq_iff)
   118 
   119 lemma INF_Int_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Inter>S)"
   120   by (simp add: fun_eq_iff)
   121 
   122 lemma Sup_SUP_eq [pred_set_conv]: "\<Squnion>S = (\<lambda>x. x \<in> UNION S Collect)"
   123   by (simp add: fun_eq_iff)
   124 
   125 lemma SUP_Sup_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Union>S)"
   126   by (simp add: fun_eq_iff)
   127 
   128 lemma Sup_SUP_eq2 [pred_set_conv]: "\<Squnion>S = (\<lambda>x y. (x, y) \<in> UNION (prod_case ` S) Collect)"
   129   by (simp add: fun_eq_iff)
   130 
   131 lemma SUP_Sup_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Union>S)"
   132   by (simp add: fun_eq_iff)
   133 
   134 
   135 subsection {* Properties of relations *}
   136 
   137 subsubsection {* Reflexivity *}
   138 
   139 definition refl_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   140 where
   141   "refl_on A r \<longleftrightarrow> r \<subseteq> A \<times> A \<and> (\<forall>x\<in>A. (x, x) \<in> r)"
   142 
   143 abbreviation refl :: "'a rel \<Rightarrow> bool"
   144 where -- {* reflexivity over a type *}
   145   "refl \<equiv> refl_on UNIV"
   146 
   147 definition reflp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   148 where
   149   "reflp r \<longleftrightarrow> (\<forall>x. r x x)"
   150 
   151 lemma reflp_refl_eq [pred_set_conv]:
   152   "reflp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> refl r" 
   153   by (simp add: refl_on_def reflp_def)
   154 
   155 lemma refl_onI: "r \<subseteq> A \<times> A ==> (!!x. x : A ==> (x, x) : r) ==> refl_on A r"
   156   by (unfold refl_on_def) (iprover intro!: ballI)
   157 
   158 lemma refl_onD: "refl_on A r ==> a : A ==> (a, a) : r"
   159   by (unfold refl_on_def) blast
   160 
   161 lemma refl_onD1: "refl_on A r ==> (x, y) : r ==> x : A"
   162   by (unfold refl_on_def) blast
   163 
   164 lemma refl_onD2: "refl_on A r ==> (x, y) : r ==> y : A"
   165   by (unfold refl_on_def) blast
   166 
   167 lemma reflpI:
   168   "(\<And>x. r x x) \<Longrightarrow> reflp r"
   169   by (auto intro: refl_onI simp add: reflp_def)
   170 
   171 lemma reflpE:
   172   assumes "reflp r"
   173   obtains "r x x"
   174   using assms by (auto dest: refl_onD simp add: reflp_def)
   175 
   176 lemma reflpD:
   177   assumes "reflp r"
   178   shows "r x x"
   179   using assms by (auto elim: reflpE)
   180 
   181 lemma refl_on_Int: "refl_on A r ==> refl_on B s ==> refl_on (A \<inter> B) (r \<inter> s)"
   182   by (unfold refl_on_def) blast
   183 
   184 lemma reflp_inf:
   185   "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<sqinter> s)"
   186   by (auto intro: reflpI elim: reflpE)
   187 
   188 lemma refl_on_Un: "refl_on A r ==> refl_on B s ==> refl_on (A \<union> B) (r \<union> s)"
   189   by (unfold refl_on_def) blast
   190 
   191 lemma reflp_sup:
   192   "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<squnion> s)"
   193   by (auto intro: reflpI elim: reflpE)
   194 
   195 lemma refl_on_INTER:
   196   "ALL x:S. refl_on (A x) (r x) ==> refl_on (INTER S A) (INTER S r)"
   197   by (unfold refl_on_def) fast
   198 
   199 lemma refl_on_UNION:
   200   "ALL x:S. refl_on (A x) (r x) \<Longrightarrow> refl_on (UNION S A) (UNION S r)"
   201   by (unfold refl_on_def) blast
   202 
   203 lemma refl_on_empty [simp]: "refl_on {} {}"
   204   by (simp add:refl_on_def)
   205 
   206 lemma refl_on_def' [nitpick_unfold, code]:
   207   "refl_on A r \<longleftrightarrow> (\<forall>(x, y) \<in> r. x \<in> A \<and> y \<in> A) \<and> (\<forall>x \<in> A. (x, x) \<in> r)"
   208   by (auto intro: refl_onI dest: refl_onD refl_onD1 refl_onD2)
   209 
   210 
   211 subsubsection {* Irreflexivity *}
   212 
   213 definition irrefl :: "'a rel \<Rightarrow> bool"
   214 where
   215   "irrefl r \<longleftrightarrow> (\<forall>x. (x, x) \<notin> r)"
   216 
   217 lemma irrefl_distinct [code]:
   218   "irrefl r \<longleftrightarrow> (\<forall>(x, y) \<in> r. x \<noteq> y)"
   219   by (auto simp add: irrefl_def)
   220 
   221 
   222 subsubsection {* Symmetry *}
   223 
   224 definition sym :: "'a rel \<Rightarrow> bool"
   225 where
   226   "sym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r)"
   227 
   228 definition symp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   229 where
   230   "symp r \<longleftrightarrow> (\<forall>x y. r x y \<longrightarrow> r y x)"
   231 
   232 lemma symp_sym_eq [pred_set_conv]:
   233   "symp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> sym r" 
   234   by (simp add: sym_def symp_def)
   235 
   236 lemma symI:
   237   "(\<And>a b. (a, b) \<in> r \<Longrightarrow> (b, a) \<in> r) \<Longrightarrow> sym r"
   238   by (unfold sym_def) iprover
   239 
   240 lemma sympI:
   241   "(\<And>a b. r a b \<Longrightarrow> r b a) \<Longrightarrow> symp r"
   242   by (fact symI [to_pred])
   243 
   244 lemma symE:
   245   assumes "sym r" and "(b, a) \<in> r"
   246   obtains "(a, b) \<in> r"
   247   using assms by (simp add: sym_def)
   248 
   249 lemma sympE:
   250   assumes "symp r" and "r b a"
   251   obtains "r a b"
   252   using assms by (rule symE [to_pred])
   253 
   254 lemma symD:
   255   assumes "sym r" and "(b, a) \<in> r"
   256   shows "(a, b) \<in> r"
   257   using assms by (rule symE)
   258 
   259 lemma sympD:
   260   assumes "symp r" and "r b a"
   261   shows "r a b"
   262   using assms by (rule symD [to_pred])
   263 
   264 lemma sym_Int:
   265   "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<inter> s)"
   266   by (fast intro: symI elim: symE)
   267 
   268 lemma symp_inf:
   269   "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<sqinter> s)"
   270   by (fact sym_Int [to_pred])
   271 
   272 lemma sym_Un:
   273   "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<union> s)"
   274   by (fast intro: symI elim: symE)
   275 
   276 lemma symp_sup:
   277   "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<squnion> s)"
   278   by (fact sym_Un [to_pred])
   279 
   280 lemma sym_INTER:
   281   "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (INTER S r)"
   282   by (fast intro: symI elim: symE)
   283 
   284 lemma symp_INF:
   285   "\<forall>x\<in>S. symp (r x) \<Longrightarrow> symp (INFI S r)"
   286   by (fact sym_INTER [to_pred])
   287 
   288 lemma sym_UNION:
   289   "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (UNION S r)"
   290   by (fast intro: symI elim: symE)
   291 
   292 lemma symp_SUP:
   293   "\<forall>x\<in>S. symp (r x) \<Longrightarrow> symp (SUPR S r)"
   294   by (fact sym_UNION [to_pred])
   295 
   296 
   297 subsubsection {* Antisymmetry *}
   298 
   299 definition antisym :: "'a rel \<Rightarrow> bool"
   300 where
   301   "antisym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r \<longrightarrow> x = y)"
   302 
   303 abbreviation antisymP :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   304 where
   305   "antisymP r \<equiv> antisym {(x, y). r x y}"
   306 
   307 lemma antisymI:
   308   "(!!x y. (x, y) : r ==> (y, x) : r ==> x=y) ==> antisym r"
   309   by (unfold antisym_def) iprover
   310 
   311 lemma antisymD: "antisym r ==> (a, b) : r ==> (b, a) : r ==> a = b"
   312   by (unfold antisym_def) iprover
   313 
   314 lemma antisym_subset: "r \<subseteq> s ==> antisym s ==> antisym r"
   315   by (unfold antisym_def) blast
   316 
   317 lemma antisym_empty [simp]: "antisym {}"
   318   by (unfold antisym_def) blast
   319 
   320 
   321 subsubsection {* Transitivity *}
   322 
   323 definition trans :: "'a rel \<Rightarrow> bool"
   324 where
   325   "trans r \<longleftrightarrow> (\<forall>x y z. (x, y) \<in> r \<longrightarrow> (y, z) \<in> r \<longrightarrow> (x, z) \<in> r)"
   326 
   327 definition transp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   328 where
   329   "transp r \<longleftrightarrow> (\<forall>x y z. r x y \<longrightarrow> r y z \<longrightarrow> r x z)"
   330 
   331 lemma transp_trans_eq [pred_set_conv]:
   332   "transp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> trans r" 
   333   by (simp add: trans_def transp_def)
   334 
   335 abbreviation transP :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   336 where -- {* FIXME drop *}
   337   "transP r \<equiv> trans {(x, y). r x y}"
   338 
   339 lemma transI:
   340   "(\<And>x y z. (x, y) \<in> r \<Longrightarrow> (y, z) \<in> r \<Longrightarrow> (x, z) \<in> r) \<Longrightarrow> trans r"
   341   by (unfold trans_def) iprover
   342 
   343 lemma transpI:
   344   "(\<And>x y z. r x y \<Longrightarrow> r y z \<Longrightarrow> r x z) \<Longrightarrow> transp r"
   345   by (fact transI [to_pred])
   346 
   347 lemma transE:
   348   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   349   obtains "(x, z) \<in> r"
   350   using assms by (unfold trans_def) iprover
   351 
   352 lemma transpE:
   353   assumes "transp r" and "r x y" and "r y z"
   354   obtains "r x z"
   355   using assms by (rule transE [to_pred])
   356 
   357 lemma transD:
   358   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   359   shows "(x, z) \<in> r"
   360   using assms by (rule transE)
   361 
   362 lemma transpD:
   363   assumes "transp r" and "r x y" and "r y z"
   364   shows "r x z"
   365   using assms by (rule transD [to_pred])
   366 
   367 lemma trans_Int:
   368   "trans r \<Longrightarrow> trans s \<Longrightarrow> trans (r \<inter> s)"
   369   by (fast intro: transI elim: transE)
   370 
   371 lemma transp_inf:
   372   "transp r \<Longrightarrow> transp s \<Longrightarrow> transp (r \<sqinter> s)"
   373   by (fact trans_Int [to_pred])
   374 
   375 lemma trans_INTER:
   376   "\<forall>x\<in>S. trans (r x) \<Longrightarrow> trans (INTER S r)"
   377   by (fast intro: transI elim: transD)
   378 
   379 (* FIXME thm trans_INTER [to_pred] *)
   380 
   381 lemma trans_join [code]:
   382   "trans r \<longleftrightarrow> (\<forall>(x, y1) \<in> r. \<forall>(y2, z) \<in> r. y1 = y2 \<longrightarrow> (x, z) \<in> r)"
   383   by (auto simp add: trans_def)
   384 
   385 lemma transp_trans:
   386   "transp r \<longleftrightarrow> trans {(x, y). r x y}"
   387   by (simp add: trans_def transp_def)
   388 
   389 
   390 subsubsection {* Totality *}
   391 
   392 definition total_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   393 where
   394   "total_on A r \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. x \<noteq> y \<longrightarrow> (x, y) \<in> r \<or> (y, x) \<in> r)"
   395 
   396 abbreviation "total \<equiv> total_on UNIV"
   397 
   398 lemma total_on_empty [simp]: "total_on {} r"
   399   by (simp add: total_on_def)
   400 
   401 
   402 subsubsection {* Single valued relations *}
   403 
   404 definition single_valued :: "('a \<times> 'b) set \<Rightarrow> bool"
   405 where
   406   "single_valued r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (\<forall>z. (x, z) \<in> r \<longrightarrow> y = z))"
   407 
   408 abbreviation single_valuedP :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool" where
   409   "single_valuedP r \<equiv> single_valued {(x, y). r x y}"
   410 
   411 lemma single_valuedI:
   412   "ALL x y. (x,y):r --> (ALL z. (x,z):r --> y=z) ==> single_valued r"
   413   by (unfold single_valued_def)
   414 
   415 lemma single_valuedD:
   416   "single_valued r ==> (x, y) : r ==> (x, z) : r ==> y = z"
   417   by (simp add: single_valued_def)
   418 
   419 lemma simgle_valued_empty[simp]: "single_valued {}"
   420 by(simp add: single_valued_def)
   421 
   422 lemma single_valued_subset:
   423   "r \<subseteq> s ==> single_valued s ==> single_valued r"
   424   by (unfold single_valued_def) blast
   425 
   426 
   427 subsection {* Relation operations *}
   428 
   429 subsubsection {* The identity relation *}
   430 
   431 definition Id :: "'a rel"
   432 where
   433   [code del]: "Id = {p. \<exists>x. p = (x, x)}"
   434 
   435 lemma IdI [intro]: "(a, a) : Id"
   436   by (simp add: Id_def)
   437 
   438 lemma IdE [elim!]: "p : Id ==> (!!x. p = (x, x) ==> P) ==> P"
   439   by (unfold Id_def) (iprover elim: CollectE)
   440 
   441 lemma pair_in_Id_conv [iff]: "((a, b) : Id) = (a = b)"
   442   by (unfold Id_def) blast
   443 
   444 lemma refl_Id: "refl Id"
   445   by (simp add: refl_on_def)
   446 
   447 lemma antisym_Id: "antisym Id"
   448   -- {* A strange result, since @{text Id} is also symmetric. *}
   449   by (simp add: antisym_def)
   450 
   451 lemma sym_Id: "sym Id"
   452   by (simp add: sym_def)
   453 
   454 lemma trans_Id: "trans Id"
   455   by (simp add: trans_def)
   456 
   457 lemma single_valued_Id [simp]: "single_valued Id"
   458   by (unfold single_valued_def) blast
   459 
   460 lemma irrefl_diff_Id [simp]: "irrefl (r - Id)"
   461   by (simp add:irrefl_def)
   462 
   463 lemma trans_diff_Id: "trans r \<Longrightarrow> antisym r \<Longrightarrow> trans (r - Id)"
   464   unfolding antisym_def trans_def by blast
   465 
   466 lemma total_on_diff_Id [simp]: "total_on A (r - Id) = total_on A r"
   467   by (simp add: total_on_def)
   468 
   469 
   470 subsubsection {* Diagonal: identity over a set *}
   471 
   472 definition Id_on  :: "'a set \<Rightarrow> 'a rel"
   473 where
   474   "Id_on A = (\<Union>x\<in>A. {(x, x)})"
   475 
   476 lemma Id_on_empty [simp]: "Id_on {} = {}"
   477   by (simp add: Id_on_def) 
   478 
   479 lemma Id_on_eqI: "a = b ==> a : A ==> (a, b) : Id_on A"
   480   by (simp add: Id_on_def)
   481 
   482 lemma Id_onI [intro!,no_atp]: "a : A ==> (a, a) : Id_on A"
   483   by (rule Id_on_eqI) (rule refl)
   484 
   485 lemma Id_onE [elim!]:
   486   "c : Id_on A ==> (!!x. x : A ==> c = (x, x) ==> P) ==> P"
   487   -- {* The general elimination rule. *}
   488   by (unfold Id_on_def) (iprover elim!: UN_E singletonE)
   489 
   490 lemma Id_on_iff: "((x, y) : Id_on A) = (x = y & x : A)"
   491   by blast
   492 
   493 lemma Id_on_def' [nitpick_unfold]:
   494   "Id_on {x. A x} = Collect (\<lambda>(x, y). x = y \<and> A x)"
   495   by auto
   496 
   497 lemma Id_on_subset_Times: "Id_on A \<subseteq> A \<times> A"
   498   by blast
   499 
   500 lemma refl_on_Id_on: "refl_on A (Id_on A)"
   501   by (rule refl_onI [OF Id_on_subset_Times Id_onI])
   502 
   503 lemma antisym_Id_on [simp]: "antisym (Id_on A)"
   504   by (unfold antisym_def) blast
   505 
   506 lemma sym_Id_on [simp]: "sym (Id_on A)"
   507   by (rule symI) clarify
   508 
   509 lemma trans_Id_on [simp]: "trans (Id_on A)"
   510   by (fast intro: transI elim: transD)
   511 
   512 lemma single_valued_Id_on [simp]: "single_valued (Id_on A)"
   513   by (unfold single_valued_def) blast
   514 
   515 
   516 subsubsection {* Composition *}
   517 
   518 inductive_set relcomp  :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'c) set \<Rightarrow> ('a \<times> 'c) set" (infixr "O" 75)
   519   for r :: "('a \<times> 'b) set" and s :: "('b \<times> 'c) set"
   520 where
   521   relcompI [intro]: "(a, b) \<in> r \<Longrightarrow> (b, c) \<in> s \<Longrightarrow> (a, c) \<in> r O s"
   522 
   523 notation relcompp (infixr "OO" 75)
   524 
   525 lemmas relcomppI = relcompp.intros
   526 
   527 text {*
   528   For historic reasons, the elimination rules are not wholly corresponding.
   529   Feel free to consolidate this.
   530 *}
   531 
   532 inductive_cases relcompEpair: "(a, c) \<in> r O s"
   533 inductive_cases relcomppE [elim!]: "(r OO s) a c"
   534 
   535 lemma relcompE [elim!]: "xz \<in> r O s \<Longrightarrow>
   536   (\<And>x y z. xz = (x, z) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> (y, z) \<in> s  \<Longrightarrow> P) \<Longrightarrow> P"
   537   by (cases xz) (simp, erule relcompEpair, iprover)
   538 
   539 lemma R_O_Id [simp]:
   540   "R O Id = R"
   541   by fast
   542 
   543 lemma Id_O_R [simp]:
   544   "Id O R = R"
   545   by fast
   546 
   547 lemma relcomp_empty1 [simp]:
   548   "{} O R = {}"
   549   by blast
   550 
   551 lemma relcompp_bot1 [simp]:
   552   "\<bottom> OO R = \<bottom>"
   553   by (fact relcomp_empty1 [to_pred])
   554 
   555 lemma relcomp_empty2 [simp]:
   556   "R O {} = {}"
   557   by blast
   558 
   559 lemma relcompp_bot2 [simp]:
   560   "R OO \<bottom> = \<bottom>"
   561   by (fact relcomp_empty2 [to_pred])
   562 
   563 lemma O_assoc:
   564   "(R O S) O T = R O (S O T)"
   565   by blast
   566 
   567 
   568 lemma relcompp_assoc:
   569   "(r OO s) OO t = r OO (s OO t)"
   570   by (fact O_assoc [to_pred])
   571 
   572 lemma trans_O_subset:
   573   "trans r \<Longrightarrow> r O r \<subseteq> r"
   574   by (unfold trans_def) blast
   575 
   576 lemma transp_relcompp_less_eq:
   577   "transp r \<Longrightarrow> r OO r \<le> r "
   578   by (fact trans_O_subset [to_pred])
   579 
   580 lemma relcomp_mono:
   581   "r' \<subseteq> r \<Longrightarrow> s' \<subseteq> s \<Longrightarrow> r' O s' \<subseteq> r O s"
   582   by blast
   583 
   584 lemma relcompp_mono:
   585   "r' \<le> r \<Longrightarrow> s' \<le> s \<Longrightarrow> r' OO s' \<le> r OO s "
   586   by (fact relcomp_mono [to_pred])
   587 
   588 lemma relcomp_subset_Sigma:
   589   "r \<subseteq> A \<times> B \<Longrightarrow> s \<subseteq> B \<times> C \<Longrightarrow> r O s \<subseteq> A \<times> C"
   590   by blast
   591 
   592 lemma relcomp_distrib [simp]:
   593   "R O (S \<union> T) = (R O S) \<union> (R O T)" 
   594   by auto
   595 
   596 lemma relcompp_distrib [simp]:
   597   "R OO (S \<squnion> T) = R OO S \<squnion> R OO T"
   598   by (fact relcomp_distrib [to_pred])
   599 
   600 lemma relcomp_distrib2 [simp]:
   601   "(S \<union> T) O R = (S O R) \<union> (T O R)"
   602   by auto
   603 
   604 lemma relcompp_distrib2 [simp]:
   605   "(S \<squnion> T) OO R = S OO R \<squnion> T OO R"
   606   by (fact relcomp_distrib2 [to_pred])
   607 
   608 lemma relcomp_UNION_distrib:
   609   "s O UNION I r = (\<Union>i\<in>I. s O r i) "
   610   by auto
   611 
   612 (* FIXME thm relcomp_UNION_distrib [to_pred] *)
   613 
   614 lemma relcomp_UNION_distrib2:
   615   "UNION I r O s = (\<Union>i\<in>I. r i O s) "
   616   by auto
   617 
   618 (* FIXME thm relcomp_UNION_distrib2 [to_pred] *)
   619 
   620 lemma single_valued_relcomp:
   621   "single_valued r \<Longrightarrow> single_valued s \<Longrightarrow> single_valued (r O s)"
   622   by (unfold single_valued_def) blast
   623 
   624 lemma relcomp_unfold:
   625   "r O s = {(x, z). \<exists>y. (x, y) \<in> r \<and> (y, z) \<in> s}"
   626   by (auto simp add: set_eq_iff)
   627 
   628 
   629 subsubsection {* Converse *}
   630 
   631 inductive_set converse :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'a) set" ("(_^-1)" [1000] 999)
   632   for r :: "('a \<times> 'b) set"
   633 where
   634   "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r^-1"
   635 
   636 notation (xsymbols)
   637   converse  ("(_\<inverse>)" [1000] 999)
   638 
   639 notation
   640   conversep ("(_^--1)" [1000] 1000)
   641 
   642 notation (xsymbols)
   643   conversep  ("(_\<inverse>\<inverse>)" [1000] 1000)
   644 
   645 lemma converseI [sym]:
   646   "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r\<inverse>"
   647   by (fact converse.intros)
   648 
   649 lemma conversepI (* CANDIDATE [sym] *):
   650   "r a b \<Longrightarrow> r\<inverse>\<inverse> b a"
   651   by (fact conversep.intros)
   652 
   653 lemma converseD [sym]:
   654   "(a, b) \<in> r\<inverse> \<Longrightarrow> (b, a) \<in> r"
   655   by (erule converse.cases) iprover
   656 
   657 lemma conversepD (* CANDIDATE [sym] *):
   658   "r\<inverse>\<inverse> b a \<Longrightarrow> r a b"
   659   by (fact converseD [to_pred])
   660 
   661 lemma converseE [elim!]:
   662   -- {* More general than @{text converseD}, as it ``splits'' the member of the relation. *}
   663   "yx \<in> r\<inverse> \<Longrightarrow> (\<And>x y. yx = (y, x) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> P) \<Longrightarrow> P"
   664   by (cases yx) (simp, erule converse.cases, iprover)
   665 
   666 lemmas conversepE [elim!] = conversep.cases
   667 
   668 lemma converse_iff [iff]:
   669   "(a, b) \<in> r\<inverse> \<longleftrightarrow> (b, a) \<in> r"
   670   by (auto intro: converseI)
   671 
   672 lemma conversep_iff [iff]:
   673   "r\<inverse>\<inverse> a b = r b a"
   674   by (fact converse_iff [to_pred])
   675 
   676 lemma converse_converse [simp]:
   677   "(r\<inverse>)\<inverse> = r"
   678   by (simp add: set_eq_iff)
   679 
   680 lemma conversep_conversep [simp]:
   681   "(r\<inverse>\<inverse>)\<inverse>\<inverse> = r"
   682   by (fact converse_converse [to_pred])
   683 
   684 lemma converse_relcomp: "(r O s)^-1 = s^-1 O r^-1"
   685   by blast
   686 
   687 lemma converse_relcompp: "(r OO s)^--1 = s^--1 OO r^--1"
   688   by (iprover intro: order_antisym conversepI relcomppI
   689     elim: relcomppE dest: conversepD)
   690 
   691 lemma converse_Int: "(r \<inter> s)^-1 = r^-1 \<inter> s^-1"
   692   by blast
   693 
   694 lemma converse_meet: "(r \<sqinter> s)^--1 = r^--1 \<sqinter> s^--1"
   695   by (simp add: inf_fun_def) (iprover intro: conversepI ext dest: conversepD)
   696 
   697 lemma converse_Un: "(r \<union> s)^-1 = r^-1 \<union> s^-1"
   698   by blast
   699 
   700 lemma converse_join: "(r \<squnion> s)^--1 = r^--1 \<squnion> s^--1"
   701   by (simp add: sup_fun_def) (iprover intro: conversepI ext dest: conversepD)
   702 
   703 lemma converse_INTER: "(INTER S r)^-1 = (INT x:S. (r x)^-1)"
   704   by fast
   705 
   706 lemma converse_UNION: "(UNION S r)^-1 = (UN x:S. (r x)^-1)"
   707   by blast
   708 
   709 lemma converse_Id [simp]: "Id^-1 = Id"
   710   by blast
   711 
   712 lemma converse_Id_on [simp]: "(Id_on A)^-1 = Id_on A"
   713   by blast
   714 
   715 lemma refl_on_converse [simp]: "refl_on A (converse r) = refl_on A r"
   716   by (unfold refl_on_def) auto
   717 
   718 lemma sym_converse [simp]: "sym (converse r) = sym r"
   719   by (unfold sym_def) blast
   720 
   721 lemma antisym_converse [simp]: "antisym (converse r) = antisym r"
   722   by (unfold antisym_def) blast
   723 
   724 lemma trans_converse [simp]: "trans (converse r) = trans r"
   725   by (unfold trans_def) blast
   726 
   727 lemma sym_conv_converse_eq: "sym r = (r^-1 = r)"
   728   by (unfold sym_def) fast
   729 
   730 lemma sym_Un_converse: "sym (r \<union> r^-1)"
   731   by (unfold sym_def) blast
   732 
   733 lemma sym_Int_converse: "sym (r \<inter> r^-1)"
   734   by (unfold sym_def) blast
   735 
   736 lemma total_on_converse [simp]: "total_on A (r^-1) = total_on A r"
   737   by (auto simp: total_on_def)
   738 
   739 lemma finite_converse [iff]: "finite (r^-1) = finite r"
   740   apply (subgoal_tac "r^-1 = (%(x,y). (y,x))`r")
   741    apply simp
   742    apply (rule iffI)
   743     apply (erule finite_imageD [unfolded inj_on_def])
   744     apply (simp split add: split_split)
   745    apply (erule finite_imageI)
   746   apply (simp add: set_eq_iff image_def, auto)
   747   apply (rule bexI)
   748    prefer 2 apply assumption
   749   apply simp
   750   done
   751 
   752 lemma conversep_noteq [simp]: "(op \<noteq>)^--1 = op \<noteq>"
   753   by (auto simp add: fun_eq_iff)
   754 
   755 lemma conversep_eq [simp]: "(op =)^--1 = op ="
   756   by (auto simp add: fun_eq_iff)
   757 
   758 lemma converse_unfold:
   759   "r\<inverse> = {(y, x). (x, y) \<in> r}"
   760   by (simp add: set_eq_iff)
   761 
   762 
   763 subsubsection {* Domain, range and field *}
   764 
   765 inductive_set Domain :: "('a \<times> 'b) set \<Rightarrow> 'a set"
   766   for r :: "('a \<times> 'b) set"
   767 where
   768   DomainI [intro]: "(a, b) \<in> r \<Longrightarrow> a \<in> Domain r"
   769 
   770 abbreviation (input) "DomainP \<equiv> Domainp"
   771 
   772 lemmas DomainPI = Domainp.DomainI
   773 
   774 inductive_cases DomainE [elim!]: "a \<in> Domain r"
   775 inductive_cases DomainpE [elim!]: "Domainp r a"
   776 
   777 inductive_set Range :: "('a \<times> 'b) set \<Rightarrow> 'b set"
   778   for r :: "('a \<times> 'b) set"
   779 where
   780   RangeI [intro]: "(a, b) \<in> r \<Longrightarrow> b \<in> Range r"
   781 
   782 abbreviation (input) "RangeP \<equiv> Rangep"
   783 
   784 lemmas RangePI = Rangep.RangeI
   785 
   786 inductive_cases RangeE [elim!]: "b \<in> Range r"
   787 inductive_cases RangepE [elim!]: "Rangep r b"
   788 
   789 definition Field :: "'a rel \<Rightarrow> 'a set"
   790 where
   791   "Field r = Domain r \<union> Range r"
   792 
   793 lemma Domain_fst [code]:
   794   "Domain r = fst ` r"
   795   by force
   796 
   797 lemma Range_snd [code]:
   798   "Range r = snd ` r"
   799   by force
   800 
   801 lemma fst_eq_Domain: "fst ` R = Domain R"
   802   by force
   803 
   804 lemma snd_eq_Range: "snd ` R = Range R"
   805   by force
   806 
   807 lemma Domain_empty [simp]: "Domain {} = {}"
   808   by auto
   809 
   810 lemma Range_empty [simp]: "Range {} = {}"
   811   by auto
   812 
   813 lemma Field_empty [simp]: "Field {} = {}"
   814   by (simp add: Field_def)
   815 
   816 lemma Domain_empty_iff: "Domain r = {} \<longleftrightarrow> r = {}"
   817   by auto
   818 
   819 lemma Range_empty_iff: "Range r = {} \<longleftrightarrow> r = {}"
   820   by auto
   821 
   822 lemma Domain_insert [simp]: "Domain (insert (a, b) r) = insert a (Domain r)"
   823   by blast
   824 
   825 lemma Range_insert [simp]: "Range (insert (a, b) r) = insert b (Range r)"
   826   by blast
   827 
   828 lemma Field_insert [simp]: "Field (insert (a, b) r) = {a, b} \<union> Field r"
   829   by (auto simp add: Field_def)
   830 
   831 lemma Domain_iff: "a \<in> Domain r \<longleftrightarrow> (\<exists>y. (a, y) \<in> r)"
   832   by blast
   833 
   834 lemma Range_iff: "a \<in> Range r \<longleftrightarrow> (\<exists>y. (y, a) \<in> r)"
   835   by blast
   836 
   837 lemma Domain_Id [simp]: "Domain Id = UNIV"
   838   by blast
   839 
   840 lemma Range_Id [simp]: "Range Id = UNIV"
   841   by blast
   842 
   843 lemma Domain_Id_on [simp]: "Domain (Id_on A) = A"
   844   by blast
   845 
   846 lemma Range_Id_on [simp]: "Range (Id_on A) = A"
   847   by blast
   848 
   849 lemma Domain_Un_eq: "Domain (A \<union> B) = Domain A \<union> Domain B"
   850   by blast
   851 
   852 lemma Range_Un_eq: "Range (A \<union> B) = Range A \<union> Range B"
   853   by blast
   854 
   855 lemma Field_Un [simp]: "Field (r \<union> s) = Field r \<union> Field s"
   856   by (auto simp: Field_def)
   857 
   858 lemma Domain_Int_subset: "Domain (A \<inter> B) \<subseteq> Domain A \<inter> Domain B"
   859   by blast
   860 
   861 lemma Range_Int_subset: "Range (A \<inter> B) \<subseteq> Range A \<inter> Range B"
   862   by blast
   863 
   864 lemma Domain_Diff_subset: "Domain A - Domain B \<subseteq> Domain (A - B)"
   865   by blast
   866 
   867 lemma Range_Diff_subset: "Range A - Range B \<subseteq> Range (A - B)"
   868   by blast
   869 
   870 lemma Domain_Union: "Domain (\<Union>S) = (\<Union>A\<in>S. Domain A)"
   871   by blast
   872 
   873 lemma Range_Union: "Range (\<Union>S) = (\<Union>A\<in>S. Range A)"
   874   by blast
   875 
   876 lemma Field_Union [simp]: "Field (\<Union>R) = \<Union>(Field ` R)"
   877   by (auto simp: Field_def)
   878 
   879 lemma Domain_converse [simp]: "Domain (r\<inverse>) = Range r"
   880   by auto
   881 
   882 lemma Range_converse [simp]: "Range (r\<inverse>) = Domain r"
   883   by blast
   884 
   885 lemma Field_converse [simp]: "Field (r\<inverse>) = Field r"
   886   by (auto simp: Field_def)
   887 
   888 lemma Domain_Collect_split [simp]: "Domain {(x, y). P x y} = {x. EX y. P x y}"
   889   by auto
   890 
   891 lemma Range_Collect_split [simp]: "Range {(x, y). P x y} = {y. EX x. P x y}"
   892   by auto
   893 
   894 lemma finite_Domain: "finite r \<Longrightarrow> finite (Domain r)"
   895   by (induct set: finite) auto
   896 
   897 lemma finite_Range: "finite r \<Longrightarrow> finite (Range r)"
   898   by (induct set: finite) auto
   899 
   900 lemma finite_Field: "finite r \<Longrightarrow> finite (Field r)"
   901   by (simp add: Field_def finite_Domain finite_Range)
   902 
   903 lemma Domain_mono: "r \<subseteq> s \<Longrightarrow> Domain r \<subseteq> Domain s"
   904   by blast
   905 
   906 lemma Range_mono: "r \<subseteq> s \<Longrightarrow> Range r \<subseteq> Range s"
   907   by blast
   908 
   909 lemma mono_Field: "r \<subseteq> s \<Longrightarrow> Field r \<subseteq> Field s"
   910   by (auto simp: Field_def Domain_def Range_def)
   911 
   912 lemma Domain_unfold:
   913   "Domain r = {x. \<exists>y. (x, y) \<in> r}"
   914   by blast
   915 
   916 lemma Domain_dprod [simp]: "Domain (dprod r s) = uprod (Domain r) (Domain s)"
   917   by auto
   918 
   919 lemma Domain_dsum [simp]: "Domain (dsum r s) = usum (Domain r) (Domain s)"
   920   by auto
   921 
   922 
   923 subsubsection {* Image of a set under a relation *}
   924 
   925 definition Image :: "('a \<times> 'b) set \<Rightarrow> 'a set \<Rightarrow> 'b set" (infixr "``" 90)
   926 where
   927   "r `` s = {y. \<exists>x\<in>s. (x, y) \<in> r}"
   928 
   929 declare Image_def [no_atp]
   930 
   931 lemma Image_iff: "(b : r``A) = (EX x:A. (x, b) : r)"
   932   by (simp add: Image_def)
   933 
   934 lemma Image_singleton: "r``{a} = {b. (a, b) : r}"
   935   by (simp add: Image_def)
   936 
   937 lemma Image_singleton_iff [iff]: "(b : r``{a}) = ((a, b) : r)"
   938   by (rule Image_iff [THEN trans]) simp
   939 
   940 lemma ImageI [intro,no_atp]: "(a, b) : r ==> a : A ==> b : r``A"
   941   by (unfold Image_def) blast
   942 
   943 lemma ImageE [elim!]:
   944   "b : r `` A ==> (!!x. (x, b) : r ==> x : A ==> P) ==> P"
   945   by (unfold Image_def) (iprover elim!: CollectE bexE)
   946 
   947 lemma rev_ImageI: "a : A ==> (a, b) : r ==> b : r `` A"
   948   -- {* This version's more effective when we already have the required @{text a} *}
   949   by blast
   950 
   951 lemma Image_empty [simp]: "R``{} = {}"
   952   by blast
   953 
   954 lemma Image_Id [simp]: "Id `` A = A"
   955   by blast
   956 
   957 lemma Image_Id_on [simp]: "Id_on A `` B = A \<inter> B"
   958   by blast
   959 
   960 lemma Image_Int_subset: "R `` (A \<inter> B) \<subseteq> R `` A \<inter> R `` B"
   961   by blast
   962 
   963 lemma Image_Int_eq:
   964   "single_valued (converse R) ==> R `` (A \<inter> B) = R `` A \<inter> R `` B"
   965   by (simp add: single_valued_def, blast) 
   966 
   967 lemma Image_Un: "R `` (A \<union> B) = R `` A \<union> R `` B"
   968   by blast
   969 
   970 lemma Un_Image: "(R \<union> S) `` A = R `` A \<union> S `` A"
   971   by blast
   972 
   973 lemma Image_subset: "r \<subseteq> A \<times> B ==> r``C \<subseteq> B"
   974   by (iprover intro!: subsetI elim!: ImageE dest!: subsetD SigmaD2)
   975 
   976 lemma Image_eq_UN: "r``B = (\<Union>y\<in> B. r``{y})"
   977   -- {* NOT suitable for rewriting *}
   978   by blast
   979 
   980 lemma Image_mono: "r' \<subseteq> r ==> A' \<subseteq> A ==> (r' `` A') \<subseteq> (r `` A)"
   981   by blast
   982 
   983 lemma Image_UN: "(r `` (UNION A B)) = (\<Union>x\<in>A. r `` (B x))"
   984   by blast
   985 
   986 lemma Image_INT_subset: "(r `` INTER A B) \<subseteq> (\<Inter>x\<in>A. r `` (B x))"
   987   by blast
   988 
   989 text{*Converse inclusion requires some assumptions*}
   990 lemma Image_INT_eq:
   991      "[|single_valued (r\<inverse>); A\<noteq>{}|] ==> r `` INTER A B = (\<Inter>x\<in>A. r `` B x)"
   992 apply (rule equalityI)
   993  apply (rule Image_INT_subset) 
   994 apply  (simp add: single_valued_def, blast)
   995 done
   996 
   997 lemma Image_subset_eq: "(r``A \<subseteq> B) = (A \<subseteq> - ((r^-1) `` (-B)))"
   998   by blast
   999 
  1000 lemma Image_Collect_split [simp]: "{(x, y). P x y} `` A = {y. EX x:A. P x y}"
  1001   by auto
  1002 
  1003 
  1004 subsubsection {* Inverse image *}
  1005 
  1006 definition inv_image :: "'b rel \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a rel"
  1007 where
  1008   "inv_image r f = {(x, y). (f x, f y) \<in> r}"
  1009 
  1010 definition inv_imagep :: "('b \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
  1011 where
  1012   "inv_imagep r f = (\<lambda>x y. r (f x) (f y))"
  1013 
  1014 lemma [pred_set_conv]: "inv_imagep (\<lambda>x y. (x, y) \<in> r) f = (\<lambda>x y. (x, y) \<in> inv_image r f)"
  1015   by (simp add: inv_image_def inv_imagep_def)
  1016 
  1017 lemma sym_inv_image: "sym r ==> sym (inv_image r f)"
  1018   by (unfold sym_def inv_image_def) blast
  1019 
  1020 lemma trans_inv_image: "trans r ==> trans (inv_image r f)"
  1021   apply (unfold trans_def inv_image_def)
  1022   apply (simp (no_asm))
  1023   apply blast
  1024   done
  1025 
  1026 lemma in_inv_image[simp]: "((x,y) : inv_image r f) = ((f x, f y) : r)"
  1027   by (auto simp:inv_image_def)
  1028 
  1029 lemma converse_inv_image[simp]: "(inv_image R f)^-1 = inv_image (R^-1) f"
  1030   unfolding inv_image_def converse_unfold by auto
  1031 
  1032 lemma in_inv_imagep [simp]: "inv_imagep r f x y = r (f x) (f y)"
  1033   by (simp add: inv_imagep_def)
  1034 
  1035 
  1036 subsubsection {* Powerset *}
  1037 
  1038 definition Powp :: "('a \<Rightarrow> bool) \<Rightarrow> 'a set \<Rightarrow> bool"
  1039 where
  1040   "Powp A = (\<lambda>B. \<forall>x \<in> B. A x)"
  1041 
  1042 lemma Powp_Pow_eq [pred_set_conv]: "Powp (\<lambda>x. x \<in> A) = (\<lambda>x. x \<in> Pow A)"
  1043   by (auto simp add: Powp_def fun_eq_iff)
  1044 
  1045 lemmas Powp_mono [mono] = Pow_mono [to_pred]
  1046 
  1047 subsubsection {* Expressing relation operations via @{const Finite_Set.fold} *}
  1048 
  1049 lemma Id_on_fold:
  1050   assumes "finite A"
  1051   shows "Id_on A = Finite_Set.fold (\<lambda>x. Set.insert (Pair x x)) {} A"
  1052 proof -
  1053   interpret comp_fun_commute "\<lambda>x. Set.insert (Pair x x)" by default auto
  1054   show ?thesis using assms unfolding Id_on_def by (induct A) simp_all
  1055 qed
  1056 
  1057 lemma comp_fun_commute_Image_fold:
  1058   "comp_fun_commute (\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A)"
  1059 proof -
  1060   interpret comp_fun_idem Set.insert
  1061       by (fact comp_fun_idem_insert)
  1062   show ?thesis 
  1063   by default (auto simp add: fun_eq_iff comp_fun_commute split:prod.split)
  1064 qed
  1065 
  1066 lemma Image_fold:
  1067   assumes "finite R"
  1068   shows "R `` S = Finite_Set.fold (\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A) {} R"
  1069 proof -
  1070   interpret comp_fun_commute "(\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A)" 
  1071     by (rule comp_fun_commute_Image_fold)
  1072   have *: "\<And>x F. Set.insert x F `` S = (if fst x \<in> S then Set.insert (snd x) (F `` S) else (F `` S))"
  1073     by (auto intro: rev_ImageI)
  1074   show ?thesis using assms by (induct R) (auto simp: *)
  1075 qed
  1076 
  1077 lemma insert_relcomp_union_fold:
  1078   assumes "finite S"
  1079   shows "{x} O S \<union> X = Finite_Set.fold (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A') X S"
  1080 proof -
  1081   interpret comp_fun_commute "\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A'"
  1082   proof - 
  1083     interpret comp_fun_idem Set.insert by (fact comp_fun_idem_insert)
  1084     show "comp_fun_commute (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A')"
  1085     by default (auto simp add: fun_eq_iff split:prod.split)
  1086   qed
  1087   have *: "{x} O S = {(x', z). x' = fst x \<and> (snd x,z) \<in> S}" by (auto simp: relcomp_unfold intro!: exI)
  1088   show ?thesis unfolding *
  1089   using `finite S` by (induct S) (auto split: prod.split)
  1090 qed
  1091 
  1092 lemma insert_relcomp_fold:
  1093   assumes "finite S"
  1094   shows "Set.insert x R O S = 
  1095     Finite_Set.fold (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A') (R O S) S"
  1096 proof -
  1097   have "Set.insert x R O S = ({x} O S) \<union> (R O S)" by auto
  1098   then show ?thesis by (auto simp: insert_relcomp_union_fold[OF assms])
  1099 qed
  1100 
  1101 lemma comp_fun_commute_relcomp_fold:
  1102   assumes "finite S"
  1103   shows "comp_fun_commute (\<lambda>(x,y) A. 
  1104     Finite_Set.fold (\<lambda>(w,z) A'. if y = w then Set.insert (x,z) A' else A') A S)"
  1105 proof -
  1106   have *: "\<And>a b A. 
  1107     Finite_Set.fold (\<lambda>(w, z) A'. if b = w then Set.insert (a, z) A' else A') A S = {(a,b)} O S \<union> A"
  1108     by (auto simp: insert_relcomp_union_fold[OF assms] cong: if_cong)
  1109   show ?thesis by default (auto simp: *)
  1110 qed
  1111 
  1112 lemma relcomp_fold:
  1113   assumes "finite R"
  1114   assumes "finite S"
  1115   shows "R O S = Finite_Set.fold 
  1116     (\<lambda>(x,y) A. Finite_Set.fold (\<lambda>(w,z) A'. if y = w then Set.insert (x,z) A' else A') A S) {} R"
  1117 proof -
  1118   show ?thesis using assms by (induct R) 
  1119     (auto simp: comp_fun_commute.fold_insert comp_fun_commute_relcomp_fold insert_relcomp_fold 
  1120       cong: if_cong)
  1121 qed
  1122 
  1123 
  1124 
  1125 end
  1126