src/HOL/Transcendental.thy
author haftmann
Sun Jun 23 21:16:07 2013 +0200 (2013-06-23)
changeset 52435 6646bb548c6b
parent 52139 40fe6b80b481
child 53015 a1119cf551e8
permissions -rw-r--r--
migration from code_(const|type|class|instance) to code_printing and from code_module to code_identifier
     1 (*  Title:      HOL/Transcendental.thy
     2     Author:     Jacques D. Fleuriot, University of Cambridge, University of Edinburgh
     3     Author:     Lawrence C Paulson
     4     Author:     Jeremy Avigad
     5 
     6 *)
     7 
     8 header{*Power Series, Transcendental Functions etc.*}
     9 
    10 theory Transcendental
    11 imports Fact Series Deriv NthRoot
    12 begin
    13 
    14 subsection {* Properties of Power Series *}
    15 
    16 lemma lemma_realpow_diff:
    17   fixes y :: "'a::monoid_mult"
    18   shows "p \<le> n \<Longrightarrow> y ^ (Suc n - p) = (y ^ (n - p)) * y"
    19 proof -
    20   assume "p \<le> n"
    21   hence "Suc n - p = Suc (n - p)" by (rule Suc_diff_le)
    22   thus ?thesis by (simp add: power_commutes)
    23 qed
    24 
    25 lemma lemma_realpow_diff_sumr:
    26   fixes y :: "'a::{comm_semiring_0,monoid_mult}" shows
    27      "(\<Sum>p=0..<Suc n. (x ^ p) * y ^ (Suc n - p)) =
    28       y * (\<Sum>p=0..<Suc n. (x ^ p) * y ^ (n - p))"
    29 by (simp add: setsum_right_distrib lemma_realpow_diff mult_ac
    30          del: setsum_op_ivl_Suc)
    31 
    32 lemma lemma_realpow_diff_sumr2:
    33   fixes y :: "'a::{comm_ring,monoid_mult}" shows
    34      "x ^ (Suc n) - y ^ (Suc n) =
    35       (x - y) * (\<Sum>p=0..<Suc n. (x ^ p) * y ^ (n - p))"
    36 apply (induct n, simp)
    37 apply (simp del: setsum_op_ivl_Suc)
    38 apply (subst setsum_op_ivl_Suc)
    39 apply (subst lemma_realpow_diff_sumr)
    40 apply (simp add: distrib_left del: setsum_op_ivl_Suc)
    41 apply (subst mult_left_commute [of "x - y"])
    42 apply (erule subst)
    43 apply (simp add: algebra_simps)
    44 done
    45 
    46 lemma lemma_realpow_rev_sumr:
    47      "(\<Sum>p=0..<Suc n. (x ^ p) * (y ^ (n - p))) =
    48       (\<Sum>p=0..<Suc n. (x ^ (n - p)) * (y ^ p))"
    49 apply (rule setsum_reindex_cong [where f="\<lambda>i. n - i"])
    50 apply (rule inj_onI, simp)
    51 apply auto
    52 apply (rule_tac x="n - x" in image_eqI, simp, simp)
    53 done
    54 
    55 text{*Power series has a `circle` of convergence, i.e. if it sums for @{term
    56 x}, then it sums absolutely for @{term z} with @{term "\<bar>z\<bar> < \<bar>x\<bar>"}.*}
    57 
    58 lemma powser_insidea:
    59   fixes x z :: "'a::real_normed_field"
    60   assumes 1: "summable (\<lambda>n. f n * x ^ n)"
    61   assumes 2: "norm z < norm x"
    62   shows "summable (\<lambda>n. norm (f n * z ^ n))"
    63 proof -
    64   from 2 have x_neq_0: "x \<noteq> 0" by clarsimp
    65   from 1 have "(\<lambda>n. f n * x ^ n) ----> 0"
    66     by (rule summable_LIMSEQ_zero)
    67   hence "convergent (\<lambda>n. f n * x ^ n)"
    68     by (rule convergentI)
    69   hence "Cauchy (\<lambda>n. f n * x ^ n)"
    70     by (rule convergent_Cauchy)
    71   hence "Bseq (\<lambda>n. f n * x ^ n)"
    72     by (rule Cauchy_Bseq)
    73   then obtain K where 3: "0 < K" and 4: "\<forall>n. norm (f n * x ^ n) \<le> K"
    74     by (simp add: Bseq_def, safe)
    75   have "\<exists>N. \<forall>n\<ge>N. norm (norm (f n * z ^ n)) \<le>
    76                    K * norm (z ^ n) * inverse (norm (x ^ n))"
    77   proof (intro exI allI impI)
    78     fix n::nat assume "0 \<le> n"
    79     have "norm (norm (f n * z ^ n)) * norm (x ^ n) =
    80           norm (f n * x ^ n) * norm (z ^ n)"
    81       by (simp add: norm_mult abs_mult)
    82     also have "\<dots> \<le> K * norm (z ^ n)"
    83       by (simp only: mult_right_mono 4 norm_ge_zero)
    84     also have "\<dots> = K * norm (z ^ n) * (inverse (norm (x ^ n)) * norm (x ^ n))"
    85       by (simp add: x_neq_0)
    86     also have "\<dots> = K * norm (z ^ n) * inverse (norm (x ^ n)) * norm (x ^ n)"
    87       by (simp only: mult_assoc)
    88     finally show "norm (norm (f n * z ^ n)) \<le>
    89                   K * norm (z ^ n) * inverse (norm (x ^ n))"
    90       by (simp add: mult_le_cancel_right x_neq_0)
    91   qed
    92   moreover have "summable (\<lambda>n. K * norm (z ^ n) * inverse (norm (x ^ n)))"
    93   proof -
    94     from 2 have "norm (norm (z * inverse x)) < 1"
    95       using x_neq_0
    96       by (simp add: nonzero_norm_divide divide_inverse [symmetric])
    97     hence "summable (\<lambda>n. norm (z * inverse x) ^ n)"
    98       by (rule summable_geometric)
    99     hence "summable (\<lambda>n. K * norm (z * inverse x) ^ n)"
   100       by (rule summable_mult)
   101     thus "summable (\<lambda>n. K * norm (z ^ n) * inverse (norm (x ^ n)))"
   102       using x_neq_0
   103       by (simp add: norm_mult nonzero_norm_inverse power_mult_distrib
   104                     power_inverse norm_power mult_assoc)
   105   qed
   106   ultimately show "summable (\<lambda>n. norm (f n * z ^ n))"
   107     by (rule summable_comparison_test)
   108 qed
   109 
   110 lemma powser_inside:
   111   fixes f :: "nat \<Rightarrow> 'a::{real_normed_field,banach}" shows
   112      "[| summable (%n. f(n) * (x ^ n)); norm z < norm x |]
   113       ==> summable (%n. f(n) * (z ^ n))"
   114 by (rule powser_insidea [THEN summable_norm_cancel])
   115 
   116 lemma sum_split_even_odd: fixes f :: "nat \<Rightarrow> real" shows
   117   "(\<Sum> i = 0 ..< 2 * n. if even i then f i else g i) =
   118    (\<Sum> i = 0 ..< n. f (2 * i)) + (\<Sum> i = 0 ..< n. g (2 * i + 1))"
   119 proof (induct n)
   120   case (Suc n)
   121   have "(\<Sum> i = 0 ..< 2 * Suc n. if even i then f i else g i) =
   122         (\<Sum> i = 0 ..< n. f (2 * i)) + (\<Sum> i = 0 ..< n. g (2 * i + 1)) + (f (2 * n) + g (2 * n + 1))"
   123     using Suc.hyps unfolding One_nat_def by auto
   124   also have "\<dots> = (\<Sum> i = 0 ..< Suc n. f (2 * i)) + (\<Sum> i = 0 ..< Suc n. g (2 * i + 1))" by auto
   125   finally show ?case .
   126 qed auto
   127 
   128 lemma sums_if': fixes g :: "nat \<Rightarrow> real" assumes "g sums x"
   129   shows "(\<lambda> n. if even n then 0 else g ((n - 1) div 2)) sums x"
   130   unfolding sums_def
   131 proof (rule LIMSEQ_I)
   132   fix r :: real assume "0 < r"
   133   from `g sums x`[unfolded sums_def, THEN LIMSEQ_D, OF this]
   134   obtain no where no_eq: "\<And> n. n \<ge> no \<Longrightarrow> (norm (setsum g { 0..<n } - x) < r)" by blast
   135 
   136   let ?SUM = "\<lambda> m. \<Sum> i = 0 ..< m. if even i then 0 else g ((i - 1) div 2)"
   137   { fix m assume "m \<ge> 2 * no" hence "m div 2 \<ge> no" by auto
   138     have sum_eq: "?SUM (2 * (m div 2)) = setsum g { 0 ..< m div 2 }"
   139       using sum_split_even_odd by auto
   140     hence "(norm (?SUM (2 * (m div 2)) - x) < r)" using no_eq unfolding sum_eq using `m div 2 \<ge> no` by auto
   141     moreover
   142     have "?SUM (2 * (m div 2)) = ?SUM m"
   143     proof (cases "even m")
   144       case True show ?thesis unfolding even_nat_div_two_times_two[OF True, unfolded numeral_2_eq_2[symmetric]] ..
   145     next
   146       case False hence "even (Suc m)" by auto
   147       from even_nat_div_two_times_two[OF this, unfolded numeral_2_eq_2[symmetric]] odd_nat_plus_one_div_two[OF False, unfolded numeral_2_eq_2[symmetric]]
   148       have eq: "Suc (2 * (m div 2)) = m" by auto
   149       hence "even (2 * (m div 2))" using `odd m` by auto
   150       have "?SUM m = ?SUM (Suc (2 * (m div 2)))" unfolding eq ..
   151       also have "\<dots> = ?SUM (2 * (m div 2))" using `even (2 * (m div 2))` by auto
   152       finally show ?thesis by auto
   153     qed
   154     ultimately have "(norm (?SUM m - x) < r)" by auto
   155   }
   156   thus "\<exists> no. \<forall> m \<ge> no. norm (?SUM m - x) < r" by blast
   157 qed
   158 
   159 lemma sums_if: fixes g :: "nat \<Rightarrow> real" assumes "g sums x" and "f sums y"
   160   shows "(\<lambda> n. if even n then f (n div 2) else g ((n - 1) div 2)) sums (x + y)"
   161 proof -
   162   let ?s = "\<lambda> n. if even n then 0 else f ((n - 1) div 2)"
   163   { fix B T E have "(if B then (0 :: real) else E) + (if B then T else 0) = (if B then T else E)"
   164       by (cases B) auto } note if_sum = this
   165   have g_sums: "(\<lambda> n. if even n then 0 else g ((n - 1) div 2)) sums x" using sums_if'[OF `g sums x`] .
   166   {
   167     have "?s 0 = 0" by auto
   168     have Suc_m1: "\<And> n. Suc n - 1 = n" by auto
   169     have if_eq: "\<And>B T E. (if \<not> B then T else E) = (if B then E else T)" by auto
   170 
   171     have "?s sums y" using sums_if'[OF `f sums y`] .
   172     from this[unfolded sums_def, THEN LIMSEQ_Suc]
   173     have "(\<lambda> n. if even n then f (n div 2) else 0) sums y"
   174       unfolding sums_def setsum_shift_lb_Suc0_0_upt[where f="?s", OF `?s 0 = 0`, symmetric]
   175                 image_Suc_atLeastLessThan[symmetric] setsum_reindex[OF inj_Suc, unfolded comp_def]
   176                 even_Suc Suc_m1 if_eq .
   177   } from sums_add[OF g_sums this]
   178   show ?thesis unfolding if_sum .
   179 qed
   180 
   181 subsection {* Alternating series test / Leibniz formula *}
   182 
   183 lemma sums_alternating_upper_lower:
   184   fixes a :: "nat \<Rightarrow> real"
   185   assumes mono: "\<And>n. a (Suc n) \<le> a n" and a_pos: "\<And>n. 0 \<le> a n" and "a ----> 0"
   186   shows "\<exists>l. ((\<forall>n. (\<Sum>i=0..<2*n. -1^i*a i) \<le> l) \<and> (\<lambda> n. \<Sum>i=0..<2*n. -1^i*a i) ----> l) \<and>
   187              ((\<forall>n. l \<le> (\<Sum>i=0..<2*n + 1. -1^i*a i)) \<and> (\<lambda> n. \<Sum>i=0..<2*n + 1. -1^i*a i) ----> l)"
   188   (is "\<exists>l. ((\<forall>n. ?f n \<le> l) \<and> _) \<and> ((\<forall>n. l \<le> ?g n) \<and> _)")
   189 proof -
   190   have fg_diff: "\<And>n. ?f n - ?g n = - a (2 * n)" unfolding One_nat_def by auto
   191 
   192   have "\<forall> n. ?f n \<le> ?f (Suc n)"
   193   proof fix n show "?f n \<le> ?f (Suc n)" using mono[of "2*n"] by auto qed
   194   moreover
   195   have "\<forall> n. ?g (Suc n) \<le> ?g n"
   196   proof fix n show "?g (Suc n) \<le> ?g n" using mono[of "Suc (2*n)"]
   197     unfolding One_nat_def by auto qed
   198   moreover
   199   have "\<forall> n. ?f n \<le> ?g n"
   200   proof fix n show "?f n \<le> ?g n" using fg_diff a_pos
   201     unfolding One_nat_def by auto qed
   202   moreover
   203   have "(\<lambda> n. ?f n - ?g n) ----> 0" unfolding fg_diff
   204   proof (rule LIMSEQ_I)
   205     fix r :: real assume "0 < r"
   206     with `a ----> 0`[THEN LIMSEQ_D]
   207     obtain N where "\<And> n. n \<ge> N \<Longrightarrow> norm (a n - 0) < r" by auto
   208     hence "\<forall> n \<ge> N. norm (- a (2 * n) - 0) < r" by auto
   209     thus "\<exists> N. \<forall> n \<ge> N. norm (- a (2 * n) - 0) < r" by auto
   210   qed
   211   ultimately
   212   show ?thesis by (rule nested_sequence_unique)
   213 qed
   214 
   215 lemma summable_Leibniz': fixes a :: "nat \<Rightarrow> real"
   216   assumes a_zero: "a ----> 0" and a_pos: "\<And> n. 0 \<le> a n"
   217   and a_monotone: "\<And> n. a (Suc n) \<le> a n"
   218   shows summable: "summable (\<lambda> n. (-1)^n * a n)"
   219   and "\<And>n. (\<Sum>i=0..<2*n. (-1)^i*a i) \<le> (\<Sum>i. (-1)^i*a i)"
   220   and "(\<lambda>n. \<Sum>i=0..<2*n. (-1)^i*a i) ----> (\<Sum>i. (-1)^i*a i)"
   221   and "\<And>n. (\<Sum>i. (-1)^i*a i) \<le> (\<Sum>i=0..<2*n+1. (-1)^i*a i)"
   222   and "(\<lambda>n. \<Sum>i=0..<2*n+1. (-1)^i*a i) ----> (\<Sum>i. (-1)^i*a i)"
   223 proof -
   224   let "?S n" = "(-1)^n * a n"
   225   let "?P n" = "\<Sum>i=0..<n. ?S i"
   226   let "?f n" = "?P (2 * n)"
   227   let "?g n" = "?P (2 * n + 1)"
   228   obtain l :: real where below_l: "\<forall> n. ?f n \<le> l" and "?f ----> l" and above_l: "\<forall> n. l \<le> ?g n" and "?g ----> l"
   229     using sums_alternating_upper_lower[OF a_monotone a_pos a_zero] by blast
   230 
   231   let ?Sa = "\<lambda> m. \<Sum> n = 0..<m. ?S n"
   232   have "?Sa ----> l"
   233   proof (rule LIMSEQ_I)
   234     fix r :: real assume "0 < r"
   235 
   236     with `?f ----> l`[THEN LIMSEQ_D]
   237     obtain f_no where f: "\<And> n. n \<ge> f_no \<Longrightarrow> norm (?f n - l) < r" by auto
   238 
   239     from `0 < r` `?g ----> l`[THEN LIMSEQ_D]
   240     obtain g_no where g: "\<And> n. n \<ge> g_no \<Longrightarrow> norm (?g n - l) < r" by auto
   241 
   242     { fix n :: nat
   243       assume "n \<ge> (max (2 * f_no) (2 * g_no))" hence "n \<ge> 2 * f_no" and "n \<ge> 2 * g_no" by auto
   244       have "norm (?Sa n - l) < r"
   245       proof (cases "even n")
   246         case True from even_nat_div_two_times_two[OF this]
   247         have n_eq: "2 * (n div 2) = n" unfolding numeral_2_eq_2[symmetric] by auto
   248         with `n \<ge> 2 * f_no` have "n div 2 \<ge> f_no" by auto
   249         from f[OF this]
   250         show ?thesis unfolding n_eq atLeastLessThanSuc_atLeastAtMost .
   251       next
   252         case False hence "even (n - 1)" by simp
   253         from even_nat_div_two_times_two[OF this]
   254         have n_eq: "2 * ((n - 1) div 2) = n - 1" unfolding numeral_2_eq_2[symmetric] by auto
   255         hence range_eq: "n - 1 + 1 = n" using odd_pos[OF False] by auto
   256 
   257         from n_eq `n \<ge> 2 * g_no` have "(n - 1) div 2 \<ge> g_no" by auto
   258         from g[OF this]
   259         show ?thesis unfolding n_eq atLeastLessThanSuc_atLeastAtMost range_eq .
   260       qed
   261     }
   262     thus "\<exists> no. \<forall> n \<ge> no. norm (?Sa n - l) < r" by blast
   263   qed
   264   hence sums_l: "(\<lambda>i. (-1)^i * a i) sums l" unfolding sums_def atLeastLessThanSuc_atLeastAtMost[symmetric] .
   265   thus "summable ?S" using summable_def by auto
   266 
   267   have "l = suminf ?S" using sums_unique[OF sums_l] .
   268 
   269   { fix n show "suminf ?S \<le> ?g n" unfolding sums_unique[OF sums_l, symmetric] using above_l by auto }
   270   { fix n show "?f n \<le> suminf ?S" unfolding sums_unique[OF sums_l, symmetric] using below_l by auto }
   271   show "?g ----> suminf ?S" using `?g ----> l` `l = suminf ?S` by auto
   272   show "?f ----> suminf ?S" using `?f ----> l` `l = suminf ?S` by auto
   273 qed
   274 
   275 theorem summable_Leibniz: fixes a :: "nat \<Rightarrow> real"
   276   assumes a_zero: "a ----> 0" and "monoseq a"
   277   shows "summable (\<lambda> n. (-1)^n * a n)" (is "?summable")
   278   and "0 < a 0 \<longrightarrow> (\<forall>n. (\<Sum>i. -1^i*a i) \<in> { \<Sum>i=0..<2*n. -1^i * a i .. \<Sum>i=0..<2*n+1. -1^i * a i})" (is "?pos")
   279   and "a 0 < 0 \<longrightarrow> (\<forall>n. (\<Sum>i. -1^i*a i) \<in> { \<Sum>i=0..<2*n+1. -1^i * a i .. \<Sum>i=0..<2*n. -1^i * a i})" (is "?neg")
   280   and "(\<lambda>n. \<Sum>i=0..<2*n. -1^i*a i) ----> (\<Sum>i. -1^i*a i)" (is "?f")
   281   and "(\<lambda>n. \<Sum>i=0..<2*n+1. -1^i*a i) ----> (\<Sum>i. -1^i*a i)" (is "?g")
   282 proof -
   283   have "?summable \<and> ?pos \<and> ?neg \<and> ?f \<and> ?g"
   284   proof (cases "(\<forall> n. 0 \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m)")
   285     case True
   286     hence ord: "\<And>n m. m \<le> n \<Longrightarrow> a n \<le> a m" and ge0: "\<And> n. 0 \<le> a n" by auto
   287     { fix n have "a (Suc n) \<le> a n" using ord[where n="Suc n" and m=n] by auto }
   288     note leibniz = summable_Leibniz'[OF `a ----> 0` ge0] and mono = this
   289     from leibniz[OF mono]
   290     show ?thesis using `0 \<le> a 0` by auto
   291   next
   292     let ?a = "\<lambda> n. - a n"
   293     case False
   294     with monoseq_le[OF `monoseq a` `a ----> 0`]
   295     have "(\<forall> n. a n \<le> 0) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)" by auto
   296     hence ord: "\<And>n m. m \<le> n \<Longrightarrow> ?a n \<le> ?a m" and ge0: "\<And> n. 0 \<le> ?a n" by auto
   297     { fix n have "?a (Suc n) \<le> ?a n" using ord[where n="Suc n" and m=n] by auto }
   298     note monotone = this
   299     note leibniz = summable_Leibniz'[OF _ ge0, of "\<lambda>x. x", OF tendsto_minus[OF `a ----> 0`, unfolded minus_zero] monotone]
   300     have "summable (\<lambda> n. (-1)^n * ?a n)" using leibniz(1) by auto
   301     then obtain l where "(\<lambda> n. (-1)^n * ?a n) sums l" unfolding summable_def by auto
   302     from this[THEN sums_minus]
   303     have "(\<lambda> n. (-1)^n * a n) sums -l" by auto
   304     hence ?summable unfolding summable_def by auto
   305     moreover
   306     have "\<And> a b :: real. \<bar> - a - - b \<bar> = \<bar>a - b\<bar>" unfolding minus_diff_minus by auto
   307 
   308     from suminf_minus[OF leibniz(1), unfolded mult_minus_right minus_minus]
   309     have move_minus: "(\<Sum>n. - (-1 ^ n * a n)) = - (\<Sum>n. -1 ^ n * a n)" by auto
   310 
   311     have ?pos using `0 \<le> ?a 0` by auto
   312     moreover have ?neg using leibniz(2,4) unfolding mult_minus_right setsum_negf move_minus neg_le_iff_le by auto
   313     moreover have ?f and ?g using leibniz(3,5)[unfolded mult_minus_right setsum_negf move_minus, THEN tendsto_minus_cancel] by auto
   314     ultimately show ?thesis by auto
   315   qed
   316   from this[THEN conjunct1] this[THEN conjunct2, THEN conjunct1] this[THEN conjunct2, THEN conjunct2, THEN conjunct1] this[THEN conjunct2, THEN conjunct2, THEN conjunct2, THEN conjunct1]
   317        this[THEN conjunct2, THEN conjunct2, THEN conjunct2, THEN conjunct2]
   318   show ?summable and ?pos and ?neg and ?f and ?g .
   319 qed
   320 
   321 subsection {* Term-by-Term Differentiability of Power Series *}
   322 
   323 definition
   324   diffs :: "(nat => 'a::ring_1) => nat => 'a" where
   325   "diffs c = (%n. of_nat (Suc n) * c(Suc n))"
   326 
   327 text{*Lemma about distributing negation over it*}
   328 lemma diffs_minus: "diffs (%n. - c n) = (%n. - diffs c n)"
   329 by (simp add: diffs_def)
   330 
   331 lemma sums_Suc_imp:
   332   assumes f: "f 0 = 0"
   333   shows "(\<lambda>n. f (Suc n)) sums s \<Longrightarrow> (\<lambda>n. f n) sums s"
   334 unfolding sums_def
   335 apply (rule LIMSEQ_imp_Suc)
   336 apply (subst setsum_shift_lb_Suc0_0_upt [where f=f, OF f, symmetric])
   337 apply (simp only: setsum_shift_bounds_Suc_ivl)
   338 done
   339 
   340 lemma diffs_equiv:
   341   fixes x :: "'a::{real_normed_vector, ring_1}"
   342   shows "summable (%n. (diffs c)(n) * (x ^ n)) ==>
   343       (%n. of_nat n * c(n) * (x ^ (n - Suc 0))) sums
   344          (\<Sum>n. (diffs c)(n) * (x ^ n))"
   345 unfolding diffs_def
   346 apply (drule summable_sums)
   347 apply (rule sums_Suc_imp, simp_all)
   348 done
   349 
   350 lemma lemma_termdiff1:
   351   fixes z :: "'a :: {monoid_mult,comm_ring}" shows
   352   "(\<Sum>p=0..<m. (((z + h) ^ (m - p)) * (z ^ p)) - (z ^ m)) =
   353    (\<Sum>p=0..<m. (z ^ p) * (((z + h) ^ (m - p)) - (z ^ (m - p))))"
   354 by(auto simp add: algebra_simps power_add [symmetric])
   355 
   356 lemma sumr_diff_mult_const2:
   357   "setsum f {0..<n} - of_nat n * (r::'a::ring_1) = (\<Sum>i = 0..<n. f i - r)"
   358 by (simp add: setsum_subtractf)
   359 
   360 lemma lemma_termdiff2:
   361   fixes h :: "'a :: {field}"
   362   assumes h: "h \<noteq> 0" shows
   363   "((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0) =
   364    h * (\<Sum>p=0..< n - Suc 0. \<Sum>q=0..< n - Suc 0 - p.
   365         (z + h) ^ q * z ^ (n - 2 - q))" (is "?lhs = ?rhs")
   366 apply (subgoal_tac "h * ?lhs = h * ?rhs", simp add: h)
   367 apply (simp add: right_diff_distrib diff_divide_distrib h)
   368 apply (simp add: mult_assoc [symmetric])
   369 apply (cases "n", simp)
   370 apply (simp add: lemma_realpow_diff_sumr2 h
   371                  right_diff_distrib [symmetric] mult_assoc
   372             del: power_Suc setsum_op_ivl_Suc of_nat_Suc)
   373 apply (subst lemma_realpow_rev_sumr)
   374 apply (subst sumr_diff_mult_const2)
   375 apply simp
   376 apply (simp only: lemma_termdiff1 setsum_right_distrib)
   377 apply (rule setsum_cong [OF refl])
   378 apply (simp add: diff_minus [symmetric] less_iff_Suc_add)
   379 apply (clarify)
   380 apply (simp add: setsum_right_distrib lemma_realpow_diff_sumr2 mult_ac
   381             del: setsum_op_ivl_Suc power_Suc)
   382 apply (subst mult_assoc [symmetric], subst power_add [symmetric])
   383 apply (simp add: mult_ac)
   384 done
   385 
   386 lemma real_setsum_nat_ivl_bounded2:
   387   fixes K :: "'a::linordered_semidom"
   388   assumes f: "\<And>p::nat. p < n \<Longrightarrow> f p \<le> K"
   389   assumes K: "0 \<le> K"
   390   shows "setsum f {0..<n-k} \<le> of_nat n * K"
   391 apply (rule order_trans [OF setsum_mono])
   392 apply (rule f, simp)
   393 apply (simp add: mult_right_mono K)
   394 done
   395 
   396 lemma lemma_termdiff3:
   397   fixes h z :: "'a::{real_normed_field}"
   398   assumes 1: "h \<noteq> 0"
   399   assumes 2: "norm z \<le> K"
   400   assumes 3: "norm (z + h) \<le> K"
   401   shows "norm (((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0))
   402           \<le> of_nat n * of_nat (n - Suc 0) * K ^ (n - 2) * norm h"
   403 proof -
   404   have "norm (((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0)) =
   405         norm (\<Sum>p = 0..<n - Suc 0. \<Sum>q = 0..<n - Suc 0 - p.
   406           (z + h) ^ q * z ^ (n - 2 - q)) * norm h"
   407     apply (subst lemma_termdiff2 [OF 1])
   408     apply (subst norm_mult)
   409     apply (rule mult_commute)
   410     done
   411   also have "\<dots> \<le> of_nat n * (of_nat (n - Suc 0) * K ^ (n - 2)) * norm h"
   412   proof (rule mult_right_mono [OF _ norm_ge_zero])
   413     from norm_ge_zero 2 have K: "0 \<le> K" by (rule order_trans)
   414     have le_Kn: "\<And>i j n. i + j = n \<Longrightarrow> norm ((z + h) ^ i * z ^ j) \<le> K ^ n"
   415       apply (erule subst)
   416       apply (simp only: norm_mult norm_power power_add)
   417       apply (intro mult_mono power_mono 2 3 norm_ge_zero zero_le_power K)
   418       done
   419     show "norm (\<Sum>p = 0..<n - Suc 0. \<Sum>q = 0..<n - Suc 0 - p.
   420               (z + h) ^ q * z ^ (n - 2 - q))
   421           \<le> of_nat n * (of_nat (n - Suc 0) * K ^ (n - 2))"
   422       apply (intro
   423          order_trans [OF norm_setsum]
   424          real_setsum_nat_ivl_bounded2
   425          mult_nonneg_nonneg
   426          of_nat_0_le_iff
   427          zero_le_power K)
   428       apply (rule le_Kn, simp)
   429       done
   430   qed
   431   also have "\<dots> = of_nat n * of_nat (n - Suc 0) * K ^ (n - 2) * norm h"
   432     by (simp only: mult_assoc)
   433   finally show ?thesis .
   434 qed
   435 
   436 lemma lemma_termdiff4:
   437   fixes f :: "'a::{real_normed_field} \<Rightarrow>
   438               'b::real_normed_vector"
   439   assumes k: "0 < (k::real)"
   440   assumes le: "\<And>h. \<lbrakk>h \<noteq> 0; norm h < k\<rbrakk> \<Longrightarrow> norm (f h) \<le> K * norm h"
   441   shows "f -- 0 --> 0"
   442 unfolding LIM_eq diff_0_right
   443 proof (safe)
   444   let ?h = "of_real (k / 2)::'a"
   445   have "?h \<noteq> 0" and "norm ?h < k" using k by simp_all
   446   hence "norm (f ?h) \<le> K * norm ?h" by (rule le)
   447   hence "0 \<le> K * norm ?h" by (rule order_trans [OF norm_ge_zero])
   448   hence zero_le_K: "0 \<le> K" using k by (simp add: zero_le_mult_iff)
   449 
   450   fix r::real assume r: "0 < r"
   451   show "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)"
   452   proof (cases)
   453     assume "K = 0"
   454     with k r le have "0 < k \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < k \<longrightarrow> norm (f x) < r)"
   455       by simp
   456     thus "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)" ..
   457   next
   458     assume K_neq_zero: "K \<noteq> 0"
   459     with zero_le_K have K: "0 < K" by simp
   460     show "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)"
   461     proof (rule exI, safe)
   462       from k r K show "0 < min k (r * inverse K / 2)"
   463         by (simp add: mult_pos_pos positive_imp_inverse_positive)
   464     next
   465       fix x::'a
   466       assume x1: "x \<noteq> 0" and x2: "norm x < min k (r * inverse K / 2)"
   467       from x2 have x3: "norm x < k" and x4: "norm x < r * inverse K / 2"
   468         by simp_all
   469       from x1 x3 le have "norm (f x) \<le> K * norm x" by simp
   470       also from x4 K have "K * norm x < K * (r * inverse K / 2)"
   471         by (rule mult_strict_left_mono)
   472       also have "\<dots> = r / 2"
   473         using K_neq_zero by simp
   474       also have "r / 2 < r"
   475         using r by simp
   476       finally show "norm (f x) < r" .
   477     qed
   478   qed
   479 qed
   480 
   481 lemma lemma_termdiff5:
   482   fixes g :: "'a::{real_normed_field} \<Rightarrow>
   483               nat \<Rightarrow> 'b::banach"
   484   assumes k: "0 < (k::real)"
   485   assumes f: "summable f"
   486   assumes le: "\<And>h n. \<lbrakk>h \<noteq> 0; norm h < k\<rbrakk> \<Longrightarrow> norm (g h n) \<le> f n * norm h"
   487   shows "(\<lambda>h. suminf (g h)) -- 0 --> 0"
   488 proof (rule lemma_termdiff4 [OF k])
   489   fix h::'a assume "h \<noteq> 0" and "norm h < k"
   490   hence A: "\<forall>n. norm (g h n) \<le> f n * norm h"
   491     by (simp add: le)
   492   hence "\<exists>N. \<forall>n\<ge>N. norm (norm (g h n)) \<le> f n * norm h"
   493     by simp
   494   moreover from f have B: "summable (\<lambda>n. f n * norm h)"
   495     by (rule summable_mult2)
   496   ultimately have C: "summable (\<lambda>n. norm (g h n))"
   497     by (rule summable_comparison_test)
   498   hence "norm (suminf (g h)) \<le> (\<Sum>n. norm (g h n))"
   499     by (rule summable_norm)
   500   also from A C B have "(\<Sum>n. norm (g h n)) \<le> (\<Sum>n. f n * norm h)"
   501     by (rule summable_le)
   502   also from f have "(\<Sum>n. f n * norm h) = suminf f * norm h"
   503     by (rule suminf_mult2 [symmetric])
   504   finally show "norm (suminf (g h)) \<le> suminf f * norm h" .
   505 qed
   506 
   507 
   508 text{* FIXME: Long proofs*}
   509 
   510 lemma termdiffs_aux:
   511   fixes x :: "'a::{real_normed_field,banach}"
   512   assumes 1: "summable (\<lambda>n. diffs (diffs c) n * K ^ n)"
   513   assumes 2: "norm x < norm K"
   514   shows "(\<lambda>h. \<Sum>n. c n * (((x + h) ^ n - x ^ n) / h
   515              - of_nat n * x ^ (n - Suc 0))) -- 0 --> 0"
   516 proof -
   517   from dense [OF 2]
   518   obtain r where r1: "norm x < r" and r2: "r < norm K" by fast
   519   from norm_ge_zero r1 have r: "0 < r"
   520     by (rule order_le_less_trans)
   521   hence r_neq_0: "r \<noteq> 0" by simp
   522   show ?thesis
   523   proof (rule lemma_termdiff5)
   524     show "0 < r - norm x" using r1 by simp
   525   next
   526     from r r2 have "norm (of_real r::'a) < norm K"
   527       by simp
   528     with 1 have "summable (\<lambda>n. norm (diffs (diffs c) n * (of_real r ^ n)))"
   529       by (rule powser_insidea)
   530     hence "summable (\<lambda>n. diffs (diffs (\<lambda>n. norm (c n))) n * r ^ n)"
   531       using r
   532       by (simp add: diffs_def norm_mult norm_power del: of_nat_Suc)
   533     hence "summable (\<lambda>n. of_nat n * diffs (\<lambda>n. norm (c n)) n * r ^ (n - Suc 0))"
   534       by (rule diffs_equiv [THEN sums_summable])
   535     also have "(\<lambda>n. of_nat n * diffs (\<lambda>n. norm (c n)) n * r ^ (n - Suc 0))
   536       = (\<lambda>n. diffs (%m. of_nat (m - Suc 0) * norm (c m) * inverse r) n * (r ^ n))"
   537       apply (rule ext)
   538       apply (simp add: diffs_def)
   539       apply (case_tac n, simp_all add: r_neq_0)
   540       done
   541     finally have "summable
   542       (\<lambda>n. of_nat n * (of_nat (n - Suc 0) * norm (c n) * inverse r) * r ^ (n - Suc 0))"
   543       by (rule diffs_equiv [THEN sums_summable])
   544     also have
   545       "(\<lambda>n. of_nat n * (of_nat (n - Suc 0) * norm (c n) * inverse r) *
   546            r ^ (n - Suc 0)) =
   547        (\<lambda>n. norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2))"
   548       apply (rule ext)
   549       apply (case_tac "n", simp)
   550       apply (case_tac "nat", simp)
   551       apply (simp add: r_neq_0)
   552       done
   553     finally show
   554       "summable (\<lambda>n. norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2))" .
   555   next
   556     fix h::'a and n::nat
   557     assume h: "h \<noteq> 0"
   558     assume "norm h < r - norm x"
   559     hence "norm x + norm h < r" by simp
   560     with norm_triangle_ineq have xh: "norm (x + h) < r"
   561       by (rule order_le_less_trans)
   562     show "norm (c n * (((x + h) ^ n - x ^ n) / h - of_nat n * x ^ (n - Suc 0)))
   563           \<le> norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2) * norm h"
   564       apply (simp only: norm_mult mult_assoc)
   565       apply (rule mult_left_mono [OF _ norm_ge_zero])
   566       apply (simp (no_asm) add: mult_assoc [symmetric])
   567       apply (rule lemma_termdiff3)
   568       apply (rule h)
   569       apply (rule r1 [THEN order_less_imp_le])
   570       apply (rule xh [THEN order_less_imp_le])
   571       done
   572   qed
   573 qed
   574 
   575 lemma termdiffs:
   576   fixes K x :: "'a::{real_normed_field,banach}"
   577   assumes 1: "summable (\<lambda>n. c n * K ^ n)"
   578   assumes 2: "summable (\<lambda>n. (diffs c) n * K ^ n)"
   579   assumes 3: "summable (\<lambda>n. (diffs (diffs c)) n * K ^ n)"
   580   assumes 4: "norm x < norm K"
   581   shows "DERIV (\<lambda>x. \<Sum>n. c n * x ^ n) x :> (\<Sum>n. (diffs c) n * x ^ n)"
   582 unfolding deriv_def
   583 proof (rule LIM_zero_cancel)
   584   show "(\<lambda>h. (suminf (\<lambda>n. c n * (x + h) ^ n) - suminf (\<lambda>n. c n * x ^ n)) / h
   585             - suminf (\<lambda>n. diffs c n * x ^ n)) -- 0 --> 0"
   586   proof (rule LIM_equal2)
   587     show "0 < norm K - norm x" using 4 by (simp add: less_diff_eq)
   588   next
   589     fix h :: 'a
   590     assume "h \<noteq> 0"
   591     assume "norm (h - 0) < norm K - norm x"
   592     hence "norm x + norm h < norm K" by simp
   593     hence 5: "norm (x + h) < norm K"
   594       by (rule norm_triangle_ineq [THEN order_le_less_trans])
   595     have A: "summable (\<lambda>n. c n * x ^ n)"
   596       by (rule powser_inside [OF 1 4])
   597     have B: "summable (\<lambda>n. c n * (x + h) ^ n)"
   598       by (rule powser_inside [OF 1 5])
   599     have C: "summable (\<lambda>n. diffs c n * x ^ n)"
   600       by (rule powser_inside [OF 2 4])
   601     show "((\<Sum>n. c n * (x + h) ^ n) - (\<Sum>n. c n * x ^ n)) / h
   602              - (\<Sum>n. diffs c n * x ^ n) =
   603           (\<Sum>n. c n * (((x + h) ^ n - x ^ n) / h - of_nat n * x ^ (n - Suc 0)))"
   604       apply (subst sums_unique [OF diffs_equiv [OF C]])
   605       apply (subst suminf_diff [OF B A])
   606       apply (subst suminf_divide [symmetric])
   607       apply (rule summable_diff [OF B A])
   608       apply (subst suminf_diff)
   609       apply (rule summable_divide)
   610       apply (rule summable_diff [OF B A])
   611       apply (rule sums_summable [OF diffs_equiv [OF C]])
   612       apply (rule arg_cong [where f="suminf"], rule ext)
   613       apply (simp add: algebra_simps)
   614       done
   615   next
   616     show "(\<lambda>h. \<Sum>n. c n * (((x + h) ^ n - x ^ n) / h -
   617                of_nat n * x ^ (n - Suc 0))) -- 0 --> 0"
   618         by (rule termdiffs_aux [OF 3 4])
   619   qed
   620 qed
   621 
   622 
   623 subsection {* Derivability of power series *}
   624 
   625 lemma DERIV_series': fixes f :: "real \<Rightarrow> nat \<Rightarrow> real"
   626   assumes DERIV_f: "\<And> n. DERIV (\<lambda> x. f x n) x0 :> (f' x0 n)"
   627   and allf_summable: "\<And> x. x \<in> {a <..< b} \<Longrightarrow> summable (f x)" and x0_in_I: "x0 \<in> {a <..< b}"
   628   and "summable (f' x0)"
   629   and "summable L" and L_def: "\<And> n x y. \<lbrakk> x \<in> { a <..< b} ; y \<in> { a <..< b} \<rbrakk> \<Longrightarrow> \<bar> f x n - f y n \<bar> \<le> L n * \<bar> x - y \<bar>"
   630   shows "DERIV (\<lambda> x. suminf (f x)) x0 :> (suminf (f' x0))"
   631   unfolding deriv_def
   632 proof (rule LIM_I)
   633   fix r :: real assume "0 < r" hence "0 < r/3" by auto
   634 
   635   obtain N_L where N_L: "\<And> n. N_L \<le> n \<Longrightarrow> \<bar> \<Sum> i. L (i + n) \<bar> < r/3"
   636     using suminf_exist_split[OF `0 < r/3` `summable L`] by auto
   637 
   638   obtain N_f' where N_f': "\<And> n. N_f' \<le> n \<Longrightarrow> \<bar> \<Sum> i. f' x0 (i + n) \<bar> < r/3"
   639     using suminf_exist_split[OF `0 < r/3` `summable (f' x0)`] by auto
   640 
   641   let ?N = "Suc (max N_L N_f')"
   642   have "\<bar> \<Sum> i. f' x0 (i + ?N) \<bar> < r/3" (is "?f'_part < r/3") and
   643     L_estimate: "\<bar> \<Sum> i. L (i + ?N) \<bar> < r/3" using N_L[of "?N"] and N_f' [of "?N"] by auto
   644 
   645   let "?diff i x" = "(f (x0 + x) i - f x0 i) / x"
   646 
   647   let ?r = "r / (3 * real ?N)"
   648   have "0 < 3 * real ?N" by auto
   649   from divide_pos_pos[OF `0 < r` this]
   650   have "0 < ?r" .
   651 
   652   let "?s n" = "SOME s. 0 < s \<and> (\<forall> x. x \<noteq> 0 \<and> \<bar> x \<bar> < s \<longrightarrow> \<bar> ?diff n x - f' x0 n \<bar> < ?r)"
   653   def S' \<equiv> "Min (?s ` { 0 ..< ?N })"
   654 
   655   have "0 < S'" unfolding S'_def
   656   proof (rule iffD2[OF Min_gr_iff])
   657     show "\<forall> x \<in> (?s ` { 0 ..< ?N }). 0 < x"
   658     proof (rule ballI)
   659       fix x assume "x \<in> ?s ` {0..<?N}"
   660       then obtain n where "x = ?s n" and "n \<in> {0..<?N}" using image_iff[THEN iffD1] by blast
   661       from DERIV_D[OF DERIV_f[where n=n], THEN LIM_D, OF `0 < ?r`, unfolded real_norm_def]
   662       obtain s where s_bound: "0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> \<bar>x\<bar> < s \<longrightarrow> \<bar>?diff n x - f' x0 n\<bar> < ?r)" by auto
   663       have "0 < ?s n" by (rule someI2[where a=s], auto simp add: s_bound)
   664       thus "0 < x" unfolding `x = ?s n` .
   665     qed
   666   qed auto
   667 
   668   def S \<equiv> "min (min (x0 - a) (b - x0)) S'"
   669   hence "0 < S" and S_a: "S \<le> x0 - a" and S_b: "S \<le> b - x0" and "S \<le> S'" using x0_in_I and `0 < S'`
   670     by auto
   671 
   672   { fix x assume "x \<noteq> 0" and "\<bar> x \<bar> < S"
   673     hence x_in_I: "x0 + x \<in> { a <..< b }" using S_a S_b by auto
   674 
   675     note diff_smbl = summable_diff[OF allf_summable[OF x_in_I] allf_summable[OF x0_in_I]]
   676     note div_smbl = summable_divide[OF diff_smbl]
   677     note all_smbl = summable_diff[OF div_smbl `summable (f' x0)`]
   678     note ign = summable_ignore_initial_segment[where k="?N"]
   679     note diff_shft_smbl = summable_diff[OF ign[OF allf_summable[OF x_in_I]] ign[OF allf_summable[OF x0_in_I]]]
   680     note div_shft_smbl = summable_divide[OF diff_shft_smbl]
   681     note all_shft_smbl = summable_diff[OF div_smbl ign[OF `summable (f' x0)`]]
   682 
   683     { fix n
   684       have "\<bar> ?diff (n + ?N) x \<bar> \<le> L (n + ?N) * \<bar> (x0 + x) - x0 \<bar> / \<bar> x \<bar>"
   685         using divide_right_mono[OF L_def[OF x_in_I x0_in_I] abs_ge_zero] unfolding abs_divide .
   686       hence "\<bar> ( \<bar> ?diff (n + ?N) x \<bar>) \<bar> \<le> L (n + ?N)" using `x \<noteq> 0` by auto
   687     } note L_ge = summable_le2[OF allI[OF this] ign[OF `summable L`]]
   688     from order_trans[OF summable_rabs[OF conjunct1[OF L_ge]] L_ge[THEN conjunct2]]
   689     have "\<bar> \<Sum> i. ?diff (i + ?N) x \<bar> \<le> (\<Sum> i. L (i + ?N))" .
   690     hence "\<bar> \<Sum> i. ?diff (i + ?N) x \<bar> \<le> r / 3" (is "?L_part \<le> r/3") using L_estimate by auto
   691 
   692     have "\<bar>\<Sum>n \<in> { 0 ..< ?N}. ?diff n x - f' x0 n \<bar> \<le> (\<Sum>n \<in> { 0 ..< ?N}. \<bar>?diff n x - f' x0 n \<bar>)" ..
   693     also have "\<dots> < (\<Sum>n \<in> { 0 ..< ?N}. ?r)"
   694     proof (rule setsum_strict_mono)
   695       fix n assume "n \<in> { 0 ..< ?N}"
   696       have "\<bar> x \<bar> < S" using `\<bar> x \<bar> < S` .
   697       also have "S \<le> S'" using `S \<le> S'` .
   698       also have "S' \<le> ?s n" unfolding S'_def
   699       proof (rule Min_le_iff[THEN iffD2])
   700         have "?s n \<in> (?s ` {0..<?N}) \<and> ?s n \<le> ?s n" using `n \<in> { 0 ..< ?N}` by auto
   701         thus "\<exists> a \<in> (?s ` {0..<?N}). a \<le> ?s n" by blast
   702       qed auto
   703       finally have "\<bar> x \<bar> < ?s n" .
   704 
   705       from DERIV_D[OF DERIV_f[where n=n], THEN LIM_D, OF `0 < ?r`, unfolded real_norm_def diff_0_right, unfolded some_eq_ex[symmetric], THEN conjunct2]
   706       have "\<forall>x. x \<noteq> 0 \<and> \<bar>x\<bar> < ?s n \<longrightarrow> \<bar>?diff n x - f' x0 n\<bar> < ?r" .
   707       with `x \<noteq> 0` and `\<bar>x\<bar> < ?s n`
   708       show "\<bar>?diff n x - f' x0 n\<bar> < ?r" by blast
   709     qed auto
   710     also have "\<dots> = of_nat (card {0 ..< ?N}) * ?r" by (rule setsum_constant)
   711     also have "\<dots> = real ?N * ?r" unfolding real_eq_of_nat by auto
   712     also have "\<dots> = r/3" by auto
   713     finally have "\<bar>\<Sum>n \<in> { 0 ..< ?N}. ?diff n x - f' x0 n \<bar> < r / 3" (is "?diff_part < r / 3") .
   714 
   715     from suminf_diff[OF allf_summable[OF x_in_I] allf_summable[OF x0_in_I]]
   716     have "\<bar> (suminf (f (x0 + x)) - (suminf (f x0))) / x - suminf (f' x0) \<bar> =
   717                     \<bar> \<Sum>n. ?diff n x - f' x0 n \<bar>" unfolding suminf_diff[OF div_smbl `summable (f' x0)`, symmetric] using suminf_divide[OF diff_smbl, symmetric] by auto
   718     also have "\<dots> \<le> ?diff_part + \<bar> (\<Sum>n. ?diff (n + ?N) x) - (\<Sum> n. f' x0 (n + ?N)) \<bar>" unfolding suminf_split_initial_segment[OF all_smbl, where k="?N"] unfolding suminf_diff[OF div_shft_smbl ign[OF `summable (f' x0)`]] by (rule abs_triangle_ineq)
   719     also have "\<dots> \<le> ?diff_part + ?L_part + ?f'_part" using abs_triangle_ineq4 by auto
   720     also have "\<dots> < r /3 + r/3 + r/3"
   721       using `?diff_part < r/3` `?L_part \<le> r/3` and `?f'_part < r/3`
   722       by (rule add_strict_mono [OF add_less_le_mono])
   723     finally have "\<bar> (suminf (f (x0 + x)) - (suminf (f x0))) / x - suminf (f' x0) \<bar> < r"
   724       by auto
   725   } thus "\<exists> s > 0. \<forall> x. x \<noteq> 0 \<and> norm (x - 0) < s \<longrightarrow>
   726       norm (((\<Sum>n. f (x0 + x) n) - (\<Sum>n. f x0 n)) / x - (\<Sum>n. f' x0 n)) < r" using `0 < S`
   727     unfolding real_norm_def diff_0_right by blast
   728 qed
   729 
   730 lemma DERIV_power_series': fixes f :: "nat \<Rightarrow> real"
   731   assumes converges: "\<And> x. x \<in> {-R <..< R} \<Longrightarrow> summable (\<lambda> n. f n * real (Suc n) * x^n)"
   732   and x0_in_I: "x0 \<in> {-R <..< R}" and "0 < R"
   733   shows "DERIV (\<lambda> x. (\<Sum> n. f n * x^(Suc n))) x0 :> (\<Sum> n. f n * real (Suc n) * x0^n)"
   734   (is "DERIV (\<lambda> x. (suminf (?f x))) x0 :> (suminf (?f' x0))")
   735 proof -
   736   { fix R' assume "0 < R'" and "R' < R" and "-R' < x0" and "x0 < R'"
   737     hence "x0 \<in> {-R' <..< R'}" and "R' \<in> {-R <..< R}" and "x0 \<in> {-R <..< R}" by auto
   738     have "DERIV (\<lambda> x. (suminf (?f x))) x0 :> (suminf (?f' x0))"
   739     proof (rule DERIV_series')
   740       show "summable (\<lambda> n. \<bar>f n * real (Suc n) * R'^n\<bar>)"
   741       proof -
   742         have "(R' + R) / 2 < R" and "0 < (R' + R) / 2" using `0 < R'` `0 < R` `R' < R` by auto
   743         hence in_Rball: "(R' + R) / 2 \<in> {-R <..< R}" using `R' < R` by auto
   744         have "norm R' < norm ((R' + R) / 2)" using `0 < R'` `0 < R` `R' < R` by auto
   745         from powser_insidea[OF converges[OF in_Rball] this] show ?thesis by auto
   746       qed
   747       { fix n x y assume "x \<in> {-R' <..< R'}" and "y \<in> {-R' <..< R'}"
   748         show "\<bar>?f x n - ?f y n\<bar> \<le> \<bar>f n * real (Suc n) * R'^n\<bar> * \<bar>x-y\<bar>"
   749         proof -
   750           have "\<bar>f n * x ^ (Suc n) - f n * y ^ (Suc n)\<bar> = (\<bar>f n\<bar> * \<bar>x-y\<bar>) * \<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar>"
   751             unfolding right_diff_distrib[symmetric] lemma_realpow_diff_sumr2 abs_mult by auto
   752           also have "\<dots> \<le> (\<bar>f n\<bar> * \<bar>x-y\<bar>) * (\<bar>real (Suc n)\<bar> * \<bar>R' ^ n\<bar>)"
   753           proof (rule mult_left_mono)
   754             have "\<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar> \<le> (\<Sum>p = 0..<Suc n. \<bar>x ^ p * y ^ (n - p)\<bar>)" by (rule setsum_abs)
   755             also have "\<dots> \<le> (\<Sum>p = 0..<Suc n. R' ^ n)"
   756             proof (rule setsum_mono)
   757               fix p assume "p \<in> {0..<Suc n}" hence "p \<le> n" by auto
   758               { fix n fix x :: real assume "x \<in> {-R'<..<R'}"
   759                 hence "\<bar>x\<bar> \<le> R'"  by auto
   760                 hence "\<bar>x^n\<bar> \<le> R'^n" unfolding power_abs by (rule power_mono, auto)
   761               } from mult_mono[OF this[OF `x \<in> {-R'<..<R'}`, of p] this[OF `y \<in> {-R'<..<R'}`, of "n-p"]] `0 < R'`
   762               have "\<bar>x^p * y^(n-p)\<bar> \<le> R'^p * R'^(n-p)" unfolding abs_mult by auto
   763               thus "\<bar>x^p * y^(n-p)\<bar> \<le> R'^n" unfolding power_add[symmetric] using `p \<le> n` by auto
   764             qed
   765             also have "\<dots> = real (Suc n) * R' ^ n" unfolding setsum_constant card_atLeastLessThan real_of_nat_def by auto
   766             finally show "\<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar> \<le> \<bar>real (Suc n)\<bar> * \<bar>R' ^ n\<bar>" unfolding abs_real_of_nat_cancel abs_of_nonneg[OF zero_le_power[OF less_imp_le[OF `0 < R'`]]] .
   767             show "0 \<le> \<bar>f n\<bar> * \<bar>x - y\<bar>" unfolding abs_mult[symmetric] by auto
   768           qed
   769           also have "\<dots> = \<bar>f n * real (Suc n) * R' ^ n\<bar> * \<bar>x - y\<bar>" unfolding abs_mult mult_assoc[symmetric] by algebra
   770           finally show ?thesis .
   771         qed }
   772       { fix n show "DERIV (\<lambda> x. ?f x n) x0 :> (?f' x0 n)"
   773           by (auto intro!: DERIV_intros simp del: power_Suc) }
   774       { fix x assume "x \<in> {-R' <..< R'}" hence "R' \<in> {-R <..< R}" and "norm x < norm R'" using assms `R' < R` by auto
   775         have "summable (\<lambda> n. f n * x^n)"
   776         proof (rule summable_le2[THEN conjunct1, OF _ powser_insidea[OF converges[OF `R' \<in> {-R <..< R}`] `norm x < norm R'`]], rule allI)
   777           fix n
   778           have le: "\<bar>f n\<bar> * 1 \<le> \<bar>f n\<bar> * real (Suc n)" by (rule mult_left_mono, auto)
   779           show "\<bar>f n * x ^ n\<bar> \<le> norm (f n * real (Suc n) * x ^ n)" unfolding real_norm_def abs_mult
   780             by (rule mult_right_mono, auto simp add: le[unfolded mult_1_right])
   781         qed
   782         from this[THEN summable_mult2[where c=x], unfolded mult_assoc, unfolded mult_commute]
   783         show "summable (?f x)" by auto }
   784       show "summable (?f' x0)" using converges[OF `x0 \<in> {-R <..< R}`] .
   785       show "x0 \<in> {-R' <..< R'}" using `x0 \<in> {-R' <..< R'}` .
   786     qed
   787   } note for_subinterval = this
   788   let ?R = "(R + \<bar>x0\<bar>) / 2"
   789   have "\<bar>x0\<bar> < ?R" using assms by auto
   790   hence "- ?R < x0"
   791   proof (cases "x0 < 0")
   792     case True
   793     hence "- x0 < ?R" using `\<bar>x0\<bar> < ?R` by auto
   794     thus ?thesis unfolding neg_less_iff_less[symmetric, of "- x0"] by auto
   795   next
   796     case False
   797     have "- ?R < 0" using assms by auto
   798     also have "\<dots> \<le> x0" using False by auto
   799     finally show ?thesis .
   800   qed
   801   hence "0 < ?R" "?R < R" "- ?R < x0" and "x0 < ?R" using assms by auto
   802   from for_subinterval[OF this]
   803   show ?thesis .
   804 qed
   805 
   806 subsection {* Exponential Function *}
   807 
   808 definition exp :: "'a \<Rightarrow> 'a::{real_normed_field,banach}" where
   809   "exp = (\<lambda>x. \<Sum>n. x ^ n /\<^sub>R real (fact n))"
   810 
   811 lemma summable_exp_generic:
   812   fixes x :: "'a::{real_normed_algebra_1,banach}"
   813   defines S_def: "S \<equiv> \<lambda>n. x ^ n /\<^sub>R real (fact n)"
   814   shows "summable S"
   815 proof -
   816   have S_Suc: "\<And>n. S (Suc n) = (x * S n) /\<^sub>R real (Suc n)"
   817     unfolding S_def by (simp del: mult_Suc)
   818   obtain r :: real where r0: "0 < r" and r1: "r < 1"
   819     using dense [OF zero_less_one] by fast
   820   obtain N :: nat where N: "norm x < real N * r"
   821     using reals_Archimedean3 [OF r0] by fast
   822   from r1 show ?thesis
   823   proof (rule ratio_test [rule_format])
   824     fix n :: nat
   825     assume n: "N \<le> n"
   826     have "norm x \<le> real N * r"
   827       using N by (rule order_less_imp_le)
   828     also have "real N * r \<le> real (Suc n) * r"
   829       using r0 n by (simp add: mult_right_mono)
   830     finally have "norm x * norm (S n) \<le> real (Suc n) * r * norm (S n)"
   831       using norm_ge_zero by (rule mult_right_mono)
   832     hence "norm (x * S n) \<le> real (Suc n) * r * norm (S n)"
   833       by (rule order_trans [OF norm_mult_ineq])
   834     hence "norm (x * S n) / real (Suc n) \<le> r * norm (S n)"
   835       by (simp add: pos_divide_le_eq mult_ac)
   836     thus "norm (S (Suc n)) \<le> r * norm (S n)"
   837       by (simp add: S_Suc inverse_eq_divide)
   838   qed
   839 qed
   840 
   841 lemma summable_norm_exp:
   842   fixes x :: "'a::{real_normed_algebra_1,banach}"
   843   shows "summable (\<lambda>n. norm (x ^ n /\<^sub>R real (fact n)))"
   844 proof (rule summable_norm_comparison_test [OF exI, rule_format])
   845   show "summable (\<lambda>n. norm x ^ n /\<^sub>R real (fact n))"
   846     by (rule summable_exp_generic)
   847 next
   848   fix n show "norm (x ^ n /\<^sub>R real (fact n)) \<le> norm x ^ n /\<^sub>R real (fact n)"
   849     by (simp add: norm_power_ineq)
   850 qed
   851 
   852 lemma summable_exp: "summable (%n. inverse (real (fact n)) * x ^ n)"
   853 by (insert summable_exp_generic [where x=x], simp)
   854 
   855 lemma exp_converges: "(\<lambda>n. x ^ n /\<^sub>R real (fact n)) sums exp x"
   856 unfolding exp_def by (rule summable_exp_generic [THEN summable_sums])
   857 
   858 
   859 lemma exp_fdiffs:
   860       "diffs (%n. inverse(real (fact n))) = (%n. inverse(real (fact n)))"
   861 by (simp add: diffs_def mult_assoc [symmetric] real_of_nat_def of_nat_mult
   862          del: mult_Suc of_nat_Suc)
   863 
   864 lemma diffs_of_real: "diffs (\<lambda>n. of_real (f n)) = (\<lambda>n. of_real (diffs f n))"
   865 by (simp add: diffs_def)
   866 
   867 lemma DERIV_exp [simp]: "DERIV exp x :> exp(x)"
   868 unfolding exp_def scaleR_conv_of_real
   869 apply (rule DERIV_cong)
   870 apply (rule termdiffs [where K="of_real (1 + norm x)"])
   871 apply (simp_all only: diffs_of_real scaleR_conv_of_real exp_fdiffs)
   872 apply (rule exp_converges [THEN sums_summable, unfolded scaleR_conv_of_real])+
   873 apply (simp del: of_real_add)
   874 done
   875 
   876 declare DERIV_exp[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
   877 
   878 lemma isCont_exp: "isCont exp x"
   879   by (rule DERIV_exp [THEN DERIV_isCont])
   880 
   881 lemma isCont_exp' [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. exp (f x)) a"
   882   by (rule isCont_o2 [OF _ isCont_exp])
   883 
   884 lemma tendsto_exp [tendsto_intros]:
   885   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. exp (f x)) ---> exp a) F"
   886   by (rule isCont_tendsto_compose [OF isCont_exp])
   887 
   888 lemma continuous_exp [continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. exp (f x))"
   889   unfolding continuous_def by (rule tendsto_exp)
   890 
   891 lemma continuous_on_exp [continuous_on_intros]: "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. exp (f x))"
   892   unfolding continuous_on_def by (auto intro: tendsto_exp)
   893 
   894 subsubsection {* Properties of the Exponential Function *}
   895 
   896 lemma powser_zero:
   897   fixes f :: "nat \<Rightarrow> 'a::{real_normed_algebra_1}"
   898   shows "(\<Sum>n. f n * 0 ^ n) = f 0"
   899 proof -
   900   have "(\<Sum>n = 0..<1. f n * 0 ^ n) = (\<Sum>n. f n * 0 ^ n)"
   901     by (rule sums_unique [OF series_zero], simp add: power_0_left)
   902   thus ?thesis unfolding One_nat_def by simp
   903 qed
   904 
   905 lemma exp_zero [simp]: "exp 0 = 1"
   906 unfolding exp_def by (simp add: scaleR_conv_of_real powser_zero)
   907 
   908 lemma setsum_cl_ivl_Suc2:
   909   "(\<Sum>i=m..Suc n. f i) = (if Suc n < m then 0 else f m + (\<Sum>i=m..n. f (Suc i)))"
   910 by (simp add: setsum_head_Suc setsum_shift_bounds_cl_Suc_ivl
   911          del: setsum_cl_ivl_Suc)
   912 
   913 lemma exp_series_add:
   914   fixes x y :: "'a::{real_field}"
   915   defines S_def: "S \<equiv> \<lambda>x n. x ^ n /\<^sub>R real (fact n)"
   916   shows "S (x + y) n = (\<Sum>i=0..n. S x i * S y (n - i))"
   917 proof (induct n)
   918   case 0
   919   show ?case
   920     unfolding S_def by simp
   921 next
   922   case (Suc n)
   923   have S_Suc: "\<And>x n. S x (Suc n) = (x * S x n) /\<^sub>R real (Suc n)"
   924     unfolding S_def by (simp del: mult_Suc)
   925   hence times_S: "\<And>x n. x * S x n = real (Suc n) *\<^sub>R S x (Suc n)"
   926     by simp
   927 
   928   have "real (Suc n) *\<^sub>R S (x + y) (Suc n) = (x + y) * S (x + y) n"
   929     by (simp only: times_S)
   930   also have "\<dots> = (x + y) * (\<Sum>i=0..n. S x i * S y (n-i))"
   931     by (simp only: Suc)
   932   also have "\<dots> = x * (\<Sum>i=0..n. S x i * S y (n-i))
   933                 + y * (\<Sum>i=0..n. S x i * S y (n-i))"
   934     by (rule distrib_right)
   935   also have "\<dots> = (\<Sum>i=0..n. (x * S x i) * S y (n-i))
   936                 + (\<Sum>i=0..n. S x i * (y * S y (n-i)))"
   937     by (simp only: setsum_right_distrib mult_ac)
   938   also have "\<dots> = (\<Sum>i=0..n. real (Suc i) *\<^sub>R (S x (Suc i) * S y (n-i)))
   939                 + (\<Sum>i=0..n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i)))"
   940     by (simp add: times_S Suc_diff_le)
   941   also have "(\<Sum>i=0..n. real (Suc i) *\<^sub>R (S x (Suc i) * S y (n-i))) =
   942              (\<Sum>i=0..Suc n. real i *\<^sub>R (S x i * S y (Suc n-i)))"
   943     by (subst setsum_cl_ivl_Suc2, simp)
   944   also have "(\<Sum>i=0..n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i))) =
   945              (\<Sum>i=0..Suc n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i)))"
   946     by (subst setsum_cl_ivl_Suc, simp)
   947   also have "(\<Sum>i=0..Suc n. real i *\<^sub>R (S x i * S y (Suc n-i))) +
   948              (\<Sum>i=0..Suc n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i))) =
   949              (\<Sum>i=0..Suc n. real (Suc n) *\<^sub>R (S x i * S y (Suc n-i)))"
   950     by (simp only: setsum_addf [symmetric] scaleR_left_distrib [symmetric]
   951               real_of_nat_add [symmetric], simp)
   952   also have "\<dots> = real (Suc n) *\<^sub>R (\<Sum>i=0..Suc n. S x i * S y (Suc n-i))"
   953     by (simp only: scaleR_right.setsum)
   954   finally show
   955     "S (x + y) (Suc n) = (\<Sum>i=0..Suc n. S x i * S y (Suc n - i))"
   956     by (simp del: setsum_cl_ivl_Suc)
   957 qed
   958 
   959 lemma exp_add: "exp (x + y) = exp x * exp y"
   960 unfolding exp_def
   961 by (simp only: Cauchy_product summable_norm_exp exp_series_add)
   962 
   963 lemma mult_exp_exp: "exp x * exp y = exp (x + y)"
   964 by (rule exp_add [symmetric])
   965 
   966 lemma exp_of_real: "exp (of_real x) = of_real (exp x)"
   967 unfolding exp_def
   968 apply (subst suminf_of_real)
   969 apply (rule summable_exp_generic)
   970 apply (simp add: scaleR_conv_of_real)
   971 done
   972 
   973 lemma exp_not_eq_zero [simp]: "exp x \<noteq> 0"
   974 proof
   975   have "exp x * exp (- x) = 1" by (simp add: mult_exp_exp)
   976   also assume "exp x = 0"
   977   finally show "False" by simp
   978 qed
   979 
   980 lemma exp_minus: "exp (- x) = inverse (exp x)"
   981 by (rule inverse_unique [symmetric], simp add: mult_exp_exp)
   982 
   983 lemma exp_diff: "exp (x - y) = exp x / exp y"
   984   unfolding diff_minus divide_inverse
   985   by (simp add: exp_add exp_minus)
   986 
   987 
   988 subsubsection {* Properties of the Exponential Function on Reals *}
   989 
   990 text {* Comparisons of @{term "exp x"} with zero. *}
   991 
   992 text{*Proof: because every exponential can be seen as a square.*}
   993 lemma exp_ge_zero [simp]: "0 \<le> exp (x::real)"
   994 proof -
   995   have "0 \<le> exp (x/2) * exp (x/2)" by simp
   996   thus ?thesis by (simp add: exp_add [symmetric])
   997 qed
   998 
   999 lemma exp_gt_zero [simp]: "0 < exp (x::real)"
  1000 by (simp add: order_less_le)
  1001 
  1002 lemma not_exp_less_zero [simp]: "\<not> exp (x::real) < 0"
  1003 by (simp add: not_less)
  1004 
  1005 lemma not_exp_le_zero [simp]: "\<not> exp (x::real) \<le> 0"
  1006 by (simp add: not_le)
  1007 
  1008 lemma abs_exp_cancel [simp]: "\<bar>exp x::real\<bar> = exp x"
  1009 by simp
  1010 
  1011 lemma exp_real_of_nat_mult: "exp(real n * x) = exp(x) ^ n"
  1012 apply (induct "n")
  1013 apply (auto simp add: real_of_nat_Suc distrib_left exp_add mult_commute)
  1014 done
  1015 
  1016 text {* Strict monotonicity of exponential. *}
  1017 
  1018 lemma exp_ge_add_one_self_aux: "0 \<le> (x::real) ==> (1 + x) \<le> exp(x)"
  1019 apply (drule order_le_imp_less_or_eq, auto)
  1020 apply (simp add: exp_def)
  1021 apply (rule order_trans)
  1022 apply (rule_tac [2] n = 2 and f = "(%n. inverse (real (fact n)) * x ^ n)" in series_pos_le)
  1023 apply (auto intro: summable_exp simp add: numeral_2_eq_2 zero_le_mult_iff)
  1024 done
  1025 
  1026 lemma exp_gt_one: "0 < (x::real) \<Longrightarrow> 1 < exp x"
  1027 proof -
  1028   assume x: "0 < x"
  1029   hence "1 < 1 + x" by simp
  1030   also from x have "1 + x \<le> exp x"
  1031     by (simp add: exp_ge_add_one_self_aux)
  1032   finally show ?thesis .
  1033 qed
  1034 
  1035 lemma exp_less_mono:
  1036   fixes x y :: real
  1037   assumes "x < y" shows "exp x < exp y"
  1038 proof -
  1039   from `x < y` have "0 < y - x" by simp
  1040   hence "1 < exp (y - x)" by (rule exp_gt_one)
  1041   hence "1 < exp y / exp x" by (simp only: exp_diff)
  1042   thus "exp x < exp y" by simp
  1043 qed
  1044 
  1045 lemma exp_less_cancel: "exp (x::real) < exp y ==> x < y"
  1046 apply (simp add: linorder_not_le [symmetric])
  1047 apply (auto simp add: order_le_less exp_less_mono)
  1048 done
  1049 
  1050 lemma exp_less_cancel_iff [iff]: "exp (x::real) < exp y \<longleftrightarrow> x < y"
  1051 by (auto intro: exp_less_mono exp_less_cancel)
  1052 
  1053 lemma exp_le_cancel_iff [iff]: "exp (x::real) \<le> exp y \<longleftrightarrow> x \<le> y"
  1054 by (auto simp add: linorder_not_less [symmetric])
  1055 
  1056 lemma exp_inj_iff [iff]: "exp (x::real) = exp y \<longleftrightarrow> x = y"
  1057 by (simp add: order_eq_iff)
  1058 
  1059 text {* Comparisons of @{term "exp x"} with one. *}
  1060 
  1061 lemma one_less_exp_iff [simp]: "1 < exp (x::real) \<longleftrightarrow> 0 < x"
  1062   using exp_less_cancel_iff [where x=0 and y=x] by simp
  1063 
  1064 lemma exp_less_one_iff [simp]: "exp (x::real) < 1 \<longleftrightarrow> x < 0"
  1065   using exp_less_cancel_iff [where x=x and y=0] by simp
  1066 
  1067 lemma one_le_exp_iff [simp]: "1 \<le> exp (x::real) \<longleftrightarrow> 0 \<le> x"
  1068   using exp_le_cancel_iff [where x=0 and y=x] by simp
  1069 
  1070 lemma exp_le_one_iff [simp]: "exp (x::real) \<le> 1 \<longleftrightarrow> x \<le> 0"
  1071   using exp_le_cancel_iff [where x=x and y=0] by simp
  1072 
  1073 lemma exp_eq_one_iff [simp]: "exp (x::real) = 1 \<longleftrightarrow> x = 0"
  1074   using exp_inj_iff [where x=x and y=0] by simp
  1075 
  1076 lemma lemma_exp_total: "1 \<le> y ==> \<exists>x. 0 \<le> x & x \<le> y - 1 & exp(x::real) = y"
  1077 proof (rule IVT)
  1078   assume "1 \<le> y"
  1079   hence "0 \<le> y - 1" by simp
  1080   hence "1 + (y - 1) \<le> exp (y - 1)" by (rule exp_ge_add_one_self_aux)
  1081   thus "y \<le> exp (y - 1)" by simp
  1082 qed (simp_all add: le_diff_eq)
  1083 
  1084 lemma exp_total: "0 < (y::real) ==> \<exists>x. exp x = y"
  1085 proof (rule linorder_le_cases [of 1 y])
  1086   assume "1 \<le> y" thus "\<exists>x. exp x = y"
  1087     by (fast dest: lemma_exp_total)
  1088 next
  1089   assume "0 < y" and "y \<le> 1"
  1090   hence "1 \<le> inverse y" by (simp add: one_le_inverse_iff)
  1091   then obtain x where "exp x = inverse y" by (fast dest: lemma_exp_total)
  1092   hence "exp (- x) = y" by (simp add: exp_minus)
  1093   thus "\<exists>x. exp x = y" ..
  1094 qed
  1095 
  1096 
  1097 subsection {* Natural Logarithm *}
  1098 
  1099 definition ln :: "real \<Rightarrow> real" where
  1100   "ln x = (THE u. exp u = x)"
  1101 
  1102 lemma ln_exp [simp]: "ln (exp x) = x"
  1103   by (simp add: ln_def)
  1104 
  1105 lemma exp_ln [simp]: "0 < x \<Longrightarrow> exp (ln x) = x"
  1106   by (auto dest: exp_total)
  1107 
  1108 lemma exp_ln_iff [simp]: "exp (ln x) = x \<longleftrightarrow> 0 < x"
  1109   by (metis exp_gt_zero exp_ln)
  1110 
  1111 lemma ln_unique: "exp y = x \<Longrightarrow> ln x = y"
  1112   by (erule subst, rule ln_exp)
  1113 
  1114 lemma ln_one [simp]: "ln 1 = 0"
  1115   by (rule ln_unique, simp)
  1116 
  1117 lemma ln_mult: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln (x * y) = ln x + ln y"
  1118   by (rule ln_unique, simp add: exp_add)
  1119 
  1120 lemma ln_inverse: "0 < x \<Longrightarrow> ln (inverse x) = - ln x"
  1121   by (rule ln_unique, simp add: exp_minus)
  1122 
  1123 lemma ln_div: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln (x / y) = ln x - ln y"
  1124   by (rule ln_unique, simp add: exp_diff)
  1125 
  1126 lemma ln_realpow: "0 < x \<Longrightarrow> ln (x ^ n) = real n * ln x"
  1127   by (rule ln_unique, simp add: exp_real_of_nat_mult)
  1128 
  1129 lemma ln_less_cancel_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x < ln y \<longleftrightarrow> x < y"
  1130   by (subst exp_less_cancel_iff [symmetric], simp)
  1131 
  1132 lemma ln_le_cancel_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x \<le> ln y \<longleftrightarrow> x \<le> y"
  1133   by (simp add: linorder_not_less [symmetric])
  1134 
  1135 lemma ln_inj_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x = ln y \<longleftrightarrow> x = y"
  1136   by (simp add: order_eq_iff)
  1137 
  1138 lemma ln_add_one_self_le_self [simp]: "0 \<le> x \<Longrightarrow> ln (1 + x) \<le> x"
  1139   apply (rule exp_le_cancel_iff [THEN iffD1])
  1140   apply (simp add: exp_ge_add_one_self_aux)
  1141   done
  1142 
  1143 lemma ln_less_self [simp]: "0 < x \<Longrightarrow> ln x < x"
  1144   by (rule order_less_le_trans [where y="ln (1 + x)"]) simp_all
  1145 
  1146 lemma ln_ge_zero [simp]: "1 \<le> x \<Longrightarrow> 0 \<le> ln x"
  1147   using ln_le_cancel_iff [of 1 x] by simp
  1148 
  1149 lemma ln_ge_zero_imp_ge_one: "\<lbrakk>0 \<le> ln x; 0 < x\<rbrakk> \<Longrightarrow> 1 \<le> x"
  1150   using ln_le_cancel_iff [of 1 x] by simp
  1151 
  1152 lemma ln_ge_zero_iff [simp]: "0 < x \<Longrightarrow> (0 \<le> ln x) = (1 \<le> x)"
  1153   using ln_le_cancel_iff [of 1 x] by simp
  1154 
  1155 lemma ln_less_zero_iff [simp]: "0 < x \<Longrightarrow> (ln x < 0) = (x < 1)"
  1156   using ln_less_cancel_iff [of x 1] by simp
  1157 
  1158 lemma ln_gt_zero: "1 < x \<Longrightarrow> 0 < ln x"
  1159   using ln_less_cancel_iff [of 1 x] by simp
  1160 
  1161 lemma ln_gt_zero_imp_gt_one: "\<lbrakk>0 < ln x; 0 < x\<rbrakk> \<Longrightarrow> 1 < x"
  1162   using ln_less_cancel_iff [of 1 x] by simp
  1163 
  1164 lemma ln_gt_zero_iff [simp]: "0 < x \<Longrightarrow> (0 < ln x) = (1 < x)"
  1165   using ln_less_cancel_iff [of 1 x] by simp
  1166 
  1167 lemma ln_eq_zero_iff [simp]: "0 < x \<Longrightarrow> (ln x = 0) = (x = 1)"
  1168   using ln_inj_iff [of x 1] by simp
  1169 
  1170 lemma ln_less_zero: "\<lbrakk>0 < x; x < 1\<rbrakk> \<Longrightarrow> ln x < 0"
  1171   by simp
  1172 
  1173 lemma isCont_ln: "0 < x \<Longrightarrow> isCont ln x"
  1174   apply (subgoal_tac "isCont ln (exp (ln x))", simp)
  1175   apply (rule isCont_inverse_function [where f=exp], simp_all)
  1176   done
  1177 
  1178 lemma tendsto_ln [tendsto_intros]:
  1179   "\<lbrakk>(f ---> a) F; 0 < a\<rbrakk> \<Longrightarrow> ((\<lambda>x. ln (f x)) ---> ln a) F"
  1180   by (rule isCont_tendsto_compose [OF isCont_ln])
  1181 
  1182 lemma continuous_ln:
  1183   "continuous F f \<Longrightarrow> 0 < f (Lim F (\<lambda>x. x)) \<Longrightarrow> continuous F (\<lambda>x. ln (f x))"
  1184   unfolding continuous_def by (rule tendsto_ln)
  1185 
  1186 lemma isCont_ln' [continuous_intros]:
  1187   "continuous (at x) f \<Longrightarrow> 0 < f x \<Longrightarrow> continuous (at x) (\<lambda>x. ln (f x))"
  1188   unfolding continuous_at by (rule tendsto_ln)
  1189 
  1190 lemma continuous_within_ln [continuous_intros]:
  1191   "continuous (at x within s) f \<Longrightarrow> 0 < f x \<Longrightarrow> continuous (at x within s) (\<lambda>x. ln (f x))"
  1192   unfolding continuous_within by (rule tendsto_ln)
  1193 
  1194 lemma continuous_on_ln [continuous_on_intros]:
  1195   "continuous_on s f \<Longrightarrow> (\<forall>x\<in>s. 0 < f x) \<Longrightarrow> continuous_on s (\<lambda>x. ln (f x))"
  1196   unfolding continuous_on_def by (auto intro: tendsto_ln)
  1197 
  1198 lemma DERIV_ln: "0 < x \<Longrightarrow> DERIV ln x :> inverse x"
  1199   apply (rule DERIV_inverse_function [where f=exp and a=0 and b="x+1"])
  1200   apply (erule DERIV_cong [OF DERIV_exp exp_ln])
  1201   apply (simp_all add: abs_if isCont_ln)
  1202   done
  1203 
  1204 lemma DERIV_ln_divide: "0 < x ==> DERIV ln x :> 1 / x"
  1205   by (rule DERIV_ln[THEN DERIV_cong], simp, simp add: divide_inverse)
  1206 
  1207 declare DERIV_ln_divide[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1208 
  1209 lemma ln_series: assumes "0 < x" and "x < 2"
  1210   shows "ln x = (\<Sum> n. (-1)^n * (1 / real (n + 1)) * (x - 1)^(Suc n))" (is "ln x = suminf (?f (x - 1))")
  1211 proof -
  1212   let "?f' x n" = "(-1)^n * (x - 1)^n"
  1213 
  1214   have "ln x - suminf (?f (x - 1)) = ln 1 - suminf (?f (1 - 1))"
  1215   proof (rule DERIV_isconst3[where x=x])
  1216     fix x :: real assume "x \<in> {0 <..< 2}" hence "0 < x" and "x < 2" by auto
  1217     have "norm (1 - x) < 1" using `0 < x` and `x < 2` by auto
  1218     have "1 / x = 1 / (1 - (1 - x))" by auto
  1219     also have "\<dots> = (\<Sum> n. (1 - x)^n)" using geometric_sums[OF `norm (1 - x) < 1`] by (rule sums_unique)
  1220     also have "\<dots> = suminf (?f' x)" unfolding power_mult_distrib[symmetric] by (rule arg_cong[where f=suminf], rule arg_cong[where f="op ^"], auto)
  1221     finally have "DERIV ln x :> suminf (?f' x)" using DERIV_ln[OF `0 < x`] unfolding divide_inverse by auto
  1222     moreover
  1223     have repos: "\<And> h x :: real. h - 1 + x = h + x - 1" by auto
  1224     have "DERIV (\<lambda>x. suminf (?f x)) (x - 1) :> (\<Sum>n. (-1)^n * (1 / real (n + 1)) * real (Suc n) * (x - 1) ^ n)"
  1225     proof (rule DERIV_power_series')
  1226       show "x - 1 \<in> {- 1<..<1}" and "(0 :: real) < 1" using `0 < x` `x < 2` by auto
  1227       { fix x :: real assume "x \<in> {- 1<..<1}" hence "norm (-x) < 1" by auto
  1228         show "summable (\<lambda>n. -1 ^ n * (1 / real (n + 1)) * real (Suc n) * x ^ n)"
  1229           unfolding One_nat_def
  1230           by (auto simp add: power_mult_distrib[symmetric] summable_geometric[OF `norm (-x) < 1`])
  1231       }
  1232     qed
  1233     hence "DERIV (\<lambda>x. suminf (?f x)) (x - 1) :> suminf (?f' x)" unfolding One_nat_def by auto
  1234     hence "DERIV (\<lambda>x. suminf (?f (x - 1))) x :> suminf (?f' x)" unfolding DERIV_iff repos .
  1235     ultimately have "DERIV (\<lambda>x. ln x - suminf (?f (x - 1))) x :> (suminf (?f' x) - suminf (?f' x))"
  1236       by (rule DERIV_diff)
  1237     thus "DERIV (\<lambda>x. ln x - suminf (?f (x - 1))) x :> 0" by auto
  1238   qed (auto simp add: assms)
  1239   thus ?thesis by auto
  1240 qed
  1241 
  1242 lemma exp_first_two_terms: "exp x = 1 + x + (\<Sum> n. inverse(fact (n+2)) * (x ^ (n+2)))"
  1243 proof -
  1244   have "exp x = suminf (%n. inverse(fact n) * (x ^ n))"
  1245     by (simp add: exp_def)
  1246   also from summable_exp have "... = (\<Sum> n::nat = 0 ..< 2. inverse(fact n) * (x ^ n)) +
  1247       (\<Sum> n. inverse(fact(n+2)) * (x ^ (n+2)))" (is "_ = ?a + _")
  1248     by (rule suminf_split_initial_segment)
  1249   also have "?a = 1 + x"
  1250     by (simp add: numeral_2_eq_2)
  1251   finally show ?thesis .
  1252 qed
  1253 
  1254 lemma exp_bound: "0 <= (x::real) ==> x <= 1 ==> exp x <= 1 + x + x^2"
  1255 proof -
  1256   assume a: "0 <= x"
  1257   assume b: "x <= 1"
  1258   { fix n :: nat
  1259     have "2 * 2 ^ n \<le> fact (n + 2)"
  1260       by (induct n, simp, simp)
  1261     hence "real ((2::nat) * 2 ^ n) \<le> real (fact (n + 2))"
  1262       by (simp only: real_of_nat_le_iff)
  1263     hence "2 * 2 ^ n \<le> real (fact (n + 2))"
  1264       by simp
  1265     hence "inverse (fact (n + 2)) \<le> inverse (2 * 2 ^ n)"
  1266       by (rule le_imp_inverse_le) simp
  1267     hence "inverse (fact (n + 2)) \<le> 1/2 * (1/2)^n"
  1268       by (simp add: inverse_mult_distrib power_inverse)
  1269     hence "inverse (fact (n + 2)) * (x^n * x\<twosuperior>) \<le> 1/2 * (1/2)^n * (1 * x\<twosuperior>)"
  1270       by (rule mult_mono)
  1271         (rule mult_mono, simp_all add: power_le_one a b mult_nonneg_nonneg)
  1272     hence "inverse (fact (n + 2)) * x ^ (n + 2) \<le> (x\<twosuperior>/2) * ((1/2)^n)"
  1273       unfolding power_add by (simp add: mult_ac del: fact_Suc) }
  1274   note aux1 = this
  1275   have "(\<lambda>n. x\<twosuperior> / 2 * (1 / 2) ^ n) sums (x\<twosuperior> / 2 * (1 / (1 - 1 / 2)))"
  1276     by (intro sums_mult geometric_sums, simp)
  1277   hence aux2: "(\<lambda>n. (x::real) ^ 2 / 2 * (1 / 2) ^ n) sums x^2"
  1278     by simp
  1279   have "suminf (%n. inverse(fact (n+2)) * (x ^ (n+2))) <= x^2"
  1280   proof -
  1281     have "suminf (%n. inverse(fact (n+2)) * (x ^ (n+2))) <=
  1282         suminf (%n. (x^2/2) * ((1/2)^n))"
  1283       apply (rule summable_le)
  1284       apply (rule allI, rule aux1)
  1285       apply (rule summable_exp [THEN summable_ignore_initial_segment])
  1286       by (rule sums_summable, rule aux2)
  1287     also have "... = x^2"
  1288       by (rule sums_unique [THEN sym], rule aux2)
  1289     finally show ?thesis .
  1290   qed
  1291   thus ?thesis unfolding exp_first_two_terms by auto
  1292 qed
  1293 
  1294 lemma ln_one_minus_pos_upper_bound: "0 <= x ==> x < 1 ==> ln (1 - x) <= - x"
  1295 proof -
  1296   assume a: "0 <= (x::real)" and b: "x < 1"
  1297   have "(1 - x) * (1 + x + x^2) = (1 - x^3)"
  1298     by (simp add: algebra_simps power2_eq_square power3_eq_cube)
  1299   also have "... <= 1"
  1300     by (auto simp add: a)
  1301   finally have "(1 - x) * (1 + x + x ^ 2) <= 1" .
  1302   moreover have c: "0 < 1 + x + x\<twosuperior>"
  1303     by (simp add: add_pos_nonneg a)
  1304   ultimately have "1 - x <= 1 / (1 + x + x^2)"
  1305     by (elim mult_imp_le_div_pos)
  1306   also have "... <= 1 / exp x"
  1307     apply (rule divide_left_mono)
  1308     apply (rule exp_bound, rule a)
  1309     apply (rule b [THEN less_imp_le])
  1310     apply simp
  1311     apply (rule mult_pos_pos)
  1312     apply (rule c)
  1313     apply simp
  1314     done
  1315   also have "... = exp (-x)"
  1316     by (auto simp add: exp_minus divide_inverse)
  1317   finally have "1 - x <= exp (- x)" .
  1318   also have "1 - x = exp (ln (1 - x))"
  1319   proof -
  1320     have "0 < 1 - x"
  1321       by (insert b, auto)
  1322     thus ?thesis
  1323       by (auto simp only: exp_ln_iff [THEN sym])
  1324   qed
  1325   finally have "exp (ln (1 - x)) <= exp (- x)" .
  1326   thus ?thesis by (auto simp only: exp_le_cancel_iff)
  1327 qed
  1328 
  1329 lemma exp_ge_add_one_self [simp]: "1 + (x::real) <= exp x"
  1330   apply (case_tac "0 <= x")
  1331   apply (erule exp_ge_add_one_self_aux)
  1332   apply (case_tac "x <= -1")
  1333   apply (subgoal_tac "1 + x <= 0")
  1334   apply (erule order_trans)
  1335   apply simp
  1336   apply simp
  1337   apply (subgoal_tac "1 + x = exp(ln (1 + x))")
  1338   apply (erule ssubst)
  1339   apply (subst exp_le_cancel_iff)
  1340   apply (subgoal_tac "ln (1 - (- x)) <= - (- x)")
  1341   apply simp
  1342   apply (rule ln_one_minus_pos_upper_bound)
  1343   apply auto
  1344 done
  1345 
  1346 lemma ln_one_plus_pos_lower_bound: "0 <= x ==> x <= 1 ==> x - x^2 <= ln (1 + x)"
  1347 proof -
  1348   assume a: "0 <= x" and b: "x <= 1"
  1349   have "exp (x - x^2) = exp x / exp (x^2)"
  1350     by (rule exp_diff)
  1351   also have "... <= (1 + x + x^2) / exp (x ^2)"
  1352     apply (rule divide_right_mono) 
  1353     apply (rule exp_bound)
  1354     apply (rule a, rule b)
  1355     apply simp
  1356     done
  1357   also have "... <= (1 + x + x^2) / (1 + x^2)"
  1358     apply (rule divide_left_mono)
  1359     apply (simp add: exp_ge_add_one_self_aux)
  1360     apply (simp add: a)
  1361     apply (simp add: mult_pos_pos add_pos_nonneg)
  1362     done
  1363   also from a have "... <= 1 + x"
  1364     by (simp add: field_simps add_strict_increasing zero_le_mult_iff)
  1365   finally have "exp (x - x^2) <= 1 + x" .
  1366   also have "... = exp (ln (1 + x))"
  1367   proof -
  1368     from a have "0 < 1 + x" by auto
  1369     thus ?thesis
  1370       by (auto simp only: exp_ln_iff [THEN sym])
  1371   qed
  1372   finally have "exp (x - x ^ 2) <= exp (ln (1 + x))" .
  1373   thus ?thesis by (auto simp only: exp_le_cancel_iff)
  1374 qed
  1375 
  1376 lemma aux5: "x < 1 ==> ln(1 - x) = - ln(1 + x / (1 - x))"
  1377 proof -
  1378   assume a: "x < 1"
  1379   have "ln(1 - x) = - ln(1 / (1 - x))"
  1380   proof -
  1381     have "ln(1 - x) = - (- ln (1 - x))"
  1382       by auto
  1383     also have "- ln(1 - x) = ln 1 - ln(1 - x)"
  1384       by simp
  1385     also have "... = ln(1 / (1 - x))"
  1386       apply (rule ln_div [THEN sym])
  1387       by (insert a, auto)
  1388     finally show ?thesis .
  1389   qed
  1390   also have " 1 / (1 - x) = 1 + x / (1 - x)" using a by(simp add:field_simps)
  1391   finally show ?thesis .
  1392 qed
  1393 
  1394 lemma ln_one_minus_pos_lower_bound: "0 <= x ==> x <= (1 / 2) ==> 
  1395     - x - 2 * x^2 <= ln (1 - x)"
  1396 proof -
  1397   assume a: "0 <= x" and b: "x <= (1 / 2)"
  1398   from b have c: "x < 1"
  1399     by auto
  1400   then have "ln (1 - x) = - ln (1 + x / (1 - x))"
  1401     by (rule aux5)
  1402   also have "- (x / (1 - x)) <= ..."
  1403   proof - 
  1404     have "ln (1 + x / (1 - x)) <= x / (1 - x)"
  1405       apply (rule ln_add_one_self_le_self)
  1406       apply (rule divide_nonneg_pos)
  1407       by (insert a c, auto) 
  1408     thus ?thesis
  1409       by auto
  1410   qed
  1411   also have "- (x / (1 - x)) = -x / (1 - x)"
  1412     by auto
  1413   finally have d: "- x / (1 - x) <= ln (1 - x)" .
  1414   have "0 < 1 - x" using a b by simp
  1415   hence e: "-x - 2 * x^2 <= - x / (1 - x)"
  1416     using mult_right_le_one_le[of "x*x" "2*x"] a b
  1417     by (simp add:field_simps power2_eq_square)
  1418   from e d show "- x - 2 * x^2 <= ln (1 - x)"
  1419     by (rule order_trans)
  1420 qed
  1421 
  1422 lemma ln_add_one_self_le_self2: "-1 < x ==> ln(1 + x) <= x"
  1423   apply (subgoal_tac "ln (1 + x) \<le> ln (exp x)", simp)
  1424   apply (subst ln_le_cancel_iff)
  1425   apply auto
  1426 done
  1427 
  1428 lemma abs_ln_one_plus_x_minus_x_bound_nonneg:
  1429     "0 <= x ==> x <= 1 ==> abs(ln (1 + x) - x) <= x^2"
  1430 proof -
  1431   assume x: "0 <= x"
  1432   assume x1: "x <= 1"
  1433   from x have "ln (1 + x) <= x"
  1434     by (rule ln_add_one_self_le_self)
  1435   then have "ln (1 + x) - x <= 0" 
  1436     by simp
  1437   then have "abs(ln(1 + x) - x) = - (ln(1 + x) - x)"
  1438     by (rule abs_of_nonpos)
  1439   also have "... = x - ln (1 + x)" 
  1440     by simp
  1441   also have "... <= x^2"
  1442   proof -
  1443     from x x1 have "x - x^2 <= ln (1 + x)"
  1444       by (intro ln_one_plus_pos_lower_bound)
  1445     thus ?thesis
  1446       by simp
  1447   qed
  1448   finally show ?thesis .
  1449 qed
  1450 
  1451 lemma abs_ln_one_plus_x_minus_x_bound_nonpos:
  1452     "-(1 / 2) <= x ==> x <= 0 ==> abs(ln (1 + x) - x) <= 2 * x^2"
  1453 proof -
  1454   assume a: "-(1 / 2) <= x"
  1455   assume b: "x <= 0"
  1456   have "abs(ln (1 + x) - x) = x - ln(1 - (-x))" 
  1457     apply (subst abs_of_nonpos)
  1458     apply simp
  1459     apply (rule ln_add_one_self_le_self2)
  1460     using a apply auto
  1461     done
  1462   also have "... <= 2 * x^2"
  1463     apply (subgoal_tac "- (-x) - 2 * (-x)^2 <= ln (1 - (-x))")
  1464     apply (simp add: algebra_simps)
  1465     apply (rule ln_one_minus_pos_lower_bound)
  1466     using a b apply auto
  1467     done
  1468   finally show ?thesis .
  1469 qed
  1470 
  1471 lemma abs_ln_one_plus_x_minus_x_bound:
  1472     "abs x <= 1 / 2 ==> abs(ln (1 + x) - x) <= 2 * x^2"
  1473   apply (case_tac "0 <= x")
  1474   apply (rule order_trans)
  1475   apply (rule abs_ln_one_plus_x_minus_x_bound_nonneg)
  1476   apply auto
  1477   apply (rule abs_ln_one_plus_x_minus_x_bound_nonpos)
  1478   apply auto
  1479 done
  1480 
  1481 lemma ln_x_over_x_mono: "exp 1 <= x ==> x <= y ==> (ln y / y) <= (ln x / x)"  
  1482 proof -
  1483   assume x: "exp 1 <= x" "x <= y"
  1484   moreover have "0 < exp (1::real)" by simp
  1485   ultimately have a: "0 < x" and b: "0 < y"
  1486     by (fast intro: less_le_trans order_trans)+
  1487   have "x * ln y - x * ln x = x * (ln y - ln x)"
  1488     by (simp add: algebra_simps)
  1489   also have "... = x * ln(y / x)"
  1490     by (simp only: ln_div a b)
  1491   also have "y / x = (x + (y - x)) / x"
  1492     by simp
  1493   also have "... = 1 + (y - x) / x"
  1494     using x a by (simp add: field_simps)
  1495   also have "x * ln(1 + (y - x) / x) <= x * ((y - x) / x)"
  1496     apply (rule mult_left_mono)
  1497     apply (rule ln_add_one_self_le_self)
  1498     apply (rule divide_nonneg_pos)
  1499     using x a apply simp_all
  1500     done
  1501   also have "... = y - x" using a by simp
  1502   also have "... = (y - x) * ln (exp 1)" by simp
  1503   also have "... <= (y - x) * ln x"
  1504     apply (rule mult_left_mono)
  1505     apply (subst ln_le_cancel_iff)
  1506     apply fact
  1507     apply (rule a)
  1508     apply (rule x)
  1509     using x apply simp
  1510     done
  1511   also have "... = y * ln x - x * ln x"
  1512     by (rule left_diff_distrib)
  1513   finally have "x * ln y <= y * ln x"
  1514     by arith
  1515   then have "ln y <= (y * ln x) / x" using a by (simp add: field_simps)
  1516   also have "... = y * (ln x / x)" by simp
  1517   finally show ?thesis using b by (simp add: field_simps)
  1518 qed
  1519 
  1520 lemma ln_le_minus_one:
  1521   "0 < x \<Longrightarrow> ln x \<le> x - 1"
  1522   using exp_ge_add_one_self[of "ln x"] by simp
  1523 
  1524 lemma ln_eq_minus_one:
  1525   assumes "0 < x" "ln x = x - 1" shows "x = 1"
  1526 proof -
  1527   let "?l y" = "ln y - y + 1"
  1528   have D: "\<And>x. 0 < x \<Longrightarrow> DERIV ?l x :> (1 / x - 1)"
  1529     by (auto intro!: DERIV_intros)
  1530 
  1531   show ?thesis
  1532   proof (cases rule: linorder_cases)
  1533     assume "x < 1"
  1534     from dense[OF `x < 1`] obtain a where "x < a" "a < 1" by blast
  1535     from `x < a` have "?l x < ?l a"
  1536     proof (rule DERIV_pos_imp_increasing, safe)
  1537       fix y assume "x \<le> y" "y \<le> a"
  1538       with `0 < x` `a < 1` have "0 < 1 / y - 1" "0 < y"
  1539         by (auto simp: field_simps)
  1540       with D show "\<exists>z. DERIV ?l y :> z \<and> 0 < z"
  1541         by auto
  1542     qed
  1543     also have "\<dots> \<le> 0"
  1544       using ln_le_minus_one `0 < x` `x < a` by (auto simp: field_simps)
  1545     finally show "x = 1" using assms by auto
  1546   next
  1547     assume "1 < x"
  1548     from dense[OF `1 < x`] obtain a where "1 < a" "a < x" by blast
  1549     from `a < x` have "?l x < ?l a"
  1550     proof (rule DERIV_neg_imp_decreasing, safe)
  1551       fix y assume "a \<le> y" "y \<le> x"
  1552       with `1 < a` have "1 / y - 1 < 0" "0 < y"
  1553         by (auto simp: field_simps)
  1554       with D show "\<exists>z. DERIV ?l y :> z \<and> z < 0"
  1555         by blast
  1556     qed
  1557     also have "\<dots> \<le> 0"
  1558       using ln_le_minus_one `1 < a` by (auto simp: field_simps)
  1559     finally show "x = 1" using assms by auto
  1560   qed simp
  1561 qed
  1562 
  1563 lemma exp_at_bot: "(exp ---> (0::real)) at_bot"
  1564   unfolding tendsto_Zfun_iff
  1565 proof (rule ZfunI, simp add: eventually_at_bot_dense)
  1566   fix r :: real assume "0 < r"
  1567   { fix x assume "x < ln r"
  1568     then have "exp x < exp (ln r)"
  1569       by simp
  1570     with `0 < r` have "exp x < r"
  1571       by simp }
  1572   then show "\<exists>k. \<forall>n<k. exp n < r" by auto
  1573 qed
  1574 
  1575 lemma exp_at_top: "LIM x at_top. exp x :: real :> at_top"
  1576   by (rule filterlim_at_top_at_top[where Q="\<lambda>x. True" and P="\<lambda>x. 0 < x" and g="ln"])
  1577      (auto intro: eventually_gt_at_top)
  1578 
  1579 lemma ln_at_0: "LIM x at_right 0. ln x :> at_bot"
  1580   by (rule filterlim_at_bot_at_right[where Q="\<lambda>x. 0 < x" and P="\<lambda>x. True" and g="exp"])
  1581      (auto simp: eventually_at_filter)
  1582 
  1583 lemma ln_at_top: "LIM x at_top. ln x :> at_top"
  1584   by (rule filterlim_at_top_at_top[where Q="\<lambda>x. 0 < x" and P="\<lambda>x. True" and g="exp"])
  1585      (auto intro: eventually_gt_at_top)
  1586 
  1587 lemma tendsto_power_div_exp_0: "((\<lambda>x. x ^ k / exp x) ---> (0::real)) at_top"
  1588 proof (induct k)
  1589   show "((\<lambda>x. x ^ 0 / exp x) ---> (0::real)) at_top"
  1590     by (simp add: inverse_eq_divide[symmetric])
  1591        (metis filterlim_compose[OF tendsto_inverse_0] exp_at_top filterlim_mono
  1592               at_top_le_at_infinity order_refl)
  1593 next
  1594   case (Suc k)
  1595   show ?case
  1596   proof (rule lhospital_at_top_at_top)
  1597     show "eventually (\<lambda>x. DERIV (\<lambda>x. x ^ Suc k) x :> (real (Suc k) * x^k)) at_top"
  1598       by eventually_elim (intro DERIV_intros, simp, simp)
  1599     show "eventually (\<lambda>x. DERIV exp x :> exp x) at_top"
  1600       by eventually_elim (auto intro!: DERIV_intros)
  1601     show "eventually (\<lambda>x. exp x \<noteq> 0) at_top"
  1602       by auto
  1603     from tendsto_mult[OF tendsto_const Suc, of "real (Suc k)"]
  1604     show "((\<lambda>x. real (Suc k) * x ^ k / exp x) ---> 0) at_top"
  1605       by simp
  1606   qed (rule exp_at_top)
  1607 qed
  1608 
  1609 
  1610 definition
  1611   powr  :: "[real,real] => real"     (infixr "powr" 80) where
  1612     --{*exponentation with real exponent*}
  1613   "x powr a = exp(a * ln x)"
  1614 
  1615 definition
  1616   log :: "[real,real] => real" where
  1617     --{*logarithm of @{term x} to base @{term a}*}
  1618   "log a x = ln x / ln a"
  1619 
  1620 
  1621 lemma tendsto_log [tendsto_intros]:
  1622   "\<lbrakk>(f ---> a) F; (g ---> b) F; 0 < a; a \<noteq> 1; 0 < b\<rbrakk> \<Longrightarrow> ((\<lambda>x. log (f x) (g x)) ---> log a b) F"
  1623   unfolding log_def by (intro tendsto_intros) auto
  1624 
  1625 lemma continuous_log:
  1626   assumes "continuous F f" and "continuous F g" and "0 < f (Lim F (\<lambda>x. x))" and "f (Lim F (\<lambda>x. x)) \<noteq> 1" and "0 < g (Lim F (\<lambda>x. x))"
  1627   shows "continuous F (\<lambda>x. log (f x) (g x))"
  1628   using assms unfolding continuous_def by (rule tendsto_log)
  1629 
  1630 lemma continuous_at_within_log[continuous_intros]:
  1631   assumes "continuous (at a within s) f" "continuous (at a within s) g" and "0 < f a" and "f a \<noteq> 1" and "0 < g a"
  1632   shows "continuous (at a within s) (\<lambda>x. log (f x) (g x))"
  1633   using assms unfolding continuous_within by (rule tendsto_log)
  1634 
  1635 lemma isCont_log[continuous_intros, simp]:
  1636   assumes "isCont f a" "isCont g a" "0 < f a" "f a \<noteq> 1" "0 < g a"
  1637   shows "isCont (\<lambda>x. log (f x) (g x)) a"
  1638   using assms unfolding continuous_at by (rule tendsto_log)
  1639 
  1640 lemma continuous_on_log[continuous_on_intros]:
  1641   assumes "continuous_on s f" "continuous_on s g" and "\<forall>x\<in>s. 0 < f x" "\<forall>x\<in>s. f x \<noteq> 1" "\<forall>x\<in>s. 0 < g x"
  1642   shows "continuous_on s (\<lambda>x. log (f x) (g x))"
  1643   using assms unfolding continuous_on_def by (fast intro: tendsto_log)
  1644 
  1645 lemma powr_one_eq_one [simp]: "1 powr a = 1"
  1646 by (simp add: powr_def)
  1647 
  1648 lemma powr_zero_eq_one [simp]: "x powr 0 = 1"
  1649 by (simp add: powr_def)
  1650 
  1651 lemma powr_one_gt_zero_iff [simp]: "(x powr 1 = x) = (0 < x)"
  1652 by (simp add: powr_def)
  1653 declare powr_one_gt_zero_iff [THEN iffD2, simp]
  1654 
  1655 lemma powr_mult: 
  1656       "[| 0 < x; 0 < y |] ==> (x * y) powr a = (x powr a) * (y powr a)"
  1657 by (simp add: powr_def exp_add [symmetric] ln_mult distrib_left)
  1658 
  1659 lemma powr_gt_zero [simp]: "0 < x powr a"
  1660 by (simp add: powr_def)
  1661 
  1662 lemma powr_ge_pzero [simp]: "0 <= x powr y"
  1663 by (rule order_less_imp_le, rule powr_gt_zero)
  1664 
  1665 lemma powr_not_zero [simp]: "x powr a \<noteq> 0"
  1666 by (simp add: powr_def)
  1667 
  1668 lemma powr_divide:
  1669      "[| 0 < x; 0 < y |] ==> (x / y) powr a = (x powr a)/(y powr a)"
  1670 apply (simp add: divide_inverse positive_imp_inverse_positive powr_mult)
  1671 apply (simp add: powr_def exp_minus [symmetric] exp_add [symmetric] ln_inverse)
  1672 done
  1673 
  1674 lemma powr_divide2: "x powr a / x powr b = x powr (a - b)"
  1675   apply (simp add: powr_def)
  1676   apply (subst exp_diff [THEN sym])
  1677   apply (simp add: left_diff_distrib)
  1678 done
  1679 
  1680 lemma powr_add: "x powr (a + b) = (x powr a) * (x powr b)"
  1681 by (simp add: powr_def exp_add [symmetric] distrib_right)
  1682 
  1683 lemma powr_mult_base:
  1684   "0 < x \<Longrightarrow>x * x powr y = x powr (1 + y)"
  1685 using assms by (auto simp: powr_add)
  1686 
  1687 lemma powr_powr: "(x powr a) powr b = x powr (a * b)"
  1688 by (simp add: powr_def)
  1689 
  1690 lemma powr_powr_swap: "(x powr a) powr b = (x powr b) powr a"
  1691 by (simp add: powr_powr mult_commute)
  1692 
  1693 lemma powr_minus: "x powr (-a) = inverse (x powr a)"
  1694 by (simp add: powr_def exp_minus [symmetric])
  1695 
  1696 lemma powr_minus_divide: "x powr (-a) = 1/(x powr a)"
  1697 by (simp add: divide_inverse powr_minus)
  1698 
  1699 lemma powr_less_mono: "[| a < b; 1 < x |] ==> x powr a < x powr b"
  1700 by (simp add: powr_def)
  1701 
  1702 lemma powr_less_cancel: "[| x powr a < x powr b; 1 < x |] ==> a < b"
  1703 by (simp add: powr_def)
  1704 
  1705 lemma powr_less_cancel_iff [simp]: "1 < x ==> (x powr a < x powr b) = (a < b)"
  1706 by (blast intro: powr_less_cancel powr_less_mono)
  1707 
  1708 lemma powr_le_cancel_iff [simp]: "1 < x ==> (x powr a \<le> x powr b) = (a \<le> b)"
  1709 by (simp add: linorder_not_less [symmetric])
  1710 
  1711 lemma log_ln: "ln x = log (exp(1)) x"
  1712 by (simp add: log_def)
  1713 
  1714 lemma DERIV_log: assumes "x > 0" shows "DERIV (\<lambda>y. log b y) x :> 1 / (ln b * x)"
  1715 proof -
  1716   def lb \<equiv> "1 / ln b"
  1717   moreover have "DERIV (\<lambda>y. lb * ln y) x :> lb / x"
  1718     using `x > 0` by (auto intro!: DERIV_intros)
  1719   ultimately show ?thesis
  1720     by (simp add: log_def)
  1721 qed
  1722 
  1723 lemmas DERIV_log[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1724 
  1725 lemma powr_log_cancel [simp]:
  1726      "[| 0 < a; a \<noteq> 1; 0 < x |] ==> a powr (log a x) = x"
  1727 by (simp add: powr_def log_def)
  1728 
  1729 lemma log_powr_cancel [simp]: "[| 0 < a; a \<noteq> 1 |] ==> log a (a powr y) = y"
  1730 by (simp add: log_def powr_def)
  1731 
  1732 lemma log_mult: 
  1733      "[| 0 < a; a \<noteq> 1; 0 < x; 0 < y |]  
  1734       ==> log a (x * y) = log a x + log a y"
  1735 by (simp add: log_def ln_mult divide_inverse distrib_right)
  1736 
  1737 lemma log_eq_div_ln_mult_log: 
  1738      "[| 0 < a; a \<noteq> 1; 0 < b; b \<noteq> 1; 0 < x |]  
  1739       ==> log a x = (ln b/ln a) * log b x"
  1740 by (simp add: log_def divide_inverse)
  1741 
  1742 text{*Base 10 logarithms*}
  1743 lemma log_base_10_eq1: "0 < x ==> log 10 x = (ln (exp 1) / ln 10) * ln x"
  1744 by (simp add: log_def)
  1745 
  1746 lemma log_base_10_eq2: "0 < x ==> log 10 x = (log 10 (exp 1)) * ln x"
  1747 by (simp add: log_def)
  1748 
  1749 lemma log_one [simp]: "log a 1 = 0"
  1750 by (simp add: log_def)
  1751 
  1752 lemma log_eq_one [simp]: "[| 0 < a; a \<noteq> 1 |] ==> log a a = 1"
  1753 by (simp add: log_def)
  1754 
  1755 lemma log_inverse:
  1756      "[| 0 < a; a \<noteq> 1; 0 < x |] ==> log a (inverse x) = - log a x"
  1757 apply (rule_tac a1 = "log a x" in add_left_cancel [THEN iffD1])
  1758 apply (simp add: log_mult [symmetric])
  1759 done
  1760 
  1761 lemma log_divide:
  1762      "[|0 < a; a \<noteq> 1; 0 < x; 0 < y|] ==> log a (x/y) = log a x - log a y"
  1763 by (simp add: log_mult divide_inverse log_inverse)
  1764 
  1765 lemma log_less_cancel_iff [simp]:
  1766      "[| 1 < a; 0 < x; 0 < y |] ==> (log a x < log a y) = (x < y)"
  1767 apply safe
  1768 apply (rule_tac [2] powr_less_cancel)
  1769 apply (drule_tac a = "log a x" in powr_less_mono, auto)
  1770 done
  1771 
  1772 lemma log_inj: assumes "1 < b" shows "inj_on (log b) {0 <..}"
  1773 proof (rule inj_onI, simp)
  1774   fix x y assume pos: "0 < x" "0 < y" and *: "log b x = log b y"
  1775   show "x = y"
  1776   proof (cases rule: linorder_cases)
  1777     assume "x < y" hence "log b x < log b y"
  1778       using log_less_cancel_iff[OF `1 < b`] pos by simp
  1779     thus ?thesis using * by simp
  1780   next
  1781     assume "y < x" hence "log b y < log b x"
  1782       using log_less_cancel_iff[OF `1 < b`] pos by simp
  1783     thus ?thesis using * by simp
  1784   qed simp
  1785 qed
  1786 
  1787 lemma log_le_cancel_iff [simp]:
  1788      "[| 1 < a; 0 < x; 0 < y |] ==> (log a x \<le> log a y) = (x \<le> y)"
  1789 by (simp add: linorder_not_less [symmetric])
  1790 
  1791 lemma zero_less_log_cancel_iff[simp]: "1 < a \<Longrightarrow> 0 < x \<Longrightarrow> 0 < log a x \<longleftrightarrow> 1 < x"
  1792   using log_less_cancel_iff[of a 1 x] by simp
  1793 
  1794 lemma zero_le_log_cancel_iff[simp]: "1 < a \<Longrightarrow> 0 < x \<Longrightarrow> 0 \<le> log a x \<longleftrightarrow> 1 \<le> x"
  1795   using log_le_cancel_iff[of a 1 x] by simp
  1796 
  1797 lemma log_less_zero_cancel_iff[simp]: "1 < a \<Longrightarrow> 0 < x \<Longrightarrow> log a x < 0 \<longleftrightarrow> x < 1"
  1798   using log_less_cancel_iff[of a x 1] by simp
  1799 
  1800 lemma log_le_zero_cancel_iff[simp]: "1 < a \<Longrightarrow> 0 < x \<Longrightarrow> log a x \<le> 0 \<longleftrightarrow> x \<le> 1"
  1801   using log_le_cancel_iff[of a x 1] by simp
  1802 
  1803 lemma one_less_log_cancel_iff[simp]: "1 < a \<Longrightarrow> 0 < x \<Longrightarrow> 1 < log a x \<longleftrightarrow> a < x"
  1804   using log_less_cancel_iff[of a a x] by simp
  1805 
  1806 lemma one_le_log_cancel_iff[simp]: "1 < a \<Longrightarrow> 0 < x \<Longrightarrow> 1 \<le> log a x \<longleftrightarrow> a \<le> x"
  1807   using log_le_cancel_iff[of a a x] by simp
  1808 
  1809 lemma log_less_one_cancel_iff[simp]: "1 < a \<Longrightarrow> 0 < x \<Longrightarrow> log a x < 1 \<longleftrightarrow> x < a"
  1810   using log_less_cancel_iff[of a x a] by simp
  1811 
  1812 lemma log_le_one_cancel_iff[simp]: "1 < a \<Longrightarrow> 0 < x \<Longrightarrow> log a x \<le> 1 \<longleftrightarrow> x \<le> a"
  1813   using log_le_cancel_iff[of a x a] by simp
  1814 
  1815 lemma powr_realpow: "0 < x ==> x powr (real n) = x^n"
  1816   apply (induct n, simp)
  1817   apply (subgoal_tac "real(Suc n) = real n + 1")
  1818   apply (erule ssubst)
  1819   apply (subst powr_add, simp, simp)
  1820 done
  1821 
  1822 lemma powr_realpow_numeral: "0 < x \<Longrightarrow> x powr (numeral n :: real) = x^(numeral n)"
  1823   unfolding real_of_nat_numeral[symmetric] by (rule powr_realpow)
  1824 
  1825 lemma powr_realpow2: "0 <= x ==> 0 < n ==> x^n = (if (x = 0) then 0 else x powr (real n))"
  1826   apply (case_tac "x = 0", simp, simp)
  1827   apply (rule powr_realpow [THEN sym], simp)
  1828 done
  1829 
  1830 lemma powr_int:
  1831   assumes "x > 0"
  1832   shows "x powr i = (if i \<ge> 0 then x ^ nat i else 1 / x ^ nat (-i))"
  1833 proof cases
  1834   assume "i < 0"
  1835   have r: "x powr i = 1 / x powr (-i)" by (simp add: powr_minus field_simps)
  1836   show ?thesis using `i < 0` `x > 0` by (simp add: r field_simps powr_realpow[symmetric])
  1837 qed (simp add: assms powr_realpow[symmetric])
  1838 
  1839 lemma powr_numeral: "0 < x \<Longrightarrow> x powr numeral n = x^numeral n"
  1840   using powr_realpow[of x "numeral n"] by simp
  1841 
  1842 lemma powr_neg_numeral: "0 < x \<Longrightarrow> x powr neg_numeral n = 1 / x^numeral n"
  1843   using powr_int[of x "neg_numeral n"] by simp
  1844 
  1845 lemma root_powr_inverse:
  1846   "0 < n \<Longrightarrow> 0 < x \<Longrightarrow> root n x = x powr (1/n)"
  1847   by (rule real_root_pos_unique) (auto simp: powr_realpow[symmetric] powr_powr)
  1848 
  1849 lemma ln_powr: "0 < x ==> 0 < y ==> ln(x powr y) = y * ln x"
  1850 by (unfold powr_def, simp)
  1851 
  1852 lemma log_powr: "0 < x ==> 0 \<le> y ==> log b (x powr y) = y * log b x"
  1853   apply (case_tac "y = 0")
  1854   apply force
  1855   apply (auto simp add: log_def ln_powr field_simps)
  1856 done
  1857 
  1858 lemma log_nat_power: "0 < x ==> log b (x^n) = real n * log b x"
  1859   apply (subst powr_realpow [symmetric])
  1860   apply (auto simp add: log_powr)
  1861 done
  1862 
  1863 lemma ln_bound: "1 <= x ==> ln x <= x"
  1864   apply (subgoal_tac "ln(1 + (x - 1)) <= x - 1")
  1865   apply simp
  1866   apply (rule ln_add_one_self_le_self, simp)
  1867 done
  1868 
  1869 lemma powr_mono: "a <= b ==> 1 <= x ==> x powr a <= x powr b"
  1870   apply (case_tac "x = 1", simp)
  1871   apply (case_tac "a = b", simp)
  1872   apply (rule order_less_imp_le)
  1873   apply (rule powr_less_mono, auto)
  1874 done
  1875 
  1876 lemma ge_one_powr_ge_zero: "1 <= x ==> 0 <= a ==> 1 <= x powr a"
  1877   apply (subst powr_zero_eq_one [THEN sym])
  1878   apply (rule powr_mono, assumption+)
  1879 done
  1880 
  1881 lemma powr_less_mono2: "0 < a ==> 0 < x ==> x < y ==> x powr a <
  1882     y powr a"
  1883   apply (unfold powr_def)
  1884   apply (rule exp_less_mono)
  1885   apply (rule mult_strict_left_mono)
  1886   apply (subst ln_less_cancel_iff, assumption)
  1887   apply (rule order_less_trans)
  1888   prefer 2
  1889   apply assumption+
  1890 done
  1891 
  1892 lemma powr_less_mono2_neg: "a < 0 ==> 0 < x ==> x < y ==> y powr a <
  1893     x powr a"
  1894   apply (unfold powr_def)
  1895   apply (rule exp_less_mono)
  1896   apply (rule mult_strict_left_mono_neg)
  1897   apply (subst ln_less_cancel_iff)
  1898   apply assumption
  1899   apply (rule order_less_trans)
  1900   prefer 2
  1901   apply assumption+
  1902 done
  1903 
  1904 lemma powr_mono2: "0 <= a ==> 0 < x ==> x <= y ==> x powr a <= y powr a"
  1905   apply (case_tac "a = 0", simp)
  1906   apply (case_tac "x = y", simp)
  1907   apply (rule order_less_imp_le)
  1908   apply (rule powr_less_mono2, auto)
  1909 done
  1910 
  1911 lemma powr_inj:
  1912   "0 < a \<Longrightarrow> a \<noteq> 1 \<Longrightarrow> a powr x = a powr y \<longleftrightarrow> x = y"
  1913   unfolding powr_def exp_inj_iff by simp
  1914 
  1915 lemma ln_powr_bound: "1 <= x ==> 0 < a ==> ln x <= (x powr a) / a"
  1916   apply (rule mult_imp_le_div_pos)
  1917   apply (assumption)
  1918   apply (subst mult_commute)
  1919   apply (subst ln_powr [THEN sym])
  1920   apply auto
  1921   apply (rule ln_bound)
  1922   apply (erule ge_one_powr_ge_zero)
  1923   apply (erule order_less_imp_le)
  1924 done
  1925 
  1926 lemma ln_powr_bound2:
  1927   assumes "1 < x" and "0 < a"
  1928   shows "(ln x) powr a <= (a powr a) * x"
  1929 proof -
  1930   from assms have "ln x <= (x powr (1 / a)) / (1 / a)"
  1931     apply (intro ln_powr_bound)
  1932     apply (erule order_less_imp_le)
  1933     apply (rule divide_pos_pos)
  1934     apply simp_all
  1935     done
  1936   also have "... = a * (x powr (1 / a))"
  1937     by simp
  1938   finally have "(ln x) powr a <= (a * (x powr (1 / a))) powr a"
  1939     apply (intro powr_mono2)
  1940     apply (rule order_less_imp_le, rule assms)
  1941     apply (rule ln_gt_zero)
  1942     apply (rule assms)
  1943     apply assumption
  1944     done
  1945   also have "... = (a powr a) * ((x powr (1 / a)) powr a)"
  1946     apply (rule powr_mult)
  1947     apply (rule assms)
  1948     apply (rule powr_gt_zero)
  1949     done
  1950   also have "(x powr (1 / a)) powr a = x powr ((1 / a) * a)"
  1951     by (rule powr_powr)
  1952   also have "... = x"
  1953     apply simp
  1954     apply (subgoal_tac "a ~= 0")
  1955     using assms apply auto
  1956     done
  1957   finally show ?thesis .
  1958 qed
  1959 
  1960 lemma tendsto_powr [tendsto_intros]:
  1961   "\<lbrakk>(f ---> a) F; (g ---> b) F; 0 < a\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x powr g x) ---> a powr b) F"
  1962   unfolding powr_def by (intro tendsto_intros)
  1963 
  1964 lemma continuous_powr:
  1965   assumes "continuous F f" and "continuous F g" and "0 < f (Lim F (\<lambda>x. x))"
  1966   shows "continuous F (\<lambda>x. (f x) powr (g x))"
  1967   using assms unfolding continuous_def by (rule tendsto_powr)
  1968 
  1969 lemma continuous_at_within_powr[continuous_intros]:
  1970   assumes "continuous (at a within s) f" "continuous (at a within s) g" and "0 < f a"
  1971   shows "continuous (at a within s) (\<lambda>x. (f x) powr (g x))"
  1972   using assms unfolding continuous_within by (rule tendsto_powr)
  1973 
  1974 lemma isCont_powr[continuous_intros, simp]:
  1975   assumes "isCont f a" "isCont g a" "0 < f a"
  1976   shows "isCont (\<lambda>x. (f x) powr g x) a"
  1977   using assms unfolding continuous_at by (rule tendsto_powr)
  1978 
  1979 lemma continuous_on_powr[continuous_on_intros]:
  1980   assumes "continuous_on s f" "continuous_on s g" and "\<forall>x\<in>s. 0 < f x"
  1981   shows "continuous_on s (\<lambda>x. (f x) powr (g x))"
  1982   using assms unfolding continuous_on_def by (fast intro: tendsto_powr)
  1983 
  1984 (* FIXME: generalize by replacing d by with g x and g ---> d? *)
  1985 lemma tendsto_zero_powrI:
  1986   assumes "eventually (\<lambda>x. 0 < f x ) F" and "(f ---> 0) F"
  1987   assumes "0 < d"
  1988   shows "((\<lambda>x. f x powr d) ---> 0) F"
  1989 proof (rule tendstoI)
  1990   fix e :: real assume "0 < e"
  1991   def Z \<equiv> "e powr (1 / d)"
  1992   with `0 < e` have "0 < Z" by simp
  1993   with assms have "eventually (\<lambda>x. 0 < f x \<and> dist (f x) 0 < Z) F"
  1994     by (intro eventually_conj tendstoD)
  1995   moreover
  1996   from assms have "\<And>x. 0 < x \<and> dist x 0 < Z \<Longrightarrow> x powr d < Z powr d"
  1997     by (intro powr_less_mono2) (auto simp: dist_real_def)
  1998   with assms `0 < e` have "\<And>x. 0 < x \<and> dist x 0 < Z \<Longrightarrow> dist (x powr d) 0 < e"
  1999     unfolding dist_real_def Z_def by (auto simp: powr_powr)
  2000   ultimately
  2001   show "eventually (\<lambda>x. dist (f x powr d) 0 < e) F" by (rule eventually_elim1)
  2002 qed
  2003 
  2004 lemma tendsto_neg_powr:
  2005   assumes "s < 0" and "LIM x F. f x :> at_top"
  2006   shows "((\<lambda>x. f x powr s) ---> 0) F"
  2007 proof (rule tendstoI)
  2008   fix e :: real assume "0 < e"
  2009   def Z \<equiv> "e powr (1 / s)"
  2010   from assms have "eventually (\<lambda>x. Z < f x) F"
  2011     by (simp add: filterlim_at_top_dense)
  2012   moreover
  2013   from assms have "\<And>x. Z < x \<Longrightarrow> x powr s < Z powr s"
  2014     by (auto simp: Z_def intro!: powr_less_mono2_neg)
  2015   with assms `0 < e` have "\<And>x. Z < x \<Longrightarrow> dist (x powr s) 0 < e"
  2016     by (simp add: powr_powr Z_def dist_real_def)
  2017   ultimately
  2018   show "eventually (\<lambda>x. dist (f x powr s) 0 < e) F" by (rule eventually_elim1)
  2019 qed
  2020 
  2021 subsection {* Sine and Cosine *}
  2022 
  2023 definition sin_coeff :: "nat \<Rightarrow> real" where
  2024   "sin_coeff = (\<lambda>n. if even n then 0 else -1 ^ ((n - Suc 0) div 2) / real (fact n))"
  2025 
  2026 definition cos_coeff :: "nat \<Rightarrow> real" where
  2027   "cos_coeff = (\<lambda>n. if even n then (-1 ^ (n div 2)) / real (fact n) else 0)"
  2028 
  2029 definition sin :: "real \<Rightarrow> real" where
  2030   "sin = (\<lambda>x. \<Sum>n. sin_coeff n * x ^ n)"
  2031 
  2032 definition cos :: "real \<Rightarrow> real" where
  2033   "cos = (\<lambda>x. \<Sum>n. cos_coeff n * x ^ n)"
  2034 
  2035 lemma sin_coeff_0 [simp]: "sin_coeff 0 = 0"
  2036   unfolding sin_coeff_def by simp
  2037 
  2038 lemma cos_coeff_0 [simp]: "cos_coeff 0 = 1"
  2039   unfolding cos_coeff_def by simp
  2040 
  2041 lemma sin_coeff_Suc: "sin_coeff (Suc n) = cos_coeff n / real (Suc n)"
  2042   unfolding cos_coeff_def sin_coeff_def
  2043   by (simp del: mult_Suc)
  2044 
  2045 lemma cos_coeff_Suc: "cos_coeff (Suc n) = - sin_coeff n / real (Suc n)"
  2046   unfolding cos_coeff_def sin_coeff_def
  2047   by (simp del: mult_Suc, auto simp add: odd_Suc_mult_two_ex)
  2048 
  2049 lemma summable_sin: "summable (\<lambda>n. sin_coeff n * x ^ n)"
  2050 unfolding sin_coeff_def
  2051 apply (rule summable_comparison_test [OF _ summable_exp [where x="\<bar>x\<bar>"]])
  2052 apply (auto simp add: divide_inverse abs_mult power_abs [symmetric] zero_le_mult_iff)
  2053 done
  2054 
  2055 lemma summable_cos: "summable (\<lambda>n. cos_coeff n * x ^ n)"
  2056 unfolding cos_coeff_def
  2057 apply (rule summable_comparison_test [OF _ summable_exp [where x="\<bar>x\<bar>"]])
  2058 apply (auto simp add: divide_inverse abs_mult power_abs [symmetric] zero_le_mult_iff)
  2059 done
  2060 
  2061 lemma sin_converges: "(\<lambda>n. sin_coeff n * x ^ n) sums sin(x)"
  2062 unfolding sin_def by (rule summable_sin [THEN summable_sums])
  2063 
  2064 lemma cos_converges: "(\<lambda>n. cos_coeff n * x ^ n) sums cos(x)"
  2065 unfolding cos_def by (rule summable_cos [THEN summable_sums])
  2066 
  2067 lemma diffs_sin_coeff: "diffs sin_coeff = cos_coeff"
  2068   by (simp add: diffs_def sin_coeff_Suc real_of_nat_def del: of_nat_Suc)
  2069 
  2070 lemma diffs_cos_coeff: "diffs cos_coeff = (\<lambda>n. - sin_coeff n)"
  2071   by (simp add: diffs_def cos_coeff_Suc real_of_nat_def del: of_nat_Suc)
  2072 
  2073 text{*Now at last we can get the derivatives of exp, sin and cos*}
  2074 
  2075 lemma DERIV_sin [simp]: "DERIV sin x :> cos(x)"
  2076   unfolding sin_def cos_def
  2077   apply (rule DERIV_cong, rule termdiffs [where K="1 + \<bar>x\<bar>"])
  2078   apply (simp_all add: diffs_sin_coeff diffs_cos_coeff
  2079     summable_minus summable_sin summable_cos)
  2080   done
  2081 
  2082 declare DERIV_sin[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2083 
  2084 lemma DERIV_cos [simp]: "DERIV cos x :> -sin(x)"
  2085   unfolding cos_def sin_def
  2086   apply (rule DERIV_cong, rule termdiffs [where K="1 + \<bar>x\<bar>"])
  2087   apply (simp_all add: diffs_sin_coeff diffs_cos_coeff diffs_minus
  2088     summable_minus summable_sin summable_cos suminf_minus)
  2089   done
  2090 
  2091 declare DERIV_cos[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2092 
  2093 lemma isCont_sin: "isCont sin x"
  2094   by (rule DERIV_sin [THEN DERIV_isCont])
  2095 
  2096 lemma isCont_cos: "isCont cos x"
  2097   by (rule DERIV_cos [THEN DERIV_isCont])
  2098 
  2099 lemma isCont_sin' [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. sin (f x)) a"
  2100   by (rule isCont_o2 [OF _ isCont_sin])
  2101 
  2102 lemma isCont_cos' [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. cos (f x)) a"
  2103   by (rule isCont_o2 [OF _ isCont_cos])
  2104 
  2105 lemma tendsto_sin [tendsto_intros]:
  2106   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. sin (f x)) ---> sin a) F"
  2107   by (rule isCont_tendsto_compose [OF isCont_sin])
  2108 
  2109 lemma tendsto_cos [tendsto_intros]:
  2110   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. cos (f x)) ---> cos a) F"
  2111   by (rule isCont_tendsto_compose [OF isCont_cos])
  2112 
  2113 lemma continuous_sin [continuous_intros]:
  2114   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. sin (f x))"
  2115   unfolding continuous_def by (rule tendsto_sin)
  2116 
  2117 lemma continuous_on_sin [continuous_on_intros]:
  2118   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. sin (f x))"
  2119   unfolding continuous_on_def by (auto intro: tendsto_sin)
  2120 
  2121 lemma continuous_cos [continuous_intros]:
  2122   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. cos (f x))"
  2123   unfolding continuous_def by (rule tendsto_cos)
  2124 
  2125 lemma continuous_on_cos [continuous_on_intros]:
  2126   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. cos (f x))"
  2127   unfolding continuous_on_def by (auto intro: tendsto_cos)
  2128 
  2129 subsection {* Properties of Sine and Cosine *}
  2130 
  2131 lemma sin_zero [simp]: "sin 0 = 0"
  2132   unfolding sin_def sin_coeff_def by (simp add: powser_zero)
  2133 
  2134 lemma cos_zero [simp]: "cos 0 = 1"
  2135   unfolding cos_def cos_coeff_def by (simp add: powser_zero)
  2136 
  2137 lemma sin_cos_squared_add [simp]: "(sin x)\<twosuperior> + (cos x)\<twosuperior> = 1"
  2138 proof -
  2139   have "\<forall>x. DERIV (\<lambda>x. (sin x)\<twosuperior> + (cos x)\<twosuperior>) x :> 0"
  2140     by (auto intro!: DERIV_intros)
  2141   hence "(sin x)\<twosuperior> + (cos x)\<twosuperior> = (sin 0)\<twosuperior> + (cos 0)\<twosuperior>"
  2142     by (rule DERIV_isconst_all)
  2143   thus "(sin x)\<twosuperior> + (cos x)\<twosuperior> = 1" by simp
  2144 qed
  2145 
  2146 lemma sin_cos_squared_add2 [simp]: "(cos x)\<twosuperior> + (sin x)\<twosuperior> = 1"
  2147   by (subst add_commute, rule sin_cos_squared_add)
  2148 
  2149 lemma sin_cos_squared_add3 [simp]: "cos x * cos x + sin x * sin x = 1"
  2150   using sin_cos_squared_add2 [unfolded power2_eq_square] .
  2151 
  2152 lemma sin_squared_eq: "(sin x)\<twosuperior> = 1 - (cos x)\<twosuperior>"
  2153   unfolding eq_diff_eq by (rule sin_cos_squared_add)
  2154 
  2155 lemma cos_squared_eq: "(cos x)\<twosuperior> = 1 - (sin x)\<twosuperior>"
  2156   unfolding eq_diff_eq by (rule sin_cos_squared_add2)
  2157 
  2158 lemma abs_sin_le_one [simp]: "\<bar>sin x\<bar> \<le> 1"
  2159   by (rule power2_le_imp_le, simp_all add: sin_squared_eq)
  2160 
  2161 lemma sin_ge_minus_one [simp]: "-1 \<le> sin x"
  2162   using abs_sin_le_one [of x] unfolding abs_le_iff by simp
  2163 
  2164 lemma sin_le_one [simp]: "sin x \<le> 1"
  2165   using abs_sin_le_one [of x] unfolding abs_le_iff by simp
  2166 
  2167 lemma abs_cos_le_one [simp]: "\<bar>cos x\<bar> \<le> 1"
  2168   by (rule power2_le_imp_le, simp_all add: cos_squared_eq)
  2169 
  2170 lemma cos_ge_minus_one [simp]: "-1 \<le> cos x"
  2171   using abs_cos_le_one [of x] unfolding abs_le_iff by simp
  2172 
  2173 lemma cos_le_one [simp]: "cos x \<le> 1"
  2174   using abs_cos_le_one [of x] unfolding abs_le_iff by simp
  2175 
  2176 lemma DERIV_fun_pow: "DERIV g x :> m ==>
  2177       DERIV (%x. (g x) ^ n) x :> real n * (g x) ^ (n - 1) * m"
  2178   by (auto intro!: DERIV_intros)
  2179 
  2180 lemma DERIV_fun_exp:
  2181      "DERIV g x :> m ==> DERIV (%x. exp(g x)) x :> exp(g x) * m"
  2182   by (auto intro!: DERIV_intros)
  2183 
  2184 lemma DERIV_fun_sin:
  2185      "DERIV g x :> m ==> DERIV (%x. sin(g x)) x :> cos(g x) * m"
  2186   by (auto intro!: DERIV_intros)
  2187 
  2188 lemma DERIV_fun_cos:
  2189      "DERIV g x :> m ==> DERIV (%x. cos(g x)) x :> -sin(g x) * m"
  2190   by (auto intro!: DERIV_intros)
  2191 
  2192 lemma sin_cos_add_lemma:
  2193      "(sin (x + y) - (sin x * cos y + cos x * sin y)) ^ 2 +
  2194       (cos (x + y) - (cos x * cos y - sin x * sin y)) ^ 2 = 0"
  2195   (is "?f x = 0")
  2196 proof -
  2197   have "\<forall>x. DERIV (\<lambda>x. ?f x) x :> 0"
  2198     by (auto intro!: DERIV_intros simp add: algebra_simps)
  2199   hence "?f x = ?f 0"
  2200     by (rule DERIV_isconst_all)
  2201   thus ?thesis by simp
  2202 qed
  2203 
  2204 lemma sin_add: "sin (x + y) = sin x * cos y + cos x * sin y"
  2205   using sin_cos_add_lemma unfolding realpow_two_sum_zero_iff by simp
  2206 
  2207 lemma cos_add: "cos (x + y) = cos x * cos y - sin x * sin y"
  2208   using sin_cos_add_lemma unfolding realpow_two_sum_zero_iff by simp
  2209 
  2210 lemma sin_cos_minus_lemma:
  2211   "(sin(-x) + sin(x))\<twosuperior> + (cos(-x) - cos(x))\<twosuperior> = 0" (is "?f x = 0")
  2212 proof -
  2213   have "\<forall>x. DERIV (\<lambda>x. ?f x) x :> 0"
  2214     by (auto intro!: DERIV_intros simp add: algebra_simps)
  2215   hence "?f x = ?f 0"
  2216     by (rule DERIV_isconst_all)
  2217   thus ?thesis by simp
  2218 qed
  2219 
  2220 lemma sin_minus [simp]: "sin (-x) = -sin(x)"
  2221   using sin_cos_minus_lemma [where x=x] by simp
  2222 
  2223 lemma cos_minus [simp]: "cos (-x) = cos(x)"
  2224   using sin_cos_minus_lemma [where x=x] by simp
  2225 
  2226 lemma sin_diff: "sin (x - y) = sin x * cos y - cos x * sin y"
  2227   by (simp add: diff_minus sin_add)
  2228 
  2229 lemma sin_diff2: "sin (x - y) = cos y * sin x - sin y * cos x"
  2230   by (simp add: sin_diff mult_commute)
  2231 
  2232 lemma cos_diff: "cos (x - y) = cos x * cos y + sin x * sin y"
  2233   by (simp add: diff_minus cos_add)
  2234 
  2235 lemma cos_diff2: "cos (x - y) = cos y * cos x + sin y * sin x"
  2236   by (simp add: cos_diff mult_commute)
  2237 
  2238 lemma sin_double [simp]: "sin(2 * x) = 2* sin x * cos x"
  2239   using sin_add [where x=x and y=x] by simp
  2240 
  2241 lemma cos_double: "cos(2* x) = ((cos x)\<twosuperior>) - ((sin x)\<twosuperior>)"
  2242   using cos_add [where x=x and y=x]
  2243   by (simp add: power2_eq_square)
  2244 
  2245 
  2246 subsection {* The Constant Pi *}
  2247 
  2248 definition pi :: "real" where
  2249   "pi = 2 * (THE x. 0 \<le> (x::real) & x \<le> 2 & cos x = 0)"
  2250 
  2251 text{*Show that there's a least positive @{term x} with @{term "cos(x) = 0"};
  2252    hence define pi.*}
  2253 
  2254 lemma sin_paired:
  2255      "(%n. -1 ^ n /(real (fact (2 * n + 1))) * x ^ (2 * n + 1))
  2256       sums  sin x"
  2257 proof -
  2258   have "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2. sin_coeff k * x ^ k) sums sin x"
  2259     by (rule sin_converges [THEN sums_group], simp)
  2260   thus ?thesis unfolding One_nat_def sin_coeff_def by (simp add: mult_ac)
  2261 qed
  2262 
  2263 lemma sin_gt_zero:
  2264   assumes "0 < x" and "x < 2" shows "0 < sin x"
  2265 proof -
  2266   let ?f = "\<lambda>n. \<Sum>k = n*2..<n*2+2. -1 ^ k / real (fact (2*k+1)) * x^(2*k+1)"
  2267   have pos: "\<forall>n. 0 < ?f n"
  2268   proof
  2269     fix n :: nat
  2270     let ?k2 = "real (Suc (Suc (4 * n)))"
  2271     let ?k3 = "real (Suc (Suc (Suc (4 * n))))"
  2272     have "x * x < ?k2 * ?k3"
  2273       using assms by (intro mult_strict_mono', simp_all)
  2274     hence "x * x * x * x ^ (n * 4) < ?k2 * ?k3 * x * x ^ (n * 4)"
  2275       by (intro mult_strict_right_mono zero_less_power `0 < x`)
  2276     thus "0 < ?f n"
  2277       by (simp del: mult_Suc,
  2278         simp add: less_divide_eq mult_pos_pos field_simps del: mult_Suc)
  2279   qed
  2280   have sums: "?f sums sin x"
  2281     by (rule sin_paired [THEN sums_group], simp)
  2282   show "0 < sin x"
  2283     unfolding sums_unique [OF sums]
  2284     using sums_summable [OF sums] pos
  2285     by (rule suminf_gt_zero)
  2286 qed
  2287 
  2288 lemma cos_double_less_one: "[| 0 < x; x < 2 |] ==> cos (2 * x) < 1"
  2289 apply (cut_tac x = x in sin_gt_zero)
  2290 apply (auto simp add: cos_squared_eq cos_double)
  2291 done
  2292 
  2293 lemma cos_paired:
  2294      "(%n. -1 ^ n /(real (fact (2 * n))) * x ^ (2 * n)) sums cos x"
  2295 proof -
  2296   have "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2. cos_coeff k * x ^ k) sums cos x"
  2297     by (rule cos_converges [THEN sums_group], simp)
  2298   thus ?thesis unfolding cos_coeff_def by (simp add: mult_ac)
  2299 qed
  2300 
  2301 lemma real_mult_inverse_cancel:
  2302      "[|(0::real) < x; 0 < x1; x1 * y < x * u |]
  2303       ==> inverse x * y < inverse x1 * u"
  2304 apply (rule_tac c=x in mult_less_imp_less_left)
  2305 apply (auto simp add: mult_assoc [symmetric])
  2306 apply (simp (no_asm) add: mult_ac)
  2307 apply (rule_tac c=x1 in mult_less_imp_less_right)
  2308 apply (auto simp add: mult_ac)
  2309 done
  2310 
  2311 lemma real_mult_inverse_cancel2:
  2312      "[|(0::real) < x;0 < x1; x1 * y < x * u |] ==> y * inverse x < u * inverse x1"
  2313 apply (auto dest: real_mult_inverse_cancel simp add: mult_ac)
  2314 done
  2315 
  2316 lemma realpow_num_eq_if:
  2317   fixes m :: "'a::power"
  2318   shows "m ^ n = (if n=0 then 1 else m * m ^ (n - 1))"
  2319 by (cases n, auto)
  2320 
  2321 lemma cos_two_less_zero [simp]: "cos (2) < 0"
  2322 apply (cut_tac x = 2 in cos_paired)
  2323 apply (drule sums_minus)
  2324 apply (rule neg_less_iff_less [THEN iffD1])
  2325 apply (frule sums_unique, auto)
  2326 apply (rule_tac y =
  2327  "\<Sum>n=0..< Suc(Suc(Suc 0)). - (-1 ^ n / (real(fact (2*n))) * 2 ^ (2*n))"
  2328        in order_less_trans)
  2329 apply (simp (no_asm) add: fact_num_eq_if_nat realpow_num_eq_if del: fact_Suc)
  2330 apply (simp (no_asm) add: mult_assoc del: setsum_op_ivl_Suc)
  2331 apply (rule sumr_pos_lt_pair)
  2332 apply (erule sums_summable, safe)
  2333 unfolding One_nat_def
  2334 apply (simp (no_asm) add: divide_inverse real_0_less_add_iff mult_assoc [symmetric]
  2335             del: fact_Suc)
  2336 apply (simp add: inverse_eq_divide less_divide_eq del: fact_Suc)
  2337 apply (subst fact_Suc [of "Suc (Suc (Suc (Suc (Suc (Suc (Suc (4 * d)))))))"])
  2338 apply (simp only: real_of_nat_mult)
  2339 apply (rule mult_strict_mono, force)
  2340   apply (rule_tac [3] real_of_nat_ge_zero)
  2341  prefer 2 apply force
  2342 apply (rule real_of_nat_less_iff [THEN iffD2])
  2343 apply (rule fact_less_mono_nat, auto)
  2344 done
  2345 
  2346 lemmas cos_two_neq_zero [simp] = cos_two_less_zero [THEN less_imp_neq]
  2347 lemmas cos_two_le_zero [simp] = cos_two_less_zero [THEN order_less_imp_le]
  2348 
  2349 lemma cos_is_zero: "EX! x. 0 \<le> x & x \<le> 2 & cos x = 0"
  2350 proof (rule ex_ex1I)
  2351   show "\<exists>x. 0 \<le> x & x \<le> 2 & cos x = 0"
  2352     by (rule IVT2, simp_all)
  2353 next
  2354   fix x y
  2355   assume x: "0 \<le> x \<and> x \<le> 2 \<and> cos x = 0"
  2356   assume y: "0 \<le> y \<and> y \<le> 2 \<and> cos y = 0"
  2357   have [simp]: "\<forall>x. cos differentiable x"
  2358     unfolding differentiable_def by (auto intro: DERIV_cos)
  2359   from x y show "x = y"
  2360     apply (cut_tac less_linear [of x y], auto)
  2361     apply (drule_tac f = cos in Rolle)
  2362     apply (drule_tac [5] f = cos in Rolle)
  2363     apply (auto dest!: DERIV_cos [THEN DERIV_unique])
  2364     apply (metis order_less_le_trans less_le sin_gt_zero)
  2365     apply (metis order_less_le_trans less_le sin_gt_zero)
  2366     done
  2367 qed
  2368 
  2369 lemma pi_half: "pi/2 = (THE x. 0 \<le> x & x \<le> 2 & cos x = 0)"
  2370 by (simp add: pi_def)
  2371 
  2372 lemma cos_pi_half [simp]: "cos (pi / 2) = 0"
  2373 by (simp add: pi_half cos_is_zero [THEN theI'])
  2374 
  2375 lemma pi_half_gt_zero [simp]: "0 < pi / 2"
  2376 apply (rule order_le_neq_trans)
  2377 apply (simp add: pi_half cos_is_zero [THEN theI'])
  2378 apply (rule notI, drule arg_cong [where f=cos], simp)
  2379 done
  2380 
  2381 lemmas pi_half_neq_zero [simp] = pi_half_gt_zero [THEN less_imp_neq, symmetric]
  2382 lemmas pi_half_ge_zero [simp] = pi_half_gt_zero [THEN order_less_imp_le]
  2383 
  2384 lemma pi_half_less_two [simp]: "pi / 2 < 2"
  2385 apply (rule order_le_neq_trans)
  2386 apply (simp add: pi_half cos_is_zero [THEN theI'])
  2387 apply (rule notI, drule arg_cong [where f=cos], simp)
  2388 done
  2389 
  2390 lemmas pi_half_neq_two [simp] = pi_half_less_two [THEN less_imp_neq]
  2391 lemmas pi_half_le_two [simp] =  pi_half_less_two [THEN order_less_imp_le]
  2392 
  2393 lemma pi_gt_zero [simp]: "0 < pi"
  2394 by (insert pi_half_gt_zero, simp)
  2395 
  2396 lemma pi_ge_zero [simp]: "0 \<le> pi"
  2397 by (rule pi_gt_zero [THEN order_less_imp_le])
  2398 
  2399 lemma pi_neq_zero [simp]: "pi \<noteq> 0"
  2400 by (rule pi_gt_zero [THEN less_imp_neq, THEN not_sym])
  2401 
  2402 lemma pi_not_less_zero [simp]: "\<not> pi < 0"
  2403 by (simp add: linorder_not_less)
  2404 
  2405 lemma minus_pi_half_less_zero: "-(pi/2) < 0"
  2406 by simp
  2407 
  2408 lemma m2pi_less_pi: "- (2 * pi) < pi"
  2409 by simp
  2410 
  2411 lemma sin_pi_half [simp]: "sin(pi/2) = 1"
  2412 apply (cut_tac x = "pi/2" in sin_cos_squared_add2)
  2413 apply (cut_tac sin_gt_zero [OF pi_half_gt_zero pi_half_less_two])
  2414 apply (simp add: power2_eq_1_iff)
  2415 done
  2416 
  2417 lemma cos_pi [simp]: "cos pi = -1"
  2418 by (cut_tac x = "pi/2" and y = "pi/2" in cos_add, simp)
  2419 
  2420 lemma sin_pi [simp]: "sin pi = 0"
  2421 by (cut_tac x = "pi/2" and y = "pi/2" in sin_add, simp)
  2422 
  2423 lemma sin_cos_eq: "sin x = cos (pi/2 - x)"
  2424 by (simp add: cos_diff)
  2425 
  2426 lemma minus_sin_cos_eq: "-sin x = cos (x + pi/2)"
  2427 by (simp add: cos_add)
  2428 
  2429 lemma cos_sin_eq: "cos x = sin (pi/2 - x)"
  2430 by (simp add: sin_diff)
  2431 
  2432 lemma sin_periodic_pi [simp]: "sin (x + pi) = - sin x"
  2433 by (simp add: sin_add)
  2434 
  2435 lemma sin_periodic_pi2 [simp]: "sin (pi + x) = - sin x"
  2436 by (simp add: sin_add)
  2437 
  2438 lemma cos_periodic_pi [simp]: "cos (x + pi) = - cos x"
  2439 by (simp add: cos_add)
  2440 
  2441 lemma sin_periodic [simp]: "sin (x + 2*pi) = sin x"
  2442 by (simp add: sin_add cos_double)
  2443 
  2444 lemma cos_periodic [simp]: "cos (x + 2*pi) = cos x"
  2445 by (simp add: cos_add cos_double)
  2446 
  2447 lemma cos_npi [simp]: "cos (real n * pi) = -1 ^ n"
  2448 apply (induct "n")
  2449 apply (auto simp add: real_of_nat_Suc distrib_right)
  2450 done
  2451 
  2452 lemma cos_npi2 [simp]: "cos (pi * real n) = -1 ^ n"
  2453 proof -
  2454   have "cos (pi * real n) = cos (real n * pi)" by (simp only: mult_commute)
  2455   also have "... = -1 ^ n" by (rule cos_npi)
  2456   finally show ?thesis .
  2457 qed
  2458 
  2459 lemma sin_npi [simp]: "sin (real (n::nat) * pi) = 0"
  2460 apply (induct "n")
  2461 apply (auto simp add: real_of_nat_Suc distrib_right)
  2462 done
  2463 
  2464 lemma sin_npi2 [simp]: "sin (pi * real (n::nat)) = 0"
  2465 by (simp add: mult_commute [of pi])
  2466 
  2467 lemma cos_two_pi [simp]: "cos (2 * pi) = 1"
  2468 by (simp add: cos_double)
  2469 
  2470 lemma sin_two_pi [simp]: "sin (2 * pi) = 0"
  2471 by simp
  2472 
  2473 lemma sin_gt_zero2: "[| 0 < x; x < pi/2 |] ==> 0 < sin x"
  2474 apply (rule sin_gt_zero, assumption)
  2475 apply (rule order_less_trans, assumption)
  2476 apply (rule pi_half_less_two)
  2477 done
  2478 
  2479 lemma sin_less_zero:
  2480   assumes lb: "- pi/2 < x" and "x < 0" shows "sin x < 0"
  2481 proof -
  2482   have "0 < sin (- x)" using assms by (simp only: sin_gt_zero2)
  2483   thus ?thesis by simp
  2484 qed
  2485 
  2486 lemma pi_less_4: "pi < 4"
  2487 by (cut_tac pi_half_less_two, auto)
  2488 
  2489 lemma cos_gt_zero: "[| 0 < x; x < pi/2 |] ==> 0 < cos x"
  2490 apply (cut_tac pi_less_4)
  2491 apply (cut_tac f = cos and a = 0 and b = x and y = 0 in IVT2_objl, safe, simp_all)
  2492 apply (cut_tac cos_is_zero, safe)
  2493 apply (rename_tac y z)
  2494 apply (drule_tac x = y in spec)
  2495 apply (drule_tac x = "pi/2" in spec, simp)
  2496 done
  2497 
  2498 lemma cos_gt_zero_pi: "[| -(pi/2) < x; x < pi/2 |] ==> 0 < cos x"
  2499 apply (rule_tac x = x and y = 0 in linorder_cases)
  2500 apply (rule cos_minus [THEN subst])
  2501 apply (rule cos_gt_zero)
  2502 apply (auto intro: cos_gt_zero)
  2503 done
  2504 
  2505 lemma cos_ge_zero: "[| -(pi/2) \<le> x; x \<le> pi/2 |] ==> 0 \<le> cos x"
  2506 apply (auto simp add: order_le_less cos_gt_zero_pi)
  2507 apply (subgoal_tac "x = pi/2", auto)
  2508 done
  2509 
  2510 lemma sin_gt_zero_pi: "[| 0 < x; x < pi  |] ==> 0 < sin x"
  2511 by (simp add: sin_cos_eq cos_gt_zero_pi)
  2512 
  2513 lemma pi_ge_two: "2 \<le> pi"
  2514 proof (rule ccontr)
  2515   assume "\<not> 2 \<le> pi" hence "pi < 2" by auto
  2516   have "\<exists>y > pi. y < 2 \<and> y < 2 * pi"
  2517   proof (cases "2 < 2 * pi")
  2518     case True with dense[OF `pi < 2`] show ?thesis by auto
  2519   next
  2520     case False have "pi < 2 * pi" by auto
  2521     from dense[OF this] and False show ?thesis by auto
  2522   qed
  2523   then obtain y where "pi < y" and "y < 2" and "y < 2 * pi" by blast
  2524   hence "0 < sin y" using sin_gt_zero by auto
  2525   moreover
  2526   have "sin y < 0" using sin_gt_zero_pi[of "y - pi"] `pi < y` and `y < 2 * pi` sin_periodic_pi[of "y - pi"] by auto
  2527   ultimately show False by auto
  2528 qed
  2529 
  2530 lemma sin_ge_zero: "[| 0 \<le> x; x \<le> pi |] ==> 0 \<le> sin x"
  2531 by (auto simp add: order_le_less sin_gt_zero_pi)
  2532 
  2533 text {* FIXME: This proof is almost identical to lemma @{text cos_is_zero}.
  2534   It should be possible to factor out some of the common parts. *}
  2535 
  2536 lemma cos_total: "[| -1 \<le> y; y \<le> 1 |] ==> EX! x. 0 \<le> x & x \<le> pi & (cos x = y)"
  2537 proof (rule ex_ex1I)
  2538   assume y: "-1 \<le> y" "y \<le> 1"
  2539   show "\<exists>x. 0 \<le> x & x \<le> pi & cos x = y"
  2540     by (rule IVT2, simp_all add: y)
  2541 next
  2542   fix a b
  2543   assume a: "0 \<le> a \<and> a \<le> pi \<and> cos a = y"
  2544   assume b: "0 \<le> b \<and> b \<le> pi \<and> cos b = y"
  2545   have [simp]: "\<forall>x. cos differentiable x"
  2546     unfolding differentiable_def by (auto intro: DERIV_cos)
  2547   from a b show "a = b"
  2548     apply (cut_tac less_linear [of a b], auto)
  2549     apply (drule_tac f = cos in Rolle)
  2550     apply (drule_tac [5] f = cos in Rolle)
  2551     apply (auto dest!: DERIV_cos [THEN DERIV_unique])
  2552     apply (metis order_less_le_trans less_le sin_gt_zero_pi)
  2553     apply (metis order_less_le_trans less_le sin_gt_zero_pi)
  2554     done
  2555 qed
  2556 
  2557 lemma sin_total:
  2558      "[| -1 \<le> y; y \<le> 1 |] ==> EX! x. -(pi/2) \<le> x & x \<le> pi/2 & (sin x = y)"
  2559 apply (rule ccontr)
  2560 apply (subgoal_tac "\<forall>x. (- (pi/2) \<le> x & x \<le> pi/2 & (sin x = y)) = (0 \<le> (x + pi/2) & (x + pi/2) \<le> pi & (cos (x + pi/2) = -y))")
  2561 apply (erule contrapos_np)
  2562 apply simp
  2563 apply (cut_tac y="-y" in cos_total, simp) apply simp
  2564 apply (erule ex1E)
  2565 apply (rule_tac a = "x - (pi/2)" in ex1I)
  2566 apply (simp (no_asm) add: add_assoc)
  2567 apply (rotate_tac 3)
  2568 apply (drule_tac x = "xa + pi/2" in spec, safe, simp_all add: cos_add)
  2569 done
  2570 
  2571 lemma reals_Archimedean4:
  2572      "[| 0 < y; 0 \<le> x |] ==> \<exists>n. real n * y \<le> x & x < real (Suc n) * y"
  2573 apply (auto dest!: reals_Archimedean3)
  2574 apply (drule_tac x = x in spec, clarify)
  2575 apply (subgoal_tac "x < real(LEAST m::nat. x < real m * y) * y")
  2576  prefer 2 apply (erule LeastI)
  2577 apply (case_tac "LEAST m::nat. x < real m * y", simp)
  2578 apply (subgoal_tac "~ x < real nat * y")
  2579  prefer 2 apply (rule not_less_Least, simp, force)
  2580 done
  2581 
  2582 (* Pre Isabelle99-2 proof was simpler- numerals arithmetic
  2583    now causes some unwanted re-arrangements of literals!   *)
  2584 lemma cos_zero_lemma:
  2585      "[| 0 \<le> x; cos x = 0 |] ==>
  2586       \<exists>n::nat. ~even n & x = real n * (pi/2)"
  2587 apply (drule pi_gt_zero [THEN reals_Archimedean4], safe)
  2588 apply (subgoal_tac "0 \<le> x - real n * pi &
  2589                     (x - real n * pi) \<le> pi & (cos (x - real n * pi) = 0) ")
  2590 apply (auto simp add: algebra_simps real_of_nat_Suc)
  2591  prefer 2 apply (simp add: cos_diff)
  2592 apply (simp add: cos_diff)
  2593 apply (subgoal_tac "EX! x. 0 \<le> x & x \<le> pi & cos x = 0")
  2594 apply (rule_tac [2] cos_total, safe)
  2595 apply (drule_tac x = "x - real n * pi" in spec)
  2596 apply (drule_tac x = "pi/2" in spec)
  2597 apply (simp add: cos_diff)
  2598 apply (rule_tac x = "Suc (2 * n)" in exI)
  2599 apply (simp add: real_of_nat_Suc algebra_simps, auto)
  2600 done
  2601 
  2602 lemma sin_zero_lemma:
  2603      "[| 0 \<le> x; sin x = 0 |] ==>
  2604       \<exists>n::nat. even n & x = real n * (pi/2)"
  2605 apply (subgoal_tac "\<exists>n::nat. ~ even n & x + pi/2 = real n * (pi/2) ")
  2606  apply (clarify, rule_tac x = "n - 1" in exI)
  2607  apply (force simp add: odd_Suc_mult_two_ex real_of_nat_Suc distrib_right)
  2608 apply (rule cos_zero_lemma)
  2609 apply (simp_all add: cos_add)
  2610 done
  2611 
  2612 
  2613 lemma cos_zero_iff:
  2614      "(cos x = 0) =
  2615       ((\<exists>n::nat. ~even n & (x = real n * (pi/2))) |
  2616        (\<exists>n::nat. ~even n & (x = -(real n * (pi/2)))))"
  2617 apply (rule iffI)
  2618 apply (cut_tac linorder_linear [of 0 x], safe)
  2619 apply (drule cos_zero_lemma, assumption+)
  2620 apply (cut_tac x="-x" in cos_zero_lemma, simp, simp)
  2621 apply (force simp add: minus_equation_iff [of x])
  2622 apply (auto simp only: odd_Suc_mult_two_ex real_of_nat_Suc distrib_right)
  2623 apply (auto simp add: cos_add)
  2624 done
  2625 
  2626 (* ditto: but to a lesser extent *)
  2627 lemma sin_zero_iff:
  2628      "(sin x = 0) =
  2629       ((\<exists>n::nat. even n & (x = real n * (pi/2))) |
  2630        (\<exists>n::nat. even n & (x = -(real n * (pi/2)))))"
  2631 apply (rule iffI)
  2632 apply (cut_tac linorder_linear [of 0 x], safe)
  2633 apply (drule sin_zero_lemma, assumption+)
  2634 apply (cut_tac x="-x" in sin_zero_lemma, simp, simp, safe)
  2635 apply (force simp add: minus_equation_iff [of x])
  2636 apply (auto simp add: even_mult_two_ex)
  2637 done
  2638 
  2639 lemma cos_monotone_0_pi: assumes "0 \<le> y" and "y < x" and "x \<le> pi"
  2640   shows "cos x < cos y"
  2641 proof -
  2642   have "- (x - y) < 0" using assms by auto
  2643 
  2644   from MVT2[OF `y < x` DERIV_cos[THEN impI, THEN allI]]
  2645   obtain z where "y < z" and "z < x" and cos_diff: "cos x - cos y = (x - y) * - sin z" by auto
  2646   hence "0 < z" and "z < pi" using assms by auto
  2647   hence "0 < sin z" using sin_gt_zero_pi by auto
  2648   hence "cos x - cos y < 0" unfolding cos_diff minus_mult_commute[symmetric] using `- (x - y) < 0` by (rule mult_pos_neg2)
  2649   thus ?thesis by auto
  2650 qed
  2651 
  2652 lemma cos_monotone_0_pi': assumes "0 \<le> y" and "y \<le> x" and "x \<le> pi" shows "cos x \<le> cos y"
  2653 proof (cases "y < x")
  2654   case True show ?thesis using cos_monotone_0_pi[OF `0 \<le> y` True `x \<le> pi`] by auto
  2655 next
  2656   case False hence "y = x" using `y \<le> x` by auto
  2657   thus ?thesis by auto
  2658 qed
  2659 
  2660 lemma cos_monotone_minus_pi_0: assumes "-pi \<le> y" and "y < x" and "x \<le> 0"
  2661   shows "cos y < cos x"
  2662 proof -
  2663   have "0 \<le> -x" and "-x < -y" and "-y \<le> pi" using assms by auto
  2664   from cos_monotone_0_pi[OF this]
  2665   show ?thesis unfolding cos_minus .
  2666 qed
  2667 
  2668 lemma cos_monotone_minus_pi_0': assumes "-pi \<le> y" and "y \<le> x" and "x \<le> 0" shows "cos y \<le> cos x"
  2669 proof (cases "y < x")
  2670   case True show ?thesis using cos_monotone_minus_pi_0[OF `-pi \<le> y` True `x \<le> 0`] by auto
  2671 next
  2672   case False hence "y = x" using `y \<le> x` by auto
  2673   thus ?thesis by auto
  2674 qed
  2675 
  2676 lemma sin_monotone_2pi': assumes "- (pi / 2) \<le> y" and "y \<le> x" and "x \<le> pi / 2" shows "sin y \<le> sin x"
  2677 proof -
  2678   have "0 \<le> y + pi / 2" and "y + pi / 2 \<le> x + pi / 2" and "x + pi /2 \<le> pi"
  2679     using pi_ge_two and assms by auto
  2680   from cos_monotone_0_pi'[OF this] show ?thesis unfolding minus_sin_cos_eq[symmetric] by auto
  2681 qed
  2682 
  2683 subsection {* Tangent *}
  2684 
  2685 definition tan :: "real \<Rightarrow> real" where
  2686   "tan = (\<lambda>x. sin x / cos x)"
  2687 
  2688 lemma tan_zero [simp]: "tan 0 = 0"
  2689   by (simp add: tan_def)
  2690 
  2691 lemma tan_pi [simp]: "tan pi = 0"
  2692   by (simp add: tan_def)
  2693 
  2694 lemma tan_npi [simp]: "tan (real (n::nat) * pi) = 0"
  2695   by (simp add: tan_def)
  2696 
  2697 lemma tan_minus [simp]: "tan (-x) = - tan x"
  2698   by (simp add: tan_def)
  2699 
  2700 lemma tan_periodic [simp]: "tan (x + 2*pi) = tan x"
  2701   by (simp add: tan_def)
  2702 
  2703 lemma lemma_tan_add1:
  2704   "\<lbrakk>cos x \<noteq> 0; cos y \<noteq> 0\<rbrakk> \<Longrightarrow> 1 - tan x * tan y = cos (x + y)/(cos x * cos y)"
  2705   by (simp add: tan_def cos_add field_simps)
  2706 
  2707 lemma add_tan_eq:
  2708   "\<lbrakk>cos x \<noteq> 0; cos y \<noteq> 0\<rbrakk> \<Longrightarrow> tan x + tan y = sin(x + y)/(cos x * cos y)"
  2709   by (simp add: tan_def sin_add field_simps)
  2710 
  2711 lemma tan_add:
  2712      "[| cos x \<noteq> 0; cos y \<noteq> 0; cos (x + y) \<noteq> 0 |]
  2713       ==> tan(x + y) = (tan(x) + tan(y))/(1 - tan(x) * tan(y))"
  2714   by (simp add: add_tan_eq lemma_tan_add1, simp add: tan_def)
  2715 
  2716 lemma tan_double:
  2717      "[| cos x \<noteq> 0; cos (2 * x) \<noteq> 0 |]
  2718       ==> tan (2 * x) = (2 * tan x)/(1 - (tan(x) ^ 2))"
  2719   using tan_add [of x x] by (simp add: power2_eq_square)
  2720 
  2721 lemma tan_gt_zero: "[| 0 < x; x < pi/2 |] ==> 0 < tan x"
  2722 by (simp add: tan_def zero_less_divide_iff sin_gt_zero2 cos_gt_zero_pi)
  2723 
  2724 lemma tan_less_zero:
  2725   assumes lb: "- pi/2 < x" and "x < 0" shows "tan x < 0"
  2726 proof -
  2727   have "0 < tan (- x)" using assms by (simp only: tan_gt_zero)
  2728   thus ?thesis by simp
  2729 qed
  2730 
  2731 lemma tan_half: "tan x = sin (2 * x) / (cos (2 * x) + 1)"
  2732   unfolding tan_def sin_double cos_double sin_squared_eq
  2733   by (simp add: power2_eq_square)
  2734 
  2735 lemma DERIV_tan [simp]: "cos x \<noteq> 0 \<Longrightarrow> DERIV tan x :> inverse ((cos x)\<twosuperior>)"
  2736   unfolding tan_def
  2737   by (auto intro!: DERIV_intros, simp add: divide_inverse power2_eq_square)
  2738 
  2739 lemma isCont_tan: "cos x \<noteq> 0 \<Longrightarrow> isCont tan x"
  2740   by (rule DERIV_tan [THEN DERIV_isCont])
  2741 
  2742 lemma isCont_tan' [simp]:
  2743   "\<lbrakk>isCont f a; cos (f a) \<noteq> 0\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. tan (f x)) a"
  2744   by (rule isCont_o2 [OF _ isCont_tan])
  2745 
  2746 lemma tendsto_tan [tendsto_intros]:
  2747   "\<lbrakk>(f ---> a) F; cos a \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. tan (f x)) ---> tan a) F"
  2748   by (rule isCont_tendsto_compose [OF isCont_tan])
  2749 
  2750 lemma continuous_tan:
  2751   "continuous F f \<Longrightarrow> cos (f (Lim F (\<lambda>x. x))) \<noteq> 0 \<Longrightarrow> continuous F (\<lambda>x. tan (f x))"
  2752   unfolding continuous_def by (rule tendsto_tan)
  2753 
  2754 lemma isCont_tan'' [continuous_intros]:
  2755   "continuous (at x) f \<Longrightarrow> cos (f x) \<noteq> 0 \<Longrightarrow> continuous (at x) (\<lambda>x. tan (f x))"
  2756   unfolding continuous_at by (rule tendsto_tan)
  2757 
  2758 lemma continuous_within_tan [continuous_intros]:
  2759   "continuous (at x within s) f \<Longrightarrow> cos (f x) \<noteq> 0 \<Longrightarrow> continuous (at x within s) (\<lambda>x. tan (f x))"
  2760   unfolding continuous_within by (rule tendsto_tan)
  2761 
  2762 lemma continuous_on_tan [continuous_on_intros]:
  2763   "continuous_on s f \<Longrightarrow> (\<forall>x\<in>s. cos (f x) \<noteq> 0) \<Longrightarrow> continuous_on s (\<lambda>x. tan (f x))"
  2764   unfolding continuous_on_def by (auto intro: tendsto_tan)
  2765 
  2766 lemma LIM_cos_div_sin: "(%x. cos(x)/sin(x)) -- pi/2 --> 0"
  2767   by (rule LIM_cong_limit, (rule tendsto_intros)+, simp_all)
  2768 
  2769 lemma lemma_tan_total: "0 < y ==> \<exists>x. 0 < x & x < pi/2 & y < tan x"
  2770 apply (cut_tac LIM_cos_div_sin)
  2771 apply (simp only: LIM_eq)
  2772 apply (drule_tac x = "inverse y" in spec, safe, force)
  2773 apply (drule_tac ?d1.0 = s in pi_half_gt_zero [THEN [2] real_lbound_gt_zero], safe)
  2774 apply (rule_tac x = "(pi/2) - e" in exI)
  2775 apply (simp (no_asm_simp))
  2776 apply (drule_tac x = "(pi/2) - e" in spec)
  2777 apply (auto simp add: tan_def sin_diff cos_diff)
  2778 apply (rule inverse_less_iff_less [THEN iffD1])
  2779 apply (auto simp add: divide_inverse)
  2780 apply (rule mult_pos_pos)
  2781 apply (subgoal_tac [3] "0 < sin e & 0 < cos e")
  2782 apply (auto intro: cos_gt_zero sin_gt_zero2 simp add: mult_commute)
  2783 done
  2784 
  2785 lemma tan_total_pos: "0 \<le> y ==> \<exists>x. 0 \<le> x & x < pi/2 & tan x = y"
  2786 apply (frule order_le_imp_less_or_eq, safe)
  2787  prefer 2 apply force
  2788 apply (drule lemma_tan_total, safe)
  2789 apply (cut_tac f = tan and a = 0 and b = x and y = y in IVT_objl)
  2790 apply (auto intro!: DERIV_tan [THEN DERIV_isCont])
  2791 apply (drule_tac y = xa in order_le_imp_less_or_eq)
  2792 apply (auto dest: cos_gt_zero)
  2793 done
  2794 
  2795 lemma lemma_tan_total1: "\<exists>x. -(pi/2) < x & x < (pi/2) & tan x = y"
  2796 apply (cut_tac linorder_linear [of 0 y], safe)
  2797 apply (drule tan_total_pos)
  2798 apply (cut_tac [2] y="-y" in tan_total_pos, safe)
  2799 apply (rule_tac [3] x = "-x" in exI)
  2800 apply (auto del: exI intro!: exI)
  2801 done
  2802 
  2803 lemma tan_total: "EX! x. -(pi/2) < x & x < (pi/2) & tan x = y"
  2804 apply (cut_tac y = y in lemma_tan_total1, auto)
  2805 apply (cut_tac x = xa and y = y in linorder_less_linear, auto)
  2806 apply (subgoal_tac [2] "\<exists>z. y < z & z < xa & DERIV tan z :> 0")
  2807 apply (subgoal_tac "\<exists>z. xa < z & z < y & DERIV tan z :> 0")
  2808 apply (rule_tac [4] Rolle)
  2809 apply (rule_tac [2] Rolle)
  2810 apply (auto del: exI intro!: DERIV_tan DERIV_isCont exI
  2811             simp add: differentiable_def)
  2812 txt{*Now, simulate TRYALL*}
  2813 apply (rule_tac [!] DERIV_tan asm_rl)
  2814 apply (auto dest!: DERIV_unique [OF _ DERIV_tan]
  2815             simp add: cos_gt_zero_pi [THEN less_imp_neq, THEN not_sym])
  2816 done
  2817 
  2818 lemma tan_monotone: assumes "- (pi / 2) < y" and "y < x" and "x < pi / 2"
  2819   shows "tan y < tan x"
  2820 proof -
  2821   have "\<forall> x'. y \<le> x' \<and> x' \<le> x \<longrightarrow> DERIV tan x' :> inverse (cos x'^2)"
  2822   proof (rule allI, rule impI)
  2823     fix x' :: real assume "y \<le> x' \<and> x' \<le> x"
  2824     hence "-(pi/2) < x'" and "x' < pi/2" using assms by auto
  2825     from cos_gt_zero_pi[OF this]
  2826     have "cos x' \<noteq> 0" by auto
  2827     thus "DERIV tan x' :> inverse (cos x'^2)" by (rule DERIV_tan)
  2828   qed
  2829   from MVT2[OF `y < x` this]
  2830   obtain z where "y < z" and "z < x" and tan_diff: "tan x - tan y = (x - y) * inverse ((cos z)\<twosuperior>)" by auto
  2831   hence "- (pi / 2) < z" and "z < pi / 2" using assms by auto
  2832   hence "0 < cos z" using cos_gt_zero_pi by auto
  2833   hence inv_pos: "0 < inverse ((cos z)\<twosuperior>)" by auto
  2834   have "0 < x - y" using `y < x` by auto
  2835   from mult_pos_pos [OF this inv_pos]
  2836   have "0 < tan x - tan y" unfolding tan_diff by auto
  2837   thus ?thesis by auto
  2838 qed
  2839 
  2840 lemma tan_monotone': assumes "- (pi / 2) < y" and "y < pi / 2" and "- (pi / 2) < x" and "x < pi / 2"
  2841   shows "(y < x) = (tan y < tan x)"
  2842 proof
  2843   assume "y < x" thus "tan y < tan x" using tan_monotone and `- (pi / 2) < y` and `x < pi / 2` by auto
  2844 next
  2845   assume "tan y < tan x"
  2846   show "y < x"
  2847   proof (rule ccontr)
  2848     assume "\<not> y < x" hence "x \<le> y" by auto
  2849     hence "tan x \<le> tan y"
  2850     proof (cases "x = y")
  2851       case True thus ?thesis by auto
  2852     next
  2853       case False hence "x < y" using `x \<le> y` by auto
  2854       from tan_monotone[OF `- (pi/2) < x` this `y < pi / 2`] show ?thesis by auto
  2855     qed
  2856     thus False using `tan y < tan x` by auto
  2857   qed
  2858 qed
  2859 
  2860 lemma tan_inverse: "1 / (tan y) = tan (pi / 2 - y)" unfolding tan_def sin_cos_eq[of y] cos_sin_eq[of y] by auto
  2861 
  2862 lemma tan_periodic_pi[simp]: "tan (x + pi) = tan x"
  2863   by (simp add: tan_def)
  2864 
  2865 lemma tan_periodic_nat[simp]: fixes n :: nat shows "tan (x + real n * pi) = tan x"
  2866 proof (induct n arbitrary: x)
  2867   case (Suc n)
  2868   have split_pi_off: "x + real (Suc n) * pi = (x + real n * pi) + pi" unfolding Suc_eq_plus1 real_of_nat_add real_of_one distrib_right by auto
  2869   show ?case unfolding split_pi_off using Suc by auto
  2870 qed auto
  2871 
  2872 lemma tan_periodic_int[simp]: fixes i :: int shows "tan (x + real i * pi) = tan x"
  2873 proof (cases "0 \<le> i")
  2874   case True hence i_nat: "real i = real (nat i)" by auto
  2875   show ?thesis unfolding i_nat by auto
  2876 next
  2877   case False hence i_nat: "real i = - real (nat (-i))" by auto
  2878   have "tan x = tan (x + real i * pi - real i * pi)" by auto
  2879   also have "\<dots> = tan (x + real i * pi)" unfolding i_nat mult_minus_left diff_minus_eq_add by (rule tan_periodic_nat)
  2880   finally show ?thesis by auto
  2881 qed
  2882 
  2883 lemma tan_periodic_n[simp]: "tan (x + numeral n * pi) = tan x"
  2884   using tan_periodic_int[of _ "numeral n" ] unfolding real_numeral .
  2885 
  2886 subsection {* Inverse Trigonometric Functions *}
  2887 
  2888 definition
  2889   arcsin :: "real => real" where
  2890   "arcsin y = (THE x. -(pi/2) \<le> x & x \<le> pi/2 & sin x = y)"
  2891 
  2892 definition
  2893   arccos :: "real => real" where
  2894   "arccos y = (THE x. 0 \<le> x & x \<le> pi & cos x = y)"
  2895 
  2896 definition
  2897   arctan :: "real => real" where
  2898   "arctan y = (THE x. -(pi/2) < x & x < pi/2 & tan x = y)"
  2899 
  2900 lemma arcsin:
  2901      "[| -1 \<le> y; y \<le> 1 |]
  2902       ==> -(pi/2) \<le> arcsin y &
  2903            arcsin y \<le> pi/2 & sin(arcsin y) = y"
  2904 unfolding arcsin_def by (rule theI' [OF sin_total])
  2905 
  2906 lemma arcsin_pi:
  2907      "[| -1 \<le> y; y \<le> 1 |]
  2908       ==> -(pi/2) \<le> arcsin y & arcsin y \<le> pi & sin(arcsin y) = y"
  2909 apply (drule (1) arcsin)
  2910 apply (force intro: order_trans)
  2911 done
  2912 
  2913 lemma sin_arcsin [simp]: "[| -1 \<le> y; y \<le> 1 |] ==> sin(arcsin y) = y"
  2914 by (blast dest: arcsin)
  2915 
  2916 lemma arcsin_bounded:
  2917      "[| -1 \<le> y; y \<le> 1 |] ==> -(pi/2) \<le> arcsin y & arcsin y \<le> pi/2"
  2918 by (blast dest: arcsin)
  2919 
  2920 lemma arcsin_lbound: "[| -1 \<le> y; y \<le> 1 |] ==> -(pi/2) \<le> arcsin y"
  2921 by (blast dest: arcsin)
  2922 
  2923 lemma arcsin_ubound: "[| -1 \<le> y; y \<le> 1 |] ==> arcsin y \<le> pi/2"
  2924 by (blast dest: arcsin)
  2925 
  2926 lemma arcsin_lt_bounded:
  2927      "[| -1 < y; y < 1 |] ==> -(pi/2) < arcsin y & arcsin y < pi/2"
  2928 apply (frule order_less_imp_le)
  2929 apply (frule_tac y = y in order_less_imp_le)
  2930 apply (frule arcsin_bounded)
  2931 apply (safe, simp)
  2932 apply (drule_tac y = "arcsin y" in order_le_imp_less_or_eq)
  2933 apply (drule_tac [2] y = "pi/2" in order_le_imp_less_or_eq, safe)
  2934 apply (drule_tac [!] f = sin in arg_cong, auto)
  2935 done
  2936 
  2937 lemma arcsin_sin: "[|-(pi/2) \<le> x; x \<le> pi/2 |] ==> arcsin(sin x) = x"
  2938 apply (unfold arcsin_def)
  2939 apply (rule the1_equality)
  2940 apply (rule sin_total, auto)
  2941 done
  2942 
  2943 lemma arccos:
  2944      "[| -1 \<le> y; y \<le> 1 |]
  2945       ==> 0 \<le> arccos y & arccos y \<le> pi & cos(arccos y) = y"
  2946 unfolding arccos_def by (rule theI' [OF cos_total])
  2947 
  2948 lemma cos_arccos [simp]: "[| -1 \<le> y; y \<le> 1 |] ==> cos(arccos y) = y"
  2949 by (blast dest: arccos)
  2950 
  2951 lemma arccos_bounded: "[| -1 \<le> y; y \<le> 1 |] ==> 0 \<le> arccos y & arccos y \<le> pi"
  2952 by (blast dest: arccos)
  2953 
  2954 lemma arccos_lbound: "[| -1 \<le> y; y \<le> 1 |] ==> 0 \<le> arccos y"
  2955 by (blast dest: arccos)
  2956 
  2957 lemma arccos_ubound: "[| -1 \<le> y; y \<le> 1 |] ==> arccos y \<le> pi"
  2958 by (blast dest: arccos)
  2959 
  2960 lemma arccos_lt_bounded:
  2961      "[| -1 < y; y < 1 |]
  2962       ==> 0 < arccos y & arccos y < pi"
  2963 apply (frule order_less_imp_le)
  2964 apply (frule_tac y = y in order_less_imp_le)
  2965 apply (frule arccos_bounded, auto)
  2966 apply (drule_tac y = "arccos y" in order_le_imp_less_or_eq)
  2967 apply (drule_tac [2] y = pi in order_le_imp_less_or_eq, auto)
  2968 apply (drule_tac [!] f = cos in arg_cong, auto)
  2969 done
  2970 
  2971 lemma arccos_cos: "[|0 \<le> x; x \<le> pi |] ==> arccos(cos x) = x"
  2972 apply (simp add: arccos_def)
  2973 apply (auto intro!: the1_equality cos_total)
  2974 done
  2975 
  2976 lemma arccos_cos2: "[|x \<le> 0; -pi \<le> x |] ==> arccos(cos x) = -x"
  2977 apply (simp add: arccos_def)
  2978 apply (auto intro!: the1_equality cos_total)
  2979 done
  2980 
  2981 lemma cos_arcsin: "\<lbrakk>-1 \<le> x; x \<le> 1\<rbrakk> \<Longrightarrow> cos (arcsin x) = sqrt (1 - x\<twosuperior>)"
  2982 apply (subgoal_tac "x\<twosuperior> \<le> 1")
  2983 apply (rule power2_eq_imp_eq)
  2984 apply (simp add: cos_squared_eq)
  2985 apply (rule cos_ge_zero)
  2986 apply (erule (1) arcsin_lbound)
  2987 apply (erule (1) arcsin_ubound)
  2988 apply simp
  2989 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> \<le> 1\<twosuperior>", simp)
  2990 apply (rule power_mono, simp, simp)
  2991 done
  2992 
  2993 lemma sin_arccos: "\<lbrakk>-1 \<le> x; x \<le> 1\<rbrakk> \<Longrightarrow> sin (arccos x) = sqrt (1 - x\<twosuperior>)"
  2994 apply (subgoal_tac "x\<twosuperior> \<le> 1")
  2995 apply (rule power2_eq_imp_eq)
  2996 apply (simp add: sin_squared_eq)
  2997 apply (rule sin_ge_zero)
  2998 apply (erule (1) arccos_lbound)
  2999 apply (erule (1) arccos_ubound)
  3000 apply simp
  3001 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> \<le> 1\<twosuperior>", simp)
  3002 apply (rule power_mono, simp, simp)
  3003 done
  3004 
  3005 lemma arctan [simp]:
  3006      "- (pi/2) < arctan y  & arctan y < pi/2 & tan (arctan y) = y"
  3007 unfolding arctan_def by (rule theI' [OF tan_total])
  3008 
  3009 lemma tan_arctan: "tan(arctan y) = y"
  3010 by auto
  3011 
  3012 lemma arctan_bounded: "- (pi/2) < arctan y  & arctan y < pi/2"
  3013 by (auto simp only: arctan)
  3014 
  3015 lemma arctan_lbound: "- (pi/2) < arctan y"
  3016 by auto
  3017 
  3018 lemma arctan_ubound: "arctan y < pi/2"
  3019 by (auto simp only: arctan)
  3020 
  3021 lemma arctan_unique:
  3022   assumes "-(pi/2) < x" and "x < pi/2" and "tan x = y"
  3023   shows "arctan y = x"
  3024   using assms arctan [of y] tan_total [of y] by (fast elim: ex1E)
  3025 
  3026 lemma arctan_tan:
  3027       "[|-(pi/2) < x; x < pi/2 |] ==> arctan(tan x) = x"
  3028   by (rule arctan_unique, simp_all)
  3029 
  3030 lemma arctan_zero_zero [simp]: "arctan 0 = 0"
  3031   by (rule arctan_unique, simp_all)
  3032 
  3033 lemma arctan_minus: "arctan (- x) = - arctan x"
  3034   apply (rule arctan_unique)
  3035   apply (simp only: neg_less_iff_less arctan_ubound)
  3036   apply (metis minus_less_iff arctan_lbound)
  3037   apply simp
  3038   done
  3039 
  3040 lemma cos_arctan_not_zero [simp]: "cos (arctan x) \<noteq> 0"
  3041   by (intro less_imp_neq [symmetric] cos_gt_zero_pi
  3042     arctan_lbound arctan_ubound)
  3043 
  3044 lemma cos_arctan: "cos (arctan x) = 1 / sqrt (1 + x\<twosuperior>)"
  3045 proof (rule power2_eq_imp_eq)
  3046   have "0 < 1 + x\<twosuperior>" by (simp add: add_pos_nonneg)
  3047   show "0 \<le> 1 / sqrt (1 + x\<twosuperior>)" by simp
  3048   show "0 \<le> cos (arctan x)"
  3049     by (intro less_imp_le cos_gt_zero_pi arctan_lbound arctan_ubound)
  3050   have "(cos (arctan x))\<twosuperior> * (1 + (tan (arctan x))\<twosuperior>) = 1"
  3051     unfolding tan_def by (simp add: distrib_left power_divide)
  3052   thus "(cos (arctan x))\<twosuperior> = (1 / sqrt (1 + x\<twosuperior>))\<twosuperior>"
  3053     using `0 < 1 + x\<twosuperior>` by (simp add: power_divide eq_divide_eq)
  3054 qed
  3055 
  3056 lemma sin_arctan: "sin (arctan x) = x / sqrt (1 + x\<twosuperior>)"
  3057   using add_pos_nonneg [OF zero_less_one zero_le_power2 [of x]]
  3058   using tan_arctan [of x] unfolding tan_def cos_arctan
  3059   by (simp add: eq_divide_eq)
  3060 
  3061 lemma tan_sec: "cos x \<noteq> 0 ==> 1 + tan(x) ^ 2 = inverse(cos x) ^ 2"
  3062 apply (rule power_inverse [THEN subst])
  3063 apply (rule_tac c1 = "(cos x)\<twosuperior>" in real_mult_right_cancel [THEN iffD1])
  3064 apply (auto dest: field_power_not_zero
  3065         simp add: power_mult_distrib distrib_right power_divide tan_def
  3066                   mult_assoc power_inverse [symmetric])
  3067 done
  3068 
  3069 lemma arctan_less_iff: "arctan x < arctan y \<longleftrightarrow> x < y"
  3070   by (metis tan_monotone' arctan_lbound arctan_ubound tan_arctan)
  3071 
  3072 lemma arctan_le_iff: "arctan x \<le> arctan y \<longleftrightarrow> x \<le> y"
  3073   by (simp only: not_less [symmetric] arctan_less_iff)
  3074 
  3075 lemma arctan_eq_iff: "arctan x = arctan y \<longleftrightarrow> x = y"
  3076   by (simp only: eq_iff [where 'a=real] arctan_le_iff)
  3077 
  3078 lemma zero_less_arctan_iff [simp]: "0 < arctan x \<longleftrightarrow> 0 < x"
  3079   using arctan_less_iff [of 0 x] by simp
  3080 
  3081 lemma arctan_less_zero_iff [simp]: "arctan x < 0 \<longleftrightarrow> x < 0"
  3082   using arctan_less_iff [of x 0] by simp
  3083 
  3084 lemma zero_le_arctan_iff [simp]: "0 \<le> arctan x \<longleftrightarrow> 0 \<le> x"
  3085   using arctan_le_iff [of 0 x] by simp
  3086 
  3087 lemma arctan_le_zero_iff [simp]: "arctan x \<le> 0 \<longleftrightarrow> x \<le> 0"
  3088   using arctan_le_iff [of x 0] by simp
  3089 
  3090 lemma arctan_eq_zero_iff [simp]: "arctan x = 0 \<longleftrightarrow> x = 0"
  3091   using arctan_eq_iff [of x 0] by simp
  3092 
  3093 lemma continuous_on_arcsin': "continuous_on {-1 .. 1} arcsin"
  3094 proof -
  3095   have "continuous_on (sin ` {- pi / 2 .. pi / 2}) arcsin"
  3096     by (rule continuous_on_inv) (auto intro: continuous_on_intros simp: arcsin_sin)
  3097   also have "sin ` {- pi / 2 .. pi / 2} = {-1 .. 1}"
  3098   proof safe
  3099     fix x :: real assume "x \<in> {-1..1}" then show "x \<in> sin ` {- pi / 2..pi / 2}"
  3100       using arcsin_lbound arcsin_ubound by (intro image_eqI[where x="arcsin x"]) auto
  3101   qed simp
  3102   finally show ?thesis .
  3103 qed
  3104 
  3105 lemma continuous_on_arcsin [continuous_on_intros]:
  3106   "continuous_on s f \<Longrightarrow> (\<forall>x\<in>s. -1 \<le> f x \<and> f x \<le> 1) \<Longrightarrow> continuous_on s (\<lambda>x. arcsin (f x))"
  3107   using continuous_on_compose[of s f, OF _ continuous_on_subset[OF  continuous_on_arcsin']]
  3108   by (auto simp: comp_def subset_eq)
  3109 
  3110 lemma isCont_arcsin: "-1 < x \<Longrightarrow> x < 1 \<Longrightarrow> isCont arcsin x"
  3111   using continuous_on_arcsin'[THEN continuous_on_subset, of "{ -1 <..< 1 }"]
  3112   by (auto simp: continuous_on_eq_continuous_at subset_eq)
  3113 
  3114 lemma continuous_on_arccos': "continuous_on {-1 .. 1} arccos"
  3115 proof -
  3116   have "continuous_on (cos ` {0 .. pi}) arccos"
  3117     by (rule continuous_on_inv) (auto intro: continuous_on_intros simp: arccos_cos)
  3118   also have "cos ` {0 .. pi} = {-1 .. 1}"
  3119   proof safe
  3120     fix x :: real assume "x \<in> {-1..1}" then show "x \<in> cos ` {0..pi}"
  3121       using arccos_lbound arccos_ubound by (intro image_eqI[where x="arccos x"]) auto
  3122   qed simp
  3123   finally show ?thesis .
  3124 qed
  3125 
  3126 lemma continuous_on_arccos [continuous_on_intros]:
  3127   "continuous_on s f \<Longrightarrow> (\<forall>x\<in>s. -1 \<le> f x \<and> f x \<le> 1) \<Longrightarrow> continuous_on s (\<lambda>x. arccos (f x))"
  3128   using continuous_on_compose[of s f, OF _ continuous_on_subset[OF  continuous_on_arccos']]
  3129   by (auto simp: comp_def subset_eq)
  3130 
  3131 lemma isCont_arccos: "-1 < x \<Longrightarrow> x < 1 \<Longrightarrow> isCont arccos x"
  3132   using continuous_on_arccos'[THEN continuous_on_subset, of "{ -1 <..< 1 }"]
  3133   by (auto simp: continuous_on_eq_continuous_at subset_eq)
  3134 
  3135 lemma isCont_arctan: "isCont arctan x"
  3136 apply (rule arctan_lbound [of x, THEN dense, THEN exE], clarify)
  3137 apply (rule arctan_ubound [of x, THEN dense, THEN exE], clarify)
  3138 apply (subgoal_tac "isCont arctan (tan (arctan x))", simp)
  3139 apply (erule (1) isCont_inverse_function2 [where f=tan])
  3140 apply (metis arctan_tan order_le_less_trans order_less_le_trans)
  3141 apply (metis cos_gt_zero_pi isCont_tan order_less_le_trans less_le)
  3142 done
  3143 
  3144 lemma tendsto_arctan [tendsto_intros]: "(f ---> x) F \<Longrightarrow> ((\<lambda>x. arctan (f x)) ---> arctan x) F"
  3145   by (rule isCont_tendsto_compose [OF isCont_arctan])
  3146 
  3147 lemma continuous_arctan [continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. arctan (f x))"
  3148   unfolding continuous_def by (rule tendsto_arctan)
  3149 
  3150 lemma continuous_on_arctan [continuous_on_intros]: "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. arctan (f x))"
  3151   unfolding continuous_on_def by (auto intro: tendsto_arctan)
  3152   
  3153 lemma DERIV_arcsin:
  3154   "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> DERIV arcsin x :> inverse (sqrt (1 - x\<twosuperior>))"
  3155 apply (rule DERIV_inverse_function [where f=sin and a="-1" and b="1"])
  3156 apply (rule DERIV_cong [OF DERIV_sin])
  3157 apply (simp add: cos_arcsin)
  3158 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> < 1\<twosuperior>", simp)
  3159 apply (rule power_strict_mono, simp, simp, simp)
  3160 apply assumption
  3161 apply assumption
  3162 apply simp
  3163 apply (erule (1) isCont_arcsin)
  3164 done
  3165 
  3166 lemma DERIV_arccos:
  3167   "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> DERIV arccos x :> inverse (- sqrt (1 - x\<twosuperior>))"
  3168 apply (rule DERIV_inverse_function [where f=cos and a="-1" and b="1"])
  3169 apply (rule DERIV_cong [OF DERIV_cos])
  3170 apply (simp add: sin_arccos)
  3171 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> < 1\<twosuperior>", simp)
  3172 apply (rule power_strict_mono, simp, simp, simp)
  3173 apply assumption
  3174 apply assumption
  3175 apply simp
  3176 apply (erule (1) isCont_arccos)
  3177 done
  3178 
  3179 lemma DERIV_arctan: "DERIV arctan x :> inverse (1 + x\<twosuperior>)"
  3180 apply (rule DERIV_inverse_function [where f=tan and a="x - 1" and b="x + 1"])
  3181 apply (rule DERIV_cong [OF DERIV_tan])
  3182 apply (rule cos_arctan_not_zero)
  3183 apply (simp add: power_inverse tan_sec [symmetric])
  3184 apply (subgoal_tac "0 < 1 + x\<twosuperior>", simp)
  3185 apply (simp add: add_pos_nonneg)
  3186 apply (simp, simp, simp, rule isCont_arctan)
  3187 done
  3188 
  3189 declare
  3190   DERIV_arcsin[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  3191   DERIV_arccos[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  3192   DERIV_arctan[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  3193 
  3194 lemma filterlim_tan_at_right: "filterlim tan at_bot (at_right (- pi/2))"
  3195   by (rule filterlim_at_bot_at_right[where Q="\<lambda>x. - pi/2 < x \<and> x < pi/2" and P="\<lambda>x. True" and g=arctan])
  3196      (auto simp: le_less eventually_at dist_real_def simp del: less_divide_eq_numeral1
  3197            intro!: tan_monotone exI[of _ "pi/2"])
  3198 
  3199 lemma filterlim_tan_at_left: "filterlim tan at_top (at_left (pi/2))"
  3200   by (rule filterlim_at_top_at_left[where Q="\<lambda>x. - pi/2 < x \<and> x < pi/2" and P="\<lambda>x. True" and g=arctan])
  3201      (auto simp: le_less eventually_at dist_real_def simp del: less_divide_eq_numeral1
  3202            intro!: tan_monotone exI[of _ "pi/2"])
  3203 
  3204 lemma tendsto_arctan_at_top: "(arctan ---> (pi/2)) at_top"
  3205 proof (rule tendstoI)
  3206   fix e :: real assume "0 < e"
  3207   def y \<equiv> "pi/2 - min (pi/2) e"
  3208   then have y: "0 \<le> y" "y < pi/2" "pi/2 \<le> e + y"
  3209     using `0 < e` by auto
  3210 
  3211   show "eventually (\<lambda>x. dist (arctan x) (pi / 2) < e) at_top"
  3212   proof (intro eventually_at_top_dense[THEN iffD2] exI allI impI)
  3213     fix x assume "tan y < x"
  3214     then have "arctan (tan y) < arctan x"
  3215       by (simp add: arctan_less_iff)
  3216     with y have "y < arctan x"
  3217       by (subst (asm) arctan_tan) simp_all
  3218     with arctan_ubound[of x, arith] y `0 < e`
  3219     show "dist (arctan x) (pi / 2) < e"
  3220       by (simp add: dist_real_def)
  3221   qed
  3222 qed
  3223 
  3224 lemma tendsto_arctan_at_bot: "(arctan ---> - (pi/2)) at_bot"
  3225   unfolding filterlim_at_bot_mirror arctan_minus by (intro tendsto_minus tendsto_arctan_at_top)
  3226 
  3227 subsection {* More Theorems about Sin and Cos *}
  3228 
  3229 lemma cos_45: "cos (pi / 4) = sqrt 2 / 2"
  3230 proof -
  3231   let ?c = "cos (pi / 4)" and ?s = "sin (pi / 4)"
  3232   have nonneg: "0 \<le> ?c"
  3233     by (simp add: cos_ge_zero)
  3234   have "0 = cos (pi / 4 + pi / 4)"
  3235     by simp
  3236   also have "cos (pi / 4 + pi / 4) = ?c\<twosuperior> - ?s\<twosuperior>"
  3237     by (simp only: cos_add power2_eq_square)
  3238   also have "\<dots> = 2 * ?c\<twosuperior> - 1"
  3239     by (simp add: sin_squared_eq)
  3240   finally have "?c\<twosuperior> = (sqrt 2 / 2)\<twosuperior>"
  3241     by (simp add: power_divide)
  3242   thus ?thesis
  3243     using nonneg by (rule power2_eq_imp_eq) simp
  3244 qed
  3245 
  3246 lemma cos_30: "cos (pi / 6) = sqrt 3 / 2"
  3247 proof -
  3248   let ?c = "cos (pi / 6)" and ?s = "sin (pi / 6)"
  3249   have pos_c: "0 < ?c"
  3250     by (rule cos_gt_zero, simp, simp)
  3251   have "0 = cos (pi / 6 + pi / 6 + pi / 6)"
  3252     by simp
  3253   also have "\<dots> = (?c * ?c - ?s * ?s) * ?c - (?s * ?c + ?c * ?s) * ?s"
  3254     by (simp only: cos_add sin_add)
  3255   also have "\<dots> = ?c * (?c\<twosuperior> - 3 * ?s\<twosuperior>)"
  3256     by (simp add: algebra_simps power2_eq_square)
  3257   finally have "?c\<twosuperior> = (sqrt 3 / 2)\<twosuperior>"
  3258     using pos_c by (simp add: sin_squared_eq power_divide)
  3259   thus ?thesis
  3260     using pos_c [THEN order_less_imp_le]
  3261     by (rule power2_eq_imp_eq) simp
  3262 qed
  3263 
  3264 lemma sin_45: "sin (pi / 4) = sqrt 2 / 2"
  3265 by (simp add: sin_cos_eq cos_45)
  3266 
  3267 lemma sin_60: "sin (pi / 3) = sqrt 3 / 2"
  3268 by (simp add: sin_cos_eq cos_30)
  3269 
  3270 lemma cos_60: "cos (pi / 3) = 1 / 2"
  3271 apply (rule power2_eq_imp_eq)
  3272 apply (simp add: cos_squared_eq sin_60 power_divide)
  3273 apply (rule cos_ge_zero, rule order_trans [where y=0], simp_all)
  3274 done
  3275 
  3276 lemma sin_30: "sin (pi / 6) = 1 / 2"
  3277 by (simp add: sin_cos_eq cos_60)
  3278 
  3279 lemma tan_30: "tan (pi / 6) = 1 / sqrt 3"
  3280 unfolding tan_def by (simp add: sin_30 cos_30)
  3281 
  3282 lemma tan_45: "tan (pi / 4) = 1"
  3283 unfolding tan_def by (simp add: sin_45 cos_45)
  3284 
  3285 lemma tan_60: "tan (pi / 3) = sqrt 3"
  3286 unfolding tan_def by (simp add: sin_60 cos_60)
  3287 
  3288 lemma sin_cos_npi [simp]: "sin (real (Suc (2 * n)) * pi / 2) = (-1) ^ n"
  3289 proof -
  3290   have "sin ((real n + 1/2) * pi) = cos (real n * pi)"
  3291     by (auto simp add: algebra_simps sin_add)
  3292   thus ?thesis
  3293     by (simp add: real_of_nat_Suc distrib_right add_divide_distrib
  3294                   mult_commute [of pi])
  3295 qed
  3296 
  3297 lemma cos_2npi [simp]: "cos (2 * real (n::nat) * pi) = 1"
  3298 by (simp add: cos_double mult_assoc power_add [symmetric] numeral_2_eq_2)
  3299 
  3300 lemma cos_3over2_pi [simp]: "cos (3 / 2 * pi) = 0"
  3301 apply (subgoal_tac "cos (pi + pi/2) = 0", simp)
  3302 apply (subst cos_add, simp)
  3303 done
  3304 
  3305 lemma sin_2npi [simp]: "sin (2 * real (n::nat) * pi) = 0"
  3306 by (auto simp add: mult_assoc)
  3307 
  3308 lemma sin_3over2_pi [simp]: "sin (3 / 2 * pi) = - 1"
  3309 apply (subgoal_tac "sin (pi + pi/2) = - 1", simp)
  3310 apply (subst sin_add, simp)
  3311 done
  3312 
  3313 lemma cos_pi_eq_zero [simp]: "cos (pi * real (Suc (2 * m)) / 2) = 0"
  3314 by (simp only: cos_add sin_add real_of_nat_Suc distrib_right distrib_left add_divide_distrib, auto)
  3315 
  3316 lemma DERIV_cos_add [simp]: "DERIV (%x. cos (x + k)) xa :> - sin (xa + k)"
  3317   by (auto intro!: DERIV_intros)
  3318 
  3319 lemma sin_zero_abs_cos_one: "sin x = 0 ==> \<bar>cos x\<bar> = 1"
  3320 by (auto simp add: sin_zero_iff even_mult_two_ex)
  3321 
  3322 lemma cos_one_sin_zero: "cos x = 1 ==> sin x = 0"
  3323 by (cut_tac x = x in sin_cos_squared_add3, auto)
  3324 
  3325 subsection {* Machins formula *}
  3326 
  3327 lemma arctan_one: "arctan 1 = pi / 4"
  3328   by (rule arctan_unique, simp_all add: tan_45 m2pi_less_pi)
  3329 
  3330 lemma tan_total_pi4: assumes "\<bar>x\<bar> < 1"
  3331   shows "\<exists> z. - (pi / 4) < z \<and> z < pi / 4 \<and> tan z = x"
  3332 proof
  3333   show "- (pi / 4) < arctan x \<and> arctan x < pi / 4 \<and> tan (arctan x) = x"
  3334     unfolding arctan_one [symmetric] arctan_minus [symmetric]
  3335     unfolding arctan_less_iff using assms by auto
  3336 qed
  3337 
  3338 lemma arctan_add: assumes "\<bar>x\<bar> \<le> 1" and "\<bar>y\<bar> < 1"
  3339   shows "arctan x + arctan y = arctan ((x + y) / (1 - x * y))"
  3340 proof (rule arctan_unique [symmetric])
  3341   have "- (pi / 4) \<le> arctan x" and "- (pi / 4) < arctan y"
  3342     unfolding arctan_one [symmetric] arctan_minus [symmetric]
  3343     unfolding arctan_le_iff arctan_less_iff using assms by auto
  3344   from add_le_less_mono [OF this]
  3345   show 1: "- (pi / 2) < arctan x + arctan y" by simp
  3346   have "arctan x \<le> pi / 4" and "arctan y < pi / 4"
  3347     unfolding arctan_one [symmetric]
  3348     unfolding arctan_le_iff arctan_less_iff using assms by auto
  3349   from add_le_less_mono [OF this]
  3350   show 2: "arctan x + arctan y < pi / 2" by simp
  3351   show "tan (arctan x + arctan y) = (x + y) / (1 - x * y)"
  3352     using cos_gt_zero_pi [OF 1 2] by (simp add: tan_add)
  3353 qed
  3354 
  3355 theorem machin: "pi / 4 = 4 * arctan (1/5) - arctan (1 / 239)"
  3356 proof -
  3357   have "\<bar>1 / 5\<bar> < (1 :: real)" by auto
  3358   from arctan_add[OF less_imp_le[OF this] this]
  3359   have "2 * arctan (1 / 5) = arctan (5 / 12)" by auto
  3360   moreover
  3361   have "\<bar>5 / 12\<bar> < (1 :: real)" by auto
  3362   from arctan_add[OF less_imp_le[OF this] this]
  3363   have "2 * arctan (5 / 12) = arctan (120 / 119)" by auto
  3364   moreover
  3365   have "\<bar>1\<bar> \<le> (1::real)" and "\<bar>1 / 239\<bar> < (1::real)" by auto
  3366   from arctan_add[OF this]
  3367   have "arctan 1 + arctan (1 / 239) = arctan (120 / 119)" by auto
  3368   ultimately have "arctan 1 + arctan (1 / 239) = 4 * arctan (1 / 5)" by auto
  3369   thus ?thesis unfolding arctan_one by algebra
  3370 qed
  3371 
  3372 subsection {* Introducing the arcus tangens power series *}
  3373 
  3374 lemma monoseq_arctan_series: fixes x :: real
  3375   assumes "\<bar>x\<bar> \<le> 1" shows "monoseq (\<lambda> n. 1 / real (n*2+1) * x^(n*2+1))" (is "monoseq ?a")
  3376 proof (cases "x = 0") case True thus ?thesis unfolding monoseq_def One_nat_def by auto
  3377 next
  3378   case False
  3379   have "norm x \<le> 1" and "x \<le> 1" and "-1 \<le> x" using assms by auto
  3380   show "monoseq ?a"
  3381   proof -
  3382     { fix n fix x :: real assume "0 \<le> x" and "x \<le> 1"
  3383       have "1 / real (Suc (Suc n * 2)) * x ^ Suc (Suc n * 2) \<le> 1 / real (Suc (n * 2)) * x ^ Suc (n * 2)"
  3384       proof (rule mult_mono)
  3385         show "1 / real (Suc (Suc n * 2)) \<le> 1 / real (Suc (n * 2))" by (rule frac_le) simp_all
  3386         show "0 \<le> 1 / real (Suc (n * 2))" by auto
  3387         show "x ^ Suc (Suc n * 2) \<le> x ^ Suc (n * 2)" by (rule power_decreasing) (simp_all add: `0 \<le> x` `x \<le> 1`)
  3388         show "0 \<le> x ^ Suc (Suc n * 2)" by (rule zero_le_power) (simp add: `0 \<le> x`)
  3389       qed
  3390     } note mono = this
  3391 
  3392     show ?thesis
  3393     proof (cases "0 \<le> x")
  3394       case True from mono[OF this `x \<le> 1`, THEN allI]
  3395       show ?thesis unfolding Suc_eq_plus1[symmetric] by (rule mono_SucI2)
  3396     next
  3397       case False hence "0 \<le> -x" and "-x \<le> 1" using `-1 \<le> x` by auto
  3398       from mono[OF this]
  3399       have "\<And>n. 1 / real (Suc (Suc n * 2)) * x ^ Suc (Suc n * 2) \<ge> 1 / real (Suc (n * 2)) * x ^ Suc (n * 2)" using `0 \<le> -x` by auto
  3400       thus ?thesis unfolding Suc_eq_plus1[symmetric] by (rule mono_SucI1[OF allI])
  3401     qed
  3402   qed
  3403 qed
  3404 
  3405 lemma zeroseq_arctan_series: fixes x :: real
  3406   assumes "\<bar>x\<bar> \<le> 1" shows "(\<lambda> n. 1 / real (n*2+1) * x^(n*2+1)) ----> 0" (is "?a ----> 0")
  3407 proof (cases "x = 0") case True thus ?thesis unfolding One_nat_def by (auto simp add: tendsto_const)
  3408 next
  3409   case False
  3410   have "norm x \<le> 1" and "x \<le> 1" and "-1 \<le> x" using assms by auto
  3411   show "?a ----> 0"
  3412   proof (cases "\<bar>x\<bar> < 1")
  3413     case True hence "norm x < 1" by auto
  3414     from tendsto_mult[OF LIMSEQ_inverse_real_of_nat LIMSEQ_power_zero[OF `norm x < 1`, THEN LIMSEQ_Suc]]
  3415     have "(\<lambda>n. 1 / real (n + 1) * x ^ (n + 1)) ----> 0"
  3416       unfolding inverse_eq_divide Suc_eq_plus1 by simp
  3417     then show ?thesis using pos2 by (rule LIMSEQ_linear)
  3418   next
  3419     case False hence "x = -1 \<or> x = 1" using `\<bar>x\<bar> \<le> 1` by auto
  3420     hence n_eq: "\<And> n. x ^ (n * 2 + 1) = x" unfolding One_nat_def by auto
  3421     from tendsto_mult[OF LIMSEQ_inverse_real_of_nat[THEN LIMSEQ_linear, OF pos2, unfolded inverse_eq_divide] tendsto_const[of x]]
  3422     show ?thesis unfolding n_eq Suc_eq_plus1 by auto
  3423   qed
  3424 qed
  3425 
  3426 lemma summable_arctan_series: fixes x :: real and n :: nat
  3427   assumes "\<bar>x\<bar> \<le> 1" shows "summable (\<lambda> k. (-1)^k * (1 / real (k*2+1) * x ^ (k*2+1)))" (is "summable (?c x)")
  3428   by (rule summable_Leibniz(1), rule zeroseq_arctan_series[OF assms], rule monoseq_arctan_series[OF assms])
  3429 
  3430 lemma less_one_imp_sqr_less_one: fixes x :: real assumes "\<bar>x\<bar> < 1" shows "x^2 < 1"
  3431 proof -
  3432   from mult_left_mono[OF less_imp_le[OF `\<bar>x\<bar> < 1`] abs_ge_zero[of x]]
  3433   have "\<bar> x^2 \<bar> < 1" using `\<bar> x \<bar> < 1` unfolding numeral_2_eq_2 power_Suc2 by auto
  3434   thus ?thesis using zero_le_power2 by auto
  3435 qed
  3436 
  3437 lemma DERIV_arctan_series: assumes "\<bar> x \<bar> < 1"
  3438   shows "DERIV (\<lambda> x'. \<Sum> k. (-1)^k * (1 / real (k*2+1) * x' ^ (k*2+1))) x :> (\<Sum> k. (-1)^k * x^(k*2))" (is "DERIV ?arctan _ :> ?Int")
  3439 proof -
  3440   let "?f n" = "if even n then (-1)^(n div 2) * 1 / real (Suc n) else 0"
  3441 
  3442   { fix n :: nat assume "even n" hence "2 * (n div 2) = n" by presburger } note n_even=this
  3443   have if_eq: "\<And> n x'. ?f n * real (Suc n) * x'^n = (if even n then (-1)^(n div 2) * x'^(2 * (n div 2)) else 0)" using n_even by auto
  3444 
  3445   { fix x :: real assume "\<bar>x\<bar> < 1" hence "x^2 < 1" by (rule less_one_imp_sqr_less_one)
  3446     have "summable (\<lambda> n. -1 ^ n * (x^2) ^n)"
  3447       by (rule summable_Leibniz(1), auto intro!: LIMSEQ_realpow_zero monoseq_realpow `x^2 < 1` order_less_imp_le[OF `x^2 < 1`])
  3448     hence "summable (\<lambda> n. -1 ^ n * x^(2*n))" unfolding power_mult .
  3449   } note summable_Integral = this
  3450 
  3451   { fix f :: "nat \<Rightarrow> real"
  3452     have "\<And> x. f sums x = (\<lambda> n. if even n then f (n div 2) else 0) sums x"
  3453     proof
  3454       fix x :: real assume "f sums x"
  3455       from sums_if[OF sums_zero this]
  3456       show "(\<lambda> n. if even n then f (n div 2) else 0) sums x" by auto
  3457     next
  3458       fix x :: real assume "(\<lambda> n. if even n then f (n div 2) else 0) sums x"
  3459       from LIMSEQ_linear[OF this[unfolded sums_def] pos2, unfolded sum_split_even_odd[unfolded mult_commute]]
  3460       show "f sums x" unfolding sums_def by auto
  3461     qed
  3462     hence "op sums f = op sums (\<lambda> n. if even n then f (n div 2) else 0)" ..
  3463   } note sums_even = this
  3464 
  3465   have Int_eq: "(\<Sum> n. ?f n * real (Suc n) * x^n) = ?Int" unfolding if_eq mult_commute[of _ 2] suminf_def sums_even[of "\<lambda> n. -1 ^ n * x ^ (2 * n)", symmetric]
  3466     by auto
  3467 
  3468   { fix x :: real
  3469     have if_eq': "\<And> n. (if even n then -1 ^ (n div 2) * 1 / real (Suc n) else 0) * x ^ Suc n =
  3470       (if even n then -1 ^ (n div 2) * (1 / real (Suc (2 * (n div 2))) * x ^ Suc (2 * (n div 2))) else 0)"
  3471       using n_even by auto
  3472     have idx_eq: "\<And> n. n * 2 + 1 = Suc (2 * n)" by auto
  3473     have "(\<Sum> n. ?f n * x^(Suc n)) = ?arctan x" unfolding if_eq' idx_eq suminf_def sums_even[of "\<lambda> n. -1 ^ n * (1 / real (Suc (2 * n)) * x ^ Suc (2 * n))", symmetric]
  3474       by auto
  3475   } note arctan_eq = this
  3476 
  3477   have "DERIV (\<lambda> x. \<Sum> n. ?f n * x^(Suc n)) x :> (\<Sum> n. ?f n * real (Suc n) * x^n)"
  3478   proof (rule DERIV_power_series')
  3479     show "x \<in> {- 1 <..< 1}" using `\<bar> x \<bar> < 1` by auto
  3480     { fix x' :: real assume x'_bounds: "x' \<in> {- 1 <..< 1}"
  3481       hence "\<bar>x'\<bar> < 1" by auto
  3482 
  3483       let ?S = "\<Sum> n. (-1)^n * x'^(2 * n)"
  3484       show "summable (\<lambda> n. ?f n * real (Suc n) * x'^n)" unfolding if_eq
  3485         by (rule sums_summable[where l="0 + ?S"], rule sums_if, rule sums_zero, rule summable_sums, rule summable_Integral[OF `\<bar>x'\<bar> < 1`])
  3486     }
  3487   qed auto
  3488   thus ?thesis unfolding Int_eq arctan_eq .
  3489 qed
  3490 
  3491 lemma arctan_series: assumes "\<bar> x \<bar> \<le> 1"
  3492   shows "arctan x = (\<Sum> k. (-1)^k * (1 / real (k*2+1) * x ^ (k*2+1)))" (is "_ = suminf (\<lambda> n. ?c x n)")
  3493 proof -
  3494   let "?c' x n" = "(-1)^n * x^(n*2)"
  3495 
  3496   { fix r x :: real assume "0 < r" and "r < 1" and "\<bar> x \<bar> < r"
  3497     have "\<bar>x\<bar> < 1" using `r < 1` and `\<bar>x\<bar> < r` by auto
  3498     from DERIV_arctan_series[OF this]
  3499     have "DERIV (\<lambda> x. suminf (?c x)) x :> (suminf (?c' x))" .
  3500   } note DERIV_arctan_suminf = this
  3501 
  3502   { fix x :: real assume "\<bar>x\<bar> \<le> 1" note summable_Leibniz[OF zeroseq_arctan_series[OF this] monoseq_arctan_series[OF this]] }
  3503   note arctan_series_borders = this
  3504 
  3505   { fix x :: real assume "\<bar>x\<bar> < 1" have "arctan x = (\<Sum> k. ?c x k)"
  3506   proof -
  3507     obtain r where "\<bar>x\<bar> < r" and "r < 1" using dense[OF `\<bar>x\<bar> < 1`] by blast
  3508     hence "0 < r" and "-r < x" and "x < r" by auto
  3509 
  3510     have suminf_eq_arctan_bounded: "\<And> x a b. \<lbrakk> -r < a ; b < r ; a < b ; a \<le> x ; x \<le> b \<rbrakk> \<Longrightarrow> suminf (?c x) - arctan x = suminf (?c a) - arctan a"
  3511     proof -
  3512       fix x a b assume "-r < a" and "b < r" and "a < b" and "a \<le> x" and "x \<le> b"
  3513       hence "\<bar>x\<bar> < r" by auto
  3514       show "suminf (?c x) - arctan x = suminf (?c a) - arctan a"
  3515       proof (rule DERIV_isconst2[of "a" "b"])
  3516         show "a < b" and "a \<le> x" and "x \<le> b" using `a < b` `a \<le> x` `x \<le> b` by auto
  3517         have "\<forall> x. -r < x \<and> x < r \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) x :> 0"
  3518         proof (rule allI, rule impI)
  3519           fix x assume "-r < x \<and> x < r" hence "\<bar>x\<bar> < r" by auto
  3520           hence "\<bar>x\<bar> < 1" using `r < 1` by auto
  3521           have "\<bar> - (x^2) \<bar> < 1" using less_one_imp_sqr_less_one[OF `\<bar>x\<bar> < 1`] by auto
  3522           hence "(\<lambda> n. (- (x^2)) ^ n) sums (1 / (1 - (- (x^2))))" unfolding real_norm_def[symmetric] by (rule geometric_sums)
  3523           hence "(?c' x) sums (1 / (1 - (- (x^2))))" unfolding power_mult_distrib[symmetric] power_mult nat_mult_commute[of _ 2] by auto
  3524           hence suminf_c'_eq_geom: "inverse (1 + x^2) = suminf (?c' x)" using sums_unique unfolding inverse_eq_divide by auto
  3525           have "DERIV (\<lambda> x. suminf (?c x)) x :> (inverse (1 + x^2))" unfolding suminf_c'_eq_geom
  3526             by (rule DERIV_arctan_suminf[OF `0 < r` `r < 1` `\<bar>x\<bar> < r`])
  3527           from DERIV_add_minus[OF this DERIV_arctan]
  3528           show "DERIV (\<lambda> x. suminf (?c x) - arctan x) x :> 0" unfolding diff_minus by auto
  3529         qed
  3530         hence DERIV_in_rball: "\<forall> y. a \<le> y \<and> y \<le> b \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) y :> 0" using `-r < a` `b < r` by auto
  3531         thus "\<forall> y. a < y \<and> y < b \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) y :> 0" using `\<bar>x\<bar> < r` by auto
  3532         show "\<forall> y. a \<le> y \<and> y \<le> b \<longrightarrow> isCont (\<lambda> x. suminf (?c x) - arctan x) y" using DERIV_in_rball DERIV_isCont by auto
  3533       qed
  3534     qed
  3535 
  3536     have suminf_arctan_zero: "suminf (?c 0) - arctan 0 = 0"
  3537       unfolding Suc_eq_plus1[symmetric] power_Suc2 mult_zero_right arctan_zero_zero suminf_zero by auto
  3538 
  3539     have "suminf (?c x) - arctan x = 0"
  3540     proof (cases "x = 0")
  3541       case True thus ?thesis using suminf_arctan_zero by auto
  3542     next
  3543       case False hence "0 < \<bar>x\<bar>" and "- \<bar>x\<bar> < \<bar>x\<bar>" by auto
  3544       have "suminf (?c (-\<bar>x\<bar>)) - arctan (-\<bar>x\<bar>) = suminf (?c 0) - arctan 0"
  3545         by (rule suminf_eq_arctan_bounded[where x="0" and a="-\<bar>x\<bar>" and b="\<bar>x\<bar>", symmetric])
  3546           (simp_all only: `\<bar>x\<bar> < r` `-\<bar>x\<bar> < \<bar>x\<bar>` neg_less_iff_less)
  3547       moreover
  3548       have "suminf (?c x) - arctan x = suminf (?c (-\<bar>x\<bar>)) - arctan (-\<bar>x\<bar>)"
  3549         by (rule suminf_eq_arctan_bounded[where x="x" and a="-\<bar>x\<bar>" and b="\<bar>x\<bar>"])
  3550           (simp_all only: `\<bar>x\<bar> < r` `-\<bar>x\<bar> < \<bar>x\<bar>` neg_less_iff_less)
  3551       ultimately
  3552       show ?thesis using suminf_arctan_zero by auto
  3553     qed
  3554     thus ?thesis by auto
  3555   qed } note when_less_one = this
  3556 
  3557   show "arctan x = suminf (\<lambda> n. ?c x n)"
  3558   proof (cases "\<bar>x\<bar> < 1")
  3559     case True thus ?thesis by (rule when_less_one)
  3560   next case False hence "\<bar>x\<bar> = 1" using `\<bar>x\<bar> \<le> 1` by auto
  3561     let "?a x n" = "\<bar>1 / real (n*2+1) * x^(n*2+1)\<bar>"
  3562     let "?diff x n" = "\<bar> arctan x - (\<Sum> i = 0..<n. ?c x i)\<bar>"
  3563     { fix n :: nat
  3564       have "0 < (1 :: real)" by auto
  3565       moreover
  3566       { fix x :: real assume "0 < x" and "x < 1" hence "\<bar>x\<bar> \<le> 1" and "\<bar>x\<bar> < 1" by auto
  3567         from `0 < x` have "0 < 1 / real (0 * 2 + (1::nat)) * x ^ (0 * 2 + 1)" by auto
  3568         note bounds = mp[OF arctan_series_borders(2)[OF `\<bar>x\<bar> \<le> 1`] this, unfolded when_less_one[OF `\<bar>x\<bar> < 1`, symmetric], THEN spec]
  3569         have "0 < 1 / real (n*2+1) * x^(n*2+1)" by (rule mult_pos_pos, auto simp only: zero_less_power[OF `0 < x`], auto)
  3570         hence a_pos: "?a x n = 1 / real (n*2+1) * x^(n*2+1)" by (rule abs_of_pos)
  3571         have "?diff x n \<le> ?a x n"
  3572         proof (cases "even n")
  3573           case True hence sgn_pos: "(-1)^n = (1::real)" by auto
  3574           from `even n` obtain m where "2 * m = n" unfolding even_mult_two_ex by auto
  3575           from bounds[of m, unfolded this atLeastAtMost_iff]
  3576           have "\<bar>arctan x - (\<Sum>i = 0..<n. (?c x i))\<bar> \<le> (\<Sum>i = 0..<n + 1. (?c x i)) - (\<Sum>i = 0..<n. (?c x i))" by auto
  3577           also have "\<dots> = ?c x n" unfolding One_nat_def by auto
  3578           also have "\<dots> = ?a x n" unfolding sgn_pos a_pos by auto
  3579           finally show ?thesis .
  3580         next
  3581           case False hence sgn_neg: "(-1)^n = (-1::real)" by auto
  3582           from `odd n` obtain m where m_def: "2 * m + 1 = n" unfolding odd_Suc_mult_two_ex by auto
  3583           hence m_plus: "2 * (m + 1) = n + 1" by auto
  3584           from bounds[of "m + 1", unfolded this atLeastAtMost_iff, THEN conjunct1] bounds[of m, unfolded m_def atLeastAtMost_iff, THEN conjunct2]
  3585           have "\<bar>arctan x - (\<Sum>i = 0..<n. (?c x i))\<bar> \<le> (\<Sum>i = 0..<n. (?c x i)) - (\<Sum>i = 0..<n+1. (?c x i))" by auto
  3586           also have "\<dots> = - ?c x n" unfolding One_nat_def by auto
  3587           also have "\<dots> = ?a x n" unfolding sgn_neg a_pos by auto
  3588           finally show ?thesis .
  3589         qed
  3590         hence "0 \<le> ?a x n - ?diff x n" by auto
  3591       }
  3592       hence "\<forall> x \<in> { 0 <..< 1 }. 0 \<le> ?a x n - ?diff x n" by auto
  3593       moreover have "\<And>x. isCont (\<lambda> x. ?a x n - ?diff x n) x"
  3594         unfolding diff_minus divide_inverse
  3595         by (auto intro!: isCont_add isCont_rabs isCont_ident isCont_minus isCont_arctan isCont_inverse isCont_mult isCont_power isCont_const isCont_setsum)
  3596       ultimately have "0 \<le> ?a 1 n - ?diff 1 n" by (rule LIM_less_bound)
  3597       hence "?diff 1 n \<le> ?a 1 n" by auto
  3598     }
  3599     have "?a 1 ----> 0"
  3600       unfolding tendsto_rabs_zero_iff power_one divide_inverse One_nat_def
  3601       by (auto intro!: tendsto_mult LIMSEQ_linear LIMSEQ_inverse_real_of_nat)
  3602     have "?diff 1 ----> 0"
  3603     proof (rule LIMSEQ_I)
  3604       fix r :: real assume "0 < r"
  3605       obtain N :: nat where N_I: "\<And> n. N \<le> n \<Longrightarrow> ?a 1 n < r" using LIMSEQ_D[OF `?a 1 ----> 0` `0 < r`] by auto
  3606       { fix n assume "N \<le> n" from `?diff 1 n \<le> ?a 1 n` N_I[OF this]
  3607         have "norm (?diff 1 n - 0) < r" by auto }
  3608       thus "\<exists> N. \<forall> n \<ge> N. norm (?diff 1 n - 0) < r" by blast
  3609     qed
  3610     from this [unfolded tendsto_rabs_zero_iff, THEN tendsto_add [OF _ tendsto_const], of "- arctan 1", THEN tendsto_minus]
  3611     have "(?c 1) sums (arctan 1)" unfolding sums_def by auto
  3612     hence "arctan 1 = (\<Sum> i. ?c 1 i)" by (rule sums_unique)
  3613 
  3614     show ?thesis
  3615     proof (cases "x = 1", simp add: `arctan 1 = (\<Sum> i. ?c 1 i)`)
  3616       assume "x \<noteq> 1" hence "x = -1" using `\<bar>x\<bar> = 1` by auto
  3617 
  3618       have "- (pi / 2) < 0" using pi_gt_zero by auto
  3619       have "- (2 * pi) < 0" using pi_gt_zero by auto
  3620 
  3621       have c_minus_minus: "\<And> i. ?c (- 1) i = - ?c 1 i" unfolding One_nat_def by auto
  3622 
  3623       have "arctan (- 1) = arctan (tan (-(pi / 4)))" unfolding tan_45 tan_minus ..
  3624       also have "\<dots> = - (pi / 4)" by (rule arctan_tan, auto simp add: order_less_trans[OF `- (pi / 2) < 0` pi_gt_zero])
  3625       also have "\<dots> = - (arctan (tan (pi / 4)))" unfolding neg_equal_iff_equal by (rule arctan_tan[symmetric], auto simp add: order_less_trans[OF `- (2 * pi) < 0` pi_gt_zero])
  3626       also have "\<dots> = - (arctan 1)" unfolding tan_45 ..
  3627       also have "\<dots> = - (\<Sum> i. ?c 1 i)" using `arctan 1 = (\<Sum> i. ?c 1 i)` by auto
  3628       also have "\<dots> = (\<Sum> i. ?c (- 1) i)" using suminf_minus[OF sums_summable[OF `(?c 1) sums (arctan 1)`]] unfolding c_minus_minus by auto
  3629       finally show ?thesis using `x = -1` by auto
  3630     qed
  3631   qed
  3632 qed
  3633 
  3634 lemma arctan_half: fixes x :: real
  3635   shows "arctan x = 2 * arctan (x / (1 + sqrt(1 + x^2)))"
  3636 proof -
  3637   obtain y where low: "- (pi / 2) < y" and high: "y < pi / 2" and y_eq: "tan y = x" using tan_total by blast
  3638   hence low2: "- (pi / 2) < y / 2" and high2: "y / 2 < pi / 2" by auto
  3639 
  3640   have divide_nonzero_divide: "\<And> A B C :: real. C \<noteq> 0 \<Longrightarrow> A / B = (A / C) / (B / C)" by auto
  3641 
  3642   have "0 < cos y" using cos_gt_zero_pi[OF low high] .
  3643   hence "cos y \<noteq> 0" and cos_sqrt: "sqrt ((cos y) ^ 2) = cos y" by auto
  3644 
  3645   have "1 + (tan y)^2 = 1 + sin y^2 / cos y^2" unfolding tan_def power_divide ..
  3646   also have "\<dots> = cos y^2 / cos y^2 + sin y^2 / cos y^2" using `cos y \<noteq> 0` by auto
  3647   also have "\<dots> = 1 / cos y^2" unfolding add_divide_distrib[symmetric] sin_cos_squared_add2 ..
  3648   finally have "1 + (tan y)^2 = 1 / cos y^2" .
  3649 
  3650   have "sin y / (cos y + 1) = tan y / ((cos y + 1) / cos y)" unfolding tan_def divide_nonzero_divide[OF `cos y \<noteq> 0`, symmetric] ..
  3651   also have "\<dots> = tan y / (1 + 1 / cos y)" using `cos y \<noteq> 0` unfolding add_divide_distrib by auto
  3652   also have "\<dots> = tan y / (1 + 1 / sqrt(cos y^2))" unfolding cos_sqrt ..
  3653   also have "\<dots> = tan y / (1 + sqrt(1 / cos y^2))" unfolding real_sqrt_divide by auto
  3654   finally have eq: "sin y / (cos y + 1) = tan y / (1 + sqrt(1 + (tan y)^2))" unfolding `1 + (tan y)^2 = 1 / cos y^2` .
  3655 
  3656   have "arctan x = y" using arctan_tan low high y_eq by auto
  3657   also have "\<dots> = 2 * (arctan (tan (y/2)))" using arctan_tan[OF low2 high2] by auto
  3658   also have "\<dots> = 2 * (arctan (sin y / (cos y + 1)))" unfolding tan_half by auto
  3659   finally show ?thesis unfolding eq `tan y = x` .
  3660 qed
  3661 
  3662 lemma arctan_monotone: assumes "x < y"
  3663   shows "arctan x < arctan y"
  3664   using assms by (simp only: arctan_less_iff)
  3665 
  3666 lemma arctan_monotone': assumes "x \<le> y" shows "arctan x \<le> arctan y"
  3667   using assms by (simp only: arctan_le_iff)
  3668 
  3669 lemma arctan_inverse:
  3670   assumes "x \<noteq> 0" shows "arctan (1 / x) = sgn x * pi / 2 - arctan x"
  3671 proof (rule arctan_unique)
  3672   show "- (pi / 2) < sgn x * pi / 2 - arctan x"
  3673     using arctan_bounded [of x] assms
  3674     unfolding sgn_real_def
  3675     apply (auto simp add: algebra_simps)
  3676     apply (drule zero_less_arctan_iff [THEN iffD2])
  3677     apply arith
  3678     done
  3679   show "sgn x * pi / 2 - arctan x < pi / 2"
  3680     using arctan_bounded [of "- x"] assms
  3681     unfolding sgn_real_def arctan_minus
  3682     by auto
  3683   show "tan (sgn x * pi / 2 - arctan x) = 1 / x"
  3684     unfolding tan_inverse [of "arctan x", unfolded tan_arctan]
  3685     unfolding sgn_real_def
  3686     by (simp add: tan_def cos_arctan sin_arctan sin_diff cos_diff)
  3687 qed
  3688 
  3689 theorem pi_series: "pi / 4 = (\<Sum> k. (-1)^k * 1 / real (k*2+1))" (is "_ = ?SUM")
  3690 proof -
  3691   have "pi / 4 = arctan 1" using arctan_one by auto
  3692   also have "\<dots> = ?SUM" using arctan_series[of 1] by auto
  3693   finally show ?thesis by auto
  3694 qed
  3695 
  3696 subsection {* Existence of Polar Coordinates *}
  3697 
  3698 lemma cos_x_y_le_one: "\<bar>x / sqrt (x\<twosuperior> + y\<twosuperior>)\<bar> \<le> 1"
  3699 apply (rule power2_le_imp_le [OF _ zero_le_one])
  3700 apply (simp add: power_divide divide_le_eq not_sum_power2_lt_zero)
  3701 done
  3702 
  3703 lemma cos_arccos_abs: "\<bar>y\<bar> \<le> 1 \<Longrightarrow> cos (arccos y) = y"
  3704 by (simp add: abs_le_iff)
  3705 
  3706 lemma sin_arccos_abs: "\<bar>y\<bar> \<le> 1 \<Longrightarrow> sin (arccos y) = sqrt (1 - y\<twosuperior>)"
  3707 by (simp add: sin_arccos abs_le_iff)
  3708 
  3709 lemmas cos_arccos_lemma1 = cos_arccos_abs [OF cos_x_y_le_one]
  3710 
  3711 lemmas sin_arccos_lemma1 = sin_arccos_abs [OF cos_x_y_le_one]
  3712 
  3713 lemma polar_ex1:
  3714      "0 < y ==> \<exists>r a. x = r * cos a & y = r * sin a"
  3715 apply (rule_tac x = "sqrt (x\<twosuperior> + y\<twosuperior>)" in exI)
  3716 apply (rule_tac x = "arccos (x / sqrt (x\<twosuperior> + y\<twosuperior>))" in exI)
  3717 apply (simp add: cos_arccos_lemma1)
  3718 apply (simp add: sin_arccos_lemma1)
  3719 apply (simp add: power_divide)
  3720 apply (simp add: real_sqrt_mult [symmetric])
  3721 apply (simp add: right_diff_distrib)
  3722 done
  3723 
  3724 lemma polar_ex2:
  3725      "y < 0 ==> \<exists>r a. x = r * cos a & y = r * sin a"
  3726 apply (insert polar_ex1 [where x=x and y="-y"], simp, clarify)
  3727 apply (metis cos_minus minus_minus minus_mult_right sin_minus)
  3728 done
  3729 
  3730 lemma polar_Ex: "\<exists>r a. x = r * cos a & y = r * sin a"
  3731 apply (rule_tac x=0 and y=y in linorder_cases)
  3732 apply (erule polar_ex1)
  3733 apply (rule_tac x=x in exI, rule_tac x=0 in exI, simp)
  3734 apply (erule polar_ex2)
  3735 done
  3736 
  3737 end